Merge remote branch 'origin/master' into fruitiex/animations
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
7 }
8
9 void Announce(string snd) {
10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
12         WriteString(MSG_ALL, snd);
13 }
14
15 void AnnounceTo(entity e, string snd) {
16         if (clienttype(e) == CLIENTTYPE_REAL)
17         {
18                 msg_entity = e;
19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
21                 WriteString(MSG_ONE, snd);
22         }
23 }
24
25 float ClientData_Send(entity to, float sf)
26 {
27         if(to != self.owner)
28         {
29                 error("wtf");
30                 return FALSE;
31         }
32
33         entity e;
34
35         e = to;
36         if(to.classname == "spectator")
37                 e = to.enemy;
38
39         sf = 0;
40
41         if(e.race_completed)
42                 sf |= 1; // forced scoreboard
43         if(to.spectatee_status)
44                 sf |= 2; // spectator ent number follows
45         if(e.zoomstate)
46                 sf |= 4; // zoomed
47         if(e.porto_v_angle_held)
48                 sf |= 8; // angles held
49
50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
51         WriteByte(MSG_ENTITY, sf);
52
53         if(sf & 2)
54                 WriteByte(MSG_ENTITY, to.spectatee_status);
55
56         if(sf & 8)
57         {
58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
60         }
61
62         return TRUE;
63 }
64
65 void ClientData_Attach()
66 {
67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
68         self.clientdata.drawonlytoclient = self;
69         self.clientdata.owner = self;
70 }
71
72 void ClientData_Detach()
73 {
74         remove(self.clientdata);
75         self.clientdata = world;
76 }
77
78 void ClientData_Touch(entity e)
79 {
80         e.clientdata.SendFlags = 1;
81
82         // make it spectatable
83         entity e2;
84         FOR_EACH_REALCLIENT(e2)
85         {
86                 if(e2 != e)
87                         if(e2.classname == "spectator")
88                                 if(e2.enemy == e)
89                                         e2.clientdata.SendFlags = 1;
90         }
91 }
92
93
94 .vector spawnpoint_score;
95 .string netname_previous;
96
97 void spawnfunc_info_player_survivor (void)
98 {
99         spawnfunc_info_player_deathmatch();
100 }
101
102 void spawnfunc_info_player_start (void)
103 {
104         spawnfunc_info_player_deathmatch();
105 }
106
107 void spawnfunc_info_player_deathmatch (void)
108 {
109         self.classname = "info_player_deathmatch";
110         relocate_spawnpoint();
111 }
112
113 void spawnpoint_use()
114 {
115         if(teamplay)
116         if(have_team_spawns > 0)
117         {
118                 self.team = activator.team;
119                 some_spawn_has_been_used = 1;
120         }
121 };
122
123 // Returns:
124 //   _x: prio (-1 if unusable)
125 //   _y: weight
126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
127 {
128         float shortest, thisdist;
129         float prio;
130         entity player;
131
132         prio = 0;
133
134         // filter out spots for the wrong team
135         if(teamcheck >= 0)
136                 if(spot.team != teamcheck)
137                         return '-1 0 0';
138
139         if(race_spawns)
140                 if(spot.target == "")
141                         return '-1 0 0';
142
143         if(clienttype(self) == CLIENTTYPE_REAL)
144         {
145                 if(spot.restriction == 1)
146                         return '-1 0 0';
147         }
148         else
149         {
150                 if(spot.restriction == 2)
151                         return '-1 0 0';
152         }
153
154         // filter out spots for assault
155         if(spot.target != "") {
156                 local entity ent;
157                 float good, found;
158                 ent = find(world, targetname, spot.target);
159
160                 while(ent) {
161                         if(ent.classname == "target_objective")
162                         {
163                                 found = 1;
164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
165                                         return '-1 0 0';
166                                 good = 1;
167                         }
168                         else if(ent.classname == "trigger_race_checkpoint")
169                         {
170                                 found = 1;
171                                 if(!anypoint) // spectators may spawn everywhere
172
173                                 {
174                                         if(g_race_qualifying)
175                                         {
176                                                 // spawn at first
177                                                 if(ent.race_checkpoint != 0)
178                                                         return '-1 0 0';
179                                                 if(spot.race_place != race_lowest_place_spawn)
180                                                         return '-1 0 0';
181                                         }
182                                         else
183                                         {
184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
185                                                         return '-1 0 0';
186                                                 // try reusing the previous spawn
187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
188                                                         prio += 1;
189                                                 if(ent.race_checkpoint == 0)
190                                                 {
191                                                         float pl;
192                                                         pl = self.race_place;
193                                                         if(pl > race_highest_place_spawn)
194                                                                 pl = 0;
195                                                         if(pl == 0 && !self.race_started)
196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
197                                                         if(spot.race_place != pl)
198                                                                 return '-1 0 0';
199                                                 }
200                                         }
201                                 }
202                                 good = 1;
203                         }
204                         ent = find(ent, targetname, spot.target);
205                 }
206
207                 if(found && !good)
208                         return '-1 0 0';
209         }
210
211         player = playerlist;
212         shortest = vlen(world.maxs - world.mins);
213         for(player = playerlist; player; player = player.chain)
214                 if (player != self)
215                 {
216                         thisdist = vlen(player.origin - spot.origin);
217                         if (thisdist < shortest)
218                                 shortest = thisdist;
219                 }
220         return prio * '1 0 0' + shortest * '0 1 0';
221 }
222
223 float spawn_allbad;
224 float spawn_allgood;
225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
226 {
227         local entity spot, spotlist, spotlistend;
228         spawn_allgood = TRUE;
229         spawn_allbad = TRUE;
230
231         spotlist = world;
232         spotlistend = world;
233
234         for(spot = firstspot; spot; spot = spot.chain)
235         {
236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
237
238                 if(autocvar_spawn_debugview)
239                 {
240                         setmodel(spot, "models/runematch/rune.mdl");
241                         if(spot.spawnpoint_score_y < mindist)
242                         {
243                                 spot.colormod = '1 0 0';
244                                 spot.scale = 1;
245                         }
246                         else
247                         {
248                                 spot.colormod = '0 1 0';
249                                 spot.scale = spot.spawnpoint_score_y / mindist;
250                         }
251                 }
252
253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
254                 {
255                         if(spot.spawnpoint_score_y < mindist)
256                         {
257                                 // too short distance
258                                 spawn_allgood = FALSE;
259                         }
260                         else
261                         {
262                                 // perfect
263                                 spawn_allbad = FALSE;
264
265                                 if(spotlistend)
266                                         spotlistend.chain = spot;
267                                 spotlistend = spot;
268                                 if(!spotlist)
269                                         spotlist = spot;
270
271                                 /*
272                                 if(teamcheck >= 0)
273                                 if(spot.team != teamcheck)
274                                         error("invalid spawn added");
275
276                                 print("added ", etos(spot), "\n");
277                                 */
278                         }
279                 }
280         }
281         if(spotlistend)
282                 spotlistend.chain = world;
283
284         /*
285                 entity e;
286                 if(teamcheck >= 0)
287                         for(e = spotlist; e; e = e.chain)
288                         {
289                                 print("seen ", etos(e), "\n");
290                                 if(e.team != teamcheck)
291                                         error("invalid spawn found");
292                         }
293         */
294
295         return spotlist;
296 }
297
298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
299 {
300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
302         local entity spot;
303
304         RandomSelection_Init();
305         for(spot = firstspot; spot; spot = spot.chain)
306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
307
308         return RandomSelection_chosen_ent;
309 }
310
311 /*
312 =============
313 SelectSpawnPoint
314
315 Finds a point to respawn
316 =============
317 */
318 entity SelectSpawnPoint (float anypoint)
319 {
320         local float teamcheck;
321         local entity firstspot_new;
322         local entity spot, firstspot, playerlist;
323
324         spot = find (world, classname, "testplayerstart");
325         if (spot)
326                 return spot;
327
328         if(anypoint)
329                 teamcheck = -1;
330         else if(have_team_spawns > 0)
331         {
332                 if(have_team_spawns_forteam[self.team] == 0)
333                 {
334                         // we request a spawn for a team, and we have team
335                         // spawns, but that team has no spawns?
336                         if(have_team_spawns_forteam[0])
337                                 // try noteam spawns
338                                 teamcheck = 0;
339                         else
340                                 // if not, any spawn has to do
341                                 teamcheck = -1;
342                 }
343                 else
344                         teamcheck = self.team; // MUST be team
345         }
346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
347                 teamcheck = 0; // MUST be noteam
348         else
349                 teamcheck = -1;
350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
351
352
353         // get the list of players
354         playerlist = findchain(classname, "player");
355         // get the entire list of spots
356         firstspot = findchain(classname, "info_player_deathmatch");
357         // filter out the bad ones
358         // (note this returns the original list if none survived)
359         if(anypoint)
360         {
361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
362         }
363         else
364         {
365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
366                 if(!firstspot_new)
367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
368                 firstspot = firstspot_new;
369
370                 // there is 50/50 chance of choosing a random spot or the furthest spot
371                 // (this means that roughly every other spawn will be furthest, so you
372                 // usually won't get fragged at spawn twice in a row)
373                 if (arena_roundbased && !g_ca)
374                 {
375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
376                         if(firstspot_new)
377                                 firstspot = firstspot_new;
378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
379                 }
380                 else if (random() > autocvar_g_spawn_furthest)
381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
382                 else
383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
384         }
385
386         if(autocvar_spawn_debugview)
387         {
388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
389
390                 entity e;
391                 if(teamcheck >= 0)
392                         for(e = firstspot; e; e = e.chain)
393                                 if(e.team != teamcheck)
394                                         error("invalid spawn found");
395         }
396
397         if (!spot)
398         {
399                 if(autocvar_spawn_debug)
400                         GotoNextMap();
401                 else
402                 {
403                         if(some_spawn_has_been_used)
404                                 return world; // team can't spawn any more, because of actions of other team
405                         else
406                                 error("Cannot find a spawn point - please fix the map!");
407                 }
408         }
409
410         return spot;
411 }
412
413 /*
414 =============
415 CheckPlayerModel
416
417 Checks if the argument string can be a valid playermodel.
418 Returns a valid one in doubt.
419 =============
420 */
421 string FallbackPlayerModel;
422 string CheckPlayerModel(string plyermodel) {
423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
424         {
425                 // note: we cannot summon Don Strunzone here, some player may
426                 // still have the model string set. In case anyone manages how
427                 // to change a cvar default, we'll have a small leak here.
428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
429         }
430         if(strlen(plyermodel) < 4)
431                 return FallbackPlayerModel;
432         if( substring(plyermodel,0,14) != "models/player/")
433                 return FallbackPlayerModel;
434         else if(autocvar_sv_servermodelsonly)
435         {
436                 if(substring(plyermodel,-4,4) != ".zym")
437                 if(substring(plyermodel,-4,4) != ".dpm")
438                 if(substring(plyermodel,-4,4) != ".iqm")
439                 if(substring(plyermodel,-4,4) != ".md3")
440                 if(substring(plyermodel,-4,4) != ".psk")
441                         return FallbackPlayerModel;
442                 // forbid the LOD models
443                 if(substring(plyermodel, -9,5) == "_lod1")
444                         return FallbackPlayerModel;
445                 if(substring(plyermodel, -9,5) == "_lod2")
446                         return FallbackPlayerModel;
447                 if(plyermodel != strtolower(plyermodel))
448                         return FallbackPlayerModel;
449                 if(!fexists(plyermodel))
450                         return FallbackPlayerModel;
451         }
452         return plyermodel;
453 }
454
455 /*
456 =============
457 Client_customizeentityforclient
458
459 LOD reduction
460 =============
461 */
462 void Client_uncustomizeentityforclient()
463 {
464         if(self.modelindex == 0) // no need to uncustomize then
465                 return;
466         self.modelindex = self.modelindex_lod0;
467         self.skin = self.skinindex;
468 }
469
470 float Client_customizeentityforclient()
471 {
472         entity modelsource;
473
474         if(self.modelindex == 0)
475                 return TRUE;
476
477         // forcemodel stuff
478
479 #ifdef PROFILING
480         float t0;
481         t0 = gettime(GETTIME_HIRES); // reference
482 #endif
483
484         modelsource = self;
485
486 #ifdef ALLOW_FORCEMODELS
487         if(other.cvar_cl_forceplayermodelsfromxonotic)
488                 if not(self.modelindex_lod0_from_xonotic)
489                         modelsource = other;
490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
491                 modelsource = other;
492 #endif
493
494         self.skin = modelsource.skinindex;
495
496 #if 0
497         if(modelsource == self)
498                 self.skin = modelsource.skinindex;
499         else
500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
501 #endif
502
503         // self: me
504         // other: the player viewing me
505         float distance;
506         float f;
507
508         if(other.cvar_cl_playerdetailreduction <= 0)
509         {
510                 if(other.cvar_cl_playerdetailreduction <= -2)
511                         self.modelindex = modelsource.modelindex_lod2;
512                 else if(other.cvar_cl_playerdetailreduction <= -1)
513                         self.modelindex = modelsource.modelindex_lod1;
514                 else
515                         self.modelindex = modelsource.modelindex_lod0;
516         }
517         else
518         {
519                 distance = vlen(self.origin - other.origin);
520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
521                 if(f > sv_loddistance2)
522                         self.modelindex = modelsource.modelindex_lod2;
523                 else if(f > sv_loddistance1)
524                         self.modelindex = modelsource.modelindex_lod1;
525                 else
526                         self.modelindex = modelsource.modelindex_lod0;
527         }
528
529 #ifdef PROFILING
530         float t1;
531         t1 = gettime(GETTIME_HIRES); // reference
532         client_cefc_accumulator += (t1 - t0);
533 #endif
534
535         return TRUE;
536 }
537
538 void setmodel_lod(entity e, string modelname)
539 {
540         string s;
541
542         if(sv_loddistance1)
543         {
544                 // FIXME: this only supports 3-letter extensions
545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
546                 if(fexists(s))
547                 {
548                         setmodel(e, s); // players have high precision
549                         self.modelindex_lod1 = self.modelindex;
550                 }
551                 else
552                         self.modelindex_lod1 = -1;
553
554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
555                 if(fexists(s))
556                 {
557                         setmodel(e, s); // players have high precision
558                         self.modelindex_lod2 = self.modelindex;
559                 }
560                 else
561                         self.modelindex_lod2 = -1;
562
563                 precache_model(modelname);
564                 setmodel(e, modelname); // players have high precision
565                 self.modelindex_lod0 = self.modelindex;
566
567                 if(self.modelindex_lod1 < 0)
568                         self.modelindex_lod1 = self.modelindex;
569
570                 if(self.modelindex_lod2 < 0)
571                         self.modelindex_lod2 = self.modelindex;
572         }
573         else
574         {
575                 precache_model(modelname);
576                 setmodel(e, modelname); // players have high precision
577                 self.modelindex_lod0 = self.modelindex;
578                         // save it for possible player model forcing
579         }
580
581         s = whichpack(self.model);
582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
583
584         player_setupanimsformodel();
585         UpdatePlayerSounds();
586 }
587
588 /*
589 =============
590 PutObserverInServer
591
592 putting a client as observer in the server
593 =============
594 */
595 void FixPlayermodel();
596 void PutObserverInServer (void)
597 {
598         entity  spot;
599     self.hud = HUD_NORMAL;
600         race_PreSpawnObserver();
601
602         spot = SelectSpawnPoint (TRUE);
603         if(!spot)
604                 error("No spawnpoints for observers?!?\n");
605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
606
607         if(clienttype(self) == CLIENTTYPE_REAL)
608         {
609                 msg_entity = self;
610                 WriteByte(MSG_ONE, SVC_SETVIEW);
611                 WriteEntity(MSG_ONE, self);
612         }
613
614         DropAllRunes(self);
615         MUTATOR_CALLHOOK(MakePlayerObserver);
616
617         if (g_minstagib)
618                 minstagib_stop_countdown();
619
620         Portal_ClearAll(self);
621
622         if(self.alivetime)
623         {
624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
625                 self.alivetime = 0;
626         }
627
628         if(self.vehicle)
629             vehicles_exit(VHEF_RELESE);
630
631         if(self.flagcarried)
632                 DropFlag(self.flagcarried, world, world);
633
634         if(self.ballcarried && g_nexball)
635                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
636
637         WaypointSprite_PlayerDead();
638
639         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
640                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
641
642         if(self.killcount != -666) {
643                 if(g_lms) {
644                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
645                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
646                         else
647                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
648                 } else
649                         bprint ("^4", self.netname, "^4 is spectating now\n");
650
651                 if(self.just_joined == FALSE) {
652                         LogTeamchange(self.playerid, -1, 4);
653                 } else
654                         self.just_joined = FALSE;
655         }
656
657         PlayerScore_Clear(self); // clear scores when needed
658
659         accuracy_resend(self);
660
661         self.spectatortime = time;
662
663         self.classname = "observer";
664         self.iscreature = FALSE;
665         self.health = -666;
666         self.takedamage = DAMAGE_NO;
667         self.solid = SOLID_NOT;
668         self.movetype = MOVETYPE_NOCLIP;
669         self.flags = FL_CLIENT | FL_NOTARGET;
670         self.armorvalue = 666;
671         self.effects = 0;
672         self.armorvalue = autocvar_g_balance_armor_start;
673         self.pauserotarmor_finished = 0;
674         self.pauserothealth_finished = 0;
675         self.pauseregen_finished = 0;
676         self.damageforcescale = 0;
677         self.death_time = 0;
678         self.dead_frame = 0;
679         self.alpha = 0;
680         self.scale = 0;
681         self.fade_time = 0;
682         self.pain_frame = 0;
683         self.pain_finished = 0;
684         self.strength_finished = 0;
685         self.invincible_finished = 0;
686         self.pushltime = 0;
687         self.think = SUB_Null;
688         self.nextthink = 0;
689         self.hook_time = 0;
690         self.runes = 0;
691         self.deadflag = DEAD_NO;
692         self.angles = spot.angles;
693         self.angles_z = 0;
694         self.fixangle = TRUE;
695         self.crouch = FALSE;
696
697         self.view_ofs = PL_VIEW_OFS;
698         setorigin (self, spot.origin);
699         setsize (self, '0 0 0', '0 0 0');
700         self.prevorigin = self.origin;
701         self.items = 0;
702         self.weapons = 0;
703         self.model = "";
704         FixPlayermodel();
705         self.model = "";
706         self.modelindex = 0;
707         self.weapon = 0;
708         self.weaponmodel = "";
709         self.weaponentity = world;
710         self.exteriorweaponentity = world;
711         self.killcount = -666;
712         self.velocity = '0 0 0';
713         self.avelocity = '0 0 0';
714         self.punchangle = '0 0 0';
715         self.punchvector = '0 0 0';
716         self.oldvelocity = self.velocity;
717         self.fire_endtime = -1;
718
719         if(sv_loddistance1)
720                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
721
722         if(g_arena)
723         {
724                 if(self.version_mismatch)
725                 {
726                         Spawnqueue_Unmark(self);
727                         Spawnqueue_Remove(self);
728                 }
729                 else
730                 {
731                         Spawnqueue_Insert(self);
732                 }
733         }
734         else if(g_lms)
735         {
736                 // Only if the player cannot play at all
737                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
738                         self.frags = FRAGS_SPECTATOR;
739                 else
740                         self.frags = FRAGS_LMS_LOSER;
741         }
742         else
743                 self.frags = FRAGS_SPECTATOR;
744 }
745
746 void FixPlayermodel()
747 {
748         local string defaultmodel;
749         local float defaultskin, chmdl, oldskin;
750         local vector m1, m2;
751
752         defaultmodel = "";
753
754         if(autocvar_sv_defaultcharacter == 1) {
755                 defaultskin = 0;
756
757                 if(teamplay)
758                 {
759                         string s;
760                         s = Team_ColorNameLowerCase(self.team);
761                         if(s != "neutral")
762                         {
763                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
764                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
765                         }
766                 }
767
768                 if(defaultmodel == "")
769                 {
770                         defaultmodel = autocvar_sv_defaultplayermodel;
771                         defaultskin = autocvar_sv_defaultplayerskin;
772                 }
773         }
774
775         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
776         {
777                 if(self.model != "")
778                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
779                 self.model = ""; // force the != checks to return true
780         }
781
782         if(defaultmodel != "")
783         {
784                 if (defaultmodel != self.model)
785                 {
786                         m1 = self.mins;
787                         m2 = self.maxs;
788                         setmodel_lod (self, defaultmodel);
789                         setsize (self, m1, m2);
790                         chmdl = TRUE;
791                 }
792
793                 oldskin = self.skinindex;
794                 self.skinindex = defaultskin;
795         } else {
796                 if (self.playermodel != self.model || self.playermodel == "")
797                 {
798                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
799                         m1 = self.mins;
800                         m2 = self.maxs;
801                         setmodel_lod (self, self.playermodel);
802                         setsize (self, m1, m2);
803                         chmdl = TRUE;
804                 }
805
806                 oldskin = self.skinindex;
807                 self.skinindex = stof(self.playerskin);
808         }
809
810         if(chmdl || oldskin != self.skinindex)
811                 self.species = player_getspecies(); // model or skin has changed
812
813         if(!teamplay)
814                 if(strlen(autocvar_sv_defaultplayercolors))
815                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
816                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
817 }
818
819 void PlayerTouchExplode(entity p1, entity p2)
820 {
821         vector org;
822         org = (p1.origin + p2.origin) * 0.5;
823         org_z += (p1.mins_z + p2.mins_z) * 0.5;
824
825         te_explosion(org);
826
827         entity e;
828         e = spawn();
829         setorigin(e, org);
830         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
831         remove(e);
832 }
833
834 /*
835 =============
836 PutClientInServer
837
838 Called when a client spawns in the server
839 =============
840 */
841 //void() ctf_playerchanged;
842 void PutClientInServer (void)
843 {
844         if(clienttype(self) == CLIENTTYPE_BOT)
845         {
846                 self.classname = "player";
847         }
848         else if(clienttype(self) == CLIENTTYPE_REAL)
849         {
850                 msg_entity = self;
851                 WriteByte(MSG_ONE, SVC_SETVIEW);
852                 WriteEntity(MSG_ONE, self);
853         }
854
855         // player is dead and becomes observer
856         // FIXME fix LMS scoring for new system
857         if(g_lms)
858         {
859                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
860                         self.classname = "observer";
861         }
862
863         if(g_arena || (g_ca && !allowed_to_spawn))
864         if(!self.spawned)
865                 self.classname = "observer";
866
867         if(gameover)
868                 self.classname = "observer";
869
870         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
871                 entity spot, oldself;
872                 float j;
873
874                 accuracy_resend(self);
875
876                 if(self.team < 0)
877                         JoinBestTeam(self, FALSE, TRUE);
878
879                 race_PreSpawn();
880
881                 spot = SelectSpawnPoint (FALSE);
882                 if(!spot)
883                 {
884                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
885                         return; // spawn failed
886                 }
887
888                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
889
890                 self.classname = "player";
891                 self.wasplayer = TRUE;
892                 self.iscreature = TRUE;
893                 self.movetype = MOVETYPE_WALK;
894                 self.solid = SOLID_SLIDEBOX;
895                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
896                 if(autocvar_g_playerclip_collisions)
897                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
898                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
899                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
900                 self.frags = FRAGS_PLAYER;
901                 if(independent_players)
902                         MAKE_INDEPENDENT_PLAYER(self);
903                 self.flags = FL_CLIENT;
904                 self.takedamage = DAMAGE_AIM;
905                 if(g_minstagib)
906                         self.effects = EF_FULLBRIGHT;
907                 else
908                         self.effects = 0;
909                 self.air_finished = time + 12;
910                 self.dmg = 2;
911                 if(autocvar_g_balance_nex_charge)
912                 {
913                         if(autocvar_g_balance_nex_secondary_chargepool)
914                                 self.nex_chargepool_ammo = 1;
915                         self.nex_charge = autocvar_g_balance_nex_charge_start;
916                 }
917
918                 if(inWarmupStage)
919                 {
920                         self.ammo_shells = warmup_start_ammo_shells;
921                         self.ammo_nails = warmup_start_ammo_nails;
922                         self.ammo_rockets = warmup_start_ammo_rockets;
923                         self.ammo_cells = warmup_start_ammo_cells;
924                         self.ammo_fuel = warmup_start_ammo_fuel;
925                         self.health = warmup_start_health;
926                         self.armorvalue = warmup_start_armorvalue;
927                         self.weapons = warmup_start_weapons;
928                 }
929                 else
930                 {
931                         self.ammo_shells = start_ammo_shells;
932                         self.ammo_nails = start_ammo_nails;
933                         self.ammo_rockets = start_ammo_rockets;
934                         self.ammo_cells = start_ammo_cells;
935                         self.ammo_fuel = start_ammo_fuel;
936                         self.health = start_health;
937                         self.armorvalue = start_armorvalue;
938                         self.weapons = start_weapons;
939                 }
940
941                 if(g_weaponarena_random)
942                 {
943                         if(g_weaponarena_random_with_laser)
944                                 self.weapons &~= WEPBIT_LASER;
945                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
946                         if(g_weaponarena_random_with_laser)
947                                 self.weapons |= WEPBIT_LASER;
948                 }
949
950                 self.items = start_items;
951                 self.jump_interval = time;
952
953                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
954                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
955                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
956                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
957                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
958                 //extend the pause of rotting if client was reset at the beginning of the countdown
959                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
960                         self.spawnshieldtime += game_starttime - time;
961                         self.pauserotarmor_finished += game_starttime - time;
962                         self.pauserothealth_finished += game_starttime - time;
963                         self.pauseregen_finished += game_starttime - time;
964                 }
965                 self.damageforcescale = 2;
966                 self.death_time = 0;
967                 self.dead_frame = 0;
968                 self.alpha = 0;
969                 self.scale = 0;
970                 self.fade_time = 0;
971                 self.pain_frame = 0;
972                 self.pain_finished = 0;
973                 self.strength_finished = 0;
974                 self.invincible_finished = 0;
975                 self.pushltime = 0;
976                 // players have no think function
977                 self.think = SUB_Null;
978                 self.nextthink = 0;
979                 self.hook_time = 0;
980                 self.dmg_team = 0;
981                 self.ballistics_density = autocvar_g_ballistics_density_player;
982
983                 self.metertime = 0;
984
985                 self.runes = 0;
986
987                 self.deadflag = DEAD_NO;
988
989                 self.angles = spot.angles;
990
991                 self.angles_z = 0; // never spawn tilted even if the spot says to
992                 self.fixangle = TRUE; // turn this way immediately
993                 self.velocity = '0 0 0';
994                 self.avelocity = '0 0 0';
995                 self.punchangle = '0 0 0';
996                 self.punchvector = '0 0 0';
997                 self.oldvelocity = self.velocity;
998                 self.fire_endtime = -1;
999
1000                 msg_entity = self;
1001                 WRITESPECTATABLE_MSG_ONE({
1002                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1003                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1004                 });
1005
1006                 if(sv_loddistance1)
1007                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1008
1009                 self.model = "";
1010                 FixPlayermodel();
1011
1012                 self.crouch = FALSE;
1013                 self.view_ofs = PL_VIEW_OFS;
1014                 setsize (self, PL_MIN, PL_MAX);
1015                 self.spawnorigin = spot.origin;
1016                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1017                 // don't reset back to last position, even if new position is stuck in solid
1018                 self.oldorigin = self.origin;
1019                 self.prevorigin = self.origin;
1020                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1021                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1022
1023                 if(g_arena)
1024                 {
1025                         Spawnqueue_Remove(self);
1026                         Spawnqueue_Mark(self);
1027                 }
1028
1029                 else if(g_ca)
1030                         self.caplayer = 1;
1031
1032                 self.event_damage = PlayerDamage;
1033
1034                 self.bot_attack = TRUE;
1035
1036                 self.statdraintime = time + 5;
1037                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1038
1039                 if(self.killcount == -666) {
1040                         PlayerScore_Clear(self);
1041                         self.killcount = 0;
1042                 }
1043
1044                 self.cnt = WEP_LASER;
1045
1046                 CL_SpawnWeaponentity();
1047                 self.alpha = default_player_alpha;
1048                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1049                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1050
1051                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1052                 self.lms_traveled_distance = 0;
1053                 self.speedrunning = FALSE;
1054
1055                 race_PostSpawn(spot);
1056
1057                 if(autocvar_spawn_debug)
1058                 {
1059                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1060                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1061                 }
1062
1063                 //stuffcmd(self, "chase_active 0");
1064                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1065
1066                 if (autocvar_g_spawnsound)
1067                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1068
1069                 if(g_assault) {
1070                         if(self.team == assault_attacker_team)
1071                                 centerprint(self, "You are attacking!");
1072                         else
1073                                 centerprint(self, "You are defending!");
1074                 }
1075
1076                 target_voicescript_clear(self);
1077
1078                 // reset fields the weapons may use
1079                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1080                 {
1081                         weapon_action(j, WR_RESETPLAYER);
1082
1083                         // all weapons must be fully loaded when we spawn
1084                         entity e;
1085                         e = get_weaponinfo(j);
1086                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1087                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1088                 }
1089                 self.weapon_forbidchange = FALSE;
1090
1091                 oldself = self;
1092                 self = spot;
1093                         activator = oldself;
1094                                 string s;
1095                                 s = self.target;
1096                                 self.target = string_null;
1097                                 SUB_UseTargets();
1098                                 self.target = s;
1099                         activator = world;
1100                 self = oldself;
1101
1102                 MUTATOR_CALLHOOK(PlayerSpawn);
1103
1104                 self.switchweapon = w_getbestweapon(self);
1105                 self.cnt = self.switchweapon;
1106                 self.weapon = 0;
1107
1108                 if(!self.alivetime)
1109                         self.alivetime = time;
1110         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1111                 PutObserverInServer ();
1112         }
1113
1114         //if(g_ctf)
1115         //      ctf_playerchanged();
1116 }
1117
1118 .float ebouncefactor, ebouncestop; // electro's values
1119 // TODO do we need all these fields, or should we stop autodetecting runtime
1120 // changes and just have a console command to update this?
1121 float ClientInit_SendEntity(entity to, float sf)
1122 {
1123         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1124         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1125         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1126         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1127         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1128         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1129         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1130         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1131         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1132         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1133         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1134         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1135         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1136         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1137         if(sv_foginterval && world.fog != "")
1138                 WriteString(MSG_ENTITY, world.fog);
1139         else
1140                 WriteString(MSG_ENTITY, "");
1141         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1142         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1143         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1144         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1145         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1146         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1147         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1148         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1149         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1150         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1151         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1152         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1153         return TRUE;
1154 }
1155
1156 void ClientInit_CheckUpdate()
1157 {
1158         self.nextthink = time;
1159         if(self.count != autocvar_g_balance_armor_blockpercent)
1160         {
1161                 self.count = autocvar_g_balance_armor_blockpercent;
1162                 self.SendFlags |= 1;
1163         }
1164         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1165         {
1166                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1167                 self.SendFlags |= 1;
1168         }
1169         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1170         {
1171                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1172                 self.SendFlags |= 1;
1173         }
1174         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1175         {
1176                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1177                 self.SendFlags |= 1;
1178         }
1179         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1180         {
1181                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1182                 self.SendFlags |= 1;
1183         }
1184         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1185         {
1186                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1187                 self.SendFlags |= 1;
1188         }
1189 }
1190
1191 void ClientInit_Spawn()
1192 {
1193         entity o;
1194         entity e;
1195         e = spawn();
1196         e.classname = "clientinit";
1197         e.think = ClientInit_CheckUpdate;
1198         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1199
1200         o = self;
1201         self = e;
1202         ClientInit_CheckUpdate();
1203         self = o;
1204 }
1205
1206 /*
1207 =============
1208 SetNewParms
1209 =============
1210 */
1211 void SetNewParms (void)
1212 {
1213         // initialize parms for a new player
1214         parm1 = -(86400 * 366);
1215 }
1216
1217 /*
1218 =============
1219 SetChangeParms
1220 =============
1221 */
1222 void SetChangeParms (void)
1223 {
1224         // save parms for level change
1225         parm1 = self.parm_idlesince - time;
1226 }
1227
1228 /*
1229 =============
1230 DecodeLevelParms
1231 =============
1232 */
1233 void DecodeLevelParms (void)
1234 {
1235         // load parms
1236         self.parm_idlesince = parm1;
1237         if(self.parm_idlesince == -(86400 * 366))
1238                 self.parm_idlesince = time;
1239
1240         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1241         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1242 }
1243
1244 /*
1245 =============
1246 ClientKill
1247
1248 Called when a client types 'kill' in the console
1249 =============
1250 */
1251
1252 .float clientkill_nexttime;
1253 void ClientKill_Now_TeamChange()
1254 {
1255         if(self.killindicator_teamchange == -1)
1256         {
1257                 self.team = -1;
1258                 JoinBestTeam( self, FALSE, FALSE );
1259         }
1260         else if(self.killindicator_teamchange == -2)
1261         {
1262                 if(g_ca)
1263                         self.caplayer = 0;
1264                 if(blockSpectators)
1265                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1266                 PutObserverInServer();
1267         }
1268         else
1269                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1270 }
1271
1272 void ClientKill_Now()
1273 {
1274         if(self.vehicle)
1275         {
1276             vehicles_exit(VHEF_RELESE);
1277             if(!self.killindicator_teamchange)
1278             {
1279             self.vehicle_health = -1;
1280             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');             
1281             }
1282         }
1283
1284         if(self.killindicator && !wasfreed(self.killindicator))
1285                 remove(self.killindicator);
1286
1287         self.killindicator = world;
1288
1289         if(self.killindicator_teamchange)
1290                 ClientKill_Now_TeamChange();
1291
1292         // in any case:
1293         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1294
1295         // now I am sure the player IS dead
1296 }
1297 void KillIndicator_Think()
1298 {
1299         if (gameover)
1300         {
1301                 self.owner.killindicator = world;
1302                 remove(self);
1303                 return;
1304         }
1305
1306         if (!self.owner.modelindex)
1307         {
1308                 self.owner.killindicator = world;
1309                 remove(self);
1310                 return;
1311         }
1312
1313         if(self.cnt <= 0)
1314         {
1315                 self = self.owner;
1316                 ClientKill_Now(); // no oldself needed
1317                 return;
1318         }
1319     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1320     {
1321         self.nextthink = time + 1;
1322         self.cnt -= 1;
1323     }
1324         else
1325         {
1326                 if(self.cnt <= 10)
1327                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1328                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1329                 {
1330                         if(self.cnt <= 10)
1331                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1332                 }
1333                 self.nextthink = time + 1;
1334                 self.cnt -= 1;
1335         }
1336 }
1337
1338 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1339 {
1340         float killtime;
1341         entity e;
1342
1343         if (gameover)
1344                 return;
1345
1346         killtime = autocvar_g_balance_kill_delay;
1347
1348         if(g_race_qualifying || g_cts)
1349                 killtime = 0;
1350
1351     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1352     {
1353                 remove(self.killindicator);
1354                 self.killindicator = world;
1355
1356         ClientKill_Now(); // allow instant kill in this case
1357         return;
1358     }
1359
1360         self.killindicator_teamchange = targetteam;
1361
1362     if(!self.killindicator)
1363         {
1364                 if(self.modelindex && self.deadflag == DEAD_NO)
1365                 {
1366                         killtime = max(killtime, self.clientkill_nexttime - time);
1367                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1368                 }
1369
1370                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1371                 {
1372                         ClientKill_Now();
1373                 }
1374                 else
1375                 {
1376                         self.killindicator = spawn();
1377                         self.killindicator.owner = self;
1378                         self.killindicator.scale = 0.5;
1379                         setattachment(self.killindicator, self, "");
1380                         setorigin(self.killindicator, '0 0 52');
1381                         self.killindicator.think = KillIndicator_Think;
1382                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1383                         self.killindicator.cnt = ceil(killtime);
1384                         self.killindicator.count = bound(0, ceil(killtime), 10);
1385                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1386
1387                         for(e = world; (e = find(e, classname, "body")) != world; )
1388                         {
1389                                 if(e.enemy != self)
1390                                         continue;
1391                                 e.killindicator = spawn();
1392                                 e.killindicator.owner = e;
1393                                 e.killindicator.scale = 0.5;
1394                                 setattachment(e.killindicator, e, "");
1395                                 setorigin(e.killindicator, '0 0 52');
1396                                 e.killindicator.think = KillIndicator_Think;
1397                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1398                                 e.killindicator.cnt = ceil(killtime);
1399                         }
1400                         self.lip = 0;
1401                 }
1402         }
1403         if(self.killindicator)
1404         {
1405                 if(targetteam == 0) // just die
1406                 {
1407                         self.killindicator.colormod = '0 0 0';
1408                         if(clienttype(self) == CLIENTTYPE_REAL)
1409                         if(self.killindicator.cnt > 0)
1410                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1411                 }
1412                 else if(targetteam == -1) // auto
1413                 {
1414                         self.killindicator.colormod = '0 1 0';
1415                         if(clienttype(self) == CLIENTTYPE_REAL)
1416                         if(self.killindicator.cnt > 0)
1417                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1418                 }
1419                 else if(targetteam == -2) // spectate
1420                 {
1421                         self.killindicator.colormod = '0.5 0.5 0.5';
1422                         if(clienttype(self) == CLIENTTYPE_REAL)
1423                         if(self.killindicator.cnt > 0)
1424                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1425                 }
1426                 else
1427                 {
1428                         self.killindicator.colormod = TeamColor(targetteam);
1429                         if(clienttype(self) == CLIENTTYPE_REAL)
1430                         if(self.killindicator.cnt > 0)
1431                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1432                 }
1433         }
1434
1435 }
1436
1437 void ClientKill (void)
1438 {
1439         if (gameover)
1440                 return;
1441
1442         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1443         {
1444                 // do nothing
1445         }
1446     else if(self.freezetag_frozen)
1447     {
1448         // do nothing
1449     }
1450         else
1451                 ClientKill_TeamChange(0);
1452 }
1453
1454 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1455 {
1456     e.killindicator = spawn();
1457     e.killindicator.owner = e;
1458     e.killindicator.think = KillIndicator_Think;
1459     e.killindicator.nextthink = time + (e.lip) * 0.05;
1460     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1461     e.killindicator.health = 1; // this is used to indicate that it should be silent
1462     e.lip = 0;
1463 }
1464
1465 void FixClientCvars(entity e)
1466 {
1467         // send prediction settings to the client
1468         stuffcmd(e, "\nin_bindmap 0 0\n");
1469         if(g_race || g_cts)
1470                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1471         if(autocvar_g_antilag == 3) // client side hitscan
1472                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1473         if(sv_gentle)
1474                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1475         /*
1476          * we no longer need to stuff this. Remove this comment block if you feel
1477          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1478         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1479         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1480         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1481         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1482         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1483         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1484         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1485         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1486         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1487         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1488         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1489         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1490         stuffcmd(e, "cl_movement_edgefriction 1\n");
1491          */
1492 }
1493
1494 float PlayerInIDList(entity p, string idlist)
1495 {
1496         float n, i;
1497         string s;
1498
1499         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1500         if not(p.crypto_idfp)
1501                 return 0;
1502
1503         // this function allows abbreviated player IDs too!
1504         n = tokenize_console(idlist);
1505         for(i = 0; i < n; ++i)
1506         {
1507                 s = argv(i);
1508                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1509                         return 1;
1510         }
1511
1512         return 0;
1513 }
1514
1515 /*
1516 =============
1517 ClientConnect
1518
1519 Called when a client connects to the server
1520 =============
1521 */
1522 //void ctf_clientconnect();
1523 string ColoredTeamName(float t);
1524 void DecodeLevelParms (void);
1525 //void dom_player_join_team(entity pl);
1526 void set_dom_state(entity e);
1527 void ClientConnect (void)
1528 {
1529         float t;
1530
1531         if(self.flags & FL_CLIENT)
1532         {
1533                 print("Warning: ClientConnect, but already connected!\n");
1534                 return;
1535         }
1536
1537         if(Ban_MaybeEnforceBan(self))
1538                 return;
1539
1540         DecodeLevelParms();
1541
1542 #ifdef WATERMARK
1543         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1544 #endif
1545
1546         self.classname = "player_joining";
1547
1548         self.flags = FL_CLIENT;
1549         self.version_nagtime = time + 10 + random() * 10;
1550
1551         if(player_count<0)
1552         {
1553                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1554                 player_count = 0;
1555         }
1556
1557         PlayerScore_Attach(self);
1558         ClientData_Attach();
1559         accuracy_init(self);
1560
1561         bot_clientconnect();
1562
1563         playerdemo_init();
1564
1565         anticheat_init();
1566
1567         race_PreSpawnObserver();
1568
1569         //if(g_domination)
1570         //      dom_player_join_team(self);
1571
1572         // identify the right forced team
1573         if(autocvar_g_campaign)
1574         {
1575                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1576                 {
1577                         switch(autocvar_g_campaign_forceteam)
1578                         {
1579                                 case 1: self.team_forced = COLOR_TEAM1; break;
1580                                 case 2: self.team_forced = COLOR_TEAM2; break;
1581                                 case 3: self.team_forced = COLOR_TEAM3; break;
1582                                 case 4: self.team_forced = COLOR_TEAM4; break;
1583                                 default: self.team_forced = 0;
1584                         }
1585                 }
1586         }
1587         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1588                 self.team_forced = COLOR_TEAM1;
1589         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1590                 self.team_forced = COLOR_TEAM2;
1591         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1592                 self.team_forced = COLOR_TEAM3;
1593         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1594                 self.team_forced = COLOR_TEAM4;
1595         else if(autocvar_g_forced_team_otherwise == "red")
1596                 self.team_forced = COLOR_TEAM1;
1597         else if(autocvar_g_forced_team_otherwise == "blue")
1598                 self.team_forced = COLOR_TEAM2;
1599         else if(autocvar_g_forced_team_otherwise == "yellow")
1600                 self.team_forced = COLOR_TEAM3;
1601         else if(autocvar_g_forced_team_otherwise == "pink")
1602                 self.team_forced = COLOR_TEAM4;
1603         else if(autocvar_g_forced_team_otherwise == "spectate")
1604                 self.team_forced = -1;
1605         else if(autocvar_g_forced_team_otherwise == "spectator")
1606                 self.team_forced = -1;
1607         else
1608                 self.team_forced = 0;
1609
1610         if(!teamplay)
1611                 if(self.team_forced > 0)
1612                         self.team_forced = 0;
1613
1614         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1615
1616         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1617                 self.classname = "observer";
1618         } else {
1619                 if(teamplay)
1620                 {
1621                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1622                         {
1623                                 self.classname = "player";
1624                                 campaign_bots_may_start = 1;
1625                         }
1626                         else
1627                         {
1628                                 self.classname = "observer"; // do it anyway
1629                         }
1630                 }
1631                 else
1632                 {
1633                         self.classname = "player";
1634                         campaign_bots_may_start = 1;
1635                 }
1636         }
1637
1638         self.playerid = (playerid_last = playerid_last + 1);
1639
1640         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1641
1642     if(clienttype(self) == CLIENTTYPE_BOT)
1643         PlayerStats_AddPlayer(self);
1644
1645         if(autocvar_sv_eventlog)
1646                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1647
1648         LogTeamchange(self.playerid, self.team, 1);
1649
1650         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1651
1652         self.netname_previous = strzone(self.netname);
1653
1654         bprint("^4", self.netname, "^4 connected");
1655
1656         if(self.classname != "observer" && (g_domination || g_ctf))
1657                 bprint(" and joined the ", ColoredTeamName(self.team));
1658
1659         bprint("\n");
1660
1661         stuffcmd(self, strcat(clientstuff, "\n"));
1662         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1663         stuffcmd(self, "cl_particles_reloadeffects\n");
1664
1665         FixClientCvars(self);
1666
1667         // spawnfunc_waypoint sprites
1668         WaypointSprite_InitClient(self);
1669
1670         // Wazat's grappling hook
1671         SetGrappleHookBindings();
1672
1673         // get autoswitch state from player when he toggles it
1674         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1675
1676         // get version info from player
1677         stuffcmd(self, "cmd clientversion $gameversion\n");
1678
1679         // get other cvars from player
1680         GetCvars(0);
1681
1682         // notify about available teams
1683         if(teamplay)
1684         {
1685                 CheckAllowedTeams(self);
1686                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1687                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1688         }
1689         else
1690                 stuffcmd(self, "set _teams_available 0\n");
1691
1692         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1693
1694         if(g_arena || g_ca)
1695         {
1696                 self.classname = "observer";
1697                 if(g_arena)
1698                         Spawnqueue_Insert(self);
1699         }
1700         /*else if(g_ctf)
1701         {
1702                 ctf_clientconnect();
1703         }*/
1704
1705         attach_entcs();
1706
1707         bot_relinkplayerlist();
1708
1709         self.spectatortime = time;
1710         if(blockSpectators)
1711         {
1712                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1713         }
1714
1715         self.jointime = time;
1716         self.allowedTimeouts = autocvar_sv_timeout_number;
1717
1718         if(clienttype(self) == CLIENTTYPE_REAL)
1719         {
1720                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1721                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1722         }
1723
1724         if(g_lms)
1725         {
1726                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1727                 {
1728                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1729                         self.frags = FRAGS_SPECTATOR;
1730                 }
1731         }
1732
1733         if(!sv_foginterval && world.fog != "")
1734                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1735
1736         SoundEntity_Attach(self);
1737
1738         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1739         {
1740                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1741                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1742         }
1743         else
1744                 self.hitplotfh = -1;
1745
1746         if(g_race || g_cts) {
1747                 string rr;
1748                 if(g_cts)
1749                         rr = CTS_RECORD;
1750                 else
1751                         rr = RACE_RECORD;
1752                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1753
1754                 msg_entity = self;
1755                 race_send_recordtime(MSG_ONE);
1756                 race_send_speedaward(MSG_ONE);
1757
1758                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1759                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1760                 race_send_speedaward_alltimebest(MSG_ONE);
1761
1762                 float i;
1763                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1764                         race_SendRankings(i, 0, 0, MSG_ONE);
1765                 }
1766         }
1767         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1768                 send_CSQC_teamnagger();
1769
1770         if (g_domination)
1771                 set_dom_state(self);
1772
1773         CheatInitClient();
1774
1775         if(!autocvar_g_campaign)
1776                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1777 }
1778
1779 /*
1780 =============
1781 ClientDisconnect
1782
1783 Called when a client disconnects from the server
1784 =============
1785 */
1786 .entity chatbubbleentity;
1787 void ReadyCount();
1788 void ClientDisconnect (void)
1789 {
1790         if(self.vehicle)
1791             vehicles_exit(VHEF_RELESE);
1792
1793         if not(self.flags & FL_CLIENT)
1794         {
1795                 print("Warning: ClientDisconnect without ClientConnect\n");
1796                 return;
1797         }
1798
1799         PlayerStats_AddGlobalInfo(self);
1800
1801         CheatShutdownClient();
1802
1803         if(self.hitplotfh >= 0)
1804         {
1805                 fclose(self.hitplotfh);
1806                 self.hitplotfh = -1;
1807         }
1808
1809         anticheat_report();
1810         anticheat_shutdown();
1811
1812         playerdemo_shutdown();
1813
1814         bot_clientdisconnect();
1815
1816         if(self.entcs)
1817                 detach_entcs();
1818
1819         if(autocvar_sv_eventlog)
1820                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1821         bprint ("^4",self.netname);
1822         bprint ("^4 disconnected\n");
1823
1824         SoundEntity_Detach(self);
1825
1826         DropAllRunes(self);
1827         MUTATOR_CALLHOOK(ClientDisconnect);
1828
1829         Portal_ClearAll(self);
1830
1831         if(self.flagcarried)
1832                 DropFlag(self.flagcarried, world, world);
1833         if(self.ballcarried && g_nexball)
1834                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1835
1836         // Here, everything has been done that requires this player to be a client.
1837
1838         self.flags &~= FL_CLIENT;
1839
1840         if (self.chatbubbleentity)
1841                 remove (self.chatbubbleentity);
1842
1843         if (self.killindicator)
1844                 remove (self.killindicator);
1845
1846         WaypointSprite_PlayerGone();
1847
1848         bot_relinkplayerlist();
1849
1850         if(g_arena)
1851         {
1852                 Spawnqueue_Unmark(self);
1853                 Spawnqueue_Remove(self);
1854         }
1855
1856         accuracy_free(self);
1857         ClientData_Detach();
1858         PlayerScore_Detach(self);
1859
1860         if(self.netname_previous)
1861                 strunzone(self.netname_previous);
1862         if(self.clientstatus)
1863                 strunzone(self.clientstatus);
1864         if(self.weaponorder_byimpulse)
1865                 strunzone(self.weaponorder_byimpulse);
1866
1867         ClearPlayerSounds();
1868
1869         if(self.personal)
1870                 remove(self.personal);
1871
1872         self.playerid = 0;
1873         ReadyCount();
1874
1875         // free cvars
1876         GetCvars(-1);
1877 }
1878
1879 .float BUTTON_CHAT;
1880 void ChatBubbleThink()
1881 {
1882         self.nextthink = time;
1883         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1884         {
1885                 if(self.owner) // but why can that ever be world?
1886                         self.owner.chatbubbleentity = world;
1887                 remove(self);
1888                 return;
1889         }
1890         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1891 #ifdef TETRIS
1892                 || self.owner.tetris_on
1893 #endif
1894         )
1895                 self.model = self.mdl;
1896         else
1897                 self.model = "";
1898 };
1899
1900 void UpdateChatBubble()
1901 {
1902         if (!self.modelindex)
1903                 return;
1904         // spawn a chatbubble entity if needed
1905         if (!self.chatbubbleentity)
1906         {
1907                 self.chatbubbleentity = spawn();
1908                 self.chatbubbleentity.owner = self;
1909                 self.chatbubbleentity.exteriormodeltoclient = self;
1910                 self.chatbubbleentity.think = ChatBubbleThink;
1911                 self.chatbubbleentity.nextthink = time;
1912                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1913                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1914                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1915                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1916                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1917                 self.chatbubbleentity.model = "";
1918                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1919         }
1920 }
1921
1922
1923 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1924 // added to the model skins
1925 /*void UpdateColorModHack()
1926 {
1927         local float c;
1928         c = self.clientcolors & 15;
1929         // LordHavoc: only bothering to support white, green, red, yellow, blue
1930              if (!teamplay) self.colormod = '0 0 0';
1931         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1932         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1933         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1934         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1935         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1936         else self.colormod = '1 1 1';
1937 };*/
1938
1939 .float oldcolormap;
1940 void respawn(void)
1941 {
1942         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1943         {
1944                 self.solid = SOLID_NOT;
1945                 self.takedamage = DAMAGE_NO;
1946                 self.movetype = MOVETYPE_FLY;
1947                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1948                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1949                 self.effects |= EF_ADDITIVE;
1950                 self.oldcolormap = self.colormap;
1951                 self.colormap = 512;
1952                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1953                 if(autocvar_g_respawn_ghosts_maxtime)
1954                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1955         }
1956
1957         CopyBody(1);
1958         self.effects |= EF_NODRAW; // prevent another CopyBody
1959         if(self.oldcolormap)
1960         {
1961                 self.colormap = self.oldcolormap;
1962                 self.oldcolormap = 0;
1963         }
1964         PutClientInServer();
1965 }
1966
1967 void play_countdown(float finished, string samp)
1968 {
1969         if(clienttype(self) == CLIENTTYPE_REAL)
1970                 if(floor(finished - time - frametime) != floor(finished - time))
1971                         if(finished - time < 6)
1972                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1973 }
1974
1975 void player_powerups (void)
1976 {
1977         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1978         olditems = self.items;
1979
1980         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1981         {
1982                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1983                 self.modelflags |= MF_ROCKET;
1984         }
1985         else
1986         {
1987                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1988                 self.modelflags &~= MF_ROCKET;
1989         }
1990
1991         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1992
1993         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1994                 return;
1995
1996         Fire_ApplyDamage(self);
1997         Fire_ApplyEffect(self);
1998
1999         if (g_minstagib)
2000         {
2001                 self.effects |= EF_FULLBRIGHT;
2002
2003                 if (self.items & IT_STRENGTH)
2004                 {
2005                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2006                         if (time > self.strength_finished)
2007                         {
2008                                 self.alpha = default_player_alpha;
2009                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2010                                 self.items &~= IT_STRENGTH;
2011                                 sprint(self, "^3Invisibility has worn off\n");
2012                         }
2013                 }
2014                 else
2015                 {
2016                         if (time < self.strength_finished)
2017                         {
2018                                 self.alpha = g_minstagib_invis_alpha;
2019                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2020                                 self.items |= IT_STRENGTH;
2021                                 sprint(self, "^3You are invisible\n");
2022                         }
2023                 }
2024
2025                 if (self.items & IT_INVINCIBLE)
2026                 {
2027                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2028                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2029                         {
2030                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2031                                 sprint(self, "^3Speed has worn off\n");
2032                         }
2033                 }
2034                 else
2035                 {
2036                         if (time < self.invincible_finished)
2037                         {
2038                                 self.items = self.items | IT_INVINCIBLE;
2039                                 sprint(self, "^3You are on speed\n");
2040                         }
2041                 }
2042         }
2043         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2044         {
2045                 if (self.items & IT_STRENGTH)
2046                 {
2047                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2048                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2049                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2050                         {
2051                                 self.items = self.items - (self.items & IT_STRENGTH);
2052                                 sprint(self, "^3Strength has worn off\n");
2053                         }
2054                 }
2055                 else
2056                 {
2057                         if (time < self.strength_finished)
2058                         {
2059                                 self.items = self.items | IT_STRENGTH;
2060                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2061                         }
2062                 }
2063                 if (self.items & IT_INVINCIBLE)
2064                 {
2065                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2066                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2067                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2068                         {
2069                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2070                                 sprint(self, "^3Shield has worn off\n");
2071                         }
2072                 }
2073                 else
2074                 {
2075                         if (time < self.invincible_finished)
2076                         {
2077                                 self.items = self.items | IT_INVINCIBLE;
2078                                 sprint(self, "^3Shield surrounds you\n");
2079                         }
2080                 }
2081
2082                 if(autocvar_g_nodepthtestplayers)
2083                         self.effects = self.effects | EF_NODEPTHTEST;
2084
2085                 if(autocvar_g_fullbrightplayers)
2086                         self.effects = self.effects | EF_FULLBRIGHT;
2087
2088                 // midair gamemode: damage only while in the air
2089                 // if in midair mode, being on ground grants temporary invulnerability
2090                 // (this is so that multishot weapon don't clear the ground flag on the
2091                 // first damage in the frame, leaving the player vulnerable to the
2092                 // remaining hits in the same frame)
2093                 if (self.flags & FL_ONGROUND)
2094                 if (g_midair)
2095                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2096
2097                 if (time >= game_starttime)
2098                 if (time < self.spawnshieldtime)
2099                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2100         }
2101
2102         MUTATOR_CALLHOOK(PlayerPowerups);
2103 }
2104
2105 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2106 {
2107         if(current > stable)
2108                 return current;
2109         else if(current > stable - 0.25) // when close enough, "snap"
2110                 return stable;
2111         else
2112                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2113 }
2114
2115 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2116 {
2117         if(current < stable)
2118                 return current;
2119         else if(current < stable + 0.25) // when close enough, "snap"
2120                 return stable;
2121         else
2122                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2123 }
2124
2125 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2126 {
2127         if(current > rotstable)
2128         {
2129                 if(rotframetime > 0)
2130                 {
2131                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2132                         current = max(rotstable, current - rotlinear * rotframetime);
2133                 }
2134         }
2135         else if(current < regenstable)
2136         {
2137                 if(regenframetime > 0)
2138                 {
2139                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2140                         current = min(regenstable, current + regenlinear * regenframetime);
2141                 }
2142         }
2143
2144         if(current > limit)
2145                 current = limit;
2146
2147         return current;
2148 }
2149
2150 void player_regen (void)
2151 {
2152         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2153         maxh = autocvar_g_balance_health_rotstable;
2154         maxa = autocvar_g_balance_armor_rotstable;
2155         maxf = autocvar_g_balance_fuel_rotstable;
2156         minh = autocvar_g_balance_health_regenstable;
2157         mina = autocvar_g_balance_armor_regenstable;
2158         minf = autocvar_g_balance_fuel_regenstable;
2159         limith = autocvar_g_balance_health_limit;
2160         limita = autocvar_g_balance_armor_limit;
2161         limitf = autocvar_g_balance_fuel_limit;
2162
2163         max_mod = regen_mod = rot_mod = limit_mod = 1;
2164
2165         if (self.runes & RUNE_REGEN)
2166         {
2167                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2168                 {
2169                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2170                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2171                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2172                 }
2173                 else
2174                 {
2175                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2176                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2177                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2178                 }
2179         }
2180         else if (self.runes & CURSE_VENOM)
2181         {
2182                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2183                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2184                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2185                 else
2186                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2187                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2188                 //if (!self.runes & RUNE_REGEN)
2189                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2190         }
2191         maxh = maxh * max_mod;
2192         //maxa = maxa * max_mod;
2193         //maxf = maxf * max_mod;
2194         minh = minh * max_mod;
2195         //mina = mina * max_mod;
2196         //minf = minf * max_mod;
2197         limith = limith * limit_mod;
2198         limita = limita * limit_mod;
2199         //limitf = limitf * limit_mod;
2200
2201         if(g_lms && g_ca)
2202                 rot_mod = 0;
2203
2204         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2205         {
2206                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2207                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2208
2209                 // if player rotted to death...  die!
2210                 if(self.health < 1)
2211                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2212         }
2213
2214         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2215                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2216 }
2217
2218 float zoomstate_set;
2219 void SetZoomState(float z)
2220 {
2221         if(z != self.zoomstate)
2222         {
2223                 self.zoomstate = z;
2224                 ClientData_Touch(self);
2225         }
2226         zoomstate_set = 1;
2227 }
2228
2229 void GetPressedKeys(void) {
2230         MUTATOR_CALLHOOK(GetPressedKeys);
2231         if (self.movement_x > 0) // get if movement keys are pressed
2232         {       // forward key pressed
2233                 self.pressedkeys |= KEY_FORWARD;
2234                 self.pressedkeys &~= KEY_BACKWARD;
2235         }
2236         else if (self.movement_x < 0)
2237         {       // backward key pressed
2238                 self.pressedkeys |= KEY_BACKWARD;
2239                 self.pressedkeys &~= KEY_FORWARD;
2240         }
2241         else
2242         {       // no x input
2243                 self.pressedkeys &~= KEY_FORWARD;
2244                 self.pressedkeys &~= KEY_BACKWARD;
2245         }
2246
2247         if (self.movement_y > 0)
2248         {       // right key pressed
2249                 self.pressedkeys |= KEY_RIGHT;
2250                 self.pressedkeys &~= KEY_LEFT;
2251         }
2252         else if (self.movement_y < 0)
2253         {       // left key pressed
2254                 self.pressedkeys |= KEY_LEFT;
2255                 self.pressedkeys &~= KEY_RIGHT;
2256         }
2257         else
2258         {       // no y input
2259                 self.pressedkeys &~= KEY_RIGHT;
2260                 self.pressedkeys &~= KEY_LEFT;
2261         }
2262
2263         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2264                 self.pressedkeys |= KEY_JUMP;
2265         else
2266                 self.pressedkeys &~= KEY_JUMP;
2267         if (self.BUTTON_CROUCH)
2268                 self.pressedkeys |= KEY_CROUCH;
2269         else
2270                 self.pressedkeys &~= KEY_CROUCH;
2271 }
2272
2273 /*
2274 ======================
2275 spectate mode routines
2276 ======================
2277 */
2278
2279 void SpectateCopy(entity spectatee) {
2280         other = spectatee;
2281         MUTATOR_CALLHOOK(SpectateCopy);
2282         self.armortype = spectatee.armortype;
2283         self.armorvalue = spectatee.armorvalue;
2284         self.ammo_cells = spectatee.ammo_cells;
2285         self.ammo_shells = spectatee.ammo_shells;
2286         self.ammo_nails = spectatee.ammo_nails;
2287         self.ammo_rockets = spectatee.ammo_rockets;
2288         self.ammo_fuel = spectatee.ammo_fuel;
2289         self.clip_load = spectatee.clip_load;
2290         self.clip_size = spectatee.clip_size;
2291         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2292         self.health = spectatee.health;
2293         self.impulse = 0;
2294         self.items = spectatee.items;
2295         self.last_pickup = spectatee.last_pickup;
2296         self.hit_time = spectatee.hit_time;
2297         self.metertime = spectatee.metertime;
2298         self.strength_finished = spectatee.strength_finished;
2299         self.invincible_finished = spectatee.invincible_finished;
2300         self.pressedkeys = spectatee.pressedkeys;
2301         self.weapons = spectatee.weapons;
2302         self.switchweapon = spectatee.switchweapon;
2303         self.weapon = spectatee.weapon;
2304         self.nex_charge = spectatee.nex_charge;
2305         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2306         self.hagar_load = spectatee.hagar_load;
2307         self.minelayer_mines = spectatee.minelayer_mines;
2308         self.punchangle = spectatee.punchangle;
2309         self.view_ofs = spectatee.view_ofs;
2310         self.v_angle = spectatee.v_angle;
2311         self.velocity = spectatee.velocity;
2312         self.dmg_take = spectatee.dmg_take;
2313         self.dmg_save = spectatee.dmg_save;
2314         self.dmg_inflictor = spectatee.dmg_inflictor;
2315         self.angles = spectatee.v_angle;
2316         self.fixangle = TRUE;
2317         setorigin(self, spectatee.origin);
2318         setsize(self, spectatee.mins, spectatee.maxs);
2319         SetZoomState(spectatee.zoomstate);
2320
2321         anticheat_spectatecopy(spectatee);
2322
2323         //self.vehicle = spectatee.vehicle;
2324
2325         self.hud = spectatee.hud;
2326         if(spectatee.vehicle)
2327     {
2328         setorigin(self, spectatee.origin);
2329         self.velocity = spectatee.vehicle.velocity;
2330         self.v_angle += spectatee.vehicle.angles;
2331         //self.v_angle_x *= -1;
2332         self.vehicle_health = spectatee.vehicle_health;
2333         self.vehicle_shield = spectatee.vehicle_shield;
2334         self.vehicle_energy = spectatee.vehicle_energy;
2335         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2336         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2337         self.vehicle_reload1 = spectatee.vehicle_reload1;
2338         self.vehicle_reload2 = spectatee.vehicle_reload2;
2339         
2340         msg_entity = self;
2341         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2342         WriteEntity(MSG_ONE, spectatee);
2343         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2344     }
2345 }
2346
2347 float SpectateUpdate() {
2348         if(!self.enemy)
2349             return 0;           
2350
2351         if (self == self.enemy)
2352                 return 0;
2353
2354         if(self.enemy.classname != "player")
2355                 return 0;
2356
2357         SpectateCopy(self.enemy);
2358
2359         return 1;
2360 }
2361
2362 float SpectateNext() {
2363         other = find(self.enemy, classname, "player");
2364
2365         if (!other)
2366                 other = find(other, classname, "player");
2367
2368         if (other)
2369                 self.enemy = other;
2370
2371         if(self.enemy.classname == "player") {
2372             if(self.enemy.vehicle)
2373             {      
2374             msg_entity = self;
2375             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2376             WriteEntity(MSG_ONE, self.enemy);
2377             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2378             self.movetype = MOVETYPE_NONE;
2379             accuracy_resend(self);
2380             }
2381             else 
2382             {           
2383             msg_entity = self;
2384             WriteByte(MSG_ONE, SVC_SETVIEW);
2385             WriteEntity(MSG_ONE, self.enemy);
2386             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2387             self.movetype = MOVETYPE_NONE;
2388             accuracy_resend(self);
2389
2390             if(!SpectateUpdate())
2391                 PutObserverInServer();
2392         }
2393         return 1;
2394         } else {
2395                 return 0;
2396         }
2397 }
2398
2399 /*
2400 =============
2401 ShowRespawnCountdown()
2402
2403 Update a respawn countdown display.
2404 =============
2405 */
2406 void ShowRespawnCountdown()
2407 {
2408         float number;
2409         if(self.deadflag == DEAD_NO) // just respawned?
2410                 return;
2411         else
2412         {
2413                 number = ceil(self.death_time - time);
2414                 if(number <= 0)
2415                         return;
2416                 if(number <= self.respawn_countdown)
2417                 {
2418                         self.respawn_countdown = number - 1;
2419                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2420                                 AnnounceTo(self, strcat(ftos(number), ""));
2421                 }
2422         }
2423 }
2424
2425 void LeaveSpectatorMode()
2426 {
2427         if(nJoinAllowed(1)) {
2428                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2429                         self.classname = "player";
2430
2431                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2432                                 JoinBestTeam(self, FALSE, TRUE);
2433
2434                         if(autocvar_g_campaign)
2435                                 campaign_bots_may_start = 1;
2436
2437                         PutClientInServer();
2438
2439                         if(self.classname == "player")
2440                                 bprint ("^4", self.netname, "^4 is playing now\n");
2441
2442                         if(!autocvar_g_campaign)
2443                         if (time < self.jointime + autocvar_welcome_message_time)
2444                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2445
2446                         return;
2447                 } else {
2448                         if (g_ca && self.caplayer) {
2449                         }       // do nothing
2450                         else
2451                                 stuffcmd(self,"menu_showteamselect\n");
2452                         return;
2453                 }
2454         }
2455         else {
2456                 //player may not join because of g_maxplayers is set
2457                 centerprint(self, PREVENT_JOIN_TEXT);
2458         }
2459 }
2460
2461 /**
2462  * Determines whether the player is allowed to join. This depends on cvar
2463  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2464  * it checks whether the number of currently playing players exceeds g_maxplayers.
2465  * @return int number of free slots for players, 0 if none
2466  */
2467 float nJoinAllowed(float includeMe) {
2468         if(self.team_forced < 0)
2469                 return FALSE; // forced spectators can never join
2470
2471         // TODO simplify this
2472         local entity e;
2473
2474         local float totalClients;
2475         FOR_EACH_CLIENT(e)
2476                 totalClients += 1;
2477
2478         if (!autocvar_g_maxplayers)
2479                 return maxclients - totalClients + includeMe;
2480
2481         local float currentlyPlaying;
2482         FOR_EACH_REALPLAYER(e)
2483                 currentlyPlaying += 1;
2484
2485         if(currentlyPlaying < autocvar_g_maxplayers)
2486                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2487
2488         return 0;
2489 }
2490
2491 /**
2492  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2493  * g_maxplayers_spectator_blocktime seconds
2494  */
2495 void checkSpectatorBlock() {
2496         if(self.classname == "spectator" || self.classname == "observer") {
2497                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2498                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2499                         dropclient(self);
2500                 }
2501         }
2502 }
2503
2504 void ObserverThink()
2505 {
2506         if (self.flags & FL_JUMPRELEASED) {
2507                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2508                         self.flags &~= FL_JUMPRELEASED;
2509                         self.flags |= FL_SPAWNING;
2510                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2511                         self.flags &~= FL_JUMPRELEASED;
2512                         if(SpectateNext() == 1) {
2513                                 self.classname = "spectator";
2514                         }
2515                 }
2516         } else {
2517                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2518                         self.flags |= FL_JUMPRELEASED;
2519                         if(self.flags & FL_SPAWNING)
2520                         {
2521                                 self.flags &~= FL_SPAWNING;
2522                                 LeaveSpectatorMode();
2523                                 return;
2524                         }
2525                 }
2526         }
2527 }
2528
2529 void SpectatorThink()
2530 {
2531         if (self.flags & FL_JUMPRELEASED) {
2532                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2533                         self.flags &~= FL_JUMPRELEASED;
2534                         self.flags |= FL_SPAWNING;
2535                 } else if(self.BUTTON_ATCK) {
2536                         self.flags &~= FL_JUMPRELEASED;
2537                         if(SpectateNext() == 1) {
2538                                 self.classname = "spectator";
2539                         } else {
2540                                 self.classname = "observer";
2541                                 PutClientInServer();
2542                         }
2543                 } else if (self.BUTTON_ATCK2) {
2544                         self.flags &~= FL_JUMPRELEASED;
2545                         self.classname = "observer";
2546                         PutClientInServer();
2547                 } else {
2548                         if(!SpectateUpdate())
2549                                 PutObserverInServer();
2550                 }
2551         } else {
2552                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2553                         self.flags |= FL_JUMPRELEASED;
2554                         if(self.flags & FL_SPAWNING)
2555                         {
2556                                 self.flags &~= FL_SPAWNING;
2557                                 LeaveSpectatorMode();
2558                                 return;
2559                         }
2560                 }
2561                 if(!SpectateUpdate())
2562                         PutObserverInServer();
2563         }
2564
2565         self.flags |= FL_CLIENT | FL_NOTARGET;
2566 }
2567
2568 float ctf_usekey();
2569 void PlayerUseKey()
2570 {
2571         if(self.classname != "player")
2572                 return;
2573
2574         if(self.vehicle)
2575         {
2576         vehicles_exit(VHEF_NORMAL);
2577         return;
2578         }
2579         
2580         // a use key was pressed; call handlers
2581         if(ctf_usekey())
2582                 return;
2583
2584         MUTATOR_CALLHOOK(PlayerUseKey);
2585 }
2586
2587 .float touchexplode_time;
2588
2589 /*
2590 =============
2591 PlayerPreThink
2592
2593 Called every frame for each client before the physics are run
2594 =============
2595 */
2596 .float usekeypressed;
2597 void() ctf_setstatus;
2598 void() nexball_setstatus;
2599 .float items_added;
2600 .float motd_actived_time; // used for both motd and campaign_message
2601 void PlayerPreThink (void)
2602 {
2603         WarpZone_PlayerPhysics_FixVAngle();
2604
2605         self.stat_game_starttime = game_starttime;
2606         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2607         self.stat_leadlimit = autocvar_leadlimit;
2608
2609         if(frametime)
2610         {
2611                 // physics frames: update anticheat stuff
2612                 anticheat_prethink();
2613         }
2614
2615         if(blockSpectators && frametime)
2616                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2617                 checkSpectatorBlock();
2618
2619         zoomstate_set = 0;
2620
2621         if(self.netname_previous != self.netname)
2622         {
2623                 if(autocvar_sv_eventlog)
2624                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2625                 if(self.netname_previous)
2626                         strunzone(self.netname_previous);
2627                 self.netname_previous = strzone(self.netname);
2628         }
2629
2630         // version nagging
2631         if(self.version_nagtime)
2632                 if(self.cvar_g_xonoticversion)
2633                         if(time > self.version_nagtime)
2634                         {
2635                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2636                                 {
2637                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2638                                         {
2639                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2640                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2641                                         }
2642                                         else
2643                                         {
2644                                                 float r;
2645                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2646                                                 if(r < 0)
2647                                                 {
2648                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2649                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2650                                                 }
2651                                                 else if(r > 0)
2652                                                 {
2653                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2654                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2655                                                 }
2656                                         }
2657                                 }
2658                                 self.version_nagtime = 0;
2659                         }
2660
2661         // GOD MODE info
2662         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2663         {
2664                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2665                 self.max_armorvalue = 0;
2666         }
2667
2668 #ifdef TETRIS
2669         if (TetrisPreFrame())
2670                 return;
2671 #endif
2672
2673         MUTATOR_CALLHOOK(PlayerPreThink);
2674
2675         if(self.BUTTON_USE && !self.usekeypressed)
2676                 PlayerUseKey();
2677         self.usekeypressed = self.BUTTON_USE;
2678
2679         if (self.motd_actived_time == 0) {
2680                 if (autocvar_g_campaign) {
2681                         if (self.classname == "player" && self.BUTTON_INFO) {
2682                                 self.motd_actived_time = time;
2683                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2684                         }
2685                 } else {
2686                         if ((self.classname == "player" || time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2687                                 self.motd_actived_time = time;
2688                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2689                         }
2690                 }
2691         } else { // showing MOTD or campaign message
2692                 if (autocvar_g_campaign) {
2693                         if (self.classname == "player") {
2694                                 if (self.BUTTON_INFO)
2695                                         self.motd_actived_time = time;
2696                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2697                                         self.motd_actived_time = 0;
2698                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2699                                 }
2700                         }
2701                 } else {
2702                         if (self.classname == "player" || (time - self.jointime) > autocvar_welcome_message_time) {
2703                                 if (self.BUTTON_INFO)
2704                                         self.motd_actived_time = time;
2705                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2706                                         self.motd_actived_time = 0;
2707                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2708                                 }
2709                         }
2710                 }
2711         }
2712
2713         if(self.classname == "player") {
2714 //              if(self.netname == "Wazat")
2715 //                      bprint(self.classname, "\n");
2716
2717                 CheckRules_Player();
2718
2719                 if (intermission_running)
2720                 {
2721                         IntermissionThink ();   // otherwise a button could be missed between
2722                         return;                                 // the think tics
2723                 }
2724
2725                 //don't allow the player to turn around while game is paused!
2726                 if(timeoutStatus == 2) {
2727                         // FIXME turn this into CSQC stuff
2728                         self.v_angle = self.lastV_angle;
2729                         self.angles = self.lastV_angle;
2730                         self.fixangle = TRUE;
2731                 }
2732
2733                 if(frametime)
2734                 {
2735                         if(self.health <= 0 && autocvar_g_deathglow)
2736                         {
2737                                 if(self.glowmod_x > 0)
2738                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2739                                 else
2740                                         self.glowmod_x = -1;
2741                                 if(self.glowmod_y > 0)
2742                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2743                                 else
2744                                         self.glowmod_y = -1;
2745                                 if(self.glowmod_z > 0)
2746                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2747                                 else
2748                                         self.glowmod_z = -1;
2749                         }
2750                         else
2751                         {
2752                                 // set weapon and player glowmod
2753                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2754
2755                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2756                                 {
2757                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2758                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2759                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2760
2761                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2762                                         {
2763                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2764                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2765                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2766                                         }
2767                                 }
2768                                 else
2769                                         self.weaponentity_glowmod = self.glowmod;
2770                         }
2771                         player_powerups();
2772                 }
2773
2774                 if (g_minstagib)
2775                         minstagib_ammocheck();
2776
2777                 if (self.deadflag != DEAD_NO)
2778                 {
2779                         float button_pressed, force_respawn;
2780                         if(self.personal && g_race_qualifying)
2781                         {
2782                                 if(time > self.death_time)
2783                                 {
2784                                         self.death_time = time + 1; // only retry once a second
2785                                         respawn();
2786                                         self.impulse = 141;
2787                                 }
2788                         }
2789                         else
2790                         {
2791                                 if(frametime)
2792                                         player_anim();
2793                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2794                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2795                                 if (self.deadflag == DEAD_DYING)
2796                                 {
2797                                         if(force_respawn)
2798                                                 self.deadflag = DEAD_RESPAWNING;
2799                                         else if(!button_pressed)
2800                                                 self.deadflag = DEAD_DEAD;
2801                                 }
2802                                 else if (self.deadflag == DEAD_DEAD)
2803                                 {
2804                                         if(button_pressed)
2805                                                 self.deadflag = DEAD_RESPAWNABLE;
2806                                 }
2807                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2808                                 {
2809                                         if(!button_pressed)
2810                                                 self.deadflag = DEAD_RESPAWNING;
2811                                 }
2812                                 else if (self.deadflag == DEAD_RESPAWNING)
2813                                 {
2814                                         if(time > self.death_time)
2815                                         {
2816                                                 self.death_time = time + 1; // only retry once a second
2817                                                 respawn();
2818                                         }
2819                                 }
2820                                 ShowRespawnCountdown();
2821                         }
2822                         return;
2823                 }
2824                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2825                 // so (self.deadflag == DEAD_NO) is always true in the code below
2826
2827                 if(g_touchexplode)
2828                 if(time > self.touchexplode_time)
2829                 if(self.classname == "player")
2830                 if(self.deadflag == DEAD_NO)
2831                 if not(IS_INDEPENDENT_PLAYER(self))
2832                 FOR_EACH_PLAYER(other) if(self != other)
2833                 {
2834                         if(time > other.touchexplode_time)
2835                         if(other.deadflag == DEAD_NO)
2836                         if not(IS_INDEPENDENT_PLAYER(other))
2837                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2838                         {
2839                                 PlayerTouchExplode(self, other);
2840                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2841                         }
2842                 }
2843
2844                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2845                 {
2846                         vector dist;
2847
2848                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2849                         dist = self.prevorigin - self.origin;
2850                         dist_z = 0;
2851                         self.lms_traveled_distance += fabs(vlen(dist));
2852
2853                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2854                         {
2855                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2856                                 self.lms_traveled_distance = 0;
2857                         }
2858
2859                         if(time > self.lms_nextcheck)
2860                         {
2861                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2862                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2863                                 {
2864                                         centerprint(self, autocvar_g_lms_campcheck_message);
2865                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2866                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2867                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2868                                 }
2869                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2870                                 self.lms_traveled_distance = 0;
2871                         }
2872                 }
2873
2874                 self.prevorigin = self.origin;
2875
2876                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != 23) // prevent crouching if using melee attack
2877                 {
2878                         if (!self.crouch)
2879                         {
2880                                 self.crouch = TRUE;
2881                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2882                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2883                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2884                         }
2885                 }
2886                 else
2887                 {
2888                         if (self.crouch)
2889                         {
2890                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2891                                 if (!trace_startsolid)
2892                                 {
2893                                         self.crouch = FALSE;
2894                                         self.view_ofs = PL_VIEW_OFS;
2895                                         setsize (self, PL_MIN, PL_MAX);
2896                                 }
2897                         }
2898                 }
2899
2900                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2901                 {
2902                         if(self.bloodloss_timer < time)
2903                         {
2904                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2905                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2906                         }
2907                 }
2908
2909                 FixPlayermodel();
2910
2911                 GrapplingHookFrame();
2912
2913                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2914                 //if(frametime)
2915                 {
2916                         self.items &~= self.items_added;
2917
2918                         W_WeaponFrame();
2919
2920                         self.items_added = 0;
2921                         if(self.items & IT_JETPACK)
2922                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2923                                         self.items_added |= IT_FUEL;
2924
2925                         self.items |= self.items_added;
2926                 }
2927
2928                 player_regen();
2929
2930                 // rot nex charge to the charge limit
2931                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2932                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2933
2934                 if(frametime)
2935                         player_anim();
2936
2937                 if(g_ctf)
2938                         ctf_setstatus();
2939
2940                 if(g_nexball)
2941                         nexball_setstatus();
2942
2943                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2944
2945                 //self.angles_y=self.v_angle_y + 90;   // temp
2946         } else if(gameover) {
2947                 if (intermission_running)
2948                         IntermissionThink ();   // otherwise a button could be missed between
2949                 return;
2950         } else if(self.classname == "observer") {
2951                 ObserverThink();
2952         } else if(self.classname == "spectator") {
2953                 SpectatorThink();
2954         }
2955
2956         if(!zoomstate_set)
2957                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2958
2959         float oldspectatee_status;
2960         oldspectatee_status = self.spectatee_status;
2961         if(self.classname == "spectator")
2962                 self.spectatee_status = num_for_edict(self.enemy);
2963         else if(self.classname == "observer")
2964                 self.spectatee_status = num_for_edict(self);
2965         else
2966                 self.spectatee_status = 0;
2967         if(self.spectatee_status != oldspectatee_status)
2968         {
2969                 ClientData_Touch(self);
2970                 if(g_race || g_cts)
2971                         race_InitSpectator();
2972         }
2973
2974         if(self.teamkill_soundtime)
2975         if(time > self.teamkill_soundtime)
2976         {
2977                 self.teamkill_soundtime = 0;
2978
2979                 entity oldpusher, oldself;
2980
2981                 oldself = self; self = self.teamkill_soundsource;
2982                 oldpusher = self.pusher; self.pusher = oldself;
2983
2984                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2985
2986                 self.pusher = oldpusher;
2987                 self = oldself;
2988         }
2989
2990         if(self.taunt_soundtime)
2991         if(time > self.taunt_soundtime)
2992         {
2993                 self.taunt_soundtime = 0;
2994                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2995         }
2996
2997         target_voicescript_next(self);
2998
2999         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3000         if(!self.weapon)
3001                 self.clip_load = self.clip_size = 0;
3002 }
3003
3004 float isInvisibleString(string s)
3005 {
3006         float i, n, c;
3007         s = strdecolorize(s);
3008         for((i = 0), (n = strlen(s)); i < n; ++i)
3009         {
3010                 c = str2chr(s, i);
3011                 switch(c)
3012                 {
3013                         case 0:
3014                         case 32: // space
3015                                 break;
3016                         case 192: // charmap space
3017                                 if (!autocvar_utf8_enable)
3018                                         break;
3019                                 return FALSE;
3020                         case 160: // space in unicode fonts
3021                         case 0xE000 + 192: // utf8 charmap space
3022                                 if (autocvar_utf8_enable)
3023                                         break;
3024                         default:
3025                                 return FALSE;
3026                 }
3027         }
3028         return TRUE;
3029 }
3030
3031 /*
3032 =============
3033 PlayerPostThink
3034
3035 Called every frame for each client after the physics are run