qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 void crosshair_trace_waypoints(entity pl);
 264 void waypoint_lock(entity pl)
 265 {
 266         crosshair_trace_waypoints(pl);
 267         pl.wp_locked = trace_ent;
 268 }
 269
 270 bool waypoint_has_hardwiredlinks(entity wp)
 271 {
 272         if (!wp)
 273                 return false;
 274         return (wp.wphw00 != NULL);
 275 }
 276
 277 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 278 {
 279         if (!(wp_from && wp_to))
 280                 return false;
 281
 282         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 283         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 284         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 285         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 286         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 287         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 288         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 289         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 290
 291         return false;
 292 }
 293
 294 void waypoint_setupmodel(entity wp);
 295 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 296 {
 297         if (!(wp_from && wp_to))
 298                 return;
 299
 300         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; waypoint_setupmodel(wp_from); return; }
 301         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 302         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 303         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 304         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 305         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 306         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 307         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 308
 309         return;
 310 }
 311
 312 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 313 {
 314         if (!(wp_from && wp_to))
 315                 return;
 316
 317         int removed = -1;
 318         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 319         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 320         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 321         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 322         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 323         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 324         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 325         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 326
 327         if (removed >= 0)
 328         {
 329                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 330                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 331                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 332                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 333                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 334                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 335                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 336                 if (removed <= 7) wp_from.wphw07 = NULL;
 337                 if (!wp_from.wphw00)
 338                         waypoint_setupmodel(wp_from);
 339         }
 340
 341         return;
 342 }
 343
 344 void waypoint_restore_hardwiredlinks(entity wp)
 345 {
 346         if (wp.wphw00) waypoint_addlink(wp, wp.wphw00);
 347         if (wp.wphw01) waypoint_addlink(wp, wp.wphw01);
 348         if (wp.wphw02) waypoint_addlink(wp, wp.wphw02);
 349         if (wp.wphw03) waypoint_addlink(wp, wp.wphw03);
 350         if (wp.wphw04) waypoint_addlink(wp, wp.wphw04);
 351         if (wp.wphw05) waypoint_addlink(wp, wp.wphw05);
 352         if (wp.wphw06) waypoint_addlink(wp, wp.wphw06);
 353         if (wp.wphw07) waypoint_addlink(wp, wp.wphw07);
 354 }
 355
 356 void waypoint_setupmodel(entity wp)
 357 {
 358         if (autocvar_g_waypointeditor)
 359         {
 360                 // TODO: add some sort of visible box in edit mode for box waypoints
 361                 vector m1 = wp.mins;
 362                 vector m2 = wp.maxs;
 363                 setmodel(wp, MDL_WAYPOINT);
 364                 setsize(wp, m1, m2);
 365                 wp.effects = EF_LOWPRECISION;
 366                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 367                         wp.colormod = '1 0 0'; // red
 368                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 369                         wp.colormod = '1 1 0'; // yellow
 370                 else if (wp.wpflags & WAYPOINTFLAG_SUPPORT)
 371                         wp.colormod = '0 1 0'; // green
 372                 else if (wp.wpflags & WAYPOINTFLAG_CUSTOM_JP)
 373                         wp.colormod = '1 0.5 0'; // orange
 374                 else if (wp.wpflags & WAYPOINTFLAG_TELEPORT)
 375                         wp.colormod = '1 0.5 0'; // orange
 376                 else if (wp.wpflags & WAYPOINTFLAG_LADDER)
 377                         wp.colormod = '1 0.5 0'; // orange
 378                 else if (wp.wpflags & WAYPOINTFLAG_JUMP)
 379                         wp.colormod = '1 0.5 0'; // orange
 380                 else if (wp.wpflags & WAYPOINTFLAG_CROUCH)
 381                         wp.colormod = '0 1 1'; // cyan
 382                 else if (waypoint_has_hardwiredlinks(wp))
 383                         wp.colormod = '0.5 0 1'; // purple
 384                 else
 385                         wp.colormod = '1 1 1';
 386         }
 387         else
 388                 wp.model = "";
 389 }
 390
 391 string waypoint_get_type_name(entity wp)
 392 {
 393         if (wp.wpflags & WAYPOINTFLAG_ITEM) return "^1Item waypoint";
 394         else if (wp.wpflags & WAYPOINTFLAG_CROUCH) return "^5Crouch waypoint";
 395         else if (wp.wpflags & WAYPOINTFLAG_JUMP) return "^xf80Jump waypoint";
 396         else if (wp.wpflags & WAYPOINTFLAG_SUPPORT) return "^2Support waypoint";
 397         else if (waypoint_has_hardwiredlinks(wp)) return "^x80fHardwired waypoint";
 398         else if (wp.wpflags & WAYPOINTFLAG_LADDER) return "^3Ladder waypoint";
 399         else if (wp.wpflags & WAYPOINTFLAG_TELEPORT)
 400         {
 401                 if (!wp.wpisbox) return "^3Warpzone waypoint";
 402                 else if (wp.wpflags & WAYPOINTFLAG_CUSTOM_JP) return "^3Custom jumppad waypoint";
 403                 else
 404                 {
 405                         IL_EACH(g_jumppads, boxesoverlap(wp.absmin, wp.absmax, it.absmin, it.absmax),
 406                                 { return "^3Jumppad waypoint"; });
 407                         return "^3Teleport waypoint";
 408                 }
 409         }
 410
 411         return "^7Waypoint";
 412 }
 413
 414 entity waypoint_get(vector m1, vector m2)
 415 {
 416         if (m1 == m2)
 417         {
 418                 m1 -= '8 8 8';
 419                 m2 += '8 8 8';
 420         }
 421         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 422
 423         return NULL;
 424 }
 425
 426 .float createdtime;
 427 entity waypoint_spawn(vector m1, vector m2, float f)
 428 {
 429         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 430         {
 431                 entity wp_found = waypoint_get(m1, m2);
 432                 if (wp_found)
 433                         return wp_found;
 434         }
 435         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 436         // otherwise links loaded from file would be applied only to the first destination
 437         // waypoint since link format doesn't specify waypoint entities but just positions
 438         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WPFLAGMASK_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 439         {
 440                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 441                 {
 442                         return it;
 443                 });
 444         }
 445
 446         entity w = new(waypoint);
 447         IL_PUSH(g_waypoints, w);
 448         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 449         w.wpflags = f;
 450         w.solid = SOLID_TRIGGER;
 451         w.createdtime = time;
 452         setorigin(w, (m1 + m2) * 0.5);
 453         setsize(w, m1 - w.origin, m2 - w.origin);
 454         if (w.size)
 455                 w.wpisbox = true;
 456
 457         if(!w.wpisbox)
 458         {
 459                 if (f & WAYPOINTFLAG_CROUCH)
 460                         setsize(w, PL_CROUCH_MIN_CONST - '1 1 0', PL_CROUCH_MAX_CONST + '1 1 0');
 461                 else
 462                         setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 463                 if(!move_out_of_solid(w))
 464                 {
 465                         if(!(f & WAYPOINTFLAG_GENERATED))
 466                         {
 467                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 468                                 delete(w);
 469                                 return NULL;
 470                         }
 471                         else
 472                         {
 473                                 if(autocvar_developer)
 474                                 {
 475                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 476                                         backtrace("Waypoint stuck");
 477                                 }
 478                         }
 479                 }
 480                 setsize(w, '0 0 0', '0 0 0');
 481         }
 482
 483         waypoint_clearlinks(w);
 484         //waypoint_schedulerelink(w);
 485
 486         waypoint_setupmodel(w);
 487
 488         return w;
 489 }
 490
 491 float trigger_push_get_push_time(entity this, vector endpos);
 492 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 493 {
 494         entity jp = NULL;
 495         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 496         {
 497                 jp = it;
 498                 break;
 499         });
 500         if (!jp)
 501                 return;
 502
 503         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 504         wp_from.wp00 = wp_to;
 505         wp_from.wp00mincost = cost;
 506         jp.nearestwaypoint = wp_from;
 507         jp.nearestwaypointtimeout = -1;
 508 }
 509
 510 bool start_wp_is_spawned;
 511 vector start_wp_origin;
 512 bool start_wp_is_hardwired;
 513 bool start_wp_is_support;
 514
 515 void waypoint_clear_start_wp_globals(entity pl, bool warn)
 516 {
 517         start_wp_is_spawned = false;
 518         start_wp_origin = '0 0 0';
 519         pl.wp_locked = NULL;
 520         start_wp_is_hardwired = false;
 521         start_wp_is_support = false;
 522         if (warn)
 523                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 524 }
 525
 526 void waypoint_start_hardwiredlink(entity pl, bool at_crosshair)
 527 {
 528         entity wp = pl.nearestwaypoint;
 529         if (at_crosshair)
 530         {
 531                 crosshair_trace_waypoints(pl);
 532                 wp = trace_ent;
 533         }
 534         string err = "";
 535         if (start_wp_is_spawned && !start_wp_is_hardwired)
 536                 err = "can't hardwire while in the process of creating a special link";
 537         else if (!wp)
 538         {
 539                 if (at_crosshair)
 540                         err = "couldn't find any waypoint at crosshair";
 541                 else
 542                         err = "couldn't find any waypoint nearby";
 543         }
 544         else if (wp.wpflags & WPFLAGMASK_NORELINK)
 545                 err = "can't hardwire a waypoint with special links";
 546
 547         if (err == "")
 548         {
 549                 start_wp_is_hardwired = true;
 550                 start_wp_is_spawned = true;
 551                 start_wp_origin = wp.origin;
 552                 pl.wp_locked = wp;
 553                 LOG_INFOF("^x80fWaypoint %s marked as hardwired link origin.\n", vtos(wp.origin));
 554         }
 555         else
 556         {
 557                 start_wp_is_hardwired = false;
 558                 LOG_INFO("Error: ", err, "\n");
 559         }
 560 }
 561
 562 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp, bool is_crouch_wp, bool is_support_wp)
 563 {
 564         if (WAYPOINT_VERSION < waypoint_version_loaded)
 565         {
 566                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 567                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 568                 return;
 569         }
 570
 571         entity e = NULL, jp = NULL;
 572         vector org = pl.origin;
 573         if (at_crosshair)
 574         {
 575                 crosshair_trace_waypoints(pl);
 576                 org = trace_endpos;
 577                 if (!trace_ent)
 578                         org.z -= PL_MIN_CONST.z;
 579                 if (!(start_wp_is_hardwired || start_wp_is_support))
 580                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 581                         {
 582                                 jp = it;
 583                                 break;
 584                         });
 585                 if (!jp && !start_wp_is_spawned && trace_ent)
 586                 {
 587                         if (trace_ent.wpflags & (WAYPOINTFLAG_JUMP))
 588                                 is_jump_wp = true;
 589                         else if (trace_ent.wpflags & (WAYPOINTFLAG_SUPPORT))
 590                                 is_support_wp = true;
 591                 }
 592         }
 593         if (jp || is_jump_wp || is_support_wp)
 594         {
 595                 if (start_wp_is_spawned)
 596                         start_wp_is_spawned = false;
 597                 LOG_INFO("^xf80Spawning start waypoint...\n");
 598         }
 599         int ctf_flags = havocbot_symmetry_origin_order;
 600         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 601                    || (autocvar_g_waypointeditor_symmetrical < 0));
 602         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 603                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 604         if (sym && ctf_flags < 2)
 605                 ctf_flags = 2;
 606         int wp_num = ctf_flags;
 607
 608         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp && !is_support_wp)
 609         {
 610                 // snap waypoint to item's origin if close enough
 611                 IL_EACH(g_items, true,
 612                 {
 613                         vector item_org = (it.absmin + it.absmax) * 0.5;
 614                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 615                         if (vlen(item_org - org) < 20)
 616                         {
 617                                 org = item_org;
 618                                 break;
 619                         }
 620                 });
 621         }
 622
 623         vector start_org = '0 0 0';
 624         if (start_wp_is_spawned)
 625         {
 626                 if (!start_wp_is_hardwired)
 627                         LOG_INFO("^xf80Spawning destination waypoint...\n");
 628                 start_org = start_wp_origin;
 629         }
 630
 631         // save org as it can be modified spawning symmetrycal waypoints
 632         vector initial_origin = '0 0 0';
 633         bool initial_origin_is_set = false;
 634
 635         LABEL(add_wp);
 636
 637         if (jp)
 638         {
 639                 e = NULL;
 640                 IL_EACH(g_waypoints, (it.wpflags & WPFLAGMASK_NORELINK)
 641                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 642                 {
 643                         e = it; break;
 644                 });
 645                 if (!e)
 646                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT);
 647                 if (!pl.wp_locked)
 648                         pl.wp_locked = e;
 649         }
 650         else if (is_jump_wp || is_support_wp)
 651         {
 652                 int type_flag = (is_jump_wp) ? WAYPOINTFLAG_JUMP : WAYPOINTFLAG_SUPPORT;
 653
 654                 entity wp_found = waypoint_get(org, org);
 655                 if (wp_found && !(wp_found.wpflags & type_flag))
 656                 {
 657                         LOG_INFOF("Error: can't spawn a %s waypoint over an existent waypoint of a different type\n", (is_jump_wp) ? "Jump" : "Support");
 658                         return;
 659                 }
 660                 e = waypoint_spawn(org, org, type_flag);
 661                 if (!pl.wp_locked)
 662                         pl.wp_locked = e;
 663         }
 664         else
 665                 e = waypoint_spawn(org, org, (is_crouch_wp) ? WAYPOINTFLAG_CROUCH : 0);
 666         if(!e)
 667         {
 668                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 669                 if (start_wp_is_spawned)
 670                         waypoint_clear_start_wp_globals(pl, true);
 671                 return;
 672         }
 673
 674         if (!initial_origin_is_set)
 675         {
 676                 initial_origin = e.origin;
 677                 initial_origin_is_set = true;
 678         }
 679
 680         entity start_wp = NULL;
 681         if (start_wp_is_spawned)
 682         {
 683                 IL_EACH(g_waypoints, (start_wp_is_hardwired || (it.wpflags & WPFLAGMASK_NORELINK))
 684                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 685                 {
 686                         start_wp = it; break;
 687                 });
 688                 if(!start_wp)
 689                 {
 690                         // should not happen
 691                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 692                         waypoint_clear_start_wp_globals(pl, true);
 693                         return;
 694                 }
 695                 if (start_wp_is_hardwired)
 696                 {
 697                         if (waypoint_is_hardwiredlink(start_wp, e))
 698                         {
 699                                 waypoint_unmark_hardwiredlink(start_wp, e);
 700                                 waypoint_removelink(start_wp, e);
 701                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 702                                 LOG_INFOF("^x80fRemoved hardwired link %s.\n", s);
 703                         }
 704                         else
 705                         {
 706                                 if (e.createdtime == time)
 707                                 {
 708                                         LOG_INFO("Error: hardwired links can be created only between 2 existing (and unconnected) waypoints.\n");
 709                                         waypoint_remove(e);
 710                                         waypoint_clear_start_wp_globals(pl, true);
 711                                         waypoint_spawn_fromeditor(pl, at_crosshair, is_jump_wp, is_crouch_wp, is_support_wp);
 712                                         return;
 713                                 }
 714                                 if (start_wp == e)
 715                                 {
 716                                         LOG_INFO("Error: start and destination waypoints coincide.\n");
 717                                         waypoint_clear_start_wp_globals(pl, true);
 718                                         return;
 719                                 }
 720                                 if (waypoint_islinked(start_wp, e))
 721                                 {
 722                                         LOG_INFO("Error: waypoints are already linked.\n");
 723                                         waypoint_clear_start_wp_globals(pl, true);
 724                                         return;
 725                                 }
 726                                 waypoint_addlink(start_wp, e);
 727                                 waypoint_mark_hardwiredlink(start_wp, e);
 728                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 729                                 LOG_INFOF("^x80fAdded hardwired link %s.\n", s);
 730                         }
 731                 }
 732                 else
 733                 {
 734                         if (start_wp_is_support)
 735                         {
 736                                 if (e.SUPPORT_WP)
 737                                 {
 738                                         LOG_INFOF("Waypoint %v has already a support waypoint, delete it first.\n", e.origin);
 739                                         waypoint_clear_start_wp_globals(pl, true);
 740                                         return;
 741                                 }
 742                                 // clear all links to e
 743                                 IL_EACH(g_waypoints, it != e,
 744                                 {
 745                                         if (waypoint_islinked(it, e) && !waypoint_is_hardwiredlink(it, e))
 746                                                 waypoint_removelink(it, e);
 747                                 });
 748                         }
 749                         waypoint_addlink(start_wp, e);
 750                 }
 751         }
 752
 753         if (!(jp || is_jump_wp || is_support_wp || start_wp_is_hardwired))
 754                 waypoint_schedulerelink(e);
 755
 756         string wp_type_str = waypoint_get_type_name(e);
 757
 758         bprint(strcat(wp_type_str, "^7 spawned at ", vtos(e.origin), "\n"));
 759
 760         if (start_wp_is_spawned)
 761         {
 762                 pl.wp_locked = NULL;
 763                 if (!start_wp_is_hardwired)
 764                         waypoint_schedulerelink(start_wp);
 765                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 766                 {
 767                         if (start_wp.wp00_original == start_wp.wp00)
 768                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 769                         else
 770                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 771                 }
 772         }
 773
 774         if (sym)
 775         {
 776                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 777                 if (jp)
 778                 {
 779                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 780                         {
 781                                 jp = it; break;
 782                         });
 783                 }
 784                 if (start_wp_is_spawned)
 785                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 786                 if (vdist(org - pl.origin, >, 32))
 787                 {
 788                         if(wp_num > 2)
 789                                 wp_num--;
 790                         else
 791                                 sym = false;
 792                         goto add_wp;
 793                 }
 794         }
 795         if (jp || is_jump_wp || is_support_wp)
 796         {
 797                 if (!start_wp_is_spawned)
 798                 {
 799                         // we've just created a custom jumppad waypoint
 800                         // the next one created by the user will be the destination waypoint
 801                         start_wp_is_spawned = true;
 802                         start_wp_origin = initial_origin;
 803                         if (is_support_wp)
 804                                 start_wp_is_support = true;
 805                 }
 806         }
 807         else if (start_wp_is_spawned)
 808         {
 809                 waypoint_clear_start_wp_globals(pl, false);
 810         }
 811 }
 812
 813 void waypoint_remove(entity wp)
 814 {
 815         IL_EACH(g_waypoints, it != wp,
 816         {
 817                 if (it.SUPPORT_WP == wp)
 818                 {
 819                         it.SUPPORT_WP = NULL;
 820                         waypoint_schedulerelink(it); // restore incoming links
 821                 }
 822                 if (waypoint_islinked(it, wp))
 823                 {
 824                         if (waypoint_is_hardwiredlink(it, wp))
 825                                 waypoint_unmark_hardwiredlink(it, wp);
 826                         waypoint_removelink(it, wp);
 827                 }
 828         });
 829         delete(wp);
 830 }
 831
 832 void waypoint_remove_fromeditor(entity pl)
 833 {
 834         if (WAYPOINT_VERSION < waypoint_version_loaded)
 835         {
 836                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 837                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 838                 return;
 839         }
 840
 841         entity e = navigation_findnearestwaypoint(pl, false);
 842
 843         int ctf_flags = havocbot_symmetry_origin_order;
 844         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 845                    || (autocvar_g_waypointeditor_symmetrical < 0));
 846         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 847                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 848         if (sym && ctf_flags < 2)
 849                 ctf_flags = 2;
 850         int wp_num = ctf_flags;
 851
 852         LABEL(remove_wp);
 853         if (!e) return;
 854
 855         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 856         {
 857                 if (start_wp_is_spawned)
 858                         waypoint_clear_start_wp_globals(pl, true);
 859                 return;
 860         }
 861
 862         if (waypoint_has_hardwiredlinks(e))
 863         {
 864                 LOG_INFO("Can't remove a waypoint with hardwired links, remove links with \"wpeditor hardwire\" first\n");
 865                 return;
 866         }
 867
 868         entity wp_sym = NULL;
 869         if (sym)
 870         {
 871                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 872                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 873                         if(vdist(org - it.origin, <, 3))
 874                         {
 875                                 wp_sym = it;
 876                                 break;
 877                         }
 878                 });
 879         }
 880
 881         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 882         te_explosion(e.origin);
 883         waypoint_remove(e);
 884
 885         if (sym && wp_sym)
 886         {
 887                 e = wp_sym;
 888                 if(wp_num > 2)
 889                         wp_num--;
 890                 else
 891                         sym = false;
 892                 goto remove_wp;
 893         }
 894
 895         if (start_wp_is_spawned)
 896                 waypoint_clear_start_wp_globals(pl, true);
 897 }
 898
 899 void waypoint_removelink(entity from, entity to)
 900 {
 901         if (from == to || ((from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT))))
 902                 return;
 903
 904         entity fromwp31_prev = from.wp31;
 905
 906         switch (waypoint_getlinknum(from, to))
 907         {
 908                 // fallthrough all the way
 909                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 910                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 911                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 912                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 913                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 914                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 915                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 916                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 917                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 918                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 919                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 920                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 921                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 922                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 923                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 924                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 925                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 926                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 927                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 928                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 929                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 930                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 931                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 932                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 933                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 934                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 935                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 936                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 937                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 938                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 939                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 940                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 941         }
 942
 943         if (fromwp31_prev && !from.wp31)
 944                 waypoint_schedulerelink(from);
 945 }
 946
 947 int waypoint_getlinknum(entity from, entity to)
 948 {
 949         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 950         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 951         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 952         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 953         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 954         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 955         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 956         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 957         return -1;
 958 }
 959
 960 bool waypoint_islinked(entity from, entity to)
 961 {
 962         return (waypoint_getlinknum(from, to) >= 0);
 963 }
 964
 965 void waypoint_updatecost_foralllinks()
 966 {
 967         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 968         {
 969                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 970                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 971                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 972                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 973                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 974                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 975                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 976                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 977                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 978                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 979                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 980                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 981                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 982                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 983                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 984                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 985                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 986                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 987                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 988                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 989                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 990                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 991                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 992                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 993                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 994                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 995                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 996                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 997                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 998                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 999                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
1000                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
1001         });
1002 }
1003
1004 float waypoint_getlinearcost(float dist)
1005 {
1006         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
1007                 return dist / (autocvar_sv_maxspeed * 1.25);
1008         return dist / autocvar_sv_maxspeed;
1009 }
1010
1011 float waypoint_getlinearcost_underwater(float dist)
1012 {
1013         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
1014         return dist / (autocvar_sv_maxspeed * 0.7);
1015 }
1016
1017 float waypoint_getlinearcost_crouched(float dist)
1018 {
1019         return dist / (autocvar_sv_maxspeed * 0.5);
1020 }
1021
1022 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
1023 {
1024         bool submerged_from = navigation_check_submerged_state(from_ent, from);
1025         bool submerged_to = navigation_check_submerged_state(to_ent, to);
1026
1027         if (submerged_from && submerged_to)
1028                 return waypoint_getlinearcost_underwater(vlen(to - from));
1029
1030         if ((from_ent.wpflags & WAYPOINTFLAG_CROUCH) && (to_ent.wpflags & WAYPOINTFLAG_CROUCH))
1031                 return waypoint_getlinearcost_crouched(vlen(to - from));
1032
1033         float c = waypoint_getlinearcost(vlen(to - from));
1034
1035         float height = from.z - to.z;
1036         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
1037         {
1038                 float height_cost; // fall cost
1039                 if (from_ent.wpflags & WAYPOINTFLAG_JUMP)
1040                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
1041                 else
1042                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
1043                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
1044                 if(height_cost > c)
1045                         c = height_cost;
1046         }
1047
1048         // consider half path underwater
1049         if (submerged_from || submerged_to)
1050                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
1051
1052         // consider half path crouched
1053         if ((from_ent.wpflags & WAYPOINTFLAG_CROUCH) || (to_ent.wpflags & WAYPOINTFLAG_CROUCH))
1054                 return (c + waypoint_getlinearcost_crouched(vlen(to - from))) / 2;
1055
1056         return c;
1057 }
1058
1059 float waypoint_getlinkcost(entity from, entity to)
1060 {
1061         vector v1 = from.origin;
1062         vector v2 = to.origin;
1063         if (from.wpisbox)
1064         {
1065                 vector m1 = from.absmin, m2 = from.absmax;
1066                 v1.x = bound(m1.x, v2.x, m2.x);
1067                 v1.y = bound(m1.y, v2.y, m2.y);
1068                 v1.z = bound(m1.z, v2.z, m2.z);
1069         }
1070         if (to.wpisbox)
1071         {
1072                 vector m1 = to.absmin, m2 = to.absmax;
1073                 v2.x = bound(m1.x, v1.x, m2.x);
1074                 v2.y = bound(m1.y, v1.y, m2.y);
1075                 v2.z = bound(m1.z, v1.z, m2.z);
1076         }
1077         return waypoint_gettravelcost(v1, v2, from, to);
1078 }
1079
1080 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
1081 // if c == -1 automatically determine cost of the link
1082 void waypoint_addlink_customcost(entity from, entity to, float c)
1083 {
1084         if (from == to || waypoint_islinked(from, to))
1085                 return;
1086         if (c == -1 && (from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1087                 return;
1088
1089         if(c == -1)
1090                 c = waypoint_getlinkcost(from, to);
1091
1092         if (from.wp31mincost < c) return;
1093         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
1094         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
1095         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
1096         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
1097         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
1098         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
1099         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
1100         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
1101         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
1102         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
1103         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
1104         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
1105         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
1106         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
1107         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
1108         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
1109         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
1110         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
1111         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
1112         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
1113         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
1114         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
1115         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
1116         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
1117         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
1118         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
1119         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
1120         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
1121         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
1122         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
1123         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
1124         from.wp00 = to;from.wp00mincost = c;return;
1125 }
1126
1127 void waypoint_addlink(entity from, entity to)
1128 {
1129         if ((from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1130                 waypoint_addlink_for_custom_jumppad(from, to);
1131         else
1132                 waypoint_addlink_customcost(from, to, -1);
1133
1134         if (from.wpflags & WAYPOINTFLAG_SUPPORT)
1135                 to.SUPPORT_WP = from;
1136 }
1137
1138 // relink this spawnfunc_waypoint
1139 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
1140 // (SLOW!)
1141 void waypoint_think(entity this)
1142 {
1143         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
1144         float sv2_height = 0, ev2_height = 0;
1145
1146         bot_calculate_stepheightvec();
1147
1148         int dphitcontentsmask_save = this.dphitcontentsmask;
1149         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1150
1151         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
1152
1153         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
1154         IL_EACH(g_waypoints, this != it,
1155         {
1156                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
1157                 {
1158                         if (!(this.wpflags & WPFLAGMASK_NORELINK))
1159                                 waypoint_addlink(this, it);
1160                         if (!(it.wpflags & WPFLAGMASK_NORELINK))
1161                                 waypoint_addlink(it, this);
1162                 }
1163                 else
1164                 {
1165                         ++relink_total;
1166                         if(!checkpvs(this.origin, it))
1167                         {
1168                                 ++relink_pvsculled;
1169                                 continue;
1170                         }
1171
1172                         sv = set_tracewalk_dest_2(this, it.origin);
1173                         sv2 = tracewalk_dest;
1174                         sv2_height = tracewalk_dest_height;
1175                         ev = set_tracewalk_dest_2(it, this.origin);
1176                         ev2 = tracewalk_dest;
1177                         ev2_height = tracewalk_dest_height;
1178
1179                         dv = ev - sv;
1180                         dv.z = 0;
1181                         int maxdist = 1050;
1182                         vector m1 = PL_MIN_CONST;
1183                         vector m2 = PL_MAX_CONST;
1184
1185                         if ((this.wpflags & WAYPOINTFLAG_CROUCH) || (it.wpflags & WAYPOINTFLAG_CROUCH))
1186                         {
1187                                 m1 = PL_CROUCH_MIN_CONST;
1188                                 m2 = PL_CROUCH_MAX_CONST;
1189                                 // links from crouch wp to normal wp (and viceversa) are very short to avoid creating many links
1190                                 // that would be wasted due to rough travel cost calculation (the longer link is, the higher cost is)
1191                                 // links from crouch wp to crouch wp can be as long as normal links
1192                                 if (!((this.wpflags & WAYPOINTFLAG_CROUCH) && (it.wpflags & WAYPOINTFLAG_CROUCH)))
1193                                         maxdist = 100;
1194                         }
1195
1196                         if (vdist(dv, >=, maxdist)) // max search distance in XY
1197                         {
1198                                 ++relink_lengthculled;
1199                                 continue;
1200                         }
1201
1202                         navigation_testtracewalk = 0;
1203
1204                         //traceline(this.origin, it.origin, false, NULL);
1205                         //if (trace_fraction == 1)
1206                         if (this.wpisbox || (this.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)) // forbid outgoing links
1207                                 || it.SUPPORT_WP) // forbid incoming links
1208                         {
1209                                 relink_walkculled += 0.5;
1210                         }
1211                         else
1212                         {
1213                                 if (tracewalk(this, sv, m1, m2, ev2, ev2_height, MOVE_NOMONSTERS))
1214                                         waypoint_addlink(this, it);
1215                                 else
1216                                         relink_walkculled += 0.5;
1217                         }
1218
1219                         // reverse direction
1220                         if (it.wpisbox || (it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)) // forbid incoming links
1221                                 || this.SUPPORT_WP) // forbid outgoing links
1222                         {
1223                                 relink_walkculled += 0.5;
1224                         }
1225                         else
1226                         {
1227                                 if (tracewalk(this, ev, m1, m2, sv2, sv2_height, MOVE_NOMONSTERS))
1228                                         waypoint_addlink(it, this);
1229                                 else
1230                                         relink_walkculled += 0.5;
1231                         }
1232                 }
1233         });
1234
1235         // waypoint_clearlinks preserves references to old hardwired links (.wphwXX links)
1236         // so they can be restored here when a wp is spawned over an existing one
1237         waypoint_restore_hardwiredlinks(this);
1238
1239         navigation_testtracewalk = 0;
1240         this.wplinked = true;
1241         this.dphitcontentsmask = dphitcontentsmask_save;
1242
1243         setthink(this, func_null);
1244         this.nextthink = 0;
1245 }
1246
1247 void waypoint_clearlinks(entity wp)
1248 {
1249         // clear links to other waypoints
1250         float f = 10000000;
1251         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1252         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1253         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1254         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1255
1256         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1257         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1258         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1259         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1260
1261         // don't remove references to hardwired links (.wphwXX fields)
1262
1263         wp.wplinked = false;
1264 }
1265
1266 // tell a spawnfunc_waypoint to relink
1267 void waypoint_schedulerelink(entity wp)
1268 {
1269         if (wp == NULL)
1270                 return;
1271
1272         waypoint_setupmodel(wp);
1273         wp.wpisbox = vdist(wp.size, >, 0);
1274         wp.enemy = NULL;
1275         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1276                 wp.owner = NULL;
1277         if (!(wp.wpflags & WPFLAGMASK_NORELINK))
1278                 waypoint_clearlinks(wp);
1279         // schedule an actual relink on next frame
1280         setthink(wp, waypoint_think);
1281         wp.nextthink = time;
1282         wp.effects = EF_LOWPRECISION;
1283 }
1284
1285 // spawnfunc_waypoint map entity
1286 spawnfunc(waypoint)
1287 {
1288         IL_PUSH(g_waypoints, this);
1289
1290         setorigin(this, this.origin);
1291         // schedule a relink after other waypoints have had a chance to spawn
1292         waypoint_clearlinks(this);
1293         //waypoint_schedulerelink(this);
1294 }
1295
1296 // tell all waypoints to relink
1297 // actually this is useful only to update relink_* stats
1298 void waypoint_schedulerelinkall()
1299 {
1300         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1301         IL_EACH(g_waypoints, true,
1302         {
1303                 waypoint_schedulerelink(it);
1304         });
1305         waypoint_load_hardwiredlinks();
1306 }
1307
1308 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1309
1310 // Load waypoint links from file
1311 bool waypoint_load_links()
1312 {
1313         string s;
1314         float file, tokens, c = 0, found;
1315         entity wp_from = NULL, wp_to;
1316         vector wp_to_pos, wp_from_pos;
1317
1318         string gt_ext = GET_GAMETYPE_EXTENSION();
1319
1320         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1321         file = fopen(filename, FILE_READ);
1322
1323         if (gt_ext != "" && file < 0)
1324         {
1325                 // if race waypoint file doesn't exist load the default one
1326                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1327                 file = fopen(filename, FILE_READ);
1328         }
1329
1330         if (file < 0)
1331         {
1332                 LOG_TRACE("waypoint links load from ", filename, " failed");
1333                 waypoint_schedulerelinkall();
1334                 return false;
1335         }
1336
1337         bool parse_comments = true;
1338         float ver = 0;
1339         string links_time = string_null;
1340
1341         while ((s = fgets(file)))
1342         {
1343                 if(parse_comments)
1344                 {
1345                         if(substring(s, 0, 2) == "//")
1346                         {
1347                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1348                                         ver = stof(substring(s, 19, -1));
1349                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1350                                         links_time = substring(s, 16, -1);
1351                                 continue;
1352                         }
1353                         else
1354                         {
1355                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1356                                 {
1357                                         if (links_time != waypoint_time)
1358                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1359                                         else
1360                                                 LOG_TRACE("waypoint links for this map are outdated.");
1361                                         if (g_assault)
1362                                         {
1363                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1364                                         }
1365                                         else
1366                                         {
1367                                                 LOG_TRACE("automatically updating...");
1368                                                 waypoint_schedulerelinkall();
1369                                                 fclose(file);
1370                                                 return false;
1371                                         }
1372                                 }
1373                                 parse_comments = false;
1374                         }
1375                 }
1376
1377                 tokens = tokenizebyseparator(s, "*");
1378
1379                 if (tokens!=2)
1380                 {
1381                         // bad file format
1382                         fclose(file);
1383                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1384                         return false;
1385                 }
1386
1387                 wp_from_pos     = stov(argv(0));
1388                 wp_to_pos       = stov(argv(1));
1389
1390                 // Search "from" waypoint
1391                 if(!wp_from || wp_from.origin!=wp_from_pos)
1392                 {
1393                         wp_from = findradius(wp_from_pos, 1);
1394                         found = false;
1395                         while(wp_from)
1396                         {
1397                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1398                                 if(wp_from.classname == "waypoint")
1399                                 {
1400                                         found = true;
1401                                         break;
1402                                 }
1403                                 wp_from = wp_from.chain;
1404                         }
1405
1406                         if(!found)
1407                         {
1408                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1409                                 continue;
1410                         }
1411                 }
1412
1413                 // Search "to" waypoint
1414                 wp_to = findradius(wp_to_pos, 1);
1415                 found = false;
1416                 while(wp_to)
1417                 {
1418                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1419                         if(wp_to.classname == "waypoint")
1420                         {
1421                                 found = true;
1422                                 break;
1423                         }
1424                         wp_to = wp_to.chain;
1425                 }
1426
1427                 if(!found)
1428                 {
1429                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1430                         continue;
1431                 }
1432
1433                 ++c;
1434                 waypoint_addlink(wp_from, wp_to);
1435                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1436                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1437         }
1438
1439         fclose(file);
1440
1441         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1442
1443         bool scheduled = false;
1444         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1445         {
1446                 if (!it.wp00)
1447                 {
1448                         waypoint_schedulerelink(it);
1449                         scheduled = true;
1450                 }
1451         });
1452         if (scheduled)
1453                 return false;
1454
1455         botframe_cachedwaypointlinks = true;
1456         return true;
1457 }
1458
1459 void waypoint_load_hardwiredlinks()
1460 {
1461         string s;
1462         float file, tokens, c = 0, found;
1463         entity wp_from = NULL, wp_to;
1464         vector wp_to_pos, wp_from_pos;
1465
1466         string gt_ext = GET_GAMETYPE_EXTENSION();
1467
1468         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1469         file = fopen(filename, FILE_READ);
1470
1471         if (gt_ext != "" && file < 0)
1472         {
1473                 // if race waypoint file doesn't exist load the default one
1474                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1475                 file = fopen(filename, FILE_READ);
1476         }
1477
1478         botframe_loadedforcedlinks = true;
1479
1480         if (file < 0)
1481         {
1482                 LOG_TRACE("waypoint links load from ", filename, " failed");
1483                 return;
1484         }
1485
1486         bool is_special = false;
1487         while ((s = fgets(file)))
1488         {
1489                 if(substring(s, 0, 2)=="//")
1490                         continue;
1491
1492                 if(substring(s, 0, 1)=="#")
1493                         continue;
1494
1495                 // special links start with *, so old xonotic versions don't load them
1496                 is_special = false;
1497                 if (substring(s, 0, 1) == "*")
1498                 {
1499                         is_special = true;
1500                         s = substring(s, 1, -1);
1501                 }
1502
1503                 tokens = tokenizebyseparator(s, "*");
1504
1505                 if (tokens!=2)
1506                         continue;
1507
1508                 wp_from_pos     = stov(argv(0));
1509                 wp_to_pos       = stov(argv(1));
1510
1511                 // Search "from" waypoint
1512                 if(!wp_from || wp_from.origin!=wp_from_pos)
1513                 {
1514                         wp_from = findradius(wp_from_pos, 5);
1515                         found = false;
1516                         while(wp_from)
1517                         {
1518                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1519                                 if(wp_from.classname == "waypoint")
1520                                 {
1521                                         found = true;
1522                                         break;
1523                                 }
1524                                 wp_from = wp_from.chain;
1525                         }
1526
1527                         if(!found)
1528                         {
1529                                 s = strcat(((is_special) ? "special link " : "hardwired link "), s);
1530                                 LOG_INFO("NOTICE: Can not find origin waypoint of the ", s, ". Path skipped");
1531                                 continue;
1532                         }
1533                 }
1534
1535                 // Search "to" waypoint
1536                 wp_to = findradius(wp_to_pos, 5);
1537                 found = false;
1538                 while(wp_to)
1539                 {
1540                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1541                         if(wp_to.classname == "waypoint")
1542                         {
1543                                 found = true;
1544                                 break;
1545                         }
1546                         wp_to = wp_to.chain;
1547                 }
1548
1549                 if(!found)
1550                 {
1551                         s = strcat(((is_special) ? "special link " : "hardwired link "), s);
1552                         LOG_INFO("NOTICE: Can not find destination waypoint of the ", s, ". Path skipped");
1553                         continue;
1554                 }
1555
1556                 ++c;
1557
1558                 if (!is_special)
1559                 {
1560                         waypoint_addlink(wp_from, wp_to);
1561                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1562                 } else if (wp_from.wpflags & WPFLAGMASK_NORELINK
1563                         && ((wp_from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT))
1564                                 || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1565                 {
1566                         waypoint_addlink(wp_from, wp_to);
1567                 }
1568         }
1569
1570         fclose(file);
1571
1572         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1573 }
1574
1575 entity waypoint_get_link(entity w, float i)
1576 {
1577         switch(i)
1578         {
1579                 case  0:return w.wp00;
1580                 case  1:return w.wp01;
1581                 case  2:return w.wp02;
1582                 case  3:return w.wp03;
1583                 case  4:return w.wp04;
1584                 case  5:return w.wp05;
1585                 case  6:return w.wp06;
1586                 case  7:return w.wp07;
1587                 case  8:return w.wp08;
1588                 case  9:return w.wp09;
1589                 case 10:return w.wp10;
1590                 case 11:return w.wp11;
1591                 case 12:return w.wp12;
1592                 case 13:return w.wp13;
1593                 case 14:return w.wp14;
1594                 case 15:return w.wp15;
1595                 case 16:return w.wp16;
1596                 case 17:return w.wp17;
1597                 case 18:return w.wp18;
1598                 case 19:return w.wp19;
1599                 case 20:return w.wp20;
1600                 case 21:return w.wp21;
1601                 case 22:return w.wp22;
1602                 case 23:return w.wp23;
1603                 case 24:return w.wp24;
1604                 case 25:return w.wp25;
1605                 case 26:return w.wp26;
1606                 case 27:return w.wp27;
1607                 case 28:return w.wp28;
1608                 case 29:return w.wp29;
1609                 case 30:return w.wp30;
1610                 case 31:return w.wp31;
1611                 default:return NULL;
1612         }
1613 }
1614
1615 // Save all hardwired waypoint links to a file
1616 void waypoint_save_hardwiredlinks()
1617 {
1618         string gt_ext = GET_GAMETYPE_EXTENSION();
1619
1620         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1621         int file = fopen(filename, FILE_WRITE);
1622         if (file < 0)
1623         {
1624                 LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1625                 return;
1626         }
1627
1628         // write hardwired links to file
1629         int count = 0;
1630         fputs(file, "// HARDWIRED LINKS\n");
1631         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1632         {
1633                 for (int j = 0; j < 32; ++j)
1634                 {
1635                         entity link = waypoint_get_link(it, j);
1636                         if (waypoint_is_hardwiredlink(it, link))
1637                         {
1638                                 // NOTE: vtos rounds vector components to 1 decimal place
1639                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1640                                 fputs(file, s);
1641                                 ++count;
1642                         }
1643                 }
1644         });
1645
1646         // write special links to file
1647         int count2 = 0;
1648         fputs(file, "\n// SPECIAL LINKS\n");
1649         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP),
1650         {
1651                 for (int j = 0; j < 32; ++j)
1652                 {
1653                         entity link = waypoint_get_link(it, j);
1654                         if (link)
1655                         {
1656                                 // NOTE: vtos rounds vector components to 1 decimal place
1657                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin), "\n");
1658                                 fputs(file, s);
1659                                 ++count2;
1660                         }
1661                 }
1662         });
1663
1664         fclose(file);
1665
1666         LOG_INFOF("saved %d hardwired links and %d special links to %s", count, count2, filename);
1667 }
1668
1669 // Save all waypoint links to a file
1670 void waypoint_save_links()
1671 {
1672         string gt_ext = GET_GAMETYPE_EXTENSION();
1673
1674         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1675         int file = fopen(filename, FILE_WRITE);
1676         if (file < 0)
1677         {
1678                 LOG_INFOF("waypoint link save to %s failed", filename);
1679                 return;
1680         }
1681
1682         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1683         if (waypoint_time != "")
1684                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1685
1686         int c = 0;
1687         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP)),
1688         {
1689                 for(int j = 0; j < 32; ++j)
1690                 {
1691                         entity link = waypoint_get_link(it, j);
1692                         if (link && !waypoint_is_hardwiredlink(it, link))
1693                         {
1694                                 // NOTE: vtos rounds vector components to 1 decimal place
1695                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1696                                 fputs(file, s);
1697                                 ++c;
1698                         }
1699                 }
1700         });
1701         fclose(file);
1702
1703         botframe_cachedwaypointlinks = true;
1704
1705         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1706 }
1707
1708 // save waypoints to gamedir/data/maps/mapname.waypoints
1709 void waypoint_saveall()
1710 {
1711         if (WAYPOINT_VERSION < waypoint_version_loaded)
1712         {
1713                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1714                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1715                 return;
1716         }
1717         string gt_ext = GET_GAMETYPE_EXTENSION();
1718
1719         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1720         int file = fopen(filename, FILE_WRITE);
1721         if (file < 0)
1722         {
1723                 waypoint_save_links(); // save anyway?
1724                 botframe_loadedforcedlinks = false;
1725
1726                 LOG_INFOF("waypoint links: save to %s failed", filename);
1727                 return;
1728         }
1729
1730         float sym = autocvar_g_waypointeditor_symmetrical;
1731         string sym_str = ftos(sym);
1732         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1733         {
1734                 if (sym == 1)
1735                 {
1736                         sym_str = cons(sym_str, "-");
1737                         sym_str = cons(sym_str, "-");
1738                 }
1739                 else
1740                 {
1741                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1742                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1743                 }
1744                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1745                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1746         }
1747         else if (autocvar_g_waypointeditor_symmetrical == -2)
1748         {
1749                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1750                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1751         }
1752
1753         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1754         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1755         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1756         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1757
1758         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1759         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1760         //fputs(file, strcat("//", "\n"));
1761         //fputs(file, strcat("//", "\n"));
1762         //fputs(file, strcat("//", "\n"));
1763
1764         int c = 0;
1765         IL_EACH(g_waypoints, true,
1766         {
1767                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1768                         continue;
1769
1770                 string s;
1771                 // NOTE: vtos rounds vector components to 1 decimal place
1772                 s = strcat(vtos(it.origin + it.mins), "\n");
1773                 s = strcat(s, vtos(it.origin + it.maxs));
1774                 s = strcat(s, "\n");
1775                 s = strcat(s, ftos(it.wpflags));
1776                 s = strcat(s, "\n");
1777                 fputs(file, s);
1778                 c++;
1779         });
1780         fclose(file);
1781         waypoint_save_links();
1782         waypoint_save_hardwiredlinks();
1783
1784         botframe_loadedforcedlinks = false;
1785
1786         waypoint_version_loaded = WAYPOINT_VERSION;
1787         LOG_INFOF("saved %d waypoints to %s", c, filename);
1788 }
1789
1790 // load waypoints from file
1791 float waypoint_loadall()
1792 {
1793         string s;
1794         int file, cwp, cwb, fl;
1795         vector m1, m2;
1796         cwp = 0;
1797         cwb = 0;
1798
1799         string gt_ext = GET_GAMETYPE_EXTENSION();
1800
1801         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1802         file = fopen(filename, FILE_READ);
1803
1804         if (gt_ext != "" && file < 0)
1805         {
1806                 // if race waypoint file doesn't exist load the default one
1807                 filename = sprintf("maps/%s.waypoints", mapname);
1808                 file = fopen(filename, FILE_READ);
1809         }
1810
1811         if (file < 0)
1812         {
1813                 LOG_TRACE("waypoint load from ", filename, " failed");
1814                 return 0;
1815         }
1816
1817         bool parse_comments = true;
1818         float ver = 0;
1819         float sym = 0;
1820         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1821
1822         while ((s = fgets(file)))
1823         {
1824                 if(parse_comments)
1825                 {
1826                         if(substring(s, 0, 2) == "//")
1827                         {
1828                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1829                                         ver = stof(substring(s, 19, -1));
1830                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1831                                 {
1832                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1833                                         if (tokens) { sym = stof(argv(0)); }
1834                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1835                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1836                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1837                                 }
1838                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1839                                         strcpy(waypoint_time, substring(s, 16, -1));
1840                                 continue;
1841                         }
1842                         else
1843                         {
1844                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1845                                 {
1846                                         LOG_TRACE("waypoints for this map are outdated");
1847                                         LOG_TRACE("please update them in the editor");
1848                                 }
1849                                 parse_comments = false;
1850                         }
1851                 }
1852                 m1 = stov(s);
1853                 s = fgets(file);
1854                 if (!s)
1855                         break;
1856                 m2 = stov(s);
1857                 s = fgets(file);
1858                 if (!s)
1859                         break;
1860                 fl = stof(s);
1861                 fl &= ~WAYPOINTFLAG_NORELINK__DEPRECATED;
1862                 waypoint_spawn(m1, m2, fl);
1863                 if (m1 == m2)
1864                         cwp = cwp + 1;
1865                 else
1866                         cwb = cwb + 1;
1867         }
1868         fclose(file);
1869         waypoint_version_loaded = ver;
1870         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1871
1872         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1873         {
1874                 string sym_str = "";
1875                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1876                 if (sym == 1 && sym_param3 < 2)
1877                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1878                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1879                 {
1880                         string params;
1881                         if (sym == 1)
1882                                 params = cons("-", "-");
1883                         else
1884                         {
1885                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1886                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1887                         }
1888                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1889                         sym_str = strcat(ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1890                 }
1891                 else if (sym == -2)
1892                 {
1893                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1894                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1895                         sym_str = strcat(ftos(sym), " with axis ", params);
1896                 }
1897                 else
1898                         sym_str = ftos(sym);
1899                 if (sym_str != "")
1900                         LOG_INFO("Waypoint editor: loaded symmetry ", sym_str);
1901                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1902         }
1903
1904         if (WAYPOINT_VERSION < waypoint_version_loaded)
1905                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1906                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1907
1908         return cwp + cwb;
1909 }
1910
1911 #define waypoint_fixorigin(position, tracetest_ent) \
1912         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1913
1914 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1915 {
1916         vector endpos = position + down_dir * 3000;
1917         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1918         if(trace_startsolid)
1919                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1920         if(trace_startsolid)
1921                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1922         if(trace_fraction < 1)
1923                 position = trace_endpos;
1924         return position;
1925 }
1926
1927 void waypoint_spawnforitem_force(entity e, vector org)
1928 {
1929         // Fix the waypoint altitude if necessary
1930         org = waypoint_fixorigin(org, NULL);
1931
1932         // don't spawn an item spawnfunc_waypoint if it already exists
1933         IL_EACH(g_waypoints, true,
1934         {
1935                 if(it.wpisbox)
1936                 {
1937                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1938                         {
1939                                 e.nearestwaypoint = it;
1940                                 return;
1941                         }
1942                 }
1943                 else
1944                 {
1945                         if(vdist(it.origin - org, <, 16))
1946                         {
1947                                 e.nearestwaypoint = it;
1948                                 return;
1949                         }
1950                 }
1951         });
1952
1953         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1954 }
1955
1956 void waypoint_spawnforitem(entity e)
1957 {
1958         if(!bot_waypoints_for_items)
1959                 return;
1960
1961         waypoint_spawnforitem_force(e, e.origin);
1962 }
1963
1964 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1965 {
1966         entity w;
1967         entity dw;
1968         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag);
1969         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1970         // one way link to the destination
1971         w.wp00_original = dw;
1972         w.wp00 = dw;
1973         w.wp00mincost = timetaken; // this is just for jump pads
1974         // the teleporter's nearest spawnfunc_waypoint is this one
1975         // (teleporters are not goals, so this is probably useless)
1976         e.nearestwaypoint = w;
1977         e.nearestwaypointtimeout = -1;
1978 }
1979
1980 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1981 {
1982         float src_angle = e.warpzone_angles.x;
1983         while (src_angle < -180) src_angle += 360;
1984         while (src_angle > 180) src_angle -= 360;
1985
1986         float dest_angle = e.enemy.warpzone_angles.x;
1987         while (dest_angle < -180) dest_angle += 360;
1988         while (dest_angle > 180) dest_angle -= 360;
1989
1990         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1991         if (src_angle == -90 || dest_angle == -90)
1992                 return;
1993
1994         makevectors(e.warpzone_angles);
1995         vector src = (e.absmin + e.absmax) * 0.5;
1996         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1997         vector down_dir_src = -v_up;
1998
1999         makevectors(e.enemy.warpzone_angles);
2000         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
2001         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
2002         vector down_dir_dest = -v_up;
2003
2004         int extra_flag = 0;
2005         // don't snap to the ground waypoints for source warpzones pointing downwards
2006         if (src_angle != 90)
2007         {
2008                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
2009                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
2010                 // oblique warpzones need a jump otherwise bots gets stuck
2011                 if (src_angle != 0)
2012                         extra_flag = WAYPOINTFLAG_JUMP;
2013         }
2014
2015         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
2016 }
2017
2018 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
2019 {
2020         destination = waypoint_fixorigin(destination, tracetest_ent);
2021         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
2022 }
2023
2024 entity waypoint_spawnpersonal(entity this, vector position)
2025 {
2026         entity w;
2027
2028         // drop the waypoint to a proper location:
2029         //   first move it up by a player height
2030         //   then move it down to hit the floor with player bbox size
2031         position = waypoint_fixorigin(position, this);
2032
2033         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
2034         w.nearestwaypoint = NULL;
2035         w.nearestwaypointtimeout = 0;
2036         w.owner = this;
2037
2038         waypoint_schedulerelink(w);
2039
2040         return w;
2041 }
2042
2043 void waypoint_showlink(entity wp1, entity wp2, int display_type)
2044 {
2045         if (!(wp1 && wp2))
2046                 return;
2047
2048         if (waypoint_is_hardwiredlink(wp1, wp2) || (wp1.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP)))
2049                 te_beam(NULL, wp1.origin, wp2.origin);
2050         else if (display_type == 1)
2051                 te_lightning2(NULL, wp1.origin, wp2.origin);
2052 }
2053
2054 void waypoint_showlinks_to(entity wp, int display_type)
2055 {
2056         IL_EACH(g_waypoints, it != wp,
2057         {
2058                 if (waypoint_islinked(it, wp))
2059                         waypoint_showlink(it, wp, display_type);
2060         });
2061 }
2062
2063 void waypoint_showlinks_from(entity wp, int display_type)
2064 {
2065         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
2066         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
2067         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
2068         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
2069         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
2070         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
2071         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
2072         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
2073         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
2074         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
2075         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
2076         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
2077         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
2078         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
2079         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
2080         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
2081 }
2082
2083 void crosshair_trace_waypoints(entity pl)
2084 {
2085         IL_EACH(g_waypoints, true, {
2086                 it.solid = SOLID_BSP;
2087                 if (!it.wpisbox)
2088                         setsize(it, '-16 -16 -16', '16 16 16');
2089         });
2090
2091         WarpZone_crosshair_trace(pl);
2092
2093         IL_EACH(g_waypoints, true, {
2094                 it.solid = SOLID_TRIGGER;
2095                 if (!it.wpisbox)
2096                         setsize(it, '0 0 0', '0 0 0');
2097         });
2098
2099         if (trace_ent.classname != "waypoint")
2100                 trace_ent = NULL;
2101         else if (!trace_ent.wpisbox)
2102                 trace_endpos = trace_ent.origin;
2103 }
2104
2105 void botframe_showwaypointlinks()
2106 {
2107         if (time < botframe_waypointeditorlightningtime)
2108                 return;
2109         botframe_waypointeditorlightningtime = time + 0.5;
2110         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
2111         {
2112                 int display_type = 0;
2113                 if (wasfreed(it.wp_aimed))
2114                         it.wp_aimed = NULL;
2115                 if (wasfreed(it.wp_locked))
2116                         it.wp_locked = NULL;
2117                 entity head = it.wp_locked;
2118                 if (!head)
2119                         head = navigation_findnearestwaypoint(it, false);
2120                 it.nearestwaypoint = head; // mainly useful for debug
2121                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
2122                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
2123                         display_type = 1; // default
2124                 else if(waypoint_has_hardwiredlinks(head))
2125                         display_type = 2; // only hardwired
2126
2127                 if (display_type)
2128                 {
2129                         //navigation_testtracewalk = true;
2130                         //print("currently selected WP is ", etos(head), "\n");
2131                         //navigation_testtracewalk = false;
2132                         if (head)
2133                         {
2134                                 te_lightning2(NULL, head.origin, it.origin);
2135                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
2136                                         waypoint_showlinks_to(head, display_type);
2137                                 else
2138                                         waypoint_showlinks_from(head, display_type);
2139                         }
2140                 }
2141                 string str;
2142                 entity wp = NULL;
2143                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
2144                 {
2145                         crosshair_trace_waypoints(it);
2146                         if (trace_ent)
2147                         {
2148                                 wp = trace_ent;
2149                                 if (wp != it.wp_aimed)
2150                                 {
2151                                         string wp_type_str = waypoint_get_type_name(wp);
2152                                         str = sprintf("\necho Entity %d: %s^7, flags: %d, origin: %s\n", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2153                                         if (wp.wpisbox)
2154                                                 str = strcat(str, sprintf("echo \" absmin: %s, absmax: %s\"\n", vtos(wp.absmin), vtos(wp.absmax)));
2155                                         stuffcmd(it, str);
2156                                         str = sprintf("Entity %d: %s^7\nflags: %d\norigin: %s", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2157                                         if (wp.wpisbox)
2158                                                 str = strcat(str, sprintf(" \nabsmin: %s\nabsmax: %s", vtos(wp.absmin), vtos(wp.absmax)));
2159                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
2160                                 }
2161                         }
2162                 }
2163                 if (it.wp_aimed != wp)
2164                         it.wp_aimed = wp;
2165         });
2166 }
2167
2168 float botframe_autowaypoints_fixdown(vector v)
2169 {
2170         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
2171         if(trace_fraction >= 1)
2172                 return 0;
2173         return 1;
2174 }
2175
2176 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
2177 {
2178         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
2179         {
2180                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
2181                 return 0;
2182         });
2183
2184         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2185         return 1;
2186 }
2187
2188 // return value:
2189 //    1 = WP created
2190 //    0 = no action needed
2191 //   -1 = temp fail, try from world too
2192 //   -2 = permanent fail, do not retry
2193 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2194 {
2195         // make it possible to go from p to wp, if we can
2196         // if wp is NULL, nearest is chosen
2197
2198         entity w;
2199         vector porg;
2200         float t, tmin, tmax;
2201         vector o;
2202         vector save;
2203
2204         if(!botframe_autowaypoints_fixdown(p.origin))
2205                 return -2;
2206         porg = trace_endpos;
2207
2208         if(wp)
2209         {
2210                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2211
2212                 // if wp -> porg, then OK
2213                 float maxdist;
2214                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2215                 {
2216                         // we may find a better one
2217                         maxdist = vlen(wp.origin - porg);
2218                 }
2219                 else
2220                 {
2221                         // accept any "good"
2222                         maxdist = 2100;
2223                 }
2224
2225                 float bestdist = maxdist;
2226                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WPFLAGMASK_NORELINK),
2227                 {
2228                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2229                         if(d < bestdist)
2230                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2231                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2232                         {
2233                                 bestdist = d;
2234                                 p.(fld) = it;
2235                         }
2236                 });
2237                 if(bestdist < maxdist)
2238                 {
2239                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2240                         return 0;
2241                 }
2242
2243                 if(bestdist < 2100)
2244                 {
2245                         // we know maxdist < 2100
2246                         // so wp -> porg is still valid
2247                         // all is good
2248                         p.(fld) = wp;
2249                         return 0;
2250                 }
2251
2252                 // otherwise, no existing WP can fix our issues
2253         }
2254         else
2255         {
2256                 save = p.origin;
2257                 setorigin(p, porg);
2258                 w = navigation_findnearestwaypoint(p, walkfromwp);
2259                 setorigin(p, save);
2260                 if(w)
2261                 {
2262                         p.(fld) = w;
2263                         return 0;
2264                 }
2265         }
2266
2267         tmin = 0;
2268         tmax = 1;
2269         for (;;)
2270         {
2271                 if(tmax - tmin < 0.001)
2272                 {
2273                         // did not get a good candidate
2274                         return -1;
2275                 }
2276
2277                 t = (tmin + tmax) * 0.5;
2278                 o = antilag_takebackorigin(p, CS(p), time - t);
2279                 if(!botframe_autowaypoints_fixdown(o))
2280                         return -2;
2281                 o = trace_endpos;
2282
2283                 if(wp)
2284                 {
2285                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2286                         {
2287                                 // we cannot walk from wp.origin to o
2288                                 // get closer to tmax
2289                                 tmin = t;
2290                                 continue;
2291                         }
2292                 }
2293                 else
2294                 {
2295                         save = p.origin;
2296                         setorigin(p, o);
2297                         w = navigation_findnearestwaypoint(p, walkfromwp);
2298                         setorigin(p, save);
2299                         if(!w)
2300                         {
2301                                 // we cannot walk from any WP to o
2302                                 // get closer to tmax
2303                                 tmin = t;
2304                                 continue;
2305                         }
2306                 }
2307
2308                 // if we get here, o is valid regarding waypoints
2309                 // check if o is connected right to the player
2310                 // we break if it succeeds, as that means o is a good waypoint location
2311                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2312                         break;
2313
2314                 // o is no good, we need to get closer to the player
2315                 tmax = t;
2316         }
2317
2318         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2319         botframe_autowaypoints_createwp(o, p, fld, 0);
2320         return 1;
2321 }
2322
2323 // automatically create missing waypoints
2324 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2325 {
2326         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2327         if(r != -1)
2328                 return;
2329         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2330         if(r != -1)
2331                 return;
2332
2333         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2334         if(!botframe_autowaypoints_fixdown(p.origin))
2335                 return; // shouldn't happen, caught above
2336         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2337 }
2338
2339 void botframe_deleteuselesswaypoints()
2340 {
2341         IL_EACH(g_items, it.bot_pickup,
2342         {
2343                 // NOTE: this protects waypoints if they're the ONLY nearest
2344                 // waypoint. That's the intention.
2345                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2346                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2347         });
2348         IL_EACH(g_waypoints, true,
2349         {
2350                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2351                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2352                 // WP is useful if:
2353                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2354                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2355                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2356                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2357                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2358                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2359                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2360                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2361                 // b) WP is closest WP for an item/spawnpoint/other entity
2362                 //    This has been done above by protecting these WPs.
2363         });
2364         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2365         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2366         {
2367                 for (int m = 0; m < 32; ++m)
2368                 {
2369                         entity w = waypoint_get_link(it, m);
2370                         if (!w)
2371                                 break;
2372                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2373                                 continue;
2374                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2375                                 continue;
2376                         for (int j = 0; j < 32; ++j)
2377                         {
2378                                 entity w2 = waypoint_get_link(w, j);
2379                                 if (!w2)
2380                                         break;
2381                                 if (it == w2)
2382                                         continue;
2383                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2384                                         continue;
2385                                 // If we got here, it != w2 exist with it -> w
2386                                 // and w -> w2. That means the waypoint is not
2387                                 // a dead end.
2388                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2389                                 for (int k = 0; k < 32; ++k)
2390                                 {
2391                                         if (waypoint_get_link(it, k) == w2)
2392                                                 continue;
2393                                         // IF WE GET HERE, w is proven useful
2394                                         // to get from it to w2!
2395                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2396                                         goto next;
2397                                 }
2398                         }
2399 LABEL(next)
2400                 }
2401         });
2402         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2403         //     they are needed to complete routes while autowaypointing.
2404
2405         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2406         {
2407                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2408                 te_explosion(it.origin);
2409                 waypoint_remove(it);
2410                 break;
2411         });
2412
2413         IL_EACH(g_waypoints, true,
2414         {
2415                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2416         });
2417 }
2418
2419 //.entity botframe_autowaypoints_lastwp0;
2420 .entity botframe_autowaypoints_lastwp1;
2421 void botframe_autowaypoints()
2422 {
2423         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2424                 // going back is broken, so only fix waypoints to walk TO the player
2425                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2426                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2427                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2428         });
2429
2430         if (autocvar_g_waypointeditor_auto >= 2) {
2431                 botframe_deleteuselesswaypoints();
2432         }
2433 }
2434