qcsrc/server/bot/waypoints.qc

   1 #include "waypoints.qh"
   2 #include "../_all.qh"
   3
   4 #include "bot.qh"
   5 #include "navigation.qh"
   6
   7 #include "../antilag.qh"
   8
   9 #include "../../common/constants.qh"
  10
  11 #include "../../warpzonelib/util_server.qh"
  12
  13 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
  14 // them back to it as well
  15 // (suitable for spawnfunc_waypoint editor)
  16 entity waypoint_spawn(vector m1, vector m2, float f)
  17 {
  18         entity w;
  19         w = find(world, classname, "waypoint");
  20
  21         if (!(f & WAYPOINTFLAG_PERSONAL))
  22         while (w)
  23         {
  24                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
  25                 if (boxesoverlap(m1, m2, w.absmin, w.absmax))
  26                         return w;
  27                 w = find(w, classname, "waypoint");
  28         }
  29
  30         w = spawn();
  31         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
  32         w.classname = "waypoint";
  33         w.wpflags = f;
  34         setorigin(w, (m1 + m2) * 0.5);
  35         setsize(w, m1 - w.origin, m2 - w.origin);
  36         if (vlen(w.size) > 0)
  37                 w.wpisbox = true;
  38
  39         if(!w.wpisbox)
  40         {
  41                 setsize(w, PL_MIN - '1 1 0', PL_MAX + '1 1 0');
  42                 if(!move_out_of_solid(w))
  43                 {
  44                         if(!(f & WAYPOINTFLAG_GENERATED))
  45                         {
  46                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin), "\n");
  47                                 remove(w);
  48                                 return world;
  49                         }
  50                         else
  51                         {
  52                                 if(autocvar_developer)
  53                                 {
  54                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
  55                                         backtrace("Waypoint stuck");
  56                                 }
  57                         }
  58                 }
  59                 setsize(w, '0 0 0', '0 0 0');
  60         }
  61
  62         waypoint_clearlinks(w);
  63         //waypoint_schedulerelink(w);
  64
  65         if (autocvar_g_waypointeditor)
  66         {
  67                 m1 = w.mins;
  68                 m2 = w.maxs;
  69                 setmodel(w, "models/runematch/rune.mdl"); w.effects = EF_LOWPRECISION;
  70                 setsize(w, m1, m2);
  71                 if (w.wpflags & WAYPOINTFLAG_ITEM)
  72                         w.colormod = '1 0 0';
  73                 else if (w.wpflags & WAYPOINTFLAG_GENERATED)
  74                         w.colormod = '1 1 0';
  75                 else
  76                         w.colormod = '1 1 1';
  77         }
  78         else
  79                 w.model = "";
  80
  81         return w;
  82 }
  83
  84 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
  85 void waypoint_addlink(entity from, entity to)
  86 {
  87         float c;
  88
  89         if (from == to)
  90                 return;
  91         if (from.wpflags & WAYPOINTFLAG_NORELINK)
  92                 return;
  93
  94         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
  95         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
  96         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
  97         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
  98         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
  99         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
 100         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
 101         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
 102
 103         if (to.wpisbox || from.wpisbox)
 104         {
 105                 // if either is a box we have to find the nearest points on them to
 106                 // calculate the distance properly
 107                 vector v1, v2, m1, m2;
 108                 v1 = from.origin;
 109                 m1 = to.absmin;
 110                 m2 = to.absmax;
 111                 v1_x = bound(m1_x, v1_x, m2_x);
 112                 v1_y = bound(m1_y, v1_y, m2_y);
 113                 v1_z = bound(m1_z, v1_z, m2_z);
 114                 v2 = to.origin;
 115                 m1 = from.absmin;
 116                 m2 = from.absmax;
 117                 v2_x = bound(m1_x, v2_x, m2_x);
 118                 v2_y = bound(m1_y, v2_y, m2_y);
 119                 v2_z = bound(m1_z, v2_z, m2_z);
 120                 v2 = to.origin;
 121                 c = vlen(v2 - v1);
 122         }
 123         else
 124                 c = vlen(to.origin - from.origin);
 125
 126         if (from.wp31mincost < c) return;
 127         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 128         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 129         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 130         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 131         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 132         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 133         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 134         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 135         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 136         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 137         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 138         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 139         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 140         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 141         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 142         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 143         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 144         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 145         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 146         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 147         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 148         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 149         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 150         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 151         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 152         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 153         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 154         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 155         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 156         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 157         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 158         from.wp00 = to;from.wp00mincost = c;return;
 159 }
 160
 161 // relink this spawnfunc_waypoint
 162 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 163 // (SLOW!)
 164 void waypoint_think()
 165 {SELFPARAM();
 166         entity e;
 167         vector sv, sm1, sm2, ev, em1, em2, dv;
 168
 169         bot_calculate_stepheightvec();
 170
 171         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 172
 173         //dprint("waypoint_think wpisbox = ", ftos(self.wpisbox), "\n");
 174         sm1 = self.origin + self.mins;
 175         sm2 = self.origin + self.maxs;
 176         for(e = world; (e = find(e, classname, "waypoint")); )
 177         {
 178                 if (boxesoverlap(self.absmin, self.absmax, e.absmin, e.absmax))
 179                 {
 180                         waypoint_addlink(self, e);
 181                         waypoint_addlink(e, self);
 182                 }
 183                 else
 184                 {
 185                         ++relink_total;
 186                         if(!checkpvs(self.origin, e))
 187                         {
 188                                 ++relink_pvsculled;
 189                                 continue;
 190                         }
 191                         sv = e.origin;
 192                         sv.x = bound(sm1_x, sv.x, sm2_x);
 193                         sv.y = bound(sm1_y, sv.y, sm2_y);
 194                         sv.z = bound(sm1_z, sv.z, sm2_z);
 195                         ev = self.origin;
 196                         em1 = e.origin + e.mins;
 197                         em2 = e.origin + e.maxs;
 198                         ev.x = bound(em1_x, ev.x, em2_x);
 199                         ev.y = bound(em1_y, ev.y, em2_y);
 200                         ev.z = bound(em1_z, ev.z, em2_z);
 201                         dv = ev - sv;
 202                         dv.z = 0;
 203                         if (vlen(dv) >= 1050) // max search distance in XY
 204                         {
 205                                 ++relink_lengthculled;
 206                                 continue;
 207                         }
 208                         navigation_testtracewalk = 0;
 209                         if (!self.wpisbox)
 210                         {
 211                                 tracebox(sv - PL_MIN.z * '0 0 1', PL_MIN, PL_MAX, sv, false, self);
 212                                 if (!trace_startsolid)
 213                                 {
 214                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 215                                         sv = trace_endpos + '0 0 1';
 216                                 }
 217                         }
 218                         if (!e.wpisbox)
 219                         {
 220                                 tracebox(ev - PL_MIN.z * '0 0 1', PL_MIN, PL_MAX, ev, false, e);
 221                                 if (!trace_startsolid)
 222                                 {
 223                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 224                                         ev = trace_endpos + '0 0 1';
 225                                 }
 226                         }
 227                         //traceline(self.origin, e.origin, false, world);
 228                         //if (trace_fraction == 1)
 229                         if (!self.wpisbox && tracewalk(self, sv, PL_MIN, PL_MAX, ev, MOVE_NOMONSTERS))
 230                                 waypoint_addlink(self, e);
 231                         else
 232                                 relink_walkculled += 0.5;
 233                         if (!e.wpisbox && tracewalk(e, ev, PL_MIN, PL_MAX, sv, MOVE_NOMONSTERS))
 234                                 waypoint_addlink(e, self);
 235                         else
 236                                 relink_walkculled += 0.5;
 237                 }
 238         }
 239         navigation_testtracewalk = 0;
 240         self.wplinked = true;
 241 }
 242
 243 void waypoint_clearlinks(entity wp)
 244 {
 245         // clear links to other waypoints
 246         float f;
 247         f = 10000000;
 248         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = world;
 249         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = world;
 250         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = world;
 251         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = world;
 252
 253         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 254         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 255         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 256         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 257
 258         wp.wplinked = false;
 259 }
 260
 261 // tell a spawnfunc_waypoint to relink
 262 void waypoint_schedulerelink(entity wp)
 263 {
 264         if (wp == world)
 265                 return;
 266         // TODO: add some sort of visible box in edit mode for box waypoints
 267         if (autocvar_g_waypointeditor)
 268         {
 269                 vector m1, m2;
 270                 m1 = wp.mins;
 271                 m2 = wp.maxs;
 272                 setmodel(wp, "models/runematch/rune.mdl"); wp.effects = EF_LOWPRECISION;
 273                 setsize(wp, m1, m2);
 274                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 275                         wp.colormod = '1 0 0';
 276                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 277                         wp.colormod = '1 1 0';
 278                 else
 279                         wp.colormod = '1 1 1';
 280         }
 281         else
 282                 wp.model = "";
 283         wp.wpisbox = vlen(wp.size) > 0;
 284         wp.enemy = world;
 285         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 286                 wp.owner = world;
 287         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 288                 waypoint_clearlinks(wp);
 289         // schedule an actual relink on next frame
 290         wp.think = waypoint_think;
 291         wp.nextthink = time;
 292         wp.effects = EF_LOWPRECISION;
 293 }
 294
 295 // spawnfunc_waypoint map entity
 296 void spawnfunc_waypoint()
 297 {SELFPARAM();
 298         setorigin(self, self.origin);
 299         // schedule a relink after other waypoints have had a chance to spawn
 300         waypoint_clearlinks(self);
 301         //waypoint_schedulerelink(self);
 302 }
 303
 304 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 305 void waypoint_remove(entity e)
 306 {
 307         // tell all linked waypoints that they need to relink
 308         waypoint_schedulerelink(e.wp00);
 309         waypoint_schedulerelink(e.wp01);
 310         waypoint_schedulerelink(e.wp02);
 311         waypoint_schedulerelink(e.wp03);
 312         waypoint_schedulerelink(e.wp04);
 313         waypoint_schedulerelink(e.wp05);
 314         waypoint_schedulerelink(e.wp06);
 315         waypoint_schedulerelink(e.wp07);
 316         waypoint_schedulerelink(e.wp08);
 317         waypoint_schedulerelink(e.wp09);
 318         waypoint_schedulerelink(e.wp10);
 319         waypoint_schedulerelink(e.wp11);
 320         waypoint_schedulerelink(e.wp12);
 321         waypoint_schedulerelink(e.wp13);
 322         waypoint_schedulerelink(e.wp14);
 323         waypoint_schedulerelink(e.wp15);
 324         waypoint_schedulerelink(e.wp16);
 325         waypoint_schedulerelink(e.wp17);
 326         waypoint_schedulerelink(e.wp18);
 327         waypoint_schedulerelink(e.wp19);
 328         waypoint_schedulerelink(e.wp20);
 329         waypoint_schedulerelink(e.wp21);
 330         waypoint_schedulerelink(e.wp22);
 331         waypoint_schedulerelink(e.wp23);
 332         waypoint_schedulerelink(e.wp24);
 333         waypoint_schedulerelink(e.wp25);
 334         waypoint_schedulerelink(e.wp26);
 335         waypoint_schedulerelink(e.wp27);
 336         waypoint_schedulerelink(e.wp28);
 337         waypoint_schedulerelink(e.wp29);
 338         waypoint_schedulerelink(e.wp30);
 339         waypoint_schedulerelink(e.wp31);
 340         // and now remove the spawnfunc_waypoint
 341         remove(e);
 342 }
 343
 344 // empties the map of waypoints
 345 void waypoint_removeall()
 346 {
 347         entity head, next;
 348         head = findchain(classname, "waypoint");
 349         while (head)
 350         {
 351                 next = head.chain;
 352                 remove(head);
 353                 head = next;
 354         }
 355 }
 356
 357 // tell all waypoints to relink
 358 // (is this useful at all?)
 359 void waypoint_schedulerelinkall()
 360 {
 361         entity head;
 362         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 363         head = findchain(classname, "waypoint");
 364         while (head)
 365         {
 366                 waypoint_schedulerelink(head);
 367                 head = head.chain;
 368         }
 369 }
 370
 371 // Load waypoint links from file
 372 float waypoint_load_links()
 373 {
 374         string filename, s;
 375         float file, tokens, c = 0, found;
 376         entity wp_from = world, wp_to;
 377         vector wp_to_pos, wp_from_pos;
 378         filename = strcat("maps/", mapname);
 379         filename = strcat(filename, ".waypoints.cache");
 380         file = fopen(filename, FILE_READ);
 381
 382         if (file < 0)
 383         {
 384                 LOG_TRACE("waypoint links load from ");
 385                 LOG_TRACE(filename);
 386                 LOG_TRACE(" failed\n");
 387                 return false;
 388         }
 389
 390         while ((s = fgets(file)))
 391         {
 392                 tokens = tokenizebyseparator(s, "*");
 393
 394                 if (tokens!=2)
 395                 {
 396                         // bad file format
 397                         fclose(file);
 398                         return false;
 399                 }
 400
 401                 wp_from_pos     = stov(argv(0));
 402                 wp_to_pos       = stov(argv(1));
 403
 404                 // Search "from" waypoint
 405                 if(!wp_from || wp_from.origin!=wp_from_pos)
 406                 {
 407                         wp_from = findradius(wp_from_pos, 1);
 408                         found = false;
 409                         while(wp_from)
 410                         {
 411                                 if(vlen(wp_from.origin-wp_from_pos)<1)
 412                                 if(wp_from.classname == "waypoint")
 413                                 {
 414                                         found = true;
 415                                         break;
 416                                 }
 417                                 wp_from = wp_from.chain;
 418                         }
 419
 420                         if(!found)
 421                         {
 422                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from.origin),"\n");
 423                                 continue;
 424                         }
 425
 426                 }
 427
 428                 // Search "to" waypoint
 429                 wp_to = findradius(wp_to_pos, 1);
 430                 found = false;
 431                 while(wp_to)
 432                 {
 433                         if(vlen(wp_to.origin-wp_to_pos)<1)
 434                         if(wp_to.classname == "waypoint")
 435                         {
 436                                 found = true;
 437                                 break;
 438                         }
 439                         wp_to = wp_to.chain;
 440                 }
 441
 442                 if(!found)
 443                 {
 444                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to.origin),"\n");
 445                         continue;
 446                 }
 447
 448                 ++c;
 449                 waypoint_addlink(wp_from, wp_to);
 450         }
 451
 452         fclose(file);
 453
 454         LOG_TRACE("loaded ");
 455         LOG_TRACE(ftos(c));
 456         LOG_TRACE(" waypoint links from maps/");
 457         LOG_TRACE(mapname);
 458         LOG_TRACE(".waypoints.cache\n");
 459
 460         botframe_cachedwaypointlinks = true;
 461         return true;
 462 }
 463
 464 void waypoint_load_links_hardwired()
 465 {
 466         string filename, s;
 467         float file, tokens, c = 0, found;
 468         entity wp_from = world, wp_to;
 469         vector wp_to_pos, wp_from_pos;
 470         filename = strcat("maps/", mapname);
 471         filename = strcat(filename, ".waypoints.hardwired");
 472         file = fopen(filename, FILE_READ);
 473
 474         botframe_loadedforcedlinks = true;
 475
 476         if (file < 0)
 477         {
 478                 LOG_TRACE("waypoint links load from ");
 479                 LOG_TRACE(filename);
 480                 LOG_TRACE(" failed\n");
 481                 return;
 482         }
 483
 484         while ((s = fgets(file)))
 485         {
 486                 if(substring(s, 0, 2)=="//")
 487                         continue;
 488
 489                 if(substring(s, 0, 1)=="#")
 490                         continue;
 491
 492                 tokens = tokenizebyseparator(s, "*");
 493
 494                 if (tokens!=2)
 495                         continue;
 496
 497                 wp_from_pos     = stov(argv(0));
 498                 wp_to_pos       = stov(argv(1));
 499
 500                 // Search "from" waypoint
 501                 if(!wp_from || wp_from.origin!=wp_from_pos)
 502                 {
 503                         wp_from = findradius(wp_from_pos, 5);
 504                         found = false;
 505                         while(wp_from)
 506                         {
 507                                 if(vlen(wp_from.origin-wp_from_pos)<5)
 508                                 if(wp_from.classname == "waypoint")
 509                                 {
 510                                         found = true;
 511                                         break;
 512                                 }
 513                                 wp_from = wp_from.chain;
 514                         }
 515
 516                         if(!found)
 517                         {
 518                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 519                                 continue;
 520                         }
 521                 }
 522
 523                 // Search "to" waypoint
 524                 wp_to = findradius(wp_to_pos, 5);
 525                 found = false;
 526                 while(wp_to)
 527                 {
 528                         if(vlen(wp_to.origin-wp_to_pos)<5)
 529                         if(wp_to.classname == "waypoint")
 530                         {
 531                                 found = true;
 532                                 break;
 533                         }
 534                         wp_to = wp_to.chain;
 535                 }
 536
 537                 if(!found)
 538                 {
 539                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 540                         continue;
 541                 }
 542
 543                 ++c;
 544                 waypoint_addlink(wp_from, wp_to);
 545                 wp_from.wphardwired = true;
 546                 wp_to.wphardwired = true;
 547         }
 548
 549         fclose(file);
 550
 551         LOG_TRACE("loaded ");
 552         LOG_TRACE(ftos(c));
 553         LOG_TRACE(" waypoint links from maps/");
 554         LOG_TRACE(mapname);
 555         LOG_TRACE(".waypoints.hardwired\n");
 556 }
 557
 558 entity waypoint_get_link(entity w, float i)
 559 {
 560         switch(i)
 561         {
 562                 case  0:return w.wp00;
 563                 case  1:return w.wp01;
 564                 case  2:return w.wp02;
 565                 case  3:return w.wp03;
 566                 case  4:return w.wp04;
 567                 case  5:return w.wp05;
 568                 case  6:return w.wp06;
 569                 case  7:return w.wp07;
 570                 case  8:return w.wp08;
 571                 case  9:return w.wp09;
 572                 case 10:return w.wp10;
 573                 case 11:return w.wp11;
 574                 case 12:return w.wp12;
 575                 case 13:return w.wp13;
 576                 case 14:return w.wp14;
 577                 case 15:return w.wp15;
 578                 case 16:return w.wp16;
 579                 case 17:return w.wp17;
 580                 case 18:return w.wp18;
 581                 case 19:return w.wp19;
 582                 case 20:return w.wp20;
 583                 case 21:return w.wp21;
 584                 case 22:return w.wp22;
 585                 case 23:return w.wp23;
 586                 case 24:return w.wp24;
 587                 case 25:return w.wp25;
 588                 case 26:return w.wp26;
 589                 case 27:return w.wp27;
 590                 case 28:return w.wp28;
 591                 case 29:return w.wp29;
 592                 case 30:return w.wp30;
 593                 case 31:return w.wp31;
 594                 default:return world;
 595         }
 596 }
 597
 598 // Save all waypoint links to a file
 599 void waypoint_save_links()
 600 {
 601         string filename, s;
 602         float file, c, i;
 603         entity w, link;
 604         filename = strcat("maps/", mapname);
 605         filename = strcat(filename, ".waypoints.cache");
 606         file = fopen(filename, FILE_WRITE);
 607         if (file < 0)
 608         {
 609                 LOG_INFO("waypoint links save to ");
 610                 LOG_INFO(filename);
 611                 LOG_INFO(" failed\n");
 612         }
 613         c = 0;
 614         w = findchain(classname, "waypoint");
 615         while (w)
 616         {
 617                 for(i=0;i<32;++i)
 618                 {
 619                         // :S
 620                         link = waypoint_get_link(w, i);
 621                         if(link==world)
 622                                 continue;
 623
 624                         s = strcat(vtos(w.origin), "*", vtos(link.origin), "\n");
 625                         fputs(file, s);
 626                         ++c;
 627                 }
 628                 w = w.chain;
 629         }
 630         fclose(file);
 631         botframe_cachedwaypointlinks = true;
 632
 633         LOG_INFO("saved ");
 634         LOG_INFO(ftos(c));
 635         LOG_INFO(" waypoints links to maps/");
 636         LOG_INFO(mapname);
 637         LOG_INFO(".waypoints.cache\n");
 638 }
 639
 640 // save waypoints to gamedir/data/maps/mapname.waypoints
 641 void waypoint_saveall()
 642 {
 643         string filename, s;
 644         float file, c;
 645         entity w;
 646         filename = strcat("maps/", mapname);
 647         filename = strcat(filename, ".waypoints");
 648         file = fopen(filename, FILE_WRITE);
 649         if (file >= 0)
 650         {
 651                 c = 0;
 652                 w = findchain(classname, "waypoint");
 653                 while (w)
 654                 {
 655                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
 656                         {
 657                                 s = strcat(vtos(w.origin + w.mins), "\n");
 658                                 s = strcat(s, vtos(w.origin + w.maxs));
 659                                 s = strcat(s, "\n");
 660                                 s = strcat(s, ftos(w.wpflags));
 661                                 s = strcat(s, "\n");
 662                                 fputs(file, s);
 663                                 c = c + 1;
 664                         }
 665                         w = w.chain;
 666                 }
 667                 fclose(file);
 668                 bprint("saved ");
 669                 bprint(ftos(c));
 670                 bprint(" waypoints to maps/");
 671                 bprint(mapname);
 672                 bprint(".waypoints\n");
 673         }
 674         else
 675         {
 676                 bprint("waypoint save to ");
 677                 bprint(filename);
 678                 bprint(" failed\n");
 679         }
 680         waypoint_save_links();
 681         botframe_loadedforcedlinks = false;
 682 }
 683
 684 // load waypoints from file
 685 float waypoint_loadall()
 686 {
 687         string filename, s;
 688         float file, cwp, cwb, fl;
 689         vector m1, m2;
 690         cwp = 0;
 691         cwb = 0;
 692         filename = strcat("maps/", mapname);
 693         filename = strcat(filename, ".waypoints");
 694         file = fopen(filename, FILE_READ);
 695         if (file >= 0)
 696         {
 697                 while ((s = fgets(file)))
 698                 {
 699                         m1 = stov(s);
 700                         s = fgets(file);
 701                         if (!s)
 702                                 break;
 703                         m2 = stov(s);
 704                         s = fgets(file);
 705                         if (!s)
 706                                 break;
 707                         fl = stof(s);
 708                         waypoint_spawn(m1, m2, fl);
 709                         if (m1 == m2)
 710                                 cwp = cwp + 1;
 711                         else
 712                                 cwb = cwb + 1;
 713                 }
 714                 fclose(file);
 715                 LOG_TRACE("loaded ");
 716                 LOG_TRACE(ftos(cwp));
 717                 LOG_TRACE(" waypoints and ");
 718                 LOG_TRACE(ftos(cwb));
 719                 LOG_TRACE(" wayboxes from maps/");
 720                 LOG_TRACE(mapname);
 721                 LOG_TRACE(".waypoints\n");
 722         }
 723         else
 724         {
 725                 LOG_TRACE("waypoint load from ");
 726                 LOG_TRACE(filename);
 727                 LOG_TRACE(" failed\n");
 728         }
 729         return cwp + cwb;
 730 }
 731
 732 vector waypoint_fixorigin(vector position)
 733 {
 734         tracebox(position + '0 0 1' * (1 - PL_MIN.z), PL_MIN, PL_MAX, position + '0 0 -512', MOVE_NOMONSTERS, world);
 735         if(trace_fraction < 1)
 736                 position = trace_endpos;
 737         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, world);
 738         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 739         return position;
 740 }
 741
 742 void waypoint_spawnforitem_force(entity e, vector org)
 743 {
 744         entity w;
 745
 746         // Fix the waypoint altitude if necessary
 747         org = waypoint_fixorigin(org);
 748
 749         // don't spawn an item spawnfunc_waypoint if it already exists
 750         w = findchain(classname, "waypoint");
 751         while (w)
 752         {
 753                 if (w.wpisbox)
 754                 {
 755                         if (boxesoverlap(org, org, w.absmin, w.absmax))
 756                         {
 757                                 e.nearestwaypoint = w;
 758                                 return;
 759                         }
 760                 }
 761                 else
 762                 {
 763                         if (vlen(w.origin - org) < 16)
 764                         {
 765                                 e.nearestwaypoint = w;
 766                                 return;
 767                         }
 768                 }
 769                 w = w.chain;
 770         }
 771         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 772 }
 773
 774 void waypoint_spawnforitem(entity e)
 775 {
 776         if(!bot_waypoints_for_items)
 777                 return;
 778
 779         waypoint_spawnforitem_force(e, e.origin);
 780 }
 781
 782 void waypoint_spawnforteleporter_boxes(entity e, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
 783 {
 784         entity w;
 785         entity dw;
 786         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 787         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
 788         // one way link to the destination
 789         w.wp00 = dw;
 790         w.wp00mincost = timetaken; // this is just for jump pads
 791         // the teleporter's nearest spawnfunc_waypoint is this one
 792         // (teleporters are not goals, so this is probably useless)
 793         e.nearestwaypoint = w;
 794         e.nearestwaypointtimeout = time + 1000000000;
 795 }
 796
 797 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
 798 {
 799         org = waypoint_fixorigin(org);
 800         destination = waypoint_fixorigin(destination);
 801         waypoint_spawnforteleporter_boxes(e, org, org, destination, destination, timetaken);
 802 }
 803
 804 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 805 {
 806         destination = waypoint_fixorigin(destination);
 807         waypoint_spawnforteleporter_boxes(e, e.absmin, e.absmax, destination, destination, timetaken);
 808 }
 809
 810 entity waypoint_spawnpersonal(vector position)
 811 {SELFPARAM();
 812         entity w;
 813
 814         // drop the waypoint to a proper location:
 815         //   first move it up by a player height
 816         //   then move it down to hit the floor with player bbox size
 817         position = waypoint_fixorigin(position);
 818
 819         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
 820         w.nearestwaypoint = world;
 821         w.nearestwaypointtimeout = 0;
 822         w.owner = self;
 823
 824         waypoint_schedulerelink(w);
 825
 826         return w;
 827 }
 828
 829 void botframe_showwaypointlinks()
 830 {
 831         entity player, head, w;
 832         if (time < botframe_waypointeditorlightningtime)
 833                 return;
 834         botframe_waypointeditorlightningtime = time + 0.5;
 835         player = find(world, classname, "player");
 836         while (player)
 837         {
 838                 if (!player.isbot)
 839                 if (player.flags & FL_ONGROUND || player.waterlevel > WATERLEVEL_NONE)
 840                 {
 841                         //navigation_testtracewalk = true;
 842                         head = navigation_findnearestwaypoint(player, false);
 843                 //      print("currently selected WP is ", etos(head), "\n");
 844                         //navigation_testtracewalk = false;
 845                         if (head)
 846                         {
 847                                 w = head     ;if (w) te_lightning2(world, w.origin, player.origin);
 848                                 w = head.wp00;if (w) te_lightning2(world, w.origin, head.origin);
 849                                 w = head.wp01;if (w) te_lightning2(world, w.origin, head.origin);
 850                                 w = head.wp02;if (w) te_lightning2(world, w.origin, head.origin);
 851                                 w = head.wp03;if (w) te_lightning2(world, w.origin, head.origin);
 852                                 w = head.wp04;if (w) te_lightning2(world, w.origin, head.origin);
 853                                 w = head.wp05;if (w) te_lightning2(world, w.origin, head.origin);
 854                                 w = head.wp06;if (w) te_lightning2(world, w.origin, head.origin);
 855                                 w = head.wp07;if (w) te_lightning2(world, w.origin, head.origin);
 856                                 w = head.wp08;if (w) te_lightning2(world, w.origin, head.origin);
 857                                 w = head.wp09;if (w) te_lightning2(world, w.origin, head.origin);
 858                                 w = head.wp10;if (w) te_lightning2(world, w.origin, head.origin);
 859                                 w = head.wp11;if (w) te_lightning2(world, w.origin, head.origin);
 860                                 w = head.wp12;if (w) te_lightning2(world, w.origin, head.origin);
 861                                 w = head.wp13;if (w) te_lightning2(world, w.origin, head.origin);
 862                                 w = head.wp14;if (w) te_lightning2(world, w.origin, head.origin);
 863                                 w = head.wp15;if (w) te_lightning2(world, w.origin, head.origin);
 864                                 w = head.wp16;if (w) te_lightning2(world, w.origin, head.origin);
 865                                 w = head.wp17;if (w) te_lightning2(world, w.origin, head.origin);
 866                                 w = head.wp18;if (w) te_lightning2(world, w.origin, head.origin);
 867                                 w = head.wp19;if (w) te_lightning2(world, w.origin, head.origin);
 868                                 w = head.wp20;if (w) te_lightning2(world, w.origin, head.origin);
 869                                 w = head.wp21;if (w) te_lightning2(world, w.origin, head.origin);
 870                                 w = head.wp22;if (w) te_lightning2(world, w.origin, head.origin);
 871                                 w = head.wp23;if (w) te_lightning2(world, w.origin, head.origin);
 872                                 w = head.wp24;if (w) te_lightning2(world, w.origin, head.origin);
 873                                 w = head.wp25;if (w) te_lightning2(world, w.origin, head.origin);
 874                                 w = head.wp26;if (w) te_lightning2(world, w.origin, head.origin);
 875                                 w = head.wp27;if (w) te_lightning2(world, w.origin, head.origin);
 876                                 w = head.wp28;if (w) te_lightning2(world, w.origin, head.origin);
 877                                 w = head.wp29;if (w) te_lightning2(world, w.origin, head.origin);
 878                                 w = head.wp30;if (w) te_lightning2(world, w.origin, head.origin);
 879                                 w = head.wp31;if (w) te_lightning2(world, w.origin, head.origin);
 880                         }
 881                 }
 882                 player = find(player, classname, "player");
 883         }
 884 }
 885
 886 float botframe_autowaypoints_fixdown(vector v)
 887 {
 888         tracebox(v, PL_MIN, PL_MAX, v + '0 0 -64', MOVE_NOMONSTERS, world);
 889         if(trace_fraction >= 1)
 890                 return 0;
 891         return 1;
 892 }
 893
 894 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
 895 {
 896         entity w;
 897
 898         w = find(world, classname, "waypoint");
 899         while (w)
 900         {
 901                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 902                 if (boxesoverlap(v - '32 32 32', v + '32 32 32', w.absmin, w.absmax))
 903                 //if (boxesoverlap(v - '4 4 4', v + '4 4 4', w.absmin, w.absmax))
 904                         return 0;
 905                 w = find(w, classname, "waypoint");
 906         }
 907
 908         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
 909         return 1;
 910 }
 911
 912 // return value:
 913 //    1 = WP created
 914 //    0 = no action needed
 915 //   -1 = temp fail, try from world too
 916 //   -2 = permanent fail, do not retry
 917 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
 918 {
 919         // make it possible to go from p to wp, if we can
 920         // if wp is world, nearest is chosen
 921
 922         entity w;
 923         vector porg;
 924         float t, tmin, tmax;
 925         vector o;
 926         vector save;
 927
 928         if(!botframe_autowaypoints_fixdown(p.origin))
 929                 return -2;
 930         porg = trace_endpos;
 931
 932         if(wp)
 933         {
 934                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
 935
 936                 // if wp -> porg, then OK
 937                 float maxdist;
 938                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
 939                 {
 940                         // we may find a better one
 941                         maxdist = vlen(wp.origin - porg);
 942                 }
 943                 else
 944                 {
 945                         // accept any "good"
 946                         maxdist = 2100;
 947                 }
 948
 949                 float bestdist;
 950                 bestdist = maxdist;
 951                 w = find(world, classname, "waypoint");
 952                 while (w)
 953                 {
 954                         if(w != wp && !(w.wpflags & WAYPOINTFLAG_NORELINK))
 955                         {
 956                                 float d;
 957                                 d = vlen(wp.origin - w.origin) + vlen(w.origin - porg);
 958                                 if(d < bestdist)
 959                                         if(navigation_waypoint_will_link(wp.origin, w.origin, p, walkfromwp, 1050))
 960                                                 if(navigation_waypoint_will_link(w.origin, porg, p, walkfromwp, 1050))
 961                                                 {
 962                                                         bestdist = d;
 963                                                         p.(fld) = w;
 964                                                 }
 965                         }
 966                         w = find(w, classname, "waypoint");
 967                 }
 968                 if(bestdist < maxdist)
 969                 {
 970                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
 971                         return 0;
 972                 }
 973
 974                 if(bestdist < 2100)
 975                 {
 976                         // we know maxdist < 2100
 977                         // so wp -> porg is still valid
 978                         // all is good
 979                         p.(fld) = wp;
 980                         return 0;
 981                 }
 982
 983                 // otherwise, no existing WP can fix our issues
 984         }
 985         else
 986         {
 987                 save = p.origin;
 988                 setorigin(p, porg);
 989                 w = navigation_findnearestwaypoint(p, walkfromwp);
 990                 setorigin(p, save);
 991                 if(w)
 992                 {
 993                         p.(fld) = w;
 994                         return 0;
 995                 }
 996         }
 997
 998         tmin = 0;
 999         tmax = 1;
1000         for (;;)
1001         {
1002                 if(tmax - tmin < 0.001)
1003                 {
1004                         // did not get a good candidate
1005                         return -1;
1006                 }
1007
1008                 t = (tmin + tmax) * 0.5;
1009                 o = antilag_takebackorigin(p, time - t);
1010                 if(!botframe_autowaypoints_fixdown(o))
1011                         return -2;
1012                 o = trace_endpos;
1013
1014                 if(wp)
1015                 {
1016                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
1017                         {
1018                                 // we cannot walk from wp.origin to o
1019                                 // get closer to tmax
1020                                 tmin = t;
1021                                 continue;
1022                         }
1023                 }
1024                 else
1025                 {
1026                         save = p.origin;
1027                         setorigin(p, o);
1028                         w = navigation_findnearestwaypoint(p, walkfromwp);
1029                         setorigin(p, save);
1030                         if(!w)
1031                         {
1032                                 // we cannot walk from any WP to o
1033                                 // get closer to tmax
1034                                 tmin = t;
1035                                 continue;
1036                         }
1037                 }
1038
1039                 // if we get here, o is valid regarding waypoints
1040                 // check if o is connected right to the player
1041                 // we break if it succeeds, as that means o is a good waypoint location
1042                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1043                         break;
1044
1045                 // o is no good, we need to get closer to the player
1046                 tmax = t;
1047         }
1048
1049         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1050         botframe_autowaypoints_createwp(o, p, fld, 0);
1051         return 1;
1052 }
1053
1054 // automatically create missing waypoints
1055 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1056 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1057 {
1058         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1059         if(r != -1)
1060                 return;
1061         r = botframe_autowaypoints_fix_from(p, walkfromwp, world, fld);
1062         if(r != -1)
1063                 return;
1064
1065         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1066         if(!botframe_autowaypoints_fixdown(p.origin))
1067                 return; // shouldn't happen, caught above
1068         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1069 }
1070
1071 void botframe_deleteuselesswaypoints()
1072 {
1073         entity w, w1, w2;
1074         float i, j, k;
1075         for (w = world; (w = findfloat(w, bot_pickup, true)); )
1076         {
1077                 // NOTE: this protects waypoints if they're the ONLY nearest
1078                 // waypoint. That's the intention.
1079                 navigation_findnearestwaypoint(w, false);  // Walk TO item.
1080                 navigation_findnearestwaypoint(w, true);  // Walk FROM item.
1081         }
1082         for (w = world; (w = find(w, classname, "waypoint")); )
1083         {
1084                 w.wpflags |= WAYPOINTFLAG_DEAD_END;
1085                 w.wpflags &= ~WAYPOINTFLAG_USEFUL;
1086                 // WP is useful if:
1087                 if (w.wpflags & WAYPOINTFLAG_ITEM)
1088                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1089                 if (w.wpflags & WAYPOINTFLAG_TELEPORT)
1090                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1091                 if (w.wpflags & WAYPOINTFLAG_PROTECTED)
1092                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1093                 // b) WP is closest WP for an item/spawnpoint/other entity
1094                 //    This has been done above by protecting these WPs.
1095         }
1096         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1097         for (w1 = world; (w1 = find(w1, classname, "waypoint")); )
1098         {
1099                 if (w1.wpflags & WAYPOINTFLAG_PERSONAL)
1100                         continue;
1101                 for (i = 0; i < 32; ++i)
1102                 {
1103                         w = waypoint_get_link(w1, i);
1104                         if (!w)
1105                                 break;
1106                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1107                                 continue;
1108                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1109                                 continue;
1110                         for (j = 0; j < 32; ++j)
1111                         {
1112                                 w2 = waypoint_get_link(w, j);
1113                                 if (!w2)
1114                                         break;
1115                                 if (w1 == w2)
1116                                         continue;
1117                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1118                                         continue;
1119                                 // If we got here, w1 != w2 exist with w1 -> w
1120                                 // and w -> w2. That means the waypoint is not
1121                                 // a dead end.
1122                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1123                                 for (k = 0; k < 32; ++k)
1124                                 {
1125                                         if (waypoint_get_link(w1, k) == w2)
1126                                                 continue;
1127                                         // IF WE GET HERE, w is proven useful
1128                                         // to get from w1 to w2!
1129                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1130                                         goto next;
1131                                 }
1132                         }
1133 :next
1134                 }
1135         }
1136         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1137         //     they are needed to complete routes while autowaypointing.
1138
1139         for (w = world; (w = find(w, classname, "waypoint")); )
1140         {
1141                 if (!(w.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)))
1142                 {
1143                         LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", w.origin);
1144                         te_explosion(w.origin);
1145                         waypoint_remove(w);
1146                         break;
1147                 }
1148         }
1149         for (w = world; (w = find(w, classname, "waypoint")); )
1150                 w.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1151 }
1152
1153 void botframe_autowaypoints()
1154 {
1155         entity p;
1156         FOR_EACH_REALPLAYER(p)
1157         {
1158                 if(p.deadflag)
1159                         continue;
1160                 // going back is broken, so only fix waypoints to walk TO the player
1161                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1162                 botframe_autowaypoints_fix(p, true, botframe_autowaypoints_lastwp1);
1163                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1164         }
1165
1166         if (autocvar_g_waypointeditor_auto >= 2) {
1167                 botframe_deleteuselesswaypoints();
1168         }
1169 }
1170