qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 void waypoint_setupmodel(entity wp)
 264 {
 265         if (autocvar_g_waypointeditor)
 266         {
 267                 // TODO: add some sort of visible box in edit mode for box waypoints
 268                 vector m1 = wp.mins;
 269                 vector m2 = wp.maxs;
 270                 setmodel(wp, MDL_WAYPOINT);
 271                 setsize(wp, m1, m2);
 272                 wp.effects = EF_LOWPRECISION;
 273                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 274                         wp.colormod = '1 0 0';
 275                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 276                         wp.colormod = '1 1 0';
 277                 else if (wp.wpflags & WAYPOINTFLAG_NORELINK)
 278                         wp.colormod = '1 0.5 0'; // orange
 279                 else if (wp.wphardwired)
 280                         wp.colormod = '0.5 0 1'; // violet
 281                 else
 282                         wp.colormod = '1 1 1';
 283         }
 284         else
 285                 wp.model = "";
 286 }
 287
 288 entity waypoint_spawn(vector m1, vector m2, float f)
 289 {
 290         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 291         {
 292                 vector em1 = m1 - '8 8 8';
 293                 vector em2 = m2 + '8 8 8';
 294                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 295                 {
 296                         return it;
 297                 });
 298         }
 299         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 300         // otherwise links loaded from file would be applied only to the first destination
 301         // waypoint since link format doesn't specify waypoint entities but just positions
 302         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WAYPOINTFLAG_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 303         {
 304                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 305                 {
 306                         return it;
 307                 });
 308         }
 309
 310         entity w = new(waypoint);
 311         IL_PUSH(g_waypoints, w);
 312         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 313         w.wpflags = f;
 314         w.solid = SOLID_TRIGGER;
 315         setorigin(w, (m1 + m2) * 0.5);
 316         setsize(w, m1 - w.origin, m2 - w.origin);
 317         if (w.size)
 318                 w.wpisbox = true;
 319
 320         if(!w.wpisbox)
 321         {
 322                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 323                 if(!move_out_of_solid(w))
 324                 {
 325                         if(!(f & WAYPOINTFLAG_GENERATED))
 326                         {
 327                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 328                                 delete(w);
 329                                 return NULL;
 330                         }
 331                         else
 332                         {
 333                                 if(autocvar_developer)
 334                                 {
 335                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 336                                         backtrace("Waypoint stuck");
 337                                 }
 338                         }
 339                 }
 340                 setsize(w, '0 0 0', '0 0 0');
 341         }
 342
 343         waypoint_clearlinks(w);
 344         //waypoint_schedulerelink(w);
 345
 346         waypoint_setupmodel(w);
 347
 348         return w;
 349 }
 350
 351 float trigger_push_get_push_time(entity this, vector endpos);
 352 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 353 {
 354         entity jp = NULL;
 355         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 356         {
 357                 jp = it;
 358         });
 359         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 360         wp_from.wp00 = wp_to;
 361         wp_from.wp00mincost = cost;
 362         jp.nearestwaypoint = wp_from;
 363         jp.nearestwaypointtimeout = -1;
 364 }
 365
 366 bool start_wp_is_spawned;
 367 vector start_wp_origin;
 368
 369 void waypoint_clear_start_wp(entity pl)
 370 {
 371         start_wp_is_spawned = false;
 372         start_wp_origin = '0 0 0';
 373         pl.wp_locked = NULL;
 374         LOG_INFO("^xf80Start waypoint has been cleared\n");
 375 }
 376
 377 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair)
 378 {
 379         entity e = NULL, jp = NULL;
 380         vector org = pl.origin;
 381         if (at_crosshair)
 382         {
 383                 crosshair_trace(pl);
 384                 org = trace_endpos - eZ * PL_MIN_CONST.z;
 385                 IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 386                 {
 387                         jp = it;
 388                         break;
 389                 });
 390                 if (jp && start_wp_is_spawned)
 391                         start_wp_is_spawned = false;
 392                 LOG_INFO("^xf80Spawning start waypoint\n");
 393         }
 394         int ctf_flags = havocbot_symmetry_origin_order;
 395         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 396                    || (autocvar_g_waypointeditor_symmetrical < 0));
 397         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 398                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 399         if (sym && ctf_flags < 2)
 400                 ctf_flags = 2;
 401         int wp_num = ctf_flags;
 402
 403         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair)
 404         {
 405                 // snap waypoint to item's origin if close enough
 406                 IL_EACH(g_items, true,
 407                 {
 408                         vector item_org = (it.absmin + it.absmax) * 0.5;
 409                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 410                         if (vlen(item_org - org) < 20)
 411                         {
 412                                 org = item_org;
 413                                 break;
 414                         }
 415                 });
 416         }
 417
 418         vector start_org = '0 0 0';
 419         if (start_wp_is_spawned)
 420         {
 421                 LOG_INFO("^xf80Spawning destination waypoint\n");
 422                 start_org = start_wp_origin;
 423         }
 424
 425         // save org as it can be modified spawning symmetrycal waypoints
 426         vector org_save = org;
 427
 428         LABEL(add_wp);
 429
 430         if (jp)
 431         {
 432                 e = NULL;
 433                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 434                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 435                 {
 436                         e = it; break;
 437                 });
 438                 if (!e)
 439                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 440                 if (!pl.wp_locked)
 441                         pl.wp_locked = e;
 442         }
 443         else
 444                 e = waypoint_spawn(org, org, 0);
 445         if(!e)
 446         {
 447                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 448                 if (start_wp_is_spawned)
 449                         waypoint_clear_start_wp(pl);
 450                 return;
 451         }
 452
 453         entity start_wp = NULL;
 454         if (start_wp_is_spawned)
 455         {
 456                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 457                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 458                 {
 459                         start_wp = it; break;
 460                 });
 461                 if(!start_wp)
 462                 {
 463                         // should not happen
 464                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 465                         waypoint_clear_start_wp(pl);
 466                         return;
 467                 }
 468                 waypoint_addlink_for_custom_jumppad(start_wp, e);
 469         }
 470
 471         waypoint_schedulerelink(e);
 472         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 473
 474         if (start_wp_is_spawned)
 475         {
 476                 pl.wp_locked = NULL;
 477                 waypoint_schedulerelink(start_wp);
 478         }
 479
 480         if (sym)
 481         {
 482                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 483                 if (jp)
 484                 {
 485                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 486                         {
 487                                 jp = it; break;
 488                         });
 489                 }
 490                 if (start_wp_is_spawned)
 491                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 492                 if (vdist(org - pl.origin, >, 32))
 493                 {
 494                         if(wp_num > 2)
 495                                 wp_num--;
 496                         else
 497                                 sym = false;
 498                         goto add_wp;
 499                 }
 500         }
 501
 502         if (jp)
 503         {
 504                 if (!start_wp_is_spawned)
 505                 {
 506                         // we've just created a custom jumppad waypoint
 507                         // the next one created by the user will be the destination waypoint
 508                         start_wp_is_spawned = true;
 509                         start_wp_origin = org_save;
 510                 }
 511         }
 512         else if (start_wp_is_spawned)
 513         {
 514                 waypoint_clear_start_wp(pl);
 515         }
 516 }
 517
 518 void waypoint_remove(entity wp)
 519 {
 520         IL_EACH(g_waypoints, it != wp,
 521         {
 522                 if (waypoint_islinked(it, wp))
 523                         waypoint_removelink(it, wp);
 524         });
 525         delete(wp);
 526 }
 527
 528 void waypoint_remove_fromeditor(entity pl)
 529 {
 530         entity e = navigation_findnearestwaypoint(pl, false);
 531
 532         int ctf_flags = havocbot_symmetry_origin_order;
 533         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 534                    || (autocvar_g_waypointeditor_symmetrical < 0));
 535         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 536                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 537         if (sym && ctf_flags < 2)
 538                 ctf_flags = 2;
 539         int wp_num = ctf_flags;
 540
 541         LABEL(remove_wp);
 542         if (!e) return;
 543         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 544         {
 545                 if (start_wp_is_spawned)
 546                         waypoint_clear_start_wp(pl);
 547                 return;
 548         }
 549
 550         if (e.wphardwired)
 551         {
 552                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 553                 return;
 554         }
 555
 556         entity wp_sym = NULL;
 557         if (sym)
 558         {
 559                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 560                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 561                         if(vdist(org - it.origin, <, 3))
 562                         {
 563                                 wp_sym = it;
 564                                 break;
 565                         }
 566                 });
 567         }
 568
 569         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 570         waypoint_remove(e);
 571
 572         if (sym && wp_sym)
 573         {
 574                 e = wp_sym;
 575                 if(wp_num > 2)
 576                         wp_num--;
 577                 else
 578                         sym = false;
 579                 goto remove_wp;
 580         }
 581
 582         if (start_wp_is_spawned)
 583                 waypoint_clear_start_wp(pl);
 584 }
 585
 586 void waypoint_removelink(entity from, entity to)
 587 {
 588         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 589                 return;
 590
 591         entity fromwp31_prev = from.wp31;
 592
 593         switch (waypoint_getlinknum(from, to))
 594         {
 595                 // fallthrough all the way
 596                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 597                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 598                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 599                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 600                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 601                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 602                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 603                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 604                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 605                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 606                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 607                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 608                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 609                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 610                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 611                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 612                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 613                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 614                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 615                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 616                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 617                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 618                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 619                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 620                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 621                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 622                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 623                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 624                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 625                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 626                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 627                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 628         }
 629
 630         if (fromwp31_prev && !from.wp31)
 631                 waypoint_schedulerelink(from);
 632 }
 633
 634 int waypoint_getlinknum(entity from, entity to)
 635 {
 636         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 637         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 638         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 639         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 640         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 641         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 642         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 643         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 644         return -1;
 645 }
 646
 647 bool waypoint_islinked(entity from, entity to)
 648 {
 649         return (waypoint_getlinknum(from, to) >= 0);
 650 }
 651
 652 void waypoint_updatecost_foralllinks()
 653 {
 654         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 655         {
 656                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 657                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 658                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 659                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 660                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 661                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 662                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 663                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 664                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 665                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 666                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 667                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 668                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 669                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 670                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 671                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 672                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 673                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 674                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 675                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 676                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 677                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 678                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 679                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 680                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 681                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 682                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 683                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 684                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 685                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 686                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 687                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 688         });
 689 }
 690
 691 float waypoint_getlinearcost(float dist)
 692 {
 693         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 694                 return dist / (autocvar_sv_maxspeed * 1.25);
 695         return dist / autocvar_sv_maxspeed;
 696 }
 697 float waypoint_getlinearcost_underwater(float dist)
 698 {
 699         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 700         return dist / (autocvar_sv_maxspeed * 0.7);
 701 }
 702
 703 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 704 {
 705         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 706         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 707
 708         if (submerged_from && submerged_to)
 709                 return waypoint_getlinearcost_underwater(vlen(to - from));
 710
 711         float c = waypoint_getlinearcost(vlen(to - from));
 712
 713         float height = from.z - to.z;
 714         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 715         {
 716                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 717                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 718                 if(height_cost > c)
 719                         c = height_cost;
 720         }
 721
 722         if (submerged_from || submerged_to)
 723                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 724         return c;
 725 }
 726
 727 float waypoint_getlinkcost(entity from, entity to)
 728 {
 729         vector v1 = from.origin;
 730         vector v2 = to.origin;
 731         if (from.wpisbox)
 732         {
 733                 vector m1 = from.absmin, m2 = from.absmax;
 734                 v1.x = bound(m1.x, v2.x, m2.x);
 735                 v1.y = bound(m1.y, v2.y, m2.y);
 736                 v1.z = bound(m1.z, v2.z, m2.z);
 737         }
 738         if (to.wpisbox)
 739         {
 740                 vector m1 = to.absmin, m2 = to.absmax;
 741                 v2.x = bound(m1.x, v1.x, m2.x);
 742                 v2.y = bound(m1.y, v1.y, m2.y);
 743                 v2.z = bound(m1.z, v1.z, m2.z);
 744         }
 745         return waypoint_gettravelcost(v1, v2, from, to);
 746 }
 747
 748 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 749 // if c == -1 automatically determine cost of the link
 750 void waypoint_addlink_customcost(entity from, entity to, float c)
 751 {
 752         if (from == to || waypoint_islinked(from, to))
 753                 return;
 754         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 755                 return;
 756
 757         if(c == -1)
 758                 c = waypoint_getlinkcost(from, to);
 759
 760         if (from.wp31mincost < c) return;
 761         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 762         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 763         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 764         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 765         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 766         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 767         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 768         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 769         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 770         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 771         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 772         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 773         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 774         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 775         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 776         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 777         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 778         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 779         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 780         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 781         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 782         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 783         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 784         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 785         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 786         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 787         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 788         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 789         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 790         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 791         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 792         from.wp00 = to;from.wp00mincost = c;return;
 793 }
 794
 795 void waypoint_addlink(entity from, entity to)
 796 {
 797         waypoint_addlink_customcost(from, to, -1);
 798 }
 799
 800 // relink this spawnfunc_waypoint
 801 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 802 // (SLOW!)
 803 void waypoint_think(entity this)
 804 {
 805         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 806         float sv2_height = 0, ev2_height = 0;
 807
 808         bot_calculate_stepheightvec();
 809
 810         int dphitcontentsmask_save = this.dphitcontentsmask;
 811         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 812
 813         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 814
 815         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 816         IL_EACH(g_waypoints, this != it,
 817         {
 818                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 819                 {
 820                         waypoint_addlink(this, it);
 821                         waypoint_addlink(it, this);
 822                 }
 823                 else
 824                 {
 825                         ++relink_total;
 826                         if(!checkpvs(this.origin, it))
 827                         {
 828                                 ++relink_pvsculled;
 829                                 continue;
 830                         }
 831
 832                         sv = set_tracewalk_dest_2(this, it.origin);
 833                         sv2 = tracewalk_dest;
 834                         sv2_height = tracewalk_dest_height;
 835                         ev = set_tracewalk_dest_2(it, this.origin);
 836                         ev2 = tracewalk_dest;
 837                         ev2_height = tracewalk_dest_height;
 838
 839                         dv = ev - sv;
 840                         dv.z = 0;
 841                         if(vdist(dv, >=, 1050)) // max search distance in XY
 842                         {
 843                                 ++relink_lengthculled;
 844                                 continue;
 845                         }
 846
 847                         navigation_testtracewalk = 0;
 848
 849                         //traceline(this.origin, it.origin, false, NULL);
 850                         //if (trace_fraction == 1)
 851                         if (this.wpisbox)
 852                                 relink_walkculled += 0.5;
 853                         else
 854                         {
 855                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 856                                         waypoint_addlink(this, it);
 857                                 else
 858                                         relink_walkculled += 0.5;
 859                         }
 860
 861                         if (it.wpisbox)
 862                                 relink_walkculled += 0.5;
 863                         else
 864                         {
 865                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 866                                         waypoint_addlink(it, this);
 867                                 else
 868                                         relink_walkculled += 0.5;
 869                         }
 870                 }
 871         });
 872         navigation_testtracewalk = 0;
 873         this.wplinked = true;
 874         this.dphitcontentsmask = dphitcontentsmask_save;
 875
 876         setthink(this, func_null);
 877         this.nextthink = 0;
 878 }
 879
 880 void waypoint_clearlinks(entity wp)
 881 {
 882         // clear links to other waypoints
 883         float f = 10000000;
 884         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 885         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 886         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 887         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 888
 889         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 890         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 891         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 892         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 893
 894         wp.wplinked = false;
 895 }
 896
 897 // tell a spawnfunc_waypoint to relink
 898 void waypoint_schedulerelink(entity wp)
 899 {
 900         if (wp == NULL)
 901                 return;
 902
 903         waypoint_setupmodel(wp);
 904         wp.wpisbox = vdist(wp.size, >, 0);
 905         wp.enemy = NULL;
 906         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 907                 wp.owner = NULL;
 908         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 909                 waypoint_clearlinks(wp);
 910         // schedule an actual relink on next frame
 911         setthink(wp, waypoint_think);
 912         wp.nextthink = time;
 913         wp.effects = EF_LOWPRECISION;
 914 }
 915
 916 // spawnfunc_waypoint map entity
 917 spawnfunc(waypoint)
 918 {
 919         IL_PUSH(g_waypoints, this);
 920
 921         setorigin(this, this.origin);
 922         // schedule a relink after other waypoints have had a chance to spawn
 923         waypoint_clearlinks(this);
 924         //waypoint_schedulerelink(this);
 925 }
 926
 927 // tell all waypoints to relink
 928 // actually this is useful only to update relink_* stats
 929 void waypoint_schedulerelinkall()
 930 {
 931         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 932         IL_EACH(g_waypoints, true,
 933         {
 934                 waypoint_schedulerelink(it);
 935         });
 936         waypoint_load_links_hardwired();
 937 }
 938
 939 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
 940
 941 // Load waypoint links from file
 942 bool waypoint_load_links()
 943 {
 944         string s;
 945         float file, tokens, c = 0, found;
 946         entity wp_from = NULL, wp_to;
 947         vector wp_to_pos, wp_from_pos;
 948
 949         string gt_ext = GET_GAMETYPE_EXTENSION();
 950
 951         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 952         file = fopen(filename, FILE_READ);
 953
 954         if (gt_ext != "" && file < 0)
 955         {
 956                 // if race waypoint file doesn't exist load the default one
 957                 filename = sprintf("maps/%s.waypoints.cache", mapname);
 958                 file = fopen(filename, FILE_READ);
 959         }
 960
 961         if (file < 0)
 962         {
 963                 LOG_TRACE("waypoint links load from ", filename, " failed");
 964                 waypoint_schedulerelinkall();
 965                 return false;
 966         }
 967
 968         bool parse_comments = true;
 969         float ver = 0;
 970         string links_time = string_null;
 971
 972         while ((s = fgets(file)))
 973         {
 974                 if(parse_comments)
 975                 {
 976                         if(substring(s, 0, 2) == "//")
 977                         {
 978                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
 979                                         ver = stof(substring(s, 19, -1));
 980                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
 981                                         links_time = substring(s, 16, -1);
 982                                 continue;
 983                         }
 984                         else
 985                         {
 986                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
 987                                 {
 988                                         if (links_time != waypoint_time)
 989                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
 990                                         else
 991                                                 LOG_TRACE("waypoint links for this map are outdated.");
 992                                         if (g_assault)
 993                                         {
 994                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
 995                                         }
 996                                         else
 997                                         {
 998                                                 LOG_TRACE("automatically updating...");
 999                                                 waypoint_schedulerelinkall();
1000                                                 fclose(file);
1001                                                 return false;
1002                                         }
1003                                 }
1004                                 parse_comments = false;
1005                         }
1006                 }
1007
1008                 tokens = tokenizebyseparator(s, "*");
1009
1010                 if (tokens!=2)
1011                 {
1012                         // bad file format
1013                         fclose(file);
1014                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1015                         return false;
1016                 }
1017
1018                 wp_from_pos     = stov(argv(0));
1019                 wp_to_pos       = stov(argv(1));
1020
1021                 // Search "from" waypoint
1022                 if(!wp_from || wp_from.origin!=wp_from_pos)
1023                 {
1024                         wp_from = findradius(wp_from_pos, 1);
1025                         found = false;
1026                         while(wp_from)
1027                         {
1028                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1029                                 if(wp_from.classname == "waypoint")
1030                                 {
1031                                         found = true;
1032                                         break;
1033                                 }
1034                                 wp_from = wp_from.chain;
1035                         }
1036
1037                         if(!found)
1038                         {
1039                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1040                                 continue;
1041                         }
1042                 }
1043
1044                 // Search "to" waypoint
1045                 wp_to = findradius(wp_to_pos, 1);
1046                 found = false;
1047                 while(wp_to)
1048                 {
1049                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1050                         if(wp_to.classname == "waypoint")
1051                         {
1052                                 found = true;
1053                                 break;
1054                         }
1055                         wp_to = wp_to.chain;
1056                 }
1057
1058                 if(!found)
1059                 {
1060                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1061                         continue;
1062                 }
1063
1064                 ++c;
1065                 if ((wp_from.wpflags & WAYPOINTFLAG_NORELINK) && !(wp_from.wpflags & WAYPOINTFLAG_GENERATED))
1066                         waypoint_addlink_for_custom_jumppad(wp_from, wp_to);
1067                 else
1068                         waypoint_addlink(wp_from, wp_to);
1069         }
1070
1071         fclose(file);
1072
1073         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1074
1075         bool scheduled = false;
1076         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1077         {
1078                 if (!it.wp00)
1079                 {
1080                         waypoint_schedulerelink(it);
1081                         scheduled = true;
1082                 }
1083         });
1084         if (scheduled)
1085                 return false;
1086
1087         botframe_cachedwaypointlinks = true;
1088         return true;
1089 }
1090
1091 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
1092 {
1093         string s;
1094         float file, tokens, c = 0, found;
1095         entity wp_from = NULL, wp_to;
1096         vector wp_to_pos, wp_from_pos;
1097
1098         string gt_ext = GET_GAMETYPE_EXTENSION();
1099
1100         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1101         file = fopen(filename, FILE_READ);
1102
1103         if (gt_ext != "" && file < 0)
1104         {
1105                 // if race waypoint file doesn't exist load the default one
1106                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1107                 file = fopen(filename, FILE_READ);
1108         }
1109
1110         botframe_loadedforcedlinks = true;
1111
1112         if (file < 0)
1113         {
1114                 if(!removal_mode)
1115                         LOG_TRACE("waypoint links load from ", filename, " failed");
1116                 return;
1117         }
1118
1119         while ((s = fgets(file)))
1120         {
1121                 if(substring(s, 0, 2)=="//")
1122                         continue;
1123
1124                 if(substring(s, 0, 1)=="#")
1125                         continue;
1126
1127                 tokens = tokenizebyseparator(s, "*");
1128
1129                 if (tokens!=2)
1130                         continue;
1131
1132                 wp_from_pos     = stov(argv(0));
1133                 wp_to_pos       = stov(argv(1));
1134
1135                 // Search "from" waypoint
1136                 if(!wp_from || wp_from.origin!=wp_from_pos)
1137                 {
1138                         wp_from = findradius(wp_from_pos, 5);
1139                         found = false;
1140                         while(wp_from)
1141                         {
1142                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1143                                 if(wp_from.classname == "waypoint")
1144                                 {
1145                                         found = true;
1146                                         break;
1147                                 }
1148                                 wp_from = wp_from.chain;
1149                         }
1150
1151                         if(!found)
1152                         {
1153                                 if(!removal_mode)
1154                                         LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1155                                 continue;
1156                         }
1157                 }
1158
1159                 // Search "to" waypoint
1160                 wp_to = findradius(wp_to_pos, 5);
1161                 found = false;
1162                 while(wp_to)
1163                 {
1164                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1165                         if(wp_to.classname == "waypoint")
1166                         {
1167                                 found = true;
1168                                 break;
1169                         }
1170                         wp_to = wp_to.chain;
1171                 }
1172
1173                 if(!found)
1174                 {
1175                         if(!removal_mode)
1176                                 LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1177                         continue;
1178                 }
1179
1180                 ++c;
1181                 if(removal_mode)
1182                 {
1183                         waypoint_removelink(wp_from, wp_to);
1184                         continue;
1185                 }
1186
1187                 waypoint_addlink(wp_from, wp_to);
1188                 wp_from.wphardwired = true;
1189                 wp_to.wphardwired = true;
1190                 waypoint_setupmodel(wp_from);
1191                 waypoint_setupmodel(wp_to);
1192         }
1193
1194         fclose(file);
1195
1196         LOG_TRACE(((removal_mode) ? "unloaded " : "loaded "),
1197                 ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1198 }
1199
1200 entity waypoint_get_link(entity w, float i)
1201 {
1202         switch(i)
1203         {
1204                 case  0:return w.wp00;
1205                 case  1:return w.wp01;
1206                 case  2:return w.wp02;
1207                 case  3:return w.wp03;
1208                 case  4:return w.wp04;
1209                 case  5:return w.wp05;
1210                 case  6:return w.wp06;
1211                 case  7:return w.wp07;
1212                 case  8:return w.wp08;
1213                 case  9:return w.wp09;
1214                 case 10:return w.wp10;
1215                 case 11:return w.wp11;
1216                 case 12:return w.wp12;
1217                 case 13:return w.wp13;
1218                 case 14:return w.wp14;
1219                 case 15:return w.wp15;
1220                 case 16:return w.wp16;
1221                 case 17:return w.wp17;
1222                 case 18:return w.wp18;
1223                 case 19:return w.wp19;
1224                 case 20:return w.wp20;
1225                 case 21:return w.wp21;
1226                 case 22:return w.wp22;
1227                 case 23:return w.wp23;
1228                 case 24:return w.wp24;
1229                 case 25:return w.wp25;
1230                 case 26:return w.wp26;
1231                 case 27:return w.wp27;
1232                 case 28:return w.wp28;
1233                 case 29:return w.wp29;
1234                 case 30:return w.wp30;
1235                 case 31:return w.wp31;
1236                 default:return NULL;
1237         }
1238 }
1239
1240 // Save all waypoint links to a file
1241 void waypoint_save_links()
1242 {
1243         // temporarily remove hardwired links so they don't get saved among normal links
1244         waypoint_remove_links_hardwired();
1245
1246         string gt_ext = GET_GAMETYPE_EXTENSION();
1247
1248         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1249         int file = fopen(filename, FILE_WRITE);
1250         if (file < 0)
1251         {
1252                 LOG_INFOF("waypoint link save to %s failed", filename);
1253                 return;
1254         }
1255
1256         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1257         if (waypoint_time != "")
1258                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1259
1260         int c = 0;
1261         IL_EACH(g_waypoints, true,
1262         {
1263                 for(int j = 0; j < 32; ++j)
1264                 {
1265                         entity link = waypoint_get_link(it, j);
1266                         if(link)
1267                         {
1268                                 // NOTE: vtos rounds vector components to 1 decimal place
1269                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1270                                 fputs(file, s);
1271                                 ++c;
1272                         }
1273                 }
1274         });
1275         fclose(file);
1276
1277         botframe_cachedwaypointlinks = true;
1278
1279         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1280
1281         waypoint_load_links_hardwired();
1282 }
1283
1284 // save waypoints to gamedir/data/maps/mapname.waypoints
1285 void waypoint_saveall()
1286 {
1287         string gt_ext = GET_GAMETYPE_EXTENSION();
1288
1289         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1290         int file = fopen(filename, FILE_WRITE);
1291         if (file < 0)
1292         {
1293                 waypoint_save_links(); // save anyway?
1294                 botframe_loadedforcedlinks = false;
1295
1296                 LOG_INFOF("waypoint links: save to %s failed", filename);
1297                 return;
1298         }
1299
1300         float sym = autocvar_g_waypointeditor_symmetrical;
1301         string sym_str = ftos(sym);
1302         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1303         {
1304                 if (sym == 1)
1305                 {
1306                         sym_str = cons(sym_str, "-");
1307                         sym_str = cons(sym_str, "-");
1308                 }
1309                 else
1310                 {
1311                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1312                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1313                 }
1314                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1315                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1316         }
1317         else if (autocvar_g_waypointeditor_symmetrical == -2)
1318         {
1319                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1320                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1321         }
1322
1323         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1324         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1325         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1326         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1327
1328         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1329         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1330         //fputs(file, strcat("//", "\n"));
1331         //fputs(file, strcat("//", "\n"));
1332         //fputs(file, strcat("//", "\n"));
1333
1334         int c = 0;
1335         IL_EACH(g_waypoints, true,
1336         {
1337                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1338                         continue;
1339
1340                 string s;
1341                 // NOTE: vtos rounds vector components to 1 decimal place
1342                 s = strcat(vtos(it.origin + it.mins), "\n");
1343                 s = strcat(s, vtos(it.origin + it.maxs));
1344                 s = strcat(s, "\n");
1345                 s = strcat(s, ftos(it.wpflags));
1346                 s = strcat(s, "\n");
1347                 fputs(file, s);
1348                 c++;
1349         });
1350         fclose(file);
1351         waypoint_save_links();
1352         botframe_loadedforcedlinks = false;
1353
1354         LOG_INFOF("saved %d waypoints to %s", c, filename);
1355 }
1356
1357 // load waypoints from file
1358 float waypoint_loadall()
1359 {
1360         string s;
1361         float file, cwp, cwb, fl;
1362         vector m1, m2;
1363         cwp = 0;
1364         cwb = 0;
1365
1366         string gt_ext = GET_GAMETYPE_EXTENSION();
1367
1368         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1369         file = fopen(filename, FILE_READ);
1370
1371         if (gt_ext != "" && file < 0)
1372         {
1373                 // if race waypoint file doesn't exist load the default one
1374                 filename = sprintf("maps/%s.waypoints", mapname);
1375                 file = fopen(filename, FILE_READ);
1376         }
1377
1378         if (file < 0)
1379         {
1380                 LOG_TRACE("waypoint load from ", filename, " failed");
1381                 return 0;
1382         }
1383
1384         bool parse_comments = true;
1385         float ver = 0;
1386         float sym = 0;
1387         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1388
1389         while ((s = fgets(file)))
1390         {
1391                 if(parse_comments)
1392                 {
1393                         if(substring(s, 0, 2) == "//")
1394                         {
1395                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1396                                         ver = stof(substring(s, 19, -1));
1397                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1398                                 {
1399                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1400                                         if (tokens) { sym = stof(argv(0)); }
1401                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1402                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1403                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1404                                 }
1405                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1406                                         strcpy(waypoint_time, substring(s, 16, -1));
1407                                 continue;
1408                         }
1409                         else
1410                         {
1411                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1412                                 {
1413                                         LOG_TRACE("waypoints for this map are outdated");
1414                                         LOG_TRACE("please update them in the editor");
1415                                 }
1416                                 parse_comments = false;
1417                         }
1418                 }
1419                 m1 = stov(s);
1420                 s = fgets(file);
1421                 if (!s)
1422                         break;
1423                 m2 = stov(s);
1424                 s = fgets(file);
1425                 if (!s)
1426                         break;
1427                 fl = stof(s);
1428                 waypoint_spawn(m1, m2, fl);
1429                 if (m1 == m2)
1430                         cwp = cwp + 1;
1431                 else
1432                         cwb = cwb + 1;
1433         }
1434         fclose(file);
1435         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1436
1437         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1438         {
1439                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1440                 if (sym == 1 && sym_param3 < 2)
1441                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1442                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1443                 {
1444                         string params;
1445                         if (sym == 1)
1446                                 params = cons("-", "-");
1447                         else
1448                         {
1449                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1450                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1451                         }
1452                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1453                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1454                 }
1455                 else if (sym == -2)
1456                 {
1457                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1458                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1459                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1460                 }
1461                 else
1462                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1463                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1464         }
1465
1466         return cwp + cwb;
1467 }
1468
1469 #define waypoint_fixorigin(position, tracetest_ent) \
1470         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1471
1472 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1473 {
1474         vector endpos = position + down_dir * 3000;
1475         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1476         if(trace_startsolid)
1477                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1478         if(trace_startsolid)
1479                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1480         if(trace_fraction < 1)
1481                 position = trace_endpos;
1482         return position;
1483 }
1484
1485 void waypoint_spawnforitem_force(entity e, vector org)
1486 {
1487         // Fix the waypoint altitude if necessary
1488         org = waypoint_fixorigin(org, NULL);
1489
1490         // don't spawn an item spawnfunc_waypoint if it already exists
1491         IL_EACH(g_waypoints, true,
1492         {
1493                 if(it.wpisbox)
1494                 {
1495                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1496                         {
1497                                 e.nearestwaypoint = it;
1498                                 return;
1499                         }
1500                 }
1501                 else
1502                 {
1503                         if(vdist(it.origin - org, <, 16))
1504                         {
1505                                 e.nearestwaypoint = it;
1506                                 return;
1507                         }
1508                 }
1509         });
1510
1511         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1512 }
1513
1514 void waypoint_spawnforitem(entity e)
1515 {
1516         if(!bot_waypoints_for_items)
1517                 return;
1518
1519         waypoint_spawnforitem_force(e, e.origin);
1520 }
1521
1522 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1523 {
1524         entity w;
1525         entity dw;
1526         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1527         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1528         // one way link to the destination
1529         w.wp00 = dw;
1530         w.wp00mincost = timetaken; // this is just for jump pads
1531         // the teleporter's nearest spawnfunc_waypoint is this one
1532         // (teleporters are not goals, so this is probably useless)
1533         e.nearestwaypoint = w;
1534         e.nearestwaypointtimeout = -1;
1535 }
1536
1537 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1538 {
1539         float src_angle = e.warpzone_angles.x;
1540         while (src_angle < -180) src_angle += 360;
1541         while (src_angle > 180) src_angle -= 360;
1542
1543         float dest_angle = e.enemy.warpzone_angles.x;
1544         while (dest_angle < -180) dest_angle += 360;
1545         while (dest_angle > 180) dest_angle -= 360;
1546
1547         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1548         if (src_angle == -90 || dest_angle == -90)
1549                 return;
1550
1551         makevectors(e.warpzone_angles);
1552         vector src = (e.absmin + e.absmax) * 0.5;
1553         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1554         vector down_dir_src = -v_up;
1555
1556         makevectors(e.enemy.warpzone_angles);
1557         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1558         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1559         vector down_dir_dest = -v_up;
1560
1561         int extra_flag = 0;
1562         // don't snap to the ground waypoints for source warpzones pointing downwards
1563         if (src_angle != 90)
1564         {
1565                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1566                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1567                 // oblique warpzones need a jump otherwise bots gets stuck
1568                 if (src_angle != 0)
1569                         extra_flag = WAYPOINTFLAG_JUMP;
1570         }
1571
1572         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1573 }
1574
1575 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1576 {
1577         destination = waypoint_fixorigin(destination, tracetest_ent);
1578         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1579 }
1580
1581 entity waypoint_spawnpersonal(entity this, vector position)
1582 {
1583         entity w;
1584
1585         // drop the waypoint to a proper location:
1586         //   first move it up by a player height
1587         //   then move it down to hit the floor with player bbox size
1588         position = waypoint_fixorigin(position, this);
1589
1590         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1591         w.nearestwaypoint = NULL;
1592         w.nearestwaypointtimeout = 0;
1593         w.owner = this;
1594
1595         waypoint_schedulerelink(w);
1596
1597         return w;
1598 }
1599
1600 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1601 {
1602         if (!(wp1 && wp2))
1603                 return;
1604
1605         if (wp1.wphardwired && wp2.wphardwired)
1606                 te_beam(NULL, wp1.origin, wp2.origin);
1607         else if (display_type == 1)
1608                 te_lightning2(NULL, wp1.origin, wp2.origin);
1609 }
1610
1611 void waypoint_showlinks_to(entity wp, int display_type)
1612 {
1613         IL_EACH(g_waypoints, it != wp,
1614         {
1615                 if (waypoint_islinked(it, wp))
1616                         waypoint_showlink(it, wp, display_type);
1617         });
1618 }
1619
1620 void waypoint_showlinks_from(entity wp, int display_type)
1621 {
1622         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1623         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1624         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1625         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1626         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1627         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1628         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1629         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1630         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1631         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1632         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1633         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1634         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1635         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1636         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1637         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1638 }
1639
1640 void crosshair_trace_waypoints(entity pl)
1641 {
1642         IL_EACH(g_waypoints, true, {
1643                 it.solid = SOLID_BSP;
1644                 if (!it.wpisbox)
1645                         setsize(it, '-16 -16 -16', '16 16 16');
1646         });
1647
1648         crosshair_trace(pl);
1649
1650         IL_EACH(g_waypoints, true, {
1651                 it.solid = SOLID_TRIGGER;
1652                 if (!it.wpisbox)
1653                         setsize(it, '0 0 0', '0 0 0');
1654         });
1655         if (trace_ent.classname != "waypoint")
1656                 trace_ent = NULL;
1657 }
1658
1659 void botframe_showwaypointlinks()
1660 {
1661         if (time < botframe_waypointeditorlightningtime)
1662                 return;
1663         botframe_waypointeditorlightningtime = time + 0.5;
1664         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1665         {
1666                 int display_type = 0;
1667                 if (wasfreed(it.wp_aimed))
1668                         it.wp_aimed = NULL;
1669                 if (wasfreed(it.wp_locked))
1670                         it.wp_locked = NULL;
1671                 if (PHYS_INPUT_BUTTON_USE(it))
1672                         it.wp_locked = it.wp_aimed;
1673                 entity head = it.wp_locked;
1674                 if (!head)
1675                         head = navigation_findnearestwaypoint(it, false);
1676                 it.nearestwaypoint = head; // mainly useful for debug
1677                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1678                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
1679                         display_type = 1; // default
1680                 else if(head && (head.wphardwired))
1681                         display_type = 2; // only hardwired
1682
1683                 if (display_type)
1684                 {
1685                         //navigation_testtracewalk = true;
1686                         //print("currently selected WP is ", etos(head), "\n");
1687                         //navigation_testtracewalk = false;
1688                         if (head)
1689                         {
1690                                 te_lightning2(NULL, head.origin, it.origin);
1691                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1692                                         waypoint_showlinks_to(head, display_type);
1693                                 else
1694                                         waypoint_showlinks_from(head, display_type);
1695                         }
1696                 }
1697                 string str;
1698                 entity wp = NULL;
1699                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
1700                 {
1701                         crosshair_trace_waypoints(it);
1702                         if (trace_ent)
1703                         {
1704                                 wp = trace_ent;
1705                                 if (wp != it.wp_aimed)
1706                                 {
1707                                         str = sprintf("\necho ^2WP info^7: entity: %d, flags: %d, origin: '%s'\n", etof(wp), wp.wpflags, vtos(wp.origin));
1708                                         if (wp.wpisbox)
1709                                                 str = strcat(str, sprintf("echo \" absmin: '%s', absmax: '%s'\"\n", vtos(wp.absmin), vtos(wp.absmax)));
1710                                         stuffcmd(it, str);
1711                                         str = sprintf("entity: %d\nflags: %d\norigin: \'%s\'", etof(wp), wp.wpflags, vtos(wp.origin));
1712                                         if (wp.wpisbox)
1713                                                 str = strcat(str, sprintf(" \nabsmin: '%s'\nabsmax: '%s'", vtos(wp.absmin), vtos(wp.absmax)));
1714                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
1715                                 }
1716                         }
1717                 }
1718                 if (it.wp_aimed != wp)
1719                         it.wp_aimed = wp;
1720         });
1721 }
1722
1723 float botframe_autowaypoints_fixdown(vector v)
1724 {
1725         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1726         if(trace_fraction >= 1)
1727                 return 0;
1728         return 1;
1729 }
1730
1731 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1732 {
1733         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1734         {
1735                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1736                 return 0;
1737         });
1738
1739         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1740         return 1;
1741 }
1742
1743 // return value:
1744 //    1 = WP created
1745 //    0 = no action needed
1746 //   -1 = temp fail, try from world too
1747 //   -2 = permanent fail, do not retry
1748 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1749 {
1750         // make it possible to go from p to wp, if we can
1751         // if wp is NULL, nearest is chosen
1752
1753         entity w;
1754         vector porg;
1755         float t, tmin, tmax;
1756         vector o;
1757         vector save;
1758
1759         if(!botframe_autowaypoints_fixdown(p.origin))
1760                 return -2;
1761         porg = trace_endpos;
1762
1763         if(wp)
1764         {
1765                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1766
1767                 // if wp -> porg, then OK
1768                 float maxdist;
1769                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1770                 {
1771                         // we may find a better one
1772                         maxdist = vlen(wp.origin - porg);
1773                 }
1774                 else
1775                 {
1776                         // accept any "good"
1777                         maxdist = 2100;
1778                 }
1779
1780                 float bestdist = maxdist;
1781                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1782                 {
1783                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1784                         if(d < bestdist)
1785                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1786                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1787                         {
1788                                 bestdist = d;
1789                                 p.(fld) = it;
1790                         }
1791                 });
1792                 if(bestdist < maxdist)
1793                 {
1794                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1795                         return 0;
1796                 }
1797
1798                 if(bestdist < 2100)
1799                 {
1800                         // we know maxdist < 2100
1801                         // so wp -> porg is still valid
1802                         // all is good
1803                         p.(fld) = wp;
1804                         return 0;
1805                 }
1806
1807                 // otherwise, no existing WP can fix our issues
1808         }
1809         else
1810         {
1811                 save = p.origin;
1812                 setorigin(p, porg);
1813                 w = navigation_findnearestwaypoint(p, walkfromwp);
1814                 setorigin(p, save);
1815                 if(w)
1816                 {
1817                         p.(fld) = w;
1818                         return 0;
1819                 }
1820         }
1821
1822         tmin = 0;
1823         tmax = 1;
1824         for (;;)
1825         {
1826                 if(tmax - tmin < 0.001)
1827                 {
1828                         // did not get a good candidate
1829                         return -1;
1830                 }
1831
1832                 t = (tmin + tmax) * 0.5;
1833                 o = antilag_takebackorigin(p, CS(p), time - t);
1834                 if(!botframe_autowaypoints_fixdown(o))
1835                         return -2;
1836                 o = trace_endpos;
1837
1838                 if(wp)
1839                 {
1840                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
1841                         {
1842                                 // we cannot walk from wp.origin to o
1843                                 // get closer to tmax
1844                                 tmin = t;
1845                                 continue;
1846                         }
1847                 }
1848                 else
1849                 {
1850                         save = p.origin;
1851                         setorigin(p, o);
1852                         w = navigation_findnearestwaypoint(p, walkfromwp);
1853                         setorigin(p, save);
1854                         if(!w)
1855                         {
1856                                 // we cannot walk from any WP to o
1857                                 // get closer to tmax
1858                                 tmin = t;
1859                                 continue;
1860                         }
1861                 }
1862
1863                 // if we get here, o is valid regarding waypoints
1864                 // check if o is connected right to the player
1865                 // we break if it succeeds, as that means o is a good waypoint location
1866                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
1867                         break;
1868
1869                 // o is no good, we need to get closer to the player
1870                 tmax = t;
1871         }
1872
1873         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
1874         botframe_autowaypoints_createwp(o, p, fld, 0);
1875         return 1;
1876 }
1877
1878 // automatically create missing waypoints
1879 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1880 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1881 {
1882         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1883         if(r != -1)
1884                 return;
1885         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1886         if(r != -1)
1887                 return;
1888
1889         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
1890         if(!botframe_autowaypoints_fixdown(p.origin))
1891                 return; // shouldn't happen, caught above
1892         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1893 }
1894
1895 void botframe_deleteuselesswaypoints()
1896 {
1897         IL_EACH(g_items, it.bot_pickup,
1898         {
1899                 // NOTE: this protects waypoints if they're the ONLY nearest
1900                 // waypoint. That's the intention.
1901                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1902                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1903         });
1904         IL_EACH(g_waypoints, true,
1905         {
1906                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1907                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1908                 // WP is useful if:
1909                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1910                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1911                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1912                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1913                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1914                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1915                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1916                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1917                 // b) WP is closest WP for an item/spawnpoint/other entity
1918                 //    This has been done above by protecting these WPs.
1919         });
1920         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1921         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1922         {
1923                 for (int m = 0; m < 32; ++m)
1924                 {
1925                         entity w = waypoint_get_link(it, m);
1926                         if (!w)
1927                                 break;
1928                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1929                                 continue;
1930                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1931                                 continue;
1932                         for (int j = 0; j < 32; ++j)
1933                         {
1934                                 entity w2 = waypoint_get_link(w, j);
1935                                 if (!w2)
1936                                         break;
1937                                 if (it == w2)
1938                                         continue;
1939                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1940                                         continue;
1941                                 // If we got here, it != w2 exist with it -> w
1942                                 // and w -> w2. That means the waypoint is not
1943                                 // a dead end.
1944                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1945                                 for (int k = 0; k < 32; ++k)
1946                                 {
1947                                         if (waypoint_get_link(it, k) == w2)
1948                                                 continue;
1949                                         // IF WE GET HERE, w is proven useful
1950                                         // to get from it to w2!
1951                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1952                                         goto next;
1953                                 }
1954                         }
1955 LABEL(next)
1956                 }
1957         });
1958         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1959         //     they are needed to complete routes while autowaypointing.
1960
1961         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1962         {
1963                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
1964                 te_explosion(it.origin);
1965                 waypoint_remove(it);
1966                 break;
1967         });
1968
1969         IL_EACH(g_waypoints, true,
1970         {
1971                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1972         });
1973 }
1974
1975 void botframe_autowaypoints()
1976 {
1977         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
1978                 // going back is broken, so only fix waypoints to walk TO the player
1979                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1980                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1981                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1982         });
1983
1984         if (autocvar_g_waypointeditor_auto >= 2) {
1985                 botframe_deleteuselesswaypoints();
1986         }
1987 }
1988