Merge branch 'master' of git://git.xonotic.org/xonotic/xonotic-data.pk3dir
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void send_CSQC_cr_maxbullets(entity e) {
10         msg_entity = e;
11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
14 }
15
16 void Announce(string snd) {
17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
19         WriteString(MSG_ALL, snd);
20 }
21
22 void AnnounceTo(entity e, string snd) {
23         if (clienttype(e) == CLIENTTYPE_REAL)
24         {
25                 msg_entity = e;
26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
28                 WriteString(MSG_ONE, snd);
29         }
30 }
31
32 float ClientData_Send(entity to, float sf)
33 {
34         if(to != self.owner)
35         {
36                 error("wtf");
37                 return FALSE;
38         }
39
40         entity e;
41
42         e = to;
43         if(to.classname == "spectator")
44                 e = to.enemy;
45
46         sf = 0;
47
48         if(e.race_completed)
49                 sf |= 1; // forced scoreboard
50         if(to.spectatee_status)
51                 sf |= 2; // spectator ent number follows
52         if(e.zoomstate)
53                 sf |= 4; // zoomed
54         if(e.porto_v_angle_held)
55                 sf |= 8; // angles held
56
57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
58         WriteByte(MSG_ENTITY, sf);
59
60         if(sf & 2)
61                 WriteByte(MSG_ENTITY, to.spectatee_status);
62
63         if(sf & 8)
64         {
65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
67         }
68
69         return TRUE;
70 }
71
72 void ClientData_Attach()
73 {
74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
75         self.clientdata.drawonlytoclient = self;
76         self.clientdata.owner = self;
77 }
78
79 void ClientData_Detach()
80 {
81         remove(self.clientdata);
82         self.clientdata = world;
83 }
84
85 void ClientData_Touch(entity e)
86 {
87         e.clientdata.SendFlags = 1;
88
89         // make it spectatable
90         entity e2;
91         FOR_EACH_REALCLIENT(e2)
92         {
93                 if(e2 != e)
94                         if(e2.classname == "spectator")
95                                 if(e2.enemy == e)
96                                         e2.clientdata.SendFlags = 1;
97         }
98 }
99
100
101 .vector spawnpoint_score;
102 .string netname_previous;
103
104 void spawnfunc_info_player_survivor (void)
105 {
106         spawnfunc_info_player_deathmatch();
107 }
108
109 void spawnfunc_info_player_start (void)
110 {
111         spawnfunc_info_player_deathmatch();
112 }
113
114 void spawnfunc_info_player_deathmatch (void)
115 {
116         self.classname = "info_player_deathmatch";
117         relocate_spawnpoint();
118 }
119
120 void spawnpoint_use()
121 {
122         if(teams_matter)
123         if(have_team_spawns > 0)
124         {
125                 self.team = activator.team;
126                 some_spawn_has_been_used = 1;
127         }
128 };
129
130 // Returns:
131 //   _x: prio (-1 if unusable)
132 //   _y: weight
133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
134 {
135         float shortest, thisdist;
136         float prio;
137         entity player;
138
139         prio = 0;
140
141         // filter out spots for the wrong team
142         if(teamcheck)
143         if(spot.team != teamcheck)
144                 return '-1 0 0';
145
146         if(race_spawns)
147                 if(spot.target == "")
148                         return '-1 0 0';
149
150         if(clienttype(self) == CLIENTTYPE_REAL)
151         {
152                 if(spot.restriction == 1)
153                         return '-1 0 0';
154         }
155         else
156         {
157                 if(spot.restriction == 2)
158                         return '-1 0 0';
159         }
160
161         // filter out spots for assault
162         if(spot.target != "") {
163                 local entity ent;
164                 float good, found;
165                 ent = find(world, targetname, spot.target);
166
167                 while(ent) {
168                         if(ent.classname == "target_objective")
169                         {
170                                 found = 1;
171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
172                                         return '-1 0 0';
173                                 good = 1;
174                         }
175                         else if(ent.classname == "trigger_race_checkpoint")
176                         {
177                                 found = 1;
178                                 if(!anypoint) // spectators may spawn everywhere
179
180                                 {
181                                         if(g_race_qualifying)
182                                         {
183                                                 // spawn at first
184                                                 if(ent.race_checkpoint != 0)
185                                                         return '-1 0 0';
186                                                 if(spot.race_place != race_lowest_place_spawn)
187                                                         return '-1 0 0';
188                                         }
189                                         else
190                                         {
191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
192                                                         return '-1 0 0';
193                                                 // try reusing the previous spawn
194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
195                                                         prio += 1;
196                                                 if(ent.race_checkpoint == 0)
197                                                 {
198                                                         float pl;
199                                                         pl = self.race_place;
200                                                         if(pl > race_highest_place_spawn)
201                                                                 pl = 0;
202                                                         if(pl == 0 && !self.race_started)
203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
204                                                         if(spot.race_place != pl)
205                                                                 return '-1 0 0';
206                                                 }
207                                         }
208                                 }
209                                 good = 1;
210                         }
211                         ent = find(ent, targetname, spot.target);
212                 }
213
214                 if(found && !good)
215                         return '-1 0 0';
216         }
217
218         player = playerlist;
219         shortest = vlen(world.maxs - world.mins);
220         for(player = playerlist; player; player = player.chain)
221                 if (player != self)
222                 {
223                         thisdist = vlen(player.origin - spot.origin);
224                         if (thisdist < shortest)
225                                 shortest = thisdist;
226                 }
227         return prio * '1 0 0' + shortest * '0 1 0';
228 }
229
230 float spawn_allbad;
231 float spawn_allgood;
232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
233 {
234         local entity spot, spotlist, spotlistend;
235         spawn_allgood = TRUE;
236         spawn_allbad = TRUE;
237
238         spotlist = world;
239         spotlistend = world;
240
241         for(spot = firstspot; spot; spot = spot.chain)
242         {
243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
244
245                 if(cvar("spawn_debugview"))
246                 {
247                         setmodel(spot, "models/runematch/rune.mdl");
248                         if(spot.spawnpoint_score_y < mindist)
249                         {
250                                 spot.colormod = '1 0 0';
251                                 spot.scale = 1;
252                         }
253                         else
254                         {
255                                 spot.colormod = '0 1 0';
256                                 spot.scale = spot.spawnpoint_score_y / mindist;
257                         }
258                 }
259
260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
261                 {
262                         if(spot.spawnpoint_score_y < mindist)
263                         {
264                                 // too short distance
265                                 spawn_allgood = FALSE;
266                         }
267                         else
268                         {
269                                 // perfect
270                                 spawn_allbad = FALSE;
271
272                                 if(spotlistend)
273                                         spotlistend.chain = spot;
274                                 spotlistend = spot;
275                                 if(!spotlist)
276                                         spotlist = spot;
277
278                                 /*
279                                 if(teamcheck)
280                                 if(spot.team != teamcheck)
281                                         error("invalid spawn added");
282
283                                 print("added ", etos(spot), "\n");
284                                 */
285                         }
286                 }
287         }
288         if(spotlistend)
289                 spotlistend.chain = world;
290
291         /*
292                 entity e;
293                 if(teamcheck)
294                         for(e = spotlist; e; e = e.chain)
295                         {
296                                 print("seen ", etos(e), "\n");
297                                 if(e.team != teamcheck)
298                                         error("invalid spawn found");
299                         }
300         */
301
302         return spotlist;
303 }
304
305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
306 {
307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
309         local entity spot;
310
311         RandomSelection_Init();
312         for(spot = firstspot; spot; spot = spot.chain)
313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
314
315         return RandomSelection_chosen_ent;
316 }
317
318 /*
319 =============
320 SelectSpawnPoint
321
322 Finds a point to respawn
323 =============
324 */
325 entity SelectSpawnPoint (float anypoint)
326 {
327         local float teamcheck;
328         local entity firstspot_new;
329         local entity spot, firstspot, playerlist;
330
331         spot = find (world, classname, "testplayerstart");
332         if (spot)
333                 return spot;
334
335         teamcheck = 0;
336
337         if(!anypoint && have_team_spawns > 0)
338                 teamcheck = self.team;
339
340         // get the list of players
341         playerlist = findchain(classname, "player");
342         // get the entire list of spots
343         firstspot = findchain(classname, "info_player_deathmatch");
344         // filter out the bad ones
345         // (note this returns the original list if none survived)
346         if(anypoint)
347         {
348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
349         }
350         else
351         {
352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
353                 if(!firstspot_new)
354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
355                 firstspot = firstspot_new;
356
357                 // there is 50/50 chance of choosing a random spot or the furthest spot
358                 // (this means that roughly every other spawn will be furthest, so you
359                 // usually won't get fragged at spawn twice in a row)
360                 if (arena_roundbased && !g_ca)
361                 {
362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
363                         if(firstspot_new)
364                                 firstspot = firstspot_new;
365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
366                 }
367                 else if (random() > cvar("g_spawn_furthest"))
368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
369                 else
370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
371         }
372
373         if(cvar("spawn_debugview"))
374         {
375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
376
377                 entity e;
378                 if(teamcheck)
379                         for(e = firstspot; e; e = e.chain)
380                                 if(e.team != teamcheck)
381                                         error("invalid spawn found");
382         }
383
384         if (!spot)
385         {
386                 if(cvar("spawn_debug"))
387                         GotoNextMap();
388                 else
389                 {
390                         if(some_spawn_has_been_used)
391                                 return world; // team can't spawn any more, because of actions of other team
392                         else
393                                 error("Cannot find a spawn point - please fix the map!");
394                 }
395         }
396
397         return spot;
398 }
399
400 /*
401 =============
402 CheckPlayerModel
403
404 Checks if the argument string can be a valid playermodel.
405 Returns a valid one in doubt.
406 =============
407 */
408 string FallbackPlayerModel;
409 string CheckPlayerModel(string plyermodel) {
410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
411         {
412                 // note: we cannot summon Don Strunzone here, some player may
413                 // still have the model string set. In case anyone manages how
414                 // to change a cvar default, we'll have a small leak here.
415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
416         }
417         if(strlen(plyermodel) < 4)
418                 return FallbackPlayerModel;
419         if( substring(plyermodel,0,14) != "models/player/")
420                 return FallbackPlayerModel;
421         else if(cvar("sv_servermodelsonly"))
422         {
423                 if(substring(plyermodel,-4,4) != ".zym")
424                 if(substring(plyermodel,-4,4) != ".dpm")
425                 if(substring(plyermodel,-4,4) != ".iqm")
426                 if(substring(plyermodel,-4,4) != ".md3")
427                 if(substring(plyermodel,-4,4) != ".psk")
428                         return FallbackPlayerModel;
429                 // forbid the LOD models
430                 if(substring(plyermodel, -9,5) == "_lod1")
431                         return FallbackPlayerModel;
432                 if(substring(plyermodel, -9,5) == "_lod2")
433                         return FallbackPlayerModel;
434                 if(plyermodel != strtolower(plyermodel))
435                         return FallbackPlayerModel;
436                 if(!fexists(plyermodel))
437                         return FallbackPlayerModel;
438         }
439         return plyermodel;
440 }
441
442 /*
443 =============
444 Client_customizeentityforclient
445
446 LOD reduction
447 =============
448 */
449 void Client_uncustomizeentityforclient()
450 {
451         if(self.modelindex == 0) // no need to uncustomize then
452                 return;
453         self.modelindex = self.modelindex_lod0;
454         self.skin = self.skinindex;
455 }
456
457 float Client_customizeentityforclient()
458 {
459         entity modelsource;
460
461         if(self.modelindex == 0)
462                 return TRUE;
463
464         // forcemodel stuff
465
466 #ifdef PROFILING
467         float t0;
468         t0 = gettime(GETTIME_HIRES); // reference
469 #endif
470
471         modelsource = self;
472
473 #ifdef ALLOW_FORCEMODELS
474         if(other.cvar_cl_forceplayermodelsfromxonotic)
475                 if not(self.modelindex_lod0_from_xonotic)
476                         modelsource = other;
477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
478                 modelsource = other;
479 #endif
480
481         self.skin = modelsource.skinindex;
482
483 #if 0
484         if(modelsource == self)
485                 self.skin = modelsource.skinindex;
486         else
487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
488 #endif
489
490         // self: me
491         // other: the player viewing me
492         float distance;
493         float f;
494
495         if(other.cvar_cl_playerdetailreduction <= 0)
496         {
497                 if(other.cvar_cl_playerdetailreduction <= -2)
498                         self.modelindex = modelsource.modelindex_lod2;
499                 else if(other.cvar_cl_playerdetailreduction <= -1)
500                         self.modelindex = modelsource.modelindex_lod1;
501                 else
502                         self.modelindex = modelsource.modelindex_lod0;
503         }
504         else
505         {
506                 distance = vlen(self.origin - other.origin);
507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
508                 if(f > sv_loddistance2)
509                         self.modelindex = modelsource.modelindex_lod2;
510                 else if(f > sv_loddistance1)
511                         self.modelindex = modelsource.modelindex_lod1;
512                 else
513                         self.modelindex = modelsource.modelindex_lod0;
514         }
515
516 #ifdef PROFILING
517         float t1;
518         t1 = gettime(GETTIME_HIRES); // reference
519         client_cefc_accumulator += (t1 - t0);
520 #endif
521
522         return TRUE;
523 }
524
525 void setmodel_lod(entity e, string modelname)
526 {
527         string s;
528
529         if(sv_loddistance1)
530         {
531                 // FIXME: this only supports 3-letter extensions
532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
533                 if(fexists(s))
534                 {
535                         setmodel(e, s); // players have high precision
536                         self.modelindex_lod1 = self.modelindex;
537                 }
538                 else
539                         self.modelindex_lod1 = -1;
540
541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
542                 if(fexists(s))
543                 {
544                         setmodel(e, s); // players have high precision
545                         self.modelindex_lod2 = self.modelindex;
546                 }
547                 else
548                         self.modelindex_lod2 = -1;
549
550                 precache_model(modelname);
551                 setmodel(e, modelname); // players have high precision
552                 self.modelindex_lod0 = self.modelindex;
553
554                 if(self.modelindex_lod1 < 0)
555                         self.modelindex_lod1 = self.modelindex;
556
557                 if(self.modelindex_lod2 < 0)
558                         self.modelindex_lod2 = self.modelindex;
559         }
560         else
561         {
562                 precache_model(modelname);
563                 setmodel(e, modelname); // players have high precision
564                 self.modelindex_lod0 = self.modelindex;
565                         // save it for possible player model forcing
566         }
567
568         s = whichpack(self.model);
569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
570
571         player_setupanimsformodel();
572         UpdatePlayerSounds();
573 }
574
575 /*
576 =============
577 PutObserverInServer
578
579 putting a client as observer in the server
580 =============
581 */
582 void FixPlayermodel();
583 void PutObserverInServer (void)
584 {
585         entity  spot;
586
587         race_PreSpawnObserver();
588
589         spot = SelectSpawnPoint (TRUE);
590         if(!spot)
591                 error("No spawnpoints for observers?!?\n");
592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
593
594         if(clienttype(self) == CLIENTTYPE_REAL)
595         {
596                 msg_entity = self;
597                 WriteByte(MSG_ONE, SVC_SETVIEW);
598                 WriteEntity(MSG_ONE, self);
599         }
600
601         DropAllRunes(self);
602
603         Portal_ClearAll(self);
604
605         if(self.flagcarried)
606                 DropFlag(self.flagcarried, world, world);
607
608         if(self.ballcarried)
609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
610
611         WaypointSprite_PlayerDead();
612
613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
615
616         if(self.killcount != -666) {
617                 if(g_lms) {
618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
620                         else
621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
622                 } else
623                         bprint ("^4", self.netname, "^4 is spectating now\n");
624
625                 if(self.just_joined == FALSE) {
626                         LogTeamchange(self.playerid, -1, 4);
627                 } else
628                         self.just_joined = FALSE;
629         }
630
631         PlayerScore_Clear(self); // clear scores when needed
632
633         self.spectatortime = time;
634
635         self.classname = "observer";
636         self.iscreature = FALSE;
637         self.health = -666;
638         self.takedamage = DAMAGE_NO;
639         self.solid = SOLID_NOT;
640         self.movetype = MOVETYPE_NOCLIP;
641         self.flags = FL_CLIENT | FL_NOTARGET;
642         self.armorvalue = 666;
643         self.effects = 0;
644         self.armorvalue = cvar("g_balance_armor_start");
645         self.pauserotarmor_finished = 0;
646         self.pauserothealth_finished = 0;
647         self.pauseregen_finished = 0;
648         self.damageforcescale = 0;
649         self.death_time = 0;
650         self.dead_frame = 0;
651         self.alpha = 0;
652         self.scale = 0;
653         self.fade_time = 0;
654         self.pain_frame = 0;
655         self.pain_finished = 0;
656         self.strength_finished = 0;
657         self.invincible_finished = 0;
658         self.pushltime = 0;
659         self.think = SUB_Null;
660         self.nextthink = 0;
661         self.hook_time = 0;
662         self.runes = 0;
663         self.deadflag = DEAD_NO;
664         self.angles = spot.angles;
665         self.angles_z = 0;
666         self.fixangle = TRUE;
667         self.crouch = FALSE;
668
669         self.view_ofs = PL_VIEW_OFS;
670         setorigin (self, spot.origin);
671         setsize (self, '0 0 0', '0 0 0');
672         self.prevorigin = self.origin;
673         self.items = 0;
674         self.weapons = 0;
675         self.model = "";
676         FixPlayermodel();
677         self.model = "";
678         self.modelindex = 0;
679         self.weapon = 0;
680         self.weaponmodel = "";
681         self.weaponentity = world;
682         self.exteriorweaponentity = world;
683         self.killcount = -666;
684         self.velocity = '0 0 0';
685         self.avelocity = '0 0 0';
686         self.punchangle = '0 0 0';
687         self.punchvector = '0 0 0';
688         self.oldvelocity = self.velocity;
689         self.fire_endtime = -1;
690
691         if(sv_loddistance1)
692                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
693
694         if(g_arena)
695         {
696                 if(self.version_mismatch)
697                 {
698                         Spawnqueue_Unmark(self);
699                         Spawnqueue_Remove(self);
700                 }
701                 else
702                 {
703                         Spawnqueue_Insert(self);
704                 }
705         }
706         else if(g_lms)
707         {
708                 // Only if the player cannot play at all
709                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
710                         self.frags = FRAGS_SPECTATOR;
711                 else
712                         self.frags = FRAGS_LMS_LOSER;
713         }
714         else
715                 self.frags = FRAGS_SPECTATOR;
716
717         MUTATOR_CALLHOOK(MakePlayerObserver);
718 }
719
720 float RestrictSkin(float s)
721 {
722         if(!teams_matter)
723                 return s;
724         if(s == 6)
725                 return 6;
726         return mod(s, 3);
727 }
728
729 void FixPlayermodel()
730 {
731         local string defaultmodel;
732         local float defaultskin, chmdl, oldskin;
733         local vector m1, m2;
734
735         defaultmodel = "";
736
737         if(cvar("sv_defaultcharacter") == 1) {
738                 defaultskin = 0;
739
740                 if(teams_matter)
741                 {
742                         string s;
743                         s = Team_ColorNameLowerCase(self.team);
744                         if(s != "neutral")
745                         {
746                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
747                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
748                         }
749                 }
750
751                 if(defaultmodel == "")
752                 {
753                         defaultmodel = cvar_string("sv_defaultplayermodel");
754                         defaultskin = cvar("sv_defaultplayerskin");
755                 }
756         }
757
758         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
759         {
760                 if(self.model != "")
761                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
762                 self.model = ""; // force the != checks to return true
763         }
764
765         if(defaultmodel != "")
766         {
767                 if (defaultmodel != self.model)
768                 {
769                         m1 = self.mins;
770                         m2 = self.maxs;
771                         setmodel_lod (self, defaultmodel);
772                         setsize (self, m1, m2);
773                         chmdl = TRUE;
774                 }
775
776                 oldskin = self.skinindex;
777                 self.skinindex = defaultskin;
778         } else {
779                 if (self.playermodel != self.model || self.playermodel == "")
780                 {
781                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
782                         m1 = self.mins;
783                         m2 = self.maxs;
784                         setmodel_lod (self, self.playermodel);
785                         setsize (self, m1, m2);
786                         chmdl = TRUE;
787                 }
788
789                 oldskin = self.skinindex;
790                 self.skinindex = RestrictSkin(stof(self.playerskin));
791         }
792
793         if(chmdl || oldskin != self.skinindex)
794                 self.species = player_getspecies(); // model or skin has changed
795
796         if(!teams_matter)
797                 if(strlen(cvar_string("sv_defaultplayercolors")))
798                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
799                                 setcolor(self, cvar("sv_defaultplayercolors"));
800 }
801
802 void PlayerTouchExplode(entity p1, entity p2)
803 {
804         vector org;
805         org = (p1.origin + p2.origin) * 0.5;
806         org_z += (p1.mins_z + p2.mins_z) * 0.5;
807
808         te_explosion(org);
809
810         entity e;
811         e = spawn();
812         setorigin(e, org);
813         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
814         remove(e);
815 }
816
817 /*
818 =============
819 PutClientInServer
820
821 Called when a client spawns in the server
822 =============
823 */
824 //void() ctf_playerchanged;
825 void PutClientInServer (void)
826 {
827         if(clienttype(self) == CLIENTTYPE_BOT)
828         {
829                 self.classname = "player";
830         }
831         else if(clienttype(self) == CLIENTTYPE_REAL)
832         {
833                 msg_entity = self;
834                 WriteByte(MSG_ONE, SVC_SETVIEW);
835                 WriteEntity(MSG_ONE, self);
836         }
837
838         // player is dead and becomes observer
839         // FIXME fix LMS scoring for new system
840         if(g_lms)
841         {
842                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
843                         self.classname = "observer";
844         }
845
846         if(g_arena || (g_ca && !allowed_to_spawn))
847         if(!self.spawned)
848                 self.classname = "observer";
849
850         if(gameover)
851                 self.classname = "observer";
852
853         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
854                 entity spot, oldself;
855                 float j;
856
857                 if(self.team < 0)
858                         JoinBestTeam(self, FALSE, TRUE);
859
860                 race_PreSpawn();
861
862                 spot = SelectSpawnPoint (FALSE);
863                 if(!spot)
864                 {
865                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
866                         return; // spawn failed
867                 }
868
869                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
870
871                 self.classname = "player";
872                 self.wasplayer = TRUE;
873                 self.iscreature = TRUE;
874                 self.movetype = MOVETYPE_WALK;
875                 self.solid = SOLID_SLIDEBOX;
876                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
877                 if(cvar("g_playerclip_collisions"))
878                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
879                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
880                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
881                 self.frags = FRAGS_PLAYER;
882                 if(independent_players)
883                         MAKE_INDEPENDENT_PLAYER(self);
884                 self.flags = FL_CLIENT;
885                 self.takedamage = DAMAGE_AIM;
886                 if(g_minstagib)
887                         self.effects = EF_FULLBRIGHT;
888                 else
889                         self.effects = 0;
890                 self.air_finished = time + 12;
891                 self.dmg = 2;
892                 if(cvar("g_balance_nex_charge"))
893                         self.nex_charge = cvar("g_balance_nex_charge_start");
894
895                 if(inWarmupStage)
896                 {
897                         self.ammo_shells = warmup_start_ammo_shells;
898                         self.ammo_nails = warmup_start_ammo_nails;
899                         self.ammo_rockets = warmup_start_ammo_rockets;
900                         self.ammo_cells = warmup_start_ammo_cells;
901                         self.ammo_fuel = warmup_start_ammo_fuel;
902                         self.health = warmup_start_health;
903                         self.armorvalue = warmup_start_armorvalue;
904                         self.weapons = warmup_start_weapons;
905                 }
906                 else
907                 {
908                         self.ammo_shells = start_ammo_shells;
909                         self.ammo_nails = start_ammo_nails;
910                         self.ammo_rockets = start_ammo_rockets;
911                         self.ammo_cells = start_ammo_cells;
912                         self.ammo_fuel = start_ammo_fuel;
913                         self.health = start_health;
914                         self.armorvalue = start_armorvalue;
915                         self.weapons = start_weapons;
916                 }
917
918                 if(g_weaponarena_random)
919                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
920
921                 self.items = start_items;
922                 self.jump_interval = time;
923
924                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
925                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
926                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
927                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
928                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
929                 //extend the pause of rotting if client was reset at the beginning of the countdown
930                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
931                         self.spawnshieldtime += game_starttime - time;
932                         self.pauserotarmor_finished += game_starttime - time;
933                         self.pauserothealth_finished += game_starttime - time;
934                         self.pauseregen_finished += game_starttime - time;
935                 }
936                 self.damageforcescale = 2;
937                 self.death_time = 0;
938                 self.dead_frame = 0;
939                 self.alpha = 0;
940                 self.scale = 0;
941                 self.fade_time = 0;
942                 self.pain_frame = 0;
943                 self.pain_finished = 0;
944                 self.strength_finished = 0;
945                 self.invincible_finished = 0;
946                 self.pushltime = 0;
947                 // players have no think function
948                 self.think = SUB_Null;
949                 self.nextthink = 0;
950                 self.hook_time = 0;
951                 self.dmg_team = 0;
952                 self.ballistics_density = cvar("g_ballistics_density_player");
953
954                 self.metertime = 0;
955
956                 self.runes = 0;
957
958                 self.deadflag = DEAD_NO;
959
960                 self.angles = spot.angles;
961
962                 self.angles_z = 0; // never spawn tilted even if the spot says to
963                 self.fixangle = TRUE; // turn this way immediately
964                 self.velocity = '0 0 0';
965                 self.avelocity = '0 0 0';
966                 self.punchangle = '0 0 0';
967                 self.punchvector = '0 0 0';
968                 self.oldvelocity = self.velocity;
969                 self.fire_endtime = -1;
970
971                 msg_entity = self;
972                 WRITESPECTATABLE_MSG_ONE({
973                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
974                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
975                 });
976
977                 if(sv_loddistance1)
978                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
979
980                 self.model = "";
981                 FixPlayermodel();
982
983                 self.crouch = FALSE;
984                 self.view_ofs = PL_VIEW_OFS;
985                 setsize (self, PL_MIN, PL_MAX);
986                 self.spawnorigin = spot.origin;
987                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
988                 // don't reset back to last position, even if new position is stuck in solid
989                 self.oldorigin = self.origin;
990                 self.prevorigin = self.origin;
991                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
992
993                 if(g_arena)
994                 {
995                         Spawnqueue_Remove(self);
996                         Spawnqueue_Mark(self);
997                 }
998
999                 else if(g_ca)
1000                         self.caplayer = 1;
1001
1002                 self.event_damage = PlayerDamage;
1003
1004                 self.bot_attack = TRUE;
1005
1006                 self.statdraintime = time + 5;
1007                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1008
1009                 if(self.killcount == -666) {
1010                         PlayerScore_Clear(self);
1011                         self.killcount = 0;
1012                 }
1013
1014                 self.cnt = WEP_LASER;
1015
1016                 CL_SpawnWeaponentity();
1017                 self.alpha = default_player_alpha;
1018                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1019                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1020
1021                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1022                 self.lms_traveled_distance = 0;
1023                 self.speedrunning = FALSE;
1024
1025                 race_PostSpawn(spot);
1026
1027                 if(cvar("spawn_debug"))
1028                 {
1029                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1030                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1031                 }
1032
1033                 //stuffcmd(self, "chase_active 0");
1034                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1035
1036                 if (cvar("g_spawnsound"))
1037                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1038
1039                 if(g_assault) {
1040                         if(self.team == assault_attacker_team)
1041                                 centerprint(self, "You are attacking!");
1042                         else
1043                                 centerprint(self, "You are defending!");
1044                 }
1045
1046                 target_voicescript_clear(self);
1047
1048                 // reset fields the weapons may use
1049                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1050                         weapon_action(j, WR_RESETPLAYER);
1051
1052                 oldself = self;
1053                 self = spot;
1054                         activator = oldself;
1055                                 SUB_UseTargets();
1056                         activator = world;
1057                 self = oldself;
1058
1059                 MUTATOR_CALLHOOK(PlayerSpawn);
1060
1061                 self.switchweapon = w_getbestweapon(self);
1062                 self.cnt = self.switchweapon;
1063                 self.weapon = 0;
1064         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1065                 PutObserverInServer ();
1066         }
1067
1068         //if(g_ctf)
1069         //      ctf_playerchanged();
1070 }
1071
1072 float ClientInit_SendEntity(entity to, float sf)
1073 {
1074         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1075         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1078         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1079         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1080         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1081         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1082         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1083         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1084         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1085         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1086         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1088         if(sv_foginterval && world.fog != "")
1089                 WriteString(MSG_ENTITY, world.fog);
1090         else
1091                 WriteString(MSG_ENTITY, "");
1092         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1093         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1094         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1095         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1096         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1097         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1098         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1099         return TRUE;
1100 }
1101
1102 void ClientInit_CheckUpdate()
1103 {
1104         self.nextthink = time;
1105         if(self.count != cvar("g_balance_armor_blockpercent"))
1106         {
1107                 self.count = cvar("g_balance_armor_blockpercent");
1108                 self.SendFlags |= 1;
1109         }
1110         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1111         {
1112                 self.cnt = cvar("g_balance_weaponswitchdelay");
1113                 self.SendFlags |= 1;
1114         }
1115         if(self.bouncefactor != cvar("g_balance_grenadelauncher_bouncefactor"))
1116         {
1117                 self.bouncefactor = cvar("g_balance_grenadelauncher_bouncefactor");
1118                 self.SendFlags |= 1;
1119         }
1120         if(self.bouncestop != cvar("g_balance_grenadelauncher_bouncestop"))
1121         {
1122                 self.bouncestop = cvar("g_balance_grenadelauncher_bouncestop");
1123                 self.SendFlags |= 1;
1124         }
1125 }
1126
1127 void ClientInit_Spawn()
1128 {
1129         entity o;
1130         entity e;
1131         e = spawn();
1132         e.classname = "clientinit";
1133         e.think = ClientInit_CheckUpdate;
1134         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1135
1136         o = self;
1137         self = e;
1138         ClientInit_CheckUpdate();
1139         self = o;
1140 }
1141
1142 /*
1143 =============
1144 SetNewParms
1145 =============
1146 */
1147 void SetNewParms (void)
1148 {
1149         // initialize parms for a new player
1150         parm1 = -(86400 * 366);
1151 }
1152
1153 /*
1154 =============
1155 SetChangeParms
1156 =============
1157 */
1158 void SetChangeParms (void)
1159 {
1160         // save parms for level change
1161         parm1 = self.parm_idlesince - time;
1162 }
1163
1164 /*
1165 =============
1166 DecodeLevelParms
1167 =============
1168 */
1169 void DecodeLevelParms (void)
1170 {
1171         // load parms
1172         self.parm_idlesince = parm1;
1173         if(self.parm_idlesince == -(86400 * 366))
1174                 self.parm_idlesince = time;
1175
1176         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1177         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1178 }
1179
1180 /*
1181 =============
1182 ClientKill
1183
1184 Called when a client types 'kill' in the console
1185 =============
1186 */
1187
1188 void ClientKill_Now_TeamChange()
1189 {
1190         if(self.killindicator_teamchange == -1)
1191         {
1192                 self.team = -1;
1193                 JoinBestTeam( self, FALSE, FALSE );
1194         }
1195         else
1196                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1197 }
1198
1199 void ClientKill_Now()
1200 {
1201         if(self.killindicator_teamchange)
1202                 ClientKill_Now_TeamChange();
1203
1204         // in any case:
1205         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1206
1207         if(self.killindicator)
1208         {
1209                 dprint("Cleaned up after a leaked kill indicator.\n");
1210                 remove(self.killindicator);
1211                 self.killindicator = world;
1212         }
1213 }
1214 void KillIndicator_Think()
1215 {
1216         if (!self.owner.modelindex)
1217         {
1218                 self.owner.killindicator = world;
1219                 remove(self);
1220                 return;
1221         }
1222
1223         if(self.cnt <= 0)
1224         {
1225                 self = self.owner;
1226                 ClientKill_Now(); // no oldself needed
1227                 return;
1228         }
1229         else
1230         {
1231                 if(self.cnt <= 10)
1232                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1233                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1234                 {
1235                         if(self.cnt <= 10)
1236                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1237                         if(self.owner.killindicator_teamchange)
1238                         {
1239                                 if(self.owner.killindicator_teamchange == -1)
1240                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1241                                 else
1242                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1243                         }
1244                         else
1245                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1246                 }
1247                 self.nextthink = time + 1;
1248                 self.cnt -= 1;
1249         }
1250 }
1251
1252 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1253 {
1254         float killtime;
1255         entity e;
1256         killtime = cvar("g_balance_kill_delay");
1257
1258         if(g_race_qualifying)
1259                 killtime = 0;
1260
1261         self.killindicator_teamchange = targetteam;
1262
1263         if(!self.killindicator)
1264         {
1265                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1266                 {
1267                         ClientKill_Now();
1268                 }
1269                 else
1270                 {
1271                         self.killindicator = spawn();
1272                         self.killindicator.owner = self;
1273                         self.killindicator.scale = 0.5;
1274                         setattachment(self.killindicator, self, "");
1275                         setorigin(self.killindicator, '0 0 52');
1276                         self.killindicator.think = KillIndicator_Think;
1277                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1278                         self.killindicator.cnt = ceil(killtime);
1279                         self.killindicator.count = bound(0, ceil(killtime), 10);
1280                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1281
1282                         for(e = world; (e = find(e, classname, "body")) != world; )
1283                         {
1284                                 if(e.enemy != self)
1285                                         continue;
1286                                 e.killindicator = spawn();
1287                                 e.killindicator.owner = e;
1288                                 e.killindicator.scale = 0.5;
1289                                 setattachment(e.killindicator, e, "");
1290                                 setorigin(e.killindicator, '0 0 52');
1291                                 e.killindicator.think = KillIndicator_Think;
1292                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1293                                 e.killindicator.cnt = ceil(killtime);
1294                         }
1295                         self.lip = 0;
1296                 }
1297         }
1298         if(self.killindicator)
1299         {
1300                 if(targetteam)
1301                         self.killindicator.colormod = TeamColor(targetteam);
1302                 else
1303                         self.killindicator.colormod = '0 0 0';
1304         }
1305 }
1306
1307 void ClientKill (void)
1308 {
1309         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1310         {
1311                 // do nothing
1312         }
1313         else
1314                 ClientKill_TeamChange(0);
1315 }
1316
1317 void CTS_ClientKill_Think (void)
1318 {
1319         self = self.owner; // set self to the player to be killed
1320         sprint(self, "^1You were killed in order to prevent cheating!");
1321         ClientKill_Now();
1322 }
1323
1324 void CTS_ClientKill (float t) // silent version of ClientKill
1325 {
1326         entity e;
1327         e = spawn();
1328         e.owner = self;
1329         e.think = CTS_ClientKill_Think;
1330         e.nextthink = t;
1331 }
1332
1333 void DoTeamChange(float destteam)
1334 {
1335         float t, c0;
1336         if(!teams_matter)
1337         {
1338                 if(destteam >= 0)
1339                         SetPlayerColors(self, destteam);
1340                 return;
1341         }
1342         if(self.classname == "player")
1343         if(destteam == -1)
1344         {
1345                 CheckAllowedTeams(self);
1346                 t = FindSmallestTeam(self, TRUE);
1347                 switch(self.team)
1348                 {
1349                         case COLOR_TEAM1: c0 = c1; break;
1350                         case COLOR_TEAM2: c0 = c2; break;
1351                         case COLOR_TEAM3: c0 = c3; break;
1352                         case COLOR_TEAM4: c0 = c4; break;
1353                         default:          c0 = 999;
1354                 }
1355                 switch(t)
1356                 {
1357                         case 1:
1358                                 if(c0 > c1)
1359                                         destteam = COLOR_TEAM1;
1360                                 break;
1361                         case 2:
1362                                 if(c0 > c2)
1363                                         destteam = COLOR_TEAM2;
1364                                 break;
1365                         case 3:
1366                                 if(c0 > c3)
1367                                         destteam = COLOR_TEAM3;
1368                                 break;
1369                         case 4:
1370                                 if(c0 > c4)
1371                                         destteam = COLOR_TEAM4;
1372                                 break;
1373                 }
1374                 if(destteam == -1)
1375                         return;
1376         }
1377         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1378                 return;
1379         ClientKill_TeamChange(destteam);
1380 }
1381
1382 void FixClientCvars(entity e)
1383 {
1384         // send prediction settings to the client
1385         stuffcmd(e, "\nin_bindmap 0 0\n");
1386         if(g_race || g_cts)
1387                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1388         if(cvar("g_antilag") == 3) // client side hitscan
1389                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1390         if(sv_gentle)
1391                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1392         /*
1393          * we no longer need to stuff this. Remove this comment block if you feel
1394          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1395         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1396         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1397         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1398         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1399         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1400         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1401         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1402         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1403         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1404         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1405         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1406         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1407         stuffcmd(e, "cl_movement_edgefriction 1\n");
1408          */
1409 }
1410
1411 /*
1412 =============
1413 ClientConnect
1414
1415 Called when a client connects to the server
1416 =============
1417 */
1418 //void ctf_clientconnect();
1419 string ColoredTeamName(float t);
1420 void DecodeLevelParms (void);
1421 //void dom_player_join_team(entity pl);
1422 void ClientConnect (void)
1423 {
1424         float t;
1425
1426         if(self.flags & FL_CLIENT)
1427         {
1428                 print("Warning: ClientConnect, but already connected!\n");
1429                 return;
1430         }
1431
1432         if(Ban_MaybeEnforceBan(self))
1433                 return;
1434
1435         DecodeLevelParms();
1436
1437 #ifdef WATERMARK
1438         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1439 #endif
1440
1441         self.classname = "player_joining";
1442
1443         self.flags = FL_CLIENT;
1444         self.version_nagtime = time + 10 + random() * 10;
1445
1446         if(player_count<0)
1447         {
1448                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1449                 player_count = 0;
1450         }
1451
1452         PlayerScore_Attach(self);
1453         ClientData_Attach();
1454
1455         bot_clientconnect();
1456
1457         playerdemo_init();
1458
1459         anticheat_init();
1460         
1461         race_PreSpawnObserver();
1462
1463         //if(g_domination)
1464         //      dom_player_join_team(self);
1465
1466         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1467
1468         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1469                 self.classname = "observer";
1470         } else {
1471                 if(teams_matter)
1472                 {
1473                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1474                         {
1475                                 self.classname = "player";
1476                                 campaign_bots_may_start = 1;
1477                         }
1478                         else
1479                         {
1480                                 self.classname = "observer"; // do it anyway
1481                         }
1482                 }
1483                 else
1484                 {
1485                         self.classname = "player";
1486                         campaign_bots_may_start = 1;
1487                 }
1488         }
1489
1490         self.playerid = (playerid_last = playerid_last + 1);
1491
1492         if(cvar("sv_eventlog"))
1493                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1494
1495         LogTeamchange(self.playerid, self.team, 1);
1496
1497         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1498
1499         self.netname_previous = strzone(self.netname);
1500
1501         bprint("^4", self.netname, "^4 connected");
1502
1503         if(self.classname != "observer" && (g_domination || g_ctf))
1504                 bprint(" and joined the ", ColoredTeamName(self.team));
1505
1506         bprint("\n");
1507
1508         self.welcomemessage_time = 0;
1509
1510         stuffcmd(self, strcat(clientstuff, "\n"));
1511         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1512         stuffcmd(self, "cl_particles_reloadeffects\n");
1513
1514         FixClientCvars(self);
1515
1516         // spawnfunc_waypoint sprites
1517         WaypointSprite_InitClient(self);
1518
1519         // Wazat's grappling hook
1520         SetGrappleHookBindings();
1521
1522         // get autoswitch state from player when he toggles it
1523         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1524
1525         // get version info from player
1526         stuffcmd(self, "cmd clientversion $gameversion\n");
1527
1528         // get other cvars from player
1529         GetCvars(0);
1530
1531         // set cvar for team scoreboard
1532         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1533
1534         // notify about available teams
1535         if(teams_matter)
1536         {
1537                 CheckAllowedTeams(self);
1538                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1539                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1540         }
1541         else
1542                 stuffcmd(self, "set _teams_available 0\n");
1543
1544         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1545
1546         if(g_arena || g_ca)
1547         {
1548                 self.classname = "observer";
1549                 if(g_arena)
1550                         Spawnqueue_Insert(self);
1551         }
1552         /*else if(g_ctf)
1553         {
1554                 ctf_clientconnect();
1555         }*/
1556
1557         if(teams_matter || radar_showennemies)
1558                 attach_entcs();
1559
1560         bot_relinkplayerlist();
1561
1562         self.spectatortime = time;
1563         if(blockSpectators)
1564         {
1565                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1566         }
1567
1568         self.jointime = time;
1569         self.allowedTimeouts = cvar("sv_timeout_number");
1570
1571         if(clienttype(self) == CLIENTTYPE_REAL)
1572         {
1573                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1574                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1575         }
1576
1577         if(g_lms)
1578         {
1579                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1580                 {
1581                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1582                         self.frags = FRAGS_SPECTATOR;
1583                 }
1584         }
1585
1586         if(!sv_foginterval && world.fog != "")
1587                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1588
1589         SoundEntity_Attach(self);
1590
1591         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1592         {
1593                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1594                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1595         }
1596         else
1597                 self.hitplotfh = -1;
1598
1599         if(g_race || g_cts) {
1600                 string rr;
1601                 if(g_cts)
1602                         rr = CTS_RECORD;
1603                 else
1604                         rr = RACE_RECORD;
1605                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1606
1607                 msg_entity = self;
1608                 race_send_recordtime(MSG_ONE);
1609                 race_send_speedaward(MSG_ONE);
1610
1611                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1612                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1613                 race_send_speedaward_alltimebest(MSG_ONE);
1614
1615                 float i;
1616                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1617                         race_SendRankings(i, 0, 0, MSG_ONE);
1618                 }
1619         }
1620         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1621                 send_CSQC_teamnagger();
1622
1623         send_CSQC_cr_maxbullets(self);
1624
1625         CheatInitClient();
1626 }
1627
1628 /*
1629 =============
1630 ClientDisconnect
1631
1632 Called when a client disconnects from the server
1633 =============
1634 */
1635 .entity chatbubbleentity;
1636 .entity teambubbleentity;
1637 void ReadyCount();
1638 void ClientDisconnect (void)
1639 {
1640         if not(self.flags & FL_CLIENT)
1641         {
1642                 print("Warning: ClientDisconnect without ClientConnect\n");
1643                 return;
1644         }
1645
1646         CheatShutdownClient();
1647
1648         if(self.hitplotfh >= 0)
1649         {
1650                 fclose(self.hitplotfh);
1651                 self.hitplotfh = -1;
1652         }
1653
1654         anticheat_report();
1655         anticheat_shutdown();
1656
1657         playerdemo_shutdown();
1658
1659         bot_clientdisconnect();
1660
1661         if(self.entcs)
1662                 detach_entcs();
1663
1664         if(cvar("sv_eventlog"))
1665                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1666         bprint ("^4",self.netname);
1667         bprint ("^4 disconnected\n");
1668
1669         SoundEntity_Detach(self);
1670
1671         DropAllRunes(self);
1672         MUTATOR_CALLHOOK(ClientDisconnect);
1673
1674         Portal_ClearAll(self);
1675
1676         if(self.flagcarried)
1677                 DropFlag(self.flagcarried, world, world);
1678         if(self.ballcarried)
1679                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1680
1681         // Here, everything has been done that requires this player to be a client.
1682
1683         self.flags &~= FL_CLIENT;
1684
1685         if (self.chatbubbleentity)
1686                 remove (self.chatbubbleentity);
1687
1688         if (self.teambubbleentity)
1689                 remove (self.teambubbleentity);
1690
1691         if (self.killindicator)
1692                 remove (self.killindicator);
1693
1694         WaypointSprite_PlayerGone();
1695
1696         bot_relinkplayerlist();
1697
1698         // remove laserdot
1699         if(self.weaponentity)
1700                 if(self.weaponentity.lasertarget)
1701                         remove(self.weaponentity.lasertarget);
1702
1703         if(g_arena)
1704         {
1705                 Spawnqueue_Unmark(self);
1706                 Spawnqueue_Remove(self);
1707         }
1708
1709         ClientData_Detach();
1710         PlayerScore_Detach(self);
1711
1712         if(self.netname_previous)
1713                 strunzone(self.netname_previous);
1714         if(self.clientstatus)
1715                 strunzone(self.clientstatus);
1716         if(self.weaponorder_byimpulse)
1717                 strunzone(self.weaponorder_byimpulse);
1718
1719         ClearPlayerSounds();
1720
1721         if(self.personal)
1722                 remove(self.personal);
1723
1724         self.playerid = 0;
1725         ReadyCount();
1726
1727         // free cvars
1728         GetCvars(-1);
1729 }
1730
1731 .float BUTTON_CHAT;
1732 void ChatBubbleThink()
1733 {
1734         self.nextthink = time;
1735         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1736         {
1737                 if(self.owner) // but why can that ever be world?
1738                         self.owner.chatbubbleentity = world;
1739                 remove(self);
1740                 return;
1741         }
1742         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1743 #ifdef TETRIS
1744                 || self.owner.tetris_on
1745 #endif
1746         )
1747                 self.model = self.mdl;
1748         else
1749                 self.model = "";
1750 };
1751
1752 void UpdateChatBubble()
1753 {
1754         if (!self.modelindex)
1755                 return;
1756         // spawn a chatbubble entity if needed
1757         if (!self.chatbubbleentity)
1758         {
1759                 self.chatbubbleentity = spawn();
1760                 self.chatbubbleentity.owner = self;
1761                 self.chatbubbleentity.exteriormodeltoclient = self;
1762                 self.chatbubbleentity.think = ChatBubbleThink;
1763                 self.chatbubbleentity.nextthink = time;
1764                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1765                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1766                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1767                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1768                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1769                 self.chatbubbleentity.model = "";
1770                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1771         }
1772 }
1773
1774
1775 void TeamBubbleThink()
1776 {
1777         self.nextthink = time;
1778         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1779         {
1780                 if(self.owner) // but why can that ever be world?
1781                         self.owner.teambubbleentity = world;
1782                 remove(self);
1783                 return;
1784         }
1785 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1786         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1787                 self.model = "";
1788         else
1789                 self.model = self.mdl;
1790
1791 };
1792
1793 float TeamBubble_customizeentityforclient()
1794 {
1795         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1796 }
1797
1798 void UpdateTeamBubble()
1799 {
1800         if (!self.modelindex || !teams_matter)
1801                 return;
1802         // spawn a teambubble entity if needed
1803         if (!self.teambubbleentity && teams_matter)
1804         {
1805                 self.teambubbleentity = spawn();
1806                 self.teambubbleentity.owner = self;
1807                 self.teambubbleentity.exteriormodeltoclient = self;
1808                 self.teambubbleentity.think = TeamBubbleThink;
1809                 self.teambubbleentity.nextthink = time;
1810                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1811 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1812                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1813                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1814                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1815                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1816                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1817                 self.teambubbleentity.effects = EF_LOWPRECISION;
1818         }
1819 }
1820
1821 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1822 // added to the model skins
1823 /*void UpdateColorModHack()
1824 {
1825         local float c;
1826         c = self.clientcolors & 15;
1827         // LordHavoc: only bothering to support white, green, red, yellow, blue
1828              if (!teams_matter) self.colormod = '0 0 0';
1829         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1830         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1831         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1832         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1833         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1834         else self.colormod = '1 1 1';
1835 };*/
1836
1837 .float oldcolormap;
1838 void respawn(void)
1839 {
1840         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1841         {
1842                 self.solid = SOLID_NOT;
1843                 self.takedamage = DAMAGE_NO;
1844                 self.movetype = MOVETYPE_FLY;
1845                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1846                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1847                 self.effects |= EF_ADDITIVE;
1848                 self.oldcolormap = self.colormap;
1849                 self.colormap = 512;
1850                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1851                 if(cvar("g_respawn_ghosts_maxtime"))
1852                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1853         }
1854
1855         CopyBody(1);
1856         self.effects |= EF_NODRAW; // prevent another CopyBody
1857         if(self.oldcolormap)
1858         {
1859                 self.colormap = self.oldcolormap;
1860                 self.oldcolormap = 0;
1861         }
1862         PutClientInServer();
1863 }
1864
1865 void play_countdown(float finished, string samp)
1866 {
1867         if(clienttype(self) == CLIENTTYPE_REAL)
1868                 if(floor(finished - time - frametime) != floor(finished - time))
1869                         if(finished - time < 6)
1870                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1871 }
1872
1873 /**
1874  * When sv_timeout is used this function returs strings like
1875  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1876  * Called by centerprint functions
1877  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1878  */
1879 string getTimeoutText(float addOneSecond) {
1880         if (!cvar("sv_timeout") || !timeoutStatus)
1881                 return "";
1882
1883         local string retStr;
1884         if (timeoutStatus == 1) {
1885                 if (addOneSecond == 1) {
1886                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1887                 }
1888                 else {
1889                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1890                 }
1891                 return retStr;
1892         }
1893         else if (timeoutStatus == 2) {
1894                 if (addOneSecond) {
1895                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1896                         //don't show messages like "Timeout ends in 0 seconds"...
1897                         if ((remainingTimeoutTime + 1) > 0)
1898                                 return retStr;
1899                         else
1900                                 return "";
1901                 }
1902                 else {
1903                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1904                         //don't show messages like "Timeout ends in 0 seconds"...
1905                         if (remainingTimeoutTime > 0)
1906                                 return retStr;
1907                         else
1908                                 return "";
1909                 }
1910         }
1911         else return "";
1912 }
1913
1914 void player_powerups (void)
1915 {
1916         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1917         {
1918                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1919                 self.modelflags |= MF_ROCKET;
1920         }
1921         else
1922         {
1923                 SoundEntity_StopSound(self, CHAN_PLAYER);
1924                 self.modelflags &~= MF_ROCKET;
1925         }
1926
1927         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1928
1929         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1930                 return;
1931         
1932         Fire_ApplyDamage(self);
1933         Fire_ApplyEffect(self);
1934
1935         if (g_minstagib)
1936         {
1937                 self.effects |= EF_FULLBRIGHT;
1938
1939                 if (self.items & IT_STRENGTH)
1940                 {
1941                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1942                         if (time > self.strength_finished)
1943                         {
1944                                 self.alpha = default_player_alpha;
1945                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1946                                 self.items &~= IT_STRENGTH;
1947                                 sprint(self, "^3Invisibility has worn off\n");
1948                         }
1949                 }
1950                 else
1951                 {
1952                         if (time < self.strength_finished)
1953                         {
1954                                 self.alpha = g_minstagib_invis_alpha;
1955                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1956                                 self.items |= IT_STRENGTH;
1957                                 sprint(self, "^3You are invisible\n");
1958                         }
1959                 }
1960
1961                 if (self.items & IT_INVINCIBLE)
1962                 {
1963                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1964                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1965                         {
1966                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1967                                 sprint(self, "^3Speed has worn off\n");
1968                         }
1969                 }
1970                 else
1971                 {
1972                         if (time < self.invincible_finished)
1973                         {
1974                                 self.items = self.items | IT_INVINCIBLE;
1975                                 sprint(self, "^3You are on speed\n");
1976                         }
1977                 }
1978                 return;
1979         }
1980
1981         if (self.items & IT_STRENGTH)
1982         {
1983                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1984                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1985                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1986                 {
1987                         self.items = self.items - (self.items & IT_STRENGTH);
1988                         sprint(self, "^3Strength has worn off\n");
1989                 }
1990         }
1991         else
1992         {
1993                 if (time < self.strength_finished)
1994                 {
1995                         self.items = self.items | IT_STRENGTH;
1996                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1997                 }
1998         }
1999         if (self.items & IT_INVINCIBLE)
2000         {
2001                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
2002                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2003                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2004                 {
2005                         self.items = self.items - (self.items & IT_INVINCIBLE);
2006                         sprint(self, "^3Shield has worn off\n");
2007                 }
2008         }
2009         else
2010         {
2011                 if (time < self.invincible_finished)
2012                 {
2013                         self.items = self.items | IT_INVINCIBLE;
2014                         sprint(self, "^3Shield surrounds you\n");
2015                 }
2016         }
2017
2018         if(cvar("g_nodepthtestplayers"))
2019                 self.effects = self.effects | EF_NODEPTHTEST;
2020
2021         if(cvar("g_fullbrightplayers"))
2022                 self.effects = self.effects | EF_FULLBRIGHT;
2023
2024         // midair gamemode: damage only while in the air
2025         // if in midair mode, being on ground grants temporary invulnerability
2026         // (this is so that multishot weapon don't clear the ground flag on the
2027         // first damage in the frame, leaving the player vulnerable to the
2028         // remaining hits in the same frame)
2029         if (self.flags & FL_ONGROUND)
2030         if (g_midair)
2031                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2032
2033         if (time >= game_starttime)
2034         if (time < self.spawnshieldtime)
2035                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2036 }
2037
2038 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2039 {
2040         if(current > stable)
2041                 return current;
2042         else if(current > stable - 0.25) // when close enough, "snap"
2043                 return stable;
2044         else
2045                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2046 }
2047
2048 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2049 {
2050         if(current < stable)
2051                 return current;
2052         else if(current < stable + 0.25) // when close enough, "snap"
2053                 return stable;
2054         else
2055                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2056 }
2057
2058 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2059 {
2060         if(current > rotstable)
2061         {
2062                 if(rotframetime > 0)
2063                 {
2064                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2065                         current = max(rotstable, current - rotlinear * rotframetime);
2066                 }
2067         }
2068         else if(current < regenstable)
2069         {
2070                 if(regenframetime > 0)
2071                 {
2072                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2073                         current = min(regenstable, current + regenlinear * regenframetime);
2074                 }
2075         }
2076
2077         if(current > limit)
2078                 current = limit;
2079
2080         return current;
2081 }
2082
2083 void player_regen (void)
2084 {
2085         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2086         maxh = cvar("g_balance_health_rotstable");
2087         maxa = cvar("g_balance_armor_rotstable");
2088         maxf = cvar("g_balance_fuel_rotstable");
2089         minh = cvar("g_balance_health_regenstable");
2090         mina = cvar("g_balance_armor_regenstable");
2091         minf = cvar("g_balance_fuel_regenstable");
2092         limith = cvar("g_balance_health_limit");
2093         limita = cvar("g_balance_armor_limit");
2094         limitf = cvar("g_balance_fuel_limit");
2095
2096         max_mod = regen_mod = rot_mod = limit_mod = 1;
2097
2098         if (self.runes & RUNE_REGEN)
2099         {
2100                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2101                 {
2102                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2103                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2104                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2105                 }
2106                 else
2107                 {
2108                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2109                         max_mod = cvar("g_balance_rune_regen_hpmod");
2110                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2111                 }
2112         }
2113         else if (self.runes & CURSE_VENOM)
2114         {
2115                 max_mod = cvar("g_balance_curse_venom_hpmod");
2116                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2117                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2118                 else
2119                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2120                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2121                 //if (!self.runes & RUNE_REGEN)
2122                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2123         }
2124         maxh = maxh * max_mod;
2125         //maxa = maxa * max_mod;
2126         //maxf = maxf * max_mod;
2127         minh = minh * max_mod;
2128         //mina = mina * max_mod;
2129         //minf = minf * max_mod;
2130         limith = limith * limit_mod;
2131         limita = limita * limit_mod;
2132         //limitf = limitf * limit_mod;
2133
2134         if(g_lms && g_ca)
2135                 rot_mod = 0;
2136
2137         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2138         {
2139                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2140                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2141
2142                 // if player rotted to death...  die!
2143                 if(self.health < 1)
2144                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2145         }
2146
2147         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2148                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2149 }
2150
2151 float zoomstate_set;
2152 void SetZoomState(float z)
2153 {
2154         if(z != self.zoomstate)
2155         {
2156                 self.zoomstate = z;
2157                 ClientData_Touch(self);
2158         }
2159         zoomstate_set = 1;
2160 }
2161
2162 void GetPressedKeys(void) {
2163         MUTATOR_CALLHOOK(GetPressedKeys);
2164         if (self.movement_x > 0) // get if movement keys are pressed
2165         {       // forward key pressed
2166                 self.pressedkeys |= KEY_FORWARD;
2167                 self.pressedkeys &~= KEY_BACKWARD;
2168         }
2169         else if (self.movement_x < 0)
2170         {       // backward key pressed
2171                 self.pressedkeys |= KEY_BACKWARD;
2172                 self.pressedkeys &~= KEY_FORWARD;
2173         }
2174         else
2175         {       // no x input
2176                 self.pressedkeys &~= KEY_FORWARD;
2177                 self.pressedkeys &~= KEY_BACKWARD;
2178         }
2179
2180         if (self.movement_y > 0)
2181         {       // right key pressed
2182                 self.pressedkeys |= KEY_RIGHT;
2183                 self.pressedkeys &~= KEY_LEFT;
2184         }
2185         else if (self.movement_y < 0)
2186         {       // left key pressed
2187                 self.pressedkeys |= KEY_LEFT;
2188                 self.pressedkeys &~= KEY_RIGHT;
2189         }
2190         else
2191         {       // no y input
2192                 self.pressedkeys &~= KEY_RIGHT;
2193                 self.pressedkeys &~= KEY_LEFT;
2194         }
2195
2196         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2197                 self.pressedkeys |= KEY_JUMP;
2198         else
2199                 self.pressedkeys &~= KEY_JUMP;
2200         if (self.BUTTON_CROUCH)
2201                 self.pressedkeys |= KEY_CROUCH;
2202         else
2203                 self.pressedkeys &~= KEY_CROUCH;
2204 }
2205
2206 void update_stats (float number, float hit, float fired) {
2207 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2208 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2209
2210         if(number) {
2211                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2212                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2213         } else {
2214                 self.stat_hit = hit * sv_accuracy_data_share;
2215                 self.stat_fired = fired * sv_accuracy_data_share;
2216         }
2217 }
2218
2219 /*
2220 ======================
2221 spectate mode routines
2222 ======================
2223 */
2224
2225 .float weapon_count;
2226 void SpectateCopy(entity spectatee) {
2227         if(spectatee.weapon_count < WEP_LAST) {
2228                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2229                 spectatee.weapon_count ++;
2230         } else
2231                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2232
2233         other = spectatee;
2234         MUTATOR_CALLHOOK(SpectateCopy);
2235         self.armortype = spectatee.armortype;
2236         self.armorvalue = spectatee.armorvalue;
2237         self.ammo_cells = spectatee.ammo_cells;
2238         self.ammo_shells = spectatee.ammo_shells;
2239         self.ammo_nails = spectatee.ammo_nails;
2240         self.ammo_rockets = spectatee.ammo_rockets;
2241         self.ammo_fuel = spectatee.ammo_fuel;
2242         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2243         self.health = spectatee.health;
2244         self.impulse = 0;
2245         self.items = spectatee.items;
2246         self.last_pickup = spectatee.last_pickup;
2247         self.metertime = spectatee.metertime;
2248         self.strength_finished = spectatee.strength_finished;
2249         self.invincible_finished = spectatee.invincible_finished;
2250         self.pressedkeys = spectatee.pressedkeys;
2251         self.weapons = spectatee.weapons;
2252         self.switchweapon = spectatee.switchweapon;
2253         self.weapon = spectatee.weapon;
2254         self.punchangle = spectatee.punchangle;
2255         self.view_ofs = spectatee.view_ofs;
2256         self.v_angle = spectatee.v_angle;
2257         self.velocity = spectatee.velocity;
2258         self.dmg_take = spectatee.dmg_take;
2259         self.dmg_save = spectatee.dmg_save;
2260         self.dmg_inflictor = spectatee.dmg_inflictor;
2261         self.angles = spectatee.v_angle;
2262         self.fixangle = TRUE;
2263         setorigin(self, spectatee.origin);
2264         setsize(self, spectatee.mins, spectatee.maxs);
2265         SetZoomState(spectatee.zoomstate);
2266
2267         anticheat_spectatecopy(spectatee);
2268 }
2269
2270 float SpectateUpdate() {
2271         if(!self.enemy)
2272                 return 0;
2273
2274         if (self == self.enemy)
2275                 return 0;
2276
2277         if(self.enemy.classname != "player")
2278                 return 0;
2279
2280         SpectateCopy(self.enemy);
2281
2282         return 1;
2283 }
2284
2285 float SpectateNext() {
2286         other = find(self.enemy, classname, "player");
2287
2288         if (!other)
2289                 other = find(other, classname, "player");
2290
2291         if (other)
2292                 self.enemy = other;
2293
2294         if(self.enemy.classname == "player") {
2295                 msg_entity = self;
2296                 WriteByte(MSG_ONE, SVC_SETVIEW);
2297                 WriteEntity(MSG_ONE, self.enemy);
2298                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2299                 self.movetype = MOVETYPE_NONE;
2300
2301                 self.enemy.weapon_count = 0;
2302
2303                 if(!SpectateUpdate())
2304                         PutObserverInServer();
2305
2306                 return 1;
2307         } else {
2308                 return 0;
2309         }
2310 }
2311
2312 /*
2313 =============
2314 ShowRespawnCountdown()
2315
2316 Update a respawn countdown display.
2317 =============
2318 */
2319 void ShowRespawnCountdown()
2320 {
2321         float number;
2322         if(self.deadflag == DEAD_NO) // just respawned?
2323                 return;
2324         else
2325         {
2326                 number = ceil(self.death_time - time);
2327                 if(number <= 0)
2328                         return;
2329                 if(number <= self.respawn_countdown)
2330                 {
2331                         self.respawn_countdown = number - 1;
2332                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2333                                 AnnounceTo(self, strcat(ftos(number), ""));
2334                 }
2335         }
2336 }
2337
2338 void LeaveSpectatorMode()
2339 {
2340         if(isJoinAllowed()) {
2341                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2342                         self.classname = "player";
2343
2344                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2345                                 JoinBestTeam(self, FALSE, TRUE);
2346
2347                         if(cvar("g_campaign"))
2348                                 campaign_bots_may_start = 1;
2349
2350                         self.stat_count = WEP_LAST;
2351
2352                         PutClientInServer();
2353
2354                         if(self.classname == "player")
2355                                 bprint ("^4", self.netname, "^4 is playing now\n");
2356
2357                         if(!cvar("g_campaign"))
2358                                 centerprint(self,""); // clear MOTD
2359
2360                         return;
2361                 } else {
2362                         if (g_ca && self.caplayer) {
2363                         }       // do nothing
2364                         else
2365                                 stuffcmd(self,"menu_showteamselect\n");
2366                         return;
2367                 }
2368         }
2369         else {
2370                 //player may not join because of g_maxplayers is set
2371                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2372         }
2373 }
2374
2375 /**
2376  * Determines whether the player is allowed to join. This depends on cvar
2377  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2378  * it checks whether the number of currently playing players exceeds g_maxplayers.
2379  * @return bool TRUE if the player is allowed to join, false otherwise
2380  */
2381 float isJoinAllowed() {
2382         if (!cvar("g_maxplayers"))
2383                 return TRUE;
2384
2385         local entity e;
2386         local float currentlyPlaying;
2387         FOR_EACH_REALPLAYER(e) {
2388                 if(e.classname == "player")
2389                         currentlyPlaying += 1;
2390         }
2391         if(currentlyPlaying < cvar("g_maxplayers"))
2392                 return TRUE;
2393
2394         return FALSE;
2395 }
2396
2397 /**
2398  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2399  * g_maxplayers_spectator_blocktime seconds
2400  */
2401 void checkSpectatorBlock() {
2402         if(self.classname == "spectator" || self.classname == "observer") {
2403                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2404                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2405                         dropclient(self);
2406                 }
2407         }
2408 }
2409
2410 float vercmp_recursive(string v1, string v2)
2411 {
2412         float dot1, dot2;
2413         string s1, s2;
2414         float r;
2415
2416         dot1 = strstrofs(v1, ".", 0);
2417         dot2 = strstrofs(v2, ".", 0);
2418         if(dot1 == -1)
2419                 s1 = v1;
2420         else
2421                 s1 = substring(v1, 0, dot1);
2422         if(dot2 == -1)
2423                 s2 = v2;
2424         else
2425                 s2 = substring(v2, 0, dot2);
2426
2427         r = stof(s1) - stof(s2);
2428         if(r != 0)
2429                 return r;
2430
2431         r = strcasecmp(s1, s2);
2432         if(r != 0)
2433                 return r;
2434
2435         if(dot1 == -1)
2436                 if(dot2 == -1)
2437                         return 0;
2438                 else
2439                         return -1;
2440         else
2441                 if(dot2 == -1)
2442                         return 1;
2443                 else
2444                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2445 }
2446
2447 float vercmp(string v1, string v2)
2448 {
2449         if(strcasecmp(v1, v2) == 0) // early out check
2450                 return 0;
2451         return vercmp_recursive(v1, v2);
2452 }
2453
2454 void ObserverThink()
2455 {
2456         if (self.flags & FL_JUMPRELEASED) {
2457                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2458                         self.welcomemessage_time = 0;
2459                         self.flags &~= FL_JUMPRELEASED;
2460                         self.flags |= FL_SPAWNING;
2461                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2462                         self.welcomemessage_time = 0;
2463                         self.flags &~= FL_JUMPRELEASED;
2464                         if(SpectateNext() == 1) {
2465                                 self.classname = "spectator";
2466                         }
2467                 }
2468         } else {
2469                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2470                         self.flags |= FL_JUMPRELEASED;
2471                         if(self.flags & FL_SPAWNING)
2472                         {
2473                                 self.flags &~= FL_SPAWNING;
2474                                 LeaveSpectatorMode();
2475                                 return;
2476                         }
2477                 }
2478         }
2479         PrintWelcomeMessage(self);
2480 }
2481
2482 void SpectatorThink()
2483 {
2484         if (self.flags & FL_JUMPRELEASED) {
2485                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2486                         self.welcomemessage_time = 0;
2487                         self.flags &~= FL_JUMPRELEASED;
2488                         self.flags |= FL_SPAWNING;
2489                 } else if(self.BUTTON_ATCK) {
2490                         self.welcomemessage_time = 0;
2491                         self.flags &~= FL_JUMPRELEASED;
2492                         if(SpectateNext() == 1) {
2493                                 self.classname = "spectator";
2494                         } else {
2495                                 self.classname = "observer";
2496                                 self.stat_count = WEP_LAST;
2497                                 PutClientInServer();
2498                         }
2499                 } else if (self.BUTTON_ATCK2) {
2500                         self.welcomemessage_time = 0;
2501                         self.flags &~= FL_JUMPRELEASED;
2502                         self.classname = "observer";
2503                         self.stat_count = WEP_LAST;
2504                         PutClientInServer();
2505                 } else {
2506                         if(!SpectateUpdate())
2507                                 PutObserverInServer();
2508                 }
2509         } else {
2510                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2511                         self.flags |= FL_JUMPRELEASED;
2512                         if(self.flags & FL_SPAWNING)
2513                         {
2514                                 self.flags &~= FL_SPAWNING;
2515                                 LeaveSpectatorMode();
2516                                 return;
2517                         }
2518                 }
2519         }
2520
2521         PrintWelcomeMessage(self);
2522         self.flags |= FL_CLIENT | FL_NOTARGET;
2523 }
2524
2525 .float touchexplode_time;
2526
2527 /*
2528 =============
2529 PlayerPreThink
2530
2531 Called every frame for each client before the physics are run
2532 =============
2533 */
2534 void() ctf_setstatus;
2535 void() nexball_setstatus;
2536 .float items_added;
2537 void PlayerPreThink (void)
2538 {
2539         self.stat_game_starttime = game_starttime;
2540         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2541         self.stat_leadlimit = cvar("leadlimit");
2542
2543         if(frametime)
2544         {
2545                 // physics frames: update anticheat stuff
2546                 anticheat_prethink();
2547         }
2548
2549         if(blockSpectators && frametime)
2550                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2551                 checkSpectatorBlock();
2552
2553         zoomstate_set = 0;
2554
2555         if(self.netname_previous != self.netname)
2556         {
2557                 if(cvar("sv_eventlog"))
2558                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2559                 if(self.netname_previous)
2560                         strunzone(self.netname_previous);
2561                 self.netname_previous = strzone(self.netname);
2562         }
2563
2564         // version nagging
2565         if(self.version_nagtime)
2566                 if(self.cvar_g_xonoticversion)
2567                         if(time > self.version_nagtime)
2568                         {
2569                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2570                                 {
2571                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2572                                         {
2573                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2574                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2575                                         }
2576                                         else
2577                                         {
2578                                                 float r;
2579                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2580                                                 if(r < 0)
2581                                                 {
2582                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2583                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2584                                                 }
2585                                                 else if(r > 0)
2586                                                 {
2587                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2588                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2589                                                 }
2590                                         }
2591                                 }
2592                                 self.version_nagtime = 0;
2593                         }
2594
2595         // GOD MODE info
2596         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2597         {
2598                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2599                 self.max_armorvalue = 0;
2600         }
2601
2602 #ifdef TETRIS
2603         if (TetrisPreFrame())
2604                 return;
2605 #endif
2606
2607         MUTATOR_CALLHOOK(PlayerPreThink);
2608
2609         if(self.classname == "player") {
2610 //              if(self.netname == "Wazat")
2611 //                      bprint(self.classname, "\n");
2612
2613                 CheckRules_Player();
2614
2615                 PrintWelcomeMessage(self);
2616
2617                 if (intermission_running)
2618                 {
2619                         IntermissionThink ();   // otherwise a button could be missed between
2620                         return;                                 // the think tics
2621                 }
2622
2623                 if(self.teleport_time)
2624                 if(time > self.teleport_time)
2625                 {
2626                         self.teleport_time = 0;
2627                         self.effects = self.effects - (self.effects & EF_NODRAW);
2628                 }
2629
2630                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2631                         UpdateSelectedPlayer();
2632
2633                 //don't allow the player to turn around while game is paused!
2634                 if(timeoutStatus == 2) {
2635                         self.v_angle = self.lastV_angle;
2636                         self.angles = self.lastV_angle;
2637                         self.fixangle = TRUE;
2638                 }
2639
2640                 if(frametime)
2641                 {
2642                         if(self.health <= 0 && cvar("g_deathglow"))
2643                         {
2644                                 if(self.glowmod_x > 0)
2645                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2646                                 else
2647                                         self.glowmod_x = -1;
2648                                 if(self.glowmod_y > 0)
2649                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2650                                 else
2651                                         self.glowmod_y = -1;
2652                                 if(self.glowmod_z > 0)
2653                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2654                                 else
2655                                         self.glowmod_z = -1;
2656                         }
2657                         else
2658                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2659                         player_powerups();
2660                 }
2661
2662                 if (self.deadflag != DEAD_NO)
2663                 {
2664                         float button_pressed, force_respawn;
2665                         if(self.personal && g_race_qualifying)
2666                         {
2667                                 if(time > self.death_time)
2668                                 {
2669                                         self.death_time = time + 1; // only retry once a second
2670                                         respawn();
2671                                         self.impulse = 141;
2672                                 }
2673                         }
2674                         else
2675                         {
2676                                 if(frametime)
2677                                         player_anim();
2678                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2679                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2680                                 if (self.deadflag == DEAD_DYING)
2681                                 {
2682                                         if(force_respawn)
2683                                                 self.deadflag = DEAD_RESPAWNING;
2684                                         else if(!button_pressed)
2685                                                 self.deadflag = DEAD_DEAD;
2686                                 }
2687                                 else if (self.deadflag == DEAD_DEAD)
2688                                 {
2689                                         if(button_pressed)
2690                                                 self.deadflag = DEAD_RESPAWNABLE;
2691                                 }
2692                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2693                                 {
2694                                         if(!button_pressed)
2695                                                 self.deadflag = DEAD_RESPAWNING;
2696                                 }
2697                                 else if (self.deadflag == DEAD_RESPAWNING)
2698                                 {
2699                                         if(time > self.death_time)
2700                                         {
2701                                                 self.death_time = time + 1; // only retry once a second
2702                                                 respawn();
2703                                         }
2704                                 }
2705                                 ShowRespawnCountdown();
2706                         }
2707                         return;
2708                 }
2709
2710                 if(g_touchexplode)
2711                 if(time > self.touchexplode_time)
2712                 if(self.classname == "player")
2713                 if(self.deadflag == DEAD_NO)
2714                 if not(IS_INDEPENDENT_PLAYER(self))
2715                 FOR_EACH_PLAYER(other) if(self != other)
2716                 {
2717                         if(time > other.touchexplode_time)
2718                         if(other.deadflag == DEAD_NO)
2719                         if not(IS_INDEPENDENT_PLAYER(other))
2720                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2721                         {
2722                                 PlayerTouchExplode(self, other);
2723                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2724                         }
2725                 }
2726
2727                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2728                 {
2729                         vector dist;
2730
2731                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2732                         dist = self.prevorigin - self.origin;
2733                         dist_z = 0;
2734                         self.lms_traveled_distance += fabs(vlen(dist));
2735
2736                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2737                         {
2738                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2739                                 self.lms_traveled_distance = 0;
2740                         }
2741
2742                         if(time > self.lms_nextcheck)
2743                         {
2744                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2745                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2746                                 {
2747                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2748                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2749                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2750                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2751                                 }
2752                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2753                                 self.lms_traveled_distance = 0;
2754                         }
2755                 }
2756
2757                 self.prevorigin = self.origin;
2758
2759                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2760                 {
2761                         if (!self.crouch)
2762                         {
2763                                 self.crouch = TRUE;
2764                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2765                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2766                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2767                         }
2768                 }
2769                 else
2770                 {
2771                         if (self.crouch)
2772                         {
2773                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2774                                 if (!trace_startsolid)
2775                                 {
2776                                         self.crouch = FALSE;
2777                                         self.view_ofs = PL_VIEW_OFS;
2778                                         setsize (self, PL_MIN, PL_MAX);
2779                                 }
2780                         }
2781                 }
2782
2783                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2784                 {
2785                         if(self.bloodloss_timer < time)
2786                         {
2787                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2788                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2789                         }
2790                 }
2791
2792                 FixPlayermodel();
2793
2794                 GrapplingHookFrame();
2795
2796                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2797                 //if(frametime)
2798                 {
2799                         self.items &~= self.items_added;
2800
2801                         W_WeaponFrame();
2802
2803                         self.items_added = 0;
2804                         if(self.items & IT_JETPACK)
2805                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2806                                         self.items_added |= IT_FUEL;
2807
2808                         self.items |= self.items_added;
2809                 }
2810
2811                 player_regen();
2812
2813                 // rot nex charge to the charge limit
2814                 if(cvar("g_balance_nex_charge_rot_rate") && self.nex_charge > cvar("g_balance_nex_charge_limit"))
2815                         self.nex_charge = bound(cvar("g_balance_nex_charge_limit"), self.nex_charge - cvar("g_balance_nex_charge_rot_rate") * frametime / W_TICSPERFRAME, 1);
2816
2817                 if(frametime)
2818                         player_anim();
2819
2820                 if (g_minstagib)
2821                         minstagib_ammocheck();
2822
2823                 ctf_setstatus();
2824                 nexball_setstatus();
2825
2826                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2827
2828                 //self.angles_y=self.v_angle_y + 90;   // temp
2829         } else if(gameover) {
2830                 if (intermission_running)
2831                         IntermissionThink ();   // otherwise a button could be missed between
2832                 return;
2833         } else if(self.classname == "observer") {
2834                 ObserverThink();
2835         } else if(self.classname == "spectator") {
2836                 SpectatorThink();
2837         }
2838
2839         if(!zoomstate_set)
2840                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2841
2842         float oldspectatee_status;
2843         oldspectatee_status = self.spectatee_status;
2844         if(self.classname == "spectator")
2845                 self.spectatee_status = num_for_edict(self.enemy);
2846         else if(self.classname == "observer")
2847                 self.spectatee_status = num_for_edict(self);
2848         else
2849                 self.spectatee_status = 0;
2850         if(self.spectatee_status != oldspectatee_status)
2851         {
2852                 ClientData_Touch(self);
2853                 if(g_race || g_cts)
2854                         race_InitSpectator();
2855         }
2856
2857         if(self.teamkill_soundtime)
2858         if(time > self.teamkill_soundtime)
2859         {
2860                 self.teamkill_soundtime = 0;
2861
2862                 entity oldpusher, oldself;
2863
2864                 oldself = self; self = self.teamkill_soundsource;
2865                 oldpusher = self.pusher; self.pusher = oldself;
2866
2867                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2868
2869                 self.pusher = oldpusher;
2870                 self = oldself;
2871         }
2872
2873         if(self.taunt_soundtime)
2874         if(time > self.taunt_soundtime)
2875         {
2876                 self.taunt_soundtime = 0;
2877                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2878         }
2879
2880         target_voicescript_next(self);
2881 }
2882
2883 float isInvisibleString(string s)
2884 {
2885         float i, n, c;
2886         s = strdecolorize(s);
2887         for((i = 0), (n = strlen(s)); i < n; ++i)
2888         {
2889                 c = str2chr(s, i);
2890                 switch(c)
2891                 {
2892                         case 0:
2893                         case 32: // space
2894                                 break;
2895                         case 192: // charmap space
2896                                 if (!cvar("utf8_enable"))
2897                                         break;
2898                                 return FALSE;
2899                         case 160: // space in unicode fonts
2900                         case 0xE000 + 192: // utf8 charmap space
2901                                 if (cvar("utf8_enable"))
2902                                         break;
2903                         default:
2904                                 return FALSE;
2905                 }
2906         }
2907         return TRUE;
2908 }
2909
2910 /*
2911 =============
2912 PlayerPostThink
2913
2914 Called every frame for each client after the physics are run
2915 =============
2916 */
2917 .float idlekick_lasttimeleft;
2918 .entity showheadshotbbox;
2919 void showheadshotbbox_think()
2920 {
2921         if(self.owner.showheadshotbbox != self)
2922         {
2923                 remove(self);
2924                 return;
2925         }
2926         self.nextthink = time;
2927         setorigin(self, self.owner.origin);
2928         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2929 }
2930 void PlayerPostThink (void)
2931 {
2932         // Savage: Check for nameless players
2933         if (isInvisibleString(self.netname)) {
2934                 self.netname = "Player";
2935                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2936         }
2937
2938         // send the clients accuracy stats to the client
2939         if(self.stat_count > 0)
2940         if(frametime)
2941         {
2942                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2943                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2944                 self.stat_count -= 1;
2945         }
2946
2947         if(sv_maxidle && frametime)
2948         {
2949                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2950                 float timeleft;
2951                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2952                 if(timeleft <= 0)
2953                 {
2954                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2955                         AnnounceTo(self, "terminated");
2956                         dropclient(self);
2957                         return;
2958                 }
2959                 else if(timeleft <= 10)
2960                 {
2961                         if(timeleft != self.idlekick_lasttimeleft)
2962                         {
2963                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2964                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2965                         }
2966                 }
2967                 else
2968                 {
2969                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2970                 }
2971                 self.idlekick_lasttimeleft = timeleft;
2972         }
2973
2974 #ifdef TETRIS
2975         if(self.impulse == 100)
2976                 ImpulseCommands();
2977         if (TetrisPostFrame())
2978                 return;
2979 #endif
2980
2981         CheatFrame();
2982
2983         if(self.classname == "player") {
2984                 CheckRules_Player();
2985                 UpdateChatBubble();
2986                 UpdateTeamBubble();
2987                 if (self.impulse)
2988                         ImpulseCommands();
2989                 if (intermission_running)
2990                         return;         // intermission or finale
2991                 GetPressedKeys();
2992         } else if (self.classname == "observer") {
2993                 //do nothing
2994         } else if (self.classname == "spectator") {
2995                 //do nothing
2996         }
2997
2998         /*
2999         float i;
3000         for(i = 0; i < 1000; ++i)
3001         {
3002                 vector end;
3003                 end = self.origin + '0 0 1024' + 512 * randomvec();
3004                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3005                 if(trace_fraction < 1)
3006                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3007                 {
3008                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3009                         break;
3010                 }
3011         }
3012         */
3013
3014         Arena_Warmup();
3015
3016         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3017
3018         if(self.waypointsprite_attachedforcarrier)
3019                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3020         
3021         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3022         {
3023                 if(!self.showheadshotbbox)
3024                 {
3025                         self.showheadshotbbox = spawn();
3026                         self.showheadshotbbox.classname = "headshotbbox";
3027                         self.showheadshotbbox.owner = self;
3028                         self.showheadshotbbox.think = showheadshotbbox_think;
3029                         self.showheadshotbbox.nextthink = time;
3030                         self = self.showheadshotbbox;
3031                         self.think();
3032                         self = self.owner;
3033                 }
3034         }
3035         else
3036         {
3037                 if(self.showheadshotbbox)
3038                         remove(self.showheadshotbbox);
3039         }
3040
3041         playerdemo_write();
3042
3043         if((g_cts || g_race) && self.cvar_cl_allow_uid2name)
3044         {
3045                 if(!self.stored_netname)
3046                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3047                 if(self.stored_netname != self.netname)
3048                 {
3049                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3050                         strunzone(self.stored_netname);
3051                         self.stored_netname = strzone(self.netname);
3052                 }
3053         }
3054
3055         /*
3056         if(g_race)
3057                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));