qcsrc/server/bot/default/havocbot/roles.qc

   1 #include "roles.qh"
   2
   3 #include "havocbot.qh"
   4
   5 #include "../cvars.qh"
   6
   7 #include "../bot.qh"
   8 #include "../navigation.qh"
   9
  10 .float max_armorvalue;
  11 .float havocbot_role_timeout;
  12
  13 .void(entity this) havocbot_previous_role;
  14 .void(entity this) havocbot_role;
  15
  16 void havocbot_goalrating_waypoints(entity this, float ratingscale, vector org, float sradius)
  17 {
  18         // rate waypoints only if there's no alternative goal
  19         if(navigation_bestgoal)
  20                 return;
  21
  22         float f;
  23         float range = 500;
  24         sradius = max(range, (0.5 + random() * 0.5) * sradius);
  25         while(sradius > 100)
  26         {
  27                 IL_EACH(g_waypoints, vdist(it.origin - org, <, sradius)
  28                         && vdist(it.origin - org, >, max(100, sradius - range))
  29                         && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
  30                 {
  31                         if(vdist(it.origin - this.wp_goal_prev0.origin, <, range * 1.5))
  32                                 f = 0.1;
  33                         else if(vdist(it.origin - this.wp_goal_prev1.origin, <, range * 1.5))
  34                                 f = 0.1;
  35                         else
  36                                 f = 0.5 + random() * 0.5;
  37                         navigation_routerating(this, it, ratingscale * f, 2000);
  38                 });
  39                 if(navigation_bestgoal)
  40                         break;
  41                 sradius -= range;
  42         }
  43 };
  44
  45 void havocbot_goalrating_items(entity this, float ratingscale, vector org, float sradius)
  46 {
  47         float rating, discard, friend_distance, enemy_distance;
  48         vector o;
  49         ratingscale = ratingscale * 0.0001; // items are rated around 10000 already
  50
  51         IL_EACH(g_items, it.bot_pickup,
  52         {
  53                 rating = 0;
  54
  55                 if(!it.solid)
  56                 {
  57                         if(!autocvar_bot_ai_timeitems)
  58                                 continue;
  59                         if(!it.scheduledrespawntime)
  60                                 continue;
  61                         if(it.respawntime < max(11, autocvar_bot_ai_timeitems_minrespawndelay))
  62                                 continue;
  63                         if(it.respawntimejitter && !it.itemdef.instanceOfPowerup)
  64                                 continue;
  65
  66                         float t = 0;
  67                         if(it.itemdef.instanceOfPowerup)
  68                                 t = bound(0, skill / 10, 1) * 6;
  69                         else if(skill >= 9)
  70                                 t = 4;
  71
  72                         if(time < it.scheduledrespawntime - t)
  73                                 continue;
  74
  75                         it.bot_pickup_respawning = true;
  76                 }
  77                 o = (it.absmin + it.absmax) * 0.5;
  78                 if(vdist(o - org, >, sradius) || (it == this.ignoregoal && time < this.ignoregoaltime) )
  79                         continue;
  80
  81                 // Check if the item can be picked up safely
  82                 if(it.classname == "droppedweapon")
  83                 {
  84                         if(!IS_ONGROUND(it))
  85                                 continue;
  86                         traceline(o, o + '0 0 -1500', true, NULL);
  87
  88                         if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(trace_endpos + '0 0 1')) & DPCONTENTS_LIQUIDSMASK)
  89                                 continue;
  90                         // this tracebox_hits_trigger_hurt call isn't needed:
  91                         // dropped weapons are removed as soon as they fall on a trigger_hurt
  92                         // and can't be rated while they are in the air
  93                         //if(tracebox_hits_trigger_hurt(it.origin, it.mins, it.maxs, trace_endpos))
  94                         //      continue;
  95                 }
  96                 else
  97                 {
  98                         // Ignore items under water
  99                         // TODO: can't .waterlevel be used here?
 100                         if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(it.origin + ((it.mins + it.maxs) * 0.5))) & DPCONTENTS_LIQUIDSMASK)
 101                                 continue;
 102                 }
 103
 104                 if(teamplay)
 105                 {
 106                         friend_distance = 10000; enemy_distance = 10000;
 107                         discard = false;
 108
 109                         entity picker = it;
 110                         FOREACH_CLIENT(IS_PLAYER(it) && it != this && !IS_DEAD(it),
 111                         {
 112                                 if ( it.team == this.team )
 113                                 {
 114                                         if ( !IS_REAL_CLIENT(it) || discard )
 115                                                 continue;
 116
 117                                         if( vdist(it.origin - o, >, friend_distance) )
 118                                                 continue;
 119
 120                                         friend_distance = vlen(it.origin - o); // distance between player and item
 121                                         discard = true;
 122
 123                                         if (picker.health && it.health > this.health) continue;
 124                                         if (picker.armorvalue && it.armorvalue > this.armorvalue) continue;
 125
 126                                         if (picker.weapons && (picker.weapons & ~it.weapons)) continue;
 127
 128                                         if (picker.ammo_shells && it.ammo_shells > this.ammo_shells) continue;
 129                                         if (picker.ammo_nails && it.ammo_nails > this.ammo_nails) continue;
 130                                         if (picker.ammo_rockets && it.ammo_rockets > this.ammo_rockets) continue;
 131                                         if (picker.ammo_cells && it.ammo_cells > this.ammo_cells) continue;
 132                                         if (picker.ammo_plasma && it.ammo_plasma > this.ammo_plasma) continue;
 133
 134                                         discard = false;
 135                                 }
 136                                 else
 137                                 {
 138                                         // If enemy only track distances
 139                                         // TODO: track only if visible ?
 140                                         if( vdist(it.origin - o, <, enemy_distance) )
 141                                                 enemy_distance = vlen(it.origin - o); // distance between player and item
 142                                 }
 143                         });
 144
 145                         // Rate the item only if no one needs it, or if an enemy is closer to it
 146                         if ( (enemy_distance < friend_distance && vdist(o - org, <, enemy_distance)) ||
 147                                 (friend_distance > autocvar_bot_ai_friends_aware_pickup_radius ) || !discard )
 148                                 rating = it.bot_pickupevalfunc(this, it);
 149                 }
 150                 else
 151                         rating = it.bot_pickupevalfunc(this, it);
 152
 153                 if(rating > 0)
 154                         navigation_routerating(this, it, rating * ratingscale, 2000);
 155         });
 156 }
 157
 158 #define BOT_RATING_ENEMY 2500
 159 void havocbot_goalrating_enemyplayers(entity this, float ratingscale, vector org, float sradius)
 160 {
 161         if (autocvar_bot_nofire)
 162                 return;
 163
 164         // don't chase players if we're under water
 165         if(this.waterlevel>WATERLEVEL_WETFEET)
 166                 return;
 167
 168         ratingscale = ratingscale * 0.00005; // enemies are rated around 20000 already
 169
 170         float t;
 171         FOREACH_CLIENT(IS_PLAYER(it) && bot_shouldattack(this, it), LAMBDA(
 172                 // TODO: Merge this logic with the bot_shouldattack function
 173                 if(vdist(it.origin - org, <, 100) || vdist(it.origin - org, >, sradius))
 174                         continue;
 175
 176                 // rate only visible enemies
 177                 /*
 178                 traceline(this.origin + this.view_ofs, it.origin, MOVE_NOMONSTERS, this);
 179                 if (trace_fraction < 1 || trace_ent != it)
 180                         continue;
 181                 */
 182
 183                 t = ((this.health + this.armorvalue) - (it.health + it.armorvalue)) / 150;
 184                 t = bound(0, 1 + t, 3);
 185                 if (skill > 3)
 186                 {
 187                         if (time < this.strength_finished - 1) t += 0.5;
 188                         if (time < it.strength_finished - 1) t -= 0.5;
 189                 }
 190                 t += max(0, 8 - skill) * 0.05; // less skilled bots attack more mindlessly
 191                 ratingscale *= t;
 192                 if (ratingscale > 0)
 193                         navigation_routerating(this, it, ratingscale * BOT_RATING_ENEMY, 2000);
 194         ));
 195 }
 196
 197 // legacy bot role for standard gamemodes
 198 // go to best items
 199 void havocbot_role_generic(entity this)
 200 {
 201         if(IS_DEAD(this))
 202                 return;
 203
 204         if (this.bot_strategytime < time)
 205         {
 206                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 207                 navigation_goalrating_start(this);
 208                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 209                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 10000);
 210                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 211                 navigation_goalrating_end(this);
 212
 213                 if(IS_PLAYER(this.goalentity))
 214                         this.bot_strategytime = time + min(2, autocvar_bot_ai_strategyinterval);
 215         }
 216 }
 217
 218 void havocbot_chooserole_generic(entity this)
 219 {
 220         this.havocbot_role = havocbot_role_generic;
 221 }
 222
 223 void havocbot_chooserole(entity this)
 224 {
 225         LOG_TRACE("choosing a role...");
 226         this.bot_strategytime = 0;
 227         if(!MUTATOR_CALLHOOK(HavocBot_ChooseRole, this))
 228                 havocbot_chooserole_generic(this);
 229 }