qcsrc/server/bot/default/havocbot/roles.qc

   1 #include "roles.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "havocbot.qh"
   6
   7 #include "../cvars.qh"
   8
   9 #include "../bot.qh"
  10 #include "../navigation.qh"
  11
  12 .float max_armorvalue;
  13 .float havocbot_role_timeout;
  14
  15 .void(entity this) havocbot_previous_role;
  16 .void(entity this) havocbot_role;
  17
  18 void havocbot_goalrating_waypoints(entity this, float ratingscale, vector org, float sradius)
  19 {
  20         // rate waypoints only if there's no alternative goal
  21         if(navigation_bestgoal)
  22                 return;
  23
  24         float f;
  25         float range = 500;
  26         sradius = max(range, (0.5 + random() * 0.5) * sradius);
  27         while(sradius > 100)
  28         {
  29                 IL_EACH(g_waypoints, vdist(it.origin - org, <, sradius)
  30                         && vdist(it.origin - org, >, max(100, sradius - range))
  31                         && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
  32                 {
  33                         if(vdist(it.origin - this.wp_goal_prev0.origin, <, range * 1.5))
  34                                 f = 0.1;
  35                         else if(vdist(it.origin - this.wp_goal_prev1.origin, <, range * 1.5))
  36                                 f = 0.1;
  37                         else
  38                                 f = 0.5 + random() * 0.5;
  39                         navigation_routerating(this, it, ratingscale * f, 2000);
  40                 });
  41                 if(navigation_bestgoal)
  42                         break;
  43                 sradius -= range;
  44         }
  45 };
  46
  47 void havocbot_goalrating_items(entity this, float ratingscale, vector org, float sradius)
  48 {
  49         float rating, discard, friend_distance, enemy_distance;
  50         vector o;
  51         ratingscale = ratingscale * 0.0001; // items are rated around 10000 already
  52
  53         IL_EACH(g_items, it.bot_pickup,
  54         {
  55                 rating = 0;
  56
  57                 if(!it.solid)
  58                 {
  59                         if(!autocvar_bot_ai_timeitems)
  60                                 continue;
  61                         if(!it.scheduledrespawntime)
  62                                 continue;
  63                         if(it.respawntime < max(11, autocvar_bot_ai_timeitems_minrespawndelay))
  64                                 continue;
  65                         if(it.respawntimejitter && !it.itemdef.instanceOfPowerup)
  66                                 continue;
  67
  68                         float t = 0;
  69                         if(it.itemdef.instanceOfPowerup)
  70                                 t = bound(0, skill / 10, 1) * 6;
  71                         else if(skill >= 9)
  72                                 t = 4;
  73
  74                         if(time < it.scheduledrespawntime - t)
  75                                 continue;
  76
  77                         it.bot_pickup_respawning = true;
  78                 }
  79                 o = (it.absmin + it.absmax) * 0.5;
  80                 if(vdist(o - org, >, sradius) || (it == this.ignoregoal && time < this.ignoregoaltime) )
  81                         continue;
  82
  83                 // Check if the item can be picked up safely
  84                 if(it.classname == "droppedweapon")
  85                 {
  86                         if(!IS_ONGROUND(it))
  87                                 continue;
  88                         traceline(o, o + '0 0 -1500', true, NULL);
  89
  90                         if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(trace_endpos + '0 0 1')) & DPCONTENTS_LIQUIDSMASK)
  91                                 continue;
  92                         // this tracebox_hits_trigger_hurt call isn't needed:
  93                         // dropped weapons are removed as soon as they fall on a trigger_hurt
  94                         // and can't be rated while they are in the air
  95                         //if(tracebox_hits_trigger_hurt(it.origin, it.mins, it.maxs, trace_endpos))
  96                         //      continue;
  97                 }
  98                 else
  99                 {
 100                         // Ignore items under water
 101                         // TODO: can't .waterlevel be used here?
 102                         if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(it.origin + ((it.mins + it.maxs) * 0.5))) & DPCONTENTS_LIQUIDSMASK)
 103                                 continue;
 104                 }
 105
 106                 if(teamplay)
 107                 {
 108                         friend_distance = 10000; enemy_distance = 10000;
 109                         discard = false;
 110
 111                         entity picker = it;
 112                         FOREACH_CLIENT(IS_PLAYER(it) && it != this && !IS_DEAD(it),
 113                         {
 114                                 if ( it.team == this.team )
 115                                 {
 116                                         if ( !IS_REAL_CLIENT(it) || discard )
 117                                                 continue;
 118
 119                                         if( vdist(it.origin - o, >, friend_distance) )
 120                                                 continue;
 121
 122                                         friend_distance = vlen(it.origin - o); // distance between player and item
 123                                         discard = true;
 124
 125                                         if (picker.health && it.health > this.health) continue;
 126                                         if (picker.armorvalue && it.armorvalue > this.armorvalue) continue;
 127
 128                                         if (picker.weapons && (picker.weapons & ~it.weapons)) continue;
 129
 130                                         if (picker.ammo_shells && it.ammo_shells > this.ammo_shells) continue;
 131                                         if (picker.ammo_nails && it.ammo_nails > this.ammo_nails) continue;
 132                                         if (picker.ammo_rockets && it.ammo_rockets > this.ammo_rockets) continue;
 133                                         if (picker.ammo_cells && it.ammo_cells > this.ammo_cells) continue;
 134                                         if (picker.ammo_plasma && it.ammo_plasma > this.ammo_plasma) continue;
 135
 136                                         discard = false;
 137                                 }
 138                                 else
 139                                 {
 140                                         // If enemy only track distances
 141                                         // TODO: track only if visible ?
 142                                         if( vdist(it.origin - o, <, enemy_distance) )
 143                                                 enemy_distance = vlen(it.origin - o); // distance between player and item
 144                                 }
 145                         });
 146
 147                         // Rate the item only if no one needs it, or if an enemy is closer to it
 148                         if ( (enemy_distance < friend_distance && vdist(o - org, <, enemy_distance)) ||
 149                                 (friend_distance > autocvar_bot_ai_friends_aware_pickup_radius ) || !discard )
 150                                 rating = it.bot_pickupevalfunc(this, it);
 151                 }
 152                 else
 153                         rating = it.bot_pickupevalfunc(this, it);
 154
 155                 if(rating > 0)
 156                         navigation_routerating(this, it, rating * ratingscale, 2000);
 157         });
 158 }
 159
 160 #define BOT_RATING_ENEMY 2500
 161 void havocbot_goalrating_enemyplayers(entity this, float ratingscale, vector org, float sradius)
 162 {
 163         if (autocvar_bot_nofire)
 164                 return;
 165
 166         // don't chase players if we're under water
 167         if(this.waterlevel>WATERLEVEL_WETFEET)
 168                 return;
 169
 170         ratingscale = ratingscale * 0.00005; // enemies are rated around 20000 already
 171
 172         float t;
 173         FOREACH_CLIENT(IS_PLAYER(it) && bot_shouldattack(this, it), {
 174                 // TODO: Merge this logic with the bot_shouldattack function
 175                 if(vdist(it.origin - org, <, 100) || vdist(it.origin - org, >, sradius))
 176                         continue;
 177
 178                 // rate only visible enemies
 179                 /*
 180                 traceline(this.origin + this.view_ofs, it.origin, MOVE_NOMONSTERS, this);
 181                 if (trace_fraction < 1 || trace_ent != it)
 182                         continue;
 183                 */
 184
 185                 t = ((this.health + this.armorvalue) - (it.health + it.armorvalue)) / 150;
 186                 t = bound(0, 1 + t, 3);
 187                 if (skill > 3)
 188                 {
 189                         if (time < this.strength_finished - 1) t += 0.5;
 190                         if (time < it.strength_finished - 1) t -= 0.5;
 191                 }
 192                 t += max(0, 8 - skill) * 0.05; // less skilled bots attack more mindlessly
 193                 ratingscale *= t;
 194                 if (ratingscale > 0)
 195                         navigation_routerating(this, it, ratingscale * BOT_RATING_ENEMY, 2000);
 196         });
 197 }
 198
 199 // legacy bot role for standard gamemodes
 200 // go to best items
 201 void havocbot_role_generic(entity this)
 202 {
 203         if(IS_DEAD(this))
 204                 return;
 205
 206         if (this.bot_strategytime < time)
 207         {
 208                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 209                 navigation_goalrating_start(this);
 210                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 211                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 10000);
 212                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 213                 navigation_goalrating_end(this);
 214
 215                 if(IS_PLAYER(this.goalentity))
 216                         this.bot_strategytime = time + min(2, autocvar_bot_ai_strategyinterval);
 217         }
 218 }
 219
 220 void havocbot_chooserole_generic(entity this)
 221 {
 222         this.havocbot_role = havocbot_role_generic;
 223 }
 224
 225 void havocbot_chooserole(entity this)
 226 {
 227         LOG_TRACE("choosing a role...");
 228         this.bot_strategytime = 0;
 229         if(!MUTATOR_CALLHOOK(HavocBot_ChooseRole, this))
 230                 havocbot_chooserole_generic(this);
 231 }