qcsrc/server/campaign.qc

   1 #include "campaign.qh"
   2 #include "cheats.qh"
   3 #include "miscfunctions.qh"
   4 #include "g_world.qh"
   5
   6 #include "../common/campaign_common.qh"
   7
   8 // campaign cvars:
   9 //   _campaign_index: index of CURRENT map
  10 //   _campaign_name: name of the current campaign
  11 //   g_campaign(name)_index: index of current LAST map (saved)
  12 //   g_campaign_skill: bot skill offset
  13
  14 float campaign_level;
  15 float campaign_won;
  16 string campaign_index_var;
  17 //float checkrules_equality;
  18
  19 float CampaignBailout(string s)
  20 {
  21         cvar = cvar_normal;
  22         cvar_string = cvar_string_normal;
  23         cvar_set = cvar_set_normal;
  24         cvar_set("g_campaign", "0");
  25         LOG_INFO("^4campaign initialization failed: ", s, "\n");
  26         if(autocvar__campaign_testrun)
  27                 error("CAMPAIGN FAIL AHAHAHAHAHAHAHAHAH))");
  28         return 1;
  29 }
  30
  31 string cvar_campaignwrapper_list; // string of format ; var value; var value; var value;
  32 string cvar_string_campaignwrapper(string theCvar)
  33 {
  34         float p, q;
  35         p = strstrofs(cvar_campaignwrapper_list, strcat("; ", theCvar, " "), 0);
  36         if(p < 0)
  37                 return cvar_defstring(theCvar);
  38         p += strlen(theCvar) + 3;
  39         q = strstrofs(cvar_campaignwrapper_list, ";", p);
  40         if(q < 0)
  41                 return cvar_defstring(theCvar);
  42         return substring(cvar_campaignwrapper_list, p, q - p);
  43 }
  44 float cvar_campaignwrapper(string theCvar)
  45 {
  46         return stof(cvar_string_campaignwrapper(theCvar));
  47 }
  48 void cvar_set_campaignwrapper(string theCvar, string theValue)
  49 {
  50         if(cvar_string_campaignwrapper(theCvar) == theValue)
  51                 return;
  52         string s;
  53         s = cvar_campaignwrapper_list;
  54         cvar_campaignwrapper_list = strzone(strcat("; ", theCvar, " ", theValue, s));
  55         strunzone(s);
  56         //print(cvar_campaignwrapper_list, "\n");
  57 }
  58
  59 float Campaign_Invalid()
  60 {
  61         string thismapname, wantedmapname;
  62         thismapname = GetMapname();
  63         wantedmapname = campaign_gametype[0];
  64         if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname))
  65                 return CampaignBailout("wrong game type!");
  66         wantedmapname = campaign_mapname[0];
  67         if(wantedmapname != thismapname)
  68                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  69         return 0;
  70 }
  71
  72 void CampaignPreInit()
  73 {
  74         float baseskill;
  75         string title;
  76         if(autocvar_sv_cheats)
  77         {
  78                 CampaignBailout("JOLLY CHEATS AHAHAHAHAHAHAH))");
  79                 return;
  80         }
  81         campaign_level = autocvar__campaign_index;
  82         campaign_name = strzone(autocvar__campaign_name);
  83         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  84         CampaignFile_Load(campaign_level, 2);
  85         if(campaign_entries < 1)
  86         {
  87                 CampaignBailout("unknown map");
  88                 return;
  89         }
  90
  91         baseskill = autocvar_g_campaign_skill;
  92         baseskill = baseskill + campaign_botskill[0];
  93         if(baseskill < 0)
  94                 baseskill = 0;
  95
  96         cvar_set("sv_public", "0");
  97         cvar_set("pausable", "1");
  98
  99         cvar_campaignwrapper_list = strzone(strcat("; ", campaign_mutators[0], "; "));
 100
 101         cvar = cvar_campaignwrapper;
 102         cvar_string = cvar_string_campaignwrapper;
 103         cvar_set = cvar_set_campaignwrapper;
 104
 105         cvar_set("g_campaign", "1");
 106         cvar_set("g_dm", "0");
 107         cvar_set("skill", ftos(baseskill));
 108         cvar_set("bot_number", ftos(campaign_bots[0]));
 109         MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
 110
 111         // copy sv_gravity cvar, as the engine needs it too (sorry, this will mess
 112         // with the menu a little still...)
 113         cvar_set_normal("sv_gravity", ftos(autocvar_sv_gravity));
 114
 115         if(Campaign_Invalid())
 116                 return;
 117
 118         title = campaign_shortdesc[0];
 119         title = strzone(strcat("Level ", ftos(campaign_level + 1), ": ", title));
 120         campaign_message = strzone(strcat(title, "\n^3\n", campaign_longdesc[0], "\n\n^1press jump to enter the game"));
 121         strunzone(title);
 122 }
 123
 124 void CampaignPostInit()
 125 {
 126         // now some sanity checks
 127         if(Campaign_Invalid())
 128                 return;
 129         if(autocvar__campaign_testrun)
 130         {
 131                 cvar_set("fraglimit", "0");
 132                 cvar_set("timelimit", "0.01");
 133                 cvar_set_normal("fraglimit", "0");
 134                 cvar_set_normal("timelimit", "0.01");
 135         }
 136         else
 137         {
 138                 cvar_set("fraglimit", ftos(campaign_fraglimit[0]));
 139                 cvar_set("timelimit", ftos(campaign_timelimit[0]));
 140                 cvar_set_normal("fraglimit", ftos(campaign_fraglimit[0]));
 141                 cvar_set_normal("timelimit", ftos(campaign_timelimit[0]));
 142         }
 143 }
 144
 145 void CampaignSaveCvar(string cvarname, float value)
 146 {
 147         float fh;
 148         float len;
 149         string contents;
 150         string l;
 151
 152         registercvar(cvarname, ftos(value));
 153         cvar_set_normal(cvarname, ftos(value));
 154         // note: cvarname must be remembered
 155
 156         fh = fopen("campaign.cfg", FILE_READ);
 157         contents = "";
 158         if(fh >= 0)
 159         {
 160                 while((l = fgets(fh)))
 161                 {
 162                         len = tokenize_console(l);
 163                         if(len != 3)
 164                                 continue;
 165                         if(argv(0) != "set")
 166                                 continue;
 167                         if(argv(1) == cvarname)
 168                                 continue;
 169                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
 170                 }
 171                 fclose(fh);
 172         }
 173         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
 174         fh = fopen("campaign.cfg", FILE_WRITE);
 175         if(fh >= 0)
 176         {
 177                 fputs(fh, contents);
 178         }
 179         else
 180         {
 181                 error("Cannot write to campaign file");
 182         }
 183 }
 184
 185 void CampaignPreIntermission()
 186 {
 187         entity head;
 188         float won;
 189         float lost;
 190         string savevar;
 191
 192         won = lost = 0;
 193
 194         head = findchain(classname, "player");
 195         while(head)
 196         {
 197                 if(IS_REAL_CLIENT(head))
 198                 {
 199                         if(head.winning)
 200                                 won = won + 1;
 201                         else
 202                                 lost = lost + 1;
 203                 }
 204                 head = head.chain;
 205         }
 206
 207         if(autocvar__campaign_testrun)
 208         {
 209                 campaign_won = 1;
 210                 bprint("Campaign test run, advancing level.\n");
 211         }
 212         else if(won == 1 && lost == 0 && checkrules_equality == 0)
 213         {
 214                 if(autocvar_timelimit != 0 && autocvar_fraglimit != 0 && time > autocvar_timelimit * 60) // checks if the timelimit has expired.
 215                 {
 216                         campaign_won = 0;
 217                         bprint("Time's up! The current level has been LOST.\n");
 218                         // sound!
 219                 }
 220                 else
 221                 {
 222                         campaign_won = 1;
 223                         bprint("The current level has been WON.\n");
 224                         // sound!
 225                 }
 226         }
 227         else if(autocvar_timelimit != 0 && time > autocvar_timelimit * 60)
 228         {
 229                 campaign_won = 0;
 230                 bprint("Time's up! The current level has been LOST.\n");
 231                 // sound!
 232         }
 233         else
 234         {
 235                 campaign_won = 0;
 236                 bprint("The current level has been LOST.\n");
 237                 // sound!
 238         }
 239
 240         if(campaign_won && cheatcount_total == 0 && !autocvar__campaign_testrun)
 241         {
 242                 if(campaign_level == cvar_normal(campaign_index_var))
 243                 {
 244                         if(campaign_entries < 2)
 245                         {
 246                                 // I have won
 247                                 savevar = strcat("g_campaign", campaign_name, "_won");
 248                                 CampaignSaveCvar(savevar, 1);
 249                                 // advance level (for menu to show it right)
 250                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 251                         }
 252                         else
 253                         {
 254                                 // advance level
 255                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 256                         }
 257                 }
 258         }
 259 }
 260
 261 void CampaignPostIntermission()
 262 {
 263         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 264
 265         if(campaign_won && campaign_entries < 2)
 266         {
 267                 // last map won!
 268                 LOG_INFO("^2test run: campaign looks GOOD\n");
 269                 localcmd("togglemenu 1\n");
 270                 CampaignFile_Unload();
 271                 return;
 272         }
 273
 274         CampaignSetup(campaign_won);
 275         CampaignFile_Unload();
 276         strunzone(campaign_message);
 277         strunzone(campaign_index_var);
 278         strunzone(campaign_name);
 279         campaign_name = "";
 280 }
 281
 282
 283
 284 void CampaignLevelWarp(float n)
 285 {
 286         if(n < 0)
 287                 n = campaign_level + 1;
 288         CampaignFile_Unload();
 289         CampaignFile_Load(n, 1);
 290         if(campaign_entries)
 291                 CampaignSetup(0);
 292         else
 293                 error("Sorry, cheater. You are NOT WELCOME.");
 294         CampaignFile_Unload();
 295 }
 296