qcsrc/server/bot/waypoints.qc

   1 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
   2 // them back to it as well
   3 // (suitable for spawnfunc_waypoint editor)
   4 entity waypoint_spawn(vector m1, vector m2, float f)
   5 {
   6         local entity w;
   7         w = find(world, classname, "waypoint");
   8
   9         if not(f & WAYPOINTFLAG_PERSONAL)
  10         while (w)
  11         {
  12                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
  13                 if (boxesoverlap(m1, m2, w.absmin, w.absmax))
  14                         return w;
  15                 w = find(w, classname, "waypoint");
  16         }
  17
  18         w = spawn();
  19         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
  20         w.classname = "waypoint";
  21         w.wpflags = f;
  22         setorigin(w, (m1 + m2) * 0.5);
  23         setsize(w, m1 - w.origin, m2 - w.origin);
  24         if (vlen(w.size) > 0)
  25                 w.wpisbox = TRUE;
  26
  27         if(!w.wpisbox)
  28         {
  29                 setsize(w, PL_MIN - '1 1 0', PL_MAX + '1 1 0');
  30                 if(!move_out_of_solid(w))
  31                 {
  32                         if(!(f & WAYPOINTFLAG_GENERATED))
  33                         {
  34                                 dprint("Killed a waypoint that was stuck in solid at ", vtos(w.origin), "\n");
  35                                 remove(w);
  36                                 return world;
  37                         }
  38                         else
  39                         {
  40                                 if(autocvar_developer)
  41                                 {
  42                                         print("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
  43                                         backtrace("Waypoint stuck");
  44                                 }
  45                         }
  46                 }
  47                 setsize(w, '0 0 0', '0 0 0');
  48         }
  49
  50         waypoint_clearlinks(w);
  51         //waypoint_schedulerelink(w);
  52
  53         if (autocvar_g_waypointeditor)
  54         {
  55                 m1 = w.mins;
  56                 m2 = w.maxs;
  57                 setmodel(w, "models/runematch/rune.mdl"); w.effects = EF_LOWPRECISION;
  58                 setsize(w, m1, m2);
  59                 if (w.wpflags & WAYPOINTFLAG_ITEM)
  60                         w.colormod = '1 0 0';
  61                 else if (w.wpflags & WAYPOINTFLAG_GENERATED)
  62                         w.colormod = '1 1 0';
  63                 else
  64                         w.colormod = '1 1 1';
  65         }
  66         else
  67                 w.model = "";
  68
  69         return w;
  70 };
  71
  72 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
  73 void waypoint_addlink(entity from, entity to)
  74 {
  75         local float c;
  76
  77         if (from == to)
  78                 return;
  79         if (from.wpflags & WAYPOINTFLAG_NORELINK)
  80                 return;
  81
  82         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
  83         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
  84         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
  85         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
  86         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
  87         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
  88         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
  89         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
  90
  91         if (to.wpisbox || from.wpisbox)
  92         {
  93                 // if either is a box we have to find the nearest points on them to
  94                 // calculate the distance properly
  95                 local vector v1, v2, m1, m2;
  96                 v1 = from.origin;
  97                 m1 = to.absmin;
  98                 m2 = to.absmax;
  99                 v1_x = bound(m1_x, v1_x, m2_x);
 100                 v1_y = bound(m1_y, v1_y, m2_y);
 101                 v1_z = bound(m1_z, v1_z, m2_z);
 102                 v2 = to.origin;
 103                 m1 = from.absmin;
 104                 m2 = from.absmax;
 105                 v2_x = bound(m1_x, v2_x, m2_x);
 106                 v2_y = bound(m1_y, v2_y, m2_y);
 107                 v2_z = bound(m1_z, v2_z, m2_z);
 108                 v2 = to.origin;
 109                 c = vlen(v2 - v1);
 110         }
 111         else
 112                 c = vlen(to.origin - from.origin);
 113
 114         if (from.wp31mincost < c) return;
 115         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 116         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 117         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 118         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 119         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 120         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 121         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 122         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 123         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 124         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 125         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 126         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 127         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 128         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 129         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 130         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 131         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 132         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 133         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 134         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 135         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 136         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 137         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 138         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 139         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 140         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 141         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 142         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 143         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 144         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 145         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 146         from.wp00 = to;from.wp00mincost = c;return;
 147 };
 148
 149 // relink this spawnfunc_waypoint
 150 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 151 // (SLOW!)
 152 void waypoint_think()
 153 {
 154         local entity e;
 155         local vector sv, sm1, sm2, ev, em1, em2, dv;
 156
 157         bot_calculate_stepheightvec();
 158
 159         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 160
 161         //dprint("waypoint_think wpisbox = ", ftos(self.wpisbox), "\n");
 162         sm1 = self.origin + self.mins;
 163         sm2 = self.origin + self.maxs;
 164         for(e = world; (e = find(e, classname, "waypoint")); )
 165         {
 166                 if (boxesoverlap(self.absmin, self.absmax, e.absmin, e.absmax))
 167                 {
 168                         waypoint_addlink(self, e);
 169                         waypoint_addlink(e, self);
 170                 }
 171                 else
 172                 {
 173                         ++relink_total;
 174                         if(!checkpvs(self.origin, e))
 175                         {
 176                                 ++relink_pvsculled;
 177                                 continue;
 178                         }
 179                         sv = e.origin;
 180                         sv_x = bound(sm1_x, sv_x, sm2_x);
 181                         sv_y = bound(sm1_y, sv_y, sm2_y);
 182                         sv_z = bound(sm1_z, sv_z, sm2_z);
 183                         ev = self.origin;
 184                         em1 = e.origin + e.mins;
 185                         em2 = e.origin + e.maxs;
 186                         ev_x = bound(em1_x, ev_x, em2_x);
 187                         ev_y = bound(em1_y, ev_y, em2_y);
 188                         ev_z = bound(em1_z, ev_z, em2_z);
 189                         dv = ev - sv;
 190                         dv_z = 0;
 191                         if (vlen(dv) >= 1050) // max search distance in XY
 192                         {
 193                                 ++relink_lengthculled;
 194                                 continue;
 195                         }
 196                         navigation_testtracewalk = 0;
 197                         if (!self.wpisbox)
 198                         {
 199                                 tracebox(sv - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, sv, FALSE, self);
 200                                 if (!trace_startsolid)
 201                                 {
 202                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 203                                         sv = trace_endpos + '0 0 1';
 204                                 }
 205                         }
 206                         if (!e.wpisbox)
 207                         {
 208                                 tracebox(ev - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, ev, FALSE, e);
 209                                 if (!trace_startsolid)
 210                                 {
 211                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 212                                         ev = trace_endpos + '0 0 1';
 213                                 }
 214                         }
 215                         //traceline(self.origin, e.origin, FALSE, world);
 216                         //if (trace_fraction == 1)
 217                         if (!self.wpisbox && tracewalk(self, sv, PL_MIN, PL_MAX, ev, MOVE_NOMONSTERS))
 218                                 waypoint_addlink(self, e);
 219                         else
 220                                 relink_walkculled += 0.5;
 221                         if (!e.wpisbox && tracewalk(e, ev, PL_MIN, PL_MAX, sv, MOVE_NOMONSTERS))
 222                                 waypoint_addlink(e, self);
 223                         else
 224                                 relink_walkculled += 0.5;
 225                 }
 226         }
 227         navigation_testtracewalk = 0;
 228         self.wplinked = TRUE;
 229 };
 230
 231 void waypoint_clearlinks(entity wp)
 232 {
 233         // clear links to other waypoints
 234         local float f;
 235         f = 10000000;
 236         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = world;
 237         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = world;
 238         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = world;
 239         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = world;
 240
 241         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 242         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 243         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 244         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 245
 246         wp.wplinked = FALSE;
 247 };
 248
 249 // tell a spawnfunc_waypoint to relink
 250 void waypoint_schedulerelink(entity wp)
 251 {
 252         if (wp == world)
 253                 return;
 254         // TODO: add some sort of visible box in edit mode for box waypoints
 255         if (autocvar_g_waypointeditor)
 256         {
 257                 local vector m1, m2;
 258                 m1 = wp.mins;
 259                 m2 = wp.maxs;
 260                 setmodel(wp, "models/runematch/rune.mdl"); wp.effects = EF_LOWPRECISION;
 261                 setsize(wp, m1, m2);
 262                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 263                         wp.colormod = '1 0 0';
 264                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 265                         wp.colormod = '1 1 0';
 266                 else
 267                         wp.colormod = '1 1 1';
 268         }
 269         else
 270                 wp.model = "";
 271         wp.wpisbox = vlen(wp.size) > 0;
 272         wp.enemy = world;
 273         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 274                 wp.owner = world;
 275         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 276                 waypoint_clearlinks(wp);
 277         // schedule an actual relink on next frame
 278         wp.think = waypoint_think;
 279         wp.nextthink = time;
 280         wp.effects = EF_LOWPRECISION;
 281 }
 282
 283 // spawnfunc_waypoint map entity
 284 void spawnfunc_waypoint()
 285 {
 286         setorigin(self, self.origin);
 287         // schedule a relink after other waypoints have had a chance to spawn
 288         waypoint_clearlinks(self);
 289         //waypoint_schedulerelink(self);
 290 };
 291
 292 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 293 void waypoint_remove(entity e)
 294 {
 295         // tell all linked waypoints that they need to relink
 296         waypoint_schedulerelink(e.wp00);
 297         waypoint_schedulerelink(e.wp01);
 298         waypoint_schedulerelink(e.wp02);
 299         waypoint_schedulerelink(e.wp03);
 300         waypoint_schedulerelink(e.wp04);
 301         waypoint_schedulerelink(e.wp05);
 302         waypoint_schedulerelink(e.wp06);
 303         waypoint_schedulerelink(e.wp07);
 304         waypoint_schedulerelink(e.wp08);
 305         waypoint_schedulerelink(e.wp09);
 306         waypoint_schedulerelink(e.wp10);
 307         waypoint_schedulerelink(e.wp11);
 308         waypoint_schedulerelink(e.wp12);
 309         waypoint_schedulerelink(e.wp13);
 310         waypoint_schedulerelink(e.wp14);
 311         waypoint_schedulerelink(e.wp15);
 312         waypoint_schedulerelink(e.wp16);
 313         waypoint_schedulerelink(e.wp17);
 314         waypoint_schedulerelink(e.wp18);
 315         waypoint_schedulerelink(e.wp19);
 316         waypoint_schedulerelink(e.wp20);
 317         waypoint_schedulerelink(e.wp21);
 318         waypoint_schedulerelink(e.wp22);
 319         waypoint_schedulerelink(e.wp23);
 320         waypoint_schedulerelink(e.wp24);
 321         waypoint_schedulerelink(e.wp25);
 322         waypoint_schedulerelink(e.wp26);
 323         waypoint_schedulerelink(e.wp27);
 324         waypoint_schedulerelink(e.wp28);
 325         waypoint_schedulerelink(e.wp29);
 326         waypoint_schedulerelink(e.wp30);
 327         waypoint_schedulerelink(e.wp31);
 328         // and now remove the spawnfunc_waypoint
 329         remove(e);
 330 };
 331
 332 // empties the map of waypoints
 333 void waypoint_removeall()
 334 {
 335         local entity head, next;
 336         head = findchain(classname, "waypoint");
 337         while (head)
 338         {
 339                 next = head.chain;
 340                 remove(head);
 341                 head = next;
 342         }
 343 };
 344
 345 // tell all waypoints to relink
 346 // (is this useful at all?)
 347 void waypoint_schedulerelinkall()
 348 {
 349         local entity head;
 350         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 351         head = findchain(classname, "waypoint");
 352         while (head)
 353         {
 354                 waypoint_schedulerelink(head);
 355                 head = head.chain;
 356         }
 357 };
 358
 359 // Load waypoint links from file
 360 float waypoint_load_links()
 361 {
 362         local string filename, s;
 363         local float file, tokens, c, found;
 364         local entity wp_from, wp_to;
 365         local vector wp_to_pos, wp_from_pos;
 366         filename = strcat("maps/", mapname);
 367         filename = strcat(filename, ".waypoints.cache");
 368         file = fopen(filename, FILE_READ);
 369
 370         if (file < 0)
 371         {
 372                 dprint("waypoint links load from ");
 373                 dprint(filename);
 374                 dprint(" failed\n");
 375                 return FALSE;
 376         }
 377
 378         while (1)
 379         {
 380                 s = fgets(file);
 381                 if (!s)
 382                         break;
 383
 384                 tokens = tokenizebyseparator(s, "*");
 385
 386                 if (tokens!=2)
 387                 {
 388                         // bad file format
 389                         fclose(file);
 390                         return FALSE;
 391                 }
 392
 393                 wp_from_pos     = stov(argv(0));
 394                 wp_to_pos       = stov(argv(1));
 395
 396                 // Search "from" waypoint
 397                 if(wp_from.origin!=wp_from_pos)
 398                 {
 399                         wp_from = findradius(wp_from_pos, 1);
 400                         found = FALSE;
 401                         while(wp_from)
 402                         {
 403                                 if(vlen(wp_from.origin-wp_from_pos)<1)
 404                                 if(wp_from.classname == "waypoint")
 405                                 {
 406                                         found = TRUE;
 407                                         break;
 408                                 }
 409                                 wp_from = wp_from.chain;
 410                         }
 411
 412                         if(!found)
 413                         {
 414                                 dprint("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from.origin),"\n");
 415                                 continue;
 416                         }
 417
 418                 }
 419
 420                 // Search "to" waypoint
 421                 wp_to = findradius(wp_to_pos, 1);
 422                 found = FALSE;
 423                 while(wp_to)
 424                 {
 425                         if(vlen(wp_to.origin-wp_to_pos)<1)
 426                         if(wp_to.classname == "waypoint")
 427                         {
 428                                 found = TRUE;
 429                                 break;
 430                         }
 431                         wp_to = wp_to.chain;
 432                 }
 433
 434                 if(!found)
 435                 {
 436                         dprint("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to.origin),"\n");
 437                         continue;
 438                 }
 439
 440                 ++c;
 441                 waypoint_addlink(wp_from, wp_to);
 442         }
 443
 444         fclose(file);
 445
 446         dprint("loaded ");
 447         dprint(ftos(c));
 448         dprint(" waypoint links from maps/");
 449         dprint(mapname);
 450         dprint(".waypoints.cache\n");
 451
 452         botframe_cachedwaypointlinks = TRUE;
 453         return TRUE;
 454 };
 455
 456 void waypoint_load_links_hardwired()
 457 {
 458         local string filename, s;
 459         local float file, tokens, c, found;
 460         local entity wp_from, wp_to;
 461         local vector wp_to_pos, wp_from_pos;
 462         filename = strcat("maps/", mapname);
 463         filename = strcat(filename, ".waypoints.hardwired");
 464         file = fopen(filename, FILE_READ);
 465
 466         botframe_loadedforcedlinks = TRUE;
 467
 468         if (file < 0)
 469         {
 470                 dprint("waypoint links load from ");
 471                 dprint(filename);
 472                 dprint(" failed\n");
 473                 return;
 474         }
 475
 476         for (;;)
 477         {
 478                 s = fgets(file);
 479                 if (!s)
 480                         break;
 481
 482                 if(substring(s, 0, 2)=="//")
 483                         continue;
 484
 485                 if(substring(s, 0, 1)=="#")
 486                         continue;
 487
 488                 tokens = tokenizebyseparator(s, "*");
 489
 490                 if (tokens!=2)
 491                         continue;
 492
 493                 wp_from_pos     = stov(argv(0));
 494                 wp_to_pos       = stov(argv(1));
 495
 496                 // Search "from" waypoint
 497                 if(wp_from.origin!=wp_from_pos)
 498                 {
 499                         wp_from = findradius(wp_from_pos, 5);
 500                         found = FALSE;
 501                         while(wp_from)
 502                         {
 503                                 if(vlen(wp_from.origin-wp_from_pos)<5)
 504                                 if(wp_from.classname == "waypoint")
 505                                 {
 506                                         found = TRUE;
 507                                         break;
 508                                 }
 509                                 wp_from = wp_from.chain;
 510                         }
 511
 512                         if(!found)
 513                         {
 514                                 print(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 515                                 continue;
 516                         }
 517                 }
 518
 519                 // Search "to" waypoint
 520                 wp_to = findradius(wp_to_pos, 5);
 521                 found = FALSE;
 522                 while(wp_to)
 523                 {
 524                         if(vlen(wp_to.origin-wp_to_pos)<5)
 525                         if(wp_to.classname == "waypoint")
 526                         {
 527                                 found = TRUE;
 528                                 break;
 529                         }
 530                         wp_to = wp_to.chain;
 531                 }
 532
 533                 if(!found)
 534                 {
 535                         print(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 536                         continue;
 537                 }
 538
 539                 ++c;
 540                 waypoint_addlink(wp_from, wp_to);
 541                 wp_from.wphardwired = TRUE;
 542                 wp_to.wphardwired = TRUE;
 543         }
 544
 545         fclose(file);
 546
 547         dprint("loaded ");
 548         dprint(ftos(c));
 549         dprint(" waypoint links from maps/");
 550         dprint(mapname);
 551         dprint(".waypoints.hardwired\n");
 552 };
 553
 554 // Save all waypoint links to a file
 555 void waypoint_save_links()
 556 {
 557         local string filename, s;
 558         local float file, c, i;
 559         local entity w, link;
 560         filename = strcat("maps/", mapname);
 561         filename = strcat(filename, ".waypoints.cache");
 562         file = fopen(filename, FILE_WRITE);
 563         if (file < 0)
 564         {
 565                 print("waypoint links save to ");
 566                 print(filename);
 567                 print(" failed\n");
 568         }
 569         c = 0;
 570         w = findchain(classname, "waypoint");
 571         while (w)
 572         {
 573                 for(i=0;i<32;++i)
 574                 {
 575                         // :S
 576                         switch(i)
 577                         {
 578                                 //      for i in $(seq -w 0 31); do echo "case $i:link = w.wp$i; break;"; done;
 579                                 case 00:link = w.wp00; break;
 580                                 case 01:link = w.wp01; break;
 581                                 case 02:link = w.wp02; break;
 582                                 case 03:link = w.wp03; break;
 583                                 case 04:link = w.wp04; break;
 584                                 case 05:link = w.wp05; break;
 585                                 case 06:link = w.wp06; break;
 586                                 case 07:link = w.wp07; break;
 587                                 case 08:link = w.wp08; break;
 588                                 case 09:link = w.wp09; break;
 589                                 case 10:link = w.wp10; break;
 590                                 case 11:link = w.wp11; break;
 591                                 case 12:link = w.wp12; break;
 592                                 case 13:link = w.wp13; break;
 593                                 case 14:link = w.wp14; break;
 594                                 case 15:link = w.wp15; break;
 595                                 case 16:link = w.wp16; break;
 596                                 case 17:link = w.wp17; break;
 597                                 case 18:link = w.wp18; break;
 598                                 case 19:link = w.wp19; break;
 599                                 case 20:link = w.wp20; break;
 600                                 case 21:link = w.wp21; break;
 601                                 case 22:link = w.wp22; break;
 602                                 case 23:link = w.wp23; break;
 603                                 case 24:link = w.wp24; break;
 604                                 case 25:link = w.wp25; break;
 605                                 case 26:link = w.wp26; break;
 606                                 case 27:link = w.wp27; break;
 607                                 case 28:link = w.wp28; break;
 608                                 case 29:link = w.wp29; break;
 609                                 case 30:link = w.wp30; break;
 610                                 case 31:link = w.wp31; break;
 611                         }
 612
 613                         if(link==world)
 614                                 continue;
 615
 616                         s = strcat(vtos(w.origin), "*", vtos(link.origin), "\n");
 617                         fputs(file, s);
 618                         ++c;
 619                 }
 620                 w = w.chain;
 621         }
 622         fclose(file);
 623         botframe_cachedwaypointlinks = TRUE;
 624
 625         print("saved ");
 626         print(ftos(c));
 627         print(" waypoints links to maps/");
 628         print(mapname);
 629         print(".waypoints.cache\n");
 630 };
 631
 632 // save waypoints to gamedir/data/maps/mapname.waypoints
 633 void waypoint_saveall()
 634 {
 635         local string filename, s;
 636         local float file, c;
 637         local entity w;
 638         filename = strcat("maps/", mapname);
 639         filename = strcat(filename, ".waypoints");
 640         file = fopen(filename, FILE_WRITE);
 641         if (file >= 0)
 642         {
 643                 c = 0;
 644                 w = findchain(classname, "waypoint");
 645                 while (w)
 646                 {
 647                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
 648                         {
 649                                 s = strcat(vtos(w.origin + w.mins), "\n");
 650                                 s = strcat(s, vtos(w.origin + w.maxs));
 651                                 s = strcat(s, "\n");
 652                                 s = strcat(s, ftos(w.wpflags));
 653                                 s = strcat(s, "\n");
 654                                 fputs(file, s);
 655                                 c = c + 1;
 656                         }
 657                         w = w.chain;
 658                 }
 659                 fclose(file);
 660                 bprint("saved ");
 661                 bprint(ftos(c));
 662                 bprint(" waypoints to maps/");
 663                 bprint(mapname);
 664                 bprint(".waypoints\n");
 665         }
 666         else
 667         {
 668                 bprint("waypoint save to ");
 669                 bprint(filename);
 670                 bprint(" failed\n");
 671         }
 672         waypoint_save_links();
 673         botframe_loadedforcedlinks = FALSE;
 674 };
 675
 676 // load waypoints from file
 677 float waypoint_loadall()
 678 {
 679         local string filename, s;
 680         local float file, cwp, cwb, fl;
 681         local vector m1, m2;
 682         cwp = 0;
 683         cwb = 0;
 684         filename = strcat("maps/", mapname);
 685         filename = strcat(filename, ".waypoints");
 686         file = fopen(filename, FILE_READ);
 687         if (file >= 0)
 688         {
 689                 while (1)
 690                 {
 691                         s = fgets(file);
 692                         if (!s)
 693                                 break;
 694                         m1 = stov(s);
 695                         s = fgets(file);
 696                         if (!s)
 697                                 break;
 698                         m2 = stov(s);
 699                         s = fgets(file);
 700                         if (!s)
 701                                 break;
 702                         fl = stof(s);
 703                         waypoint_spawn(m1, m2, fl);
 704                         if (m1 == m2)
 705                                 cwp = cwp + 1;
 706                         else
 707                                 cwb = cwb + 1;
 708                 }
 709                 fclose(file);
 710                 dprint("loaded ");
 711                 dprint(ftos(cwp));
 712                 dprint(" waypoints and ");
 713                 dprint(ftos(cwb));
 714                 dprint(" wayboxes from maps/");
 715                 dprint(mapname);
 716                 dprint(".waypoints\n");
 717         }
 718         else
 719         {
 720                 dprint("waypoint load from ");
 721                 dprint(filename);
 722                 dprint(" failed\n");
 723         }
 724         return cwp + cwb;
 725 };
 726
 727 vector waypoint_fixorigin(vector position)
 728 {
 729         tracebox(position + '0 0 1' * (1 - PL_MIN_z), PL_MIN, PL_MAX, position + '0 0 -512', MOVE_NOMONSTERS, world);
 730         if(trace_fraction < 1)
 731                 position = trace_endpos;
 732         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, world);
 733         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 734         return position;
 735 }
 736
 737 void waypoint_spawnforitem_force(entity e, vector org)
 738 {
 739         local entity w;
 740
 741         // Fix the waypoint altitude if necessary
 742         org = waypoint_fixorigin(org);
 743
 744         // don't spawn an item spawnfunc_waypoint if it already exists
 745         w = findchain(classname, "waypoint");
 746         while (w)
 747         {
 748                 if (w.wpisbox)
 749                 {
 750                         if (boxesoverlap(org, org, w.absmin, w.absmax))
 751                         {
 752                                 e.nearestwaypoint = w;
 753                                 return;
 754                         }
 755                 }
 756                 else
 757                 {
 758                         if (vlen(w.origin - org) < 16)
 759                         {
 760                                 e.nearestwaypoint = w;
 761                                 return;
 762                         }
 763                 }
 764                 w = w.chain;
 765         }
 766         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 767 }
 768
 769 void waypoint_spawnforitem(entity e)
 770 {
 771         if(!bot_waypoints_for_items)
 772                 return;
 773
 774         waypoint_spawnforitem_force(e, e.origin);
 775 };
 776
 777 void waypoint_spawnforteleporter_boxes(entity e, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
 778 {
 779         local entity w;
 780         local entity dw;
 781         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 782         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
 783         // one way link to the destination
 784         w.wp00 = dw;
 785         w.wp00mincost = timetaken; // this is just for jump pads
 786         // the teleporter's nearest spawnfunc_waypoint is this one
 787         // (teleporters are not goals, so this is probably useless)
 788         e.nearestwaypoint = w;
 789         e.nearestwaypointtimeout = time + 1000000000;
 790 };
 791
 792 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
 793 {
 794         org = waypoint_fixorigin(org);
 795         destination = waypoint_fixorigin(destination);
 796         waypoint_spawnforteleporter_boxes(e, org, org, destination, destination, timetaken);
 797 };
 798
 799 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 800 {
 801         destination = waypoint_fixorigin(destination);
 802         waypoint_spawnforteleporter_boxes(e, e.absmin, e.absmax, destination, destination, timetaken);
 803 };
 804
 805 entity waypoint_spawnpersonal(vector position)
 806 {
 807         entity w;
 808
 809         // drop the waypoint to a proper location:
 810         //   first move it up by a player height
 811         //   then move it down to hit the floor with player bbox size
 812         position = waypoint_fixorigin(position);
 813
 814         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
 815         w.nearestwaypoint = world;
 816         w.nearestwaypointtimeout = 0;
 817         w.owner = self;
 818
 819         waypoint_schedulerelink(w);
 820
 821         return w;
 822 };
 823
 824 void botframe_showwaypointlinks()
 825 {
 826         local entity player, head, w;
 827         if (time < botframe_waypointeditorlightningtime)
 828                 return;
 829         botframe_waypointeditorlightningtime = time + 0.5;
 830         player = find(world, classname, "player");
 831         while (player)
 832         {
 833                 if (!player.isbot)
 834                 if (player.flags & FL_ONGROUND || player.waterlevel > WATERLEVEL_NONE)
 835                 {
 836                         //navigation_testtracewalk = TRUE;
 837                         head = navigation_findnearestwaypoint(player, FALSE);
 838                 //      print("currently selected WP is ", etos(head), "\n");
 839                         //navigation_testtracewalk = FALSE;
 840                         if (head)
 841                         {
 842                                 w = head     ;if (w) te_lightning2(world, w.origin, player.origin);
 843                                 w = head.wp00;if (w) te_lightning2(world, w.origin, head.origin);
 844                                 w = head.wp01;if (w) te_lightning2(world, w.origin, head.origin);
 845                                 w = head.wp02;if (w) te_lightning2(world, w.origin, head.origin);
 846                                 w = head.wp03;if (w) te_lightning2(world, w.origin, head.origin);
 847                                 w = head.wp04;if (w) te_lightning2(world, w.origin, head.origin);
 848                                 w = head.wp05;if (w) te_lightning2(world, w.origin, head.origin);
 849                                 w = head.wp06;if (w) te_lightning2(world, w.origin, head.origin);
 850                                 w = head.wp07;if (w) te_lightning2(world, w.origin, head.origin);
 851                                 w = head.wp08;if (w) te_lightning2(world, w.origin, head.origin);
 852                                 w = head.wp09;if (w) te_lightning2(world, w.origin, head.origin);
 853                                 w = head.wp10;if (w) te_lightning2(world, w.origin, head.origin);
 854                                 w = head.wp11;if (w) te_lightning2(world, w.origin, head.origin);
 855                                 w = head.wp12;if (w) te_lightning2(world, w.origin, head.origin);
 856                                 w = head.wp13;if (w) te_lightning2(world, w.origin, head.origin);
 857                                 w = head.wp14;if (w) te_lightning2(world, w.origin, head.origin);
 858                                 w = head.wp15;if (w) te_lightning2(world, w.origin, head.origin);
 859                                 w = head.wp16;if (w) te_lightning2(world, w.origin, head.origin);
 860                                 w = head.wp17;if (w) te_lightning2(world, w.origin, head.origin);
 861                                 w = head.wp18;if (w) te_lightning2(world, w.origin, head.origin);
 862                                 w = head.wp19;if (w) te_lightning2(world, w.origin, head.origin);
 863                                 w = head.wp20;if (w) te_lightning2(world, w.origin, head.origin);
 864                                 w = head.wp21;if (w) te_lightning2(world, w.origin, head.origin);
 865                                 w = head.wp22;if (w) te_lightning2(world, w.origin, head.origin);
 866                                 w = head.wp23;if (w) te_lightning2(world, w.origin, head.origin);
 867                                 w = head.wp24;if (w) te_lightning2(world, w.origin, head.origin);
 868                                 w = head.wp25;if (w) te_lightning2(world, w.origin, head.origin);
 869                                 w = head.wp26;if (w) te_lightning2(world, w.origin, head.origin);
 870                                 w = head.wp27;if (w) te_lightning2(world, w.origin, head.origin);
 871                                 w = head.wp28;if (w) te_lightning2(world, w.origin, head.origin);
 872                                 w = head.wp29;if (w) te_lightning2(world, w.origin, head.origin);
 873                                 w = head.wp30;if (w) te_lightning2(world, w.origin, head.origin);
 874                                 w = head.wp31;if (w) te_lightning2(world, w.origin, head.origin);
 875                         }
 876                 }
 877                 player = find(player, classname, "player");
 878         }
 879 };