qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 bool waypoint_has_hardwiredlinks(entity wp)
 264 {
 265         if (!wp)
 266                 return false;
 267         return (wp.wphw00 != NULL);
 268 }
 269
 270 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 271 {
 272         if (!(wp_from && wp_to))
 273                 return false;
 274
 275         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 276         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 277         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 278         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 279         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 280         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 281         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 282         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 283
 284         return false;
 285 }
 286
 287 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 288 {
 289         if (!(wp_from && wp_to))
 290                 return;
 291
 292         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; return; }
 293         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 294         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 295         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 296         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 297         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 298         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 299         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 300
 301         return;
 302 }
 303
 304 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 305 {
 306         if (!(wp_from && wp_to))
 307                 return;
 308
 309         int removed = -1;
 310         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 311         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 312         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 313         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 314         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 315         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 316         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 317         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 318
 319         if (removed >= 0)
 320         {
 321                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 322                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 323                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 324                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 325                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 326                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 327                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 328         }
 329
 330         return;
 331 }
 332
 333 void waypoint_setupmodel(entity wp)
 334 {
 335         if (autocvar_g_waypointeditor)
 336         {
 337                 // TODO: add some sort of visible box in edit mode for box waypoints
 338                 vector m1 = wp.mins;
 339                 vector m2 = wp.maxs;
 340                 setmodel(wp, MDL_WAYPOINT);
 341                 setsize(wp, m1, m2);
 342                 wp.effects = EF_LOWPRECISION;
 343                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 344                         wp.colormod = '1 0 0';
 345                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 346                         wp.colormod = '1 1 0';
 347                 else if (wp.wpflags & WAYPOINTFLAG_NORELINK)
 348                         wp.colormod = '1 0.5 0'; // orange
 349                 else if (waypoint_has_hardwiredlinks(wp))
 350                         wp.colormod = '0.5 0 1'; // violet
 351                 else
 352                         wp.colormod = '1 1 1';
 353         }
 354         else
 355                 wp.model = "";
 356 }
 357
 358 entity waypoint_get(vector m1, vector m2)
 359 {
 360         if (m1 == m2)
 361         {
 362                 m1 -= '8 8 8';
 363                 m2 += '8 8 8';
 364         }
 365         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 366
 367         return NULL;
 368 }
 369
 370 entity waypoint_spawn(vector m1, vector m2, float f)
 371 {
 372         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 373         {
 374                 entity wp_found = waypoint_get(m1, m2);
 375                 if (wp_found)
 376                         return wp_found;
 377         }
 378         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 379         // otherwise links loaded from file would be applied only to the first destination
 380         // waypoint since link format doesn't specify waypoint entities but just positions
 381         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WAYPOINTFLAG_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 382         {
 383                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 384                 {
 385                         return it;
 386                 });
 387         }
 388
 389         entity w = new(waypoint);
 390         IL_PUSH(g_waypoints, w);
 391         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 392         w.wpflags = f;
 393         w.solid = SOLID_TRIGGER;
 394         setorigin(w, (m1 + m2) * 0.5);
 395         setsize(w, m1 - w.origin, m2 - w.origin);
 396         if (w.size)
 397                 w.wpisbox = true;
 398
 399         if(!w.wpisbox)
 400         {
 401                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 402                 if(!move_out_of_solid(w))
 403                 {
 404                         if(!(f & WAYPOINTFLAG_GENERATED))
 405                         {
 406                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 407                                 delete(w);
 408                                 return NULL;
 409                         }
 410                         else
 411                         {
 412                                 if(autocvar_developer)
 413                                 {
 414                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 415                                         backtrace("Waypoint stuck");
 416                                 }
 417                         }
 418                 }
 419                 setsize(w, '0 0 0', '0 0 0');
 420         }
 421
 422         waypoint_clearlinks(w);
 423         //waypoint_schedulerelink(w);
 424
 425         waypoint_setupmodel(w);
 426
 427         return w;
 428 }
 429
 430 float trigger_push_get_push_time(entity this, vector endpos);
 431 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 432 {
 433         entity jp = NULL;
 434         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 435         {
 436                 jp = it;
 437                 break;
 438         });
 439         if (!jp)
 440                 return;
 441
 442         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 443         wp_from.wp00 = wp_to;
 444         wp_from.wp00mincost = cost;
 445         jp.nearestwaypoint = wp_from;
 446         jp.nearestwaypointtimeout = -1;
 447 }
 448
 449 bool start_wp_is_spawned;
 450 vector start_wp_origin;
 451
 452 void waypoint_clear_start_wp(entity pl, bool warn)
 453 {
 454         start_wp_is_spawned = false;
 455         start_wp_origin = '0 0 0';
 456         pl.wp_locked = NULL;
 457         if (warn)
 458                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 459 }
 460
 461 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp)
 462 {
 463         if (WAYPOINT_VERSION < waypoint_version_loaded)
 464         {
 465                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 466                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 467                 return;
 468         }
 469
 470         entity e = NULL, jp = NULL;
 471         vector org = pl.origin;
 472         if (at_crosshair)
 473         {
 474                 crosshair_trace(pl);
 475                 org = trace_endpos - eZ * PL_MIN_CONST.z;
 476                 IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 477                 {
 478                         jp = it;
 479                         break;
 480                 });
 481         }
 482         if (jp || is_jump_wp)
 483         {
 484                 if (start_wp_is_spawned)
 485                         start_wp_is_spawned = false;
 486                 LOG_INFO("^xf80Spawning start waypoint...\n");
 487         }
 488         int ctf_flags = havocbot_symmetry_origin_order;
 489         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 490                    || (autocvar_g_waypointeditor_symmetrical < 0));
 491         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 492                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 493         if (sym && ctf_flags < 2)
 494                 ctf_flags = 2;
 495         int wp_num = ctf_flags;
 496
 497         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp)
 498         {
 499                 // snap waypoint to item's origin if close enough
 500                 IL_EACH(g_items, true,
 501                 {
 502                         vector item_org = (it.absmin + it.absmax) * 0.5;
 503                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 504                         if (vlen(item_org - org) < 20)
 505                         {
 506                                 org = item_org;
 507                                 break;
 508                         }
 509                 });
 510         }
 511
 512         vector start_org = '0 0 0';
 513         if (start_wp_is_spawned)
 514         {
 515                 LOG_INFO("^xf80Spawning destination waypoint...\n");
 516                 start_org = start_wp_origin;
 517         }
 518
 519         // save org as it can be modified spawning symmetrycal waypoints
 520         vector initial_origin = '0 0 0';
 521         bool initial_origin_is_set = false;
 522
 523         LABEL(add_wp);
 524
 525         if (jp)
 526         {
 527                 e = NULL;
 528                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 529                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 530                 {
 531                         e = it; break;
 532                 });
 533                 if (!e)
 534                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 535                 if (!pl.wp_locked)
 536                         pl.wp_locked = e;
 537         }
 538         else if (is_jump_wp)
 539         {
 540                 entity wp_found = waypoint_get(org, org);
 541                 if (wp_found && !(wp_found.wpflags & WAYPOINTFLAG_JUMP))
 542                 {
 543                         LOG_INFO("Error: can't spawn a jump waypoint over an existent waypoint of a different type\n");
 544                         return;
 545                 }
 546                 e = waypoint_spawn(org, org, WAYPOINTFLAG_JUMP | WAYPOINTFLAG_NORELINK);
 547                 if (!pl.wp_locked)
 548                         pl.wp_locked = e;
 549         }
 550         else
 551                 e = waypoint_spawn(org, org, 0);
 552         if(!e)
 553         {
 554                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 555                 if (start_wp_is_spawned)
 556                         waypoint_clear_start_wp(pl, true);
 557                 return;
 558         }
 559
 560         if (!initial_origin_is_set)
 561         {
 562                 initial_origin = e.origin;
 563                 initial_origin_is_set = true;
 564         }
 565
 566         entity start_wp = NULL;
 567         if (start_wp_is_spawned)
 568         {
 569                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 570                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 571                 {
 572                         start_wp = it; break;
 573                 });
 574                 if(!start_wp)
 575                 {
 576                         // should not happen
 577                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 578                         waypoint_clear_start_wp(pl, true);
 579                         return;
 580                 }
 581                 waypoint_addlink(start_wp, e);
 582         }
 583
 584         if (!(jp || is_jump_wp))
 585                 waypoint_schedulerelink(e);
 586         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 587
 588         if (start_wp_is_spawned)
 589         {
 590                 pl.wp_locked = NULL;
 591                 waypoint_schedulerelink(start_wp);
 592                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 593                 {
 594                         if (start_wp.wp00_original == start_wp.wp00)
 595                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 596                         else
 597                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 598                 }
 599         }
 600
 601         if (sym)
 602         {
 603                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 604                 if (jp)
 605                 {
 606                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 607                         {
 608                                 jp = it; break;
 609                         });
 610                 }
 611                 if (start_wp_is_spawned)
 612                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 613                 if (vdist(org - pl.origin, >, 32))
 614                 {
 615                         if(wp_num > 2)
 616                                 wp_num--;
 617                         else
 618                                 sym = false;
 619                         goto add_wp;
 620                 }
 621         }
 622         if (jp || is_jump_wp)
 623         {
 624                 if (!start_wp_is_spawned)
 625                 {
 626                         // we've just created a custom jumppad waypoint
 627                         // the next one created by the user will be the destination waypoint
 628                         start_wp_is_spawned = true;
 629                         start_wp_origin = initial_origin;
 630                 }
 631         }
 632         else if (start_wp_is_spawned)
 633         {
 634                 waypoint_clear_start_wp(pl, false);
 635         }
 636 }
 637
 638 void waypoint_remove(entity wp)
 639 {
 640         IL_EACH(g_waypoints, it != wp,
 641         {
 642                 if (waypoint_islinked(it, wp))
 643                 {
 644                         if (waypoint_is_hardwiredlink(it, wp))
 645                                 waypoint_unmark_hardwiredlink(it, wp);
 646                         waypoint_removelink(it, wp);
 647                 }
 648         });
 649         delete(wp);
 650 }
 651
 652 void waypoint_remove_fromeditor(entity pl)
 653 {
 654         if (WAYPOINT_VERSION < waypoint_version_loaded)
 655         {
 656                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 657                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 658                 return;
 659         }
 660
 661         entity e = navigation_findnearestwaypoint(pl, false);
 662
 663         int ctf_flags = havocbot_symmetry_origin_order;
 664         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 665                    || (autocvar_g_waypointeditor_symmetrical < 0));
 666         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 667                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 668         if (sym && ctf_flags < 2)
 669                 ctf_flags = 2;
 670         int wp_num = ctf_flags;
 671
 672         LABEL(remove_wp);
 673         if (!e) return;
 674
 675         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 676         {
 677                 if (start_wp_is_spawned)
 678                         waypoint_clear_start_wp(pl, true);
 679                 return;
 680         }
 681
 682         if (waypoint_has_hardwiredlinks(e))
 683         {
 684                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 685                 return;
 686         }
 687
 688         entity wp_sym = NULL;
 689         if (sym)
 690         {
 691                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 692                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 693                         if(vdist(org - it.origin, <, 3))
 694                         {
 695                                 wp_sym = it;
 696                                 break;
 697                         }
 698                 });
 699         }
 700
 701         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 702         waypoint_remove(e);
 703
 704         if (sym && wp_sym)
 705         {
 706                 e = wp_sym;
 707                 if(wp_num > 2)
 708                         wp_num--;
 709                 else
 710                         sym = false;
 711                 goto remove_wp;
 712         }
 713
 714         if (start_wp_is_spawned)
 715                 waypoint_clear_start_wp(pl, true);
 716 }
 717
 718 void waypoint_removelink(entity from, entity to)
 719 {
 720         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK && !(from.wpflags & WAYPOINTFLAG_JUMP)))
 721                 return;
 722
 723         entity fromwp31_prev = from.wp31;
 724
 725         switch (waypoint_getlinknum(from, to))
 726         {
 727                 // fallthrough all the way
 728                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 729                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 730                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 731                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 732                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 733                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 734                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 735                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 736                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 737                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 738                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 739                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 740                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 741                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 742                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 743                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 744                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 745                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 746                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 747                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 748                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 749                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 750                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 751                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 752                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 753                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 754                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 755                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 756                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 757                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 758                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 759                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 760         }
 761
 762         if (fromwp31_prev && !from.wp31)
 763                 waypoint_schedulerelink(from);
 764 }
 765
 766 int waypoint_getlinknum(entity from, entity to)
 767 {
 768         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 769         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 770         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 771         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 772         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 773         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 774         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 775         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 776         return -1;
 777 }
 778
 779 bool waypoint_islinked(entity from, entity to)
 780 {
 781         return (waypoint_getlinknum(from, to) >= 0);
 782 }
 783
 784 void waypoint_updatecost_foralllinks()
 785 {
 786         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 787         {
 788                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 789                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 790                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 791                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 792                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 793                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 794                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 795                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 796                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 797                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 798                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 799                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 800                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 801                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 802                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 803                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 804                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 805                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 806                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 807                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 808                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 809                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 810                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 811                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 812                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 813                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 814                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 815                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 816                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 817                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 818                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 819                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 820         });
 821 }
 822
 823 float waypoint_getlinearcost(float dist)
 824 {
 825         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 826                 return dist / (autocvar_sv_maxspeed * 1.25);
 827         return dist / autocvar_sv_maxspeed;
 828 }
 829 float waypoint_getlinearcost_underwater(float dist)
 830 {
 831         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 832         return dist / (autocvar_sv_maxspeed * 0.7);
 833 }
 834
 835 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 836 {
 837         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 838         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 839
 840         if (submerged_from && submerged_to)
 841                 return waypoint_getlinearcost_underwater(vlen(to - from));
 842
 843         float c = waypoint_getlinearcost(vlen(to - from));
 844
 845         float height = from.z - to.z;
 846         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 847         {
 848                 float height_cost;
 849                 if (boolean(from_ent.wpflags & WAYPOINTFLAG_JUMP))
 850                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
 851                 else
 852                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 853                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 854                 if(height_cost > c)
 855                         c = height_cost;
 856         }
 857
 858         if (submerged_from || submerged_to)
 859                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 860         return c;
 861 }
 862
 863 float waypoint_getlinkcost(entity from, entity to)
 864 {
 865         vector v1 = from.origin;
 866         vector v2 = to.origin;
 867         if (from.wpisbox)
 868         {
 869                 vector m1 = from.absmin, m2 = from.absmax;
 870                 v1.x = bound(m1.x, v2.x, m2.x);
 871                 v1.y = bound(m1.y, v2.y, m2.y);
 872                 v1.z = bound(m1.z, v2.z, m2.z);
 873         }
 874         if (to.wpisbox)
 875         {
 876                 vector m1 = to.absmin, m2 = to.absmax;
 877                 v2.x = bound(m1.x, v1.x, m2.x);
 878                 v2.y = bound(m1.y, v1.y, m2.y);
 879                 v2.z = bound(m1.z, v1.z, m2.z);
 880         }
 881         return waypoint_gettravelcost(v1, v2, from, to);
 882 }
 883
 884 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 885 // if c == -1 automatically determine cost of the link
 886 void waypoint_addlink_customcost(entity from, entity to, float c)
 887 {
 888         if (from == to || waypoint_islinked(from, to))
 889                 return;
 890         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & WAYPOINTFLAG_JUMP))
 891                 return;
 892
 893         if(c == -1)
 894                 c = waypoint_getlinkcost(from, to);
 895
 896         if (from.wp31mincost < c) return;
 897         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 898         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 899         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 900         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 901         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 902         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 903         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 904         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 905         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 906         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 907         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 908         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 909         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 910         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 911         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 912         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 913         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 914         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 915         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 916         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 917         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 918         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 919         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 920         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 921         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 922         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 923         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 924         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 925         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 926         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 927         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 928         from.wp00 = to;from.wp00mincost = c;return;
 929 }
 930
 931 void waypoint_addlink(entity from, entity to)
 932 {
 933         if ((from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP)))
 934                 waypoint_addlink_for_custom_jumppad(from, to);
 935         else
 936                 waypoint_addlink_customcost(from, to, -1);
 937 }
 938
 939 // relink this spawnfunc_waypoint
 940 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 941 // (SLOW!)
 942 void waypoint_think(entity this)
 943 {
 944         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 945         float sv2_height = 0, ev2_height = 0;
 946
 947         bot_calculate_stepheightvec();
 948
 949         int dphitcontentsmask_save = this.dphitcontentsmask;
 950         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 951
 952         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 953
 954         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 955         IL_EACH(g_waypoints, this != it,
 956         {
 957                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 958                 {
 959                         waypoint_addlink(this, it);
 960                         waypoint_addlink(it, this);
 961                 }
 962                 else
 963                 {
 964                         ++relink_total;
 965                         if(!checkpvs(this.origin, it))
 966                         {
 967                                 ++relink_pvsculled;
 968                                 continue;
 969                         }
 970
 971                         sv = set_tracewalk_dest_2(this, it.origin);
 972                         sv2 = tracewalk_dest;
 973                         sv2_height = tracewalk_dest_height;
 974                         ev = set_tracewalk_dest_2(it, this.origin);
 975                         ev2 = tracewalk_dest;
 976                         ev2_height = tracewalk_dest_height;
 977
 978                         dv = ev - sv;
 979                         dv.z = 0;
 980                         if(vdist(dv, >=, 1050)) // max search distance in XY
 981                         {
 982                                 ++relink_lengthculled;
 983                                 continue;
 984                         }
 985
 986                         navigation_testtracewalk = 0;
 987
 988                         //traceline(this.origin, it.origin, false, NULL);
 989                         //if (trace_fraction == 1)
 990                         if (this.wpisbox || this.wpflags & WAYPOINTFLAG_JUMP)
 991                                 relink_walkculled += 0.5;
 992                         else
 993                         {
 994                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 995                                         waypoint_addlink(this, it);
 996                                 else
 997                                         relink_walkculled += 0.5;
 998                         }
 999
1000                         if (it.wpisbox || it.wpflags & WAYPOINTFLAG_JUMP)
1001                                 relink_walkculled += 0.5;
1002                         else
1003                         {
1004                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
1005                                         waypoint_addlink(it, this);
1006                                 else
1007                                         relink_walkculled += 0.5;
1008                         }
1009                 }
1010         });
1011         navigation_testtracewalk = 0;
1012         this.wplinked = true;
1013         this.dphitcontentsmask = dphitcontentsmask_save;
1014
1015         setthink(this, func_null);
1016         this.nextthink = 0;
1017 }
1018
1019 void waypoint_clearlinks(entity wp)
1020 {
1021         // clear links to other waypoints
1022         float f = 10000000;
1023         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1024         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1025         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1026         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1027
1028         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1029         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1030         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1031         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1032
1033         wp.wplinked = false;
1034 }
1035
1036 // tell a spawnfunc_waypoint to relink
1037 void waypoint_schedulerelink(entity wp)
1038 {
1039         if (wp == NULL)
1040                 return;
1041
1042         waypoint_setupmodel(wp);
1043         wp.wpisbox = vdist(wp.size, >, 0);
1044         wp.enemy = NULL;
1045         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1046                 wp.owner = NULL;
1047         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
1048                 waypoint_clearlinks(wp);
1049         // schedule an actual relink on next frame
1050         setthink(wp, waypoint_think);
1051         wp.nextthink = time;
1052         wp.effects = EF_LOWPRECISION;
1053 }
1054
1055 // spawnfunc_waypoint map entity
1056 spawnfunc(waypoint)
1057 {
1058         IL_PUSH(g_waypoints, this);
1059
1060         setorigin(this, this.origin);
1061         // schedule a relink after other waypoints have had a chance to spawn
1062         waypoint_clearlinks(this);
1063         //waypoint_schedulerelink(this);
1064 }
1065
1066 // tell all waypoints to relink
1067 // actually this is useful only to update relink_* stats
1068 void waypoint_schedulerelinkall()
1069 {
1070         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1071         IL_EACH(g_waypoints, true,
1072         {
1073                 waypoint_schedulerelink(it);
1074         });
1075         waypoint_load_links_hardwired();
1076 }
1077
1078 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1079
1080 // Load waypoint links from file
1081 bool waypoint_load_links()
1082 {
1083         string s;
1084         float file, tokens, c = 0, found;
1085         entity wp_from = NULL, wp_to;
1086         vector wp_to_pos, wp_from_pos;
1087
1088         string gt_ext = GET_GAMETYPE_EXTENSION();
1089
1090         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1091         file = fopen(filename, FILE_READ);
1092
1093         if (gt_ext != "" && file < 0)
1094         {
1095                 // if race waypoint file doesn't exist load the default one
1096                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1097                 file = fopen(filename, FILE_READ);
1098         }
1099
1100         if (file < 0)
1101         {
1102                 LOG_TRACE("waypoint links load from ", filename, " failed");
1103                 waypoint_schedulerelinkall();
1104                 return false;
1105         }
1106
1107         bool parse_comments = true;
1108         float ver = 0;
1109         string links_time = string_null;
1110
1111         while ((s = fgets(file)))
1112         {
1113                 if(parse_comments)
1114                 {
1115                         if(substring(s, 0, 2) == "//")
1116                         {
1117                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1118                                         ver = stof(substring(s, 19, -1));
1119                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1120                                         links_time = substring(s, 16, -1);
1121                                 continue;
1122                         }
1123                         else
1124                         {
1125                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1126                                 {
1127                                         if (links_time != waypoint_time)
1128                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1129                                         else
1130                                                 LOG_TRACE("waypoint links for this map are outdated.");
1131                                         if (g_assault)
1132                                         {
1133                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1134                                         }
1135                                         else
1136                                         {
1137                                                 LOG_TRACE("automatically updating...");
1138                                                 waypoint_schedulerelinkall();
1139                                                 fclose(file);
1140                                                 return false;
1141                                         }
1142                                 }
1143                                 parse_comments = false;
1144                         }
1145                 }
1146
1147                 tokens = tokenizebyseparator(s, "*");
1148
1149                 if (tokens!=2)
1150                 {
1151                         // bad file format
1152                         fclose(file);
1153                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1154                         return false;
1155                 }
1156
1157                 wp_from_pos     = stov(argv(0));
1158                 wp_to_pos       = stov(argv(1));
1159
1160                 // Search "from" waypoint
1161                 if(!wp_from || wp_from.origin!=wp_from_pos)
1162                 {
1163                         wp_from = findradius(wp_from_pos, 1);
1164                         found = false;
1165                         while(wp_from)
1166                         {
1167                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1168                                 if(wp_from.classname == "waypoint")
1169                                 {
1170                                         found = true;
1171                                         break;
1172                                 }
1173                                 wp_from = wp_from.chain;
1174                         }
1175
1176                         if(!found)
1177                         {
1178                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1179                                 continue;
1180                         }
1181                 }
1182
1183                 // Search "to" waypoint
1184                 wp_to = findradius(wp_to_pos, 1);
1185                 found = false;
1186                 while(wp_to)
1187                 {
1188                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1189                         if(wp_to.classname == "waypoint")
1190                         {
1191                                 found = true;
1192                                 break;
1193                         }
1194                         wp_to = wp_to.chain;
1195                 }
1196
1197                 if(!found)
1198                 {
1199                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1200                         continue;
1201                 }
1202
1203                 ++c;
1204                 waypoint_addlink(wp_from, wp_to);
1205                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1206                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1207         }
1208
1209         fclose(file);
1210
1211         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1212
1213         bool scheduled = false;
1214         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1215         {
1216                 if (!it.wp00)
1217                 {
1218                         waypoint_schedulerelink(it);
1219                         scheduled = true;
1220                 }
1221         });
1222         if (scheduled)
1223                 return false;
1224
1225         botframe_cachedwaypointlinks = true;
1226         return true;
1227 }
1228
1229 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
1230 {
1231         string s;
1232         float file, tokens, c = 0, found;
1233         entity wp_from = NULL, wp_to;
1234         vector wp_to_pos, wp_from_pos;
1235
1236         string gt_ext = GET_GAMETYPE_EXTENSION();
1237
1238         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1239         file = fopen(filename, FILE_READ);
1240
1241         if (gt_ext != "" && file < 0)
1242         {
1243                 // if race waypoint file doesn't exist load the default one
1244                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1245                 file = fopen(filename, FILE_READ);
1246         }
1247
1248         botframe_loadedforcedlinks = true;
1249
1250         if (file < 0)
1251         {
1252                 if(!removal_mode)
1253                         LOG_TRACE("waypoint links load from ", filename, " failed");
1254                 return;
1255         }
1256
1257         bool is_special = false;
1258         while ((s = fgets(file)))
1259         {
1260                 if(substring(s, 0, 2)=="//")
1261                         continue;
1262
1263                 if(substring(s, 0, 1)=="#")
1264                         continue;
1265
1266                 // special links start with *, so old xonotic versions don't load them
1267                 is_special = false;
1268                 if (substring(s, 0, 1) == "*")
1269                 {
1270                         is_special = true;
1271                         s = substring(s, 1, -1);
1272                 }
1273
1274                 tokens = tokenizebyseparator(s, "*");
1275
1276                 if (tokens!=2)
1277                         continue;
1278
1279                 wp_from_pos     = stov(argv(0));
1280                 wp_to_pos       = stov(argv(1));
1281
1282                 // Search "from" waypoint
1283                 if(!wp_from || wp_from.origin!=wp_from_pos)
1284                 {
1285                         wp_from = findradius(wp_from_pos, 5);
1286                         found = false;
1287                         while(wp_from)
1288                         {
1289                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1290                                 if(wp_from.classname == "waypoint")
1291                                 {
1292                                         found = true;
1293                                         break;
1294                                 }
1295                                 wp_from = wp_from.chain;
1296                         }
1297
1298                         if(!found)
1299                         {
1300                                 if(!removal_mode)
1301                                         LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1302                                 continue;
1303                         }
1304                 }
1305
1306                 // Search "to" waypoint
1307                 wp_to = findradius(wp_to_pos, 5);
1308                 found = false;
1309                 while(wp_to)
1310                 {
1311                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1312                         if(wp_to.classname == "waypoint")
1313                         {
1314                                 found = true;
1315                                 break;
1316                         }
1317                         wp_to = wp_to.chain;
1318                 }
1319
1320                 if(!found)
1321                 {
1322                         if(!removal_mode)
1323                                 LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1324                         continue;
1325                 }
1326
1327                 ++c;
1328                 if (removal_mode && !is_special)
1329                 {
1330                         waypoint_unmark_hardwiredlink(wp_from, wp_to);
1331                         waypoint_removelink(wp_from, wp_to);
1332                         continue;
1333                 }
1334
1335                 if (!is_special)
1336                 {
1337                         waypoint_addlink(wp_from, wp_to);
1338                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1339                         waypoint_setupmodel(wp_from);
1340                         waypoint_setupmodel(wp_to);
1341                 } else if (wp_from.wpflags & WAYPOINTFLAG_NORELINK
1342                         && (wp_from.wpflags & WAYPOINTFLAG_JUMP || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1343                 {
1344                         waypoint_addlink(wp_from, wp_to);
1345                 }
1346         }
1347
1348         fclose(file);
1349
1350         LOG_TRACE(((removal_mode) ? "unloaded " : "loaded "),
1351                 ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1352 }
1353
1354 entity waypoint_get_link(entity w, float i)
1355 {
1356         switch(i)
1357         {
1358                 case  0:return w.wp00;
1359                 case  1:return w.wp01;
1360                 case  2:return w.wp02;
1361                 case  3:return w.wp03;
1362                 case  4:return w.wp04;
1363                 case  5:return w.wp05;
1364                 case  6:return w.wp06;
1365                 case  7:return w.wp07;
1366                 case  8:return w.wp08;
1367                 case  9:return w.wp09;
1368                 case 10:return w.wp10;
1369                 case 11:return w.wp11;
1370                 case 12:return w.wp12;
1371                 case 13:return w.wp13;
1372                 case 14:return w.wp14;
1373                 case 15:return w.wp15;
1374                 case 16:return w.wp16;
1375                 case 17:return w.wp17;
1376                 case 18:return w.wp18;
1377                 case 19:return w.wp19;
1378                 case 20:return w.wp20;
1379                 case 21:return w.wp21;
1380                 case 22:return w.wp22;
1381                 case 23:return w.wp23;
1382                 case 24:return w.wp24;
1383                 case 25:return w.wp25;
1384                 case 26:return w.wp26;
1385                 case 27:return w.wp27;
1386                 case 28:return w.wp28;
1387                 case 29:return w.wp29;
1388                 case 30:return w.wp30;
1389                 case 31:return w.wp31;
1390                 default:return NULL;
1391         }
1392 }
1393
1394 // Save all hardwired waypoint links to a file
1395 void waypoint_save_links_hardwired()
1396 {
1397         string gt_ext = GET_GAMETYPE_EXTENSION();
1398
1399         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1400         int file = fopen(filename, FILE_READ);
1401
1402         if (gt_ext != "" && file < 0)
1403         {
1404                 // if race waypoint file doesn't exist load the default one
1405                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1406                 file = fopen(filename, FILE_READ);
1407         }
1408
1409         if (file < 0)
1410         {
1411                 filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1412                 file = fopen(filename, FILE_WRITE);
1413                 if (file < 0)
1414                 {
1415                         LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1416                         return;
1417                 }
1418                 fputs(file, "// HARDWIRED LINKS\n\n");
1419                 fclose(file);
1420                 fopen(filename, FILE_READ);
1421                 if (file < 0)
1422                 {
1423                         LOG_TRACE("waypoint hardwired links load from ", filename, " failed");
1424                         return;
1425                 }
1426         }
1427
1428         int buf = buf_create();
1429         string s;
1430         int pos = 0;
1431
1432         // read comments and hardwired links from file to buf, they won't be changed
1433         while ((s = fgets(file)))
1434         {
1435                 // special links start with *, so old xonotic versions don't load them
1436                 if (substring(s, 0, 1) == "*")
1437                         break;
1438                 bufstr_add(buf, s, false);
1439                 ++pos;
1440         }
1441         fclose(file);
1442
1443         // read links to buf
1444         bool special_link_found = false;
1445         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP),
1446         {
1447                 for (int j = 0; j < 32; ++j)
1448                 {
1449                         entity link = waypoint_get_link(it, j);
1450                         if (link)
1451                         {
1452                                 if (!special_link_found)
1453                                 {
1454                                         special_link_found = true;
1455                                         if (pos == 0 || substring(bufstr_get(buf, pos - 1), 0, 16) != "// SPECIAL LINKS")
1456                                         {
1457                                                 bufstr_add(buf, "// SPECIAL LINKS (saved in the waypoint editor, comments added hereby won't be preserved)", false);
1458                                         }
1459                                 }
1460                                 // NOTE: vtos rounds vector components to 1 decimal place
1461                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin));
1462                                 bufstr_add(buf, s, false);
1463                         }
1464                 }
1465         });
1466
1467         // write buf to file
1468         gt_ext = GET_GAMETYPE_EXTENSION();
1469         filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1470         file = fopen(filename, FILE_WRITE);
1471         if (file < 0)
1472         {
1473                 LOG_INFOF("waypoint hardwired link save to %s failed", filename);
1474                 return;
1475         }
1476         int n = buf_getsize(buf);
1477         for (int i = 0; i < n; ++i)
1478         {
1479                 fputs(file, (strcat(bufstr_get(buf, i), "\n")));
1480         }
1481         buf_del(buf);
1482         fclose(file);
1483
1484         LOG_INFOF("saved hardwired waypoint links to %s", filename);
1485 }
1486
1487 // Save all waypoint links to a file
1488 void waypoint_save_links()
1489 {
1490         // temporarily remove hardwired links so they don't get saved among normal links
1491         waypoint_remove_links_hardwired();
1492
1493         string gt_ext = GET_GAMETYPE_EXTENSION();
1494
1495         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1496         int file = fopen(filename, FILE_WRITE);
1497         if (file < 0)
1498         {
1499                 LOG_INFOF("waypoint link save to %s failed", filename);
1500                 return;
1501         }
1502
1503         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1504         if (waypoint_time != "")
1505                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1506
1507         int c = 0;
1508         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP)),
1509         {
1510                 for(int j = 0; j < 32; ++j)
1511                 {
1512                         entity link = waypoint_get_link(it, j);
1513                         if(link)
1514                         {
1515                                 // NOTE: vtos rounds vector components to 1 decimal place
1516                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1517                                 fputs(file, s);
1518                                 ++c;
1519                         }
1520                 }
1521         });
1522         fclose(file);
1523
1524         botframe_cachedwaypointlinks = true;
1525
1526         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1527
1528         waypoint_load_links_hardwired();
1529 }
1530
1531 // save waypoints to gamedir/data/maps/mapname.waypoints
1532 void waypoint_saveall()
1533 {
1534         if (WAYPOINT_VERSION < waypoint_version_loaded)
1535         {
1536                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1537                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1538                 return;
1539         }
1540         string gt_ext = GET_GAMETYPE_EXTENSION();
1541
1542         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1543         int file = fopen(filename, FILE_WRITE);
1544         if (file < 0)
1545         {
1546                 waypoint_save_links(); // save anyway?
1547                 botframe_loadedforcedlinks = false;
1548
1549                 LOG_INFOF("waypoint links: save to %s failed", filename);
1550                 return;
1551         }
1552
1553         float sym = autocvar_g_waypointeditor_symmetrical;
1554         string sym_str = ftos(sym);
1555         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1556         {
1557                 if (sym == 1)
1558                 {
1559                         sym_str = cons(sym_str, "-");
1560                         sym_str = cons(sym_str, "-");
1561                 }
1562                 else
1563                 {
1564                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1565                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1566                 }
1567                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1568                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1569         }
1570         else if (autocvar_g_waypointeditor_symmetrical == -2)
1571         {
1572                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1573                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1574         }
1575
1576         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1577         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1578         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1579         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1580
1581         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1582         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1583         //fputs(file, strcat("//", "\n"));
1584         //fputs(file, strcat("//", "\n"));
1585         //fputs(file, strcat("//", "\n"));
1586
1587         int c = 0;
1588         IL_EACH(g_waypoints, true,
1589         {
1590                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1591                         continue;
1592
1593                 string s;
1594                 // NOTE: vtos rounds vector components to 1 decimal place
1595                 s = strcat(vtos(it.origin + it.mins), "\n");
1596                 s = strcat(s, vtos(it.origin + it.maxs));
1597                 s = strcat(s, "\n");
1598                 s = strcat(s, ftos(it.wpflags));
1599                 s = strcat(s, "\n");
1600                 fputs(file, s);
1601                 c++;
1602         });
1603         fclose(file);
1604         waypoint_save_links();
1605         waypoint_save_links_hardwired();
1606
1607         botframe_loadedforcedlinks = false;
1608
1609         waypoint_version_loaded = WAYPOINT_VERSION;
1610         LOG_INFOF("saved %d waypoints to %s", c, filename);
1611 }
1612
1613 // load waypoints from file
1614 float waypoint_loadall()
1615 {
1616         string s;
1617         float file, cwp, cwb, fl;
1618         vector m1, m2;
1619         cwp = 0;
1620         cwb = 0;
1621
1622         string gt_ext = GET_GAMETYPE_EXTENSION();
1623
1624         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1625         file = fopen(filename, FILE_READ);
1626
1627         if (gt_ext != "" && file < 0)
1628         {
1629                 // if race waypoint file doesn't exist load the default one
1630                 filename = sprintf("maps/%s.waypoints", mapname);
1631                 file = fopen(filename, FILE_READ);
1632         }
1633
1634         if (file < 0)
1635         {
1636                 LOG_TRACE("waypoint load from ", filename, " failed");
1637                 return 0;
1638         }
1639
1640         bool parse_comments = true;
1641         float ver = 0;
1642         float sym = 0;
1643         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1644
1645         while ((s = fgets(file)))
1646         {
1647                 if(parse_comments)
1648                 {
1649                         if(substring(s, 0, 2) == "//")
1650                         {
1651                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1652                                         ver = stof(substring(s, 19, -1));
1653                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1654                                 {
1655                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1656                                         if (tokens) { sym = stof(argv(0)); }
1657                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1658                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1659                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1660                                 }
1661                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1662                                         strcpy(waypoint_time, substring(s, 16, -1));
1663                                 continue;
1664                         }
1665                         else
1666                         {
1667                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1668                                 {
1669                                         LOG_TRACE("waypoints for this map are outdated");
1670                                         LOG_TRACE("please update them in the editor");
1671                                 }
1672                                 parse_comments = false;
1673                         }
1674                 }
1675                 m1 = stov(s);
1676                 s = fgets(file);
1677                 if (!s)
1678                         break;
1679                 m2 = stov(s);
1680                 s = fgets(file);
1681                 if (!s)
1682                         break;
1683                 fl = stof(s);
1684                 waypoint_spawn(m1, m2, fl);
1685                 if (m1 == m2)
1686                         cwp = cwp + 1;
1687                 else
1688                         cwb = cwb + 1;
1689         }
1690         fclose(file);
1691         waypoint_version_loaded = ver;
1692         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1693
1694         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1695         {
1696                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1697                 if (sym == 1 && sym_param3 < 2)
1698                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1699                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1700                 {
1701                         string params;
1702                         if (sym == 1)
1703                                 params = cons("-", "-");
1704                         else
1705                         {
1706                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1707                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1708                         }
1709                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1710                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1711                 }
1712                 else if (sym == -2)
1713                 {
1714                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1715                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1716                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1717                 }
1718                 else
1719                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1720                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1721         }
1722
1723         if (WAYPOINT_VERSION < waypoint_version_loaded)
1724                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1725                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1726
1727         return cwp + cwb;
1728 }
1729
1730 #define waypoint_fixorigin(position, tracetest_ent) \
1731         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1732
1733 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1734 {
1735         vector endpos = position + down_dir * 3000;
1736         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1737         if(trace_startsolid)
1738                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1739         if(trace_startsolid)
1740                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1741         if(trace_fraction < 1)
1742                 position = trace_endpos;
1743         return position;
1744 }
1745
1746 void waypoint_spawnforitem_force(entity e, vector org)
1747 {
1748         // Fix the waypoint altitude if necessary
1749         org = waypoint_fixorigin(org, NULL);
1750
1751         // don't spawn an item spawnfunc_waypoint if it already exists
1752         IL_EACH(g_waypoints, true,
1753         {
1754                 if(it.wpisbox)
1755                 {
1756                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1757                         {
1758                                 e.nearestwaypoint = it;
1759                                 return;
1760                         }
1761                 }
1762                 else
1763                 {
1764                         if(vdist(it.origin - org, <, 16))
1765                         {
1766                                 e.nearestwaypoint = it;
1767                                 return;
1768                         }
1769                 }
1770         });
1771
1772         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1773 }
1774
1775 void waypoint_spawnforitem(entity e)
1776 {
1777         if(!bot_waypoints_for_items)
1778                 return;
1779
1780         waypoint_spawnforitem_force(e, e.origin);
1781 }
1782
1783 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1784 {
1785         entity w;
1786         entity dw;
1787         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1788         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1789         // one way link to the destination
1790         w.wp00_original = dw;
1791         w.wp00 = dw;
1792         w.wp00mincost = timetaken; // this is just for jump pads
1793         // the teleporter's nearest spawnfunc_waypoint is this one
1794         // (teleporters are not goals, so this is probably useless)
1795         e.nearestwaypoint = w;
1796         e.nearestwaypointtimeout = -1;
1797 }
1798
1799 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1800 {
1801         float src_angle = e.warpzone_angles.x;
1802         while (src_angle < -180) src_angle += 360;
1803         while (src_angle > 180) src_angle -= 360;
1804
1805         float dest_angle = e.enemy.warpzone_angles.x;
1806         while (dest_angle < -180) dest_angle += 360;
1807         while (dest_angle > 180) dest_angle -= 360;
1808
1809         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1810         if (src_angle == -90 || dest_angle == -90)
1811                 return;
1812
1813         makevectors(e.warpzone_angles);
1814         vector src = (e.absmin + e.absmax) * 0.5;
1815         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1816         vector down_dir_src = -v_up;
1817
1818         makevectors(e.enemy.warpzone_angles);
1819         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1820         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1821         vector down_dir_dest = -v_up;
1822
1823         int extra_flag = 0;
1824         // don't snap to the ground waypoints for source warpzones pointing downwards
1825         if (src_angle != 90)
1826         {
1827                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1828                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1829                 // oblique warpzones need a jump otherwise bots gets stuck
1830                 if (src_angle != 0)
1831                         extra_flag = WAYPOINTFLAG_JUMP;
1832         }
1833
1834         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1835 }
1836
1837 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1838 {
1839         destination = waypoint_fixorigin(destination, tracetest_ent);
1840         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1841 }
1842
1843 entity waypoint_spawnpersonal(entity this, vector position)
1844 {
1845         entity w;
1846
1847         // drop the waypoint to a proper location:
1848         //   first move it up by a player height
1849         //   then move it down to hit the floor with player bbox size
1850         position = waypoint_fixorigin(position, this);
1851
1852         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1853         w.nearestwaypoint = NULL;
1854         w.nearestwaypointtimeout = 0;
1855         w.owner = this;
1856
1857         waypoint_schedulerelink(w);
1858
1859         return w;
1860 }
1861
1862 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1863 {
1864         if (!(wp1 && wp2))
1865                 return;
1866
1867         if (waypoint_is_hardwiredlink(wp1, wp2))
1868                 te_beam(NULL, wp1.origin, wp2.origin);
1869         else if (display_type == 1)
1870                 te_lightning2(NULL, wp1.origin, wp2.origin);
1871 }
1872
1873 void waypoint_showlinks_to(entity wp, int display_type)
1874 {
1875         IL_EACH(g_waypoints, it != wp,
1876         {
1877                 if (waypoint_islinked(it, wp))
1878                         waypoint_showlink(it, wp, display_type);
1879         });
1880 }
1881
1882 void waypoint_showlinks_from(entity wp, int display_type)
1883 {
1884         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
1885         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
1886         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
1887         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
1888         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
1889         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
1890         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
1891         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
1892         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
1893         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
1894         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
1895         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
1896         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
1897         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
1898         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
1899         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
1900 }
1901
1902 void crosshair_trace_waypoints(entity pl)
1903 {
1904         IL_EACH(g_waypoints, true, {
1905                 it.solid = SOLID_BSP;
1906                 if (!it.wpisbox)
1907                         setsize(it, '-16 -16 -16', '16 16 16');
1908         });
1909
1910         crosshair_trace(pl);
1911
1912         IL_EACH(g_waypoints, true, {
1913                 it.solid = SOLID_TRIGGER;
1914                 if (!it.wpisbox)
1915                         setsize(it, '0 0 0', '0 0 0');
1916         });
1917         if (trace_ent.classname != "waypoint")
1918                 trace_ent = NULL;
1919 }
1920
1921 void botframe_showwaypointlinks()
1922 {
1923         if (time < botframe_waypointeditorlightningtime)
1924                 return;
1925         botframe_waypointeditorlightningtime = time + 0.5;
1926         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1927         {
1928                 int display_type = 0;
1929                 if (wasfreed(it.wp_aimed))
1930                         it.wp_aimed = NULL;
1931                 if (wasfreed(it.wp_locked))
1932                         it.wp_locked = NULL;
1933                 if (PHYS_INPUT_BUTTON_USE(it))
1934                         it.wp_locked = it.wp_aimed;
1935                 entity head = it.wp_locked;
1936                 if (!head)
1937                         head = navigation_findnearestwaypoint(it, false);
1938                 it.nearestwaypoint = head; // mainly useful for debug
1939                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1940                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
1941                         display_type = 1; // default
1942                 else if(waypoint_has_hardwiredlinks(head))
1943                         display_type = 2; // only hardwired
1944
1945                 if (display_type)
1946                 {
1947                         //navigation_testtracewalk = true;
1948                         //print("currently selected WP is ", etos(head), "\n");
1949                         //navigation_testtracewalk = false;
1950                         if (head)
1951                         {
1952                                 te_lightning2(NULL, head.origin, it.origin);
1953                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1954                                         waypoint_showlinks_to(head, display_type);
1955                                 else
1956                                         waypoint_showlinks_from(head, display_type);
1957                         }
1958                 }
1959                 string str;
1960                 entity wp = NULL;
1961                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
1962                 {
1963                         crosshair_trace_waypoints(it);
1964                         if (trace_ent)
1965                         {
1966                                 wp = trace_ent;
1967                                 if (wp != it.wp_aimed)
1968                                 {
1969                                         str = sprintf("\necho ^2WP info^7: entity: %d, flags: %d, origin: '%s'\n", etof(wp), wp.wpflags, vtos(wp.origin));
1970                                         if (wp.wpisbox)
1971                                                 str = strcat(str, sprintf("echo \" absmin: '%s', absmax: '%s'\"\n", vtos(wp.absmin), vtos(wp.absmax)));
1972                                         stuffcmd(it, str);
1973                                         str = sprintf("entity: %d\nflags: %d\norigin: \'%s\'", etof(wp), wp.wpflags, vtos(wp.origin));
1974                                         if (wp.wpisbox)
1975                                                 str = strcat(str, sprintf(" \nabsmin: '%s'\nabsmax: '%s'", vtos(wp.absmin), vtos(wp.absmax)));
1976                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
1977                                 }
1978                         }
1979                 }
1980                 if (it.wp_aimed != wp)
1981                         it.wp_aimed = wp;
1982         });
1983 }
1984
1985 float botframe_autowaypoints_fixdown(vector v)
1986 {
1987         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1988         if(trace_fraction >= 1)
1989                 return 0;
1990         return 1;
1991 }
1992
1993 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1994 {
1995         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1996         {
1997                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1998                 return 0;
1999         });
2000
2001         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2002         return 1;
2003 }
2004
2005 // return value:
2006 //    1 = WP created
2007 //    0 = no action needed
2008 //   -1 = temp fail, try from world too
2009 //   -2 = permanent fail, do not retry
2010 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2011 {
2012         // make it possible to go from p to wp, if we can
2013         // if wp is NULL, nearest is chosen
2014
2015         entity w;
2016         vector porg;
2017         float t, tmin, tmax;
2018         vector o;
2019         vector save;
2020
2021         if(!botframe_autowaypoints_fixdown(p.origin))
2022                 return -2;
2023         porg = trace_endpos;
2024
2025         if(wp)
2026         {
2027                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2028
2029                 // if wp -> porg, then OK
2030                 float maxdist;
2031                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2032                 {
2033                         // we may find a better one
2034                         maxdist = vlen(wp.origin - porg);
2035                 }
2036                 else
2037                 {
2038                         // accept any "good"
2039                         maxdist = 2100;
2040                 }
2041
2042                 float bestdist = maxdist;
2043                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
2044                 {
2045                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2046                         if(d < bestdist)
2047                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2048                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2049                         {
2050                                 bestdist = d;
2051                                 p.(fld) = it;
2052                         }
2053                 });
2054                 if(bestdist < maxdist)
2055                 {
2056                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2057                         return 0;
2058                 }
2059
2060                 if(bestdist < 2100)
2061                 {
2062                         // we know maxdist < 2100
2063                         // so wp -> porg is still valid
2064                         // all is good
2065                         p.(fld) = wp;
2066                         return 0;
2067                 }
2068
2069                 // otherwise, no existing WP can fix our issues
2070         }
2071         else
2072         {
2073                 save = p.origin;
2074                 setorigin(p, porg);
2075                 w = navigation_findnearestwaypoint(p, walkfromwp);
2076                 setorigin(p, save);
2077                 if(w)
2078                 {
2079                         p.(fld) = w;
2080                         return 0;
2081                 }
2082         }
2083
2084         tmin = 0;
2085         tmax = 1;
2086         for (;;)
2087         {
2088                 if(tmax - tmin < 0.001)
2089                 {
2090                         // did not get a good candidate
2091                         return -1;
2092                 }
2093
2094                 t = (tmin + tmax) * 0.5;
2095                 o = antilag_takebackorigin(p, CS(p), time - t);
2096                 if(!botframe_autowaypoints_fixdown(o))
2097                         return -2;
2098                 o = trace_endpos;
2099
2100                 if(wp)
2101                 {
2102                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2103                         {
2104                                 // we cannot walk from wp.origin to o
2105                                 // get closer to tmax
2106                                 tmin = t;
2107                                 continue;
2108                         }
2109                 }
2110                 else
2111                 {
2112                         save = p.origin;
2113                         setorigin(p, o);
2114                         w = navigation_findnearestwaypoint(p, walkfromwp);
2115                         setorigin(p, save);
2116                         if(!w)
2117                         {
2118                                 // we cannot walk from any WP to o
2119                                 // get closer to tmax
2120                                 tmin = t;
2121                                 continue;
2122                         }
2123                 }
2124
2125                 // if we get here, o is valid regarding waypoints
2126                 // check if o is connected right to the player
2127                 // we break if it succeeds, as that means o is a good waypoint location
2128                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2129                         break;
2130
2131                 // o is no good, we need to get closer to the player
2132                 tmax = t;
2133         }
2134
2135         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2136         botframe_autowaypoints_createwp(o, p, fld, 0);
2137         return 1;
2138 }
2139
2140 // automatically create missing waypoints
2141 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
2142 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2143 {
2144         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2145         if(r != -1)
2146                 return;
2147         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2148         if(r != -1)
2149                 return;
2150
2151         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2152         if(!botframe_autowaypoints_fixdown(p.origin))
2153                 return; // shouldn't happen, caught above
2154         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2155 }
2156
2157 void botframe_deleteuselesswaypoints()
2158 {
2159         IL_EACH(g_items, it.bot_pickup,
2160         {
2161                 // NOTE: this protects waypoints if they're the ONLY nearest
2162                 // waypoint. That's the intention.
2163                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2164                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2165         });
2166         IL_EACH(g_waypoints, true,
2167         {
2168                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2169                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2170                 // WP is useful if:
2171                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2172                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2173                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2174                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2175                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2176                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2177                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2178                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2179                 // b) WP is closest WP for an item/spawnpoint/other entity
2180                 //    This has been done above by protecting these WPs.
2181         });
2182         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2183         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2184         {
2185                 for (int m = 0; m < 32; ++m)
2186                 {
2187                         entity w = waypoint_get_link(it, m);
2188                         if (!w)
2189                                 break;
2190                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2191                                 continue;
2192                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2193                                 continue;
2194                         for (int j = 0; j < 32; ++j)
2195                         {
2196                                 entity w2 = waypoint_get_link(w, j);
2197                                 if (!w2)
2198                                         break;
2199                                 if (it == w2)
2200                                         continue;
2201                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2202                                         continue;
2203                                 // If we got here, it != w2 exist with it -> w
2204                                 // and w -> w2. That means the waypoint is not
2205                                 // a dead end.
2206                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2207                                 for (int k = 0; k < 32; ++k)
2208                                 {
2209                                         if (waypoint_get_link(it, k) == w2)
2210                                                 continue;
2211                                         // IF WE GET HERE, w is proven useful
2212                                         // to get from it to w2!
2213                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2214                                         goto next;
2215                                 }
2216                         }
2217 LABEL(next)
2218                 }
2219         });
2220         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2221         //     they are needed to complete routes while autowaypointing.
2222
2223         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2224         {
2225                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2226                 te_explosion(it.origin);
2227                 waypoint_remove(it);
2228                 break;
2229         });
2230
2231         IL_EACH(g_waypoints, true,
2232         {
2233                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2234         });
2235 }
2236
2237 void botframe_autowaypoints()
2238 {
2239         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2240                 // going back is broken, so only fix waypoints to walk TO the player
2241                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2242                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2243                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2244         });
2245
2246         if (autocvar_g_waypointeditor_auto >= 2) {
2247                 botframe_deleteuselesswaypoints();
2248         }
2249 }
2250