qcsrc/server/campaign.qc

   1 #include "campaign.qh"
   2
   3 #include "defs.qh"
   4
   5 #include "cheats.qh"
   6 #include "miscfunctions.qh"
   7 #include "g_world.qh"
   8
   9 #include "../common/campaign_common.qh"
  10
  11 // campaign cvars:
  12 //   _campaign_index: index of CURRENT map
  13 //   _campaign_name: name of the current campaign
  14 //   g_campaign(name)_index: index of current LAST map (saved)
  15 //   g_campaign_skill: bot skill offset
  16
  17 float campaign_level;
  18 float campaign_won;
  19 string campaign_index_var;
  20 //float checkrules_equality;
  21
  22 float CampaignBailout(string s)
  23 {
  24         cvar = cvar_normal;
  25         cvar_string = cvar_string_normal;
  26         cvar_set = cvar_set_normal;
  27         cvar_set("g_campaign", "0");
  28         LOG_INFO("^4campaign initialization failed: ", s);
  29         if(autocvar__campaign_testrun)
  30                 error("CAMPAIGN FAIL AHAHAHAHAHAHAHAHAH))");
  31         return 1;
  32 }
  33
  34 string cvar_campaignwrapper_list; // string of format ; var value; var value; var value;
  35 string cvar_string_campaignwrapper(string theCvar)
  36 {
  37         float p, q;
  38         p = strstrofs(cvar_campaignwrapper_list, strcat("; ", theCvar, " "), 0);
  39         if(p < 0)
  40                 return cvar_defstring(theCvar);
  41         p += strlen(theCvar) + 3;
  42         q = strstrofs(cvar_campaignwrapper_list, ";", p);
  43         if(q < 0)
  44                 return cvar_defstring(theCvar);
  45         return substring(cvar_campaignwrapper_list, p, q - p);
  46 }
  47 float cvar_campaignwrapper(string theCvar)
  48 {
  49         return stof(cvar_string_campaignwrapper(theCvar));
  50 }
  51 void cvar_set_campaignwrapper(string theCvar, string theValue)
  52 {
  53         if(cvar_string_campaignwrapper(theCvar) == theValue)
  54                 return;
  55         string s = cvar_campaignwrapper_list;
  56         cvar_campaignwrapper_list = strzone(strcat("; ", theCvar, " ", theValue, s));
  57         strunzone(s);
  58         //print(cvar_campaignwrapper_list, "\n");
  59 }
  60
  61 float Campaign_Invalid()
  62 {
  63         string thismapname, wantedmapname;
  64         thismapname = GetMapname();
  65         wantedmapname = campaign_gametype[0];
  66         if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname))
  67                 return CampaignBailout("wrong game type!");
  68         wantedmapname = campaign_mapname[0];
  69         if(wantedmapname != thismapname)
  70                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  71         return 0;
  72 }
  73
  74 void CampaignPreInit()
  75 {
  76         float baseskill;
  77         string title;
  78         campaign_level = autocvar__campaign_index;
  79         campaign_name = strzone(autocvar__campaign_name);
  80         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  81         CampaignFile_Load(campaign_level, 2);
  82
  83         if(campaign_entries < 1)
  84         {
  85                 CampaignBailout("unknown map");
  86                 return;
  87         }
  88
  89         if(autocvar_sv_cheats)
  90         {
  91                 MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
  92                 CampaignFile_Unload();
  93                 CampaignBailout("JOLLY CHEATS AHAHAHAHAHAHAH))");
  94                 return;
  95         }
  96
  97         baseskill = autocvar_g_campaign_skill;
  98         baseskill = baseskill + campaign_botskill[0];
  99         if(baseskill < 0)
 100                 baseskill = 0;
 101
 102         cvar_set("sv_public", "0");
 103         cvar_set("pausable", "1");
 104
 105         cvar_campaignwrapper_list = strzone(strcat("; ", campaign_mutators[0], "; "));
 106
 107         cvar = cvar_campaignwrapper;
 108         cvar_string = cvar_string_campaignwrapper;
 109         cvar_set = cvar_set_campaignwrapper;
 110
 111         cvar_set("g_campaign", "1");
 112         cvar_set("g_dm", "0");
 113         cvar_set("skill", ftos(baseskill));
 114         cvar_set("bot_number", ftos(campaign_bots[0]));
 115         MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
 116
 117         // copy sv_gravity cvar, as the engine needs it too (sorry, this will mess
 118         // with the menu a little still...)
 119         cvar_set_normal("sv_gravity", ftos(autocvar_sv_gravity));
 120
 121         if(Campaign_Invalid())
 122                 return;
 123
 124         title = campaign_shortdesc[0];
 125         title = strzone(strcat("Level ", ftos(campaign_level + 1), ": ", title));
 126         campaign_message = strzone(strcat(title, "\n^3\n", campaign_longdesc[0], "\n\n^1press jump to enter the game"));
 127         strunzone(title);
 128 }
 129
 130 void CampaignPostInit()
 131 {
 132         // now some sanity checks
 133         if(Campaign_Invalid())
 134                 return;
 135         if(autocvar__campaign_testrun)
 136         {
 137                 cvar_set("fraglimit", "0");
 138                 cvar_set("timelimit", "0.01");
 139                 cvar_set_normal("fraglimit", "0");
 140                 cvar_set_normal("timelimit", "0.01");
 141         }
 142         else
 143         {
 144                 cvar_set("fraglimit", ftos(campaign_fraglimit[0]));
 145                 cvar_set("timelimit", ftos(campaign_timelimit[0]));
 146                 cvar_set_normal("fraglimit", ftos(campaign_fraglimit[0]));
 147                 cvar_set_normal("timelimit", ftos(campaign_timelimit[0]));
 148         }
 149 }
 150
 151 void CampaignSaveCvar(string cvarname, float value)
 152 {
 153         float fh;
 154         float len;
 155         string contents;
 156         string l;
 157
 158         registercvar(cvarname, ftos(value));
 159         cvar_set_normal(cvarname, ftos(value));
 160         // note: cvarname must be remembered
 161
 162         fh = fopen("campaign.cfg", FILE_READ);
 163         contents = "";
 164         if(fh >= 0)
 165         {
 166                 while((l = fgets(fh)))
 167                 {
 168                         len = tokenize_console(l);
 169                         if(len != 3)
 170                                 continue;
 171                         if(argv(0) != "set")
 172                                 continue;
 173                         if(argv(1) == cvarname)
 174                                 continue;
 175                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
 176                 }
 177                 fclose(fh);
 178         }
 179         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
 180         fh = fopen("campaign.cfg", FILE_WRITE);
 181         if(fh >= 0)
 182         {
 183                 fputs(fh, contents);
 184         }
 185         else
 186         {
 187                 error("Cannot write to campaign file");
 188         }
 189 }
 190
 191 void CampaignPreIntermission()
 192 {
 193         int won = 0;
 194         int lost = 0;
 195         string savevar;
 196
 197         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 198                 if(it.winning)
 199                         won += 1;
 200                 else
 201                         lost += 1;
 202         });
 203
 204         if(autocvar__campaign_testrun)
 205         {
 206                 campaign_won = 1;
 207                 bprint("Campaign test run, advancing level.\n");
 208         }
 209         else if(won == 1 && lost == 0 && checkrules_equality == 0)
 210         {
 211                 if(autocvar_timelimit != 0 && autocvar_fraglimit != 0 && time > autocvar_timelimit * 60) // checks if the timelimit has expired.
 212                 {
 213                         campaign_won = 0;
 214                         bprint("Time's up! The current level has been LOST.\n");
 215                         // sound!
 216                 }
 217                 else
 218                 {
 219                         campaign_won = 1;
 220                         bprint("The current level has been WON.\n");
 221                         // sound!
 222                 }
 223         }
 224         else if(autocvar_timelimit != 0 && time > autocvar_timelimit * 60)
 225         {
 226                 campaign_won = 0;
 227                 bprint("Time's up! The current level has been LOST.\n");
 228                 // sound!
 229         }
 230         else
 231         {
 232                 campaign_won = 0;
 233                 bprint("The current level has been LOST.\n");
 234                 // sound!
 235         }
 236
 237         if(campaign_won && cheatcount_total == 0 && !autocvar__campaign_testrun)
 238         {
 239                 if(campaign_level == cvar_normal(campaign_index_var))
 240                 {
 241                         if(campaign_entries < 2)
 242                         {
 243                                 // I have won
 244                                 savevar = strcat("g_campaign", campaign_name, "_won");
 245                                 CampaignSaveCvar(savevar, 1);
 246                                 // advance level (for menu to show it right)
 247                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 248                         }
 249                         else
 250                         {
 251                                 // advance level
 252                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 253                         }
 254                 }
 255         }
 256 }
 257
 258 void CampaignPostIntermission()
 259 {
 260         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 261
 262         if(campaign_won && campaign_entries < 2)
 263         {
 264                 // last map won!
 265                 LOG_DEBUG("^2test run: campaign looks GOOD");
 266                 localcmd("togglemenu 1\n");
 267                 CampaignFile_Unload();
 268                 return;
 269         }
 270
 271         CampaignSetup(campaign_won);
 272         CampaignFile_Unload();
 273         strunzone(campaign_message);
 274         strunzone(campaign_index_var);
 275         strunzone(campaign_name);
 276         campaign_name = "";
 277 }
 278
 279
 280
 281 void CampaignLevelWarp(float n)
 282 {
 283         if(n < 0)
 284                 n = campaign_level + 1;
 285         CampaignFile_Unload();
 286         CampaignFile_Load(n, 1);
 287         if(campaign_entries)
 288                 CampaignSetup(0);
 289         else
 290                 error("Sorry, cheater. You are NOT WELCOME.");
 291         CampaignFile_Unload();
 292 }
 293