qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17
  18 #include <lib/warpzone/common.qh>
  19 #include <lib/warpzone/util_server.qh>
  20
  21 .entity spawnpointmodel;
  22 void waypoint_unreachable(entity pl)
  23 {
  24         IL_EACH(g_waypoints, true,
  25         {
  26                 it.colormod = '0.5 0.5 0.5';
  27                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  28         });
  29
  30         entity e2 = navigation_findnearestwaypoint(pl, false);
  31         if(!e2)
  32         {
  33                 LOG_INFOF("Can't find any waypoint nearby\n");
  34                 return;
  35         }
  36
  37         navigation_markroutes(pl, e2);
  38
  39         int j = 0;
  40         int m = 0;
  41         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  42         {
  43                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  44                 it.colormod_z = 8;
  45                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  46                 j++;
  47                 m++;
  48         });
  49         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  50         navigation_markroutes_inverted(e2);
  51
  52         j = 0;
  53         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  54         {
  55                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  56                 it.colormod_x = 8;
  57                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  58                         m++;
  59                 it.effects |= EF_NODEPTHTEST | EF_RED;
  60                 j++;
  61         });
  62         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  63         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  64
  65         j = 0;
  66         IL_EACH(g_spawnpoints, true,
  67         {
  68                 if (navigation_findnearestwaypoint(it, false))
  69                 {
  70                         if(it.spawnpointmodel)
  71                         {
  72                                 delete(it.spawnpointmodel);
  73                                 it.spawnpointmodel = NULL;
  74                         }
  75                 }
  76                 else
  77                 {
  78                         if(!it.spawnpointmodel)
  79                         {
  80                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  81                                 entity e = new(spawnpointmodel);
  82                                 vector org = trace_endpos + eZ;
  83                                 setorigin(e, org);
  84                                 e.solid = SOLID_TRIGGER;
  85                                 it.spawnpointmodel = e;
  86                         }
  87                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  88                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  89                         _setmodel(it.spawnpointmodel, pl.model);
  90                         it.spawnpointmodel.frame = pl.frame;
  91                         it.spawnpointmodel.skin = pl.skin;
  92                         it.spawnpointmodel.colormap = pl.colormap;
  93                         it.spawnpointmodel.colormod = pl.colormod;
  94                         it.spawnpointmodel.glowmod = pl.glowmod;
  95                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  96                         j++;
  97                 }
  98         });
  99         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 100
 101         j = 0;
 102         IL_EACH(g_items, true,
 103         {
 104                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 105                 it.colormod = '0.5 0.5 0.5';
 106         });
 107         IL_EACH(g_items, true,
 108         {
 109                 if (navigation_findnearestwaypoint(it, false))
 110                         continue;
 111                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 112                 it.effects |= EF_NODEPTHTEST | EF_RED;
 113                 it.colormod_x = 8;
 114                 j++;
 115         });
 116         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 117
 118         j = 0;
 119         IL_EACH(g_items, true,
 120         {
 121                 if (navigation_findnearestwaypoint(it, true))
 122                         continue;
 123                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 124                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 125                 it.colormod_z = 8;
 126                 j++;
 127         });
 128         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 129 }
 130
 131 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 132 {
 133         vector new_org = org;
 134         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 135         {
 136                 vector map_center = havocbot_middlepoint;
 137                 if (autocvar_g_waypointeditor_symmetrical == -1)
 138                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 139
 140                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 141         }
 142         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 143         {
 144                 float m = havocbot_symmetry_axis_m;
 145                 float q = havocbot_symmetry_axis_q;
 146                 if (autocvar_g_waypointeditor_symmetrical == -2)
 147                 {
 148                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 149                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 150                 }
 151
 152                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 153                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 154         }
 155         new_org.z = org.z;
 156         return new_org;
 157 }
 158
 159 void waypoint_setupmodel(entity wp)
 160 {
 161         if (autocvar_g_waypointeditor)
 162         {
 163                 // TODO: add some sort of visible box in edit mode for box waypoints
 164                 vector m1 = wp.mins;
 165                 vector m2 = wp.maxs;
 166                 setmodel(wp, MDL_WAYPOINT);
 167                 setsize(wp, m1, m2);
 168                 wp.effects = EF_LOWPRECISION;
 169                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 170                         wp.colormod = '1 0 0';
 171                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 172                         wp.colormod = '1 1 0';
 173                 else if (wp.wphardwired)
 174                         wp.colormod = '0.5 0 1';
 175                 else
 176                         wp.colormod = '1 1 1';
 177         }
 178         else
 179                 wp.model = "";
 180 }
 181
 182 entity waypoint_spawn(vector m1, vector m2, float f)
 183 {
 184         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 185         {
 186                 vector em1 = m1 - '8 8 8';
 187                 vector em2 = m2 + '8 8 8';
 188                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 189                 {
 190                         return it;
 191                 });
 192         }
 193         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 194         // otherwise links loaded from file would be applied only to the first destination
 195         // waypoint since link format doesn't specify waypoint entities but just positions
 196         if((f & WAYPOINTFLAG_GENERATED) && !(f & WAYPOINTFLAG_NORELINK) && m1 == m2)
 197         {
 198                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 199                 {
 200                         return it;
 201                 });
 202         }
 203
 204         entity w = new(waypoint);
 205         IL_PUSH(g_waypoints, w);
 206         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 207         w.wpflags = f;
 208         w.solid = SOLID_TRIGGER;
 209         setorigin(w, (m1 + m2) * 0.5);
 210         setsize(w, m1 - w.origin, m2 - w.origin);
 211         if (w.size)
 212                 w.wpisbox = true;
 213
 214         if(!w.wpisbox)
 215         {
 216                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 217                 if(!move_out_of_solid(w))
 218                 {
 219                         if(!(f & WAYPOINTFLAG_GENERATED))
 220                         {
 221                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 222                                 delete(w);
 223                                 return NULL;
 224                         }
 225                         else
 226                         {
 227                                 if(autocvar_developer)
 228                                 {
 229                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 230                                         backtrace("Waypoint stuck");
 231                                 }
 232                         }
 233                 }
 234                 setsize(w, '0 0 0', '0 0 0');
 235         }
 236
 237         waypoint_clearlinks(w);
 238         //waypoint_schedulerelink(w);
 239
 240         waypoint_setupmodel(w);
 241
 242         return w;
 243 }
 244
 245 void waypoint_spawn_fromeditor(entity pl)
 246 {
 247         entity e;
 248         vector org = pl.origin;
 249         int ctf_flags = havocbot_symmetry_origin_order;
 250         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 251                    || (autocvar_g_waypointeditor_symmetrical < 0));
 252         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 253                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 254         int wp_num = ctf_flags;
 255
 256         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 257         {
 258                 // snap waypoint to item's origin if close enough
 259                 IL_EACH(g_items, true,
 260                 {
 261                         vector item_org = (it.absmin + it.absmax) * 0.5;
 262                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 263                         if (vlen(item_org - org) < 20)
 264                         {
 265                                 org = item_org;
 266                                 break;
 267                         }
 268                 });
 269         }
 270
 271         LABEL(add_wp);
 272         e = waypoint_spawn(org, org, 0);
 273         if(!e)
 274         {
 275                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 276                 return;
 277         }
 278         waypoint_schedulerelink(e);
 279         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 280         if(sym)
 281         {
 282                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 283                 if (vdist(org - pl.origin, >, 32))
 284                 {
 285                         if(wp_num > 2)
 286                                 wp_num--;
 287                         else
 288                                 sym = false;
 289                         goto add_wp;
 290                 }
 291         }
 292 }
 293
 294 void waypoint_remove(entity wp)
 295 {
 296         IL_EACH(g_waypoints, it != wp,
 297         {
 298                 if (waypoint_islinked(it, wp))
 299                         waypoint_removelink(it, wp);
 300         });
 301         delete(wp);
 302 }
 303
 304 void waypoint_remove_fromeditor(entity pl)
 305 {
 306         entity e = navigation_findnearestwaypoint(pl, false);
 307
 308         int ctf_flags = havocbot_symmetry_origin_order;
 309         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 310                    || (autocvar_g_waypointeditor_symmetrical < 0));
 311         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 312                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 313         int wp_num = ctf_flags;
 314
 315         LABEL(remove_wp);
 316         if (!e) return;
 317         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 318
 319         if (e.wphardwired)
 320         {
 321                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 322                 return;
 323         }
 324
 325         entity wp_sym = NULL;
 326         if (sym)
 327         {
 328                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 329                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 330                         if(vdist(org - it.origin, <, 3))
 331                         {
 332                                 wp_sym = it;
 333                                 break;
 334                         }
 335                 });
 336         }
 337
 338         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 339         waypoint_remove(e);
 340
 341         if (sym && wp_sym)
 342         {
 343                 e = wp_sym;
 344                 if(wp_num > 2)
 345                         wp_num--;
 346                 else
 347                         sym = false;
 348                 goto remove_wp;
 349         }
 350 }
 351
 352 void waypoint_removelink(entity from, entity to)
 353 {
 354         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 355                 return;
 356
 357         bool found = false;
 358         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 359         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 360         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 361         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 362         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 363         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 364         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 365         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 366         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 367         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 368         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 369         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 370         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 371         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 372         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 373         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 374         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 375         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 376         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 377         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 378         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 379         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 380         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 381         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 382         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 383         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 384         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 385         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 386         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 387         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 388         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 389         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 390 }
 391
 392 bool waypoint_islinked(entity from, entity to)
 393 {
 394         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 395         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 396         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 397         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 398         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 399         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 400         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 401         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 402         return false;
 403 }
 404
 405 void waypoint_updatecost_foralllinks()
 406 {
 407         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 408         {
 409                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 410                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 411                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 412                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 413                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 414                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 415                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 416                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 417                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 418                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 419                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 420                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 421                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 422                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 423                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 424                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 425                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 426                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 427                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 428                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 429                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 430                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 431                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 432                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 433                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 434                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 435                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 436                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 437                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 438                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 439                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 440                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 441         });
 442 }
 443
 444 float waypoint_getlinearcost(float dist)
 445 {
 446         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 447                 return dist / (autocvar_sv_maxspeed * 1.25);
 448         return dist / autocvar_sv_maxspeed;
 449 }
 450 float waypoint_getlinearcost_underwater(float dist)
 451 {
 452         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 453         return dist / (autocvar_sv_maxspeed * 0.7);
 454 }
 455
 456 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 457 {
 458         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 459         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 460
 461         if (submerged_from && submerged_to)
 462                 return waypoint_getlinearcost_underwater(vlen(to - from));
 463
 464         float c = waypoint_getlinearcost(vlen(to - from));
 465
 466         float height = from.z - to.z;
 467         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 468         {
 469                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 470                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 471                 if(height_cost > c)
 472                         c = height_cost;
 473         }
 474
 475         if (submerged_from || submerged_to)
 476                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 477         return c;
 478 }
 479
 480 float waypoint_getlinkcost(entity from, entity to)
 481 {
 482         vector v1 = from.origin;
 483         vector v2 = to.origin;
 484         if (from.wpisbox)
 485         {
 486                 vector m1 = from.absmin, m2 = from.absmax;
 487                 v1.x = bound(m1.x, v2.x, m2.x);
 488                 v1.y = bound(m1.y, v2.y, m2.y);
 489                 v1.z = bound(m1.z, v2.z, m2.z);
 490         }
 491         if (to.wpisbox)
 492         {
 493                 vector m1 = to.absmin, m2 = to.absmax;
 494                 v2.x = bound(m1.x, v1.x, m2.x);
 495                 v2.y = bound(m1.y, v1.y, m2.y);
 496                 v2.z = bound(m1.z, v1.z, m2.z);
 497         }
 498         return waypoint_gettravelcost(v1, v2, from, to);
 499 }
 500
 501 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 502 // if c == -1 automatically determine cost of the link
 503 void waypoint_addlink_customcost(entity from, entity to, float c)
 504 {
 505         if (from == to || waypoint_islinked(from, to))
 506                 return;
 507         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 508                 return;
 509
 510         if(c == -1)
 511                 c = waypoint_getlinkcost(from, to);
 512
 513         if (from.wp31mincost < c) return;
 514         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 515         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 516         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 517         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 518         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 519         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 520         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 521         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 522         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 523         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 524         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 525         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 526         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 527         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 528         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 529         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 530         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 531         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 532         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 533         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 534         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 535         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 536         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 537         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 538         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 539         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 540         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 541         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 542         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 543         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 544         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 545         from.wp00 = to;from.wp00mincost = c;return;
 546 }
 547
 548 void waypoint_addlink(entity from, entity to)
 549 {
 550         waypoint_addlink_customcost(from, to, -1);
 551 }
 552
 553 // relink this spawnfunc_waypoint
 554 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 555 // (SLOW!)
 556 void waypoint_think(entity this)
 557 {
 558         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 559         float sv2_height = 0, ev2_height = 0;
 560
 561         bot_calculate_stepheightvec();
 562
 563         int dphitcontentsmask_save = this.dphitcontentsmask;
 564         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 565
 566         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 567
 568         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 569         IL_EACH(g_waypoints, this != it,
 570         {
 571                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 572                 {
 573                         waypoint_addlink(this, it);
 574                         waypoint_addlink(it, this);
 575                 }
 576                 else
 577                 {
 578                         ++relink_total;
 579                         if(!checkpvs(this.origin, it))
 580                         {
 581                                 ++relink_pvsculled;
 582                                 continue;
 583                         }
 584
 585                         sv = set_tracewalk_dest_2(this, it.origin);
 586                         sv2 = tracewalk_dest;
 587                         sv2_height = tracewalk_dest_height;
 588                         ev = set_tracewalk_dest_2(it, this.origin);
 589                         ev2 = tracewalk_dest;
 590                         ev2_height = tracewalk_dest_height;
 591
 592                         dv = ev - sv;
 593                         dv.z = 0;
 594                         if(vdist(dv, >=, 1050)) // max search distance in XY
 595                         {
 596                                 ++relink_lengthculled;
 597                                 continue;
 598                         }
 599
 600                         navigation_testtracewalk = 0;
 601
 602                         //traceline(this.origin, it.origin, false, NULL);
 603                         //if (trace_fraction == 1)
 604                         if (this.wpisbox)
 605                                 relink_walkculled += 0.5;
 606                         else
 607                         {
 608                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 609                                         waypoint_addlink(this, it);
 610                                 else
 611                                         relink_walkculled += 0.5;
 612                         }
 613
 614                         if (it.wpisbox)
 615                                 relink_walkculled += 0.5;
 616                         else
 617                         {
 618                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 619                                         waypoint_addlink(it, this);
 620                                 else
 621                                         relink_walkculled += 0.5;
 622                         }
 623                 }
 624         });
 625         navigation_testtracewalk = 0;
 626         this.wplinked = true;
 627         this.dphitcontentsmask = dphitcontentsmask_save;
 628 }
 629
 630 void waypoint_clearlinks(entity wp)
 631 {
 632         // clear links to other waypoints
 633         float f = 10000000;
 634         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 635         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 636         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 637         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 638
 639         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 640         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 641         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 642         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 643
 644         wp.wplinked = false;
 645 }
 646
 647 // tell a spawnfunc_waypoint to relink
 648 void waypoint_schedulerelink(entity wp)
 649 {
 650         if (wp == NULL)
 651                 return;
 652
 653         waypoint_setupmodel(wp);
 654         wp.wpisbox = vdist(wp.size, >, 0);
 655         wp.enemy = NULL;
 656         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 657                 wp.owner = NULL;
 658         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 659                 waypoint_clearlinks(wp);
 660         // schedule an actual relink on next frame
 661         setthink(wp, waypoint_think);
 662         wp.nextthink = time;
 663         wp.effects = EF_LOWPRECISION;
 664 }
 665
 666 // spawnfunc_waypoint map entity
 667 spawnfunc(waypoint)
 668 {
 669         IL_PUSH(g_waypoints, this);
 670
 671         setorigin(this, this.origin);
 672         // schedule a relink after other waypoints have had a chance to spawn
 673         waypoint_clearlinks(this);
 674         //waypoint_schedulerelink(this);
 675 }
 676
 677 // tell all waypoints to relink
 678 // actually this is useful only to update relink_* stats
 679 void waypoint_schedulerelinkall()
 680 {
 681         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 682         IL_EACH(g_waypoints, true,
 683         {
 684                 waypoint_schedulerelink(it);
 685         });
 686         waypoint_load_links_hardwired();
 687 }
 688
 689 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
 690
 691 // Load waypoint links from file
 692 bool waypoint_load_links()
 693 {
 694         string s;
 695         float file, tokens, c = 0, found;
 696         entity wp_from = NULL, wp_to;
 697         vector wp_to_pos, wp_from_pos;
 698
 699         string gt_ext = GET_GAMETYPE_EXTENSION();
 700
 701         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 702         file = fopen(filename, FILE_READ);
 703
 704         if (gt_ext != "" && file < 0)
 705         {
 706                 // if race waypoint file doesn't exist load the default one
 707                 filename = sprintf("maps/%s.waypoints.cache", mapname);
 708                 file = fopen(filename, FILE_READ);
 709         }
 710
 711         if (file < 0)
 712         {
 713                 LOG_TRACE("waypoint links load from ", filename, " failed");
 714                 waypoint_schedulerelinkall();
 715                 return false;
 716         }
 717
 718         bool parse_comments = true;
 719         float ver = 0;
 720         string links_time = string_null;
 721
 722         while ((s = fgets(file)))
 723         {
 724                 if(parse_comments)
 725                 {
 726                         if(substring(s, 0, 2) == "//")
 727                         {
 728                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
 729                                         ver = stof(substring(s, 19, -1));
 730                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
 731                                         links_time = substring(s, 16, -1);
 732                                 continue;
 733                         }
 734                         else
 735                         {
 736                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
 737                                 {
 738                                         if (links_time != waypoint_time)
 739                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
 740                                         else
 741                                                 LOG_TRACE("waypoint links for this map are outdated.");
 742                                         if (g_assault)
 743                                         {
 744                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
 745                                         }
 746                                         else
 747                                         {
 748                                                 LOG_TRACE("automatically updating...");
 749                                                 waypoint_schedulerelinkall();
 750                                                 fclose(file);
 751                                                 return false;
 752                                         }
 753                                 }
 754                                 parse_comments = false;
 755                         }
 756                 }
 757
 758                 tokens = tokenizebyseparator(s, "*");
 759
 760                 if (tokens!=2)
 761                 {
 762                         // bad file format
 763                         fclose(file);
 764                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
 765                         return false;
 766                 }
 767
 768                 wp_from_pos     = stov(argv(0));
 769                 wp_to_pos       = stov(argv(1));
 770
 771                 // Search "from" waypoint
 772                 if(!wp_from || wp_from.origin!=wp_from_pos)
 773                 {
 774                         wp_from = findradius(wp_from_pos, 1);
 775                         found = false;
 776                         while(wp_from)
 777                         {
 778                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 779                                 if(wp_from.classname == "waypoint")
 780                                 {
 781                                         found = true;
 782                                         break;
 783                                 }
 784                                 wp_from = wp_from.chain;
 785                         }
 786
 787                         if(!found)
 788                         {
 789                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 790                                 continue;
 791                         }
 792                 }
 793
 794                 // Search "to" waypoint
 795                 wp_to = findradius(wp_to_pos, 1);
 796                 found = false;
 797                 while(wp_to)
 798                 {
 799                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 800                         if(wp_to.classname == "waypoint")
 801                         {
 802                                 found = true;
 803                                 break;
 804                         }
 805                         wp_to = wp_to.chain;
 806                 }
 807
 808                 if(!found)
 809                 {
 810                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 811                         continue;
 812                 }
 813
 814                 ++c;
 815                 waypoint_addlink(wp_from, wp_to);
 816         }
 817
 818         fclose(file);
 819
 820         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
 821
 822         bool scheduled = false;
 823         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
 824         {
 825                 if (!it.wp00)
 826                 {
 827                         waypoint_schedulerelink(it);
 828                         scheduled = true;
 829                 }
 830         });
 831         if (scheduled)
 832                 return false;
 833
 834         botframe_cachedwaypointlinks = true;
 835         return true;
 836 }
 837
 838 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 839 {
 840         string s;
 841         float file, tokens, c = 0, found;
 842         entity wp_from = NULL, wp_to;
 843         vector wp_to_pos, wp_from_pos;
 844
 845         string gt_ext = GET_GAMETYPE_EXTENSION();
 846
 847         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
 848         file = fopen(filename, FILE_READ);
 849
 850         if (gt_ext != "" && file < 0)
 851         {
 852                 // if race waypoint file doesn't exist load the default one
 853                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
 854                 file = fopen(filename, FILE_READ);
 855         }
 856
 857         botframe_loadedforcedlinks = true;
 858
 859         if (file < 0)
 860         {
 861                 if(!removal_mode)
 862                         LOG_TRACE("waypoint links load from ", filename, " failed");
 863                 return;
 864         }
 865
 866         while ((s = fgets(file)))
 867         {
 868                 if(substring(s, 0, 2)=="//")
 869                         continue;
 870
 871                 if(substring(s, 0, 1)=="#")
 872                         continue;
 873
 874                 tokens = tokenizebyseparator(s, "*");
 875
 876                 if (tokens!=2)
 877                         continue;
 878
 879                 wp_from_pos     = stov(argv(0));
 880                 wp_to_pos       = stov(argv(1));
 881
 882                 // Search "from" waypoint
 883                 if(!wp_from || wp_from.origin!=wp_from_pos)
 884                 {
 885                         wp_from = findradius(wp_from_pos, 5);
 886                         found = false;
 887                         while(wp_from)
 888                         {
 889                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 890                                 if(wp_from.classname == "waypoint")
 891                                 {
 892                                         found = true;
 893                                         break;
 894                                 }
 895                                 wp_from = wp_from.chain;
 896                         }
 897
 898                         if(!found)
 899                         {
 900                                 if(!removal_mode)
 901                                         LOG_INFO("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped");
 902                                 continue;
 903                         }
 904                 }
 905
 906                 // Search "to" waypoint
 907                 wp_to = findradius(wp_to_pos, 5);
 908                 found = false;
 909                 while(wp_to)
 910                 {
 911                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 912                         if(wp_to.classname == "waypoint")
 913                         {
 914                                 found = true;
 915                                 break;
 916                         }
 917                         wp_to = wp_to.chain;
 918                 }
 919
 920                 if(!found)
 921                 {
 922                         if(!removal_mode)
 923                                 LOG_INFO("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped");
 924                         continue;
 925                 }
 926
 927                 ++c;
 928                 if(removal_mode)
 929                 {
 930                         waypoint_removelink(wp_from, wp_to);
 931                         continue;
 932                 }
 933
 934                 waypoint_addlink(wp_from, wp_to);
 935                 wp_from.wphardwired = true;
 936                 wp_to.wphardwired = true;
 937                 waypoint_setupmodel(wp_from);
 938                 waypoint_setupmodel(wp_to);
 939         }
 940
 941         fclose(file);
 942
 943         LOG_TRACE(((removal_mode) ? "unloaded " : "loaded "),
 944                 ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 945 }
 946
 947 entity waypoint_get_link(entity w, float i)
 948 {
 949         switch(i)
 950         {
 951                 case  0:return w.wp00;
 952                 case  1:return w.wp01;
 953                 case  2:return w.wp02;
 954                 case  3:return w.wp03;
 955                 case  4:return w.wp04;
 956                 case  5:return w.wp05;
 957                 case  6:return w.wp06;
 958                 case  7:return w.wp07;
 959                 case  8:return w.wp08;
 960                 case  9:return w.wp09;
 961                 case 10:return w.wp10;
 962                 case 11:return w.wp11;
 963                 case 12:return w.wp12;
 964                 case 13:return w.wp13;
 965                 case 14:return w.wp14;
 966                 case 15:return w.wp15;
 967                 case 16:return w.wp16;
 968                 case 17:return w.wp17;
 969                 case 18:return w.wp18;
 970                 case 19:return w.wp19;
 971                 case 20:return w.wp20;
 972                 case 21:return w.wp21;
 973                 case 22:return w.wp22;
 974                 case 23:return w.wp23;
 975                 case 24:return w.wp24;
 976                 case 25:return w.wp25;
 977                 case 26:return w.wp26;
 978                 case 27:return w.wp27;
 979                 case 28:return w.wp28;
 980                 case 29:return w.wp29;
 981                 case 30:return w.wp30;
 982                 case 31:return w.wp31;
 983                 default:return NULL;
 984         }
 985 }
 986
 987 // Save all waypoint links to a file
 988 void waypoint_save_links()
 989 {
 990         // temporarily remove hardwired links so they don't get saved among normal links
 991         waypoint_remove_links_hardwired();
 992
 993         string gt_ext = GET_GAMETYPE_EXTENSION();
 994
 995         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 996         int file = fopen(filename, FILE_WRITE);
 997         if (file < 0)
 998         {
 999                 LOG_INFOF("waypoint link save to %s failed", filename);
1000                 return;
1001         }
1002
1003         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1004         if (waypoint_time != "")
1005                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1006
1007         int c = 0;
1008         IL_EACH(g_waypoints, true,
1009         {
1010                 for(int j = 0; j < 32; ++j)
1011                 {
1012                         entity link = waypoint_get_link(it, j);
1013                         if(link)
1014                         {
1015                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1016                                 fputs(file, s);
1017                                 ++c;
1018                         }
1019                 }
1020         });
1021         fclose(file);
1022
1023         botframe_cachedwaypointlinks = true;
1024
1025         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1026
1027         waypoint_load_links_hardwired();
1028 }
1029
1030 // save waypoints to gamedir/data/maps/mapname.waypoints
1031 void waypoint_saveall()
1032 {
1033         string gt_ext = GET_GAMETYPE_EXTENSION();
1034
1035         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1036         int file = fopen(filename, FILE_WRITE);
1037         if (file < 0)
1038         {
1039                 waypoint_save_links(); // save anyway?
1040                 botframe_loadedforcedlinks = false;
1041
1042                 LOG_INFOF("waypoint links: save to %s failed", filename);
1043                 return;
1044         }
1045
1046         float sym = autocvar_g_waypointeditor_symmetrical;
1047         string sym_str = ftos(sym);
1048         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1049         {
1050                 if (sym == 1)
1051                 {
1052                         sym_str = cons(sym_str, "-");
1053                         sym_str = cons(sym_str, "-");
1054                 }
1055                 else
1056                 {
1057                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1058                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1059                 }
1060                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1061                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1062         }
1063         else if (autocvar_g_waypointeditor_symmetrical == -2)
1064         {
1065                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1066                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1067         }
1068
1069         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1070         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1071         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1072         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1073
1074         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1075         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1076         //fputs(file, strcat("//", "\n"));
1077         //fputs(file, strcat("//", "\n"));
1078         //fputs(file, strcat("//", "\n"));
1079
1080         int c = 0;
1081         IL_EACH(g_waypoints, true,
1082         {
1083                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1084                         continue;
1085
1086                 string s;
1087                 s = strcat(vtos(it.origin + it.mins), "\n");
1088                 s = strcat(s, vtos(it.origin + it.maxs));
1089                 s = strcat(s, "\n");
1090                 s = strcat(s, ftos(it.wpflags));
1091                 s = strcat(s, "\n");
1092                 fputs(file, s);
1093                 c++;
1094         });
1095         fclose(file);
1096         waypoint_save_links();
1097         botframe_loadedforcedlinks = false;
1098
1099         LOG_INFOF("saved %d waypoints to %s", c, filename);
1100 }
1101
1102 // load waypoints from file
1103 float waypoint_loadall()
1104 {
1105         string s;
1106         float file, cwp, cwb, fl;
1107         vector m1, m2;
1108         cwp = 0;
1109         cwb = 0;
1110
1111         string gt_ext = GET_GAMETYPE_EXTENSION();
1112
1113         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1114         file = fopen(filename, FILE_READ);
1115
1116         if (gt_ext != "" && file < 0)
1117         {
1118                 // if race waypoint file doesn't exist load the default one
1119                 filename = sprintf("maps/%s.waypoints", mapname);
1120                 file = fopen(filename, FILE_READ);
1121         }
1122
1123         if (file < 0)
1124         {
1125                 LOG_TRACE("waypoint load from ", filename, " failed");
1126                 return 0;
1127         }
1128
1129         bool parse_comments = true;
1130         float ver = 0;
1131         float sym = 0;
1132         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1133
1134         while ((s = fgets(file)))
1135         {
1136                 if(parse_comments)
1137                 {
1138                         if(substring(s, 0, 2) == "//")
1139                         {
1140                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1141                                         ver = stof(substring(s, 19, -1));
1142                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1143                                 {
1144                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1145                                         if (tokens) { sym = stof(argv(0)); }
1146                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1147                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1148                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1149                                 }
1150                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1151                                         strcpy(waypoint_time, substring(s, 16, -1));
1152                                 continue;
1153                         }
1154                         else
1155                         {
1156                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1157                                 {
1158                                         LOG_TRACE("waypoints for this map are outdated");
1159                                         LOG_TRACE("please update them in the editor");
1160                                 }
1161                                 parse_comments = false;
1162                         }
1163                 }
1164                 m1 = stov(s);
1165                 s = fgets(file);
1166                 if (!s)
1167                         break;
1168                 m2 = stov(s);
1169                 s = fgets(file);
1170                 if (!s)
1171                         break;
1172                 fl = stof(s);
1173                 waypoint_spawn(m1, m2, fl);
1174                 if (m1 == m2)
1175                         cwp = cwp + 1;
1176                 else
1177                         cwb = cwb + 1;
1178         }
1179         fclose(file);
1180         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1181
1182         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1183         {
1184                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1185                 if (sym == 1 && sym_param3 < 2)
1186                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1187                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1188                 {
1189                         string params;
1190                         if (sym == 1)
1191                                 params = cons("-", "-");
1192                         else
1193                         {
1194                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1195                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1196                         }
1197                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1198                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1199                 }
1200                 else if (sym == -2)
1201                 {
1202                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1203                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1204                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1205                 }
1206                 else
1207                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1208                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1209         }
1210
1211         return cwp + cwb;
1212 }
1213
1214 #define waypoint_fixorigin(position, tracetest_ent) \
1215         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1216
1217 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1218 {
1219         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1220         if(trace_startsolid)
1221                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1222         if(trace_startsolid)
1223                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1224         if(trace_fraction < 1)
1225                 position = trace_endpos;
1226         return position;
1227 }
1228
1229 void waypoint_spawnforitem_force(entity e, vector org)
1230 {
1231         // Fix the waypoint altitude if necessary
1232         org = waypoint_fixorigin(org, NULL);
1233
1234         // don't spawn an item spawnfunc_waypoint if it already exists
1235         IL_EACH(g_waypoints, true,
1236         {
1237                 if(it.wpisbox)
1238                 {
1239                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1240                         {
1241                                 e.nearestwaypoint = it;
1242                                 return;
1243                         }
1244                 }
1245                 else
1246                 {
1247                         if(vdist(it.origin - org, <, 16))
1248                         {
1249                                 e.nearestwaypoint = it;
1250                                 return;
1251                         }
1252                 }
1253         });
1254
1255         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1256 }
1257
1258 void waypoint_spawnforitem(entity e)
1259 {
1260         if(!bot_waypoints_for_items)
1261                 return;
1262
1263         waypoint_spawnforitem_force(e, e.origin);
1264 }
1265
1266 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1267 {
1268         entity w;
1269         entity dw;
1270         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1271         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1272         // one way link to the destination
1273         w.wp00 = dw;
1274         w.wp00mincost = timetaken; // this is just for jump pads
1275         // the teleporter's nearest spawnfunc_waypoint is this one
1276         // (teleporters are not goals, so this is probably useless)
1277         e.nearestwaypoint = w;
1278         e.nearestwaypointtimeout = -1;
1279 }
1280
1281 void waypoint_spawnforteleporter_wz(entity e, vector org, vector destination, float timetaken, vector down_dir, entity tracetest_ent)
1282 {
1283         // warpzones with oblique warp plane rely on down_dir to snap waypoints
1284         // to the ground without leaving the warp plane
1285         // warpzones with horizontal warp plane (down_dir.x == -1) generate
1286         // destination waypoint snapped to the ground (leaving warpzone), source
1287         // waypoint in the center of the warp plane
1288         if(down_dir.x != -1)
1289                 org = waypoint_fixorigin_down_dir(org, tracetest_ent, down_dir);
1290         if(down_dir.x == -1)
1291                 down_dir = '0 0 -1';
1292         destination = waypoint_fixorigin_down_dir(destination, tracetest_ent, down_dir);
1293         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1294 }
1295
1296 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1297 {
1298         destination = waypoint_fixorigin(destination, tracetest_ent);
1299         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1300 }
1301
1302 entity waypoint_spawnpersonal(entity this, vector position)
1303 {
1304         entity w;
1305
1306         // drop the waypoint to a proper location:
1307         //   first move it up by a player height
1308         //   then move it down to hit the floor with player bbox size
1309         position = waypoint_fixorigin(position, this);
1310
1311         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1312         w.nearestwaypoint = NULL;
1313         w.nearestwaypointtimeout = 0;
1314         w.owner = this;
1315
1316         waypoint_schedulerelink(w);
1317
1318         return w;
1319 }
1320
1321 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1322 {
1323         if (!(wp1 && wp2))
1324                 return;
1325
1326         if (wp1.wphardwired && wp2.wphardwired)
1327                 te_beam(NULL, wp1.origin, wp2.origin);
1328         else if (display_type == 1)
1329                 te_lightning2(NULL, wp1.origin, wp2.origin);
1330 }
1331
1332 void waypoint_showlinks_to(entity wp, int display_type)
1333 {
1334         IL_EACH(g_waypoints, it != wp,
1335         {
1336                 if (waypoint_islinked(it, wp))
1337                         waypoint_showlink(it, wp, display_type);
1338         });
1339 }
1340
1341 void waypoint_showlinks_from(entity wp, int display_type)
1342 {
1343         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1344         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1345         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1346         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1347         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1348         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1349         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1350         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1351         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1352         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1353         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1354         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1355         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1356         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1357         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1358         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1359 }
1360
1361 void botframe_showwaypointlinks()
1362 {
1363         if (time < botframe_waypointeditorlightningtime)
1364                 return;
1365         botframe_waypointeditorlightningtime = time + 0.5;
1366         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1367         {
1368                 int display_type = 0;
1369                 entity head = navigation_findnearestwaypoint(it, false);
1370                 it.nearestwaypoint = head; // mainly useful for debug
1371                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1372                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1373                         display_type = 1; // default
1374                 else if(head && (head.wphardwired))
1375                         display_type = 2; // only hardwired
1376
1377                 if (display_type)
1378                 {
1379                         //navigation_testtracewalk = true;
1380                         //print("currently selected WP is ", etos(head), "\n");
1381                         //navigation_testtracewalk = false;
1382                         if (head)
1383                         {
1384                                 te_lightning2(NULL, head.origin, it.origin);
1385                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1386                                         waypoint_showlinks_to(head, display_type);
1387                                 else
1388                                         waypoint_showlinks_from(head, display_type);
1389                         }
1390                 }
1391         });
1392 }
1393
1394 float botframe_autowaypoints_fixdown(vector v)
1395 {
1396         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1397         if(trace_fraction >= 1)
1398                 return 0;
1399         return 1;
1400 }
1401
1402 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1403 {
1404         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1405         {
1406                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1407                 return 0;
1408         });
1409
1410         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1411         return 1;
1412 }
1413
1414 // return value:
1415 //    1 = WP created
1416 //    0 = no action needed
1417 //   -1 = temp fail, try from world too
1418 //   -2 = permanent fail, do not retry
1419 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1420 {
1421         // make it possible to go from p to wp, if we can
1422         // if wp is NULL, nearest is chosen
1423
1424         entity w;
1425         vector porg;
1426         float t, tmin, tmax;
1427         vector o;
1428         vector save;
1429
1430         if(!botframe_autowaypoints_fixdown(p.origin))
1431                 return -2;
1432         porg = trace_endpos;
1433
1434         if(wp)
1435         {
1436                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1437
1438                 // if wp -> porg, then OK
1439                 float maxdist;
1440                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1441                 {
1442                         // we may find a better one
1443                         maxdist = vlen(wp.origin - porg);
1444                 }
1445                 else
1446                 {
1447                         // accept any "good"
1448                         maxdist = 2100;
1449                 }
1450
1451                 float bestdist = maxdist;
1452                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1453                 {
1454                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1455                         if(d < bestdist)
1456                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1457                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1458                         {
1459                                 bestdist = d;
1460                                 p.(fld) = it;
1461                         }
1462                 });
1463                 if(bestdist < maxdist)
1464                 {
1465                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1466                         return 0;
1467                 }
1468
1469                 if(bestdist < 2100)
1470                 {
1471                         // we know maxdist < 2100
1472                         // so wp -> porg is still valid
1473                         // all is good
1474                         p.(fld) = wp;
1475                         return 0;
1476                 }
1477
1478                 // otherwise, no existing WP can fix our issues
1479         }
1480         else
1481         {
1482                 save = p.origin;
1483                 setorigin(p, porg);
1484                 w = navigation_findnearestwaypoint(p, walkfromwp);
1485                 setorigin(p, save);
1486                 if(w)
1487                 {
1488                         p.(fld) = w;
1489                         return 0;
1490                 }
1491         }
1492
1493         tmin = 0;
1494         tmax = 1;
1495         for (;;)
1496         {
1497                 if(tmax - tmin < 0.001)
1498                 {
1499                         // did not get a good candidate
1500                         return -1;
1501                 }
1502
1503                 t = (tmin + tmax) * 0.5;
1504                 o = antilag_takebackorigin(p, CS(p), time - t);
1505                 if(!botframe_autowaypoints_fixdown(o))
1506                         return -2;
1507                 o = trace_endpos;
1508
1509                 if(wp)
1510                 {
1511                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
1512                         {
1513                                 // we cannot walk from wp.origin to o
1514                                 // get closer to tmax
1515                                 tmin = t;
1516                                 continue;
1517                         }
1518                 }
1519                 else
1520                 {
1521                         save = p.origin;
1522                         setorigin(p, o);
1523                         w = navigation_findnearestwaypoint(p, walkfromwp);
1524                         setorigin(p, save);
1525                         if(!w)
1526                         {
1527                                 // we cannot walk from any WP to o
1528                                 // get closer to tmax
1529                                 tmin = t;
1530                                 continue;
1531                         }
1532                 }
1533
1534                 // if we get here, o is valid regarding waypoints
1535                 // check if o is connected right to the player
1536                 // we break if it succeeds, as that means o is a good waypoint location
1537                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
1538                         break;
1539
1540                 // o is no good, we need to get closer to the player
1541                 tmax = t;
1542         }
1543
1544         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
1545         botframe_autowaypoints_createwp(o, p, fld, 0);
1546         return 1;
1547 }
1548
1549 // automatically create missing waypoints
1550 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1551 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1552 {
1553         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1554         if(r != -1)
1555                 return;
1556         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1557         if(r != -1)
1558                 return;
1559
1560         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
1561         if(!botframe_autowaypoints_fixdown(p.origin))
1562                 return; // shouldn't happen, caught above
1563         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1564 }
1565
1566 void botframe_deleteuselesswaypoints()
1567 {
1568         IL_EACH(g_items, it.bot_pickup,
1569         {
1570                 // NOTE: this protects waypoints if they're the ONLY nearest
1571                 // waypoint. That's the intention.
1572                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1573                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1574         });
1575         IL_EACH(g_waypoints, true,
1576         {
1577                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1578                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1579                 // WP is useful if:
1580                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1581                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1582                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1583                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1584                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1585                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1586                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1587                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1588                 // b) WP is closest WP for an item/spawnpoint/other entity
1589                 //    This has been done above by protecting these WPs.
1590         });
1591         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1592         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1593         {
1594                 for (int m = 0; m < 32; ++m)
1595                 {
1596                         entity w = waypoint_get_link(it, m);
1597                         if (!w)
1598                                 break;
1599                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1600                                 continue;
1601                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1602                                 continue;
1603                         for (int j = 0; j < 32; ++j)
1604                         {
1605                                 entity w2 = waypoint_get_link(w, j);
1606                                 if (!w2)
1607                                         break;
1608                                 if (it == w2)
1609                                         continue;
1610                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1611                                         continue;
1612                                 // If we got here, it != w2 exist with it -> w
1613                                 // and w -> w2. That means the waypoint is not
1614                                 // a dead end.
1615                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1616                                 for (int k = 0; k < 32; ++k)
1617                                 {
1618                                         if (waypoint_get_link(it, k) == w2)
1619                                                 continue;
1620                                         // IF WE GET HERE, w is proven useful
1621                                         // to get from it to w2!
1622                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1623                                         goto next;
1624                                 }
1625                         }
1626 LABEL(next)
1627                 }
1628         });
1629         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1630         //     they are needed to complete routes while autowaypointing.
1631
1632         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1633         {
1634                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
1635                 te_explosion(it.origin);
1636                 waypoint_remove(it);
1637                 break;
1638         });
1639
1640         IL_EACH(g_waypoints, true,
1641         {
1642                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1643         });
1644 }
1645
1646 void botframe_autowaypoints()
1647 {
1648         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
1649                 // going back is broken, so only fix waypoints to walk TO the player
1650                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1651                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1652                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1653         });
1654
1655         if (autocvar_g_waypointeditor_auto >= 2) {
1656                 botframe_deleteuselesswaypoints();
1657         }
1658 }
1659