qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <common/weapons/_all.qh>
   4 #include <common/stats.qh>
   5 #include <server/items/items.qh>
   6 #include <server/spawnpoints.qh>
   7 #include <server/weapons/tracing.qh>
   8 #include "cvars.qh"
   9
  10 #include "bot.qh"
  11 #include "navigation.qh"
  12
  13 #include <common/state.qh>
  14
  15 #include "../../antilag.qh"
  16
  17 #include <common/constants.qh>
  18 #include <common/debug.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/mapobjects/trigger/jumppads.qh>
  21 #include <common/net_linked.qh>
  22 #include <common/physics/player.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25 #include <lib/warpzone/util_server.qh>
  26
  27 .entity spawnpointmodel;
  28 void waypoint_unreachable(entity pl)
  29 {
  30         IL_EACH(g_waypoints, true,
  31         {
  32                 it.colormod = '0.5 0.5 0.5';
  33                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  34         });
  35
  36         entity e2 = navigation_findnearestwaypoint(pl, false);
  37         if(!e2)
  38         {
  39                 LOG_INFO("Can't find any waypoint nearby\n");
  40                 return;
  41         }
  42
  43         navigation_markroutes(pl, e2);
  44
  45         int j = 0;
  46         int m = 0;
  47         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  48         {
  49                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  50                 it.colormod_z = 8;
  51                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  52                 j++;
  53                 m++;
  54         });
  55         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  56         navigation_markroutes_inverted(e2);
  57
  58         j = 0;
  59         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  60         {
  61                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  62                 it.colormod_x = 8;
  63                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  64                         m++;
  65                 it.effects |= EF_NODEPTHTEST | EF_RED;
  66                 j++;
  67         });
  68         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  69         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  70
  71         j = 0;
  72         IL_EACH(g_spawnpoints, true,
  73         {
  74                 if (navigation_findnearestwaypoint(it, false))
  75                 {
  76                         if(it.spawnpointmodel)
  77                         {
  78                                 delete(it.spawnpointmodel);
  79                                 it.spawnpointmodel = NULL;
  80                         }
  81                 }
  82                 else
  83                 {
  84                         if(!it.spawnpointmodel)
  85                         {
  86                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  87                                 entity e = new(spawnpointmodel);
  88                                 vector org = trace_endpos + eZ;
  89                                 setorigin(e, org);
  90                                 e.solid = SOLID_TRIGGER;
  91                                 it.spawnpointmodel = e;
  92                         }
  93                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  94                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  95                         _setmodel(it.spawnpointmodel, pl.model);
  96                         it.spawnpointmodel.frame = pl.frame;
  97                         it.spawnpointmodel.skin = pl.skin;
  98                         it.spawnpointmodel.colormap = pl.colormap;
  99                         it.spawnpointmodel.colormod = pl.colormod;
 100                         it.spawnpointmodel.glowmod = pl.glowmod;
 101                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
 102                         j++;
 103                 }
 104         });
 105         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 106
 107         j = 0;
 108         IL_EACH(g_items, true,
 109         {
 110                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 111                 it.colormod = '0.5 0.5 0.5';
 112         });
 113         IL_EACH(g_items, true,
 114         {
 115                 if (navigation_findnearestwaypoint(it, false))
 116                         continue;
 117                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 118                 it.effects |= EF_NODEPTHTEST | EF_RED;
 119                 it.colormod_x = 8;
 120                 j++;
 121         });
 122         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 123
 124         j = 0;
 125         IL_EACH(g_items, true,
 126         {
 127                 if (navigation_findnearestwaypoint(it, true))
 128                         continue;
 129                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 130                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 131                 it.colormod_z = 8;
 132                 j++;
 133         });
 134         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 135 }
 136
 137 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 138 {
 139         vector v1 = stov(argv(arg_idx++));
 140         vector v2 = stov(argv(arg_idx++));
 141         vector mid = (v1 + v2) / 2;
 142
 143         float diffy = (v2.y - v1.y);
 144         float diffx = (v2.x - v1.x);
 145         if (v1.y == v2.y)
 146                 diffy = 0.000001;
 147         if (v1.x == v2.x)
 148                 diffx = 0.000001;
 149         float m = - diffx / diffy;
 150         float q = - m * mid.x + mid.y;
 151         if (fabs(m) <= 0.000001) m = 0;
 152         if (fabs(q) <= 0.000001) q = 0;
 153
 154         string axis_str =  strcat(ftos(m), " ", ftos(q));
 155         if (save)
 156                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 157         axis_str = strcat("\"", axis_str, "\"");
 158         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 159         if (save)
 160                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 161         if (save)
 162         {
 163                 cvar_set("g_waypointeditor_symmetrical", "-2");
 164                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 165                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 166         }
 167 }
 168
 169 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 170 {
 171         vector org = '0 0 0';
 172         int ctf_flags = 0;
 173         for (int i = 0; i < 6; i++)
 174         {
 175                 if (argv(arg_idx + i) != "")
 176                         ctf_flags++;
 177         }
 178         if (ctf_flags < 2)
 179         {
 180                 ctf_flags = 0;
 181                 org = vec2(havocbot_middlepoint);
 182                 if (argv(arg_idx) != "")
 183                         sprint(caller, "WARNING: Ignoring single input point\n");
 184                 if (havocbot_middlepoint_radius == 0)
 185                 {
 186                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 187                         return;
 188                 }
 189         }
 190         else
 191         {
 192                 vector v1, v2, v3, v4, v5, v6;
 193                 for (int i = 1; i <= ctf_flags; i++)
 194                 {
 195                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 196                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 197                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 198                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 199                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 200                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 201                 }
 202         }
 203
 204         if (fabs(org.x) <= 0.000001) org.x = 0;
 205         if (fabs(org.y) <= 0.000001) org.y = 0;
 206         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 207         if (save)
 208         {
 209                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 210                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 211         }
 212         org_str = strcat("\"", org_str, "\"");
 213
 214         if (ctf_flags < 2)
 215                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 216         else
 217                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 218         if (save)
 219                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 220
 221         if (ctf_flags < 2)
 222                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 223         else
 224                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 225         if (save)
 226                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 227
 228         if (save)
 229         {
 230                 if (ctf_flags < 2)
 231                         cvar_set("g_waypointeditor_symmetrical", "0");
 232                 else
 233                         cvar_set("g_waypointeditor_symmetrical", "-1");
 234                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 235                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 236         }
 237 }
 238
 239 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 240 {
 241         vector new_org = org;
 242         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 243         {
 244                 vector map_center = havocbot_middlepoint;
 245                 if (autocvar_g_waypointeditor_symmetrical == -1)
 246                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 247
 248                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 249         }
 250         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 251         {
 252                 float m = havocbot_symmetry_axis_m;
 253                 float q = havocbot_symmetry_axis_q;
 254                 if (autocvar_g_waypointeditor_symmetrical == -2)
 255                 {
 256                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 257                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 258                 }
 259
 260                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 261                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 262         }
 263         new_org.z = org.z;
 264         return new_org;
 265 }
 266
 267 void crosshair_trace_waypoints(entity pl);
 268 void waypoint_lock(entity pl)
 269 {
 270         crosshair_trace_waypoints(pl);
 271         pl.wp_locked = trace_ent;
 272 }
 273
 274 bool waypoint_has_hardwiredlinks(entity wp)
 275 {
 276         if (!wp)
 277                 return false;
 278         return (wp.wphw00 != NULL);
 279 }
 280
 281 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 282 {
 283         if (!(wp_from && wp_to))
 284                 return false;
 285
 286         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 287         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 288         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 289         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 290         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 291         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 292         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 293         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 294
 295         return false;
 296 }
 297
 298 void waypoint_setupmodel(entity wp);
 299 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 300 {
 301         if (!(wp_from && wp_to))
 302                 return;
 303
 304         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; waypoint_setupmodel(wp_from); return; }
 305         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 306         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 307         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 308         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 309         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 310         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 311         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 312
 313         return;
 314 }
 315
 316 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 317 {
 318         if (!(wp_from && wp_to))
 319                 return;
 320
 321         int removed = -1;
 322         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 323         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 324         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 325         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 326         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 327         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 328         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 329         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 330
 331         if (removed >= 0)
 332         {
 333                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 334                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 335                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 336                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 337                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 338                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 339                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 340                 if (removed <= 7) wp_from.wphw07 = NULL;
 341                 if (!wp_from.wphw00)
 342                         waypoint_setupmodel(wp_from);
 343         }
 344
 345         return;
 346 }
 347
 348 void waypoint_restore_hardwiredlinks(entity wp)
 349 {
 350         if (wp.wphw00) waypoint_addlink(wp, wp.wphw00);
 351         if (wp.wphw01) waypoint_addlink(wp, wp.wphw01);
 352         if (wp.wphw02) waypoint_addlink(wp, wp.wphw02);
 353         if (wp.wphw03) waypoint_addlink(wp, wp.wphw03);
 354         if (wp.wphw04) waypoint_addlink(wp, wp.wphw04);
 355         if (wp.wphw05) waypoint_addlink(wp, wp.wphw05);
 356         if (wp.wphw06) waypoint_addlink(wp, wp.wphw06);
 357         if (wp.wphw07) waypoint_addlink(wp, wp.wphw07);
 358 }
 359
 360 void waypoint_setupmodel(entity wp)
 361 {
 362         if (autocvar_g_waypointeditor)
 363         {
 364                 // TODO: add some sort of visible box in edit mode for box waypoints
 365                 vector m1 = wp.mins;
 366                 vector m2 = wp.maxs;
 367                 setmodel(wp, MDL_WAYPOINT);
 368                 setsize(wp, m1, m2);
 369                 wp.effects = EF_LOWPRECISION;
 370                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 371                         wp.colormod = '1 0 0'; // red
 372                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 373                         wp.colormod = '1 1 0'; // yellow
 374                 else if (wp.wpflags & WAYPOINTFLAG_SUPPORT)
 375                         wp.colormod = '0 1 0'; // green
 376                 else if (wp.wpflags & WAYPOINTFLAG_CUSTOM_JP)
 377                         wp.colormod = '1 0.5 0'; // orange
 378                 else if (wp.wpflags & WAYPOINTFLAG_TELEPORT)
 379                         wp.colormod = '1 0.5 0'; // orange
 380                 else if (wp.wpflags & WAYPOINTFLAG_LADDER)
 381                         wp.colormod = '1 0.5 0'; // orange
 382                 else if (wp.wpflags & WAYPOINTFLAG_JUMP)
 383                         wp.colormod = '1 0.5 0'; // orange
 384                 else if (wp.wpflags & WAYPOINTFLAG_CROUCH)
 385                         wp.colormod = '0 1 1'; // cyan
 386                 else if (waypoint_has_hardwiredlinks(wp))
 387                         wp.colormod = '0.5 0 1'; // purple
 388                 else
 389                         wp.colormod = '1 1 1';
 390         }
 391         else
 392                 wp.model = "";
 393 }
 394
 395 string waypoint_get_type_name(entity wp)
 396 {
 397         if (wp.wpflags & WAYPOINTFLAG_ITEM) return "^1Item waypoint";
 398         else if (wp.wpflags & WAYPOINTFLAG_CROUCH) return "^5Crouch waypoint";
 399         else if (wp.wpflags & WAYPOINTFLAG_JUMP) return "^xf80Jump waypoint";
 400         else if (wp.wpflags & WAYPOINTFLAG_SUPPORT) return "^2Support waypoint";
 401         else if (waypoint_has_hardwiredlinks(wp)) return "^x80fHardwired waypoint";
 402         else if (wp.wpflags & WAYPOINTFLAG_LADDER) return "^3Ladder waypoint";
 403         else if (wp.wpflags & WAYPOINTFLAG_TELEPORT)
 404         {
 405                 if (!wp.wpisbox) return "^3Warpzone waypoint";
 406                 else if (wp.wpflags & WAYPOINTFLAG_CUSTOM_JP) return "^3Custom jumppad waypoint";
 407                 else
 408                 {
 409                         IL_EACH(g_jumppads, boxesoverlap(wp.absmin, wp.absmax, it.absmin, it.absmax),
 410                                 { return "^3Jumppad waypoint"; });
 411                         return "^3Teleport waypoint";
 412                 }
 413         }
 414
 415         return "^7Waypoint";
 416 }
 417
 418 entity waypoint_get(vector m1, vector m2)
 419 {
 420         if (m1 == m2)
 421         {
 422                 m1 -= '8 8 8';
 423                 m2 += '8 8 8';
 424         }
 425         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 426
 427         return NULL;
 428 }
 429
 430 .float createdtime;
 431 entity waypoint_spawn(vector m1, vector m2, float f)
 432 {
 433         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 434         {
 435                 entity wp_found = waypoint_get(m1, m2);
 436                 if (wp_found)
 437                         return wp_found;
 438         }
 439         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 440         // otherwise links loaded from file would be applied only to the first destination
 441         // waypoint since link format doesn't specify waypoint entities but just positions
 442         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WPFLAGMASK_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 443         {
 444                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 445                 {
 446                         return it;
 447                 });
 448         }
 449
 450         entity w = new(waypoint);
 451         IL_PUSH(g_waypoints, w);
 452         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 453         w.wpflags = f;
 454         w.solid = SOLID_TRIGGER;
 455         w.createdtime = time;
 456         setorigin(w, (m1 + m2) * 0.5);
 457         setsize(w, m1 - w.origin, m2 - w.origin);
 458         if (w.size)
 459                 w.wpisbox = true;
 460
 461         if(!w.wpisbox)
 462         {
 463                 if (f & WAYPOINTFLAG_CROUCH)
 464                         setsize(w, PL_CROUCH_MIN_CONST - '1 1 0', PL_CROUCH_MAX_CONST + '1 1 0');
 465                 else
 466                         setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 467                 if(!move_out_of_solid(w))
 468                 {
 469                         if(!(f & WAYPOINTFLAG_GENERATED))
 470                         {
 471                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 472                                 delete(w);
 473                                 return NULL;
 474                         }
 475                         else
 476                         {
 477                                 if(autocvar_developer > 0)
 478                                 {
 479                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 480                                         backtrace("Waypoint stuck");
 481                                 }
 482                         }
 483                 }
 484                 setsize(w, '0 0 0', '0 0 0');
 485         }
 486
 487         waypoint_clearlinks(w);
 488         //waypoint_schedulerelink(w);
 489
 490         waypoint_setupmodel(w);
 491
 492         return w;
 493 }
 494
 495 float trigger_push_get_push_time(entity this, vector endpos);
 496 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 497 {
 498         entity jp = NULL;
 499         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 500         {
 501                 jp = it;
 502                 break;
 503         });
 504         if (!jp)
 505                 return;
 506
 507         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 508         wp_from.wp00 = wp_to;
 509         wp_from.wp00mincost = cost;
 510         jp.nearestwaypoint = wp_from;
 511         jp.nearestwaypointtimeout = -1;
 512 }
 513
 514 bool start_wp_is_spawned;
 515 vector start_wp_origin;
 516 bool start_wp_is_hardwired;
 517 bool start_wp_is_support;
 518
 519 void waypoint_clear_start_wp_globals(entity pl, bool warn)
 520 {
 521         start_wp_is_spawned = false;
 522         start_wp_origin = '0 0 0';
 523         pl.wp_locked = NULL;
 524         start_wp_is_hardwired = false;
 525         start_wp_is_support = false;
 526         if (warn)
 527                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 528 }
 529
 530 void waypoint_start_hardwiredlink(entity pl, bool at_crosshair)
 531 {
 532         entity wp = pl.nearestwaypoint;
 533         if (at_crosshair)
 534         {
 535                 crosshair_trace_waypoints(pl);
 536                 wp = trace_ent;
 537         }
 538         string err = "";
 539         if (start_wp_is_spawned && !start_wp_is_hardwired)
 540                 err = "can't hardwire while in the process of creating a special link";
 541         else if (!wp)
 542         {
 543                 if (at_crosshair)
 544                         err = "couldn't find any waypoint at crosshair";
 545                 else
 546                         err = "couldn't find any waypoint nearby";
 547         }
 548         else if (wp.wpflags & WPFLAGMASK_NORELINK)
 549                 err = "can't hardwire a waypoint with special links";
 550
 551         if (err == "")
 552         {
 553                 start_wp_is_hardwired = true;
 554                 start_wp_is_spawned = true;
 555                 start_wp_origin = wp.origin;
 556                 pl.wp_locked = wp;
 557                 LOG_INFOF("^x80fWaypoint %s marked as hardwired link origin.\n", vtos(wp.origin));
 558         }
 559         else
 560         {
 561                 start_wp_is_hardwired = false;
 562                 LOG_INFO("Error: ", err, "\n");
 563         }
 564 }
 565
 566 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp, bool is_crouch_wp, bool is_support_wp)
 567 {
 568         if (WAYPOINT_VERSION < waypoint_version_loaded)
 569         {
 570                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 571                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 572                 return;
 573         }
 574
 575         entity e = NULL, jp = NULL;
 576         vector org = pl.origin;
 577         if (at_crosshair)
 578         {
 579                 crosshair_trace_waypoints(pl);
 580                 org = trace_endpos;
 581                 if (!trace_ent)
 582                         org.z -= PL_MIN_CONST.z;
 583                 if (!(start_wp_is_hardwired || start_wp_is_support))
 584                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 585                         {
 586                                 jp = it;
 587                                 break;
 588                         });
 589                 if (!jp && !start_wp_is_spawned && trace_ent)
 590                 {
 591                         if (trace_ent.wpflags & (WAYPOINTFLAG_JUMP))
 592                                 is_jump_wp = true;
 593                         else if (trace_ent.wpflags & (WAYPOINTFLAG_SUPPORT))
 594                                 is_support_wp = true;
 595                 }
 596         }
 597         if (jp || is_jump_wp || is_support_wp)
 598         {
 599                 if (start_wp_is_spawned)
 600                         start_wp_is_spawned = false;
 601                 LOG_INFO("^xf80Spawning start waypoint...\n");
 602         }
 603         int ctf_flags = havocbot_symmetry_origin_order;
 604         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 605                    || (autocvar_g_waypointeditor_symmetrical < 0));
 606         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 607                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 608         if (sym && ctf_flags < 2)
 609                 ctf_flags = 2;
 610         int wp_num = ctf_flags;
 611
 612         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp && !is_support_wp)
 613         {
 614                 // snap waypoint to item's origin if close enough
 615                 IL_EACH(g_items, true,
 616                 {
 617                         vector item_org = (it.absmin + it.absmax) * 0.5;
 618                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 619                         if (vlen(item_org - org) < 20)
 620                         {
 621                                 org = item_org;
 622                                 break;
 623                         }
 624                 });
 625         }
 626
 627         vector start_org = '0 0 0';
 628         if (start_wp_is_spawned)
 629         {
 630                 if (!start_wp_is_hardwired)
 631                         LOG_INFO("^xf80Spawning destination waypoint...\n");
 632                 start_org = start_wp_origin;
 633         }
 634
 635         // save org as it can be modified spawning symmetrycal waypoints
 636         vector initial_origin = '0 0 0';
 637         bool initial_origin_is_set = false;
 638
 639         LABEL(add_wp);
 640
 641         if (jp)
 642         {
 643                 e = NULL;
 644                 IL_EACH(g_waypoints, (it.wpflags & WPFLAGMASK_NORELINK)
 645                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 646                 {
 647                         e = it; break;
 648                 });
 649                 if (!e)
 650                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT);
 651                 if (!pl.wp_locked)
 652                         pl.wp_locked = e;
 653         }
 654         else if (is_jump_wp || is_support_wp)
 655         {
 656                 int type_flag = (is_jump_wp) ? WAYPOINTFLAG_JUMP : WAYPOINTFLAG_SUPPORT;
 657
 658                 entity wp_found = waypoint_get(org, org);
 659                 if (wp_found && !(wp_found.wpflags & type_flag))
 660                 {
 661                         LOG_INFOF("Error: can't spawn a %s waypoint over an existent waypoint of a different type\n", (is_jump_wp) ? "Jump" : "Support");
 662                         return;
 663                 }
 664                 e = waypoint_spawn(org, org, type_flag);
 665                 if (!pl.wp_locked)
 666                         pl.wp_locked = e;
 667         }
 668         else
 669                 e = waypoint_spawn(org, org, (is_crouch_wp) ? WAYPOINTFLAG_CROUCH : 0);
 670         if(!e)
 671         {
 672                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 673                 if (start_wp_is_spawned)
 674                         waypoint_clear_start_wp_globals(pl, true);
 675                 return;
 676         }
 677
 678         if (!initial_origin_is_set)
 679         {
 680                 initial_origin = e.origin;
 681                 initial_origin_is_set = true;
 682         }
 683
 684         entity start_wp = NULL;
 685         if (start_wp_is_spawned)
 686         {
 687                 IL_EACH(g_waypoints, (start_wp_is_hardwired || (it.wpflags & WPFLAGMASK_NORELINK))
 688                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 689                 {
 690                         start_wp = it; break;
 691                 });
 692                 if(!start_wp)
 693                 {
 694                         // should not happen
 695                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 696                         waypoint_clear_start_wp_globals(pl, true);
 697                         return;
 698                 }
 699                 if (start_wp_is_hardwired)
 700                 {
 701                         if (waypoint_is_hardwiredlink(start_wp, e))
 702                         {
 703                                 waypoint_unmark_hardwiredlink(start_wp, e);
 704                                 waypoint_removelink(start_wp, e);
 705                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 706                                 LOG_INFOF("^x80fRemoved hardwired link %s.\n", s);
 707                         }
 708                         else
 709                         {
 710                                 if (e.createdtime == time)
 711                                 {
 712                                         LOG_INFO("Error: hardwired links can be created only between 2 existing (and unconnected) waypoints.\n");
 713                                         waypoint_remove(e);
 714                                         waypoint_clear_start_wp_globals(pl, true);
 715                                         waypoint_spawn_fromeditor(pl, at_crosshair, is_jump_wp, is_crouch_wp, is_support_wp);
 716                                         return;
 717                                 }
 718                                 if (start_wp == e)
 719                                 {
 720                                         LOG_INFO("Error: start and destination waypoints coincide.\n");
 721                                         waypoint_clear_start_wp_globals(pl, true);
 722                                         return;
 723                                 }
 724                                 if (waypoint_islinked(start_wp, e))
 725                                 {
 726                                         LOG_INFO("Error: waypoints are already linked.\n");
 727                                         waypoint_clear_start_wp_globals(pl, true);
 728                                         return;
 729                                 }
 730                                 waypoint_addlink(start_wp, e);
 731                                 waypoint_mark_hardwiredlink(start_wp, e);
 732                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 733                                 LOG_INFOF("^x80fAdded hardwired link %s.\n", s);
 734                         }
 735                 }
 736                 else
 737                 {
 738                         if (start_wp_is_support)
 739                         {
 740                                 if (e.SUPPORT_WP)
 741                                 {
 742                                         LOG_INFOF("Waypoint %v has already a support waypoint, delete it first.\n", e.origin);
 743                                         waypoint_clear_start_wp_globals(pl, true);
 744                                         return;
 745                                 }
 746                                 // clear all links to e
 747                                 IL_EACH(g_waypoints, it != e,
 748                                 {
 749                                         if (waypoint_islinked(it, e) && !waypoint_is_hardwiredlink(it, e))
 750                                                 waypoint_removelink(it, e);
 751                                 });
 752                         }
 753                         waypoint_addlink(start_wp, e);
 754                 }
 755         }
 756
 757         if (!(jp || is_jump_wp || is_support_wp || start_wp_is_hardwired))
 758                 waypoint_schedulerelink(e);
 759
 760         string wp_type_str = waypoint_get_type_name(e);
 761
 762         bprint(strcat(wp_type_str, "^7 spawned at ", vtos(e.origin), "\n"));
 763
 764         if (start_wp_is_spawned)
 765         {
 766                 pl.wp_locked = NULL;
 767                 if (!start_wp_is_hardwired)
 768                         waypoint_schedulerelink(start_wp);
 769                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 770                 {
 771                         if (start_wp.wp00_original == start_wp.wp00)
 772                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 773                         else
 774                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 775                 }
 776         }
 777
 778         if (sym)
 779         {
 780                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 781                 if (jp)
 782                 {
 783                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 784                         {
 785                                 jp = it; break;
 786                         });
 787                 }
 788                 if (start_wp_is_spawned)
 789                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 790                 if (vdist(org - pl.origin, >, 32))
 791                 {
 792                         if(wp_num > 2)
 793                                 wp_num--;
 794                         else
 795                                 sym = false;
 796                         goto add_wp;
 797                 }
 798         }
 799         if (jp || is_jump_wp || is_support_wp)
 800         {
 801                 if (!start_wp_is_spawned)
 802                 {
 803                         // we've just created a custom jumppad waypoint
 804                         // the next one created by the user will be the destination waypoint
 805                         start_wp_is_spawned = true;
 806                         start_wp_origin = initial_origin;
 807                         if (is_support_wp)
 808                                 start_wp_is_support = true;
 809                 }
 810         }
 811         else if (start_wp_is_spawned)
 812         {
 813                 waypoint_clear_start_wp_globals(pl, false);
 814         }
 815 }
 816
 817 void waypoint_remove(entity wp)
 818 {
 819         IL_EACH(g_waypoints, it != wp,
 820         {
 821                 if (it.SUPPORT_WP == wp)
 822                 {
 823                         it.SUPPORT_WP = NULL;
 824                         waypoint_schedulerelink(it); // restore incoming links
 825                 }
 826                 if (waypoint_islinked(it, wp))
 827                 {
 828                         if (waypoint_is_hardwiredlink(it, wp))
 829                                 waypoint_unmark_hardwiredlink(it, wp);
 830                         waypoint_removelink(it, wp);
 831                 }
 832         });
 833         delete(wp);
 834 }
 835
 836 void waypoint_remove_fromeditor(entity pl)
 837 {
 838         if (WAYPOINT_VERSION < waypoint_version_loaded)
 839         {
 840                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 841                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 842                 return;
 843         }
 844
 845         entity e = navigation_findnearestwaypoint(pl, false);
 846
 847         int ctf_flags = havocbot_symmetry_origin_order;
 848         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 849                    || (autocvar_g_waypointeditor_symmetrical < 0));
 850         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 851                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 852         if (sym && ctf_flags < 2)
 853                 ctf_flags = 2;
 854         int wp_num = ctf_flags;
 855
 856         LABEL(remove_wp);
 857         if (!e) return;
 858
 859         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 860         {
 861                 if (start_wp_is_spawned)
 862                         waypoint_clear_start_wp_globals(pl, true);
 863                 return;
 864         }
 865
 866         if (waypoint_has_hardwiredlinks(e))
 867         {
 868                 LOG_INFO("Can't remove a waypoint with hardwired links, remove links with \"wpeditor hardwire\" first\n");
 869                 return;
 870         }
 871
 872         entity wp_sym = NULL;
 873         if (sym)
 874         {
 875                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 876                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 877                         if(vdist(org - it.origin, <, 3))
 878                         {
 879                                 wp_sym = it;
 880                                 break;
 881                         }
 882                 });
 883         }
 884
 885         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 886         te_explosion(e.origin);
 887         waypoint_remove(e);
 888
 889         if (sym && wp_sym)
 890         {
 891                 e = wp_sym;
 892                 if(wp_num > 2)
 893                         wp_num--;
 894                 else
 895                         sym = false;
 896                 goto remove_wp;
 897         }
 898
 899         if (start_wp_is_spawned)
 900                 waypoint_clear_start_wp_globals(pl, true);
 901 }
 902
 903 void waypoint_removelink(entity from, entity to)
 904 {
 905         if (from == to || ((from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT))))
 906                 return;
 907
 908         entity fromwp31_prev = from.wp31;
 909
 910         switch (waypoint_getlinknum(from, to))
 911         {
 912                 // fallthrough all the way
 913                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 914                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 915                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 916                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 917                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 918                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 919                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 920                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 921                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 922                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 923                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 924                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 925                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 926                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 927                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 928                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 929                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 930                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 931                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 932                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 933                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 934                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 935                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 936                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 937                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 938                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 939                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 940                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 941                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 942                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 943                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 944                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 945         }
 946
 947         if (fromwp31_prev && !from.wp31)
 948                 waypoint_schedulerelink(from);
 949 }
 950
 951 int waypoint_getlinknum(entity from, entity to)
 952 {
 953         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 954         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 955         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 956         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 957         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 958         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 959         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 960         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 961         return -1;
 962 }
 963
 964 bool waypoint_islinked(entity from, entity to)
 965 {
 966         return (waypoint_getlinknum(from, to) >= 0);
 967 }
 968
 969 void waypoint_updatecost_foralllinks()
 970 {
 971         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 972         {
 973                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 974                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 975                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 976                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 977                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 978                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 979                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 980                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 981                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 982                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 983                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 984                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 985                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 986                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 987                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 988                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 989                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 990                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 991                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 992                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 993                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 994                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 995                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 996                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 997                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 998                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 999                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
1000                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
1001                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
1002                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
1003                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
1004                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
1005         });
1006 }
1007
1008 float waypoint_getlinearcost(float dist)
1009 {
1010         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
1011                 return dist / (autocvar_sv_maxspeed * 1.25);
1012         return dist / autocvar_sv_maxspeed;
1013 }
1014
1015 float waypoint_getlinearcost_underwater(float dist)
1016 {
1017         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
1018         return dist / (autocvar_sv_maxspeed * 0.7);
1019 }
1020
1021 float waypoint_getlinearcost_crouched(float dist)
1022 {
1023         return dist / (autocvar_sv_maxspeed * 0.5);
1024 }
1025
1026 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
1027 {
1028         bool submerged_from = navigation_check_submerged_state(from_ent, from);
1029         bool submerged_to = navigation_check_submerged_state(to_ent, to);
1030
1031         if (submerged_from && submerged_to)
1032                 return waypoint_getlinearcost_underwater(vlen(to - from));
1033
1034         if ((from_ent.wpflags & WAYPOINTFLAG_CROUCH) && (to_ent.wpflags & WAYPOINTFLAG_CROUCH))
1035                 return waypoint_getlinearcost_crouched(vlen(to - from));
1036
1037         float c = waypoint_getlinearcost(vlen(to - from));
1038
1039         float height = from.z - to.z;
1040         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
1041         {
1042                 float height_cost; // fall cost
1043                 if (from_ent.wpflags & WAYPOINTFLAG_JUMP)
1044                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
1045                 else
1046                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
1047                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
1048                 if(height_cost > c)
1049                         c = height_cost;
1050         }
1051
1052         // consider half path underwater
1053         if (submerged_from || submerged_to)
1054                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
1055
1056         // consider half path crouched
1057         if ((from_ent.wpflags & WAYPOINTFLAG_CROUCH) || (to_ent.wpflags & WAYPOINTFLAG_CROUCH))
1058                 return (c + waypoint_getlinearcost_crouched(vlen(to - from))) / 2;
1059
1060         return c;
1061 }
1062
1063 float waypoint_getlinkcost(entity from, entity to)
1064 {
1065         vector v1 = from.origin;
1066         vector v2 = to.origin;
1067         if (from.wpisbox)
1068         {
1069                 vector m1 = from.absmin, m2 = from.absmax;
1070                 v1.x = bound(m1.x, v2.x, m2.x);
1071                 v1.y = bound(m1.y, v2.y, m2.y);
1072                 v1.z = bound(m1.z, v2.z, m2.z);
1073         }
1074         if (to.wpisbox)
1075         {
1076                 vector m1 = to.absmin, m2 = to.absmax;
1077                 v2.x = bound(m1.x, v1.x, m2.x);
1078                 v2.y = bound(m1.y, v1.y, m2.y);
1079                 v2.z = bound(m1.z, v1.z, m2.z);
1080         }
1081         return waypoint_gettravelcost(v1, v2, from, to);
1082 }
1083
1084 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
1085 // if c == -1 automatically determine cost of the link
1086 void waypoint_addlink_customcost(entity from, entity to, float c)
1087 {
1088         if (from == to || waypoint_islinked(from, to))
1089                 return;
1090         if (c == -1 && (from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1091                 return;
1092
1093         if(c == -1)
1094                 c = waypoint_getlinkcost(from, to);
1095
1096         if (from.wp31mincost < c) return;
1097         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
1098         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
1099         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
1100         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
1101         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
1102         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
1103         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
1104         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
1105         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
1106         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
1107         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
1108         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
1109         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
1110         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
1111         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
1112         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
1113         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
1114         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
1115         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
1116         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
1117         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
1118         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
1119         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
1120         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
1121         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
1122         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
1123         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
1124         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
1125         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
1126         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
1127         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
1128         from.wp00 = to;from.wp00mincost = c;return;
1129 }
1130
1131 void waypoint_addlink(entity from, entity to)
1132 {
1133         if ((from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1134                 waypoint_addlink_for_custom_jumppad(from, to);
1135         else
1136                 waypoint_addlink_customcost(from, to, -1);
1137
1138         if (from.wpflags & WAYPOINTFLAG_SUPPORT)
1139                 to.SUPPORT_WP = from;
1140 }
1141
1142 // relink this spawnfunc_waypoint
1143 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
1144 // (SLOW!)
1145 void waypoint_think(entity this)
1146 {
1147         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
1148         float sv2_height = 0, ev2_height = 0;
1149
1150         bot_calculate_stepheightvec();
1151
1152         int dphitcontentsmask_save = this.dphitcontentsmask;
1153         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1154
1155         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
1156
1157         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
1158         IL_EACH(g_waypoints, this != it,
1159         {
1160                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
1161                 {
1162                         if (!(this.wpflags & WPFLAGMASK_NORELINK))
1163                                 waypoint_addlink(this, it);
1164                         if (!(it.wpflags & WPFLAGMASK_NORELINK))
1165                                 waypoint_addlink(it, this);
1166                 }
1167                 else
1168                 {
1169                         ++relink_total;
1170                         if(!checkpvs(this.origin, it))
1171                         {
1172                                 ++relink_pvsculled;
1173                                 continue;
1174                         }
1175
1176                         sv = set_tracewalk_dest_2(this, it.origin);
1177                         sv2 = tracewalk_dest;
1178                         sv2_height = tracewalk_dest_height;
1179                         ev = set_tracewalk_dest_2(it, this.origin);
1180                         ev2 = tracewalk_dest;
1181                         ev2_height = tracewalk_dest_height;
1182
1183                         dv = ev - sv;
1184                         dv.z = 0;
1185                         int maxdist = 1050;
1186                         vector m1 = PL_MIN_CONST;
1187                         vector m2 = PL_MAX_CONST;
1188
1189                         if ((this.wpflags & WAYPOINTFLAG_CROUCH) || (it.wpflags & WAYPOINTFLAG_CROUCH))
1190                         {
1191                                 m1 = PL_CROUCH_MIN_CONST;
1192                                 m2 = PL_CROUCH_MAX_CONST;
1193                                 // links from crouch wp to normal wp (and viceversa) are very short to avoid creating many links
1194                                 // that would be wasted due to rough travel cost calculation (the longer link is, the higher cost is)
1195                                 // links from crouch wp to crouch wp can be as long as normal links
1196                                 if (!((this.wpflags & WAYPOINTFLAG_CROUCH) && (it.wpflags & WAYPOINTFLAG_CROUCH)))
1197                                         maxdist = 100;
1198                         }
1199
1200                         if (vdist(dv, >=, maxdist)) // max search distance in XY
1201                         {
1202                                 ++relink_lengthculled;
1203                                 continue;
1204                         }
1205
1206                         navigation_testtracewalk = 0;
1207
1208                         //traceline(this.origin, it.origin, false, NULL);
1209                         //if (trace_fraction == 1)
1210                         if (this.wpisbox || (this.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)) // forbid outgoing links
1211                                 || it.SUPPORT_WP) // forbid incoming links
1212                         {
1213                                 relink_walkculled += 0.5;
1214                         }
1215                         else
1216                         {
1217                                 if (tracewalk(this, sv, m1, m2, ev2, ev2_height, MOVE_NOMONSTERS))
1218                                         waypoint_addlink(this, it);
1219                                 else
1220                                         relink_walkculled += 0.5;
1221                         }
1222
1223                         // reverse direction
1224                         if (it.wpisbox || (it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)) // forbid incoming links
1225                                 || this.SUPPORT_WP) // forbid outgoing links
1226                         {
1227                                 relink_walkculled += 0.5;
1228                         }
1229                         else
1230                         {
1231                                 if (tracewalk(this, ev, m1, m2, sv2, sv2_height, MOVE_NOMONSTERS))
1232                                         waypoint_addlink(it, this);
1233                                 else
1234                                         relink_walkculled += 0.5;
1235                         }
1236                 }
1237         });
1238
1239         // waypoint_clearlinks preserves references to old hardwired links (.wphwXX links)
1240         // so they can be restored here when a wp is spawned over an existing one
1241         waypoint_restore_hardwiredlinks(this);
1242
1243         navigation_testtracewalk = 0;
1244         this.wplinked = true;
1245         this.dphitcontentsmask = dphitcontentsmask_save;
1246
1247         setthink(this, func_null);
1248         this.nextthink = 0;
1249 }
1250
1251 void waypoint_clearlinks(entity wp)
1252 {
1253         // clear links to other waypoints
1254         float f = 10000000;
1255         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1256         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1257         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1258         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1259
1260         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1261         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1262         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1263         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1264
1265         // don't remove references to hardwired links (.wphwXX fields)
1266
1267         wp.wplinked = false;
1268 }
1269
1270 // tell a spawnfunc_waypoint to relink
1271 void waypoint_schedulerelink(entity wp)
1272 {
1273         if (wp == NULL)
1274                 return;
1275
1276         waypoint_setupmodel(wp);
1277         wp.wpisbox = vdist(wp.size, >, 0);
1278         wp.enemy = NULL;
1279         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1280                 wp.owner = NULL;
1281         if (!(wp.wpflags & WPFLAGMASK_NORELINK))
1282                 waypoint_clearlinks(wp);
1283         // schedule an actual relink on next frame
1284         setthink(wp, waypoint_think);
1285         wp.nextthink = time;
1286         wp.effects = EF_LOWPRECISION;
1287 }
1288
1289 // spawnfunc_waypoint map entity
1290 spawnfunc(waypoint)
1291 {
1292         IL_PUSH(g_waypoints, this);
1293
1294         setorigin(this, this.origin);
1295         // schedule a relink after other waypoints have had a chance to spawn
1296         waypoint_clearlinks(this);
1297         //waypoint_schedulerelink(this);
1298 }
1299
1300 // tell all waypoints to relink
1301 // actually this is useful only to update relink_* stats
1302 void waypoint_schedulerelinkall()
1303 {
1304         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1305         IL_EACH(g_waypoints, true,
1306         {
1307                 waypoint_schedulerelink(it);
1308         });
1309         waypoint_load_hardwiredlinks();
1310 }
1311
1312 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1313
1314 // Load waypoint links from file
1315 bool waypoint_load_links()
1316 {
1317         string s;
1318         float file, tokens, c = 0, found;
1319         entity wp_from = NULL, wp_to;
1320         vector wp_to_pos, wp_from_pos;
1321
1322         string gt_ext = GET_GAMETYPE_EXTENSION();
1323
1324         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1325         file = fopen(filename, FILE_READ);
1326
1327         if (gt_ext != "" && file < 0)
1328         {
1329                 // if race waypoint file doesn't exist load the default one
1330                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1331                 file = fopen(filename, FILE_READ);
1332         }
1333
1334         if (file < 0)
1335         {
1336                 LOG_TRACE("waypoint links load from ", filename, " failed");
1337                 waypoint_schedulerelinkall();
1338                 return false;
1339         }
1340
1341         bool parse_comments = true;
1342         float ver = 0;
1343         string links_time = string_null;
1344
1345         while ((s = fgets(file)))
1346         {
1347                 if(parse_comments)
1348                 {
1349                         if(substring(s, 0, 2) == "//")
1350                         {
1351                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1352                                         ver = stof(substring(s, 19, -1));
1353                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1354                                         links_time = substring(s, 16, -1);
1355                                 continue;
1356                         }
1357                         else
1358                         {
1359                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1360                                 {
1361                                         if (links_time != waypoint_time)
1362                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1363                                         else
1364                                                 LOG_TRACE("waypoint links for this map are outdated.");
1365                                         if (g_assault)
1366                                         {
1367                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1368                                         }
1369                                         else
1370                                         {
1371                                                 LOG_TRACE("automatically updating...");
1372                                                 waypoint_schedulerelinkall();
1373                                                 fclose(file);
1374                                                 return false;
1375                                         }
1376                                 }
1377                                 parse_comments = false;
1378                         }
1379                 }
1380
1381                 tokens = tokenizebyseparator(s, "*");
1382
1383                 if (tokens!=2)
1384                 {
1385                         // bad file format
1386                         fclose(file);
1387                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1388                         return false;
1389                 }
1390
1391                 wp_from_pos     = stov(argv(0));
1392                 wp_to_pos       = stov(argv(1));
1393
1394                 // Search "from" waypoint
1395                 if(!wp_from || wp_from.origin!=wp_from_pos)
1396                 {
1397                         wp_from = findradius(wp_from_pos, 1);
1398                         found = false;
1399                         while(wp_from)
1400                         {
1401                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1402                                 if(wp_from.classname == "waypoint")
1403                                 {
1404                                         found = true;
1405                                         break;
1406                                 }
1407                                 wp_from = wp_from.chain;
1408                         }
1409
1410                         if(!found)
1411                         {
1412                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1413                                 continue;
1414                         }
1415                 }
1416
1417                 // Search "to" waypoint
1418                 wp_to = findradius(wp_to_pos, 1);
1419                 found = false;
1420                 while(wp_to)
1421                 {
1422                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1423                         if(wp_to.classname == "waypoint")
1424                         {
1425                                 found = true;
1426                                 break;
1427                         }
1428                         wp_to = wp_to.chain;
1429                 }
1430
1431                 if(!found)
1432                 {
1433                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1434                         continue;
1435                 }
1436
1437                 ++c;
1438                 waypoint_addlink(wp_from, wp_to);
1439                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1440                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1441         }
1442
1443         fclose(file);
1444
1445         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1446
1447         bool scheduled = false;
1448         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1449         {
1450                 if (!it.wp00)
1451                 {
1452                         waypoint_schedulerelink(it);
1453                         scheduled = true;
1454                 }
1455         });
1456         if (scheduled)
1457                 return false;
1458
1459         botframe_cachedwaypointlinks = true;
1460         return true;
1461 }
1462
1463 void waypoint_load_hardwiredlinks()
1464 {
1465         string s;
1466         float file, tokens, c = 0, found;
1467         entity wp_from = NULL, wp_to;
1468         vector wp_to_pos, wp_from_pos;
1469
1470         string gt_ext = GET_GAMETYPE_EXTENSION();
1471
1472         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1473         file = fopen(filename, FILE_READ);
1474
1475         if (gt_ext != "" && file < 0)
1476         {
1477                 // if race waypoint file doesn't exist load the default one
1478                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1479                 file = fopen(filename, FILE_READ);
1480         }
1481
1482         botframe_loadedforcedlinks = true;
1483
1484         if (file < 0)
1485         {
1486                 LOG_TRACE("waypoint links load from ", filename, " failed");
1487                 return;
1488         }
1489
1490         bool is_special = false;
1491         while ((s = fgets(file)))
1492         {
1493                 if(substring(s, 0, 2)=="//")
1494                         continue;
1495
1496                 if(substring(s, 0, 1)=="#")
1497                         continue;
1498
1499                 // special links start with *, so old xonotic versions don't load them
1500                 is_special = false;
1501                 if (substring(s, 0, 1) == "*")
1502                 {
1503                         is_special = true;
1504                         s = substring(s, 1, -1);
1505                 }
1506
1507                 tokens = tokenizebyseparator(s, "*");
1508
1509                 if (tokens!=2)
1510                         continue;
1511
1512                 wp_from_pos     = stov(argv(0));
1513                 wp_to_pos       = stov(argv(1));
1514
1515                 // Search "from" waypoint
1516                 if(!wp_from || wp_from.origin!=wp_from_pos)
1517                 {
1518                         wp_from = findradius(wp_from_pos, 5);
1519                         found = false;
1520                         while(wp_from)
1521                         {
1522                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1523                                 if(wp_from.classname == "waypoint")
1524                                 {
1525                                         found = true;
1526                                         break;
1527                                 }
1528                                 wp_from = wp_from.chain;
1529                         }
1530
1531                         if(!found)
1532                         {
1533                                 s = strcat(((is_special) ? "special link " : "hardwired link "), s);
1534                                 LOG_INFO("NOTICE: Can not find origin waypoint of the ", s, ". Path skipped");
1535                                 continue;
1536                         }
1537                 }
1538
1539                 // Search "to" waypoint
1540                 wp_to = findradius(wp_to_pos, 5);
1541                 found = false;
1542                 while(wp_to)
1543                 {
1544                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1545                         if(wp_to.classname == "waypoint")
1546                         {
1547                                 found = true;
1548                                 break;
1549                         }
1550                         wp_to = wp_to.chain;
1551                 }
1552
1553                 if(!found)
1554                 {
1555                         s = strcat(((is_special) ? "special link " : "hardwired link "), s);
1556                         LOG_INFO("NOTICE: Can not find destination waypoint of the ", s, ". Path skipped");
1557                         continue;
1558                 }
1559
1560                 ++c;
1561
1562                 if (!is_special)
1563                 {
1564                         waypoint_addlink(wp_from, wp_to);
1565                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1566                 } else if (wp_from.wpflags & WPFLAGMASK_NORELINK
1567                         && ((wp_from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT))
1568                                 || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1569                 {
1570                         waypoint_addlink(wp_from, wp_to);
1571                 }
1572         }
1573
1574         fclose(file);
1575
1576         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1577 }
1578
1579 float waypoint_get_assigned_link_cost(entity w, float i)
1580 {
1581         switch(i)
1582         {
1583                 case  0: return w.wp00mincost;
1584                 case  1: return w.wp01mincost;
1585                 case  2: return w.wp02mincost;
1586                 case  3: return w.wp03mincost;
1587                 case  4: return w.wp04mincost;
1588                 case  5: return w.wp05mincost;
1589                 case  6: return w.wp06mincost;
1590                 case  7: return w.wp07mincost;
1591                 case  8: return w.wp08mincost;
1592                 case  9: return w.wp09mincost;
1593                 case 10: return w.wp10mincost;
1594                 case 11: return w.wp11mincost;
1595                 case 12: return w.wp12mincost;
1596                 case 13: return w.wp13mincost;
1597                 case 14: return w.wp14mincost;
1598                 case 15: return w.wp15mincost;
1599                 case 16: return w.wp16mincost;
1600                 case 17: return w.wp17mincost;
1601                 case 18: return w.wp18mincost;
1602                 case 19: return w.wp19mincost;
1603                 case 20: return w.wp20mincost;
1604                 case 21: return w.wp21mincost;
1605                 case 22: return w.wp22mincost;
1606                 case 23: return w.wp23mincost;
1607                 case 24: return w.wp24mincost;
1608                 case 25: return w.wp25mincost;
1609                 case 26: return w.wp26mincost;
1610                 case 27: return w.wp27mincost;
1611                 case 28: return w.wp28mincost;
1612                 case 29: return w.wp29mincost;
1613                 case 30: return w.wp30mincost;
1614                 case 31: return w.wp31mincost;
1615                 default: return -1;
1616         }
1617 }
1618
1619 entity waypoint_get_link(entity w, float i)
1620 {
1621         switch(i)
1622         {
1623                 case  0:return w.wp00;
1624                 case  1:return w.wp01;
1625                 case  2:return w.wp02;
1626                 case  3:return w.wp03;
1627                 case  4:return w.wp04;
1628                 case  5:return w.wp05;
1629                 case  6:return w.wp06;
1630                 case  7:return w.wp07;
1631                 case  8:return w.wp08;
1632                 case  9:return w.wp09;
1633                 case 10:return w.wp10;
1634                 case 11:return w.wp11;
1635                 case 12:return w.wp12;
1636                 case 13:return w.wp13;
1637                 case 14:return w.wp14;
1638                 case 15:return w.wp15;
1639                 case 16:return w.wp16;
1640                 case 17:return w.wp17;
1641                 case 18:return w.wp18;
1642                 case 19:return w.wp19;
1643                 case 20:return w.wp20;
1644                 case 21:return w.wp21;
1645                 case 22:return w.wp22;
1646                 case 23:return w.wp23;
1647                 case 24:return w.wp24;
1648                 case 25:return w.wp25;
1649                 case 26:return w.wp26;
1650                 case 27:return w.wp27;
1651                 case 28:return w.wp28;
1652                 case 29:return w.wp29;
1653                 case 30:return w.wp30;
1654                 case 31:return w.wp31;
1655                 default:return NULL;
1656         }
1657 }
1658
1659 // Save all hardwired waypoint links to a file
1660 void waypoint_save_hardwiredlinks()
1661 {
1662         string gt_ext = GET_GAMETYPE_EXTENSION();
1663
1664         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1665         int file = fopen(filename, FILE_WRITE);
1666         if (file < 0)
1667         {
1668                 LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1669                 return;
1670         }
1671
1672         // write hardwired links to file
1673         int count = 0;
1674         fputs(file, "// HARDWIRED LINKS\n");
1675         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1676         {
1677                 for (int j = 0; j < 32; ++j)
1678                 {
1679                         entity link = waypoint_get_link(it, j);
1680                         if (waypoint_is_hardwiredlink(it, link))
1681                         {
1682                                 // NOTE: vtos rounds vector components to 1 decimal place
1683                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1684                                 fputs(file, s);
1685                                 ++count;
1686                         }
1687                 }
1688         });
1689
1690         // write special links to file
1691         int count2 = 0;
1692         fputs(file, "\n// SPECIAL LINKS\n");
1693         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP),
1694         {
1695                 for (int j = 0; j < 32; ++j)
1696                 {
1697                         entity link = waypoint_get_link(it, j);
1698                         if (link)
1699                         {
1700                                 // NOTE: vtos rounds vector components to 1 decimal place
1701                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin), "\n");
1702                                 fputs(file, s);
1703                                 ++count2;
1704                         }
1705                 }
1706         });
1707
1708         fclose(file);
1709
1710         LOG_INFOF("saved %d hardwired links and %d special links to %s", count, count2, filename);
1711 }
1712
1713 // Save all waypoint links to a file
1714 void waypoint_save_links()
1715 {
1716         string gt_ext = GET_GAMETYPE_EXTENSION();
1717
1718         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1719         int file = fopen(filename, FILE_WRITE);
1720         if (file < 0)
1721         {
1722                 LOG_INFOF("waypoint link save to %s failed", filename);
1723                 return;
1724         }
1725
1726         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1727         if (waypoint_time != "")
1728                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1729
1730         int c = 0;
1731         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP)),
1732         {
1733                 for(int j = 0; j < 32; ++j)
1734                 {
1735                         entity link = waypoint_get_link(it, j);
1736                         if (link && !waypoint_is_hardwiredlink(it, link))
1737                         {
1738                                 // NOTE: vtos rounds vector components to 1 decimal place
1739                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1740                                 fputs(file, s);
1741                                 ++c;
1742                         }
1743                 }
1744         });
1745         fclose(file);
1746
1747         botframe_cachedwaypointlinks = true;
1748
1749         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1750 }
1751
1752 // save waypoints to gamedir/data/maps/mapname.waypoints
1753 void waypoint_saveall()
1754 {
1755         if (WAYPOINT_VERSION < waypoint_version_loaded)
1756         {
1757                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1758                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1759                 return;
1760         }
1761         string gt_ext = GET_GAMETYPE_EXTENSION();
1762
1763         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1764         int file = fopen(filename, FILE_WRITE);
1765         if (file < 0)
1766         {
1767                 waypoint_save_links(); // save anyway?
1768                 botframe_loadedforcedlinks = false;
1769
1770                 LOG_INFOF("waypoint links: save to %s failed", filename);
1771                 return;
1772         }
1773
1774         float sym = autocvar_g_waypointeditor_symmetrical;
1775         string sym_str = ftos(sym);
1776         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1777         {
1778                 if (sym == 1)
1779                 {
1780                         sym_str = cons(sym_str, "-");
1781                         sym_str = cons(sym_str, "-");
1782                 }
1783                 else
1784                 {
1785                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1786                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1787                 }
1788                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1789                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1790         }
1791         else if (autocvar_g_waypointeditor_symmetrical == -2)
1792         {
1793                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1794                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1795         }
1796
1797         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1798         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1799         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1800         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1801
1802         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1803         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1804         //fputs(file, strcat("//", "\n"));
1805         //fputs(file, strcat("//", "\n"));
1806         //fputs(file, strcat("//", "\n"));
1807
1808         int c = 0;
1809         IL_EACH(g_waypoints, true,
1810         {
1811                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1812                         continue;
1813
1814                 string s;
1815                 // NOTE: vtos rounds vector components to 1 decimal place
1816                 s = strcat(vtos(it.origin + it.mins), "\n");
1817                 s = strcat(s, vtos(it.origin + it.maxs));
1818                 s = strcat(s, "\n");
1819                 s = strcat(s, ftos(it.wpflags));
1820                 s = strcat(s, "\n");
1821                 fputs(file, s);
1822                 c++;
1823         });
1824         fclose(file);
1825         waypoint_save_links();
1826         waypoint_save_hardwiredlinks();
1827
1828         botframe_loadedforcedlinks = false;
1829
1830         waypoint_version_loaded = WAYPOINT_VERSION;
1831         LOG_INFOF("saved %d waypoints to %s", c, filename);
1832 }
1833
1834 // load waypoints from file
1835 float waypoint_loadall()
1836 {
1837         string s;
1838         int file, cwp, cwb, fl;
1839         vector m1, m2;
1840         cwp = 0;
1841         cwb = 0;
1842
1843         string gt_ext = GET_GAMETYPE_EXTENSION();
1844
1845         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1846         file = fopen(filename, FILE_READ);
1847
1848         if (gt_ext != "" && file < 0)
1849         {
1850                 // if race waypoint file doesn't exist load the default one
1851                 filename = sprintf("maps/%s.waypoints", mapname);
1852                 file = fopen(filename, FILE_READ);
1853         }
1854
1855         if (file < 0)
1856         {
1857                 LOG_TRACE("waypoint load from ", filename, " failed");
1858                 return 0;
1859         }
1860
1861         bool parse_comments = true;
1862         float ver = 0;
1863         float sym = 0;
1864         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1865
1866         while ((s = fgets(file)))
1867         {
1868                 if(parse_comments)
1869                 {
1870                         if(substring(s, 0, 2) == "//")
1871                         {
1872                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1873                                         ver = stof(substring(s, 19, -1));
1874                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1875                                 {
1876                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1877                                         if (tokens) { sym = stof(argv(0)); }
1878                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1879                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1880                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1881                                 }
1882                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1883                                         strcpy(waypoint_time, substring(s, 16, -1));
1884                                 continue;
1885                         }
1886                         else
1887                         {
1888                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1889                                 {
1890                                         LOG_TRACE("waypoints for this map are outdated");
1891                                         LOG_TRACE("please update them in the editor");
1892                                 }
1893                                 parse_comments = false;
1894                         }
1895                 }
1896                 m1 = stov(s);
1897                 s = fgets(file);
1898                 if (!s)
1899                         break;
1900                 m2 = stov(s);
1901                 s = fgets(file);
1902                 if (!s)
1903                         break;
1904                 fl = stof(s);
1905                 fl &= ~WAYPOINTFLAG_NORELINK__DEPRECATED;
1906                 waypoint_spawn(m1, m2, fl);
1907                 if (m1 == m2)
1908                         cwp = cwp + 1;
1909                 else
1910                         cwb = cwb + 1;
1911         }
1912         fclose(file);
1913         waypoint_version_loaded = ver;
1914         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1915
1916         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1917         {
1918                 string sym_str = "";
1919                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1920                 if (sym == 1 && sym_param3 < 2)
1921                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1922                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1923                 {
1924                         string params;
1925                         if (sym == 1)
1926                                 params = cons("-", "-");
1927                         else
1928                         {
1929                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1930                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1931                         }
1932                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1933                         sym_str = strcat(ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1934                 }
1935                 else if (sym == -2)
1936                 {
1937                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1938                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1939                         sym_str = strcat(ftos(sym), " with axis ", params);
1940                 }
1941                 else
1942                         sym_str = ftos(sym);
1943                 if (sym_str != "")
1944                         LOG_INFO("Waypoint editor: loaded symmetry ", sym_str);
1945                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1946         }
1947
1948         if (WAYPOINT_VERSION < waypoint_version_loaded)
1949                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1950                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1951
1952         return cwp + cwb;
1953 }
1954
1955 #define waypoint_fixorigin(position, tracetest_ent) \
1956         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1957
1958 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1959 {
1960         vector endpos = position + down_dir * 3000;
1961         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1962         if(trace_startsolid)
1963                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1964         if(trace_startsolid)
1965                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1966         if(trace_fraction < 1)
1967                 position = trace_endpos;
1968         return position;
1969 }
1970
1971 void waypoint_spawnforitem_force(entity e, vector org)
1972 {
1973         // Fix the waypoint altitude if necessary
1974         org = waypoint_fixorigin(org, NULL);
1975
1976         // don't spawn an item spawnfunc_waypoint if it already exists
1977         IL_EACH(g_waypoints, true,
1978         {
1979                 if(it.wpisbox)
1980                 {
1981                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1982                         {
1983                                 e.nearestwaypoint = it;
1984                                 return;
1985                         }
1986                 }
1987                 else
1988                 {
1989                         if(vdist(it.origin - org, <, 16))
1990                         {
1991                                 e.nearestwaypoint = it;
1992                                 return;
1993                         }
1994                 }
1995         });
1996
1997         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1998 }
1999
2000 void waypoint_spawnforitem(entity e)
2001 {
2002         if(!bot_waypoints_for_items)
2003                 return;
2004
2005         waypoint_spawnforitem_force(e, e.origin);
2006 }
2007
2008 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
2009 {
2010         entity w;
2011         entity dw;
2012         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag);
2013         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
2014         // one way link to the destination
2015         w.wp00_original = dw;
2016         w.wp00 = dw;
2017         w.wp00mincost = timetaken; // this is just for jump pads
2018         // the teleporter's nearest spawnfunc_waypoint is this one
2019         // (teleporters are not goals, so this is probably useless)
2020         e.nearestwaypoint = w;
2021         e.nearestwaypointtimeout = -1;
2022 }
2023
2024 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
2025 {
2026         float src_angle = e.warpzone_angles.x;
2027         while (src_angle < -180) src_angle += 360;
2028         while (src_angle > 180) src_angle -= 360;
2029
2030         float dest_angle = e.enemy.warpzone_angles.x;
2031         while (dest_angle < -180) dest_angle += 360;
2032         while (dest_angle > 180) dest_angle -= 360;
2033
2034         // no waypoints for warpzones pointing upwards, they can't be used by the bots
2035         if (src_angle == -90 || dest_angle == -90)
2036                 return;
2037
2038         makevectors(e.warpzone_angles);
2039         vector src = (e.absmin + e.absmax) * 0.5;
2040         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
2041         vector down_dir_src = -v_up;
2042
2043         makevectors(e.enemy.warpzone_angles);
2044         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
2045         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
2046         vector down_dir_dest = -v_up;
2047
2048         int extra_flag = 0;
2049         // don't snap to the ground waypoints for source warpzones pointing downwards
2050         if (src_angle != 90)
2051         {
2052                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
2053                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
2054                 // oblique warpzones need a jump otherwise bots gets stuck
2055                 if (src_angle != 0)
2056                         extra_flag = WAYPOINTFLAG_JUMP;
2057         }
2058
2059         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
2060 }
2061
2062 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
2063 {
2064         destination = waypoint_fixorigin(destination, tracetest_ent);
2065         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
2066 }
2067
2068 entity waypoint_spawnpersonal(entity this, vector position)
2069 {
2070         entity w;
2071
2072         // drop the waypoint to a proper location:
2073         //   first move it up by a player height
2074         //   then move it down to hit the floor with player bbox size
2075         position = waypoint_fixorigin(position, this);
2076
2077         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
2078         w.nearestwaypoint = NULL;
2079         w.nearestwaypointtimeout = 0;
2080         w.owner = this;
2081
2082         waypoint_schedulerelink(w);
2083
2084         return w;
2085 }
2086
2087 void waypoint_showlink(entity wp1, entity wp2, int display_type)
2088 {
2089         if (!(wp1 && wp2))
2090                 return;
2091
2092         if (waypoint_is_hardwiredlink(wp1, wp2) || (wp1.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP)))
2093                 te_beam(NULL, wp1.origin, wp2.origin);
2094         else if (display_type == 1)
2095                 te_lightning2(NULL, wp1.origin, wp2.origin);
2096 }
2097
2098 void waypoint_showlinks_to(entity wp, int display_type)
2099 {
2100         IL_EACH(g_waypoints, it != wp,
2101         {
2102                 if (waypoint_islinked(it, wp))
2103                         waypoint_showlink(it, wp, display_type);
2104         });
2105 }
2106
2107 void waypoint_showlinks_from(entity wp, int display_type)
2108 {
2109         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
2110         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
2111         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
2112         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
2113         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
2114         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
2115         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
2116         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
2117         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
2118         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
2119         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
2120         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
2121         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
2122         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
2123         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
2124         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
2125 }
2126
2127 void crosshair_trace_waypoints(entity pl)
2128 {
2129         IL_EACH(g_waypoints, true, {
2130                 it.solid = SOLID_BSP;
2131                 if (!it.wpisbox)
2132                         setsize(it, '-16 -16 -16', '16 16 16');
2133         });
2134
2135         WarpZone_crosshair_trace(pl);
2136
2137         IL_EACH(g_waypoints, true, {
2138                 it.solid = SOLID_TRIGGER;
2139                 if (!it.wpisbox)
2140                         setsize(it, '0 0 0', '0 0 0');
2141         });
2142
2143         if (trace_ent.classname != "waypoint")
2144                 trace_ent = NULL;
2145         else if (!trace_ent.wpisbox)
2146                 trace_endpos = trace_ent.origin;
2147 }
2148
2149 void botframe_showwaypointlinks()
2150 {
2151         if (time < botframe_waypointeditorlightningtime)
2152                 return;
2153         botframe_waypointeditorlightningtime = time + 0.5;
2154         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
2155         {
2156                 int display_type = 0;
2157                 if (wasfreed(it.wp_aimed))
2158                         it.wp_aimed = NULL;
2159                 if (wasfreed(it.wp_locked))
2160                         it.wp_locked = NULL;
2161                 entity head = it.wp_locked;
2162                 if (!head)
2163                         head = navigation_findnearestwaypoint(it, false);
2164                 it.nearestwaypoint = head; // mainly useful for debug
2165                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
2166                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
2167                         display_type = 1; // default
2168                 else if(waypoint_has_hardwiredlinks(head))
2169                         display_type = 2; // only hardwired
2170
2171                 if (display_type)
2172                 {
2173                         //navigation_testtracewalk = true;
2174                         //print("currently selected WP is ", etos(head), "\n");
2175                         //navigation_testtracewalk = false;
2176                         if (head)
2177                         {
2178                                 te_lightning2(NULL, head.origin, it.origin);
2179                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
2180                                         waypoint_showlinks_to(head, display_type);
2181                                 else
2182                                         waypoint_showlinks_from(head, display_type);
2183                         }
2184                 }
2185                 string str;
2186                 entity wp = NULL;
2187                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
2188                 {
2189                         crosshair_trace_waypoints(it);
2190                         if (trace_ent)
2191                         {
2192                                 wp = trace_ent;
2193                                 if (wp != it.wp_aimed)
2194                                 {
2195                                         string wp_type_str = waypoint_get_type_name(wp);
2196                                         str = sprintf("\necho Entity %d: %s^7, flags: %d, origin: %s\n", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2197                                         if (wp.wpisbox)
2198                                                 str = strcat(str, sprintf("echo \" absmin: %s, absmax: %s\"\n", vtos(wp.absmin), vtos(wp.absmax)));
2199                                         stuffcmd(it, str);
2200                                         str = sprintf("Entity %d: %s^7\nflags: %d\norigin: %s", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2201                                         if (wp.wpisbox)
2202                                                 str = strcat(str, sprintf(" \nabsmin: %s\nabsmax: %s", vtos(wp.absmin), vtos(wp.absmax)));
2203                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
2204                                 }
2205                         }
2206                 }
2207                 if (it.wp_aimed != wp)
2208                         it.wp_aimed = wp;
2209         });
2210 }
2211
2212 float botframe_autowaypoints_fixdown(vector v)
2213 {
2214         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
2215         if(trace_fraction >= 1)
2216                 return 0;
2217         return 1;
2218 }
2219
2220 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
2221 {
2222         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
2223         {
2224                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
2225                 return 0;
2226         });
2227
2228         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2229         return 1;
2230 }
2231
2232 // return value:
2233 //    1 = WP created
2234 //    0 = no action needed
2235 //   -1 = temp fail, try from world too
2236 //   -2 = permanent fail, do not retry
2237 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2238 {
2239         // make it possible to go from p to wp, if we can
2240         // if wp is NULL, nearest is chosen
2241
2242         entity w;
2243         vector porg;
2244         float t, tmin, tmax;
2245         vector o;
2246         vector save;
2247
2248         if(!botframe_autowaypoints_fixdown(p.origin))
2249                 return -2;
2250         porg = trace_endpos;
2251
2252         if(wp)
2253         {
2254                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2255
2256                 // if wp -> porg, then OK
2257                 float maxdist;
2258                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2259                 {
2260                         // we may find a better one
2261                         maxdist = vlen(wp.origin - porg);
2262                 }
2263                 else
2264                 {
2265                         // accept any "good"
2266                         maxdist = 2100;
2267                 }
2268
2269                 float bestdist = maxdist;
2270                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WPFLAGMASK_NORELINK),
2271                 {
2272                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2273                         if(d < bestdist)
2274                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2275                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2276                         {
2277                                 bestdist = d;
2278                                 p.(fld) = it;
2279                         }
2280                 });
2281                 if(bestdist < maxdist)
2282                 {
2283                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2284                         return 0;
2285                 }
2286
2287                 if(bestdist < 2100)
2288                 {
2289                         // we know maxdist < 2100
2290                         // so wp -> porg is still valid
2291                         // all is good
2292                         p.(fld) = wp;
2293                         return 0;
2294                 }
2295
2296                 // otherwise, no existing WP can fix our issues
2297         }
2298         else
2299         {
2300                 save = p.origin;
2301                 setorigin(p, porg);
2302                 w = navigation_findnearestwaypoint(p, walkfromwp);
2303                 setorigin(p, save);
2304                 if(w)
2305                 {
2306                         p.(fld) = w;
2307                         return 0;
2308                 }
2309         }
2310
2311         tmin = 0;
2312         tmax = 1;
2313         for (;;)
2314         {
2315                 if(tmax - tmin < 0.001)
2316                 {
2317                         // did not get a good candidate
2318                         return -1;
2319                 }
2320
2321                 t = (tmin + tmax) * 0.5;
2322                 o = antilag_takebackorigin(p, CS(p), time - t);
2323                 if(!botframe_autowaypoints_fixdown(o))
2324                         return -2;
2325                 o = trace_endpos;
2326
2327                 if(wp)
2328                 {
2329                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2330                         {
2331                                 // we cannot walk from wp.origin to o
2332                                 // get closer to tmax
2333                                 tmin = t;
2334                                 continue;
2335                         }
2336                 }
2337                 else
2338                 {
2339                         save = p.origin;
2340                         setorigin(p, o);
2341                         w = navigation_findnearestwaypoint(p, walkfromwp);
2342                         setorigin(p, save);
2343                         if(!w)
2344                         {
2345                                 // we cannot walk from any WP to o
2346                                 // get closer to tmax
2347                                 tmin = t;
2348                                 continue;
2349                         }
2350                 }
2351
2352                 // if we get here, o is valid regarding waypoints
2353                 // check if o is connected right to the player
2354                 // we break if it succeeds, as that means o is a good waypoint location
2355                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2356                         break;
2357
2358                 // o is no good, we need to get closer to the player
2359                 tmax = t;
2360         }
2361
2362         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2363         botframe_autowaypoints_createwp(o, p, fld, 0);
2364         return 1;
2365 }
2366
2367 // automatically create missing waypoints
2368 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2369 {
2370         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2371         if(r != -1)
2372                 return;
2373         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2374         if(r != -1)
2375                 return;
2376
2377         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2378         if(!botframe_autowaypoints_fixdown(p.origin))
2379                 return; // shouldn't happen, caught above
2380         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2381 }
2382
2383 void botframe_deleteuselesswaypoints()
2384 {
2385         IL_EACH(g_items, it.bot_pickup,
2386         {
2387                 // NOTE: this protects waypoints if they're the ONLY nearest
2388                 // waypoint. That's the intention.
2389                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2390                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2391         });
2392         IL_EACH(g_waypoints, true,
2393         {
2394                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2395                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2396                 // WP is useful if:
2397                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2398                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2399                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2400                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2401                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2402                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2403                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2404                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2405                 // b) WP is closest WP for an item/spawnpoint/other entity
2406                 //    This has been done above by protecting these WPs.
2407         });
2408         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2409         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2410         {
2411                 for (int m = 0; m < 32; ++m)
2412                 {
2413                         entity w = waypoint_get_link(it, m);
2414                         if (!w)
2415                                 break;
2416                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2417                                 continue;
2418                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2419                                 continue;
2420                         for (int j = 0; j < 32; ++j)
2421                         {
2422                                 entity w2 = waypoint_get_link(w, j);
2423                                 if (!w2)
2424                                         break;
2425                                 if (it == w2)
2426                                         continue;
2427                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2428                                         continue;
2429                                 // If we got here, it != w2 exist with it -> w
2430                                 // and w -> w2. That means the waypoint is not
2431                                 // a dead end.
2432                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2433                                 for (int k = 0; k < 32; ++k)
2434                                 {
2435                                         if (waypoint_get_link(it, k) == w2)
2436                                                 continue;
2437                                         // IF WE GET HERE, w is proven useful
2438                                         // to get from it to w2!
2439                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2440                                         goto next;
2441                                 }
2442                         }
2443 LABEL(next)
2444                 }
2445         });
2446         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2447         //     they are needed to complete routes while autowaypointing.
2448
2449         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2450         {
2451                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2452                 te_explosion(it.origin);
2453                 waypoint_remove(it);
2454                 break;
2455         });
2456
2457         IL_EACH(g_waypoints, true,
2458         {
2459                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2460         });
2461 }
2462
2463 //.entity botframe_autowaypoints_lastwp0;
2464 .entity botframe_autowaypoints_lastwp1;
2465 void botframe_autowaypoints()
2466 {
2467         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2468                 // going back is broken, so only fix waypoints to walk TO the player
2469                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2470                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2471                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2472         });
2473
2474         if (autocvar_g_waypointeditor_auto >= 2) {
2475                 botframe_deleteuselesswaypoints();
2476         }
2477 }
2478