qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17
  18 #include <lib/warpzone/common.qh>
  19 #include <lib/warpzone/util_server.qh>
  20
  21 .entity spawnpointmodel;
  22 void waypoint_unreachable(entity pl)
  23 {
  24         IL_EACH(g_waypoints, true,
  25         {
  26                 it.colormod = '0.5 0.5 0.5';
  27                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  28         });
  29
  30         entity e2 = navigation_findnearestwaypoint(pl, false);
  31         if(!e2)
  32         {
  33                 LOG_INFOF("Can't find any waypoint nearby\n");
  34                 return;
  35         }
  36
  37         navigation_markroutes(pl, e2);
  38
  39         int j = 0;
  40         int m = 0;
  41         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  42         {
  43                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  44                 it.colormod_z = 8;
  45                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  46                 j++;
  47                 m++;
  48         });
  49         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  50         navigation_markroutes_inverted(e2);
  51
  52         j = 0;
  53         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  54         {
  55                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  56                 it.colormod_x = 8;
  57                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  58                         m++;
  59                 it.effects |= EF_NODEPTHTEST | EF_RED;
  60                 j++;
  61         });
  62         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  63         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  64
  65         j = 0;
  66         IL_EACH(g_spawnpoints, true,
  67         {
  68                 if (navigation_findnearestwaypoint(it, false))
  69                 {
  70                         if(it.spawnpointmodel)
  71                         {
  72                                 delete(it.spawnpointmodel);
  73                                 it.spawnpointmodel = NULL;
  74                         }
  75                 }
  76                 else
  77                 {
  78                         if(!it.spawnpointmodel)
  79                         {
  80                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  81                                 entity e = new(spawnpointmodel);
  82                                 vector org = trace_endpos + eZ;
  83                                 setorigin(e, org);
  84                                 e.solid = SOLID_TRIGGER;
  85                                 it.spawnpointmodel = e;
  86                         }
  87                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  88                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  89                         _setmodel(it.spawnpointmodel, pl.model);
  90                         it.spawnpointmodel.frame = pl.frame;
  91                         it.spawnpointmodel.skin = pl.skin;
  92                         it.spawnpointmodel.colormap = pl.colormap;
  93                         it.spawnpointmodel.colormod = pl.colormod;
  94                         it.spawnpointmodel.glowmod = pl.glowmod;
  95                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  96                         j++;
  97                 }
  98         });
  99         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 100
 101         j = 0;
 102         IL_EACH(g_items, true,
 103         {
 104                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 105                 it.colormod = '0.5 0.5 0.5';
 106         });
 107         IL_EACH(g_items, true,
 108         {
 109                 if (navigation_findnearestwaypoint(it, false))
 110                         continue;
 111                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 112                 it.effects |= EF_NODEPTHTEST | EF_RED;
 113                 it.colormod_x = 8;
 114                 j++;
 115         });
 116         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 117
 118         j = 0;
 119         IL_EACH(g_items, true,
 120         {
 121                 if (navigation_findnearestwaypoint(it, true))
 122                         continue;
 123                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 124                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 125                 it.colormod_z = 8;
 126                 j++;
 127         });
 128         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 129 }
 130
 131 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 132 {
 133         vector new_org = org;
 134         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 135         {
 136                 vector map_center = havocbot_middlepoint;
 137                 if (autocvar_g_waypointeditor_symmetrical == -1)
 138                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 139
 140                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 141         }
 142         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 143         {
 144                 float m = havocbot_symmetry_axis_m;
 145                 float q = havocbot_symmetry_axis_q;
 146                 if (autocvar_g_waypointeditor_symmetrical == -2)
 147                 {
 148                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 149                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 150                 }
 151
 152                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 153                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 154         }
 155         new_org.z = org.z;
 156         return new_org;
 157 }
 158
 159 void waypoint_setupmodel(entity wp)
 160 {
 161         if (autocvar_g_waypointeditor)
 162         {
 163                 // TODO: add some sort of visible box in edit mode for box waypoints
 164                 vector m1 = wp.mins;
 165                 vector m2 = wp.maxs;
 166                 setmodel(wp, MDL_WAYPOINT);
 167                 setsize(wp, m1, m2);
 168                 wp.effects = EF_LOWPRECISION;
 169                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 170                         wp.colormod = '1 0 0';
 171                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 172                         wp.colormod = '1 1 0';
 173                 else if (wp.wphardwired)
 174                         wp.colormod = '0.5 0 1';
 175                 else
 176                         wp.colormod = '1 1 1';
 177         }
 178         else
 179                 wp.model = "";
 180 }
 181
 182 entity waypoint_spawn(vector m1, vector m2, float f)
 183 {
 184         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 185         {
 186                 vector em1 = m1 - '8 8 8';
 187                 vector em2 = m2 + '8 8 8';
 188                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 189                 {
 190                         return it;
 191                 });
 192         }
 193         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 194         // otherwise links loaded from file would be applied only to the first destination
 195         // waypoint since link format doesn't specify waypoint entities but just positions
 196         if((f & WAYPOINTFLAG_GENERATED) && !(f & WAYPOINTFLAG_NORELINK) && m1 == m2)
 197         {
 198                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 199                 {
 200                         return it;
 201                 });
 202         }
 203
 204         entity w = new(waypoint);
 205         IL_PUSH(g_waypoints, w);
 206         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 207         w.wpflags = f;
 208         w.solid = SOLID_TRIGGER;
 209         setorigin(w, (m1 + m2) * 0.5);
 210         setsize(w, m1 - w.origin, m2 - w.origin);
 211         if (w.size)
 212                 w.wpisbox = true;
 213
 214         if(!w.wpisbox)
 215         {
 216                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 217                 if(!move_out_of_solid(w))
 218                 {
 219                         if(!(f & WAYPOINTFLAG_GENERATED))
 220                         {
 221                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 222                                 delete(w);
 223                                 return NULL;
 224                         }
 225                         else
 226                         {
 227                                 if(autocvar_developer)
 228                                 {
 229                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 230                                         backtrace("Waypoint stuck");
 231                                 }
 232                         }
 233                 }
 234                 setsize(w, '0 0 0', '0 0 0');
 235         }
 236
 237         waypoint_clearlinks(w);
 238         //waypoint_schedulerelink(w);
 239
 240         waypoint_setupmodel(w);
 241
 242         return w;
 243 }
 244
 245 void waypoint_spawn_fromeditor(entity pl)
 246 {
 247         entity e;
 248         vector org = pl.origin;
 249         int ctf_flags = havocbot_symmetry_origin_order;
 250         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 251                    || (autocvar_g_waypointeditor_symmetrical < 0));
 252         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 253                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 254         if (sym && ctf_flags < 2)
 255                 ctf_flags = 2;
 256         int wp_num = ctf_flags;
 257
 258         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 259         {
 260                 // snap waypoint to item's origin if close enough
 261                 IL_EACH(g_items, true,
 262                 {
 263                         vector item_org = (it.absmin + it.absmax) * 0.5;
 264                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 265                         if (vlen(item_org - org) < 20)
 266                         {
 267                                 org = item_org;
 268                                 break;
 269                         }
 270                 });
 271         }
 272
 273         LABEL(add_wp);
 274         e = waypoint_spawn(org, org, 0);
 275         if(!e)
 276         {
 277                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 278                 return;
 279         }
 280         waypoint_schedulerelink(e);
 281         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 282         if(sym)
 283         {
 284                 org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 285                 if (vdist(org - pl.origin, >, 32))
 286                 {
 287                         if(wp_num > 2)
 288                                 wp_num--;
 289                         else
 290                                 sym = false;
 291                         goto add_wp;
 292                 }
 293         }
 294 }
 295
 296 void waypoint_remove(entity wp)
 297 {
 298         IL_EACH(g_waypoints, it != wp,
 299         {
 300                 if (waypoint_islinked(it, wp))
 301                         waypoint_removelink(it, wp);
 302         });
 303         delete(wp);
 304 }
 305
 306 void waypoint_remove_fromeditor(entity pl)
 307 {
 308         entity e = navigation_findnearestwaypoint(pl, false);
 309
 310         int ctf_flags = havocbot_symmetry_origin_order;
 311         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 312                    || (autocvar_g_waypointeditor_symmetrical < 0));
 313         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 314                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 315         if (sym && ctf_flags < 2)
 316                 ctf_flags = 2;
 317         int wp_num = ctf_flags;
 318
 319         LABEL(remove_wp);
 320         if (!e) return;
 321         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 322
 323         if (e.wphardwired)
 324         {
 325                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 326                 return;
 327         }
 328
 329         entity wp_sym = NULL;
 330         if (sym)
 331         {
 332                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 333                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 334                         if(vdist(org - it.origin, <, 3))
 335                         {
 336                                 wp_sym = it;
 337                                 break;
 338                         }
 339                 });
 340         }
 341
 342         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 343         waypoint_remove(e);
 344
 345         if (sym && wp_sym)
 346         {
 347                 e = wp_sym;
 348                 if(wp_num > 2)
 349                         wp_num--;
 350                 else
 351                         sym = false;
 352                 goto remove_wp;
 353         }
 354 }
 355
 356 void waypoint_removelink(entity from, entity to)
 357 {
 358         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 359                 return;
 360
 361         entity fromwp31_prev = from.wp31;
 362
 363         switch (waypoint_getlinknum(from, to))
 364         {
 365                 // fallthrough all the way
 366                 case 00: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 367                 case 01: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 368                 case 02: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 369                 case 03: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 370                 case 04: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 371                 case 05: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 372                 case 06: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 373                 case 07: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 374                 case 08: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 375                 case 09: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 376                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 377                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 378                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 379                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 380                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 381                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 382                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 383                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 384                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 385                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 386                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 387                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 388                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 389                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 390                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 391                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 392                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 393                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 394                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 395                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 396                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 397                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 398         }
 399
 400         if (fromwp31_prev && !from.wp31)
 401                 waypoint_schedulerelink(from);
 402 }
 403
 404 int waypoint_getlinknum(entity from, entity to)
 405 {
 406         if (from.wp00 == to) return 00; if (from.wp01 == to) return 01; if (from.wp02 == to) return 02; if (from.wp03 == to) return 03;
 407         if (from.wp04 == to) return 04; if (from.wp05 == to) return 05; if (from.wp06 == to) return 06; if (from.wp07 == to) return 07;
 408         if (from.wp08 == to) return 08; if (from.wp09 == to) return 09; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 409         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 410         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 411         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 412         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 413         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 414         return -1;
 415 }
 416
 417 bool waypoint_islinked(entity from, entity to)
 418 {
 419         return (waypoint_getlinknum(from, to) >= 0);
 420 }
 421
 422 void waypoint_updatecost_foralllinks()
 423 {
 424         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 425         {
 426                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 427                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 428                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 429                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 430                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 431                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 432                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 433                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 434                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 435                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 436                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 437                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 438                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 439                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 440                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 441                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 442                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 443                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 444                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 445                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 446                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 447                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 448                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 449                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 450                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 451                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 452                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 453                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 454                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 455                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 456                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 457                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 458         });
 459 }
 460
 461 float waypoint_getlinearcost(float dist)
 462 {
 463         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 464                 return dist / (autocvar_sv_maxspeed * 1.25);
 465         return dist / autocvar_sv_maxspeed;
 466 }
 467 float waypoint_getlinearcost_underwater(float dist)
 468 {
 469         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 470         return dist / (autocvar_sv_maxspeed * 0.7);
 471 }
 472
 473 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 474 {
 475         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 476         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 477
 478         if (submerged_from && submerged_to)
 479                 return waypoint_getlinearcost_underwater(vlen(to - from));
 480
 481         float c = waypoint_getlinearcost(vlen(to - from));
 482
 483         float height = from.z - to.z;
 484         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 485         {
 486                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 487                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 488                 if(height_cost > c)
 489                         c = height_cost;
 490         }
 491
 492         if (submerged_from || submerged_to)
 493                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 494         return c;
 495 }
 496
 497 float waypoint_getlinkcost(entity from, entity to)
 498 {
 499         vector v1 = from.origin;
 500         vector v2 = to.origin;
 501         if (from.wpisbox)
 502         {
 503                 vector m1 = from.absmin, m2 = from.absmax;
 504                 v1.x = bound(m1.x, v2.x, m2.x);
 505                 v1.y = bound(m1.y, v2.y, m2.y);
 506                 v1.z = bound(m1.z, v2.z, m2.z);
 507         }
 508         if (to.wpisbox)
 509         {
 510                 vector m1 = to.absmin, m2 = to.absmax;
 511                 v2.x = bound(m1.x, v1.x, m2.x);
 512                 v2.y = bound(m1.y, v1.y, m2.y);
 513                 v2.z = bound(m1.z, v1.z, m2.z);
 514         }
 515         return waypoint_gettravelcost(v1, v2, from, to);
 516 }
 517
 518 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 519 // if c == -1 automatically determine cost of the link
 520 void waypoint_addlink_customcost(entity from, entity to, float c)
 521 {
 522         if (from == to || waypoint_islinked(from, to))
 523                 return;
 524         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 525                 return;
 526
 527         if(c == -1)
 528                 c = waypoint_getlinkcost(from, to);
 529
 530         if (from.wp31mincost < c) return;
 531         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 532         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 533         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 534         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 535         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 536         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 537         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 538         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 539         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 540         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 541         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 542         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 543         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 544         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 545         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 546         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 547         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 548         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 549         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 550         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 551         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 552         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 553         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 554         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 555         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 556         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 557         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 558         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 559         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 560         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 561         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 562         from.wp00 = to;from.wp00mincost = c;return;
 563 }
 564
 565 void waypoint_addlink(entity from, entity to)
 566 {
 567         waypoint_addlink_customcost(from, to, -1);
 568 }
 569
 570 // relink this spawnfunc_waypoint
 571 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 572 // (SLOW!)
 573 void waypoint_think(entity this)
 574 {
 575         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 576         float sv2_height = 0, ev2_height = 0;
 577
 578         bot_calculate_stepheightvec();
 579
 580         int dphitcontentsmask_save = this.dphitcontentsmask;
 581         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 582
 583         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 584
 585         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 586         IL_EACH(g_waypoints, this != it,
 587         {
 588                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 589                 {
 590                         waypoint_addlink(this, it);
 591                         waypoint_addlink(it, this);
 592                 }
 593                 else
 594                 {
 595                         ++relink_total;
 596                         if(!checkpvs(this.origin, it))
 597                         {
 598                                 ++relink_pvsculled;
 599                                 continue;
 600                         }
 601
 602                         sv = set_tracewalk_dest_2(this, it.origin);
 603                         sv2 = tracewalk_dest;
 604                         sv2_height = tracewalk_dest_height;
 605                         ev = set_tracewalk_dest_2(it, this.origin);
 606                         ev2 = tracewalk_dest;
 607                         ev2_height = tracewalk_dest_height;
 608
 609                         dv = ev - sv;
 610                         dv.z = 0;
 611                         if(vdist(dv, >=, 1050)) // max search distance in XY
 612                         {
 613                                 ++relink_lengthculled;
 614                                 continue;
 615                         }
 616
 617                         navigation_testtracewalk = 0;
 618
 619                         //traceline(this.origin, it.origin, false, NULL);
 620                         //if (trace_fraction == 1)
 621                         if (this.wpisbox)
 622                                 relink_walkculled += 0.5;
 623                         else
 624                         {
 625                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 626                                         waypoint_addlink(this, it);
 627                                 else
 628                                         relink_walkculled += 0.5;
 629                         }
 630
 631                         if (it.wpisbox)
 632                                 relink_walkculled += 0.5;
 633                         else
 634                         {
 635                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 636                                         waypoint_addlink(it, this);
 637                                 else
 638                                         relink_walkculled += 0.5;
 639                         }
 640                 }
 641         });
 642         navigation_testtracewalk = 0;
 643         this.wplinked = true;
 644         this.dphitcontentsmask = dphitcontentsmask_save;
 645 }
 646
 647 void waypoint_clearlinks(entity wp)
 648 {
 649         // clear links to other waypoints
 650         float f = 10000000;
 651         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 652         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 653         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 654         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 655
 656         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 657         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 658         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 659         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 660
 661         wp.wplinked = false;
 662 }
 663
 664 // tell a spawnfunc_waypoint to relink
 665 void waypoint_schedulerelink(entity wp)
 666 {
 667         if (wp == NULL)
 668                 return;
 669
 670         waypoint_setupmodel(wp);
 671         wp.wpisbox = vdist(wp.size, >, 0);
 672         wp.enemy = NULL;
 673         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 674                 wp.owner = NULL;
 675         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 676                 waypoint_clearlinks(wp);
 677         // schedule an actual relink on next frame
 678         setthink(wp, waypoint_think);
 679         wp.nextthink = time;
 680         wp.effects = EF_LOWPRECISION;
 681 }
 682
 683 // spawnfunc_waypoint map entity
 684 spawnfunc(waypoint)
 685 {
 686         IL_PUSH(g_waypoints, this);
 687
 688         setorigin(this, this.origin);
 689         // schedule a relink after other waypoints have had a chance to spawn
 690         waypoint_clearlinks(this);
 691         //waypoint_schedulerelink(this);
 692 }
 693
 694 // tell all waypoints to relink
 695 // actually this is useful only to update relink_* stats
 696 void waypoint_schedulerelinkall()
 697 {
 698         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 699         IL_EACH(g_waypoints, true,
 700         {
 701                 waypoint_schedulerelink(it);
 702         });
 703         waypoint_load_links_hardwired();
 704 }
 705
 706 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
 707
 708 // Load waypoint links from file
 709 bool waypoint_load_links()
 710 {
 711         string s;
 712         float file, tokens, c = 0, found;
 713         entity wp_from = NULL, wp_to;
 714         vector wp_to_pos, wp_from_pos;
 715
 716         string gt_ext = GET_GAMETYPE_EXTENSION();
 717
 718         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 719         file = fopen(filename, FILE_READ);
 720
 721         if (gt_ext != "" && file < 0)
 722         {
 723                 // if race waypoint file doesn't exist load the default one
 724                 filename = sprintf("maps/%s.waypoints.cache", mapname);
 725                 file = fopen(filename, FILE_READ);
 726         }
 727
 728         if (file < 0)
 729         {
 730                 LOG_TRACE("waypoint links load from ", filename, " failed");
 731                 waypoint_schedulerelinkall();
 732                 return false;
 733         }
 734
 735         bool parse_comments = true;
 736         float ver = 0;
 737         string links_time = string_null;
 738
 739         while ((s = fgets(file)))
 740         {
 741                 if(parse_comments)
 742                 {
 743                         if(substring(s, 0, 2) == "//")
 744                         {
 745                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
 746                                         ver = stof(substring(s, 19, -1));
 747                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
 748                                         links_time = substring(s, 16, -1);
 749                                 continue;
 750                         }
 751                         else
 752                         {
 753                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
 754                                 {
 755                                         if (links_time != waypoint_time)
 756                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
 757                                         else
 758                                                 LOG_TRACE("waypoint links for this map are outdated.");
 759                                         if (g_assault)
 760                                         {
 761                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
 762                                         }
 763                                         else
 764                                         {
 765                                                 LOG_TRACE("automatically updating...");
 766                                                 waypoint_schedulerelinkall();
 767                                                 fclose(file);
 768                                                 return false;
 769                                         }
 770                                 }
 771                                 parse_comments = false;
 772                         }
 773                 }
 774
 775                 tokens = tokenizebyseparator(s, "*");
 776
 777                 if (tokens!=2)
 778                 {
 779                         // bad file format
 780                         fclose(file);
 781                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
 782                         return false;
 783                 }
 784
 785                 wp_from_pos     = stov(argv(0));
 786                 wp_to_pos       = stov(argv(1));
 787
 788                 // Search "from" waypoint
 789                 if(!wp_from || wp_from.origin!=wp_from_pos)
 790                 {
 791                         wp_from = findradius(wp_from_pos, 1);
 792                         found = false;
 793                         while(wp_from)
 794                         {
 795                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 796                                 if(wp_from.classname == "waypoint")
 797                                 {
 798                                         found = true;
 799                                         break;
 800                                 }
 801                                 wp_from = wp_from.chain;
 802                         }
 803
 804                         if(!found)
 805                         {
 806                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 807                                 continue;
 808                         }
 809                 }
 810
 811                 // Search "to" waypoint
 812                 wp_to = findradius(wp_to_pos, 1);
 813                 found = false;
 814                 while(wp_to)
 815                 {
 816                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 817                         if(wp_to.classname == "waypoint")
 818                         {
 819                                 found = true;
 820                                 break;
 821                         }
 822                         wp_to = wp_to.chain;
 823                 }
 824
 825                 if(!found)
 826                 {
 827                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 828                         continue;
 829                 }
 830
 831                 ++c;
 832                 waypoint_addlink(wp_from, wp_to);
 833         }
 834
 835         fclose(file);
 836
 837         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
 838
 839         bool scheduled = false;
 840         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
 841         {
 842                 if (!it.wp00)
 843                 {
 844                         waypoint_schedulerelink(it);
 845                         scheduled = true;
 846                 }
 847         });
 848         if (scheduled)
 849                 return false;
 850
 851         botframe_cachedwaypointlinks = true;
 852         return true;
 853 }
 854
 855 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 856 {
 857         string s;
 858         float file, tokens, c = 0, found;
 859         entity wp_from = NULL, wp_to;
 860         vector wp_to_pos, wp_from_pos;
 861
 862         string gt_ext = GET_GAMETYPE_EXTENSION();
 863
 864         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
 865         file = fopen(filename, FILE_READ);
 866
 867         if (gt_ext != "" && file < 0)
 868         {
 869                 // if race waypoint file doesn't exist load the default one
 870                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
 871                 file = fopen(filename, FILE_READ);
 872         }
 873
 874         botframe_loadedforcedlinks = true;
 875
 876         if (file < 0)
 877         {
 878                 if(!removal_mode)
 879                         LOG_TRACE("waypoint links load from ", filename, " failed");
 880                 return;
 881         }
 882
 883         while ((s = fgets(file)))
 884         {
 885                 if(substring(s, 0, 2)=="//")
 886                         continue;
 887
 888                 if(substring(s, 0, 1)=="#")
 889                         continue;
 890
 891                 tokens = tokenizebyseparator(s, "*");
 892
 893                 if (tokens!=2)
 894                         continue;
 895
 896                 wp_from_pos     = stov(argv(0));
 897                 wp_to_pos       = stov(argv(1));
 898
 899                 // Search "from" waypoint
 900                 if(!wp_from || wp_from.origin!=wp_from_pos)
 901                 {
 902                         wp_from = findradius(wp_from_pos, 5);
 903                         found = false;
 904                         while(wp_from)
 905                         {
 906                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 907                                 if(wp_from.classname == "waypoint")
 908                                 {
 909                                         found = true;
 910                                         break;
 911                                 }
 912                                 wp_from = wp_from.chain;
 913                         }
 914
 915                         if(!found)
 916                         {
 917                                 if(!removal_mode)
 918                                         LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
 919                                 continue;
 920                         }
 921                 }
 922
 923                 // Search "to" waypoint
 924                 wp_to = findradius(wp_to_pos, 5);
 925                 found = false;
 926                 while(wp_to)
 927                 {
 928                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 929                         if(wp_to.classname == "waypoint")
 930                         {
 931                                 found = true;
 932                                 break;
 933                         }
 934                         wp_to = wp_to.chain;
 935                 }
 936
 937                 if(!found)
 938                 {
 939                         if(!removal_mode)
 940                                 LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
 941                         continue;
 942                 }
 943
 944                 ++c;
 945                 if(removal_mode)
 946                 {
 947                         waypoint_removelink(wp_from, wp_to);
 948                         continue;
 949                 }
 950
 951                 waypoint_addlink(wp_from, wp_to);
 952                 wp_from.wphardwired = true;
 953                 wp_to.wphardwired = true;
 954                 waypoint_setupmodel(wp_from);
 955                 waypoint_setupmodel(wp_to);
 956         }
 957
 958         fclose(file);
 959
 960         LOG_TRACE(((removal_mode) ? "unloaded " : "loaded "),
 961                 ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 962 }
 963
 964 entity waypoint_get_link(entity w, float i)
 965 {
 966         switch(i)
 967         {
 968                 case  0:return w.wp00;
 969                 case  1:return w.wp01;
 970                 case  2:return w.wp02;
 971                 case  3:return w.wp03;
 972                 case  4:return w.wp04;
 973                 case  5:return w.wp05;
 974                 case  6:return w.wp06;
 975                 case  7:return w.wp07;
 976                 case  8:return w.wp08;
 977                 case  9:return w.wp09;
 978                 case 10:return w.wp10;
 979                 case 11:return w.wp11;
 980                 case 12:return w.wp12;
 981                 case 13:return w.wp13;
 982                 case 14:return w.wp14;
 983                 case 15:return w.wp15;
 984                 case 16:return w.wp16;
 985                 case 17:return w.wp17;
 986                 case 18:return w.wp18;
 987                 case 19:return w.wp19;
 988                 case 20:return w.wp20;
 989                 case 21:return w.wp21;
 990                 case 22:return w.wp22;
 991                 case 23:return w.wp23;
 992                 case 24:return w.wp24;
 993                 case 25:return w.wp25;
 994                 case 26:return w.wp26;
 995                 case 27:return w.wp27;
 996                 case 28:return w.wp28;
 997                 case 29:return w.wp29;
 998                 case 30:return w.wp30;
 999                 case 31:return w.wp31;
1000                 default:return NULL;
1001         }
1002 }
1003
1004 // Save all waypoint links to a file
1005 void waypoint_save_links()
1006 {
1007         // temporarily remove hardwired links so they don't get saved among normal links
1008         waypoint_remove_links_hardwired();
1009
1010         string gt_ext = GET_GAMETYPE_EXTENSION();
1011
1012         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1013         int file = fopen(filename, FILE_WRITE);
1014         if (file < 0)
1015         {
1016                 LOG_INFOF("waypoint link save to %s failed", filename);
1017                 return;
1018         }
1019
1020         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1021         if (waypoint_time != "")
1022                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1023
1024         int c = 0;
1025         IL_EACH(g_waypoints, true,
1026         {
1027                 for(int j = 0; j < 32; ++j)
1028                 {
1029                         entity link = waypoint_get_link(it, j);
1030                         if(link)
1031                         {
1032                                 // NOTE: vtos rounds vector components to 1 decimal place
1033                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1034                                 fputs(file, s);
1035                                 ++c;
1036                         }
1037                 }
1038         });
1039         fclose(file);
1040
1041         botframe_cachedwaypointlinks = true;
1042
1043         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1044
1045         waypoint_load_links_hardwired();
1046 }
1047
1048 // save waypoints to gamedir/data/maps/mapname.waypoints
1049 void waypoint_saveall()
1050 {
1051         string gt_ext = GET_GAMETYPE_EXTENSION();
1052
1053         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1054         int file = fopen(filename, FILE_WRITE);
1055         if (file < 0)
1056         {
1057                 waypoint_save_links(); // save anyway?
1058                 botframe_loadedforcedlinks = false;
1059
1060                 LOG_INFOF("waypoint links: save to %s failed", filename);
1061                 return;
1062         }
1063
1064         float sym = autocvar_g_waypointeditor_symmetrical;
1065         string sym_str = ftos(sym);
1066         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1067         {
1068                 if (sym == 1)
1069                 {
1070                         sym_str = cons(sym_str, "-");
1071                         sym_str = cons(sym_str, "-");
1072                 }
1073                 else
1074                 {
1075                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1076                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1077                 }
1078                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1079                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1080         }
1081         else if (autocvar_g_waypointeditor_symmetrical == -2)
1082         {
1083                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1084                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1085         }
1086
1087         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1088         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1089         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1090         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1091
1092         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1093         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1094         //fputs(file, strcat("//", "\n"));
1095         //fputs(file, strcat("//", "\n"));
1096         //fputs(file, strcat("//", "\n"));
1097
1098         int c = 0;
1099         IL_EACH(g_waypoints, true,
1100         {
1101                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1102                         continue;
1103
1104                 string s;
1105                 // NOTE: vtos rounds vector components to 1 decimal place
1106                 s = strcat(vtos(it.origin + it.mins), "\n");
1107                 s = strcat(s, vtos(it.origin + it.maxs));
1108                 s = strcat(s, "\n");
1109                 s = strcat(s, ftos(it.wpflags));
1110                 s = strcat(s, "\n");
1111                 fputs(file, s);
1112                 c++;
1113         });
1114         fclose(file);
1115         waypoint_save_links();
1116         botframe_loadedforcedlinks = false;
1117
1118         LOG_INFOF("saved %d waypoints to %s", c, filename);
1119 }
1120
1121 // load waypoints from file
1122 float waypoint_loadall()
1123 {
1124         string s;
1125         float file, cwp, cwb, fl;
1126         vector m1, m2;
1127         cwp = 0;
1128         cwb = 0;
1129
1130         string gt_ext = GET_GAMETYPE_EXTENSION();
1131
1132         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1133         file = fopen(filename, FILE_READ);
1134
1135         if (gt_ext != "" && file < 0)
1136         {
1137                 // if race waypoint file doesn't exist load the default one
1138                 filename = sprintf("maps/%s.waypoints", mapname);
1139                 file = fopen(filename, FILE_READ);
1140         }
1141
1142         if (file < 0)
1143         {
1144                 LOG_TRACE("waypoint load from ", filename, " failed");
1145                 return 0;
1146         }
1147
1148         bool parse_comments = true;
1149         float ver = 0;
1150         float sym = 0;
1151         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1152
1153         while ((s = fgets(file)))
1154         {
1155                 if(parse_comments)
1156                 {
1157                         if(substring(s, 0, 2) == "//")
1158                         {
1159                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1160                                         ver = stof(substring(s, 19, -1));
1161                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1162                                 {
1163                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1164                                         if (tokens) { sym = stof(argv(0)); }
1165                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1166                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1167                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1168                                 }
1169                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1170                                         strcpy(waypoint_time, substring(s, 16, -1));
1171                                 continue;
1172                         }
1173                         else
1174                         {
1175                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1176                                 {
1177                                         LOG_TRACE("waypoints for this map are outdated");
1178                                         LOG_TRACE("please update them in the editor");
1179                                 }
1180                                 parse_comments = false;
1181                         }
1182                 }
1183                 m1 = stov(s);
1184                 s = fgets(file);
1185                 if (!s)
1186                         break;
1187                 m2 = stov(s);
1188                 s = fgets(file);
1189                 if (!s)
1190                         break;
1191                 fl = stof(s);
1192                 waypoint_spawn(m1, m2, fl);
1193                 if (m1 == m2)
1194                         cwp = cwp + 1;
1195                 else
1196                         cwb = cwb + 1;
1197         }
1198         fclose(file);
1199         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1200
1201         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1202         {
1203                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1204                 if (sym == 1 && sym_param3 < 2)
1205                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1206                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1207                 {
1208                         string params;
1209                         if (sym == 1)
1210                                 params = cons("-", "-");
1211                         else
1212                         {
1213                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1214                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1215                         }
1216                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1217                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1218                 }
1219                 else if (sym == -2)
1220                 {
1221                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1222                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1223                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1224                 }
1225                 else
1226                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1227                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1228         }
1229
1230         return cwp + cwb;
1231 }
1232
1233 #define waypoint_fixorigin(position, tracetest_ent) \
1234         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1235
1236 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1237 {
1238         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1239         if(trace_startsolid)
1240                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1241         if(trace_startsolid)
1242                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1243         if(trace_fraction < 1)
1244                 position = trace_endpos;
1245         return position;
1246 }
1247
1248 void waypoint_spawnforitem_force(entity e, vector org)
1249 {
1250         // Fix the waypoint altitude if necessary
1251         org = waypoint_fixorigin(org, NULL);
1252
1253         // don't spawn an item spawnfunc_waypoint if it already exists
1254         IL_EACH(g_waypoints, true,
1255         {
1256                 if(it.wpisbox)
1257                 {
1258                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1259                         {
1260                                 e.nearestwaypoint = it;
1261                                 return;
1262                         }
1263                 }
1264                 else
1265                 {
1266                         if(vdist(it.origin - org, <, 16))
1267                         {
1268                                 e.nearestwaypoint = it;
1269                                 return;
1270                         }
1271                 }
1272         });
1273
1274         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1275 }
1276
1277 void waypoint_spawnforitem(entity e)
1278 {
1279         if(!bot_waypoints_for_items)
1280                 return;
1281
1282         waypoint_spawnforitem_force(e, e.origin);
1283 }
1284
1285 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1286 {
1287         entity w;
1288         entity dw;
1289         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1290         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1291         // one way link to the destination
1292         w.wp00 = dw;
1293         w.wp00mincost = timetaken; // this is just for jump pads
1294         // the teleporter's nearest spawnfunc_waypoint is this one
1295         // (teleporters are not goals, so this is probably useless)
1296         e.nearestwaypoint = w;
1297         e.nearestwaypointtimeout = -1;
1298 }
1299
1300 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1301 {
1302         float src_angle = e.warpzone_angles.x;
1303         while (src_angle < -180) src_angle += 360;
1304         while (src_angle > 180) src_angle -= 360;
1305
1306         float dest_angle = e.enemy.warpzone_angles.x;
1307         while (dest_angle < -180) dest_angle += 360;
1308         while (dest_angle > 180) dest_angle -= 360;
1309
1310         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1311         if (src_angle == -90 || dest_angle == -90)
1312                 return;
1313
1314         makevectors(e.warpzone_angles);
1315         vector src = (e.absmin + e.absmax) * 0.5;
1316         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1317         vector down_dir_src = -v_up;
1318
1319         makevectors(e.enemy.warpzone_angles);
1320         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1321         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1322         vector down_dir_dest = -v_up;
1323
1324         int extra_flag = 0;
1325         // don't snap to the ground waypoints for source warpzones pointing downwards
1326         if (src_angle != 90)
1327         {
1328                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1329                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1330                 // oblique warpzones need a jump otherwise bots gets stuck
1331                 if (src_angle != 0)
1332                         extra_flag = WAYPOINTFLAG_JUMP;
1333         }
1334
1335         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1336 }
1337
1338 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1339 {
1340         destination = waypoint_fixorigin(destination, tracetest_ent);
1341         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1342 }
1343
1344 entity waypoint_spawnpersonal(entity this, vector position)
1345 {
1346         entity w;
1347
1348         // drop the waypoint to a proper location:
1349         //   first move it up by a player height
1350         //   then move it down to hit the floor with player bbox size
1351         position = waypoint_fixorigin(position, this);
1352
1353         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1354         w.nearestwaypoint = NULL;
1355         w.nearestwaypointtimeout = 0;
1356         w.owner = this;
1357
1358         waypoint_schedulerelink(w);
1359
1360         return w;
1361 }
1362
1363 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1364 {
1365         if (!(wp1 && wp2))
1366                 return;
1367
1368         if (wp1.wphardwired && wp2.wphardwired)
1369                 te_beam(NULL, wp1.origin, wp2.origin);
1370         else if (display_type == 1)
1371                 te_lightning2(NULL, wp1.origin, wp2.origin);
1372 }
1373
1374 void waypoint_showlinks_to(entity wp, int display_type)
1375 {
1376         IL_EACH(g_waypoints, it != wp,
1377         {
1378                 if (waypoint_islinked(it, wp))
1379                         waypoint_showlink(it, wp, display_type);
1380         });
1381 }
1382
1383 void waypoint_showlinks_from(entity wp, int display_type)
1384 {
1385         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1386         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1387         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1388         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1389         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1390         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1391         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1392         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1393         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1394         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1395         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1396         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1397         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1398         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1399         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1400         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1401 }
1402
1403 void botframe_showwaypointlinks()
1404 {
1405         if (time < botframe_waypointeditorlightningtime)
1406                 return;
1407         botframe_waypointeditorlightningtime = time + 0.5;
1408         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1409         {
1410                 int display_type = 0;
1411                 entity head = navigation_findnearestwaypoint(it, false);
1412                 it.nearestwaypoint = head; // mainly useful for debug
1413                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1414                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1415                         display_type = 1; // default
1416                 else if(head && (head.wphardwired))
1417                         display_type = 2; // only hardwired
1418
1419                 if (display_type)
1420                 {
1421                         //navigation_testtracewalk = true;
1422                         //print("currently selected WP is ", etos(head), "\n");
1423                         //navigation_testtracewalk = false;
1424                         if (head)
1425                         {
1426                                 te_lightning2(NULL, head.origin, it.origin);
1427                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1428                                         waypoint_showlinks_to(head, display_type);
1429                                 else
1430                                         waypoint_showlinks_from(head, display_type);
1431                         }
1432                 }
1433         });
1434 }
1435
1436 float botframe_autowaypoints_fixdown(vector v)
1437 {
1438         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1439         if(trace_fraction >= 1)
1440                 return 0;
1441         return 1;
1442 }
1443
1444 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1445 {
1446         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1447         {
1448                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1449                 return 0;
1450         });
1451
1452         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1453         return 1;
1454 }
1455
1456 // return value:
1457 //    1 = WP created
1458 //    0 = no action needed
1459 //   -1 = temp fail, try from world too
1460 //   -2 = permanent fail, do not retry
1461 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1462 {
1463         // make it possible to go from p to wp, if we can
1464         // if wp is NULL, nearest is chosen
1465
1466         entity w;
1467         vector porg;
1468         float t, tmin, tmax;
1469         vector o;
1470         vector save;
1471
1472         if(!botframe_autowaypoints_fixdown(p.origin))
1473                 return -2;
1474         porg = trace_endpos;
1475
1476         if(wp)
1477         {
1478                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1479
1480                 // if wp -> porg, then OK
1481                 float maxdist;
1482                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1483                 {
1484                         // we may find a better one
1485                         maxdist = vlen(wp.origin - porg);
1486                 }
1487                 else
1488                 {
1489                         // accept any "good"
1490                         maxdist = 2100;
1491                 }
1492
1493                 float bestdist = maxdist;
1494                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1495                 {
1496                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1497                         if(d < bestdist)
1498                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1499                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1500                         {
1501                                 bestdist = d;
1502                                 p.(fld) = it;
1503                         }
1504                 });
1505                 if(bestdist < maxdist)
1506                 {
1507                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1508                         return 0;
1509                 }
1510
1511                 if(bestdist < 2100)
1512                 {
1513                         // we know maxdist < 2100
1514                         // so wp -> porg is still valid
1515                         // all is good
1516                         p.(fld) = wp;
1517                         return 0;
1518                 }
1519
1520                 // otherwise, no existing WP can fix our issues
1521         }
1522         else
1523         {
1524                 save = p.origin;
1525                 setorigin(p, porg);
1526                 w = navigation_findnearestwaypoint(p, walkfromwp);
1527                 setorigin(p, save);
1528                 if(w)
1529                 {
1530                         p.(fld) = w;
1531                         return 0;
1532                 }
1533         }
1534
1535         tmin = 0;
1536         tmax = 1;
1537         for (;;)
1538         {
1539                 if(tmax - tmin < 0.001)
1540                 {
1541                         // did not get a good candidate
1542                         return -1;
1543                 }
1544
1545                 t = (tmin + tmax) * 0.5;
1546                 o = antilag_takebackorigin(p, CS(p), time - t);
1547                 if(!botframe_autowaypoints_fixdown(o))
1548                         return -2;
1549                 o = trace_endpos;
1550
1551                 if(wp)
1552                 {
1553                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
1554                         {
1555                                 // we cannot walk from wp.origin to o
1556                                 // get closer to tmax
1557                                 tmin = t;
1558                                 continue;
1559                         }
1560                 }
1561                 else
1562                 {
1563                         save = p.origin;
1564                         setorigin(p, o);
1565                         w = navigation_findnearestwaypoint(p, walkfromwp);
1566                         setorigin(p, save);
1567                         if(!w)
1568                         {
1569                                 // we cannot walk from any WP to o
1570                                 // get closer to tmax
1571                                 tmin = t;
1572                                 continue;
1573                         }
1574                 }
1575
1576                 // if we get here, o is valid regarding waypoints
1577                 // check if o is connected right to the player
1578                 // we break if it succeeds, as that means o is a good waypoint location
1579                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
1580                         break;
1581
1582                 // o is no good, we need to get closer to the player
1583                 tmax = t;
1584         }
1585
1586         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
1587         botframe_autowaypoints_createwp(o, p, fld, 0);
1588         return 1;
1589 }
1590
1591 // automatically create missing waypoints
1592 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1593 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1594 {
1595         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1596         if(r != -1)
1597                 return;
1598         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1599         if(r != -1)
1600                 return;
1601
1602         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
1603         if(!botframe_autowaypoints_fixdown(p.origin))
1604                 return; // shouldn't happen, caught above
1605         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1606 }
1607
1608 void botframe_deleteuselesswaypoints()
1609 {
1610         IL_EACH(g_items, it.bot_pickup,
1611         {
1612                 // NOTE: this protects waypoints if they're the ONLY nearest
1613                 // waypoint. That's the intention.
1614                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1615                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1616         });
1617         IL_EACH(g_waypoints, true,
1618         {
1619                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1620                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1621                 // WP is useful if:
1622                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1623                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1624                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1625                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1626                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1627                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1628                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1629                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1630                 // b) WP is closest WP for an item/spawnpoint/other entity
1631                 //    This has been done above by protecting these WPs.
1632         });
1633         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1634         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1635         {
1636                 for (int m = 0; m < 32; ++m)
1637                 {
1638                         entity w = waypoint_get_link(it, m);
1639                         if (!w)
1640                                 break;
1641                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1642                                 continue;
1643                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1644                                 continue;
1645                         for (int j = 0; j < 32; ++j)
1646                         {
1647                                 entity w2 = waypoint_get_link(w, j);
1648                                 if (!w2)
1649                                         break;
1650                                 if (it == w2)
1651                                         continue;
1652                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1653                                         continue;
1654                                 // If we got here, it != w2 exist with it -> w
1655                                 // and w -> w2. That means the waypoint is not
1656                                 // a dead end.
1657                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1658                                 for (int k = 0; k < 32; ++k)
1659                                 {
1660                                         if (waypoint_get_link(it, k) == w2)
1661                                                 continue;
1662                                         // IF WE GET HERE, w is proven useful
1663                                         // to get from it to w2!
1664                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1665                                         goto next;
1666                                 }
1667                         }
1668 LABEL(next)
1669                 }
1670         });
1671         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1672         //     they are needed to complete routes while autowaypointing.
1673
1674         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1675         {
1676                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
1677                 te_explosion(it.origin);
1678                 waypoint_remove(it);
1679                 break;
1680         });
1681
1682         IL_EACH(g_waypoints, true,
1683         {
1684                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1685         });
1686 }
1687
1688 void botframe_autowaypoints()
1689 {
1690         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
1691                 // going back is broken, so only fix waypoints to walk TO the player
1692                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1693                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1694                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1695         });
1696
1697         if (autocvar_g_waypointeditor_auto >= 2) {
1698                 botframe_deleteuselesswaypoints();
1699         }
1700 }
1701