qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 bool waypoint_has_hardwiredlinks(entity wp)
 264 {
 265         if (!wp)
 266                 return false;
 267         return (wp.wphw00 != NULL);
 268 }
 269
 270 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 271 {
 272         if (!(wp_from && wp_to))
 273                 return false;
 274
 275         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 276         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 277         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 278         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 279         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 280         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 281         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 282         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 283
 284         return false;
 285 }
 286
 287 void waypoint_setupmodel(entity wp);
 288 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 289 {
 290         if (!(wp_from && wp_to))
 291                 return;
 292
 293         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; waypoint_setupmodel(wp_from); return; }
 294         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 295         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 296         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 297         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 298         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 299         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 300         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 301
 302         return;
 303 }
 304
 305 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 306 {
 307         if (!(wp_from && wp_to))
 308                 return;
 309
 310         int removed = -1;
 311         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 312         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 313         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 314         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 315         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 316         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 317         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 318         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 319
 320         if (removed >= 0)
 321         {
 322                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 323                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 324                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 325                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 326                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 327                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 328                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 329                 if (removed <= 7) wp_from.wphw07 = NULL;
 330                 if (!wp_from.wphw00)
 331                         waypoint_setupmodel(wp_from);
 332         }
 333
 334         return;
 335 }
 336
 337 void waypoint_setupmodel(entity wp)
 338 {
 339         if (autocvar_g_waypointeditor)
 340         {
 341                 // TODO: add some sort of visible box in edit mode for box waypoints
 342                 vector m1 = wp.mins;
 343                 vector m2 = wp.maxs;
 344                 setmodel(wp, MDL_WAYPOINT);
 345                 setsize(wp, m1, m2);
 346                 wp.effects = EF_LOWPRECISION;
 347                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 348                         wp.colormod = '1 0 0'; // red
 349                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 350                         wp.colormod = '1 1 0'; // yellow
 351                 else if (wp.wpflags & WAYPOINTFLAG_NORELINK)
 352                         wp.colormod = '1 0.5 0'; // orange
 353                 else if (wp.wpflags & WAYPOINTFLAG_CROUCH)
 354                         wp.colormod = '0 1 1'; // cyan
 355                 else if (waypoint_has_hardwiredlinks(wp))
 356                         wp.colormod = '0.5 0 1'; // purple
 357                 else
 358                         wp.colormod = '1 1 1';
 359         }
 360         else
 361                 wp.model = "";
 362 }
 363
 364 entity waypoint_get(vector m1, vector m2)
 365 {
 366         if (m1 == m2)
 367         {
 368                 m1 -= '8 8 8';
 369                 m2 += '8 8 8';
 370         }
 371         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 372
 373         return NULL;
 374 }
 375
 376 .float createdtime;
 377 entity waypoint_spawn(vector m1, vector m2, float f)
 378 {
 379         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 380         {
 381                 entity wp_found = waypoint_get(m1, m2);
 382                 if (wp_found)
 383                         return wp_found;
 384         }
 385         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 386         // otherwise links loaded from file would be applied only to the first destination
 387         // waypoint since link format doesn't specify waypoint entities but just positions
 388         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WAYPOINTFLAG_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 389         {
 390                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 391                 {
 392                         return it;
 393                 });
 394         }
 395
 396         entity w = new(waypoint);
 397         IL_PUSH(g_waypoints, w);
 398         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 399         w.wpflags = f;
 400         w.solid = SOLID_TRIGGER;
 401         w.createdtime = time;
 402         setorigin(w, (m1 + m2) * 0.5);
 403         setsize(w, m1 - w.origin, m2 - w.origin);
 404         if (w.size)
 405                 w.wpisbox = true;
 406
 407         if(!w.wpisbox)
 408         {
 409                 if (f & WAYPOINTFLAG_CROUCH)
 410                         setsize(w, PL_CROUCH_MIN_CONST - '1 1 0', PL_CROUCH_MAX_CONST + '1 1 0');
 411                 else
 412                         setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 413                 if(!move_out_of_solid(w))
 414                 {
 415                         if(!(f & WAYPOINTFLAG_GENERATED))
 416                         {
 417                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 418                                 delete(w);
 419                                 return NULL;
 420                         }
 421                         else
 422                         {
 423                                 if(autocvar_developer)
 424                                 {
 425                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 426                                         backtrace("Waypoint stuck");
 427                                 }
 428                         }
 429                 }
 430                 setsize(w, '0 0 0', '0 0 0');
 431         }
 432
 433         waypoint_clearlinks(w);
 434         //waypoint_schedulerelink(w);
 435
 436         waypoint_setupmodel(w);
 437
 438         return w;
 439 }
 440
 441 float trigger_push_get_push_time(entity this, vector endpos);
 442 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 443 {
 444         entity jp = NULL;
 445         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 446         {
 447                 jp = it;
 448                 break;
 449         });
 450         if (!jp)
 451                 return;
 452
 453         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 454         wp_from.wp00 = wp_to;
 455         wp_from.wp00mincost = cost;
 456         jp.nearestwaypoint = wp_from;
 457         jp.nearestwaypointtimeout = -1;
 458 }
 459
 460 bool start_wp_is_spawned;
 461 vector start_wp_origin;
 462 bool start_wp_is_hardwired;
 463
 464 void waypoint_clear_start_wp(entity pl, bool warn)
 465 {
 466         start_wp_is_spawned = false;
 467         start_wp_origin = '0 0 0';
 468         pl.wp_locked = NULL;
 469         start_wp_is_hardwired = false;
 470         if (warn)
 471                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 472 }
 473
 474 void waypoint_start_hardwiredlink(entity pl)
 475 {
 476         entity wp = pl.nearestwaypoint;
 477         if ((!start_wp_is_spawned || start_wp_is_hardwired) && wp && !(wp.wpflags & WAYPOINTFLAG_NORELINK))
 478         {
 479                 start_wp_is_hardwired = true;
 480                 start_wp_is_spawned = true;
 481                 start_wp_origin = wp.origin;
 482                 pl.wp_locked = wp;
 483                 LOG_INFOF("^x80fNearest waypoint %s marked as hardwired link origin.\n", vtos(wp.origin));
 484         }
 485         else
 486                 start_wp_is_hardwired = false;
 487 }
 488
 489 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp, bool is_crouch_wp)
 490 {
 491         if (WAYPOINT_VERSION < waypoint_version_loaded)
 492         {
 493                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 494                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 495                 return;
 496         }
 497
 498         entity e = NULL, jp = NULL;
 499         vector org = pl.origin;
 500         if (at_crosshair)
 501         {
 502                 crosshair_trace(pl);
 503                 org = trace_endpos - eZ * PL_MIN_CONST.z;
 504                 IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 505                 {
 506                         jp = it;
 507                         break;
 508                 });
 509         }
 510         if (jp || is_jump_wp)
 511         {
 512                 if (start_wp_is_spawned)
 513                         start_wp_is_spawned = false;
 514                 LOG_INFO("^xf80Spawning start waypoint...\n");
 515         }
 516         int ctf_flags = havocbot_symmetry_origin_order;
 517         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 518                    || (autocvar_g_waypointeditor_symmetrical < 0));
 519         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 520                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 521         if (sym && ctf_flags < 2)
 522                 ctf_flags = 2;
 523         int wp_num = ctf_flags;
 524
 525         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp)
 526         {
 527                 // snap waypoint to item's origin if close enough
 528                 IL_EACH(g_items, true,
 529                 {
 530                         vector item_org = (it.absmin + it.absmax) * 0.5;
 531                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 532                         if (vlen(item_org - org) < 20)
 533                         {
 534                                 org = item_org;
 535                                 break;
 536                         }
 537                 });
 538         }
 539
 540         vector start_org = '0 0 0';
 541         if (start_wp_is_spawned)
 542         {
 543                 if (!start_wp_is_hardwired)
 544                         LOG_INFO("^xf80Spawning destination waypoint...\n");
 545                 start_org = start_wp_origin;
 546         }
 547
 548         // save org as it can be modified spawning symmetrycal waypoints
 549         vector initial_origin = '0 0 0';
 550         bool initial_origin_is_set = false;
 551
 552         LABEL(add_wp);
 553
 554         if (jp)
 555         {
 556                 e = NULL;
 557                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 558                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 559                 {
 560                         e = it; break;
 561                 });
 562                 if (!e)
 563                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 564                 if (!pl.wp_locked)
 565                         pl.wp_locked = e;
 566         }
 567         else if (is_jump_wp)
 568         {
 569                 entity wp_found = waypoint_get(org, org);
 570                 if (wp_found && !(wp_found.wpflags & WAYPOINTFLAG_JUMP))
 571                 {
 572                         LOG_INFO("Error: can't spawn a jump waypoint over an existent waypoint of a different type\n");
 573                         return;
 574                 }
 575                 e = waypoint_spawn(org, org, WAYPOINTFLAG_JUMP | WAYPOINTFLAG_NORELINK);
 576                 if (!pl.wp_locked)
 577                         pl.wp_locked = e;
 578         }
 579         else
 580                 e = waypoint_spawn(org, org, (is_crouch_wp) ? WAYPOINTFLAG_CROUCH : 0);
 581         if(!e)
 582         {
 583                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 584                 if (start_wp_is_spawned)
 585                         waypoint_clear_start_wp(pl, true);
 586                 return;
 587         }
 588
 589         if (!initial_origin_is_set)
 590         {
 591                 initial_origin = e.origin;
 592                 initial_origin_is_set = true;
 593         }
 594
 595         entity start_wp = NULL;
 596         if (start_wp_is_spawned)
 597         {
 598                 IL_EACH(g_waypoints, (start_wp_is_hardwired || it.wpflags & WAYPOINTFLAG_NORELINK)
 599                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 600                 {
 601                         start_wp = it; break;
 602                 });
 603                 if(!start_wp)
 604                 {
 605                         // should not happen
 606                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 607                         waypoint_clear_start_wp(pl, true);
 608                         return;
 609                 }
 610                 if (start_wp_is_hardwired)
 611                 {
 612                         if (waypoint_is_hardwiredlink(start_wp, e))
 613                         {
 614                                 waypoint_unmark_hardwiredlink(start_wp, e);
 615                                 waypoint_removelink(start_wp, e);
 616                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 617                                 LOG_INFOF("^x80fRemoved hardwired link %s.\n", s);
 618                         }
 619                         else
 620                         {
 621                                 if (e.createdtime == time)
 622                                 {
 623                                         LOG_INFO("Error: hardwired links can be created only between 2 existing (and unconnected) waypoints.\n");
 624                                         waypoint_remove(e);
 625                                         waypoint_clear_start_wp(pl, true);
 626                                         waypoint_spawn_fromeditor(pl, at_crosshair, is_jump_wp, is_crouch_wp);
 627                                         return;
 628                                 }
 629                                 if (start_wp == e)
 630                                 {
 631                                         LOG_INFO("Error: start and destination waypoints coincide.\n");
 632                                         waypoint_clear_start_wp(pl, true);
 633                                         return;
 634                                 }
 635                                 if (waypoint_islinked(start_wp, e))
 636                                 {
 637                                         LOG_INFO("Error: waypoints are already linked.\n");
 638                                         waypoint_clear_start_wp(pl, true);
 639                                         return;
 640                                 }
 641                                 waypoint_addlink(start_wp, e);
 642                                 waypoint_mark_hardwiredlink(start_wp, e);
 643                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 644                                 LOG_INFOF("^x80fAdded hardwired link %s.\n", s);
 645                         }
 646                 }
 647                 else
 648                         waypoint_addlink(start_wp, e);
 649         }
 650
 651         if (!(jp || is_jump_wp || start_wp_is_hardwired))
 652                 waypoint_schedulerelink(e);
 653         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 654
 655         if (start_wp_is_spawned)
 656         {
 657                 pl.wp_locked = NULL;
 658                 if (!start_wp_is_hardwired)
 659                         waypoint_schedulerelink(start_wp);
 660                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 661                 {
 662                         if (start_wp.wp00_original == start_wp.wp00)
 663                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 664                         else
 665                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 666                 }
 667         }
 668
 669         if (sym)
 670         {
 671                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 672                 if (jp)
 673                 {
 674                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 675                         {
 676                                 jp = it; break;
 677                         });
 678                 }
 679                 if (start_wp_is_spawned)
 680                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 681                 if (vdist(org - pl.origin, >, 32))
 682                 {
 683                         if(wp_num > 2)
 684                                 wp_num--;
 685                         else
 686                                 sym = false;
 687                         goto add_wp;
 688                 }
 689         }
 690         if (jp || is_jump_wp)
 691         {
 692                 if (!start_wp_is_spawned)
 693                 {
 694                         // we've just created a custom jumppad waypoint
 695                         // the next one created by the user will be the destination waypoint
 696                         start_wp_is_spawned = true;
 697                         start_wp_origin = initial_origin;
 698                 }
 699         }
 700         else if (start_wp_is_spawned)
 701         {
 702                 waypoint_clear_start_wp(pl, false);
 703         }
 704 }
 705
 706 void waypoint_remove(entity wp)
 707 {
 708         IL_EACH(g_waypoints, it != wp,
 709         {
 710                 if (waypoint_islinked(it, wp))
 711                 {
 712                         if (waypoint_is_hardwiredlink(it, wp))
 713                                 waypoint_unmark_hardwiredlink(it, wp);
 714                         waypoint_removelink(it, wp);
 715                 }
 716         });
 717         delete(wp);
 718 }
 719
 720 void waypoint_remove_fromeditor(entity pl)
 721 {
 722         if (WAYPOINT_VERSION < waypoint_version_loaded)
 723         {
 724                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 725                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 726                 return;
 727         }
 728
 729         entity e = navigation_findnearestwaypoint(pl, false);
 730
 731         int ctf_flags = havocbot_symmetry_origin_order;
 732         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 733                    || (autocvar_g_waypointeditor_symmetrical < 0));
 734         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 735                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 736         if (sym && ctf_flags < 2)
 737                 ctf_flags = 2;
 738         int wp_num = ctf_flags;
 739
 740         LABEL(remove_wp);
 741         if (!e) return;
 742
 743         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 744         {
 745                 if (start_wp_is_spawned)
 746                         waypoint_clear_start_wp(pl, true);
 747                 return;
 748         }
 749
 750         if (waypoint_has_hardwiredlinks(e))
 751         {
 752                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 753                 return;
 754         }
 755
 756         entity wp_sym = NULL;
 757         if (sym)
 758         {
 759                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 760                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 761                         if(vdist(org - it.origin, <, 3))
 762                         {
 763                                 wp_sym = it;
 764                                 break;
 765                         }
 766                 });
 767         }
 768
 769         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 770         waypoint_remove(e);
 771
 772         if (sym && wp_sym)
 773         {
 774                 e = wp_sym;
 775                 if(wp_num > 2)
 776                         wp_num--;
 777                 else
 778                         sym = false;
 779                 goto remove_wp;
 780         }
 781
 782         if (start_wp_is_spawned)
 783                 waypoint_clear_start_wp(pl, true);
 784 }
 785
 786 void waypoint_removelink(entity from, entity to)
 787 {
 788         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK && !(from.wpflags & WAYPOINTFLAG_JUMP)))
 789                 return;
 790
 791         entity fromwp31_prev = from.wp31;
 792
 793         switch (waypoint_getlinknum(from, to))
 794         {
 795                 // fallthrough all the way
 796                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 797                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 798                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 799                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 800                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 801                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 802                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 803                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 804                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 805                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 806                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 807                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 808                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 809                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 810                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 811                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 812                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 813                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 814                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 815                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 816                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 817                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 818                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 819                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 820                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 821                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 822                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 823                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 824                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 825                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 826                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 827                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 828         }
 829
 830         if (fromwp31_prev && !from.wp31)
 831                 waypoint_schedulerelink(from);
 832 }
 833
 834 int waypoint_getlinknum(entity from, entity to)
 835 {
 836         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 837         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 838         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 839         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 840         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 841         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 842         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 843         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 844         return -1;
 845 }
 846
 847 bool waypoint_islinked(entity from, entity to)
 848 {
 849         return (waypoint_getlinknum(from, to) >= 0);
 850 }
 851
 852 void waypoint_updatecost_foralllinks()
 853 {
 854         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 855         {
 856                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 857                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 858                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 859                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 860                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 861                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 862                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 863                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 864                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 865                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 866                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 867                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 868                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 869                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 870                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 871                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 872                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 873                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 874                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 875                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 876                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 877                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 878                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 879                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 880                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 881                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 882                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 883                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 884                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 885                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 886                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 887                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 888         });
 889 }
 890
 891 float waypoint_getlinearcost(float dist)
 892 {
 893         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 894                 return dist / (autocvar_sv_maxspeed * 1.25);
 895         return dist / autocvar_sv_maxspeed;
 896 }
 897
 898 float waypoint_getlinearcost_underwater(float dist)
 899 {
 900         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 901         return dist / (autocvar_sv_maxspeed * 0.7);
 902 }
 903
 904 float waypoint_getlinearcost_crouched(float dist)
 905 {
 906         return dist / (autocvar_sv_maxspeed * 0.5);
 907 }
 908
 909 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 910 {
 911         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 912         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 913
 914         if (submerged_from && submerged_to)
 915                 return waypoint_getlinearcost_underwater(vlen(to - from));
 916
 917         if (from_ent.wpflags & WAYPOINTFLAG_CROUCH && to_ent.wpflags & WAYPOINTFLAG_CROUCH)
 918                 return waypoint_getlinearcost_crouched(vlen(to - from));
 919
 920         float c = waypoint_getlinearcost(vlen(to - from));
 921
 922         float height = from.z - to.z;
 923         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 924         {
 925                 float height_cost; // fall cost
 926                 if (boolean(from_ent.wpflags & WAYPOINTFLAG_JUMP))
 927                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
 928                 else
 929                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 930                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 931                 if(height_cost > c)
 932                         c = height_cost;
 933         }
 934
 935         // consider half path underwater
 936         if (submerged_from || submerged_to)
 937                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 938
 939         // consider half path crouched
 940         if (from_ent.wpflags & WAYPOINTFLAG_CROUCH || to_ent.wpflags & WAYPOINTFLAG_CROUCH)
 941                 return (c + waypoint_getlinearcost_crouched(vlen(to - from))) / 2;
 942
 943         return c;
 944 }
 945
 946 float waypoint_getlinkcost(entity from, entity to)
 947 {
 948         vector v1 = from.origin;
 949         vector v2 = to.origin;
 950         if (from.wpisbox)
 951         {
 952                 vector m1 = from.absmin, m2 = from.absmax;
 953                 v1.x = bound(m1.x, v2.x, m2.x);
 954                 v1.y = bound(m1.y, v2.y, m2.y);
 955                 v1.z = bound(m1.z, v2.z, m2.z);
 956         }
 957         if (to.wpisbox)
 958         {
 959                 vector m1 = to.absmin, m2 = to.absmax;
 960                 v2.x = bound(m1.x, v1.x, m2.x);
 961                 v2.y = bound(m1.y, v1.y, m2.y);
 962                 v2.z = bound(m1.z, v1.z, m2.z);
 963         }
 964         return waypoint_gettravelcost(v1, v2, from, to);
 965 }
 966
 967 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 968 // if c == -1 automatically determine cost of the link
 969 void waypoint_addlink_customcost(entity from, entity to, float c)
 970 {
 971         if (from == to || waypoint_islinked(from, to))
 972                 return;
 973         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & WAYPOINTFLAG_JUMP))
 974                 return;
 975
 976         if(c == -1)
 977                 c = waypoint_getlinkcost(from, to);
 978
 979         if (from.wp31mincost < c) return;
 980         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 981         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 982         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 983         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 984         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 985         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 986         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 987         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 988         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 989         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 990         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 991         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 992         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 993         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 994         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 995         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 996         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 997         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 998         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 999         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
1000         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
1001         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
1002         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
1003         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
1004         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
1005         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
1006         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
1007         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
1008         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
1009         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
1010         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
1011         from.wp00 = to;from.wp00mincost = c;return;
1012 }
1013
1014 void waypoint_addlink(entity from, entity to)
1015 {
1016         if ((from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP)))
1017                 waypoint_addlink_for_custom_jumppad(from, to);
1018         else
1019                 waypoint_addlink_customcost(from, to, -1);
1020 }
1021
1022 // relink this spawnfunc_waypoint
1023 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
1024 // (SLOW!)
1025 void waypoint_think(entity this)
1026 {
1027         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
1028         float sv2_height = 0, ev2_height = 0;
1029
1030         bot_calculate_stepheightvec();
1031
1032         int dphitcontentsmask_save = this.dphitcontentsmask;
1033         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1034
1035         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
1036
1037         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
1038         IL_EACH(g_waypoints, this != it,
1039         {
1040                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
1041                 {
1042                         waypoint_addlink(this, it);
1043                         waypoint_addlink(it, this);
1044                 }
1045                 else
1046                 {
1047                         ++relink_total;
1048                         if(!checkpvs(this.origin, it))
1049                         {
1050                                 ++relink_pvsculled;
1051                                 continue;
1052                         }
1053
1054                         sv = set_tracewalk_dest_2(this, it.origin);
1055                         sv2 = tracewalk_dest;
1056                         sv2_height = tracewalk_dest_height;
1057                         ev = set_tracewalk_dest_2(it, this.origin);
1058                         ev2 = tracewalk_dest;
1059                         ev2_height = tracewalk_dest_height;
1060
1061                         dv = ev - sv;
1062                         dv.z = 0;
1063                         int maxdist = 1050;
1064                         vector m1 = PL_MIN_CONST;
1065                         vector m2 = PL_MAX_CONST;
1066
1067                         if (this.wpflags & WAYPOINTFLAG_CROUCH || it.wpflags & WAYPOINTFLAG_CROUCH)
1068                         {
1069                                 m1 = PL_CROUCH_MIN_CONST;
1070                                 m2 = PL_CROUCH_MAX_CONST;
1071                                 // links from crouch wp to normal wp (and viceversa) are very short to avoid creating many links
1072                                 // that would be wasted due to rough travel cost calculation (the longer link is, the higher cost is)
1073                                 // links from crouch wp to crouch wp can be as long as normal links
1074                                 if (!(this.wpflags & WAYPOINTFLAG_CROUCH && it.wpflags & WAYPOINTFLAG_CROUCH))
1075                                         maxdist = 100;
1076                         }
1077
1078                         if (vdist(dv, >=, maxdist)) // max search distance in XY
1079                         {
1080                                 ++relink_lengthculled;
1081                                 continue;
1082                         }
1083
1084                         navigation_testtracewalk = 0;
1085
1086                         //traceline(this.origin, it.origin, false, NULL);
1087                         //if (trace_fraction == 1)
1088                         if (this.wpisbox || this.wpflags & WAYPOINTFLAG_JUMP)
1089                                 relink_walkculled += 0.5;
1090                         else
1091                         {
1092                                 if (tracewalk(this, sv, m1, m2, ev2, ev2_height, MOVE_NOMONSTERS))
1093                                         waypoint_addlink(this, it);
1094                                 else
1095                                         relink_walkculled += 0.5;
1096                         }
1097
1098                         if (it.wpisbox || it.wpflags & WAYPOINTFLAG_JUMP)
1099                                 relink_walkculled += 0.5;
1100                         else
1101                         {
1102                                 if (tracewalk(this, ev, m1, m2, sv2, sv2_height, MOVE_NOMONSTERS))
1103                                         waypoint_addlink(it, this);
1104                                 else
1105                                         relink_walkculled += 0.5;
1106                         }
1107                 }
1108         });
1109         navigation_testtracewalk = 0;
1110         this.wplinked = true;
1111         this.dphitcontentsmask = dphitcontentsmask_save;
1112
1113         setthink(this, func_null);
1114         this.nextthink = 0;
1115 }
1116
1117 void waypoint_clearlinks(entity wp)
1118 {
1119         // clear links to other waypoints
1120         float f = 10000000;
1121         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1122         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1123         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1124         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1125
1126         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1127         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1128         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1129         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1130
1131         wp.wplinked = false;
1132 }
1133
1134 // tell a spawnfunc_waypoint to relink
1135 void waypoint_schedulerelink(entity wp)
1136 {
1137         if (wp == NULL)
1138                 return;
1139
1140         waypoint_setupmodel(wp);
1141         wp.wpisbox = vdist(wp.size, >, 0);
1142         wp.enemy = NULL;
1143         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1144                 wp.owner = NULL;
1145         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
1146                 waypoint_clearlinks(wp);
1147         // schedule an actual relink on next frame
1148         setthink(wp, waypoint_think);
1149         wp.nextthink = time;
1150         wp.effects = EF_LOWPRECISION;
1151 }
1152
1153 // spawnfunc_waypoint map entity
1154 spawnfunc(waypoint)
1155 {
1156         IL_PUSH(g_waypoints, this);
1157
1158         setorigin(this, this.origin);
1159         // schedule a relink after other waypoints have had a chance to spawn
1160         waypoint_clearlinks(this);
1161         //waypoint_schedulerelink(this);
1162 }
1163
1164 // tell all waypoints to relink
1165 // actually this is useful only to update relink_* stats
1166 void waypoint_schedulerelinkall()
1167 {
1168         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1169         IL_EACH(g_waypoints, true,
1170         {
1171                 waypoint_schedulerelink(it);
1172         });
1173         waypoint_load_hardwiredlinks();
1174 }
1175
1176 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1177
1178 // Load waypoint links from file
1179 bool waypoint_load_links()
1180 {
1181         string s;
1182         float file, tokens, c = 0, found;
1183         entity wp_from = NULL, wp_to;
1184         vector wp_to_pos, wp_from_pos;
1185
1186         string gt_ext = GET_GAMETYPE_EXTENSION();
1187
1188         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1189         file = fopen(filename, FILE_READ);
1190
1191         if (gt_ext != "" && file < 0)
1192         {
1193                 // if race waypoint file doesn't exist load the default one
1194                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1195                 file = fopen(filename, FILE_READ);
1196         }
1197
1198         if (file < 0)
1199         {
1200                 LOG_TRACE("waypoint links load from ", filename, " failed");
1201                 waypoint_schedulerelinkall();
1202                 return false;
1203         }
1204
1205         bool parse_comments = true;
1206         float ver = 0;
1207         string links_time = string_null;
1208
1209         while ((s = fgets(file)))
1210         {
1211                 if(parse_comments)
1212                 {
1213                         if(substring(s, 0, 2) == "//")
1214                         {
1215                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1216                                         ver = stof(substring(s, 19, -1));
1217                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1218                                         links_time = substring(s, 16, -1);
1219                                 continue;
1220                         }
1221                         else
1222                         {
1223                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1224                                 {
1225                                         if (links_time != waypoint_time)
1226                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1227                                         else
1228                                                 LOG_TRACE("waypoint links for this map are outdated.");
1229                                         if (g_assault)
1230                                         {
1231                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1232                                         }
1233                                         else
1234                                         {
1235                                                 LOG_TRACE("automatically updating...");
1236                                                 waypoint_schedulerelinkall();
1237                                                 fclose(file);
1238                                                 return false;
1239                                         }
1240                                 }
1241                                 parse_comments = false;
1242                         }
1243                 }
1244
1245                 tokens = tokenizebyseparator(s, "*");
1246
1247                 if (tokens!=2)
1248                 {
1249                         // bad file format
1250                         fclose(file);
1251                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1252                         return false;
1253                 }
1254
1255                 wp_from_pos     = stov(argv(0));
1256                 wp_to_pos       = stov(argv(1));
1257
1258                 // Search "from" waypoint
1259                 if(!wp_from || wp_from.origin!=wp_from_pos)
1260                 {
1261                         wp_from = findradius(wp_from_pos, 1);
1262                         found = false;
1263                         while(wp_from)
1264                         {
1265                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1266                                 if(wp_from.classname == "waypoint")
1267                                 {
1268                                         found = true;
1269                                         break;
1270                                 }
1271                                 wp_from = wp_from.chain;
1272                         }
1273
1274                         if(!found)
1275                         {
1276                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1277                                 continue;
1278                         }
1279                 }
1280
1281                 // Search "to" waypoint
1282                 wp_to = findradius(wp_to_pos, 1);
1283                 found = false;
1284                 while(wp_to)
1285                 {
1286                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1287                         if(wp_to.classname == "waypoint")
1288                         {
1289                                 found = true;
1290                                 break;
1291                         }
1292                         wp_to = wp_to.chain;
1293                 }
1294
1295                 if(!found)
1296                 {
1297                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1298                         continue;
1299                 }
1300
1301                 ++c;
1302                 waypoint_addlink(wp_from, wp_to);
1303                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1304                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1305         }
1306
1307         fclose(file);
1308
1309         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1310
1311         bool scheduled = false;
1312         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1313         {
1314                 if (!it.wp00)
1315                 {
1316                         waypoint_schedulerelink(it);
1317                         scheduled = true;
1318                 }
1319         });
1320         if (scheduled)
1321                 return false;
1322
1323         botframe_cachedwaypointlinks = true;
1324         return true;
1325 }
1326
1327 void waypoint_load_hardwiredlinks()
1328 {
1329         string s;
1330         float file, tokens, c = 0, found;
1331         entity wp_from = NULL, wp_to;
1332         vector wp_to_pos, wp_from_pos;
1333
1334         string gt_ext = GET_GAMETYPE_EXTENSION();
1335
1336         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1337         file = fopen(filename, FILE_READ);
1338
1339         if (gt_ext != "" && file < 0)
1340         {
1341                 // if race waypoint file doesn't exist load the default one
1342                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1343                 file = fopen(filename, FILE_READ);
1344         }
1345
1346         botframe_loadedforcedlinks = true;
1347
1348         if (file < 0)
1349         {
1350                 LOG_TRACE("waypoint links load from ", filename, " failed");
1351                 return;
1352         }
1353
1354         bool is_special = false;
1355         while ((s = fgets(file)))
1356         {
1357                 if(substring(s, 0, 2)=="//")
1358                         continue;
1359
1360                 if(substring(s, 0, 1)=="#")
1361                         continue;
1362
1363                 // special links start with *, so old xonotic versions don't load them
1364                 is_special = false;
1365                 if (substring(s, 0, 1) == "*")
1366                 {
1367                         is_special = true;
1368                         s = substring(s, 1, -1);
1369                 }
1370
1371                 tokens = tokenizebyseparator(s, "*");
1372
1373                 if (tokens!=2)
1374                         continue;
1375
1376                 wp_from_pos     = stov(argv(0));
1377                 wp_to_pos       = stov(argv(1));
1378
1379                 // Search "from" waypoint
1380                 if(!wp_from || wp_from.origin!=wp_from_pos)
1381                 {
1382                         wp_from = findradius(wp_from_pos, 5);
1383                         found = false;
1384                         while(wp_from)
1385                         {
1386                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1387                                 if(wp_from.classname == "waypoint")
1388                                 {
1389                                         found = true;
1390                                         break;
1391                                 }
1392                                 wp_from = wp_from.chain;
1393                         }
1394
1395                         if(!found)
1396                         {
1397                                 LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1398                                 continue;
1399                         }
1400                 }
1401
1402                 // Search "to" waypoint
1403                 wp_to = findradius(wp_to_pos, 5);
1404                 found = false;
1405                 while(wp_to)
1406                 {
1407                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1408                         if(wp_to.classname == "waypoint")
1409                         {
1410                                 found = true;
1411                                 break;
1412                         }
1413                         wp_to = wp_to.chain;
1414                 }
1415
1416                 if(!found)
1417                 {
1418                         LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1419                         continue;
1420                 }
1421
1422                 ++c;
1423
1424                 if (!is_special)
1425                 {
1426                         waypoint_addlink(wp_from, wp_to);
1427                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1428                 } else if (wp_from.wpflags & WAYPOINTFLAG_NORELINK
1429                         && (wp_from.wpflags & WAYPOINTFLAG_JUMP || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1430                 {
1431                         waypoint_addlink(wp_from, wp_to);
1432                 }
1433         }
1434
1435         fclose(file);
1436
1437         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1438 }
1439
1440 entity waypoint_get_link(entity w, float i)
1441 {
1442         switch(i)
1443         {
1444                 case  0:return w.wp00;
1445                 case  1:return w.wp01;
1446                 case  2:return w.wp02;
1447                 case  3:return w.wp03;
1448                 case  4:return w.wp04;
1449                 case  5:return w.wp05;
1450                 case  6:return w.wp06;
1451                 case  7:return w.wp07;
1452                 case  8:return w.wp08;
1453                 case  9:return w.wp09;
1454                 case 10:return w.wp10;
1455                 case 11:return w.wp11;
1456                 case 12:return w.wp12;
1457                 case 13:return w.wp13;
1458                 case 14:return w.wp14;
1459                 case 15:return w.wp15;
1460                 case 16:return w.wp16;
1461                 case 17:return w.wp17;
1462                 case 18:return w.wp18;
1463                 case 19:return w.wp19;
1464                 case 20:return w.wp20;
1465                 case 21:return w.wp21;
1466                 case 22:return w.wp22;
1467                 case 23:return w.wp23;
1468                 case 24:return w.wp24;
1469                 case 25:return w.wp25;
1470                 case 26:return w.wp26;
1471                 case 27:return w.wp27;
1472                 case 28:return w.wp28;
1473                 case 29:return w.wp29;
1474                 case 30:return w.wp30;
1475                 case 31:return w.wp31;
1476                 default:return NULL;
1477         }
1478 }
1479
1480 // Save all hardwired waypoint links to a file
1481 void waypoint_save_hardwiredlinks()
1482 {
1483         string gt_ext = GET_GAMETYPE_EXTENSION();
1484
1485         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1486         int file = fopen(filename, FILE_WRITE);
1487         if (file < 0)
1488         {
1489                 LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1490                 return;
1491         }
1492
1493         // write hardwired links to file
1494         int count = 0;
1495         fputs(file, "// HARDWIRED LINKS\n");
1496         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1497         {
1498                 for (int j = 0; j < 32; ++j)
1499                 {
1500                         entity link = waypoint_get_link(it, j);
1501                         if (waypoint_is_hardwiredlink(it, link))
1502                         {
1503                                 // NOTE: vtos rounds vector components to 1 decimal place
1504                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1505                                 fputs(file, s);
1506                                 ++count;
1507                         }
1508                 }
1509         });
1510
1511         // write special links to file
1512         int count2 = 0;
1513         fputs(file, "\n// SPECIAL LINKS\n");
1514         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP),
1515         {
1516                 for (int j = 0; j < 32; ++j)
1517                 {
1518                         entity link = waypoint_get_link(it, j);
1519                         if (link)
1520                         {
1521                                 // NOTE: vtos rounds vector components to 1 decimal place
1522                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin), "\n");
1523                                 fputs(file, s);
1524                                 ++count2;
1525                         }
1526                 }
1527         });
1528
1529         fclose(file);
1530
1531         LOG_INFOF("saved %d hardwired links and %d special links to %s", count, count2, filename);
1532 }
1533
1534 // Save all waypoint links to a file
1535 void waypoint_save_links()
1536 {
1537         string gt_ext = GET_GAMETYPE_EXTENSION();
1538
1539         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1540         int file = fopen(filename, FILE_WRITE);
1541         if (file < 0)
1542         {
1543                 LOG_INFOF("waypoint link save to %s failed", filename);
1544                 return;
1545         }
1546
1547         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1548         if (waypoint_time != "")
1549                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1550
1551         int c = 0;
1552         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP)),
1553         {
1554                 for(int j = 0; j < 32; ++j)
1555                 {
1556                         entity link = waypoint_get_link(it, j);
1557                         if (link && !waypoint_is_hardwiredlink(it, link))
1558                         {
1559                                 // NOTE: vtos rounds vector components to 1 decimal place
1560                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1561                                 fputs(file, s);
1562                                 ++c;
1563                         }
1564                 }
1565         });
1566         fclose(file);
1567
1568         botframe_cachedwaypointlinks = true;
1569
1570         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1571 }
1572
1573 // save waypoints to gamedir/data/maps/mapname.waypoints
1574 void waypoint_saveall()
1575 {
1576         if (WAYPOINT_VERSION < waypoint_version_loaded)
1577         {
1578                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1579                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1580                 return;
1581         }
1582         string gt_ext = GET_GAMETYPE_EXTENSION();
1583
1584         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1585         int file = fopen(filename, FILE_WRITE);
1586         if (file < 0)
1587         {
1588                 waypoint_save_links(); // save anyway?
1589                 botframe_loadedforcedlinks = false;
1590
1591                 LOG_INFOF("waypoint links: save to %s failed", filename);
1592                 return;
1593         }
1594
1595         float sym = autocvar_g_waypointeditor_symmetrical;
1596         string sym_str = ftos(sym);
1597         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1598         {
1599                 if (sym == 1)
1600                 {
1601                         sym_str = cons(sym_str, "-");
1602                         sym_str = cons(sym_str, "-");
1603                 }
1604                 else
1605                 {
1606                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1607                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1608                 }
1609                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1610                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1611         }
1612         else if (autocvar_g_waypointeditor_symmetrical == -2)
1613         {
1614                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1615                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1616         }
1617
1618         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1619         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1620         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1621         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1622
1623         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1624         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1625         //fputs(file, strcat("//", "\n"));
1626         //fputs(file, strcat("//", "\n"));
1627         //fputs(file, strcat("//", "\n"));
1628
1629         int c = 0;
1630         IL_EACH(g_waypoints, true,
1631         {
1632                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1633                         continue;
1634
1635                 string s;
1636                 // NOTE: vtos rounds vector components to 1 decimal place
1637                 s = strcat(vtos(it.origin + it.mins), "\n");
1638                 s = strcat(s, vtos(it.origin + it.maxs));
1639                 s = strcat(s, "\n");
1640                 s = strcat(s, ftos(it.wpflags));
1641                 s = strcat(s, "\n");
1642                 fputs(file, s);
1643                 c++;
1644         });
1645         fclose(file);
1646         waypoint_save_links();
1647         waypoint_save_hardwiredlinks();
1648
1649         botframe_loadedforcedlinks = false;
1650
1651         waypoint_version_loaded = WAYPOINT_VERSION;
1652         LOG_INFOF("saved %d waypoints to %s", c, filename);
1653 }
1654
1655 // load waypoints from file
1656 float waypoint_loadall()
1657 {
1658         string s;
1659         float file, cwp, cwb, fl;
1660         vector m1, m2;
1661         cwp = 0;
1662         cwb = 0;
1663
1664         string gt_ext = GET_GAMETYPE_EXTENSION();
1665
1666         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1667         file = fopen(filename, FILE_READ);
1668
1669         if (gt_ext != "" && file < 0)
1670         {
1671                 // if race waypoint file doesn't exist load the default one
1672                 filename = sprintf("maps/%s.waypoints", mapname);
1673                 file = fopen(filename, FILE_READ);
1674         }
1675
1676         if (file < 0)
1677         {
1678                 LOG_TRACE("waypoint load from ", filename, " failed");
1679                 return 0;
1680         }
1681
1682         bool parse_comments = true;
1683         float ver = 0;
1684         float sym = 0;
1685         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1686
1687         while ((s = fgets(file)))
1688         {
1689                 if(parse_comments)
1690                 {
1691                         if(substring(s, 0, 2) == "//")
1692                         {
1693                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1694                                         ver = stof(substring(s, 19, -1));
1695                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1696                                 {
1697                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1698                                         if (tokens) { sym = stof(argv(0)); }
1699                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1700                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1701                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1702                                 }
1703                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1704                                         strcpy(waypoint_time, substring(s, 16, -1));
1705                                 continue;
1706                         }
1707                         else
1708                         {
1709                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1710                                 {
1711                                         LOG_TRACE("waypoints for this map are outdated");
1712                                         LOG_TRACE("please update them in the editor");
1713                                 }
1714                                 parse_comments = false;
1715                         }
1716                 }
1717                 m1 = stov(s);
1718                 s = fgets(file);
1719                 if (!s)
1720                         break;
1721                 m2 = stov(s);
1722                 s = fgets(file);
1723                 if (!s)
1724                         break;
1725                 fl = stof(s);
1726                 waypoint_spawn(m1, m2, fl);
1727                 if (m1 == m2)
1728                         cwp = cwp + 1;
1729                 else
1730                         cwb = cwb + 1;
1731         }
1732         fclose(file);
1733         waypoint_version_loaded = ver;
1734         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1735
1736         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1737         {
1738                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1739                 if (sym == 1 && sym_param3 < 2)
1740                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1741                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1742                 {
1743                         string params;
1744                         if (sym == 1)
1745                                 params = cons("-", "-");
1746                         else
1747                         {
1748                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1749                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1750                         }
1751                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1752                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1753                 }
1754                 else if (sym == -2)
1755                 {
1756                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1757                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1758                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1759                 }
1760                 else
1761                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1762                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1763         }
1764
1765         if (WAYPOINT_VERSION < waypoint_version_loaded)
1766                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1767                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1768
1769         return cwp + cwb;
1770 }
1771
1772 #define waypoint_fixorigin(position, tracetest_ent) \
1773         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1774
1775 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1776 {
1777         vector endpos = position + down_dir * 3000;
1778         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1779         if(trace_startsolid)
1780                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1781         if(trace_startsolid)
1782                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1783         if(trace_fraction < 1)
1784                 position = trace_endpos;
1785         return position;
1786 }
1787
1788 void waypoint_spawnforitem_force(entity e, vector org)
1789 {
1790         // Fix the waypoint altitude if necessary
1791         org = waypoint_fixorigin(org, NULL);
1792
1793         // don't spawn an item spawnfunc_waypoint if it already exists
1794         IL_EACH(g_waypoints, true,
1795         {
1796                 if(it.wpisbox)
1797                 {
1798                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1799                         {
1800                                 e.nearestwaypoint = it;
1801                                 return;
1802                         }
1803                 }
1804                 else
1805                 {
1806                         if(vdist(it.origin - org, <, 16))
1807                         {
1808                                 e.nearestwaypoint = it;
1809                                 return;
1810                         }
1811                 }
1812         });
1813
1814         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1815 }
1816
1817 void waypoint_spawnforitem(entity e)
1818 {
1819         if(!bot_waypoints_for_items)
1820                 return;
1821
1822         waypoint_spawnforitem_force(e, e.origin);
1823 }
1824
1825 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1826 {
1827         entity w;
1828         entity dw;
1829         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1830         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1831         // one way link to the destination
1832         w.wp00_original = dw;
1833         w.wp00 = dw;
1834         w.wp00mincost = timetaken; // this is just for jump pads
1835         // the teleporter's nearest spawnfunc_waypoint is this one
1836         // (teleporters are not goals, so this is probably useless)
1837         e.nearestwaypoint = w;
1838         e.nearestwaypointtimeout = -1;
1839 }
1840
1841 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1842 {
1843         float src_angle = e.warpzone_angles.x;
1844         while (src_angle < -180) src_angle += 360;
1845         while (src_angle > 180) src_angle -= 360;
1846
1847         float dest_angle = e.enemy.warpzone_angles.x;
1848         while (dest_angle < -180) dest_angle += 360;
1849         while (dest_angle > 180) dest_angle -= 360;
1850
1851         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1852         if (src_angle == -90 || dest_angle == -90)
1853                 return;
1854
1855         makevectors(e.warpzone_angles);
1856         vector src = (e.absmin + e.absmax) * 0.5;
1857         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1858         vector down_dir_src = -v_up;
1859
1860         makevectors(e.enemy.warpzone_angles);
1861         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1862         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1863         vector down_dir_dest = -v_up;
1864
1865         int extra_flag = 0;
1866         // don't snap to the ground waypoints for source warpzones pointing downwards
1867         if (src_angle != 90)
1868         {
1869                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1870                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1871                 // oblique warpzones need a jump otherwise bots gets stuck
1872                 if (src_angle != 0)
1873                         extra_flag = WAYPOINTFLAG_JUMP;
1874         }
1875
1876         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1877 }
1878
1879 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1880 {
1881         destination = waypoint_fixorigin(destination, tracetest_ent);
1882         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1883 }
1884
1885 entity waypoint_spawnpersonal(entity this, vector position)
1886 {
1887         entity w;
1888
1889         // drop the waypoint to a proper location:
1890         //   first move it up by a player height
1891         //   then move it down to hit the floor with player bbox size
1892         position = waypoint_fixorigin(position, this);
1893
1894         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1895         w.nearestwaypoint = NULL;
1896         w.nearestwaypointtimeout = 0;
1897         w.owner = this;
1898
1899         waypoint_schedulerelink(w);
1900
1901         return w;
1902 }
1903
1904 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1905 {
1906         if (!(wp1 && wp2))
1907                 return;
1908
1909         if (waypoint_is_hardwiredlink(wp1, wp2))
1910                 te_beam(NULL, wp1.origin, wp2.origin);
1911         else if (display_type == 1)
1912                 te_lightning2(NULL, wp1.origin, wp2.origin);
1913 }
1914
1915 void waypoint_showlinks_to(entity wp, int display_type)
1916 {
1917         IL_EACH(g_waypoints, it != wp,
1918         {
1919                 if (waypoint_islinked(it, wp))
1920                         waypoint_showlink(it, wp, display_type);
1921         });
1922 }
1923
1924 void waypoint_showlinks_from(entity wp, int display_type)
1925 {
1926         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
1927         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
1928         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
1929         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
1930         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
1931         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
1932         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
1933         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
1934         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
1935         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
1936         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
1937         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
1938         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
1939         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
1940         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
1941         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
1942 }
1943
1944 void crosshair_trace_waypoints(entity pl)
1945 {
1946         IL_EACH(g_waypoints, true, {
1947                 it.solid = SOLID_BSP;
1948                 if (!it.wpisbox)
1949                         setsize(it, '-16 -16 -16', '16 16 16');
1950         });
1951
1952         crosshair_trace(pl);
1953
1954         IL_EACH(g_waypoints, true, {
1955                 it.solid = SOLID_TRIGGER;
1956                 if (!it.wpisbox)
1957                         setsize(it, '0 0 0', '0 0 0');
1958         });
1959         if (trace_ent.classname != "waypoint")
1960                 trace_ent = NULL;
1961 }
1962
1963 void botframe_showwaypointlinks()
1964 {
1965         if (time < botframe_waypointeditorlightningtime)
1966                 return;
1967         botframe_waypointeditorlightningtime = time + 0.5;
1968         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1969         {
1970                 int display_type = 0;
1971                 if (wasfreed(it.wp_aimed))
1972                         it.wp_aimed = NULL;
1973                 if (wasfreed(it.wp_locked))
1974                         it.wp_locked = NULL;
1975                 if (PHYS_INPUT_BUTTON_USE(it))
1976                         it.wp_locked = it.wp_aimed;
1977                 entity head = it.wp_locked;
1978                 if (!head)
1979                         head = navigation_findnearestwaypoint(it, false);
1980                 it.nearestwaypoint = head; // mainly useful for debug
1981                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1982                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
1983                         display_type = 1; // default
1984                 else if(waypoint_has_hardwiredlinks(head))
1985                         display_type = 2; // only hardwired
1986
1987                 if (display_type)
1988                 {
1989                         //navigation_testtracewalk = true;
1990                         //print("currently selected WP is ", etos(head), "\n");
1991                         //navigation_testtracewalk = false;
1992                         if (head)
1993                         {
1994                                 te_lightning2(NULL, head.origin, it.origin);
1995                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1996                                         waypoint_showlinks_to(head, display_type);
1997                                 else
1998                                         waypoint_showlinks_from(head, display_type);
1999                         }
2000                 }
2001                 string str;
2002                 entity wp = NULL;
2003                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
2004                 {
2005                         crosshair_trace_waypoints(it);
2006                         if (trace_ent)
2007                         {
2008                                 wp = trace_ent;
2009                                 if (wp != it.wp_aimed)
2010                                 {
2011                                         str = sprintf("\necho ^2WP info^7: entity: %d, flags: %d, origin: %s\n", etof(wp), wp.wpflags, vtos(wp.origin));
2012                                         if (wp.wpisbox)
2013                                                 str = strcat(str, sprintf("echo \" absmin: %s, absmax: %s\"\n", vtos(wp.absmin), vtos(wp.absmax)));
2014                                         stuffcmd(it, str);
2015                                         str = sprintf("entity: %d\nflags: %d\norigin: %s", etof(wp), wp.wpflags, vtos(wp.origin));
2016                                         if (wp.wpisbox)
2017                                                 str = strcat(str, sprintf(" \nabsmin: %s\nabsmax: %s", vtos(wp.absmin), vtos(wp.absmax)));
2018                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
2019                                 }
2020                         }
2021                 }
2022                 if (it.wp_aimed != wp)
2023                         it.wp_aimed = wp;
2024         });
2025 }
2026
2027 float botframe_autowaypoints_fixdown(vector v)
2028 {
2029         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
2030         if(trace_fraction >= 1)
2031                 return 0;
2032         return 1;
2033 }
2034
2035 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
2036 {
2037         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
2038         {
2039                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
2040                 return 0;
2041         });
2042
2043         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2044         return 1;
2045 }
2046
2047 // return value:
2048 //    1 = WP created
2049 //    0 = no action needed
2050 //   -1 = temp fail, try from world too
2051 //   -2 = permanent fail, do not retry
2052 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2053 {
2054         // make it possible to go from p to wp, if we can
2055         // if wp is NULL, nearest is chosen
2056
2057         entity w;
2058         vector porg;
2059         float t, tmin, tmax;
2060         vector o;
2061         vector save;
2062
2063         if(!botframe_autowaypoints_fixdown(p.origin))
2064                 return -2;
2065         porg = trace_endpos;
2066
2067         if(wp)
2068         {
2069                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2070
2071                 // if wp -> porg, then OK
2072                 float maxdist;
2073                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2074                 {
2075                         // we may find a better one
2076                         maxdist = vlen(wp.origin - porg);
2077                 }
2078                 else
2079                 {
2080                         // accept any "good"
2081                         maxdist = 2100;
2082                 }
2083
2084                 float bestdist = maxdist;
2085                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
2086                 {
2087                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2088                         if(d < bestdist)
2089                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2090                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2091                         {
2092                                 bestdist = d;
2093                                 p.(fld) = it;
2094                         }
2095                 });
2096                 if(bestdist < maxdist)
2097                 {
2098                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2099                         return 0;
2100                 }
2101
2102                 if(bestdist < 2100)
2103                 {
2104                         // we know maxdist < 2100
2105                         // so wp -> porg is still valid
2106                         // all is good
2107                         p.(fld) = wp;
2108                         return 0;
2109                 }
2110
2111                 // otherwise, no existing WP can fix our issues
2112         }
2113         else
2114         {
2115                 save = p.origin;
2116                 setorigin(p, porg);
2117                 w = navigation_findnearestwaypoint(p, walkfromwp);
2118                 setorigin(p, save);
2119                 if(w)
2120                 {
2121                         p.(fld) = w;
2122                         return 0;
2123                 }
2124         }
2125
2126         tmin = 0;
2127         tmax = 1;
2128         for (;;)
2129         {
2130                 if(tmax - tmin < 0.001)
2131                 {
2132                         // did not get a good candidate
2133                         return -1;
2134                 }
2135
2136                 t = (tmin + tmax) * 0.5;
2137                 o = antilag_takebackorigin(p, CS(p), time - t);
2138                 if(!botframe_autowaypoints_fixdown(o))
2139                         return -2;
2140                 o = trace_endpos;
2141
2142                 if(wp)
2143                 {
2144                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2145                         {
2146                                 // we cannot walk from wp.origin to o
2147                                 // get closer to tmax
2148                                 tmin = t;
2149                                 continue;
2150                         }
2151                 }
2152                 else
2153                 {
2154                         save = p.origin;
2155                         setorigin(p, o);
2156                         w = navigation_findnearestwaypoint(p, walkfromwp);
2157                         setorigin(p, save);
2158                         if(!w)
2159                         {
2160                                 // we cannot walk from any WP to o
2161                                 // get closer to tmax
2162                                 tmin = t;
2163                                 continue;
2164                         }
2165                 }
2166
2167                 // if we get here, o is valid regarding waypoints
2168                 // check if o is connected right to the player
2169                 // we break if it succeeds, as that means o is a good waypoint location
2170                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2171                         break;
2172
2173                 // o is no good, we need to get closer to the player
2174                 tmax = t;
2175         }
2176
2177         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2178         botframe_autowaypoints_createwp(o, p, fld, 0);
2179         return 1;
2180 }
2181
2182 // automatically create missing waypoints
2183 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
2184 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2185 {
2186         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2187         if(r != -1)
2188                 return;
2189         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2190         if(r != -1)
2191                 return;
2192
2193         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2194         if(!botframe_autowaypoints_fixdown(p.origin))
2195                 return; // shouldn't happen, caught above
2196         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2197 }
2198
2199 void botframe_deleteuselesswaypoints()
2200 {
2201         IL_EACH(g_items, it.bot_pickup,
2202         {
2203                 // NOTE: this protects waypoints if they're the ONLY nearest
2204                 // waypoint. That's the intention.
2205                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2206                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2207         });
2208         IL_EACH(g_waypoints, true,
2209         {
2210                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2211                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2212                 // WP is useful if:
2213                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2214                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2215                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2216                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2217                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2218                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2219                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2220                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2221                 // b) WP is closest WP for an item/spawnpoint/other entity
2222                 //    This has been done above by protecting these WPs.
2223         });
2224         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2225         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2226         {
2227                 for (int m = 0; m < 32; ++m)
2228                 {
2229                         entity w = waypoint_get_link(it, m);
2230                         if (!w)
2231                                 break;
2232                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2233                                 continue;
2234                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2235                                 continue;
2236                         for (int j = 0; j < 32; ++j)
2237                         {
2238                                 entity w2 = waypoint_get_link(w, j);
2239                                 if (!w2)
2240                                         break;
2241                                 if (it == w2)
2242                                         continue;
2243                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2244                                         continue;
2245                                 // If we got here, it != w2 exist with it -> w
2246                                 // and w -> w2. That means the waypoint is not
2247                                 // a dead end.
2248                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2249                                 for (int k = 0; k < 32; ++k)
2250                                 {
2251                                         if (waypoint_get_link(it, k) == w2)
2252                                                 continue;
2253                                         // IF WE GET HERE, w is proven useful
2254                                         // to get from it to w2!
2255                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2256                                         goto next;
2257                                 }
2258                         }
2259 LABEL(next)
2260                 }
2261         });
2262         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2263         //     they are needed to complete routes while autowaypointing.
2264
2265         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2266         {
2267                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2268                 te_explosion(it.origin);
2269                 waypoint_remove(it);
2270                 break;
2271         });
2272
2273         IL_EACH(g_waypoints, true,
2274         {
2275                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2276         });
2277 }
2278
2279 void botframe_autowaypoints()
2280 {
2281         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2282                 // going back is broken, so only fix waypoints to walk TO the player
2283                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2284                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2285                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2286         });
2287
2288         if (autocvar_g_waypointeditor_auto >= 2) {
2289                 botframe_deleteuselesswaypoints();
2290         }
2291 }
2292