Merge remote-tracking branch 'origin/master' into fruitiex/animations
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
7 }
8
9 void Announce(string snd) {
10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
12         WriteString(MSG_ALL, snd);
13 }
14
15 void AnnounceTo(entity e, string snd) {
16         if (clienttype(e) == CLIENTTYPE_REAL)
17         {
18                 msg_entity = e;
19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
21                 WriteString(MSG_ONE, snd);
22         }
23 }
24
25 float ClientData_Send(entity to, float sf)
26 {
27         if(to != self.owner)
28         {
29                 error("wtf");
30                 return FALSE;
31         }
32
33         entity e;
34
35         e = to;
36         if(to.classname == "spectator")
37                 e = to.enemy;
38
39         sf = 0;
40
41         if(e.race_completed)
42                 sf |= 1; // forced scoreboard
43         if(to.spectatee_status)
44                 sf |= 2; // spectator ent number follows
45         if(e.zoomstate)
46                 sf |= 4; // zoomed
47         if(e.porto_v_angle_held)
48                 sf |= 8; // angles held
49
50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
51         WriteByte(MSG_ENTITY, sf);
52
53         if(sf & 2)
54                 WriteByte(MSG_ENTITY, to.spectatee_status);
55
56         if(sf & 8)
57         {
58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
60         }
61
62         return TRUE;
63 }
64
65 void ClientData_Attach()
66 {
67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
68         self.clientdata.drawonlytoclient = self;
69         self.clientdata.owner = self;
70 }
71
72 void ClientData_Detach()
73 {
74         remove(self.clientdata);
75         self.clientdata = world;
76 }
77
78 void ClientData_Touch(entity e)
79 {
80         e.clientdata.SendFlags = 1;
81
82         // make it spectatable
83         entity e2;
84         FOR_EACH_REALCLIENT(e2)
85         {
86                 if(e2 != e)
87                         if(e2.classname == "spectator")
88                                 if(e2.enemy == e)
89                                         e2.clientdata.SendFlags = 1;
90         }
91 }
92
93
94 .vector spawnpoint_score;
95 .string netname_previous;
96
97 void spawnfunc_info_player_survivor (void)
98 {
99         spawnfunc_info_player_deathmatch();
100 }
101
102 void spawnfunc_info_player_start (void)
103 {
104         spawnfunc_info_player_deathmatch();
105 }
106
107 void spawnfunc_info_player_deathmatch (void)
108 {
109         self.classname = "info_player_deathmatch";
110         relocate_spawnpoint();
111 }
112
113 void spawnpoint_use()
114 {
115         if(teamplay)
116         if(have_team_spawns > 0)
117         {
118                 self.team = activator.team;
119                 some_spawn_has_been_used = 1;
120         }
121 };
122
123 // Returns:
124 //   _x: prio (-1 if unusable)
125 //   _y: weight
126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
127 {
128         float shortest, thisdist;
129         float prio;
130         entity player;
131
132         prio = 0;
133
134         // filter out spots for the wrong team
135         if(teamcheck >= 0)
136                 if(spot.team != teamcheck)
137                         return '-1 0 0';
138
139         if(race_spawns)
140                 if(spot.target == "")
141                         return '-1 0 0';
142
143         if(clienttype(self) == CLIENTTYPE_REAL)
144         {
145                 if(spot.restriction == 1)
146                         return '-1 0 0';
147         }
148         else
149         {
150                 if(spot.restriction == 2)
151                         return '-1 0 0';
152         }
153
154         // filter out spots for assault
155         if(spot.target != "") {
156                 local entity ent;
157                 float good, found;
158                 ent = find(world, targetname, spot.target);
159
160                 while(ent) {
161                         if(ent.classname == "target_objective")
162                         {
163                                 found = 1;
164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
165                                         return '-1 0 0';
166                                 good = 1;
167                         }
168                         else if(ent.classname == "trigger_race_checkpoint")
169                         {
170                                 found = 1;
171                                 if(!anypoint) // spectators may spawn everywhere
172
173                                 {
174                                         if(g_race_qualifying)
175                                         {
176                                                 // spawn at first
177                                                 if(ent.race_checkpoint != 0)
178                                                         return '-1 0 0';
179                                                 if(spot.race_place != race_lowest_place_spawn)
180                                                         return '-1 0 0';
181                                         }
182                                         else
183                                         {
184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
185                                                         return '-1 0 0';
186                                                 // try reusing the previous spawn
187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
188                                                         prio += 1;
189                                                 if(ent.race_checkpoint == 0)
190                                                 {
191                                                         float pl;
192                                                         pl = self.race_place;
193                                                         if(pl > race_highest_place_spawn)
194                                                                 pl = 0;
195                                                         if(pl == 0 && !self.race_started)
196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
197                                                         if(spot.race_place != pl)
198                                                                 return '-1 0 0';
199                                                 }
200                                         }
201                                 }
202                                 good = 1;
203                         }
204                         ent = find(ent, targetname, spot.target);
205                 }
206
207                 if(found && !good)
208                         return '-1 0 0';
209         }
210
211         player = playerlist;
212         shortest = vlen(world.maxs - world.mins);
213         for(player = playerlist; player; player = player.chain)
214                 if (player != self)
215                 {
216                         thisdist = vlen(player.origin - spot.origin);
217                         if (thisdist < shortest)
218                                 shortest = thisdist;
219                 }
220         return prio * '1 0 0' + shortest * '0 1 0';
221 }
222
223 float spawn_allbad;
224 float spawn_allgood;
225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
226 {
227         local entity spot, spotlist, spotlistend;
228         spawn_allgood = TRUE;
229         spawn_allbad = TRUE;
230
231         spotlist = world;
232         spotlistend = world;
233
234         for(spot = firstspot; spot; spot = spot.chain)
235         {
236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
237
238                 if(autocvar_spawn_debugview)
239                 {
240                         setmodel(spot, "models/runematch/rune.mdl");
241                         if(spot.spawnpoint_score_y < mindist)
242                         {
243                                 spot.colormod = '1 0 0';
244                                 spot.scale = 1;
245                         }
246                         else
247                         {
248                                 spot.colormod = '0 1 0';
249                                 spot.scale = spot.spawnpoint_score_y / mindist;
250                         }
251                 }
252
253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
254                 {
255                         if(spot.spawnpoint_score_y < mindist)
256                         {
257                                 // too short distance
258                                 spawn_allgood = FALSE;
259                         }
260                         else
261                         {
262                                 // perfect
263                                 spawn_allbad = FALSE;
264
265                                 if(spotlistend)
266                                         spotlistend.chain = spot;
267                                 spotlistend = spot;
268                                 if(!spotlist)
269                                         spotlist = spot;
270
271                                 /*
272                                 if(teamcheck >= 0)
273                                 if(spot.team != teamcheck)
274                                         error("invalid spawn added");
275
276                                 print("added ", etos(spot), "\n");
277                                 */
278                         }
279                 }
280         }
281         if(spotlistend)
282                 spotlistend.chain = world;
283
284         /*
285                 entity e;
286                 if(teamcheck >= 0)
287                         for(e = spotlist; e; e = e.chain)
288                         {
289                                 print("seen ", etos(e), "\n");
290                                 if(e.team != teamcheck)
291                                         error("invalid spawn found");
292                         }
293         */
294
295         return spotlist;
296 }
297
298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
299 {
300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
302         local entity spot;
303
304         RandomSelection_Init();
305         for(spot = firstspot; spot; spot = spot.chain)
306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
307
308         return RandomSelection_chosen_ent;
309 }
310
311 /*
312 =============
313 SelectSpawnPoint
314
315 Finds a point to respawn
316 =============
317 */
318 entity SelectSpawnPoint (float anypoint)
319 {
320         local float teamcheck;
321         local entity firstspot_new;
322         local entity spot, firstspot, playerlist;
323
324         spot = find (world, classname, "testplayerstart");
325         if (spot)
326                 return spot;
327
328         if(anypoint)
329                 teamcheck = -1;
330         else if(have_team_spawns > 0)
331         {
332                 if(have_team_spawns_forteam[self.team] == 0)
333                 {
334                         // we request a spawn for a team, and we have team
335                         // spawns, but that team has no spawns?
336                         if(have_team_spawns_forteam[0])
337                                 // try noteam spawns
338                                 teamcheck = 0;
339                         else
340                                 // if not, any spawn has to do
341                                 teamcheck = -1;
342                 }
343                 else
344                         teamcheck = self.team; // MUST be team
345         }
346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
347                 teamcheck = 0; // MUST be noteam
348         else
349                 teamcheck = -1;
350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
351
352
353         // get the list of players
354         playerlist = findchain(classname, "player");
355         // get the entire list of spots
356         firstspot = findchain(classname, "info_player_deathmatch");
357         // filter out the bad ones
358         // (note this returns the original list if none survived)
359         if(anypoint)
360         {
361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
362         }
363         else
364         {
365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
366                 if(!firstspot_new)
367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
368                 firstspot = firstspot_new;
369
370                 // there is 50/50 chance of choosing a random spot or the furthest spot
371                 // (this means that roughly every other spawn will be furthest, so you
372                 // usually won't get fragged at spawn twice in a row)
373                 if (arena_roundbased && !g_ca)
374                 {
375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
376                         if(firstspot_new)
377                                 firstspot = firstspot_new;
378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
379                 }
380                 else if (random() > autocvar_g_spawn_furthest)
381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
382                 else
383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
384         }
385
386         if(autocvar_spawn_debugview)
387         {
388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
389
390                 entity e;
391                 if(teamcheck >= 0)
392                         for(e = firstspot; e; e = e.chain)
393                                 if(e.team != teamcheck)
394                                         error("invalid spawn found");
395         }
396
397         if (!spot)
398         {
399                 if(autocvar_spawn_debug)
400                         GotoNextMap();
401                 else
402                 {
403                         if(some_spawn_has_been_used)
404                                 return world; // team can't spawn any more, because of actions of other team
405                         else
406                                 error("Cannot find a spawn point - please fix the map!");
407                 }
408         }
409
410         return spot;
411 }
412
413 /*
414 =============
415 CheckPlayerModel
416
417 Checks if the argument string can be a valid playermodel.
418 Returns a valid one in doubt.
419 =============
420 */
421 string FallbackPlayerModel;
422 string CheckPlayerModel(string plyermodel) {
423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
424         {
425                 // note: we cannot summon Don Strunzone here, some player may
426                 // still have the model string set. In case anyone manages how
427                 // to change a cvar default, we'll have a small leak here.
428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
429         }
430         if(strlen(plyermodel) < 4)
431                 return FallbackPlayerModel;
432         if( substring(plyermodel,0,14) != "models/player/")
433                 return FallbackPlayerModel;
434         else if(autocvar_sv_servermodelsonly)
435         {
436                 if(substring(plyermodel,-4,4) != ".zym")
437                 if(substring(plyermodel,-4,4) != ".dpm")
438                 if(substring(plyermodel,-4,4) != ".iqm")
439                 if(substring(plyermodel,-4,4) != ".md3")
440                 if(substring(plyermodel,-4,4) != ".psk")
441                         return FallbackPlayerModel;
442                 // forbid the LOD models
443                 if(substring(plyermodel, -9,5) == "_lod1")
444                         return FallbackPlayerModel;
445                 if(substring(plyermodel, -9,5) == "_lod2")
446                         return FallbackPlayerModel;
447                 if(plyermodel != strtolower(plyermodel))
448                         return FallbackPlayerModel;
449                 if(!fexists(plyermodel))
450                         return FallbackPlayerModel;
451         }
452         return plyermodel;
453 }
454
455 /*
456 =============
457 Client_customizeentityforclient
458
459 LOD reduction
460 =============
461 */
462 void Client_uncustomizeentityforclient()
463 {
464         if(self.modelindex == 0) // no need to uncustomize then
465                 return;
466         self.modelindex = self.modelindex_lod0;
467         self.skin = self.skinindex;
468 }
469
470 float Client_customizeentityforclient()
471 {
472         entity modelsource;
473
474         if(self.modelindex == 0)
475                 return TRUE;
476
477         // forcemodel stuff
478
479 #ifdef PROFILING
480         float t0;
481         t0 = gettime(GETTIME_HIRES); // reference
482 #endif
483
484         modelsource = self;
485
486 #ifdef ALLOW_FORCEMODELS
487         if(other.cvar_cl_forceplayermodelsfromxonotic)
488                 if not(self.modelindex_lod0_from_xonotic)
489                         modelsource = other;
490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
491                 modelsource = other;
492 #endif
493
494         self.skin = modelsource.skinindex;
495
496 #if 0
497         if(modelsource == self)
498                 self.skin = modelsource.skinindex;
499         else
500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
501 #endif
502
503         // self: me
504         // other: the player viewing me
505         float distance;
506         float f;
507
508         if(other.cvar_cl_playerdetailreduction <= 0)
509         {
510                 if(other.cvar_cl_playerdetailreduction <= -2)
511                         self.modelindex = modelsource.modelindex_lod2;
512                 else if(other.cvar_cl_playerdetailreduction <= -1)
513                         self.modelindex = modelsource.modelindex_lod1;
514                 else
515                         self.modelindex = modelsource.modelindex_lod0;
516         }
517         else
518         {
519                 distance = vlen(self.origin - other.origin);
520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
521                 if(f > sv_loddistance2)
522                         self.modelindex = modelsource.modelindex_lod2;
523                 else if(f > sv_loddistance1)
524                         self.modelindex = modelsource.modelindex_lod1;
525                 else
526                         self.modelindex = modelsource.modelindex_lod0;
527         }
528
529 #ifdef PROFILING
530         float t1;
531         t1 = gettime(GETTIME_HIRES); // reference
532         client_cefc_accumulator += (t1 - t0);
533 #endif
534
535         return TRUE;
536 }
537
538 void setmodel_lod(entity e, string modelname)
539 {
540         string s;
541
542         if(sv_loddistance1)
543         {
544                 // FIXME: this only supports 3-letter extensions
545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
546                 if(fexists(s))
547                 {
548                         setmodel(e, s); // players have high precision
549                         self.modelindex_lod1 = self.modelindex;
550                 }
551                 else
552                         self.modelindex_lod1 = -1;
553
554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
555                 if(fexists(s))
556                 {
557                         setmodel(e, s); // players have high precision
558                         self.modelindex_lod2 = self.modelindex;
559                 }
560                 else
561                         self.modelindex_lod2 = -1;
562
563                 precache_model(modelname);
564                 setmodel(e, modelname); // players have high precision
565                 self.modelindex_lod0 = self.modelindex;
566
567                 if(self.modelindex_lod1 < 0)
568                         self.modelindex_lod1 = self.modelindex;
569
570                 if(self.modelindex_lod2 < 0)
571                         self.modelindex_lod2 = self.modelindex;
572         }
573         else
574         {
575                 precache_model(modelname);
576                 setmodel(e, modelname); // players have high precision
577                 self.modelindex_lod0 = self.modelindex;
578                         // save it for possible player model forcing
579         }
580
581         s = whichpack(self.model);
582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
583
584         player_setupanimsformodel();
585         UpdatePlayerSounds();
586 }
587
588 /*
589 =============
590 PutObserverInServer
591
592 putting a client as observer in the server
593 =============
594 */
595 void FixPlayermodel();
596 void PutObserverInServer (void)
597 {
598         entity  spot;
599     self.hud = HUD_NORMAL;
600         race_PreSpawnObserver();
601
602         spot = SelectSpawnPoint (TRUE);
603         if(!spot)
604                 error("No spawnpoints for observers?!?\n");
605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
606
607         if(clienttype(self) == CLIENTTYPE_REAL)
608         {
609                 msg_entity = self;
610                 WriteByte(MSG_ONE, SVC_SETVIEW);
611                 WriteEntity(MSG_ONE, self);
612         }
613
614         DropAllRunes(self);
615         MUTATOR_CALLHOOK(MakePlayerObserver);
616
617         if (g_minstagib)
618                 minstagib_stop_countdown();
619
620         Portal_ClearAll(self);
621
622         if(self.alivetime)
623         {
624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
625                 self.alivetime = 0;
626         }
627
628         if(self.vehicle)
629             vehicles_exit(VHEF_RELESE);
630
631         if(self.flagcarried)
632                 DropFlag(self.flagcarried, world, world);
633
634         if(self.ballcarried && g_nexball)
635                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
636
637         WaypointSprite_PlayerDead();
638
639         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
640                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
641
642         if(self.killcount != -666) {
643                 if(g_lms) {
644                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
645                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
646                         else
647                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
648                 } else
649                         bprint ("^4", self.netname, "^4 is spectating now\n");
650
651                 if(self.just_joined == FALSE) {
652                         LogTeamchange(self.playerid, -1, 4);
653                 } else
654                         self.just_joined = FALSE;
655         }
656
657         PlayerScore_Clear(self); // clear scores when needed
658
659         accuracy_resend(self);
660
661         self.spectatortime = time;
662         
663         self.classname = "observer";
664         self.iscreature = FALSE;
665         self.health = -666;
666         self.takedamage = DAMAGE_NO;
667         self.solid = SOLID_NOT;
668         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
669         self.flags = FL_CLIENT | FL_NOTARGET;
670         self.armorvalue = 666;
671         self.effects = 0;
672         self.armorvalue = autocvar_g_balance_armor_start;
673         self.pauserotarmor_finished = 0;
674         self.pauserothealth_finished = 0;
675         self.pauseregen_finished = 0;
676         self.damageforcescale = 0;
677         self.death_time = 0;
678         self.dead_frame = 0;
679         self.alpha = 0;
680         self.scale = 0;
681         self.fade_time = 0;
682         self.pain_frame = 0;
683         self.pain_finished = 0;
684         self.strength_finished = 0;
685         self.invincible_finished = 0;
686         self.pushltime = 0;
687         self.think = SUB_Null;
688         self.nextthink = 0;
689         self.hook_time = 0;
690         self.runes = 0;
691         self.deadflag = DEAD_NO;
692         self.angles = spot.angles;
693         self.angles_z = 0;
694         self.fixangle = TRUE;
695         self.crouch = FALSE;
696
697         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
698         setorigin (self, spot.origin);
699         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
700         self.prevorigin = self.origin;
701         self.items = 0;
702         self.weapons = 0;
703         self.model = "";
704         FixPlayermodel();
705         self.model = "";
706         self.modelindex = 0;
707         self.weapon = 0;
708         self.weaponname = "";
709         self.switchingweapon = 0;
710         self.weaponmodel = "";
711         self.weaponentity = world;
712         self.exteriorweaponentity = world;
713         self.killcount = -666;
714         self.velocity = '0 0 0';
715         self.avelocity = '0 0 0';
716         self.punchangle = '0 0 0';
717         self.punchvector = '0 0 0';
718         self.oldvelocity = self.velocity;
719         self.fire_endtime = -1;
720
721         if(sv_loddistance1)
722                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
723
724         if(g_arena)
725         {
726                 if(self.version_mismatch)
727                 {
728                         Spawnqueue_Unmark(self);
729                         Spawnqueue_Remove(self);
730                 }
731                 else
732                 {
733                         Spawnqueue_Insert(self);
734                 }
735         }
736         else if(g_lms)
737         {
738                 // Only if the player cannot play at all
739                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
740                         self.frags = FRAGS_SPECTATOR;
741                 else
742                         self.frags = FRAGS_LMS_LOSER;
743         }
744         else if(g_ca)
745         {
746                 if(self.caplayer)
747                         self.frags = FRAGS_LMS_LOSER;
748                 else
749                         self.frags = FRAGS_SPECTATOR;
750         }
751         else
752                 self.frags = FRAGS_SPECTATOR;
753 }
754
755 void FixPlayermodel()
756 {
757         local string defaultmodel;
758         local float defaultskin, chmdl, oldskin;
759         local vector m1, m2;
760
761         defaultmodel = "";
762
763         if(autocvar_sv_defaultcharacter == 1) {
764                 defaultskin = 0;
765
766                 if(teamplay)
767                 {
768                         string s;
769                         s = Team_ColorNameLowerCase(self.team);
770                         if(s != "neutral")
771                         {
772                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
773                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
774                         }
775                 }
776
777                 if(defaultmodel == "")
778                 {
779                         defaultmodel = autocvar_sv_defaultplayermodel;
780                         defaultskin = autocvar_sv_defaultplayerskin;
781                 }
782         }
783
784         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
785         {
786                 if(self.model != "")
787                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
788                 self.model = ""; // force the != checks to return true
789         }
790
791         if(defaultmodel != "")
792         {
793                 if (defaultmodel != self.model)
794                 {
795                         m1 = self.mins;
796                         m2 = self.maxs;
797                         setmodel_lod (self, defaultmodel);
798                         setsize (self, m1, m2);
799                         chmdl = TRUE;
800                 }
801
802                 oldskin = self.skinindex;
803                 self.skinindex = defaultskin;
804         } else {
805                 if (self.playermodel != self.model || self.playermodel == "")
806                 {
807                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
808                         m1 = self.mins;
809                         m2 = self.maxs;
810                         setmodel_lod (self, self.playermodel);
811                         setsize (self, m1, m2);
812                         chmdl = TRUE;
813                 }
814
815                 oldskin = self.skinindex;
816                 self.skinindex = stof(self.playerskin);
817         }
818
819         if(chmdl || oldskin != self.skinindex)
820                 self.species = player_getspecies(); // model or skin has changed
821
822         if(!teamplay)
823                 if(strlen(autocvar_sv_defaultplayercolors))
824                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
825                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
826 }
827
828 void PlayerTouchExplode(entity p1, entity p2)
829 {
830         vector org;
831         org = (p1.origin + p2.origin) * 0.5;
832         org_z += (p1.mins_z + p2.mins_z) * 0.5;
833
834         te_explosion(org);
835
836         entity e;
837         e = spawn();
838         setorigin(e, org);
839         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
840         remove(e);
841 }
842
843 /*
844 =============
845 PutClientInServer
846
847 Called when a client spawns in the server
848 =============
849 */
850 //void() ctf_playerchanged;
851 void PutClientInServer (void)
852 {
853         if(clienttype(self) == CLIENTTYPE_BOT)
854         {
855                 self.classname = "player";
856         }
857         else if(clienttype(self) == CLIENTTYPE_REAL)
858         {
859                 msg_entity = self;
860                 WriteByte(MSG_ONE, SVC_SETVIEW);
861                 WriteEntity(MSG_ONE, self);
862         }
863
864         // player is dead and becomes observer
865         // FIXME fix LMS scoring for new system
866         if(g_lms)
867         {
868                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
869                         self.classname = "observer";
870         }
871
872         if(g_arena || (g_ca && !allowed_to_spawn))
873         if(!self.spawned)
874                 self.classname = "observer";
875
876         if(gameover)
877                 self.classname = "observer";
878
879         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
880                 entity spot, oldself;
881                 float j;
882
883                 accuracy_resend(self);
884
885                 if(self.team < 0)
886                         JoinBestTeam(self, FALSE, TRUE);
887
888                 race_PreSpawn();
889
890                 spot = SelectSpawnPoint (FALSE);
891                 if(!spot)
892                 {
893                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
894                         return; // spawn failed
895                 }
896
897                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
898
899                 self.classname = "player";
900                 self.wasplayer = TRUE;
901                 self.iscreature = TRUE;
902                 self.movetype = MOVETYPE_WALK;
903                 self.solid = SOLID_SLIDEBOX;
904                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
905                 if(autocvar_g_playerclip_collisions)
906                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
907                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
908                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
909                 self.frags = FRAGS_PLAYER;
910                 if(INDEPENDENT_PLAYERS)
911                         MAKE_INDEPENDENT_PLAYER(self);
912                 self.flags = FL_CLIENT;
913                 self.takedamage = DAMAGE_AIM;
914                 if(g_minstagib)
915                         self.effects = EF_FULLBRIGHT;
916                 else
917                         self.effects = 0;
918                 self.air_finished = time + 12;
919                 self.dmg = 2;
920                 if(autocvar_g_balance_nex_charge)
921                 {
922                         if(autocvar_g_balance_nex_secondary_chargepool)
923                                 self.nex_chargepool_ammo = 1;
924                         self.nex_charge = autocvar_g_balance_nex_charge_start;
925                 }
926
927                 if(inWarmupStage)
928                 {
929                         self.ammo_shells = warmup_start_ammo_shells;
930                         self.ammo_nails = warmup_start_ammo_nails;
931                         self.ammo_rockets = warmup_start_ammo_rockets;
932                         self.ammo_cells = warmup_start_ammo_cells;
933                         self.ammo_fuel = warmup_start_ammo_fuel;
934                         self.health = warmup_start_health;
935                         self.armorvalue = warmup_start_armorvalue;
936                         self.weapons = warmup_start_weapons;
937                 }
938                 else
939                 {
940                         self.ammo_shells = start_ammo_shells;
941                         self.ammo_nails = start_ammo_nails;
942                         self.ammo_rockets = start_ammo_rockets;
943                         self.ammo_cells = start_ammo_cells;
944                         self.ammo_fuel = start_ammo_fuel;
945                         self.health = start_health;
946                         self.armorvalue = start_armorvalue;
947                         self.weapons = start_weapons;
948                 }
949
950                 if(g_weaponarena_random)
951                 {
952                         if(g_weaponarena_random_with_laser)
953                                 self.weapons &~= WEPBIT_LASER;
954                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
955                         if(g_weaponarena_random_with_laser)
956                                 self.weapons |= WEPBIT_LASER;
957                 }
958
959                 self.items = start_items;
960                 self.jump_interval = time;
961
962                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
963                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
964                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
965                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
966                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
967                 //extend the pause of rotting if client was reset at the beginning of the countdown
968                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
969                         self.spawnshieldtime += game_starttime - time;
970                         self.pauserotarmor_finished += game_starttime - time;
971                         self.pauserothealth_finished += game_starttime - time;
972                         self.pauseregen_finished += game_starttime - time;
973                 }
974                 self.damageforcescale = 2;
975                 self.death_time = 0;
976                 self.dead_frame = 0;
977                 self.alpha = 0;
978                 self.scale = 0;
979                 self.fade_time = 0;
980                 self.pain_frame = 0;
981                 self.pain_finished = 0;
982                 self.strength_finished = 0;
983                 self.invincible_finished = 0;
984                 self.pushltime = 0;
985                 // players have no think function
986                 self.think = SUB_Null;
987                 self.nextthink = 0;
988                 self.hook_time = 0;
989                 self.dmg_team = 0;
990                 self.ballistics_density = autocvar_g_ballistics_density_player;
991
992                 self.metertime = 0;
993
994                 self.runes = 0;
995
996                 self.deadflag = DEAD_NO;
997
998                 self.angles = spot.angles;
999
1000                 self.angles_z = 0; // never spawn tilted even if the spot says to
1001                 self.fixangle = TRUE; // turn this way immediately
1002                 self.velocity = '0 0 0';
1003                 self.avelocity = '0 0 0';
1004                 self.punchangle = '0 0 0';
1005                 self.punchvector = '0 0 0';
1006                 self.oldvelocity = self.velocity;
1007                 self.fire_endtime = -1;
1008
1009                 msg_entity = self;
1010                 WRITESPECTATABLE_MSG_ONE({
1011                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1012                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1013                 });
1014
1015                 if(sv_loddistance1)
1016                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1017
1018                 self.model = "";
1019                 FixPlayermodel();
1020
1021                 self.crouch = FALSE;
1022                 self.view_ofs = PL_VIEW_OFS;
1023                 setsize (self, PL_MIN, PL_MAX);
1024                 self.spawnorigin = spot.origin;
1025                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1026                 // don't reset back to last position, even if new position is stuck in solid
1027                 self.oldorigin = self.origin;
1028                 self.prevorigin = self.origin;
1029                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1030                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1031
1032                 if(g_arena)
1033                 {
1034                         Spawnqueue_Remove(self);
1035                         Spawnqueue_Mark(self);
1036                 }
1037
1038                 else if(g_ca)
1039                         self.caplayer = 1;
1040
1041                 self.event_damage = PlayerDamage;
1042
1043                 self.bot_attack = TRUE;
1044
1045                 self.statdraintime = time + 5;
1046                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1047
1048                 if(self.killcount == -666) {
1049                         PlayerScore_Clear(self);
1050                         self.killcount = 0;
1051                 }
1052
1053                 CL_SpawnWeaponentity();
1054                 self.alpha = default_player_alpha;
1055                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1056                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1057
1058                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1059                 self.lms_traveled_distance = 0;
1060                 self.speedrunning = FALSE;
1061
1062                 race_PostSpawn(spot);
1063
1064                 if(autocvar_spawn_debug)
1065                 {
1066                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1067                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1068                 }
1069
1070                 //stuffcmd(self, "chase_active 0");
1071                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1072
1073                 if (autocvar_g_spawnsound)
1074                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1075
1076                 if(g_assault) {
1077                         if(self.team == assault_attacker_team)
1078                                 centerprint(self, "You are attacking!");
1079                         else
1080                                 centerprint(self, "You are defending!");
1081                 }
1082
1083                 target_voicescript_clear(self);
1084
1085                 // reset fields the weapons may use
1086                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1087                 {
1088                         weapon_action(j, WR_RESETPLAYER);
1089
1090                         // all weapons must be fully loaded when we spawn
1091                         entity e;
1092                         e = get_weaponinfo(j);
1093                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1094                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1095                 }
1096
1097                 oldself = self;
1098                 self = spot;
1099                         activator = oldself;
1100                                 string s;
1101                                 s = self.target;
1102                                 self.target = string_null;
1103                                 SUB_UseTargets();
1104                                 self.target = s;
1105                         activator = world;
1106                 self = oldself;
1107
1108                 MUTATOR_CALLHOOK(PlayerSpawn);
1109
1110                 self.switchweapon = w_getbestweapon(self);
1111                 self.cnt = -1; // W_LastWeapon will not complain
1112                 self.weapon = 0;
1113                 self.weaponname = "";
1114                 self.switchingweapon = 0;
1115
1116                 if(!self.alivetime)
1117                         self.alivetime = time;
1118         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1119                 PutObserverInServer ();
1120         }
1121
1122         //if(g_ctf)
1123         //      ctf_playerchanged();
1124 }
1125
1126 .float ebouncefactor, ebouncestop; // electro's values
1127 // TODO do we need all these fields, or should we stop autodetecting runtime
1128 // changes and just have a console command to update this?
1129 float ClientInit_SendEntity(entity to, float sf)
1130 {
1131         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1132         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1133         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1134         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1135         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1136         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1137         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1138         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1139         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1140         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1141         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1142         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1143         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1144         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1145         if(sv_foginterval && world.fog != "")
1146                 WriteString(MSG_ENTITY, world.fog);
1147         else
1148                 WriteString(MSG_ENTITY, "");
1149         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1150         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1151         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1152         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1153         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1154         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1155         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1156         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1157         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1158         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1159         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1160         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1161         return TRUE;
1162 }
1163
1164 void ClientInit_CheckUpdate()
1165 {
1166         self.nextthink = time;
1167         if(self.count != autocvar_g_balance_armor_blockpercent)
1168         {
1169                 self.count = autocvar_g_balance_armor_blockpercent;
1170                 self.SendFlags |= 1;
1171         }
1172         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1173         {
1174                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1175                 self.SendFlags |= 1;
1176         }
1177         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1178         {
1179                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1180                 self.SendFlags |= 1;
1181         }
1182         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1183         {
1184                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1185                 self.SendFlags |= 1;
1186         }
1187         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1188         {
1189                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1190                 self.SendFlags |= 1;
1191         }
1192         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1193         {
1194                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1195                 self.SendFlags |= 1;
1196         }
1197 }
1198
1199 void ClientInit_Spawn()
1200 {
1201         entity o;
1202         entity e;
1203         e = spawn();
1204         e.classname = "clientinit";
1205         e.think = ClientInit_CheckUpdate;
1206         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1207
1208         o = self;
1209         self = e;
1210         ClientInit_CheckUpdate();
1211         self = o;
1212 }
1213
1214 /*
1215 =============
1216 SetNewParms
1217 =============
1218 */
1219 void SetNewParms (void)
1220 {
1221         // initialize parms for a new player
1222         parm1 = -(86400 * 366);
1223 }
1224
1225 /*
1226 =============
1227 SetChangeParms
1228 =============
1229 */
1230 void SetChangeParms (void)
1231 {
1232         // save parms for level change
1233         parm1 = self.parm_idlesince - time;
1234 }
1235
1236 /*
1237 =============
1238 DecodeLevelParms
1239 =============
1240 */
1241 void DecodeLevelParms (void)
1242 {
1243         // load parms
1244         self.parm_idlesince = parm1;
1245         if(self.parm_idlesince == -(86400 * 366))
1246                 self.parm_idlesince = time;
1247
1248         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1249         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1250 }
1251
1252 /*
1253 =============
1254 ClientKill
1255
1256 Called when a client types 'kill' in the console
1257 =============
1258 */
1259
1260 .float clientkill_nexttime;
1261 void ClientKill_Now_TeamChange()
1262 {
1263         if(self.killindicator_teamchange == -1)
1264         {
1265                 self.team = -1;
1266                 JoinBestTeam( self, FALSE, FALSE );
1267         }
1268         else if(self.killindicator_teamchange == -2)
1269         {
1270                 if(g_ca)
1271                         self.caplayer = 0;
1272                 if(blockSpectators)
1273                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1274                 PutObserverInServer();
1275         }
1276         else
1277                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1278 }
1279
1280 void ClientKill_Now()
1281 {
1282         if(self.vehicle)
1283         {
1284             vehicles_exit(VHEF_RELESE);
1285             if(!self.killindicator_teamchange)
1286             {
1287             self.vehicle_health = -1;
1288             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');             
1289             }
1290         }
1291
1292         if(self.killindicator && !wasfreed(self.killindicator))
1293                 remove(self.killindicator);
1294
1295         self.killindicator = world;
1296
1297         if(self.killindicator_teamchange)
1298                 ClientKill_Now_TeamChange();
1299
1300         // in any case:
1301         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1302
1303         // now I am sure the player IS dead
1304 }
1305 void KillIndicator_Think()
1306 {
1307         if (gameover)
1308         {
1309                 self.owner.killindicator = world;
1310                 remove(self);
1311                 return;
1312         }
1313
1314         if (!self.owner.modelindex)
1315         {
1316                 self.owner.killindicator = world;
1317                 remove(self);
1318                 return;
1319         }
1320
1321         if(self.cnt <= 0)
1322         {
1323                 self = self.owner;
1324                 ClientKill_Now(); // no oldself needed
1325                 return;
1326         }
1327     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1328     {
1329         self.nextthink = time + 1;
1330         self.cnt -= 1;
1331     }
1332         else
1333         {
1334                 if(self.cnt <= 10)
1335                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1336                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1337                 {
1338                         if(self.cnt <= 10)
1339                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1340                 }
1341                 self.nextthink = time + 1;
1342                 self.cnt -= 1;
1343         }
1344 }
1345
1346 float clientkilltime;
1347 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1348 {
1349         float killtime;
1350         float starttime;
1351         entity e;
1352
1353         if (gameover)
1354                 return;
1355
1356         killtime = autocvar_g_balance_kill_delay;
1357
1358         if(g_race_qualifying || g_cts)
1359                 killtime = 0;
1360
1361     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1362     {
1363                 remove(self.killindicator);
1364                 self.killindicator = world;
1365
1366         ClientKill_Now(); // allow instant kill in this case
1367         return;
1368     }
1369
1370         self.killindicator_teamchange = targetteam;
1371
1372     if(!self.killindicator)
1373         {
1374                 if(self.modelindex && self.deadflag == DEAD_NO)
1375                 {
1376                         killtime = max(killtime, self.clientkill_nexttime - time);
1377                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1378                 }
1379
1380                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1381                 {
1382                         ClientKill_Now();
1383                 }
1384                 else
1385                 {
1386                         starttime = max(time, clientkilltime);
1387
1388                         self.killindicator = spawn();
1389                         self.killindicator.owner = self;
1390                         self.killindicator.scale = 0.5;
1391                         setattachment(self.killindicator, self, "");
1392                         setorigin(self.killindicator, '0 0 52');
1393                         self.killindicator.think = KillIndicator_Think;
1394                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1395                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1396                         self.killindicator.cnt = ceil(killtime);
1397                         self.killindicator.count = bound(0, ceil(killtime), 10);
1398                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1399
1400                         for(e = world; (e = find(e, classname, "body")) != world; )
1401                         {
1402                                 if(e.enemy != self)
1403                                         continue;
1404                                 e.killindicator = spawn();
1405                                 e.killindicator.owner = e;
1406                                 e.killindicator.scale = 0.5;
1407                                 setattachment(e.killindicator, e, "");
1408                                 setorigin(e.killindicator, '0 0 52');
1409                                 e.killindicator.think = KillIndicator_Think;
1410                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1411                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1412                                 e.killindicator.cnt = ceil(killtime);
1413                         }
1414                         self.lip = 0;
1415                 }
1416         }
1417         if(self.killindicator)
1418         {
1419                 if(targetteam == 0) // just die
1420                 {
1421                         self.killindicator.colormod = '0 0 0';
1422                         if(clienttype(self) == CLIENTTYPE_REAL)
1423                         if(self.killindicator.cnt > 0)
1424                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1425                 }
1426                 else if(targetteam == -1) // auto
1427                 {
1428                         self.killindicator.colormod = '0 1 0';
1429                         if(clienttype(self) == CLIENTTYPE_REAL)
1430                         if(self.killindicator.cnt > 0)
1431                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1432                 }
1433                 else if(targetteam == -2) // spectate
1434                 {
1435                         self.killindicator.colormod = '0.5 0.5 0.5';
1436                         if(clienttype(self) == CLIENTTYPE_REAL)
1437                         if(self.killindicator.cnt > 0)
1438                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1439                 }
1440                 else
1441                 {
1442                         self.killindicator.colormod = TeamColor(targetteam);
1443                         if(clienttype(self) == CLIENTTYPE_REAL)
1444                         if(self.killindicator.cnt > 0)
1445                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1446                 }
1447         }
1448
1449 }
1450
1451 void ClientKill (void)
1452 {
1453         if (gameover)
1454                 return;
1455
1456         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1457         {
1458                 // do nothing
1459         }
1460     else if(self.freezetag_frozen)
1461     {
1462         // do nothing
1463     }
1464         else
1465                 ClientKill_TeamChange(0);
1466 }
1467
1468 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1469 {
1470     e.killindicator = spawn();
1471     e.killindicator.owner = e;
1472     e.killindicator.think = KillIndicator_Think;
1473     e.killindicator.nextthink = time + (e.lip) * 0.05;
1474     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1475     e.killindicator.health = 1; // this is used to indicate that it should be silent
1476     e.lip = 0;
1477 }
1478
1479 void FixClientCvars(entity e)
1480 {
1481         // send prediction settings to the client
1482         stuffcmd(e, "\nin_bindmap 0 0\n");
1483         if(g_race || g_cts)
1484                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1485         if(autocvar_g_antilag == 3) // client side hitscan
1486                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1487         if(sv_gentle)
1488                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1489         /*
1490          * we no longer need to stuff this. Remove this comment block if you feel
1491          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1492         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1493         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1494         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1495         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1496         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1497         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1498         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1499         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1500         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1501         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1502         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1503         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1504         stuffcmd(e, "cl_movement_edgefriction 1\n");
1505          */
1506 }
1507
1508 float PlayerInIDList(entity p, string idlist)
1509 {
1510         float n, i;
1511         string s;
1512
1513         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1514         if not(p.crypto_idfp)
1515                 return 0;
1516
1517         // this function allows abbreviated player IDs too!
1518         n = tokenize_console(idlist);
1519         for(i = 0; i < n; ++i)
1520         {
1521                 s = argv(i);
1522                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1523                         return 1;
1524         }
1525
1526         return 0;
1527 }
1528
1529 /*
1530 =============
1531 ClientConnect
1532
1533 Called when a client connects to the server
1534 =============
1535 */
1536 //void ctf_clientconnect();
1537 string ColoredTeamName(float t);
1538 void DecodeLevelParms (void);
1539 //void dom_player_join_team(entity pl);
1540 void set_dom_state(entity e);
1541 void ClientConnect (void)
1542 {
1543         float t;
1544
1545         if(self.flags & FL_CLIENT)
1546         {
1547                 print("Warning: ClientConnect, but already connected!\n");
1548                 return;
1549         }
1550
1551         if(Ban_MaybeEnforceBan(self))
1552                 return;
1553
1554         DecodeLevelParms();
1555
1556 #ifdef WATERMARK
1557         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1558 #endif
1559
1560         self.classname = "player_joining";
1561
1562         self.flags = FL_CLIENT;
1563         self.version_nagtime = time + 10 + random() * 10;
1564
1565         if(player_count<0)
1566         {
1567                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1568                 player_count = 0;
1569         }
1570
1571         PlayerScore_Attach(self);
1572         ClientData_Attach();
1573         accuracy_init(self);
1574
1575         bot_clientconnect();
1576
1577         playerdemo_init();
1578
1579         anticheat_init();
1580
1581         race_PreSpawnObserver();
1582
1583         //if(g_domination)
1584         //      dom_player_join_team(self);
1585
1586         // identify the right forced team
1587         if(autocvar_g_campaign)
1588         {
1589                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1590                 {
1591                         switch(autocvar_g_campaign_forceteam)
1592                         {
1593                                 case 1: self.team_forced = COLOR_TEAM1; break;
1594                                 case 2: self.team_forced = COLOR_TEAM2; break;
1595                                 case 3: self.team_forced = COLOR_TEAM3; break;
1596                                 case 4: self.team_forced = COLOR_TEAM4; break;
1597                                 default: self.team_forced = 0;
1598                         }
1599                 }
1600         }
1601         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1602                 self.team_forced = COLOR_TEAM1;
1603         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1604                 self.team_forced = COLOR_TEAM2;
1605         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1606                 self.team_forced = COLOR_TEAM3;
1607         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1608                 self.team_forced = COLOR_TEAM4;
1609         else if(autocvar_g_forced_team_otherwise == "red")
1610                 self.team_forced = COLOR_TEAM1;
1611         else if(autocvar_g_forced_team_otherwise == "blue")
1612                 self.team_forced = COLOR_TEAM2;
1613         else if(autocvar_g_forced_team_otherwise == "yellow")
1614                 self.team_forced = COLOR_TEAM3;
1615         else if(autocvar_g_forced_team_otherwise == "pink")
1616                 self.team_forced = COLOR_TEAM4;
1617         else if(autocvar_g_forced_team_otherwise == "spectate")
1618                 self.team_forced = -1;
1619         else if(autocvar_g_forced_team_otherwise == "spectator")
1620                 self.team_forced = -1;
1621         else
1622                 self.team_forced = 0;
1623
1624         if(!teamplay)
1625                 if(self.team_forced > 0)
1626                         self.team_forced = 0;
1627
1628         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1629
1630         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1631                 self.classname = "observer";
1632         } else {
1633                 if(teamplay)
1634                 {
1635                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1636                         {
1637                                 self.classname = "player";
1638                                 campaign_bots_may_start = 1;
1639                         }
1640                         else
1641                         {
1642                                 self.classname = "observer"; // do it anyway
1643                         }
1644                 }
1645                 else
1646                 {
1647                         self.classname = "player";
1648                         campaign_bots_may_start = 1;
1649                 }
1650         }
1651
1652         self.playerid = (playerid_last = playerid_last + 1);
1653
1654         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1655
1656     if(clienttype(self) == CLIENTTYPE_BOT)
1657         PlayerStats_AddPlayer(self);
1658
1659         if(autocvar_sv_eventlog)
1660                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1661
1662         LogTeamchange(self.playerid, self.team, 1);
1663
1664         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1665
1666         self.netname_previous = strzone(self.netname);
1667
1668         bprint("^4", self.netname, "^4 connected");
1669
1670         if(self.classname != "observer" && (g_domination || g_ctf))
1671                 bprint(" and joined the ", ColoredTeamName(self.team));
1672
1673         bprint("\n");
1674
1675         stuffcmd(self, strcat(clientstuff, "\n"));
1676         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1677
1678         FixClientCvars(self);
1679
1680         // spawnfunc_waypoint sprites
1681         WaypointSprite_InitClient(self);
1682
1683         // Wazat's grappling hook
1684         SetGrappleHookBindings();
1685
1686         // get autoswitch state from player when he toggles it
1687         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1688
1689         // get version info from player
1690         stuffcmd(self, "cmd clientversion $gameversion\n");
1691
1692         // get other cvars from player
1693         GetCvars(0);
1694
1695         // notify about available teams
1696         if(teamplay)
1697         {
1698                 CheckAllowedTeams(self);
1699                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1700                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1701         }
1702         else
1703                 stuffcmd(self, "set _teams_available 0\n");
1704
1705         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1706
1707         if(g_arena || g_ca)
1708         {
1709                 self.classname = "observer";
1710                 if(g_arena)
1711                         Spawnqueue_Insert(self);
1712         }
1713         /*else if(g_ctf)
1714         {
1715                 ctf_clientconnect();
1716         }*/
1717
1718         attach_entcs();
1719
1720         bot_relinkplayerlist();
1721
1722         self.spectatortime = time;
1723         if(blockSpectators)
1724         {
1725                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1726         }
1727
1728         self.jointime = time;
1729         self.allowedTimeouts = autocvar_sv_timeout_number;
1730
1731         if(clienttype(self) == CLIENTTYPE_REAL)
1732         {
1733                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1734                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1735         }
1736
1737         if(g_lms)
1738         {
1739                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1740                 {
1741                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1742                         self.frags = FRAGS_SPECTATOR;
1743                 }
1744         }
1745
1746         if(!sv_foginterval && world.fog != "")
1747                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1748
1749         SoundEntity_Attach(self);
1750
1751         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1752         {
1753                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1754                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1755         }
1756         else
1757                 self.hitplotfh = -1;
1758
1759         if(g_race || g_cts) {
1760                 string rr;
1761                 if(g_cts)
1762                         rr = CTS_RECORD;
1763                 else
1764                         rr = RACE_RECORD;
1765                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1766
1767                 msg_entity = self;
1768                 race_send_recordtime(MSG_ONE);
1769                 race_send_speedaward(MSG_ONE);
1770
1771                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1772                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1773                 race_send_speedaward_alltimebest(MSG_ONE);
1774
1775                 float i;
1776                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1777                         race_SendRankings(i, 0, 0, MSG_ONE);
1778                 }
1779         }
1780         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1781                 send_CSQC_teamnagger();
1782
1783         if (g_domination)
1784                 set_dom_state(self);
1785
1786         CheatInitClient();
1787
1788         if(!autocvar_g_campaign)
1789                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1790 }
1791
1792 /*
1793 =============
1794 ClientDisconnect
1795
1796 Called when a client disconnects from the server
1797 =============
1798 */
1799 .entity chatbubbleentity;
1800 void ReadyCount();
1801 void ClientDisconnect (void)
1802 {
1803         if(self.vehicle)
1804             vehicles_exit(VHEF_RELESE);
1805
1806         if not(self.flags & FL_CLIENT)
1807         {
1808                 print("Warning: ClientDisconnect without ClientConnect\n");
1809                 return;
1810         }
1811
1812         PlayerStats_AddGlobalInfo(self);
1813
1814         CheatShutdownClient();
1815
1816         if(self.hitplotfh >= 0)
1817         {
1818                 fclose(self.hitplotfh);
1819                 self.hitplotfh = -1;
1820         }
1821
1822         anticheat_report();
1823         anticheat_shutdown();
1824
1825         playerdemo_shutdown();
1826
1827         bot_clientdisconnect();
1828
1829         if(self.entcs)
1830                 detach_entcs();
1831
1832         if(autocvar_sv_eventlog)
1833                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1834         bprint ("^4",self.netname);
1835         bprint ("^4 disconnected\n");
1836
1837         SoundEntity_Detach(self);
1838
1839         DropAllRunes(self);
1840         MUTATOR_CALLHOOK(ClientDisconnect);
1841
1842         Portal_ClearAll(self);
1843
1844         if(self.flagcarried)
1845                 DropFlag(self.flagcarried, world, world);
1846         if(self.ballcarried && g_nexball)
1847                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1848
1849         // Here, everything has been done that requires this player to be a client.
1850
1851         self.flags &~= FL_CLIENT;
1852
1853         if (self.chatbubbleentity)
1854                 remove (self.chatbubbleentity);
1855
1856         if (self.killindicator)
1857                 remove (self.killindicator);
1858
1859         WaypointSprite_PlayerGone();
1860
1861         bot_relinkplayerlist();
1862
1863         if(g_arena)
1864         {
1865                 Spawnqueue_Unmark(self);
1866                 Spawnqueue_Remove(self);
1867         }
1868
1869         accuracy_free(self);
1870         ClientData_Detach();
1871         PlayerScore_Detach(self);
1872
1873         if(self.netname_previous)
1874                 strunzone(self.netname_previous);
1875         if(self.clientstatus)
1876                 strunzone(self.clientstatus);
1877         if(self.weaponorder_byimpulse)
1878                 strunzone(self.weaponorder_byimpulse);
1879
1880         ClearPlayerSounds();
1881
1882         if(self.personal)
1883                 remove(self.personal);
1884
1885         self.playerid = 0;
1886         ReadyCount();
1887
1888         // free cvars
1889         GetCvars(-1);
1890 }
1891
1892 .float BUTTON_CHAT;
1893 void ChatBubbleThink()
1894 {
1895         self.nextthink = time;
1896         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1897         {
1898                 if(self.owner) // but why can that ever be world?
1899                         self.owner.chatbubbleentity = world;
1900                 remove(self);
1901                 return;
1902         }
1903         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1904 #ifdef TETRIS
1905                 || self.owner.tetris_on
1906 #endif
1907         )
1908                 self.model = self.mdl;
1909         else
1910                 self.model = "";
1911 };
1912
1913 void UpdateChatBubble()
1914 {
1915         if (!self.modelindex)
1916                 return;
1917         // spawn a chatbubble entity if needed
1918         if (!self.chatbubbleentity)
1919         {
1920                 self.chatbubbleentity = spawn();
1921                 self.chatbubbleentity.owner = self;
1922                 self.chatbubbleentity.exteriormodeltoclient = self;
1923                 self.chatbubbleentity.think = ChatBubbleThink;
1924                 self.chatbubbleentity.nextthink = time;
1925                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1926                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1927                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1928                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1929                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1930                 self.chatbubbleentity.model = "";
1931                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1932         }
1933 }
1934
1935
1936 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1937 // added to the model skins
1938 /*void UpdateColorModHack()
1939 {
1940         local float c;
1941         c = self.clientcolors & 15;
1942         // LordHavoc: only bothering to support white, green, red, yellow, blue
1943              if (!teamplay) self.colormod = '0 0 0';
1944         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1945         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1946         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1947         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1948         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1949         else self.colormod = '1 1 1';
1950 };*/
1951
1952 .float oldcolormap;
1953 void respawn(void)
1954 {
1955         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1956         {
1957                 self.solid = SOLID_NOT;
1958                 self.takedamage = DAMAGE_NO;
1959                 self.movetype = MOVETYPE_FLY;
1960                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1961                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1962                 self.effects |= EF_ADDITIVE;
1963                 self.oldcolormap = self.colormap;
1964                 self.colormap = 512;
1965                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1966                 if(autocvar_g_respawn_ghosts_maxtime)
1967                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1968         }
1969
1970         CopyBody(1);
1971         self.effects |= EF_NODRAW; // prevent another CopyBody
1972         if(self.oldcolormap)
1973         {
1974                 self.colormap = self.oldcolormap;
1975                 self.oldcolormap = 0;
1976         }
1977         PutClientInServer();
1978 }
1979
1980 void play_countdown(float finished, string samp)
1981 {
1982         if(clienttype(self) == CLIENTTYPE_REAL)
1983                 if(floor(finished - time - frametime) != floor(finished - time))
1984                         if(finished - time < 6)
1985                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1986 }
1987
1988 void player_powerups (void)
1989 {
1990         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1991         olditems = self.items;
1992
1993         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1994         {
1995                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1996                 self.modelflags |= MF_ROCKET;
1997         }
1998         else
1999         {
2000                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
2001                 self.modelflags &~= MF_ROCKET;
2002         }
2003
2004         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2005
2006         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2007                 return;
2008
2009         Fire_ApplyDamage(self);
2010         Fire_ApplyEffect(self);
2011
2012         if (g_minstagib)
2013         {
2014                 self.effects |= EF_FULLBRIGHT;
2015
2016                 if (self.items & IT_STRENGTH)
2017                 {
2018                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2019                         if (time > self.strength_finished)
2020                         {
2021                                 self.alpha = default_player_alpha;
2022                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2023                                 self.items &~= IT_STRENGTH;
2024                                 sprint(self, "^3Invisibility has worn off\n");
2025                         }
2026                 }
2027                 else
2028                 {
2029                         if (time < self.strength_finished)
2030                         {
2031                                 self.alpha = g_minstagib_invis_alpha;
2032                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2033                                 self.items |= IT_STRENGTH;
2034                                 sprint(self, "^3You are invisible\n");
2035                         }
2036                 }
2037
2038                 if (self.items & IT_INVINCIBLE)
2039                 {
2040                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2041                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2042                         {
2043                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2044                                 sprint(self, "^3Speed has worn off\n");
2045                         }
2046                 }
2047                 else
2048                 {
2049                         if (time < self.invincible_finished)
2050                         {
2051                                 self.items = self.items | IT_INVINCIBLE;
2052                                 sprint(self, "^3You are on speed\n");
2053                         }
2054                 }
2055         }
2056         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2057         {
2058                 if (self.items & IT_STRENGTH)
2059                 {
2060                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2061                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2062                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2063                         {
2064                                 self.items = self.items - (self.items & IT_STRENGTH);
2065                                 sprint(self, "^3Strength has worn off\n");
2066                         }
2067                 }
2068                 else
2069                 {
2070                         if (time < self.strength_finished)
2071                         {
2072                                 self.items = self.items | IT_STRENGTH;
2073                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2074                         }
2075                 }
2076                 if (self.items & IT_INVINCIBLE)
2077                 {
2078                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2079                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2080                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2081                         {
2082                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2083                                 sprint(self, "^3Shield has worn off\n");
2084                         }
2085                 }
2086                 else
2087                 {
2088                         if (time < self.invincible_finished)
2089                         {
2090                                 self.items = self.items | IT_INVINCIBLE;
2091                                 sprint(self, "^3Shield surrounds you\n");
2092                         }
2093                 }
2094
2095                 if(autocvar_g_nodepthtestplayers)
2096                         self.effects = self.effects | EF_NODEPTHTEST;
2097
2098                 if(autocvar_g_fullbrightplayers)
2099                         self.effects = self.effects | EF_FULLBRIGHT;
2100
2101                 // midair gamemode: damage only while in the air
2102                 // if in midair mode, being on ground grants temporary invulnerability
2103                 // (this is so that multishot weapon don't clear the ground flag on the
2104                 // first damage in the frame, leaving the player vulnerable to the
2105                 // remaining hits in the same frame)
2106                 if (self.flags & FL_ONGROUND)
2107                 if (g_midair)
2108                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2109
2110                 if (time >= game_starttime)
2111                 if (time < self.spawnshieldtime)
2112                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2113         }
2114
2115         MUTATOR_CALLHOOK(PlayerPowerups);
2116 }
2117
2118 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2119 {
2120         if(current > stable)
2121                 return current;
2122         else if(current > stable - 0.25) // when close enough, "snap"
2123                 return stable;
2124         else
2125                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2126 }
2127
2128 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2129 {
2130         if(current < stable)
2131                 return current;
2132         else if(current < stable + 0.25) // when close enough, "snap"
2133                 return stable;
2134         else
2135                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2136 }
2137
2138 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2139 {
2140         if(current > rotstable)
2141         {
2142                 if(rotframetime > 0)
2143                 {
2144                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2145                         current = max(rotstable, current - rotlinear * rotframetime);
2146                 }
2147         }
2148         else if(current < regenstable)
2149         {
2150                 if(regenframetime > 0)
2151                 {
2152                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2153                         current = min(regenstable, current + regenlinear * regenframetime);
2154                 }
2155         }
2156
2157         if(current > limit)
2158                 current = limit;
2159
2160         return current;
2161 }
2162
2163 void player_regen (void)
2164 {
2165         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2166         maxh = autocvar_g_balance_health_rotstable;
2167         maxa = autocvar_g_balance_armor_rotstable;
2168         maxf = autocvar_g_balance_fuel_rotstable;
2169         minh = autocvar_g_balance_health_regenstable;
2170         mina = autocvar_g_balance_armor_regenstable;
2171         minf = autocvar_g_balance_fuel_regenstable;
2172         limith = autocvar_g_balance_health_limit;
2173         limita = autocvar_g_balance_armor_limit;
2174         limitf = autocvar_g_balance_fuel_limit;
2175
2176         max_mod = regen_mod = rot_mod = limit_mod = 1;
2177
2178         if (self.runes & RUNE_REGEN)
2179         {
2180                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2181                 {
2182                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2183                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2184                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2185                 }
2186                 else
2187                 {
2188                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2189                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2190                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2191                 }
2192         }
2193         else if (self.runes & CURSE_VENOM)
2194         {
2195                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2196                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2197                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2198                 else
2199                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2200                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2201                 //if (!self.runes & RUNE_REGEN)
2202                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2203         }
2204         maxh = maxh * max_mod;
2205         //maxa = maxa * max_mod;
2206         //maxf = maxf * max_mod;
2207         minh = minh * max_mod;
2208         //mina = mina * max_mod;
2209         //minf = minf * max_mod;
2210         limith = limith * limit_mod;
2211         limita = limita * limit_mod;
2212         //limitf = limitf * limit_mod;
2213
2214         if(g_lms && g_ca)
2215                 rot_mod = 0;
2216
2217         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2218         {
2219                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2220                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2221
2222                 // if player rotted to death...  die!
2223                 if(self.health < 1)
2224                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2225         }
2226
2227         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2228                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2229 }
2230
2231 float zoomstate_set;
2232 void SetZoomState(float z)
2233 {
2234         if(z != self.zoomstate)
2235         {
2236                 self.zoomstate = z;
2237                 ClientData_Touch(self);
2238         }
2239         zoomstate_set = 1;
2240 }
2241
2242 void GetPressedKeys(void) {
2243         MUTATOR_CALLHOOK(GetPressedKeys);
2244         if (self.movement_x > 0) // get if movement keys are pressed
2245         {       // forward key pressed
2246                 self.pressedkeys |= KEY_FORWARD;
2247                 self.pressedkeys &~= KEY_BACKWARD;
2248         }
2249         else if (self.movement_x < 0)
2250         {       // backward key pressed
2251                 self.pressedkeys |= KEY_BACKWARD;
2252                 self.pressedkeys &~= KEY_FORWARD;
2253         }
2254         else
2255         {       // no x input
2256                 self.pressedkeys &~= KEY_FORWARD;
2257                 self.pressedkeys &~= KEY_BACKWARD;
2258         }
2259
2260         if (self.movement_y > 0)
2261         {       // right key pressed
2262                 self.pressedkeys |= KEY_RIGHT;
2263                 self.pressedkeys &~= KEY_LEFT;
2264         }
2265         else if (self.movement_y < 0)
2266         {       // left key pressed
2267                 self.pressedkeys |= KEY_LEFT;
2268                 self.pressedkeys &~= KEY_RIGHT;
2269         }
2270         else
2271         {       // no y input
2272                 self.pressedkeys &~= KEY_RIGHT;
2273                 self.pressedkeys &~= KEY_LEFT;
2274         }
2275
2276         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2277                 self.pressedkeys |= KEY_JUMP;
2278         else
2279                 self.pressedkeys &~= KEY_JUMP;
2280         if (self.BUTTON_CROUCH)
2281                 self.pressedkeys |= KEY_CROUCH;
2282         else
2283                 self.pressedkeys &~= KEY_CROUCH;
2284 }
2285
2286 /*
2287 ======================
2288 spectate mode routines
2289 ======================
2290 */
2291
2292 void SpectateCopy(entity spectatee) {
2293         other = spectatee;
2294         MUTATOR_CALLHOOK(SpectateCopy);
2295         self.armortype = spectatee.armortype;
2296         self.armorvalue = spectatee.armorvalue;
2297         self.ammo_cells = spectatee.ammo_cells;
2298         self.ammo_shells = spectatee.ammo_shells;
2299         self.ammo_nails = spectatee.ammo_nails;
2300         self.ammo_rockets = spectatee.ammo_rockets;
2301         self.ammo_fuel = spectatee.ammo_fuel;
2302         self.clip_load = spectatee.clip_load;
2303         self.clip_size = spectatee.clip_size;
2304         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2305         self.health = spectatee.health;
2306         self.impulse = 0;
2307         self.items = spectatee.items;
2308         self.last_pickup = spectatee.last_pickup;
2309         self.hit_time = spectatee.hit_time;
2310         self.metertime = spectatee.metertime;
2311         self.strength_finished = spectatee.strength_finished;
2312         self.invincible_finished = spectatee.invincible_finished;
2313         self.pressedkeys = spectatee.pressedkeys;
2314         self.weapons = spectatee.weapons;
2315         self.switchweapon = spectatee.switchweapon;
2316         self.switchingweapon = spectatee.switchingweapon;
2317         self.weapon = spectatee.weapon;
2318         self.nex_charge = spectatee.nex_charge;
2319         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2320         self.hagar_load = spectatee.hagar_load;
2321         self.minelayer_mines = spectatee.minelayer_mines;
2322         self.punchangle = spectatee.punchangle;
2323         self.view_ofs = spectatee.view_ofs;
2324         self.v_angle = spectatee.v_angle;
2325         self.velocity = spectatee.velocity;
2326         self.dmg_take = spectatee.dmg_take;
2327         self.dmg_save = spectatee.dmg_save;
2328         self.dmg_inflictor = spectatee.dmg_inflictor;
2329         self.angles = spectatee.v_angle;
2330         if(!self.BUTTON_USE)
2331                 self.fixangle = TRUE;
2332         setorigin(self, spectatee.origin);
2333         setsize(self, spectatee.mins, spectatee.maxs);
2334         SetZoomState(spectatee.zoomstate);
2335
2336         anticheat_spectatecopy(spectatee);
2337
2338         //self.vehicle = spectatee.vehicle;
2339
2340         self.hud = spectatee.hud;
2341         if(spectatee.vehicle)
2342     {
2343         setorigin(self, spectatee.origin);
2344         self.velocity = spectatee.vehicle.velocity;
2345         self.v_angle += spectatee.vehicle.angles;
2346         //self.v_angle_x *= -1;
2347         self.vehicle_health = spectatee.vehicle_health;
2348         self.vehicle_shield = spectatee.vehicle_shield;
2349         self.vehicle_energy = spectatee.vehicle_energy;
2350         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2351         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2352         self.vehicle_reload1 = spectatee.vehicle_reload1;
2353         self.vehicle_reload2 = spectatee.vehicle_reload2;
2354         
2355         msg_entity = self;
2356         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2357         WriteEntity(MSG_ONE, spectatee);
2358         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2359     }
2360 }
2361
2362 float SpectateUpdate() {
2363         if(!self.enemy)
2364             return 0;           
2365
2366         if (self == self.enemy)
2367                 return 0;
2368
2369         if(self.enemy.classname != "player")
2370                 return 0;
2371
2372         SpectateCopy(self.enemy);
2373
2374         return 1;
2375 }
2376
2377
2378 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2379 entity CA_SpectateNext(entity start) {
2380         if (start.team == self.team) {
2381                 return start;
2382         }
2383         
2384         other = start;
2385         // continue from current player
2386         while(other && other.team != self.team) {
2387                 other = find(other, classname, "player");
2388         }
2389         
2390         if (!other) {
2391                 // restart from begining
2392                 other = find(other, classname, "player");
2393                 while(other && other.team != self.team) {
2394                         other = find(other, classname, "player");
2395                 }
2396         }
2397         
2398         return other;
2399 }
2400
2401 float SpectateNext() {
2402         other = find(self.enemy, classname, "player");
2403         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2404                 // CA and ca players when spectating enemies is forbidden
2405                 other = CA_SpectateNext(other);
2406         } else {
2407                 // other modes and ca spectators or spectating enemies is allowed
2408                 if (!other)
2409                         other = find(other, classname, "player");
2410         }
2411         
2412         if (other)
2413                 self.enemy = other;
2414
2415         if(self.enemy.classname == "player") {
2416             if(self.enemy.vehicle)
2417             {      
2418             msg_entity = self;
2419             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2420             WriteEntity(MSG_ONE, self.enemy);
2421             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2422             self.movetype = MOVETYPE_NONE;
2423             accuracy_resend(self);
2424             }
2425             else 
2426             {           
2427             msg_entity = self;
2428             WriteByte(MSG_ONE, SVC_SETVIEW);
2429             WriteEntity(MSG_ONE, self.enemy);
2430             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2431             self.movetype = MOVETYPE_NONE;
2432             accuracy_resend(self);
2433
2434             if(!SpectateUpdate())
2435                 PutObserverInServer();
2436         }
2437         return 1;
2438         } else {
2439                 return 0;
2440         }
2441 }
2442
2443 /*
2444 =============
2445 ShowRespawnCountdown()
2446
2447 Update a respawn countdown display.
2448 =============
2449 */
2450 void ShowRespawnCountdown()
2451 {
2452         float number;
2453         if(self.deadflag == DEAD_NO) // just respawned?
2454                 return;
2455         else
2456         {
2457                 number = ceil(self.death_time - time);
2458                 if(number <= 0)
2459                         return;
2460                 if(number <= self.respawn_countdown)
2461                 {
2462                         self.respawn_countdown = number - 1;
2463                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2464                                 AnnounceTo(self, strcat(ftos(number), ""));
2465                 }
2466         }
2467 }
2468
2469 .float prevent_join_msgtime;
2470 void LeaveSpectatorMode()
2471 {
2472         if(nJoinAllowed(1)) {
2473                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2474                         self.classname = "player";
2475
2476                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2477                                 JoinBestTeam(self, FALSE, TRUE);
2478
2479                         if(autocvar_g_campaign)
2480                                 campaign_bots_may_start = 1;
2481
2482                         PutClientInServer();
2483
2484                         if(self.classname == "player")
2485                                 bprint ("^4", self.netname, "^4 is playing now\n");
2486
2487                         if(!autocvar_g_campaign)
2488                         if (time < self.jointime + autocvar_welcome_message_time)
2489                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2490
2491                         if (self.prevent_join_msgtime)
2492                         {
2493                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2494                                 self.prevent_join_msgtime = 0;
2495                         }
2496
2497                         return;
2498                 } else {
2499                         if (g_ca && self.caplayer) {
2500                         }       // do nothing
2501                         else
2502                                 stuffcmd(self,"menu_showteamselect\n");
2503                         return;
2504                 }
2505         }
2506         else {
2507                 //player may not join because of g_maxplayers is set
2508                 if (time - self.prevent_join_msgtime > 2)
2509                 {
2510                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2511                         self.prevent_join_msgtime = time;
2512                 }
2513         }
2514 }
2515
2516 /**
2517  * Determines whether the player is allowed to join. This depends on cvar
2518  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2519  * it checks whether the number of currently playing players exceeds g_maxplayers.
2520  * @return int number of free slots for players, 0 if none
2521  */
2522 float nJoinAllowed(float includeMe) {
2523         if(self.team_forced < 0)
2524                 return FALSE; // forced spectators can never join
2525
2526         // TODO simplify this
2527         local entity e;
2528
2529         local float totalClients;
2530         FOR_EACH_CLIENT(e)
2531                 totalClients += 1;
2532
2533         if (!autocvar_g_maxplayers)
2534                 return maxclients - totalClients + includeMe;
2535
2536         local float currentlyPlaying;
2537         FOR_EACH_REALPLAYER(e)
2538                 currentlyPlaying += 1;
2539
2540         if(currentlyPlaying < autocvar_g_maxplayers)
2541                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2542
2543         return 0;
2544 }
2545
2546 /**
2547  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2548  * g_maxplayers_spectator_blocktime seconds
2549  */
2550 void checkSpectatorBlock() {
2551         if(self.classname == "spectator" || self.classname == "observer") {
2552                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2553                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2554                         dropclient(self);
2555                 }
2556         }
2557 }
2558
2559 .float motd_actived_time; // used for both motd and campaign_message
2560 void PrintWelcomeMessage()
2561 {
2562         if (self.motd_actived_time == 0) { // is there already a message showing?
2563                 if (autocvar_g_campaign) {
2564                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2565                                 self.motd_actived_time = time;
2566                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2567                         }
2568                 } else {
2569                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2570                                 self.motd_actived_time = time;
2571                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2572                         }
2573                 }
2574         } else { // showing MOTD or campaign message
2575                 if (autocvar_g_campaign) {
2576                         if (self.BUTTON_INFO)
2577                                 self.motd_actived_time = time;
2578                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2579                                 self.motd_actived_time = 0;
2580                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2581                         }
2582                 } else {
2583                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2584                                 if (self.BUTTON_INFO)
2585                                         self.motd_actived_time = time;
2586                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2587                                         self.motd_actived_time = 0;
2588                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2589                                 }
2590                         }
2591                 }
2592         }
2593 }
2594
2595 void ObserverThink()
2596 {
2597         float prefered_movetype;
2598         if (self.flags & FL_JUMPRELEASED) {
2599                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2600                         self.flags &~= FL_JUMPRELEASED;
2601                         self.flags |= FL_SPAWNING;
2602                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2603                         self.flags &~= FL_JUMPRELEASED;
2604                         if(SpectateNext() == 1) {
2605                                 self.classname = "spectator";
2606                         }
2607                 } else {
2608                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2609                         if (self.movetype != prefered_movetype)
2610                                 self.movetype = prefered_movetype;
2611                 }
2612         } else {
2613                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2614                         self.flags |= FL_JUMPRELEASED;
2615                         if(self.flags & FL_SPAWNING)
2616                         {
2617                                 self.flags &~= FL_SPAWNING;
2618                                 LeaveSpectatorMode();
2619                                 return;
2620                         }
2621                 }
2622         }
2623
2624         PrintWelcomeMessage();
2625 }
2626
2627 void SpectatorThink()
2628 {
2629         if (self.flags & FL_JUMPRELEASED) {
2630                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2631                         self.flags &~= FL_JUMPRELEASED;
2632                         self.flags |= FL_SPAWNING;
2633                 } else if(self.BUTTON_ATCK) {
2634                         self.flags &~= FL_JUMPRELEASED;
2635                         if(SpectateNext() == 1) {
2636                                 self.classname = "spectator";
2637                         } else {
2638                                 self.classname = "observer";
2639                                 PutClientInServer();
2640                         }
2641                 } else if (self.BUTTON_ATCK2) {
2642                         self.flags &~= FL_JUMPRELEASED;
2643                         self.classname = "observer";
2644                         PutClientInServer();
2645                 } else {
2646                         if(!SpectateUpdate())
2647                                 PutObserverInServer();
2648                 }
2649         } else {
2650                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2651                         self.flags |= FL_JUMPRELEASED;
2652                         if(self.flags & FL_SPAWNING)
2653                         {
2654                                 self.flags &~= FL_SPAWNING;
2655                                 LeaveSpectatorMode();
2656                                 return;
2657                         }
2658                 }
2659                 if(!SpectateUpdate())
2660                         PutObserverInServer();
2661         }
2662
2663         PrintWelcomeMessage();
2664         self.flags |= FL_CLIENT | FL_NOTARGET;
2665 }
2666
2667 float ctf_usekey();
2668 void PlayerUseKey()
2669 {
2670         if(self.classname != "player")
2671                 return;
2672
2673         if(self.vehicle)
2674         {
2675         vehicles_exit(VHEF_NORMAL);
2676         return;
2677         }
2678         
2679         // a use key was pressed; call handlers
2680         if(ctf_usekey())
2681                 return;
2682
2683         MUTATOR_CALLHOOK(PlayerUseKey);
2684 }
2685
2686 .float touchexplode_time;
2687
2688 /*
2689 =============
2690 PlayerPreThink
2691
2692 Called every frame for each client before the physics are run
2693 =============
2694 */
2695 .float usekeypressed;
2696 void() ctf_setstatus;
2697 void() nexball_setstatus;
2698 .float items_added;
2699 void PlayerPreThink (void)
2700 {
2701         WarpZone_PlayerPhysics_FixVAngle();
2702
2703         self.stat_game_starttime = game_starttime;
2704         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2705         self.stat_leadlimit = autocvar_leadlimit;
2706
2707         if(frametime)
2708         {
2709                 // physics frames: update anticheat stuff
2710                 anticheat_prethink();
2711         }
2712
2713         if(blockSpectators && frametime)
2714                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2715                 checkSpectatorBlock();
2716
2717         zoomstate_set = 0;
2718
2719         if(self.netname_previous != self.netname)
2720         {
2721                 if(autocvar_sv_eventlog)
2722                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2723                 if(self.netname_previous)
2724                         strunzone(self.netname_previous);
2725                 self.netname_previous = strzone(self.netname);
2726         }
2727
2728         // version nagging
2729         if(self.version_nagtime)
2730                 if(self.cvar_g_xonoticversion)
2731                         if(time > self.version_nagtime)
2732                         {
2733                                 // don't notify git users
2734                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2735                                 {
2736                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2737                                         {
2738                                                 // notify release users if connecting to git
2739                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2740                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2741                                         }
2742                                         else
2743                                         {
2744                                                 float r;
2745                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2746                                                 if(r < 0)
2747                                                 {
2748                                                         // give users new version
2749                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2750                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2751                                                 }
2752                                                 else if(r > 0)
2753                                                 {
2754                                                         // notify users about old server version
2755                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2756                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2757                                                 }
2758                                         }
2759                                 }
2760                                 self.version_nagtime = 0;
2761                         }
2762
2763         // GOD MODE info
2764         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2765         {
2766                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2767                 self.max_armorvalue = 0;
2768         }
2769
2770 #ifdef TETRIS
2771         if (TetrisPreFrame())
2772                 return;
2773 #endif
2774
2775         MUTATOR_CALLHOOK(PlayerPreThink);
2776
2777         if(self.BUTTON_USE && !self.usekeypressed)
2778                 PlayerUseKey();
2779         self.usekeypressed = self.BUTTON_USE;
2780
2781         PrintWelcomeMessage();
2782
2783         if(self.classname == "player") {
2784 //              if(self.netname == "Wazat")
2785 //                      bprint(self.classname, "\n");
2786
2787                 CheckRules_Player();
2788
2789                 if (intermission_running)
2790                 {
2791                         IntermissionThink ();   // otherwise a button could be missed between
2792                         return;                                 // the think tics
2793                 }
2794
2795                 //don't allow the player to turn around while game is paused!
2796                 if(timeoutStatus == 2) {
2797                         // FIXME turn this into CSQC stuff
2798                         self.v_angle = self.lastV_angle;
2799                         self.angles = self.lastV_angle;
2800                         self.fixangle = TRUE;
2801                 }
2802
2803                 if(frametime)
2804                 {
2805                         if(self.health <= 0 && autocvar_g_deathglow)
2806                         {
2807                                 if(self.glowmod_x > 0)
2808                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2809                                 else
2810                                         self.glowmod_x = -1;
2811                                 if(self.glowmod_y > 0)
2812                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2813                                 else
2814                                         self.glowmod_y = -1;
2815                                 if(self.glowmod_z > 0)
2816                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2817                                 else
2818                                         self.glowmod_z = -1;
2819                         }
2820                         else
2821                         {
2822                                 // set weapon and player glowmod
2823                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2824
2825                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2826                                 {
2827                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2828                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2829                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2830
2831                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2832                                         {
2833                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2834                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2835                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2836                                         }
2837                                 }
2838                                 else
2839                                         self.weaponentity_glowmod = self.glowmod;
2840                         }
2841                         player_powerups();
2842                 }
2843
2844                 if (g_minstagib)
2845                         minstagib_ammocheck();
2846
2847                 if (self.deadflag != DEAD_NO)
2848                 {
2849                         float button_pressed, force_respawn;
2850                         if(self.personal && g_race_qualifying)
2851                         {
2852                                 if(time > self.death_time)
2853                                 {
2854                                         self.death_time = time + 1; // only retry once a second
2855                                         respawn();
2856                                         self.impulse = 141;
2857                                 }
2858                         }
2859                         else
2860                         {
2861                                 if(frametime)
2862                                         player_anim();
2863                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2864                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2865                                 if (self.deadflag == DEAD_DYING)
2866                                 {
2867                                         if(force_respawn)
2868                                                 self.deadflag = DEAD_RESPAWNING;
2869                                         else if(!button_pressed)
2870                                                 self.deadflag = DEAD_DEAD;
2871                                 }
2872                                 else if (self.deadflag == DEAD_DEAD)
2873                                 {
2874                                         if(button_pressed)
2875                                                 self.deadflag = DEAD_RESPAWNABLE;
2876                                 }
2877                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2878                                 {
2879                                         if(!button_pressed)
2880                                                 self.deadflag = DEAD_RESPAWNING;
2881                                 }
2882                                 else if (self.deadflag == DEAD_RESPAWNING)
2883                                 {
2884                                         if(time > self.death_time)
2885                                         {
2886                                                 self.death_time = time + 1; // only retry once a second
2887                                                 respawn();
2888                                         }
2889                                 }
2890                                 ShowRespawnCountdown();
2891                         }
2892                         return;
2893                 }
2894                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2895                 // so (self.deadflag == DEAD_NO) is always true in the code below
2896
2897                 if(g_touchexplode)
2898                 if(time > self.touchexplode_time)
2899                 if(self.classname == "player")
2900                 if(self.deadflag == DEAD_NO)
2901                 if not(IS_INDEPENDENT_PLAYER(self))
2902                 FOR_EACH_PLAYER(other) if(self != other)
2903                 {
2904                         if(time > other.touchexplode_time)
2905                         if(other.deadflag == DEAD_NO)
2906                         if not(IS_INDEPENDENT_PLAYER(other))
2907                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2908                         {
2909                                 PlayerTouchExplode(self, other);
2910                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2911                         }
2912                 }
2913
2914                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2915                 {
2916                         vector dist;
2917
2918                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2919                         dist = self.prevorigin - self.origin;
2920                         dist_z = 0;
2921                         self.lms_traveled_distance += fabs(vlen(dist));
2922
2923                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2924                         {
2925                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2926                                 self.lms_traveled_distance = 0;
2927                         }
2928
2929                         if(time > self.lms_nextcheck)
2930                         {
2931                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2932                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2933                                 {
2934                                         centerprint(self, autocvar_g_lms_campcheck_message);
2935                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2936                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2937                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2938                                 }
2939                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2940                                 self.lms_traveled_distance = 0;
2941                         }
2942                 }
2943
2944                 self.prevorigin = self.origin;
2945
2946                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2947                 {
2948                         if (!self.crouch)
2949                         {
2950                                 self.crouch = TRUE;
2951                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2952                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2953                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2954                         }
2955                 }
2956                 else
2957                 {
2958                         if (self.crouch)
2959                         {
2960                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2961                                 if (!trace_startsolid)
2962                                 {
2963                                         self.crouch = FALSE;
2964                                         self.view_ofs = PL_VIEW_OFS;
2965                                         setsize (self, PL_MIN, PL_MAX);
2966                                 }
2967                         }
2968                 }
2969
2970                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2971                 {
2972                         if(self.bloodloss_timer < time)
2973                         {
2974                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2975                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2976                         }
2977                 }
2978
2979                 FixPlayermodel();
2980
2981                 GrapplingHookFrame();
2982
2983                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2984                 //if(frametime)
2985                 {
2986                         self.items &~= self.items_added;
2987
2988                         W_WeaponFrame();
2989
2990                         self.items_added = 0;
2991                         if(self.items & IT_JETPACK)
2992                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2993                                         self.items_added |= IT_FUEL;
2994
2995                         self.items |= self.items_added;
2996                 }
2997
2998                 player_regen();
2999
3000                 // rot nex charge to the charge limit
3001                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
3002                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
3003
3004                 if(frametime)
3005                         player_anim();
3006
3007                 if(g_ctf)
3008                         ctf_setstatus();
3009
3010                 if(g_nexball)
3011                         nexball_setstatus();
3012
3013                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
3014
3015                 //self.angles_y=self.v_angle_y + 90;   // temp
3016         } else if(gameover) {
3017                 if (intermission_running)
3018                         IntermissionThink ();   // otherwise a button could be missed between
3019                 return;
3020         } else if(self.classname == "observer") {
3021                 ObserverThink();
3022         } else if(self.classname == "spectator") {
3023                 SpectatorThink();
3024         }
3025
3026         if(!zoomstate_set)
3027                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));