qcsrc/server/bot/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "bot.qh"
   4 #include "navigation.qh"
   5
   6 #include <common/state.qh>
   7
   8 #include "../antilag.qh"
   9
  10 #include <common/constants.qh>
  11
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14
  15 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
  16 // them back to it as well
  17 // (suitable for spawnfunc_waypoint editor)
  18 entity waypoint_spawn(vector m1, vector m2, float f)
  19 {
  20         entity w;
  21         w = find(NULL, classname, "waypoint");
  22
  23         if (!(f & WAYPOINTFLAG_PERSONAL))
  24         while (w)
  25         {
  26                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
  27                 if (boxesoverlap(m1, m2, w.absmin, w.absmax))
  28                         return w;
  29                 w = find(w, classname, "waypoint");
  30         }
  31
  32         w = new(waypoint);
  33         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
  34         w.wpflags = f;
  35         w.solid = SOLID_TRIGGER;
  36         setorigin(w, (m1 + m2) * 0.5);
  37         setsize(w, m1 - w.origin, m2 - w.origin);
  38         if (vlen(w.size) > 0)
  39                 w.wpisbox = true;
  40
  41         if(!w.wpisbox)
  42         {
  43                 setsize(w, STAT(PL_MIN, NULL) - '1 1 0', STAT(PL_MAX, NULL) + '1 1 0');
  44                 if(!move_out_of_solid(w))
  45                 {
  46                         if(!(f & WAYPOINTFLAG_GENERATED))
  47                         {
  48                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin), "\n");
  49                                 remove(w);
  50                                 return NULL;
  51                         }
  52                         else
  53                         {
  54                                 if(autocvar_developer)
  55                                 {
  56                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
  57                                         backtrace("Waypoint stuck");
  58                                 }
  59                         }
  60                 }
  61                 setsize(w, '0 0 0', '0 0 0');
  62         }
  63
  64         waypoint_clearlinks(w);
  65         //waypoint_schedulerelink(w);
  66
  67         if (autocvar_g_waypointeditor)
  68         {
  69                 m1 = w.mins;
  70                 m2 = w.maxs;
  71                 setmodel(w, MDL_WAYPOINT); w.effects = EF_LOWPRECISION;
  72                 setsize(w, m1, m2);
  73                 if (w.wpflags & WAYPOINTFLAG_ITEM)
  74                         w.colormod = '1 0 0';
  75                 else if (w.wpflags & WAYPOINTFLAG_GENERATED)
  76                         w.colormod = '1 1 0';
  77                 else
  78                         w.colormod = '1 1 1';
  79         }
  80         else
  81                 w.model = "";
  82
  83         return w;
  84 }
  85
  86 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
  87 void waypoint_addlink(entity from, entity to)
  88 {
  89         float c;
  90
  91         if (from == to)
  92                 return;
  93         if (from.wpflags & WAYPOINTFLAG_NORELINK)
  94                 return;
  95
  96         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
  97         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
  98         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
  99         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
 100         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
 101         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
 102         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
 103         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
 104
 105         if (to.wpisbox || from.wpisbox)
 106         {
 107                 // if either is a box we have to find the nearest points on them to
 108                 // calculate the distance properly
 109                 vector v1, v2, m1, m2;
 110                 v1 = from.origin;
 111                 m1 = to.absmin;
 112                 m2 = to.absmax;
 113                 v1_x = bound(m1_x, v1_x, m2_x);
 114                 v1_y = bound(m1_y, v1_y, m2_y);
 115                 v1_z = bound(m1_z, v1_z, m2_z);
 116                 v2 = to.origin;
 117                 m1 = from.absmin;
 118                 m2 = from.absmax;
 119                 v2_x = bound(m1_x, v2_x, m2_x);
 120                 v2_y = bound(m1_y, v2_y, m2_y);
 121                 v2_z = bound(m1_z, v2_z, m2_z);
 122                 v2 = to.origin;
 123                 c = vlen(v2 - v1);
 124         }
 125         else
 126                 c = vlen(to.origin - from.origin);
 127
 128         if (from.wp31mincost < c) return;
 129         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 130         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 131         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 132         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 133         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 134         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 135         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 136         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 137         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 138         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 139         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 140         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 141         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 142         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 143         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 144         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 145         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 146         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 147         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 148         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 149         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 150         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 151         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 152         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 153         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 154         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 155         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 156         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 157         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 158         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 159         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 160         from.wp00 = to;from.wp00mincost = c;return;
 161 }
 162
 163 // relink this spawnfunc_waypoint
 164 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 165 // (SLOW!)
 166 void waypoint_think(entity this)
 167 {
 168         entity e;
 169         vector sv, sm1, sm2, ev, em1, em2, dv;
 170
 171         bot_calculate_stepheightvec();
 172
 173         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 174
 175         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 176         sm1 = this.origin + this.mins;
 177         sm2 = this.origin + this.maxs;
 178         for(e = NULL; (e = find(e, classname, "waypoint")); )
 179         {
 180                 if (boxesoverlap(this.absmin, this.absmax, e.absmin, e.absmax))
 181                 {
 182                         waypoint_addlink(this, e);
 183                         waypoint_addlink(e, this);
 184                 }
 185                 else
 186                 {
 187                         ++relink_total;
 188                         if(!checkpvs(this.origin, e))
 189                         {
 190                                 ++relink_pvsculled;
 191                                 continue;
 192                         }
 193                         sv = e.origin;
 194                         sv.x = bound(sm1_x, sv.x, sm2_x);
 195                         sv.y = bound(sm1_y, sv.y, sm2_y);
 196                         sv.z = bound(sm1_z, sv.z, sm2_z);
 197                         ev = this.origin;
 198                         em1 = e.origin + e.mins;
 199                         em2 = e.origin + e.maxs;
 200                         ev.x = bound(em1_x, ev.x, em2_x);
 201                         ev.y = bound(em1_y, ev.y, em2_y);
 202                         ev.z = bound(em1_z, ev.z, em2_z);
 203                         dv = ev - sv;
 204                         dv.z = 0;
 205                         if(vdist(dv, >=, 1050)) // max search distance in XY
 206                         {
 207                                 ++relink_lengthculled;
 208                                 continue;
 209                         }
 210                         navigation_testtracewalk = 0;
 211                         if (!this.wpisbox)
 212                         {
 213                                 tracebox(sv - STAT(PL_MIN, NULL).z * '0 0 1', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), sv, false, this);
 214                                 if (!trace_startsolid)
 215                                 {
 216                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 217                                         sv = trace_endpos + '0 0 1';
 218                                 }
 219                         }
 220                         if (!e.wpisbox)
 221                         {
 222                                 tracebox(ev - STAT(PL_MIN, NULL).z * '0 0 1', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), ev, false, e);
 223                                 if (!trace_startsolid)
 224                                 {
 225                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 226                                         ev = trace_endpos + '0 0 1';
 227                                 }
 228                         }
 229                         //traceline(this.origin, e.origin, false, NULL);
 230                         //if (trace_fraction == 1)
 231                         if (!this.wpisbox && tracewalk(this, sv, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), ev, MOVE_NOMONSTERS))
 232                                 waypoint_addlink(this, e);
 233                         else
 234                                 relink_walkculled += 0.5;
 235                         if (!e.wpisbox && tracewalk(e, ev, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), sv, MOVE_NOMONSTERS))
 236                                 waypoint_addlink(e, this);
 237                         else
 238                                 relink_walkculled += 0.5;
 239                 }
 240         }
 241         navigation_testtracewalk = 0;
 242         this.wplinked = true;
 243 }
 244
 245 void waypoint_clearlinks(entity wp)
 246 {
 247         // clear links to other waypoints
 248         float f;
 249         f = 10000000;
 250         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 251         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 252         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 253         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 254
 255         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 256         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 257         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 258         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 259
 260         wp.wplinked = false;
 261 }
 262
 263 // tell a spawnfunc_waypoint to relink
 264 void waypoint_schedulerelink(entity wp)
 265 {
 266         if (wp == NULL)
 267                 return;
 268         // TODO: add some sort of visible box in edit mode for box waypoints
 269         if (autocvar_g_waypointeditor)
 270         {
 271                 vector m1, m2;
 272                 m1 = wp.mins;
 273                 m2 = wp.maxs;
 274                 setmodel(wp, MDL_WAYPOINT); wp.effects = EF_LOWPRECISION;
 275                 setsize(wp, m1, m2);
 276                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 277                         wp.colormod = '1 0 0';
 278                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 279                         wp.colormod = '1 1 0';
 280                 else
 281                         wp.colormod = '1 1 1';
 282         }
 283         else
 284                 wp.model = "";
 285         wp.wpisbox = vlen(wp.size) > 0;
 286         wp.enemy = NULL;
 287         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 288                 wp.owner = NULL;
 289         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 290                 waypoint_clearlinks(wp);
 291         // schedule an actual relink on next frame
 292         setthink(wp, waypoint_think);
 293         wp.nextthink = time;
 294         wp.effects = EF_LOWPRECISION;
 295 }
 296
 297 // spawnfunc_waypoint map entity
 298 spawnfunc(waypoint)
 299 {
 300         setorigin(this, this.origin);
 301         // schedule a relink after other waypoints have had a chance to spawn
 302         waypoint_clearlinks(this);
 303         //waypoint_schedulerelink(this);
 304 }
 305
 306 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 307 void waypoint_remove(entity e)
 308 {
 309         // tell all linked waypoints that they need to relink
 310         waypoint_schedulerelink(e.wp00);
 311         waypoint_schedulerelink(e.wp01);
 312         waypoint_schedulerelink(e.wp02);
 313         waypoint_schedulerelink(e.wp03);
 314         waypoint_schedulerelink(e.wp04);
 315         waypoint_schedulerelink(e.wp05);
 316         waypoint_schedulerelink(e.wp06);
 317         waypoint_schedulerelink(e.wp07);
 318         waypoint_schedulerelink(e.wp08);
 319         waypoint_schedulerelink(e.wp09);
 320         waypoint_schedulerelink(e.wp10);
 321         waypoint_schedulerelink(e.wp11);
 322         waypoint_schedulerelink(e.wp12);
 323         waypoint_schedulerelink(e.wp13);
 324         waypoint_schedulerelink(e.wp14);
 325         waypoint_schedulerelink(e.wp15);
 326         waypoint_schedulerelink(e.wp16);
 327         waypoint_schedulerelink(e.wp17);
 328         waypoint_schedulerelink(e.wp18);
 329         waypoint_schedulerelink(e.wp19);
 330         waypoint_schedulerelink(e.wp20);
 331         waypoint_schedulerelink(e.wp21);
 332         waypoint_schedulerelink(e.wp22);
 333         waypoint_schedulerelink(e.wp23);
 334         waypoint_schedulerelink(e.wp24);
 335         waypoint_schedulerelink(e.wp25);
 336         waypoint_schedulerelink(e.wp26);
 337         waypoint_schedulerelink(e.wp27);
 338         waypoint_schedulerelink(e.wp28);
 339         waypoint_schedulerelink(e.wp29);
 340         waypoint_schedulerelink(e.wp30);
 341         waypoint_schedulerelink(e.wp31);
 342         // and now remove the spawnfunc_waypoint
 343         remove(e);
 344 }
 345
 346 // empties the map of waypoints
 347 void waypoint_removeall()
 348 {
 349         entity head, next;
 350         head = findchain(classname, "waypoint");
 351         while (head)
 352         {
 353                 next = head.chain;
 354                 remove(head);
 355                 head = next;
 356         }
 357 }
 358
 359 // tell all waypoints to relink
 360 // (is this useful at all?)
 361 void waypoint_schedulerelinkall()
 362 {
 363         entity head;
 364         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 365         head = findchain(classname, "waypoint");
 366         while (head)
 367         {
 368                 waypoint_schedulerelink(head);
 369                 head = head.chain;
 370         }
 371 }
 372
 373 // Load waypoint links from file
 374 float waypoint_load_links()
 375 {
 376         string filename, s;
 377         float file, tokens, c = 0, found;
 378         entity wp_from = NULL, wp_to;
 379         vector wp_to_pos, wp_from_pos;
 380         filename = strcat("maps/", mapname);
 381         filename = strcat(filename, ".waypoints.cache");
 382         file = fopen(filename, FILE_READ);
 383
 384         if (file < 0)
 385         {
 386                 LOG_TRACE("waypoint links load from ");
 387                 LOG_TRACE(filename);
 388                 LOG_TRACE(" failed\n");
 389                 return false;
 390         }
 391
 392         while ((s = fgets(file)))
 393         {
 394                 tokens = tokenizebyseparator(s, "*");
 395
 396                 if (tokens!=2)
 397                 {
 398                         // bad file format
 399                         fclose(file);
 400                         return false;
 401                 }
 402
 403                 wp_from_pos     = stov(argv(0));
 404                 wp_to_pos       = stov(argv(1));
 405
 406                 // Search "from" waypoint
 407                 if(!wp_from || wp_from.origin!=wp_from_pos)
 408                 {
 409                         wp_from = findradius(wp_from_pos, 1);
 410                         found = false;
 411                         while(wp_from)
 412                         {
 413                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 414                                 if(wp_from.classname == "waypoint")
 415                                 {
 416                                         found = true;
 417                                         break;
 418                                 }
 419                                 wp_from = wp_from.chain;
 420                         }
 421
 422                         if(!found)
 423                         {
 424                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from.origin),"\n");
 425                                 continue;
 426                         }
 427
 428                 }
 429
 430                 // Search "to" waypoint
 431                 wp_to = findradius(wp_to_pos, 1);
 432                 found = false;
 433                 while(wp_to)
 434                 {
 435                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 436                         if(wp_to.classname == "waypoint")
 437                         {
 438                                 found = true;
 439                                 break;
 440                         }
 441                         wp_to = wp_to.chain;
 442                 }
 443
 444                 if(!found)
 445                 {
 446                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to.origin),"\n");
 447                         continue;
 448                 }
 449
 450                 ++c;
 451                 waypoint_addlink(wp_from, wp_to);
 452         }
 453
 454         fclose(file);
 455
 456         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache\n");
 457
 458         botframe_cachedwaypointlinks = true;
 459         return true;
 460 }
 461
 462 void waypoint_load_links_hardwired()
 463 {
 464         string filename, s;
 465         float file, tokens, c = 0, found;
 466         entity wp_from = NULL, wp_to;
 467         vector wp_to_pos, wp_from_pos;
 468         filename = strcat("maps/", mapname);
 469         filename = strcat(filename, ".waypoints.hardwired");
 470         file = fopen(filename, FILE_READ);
 471
 472         botframe_loadedforcedlinks = true;
 473
 474         if (file < 0)
 475         {
 476                 LOG_TRACE("waypoint links load from ", filename, " failed\n");
 477                 return;
 478         }
 479
 480         while ((s = fgets(file)))
 481         {
 482                 if(substring(s, 0, 2)=="//")
 483                         continue;
 484
 485                 if(substring(s, 0, 1)=="#")
 486                         continue;
 487
 488                 tokens = tokenizebyseparator(s, "*");
 489
 490                 if (tokens!=2)
 491                         continue;
 492
 493                 wp_from_pos     = stov(argv(0));
 494                 wp_to_pos       = stov(argv(1));
 495
 496                 // Search "from" waypoint
 497                 if(!wp_from || wp_from.origin!=wp_from_pos)
 498                 {
 499                         wp_from = findradius(wp_from_pos, 5);
 500                         found = false;
 501                         while(wp_from)
 502                         {
 503                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 504                                 if(wp_from.classname == "waypoint")
 505                                 {
 506                                         found = true;
 507                                         break;
 508                                 }
 509                                 wp_from = wp_from.chain;
 510                         }
 511
 512                         if(!found)
 513                         {
 514                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 515                                 continue;
 516                         }
 517                 }
 518
 519                 // Search "to" waypoint
 520                 wp_to = findradius(wp_to_pos, 5);
 521                 found = false;
 522                 while(wp_to)
 523                 {
 524                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 525                         if(wp_to.classname == "waypoint")
 526                         {
 527                                 found = true;
 528                                 break;
 529                         }
 530                         wp_to = wp_to.chain;
 531                 }
 532
 533                 if(!found)
 534                 {
 535                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 536                         continue;
 537                 }
 538
 539                 ++c;
 540                 waypoint_addlink(wp_from, wp_to);
 541                 wp_from.wphardwired = true;
 542                 wp_to.wphardwired = true;
 543         }
 544
 545         fclose(file);
 546
 547         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired\n");
 548 }
 549
 550 entity waypoint_get_link(entity w, float i)
 551 {
 552         switch(i)
 553         {
 554                 case  0:return w.wp00;
 555                 case  1:return w.wp01;
 556                 case  2:return w.wp02;
 557                 case  3:return w.wp03;
 558                 case  4:return w.wp04;
 559                 case  5:return w.wp05;
 560                 case  6:return w.wp06;
 561                 case  7:return w.wp07;
 562                 case  8:return w.wp08;
 563                 case  9:return w.wp09;
 564                 case 10:return w.wp10;
 565                 case 11:return w.wp11;
 566                 case 12:return w.wp12;
 567                 case 13:return w.wp13;
 568                 case 14:return w.wp14;
 569                 case 15:return w.wp15;
 570                 case 16:return w.wp16;
 571                 case 17:return w.wp17;
 572                 case 18:return w.wp18;
 573                 case 19:return w.wp19;
 574                 case 20:return w.wp20;
 575                 case 21:return w.wp21;
 576                 case 22:return w.wp22;
 577                 case 23:return w.wp23;
 578                 case 24:return w.wp24;
 579                 case 25:return w.wp25;
 580                 case 26:return w.wp26;
 581                 case 27:return w.wp27;
 582                 case 28:return w.wp28;
 583                 case 29:return w.wp29;
 584                 case 30:return w.wp30;
 585                 case 31:return w.wp31;
 586                 default:return NULL;
 587         }
 588 }
 589
 590 // Save all waypoint links to a file
 591 void waypoint_save_links()
 592 {
 593         string filename, s;
 594         float file, c, i;
 595         entity w, link;
 596         filename = strcat("maps/", mapname);
 597         filename = strcat(filename, ".waypoints.cache");
 598         file = fopen(filename, FILE_WRITE);
 599         if (file < 0)
 600         {
 601                 LOG_INFO("waypoint links save to ");
 602                 LOG_INFO(filename);
 603                 LOG_INFO(" failed\n");
 604         }
 605         c = 0;
 606         w = findchain(classname, "waypoint");
 607         while (w)
 608         {
 609                 for(i=0;i<32;++i)
 610                 {
 611                         // :S
 612                         link = waypoint_get_link(w, i);
 613                         if(link==NULL)
 614                                 continue;
 615
 616                         s = strcat(vtos(w.origin), "*", vtos(link.origin), "\n");
 617                         fputs(file, s);
 618                         ++c;
 619                 }
 620                 w = w.chain;
 621         }
 622         fclose(file);
 623         botframe_cachedwaypointlinks = true;
 624
 625         LOG_INFO("saved ");
 626         LOG_INFO(ftos(c));
 627         LOG_INFO(" waypoints links to maps/");
 628         LOG_INFO(mapname);
 629         LOG_INFO(".waypoints.cache\n");
 630 }
 631
 632 // save waypoints to gamedir/data/maps/mapname.waypoints
 633 void waypoint_saveall()
 634 {
 635         string filename, s;
 636         float file, c;
 637         entity w;
 638         filename = strcat("maps/", mapname);
 639         filename = strcat(filename, ".waypoints");
 640         file = fopen(filename, FILE_WRITE);
 641         if (file >= 0)
 642         {
 643                 c = 0;
 644                 w = findchain(classname, "waypoint");
 645                 while (w)
 646                 {
 647                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
 648                         {
 649                                 s = strcat(vtos(w.origin + w.mins), "\n");
 650                                 s = strcat(s, vtos(w.origin + w.maxs));
 651                                 s = strcat(s, "\n");
 652                                 s = strcat(s, ftos(w.wpflags));
 653                                 s = strcat(s, "\n");
 654                                 fputs(file, s);
 655                                 c = c + 1;
 656                         }
 657                         w = w.chain;
 658                 }
 659                 fclose(file);
 660                 bprint("saved ");
 661                 bprint(ftos(c));
 662                 bprint(" waypoints to maps/");
 663                 bprint(mapname);
 664                 bprint(".waypoints\n");
 665         }
 666         else
 667         {
 668                 bprint("waypoint save to ");
 669                 bprint(filename);
 670                 bprint(" failed\n");
 671         }
 672         waypoint_save_links();
 673         botframe_loadedforcedlinks = false;
 674 }
 675
 676 // load waypoints from file
 677 float waypoint_loadall()
 678 {
 679         string filename, s;
 680         float file, cwp, cwb, fl;
 681         vector m1, m2;
 682         cwp = 0;
 683         cwb = 0;
 684         filename = strcat("maps/", mapname);
 685         filename = strcat(filename, ".waypoints");
 686         file = fopen(filename, FILE_READ);
 687         if (file >= 0)
 688         {
 689                 while ((s = fgets(file)))
 690                 {
 691                         m1 = stov(s);
 692                         s = fgets(file);
 693                         if (!s)
 694                                 break;
 695                         m2 = stov(s);
 696                         s = fgets(file);
 697                         if (!s)
 698                                 break;
 699                         fl = stof(s);
 700                         waypoint_spawn(m1, m2, fl);
 701                         if (m1 == m2)
 702                                 cwp = cwp + 1;
 703                         else
 704                                 cwb = cwb + 1;
 705                 }
 706                 fclose(file);
 707                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints\n");
 708         }
 709         else
 710         {
 711                 LOG_TRACE("waypoint load from ", filename, " failed\n");
 712         }
 713         return cwp + cwb;
 714 }
 715
 716 vector waypoint_fixorigin(vector position)
 717 {
 718         tracebox(position + '0 0 1' * (1 - STAT(PL_MIN, NULL).z), STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 719         if(trace_fraction < 1)
 720                 position = trace_endpos;
 721         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 722         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 723         return position;
 724 }
 725
 726 void waypoint_spawnforitem_force(entity e, vector org)
 727 {
 728         entity w;
 729
 730         // Fix the waypoint altitude if necessary
 731         org = waypoint_fixorigin(org);
 732
 733         // don't spawn an item spawnfunc_waypoint if it already exists
 734         w = findchain(classname, "waypoint");
 735         while (w)
 736         {
 737                 if (w.wpisbox)
 738                 {
 739                         if (boxesoverlap(org, org, w.absmin, w.absmax))
 740                         {
 741                                 e.nearestwaypoint = w;
 742                                 return;
 743                         }
 744                 }
 745                 else
 746                 {
 747                         if (vlen(w.origin - org) < 16)
 748                         {
 749                                 e.nearestwaypoint = w;
 750                                 return;
 751                         }
 752                 }
 753                 w = w.chain;
 754         }
 755         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 756 }
 757
 758 void waypoint_spawnforitem(entity e)
 759 {
 760         if(!bot_waypoints_for_items)
 761                 return;
 762
 763         waypoint_spawnforitem_force(e, e.origin);
 764 }
 765
 766 void waypoint_spawnforteleporter_boxes(entity e, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
 767 {
 768         entity w;
 769         entity dw;
 770         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 771         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
 772         // one way link to the destination
 773         w.wp00 = dw;
 774         w.wp00mincost = timetaken; // this is just for jump pads
 775         // the teleporter's nearest spawnfunc_waypoint is this one
 776         // (teleporters are not goals, so this is probably useless)
 777         e.nearestwaypoint = w;
 778         e.nearestwaypointtimeout = time + 1000000000;
 779 }
 780
 781 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
 782 {
 783         org = waypoint_fixorigin(org);
 784         destination = waypoint_fixorigin(destination);
 785         waypoint_spawnforteleporter_boxes(e, org, org, destination, destination, timetaken);
 786 }
 787
 788 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 789 {
 790         destination = waypoint_fixorigin(destination);
 791         waypoint_spawnforteleporter_boxes(e, e.absmin, e.absmax, destination, destination, timetaken);
 792 }
 793
 794 entity waypoint_spawnpersonal(entity this, vector position)
 795 {
 796         entity w;
 797
 798         // drop the waypoint to a proper location:
 799         //   first move it up by a player height
 800         //   then move it down to hit the floor with player bbox size
 801         position = waypoint_fixorigin(position);
 802
 803         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
 804         w.nearestwaypoint = NULL;
 805         w.nearestwaypointtimeout = 0;
 806         w.owner = this;
 807
 808         waypoint_schedulerelink(w);
 809
 810         return w;
 811 }
 812
 813 void botframe_showwaypointlinks()
 814 {
 815         entity head, w;
 816         if (time < botframe_waypointeditorlightningtime)
 817                 return;
 818         botframe_waypointeditorlightningtime = time + 0.5;
 819         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot, LAMBDA(
 820                 if(IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
 821                 {
 822                         //navigation_testtracewalk = true;
 823                         head = navigation_findnearestwaypoint(it, false);
 824                 //      print("currently selected WP is ", etos(head), "\n");
 825                         //navigation_testtracewalk = false;
 826                         if (head)
 827                         {
 828                                 w = head     ;if (w) te_lightning2(NULL, w.origin, it.origin);
 829                                 w = head.wp00;if (w) te_lightning2(NULL, w.origin, head.origin);
 830                                 w = head.wp01;if (w) te_lightning2(NULL, w.origin, head.origin);
 831                                 w = head.wp02;if (w) te_lightning2(NULL, w.origin, head.origin);
 832                                 w = head.wp03;if (w) te_lightning2(NULL, w.origin, head.origin);
 833                                 w = head.wp04;if (w) te_lightning2(NULL, w.origin, head.origin);
 834                                 w = head.wp05;if (w) te_lightning2(NULL, w.origin, head.origin);
 835                                 w = head.wp06;if (w) te_lightning2(NULL, w.origin, head.origin);
 836                                 w = head.wp07;if (w) te_lightning2(NULL, w.origin, head.origin);
 837                                 w = head.wp08;if (w) te_lightning2(NULL, w.origin, head.origin);
 838                                 w = head.wp09;if (w) te_lightning2(NULL, w.origin, head.origin);
 839                                 w = head.wp10;if (w) te_lightning2(NULL, w.origin, head.origin);
 840                                 w = head.wp11;if (w) te_lightning2(NULL, w.origin, head.origin);
 841                                 w = head.wp12;if (w) te_lightning2(NULL, w.origin, head.origin);
 842                                 w = head.wp13;if (w) te_lightning2(NULL, w.origin, head.origin);
 843                                 w = head.wp14;if (w) te_lightning2(NULL, w.origin, head.origin);
 844                                 w = head.wp15;if (w) te_lightning2(NULL, w.origin, head.origin);
 845                                 w = head.wp16;if (w) te_lightning2(NULL, w.origin, head.origin);
 846                                 w = head.wp17;if (w) te_lightning2(NULL, w.origin, head.origin);
 847                                 w = head.wp18;if (w) te_lightning2(NULL, w.origin, head.origin);
 848                                 w = head.wp19;if (w) te_lightning2(NULL, w.origin, head.origin);
 849                                 w = head.wp20;if (w) te_lightning2(NULL, w.origin, head.origin);
 850                                 w = head.wp21;if (w) te_lightning2(NULL, w.origin, head.origin);
 851                                 w = head.wp22;if (w) te_lightning2(NULL, w.origin, head.origin);
 852                                 w = head.wp23;if (w) te_lightning2(NULL, w.origin, head.origin);
 853                                 w = head.wp24;if (w) te_lightning2(NULL, w.origin, head.origin);
 854                                 w = head.wp25;if (w) te_lightning2(NULL, w.origin, head.origin);
 855                                 w = head.wp26;if (w) te_lightning2(NULL, w.origin, head.origin);
 856                                 w = head.wp27;if (w) te_lightning2(NULL, w.origin, head.origin);
 857                                 w = head.wp28;if (w) te_lightning2(NULL, w.origin, head.origin);
 858                                 w = head.wp29;if (w) te_lightning2(NULL, w.origin, head.origin);
 859                                 w = head.wp30;if (w) te_lightning2(NULL, w.origin, head.origin);
 860                                 w = head.wp31;if (w) te_lightning2(NULL, w.origin, head.origin);
 861                         }
 862                 }
 863         ));
 864 }
 865
 866 float botframe_autowaypoints_fixdown(vector v)
 867 {
 868         tracebox(v, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v + '0 0 -64', MOVE_NOMONSTERS, NULL);
 869         if(trace_fraction >= 1)
 870                 return 0;
 871         return 1;
 872 }
 873
 874 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
 875 {
 876         entity w;
 877
 878         w = find(NULL, classname, "waypoint");
 879         while (w)
 880         {
 881                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 882                 if (boxesoverlap(v - '32 32 32', v + '32 32 32', w.absmin, w.absmax))
 883                 //if (boxesoverlap(v - '4 4 4', v + '4 4 4', w.absmin, w.absmax))
 884                         return 0;
 885                 w = find(w, classname, "waypoint");
 886         }
 887
 888         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
 889         return 1;
 890 }
 891
 892 // return value:
 893 //    1 = WP created
 894 //    0 = no action needed
 895 //   -1 = temp fail, try from world too
 896 //   -2 = permanent fail, do not retry
 897 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
 898 {
 899         // make it possible to go from p to wp, if we can
 900         // if wp is NULL, nearest is chosen
 901
 902         entity w;
 903         vector porg;
 904         float t, tmin, tmax;
 905         vector o;
 906         vector save;
 907
 908         if(!botframe_autowaypoints_fixdown(p.origin))
 909                 return -2;
 910         porg = trace_endpos;
 911
 912         if(wp)
 913         {
 914                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
 915
 916                 // if wp -> porg, then OK
 917                 float maxdist;
 918                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
 919                 {
 920                         // we may find a better one
 921                         maxdist = vlen(wp.origin - porg);
 922                 }
 923                 else
 924                 {
 925                         // accept any "good"
 926                         maxdist = 2100;
 927                 }
 928
 929                 float bestdist;
 930                 bestdist = maxdist;
 931                 w = find(NULL, classname, "waypoint");
 932                 while (w)
 933                 {
 934                         if(w != wp && !(w.wpflags & WAYPOINTFLAG_NORELINK))
 935                         {
 936                                 float d;
 937                                 d = vlen(wp.origin - w.origin) + vlen(w.origin - porg);
 938                                 if(d < bestdist)
 939                                         if(navigation_waypoint_will_link(wp.origin, w.origin, p, walkfromwp, 1050))
 940                                                 if(navigation_waypoint_will_link(w.origin, porg, p, walkfromwp, 1050))
 941                                                 {
 942                                                         bestdist = d;
 943                                                         p.(fld) = w;
 944                                                 }
 945                         }
 946                         w = find(w, classname, "waypoint");
 947                 }
 948                 if(bestdist < maxdist)
 949                 {
 950                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
 951                         return 0;
 952                 }
 953
 954                 if(bestdist < 2100)
 955                 {
 956                         // we know maxdist < 2100
 957                         // so wp -> porg is still valid
 958                         // all is good
 959                         p.(fld) = wp;
 960                         return 0;
 961                 }
 962
 963                 // otherwise, no existing WP can fix our issues
 964         }
 965         else
 966         {
 967                 save = p.origin;
 968                 setorigin(p, porg);
 969                 w = navigation_findnearestwaypoint(p, walkfromwp);
 970                 setorigin(p, save);
 971                 if(w)
 972                 {
 973                         p.(fld) = w;
 974                         return 0;
 975                 }
 976         }
 977
 978         tmin = 0;
 979         tmax = 1;
 980         for (;;)
 981         {
 982                 if(tmax - tmin < 0.001)
 983                 {
 984                         // did not get a good candidate
 985                         return -1;
 986                 }
 987
 988                 t = (tmin + tmax) * 0.5;
 989                 o = antilag_takebackorigin(p, CS(p), time - t);
 990                 if(!botframe_autowaypoints_fixdown(o))
 991                         return -2;
 992                 o = trace_endpos;
 993
 994                 if(wp)
 995                 {
 996                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
 997                         {
 998                                 // we cannot walk from wp.origin to o
 999                                 // get closer to tmax
1000                                 tmin = t;
1001                                 continue;
1002                         }
1003                 }
1004                 else
1005                 {
1006                         save = p.origin;
1007                         setorigin(p, o);
1008                         w = navigation_findnearestwaypoint(p, walkfromwp);
1009                         setorigin(p, save);
1010                         if(!w)
1011                         {
1012                                 // we cannot walk from any WP to o
1013                                 // get closer to tmax
1014                                 tmin = t;
1015                                 continue;
1016                         }
1017                 }
1018
1019                 // if we get here, o is valid regarding waypoints
1020                 // check if o is connected right to the player
1021                 // we break if it succeeds, as that means o is a good waypoint location
1022                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1023                         break;
1024
1025                 // o is no good, we need to get closer to the player
1026                 tmax = t;
1027         }
1028
1029         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1030         botframe_autowaypoints_createwp(o, p, fld, 0);
1031         return 1;
1032 }
1033
1034 // automatically create missing waypoints
1035 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1036 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1037 {
1038         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1039         if(r != -1)
1040                 return;
1041         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1042         if(r != -1)
1043                 return;
1044
1045         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1046         if(!botframe_autowaypoints_fixdown(p.origin))
1047                 return; // shouldn't happen, caught above
1048         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1049 }
1050
1051 void botframe_deleteuselesswaypoints()
1052 {
1053         entity w, w1, w2;
1054         float i, j, k;
1055         for (w = NULL; (w = findfloat(w, bot_pickup, true)); )
1056         {
1057                 // NOTE: this protects waypoints if they're the ONLY nearest
1058                 // waypoint. That's the intention.
1059                 navigation_findnearestwaypoint(w, false);  // Walk TO item.
1060                 navigation_findnearestwaypoint(w, true);  // Walk FROM item.
1061         }
1062         for (w = NULL; (w = find(w, classname, "waypoint")); )
1063         {
1064                 w.wpflags |= WAYPOINTFLAG_DEAD_END;
1065                 w.wpflags &= ~WAYPOINTFLAG_USEFUL;
1066                 // WP is useful if:
1067                 if (w.wpflags & WAYPOINTFLAG_ITEM)
1068                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1069                 if (w.wpflags & WAYPOINTFLAG_TELEPORT)
1070                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1071                 if (w.wpflags & WAYPOINTFLAG_PROTECTED)
1072                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1073                 // b) WP is closest WP for an item/spawnpoint/other entity
1074                 //    This has been done above by protecting these WPs.
1075         }
1076         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1077         for (w1 = NULL; (w1 = find(w1, classname, "waypoint")); )
1078         {
1079                 if (w1.wpflags & WAYPOINTFLAG_PERSONAL)
1080                         continue;
1081                 for (i = 0; i < 32; ++i)
1082                 {
1083                         w = waypoint_get_link(w1, i);
1084                         if (!w)
1085                                 break;
1086                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1087                                 continue;
1088                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1089                                 continue;
1090                         for (j = 0; j < 32; ++j)
1091                         {
1092                                 w2 = waypoint_get_link(w, j);
1093                                 if (!w2)
1094                                         break;
1095                                 if (w1 == w2)
1096                                         continue;
1097                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1098                                         continue;
1099                                 // If we got here, w1 != w2 exist with w1 -> w
1100                                 // and w -> w2. That means the waypoint is not
1101                                 // a dead end.
1102                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1103                                 for (k = 0; k < 32; ++k)
1104                                 {
1105                                         if (waypoint_get_link(w1, k) == w2)
1106                                                 continue;
1107                                         // IF WE GET HERE, w is proven useful
1108                                         // to get from w1 to w2!
1109                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1110                                         goto next;
1111                                 }
1112                         }
1113 LABEL(next)
1114                 }
1115         }
1116         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1117         //     they are needed to complete routes while autowaypointing.
1118
1119         for (w = NULL; (w = find(w, classname, "waypoint")); )
1120         {
1121                 if (!(w.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)))
1122                 {
1123                         LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", w.origin);
1124                         te_explosion(w.origin);
1125                         waypoint_remove(w);
1126                         break;
1127                 }
1128         }
1129         for (w = NULL; (w = find(w, classname, "waypoint")); )
1130                 w.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1131 }
1132
1133 void botframe_autowaypoints()
1134 {
1135         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1136                 // going back is broken, so only fix waypoints to walk TO the player
1137                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1138                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1139                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1140         ));
1141
1142         if (autocvar_g_waypointeditor_auto >= 2) {
1143                 botframe_deleteuselesswaypoints();
1144         }
1145 }
1146