qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(cvar("spawn_debugview"))
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > cvar("g_spawn_furthest"))
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(cvar("spawn_debugview"))
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(cvar("spawn_debug"))
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(cvar("sv_servermodelsonly"))
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595
 596         Portal_ClearAll(self);
 597
 598         if(self.flagcarried)
 599                 DropFlag(self.flagcarried, world, world);
 600
 601         if(self.ballcarried)
 602                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 603
 604         WaypointSprite_PlayerDead();
 605
 606         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 607                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 608
 609         if(self.killcount != -666) {
 610                 if(g_lms) {
 611                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 612                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 613                         else
 614                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 615                 } else
 616                         bprint ("^4", self.netname, "^4 is spectating now\n");
 617
 618                 if(self.just_joined == FALSE) {
 619                         LogTeamchange(self.playerid, -1, 4);
 620                 } else
 621                         self.just_joined = FALSE;
 622         }
 623
 624         PlayerScore_Clear(self); // clear scores when needed
 625
 626         self.spectatortime = time;
 627
 628         self.classname = "observer";
 629         self.iscreature = FALSE;
 630         self.health = -666;
 631         self.takedamage = DAMAGE_NO;
 632         self.solid = SOLID_NOT;
 633         self.movetype = MOVETYPE_NOCLIP;
 634         self.flags = FL_CLIENT | FL_NOTARGET;
 635         self.armorvalue = 666;
 636         self.effects = 0;
 637         self.armorvalue = cvar("g_balance_armor_start");
 638         self.pauserotarmor_finished = 0;
 639         self.pauserothealth_finished = 0;
 640         self.pauseregen_finished = 0;
 641         self.damageforcescale = 0;
 642         self.death_time = 0;
 643         self.dead_frame = 0;
 644         self.alpha = 0;
 645         self.scale = 0;
 646         self.fade_time = 0;
 647         self.pain_frame = 0;
 648         self.pain_finished = 0;
 649         self.strength_finished = 0;
 650         self.invincible_finished = 0;
 651         self.pushltime = 0;
 652         self.think = SUB_Null;
 653         self.nextthink = 0;
 654         self.hook_time = 0;
 655         self.runes = 0;
 656         self.deadflag = DEAD_NO;
 657         self.angles = spot.angles;
 658         self.angles_z = 0;
 659         self.fixangle = TRUE;
 660         self.crouch = FALSE;
 661
 662         self.view_ofs = PL_VIEW_OFS;
 663         setorigin (self, spot.origin);
 664         setsize (self, '0 0 0', '0 0 0');
 665         self.prevorigin = self.origin;
 666         self.items = 0;
 667         self.weapons = 0;
 668         self.model = "";
 669         FixPlayermodel();
 670         self.model = "";
 671         self.modelindex = 0;
 672         self.weapon = 0;
 673         self.weaponmodel = "";
 674         self.weaponentity = world;
 675         self.exteriorweaponentity = world;
 676         self.killcount = -666;
 677         self.velocity = '0 0 0';
 678         self.avelocity = '0 0 0';
 679         self.punchangle = '0 0 0';
 680         self.punchvector = '0 0 0';
 681         self.oldvelocity = self.velocity;
 682         self.fire_endtime = -1;
 683
 684         if(sv_loddistance1)
 685                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 686
 687         if(g_arena)
 688         {
 689                 if(self.version_mismatch)
 690                 {
 691                         Spawnqueue_Unmark(self);
 692                         Spawnqueue_Remove(self);
 693                 }
 694                 else
 695                 {
 696                         Spawnqueue_Insert(self);
 697                 }
 698         }
 699         else if(g_lms)
 700         {
 701                 // Only if the player cannot play at all
 702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 703                         self.frags = FRAGS_SPECTATOR;
 704                 else
 705                         self.frags = FRAGS_LMS_LOSER;
 706         }
 707         else
 708                 self.frags = FRAGS_SPECTATOR;
 709
 710         MUTATOR_CALLHOOK(MakePlayerObserver);
 711 }
 712
 713 float RestrictSkin(float s)
 714 {
 715         if(!teams_matter)
 716                 return s;
 717         if(s == 6)
 718                 return 6;
 719         return mod(s, 3);
 720 }
 721
 722 void FixPlayermodel()
 723 {
 724         local string defaultmodel;
 725         local float defaultskin, chmdl, oldskin;
 726         local vector m1, m2;
 727
 728         defaultmodel = "";
 729
 730         if(cvar("sv_defaultcharacter") == 1) {
 731                 defaultskin = 0;
 732
 733                 if(teams_matter)
 734                 {
 735                         string s;
 736                         s = Team_ColorNameLowerCase(self.team);
 737                         if(s != "neutral")
 738                         {
 739                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 740                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 741                         }
 742                 }
 743
 744                 if(defaultmodel == "")
 745                 {
 746                         defaultmodel = cvar_string("sv_defaultplayermodel");
 747                         defaultskin = cvar("sv_defaultplayerskin");
 748                 }
 749         }
 750
 751         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 752         {
 753                 if(self.model != "")
 754                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 755                 self.model = ""; // force the != checks to return true
 756         }
 757
 758         if(defaultmodel != "")
 759         {
 760                 if (defaultmodel != self.model)
 761                 {
 762                         m1 = self.mins;
 763                         m2 = self.maxs;
 764                         setmodel_lod (self, defaultmodel);
 765                         setsize (self, m1, m2);
 766                         chmdl = TRUE;
 767                 }
 768
 769                 oldskin = self.skinindex;
 770                 self.skinindex = defaultskin;
 771         } else {
 772                 if (self.playermodel != self.model || self.playermodel == "")
 773                 {
 774                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 775                         m1 = self.mins;
 776                         m2 = self.maxs;
 777                         setmodel_lod (self, self.playermodel);
 778                         setsize (self, m1, m2);
 779                         chmdl = TRUE;
 780                 }
 781
 782                 oldskin = self.skinindex;
 783                 self.skinindex = RestrictSkin(stof(self.playerskin));
 784         }
 785
 786         if(chmdl || oldskin != self.skinindex)
 787                 self.species = player_getspecies(); // model or skin has changed
 788
 789         if(!teams_matter)
 790                 if(strlen(cvar_string("sv_defaultplayercolors")))
 791                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 792                                 setcolor(self, cvar("sv_defaultplayercolors"));
 793 }
 794
 795 void PlayerTouchExplode(entity p1, entity p2)
 796 {
 797         vector org;
 798         org = (p1.origin + p2.origin) * 0.5;
 799         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 800
 801         te_explosion(org);
 802
 803         entity e;
 804         e = spawn();
 805         setorigin(e, org);
 806         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 807         remove(e);
 808 }
 809
 810 /*
 811 =============
 812 PutClientInServer
 813
 814 Called when a client spawns in the server
 815 =============
 816 */
 817 //void() ctf_playerchanged;
 818 void PutClientInServer (void)
 819 {
 820         if(clienttype(self) == CLIENTTYPE_BOT)
 821         {
 822                 self.classname = "player";
 823         }
 824         else if(clienttype(self) == CLIENTTYPE_REAL)
 825         {
 826                 msg_entity = self;
 827                 WriteByte(MSG_ONE, SVC_SETVIEW);
 828                 WriteEntity(MSG_ONE, self);
 829         }
 830
 831         // player is dead and becomes observer
 832         // FIXME fix LMS scoring for new system
 833         if(g_lms)
 834         {
 835                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 836                         self.classname = "observer";
 837         }
 838
 839         if(g_arena || (g_ca && !allowed_to_spawn))
 840         if(!self.spawned)
 841                 self.classname = "observer";
 842
 843         if(gameover)
 844                 self.classname = "observer";
 845
 846         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 847                 entity spot, oldself;
 848                 float j;
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 if(cvar("g_playerclip_collisions"))
 870                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 871                 else
 872                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 873                 self.frags = FRAGS_PLAYER;
 874                 if(independent_players)
 875                         MAKE_INDEPENDENT_PLAYER(self);
 876                 self.flags = FL_CLIENT;
 877                 self.takedamage = DAMAGE_AIM;
 878                 if(g_minstagib)
 879                         self.effects = EF_FULLBRIGHT;
 880                 else
 881                         self.effects = 0;
 882                 self.air_finished = time + 12;
 883                 self.dmg = 2;
 884
 885                 if(inWarmupStage)
 886                 {
 887                         self.ammo_shells = warmup_start_ammo_shells;
 888                         self.ammo_nails = warmup_start_ammo_nails;
 889                         self.ammo_rockets = warmup_start_ammo_rockets;
 890                         self.ammo_cells = warmup_start_ammo_cells;
 891                         self.ammo_fuel = warmup_start_ammo_fuel;
 892                         self.health = warmup_start_health;
 893                         self.armorvalue = warmup_start_armorvalue;
 894                         self.weapons = warmup_start_weapons;
 895                 }
 896                 else
 897                 {
 898                         self.ammo_shells = start_ammo_shells;
 899                         self.ammo_nails = start_ammo_nails;
 900                         self.ammo_rockets = start_ammo_rockets;
 901                         self.ammo_cells = start_ammo_cells;
 902                         self.ammo_fuel = start_ammo_fuel;
 903                         self.health = start_health;
 904                         self.armorvalue = start_armorvalue;
 905                         self.weapons = start_weapons;
 906                 }
 907
 908                 if(g_weaponarena_random)
 909                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 910
 911                 self.items = start_items;
 912                 self.jump_interval = time;
 913
 914                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 915                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 916                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 917                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 918                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 919                 //extend the pause of rotting if client was reset at the beginning of the countdown
 920                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 921                         self.spawnshieldtime += game_starttime - time;
 922                         self.pauserotarmor_finished += game_starttime - time;
 923                         self.pauserothealth_finished += game_starttime - time;
 924                         self.pauseregen_finished += game_starttime - time;
 925                 }
 926                 self.damageforcescale = 2;
 927                 self.death_time = 0;
 928                 self.dead_frame = 0;
 929                 self.alpha = 0;
 930                 self.scale = 0;
 931                 self.fade_time = 0;
 932                 self.pain_frame = 0;
 933                 self.pain_finished = 0;
 934                 self.strength_finished = 0;
 935                 self.invincible_finished = 0;
 936                 self.pushltime = 0;
 937                 // players have no think function
 938                 self.think = SUB_Null;
 939                 self.nextthink = 0;
 940                 self.hook_time = 0;
 941                 self.dmg_team = 0;
 942                 self.ballistics_density = cvar("g_ballistics_density_player");
 943
 944                 self.metertime = 0;
 945
 946                 self.runes = 0;
 947
 948                 self.deadflag = DEAD_NO;
 949
 950                 self.angles = spot.angles;
 951
 952                 self.angles_z = 0; // never spawn tilted even if the spot says to
 953                 self.fixangle = TRUE; // turn this way immediately
 954                 self.velocity = '0 0 0';
 955                 self.avelocity = '0 0 0';
 956                 self.punchangle = '0 0 0';
 957                 self.punchvector = '0 0 0';
 958                 self.oldvelocity = self.velocity;
 959                 self.fire_endtime = -1;
 960
 961                 msg_entity = self;
 962                 WRITESPECTATABLE_MSG_ONE({
 963                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 964                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 965                 });
 966
 967                 if(sv_loddistance1)
 968                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 969
 970                 self.model = "";
 971                 FixPlayermodel();
 972
 973                 self.crouch = FALSE;
 974                 self.view_ofs = PL_VIEW_OFS;
 975                 setsize (self, PL_MIN, PL_MAX);
 976                 self.spawnorigin = spot.origin;
 977                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 978                 // don't reset back to last position, even if new position is stuck in solid
 979                 self.oldorigin = self.origin;
 980                 self.prevorigin = self.origin;
 981                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 982
 983                 if(g_arena)
 984                 {
 985                         Spawnqueue_Remove(self);
 986                         Spawnqueue_Mark(self);
 987                 }
 988
 989                 else if(g_ca)
 990                         self.caplayer = 1;
 991
 992                 self.event_damage = PlayerDamage;
 993
 994                 self.bot_attack = TRUE;
 995
 996                 self.statdraintime = time + 5;
 997                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 998
 999                 if(self.killcount == -666) {
1000                         PlayerScore_Clear(self);
1001                         self.killcount = 0;
1002                 }
1003
1004                 self.cnt = WEP_LASER;
1005
1006                 CL_SpawnWeaponentity();
1007                 self.alpha = default_player_alpha;
1008                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1009                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1010
1011                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1012                 self.lms_traveled_distance = 0;
1013                 self.speedrunning = FALSE;
1014
1015                 race_PostSpawn(spot);
1016
1017                 if(cvar("spawn_debug"))
1018                 {
1019                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1020                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1021                 }
1022
1023                 //stuffcmd(self, "chase_active 0");
1024                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1025
1026                 if (cvar("g_spawnsound"))
1027                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1028
1029                 if(g_assault) {
1030                         if(self.team == assault_attacker_team)
1031                                 centerprint(self, "You are attacking!");
1032                         else
1033                                 centerprint(self, "You are defending!");
1034                 }
1035
1036                 target_voicescript_clear(self);
1037
1038                 // reset fields the weapons may use
1039                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1040                         weapon_action(j, WR_RESETPLAYER);
1041
1042                 oldself = self;
1043                 self = spot;
1044                         activator = oldself;
1045                                 SUB_UseTargets();
1046                         activator = world;
1047                 self = oldself;
1048
1049                 MUTATOR_CALLHOOK(PlayerSpawn);
1050
1051                 self.switchweapon = w_getbestweapon(self);
1052                 self.cnt = self.switchweapon;
1053                 self.weapon = 0;
1054         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1055                 PutObserverInServer ();
1056         }
1057
1058         //if(g_ctf)
1059         //      ctf_playerchanged();
1060 }
1061
1062 float ClientInit_SendEntity(entity to, float sf)
1063 {
1064         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1065         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1066         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1067         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1068         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1069         WriteCoord(MSG_ENTITY, electro_shotorigin_x);
1070         WriteCoord(MSG_ENTITY, electro_shotorigin_y);
1071         WriteCoord(MSG_ENTITY, electro_shotorigin_z);
1072         if(sv_foginterval && world.fog != "")
1073                 WriteString(MSG_ENTITY, world.fog);
1074         else
1075                 WriteString(MSG_ENTITY, "");
1076         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1077         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1078         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1079         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1080         return TRUE;
1081 }
1082
1083 void ClientInit_CheckUpdate()
1084 {
1085         self.nextthink = time;
1086         if(self.count != cvar("g_balance_armor_blockpercent"))
1087         {
1088                 self.count = cvar("g_balance_armor_blockpercent");
1089                 self.SendFlags |= 1;
1090         }
1091         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1092         {
1093                 self.cnt = cvar("g_balance_weaponswitchdelay");
1094                 self.SendFlags |= 1;
1095         }
1096         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1097         {
1098                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1099                 self.SendFlags |= 1;
1100         }
1101         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1102         {
1103                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1104                 self.SendFlags |= 1;
1105         }
1106 }
1107
1108 void ClientInit_Spawn()
1109 {
1110         entity o;
1111         entity e;
1112         e = spawn();
1113         e.classname = "clientinit";
1114         e.think = ClientInit_CheckUpdate;
1115         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1116
1117         o = self;
1118         self = e;
1119         ClientInit_CheckUpdate();
1120         self = o;
1121 }
1122
1123 /*
1124 =============
1125 SetNewParms
1126 =============
1127 */
1128 void SetNewParms (void)
1129 {
1130         // initialize parms for a new player
1131         parm1 = -(86400 * 366);
1132 }
1133
1134 /*
1135 =============
1136 SetChangeParms
1137 =============
1138 */
1139 void SetChangeParms (void)
1140 {
1141         // save parms for level change
1142         parm1 = self.parm_idlesince - time;
1143 }
1144
1145 /*
1146 =============
1147 DecodeLevelParms
1148 =============
1149 */
1150 void DecodeLevelParms (void)
1151 {
1152         // load parms
1153         self.parm_idlesince = parm1;
1154         if(self.parm_idlesince == -(86400 * 366))
1155                 self.parm_idlesince = time;
1156
1157         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1158         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1159 }
1160
1161 /*
1162 =============
1163 ClientKill
1164
1165 Called when a client types 'kill' in the console
1166 =============
1167 */
1168
1169 void ClientKill_Now_TeamChange()
1170 {
1171         if(self.killindicator_teamchange == -1)
1172         {
1173                 self.team = -1;
1174                 JoinBestTeam( self, FALSE, FALSE );
1175         }
1176         else
1177                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1178 }
1179
1180 void ClientKill_Now()
1181 {
1182         if(self.killindicator_teamchange)
1183                 ClientKill_Now_TeamChange();
1184
1185         // in any case:
1186         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1187
1188         if(self.killindicator)
1189         {
1190                 dprint("Cleaned up after a leaked kill indicator.\n");
1191                 remove(self.killindicator);
1192                 self.killindicator = world;
1193         }
1194 }
1195 void KillIndicator_Think()
1196 {
1197         if (!self.owner.modelindex)
1198         {
1199                 self.owner.killindicator = world;
1200                 remove(self);
1201                 return;
1202         }
1203
1204         if(self.cnt <= 0)
1205         {
1206                 self = self.owner;
1207                 ClientKill_Now(); // no oldself needed
1208                 return;
1209         }
1210         else
1211         {
1212                 if(self.cnt <= 10)
1213                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1214                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1215                 {
1216                         if(self.cnt <= 10)
1217                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1218                         if(self.owner.killindicator_teamchange)
1219                         {
1220                                 if(self.owner.killindicator_teamchange == -1)
1221                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1222                                 else
1223                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1224                         }
1225                         else
1226                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1227                 }
1228                 self.nextthink = time + 1;
1229                 self.cnt -= 1;
1230         }
1231 }
1232
1233 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1234 {
1235         float killtime;
1236         entity e;
1237         killtime = cvar("g_balance_kill_delay");
1238
1239         if(g_race_qualifying)
1240                 killtime = 0;
1241
1242         self.killindicator_teamchange = targetteam;
1243
1244         if(!self.killindicator)
1245         {
1246                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1247                 {
1248                         ClientKill_Now();
1249                 }
1250                 else
1251                 {
1252                         self.killindicator = spawn();
1253                         self.killindicator.owner = self;
1254                         self.killindicator.scale = 0.5;
1255                         setattachment(self.killindicator, self, "");
1256                         setorigin(self.killindicator, '0 0 52');
1257                         self.killindicator.think = KillIndicator_Think;
1258                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1259                         self.killindicator.cnt = ceil(killtime);
1260                         self.killindicator.count = bound(0, ceil(killtime), 10);
1261                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1262
1263                         for(e = world; (e = find(e, classname, "body")) != world; )
1264                         {
1265                                 if(e.enemy != self)
1266                                         continue;
1267                                 e.killindicator = spawn();
1268                                 e.killindicator.owner = e;
1269                                 e.killindicator.scale = 0.5;
1270                                 setattachment(e.killindicator, e, "");
1271                                 setorigin(e.killindicator, '0 0 52');
1272                                 e.killindicator.think = KillIndicator_Think;
1273                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1274                                 e.killindicator.cnt = ceil(killtime);
1275                         }
1276                         self.lip = 0;
1277                 }
1278         }
1279         if(self.killindicator)
1280         {
1281                 if(targetteam)
1282                         self.killindicator.colormod = TeamColor(targetteam);
1283                 else
1284                         self.killindicator.colormod = '0 0 0';
1285         }
1286 }
1287
1288 void ClientKill (void)
1289 {
1290         ClientKill_TeamChange(0);
1291 }
1292
1293 void DoTeamChange(float destteam)
1294 {
1295         float t, c0;
1296         if(!teams_matter)
1297         {
1298                 if(destteam >= 0)
1299                         SetPlayerColors(self, destteam);
1300                 return;
1301         }
1302         if(self.classname == "player")
1303         if(destteam == -1)
1304         {
1305                 CheckAllowedTeams(self);
1306                 t = FindSmallestTeam(self, TRUE);
1307                 switch(self.team)
1308                 {
1309                         case COLOR_TEAM1: c0 = c1; break;
1310                         case COLOR_TEAM2: c0 = c2; break;
1311                         case COLOR_TEAM3: c0 = c3; break;
1312                         case COLOR_TEAM4: c0 = c4; break;
1313                         default:          c0 = 999;
1314                 }
1315                 switch(t)
1316                 {
1317                         case 1:
1318                                 if(c0 > c1)
1319                                         destteam = COLOR_TEAM1;
1320                                 break;
1321                         case 2:
1322                                 if(c0 > c2)
1323                                         destteam = COLOR_TEAM2;
1324                                 break;
1325                         case 3:
1326                                 if(c0 > c3)
1327                                         destteam = COLOR_TEAM3;
1328                                 break;
1329                         case 4:
1330                                 if(c0 > c4)
1331                                         destteam = COLOR_TEAM4;
1332                                 break;
1333                 }
1334                 if(destteam == -1)
1335                         return;
1336         }
1337         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1338                 return;
1339         ClientKill_TeamChange(destteam);
1340 }
1341
1342 void FixClientCvars(entity e)
1343 {
1344         // send prediction settings to the client
1345         stuffcmd(e, "\nin_bindmap 0 0\n");
1346         if(g_race || g_cts)
1347                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1348         if(cvar("g_antilag") == 3) // client side hitscan
1349                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1350                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1351         /*
1352          * we no longer need to stuff this. Remove this comment block if you feel
1353          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1354         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1355         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1356         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1357         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1358         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1359         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1360         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1361         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1362         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1363         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1364         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1365         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1366         stuffcmd(e, "cl_movement_edgefriction 1\n");
1367          */
1368 }
1369
1370 /*
1371 =============
1372 ClientConnect
1373
1374 Called when a client connects to the server
1375 =============
1376 */
1377 //void ctf_clientconnect();
1378 string ColoredTeamName(float t);
1379 void DecodeLevelParms (void);
1380 //void dom_player_join_team(entity pl);
1381 #ifdef UID
1382 .float uid_kicktime;
1383 .string uid;
1384 #endif
1385 void ClientConnect (void)
1386 {
1387         float t;
1388
1389         if(self.flags & FL_CLIENT)
1390         {
1391                 print("Warning: ClientConnect, but already connected!\n");
1392                 return;
1393         }
1394
1395         if(Ban_MaybeEnforceBan(self))
1396                 return;
1397
1398         DecodeLevelParms();
1399
1400 #ifdef WATERMARK
1401         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1402 #endif
1403
1404         self.classname = "player_joining";
1405
1406         self.flags = FL_CLIENT;
1407         self.version_nagtime = time + 10 + random() * 10;
1408
1409         if(player_count<0)
1410         {
1411                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1412                 player_count = 0;
1413         }
1414
1415         PlayerScore_Attach(self);
1416         ClientData_Attach();
1417
1418         bot_clientconnect();
1419
1420         playerdemo_init();
1421
1422         anticheat_init();
1423
1424         race_PreSpawnObserver();
1425
1426         //if(g_domination)
1427         //      dom_player_join_team(self);
1428
1429         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1430
1431         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1432                 self.classname = "observer";
1433         } else {
1434                 if(teams_matter)
1435                 {
1436                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1437                         {
1438                                 self.classname = "player";
1439                                 campaign_bots_may_start = 1;
1440                         }
1441                         else
1442                         {
1443                                 self.classname = "observer"; // do it anyway
1444                         }
1445                 }
1446                 else
1447                 {
1448                         self.classname = "player";
1449                         campaign_bots_may_start = 1;
1450                 }
1451         }
1452
1453         self.playerid = (playerid_last = playerid_last + 1);
1454
1455         if(cvar("sv_eventlog"))
1456                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1457
1458         LogTeamchange(self.playerid, self.team, 1);
1459
1460         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1461
1462         self.netname_previous = strzone(self.netname);
1463
1464         bprint("^4", self.netname, "^4 connected");
1465
1466         if(self.classname != "observer" && (g_domination || g_ctf))
1467                 bprint(" and joined the ", ColoredTeamName(self.team));
1468
1469         bprint("\n");
1470
1471         self.welcomemessage_time = 0;
1472
1473         stuffcmd(self, strcat(clientstuff, "\n"));
1474         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1475         stuffcmd(self, "cl_particles_reloadeffects\n");
1476
1477         FixClientCvars(self);
1478
1479         // spawnfunc_waypoint sprites
1480         WaypointSprite_InitClient(self);
1481
1482         // Wazat's grappling hook
1483         SetGrappleHookBindings();
1484
1485         // get autoswitch state from player when he toggles it
1486         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1487
1488         // get version info from player
1489         stuffcmd(self, "cmd clientversion $gameversion\n");
1490
1491         // get other cvars from player
1492         GetCvars(0);
1493
1494         // set cvar for team scoreboard
1495         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1496
1497         // notify about available teams
1498         if(teams_matter)
1499         {
1500                 CheckAllowedTeams(self);
1501                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1502                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1503         }
1504         else
1505                 stuffcmd(self, "set _teams_available 0\n");
1506
1507         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1508
1509         if(g_arena || g_ca)
1510         {
1511                 self.classname = "observer";
1512                 if(g_arena)
1513                         Spawnqueue_Insert(self);
1514         }
1515         /*else if(g_ctf)
1516         {
1517                 ctf_clientconnect();
1518         }*/
1519
1520         if(teams_matter || radar_showennemies)
1521                 attach_entcs();
1522
1523         bot_relinkplayerlist();
1524
1525         self.spectatortime = time;
1526         if(blockSpectators)
1527         {
1528                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1529         }
1530
1531         self.jointime = time;
1532         self.allowedTimeouts = cvar("sv_timeout_number");
1533
1534         if(clienttype(self) == CLIENTTYPE_REAL)
1535         {
1536                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1537                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1538         }
1539
1540         if(g_lms)
1541         {
1542                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1543                 {
1544                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1545                         self.frags = FRAGS_SPECTATOR;
1546                 }
1547         }
1548
1549         if(!sv_foginterval && world.fog != "")
1550                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1551
1552         SoundEntity_Attach(self);
1553
1554         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1555         {
1556                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1557                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1558         }
1559         else
1560                 self.hitplotfh = -1;
1561
1562 #ifdef UID
1563         if(clienttype(self) == CLIENTTYPE_REAL)
1564         if not(self.uid)
1565                 self.uid_kicktime = time + 60;
1566 #endif
1567
1568         if(g_race || g_cts) {
1569                 string rr;
1570                 if(g_cts)
1571                         rr = CTS_RECORD;
1572                 else
1573                         rr = RACE_RECORD;
1574                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1575
1576                 race_send_recordtime(MSG_ONE);
1577                 race_send_speedaward(MSG_ONE);
1578
1579                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1580                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1581                 race_send_speedaward_alltimebest(MSG_ONE);
1582
1583                 float i;
1584                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1585                         race_SendRankings(i, 0, 0, MSG_ONE);
1586                 }
1587         }
1588         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1589                 send_CSQC_teamnagger();
1590
1591         CheatInitClient();
1592 }
1593
1594 /*
1595 =============
1596 ClientDisconnect
1597
1598 Called when a client disconnects from the server
1599 =============
1600 */
1601 .entity chatbubbleentity;
1602 .entity teambubbleentity;
1603 void ReadyCount();
1604 void ClientDisconnect (void)
1605 {
1606         if not(self.flags & FL_CLIENT)
1607         {
1608                 print("Warning: ClientDisconnect without ClientConnect\n");
1609                 return;
1610         }
1611
1612         CheatShutdownClient();
1613
1614         if(self.hitplotfh >= 0)
1615         {
1616                 fclose(self.hitplotfh);
1617                 self.hitplotfh = -1;
1618         }
1619
1620         anticheat_report();
1621         anticheat_shutdown();
1622
1623         playerdemo_shutdown();
1624
1625         bot_clientdisconnect();
1626
1627         if(self.entcs)
1628                 detach_entcs();
1629
1630         if(cvar("sv_eventlog"))
1631                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1632         bprint ("^4",self.netname);
1633         bprint ("^4 disconnected\n");
1634
1635         SoundEntity_Detach(self);
1636
1637         DropAllRunes(self);
1638         MUTATOR_CALLHOOK(ClientDisconnect);
1639
1640         Portal_ClearAll(self);
1641
1642         if(self.flagcarried)
1643                 DropFlag(self.flagcarried, world, world);
1644         if(self.ballcarried)
1645                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1646
1647         // Here, everything has been done that requires this player to be a client.
1648
1649         self.flags &~= FL_CLIENT;
1650
1651         if (self.chatbubbleentity)
1652                 remove (self.chatbubbleentity);
1653
1654         if (self.teambubbleentity)
1655                 remove (self.teambubbleentity);
1656
1657         if (self.killindicator)
1658                 remove (self.killindicator);
1659
1660         WaypointSprite_PlayerGone();
1661
1662         bot_relinkplayerlist();
1663
1664         // remove laserdot
1665         if(self.weaponentity)
1666                 if(self.weaponentity.lasertarget)
1667                         remove(self.weaponentity.lasertarget);
1668
1669         if(g_arena)
1670         {
1671                 Spawnqueue_Unmark(self);
1672                 Spawnqueue_Remove(self);
1673         }
1674
1675         ClientData_Detach();
1676         PlayerScore_Detach(self);
1677
1678         if(self.netname_previous)
1679                 strunzone(self.netname_previous);
1680         if(self.clientstatus)
1681                 strunzone(self.clientstatus);
1682
1683         ClearPlayerSounds();
1684
1685         if(self.personal)
1686                 remove(self.personal);
1687
1688         self.playerid = 0;
1689         ReadyCount();
1690
1691         // free cvars
1692         GetCvars(-1);
1693 }
1694
1695 .float BUTTON_CHAT;
1696 void ChatBubbleThink()
1697 {
1698         self.nextthink = time;
1699         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1700         {
1701                 if(self.owner) // but why can that ever be world?
1702                         self.owner.chatbubbleentity = world;
1703                 remove(self);
1704                 return;
1705         }
1706         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1707 #ifdef TETRIS
1708                 || self.owner.tetris_on
1709 #endif
1710         )
1711                 self.model = self.mdl;
1712         else
1713                 self.model = "";
1714 };
1715
1716 void UpdateChatBubble()
1717 {
1718         if (!self.modelindex)
1719                 return;
1720         // spawn a chatbubble entity if needed
1721         if (!self.chatbubbleentity)
1722         {
1723                 self.chatbubbleentity = spawn();
1724                 self.chatbubbleentity.owner = self;
1725                 self.chatbubbleentity.exteriormodeltoclient = self;
1726                 self.chatbubbleentity.think = ChatBubbleThink;
1727                 self.chatbubbleentity.nextthink = time;
1728                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1729                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1730                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1731                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1732                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1733                 self.chatbubbleentity.model = "";
1734                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1735         }
1736 }
1737
1738
1739 void TeamBubbleThink()
1740 {
1741         self.nextthink = time;
1742         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1743         {
1744                 if(self.owner) // but why can that ever be world?
1745                         self.owner.teambubbleentity = world;
1746                 remove(self);
1747                 return;
1748         }
1749 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1750         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1751                 self.model = "";
1752         else
1753                 self.model = self.mdl;
1754
1755 };
1756
1757 float TeamBubble_customizeentityforclient()
1758 {
1759         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1760 }
1761
1762 void UpdateTeamBubble()
1763 {
1764         if (!self.modelindex || !teams_matter)
1765                 return;
1766         // spawn a teambubble entity if needed
1767         if (!self.teambubbleentity && teams_matter)
1768         {
1769                 self.teambubbleentity = spawn();
1770                 self.teambubbleentity.owner = self;
1771                 self.teambubbleentity.exteriormodeltoclient = self;
1772                 self.teambubbleentity.think = TeamBubbleThink;
1773                 self.teambubbleentity.nextthink = time;
1774                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1775 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1776                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1777                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1778                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1779                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1780                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1781                 self.teambubbleentity.effects = EF_LOWPRECISION;
1782         }
1783 }
1784
1785 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1786 // added to the model skins
1787 /*void UpdateColorModHack()
1788 {
1789         local float c;
1790         c = self.clientcolors & 15;
1791         // LordHavoc: only bothering to support white, green, red, yellow, blue
1792              if (!teams_matter) self.colormod = '0 0 0';
1793         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1794         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1795         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1796         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1797         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1798         else self.colormod = '1 1 1';
1799 };*/
1800
1801 .float oldcolormap;
1802 void respawn(void)
1803 {
1804         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1805         {
1806                 self.solid = SOLID_NOT;
1807                 self.takedamage = DAMAGE_NO;
1808                 self.movetype = MOVETYPE_FLY;
1809                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1810                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1811                 self.effects |= EF_ADDITIVE;
1812                 self.oldcolormap = self.colormap;
1813                 self.colormap = 512;
1814                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1815                 if(cvar("g_respawn_ghosts_maxtime"))
1816                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1817         }
1818
1819         CopyBody(1);
1820         self.effects |= EF_NODRAW; // prevent another CopyBody
1821         if(self.oldcolormap)
1822         {
1823                 self.colormap = self.oldcolormap;
1824                 self.oldcolormap = 0;
1825         }
1826         PutClientInServer();
1827 }
1828
1829 void play_countdown(float finished, string samp)
1830 {
1831         if(clienttype(self) == CLIENTTYPE_REAL)
1832                 if(floor(finished - time - frametime) != floor(finished - time))
1833                         if(finished - time < 6)
1834                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1835 }
1836
1837 /**
1838  * When sv_timeout is used this function returs strings like
1839  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1840  * Called by centerprint functions
1841  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1842  */
1843 string getTimeoutText(float addOneSecond) {
1844         if (!cvar("sv_timeout") || !timeoutStatus)
1845                 return "";
1846
1847         local string retStr;
1848         if (timeoutStatus == 1) {
1849                 if (addOneSecond == 1) {
1850                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1851                 }
1852                 else {
1853                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1854                 }
1855                 return retStr;
1856         }
1857         else if (timeoutStatus == 2) {
1858                 if (addOneSecond) {
1859                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1860                         //don't show messages like "Timeout ends in 0 seconds"...
1861                         if ((remainingTimeoutTime + 1) > 0)
1862                                 return retStr;
1863                         else
1864                                 return "";
1865                 }
1866                 else {
1867                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1868                         //don't show messages like "Timeout ends in 0 seconds"...
1869                         if (remainingTimeoutTime > 0)
1870                                 return retStr;
1871                         else
1872                                 return "";
1873                 }
1874         }
1875         else return "";
1876 }
1877
1878 void player_powerups (void)
1879 {
1880         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1881         {
1882                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1883                 self.modelflags |= MF_ROCKET;
1884         }
1885         else
1886         {
1887                 SoundEntity_StopSound(self, CHAN_PLAYER);
1888                 self.modelflags &~= MF_ROCKET;
1889         }
1890
1891         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1892
1893         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1894                 return;
1895
1896         Fire_ApplyDamage(self);
1897         Fire_ApplyEffect(self);
1898
1899         if (g_minstagib)
1900         {
1901                 self.effects |= EF_FULLBRIGHT;
1902
1903                 if (self.items & IT_STRENGTH)
1904                 {
1905                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1906                         if (time > self.strength_finished)
1907                         {
1908                                 self.alpha = default_player_alpha;
1909                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1910                                 self.items &~= IT_STRENGTH;
1911                                 sprint(self, "^3Invisibility has worn off\n");
1912                         }
1913                 }
1914                 else
1915                 {
1916                         if (time < self.strength_finished)
1917                         {
1918                                 self.alpha = g_minstagib_invis_alpha;
1919                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1920                                 self.items |= IT_STRENGTH;
1921                                 sprint(self, "^3You are invisible\n");
1922                         }
1923                 }
1924
1925                 if (self.items & IT_INVINCIBLE)
1926                 {
1927                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1928                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1929                         {
1930                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1931                                 sprint(self, "^3Speed has worn off\n");
1932                         }
1933                 }
1934                 else
1935                 {
1936                         if (time < self.invincible_finished)
1937                         {
1938                                 self.items = self.items | IT_INVINCIBLE;
1939                                 sprint(self, "^3You are on speed\n");
1940                         }
1941                 }
1942                 return;
1943         }
1944
1945         if (self.items & IT_STRENGTH)
1946         {
1947                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1948                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1949                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1950                 {
1951                         self.items = self.items - (self.items & IT_STRENGTH);
1952                         sprint(self, "^3Strength has worn off\n");
1953                 }
1954         }
1955         else
1956         {
1957                 if (time < self.strength_finished)
1958                 {
1959                         self.items = self.items | IT_STRENGTH;
1960                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1961                 }
1962         }
1963         if (self.items & IT_INVINCIBLE)
1964         {
1965                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1966                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1967                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1968                 {
1969                         self.items = self.items - (self.items & IT_INVINCIBLE);
1970                         sprint(self, "^3Shield has worn off\n");
1971                 }
1972         }
1973         else
1974         {
1975                 if (time < self.invincible_finished)
1976                 {
1977                         self.items = self.items | IT_INVINCIBLE;
1978                         sprint(self, "^3Shield surrounds you\n");
1979                 }
1980         }
1981
1982         if(cvar("g_nodepthtestplayers"))
1983                 self.effects = self.effects | EF_NODEPTHTEST;
1984
1985         if(cvar("g_fullbrightplayers"))
1986                 self.effects = self.effects | EF_FULLBRIGHT;
1987
1988         // midair gamemode: damage only while in the air
1989         // if in midair mode, being on ground grants temporary invulnerability
1990         // (this is so that multishot weapon don't clear the ground flag on the
1991         // first damage in the frame, leaving the player vulnerable to the
1992         // remaining hits in the same frame)
1993         if (self.flags & FL_ONGROUND)
1994         if (g_midair)
1995                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1996
1997         if (time >= game_starttime)
1998         if (time < self.spawnshieldtime)
1999                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2000 }
2001
2002 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2003 {
2004         if(current > stable)
2005                 return current;
2006         else if(current > stable - 0.25) // when close enough, "snap"
2007                 return stable;
2008         else
2009                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2010 }
2011
2012 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2013 {
2014         if(current < stable)
2015                 return current;
2016         else if(current < stable + 0.25) // when close enough, "snap"
2017                 return stable;
2018         else
2019                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2020 }
2021
2022 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2023 {
2024         if(current > rotstable)
2025         {
2026                 if(rotframetime > 0)
2027                 {
2028                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2029                         current = max(rotstable, current - rotlinear * rotframetime);
2030                 }
2031         }
2032         else if(current < regenstable)
2033         {
2034                 if(regenframetime > 0)
2035                 {
2036                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2037                         current = min(regenstable, current + regenlinear * regenframetime);
2038                 }
2039         }
2040
2041         if(current > limit)
2042                 current = limit;
2043
2044         return current;
2045 }
2046
2047 void player_regen (void)
2048 {
2049         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2050         maxh = cvar("g_balance_health_rotstable");
2051         maxa = cvar("g_balance_armor_rotstable");
2052         maxf = cvar("g_balance_fuel_rotstable");
2053         minh = cvar("g_balance_health_regenstable");
2054         mina = cvar("g_balance_armor_regenstable");
2055         minf = cvar("g_balance_fuel_regenstable");
2056         limith = cvar("g_balance_health_limit");
2057         limita = cvar("g_balance_armor_limit");
2058         limitf = cvar("g_balance_fuel_limit");
2059
2060         max_mod = regen_mod = rot_mod = limit_mod = 1;
2061
2062         if (self.runes & RUNE_REGEN)
2063         {
2064                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2065                 {
2066                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2067                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2068                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2069                 }
2070                 else
2071                 {
2072                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2073                         max_mod = cvar("g_balance_rune_regen_hpmod");
2074                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2075                 }
2076         }
2077         else if (self.runes & CURSE_VENOM)
2078         {
2079                 max_mod = cvar("g_balance_curse_venom_hpmod");
2080                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2081                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2082                 else
2083                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2084                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2085                 //if (!self.runes & RUNE_REGEN)
2086                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2087         }
2088         maxh = maxh * max_mod;
2089         //maxa = maxa * max_mod;
2090         //maxf = maxf * max_mod;
2091         minh = minh * max_mod;
2092         //mina = mina * max_mod;
2093         //minf = minf * max_mod;
2094         limith = limith * limit_mod;
2095         limita = limita * limit_mod;
2096         //limitf = limitf * limit_mod;
2097
2098         if(g_lms && g_ca)
2099                 rot_mod = 0;
2100
2101         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2102         {
2103                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2104                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2105
2106                 // if player rotted to death...  die!
2107                 if(self.health < 1)
2108                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2109         }
2110
2111         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2112                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2113 }
2114
2115 float zoomstate_set;
2116 void SetZoomState(float z)
2117 {
2118         if(z != self.zoomstate)
2119         {
2120                 self.zoomstate = z;
2121                 ClientData_Touch(self);
2122         }
2123         zoomstate_set = 1;
2124 }
2125
2126 void GetPressedKeys(void) {
2127         MUTATOR_CALLHOOK(GetPressedKeys);
2128         if (self.movement_x > 0) // get if movement keys are pressed
2129         {       // forward key pressed
2130                 self.pressedkeys |= KEY_FORWARD;
2131                 self.pressedkeys &~= KEY_BACKWARD;
2132         }
2133         else if (self.movement_x < 0)
2134         {       // backward key pressed
2135                 self.pressedkeys |= KEY_BACKWARD;
2136                 self.pressedkeys &~= KEY_FORWARD;
2137         }
2138         else
2139         {       // no x input
2140                 self.pressedkeys &~= KEY_FORWARD;
2141                 self.pressedkeys &~= KEY_BACKWARD;
2142         }
2143
2144         if (self.movement_y > 0)
2145         {       // right key pressed
2146                 self.pressedkeys |= KEY_RIGHT;
2147                 self.pressedkeys &~= KEY_LEFT;
2148         }
2149         else if (self.movement_y < 0)
2150         {       // left key pressed
2151                 self.pressedkeys |= KEY_LEFT;
2152                 self.pressedkeys &~= KEY_RIGHT;
2153         }
2154         else
2155         {       // no y input
2156                 self.pressedkeys &~= KEY_RIGHT;
2157                 self.pressedkeys &~= KEY_LEFT;
2158         }
2159
2160         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2161                 self.pressedkeys |= KEY_JUMP;
2162         else
2163                 self.pressedkeys &~= KEY_JUMP;
2164         if (self.BUTTON_CROUCH)
2165                 self.pressedkeys |= KEY_CROUCH;
2166         else
2167                 self.pressedkeys &~= KEY_CROUCH;
2168 }
2169
2170 void update_stats (float number, float hit, float fired) {
2171 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2172 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2173
2174         if(number) {
2175                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2176                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2177         } else {
2178                 self.stat_hit = hit * sv_accuracy_data_share;
2179                 self.stat_fired = fired * sv_accuracy_data_share;
2180         }
2181 }
2182
2183 /*
2184 ======================
2185 spectate mode routines
2186 ======================
2187 */
2188
2189 .float weapon_count;
2190 void SpectateCopy(entity spectatee) {
2191         if(spectatee.weapon_count < WEP_LAST) {
2192                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2193                 spectatee.weapon_count ++;
2194         } else
2195                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2196
2197         other = spectatee;
2198         MUTATOR_CALLHOOK(SpectateCopy);
2199         self.armortype = spectatee.armortype;
2200         self.armorvalue = spectatee.armorvalue;
2201         self.ammo_cells = spectatee.ammo_cells;
2202         self.ammo_shells = spectatee.ammo_shells;
2203         self.ammo_nails = spectatee.ammo_nails;
2204         self.ammo_rockets = spectatee.ammo_rockets;
2205         self.ammo_fuel = spectatee.ammo_fuel;
2206         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2207         self.health = spectatee.health;
2208         self.impulse = 0;
2209         self.items = spectatee.items;
2210         self.metertime = spectatee.metertime;
2211         self.strength_finished = spectatee.strength_finished;
2212         self.invincible_finished = spectatee.invincible_finished;
2213         self.pressedkeys = spectatee.pressedkeys;
2214         self.weapons = spectatee.weapons;
2215         self.switchweapon = spectatee.switchweapon;
2216         self.weapon = spectatee.weapon;
2217         self.punchangle = spectatee.punchangle;
2218         self.view_ofs = spectatee.view_ofs;
2219         self.v_angle = spectatee.v_angle;
2220         self.velocity = spectatee.velocity;
2221         self.dmg_take = spectatee.dmg_take;
2222         self.dmg_save = spectatee.dmg_save;
2223         self.dmg_inflictor = spectatee.dmg_inflictor;
2224         self.angles = spectatee.v_angle;
2225         self.fixangle = TRUE;
2226         setorigin(self, spectatee.origin);
2227         setsize(self, spectatee.mins, spectatee.maxs);
2228         SetZoomState(spectatee.zoomstate);
2229
2230         anticheat_spectatecopy(spectatee);
2231 }
2232
2233 float SpectateUpdate() {
2234         if(!self.enemy)
2235                 return 0;
2236
2237         if (self == self.enemy)
2238                 return 0;
2239
2240         if(self.enemy.classname != "player")
2241                 return 0;
2242
2243         SpectateCopy(self.enemy);
2244
2245         return 1;
2246 }
2247
2248 float SpectateNext() {
2249         other = find(self.enemy, classname, "player");
2250
2251         if (!other)
2252                 other = find(other, classname, "player");
2253
2254         if (other)
2255                 self.enemy = other;
2256
2257         if(self.enemy.classname == "player") {
2258                 msg_entity = self;
2259                 WriteByte(MSG_ONE, SVC_SETVIEW);
2260                 WriteEntity(MSG_ONE, self.enemy);
2261                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2262                 self.movetype = MOVETYPE_NONE;
2263
2264                 self.enemy.weapon_count = 0;
2265
2266                 if(!SpectateUpdate())
2267                         PutObserverInServer();
2268
2269                 return 1;
2270         } else {
2271                 return 0;
2272         }
2273 }
2274
2275 /*
2276 =============
2277 ShowRespawnCountdown()
2278
2279 Update a respawn countdown display.
2280 =============
2281 */
2282 void ShowRespawnCountdown()
2283 {
2284         float number;
2285         if(self.deadflag == DEAD_NO) // just respawned?
2286                 return;
2287         else
2288         {
2289                 number = ceil(self.death_time - time);
2290                 if(number <= 0)
2291                         return;
2292                 if(number <= self.respawn_countdown)
2293                 {
2294                         self.respawn_countdown = number - 1;
2295                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2296                                 AnnounceTo(self, strcat(ftos(number), ""));
2297                 }
2298         }
2299 }
2300
2301 void LeaveSpectatorMode()
2302 {
2303         if(isJoinAllowed()) {
2304                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2305                         self.classname = "player";
2306
2307                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2308                                 JoinBestTeam(self, FALSE, TRUE);
2309
2310                         if(cvar("g_campaign"))
2311                                 campaign_bots_may_start = 1;
2312
2313                         self.stat_count = WEP_LAST;
2314
2315                         PutClientInServer();
2316
2317                         if(self.classname == "player")
2318                                 bprint ("^4", self.netname, "^4 is playing now\n");
2319
2320                         if(!cvar("g_campaign"))
2321                                 centerprint(self,""); // clear MOTD
2322
2323                         return;
2324                 } else {
2325                         if (g_ca && self.caplayer) {
2326                         }       // do nothing
2327                         else
2328                                 stuffcmd(self,"menu_showteamselect\n");
2329                         return;
2330                 }
2331         }
2332         else {
2333                 //player may not join because of g_maxplayers is set
2334                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2335         }
2336 }
2337
2338 /**
2339  * Determines whether the player is allowed to join. This depends on cvar
2340  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2341  * it checks whether the number of currently playing players exceeds g_maxplayers.
2342  * @return bool TRUE if the player is allowed to join, false otherwise
2343  */
2344 float isJoinAllowed() {
2345         if (!cvar("g_maxplayers"))
2346                 return TRUE;
2347
2348         local entity e;
2349         local float currentlyPlaying;
2350         FOR_EACH_REALPLAYER(e) {
2351                 if(e.classname == "player")
2352                         currentlyPlaying += 1;
2353         }
2354         if(currentlyPlaying < cvar("g_maxplayers"))
2355                 return TRUE;
2356
2357         return FALSE;
2358 }
2359
2360 /**
2361  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2362  * g_maxplayers_spectator_blocktime seconds
2363  */
2364 void checkSpectatorBlock() {
2365         if(self.classname == "spectator" || self.classname == "observer") {
2366                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2367                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2368                         dropclient(self);
2369                 }
2370         }
2371 }
2372
2373 float vercmp_recursive(string v1, string v2)
2374 {
2375         float dot1, dot2;
2376         string s1, s2;
2377         float r;
2378
2379         dot1 = strstrofs(v1, ".", 0);
2380         dot2 = strstrofs(v2, ".", 0);
2381         if(dot1 == -1)
2382                 s1 = v1;
2383         else
2384                 s1 = substring(v1, 0, dot1);
2385         if(dot2 == -1)
2386                 s2 = v2;
2387         else
2388                 s2 = substring(v2, 0, dot2);
2389
2390         r = stof(s1) - stof(s2);
2391         if(r != 0)
2392                 return r;
2393
2394         r = strcasecmp(s1, s2);
2395         if(r != 0)
2396                 return r;
2397
2398         if(dot1 == -1)
2399                 if(dot2 == -1)
2400                         return 0;
2401                 else
2402                         return -1;
2403         else
2404                 if(dot2 == -1)
2405                         return 1;
2406                 else
2407                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2408 }
2409
2410 float vercmp(string v1, string v2)
2411 {
2412         if(strcasecmp(v1, v2) == 0) // early out check
2413                 return 0;
2414         return vercmp_recursive(v1, v2);
2415 }
2416
2417 void ObserverThink()
2418 {
2419         if (self.flags & FL_JUMPRELEASED) {
2420                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2421                         self.welcomemessage_time = 0;
2422                         self.flags &~= FL_JUMPRELEASED;
2423                         self.flags |= FL_SPAWNING;
2424                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2425                         self.welcomemessage_time = 0;
2426                         self.flags &~= FL_JUMPRELEASED;
2427                         if(SpectateNext() == 1) {
2428                                 self.classname = "spectator";
2429                         }
2430                 }
2431         } else {
2432                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2433                         self.flags |= FL_JUMPRELEASED;
2434                         if(self.flags & FL_SPAWNING)
2435                         {
2436                                 self.flags &~= FL_SPAWNING;
2437                                 LeaveSpectatorMode();
2438                                 return;
2439                         }
2440                 }
2441         }
2442         PrintWelcomeMessage(self);
2443 }
2444
2445 void SpectatorThink()
2446 {
2447         if (self.flags & FL_JUMPRELEASED) {
2448                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2449                         self.welcomemessage_time = 0;
2450                         self.flags &~= FL_JUMPRELEASED;
2451                         self.flags |= FL_SPAWNING;
2452                 } else if(self.BUTTON_ATCK) {
2453                         self.welcomemessage_time = 0;
2454                         self.flags &~= FL_JUMPRELEASED;
2455                         if(SpectateNext() == 1) {
2456                                 self.classname = "spectator";
2457                         } else {
2458                                 self.classname = "observer";
2459                                 self.stat_count = WEP_LAST;
2460                                 PutClientInServer();
2461                         }
2462                 } else if (self.BUTTON_ATCK2) {
2463                         self.welcomemessage_time = 0;
2464                         self.flags &~= FL_JUMPRELEASED;
2465                         self.classname = "observer";
2466                         self.stat_count = WEP_LAST;
2467                         PutClientInServer();
2468                 } else {
2469                         if(!SpectateUpdate())
2470                                 PutObserverInServer();
2471                 }
2472         } else {
2473                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2474                         self.flags |= FL_JUMPRELEASED;
2475                         if(self.flags & FL_SPAWNING)
2476                         {
2477                                 self.flags &~= FL_SPAWNING;
2478                                 LeaveSpectatorMode();
2479                                 return;
2480                         }
2481                 }
2482         }
2483
2484         PrintWelcomeMessage(self);
2485         self.flags |= FL_CLIENT | FL_NOTARGET;
2486 }
2487
2488 .float touchexplode_time;
2489
2490 /*
2491 =============
2492 PlayerPreThink
2493
2494 Called every frame for each client before the physics are run
2495 =============
2496 */
2497 void() ctf_setstatus;
2498 void() nexball_setstatus;
2499 .float items_added;
2500 void PlayerPreThink (void)
2501 {
2502         self.stat_game_starttime = game_starttime;
2503         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2504         self.stat_leadlimit = cvar("leadlimit");
2505
2506         if(frametime)
2507         {
2508                 // physics frames: update anticheat stuff
2509                 anticheat_prethink();
2510         }
2511
2512         if(blockSpectators && frametime)
2513                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2514                 checkSpectatorBlock();
2515
2516         zoomstate_set = 0;
2517
2518         if(self.netname_previous != self.netname)
2519         {
2520                 if(cvar("sv_eventlog"))
2521                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2522                 if(self.netname_previous)
2523                         strunzone(self.netname_previous);
2524                 self.netname_previous = strzone(self.netname);
2525         }
2526
2527         // version nagging
2528         if(self.version_nagtime)
2529                 if(self.cvar_g_xonoticversion)
2530                         if(time > self.version_nagtime)
2531                         {
2532                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2533                                 {
2534                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2535                                         {
2536                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2537                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2538                                         }
2539                                         else
2540                                         {
2541                                                 float r;
2542                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2543                                                 if(r < 0)
2544                                                 {
2545                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2546                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2547                                                 }
2548                                                 else if(r > 0)
2549                                                 {
2550                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2551                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2552                                                 }
2553                                         }
2554                                 }
2555                                 self.version_nagtime = 0;
2556                         }
2557
2558         // GOD MODE info
2559         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2560         {
2561                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2562                 self.max_armorvalue = 0;
2563         }
2564
2565 #ifdef TETRIS
2566         if (TetrisPreFrame())
2567                 return;
2568 #endif
2569
2570         MUTATOR_CALLHOOK(PlayerPreThink);
2571
2572         if(self.classname == "player") {
2573 //              if(self.netname == "Wazat")
2574 //                      bprint(self.classname, "\n");
2575
2576                 CheckRules_Player();
2577
2578                 PrintWelcomeMessage(self);
2579
2580                 if (intermission_running)
2581                 {
2582                         IntermissionThink ();   // otherwise a button could be missed between
2583                         return;                                 // the think tics
2584                 }
2585
2586                 if(self.teleport_time)
2587                 if(time > self.teleport_time)
2588                 {
2589                         self.teleport_time = 0;
2590                         self.effects = self.effects - (self.effects & EF_NODRAW);
2591                 }
2592
2593                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2594                         UpdateSelectedPlayer();
2595
2596                 //don't allow the player to turn around while game is paused!
2597                 if(timeoutStatus == 2) {
2598                         self.v_angle = self.lastV_angle;
2599                         self.angles = self.lastV_angle;
2600                         self.fixangle = TRUE;
2601                 }
2602
2603                 if(frametime)
2604                 {
2605                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2606                         player_powerups();
2607                 }
2608
2609                 if (self.deadflag != DEAD_NO)
2610                 {
2611                         float button_pressed, force_respawn;
2612                         if(self.personal && g_race_qualifying)
2613                         {
2614                                 if(time > self.death_time)
2615                                 {
2616                                         self.death_time = time + 1; // only retry once a second
2617                                         respawn();
2618                                         self.impulse = 141;
2619                                 }
2620                         }
2621                         else
2622                         {
2623                                 if(frametime)
2624                                         player_anim();
2625                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2626                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2627                                 if (self.deadflag == DEAD_DYING)
2628                                 {
2629                                         if(force_respawn)
2630                                                 self.deadflag = DEAD_RESPAWNING;
2631                                         else if(!button_pressed)
2632                                                 self.deadflag = DEAD_DEAD;
2633                                 }
2634                                 else if (self.deadflag == DEAD_DEAD)
2635                                 {
2636                                         if(button_pressed)
2637                                                 self.deadflag = DEAD_RESPAWNABLE;
2638                                 }
2639                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2640                                 {
2641                                         if(!button_pressed)
2642                                                 self.deadflag = DEAD_RESPAWNING;
2643                                 }
2644                                 else if (self.deadflag == DEAD_RESPAWNING)
2645                                 {
2646                                         if(time > self.death_time)
2647                                         {
2648                                                 self.death_time = time + 1; // only retry once a second
2649                                                 respawn();
2650                                         }
2651                                 }
2652                                 ShowRespawnCountdown();
2653                         }
2654                         return;
2655                 }
2656
2657                 if(g_touchexplode)
2658                 if(time > self.touchexplode_time)
2659                 if(self.classname == "player")
2660                 if(self.deadflag == DEAD_NO)
2661                 if not(IS_INDEPENDENT_PLAYER(self))
2662                 FOR_EACH_PLAYER(other) if(self != other)
2663                 {
2664                         if(time > other.touchexplode_time)
2665                         if(other.deadflag == DEAD_NO)
2666                         if not(IS_INDEPENDENT_PLAYER(other))
2667                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2668                         {
2669                                 PlayerTouchExplode(self, other);
2670                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2671                         }
2672                 }
2673
2674                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2675                 {
2676                         vector dist;
2677
2678                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2679                         dist = self.prevorigin - self.origin;
2680                         dist_z = 0;
2681                         self.lms_traveled_distance += fabs(vlen(dist));
2682
2683                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2684                         {
2685                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2686                                 self.lms_traveled_distance = 0;
2687                         }
2688
2689                         if(time > self.lms_nextcheck)
2690                         {
2691                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2692                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2693                                 {
2694                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2695                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2696                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2697                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2698                                 }
2699                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2700                                 self.lms_traveled_distance = 0;
2701                         }
2702                 }
2703
2704                 self.prevorigin = self.origin;
2705
2706                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2707                 {
2708                         if (!self.crouch)
2709                         {
2710                                 self.crouch = TRUE;
2711                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2712                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2713                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2714                         }
2715                 }
2716                 else
2717                 {
2718                         if (self.crouch)
2719                         {
2720                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2721                                 if (!trace_startsolid)
2722                                 {
2723                                         self.crouch = FALSE;
2724                                         self.view_ofs = PL_VIEW_OFS;
2725                                         setsize (self, PL_MIN, PL_MAX);
2726                                 }
2727                         }
2728                 }
2729
2730                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2731                 {
2732                         if(self.bloodloss_timer < time)
2733                         {
2734                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2735                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2736                         }
2737                 }
2738
2739                 FixPlayermodel();
2740
2741                 GrapplingHookFrame();
2742
2743                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2744                 //if(frametime)
2745                 {
2746                         self.items &~= self.items_added;
2747
2748                         W_WeaponFrame();
2749
2750                         self.items_added = 0;
2751                         if(self.items & IT_JETPACK)
2752                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2753                                         self.items_added |= IT_FUEL;
2754
2755                         self.items |= self.items_added;
2756                 }
2757
2758                 player_regen();
2759                 if(frametime)
2760                         player_anim();
2761
2762                 if (g_minstagib)
2763                         minstagib_ammocheck();
2764
2765                 ctf_setstatus();
2766                 nexball_setstatus();
2767
2768                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2769
2770                 //self.angles_y=self.v_angle_y + 90;   // temp
2771         } else if(gameover) {
2772                 if (intermission_running)
2773                         IntermissionThink ();   // otherwise a button could be missed between
2774                 return;
2775         } else if(self.classname == "observer") {
2776                 ObserverThink();
2777         } else if(self.classname == "spectator") {
2778                 SpectatorThink();
2779         }
2780
2781         if(!zoomstate_set)
2782                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2783
2784         float oldspectatee_status;
2785         oldspectatee_status = self.spectatee_status;
2786         if(self.classname == "spectator")
2787                 self.spectatee_status = num_for_edict(self.enemy);
2788         else if(self.classname == "observer")
2789                 self.spectatee_status = num_for_edict(self);
2790         else
2791                 self.spectatee_status = 0;
2792         if(self.spectatee_status != oldspectatee_status)
2793         {
2794                 ClientData_Touch(self);
2795                 if(g_race || g_cts)
2796                         race_InitSpectator();
2797         }
2798
2799         if(self.teamkill_soundtime)
2800         if(time > self.teamkill_soundtime)
2801         {
2802                 self.teamkill_soundtime = 0;
2803
2804                 entity oldpusher, oldself;
2805
2806                 oldself = self; self = self.teamkill_soundsource;
2807                 oldpusher = self.pusher; self.pusher = oldself;
2808
2809                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2810
2811                 self.pusher = oldpusher;
2812                 self = oldself;
2813         }
2814
2815         if(self.taunt_soundtime)
2816         if(time > self.taunt_soundtime)
2817         {
2818                 self.taunt_soundtime = 0;
2819                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2820         }
2821
2822         target_voicescript_next(self);
2823 }
2824
2825 float isInvisibleString(string s)
2826 {
2827         float i, n, c;
2828         s = strdecolorize(s);
2829         for((i = 0), (n = strlen(s)); i < n; ++i)
2830         {
2831                 c = str2chr(s, i);
2832                 switch(c)
2833                 {
2834                         case 0:
2835                         case 32:
2836                         case 160:
2837                                 break;
2838                         default:
2839                                 return FALSE;
2840                 }
2841         }
2842         return TRUE;
2843 }
2844
2845 /*
2846 =============
2847 PlayerPostThink
2848
2849 Called every frame for each client after the physics are run
2850 =============
2851 */
2852 .float idlekick_lasttimeleft;
2853 .entity showheadshotbbox;
2854 void showheadshotbbox_think()
2855 {
2856         if(self.owner.showheadshotbbox != self)
2857         {
2858                 remove(self);
2859                 return;
2860         }
2861         self.nextthink = time;
2862         setorigin(self, self.owner.origin);
2863         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2864 }
2865 void PlayerPostThink (void)
2866 {
2867         // Savage: Check for nameless players
2868         if (isInvisibleString(self.netname)) {
2869                 self.netname = "Player";
2870                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2871         }
2872
2873         // send the clients accuracy stats to the client
2874         if(self.stat_count > 0)
2875         if(frametime)
2876         {
2877                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2878                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2879                 self.stat_count -= 1;
2880         }
2881
2882 #ifdef UID
2883         if(self.uid_kicktime)
2884         if(time > self.uid_kicktime)
2885         {
2886                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2887                 dropclient(self);
2888                 return;
2889         }
2890 #endif
2891
2892         if(sv_maxidle && frametime)
2893         {
2894                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2895                 float timeleft;
2896                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2897                 if(timeleft <= 0)
2898                 {
2899                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2900                         AnnounceTo(self, "terminated");
2901                         dropclient(self);
2902                         return;
2903                 }
2904                 else if(timeleft <= 10)
2905                 {
2906                         if(timeleft != self.idlekick_lasttimeleft)
2907                         {
2908                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2909                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2910                         }
2911                 }
2912                 else
2913                 {
2914                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2915                 }
2916                 self.idlekick_lasttimeleft = timeleft;
2917         }
2918
2919 #ifdef TETRIS
2920         if(self.impulse == 100)
2921                 ImpulseCommands();
2922         if (TetrisPostFrame())
2923                 return;
2924 #endif
2925
2926         CheatFrame();
2927
2928         if(self.classname == "player") {
2929                 CheckRules_Player();
2930                 UpdateChatBubble();
2931                 UpdateTeamBubble();
2932                 if (self.impulse)
2933                         ImpulseCommands();
2934                 if (intermission_running)
2935                         return;         // intermission or finale
2936                 GetPressedKeys();
2937         } else if (self.classname == "observer") {
2938                 //do nothing
2939         } else if (self.classname == "spectator") {
2940                 //do nothing
2941         }
2942
2943         /*
2944         float i;
2945         for(i = 0; i < 1000; ++i)
2946         {
2947                 vector end;
2948                 end = self.origin + '0 0 1024' + 512 * randomvec();
2949                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2950                 if(trace_fraction < 1)
2951                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2952                 {
2953                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2954                         break;
2955                 }
2956         }
2957         */
2958
2959         Arena_Warmup();
2960
2961         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2962
2963         if(self.waypointsprite_attachedforcarrier)
2964                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2965
2966         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
2967         {
2968                 if(!self.showheadshotbbox)
2969                 {
2970                         self.showheadshotbbox = spawn();
2971                         self.showheadshotbbox.classname = "headshotbbox";
2972                         self.showheadshotbbox.owner = self;
2973                         self.showheadshotbbox.think = showheadshotbbox_think;
2974                         self.showheadshotbbox.nextthink = time;
2975                         self = self.showheadshotbbox;
2976                         self.think();
2977                         self = self.owner;
2978                 }
2979         }
2980         else
2981         {
2982                 if(self.showheadshotbbox)
2983                         remove(self.showheadshotbbox);
2984         }
2985
2986         playerdemo_write();
2987
2988         /*
2989         if(g_race)
2990                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2991         */
2992 }