qcsrc/server/bot/default/scripting.qc

   1 #include "scripting.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include <common/state.qh>
   6 #include <common/physics/player.qh>
   7
   8 #include "bot.qh"
   9
  10 .int state;
  11
  12 .float bot_cmdqueuebuf_allocated;
  13 .float bot_cmdqueuebuf;
  14 .float bot_cmdqueuebuf_start;
  15 .float bot_cmdqueuebuf_end;
  16
  17 void bot_clearqueue(entity bot)
  18 {
  19         if(!bot.bot_cmdqueuebuf_allocated)
  20                 return;
  21         buf_del(bot.bot_cmdqueuebuf);
  22         bot.bot_cmdqueuebuf_allocated = false;
  23         LOG_TRACE("bot ", bot.netname, " queue cleared");
  24 }
  25
  26 void bot_queuecommand(entity bot, string cmdstring)
  27 {
  28         if(!bot.bot_cmdqueuebuf_allocated)
  29         {
  30                 bot.bot_cmdqueuebuf = buf_create();
  31                 bot.bot_cmdqueuebuf_allocated = true;
  32                 bot.bot_cmdqueuebuf_start = 0;
  33                 bot.bot_cmdqueuebuf_end = 0;
  34         }
  35
  36         bufstr_set(bot.bot_cmdqueuebuf, bot.bot_cmdqueuebuf_end, cmdstring);
  37
  38         // if the command was a "sound" command, precache the sound NOW
  39         // this prevents lagging!
  40         {
  41                 float sp;
  42                 string parm;
  43                 string cmdstr;
  44
  45                 sp = strstrofs(cmdstring, " ", 0);
  46                 if(sp >= 0)
  47                 {
  48                         parm = substring(cmdstring, sp + 1, -1);
  49                         cmdstr = substring(cmdstring, 0, sp);
  50                         if(cmdstr == "sound")
  51                         {
  52                                 // find the LAST word
  53                                 for (;;)
  54                                 {
  55                                         sp = strstrofs(parm, " ", 0);
  56                                         if(sp < 0)
  57                                                 break;
  58                                         parm = substring(parm, sp + 1, -1);
  59                                 }
  60                                 precache_sound(parm);
  61                         }
  62                 }
  63         }
  64
  65         bot.bot_cmdqueuebuf_end += 1;
  66 }
  67
  68 void bot_dequeuecommand(entity bot, float idx)
  69 {
  70         if(!bot.bot_cmdqueuebuf_allocated)
  71                 error("dequeuecommand but no queue allocated");
  72         if(idx < bot.bot_cmdqueuebuf_start)
  73                 error("dequeueing a command in the past");
  74         if(idx >= bot.bot_cmdqueuebuf_end)
  75                 error("dequeueing a command in the future");
  76         bufstr_set(bot.bot_cmdqueuebuf, idx, "");
  77         if(idx == bot.bot_cmdqueuebuf_start)
  78                 bot.bot_cmdqueuebuf_start += 1;
  79         if(bot.bot_cmdqueuebuf_start >= bot.bot_cmdqueuebuf_end)
  80                 bot_clearqueue(bot);
  81 }
  82
  83 string bot_readcommand(entity bot, float idx)
  84 {
  85         if(!bot.bot_cmdqueuebuf_allocated)
  86                 error("readcommand but no queue allocated");
  87         if(idx < bot.bot_cmdqueuebuf_start)
  88                 error("reading a command in the past");
  89         if(idx >= bot.bot_cmdqueuebuf_end)
  90                 error("reading a command in the future");
  91         return bufstr_get(bot.bot_cmdqueuebuf, idx);
  92 }
  93
  94 bool bot_havecommand(entity this, int idx)
  95 {
  96         if(!this.bot_cmdqueuebuf_allocated)
  97                 return false;
  98         if(idx < this.bot_cmdqueuebuf_start)
  99                 return false;
 100         if(idx >= this.bot_cmdqueuebuf_end)
 101                 return false;
 102         return true;
 103 }
 104
 105 const int MAX_BOT_PLACES = 4;
 106 .float bot_places_count;
 107 .entity bot_places[MAX_BOT_PLACES];
 108 .string bot_placenames[MAX_BOT_PLACES];
 109 entity bot_getplace(entity this, string placename)
 110 {
 111         entity e;
 112         if(substring(placename, 0, 1) == "@")
 113         {
 114                 int i, p;
 115                 placename = substring(placename, 1, -1);
 116                 string s, s2;
 117                 for(i = 0; i < this.bot_places_count; ++i)
 118                         if(this.(bot_placenames[i]) == placename)
 119                                 return this.(bot_places[i]);
 120                 // now: i == this.bot_places_count
 121                 s = s2 = cvar_string(placename);
 122                 p = strstrofs(s2, " ", 0);
 123                 if(p >= 0)
 124                 {
 125                         s = substring(s2, 0, p);
 126                         //print("places: ", placename, " -> ", cvar_string(placename), "\n");
 127                         cvar_set(placename, strcat(substring(s2, p+1, -1), " ", s));
 128                         //print("places: ", placename, " := ", cvar_string(placename), "\n");
 129                 }
 130                 e = find(NULL, targetname, s);
 131                 if(!e)
 132                         LOG_INFO("invalid place ", s, "\n");
 133                 if(i < MAX_BOT_PLACES)
 134                 {
 135                         this.(bot_placenames[i]) = strzone(placename);
 136                         this.(bot_places[i]) = e;
 137                         this.bot_places_count += 1;
 138                 }
 139                 return e;
 140         }
 141         else
 142         {
 143                 e = find(NULL, targetname, placename);
 144                 if(!e)
 145                         LOG_INFO("invalid place ", placename, "\n");
 146                 return e;
 147         }
 148 }
 149
 150
 151 // Initialize global commands list
 152 // NOTE: New commands should be initialized here
 153 void bot_commands_init()
 154 {
 155         bot_cmd_string[BOT_CMD_NULL] = "";
 156         bot_cmd_parm_type[BOT_CMD_NULL] = BOT_CMD_PARAMETER_NONE;
 157
 158         bot_cmd_string[BOT_CMD_PAUSE] = "pause";
 159         bot_cmd_parm_type[BOT_CMD_PAUSE] = BOT_CMD_PARAMETER_NONE;
 160
 161         bot_cmd_string[BOT_CMD_CONTINUE] = "continue";
 162         bot_cmd_parm_type[BOT_CMD_CONTINUE] = BOT_CMD_PARAMETER_NONE;
 163
 164         bot_cmd_string[BOT_CMD_WAIT] = "wait";
 165         bot_cmd_parm_type[BOT_CMD_WAIT] = BOT_CMD_PARAMETER_FLOAT;
 166
 167         bot_cmd_string[BOT_CMD_TURN] = "turn";
 168         bot_cmd_parm_type[BOT_CMD_TURN] = BOT_CMD_PARAMETER_FLOAT;
 169
 170         bot_cmd_string[BOT_CMD_MOVETO] = "moveto";
 171         bot_cmd_parm_type[BOT_CMD_MOVETO] = BOT_CMD_PARAMETER_VECTOR;
 172
 173         bot_cmd_string[BOT_CMD_MOVETOTARGET] = "movetotarget";
 174         bot_cmd_parm_type[BOT_CMD_MOVETOTARGET] = BOT_CMD_PARAMETER_STRING;
 175
 176         bot_cmd_string[BOT_CMD_RESETGOAL] = "resetgoal";
 177         bot_cmd_parm_type[BOT_CMD_RESETGOAL] = BOT_CMD_PARAMETER_NONE;
 178
 179         bot_cmd_string[BOT_CMD_CC] = "cc";
 180         bot_cmd_parm_type[BOT_CMD_CC] = BOT_CMD_PARAMETER_STRING;
 181
 182         bot_cmd_string[BOT_CMD_IF] = "if";
 183         bot_cmd_parm_type[BOT_CMD_IF] = BOT_CMD_PARAMETER_STRING;
 184
 185         bot_cmd_string[BOT_CMD_ELSE] = "else";
 186         bot_cmd_parm_type[BOT_CMD_ELSE] = BOT_CMD_PARAMETER_NONE;
 187
 188         bot_cmd_string[BOT_CMD_FI] = "fi";
 189         bot_cmd_parm_type[BOT_CMD_FI] = BOT_CMD_PARAMETER_NONE;
 190
 191         bot_cmd_string[BOT_CMD_RESETAIM] = "resetaim";
 192         bot_cmd_parm_type[BOT_CMD_RESETAIM] = BOT_CMD_PARAMETER_NONE;
 193
 194         bot_cmd_string[BOT_CMD_AIM] = "aim";
 195         bot_cmd_parm_type[BOT_CMD_AIM] = BOT_CMD_PARAMETER_STRING;
 196
 197         bot_cmd_string[BOT_CMD_AIMTARGET] = "aimtarget";
 198         bot_cmd_parm_type[BOT_CMD_AIMTARGET] = BOT_CMD_PARAMETER_STRING;
 199
 200         bot_cmd_string[BOT_CMD_PRESSKEY] = "presskey";
 201         bot_cmd_parm_type[BOT_CMD_PRESSKEY] = BOT_CMD_PARAMETER_STRING;
 202
 203         bot_cmd_string[BOT_CMD_RELEASEKEY] = "releasekey";
 204         bot_cmd_parm_type[BOT_CMD_RELEASEKEY] = BOT_CMD_PARAMETER_STRING;
 205
 206         bot_cmd_string[BOT_CMD_SELECTWEAPON] = "selectweapon";
 207         bot_cmd_parm_type[BOT_CMD_SELECTWEAPON] = BOT_CMD_PARAMETER_FLOAT;
 208
 209         bot_cmd_string[BOT_CMD_IMPULSE] = "impulse";
 210         bot_cmd_parm_type[BOT_CMD_IMPULSE] = BOT_CMD_PARAMETER_FLOAT;
 211
 212         bot_cmd_string[BOT_CMD_WAIT_UNTIL] = "wait_until";
 213         bot_cmd_parm_type[BOT_CMD_WAIT_UNTIL] = BOT_CMD_PARAMETER_FLOAT;
 214
 215         bot_cmd_string[BOT_CMD_BARRIER] = "barrier";
 216         bot_cmd_parm_type[BOT_CMD_BARRIER] = BOT_CMD_PARAMETER_NONE;
 217
 218         bot_cmd_string[BOT_CMD_CONSOLE] = "console";
 219         bot_cmd_parm_type[BOT_CMD_CONSOLE] = BOT_CMD_PARAMETER_STRING;
 220
 221         bot_cmd_string[BOT_CMD_SOUND] = "sound";
 222         bot_cmd_parm_type[BOT_CMD_SOUND] = BOT_CMD_PARAMETER_STRING;
 223
 224         bot_cmd_string[BOT_CMD_DEBUG_ASSERT_CANFIRE] = "debug_assert_canfire";
 225         bot_cmd_parm_type[BOT_CMD_DEBUG_ASSERT_CANFIRE] = BOT_CMD_PARAMETER_FLOAT;
 226
 227         bot_cmds_initialized = true;
 228 }
 229
 230 // Returns first bot with matching name
 231 entity find_bot_by_name(string name)
 232 {
 233         FOREACH_CLIENT(IS_BOT_CLIENT(it) && it.netname == name,
 234         {
 235                 return it;
 236         });
 237
 238         return NULL;
 239 }
 240
 241 // Returns a bot by number on list
 242 entity find_bot_by_number(float number)
 243 {
 244         entity bot;
 245         float c = 0;
 246
 247         if(!number)
 248                 return NULL;
 249
 250         bot = findchainflags(flags, FL_CLIENT); // TODO: doesn't findchainflags loop backwards through entities?
 251         while (bot)
 252         {
 253                 if(IS_BOT_CLIENT(bot))
 254                 {
 255                         if(++c==number)
 256                                 return bot;
 257                 }
 258                 bot = bot.chain;
 259         }
 260
 261         return NULL;
 262 }
 263
 264 float bot_decodecommand(string cmdstring)
 265 {
 266         float cmd_parm_type;
 267         float sp;
 268         string parm;
 269
 270         sp = strstrofs(cmdstring, " ", 0);
 271         if(sp < 0)
 272         {
 273                 parm = "";
 274         }
 275         else
 276         {
 277                 parm = substring(cmdstring, sp + 1, -1);
 278                 cmdstring = substring(cmdstring, 0, sp);
 279         }
 280
 281         if(!bot_cmds_initialized)
 282                 bot_commands_init();
 283
 284         int i;
 285         for(i=1;i<BOT_CMD_COUNTER;++i)
 286         {
 287                 if(bot_cmd_string[i]!=cmdstring)
 288                         continue;
 289
 290                 cmd_parm_type = bot_cmd_parm_type[i];
 291
 292                 if(cmd_parm_type!=BOT_CMD_PARAMETER_NONE&&parm=="")
 293                 {
 294                         LOG_INFO("ERROR: A parameter is required for this command\n");
 295                         return 0;
 296                 }
 297
 298                 // Load command into queue
 299                 bot_cmd.bot_cmd_type = i;
 300
 301                 // Attach parameter
 302                 switch(cmd_parm_type)
 303                 {
 304                         case BOT_CMD_PARAMETER_FLOAT:
 305                                 bot_cmd.bot_cmd_parm_float = stof(parm);
 306                                 break;
 307                         case BOT_CMD_PARAMETER_STRING:
 308                                 if(bot_cmd.bot_cmd_parm_string)
 309                                         strunzone(bot_cmd.bot_cmd_parm_string);
 310                                 bot_cmd.bot_cmd_parm_string = strzone(parm);
 311                                 break;
 312                         case BOT_CMD_PARAMETER_VECTOR:
 313                                 bot_cmd.bot_cmd_parm_vector = stov(parm);
 314                                 break;
 315                         default:
 316                                 break;
 317                 }
 318                 return 1;
 319         }
 320         LOG_INFO("ERROR: No such command '", cmdstring, "'\n");
 321         return 0;
 322 }
 323
 324 void bot_cmdhelp(string scmd)
 325 {
 326         int i, ntype;
 327         string stype;
 328
 329         if(!bot_cmds_initialized)
 330                 bot_commands_init();
 331
 332         for(i=1;i<BOT_CMD_COUNTER;++i)
 333         {
 334                 if(bot_cmd_string[i]!=scmd)
 335                         continue;
 336
 337                 ntype = bot_cmd_parm_type[i];
 338
 339                 switch(ntype)
 340                 {
 341                         case BOT_CMD_PARAMETER_FLOAT:
 342                                 stype = "float number";
 343                                 break;
 344                         case BOT_CMD_PARAMETER_STRING:
 345                                 stype = "string";
 346                                 break;
 347                         case BOT_CMD_PARAMETER_VECTOR:
 348                                 stype = "vector";
 349                                 break;
 350                         default:
 351                                 stype = "none";
 352                                 break;
 353                 }
 354
 355                 LOG_INFO(strcat("Command: ",bot_cmd_string[i],"\nParameter: <",stype,"> \n"));
 356
 357                 LOG_INFO("Description: ");
 358                 switch(i)
 359                 {
 360                         case BOT_CMD_PAUSE:
 361                                 LOG_INFO("Stops the bot completely. Any command other than 'continue' will be ignored.");
 362                                 break;
 363                         case BOT_CMD_CONTINUE:
 364                                 LOG_INFO("Disable paused status");
 365                                 break;
 366                         case BOT_CMD_WAIT:
 367                                 LOG_INFO("Pause command parsing and bot ai for N seconds. Pressed key will remain pressed");
 368                                 break;
 369                         case BOT_CMD_WAIT_UNTIL:
 370                                 LOG_INFO("Pause command parsing and bot ai until time is N from the last barrier. Pressed key will remain pressed");
 371                                 break;
 372                         case BOT_CMD_BARRIER:
 373                                 LOG_INFO("Waits till all bots that have a command queue reach this command. Pressed key will remain pressed");
 374                                 break;
 375                         case BOT_CMD_TURN:
 376                                 LOG_INFO("Look to the right or left N degrees. For turning to the left use positive numbers.");
 377                                 break;
 378                         case BOT_CMD_MOVETO:
 379                                 LOG_INFO("Walk to an specific coordinate on the map. Usage: moveto \"x y z\"");
 380                                 break;
 381                         case BOT_CMD_MOVETOTARGET:
 382                                 LOG_INFO("Walk to the specific target on the map");
 383                                 break;
 384                         case BOT_CMD_RESETGOAL:
 385                                 LOG_INFO("Resets the goal stack");
 386                                 break;
 387                         case BOT_CMD_CC:
 388                                 LOG_INFO("Execute client command. Examples: cc \"say something\"; cc god; cc \"name newnickname\"; cc kill;");
 389                                 break;
 390                         case BOT_CMD_IF:
 391                                 LOG_INFO("Perform simple conditional execution.\n");
 392                                 LOG_INFO("Syntax: \n");
 393                                 LOG_INFO("        sv_cmd .. if \"condition\"\n");
 394                                 LOG_INFO("        sv_cmd ..     <instruction if true>\n");
 395                                 LOG_INFO("        sv_cmd ..     <instruction if true>\n");
 396                                 LOG_INFO("        sv_cmd .. else\n");
 397                                 LOG_INFO("        sv_cmd ..     <instruction if false>\n");
 398                                 LOG_INFO("        sv_cmd ..     <instruction if false>\n");
 399                                 LOG_INFO("        sv_cmd .. fi\n");
 400                                 LOG_INFO("Conditions: a=b, a>b, a<b, a\t\t(spaces not allowed)\n");
 401                                 LOG_INFO("            Values in conditions can be numbers, cvars in the form cvar.cvar_string or special fields\n");
 402                                 LOG_INFO("Fields: health, speed, flagcarrier\n");
 403                                 LOG_INFO("Examples: if health>50; if health>cvar.g_balance_laser_primary_damage; if flagcarrier;");
 404                                 break;
 405                         case BOT_CMD_RESETAIM:
 406                                 LOG_INFO("Points the aim to the coordinates x,y 0,0");
 407                                 break;
 408                         case BOT_CMD_AIM:
 409                                 LOG_INFO("Move the aim x/y (horizontal/vertical) degrees relatives to the bot\n");
 410                                 LOG_INFO("There is a 3rd optional parameter telling in how many seconds the aim has to reach the new position\n");
 411                                 LOG_INFO("Examples: aim \"90 0\"        // Turn 90 degrees inmediately (positive numbers move to the left/up)\n");
 412                                 LOG_INFO("          aim \"0 90 2\"      // Will gradually look to the sky in the next two seconds");
 413                                 break;
 414                         case BOT_CMD_AIMTARGET:
 415                                 LOG_INFO("Points the aim to given target");
 416                                 break;
 417                         case BOT_CMD_PRESSKEY:
 418                                 LOG_INFO("Press one of the following keys: forward, backward, left, right, jump, crouch, attack1, attack2, use\n");
 419                                 LOG_INFO("Multiple keys can be pressed at time (with many presskey calls) and it will remain pressed until the command \"releasekey\" is called");
 420                                 LOG_INFO("Note: The script will not return the control to the bot ai until all keys are released");
 421                                 break;
 422                         case BOT_CMD_RELEASEKEY:
 423                                 LOG_INFO("Release previoulsy used keys. Use the parameter \"all\" to release all keys");
 424                                 break;
 425                         case BOT_CMD_SOUND:
 426                                 LOG_INFO("play sound file at bot location");
 427                                 break;
 428                         case BOT_CMD_DEBUG_ASSERT_CANFIRE:
 429                                 LOG_INFO("verify the state of the weapon entity");
 430                                 break;
 431                         default:
 432                                 LOG_INFO("This command has no description yet.");
 433                                 break;
 434                 }
 435                 LOG_INFO("\n");
 436         }
 437 }
 438
 439 void bot_list_commands()
 440 {
 441         int i;
 442         string ptype;
 443
 444         if(!bot_cmds_initialized)
 445                 bot_commands_init();
 446
 447         LOG_INFO("List of all available commands:\n");
 448         LOG_INFO("  Command - Parameter Type\n");
 449
 450         for(i=1;i<BOT_CMD_COUNTER;++i)
 451         {
 452                 switch(bot_cmd_parm_type[i])
 453                 {
 454                         case BOT_CMD_PARAMETER_FLOAT:
 455                                 ptype = "float number";
 456                                 break;
 457                         case BOT_CMD_PARAMETER_STRING:
 458                                 ptype = "string";
 459                                 break;
 460                         case BOT_CMD_PARAMETER_VECTOR:
 461                                 ptype = "vector";
 462                                 break;
 463                         default:
 464                                 ptype = "none";
 465                                 break;
 466                 }
 467                 LOG_INFO(strcat("  ",bot_cmd_string[i]," - <",ptype,"> \n"));
 468         }
 469 }
 470
 471 // Commands code
 472 .int bot_exec_status;
 473
 474 float bot_cmd_cc(entity this)
 475 {
 476         SV_ParseClientCommand(this, bot_cmd.bot_cmd_parm_string);
 477         return CMD_STATUS_FINISHED;
 478 }
 479
 480 float bot_cmd_impulse(entity this)
 481 {
 482         this.impulse = bot_cmd.bot_cmd_parm_float;
 483         return CMD_STATUS_FINISHED;
 484 }
 485
 486 float bot_cmd_continue(entity this)
 487 {
 488         this.bot_exec_status &= ~BOT_EXEC_STATUS_PAUSED;
 489         return CMD_STATUS_FINISHED;
 490 }
 491
 492 .float bot_cmd_wait_time;
 493 float bot_cmd_wait(entity this)
 494 {
 495         if(this.bot_exec_status & BOT_EXEC_STATUS_WAITING)
 496         {
 497                 if(time>=this.bot_cmd_wait_time)
 498                 {
 499                         this.bot_exec_status &= ~BOT_EXEC_STATUS_WAITING;
 500                         return CMD_STATUS_FINISHED;
 501                 }
 502                 else
 503                         return CMD_STATUS_EXECUTING;
 504         }
 505
 506         this.bot_cmd_wait_time = time + bot_cmd.bot_cmd_parm_float;
 507         this.bot_exec_status |= BOT_EXEC_STATUS_WAITING;
 508         return CMD_STATUS_EXECUTING;
 509 }
 510
 511 float bot_cmd_wait_until(entity this)
 512 {
 513         if(time < bot_cmd.bot_cmd_parm_float + bot_barriertime)
 514         {
 515                 this.bot_exec_status |= BOT_EXEC_STATUS_WAITING;
 516                 return CMD_STATUS_EXECUTING;
 517         }
 518         this.bot_exec_status &= ~BOT_EXEC_STATUS_WAITING;
 519         return CMD_STATUS_FINISHED;
 520 }
 521
 522 float bot_cmd_barrier(entity this)
 523 {
 524         // 0 = no barrier, 1 = waiting, 2 = waiting finished
 525
 526         if(this.bot_barrier == 0) // initialization
 527         {
 528                 this.bot_barrier = 1;
 529
 530                 //this.colormod = '4 4 0';
 531         }
 532
 533         if(this.bot_barrier == 1) // find other bots
 534         {
 535                 FOREACH_CLIENT(it.isbot, LAMBDA(
 536                         if(it.bot_cmdqueuebuf_allocated)
 537                         if(it.bot_barrier != 1)
 538                                 return CMD_STATUS_EXECUTING; // not all are at the barrier yet
 539                 ));
 540
 541                 // all bots hit the barrier!
 542
 543                 // acknowledge barrier
 544                 FOREACH_CLIENT(it.isbot, LAMBDA(it.bot_barrier = 2));
 545
 546                 bot_barriertime = time;
 547         }
 548
 549         // if we get here, the barrier is finished
 550         // so end it...
 551         this.bot_barrier = 0;
 552         //this.colormod = '0 0 0';
 553
 554         return CMD_STATUS_FINISHED;
 555 }
 556
 557 float bot_cmd_turn(entity this)
 558 {
 559         this.v_angle_y = this.v_angle.y + bot_cmd.bot_cmd_parm_float;
 560         this.v_angle_y = this.v_angle.y - floor(this.v_angle.y / 360) * 360;
 561         return CMD_STATUS_FINISHED;
 562 }
 563
 564 float bot_cmd_select_weapon(entity this)
 565 {
 566         float id = bot_cmd.bot_cmd_parm_float;
 567
 568         if(id < WEP_FIRST || id > WEP_LAST)
 569                 return CMD_STATUS_ERROR;
 570
 571         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 572
 573         if(client_hasweapon(this, Weapons_from(id), true, false))
 574                 this.(weaponentity).m_switchweapon = Weapons_from(id);
 575         else
 576                 return CMD_STATUS_ERROR;
 577
 578         return CMD_STATUS_FINISHED;
 579 }
 580
 581 .int bot_cmd_condition_status;
 582
 583 const int CMD_CONDITION_NONE = 0;
 584 const int CMD_CONDITION_true = 1;
 585 const int CMD_CONDITION_false = 2;
 586 const int CMD_CONDITION_true_BLOCK = 4;
 587 const int CMD_CONDITION_false_BLOCK = 8;
 588
 589 float bot_cmd_eval(entity this, string expr)
 590 {
 591         // Search for numbers
 592         if(IS_DIGIT(substring(expr, 0, 1)))
 593                 return stof(expr);
 594
 595         // Search for cvars
 596         if(substring(expr, 0, 5)=="cvar.")
 597                 return cvar(substring(expr, 5, strlen(expr)));
 598
 599         // Search for fields
 600         switch(expr)
 601         {
 602                 case "health":
 603                         return this.health;
 604                 case "speed":
 605                         return vlen(this.velocity);
 606                 case "flagcarrier":
 607                         return ((this.flagcarried!=NULL));
 608         }
 609
 610         LOG_INFO(strcat("ERROR: Unable to convert the expression '",expr,"' into a numeric value\n"));
 611         return 0;
 612 }
 613
 614 float bot_cmd_if(entity this)
 615 {
 616         string expr, val_a, val_b;
 617         float cmpofs;
 618
 619         if(this.bot_cmd_condition_status != CMD_CONDITION_NONE)
 620         {
 621                 // Only one "if" block is allowed at time
 622                 LOG_INFO("ERROR: Only one conditional block can be processed at time");
 623                 bot_clearqueue(this);
 624                 return CMD_STATUS_ERROR;
 625         }
 626
 627         this.bot_cmd_condition_status |= CMD_CONDITION_true_BLOCK;
 628
 629         // search for operators
 630         expr = bot_cmd.bot_cmd_parm_string;
 631
 632         cmpofs = strstrofs(expr,"=",0);
 633
 634         if(cmpofs>0)
 635         {
 636                 val_a = substring(expr,0,cmpofs);
 637                 val_b = substring(expr,cmpofs+1,strlen(expr));
 638
 639                 if(bot_cmd_eval(this, val_a)==bot_cmd_eval(this, val_b))
 640                         this.bot_cmd_condition_status |= CMD_CONDITION_true;
 641                 else
 642                         this.bot_cmd_condition_status |= CMD_CONDITION_false;
 643
 644                 return CMD_STATUS_FINISHED;
 645         }
 646
 647         cmpofs = strstrofs(expr,">",0);
 648
 649         if(cmpofs>0)
 650         {
 651                 val_a = substring(expr,0,cmpofs);
 652                 val_b = substring(expr,cmpofs+1,strlen(expr));
 653
 654                 if(bot_cmd_eval(this, val_a)>bot_cmd_eval(this, val_b))
 655                         this.bot_cmd_condition_status |= CMD_CONDITION_true;
 656                 else
 657                         this.bot_cmd_condition_status |= CMD_CONDITION_false;
 658
 659                 return CMD_STATUS_FINISHED;
 660         }
 661
 662         cmpofs = strstrofs(expr,"<",0);
 663
 664         if(cmpofs>0)
 665         {
 666                 val_a = substring(expr,0,cmpofs);
 667                 val_b = substring(expr,cmpofs+1,strlen(expr));
 668
 669                 if(bot_cmd_eval(this, val_a)<bot_cmd_eval(this, val_b))
 670                         this.bot_cmd_condition_status |= CMD_CONDITION_true;
 671                 else
 672                         this.bot_cmd_condition_status |= CMD_CONDITION_false;
 673
 674                 return CMD_STATUS_FINISHED;
 675         }
 676
 677         if(bot_cmd_eval(this, expr))
 678                 this.bot_cmd_condition_status |= CMD_CONDITION_true;
 679         else
 680                 this.bot_cmd_condition_status |= CMD_CONDITION_false;
 681
 682         return CMD_STATUS_FINISHED;
 683 }
 684
 685 float bot_cmd_else(entity this)
 686 {
 687         this.bot_cmd_condition_status &= ~CMD_CONDITION_true_BLOCK;
 688         this.bot_cmd_condition_status |= CMD_CONDITION_false_BLOCK;
 689         return CMD_STATUS_FINISHED;
 690 }
 691
 692 float bot_cmd_fi(entity this)
 693 {
 694         this.bot_cmd_condition_status = CMD_CONDITION_NONE;
 695         return CMD_STATUS_FINISHED;
 696 }
 697
 698 float bot_cmd_resetaim(entity this)
 699 {
 700         this.v_angle = '0 0 0';
 701         return CMD_STATUS_FINISHED;
 702 }
 703
 704 .float bot_cmd_aim_begintime;
 705 .float bot_cmd_aim_endtime;
 706 .vector bot_cmd_aim_begin;
 707 .vector bot_cmd_aim_end;
 708
 709 float bot_cmd_aim(entity this)
 710 {
 711         // Current direction
 712         if(this.bot_cmd_aim_endtime)
 713         {
 714                 float progress;
 715
 716                 progress = min(1 - (this.bot_cmd_aim_endtime - time) / (this.bot_cmd_aim_endtime - this.bot_cmd_aim_begintime),1);
 717                 this.v_angle = this.bot_cmd_aim_begin + ((this.bot_cmd_aim_end - this.bot_cmd_aim_begin) * progress);
 718
 719                 if(time>=this.bot_cmd_aim_endtime)
 720                 {
 721                         this.bot_cmd_aim_endtime = 0;
 722                         return CMD_STATUS_FINISHED;
 723                 }
 724                 else
 725                         return CMD_STATUS_EXECUTING;
 726         }
 727
 728         // New aiming direction
 729         string parms;
 730         float tokens, step;
 731
 732         parms = bot_cmd.bot_cmd_parm_string;
 733
 734         tokens = tokenizebyseparator(parms, " ");
 735
 736         if(tokens<2||tokens>3)
 737                 return CMD_STATUS_ERROR;
 738
 739         step = (tokens == 3) ? stof(argv(2)) : 0;
 740
 741         if(step == 0)
 742         {
 743                 this.v_angle_x -= stof(argv(1));
 744                 this.v_angle_y += stof(argv(0));
 745                 return CMD_STATUS_FINISHED;
 746         }
 747
 748         this.bot_cmd_aim_begin = this.v_angle;
 749
 750         this.bot_cmd_aim_end_x = this.v_angle.x - stof(argv(1));
 751         this.bot_cmd_aim_end_y = this.v_angle.y + stof(argv(0));
 752         this.bot_cmd_aim_end_z = 0;
 753
 754         this.bot_cmd_aim_begintime = time;
 755         this.bot_cmd_aim_endtime = time + step;
 756
 757         return CMD_STATUS_EXECUTING;
 758 }
 759
 760 float bot_cmd_aimtarget(entity this)
 761 {
 762         if(this.bot_cmd_aim_endtime)
 763         {
 764                 return bot_cmd_aim(this);
 765         }
 766
 767         entity e;
 768         string parms;
 769         vector v;
 770         float tokens, step;
 771
 772         parms = bot_cmd.bot_cmd_parm_string;
 773
 774         tokens = tokenizebyseparator(parms, " ");
 775
 776         e = bot_getplace(this, argv(0));
 777         if(!e)
 778                 return CMD_STATUS_ERROR;
 779
 780         v = e.origin + (e.mins + e.maxs) * 0.5;
 781
 782         if(tokens==1)
 783         {
 784                 this.v_angle = vectoangles(v - (this.origin + this.view_ofs));
 785                 this.v_angle_x = -this.v_angle.x;
 786                 return CMD_STATUS_FINISHED;
 787         }
 788
 789         if(tokens<1||tokens>2)
 790                 return CMD_STATUS_ERROR;
 791
 792         step = stof(argv(1));
 793
 794         this.bot_cmd_aim_begin = this.v_angle;
 795         this.bot_cmd_aim_end = vectoangles(v - (this.origin + this.view_ofs));
 796         this.bot_cmd_aim_end_x = -this.bot_cmd_aim_end.x;
 797
 798         this.bot_cmd_aim_begintime = time;
 799         this.bot_cmd_aim_endtime = time + step;
 800
 801         return CMD_STATUS_EXECUTING;
 802 }
 803
 804 .int bot_cmd_keys;
 805
 806 const int BOT_CMD_KEY_NONE              = 0;
 807 const int BOT_CMD_KEY_FORWARD   = BIT(0);
 808 const int BOT_CMD_KEY_BACKWARD  = BIT(1);
 809 const int BOT_CMD_KEY_RIGHT     = BIT(2);
 810 const int BOT_CMD_KEY_LEFT              = BIT(3);
 811 const int BOT_CMD_KEY_JUMP              = BIT(4);
 812 const int BOT_CMD_KEY_ATTACK1   = BIT(5);
 813 const int BOT_CMD_KEY_ATTACK2   = BIT(6);
 814 const int BOT_CMD_KEY_USE               = BIT(7);
 815 const int BOT_CMD_KEY_HOOK              = BIT(8);
 816 const int BOT_CMD_KEY_CROUCH    = BIT(9);
 817 const int BOT_CMD_KEY_CHAT              = BIT(10);
 818
 819 bool bot_presskeys(entity this)
 820 {
 821         this.movement = '0 0 0';
 822         PHYS_INPUT_BUTTON_JUMP(this) = false;
 823         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 824         PHYS_INPUT_BUTTON_ATCK(this) = false;
 825         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 826         PHYS_INPUT_BUTTON_USE(this) = false;
 827         PHYS_INPUT_BUTTON_HOOK(this) = false;
 828         PHYS_INPUT_BUTTON_CHAT(this) = false;
 829
 830         if(this.bot_cmd_keys == BOT_CMD_KEY_NONE)
 831                 return false;
 832
 833         if(this.bot_cmd_keys & BOT_CMD_KEY_FORWARD)
 834                 this.movement_x = autocvar_sv_maxspeed;
 835         else if(this.bot_cmd_keys & BOT_CMD_KEY_BACKWARD)
 836                 this.movement_x = -autocvar_sv_maxspeed;
 837
 838         if(this.bot_cmd_keys & BOT_CMD_KEY_RIGHT)
 839                 this.movement_y = autocvar_sv_maxspeed;
 840         else if(this.bot_cmd_keys & BOT_CMD_KEY_LEFT)
 841                 this.movement_y = -autocvar_sv_maxspeed;
 842
 843         if(this.bot_cmd_keys & BOT_CMD_KEY_JUMP)
 844                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 845
 846         if(this.bot_cmd_keys & BOT_CMD_KEY_CROUCH)
 847                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 848
 849         if(this.bot_cmd_keys & BOT_CMD_KEY_ATTACK1)
 850                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 851
 852         if(this.bot_cmd_keys & BOT_CMD_KEY_ATTACK2)
 853                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 854
 855         if(this.bot_cmd_keys & BOT_CMD_KEY_USE)
 856                 PHYS_INPUT_BUTTON_USE(this) = true;
 857
 858         if(this.bot_cmd_keys & BOT_CMD_KEY_HOOK)
 859                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 860
 861         if(this.bot_cmd_keys & BOT_CMD_KEY_CHAT)
 862                 PHYS_INPUT_BUTTON_CHAT(this) = true;
 863
 864         return true;
 865 }
 866
 867
 868 float bot_cmd_keypress_handler(entity this, string key, float enabled)
 869 {
 870         switch(key)
 871         {
 872                 case "all":
 873                         if(enabled)
 874                                 this.bot_cmd_keys = power2of(20) - 1; // >:)
 875                         else
 876                                 this.bot_cmd_keys = BOT_CMD_KEY_NONE;
 877                 case "forward":
 878                         if(enabled)
 879                         {
 880                                 this.bot_cmd_keys |= BOT_CMD_KEY_FORWARD;
 881                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_BACKWARD;
 882                         }
 883                         else
 884                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_FORWARD;
 885                         break;
 886                 case "backward":
 887                         if(enabled)
 888                         {
 889                                 this.bot_cmd_keys |= BOT_CMD_KEY_BACKWARD;
 890                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_FORWARD;
 891                         }
 892                         else
 893                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_BACKWARD;
 894                         break;
 895                 case "left":
 896                         if(enabled)
 897                         {
 898                                 this.bot_cmd_keys |= BOT_CMD_KEY_LEFT;
 899                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_RIGHT;
 900                         }
 901                         else
 902                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_LEFT;
 903                         break;
 904                 case "right":
 905                         if(enabled)
 906                         {
 907                                 this.bot_cmd_keys |= BOT_CMD_KEY_RIGHT;
 908                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_LEFT;
 909                         }
 910                         else
 911                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_RIGHT;
 912                         break;
 913                 case "jump":
 914                         if(enabled)
 915                                 this.bot_cmd_keys |= BOT_CMD_KEY_JUMP;
 916                         else
 917                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_JUMP;
 918                         break;
 919                 case "crouch":
 920                         if(enabled)
 921                                 this.bot_cmd_keys |= BOT_CMD_KEY_CROUCH;
 922                         else
 923                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_CROUCH;
 924                         break;
 925                 case "attack1":
 926                         if(enabled)
 927                                 this.bot_cmd_keys |= BOT_CMD_KEY_ATTACK1;
 928                         else
 929                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_ATTACK1;
 930                         break;
 931                 case "attack2":
 932                         if(enabled)
 933                                 this.bot_cmd_keys |= BOT_CMD_KEY_ATTACK2;
 934                         else
 935                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_ATTACK2;
 936                         break;
 937                 case "use":
 938                         if(enabled)
 939                                 this.bot_cmd_keys |= BOT_CMD_KEY_USE;
 940                         else
 941                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_USE;
 942                         break;
 943                 case "hook":
 944                         if(enabled)
 945                                 this.bot_cmd_keys |= BOT_CMD_KEY_HOOK;
 946                         else
 947                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_HOOK;
 948                         break;
 949                 case "chat":
 950                         if(enabled)
 951                                 this.bot_cmd_keys |= BOT_CMD_KEY_CHAT;
 952                         else
 953                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_CHAT;
 954                         break;
 955                 default:
 956                         break;
 957         }
 958
 959         return CMD_STATUS_FINISHED;
 960 }
 961
 962 float bot_cmd_presskey(entity this)
 963 {
 964         string key;
 965
 966         key = bot_cmd.bot_cmd_parm_string;
 967
 968         bot_cmd_keypress_handler(this, key,true);
 969
 970         return CMD_STATUS_FINISHED;
 971 }
 972
 973 float bot_cmd_releasekey(entity this)
 974 {
 975         string key;
 976
 977         key = bot_cmd.bot_cmd_parm_string;
 978
 979         return bot_cmd_keypress_handler(this, key,false);
 980 }
 981
 982 float bot_cmd_pause(entity this)
 983 {
 984         PHYS_INPUT_BUTTON_DRAG(this) = false;
 985         PHYS_INPUT_BUTTON_USE(this) = false;
 986         PHYS_INPUT_BUTTON_ATCK(this) = false;
 987         PHYS_INPUT_BUTTON_JUMP(this) = false;
 988         PHYS_INPUT_BUTTON_HOOK(this) = false;
 989         PHYS_INPUT_BUTTON_CHAT(this) = false;
 990         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 991         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 992
 993         this.movement = '0 0 0';
 994         this.bot_cmd_keys = BOT_CMD_KEY_NONE;
 995
 996         this.bot_exec_status |= BOT_EXEC_STATUS_PAUSED;
 997         return CMD_STATUS_FINISHED;
 998 }
 999
1000 float bot_cmd_moveto(entity this)
1001 {
1002         return this.cmd_moveto(this, bot_cmd.bot_cmd_parm_vector);
1003 }
1004
1005 float bot_cmd_movetotarget(entity this)
1006 {
1007         entity e;
1008         e = bot_getplace(this, bot_cmd.bot_cmd_parm_string);
1009         if(!e)
1010                 return CMD_STATUS_ERROR;
1011         return this.cmd_moveto(this, e.origin + (e.mins + e.maxs) * 0.5);
1012 }
1013
1014 float bot_cmd_resetgoal(entity this)
1015 {
1016         return this.cmd_resetgoal(this);
1017 }
1018
1019
1020 float bot_cmd_sound(entity this)
1021 {
1022         string f;
1023         f = bot_cmd.bot_cmd_parm_string;
1024
1025         float n = tokenizebyseparator(f, " ");
1026
1027         string sample = f;
1028         float chan = CH_WEAPON_B;
1029         float vol = VOL_BASE;
1030         float atten = ATTEN_MIN;
1031
1032         if(n >= 1)
1033                 sample = argv(n - 1);
1034         if(n >= 2)
1035                 chan = stof(argv(0));
1036         if(n >= 3)
1037                 vol = stof(argv(1));
1038         if(n >= 4)
1039                 atten = stof(argv(2));
1040
1041         precache_sound(f);
1042         _sound(this, chan, sample, vol, atten);
1043
1044         return CMD_STATUS_FINISHED;
1045 }
1046
1047 .entity tuba_note;
1048 float bot_cmd_debug_assert_canfire(entity this)
1049 {
1050         float f = bot_cmd.bot_cmd_parm_float;
1051
1052         int slot = 0; // TODO: unhardcode?
1053         .entity weaponentity = weaponentities[slot];
1054         if(this.(weaponentity).state != WS_READY)
1055         {
1056                 if(f)
1057                 {
1058                         this.colormod = '0 8 8';
1059                         LOG_INFO("Bot ", this.netname, " using ", this.(weaponentity).weaponname, " wants to fire, inhibited by weaponentity state\n");
1060                 }
1061         }
1062         else if(ATTACK_FINISHED(this, slot) > time)
1063         {
1064                 if(f)
1065                 {
1066                         this.colormod = '8 0 8';
1067                         LOG_INFO("Bot ", this.netname, " using ", this.(weaponentity).weaponname, " wants to fire, inhibited by ATTACK_FINISHED (", ftos(ATTACK_FINISHED(this, slot) - time), " seconds left)\n");
1068                 }
1069         }
1070         else if(this.tuba_note)
1071         {
1072                 if(f)
1073                 {
1074                         this.colormod = '8 0 0';
1075                         LOG_INFO("Bot ", this.netname, " using ", this.(weaponentity).weaponname, " wants to fire, bot still has an active tuba note\n");
1076                 }
1077         }
1078         else
1079         {
1080                 if(!f)
1081                 {
1082                         this.colormod = '8 8 0';
1083                         LOG_INFO("Bot ", this.netname, " using ", this.(weaponentity).weaponname, " thinks it has fired, but apparently did not; ATTACK_FINISHED says ", ftos(ATTACK_FINISHED(this, slot) - time), " seconds left\n");
1084                 }
1085         }
1086
1087         return CMD_STATUS_FINISHED;
1088 }
1089
1090 //
1091
1092 void bot_command_executed(entity this, bool rm)
1093 {
1094         entity cmd;
1095
1096         cmd = bot_cmd;
1097
1098         if(rm)
1099                 bot_dequeuecommand(this, this.bot_cmd_execution_index);
1100
1101         this.bot_cmd_execution_index++;
1102 }
1103
1104 void bot_setcurrentcommand(entity this)
1105 {
1106         bot_cmd = NULL;
1107
1108         if(!this.bot_cmd_current)
1109         {
1110                 this.bot_cmd_current = new_pure(bot_cmd);
1111                 this.bot_cmd_current.is_bot_cmd = true;
1112         }
1113
1114         bot_cmd = this.bot_cmd_current;
1115         if(bot_cmd.bot_cmd_index != this.bot_cmd_execution_index || this.bot_cmd_execution_index == 0)
1116         {
1117                 if(bot_havecommand(this, this.bot_cmd_execution_index))
1118                 {
1119                         string cmdstring;
1120                         cmdstring = bot_readcommand(this, this.bot_cmd_execution_index);
1121                         if(bot_decodecommand(cmdstring))
1122                         {
1123                                 bot_cmd.owner = this;
1124                                 bot_cmd.bot_cmd_index = this.bot_cmd_execution_index;
1125                         }
1126                         else
1127                         {
1128                                 // Invalid command, remove from queue
1129                                 bot_cmd = NULL;
1130                                 bot_dequeuecommand(this, this.bot_cmd_execution_index);
1131                                 this.bot_cmd_execution_index++;
1132                         }
1133                 }
1134                 else
1135                         bot_cmd = NULL;
1136         }
1137 }
1138
1139 void bot_resetqueues()
1140 {
1141         FOREACH_CLIENT(it.isbot, LAMBDA(
1142                 it.bot_cmd_execution_index = 0;
1143                 bot_clearqueue(it);
1144                 // also, cancel all barriers
1145                 it.bot_barrier = 0;
1146                 for(int i = 0; i < it.bot_places_count; ++i)
1147                 {
1148                         strunzone(it.(bot_placenames[i]));
1149                         it.(bot_placenames[i]) = string_null;
1150                 }
1151                 it.bot_places_count = 0;
1152         ));
1153
1154         bot_barriertime = time;
1155 }
1156
1157 // Here we map commands to functions and deal with complex interactions between commands and execution states
1158 // NOTE: Of course you need to include your commands here too :)
1159 float bot_execute_commands_once(entity this)
1160 {
1161         float status, ispressingkey;
1162
1163         // Find command
1164         bot_setcurrentcommand(this);
1165
1166         // if we have no bot command, better return
1167         // old logic kept pressing previously pressed keys, but that has problems
1168         // (namely, it means you cannot make a bot "normal" ever again)
1169         // to keep a bot walking for a while, use the "wait" bot command
1170         if(bot_cmd == NULL)
1171                 return false;
1172
1173         // Ignore all commands except continue when the bot is paused
1174         if(this.bot_exec_status & BOT_EXEC_STATUS_PAUSED)
1175         if(bot_cmd.bot_cmd_type!=BOT_CMD_CONTINUE)
1176         {
1177                 if(bot_cmd.bot_cmd_type!=BOT_CMD_NULL)
1178                 {
1179                         bot_command_executed(this, true);
1180                         LOG_INFO( "WARNING: Commands are ignored while the bot is paused. Use the command 'continue' instead.\n");
1181                 }
1182                 return 1;
1183         }
1184
1185         // Keep pressing keys raised by the "presskey" command
1186         ispressingkey = boolean(bot_presskeys(this));
1187
1188         // Handle conditions
1189         if (!(bot_cmd.bot_cmd_type==BOT_CMD_FI||bot_cmd.bot_cmd_type==BOT_CMD_ELSE))
1190         if(this.bot_cmd_condition_status & CMD_CONDITION_true && this.bot_cmd_condition_status & CMD_CONDITION_false_BLOCK)
1191         {
1192                 bot_command_executed(this, true);
1193                 return -1;
1194         }
1195         else if(this.bot_cmd_condition_status & CMD_CONDITION_false && this.bot_cmd_condition_status & CMD_CONDITION_true_BLOCK)
1196         {
1197                 bot_command_executed(this, true);
1198                 return -1;
1199         }
1200
1201         // Map commands to functions
1202         switch(bot_cmd.bot_cmd_type)
1203         {
1204                 case BOT_CMD_NULL:
1205                         return ispressingkey;
1206                         //break;
1207                 case BOT_CMD_PAUSE:
1208                         status = bot_cmd_pause(this);
1209                         break;
1210                 case BOT_CMD_CONTINUE:
1211                         status = bot_cmd_continue(this);
1212                         break;
1213                 case BOT_CMD_WAIT:
1214                         status = bot_cmd_wait(this);
1215                         break;
1216                 case BOT_CMD_WAIT_UNTIL:
1217                         status = bot_cmd_wait_until(this);
1218                         break;
1219                 case BOT_CMD_TURN:
1220                         status = bot_cmd_turn(this);
1221                         break;
1222                 case BOT_CMD_MOVETO:
1223                         status = bot_cmd_moveto(this);
1224                         break;
1225                 case BOT_CMD_MOVETOTARGET:
1226                         status = bot_cmd_movetotarget(this);
1227                         break;
1228                 case BOT_CMD_RESETGOAL:
1229                         status = bot_cmd_resetgoal(this);
1230                         break;
1231                 case BOT_CMD_CC:
1232                         status = bot_cmd_cc(this);
1233                         break;
1234                 case BOT_CMD_IF:
1235                         status = bot_cmd_if(this);
1236                         break;
1237                 case BOT_CMD_ELSE:
1238                         status = bot_cmd_else(this);
1239                         break;
1240                 case BOT_CMD_FI:
1241                         status = bot_cmd_fi(this);
1242                         break;
1243                 case BOT_CMD_RESETAIM:
1244                         status = bot_cmd_resetaim(this);
1245                         break;
1246                 case BOT_CMD_AIM:
1247                         status = bot_cmd_aim(this);
1248                         break;
1249                 case BOT_CMD_AIMTARGET:
1250                         status = bot_cmd_aimtarget(this);
1251                         break;
1252                 case BOT_CMD_PRESSKEY:
1253                         status = bot_cmd_presskey(this);
1254                         break;
1255                 case BOT_CMD_RELEASEKEY:
1256                         status = bot_cmd_releasekey(this);
1257                         break;
1258                 case BOT_CMD_SELECTWEAPON:
1259                         status = bot_cmd_select_weapon(this);
1260                         break;
1261                 case BOT_CMD_IMPULSE:
1262                         status = bot_cmd_impulse(this);
1263                         break;
1264                 case BOT_CMD_BARRIER:
1265                         status = bot_cmd_barrier(this);
1266                         break;
1267                 case BOT_CMD_CONSOLE:
1268                         localcmd(strcat(bot_cmd.bot_cmd_parm_string, "\n"));
1269                         status = CMD_STATUS_FINISHED;
1270                         break;
1271                 case BOT_CMD_SOUND:
1272                         status = bot_cmd_sound(this);
1273                         break;
1274                 case BOT_CMD_DEBUG_ASSERT_CANFIRE:
1275                         status = bot_cmd_debug_assert_canfire(this);
1276                         break;
1277                 default:
1278                         LOG_INFO(strcat("ERROR: Invalid command on queue with id '",ftos(bot_cmd.bot_cmd_type),"'\n"));
1279                         return 0;
1280         }
1281
1282         if (status==CMD_STATUS_ERROR)
1283                 LOG_INFO(strcat("ERROR: The command '",bot_cmd_string[bot_cmd.bot_cmd_type],"' returned an error status\n"));
1284
1285         // Move execution pointer
1286         if(status==CMD_STATUS_EXECUTING)
1287         {
1288                 return 1;
1289         }
1290         else
1291         {
1292                 if(autocvar_g_debug_bot_commands)
1293                 {
1294                         string parms;
1295
1296                         switch(bot_cmd_parm_type[bot_cmd.bot_cmd_type])
1297                         {
1298                                 case BOT_CMD_PARAMETER_FLOAT:
1299                                         parms = ftos(bot_cmd.bot_cmd_parm_float);
1300                                         break;
1301                                 case BOT_CMD_PARAMETER_STRING:
1302                                         parms = bot_cmd.bot_cmd_parm_string;
1303                                         break;
1304                                 case BOT_CMD_PARAMETER_VECTOR:
1305                                         parms = vtos(bot_cmd.bot_cmd_parm_vector);
1306                                         break;
1307                                 default:
1308                                         parms = "";
1309                                         break;
1310                         }
1311                         clientcommand(this,strcat("say ^7", bot_cmd_string[bot_cmd.bot_cmd_type]," ",parms,"\n"));
1312                 }
1313
1314                 bot_command_executed(this, true);
1315         }
1316
1317         if(status == CMD_STATUS_FINISHED)
1318                 return -1;
1319
1320         return CMD_STATUS_ERROR;
1321 }
1322
1323 // This function should be (the only) called directly from the bot ai loop
1324 int bot_execute_commands(entity this)
1325 {
1326         int f;
1327         do
1328         {
1329                 f = bot_execute_commands_once(this);
1330         }
1331         while(f < 0);
1332         return f;
1333 }