qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, autocvar_g_balance_campingrifle_magazinecapacity);
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(autocvar_spawn_debugview)
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > autocvar_g_spawn_furthest)
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(autocvar_spawn_debugview)
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(autocvar_spawn_debug)
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(autocvar_sv_servermodelsonly)
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602         MUTATOR_CALLHOOK(MakePlayerObserver);
 603
 604         Portal_ClearAll(self);
 605
 606         if(self.alivetime)
 607         {
 608                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 609                 self.alivetime = 0;
 610         }
 611
 612         if(self.flagcarried)
 613                 DropFlag(self.flagcarried, world, world);
 614
 615         if(self.ballcarried && g_nexball)
 616                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 617
 618         WaypointSprite_PlayerDead();
 619
 620         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 621                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 622
 623         if(self.killcount != -666) {
 624                 if(g_lms) {
 625                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 626                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 627                         else
 628                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 629                 } else
 630                         bprint ("^4", self.netname, "^4 is spectating now\n");
 631
 632                 if(self.just_joined == FALSE) {
 633                         LogTeamchange(self.playerid, -1, 4);
 634                 } else
 635                         self.just_joined = FALSE;
 636         }
 637
 638         PlayerScore_Clear(self); // clear scores when needed
 639
 640         accuracy_resend(self);
 641
 642         self.spectatortime = time;
 643
 644         self.classname = "observer";
 645         self.iscreature = FALSE;
 646         self.health = -666;
 647         self.takedamage = DAMAGE_NO;
 648         self.solid = SOLID_NOT;
 649         self.movetype = MOVETYPE_NOCLIP;
 650         self.flags = FL_CLIENT | FL_NOTARGET;
 651         self.armorvalue = 666;
 652         self.effects = 0;
 653         self.armorvalue = autocvar_g_balance_armor_start;
 654         self.pauserotarmor_finished = 0;
 655         self.pauserothealth_finished = 0;
 656         self.pauseregen_finished = 0;
 657         self.damageforcescale = 0;
 658         self.death_time = 0;
 659         self.dead_frame = 0;
 660         self.alpha = 0;
 661         self.scale = 0;
 662         self.fade_time = 0;
 663         self.pain_frame = 0;
 664         self.pain_finished = 0;
 665         self.strength_finished = 0;
 666         self.invincible_finished = 0;
 667         self.pushltime = 0;
 668         self.think = SUB_Null;
 669         self.nextthink = 0;
 670         self.hook_time = 0;
 671         self.runes = 0;
 672         self.deadflag = DEAD_NO;
 673         self.angles = spot.angles;
 674         self.angles_z = 0;
 675         self.fixangle = TRUE;
 676         self.crouch = FALSE;
 677
 678         self.view_ofs = PL_VIEW_OFS;
 679         setorigin (self, spot.origin);
 680         setsize (self, '0 0 0', '0 0 0');
 681         self.prevorigin = self.origin;
 682         self.items = 0;
 683         self.weapons = 0;
 684         self.model = "";
 685         FixPlayermodel();
 686         self.model = "";
 687         self.modelindex = 0;
 688         self.weapon = 0;
 689         self.weaponmodel = "";
 690         self.weaponentity = world;
 691         self.exteriorweaponentity = world;
 692         self.killcount = -666;
 693         self.velocity = '0 0 0';
 694         self.avelocity = '0 0 0';
 695         self.punchangle = '0 0 0';
 696         self.punchvector = '0 0 0';
 697         self.oldvelocity = self.velocity;
 698         self.fire_endtime = -1;
 699
 700         if(sv_loddistance1)
 701                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 702
 703         if(g_arena)
 704         {
 705                 if(self.version_mismatch)
 706                 {
 707                         Spawnqueue_Unmark(self);
 708                         Spawnqueue_Remove(self);
 709                 }
 710                 else
 711                 {
 712                         Spawnqueue_Insert(self);
 713                 }
 714         }
 715         else if(g_lms)
 716         {
 717                 // Only if the player cannot play at all
 718                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 719                         self.frags = FRAGS_SPECTATOR;
 720                 else
 721                         self.frags = FRAGS_LMS_LOSER;
 722         }
 723         else
 724                 self.frags = FRAGS_SPECTATOR;
 725 }
 726
 727 float RestrictSkin(float s)
 728 {
 729         if(!teams_matter)
 730                 return s;
 731         if(s == 6)
 732                 return 6;
 733         return mod(s, 3);
 734 }
 735
 736 void FixPlayermodel()
 737 {
 738         local string defaultmodel;
 739         local float defaultskin, chmdl, oldskin;
 740         local vector m1, m2;
 741
 742         defaultmodel = "";
 743
 744         if(autocvar_sv_defaultcharacter == 1) {
 745                 defaultskin = 0;
 746
 747                 if(teams_matter)
 748                 {
 749                         string s;
 750                         s = Team_ColorNameLowerCase(self.team);
 751                         if(s != "neutral")
 752                         {
 753                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 754                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 755                         }
 756                 }
 757
 758                 if(defaultmodel == "")
 759                 {
 760                         defaultmodel = autocvar_sv_defaultplayermodel;
 761                         defaultskin = autocvar_sv_defaultplayerskin;
 762                 }
 763         }
 764
 765         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 766         {
 767                 if(self.model != "")
 768                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 769                 self.model = ""; // force the != checks to return true
 770         }
 771
 772         if(defaultmodel != "")
 773         {
 774                 if (defaultmodel != self.model)
 775                 {
 776                         m1 = self.mins;
 777                         m2 = self.maxs;
 778                         setmodel_lod (self, defaultmodel);
 779                         setsize (self, m1, m2);
 780                         chmdl = TRUE;
 781                 }
 782
 783                 oldskin = self.skinindex;
 784                 self.skinindex = defaultskin;
 785         } else {
 786                 if (self.playermodel != self.model || self.playermodel == "")
 787                 {
 788                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 789                         m1 = self.mins;
 790                         m2 = self.maxs;
 791                         setmodel_lod (self, self.playermodel);
 792                         setsize (self, m1, m2);
 793                         chmdl = TRUE;
 794                 }
 795
 796                 oldskin = self.skinindex;
 797                 self.skinindex = RestrictSkin(stof(self.playerskin));
 798         }
 799
 800         if(chmdl || oldskin != self.skinindex)
 801                 self.species = player_getspecies(); // model or skin has changed
 802
 803         if(!teams_matter)
 804                 if(strlen(autocvar_sv_defaultplayercolors))
 805                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 806                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 807 }
 808
 809 void PlayerTouchExplode(entity p1, entity p2)
 810 {
 811         vector org;
 812         org = (p1.origin + p2.origin) * 0.5;
 813         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 814
 815         te_explosion(org);
 816
 817         entity e;
 818         e = spawn();
 819         setorigin(e, org);
 820         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 821         remove(e);
 822 }
 823
 824 /*
 825 =============
 826 PutClientInServer
 827
 828 Called when a client spawns in the server
 829 =============
 830 */
 831 //void() ctf_playerchanged;
 832 void PutClientInServer (void)
 833 {
 834         if(clienttype(self) == CLIENTTYPE_BOT)
 835         {
 836                 self.classname = "player";
 837         }
 838         else if(clienttype(self) == CLIENTTYPE_REAL)
 839         {
 840                 msg_entity = self;
 841                 WriteByte(MSG_ONE, SVC_SETVIEW);
 842                 WriteEntity(MSG_ONE, self);
 843         }
 844
 845         // player is dead and becomes observer
 846         // FIXME fix LMS scoring for new system
 847         if(g_lms)
 848         {
 849                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 850                         self.classname = "observer";
 851         }
 852
 853         if(g_arena || (g_ca && !allowed_to_spawn))
 854         if(!self.spawned)
 855                 self.classname = "observer";
 856
 857         if(gameover)
 858                 self.classname = "observer";
 859
 860         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 861                 entity spot, oldself;
 862                 float j;
 863
 864                 accuracy_resend(self);
 865
 866                 if(self.team < 0)
 867                         JoinBestTeam(self, FALSE, TRUE);
 868
 869                 race_PreSpawn();
 870
 871                 spot = SelectSpawnPoint (FALSE);
 872                 if(!spot)
 873                 {
 874                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 875                         return; // spawn failed
 876                 }
 877
 878                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 879
 880                 self.classname = "player";
 881                 self.wasplayer = TRUE;
 882                 self.iscreature = TRUE;
 883                 self.movetype = MOVETYPE_WALK;
 884                 self.solid = SOLID_SLIDEBOX;
 885                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 886                 if(autocvar_g_playerclip_collisions)
 887                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 888                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 889                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 890                 self.frags = FRAGS_PLAYER;
 891                 if(independent_players)
 892                         MAKE_INDEPENDENT_PLAYER(self);
 893                 self.flags = FL_CLIENT;
 894                 self.takedamage = DAMAGE_AIM;
 895                 if(g_minstagib)
 896                         self.effects = EF_FULLBRIGHT;
 897                 else
 898                         self.effects = 0;
 899                 self.air_finished = time + 12;
 900                 self.dmg = 2;
 901                 if(autocvar_g_balance_nex_charge)
 902                 {
 903                         if(autocvar_g_balance_nex_secondary_chargepool)
 904                                 self.nex_chargepool_ammo = 1;
 905                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 906                 }
 907
 908                 if(inWarmupStage)
 909                 {
 910                         self.ammo_shells = warmup_start_ammo_shells;
 911                         self.ammo_nails = warmup_start_ammo_nails;
 912                         self.ammo_rockets = warmup_start_ammo_rockets;
 913                         self.ammo_cells = warmup_start_ammo_cells;
 914                         self.ammo_fuel = warmup_start_ammo_fuel;
 915                         self.health = warmup_start_health;
 916                         self.armorvalue = warmup_start_armorvalue;
 917                         self.weapons = warmup_start_weapons;
 918                 }
 919                 else
 920                 {
 921                         self.ammo_shells = start_ammo_shells;
 922                         self.ammo_nails = start_ammo_nails;
 923                         self.ammo_rockets = start_ammo_rockets;
 924                         self.ammo_cells = start_ammo_cells;
 925                         self.ammo_fuel = start_ammo_fuel;
 926                         self.health = start_health;
 927                         self.armorvalue = start_armorvalue;
 928                         self.weapons = start_weapons;
 929                 }
 930
 931                 if(g_weaponarena_random)
 932                 {
 933                         if(g_weaponarena_random_with_laser)
 934                                 self.weapons &~= WEPBIT_LASER;
 935                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 936                         if(g_weaponarena_random_with_laser)
 937                                 self.weapons |= WEPBIT_LASER;
 938                 }
 939
 940                 self.items = start_items;
 941                 self.jump_interval = time;
 942
 943                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 944                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 945                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 946                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 947                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 948                 //extend the pause of rotting if client was reset at the beginning of the countdown
 949                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 950                         self.spawnshieldtime += game_starttime - time;
 951                         self.pauserotarmor_finished += game_starttime - time;
 952                         self.pauserothealth_finished += game_starttime - time;
 953                         self.pauseregen_finished += game_starttime - time;
 954                 }
 955                 self.damageforcescale = 2;
 956                 self.death_time = 0;
 957                 self.dead_frame = 0;
 958                 self.alpha = 0;
 959                 self.scale = 0;
 960                 self.fade_time = 0;
 961                 self.pain_frame = 0;
 962                 self.pain_finished = 0;
 963                 self.strength_finished = 0;
 964                 self.invincible_finished = 0;
 965                 self.pushltime = 0;
 966                 // players have no think function
 967                 self.think = SUB_Null;
 968                 self.nextthink = 0;
 969                 self.hook_time = 0;
 970                 self.dmg_team = 0;
 971                 self.ballistics_density = autocvar_g_ballistics_density_player;
 972
 973                 self.metertime = 0;
 974
 975                 self.runes = 0;
 976
 977                 self.deadflag = DEAD_NO;
 978
 979                 self.angles = spot.angles;
 980
 981                 self.angles_z = 0; // never spawn tilted even if the spot says to
 982                 self.fixangle = TRUE; // turn this way immediately
 983                 self.velocity = '0 0 0';
 984                 self.avelocity = '0 0 0';
 985                 self.punchangle = '0 0 0';
 986                 self.punchvector = '0 0 0';
 987                 self.oldvelocity = self.velocity;
 988                 self.fire_endtime = -1;
 989
 990                 msg_entity = self;
 991                 WRITESPECTATABLE_MSG_ONE({
 992                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 993                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 994                 });
 995
 996                 if(sv_loddistance1)
 997                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 998
 999                 self.model = "";
1000                 FixPlayermodel();
1001
1002                 self.crouch = FALSE;
1003                 self.view_ofs = PL_VIEW_OFS;
1004                 setsize (self, PL_MIN, PL_MAX);
1005                 self.spawnorigin = spot.origin;
1006                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1007                 // don't reset back to last position, even if new position is stuck in solid
1008                 self.oldorigin = self.origin;
1009                 self.prevorigin = self.origin;
1010                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1011
1012                 if(g_arena)
1013                 {
1014                         Spawnqueue_Remove(self);
1015                         Spawnqueue_Mark(self);
1016                 }
1017
1018                 else if(g_ca)
1019                         self.caplayer = 1;
1020
1021                 self.event_damage = PlayerDamage;
1022
1023                 self.bot_attack = TRUE;
1024
1025                 self.statdraintime = time + 5;
1026                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1027
1028                 if(self.killcount == -666) {
1029                         PlayerScore_Clear(self);
1030                         self.killcount = 0;
1031                 }
1032
1033                 self.cnt = WEP_LASER;
1034
1035                 CL_SpawnWeaponentity();
1036                 self.alpha = default_player_alpha;
1037                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1038                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1039
1040                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1041                 self.lms_traveled_distance = 0;
1042                 self.speedrunning = FALSE;
1043
1044                 race_PostSpawn(spot);
1045
1046                 if(autocvar_spawn_debug)
1047                 {
1048                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1049                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1050                 }
1051
1052                 //stuffcmd(self, "chase_active 0");
1053                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1054
1055                 if (autocvar_g_spawnsound)
1056                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1057
1058                 if(g_assault) {
1059                         if(self.team == assault_attacker_team)
1060                                 centerprint(self, "You are attacking!");
1061                         else
1062                                 centerprint(self, "You are defending!");
1063                 }
1064
1065                 target_voicescript_clear(self);
1066
1067                 // reset fields the weapons may use
1068                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1069                         weapon_action(j, WR_RESETPLAYER);
1070
1071                 oldself = self;
1072                 self = spot;
1073                         activator = oldself;
1074                                 SUB_UseTargets();
1075                         activator = world;
1076                 self = oldself;
1077
1078                 MUTATOR_CALLHOOK(PlayerSpawn);
1079
1080                 self.switchweapon = w_getbestweapon(self);
1081                 self.cnt = self.switchweapon;
1082                 self.weapon = 0;
1083
1084                 if(!self.alivetime)
1085                         self.alivetime = time;
1086         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1087                 PutObserverInServer ();
1088         }
1089
1090         //if(g_ctf)
1091         //      ctf_playerchanged();
1092 }
1093
1094 .float ebouncefactor, ebouncestop; // electro's values
1095 // TODO do we need all these fields, or should we stop autodetecting runtime
1096 // changes and just have a console command to update this?
1097 float ClientInit_SendEntity(entity to, float sf)
1098 {
1099         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1100         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1110         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1111         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1112         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1113         if(sv_foginterval && world.fog != "")
1114                 WriteString(MSG_ENTITY, world.fog);
1115         else
1116                 WriteString(MSG_ENTITY, "");
1117         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1118         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1119         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1120         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1121         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1122         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1123         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1124         WriteByte(MSG_ENTITY, autocvar_g_balance_campingrifle_secondary); // client has to know if it should zoom or not
1125         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1126         return TRUE;
1127 }
1128
1129 void ClientInit_CheckUpdate()
1130 {
1131         self.nextthink = time;
1132         if(self.count != autocvar_g_balance_armor_blockpercent)
1133         {
1134                 self.count = autocvar_g_balance_armor_blockpercent;
1135                 self.SendFlags |= 1;
1136         }
1137         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1138         {
1139                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1140                 self.SendFlags |= 1;
1141         }
1142         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1143         {
1144                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1145                 self.SendFlags |= 1;
1146         }
1147         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1148         {
1149                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1150                 self.SendFlags |= 1;
1151         }
1152         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1153         {
1154                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1155                 self.SendFlags |= 1;
1156         }
1157         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1158         {
1159                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1160                 self.SendFlags |= 1;
1161         }
1162 }
1163
1164 void ClientInit_Spawn()
1165 {
1166         entity o;
1167         entity e;
1168         e = spawn();
1169         e.classname = "clientinit";
1170         e.think = ClientInit_CheckUpdate;
1171         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1172
1173         o = self;
1174         self = e;
1175         ClientInit_CheckUpdate();
1176         self = o;
1177 }
1178
1179 /*
1180 =============
1181 SetNewParms
1182 =============
1183 */
1184 void SetNewParms (void)
1185 {
1186         // initialize parms for a new player
1187         parm1 = -(86400 * 366);
1188 }
1189
1190 /*
1191 =============
1192 SetChangeParms
1193 =============
1194 */
1195 void SetChangeParms (void)
1196 {
1197         // save parms for level change
1198         parm1 = self.parm_idlesince - time;
1199 }
1200
1201 /*
1202 =============
1203 DecodeLevelParms
1204 =============
1205 */
1206 void DecodeLevelParms (void)
1207 {
1208         // load parms
1209         self.parm_idlesince = parm1;
1210         if(self.parm_idlesince == -(86400 * 366))
1211                 self.parm_idlesince = time;
1212
1213         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1214         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1215 }
1216
1217 /*
1218 =============
1219 ClientKill
1220
1221 Called when a client types 'kill' in the console
1222 =============
1223 */
1224
1225 void ClientKill_Now_TeamChange()
1226 {
1227         if(self.killindicator_teamchange == -1)
1228         {
1229                 self.team = -1;
1230                 JoinBestTeam( self, FALSE, FALSE );
1231         }
1232         else
1233                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1234 }
1235
1236 void ClientKill_Now()
1237 {
1238         if(self.killindicator_teamchange)
1239                 ClientKill_Now_TeamChange();
1240
1241         // in any case:
1242         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1243
1244         if(self.killindicator)
1245         {
1246                 dprint("Cleaned up after a leaked kill indicator.\n");
1247                 remove(self.killindicator);
1248                 self.killindicator = world;
1249         }
1250 }
1251 void KillIndicator_Think()
1252 {
1253         if (!self.owner.modelindex)
1254         {
1255                 self.owner.killindicator = world;
1256                 remove(self);
1257                 return;
1258         }
1259
1260         if(self.cnt <= 0)
1261         {
1262                 self = self.owner;
1263                 ClientKill_Now(); // no oldself needed
1264                 return;
1265         }
1266         else
1267         {
1268                 if(self.cnt <= 10)
1269                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1270                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1271                 {
1272                         if(self.cnt <= 10)
1273                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1274                         if(self.owner.killindicator_teamchange)
1275                         {
1276                                 if(self.owner.killindicator_teamchange == -1)
1277                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1278                                 else
1279                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1280                         }
1281                         else
1282                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1283                 }
1284                 self.nextthink = time + 1;
1285                 self.cnt -= 1;
1286         }
1287 }
1288
1289 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1290 {
1291         float killtime;
1292         entity e;
1293         killtime = autocvar_g_balance_kill_delay;
1294
1295         if(g_race_qualifying)
1296                 killtime = 0;
1297
1298         self.killindicator_teamchange = targetteam;
1299
1300         if(!self.killindicator)
1301         {
1302                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1303                 {
1304                         ClientKill_Now();
1305                 }
1306                 else
1307                 {
1308                         self.killindicator = spawn();
1309                         self.killindicator.owner = self;
1310                         self.killindicator.scale = 0.5;
1311                         setattachment(self.killindicator, self, "");
1312                         setorigin(self.killindicator, '0 0 52');
1313                         self.killindicator.think = KillIndicator_Think;
1314                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1315                         self.killindicator.cnt = ceil(killtime);
1316                         self.killindicator.count = bound(0, ceil(killtime), 10);
1317                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1318
1319                         for(e = world; (e = find(e, classname, "body")) != world; )
1320                         {
1321                                 if(e.enemy != self)
1322                                         continue;
1323                                 e.killindicator = spawn();
1324                                 e.killindicator.owner = e;
1325                                 e.killindicator.scale = 0.5;
1326                                 setattachment(e.killindicator, e, "");
1327                                 setorigin(e.killindicator, '0 0 52');
1328                                 e.killindicator.think = KillIndicator_Think;
1329                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1330                                 e.killindicator.cnt = ceil(killtime);
1331                         }
1332                         self.lip = 0;
1333                 }
1334         }
1335         if(self.killindicator)
1336         {
1337                 if(targetteam)
1338                         self.killindicator.colormod = TeamColor(targetteam);
1339                 else
1340                         self.killindicator.colormod = '0 0 0';
1341         }
1342 }
1343
1344 void ClientKill (void)
1345 {
1346         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1347         {
1348                 // do nothing
1349         }
1350     else if(g_freezetag && self.freezetag_frozen == 1)
1351     {
1352         // do nothing
1353     }
1354         else
1355                 ClientKill_TeamChange(0);
1356 }
1357
1358 void CTS_ClientKill_Think (void)
1359 {
1360         self = self.owner; // set self to the player to be killed
1361         sprint(self, "^1You were killed in order to prevent cheating!");
1362         ClientKill_Now();
1363 }
1364
1365 void CTS_ClientKill (float t) // silent version of ClientKill
1366 {
1367         entity e;
1368         e = spawn();
1369         e.owner = self;
1370         e.think = CTS_ClientKill_Think;
1371         e.nextthink = t;
1372 }
1373
1374 void DoTeamChange(float destteam)
1375 {
1376         float t, c0;
1377         if(!teams_matter)
1378         {
1379                 if(destteam >= 0)
1380                         SetPlayerColors(self, destteam);
1381                 return;
1382         }
1383         if(self.classname == "player")
1384         if(destteam == -1)
1385         {
1386                 CheckAllowedTeams(self);
1387                 t = FindSmallestTeam(self, TRUE);
1388                 switch(self.team)
1389                 {
1390                         case COLOR_TEAM1: c0 = c1; break;
1391                         case COLOR_TEAM2: c0 = c2; break;
1392                         case COLOR_TEAM3: c0 = c3; break;
1393                         case COLOR_TEAM4: c0 = c4; break;
1394                         default:          c0 = 999;
1395                 }
1396                 switch(t)
1397                 {
1398                         case 1:
1399                                 if(c0 > c1)
1400                                         destteam = COLOR_TEAM1;
1401                                 break;
1402                         case 2:
1403                                 if(c0 > c2)
1404                                         destteam = COLOR_TEAM2;
1405                                 break;
1406                         case 3:
1407                                 if(c0 > c3)
1408                                         destteam = COLOR_TEAM3;
1409                                 break;
1410                         case 4:
1411                                 if(c0 > c4)
1412                                         destteam = COLOR_TEAM4;
1413                                 break;
1414                 }
1415                 if(destteam == -1)
1416                         return;
1417         }
1418         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1419                 return;
1420         ClientKill_TeamChange(destteam);
1421 }
1422
1423 void FixClientCvars(entity e)
1424 {
1425         // send prediction settings to the client
1426         stuffcmd(e, "\nin_bindmap 0 0\n");
1427         if(g_race || g_cts)
1428                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1429         if(autocvar_g_antilag == 3) // client side hitscan
1430                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1431         if(sv_gentle)
1432                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1433         /*
1434          * we no longer need to stuff this. Remove this comment block if you feel
1435          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1436         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1437         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1438         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1439         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1440         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1441         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1442         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1443         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1444         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1445         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1446         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1447         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1448         stuffcmd(e, "cl_movement_edgefriction 1\n");
1449          */
1450 }
1451
1452 float PlayerInIDList(entity p, string idlist)
1453 {
1454         float n, i;
1455         string s;
1456
1457         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1458         if not(p.crypto_idfp)
1459                 return 0;
1460
1461         // this function allows abbreviated player IDs too!
1462         n = tokenize_console(idlist);
1463         for(i = 0; i < n; ++i)
1464         {
1465                 s = argv(i);
1466                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1467                         return 1;
1468         }
1469
1470         return 0;
1471 }
1472
1473 /*
1474 =============
1475 ClientConnect
1476
1477 Called when a client connects to the server
1478 =============
1479 */
1480 //void ctf_clientconnect();
1481 string ColoredTeamName(float t);
1482 void DecodeLevelParms (void);
1483 //void dom_player_join_team(entity pl);
1484 void ClientConnect (void)
1485 {
1486         float t;
1487
1488         if(self.flags & FL_CLIENT)
1489         {
1490                 print("Warning: ClientConnect, but already connected!\n");
1491                 return;
1492         }
1493
1494         if(Ban_MaybeEnforceBan(self))
1495                 return;
1496
1497         DecodeLevelParms();
1498
1499 #ifdef WATERMARK
1500         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1501 #endif
1502
1503         self.classname = "player_joining";
1504
1505         self.flags = FL_CLIENT;
1506         self.version_nagtime = time + 10 + random() * 10;
1507
1508         if(player_count<0)
1509         {
1510                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1511                 player_count = 0;
1512         }
1513
1514         PlayerScore_Attach(self);
1515         ClientData_Attach();
1516         accuracy_init(self);
1517
1518         bot_clientconnect();
1519
1520         playerdemo_init();
1521
1522         anticheat_init();
1523
1524         race_PreSpawnObserver();
1525
1526         //if(g_domination)
1527         //      dom_player_join_team(self);
1528
1529         // identify the right forced team
1530         if(autocvar_g_campaign)
1531         {
1532                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1533                 {
1534                         switch(autocvar_g_campaign_forceteam)
1535                         {
1536                                 case 1: self.team_forced = COLOR_TEAM1; break;
1537                                 case 2: self.team_forced = COLOR_TEAM2; break;
1538                                 case 3: self.team_forced = COLOR_TEAM3; break;
1539                                 case 4: self.team_forced = COLOR_TEAM4; break;
1540                                 default: self.team_forced = 0;
1541                         }
1542                 }
1543         }
1544         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1545                 self.team_forced = COLOR_TEAM1;
1546         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1547                 self.team_forced = COLOR_TEAM2;
1548         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1549                 self.team_forced = COLOR_TEAM3;
1550         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1551                 self.team_forced = COLOR_TEAM4;
1552         else if(autocvar_g_forced_team_otherwise == "red")
1553                 self.team_forced = COLOR_TEAM1;
1554         else if(autocvar_g_forced_team_otherwise == "blue")
1555                 self.team_forced = COLOR_TEAM2;
1556         else if(autocvar_g_forced_team_otherwise == "yellow")
1557                 self.team_forced = COLOR_TEAM3;
1558         else if(autocvar_g_forced_team_otherwise == "pink")
1559                 self.team_forced = COLOR_TEAM4;
1560         else if(autocvar_g_forced_team_otherwise == "spectate")
1561                 self.team_forced = -1;
1562         else if(autocvar_g_forced_team_otherwise == "spectator")
1563                 self.team_forced = -1;
1564         else
1565                 self.team_forced = 0;
1566
1567         if(!teams_matter)
1568                 if(self.team_forced > 0)
1569                         self.team_forced = 0;
1570
1571         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1572
1573         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1574                 self.classname = "observer";
1575         } else {
1576                 if(teams_matter)
1577                 {
1578                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1579                         {
1580                                 self.classname = "player";
1581                                 campaign_bots_may_start = 1;
1582                         }
1583                         else
1584                         {
1585                                 self.classname = "observer"; // do it anyway
1586                         }
1587                 }
1588                 else
1589                 {
1590                         self.classname = "player";
1591                         campaign_bots_may_start = 1;
1592                 }
1593         }
1594
1595         self.playerid = (playerid_last = playerid_last + 1);
1596
1597         if(autocvar_sv_eventlog)
1598                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1599
1600         LogTeamchange(self.playerid, self.team, 1);
1601
1602         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1603
1604         self.netname_previous = strzone(self.netname);
1605
1606         bprint("^4", self.netname, "^4 connected");
1607
1608         if(self.classname != "observer" && (g_domination || g_ctf))
1609                 bprint(" and joined the ", ColoredTeamName(self.team));
1610
1611         bprint("\n");
1612
1613         self.welcomemessage_time = 0;
1614
1615         stuffcmd(self, strcat(clientstuff, "\n"));
1616         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1617         stuffcmd(self, "cl_particles_reloadeffects\n");
1618
1619         FixClientCvars(self);
1620
1621         // spawnfunc_waypoint sprites
1622         WaypointSprite_InitClient(self);
1623
1624         // Wazat's grappling hook
1625         SetGrappleHookBindings();
1626
1627         // get autoswitch state from player when he toggles it
1628         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1629
1630         // get version info from player
1631         stuffcmd(self, "cmd clientversion $gameversion\n");
1632
1633         // get other cvars from player
1634         GetCvars(0);
1635
1636         // notify about available teams
1637         if(teams_matter)
1638         {
1639                 CheckAllowedTeams(self);
1640                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1641                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1642         }
1643         else
1644                 stuffcmd(self, "set _teams_available 0\n");
1645
1646         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1647
1648         if(g_arena || g_ca)
1649         {
1650                 self.classname = "observer";
1651                 if(g_arena)
1652                         Spawnqueue_Insert(self);
1653         }
1654         /*else if(g_ctf)
1655         {
1656                 ctf_clientconnect();
1657         }*/
1658
1659         if(teams_matter || radar_showennemies)
1660                 attach_entcs();
1661
1662         bot_relinkplayerlist();
1663
1664         self.spectatortime = time;
1665         if(blockSpectators)
1666         {
1667                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1668         }
1669
1670         self.jointime = time;
1671         self.allowedTimeouts = autocvar_sv_timeout_number;
1672
1673         if(clienttype(self) == CLIENTTYPE_REAL)
1674         {
1675                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1676                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1677         }
1678
1679         if(g_lms)
1680         {
1681                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1682                 {
1683                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1684                         self.frags = FRAGS_SPECTATOR;
1685                 }
1686         }
1687
1688         if(!sv_foginterval && world.fog != "")
1689                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1690
1691         SoundEntity_Attach(self);
1692
1693         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1694         {
1695                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1696                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1697         }
1698         else
1699                 self.hitplotfh = -1;
1700
1701         if(g_race || g_cts) {
1702                 string rr;
1703                 if(g_cts)
1704                         rr = CTS_RECORD;
1705                 else
1706                         rr = RACE_RECORD;
1707                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1708
1709                 msg_entity = self;
1710                 race_send_recordtime(MSG_ONE);
1711                 race_send_speedaward(MSG_ONE);
1712
1713                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1714                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1715                 race_send_speedaward_alltimebest(MSG_ONE);
1716
1717                 float i;
1718                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1719                         race_SendRankings(i, 0, 0, MSG_ONE);
1720                 }
1721         }
1722         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1723                 send_CSQC_teamnagger();
1724
1725         send_CSQC_cr_maxbullets(self);
1726
1727         CheatInitClient();
1728
1729         PlayerStats_AddPlayer(self);
1730 }
1731
1732 /*
1733 =============
1734 ClientDisconnect
1735
1736 Called when a client disconnects from the server
1737 =============
1738 */
1739 .entity chatbubbleentity;
1740 .entity teambubbleentity;
1741 void ReadyCount();
1742 void ClientDisconnect (void)
1743 {
1744         if not(self.flags & FL_CLIENT)
1745         {
1746                 print("Warning: ClientDisconnect without ClientConnect\n");
1747                 return;
1748         }
1749
1750         PlayerStats_AddGlobalInfo(self);
1751
1752         CheatShutdownClient();
1753
1754         if(self.hitplotfh >= 0)
1755         {
1756                 fclose(self.hitplotfh);
1757                 self.hitplotfh = -1;
1758         }
1759
1760         anticheat_report();
1761         anticheat_shutdown();
1762
1763         playerdemo_shutdown();
1764
1765         bot_clientdisconnect();
1766
1767         if(self.entcs)
1768                 detach_entcs();
1769
1770         if(autocvar_sv_eventlog)
1771                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1772         bprint ("^4",self.netname);
1773         bprint ("^4 disconnected\n");
1774
1775         SoundEntity_Detach(self);
1776
1777         DropAllRunes(self);
1778         MUTATOR_CALLHOOK(ClientDisconnect);
1779
1780         Portal_ClearAll(self);
1781
1782         if(self.flagcarried)
1783                 DropFlag(self.flagcarried, world, world);
1784         if(self.ballcarried && g_nexball)
1785                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1786
1787         // Here, everything has been done that requires this player to be a client.
1788
1789         self.flags &~= FL_CLIENT;
1790
1791         if (self.chatbubbleentity)
1792                 remove (self.chatbubbleentity);
1793
1794         if (self.teambubbleentity)
1795                 remove (self.teambubbleentity);
1796
1797         if (self.killindicator)
1798                 remove (self.killindicator);
1799
1800         WaypointSprite_PlayerGone();
1801
1802         bot_relinkplayerlist();
1803
1804         if(g_arena)
1805         {
1806                 Spawnqueue_Unmark(self);
1807                 Spawnqueue_Remove(self);
1808         }
1809
1810         accuracy_free(self);
1811         ClientData_Detach();
1812         PlayerScore_Detach(self);
1813
1814         if(self.netname_previous)
1815                 strunzone(self.netname_previous);
1816         if(self.clientstatus)
1817                 strunzone(self.clientstatus);
1818         if(self.weaponorder_byimpulse)
1819                 strunzone(self.weaponorder_byimpulse);
1820
1821         ClearPlayerSounds();
1822
1823         if(self.personal)
1824                 remove(self.personal);
1825
1826         self.playerid = 0;
1827         ReadyCount();
1828
1829         // free cvars
1830         GetCvars(-1);
1831 }
1832
1833 .float BUTTON_CHAT;
1834 void ChatBubbleThink()
1835 {
1836         self.nextthink = time;
1837         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1838         {
1839                 if(self.owner) // but why can that ever be world?
1840                         self.owner.chatbubbleentity = world;
1841                 remove(self);
1842                 return;
1843         }
1844         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1845 #ifdef TETRIS
1846                 || self.owner.tetris_on
1847 #endif
1848         )
1849                 self.model = self.mdl;
1850         else
1851                 self.model = "";
1852 };
1853
1854 void UpdateChatBubble()
1855 {
1856         if (!self.modelindex)
1857                 return;
1858         // spawn a chatbubble entity if needed
1859         if (!self.chatbubbleentity)
1860         {
1861                 self.chatbubbleentity = spawn();
1862                 self.chatbubbleentity.owner = self;
1863                 self.chatbubbleentity.exteriormodeltoclient = self;
1864                 self.chatbubbleentity.think = ChatBubbleThink;
1865                 self.chatbubbleentity.nextthink = time;
1866                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1867                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1868                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1869                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1870                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1871                 self.chatbubbleentity.model = "";
1872                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1873         }
1874 }
1875
1876
1877 void TeamBubbleThink()
1878 {
1879         self.nextthink = time;
1880         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1881         {
1882                 if(self.owner) // but why can that ever be world?
1883                         self.owner.teambubbleentity = world;
1884                 remove(self);
1885                 return;
1886         }
1887 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1888         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1889                 self.model = "";
1890         else
1891                 self.model = self.mdl;
1892
1893 };
1894
1895 float TeamBubble_customizeentityforclient()
1896 {
1897         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1898 }
1899
1900 void UpdateTeamBubble()
1901 {
1902         if (!self.modelindex || !teams_matter)
1903                 return;
1904         // spawn a teambubble entity if needed
1905         if (!self.teambubbleentity && teams_matter)
1906         {
1907                 self.teambubbleentity = spawn();
1908                 self.teambubbleentity.owner = self;
1909                 self.teambubbleentity.exteriormodeltoclient = self;
1910                 self.teambubbleentity.think = TeamBubbleThink;
1911                 self.teambubbleentity.nextthink = time;
1912                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1913 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1914                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1915                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1916                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1917                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1918                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1919                 self.teambubbleentity.effects = EF_LOWPRECISION;
1920         }
1921 }
1922
1923 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1924 // added to the model skins
1925 /*void UpdateColorModHack()
1926 {
1927         local float c;
1928         c = self.clientcolors & 15;
1929         // LordHavoc: only bothering to support white, green, red, yellow, blue
1930              if (!teams_matter) self.colormod = '0 0 0';
1931         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1932         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1933         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1934         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1935         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1936         else self.colormod = '1 1 1';
1937 };*/
1938
1939 .float oldcolormap;
1940 void respawn(void)
1941 {
1942         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1943         {
1944                 self.solid = SOLID_NOT;
1945                 self.takedamage = DAMAGE_NO;
1946                 self.movetype = MOVETYPE_FLY;
1947                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1948                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1949                 self.effects |= EF_ADDITIVE;
1950                 self.oldcolormap = self.colormap;
1951                 self.colormap = 512;
1952                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1953                 if(autocvar_g_respawn_ghosts_maxtime)
1954                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1955         }
1956
1957         CopyBody(1);
1958         self.effects |= EF_NODRAW; // prevent another CopyBody
1959         if(self.oldcolormap)
1960         {
1961                 self.colormap = self.oldcolormap;
1962                 self.oldcolormap = 0;
1963         }
1964         PutClientInServer();
1965 }
1966
1967 void play_countdown(float finished, string samp)
1968 {
1969         if(clienttype(self) == CLIENTTYPE_REAL)
1970                 if(floor(finished - time - frametime) != floor(finished - time))
1971                         if(finished - time < 6)
1972                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1973 }
1974
1975 /**
1976  * When sv_timeout is used this function returs strings like
1977  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1978  * Called by centerprint functions
1979  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1980  */
1981 string getTimeoutText(float addOneSecond) {
1982         if (!autocvar_sv_timeout || !timeoutStatus)
1983                 return "";
1984
1985         local string retStr;
1986         if (timeoutStatus == 1) {
1987                 if (addOneSecond == 1) {
1988                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1989                 }
1990                 else {
1991                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1992                 }
1993                 return retStr;
1994         }
1995         else if (timeoutStatus == 2) {
1996                 if (addOneSecond) {
1997                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1998                         //don't show messages like "Timeout ends in 0 seconds"...
1999                         if ((remainingTimeoutTime + 1) > 0)
2000                                 return retStr;
2001                         else
2002                                 return "";
2003                 }
2004                 else {
2005                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2006                         //don't show messages like "Timeout ends in 0 seconds"...
2007                         if (remainingTimeoutTime > 0)
2008                                 return retStr;
2009                         else
2010                                 return "";
2011                 }
2012         }
2013         else return "";
2014 }
2015
2016 void player_powerups (void)
2017 {
2018         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2019         olditems = self.items;
2020
2021         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2022         {
2023                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2024                 self.modelflags |= MF_ROCKET;
2025         }
2026         else
2027         {
2028                 SoundEntity_StopSound(self, CHAN_PLAYER);
2029                 self.modelflags &~= MF_ROCKET;
2030         }
2031
2032         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2033
2034         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2035                 return;
2036
2037         Fire_ApplyDamage(self);
2038         Fire_ApplyEffect(self);
2039
2040         if (g_minstagib)
2041         {
2042                 self.effects |= EF_FULLBRIGHT;
2043
2044                 if (self.items & IT_STRENGTH)
2045                 {
2046                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2047                         if (time > self.strength_finished)
2048                         {
2049                                 self.alpha = default_player_alpha;
2050                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2051                                 self.items &~= IT_STRENGTH;
2052                                 sprint(self, "^3Invisibility has worn off\n");
2053                         }
2054                 }
2055                 else
2056                 {
2057                         if (time < self.strength_finished)
2058                         {
2059                                 self.alpha = g_minstagib_invis_alpha;
2060                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2061                                 self.items |= IT_STRENGTH;
2062                                 sprint(self, "^3You are invisible\n");
2063                         }
2064                 }
2065
2066                 if (self.items & IT_INVINCIBLE)
2067                 {
2068                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2069                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2070                         {
2071                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2072                                 sprint(self, "^3Speed has worn off\n");
2073                         }
2074                 }
2075                 else
2076                 {
2077                         if (time < self.invincible_finished)
2078                         {
2079                                 self.items = self.items | IT_INVINCIBLE;
2080                                 sprint(self, "^3You are on speed\n");
2081                         }
2082                 }
2083         }
2084         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2085         {
2086                 if (self.items & IT_STRENGTH)
2087                 {
2088                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2089                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2090                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2091                         {
2092                                 self.items = self.items - (self.items & IT_STRENGTH);
2093                                 sprint(self, "^3Strength has worn off\n");
2094                         }
2095                 }
2096                 else
2097                 {
2098                         if (time < self.strength_finished)
2099                         {
2100                                 self.items = self.items | IT_STRENGTH;
2101                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2102                         }
2103                 }
2104                 if (self.items & IT_INVINCIBLE)
2105                 {
2106                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2107                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2108                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2109                         {
2110                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2111                                 sprint(self, "^3Shield has worn off\n");
2112                         }
2113                 }
2114                 else
2115                 {
2116                         if (time < self.invincible_finished)
2117                         {
2118                                 self.items = self.items | IT_INVINCIBLE;
2119                                 sprint(self, "^3Shield surrounds you\n");
2120                         }
2121                 }
2122
2123                 if(autocvar_g_nodepthtestplayers)
2124                         self.effects = self.effects | EF_NODEPTHTEST;
2125
2126                 if(autocvar_g_fullbrightplayers)
2127                         self.effects = self.effects | EF_FULLBRIGHT;
2128
2129                 // midair gamemode: damage only while in the air
2130                 // if in midair mode, being on ground grants temporary invulnerability
2131                 // (this is so that multishot weapon don't clear the ground flag on the
2132                 // first damage in the frame, leaving the player vulnerable to the
2133                 // remaining hits in the same frame)
2134                 if (self.flags & FL_ONGROUND)
2135                 if (g_midair)
2136                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2137
2138                 if (time >= game_starttime)
2139                 if (time < self.spawnshieldtime)
2140                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2141         }
2142
2143         MUTATOR_CALLHOOK(PlayerPowerups);
2144 }
2145
2146 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2147 {
2148         if(current > stable)
2149                 return current;
2150         else if(current > stable - 0.25) // when close enough, "snap"
2151                 return stable;
2152         else
2153                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2154 }
2155
2156 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2157 {
2158         if(current < stable)
2159                 return current;
2160         else if(current < stable + 0.25) // when close enough, "snap"
2161                 return stable;
2162         else
2163                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2164 }
2165
2166 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2167 {
2168         if(current > rotstable)
2169         {
2170                 if(rotframetime > 0)
2171                 {
2172                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2173                         current = max(rotstable, current - rotlinear * rotframetime);
2174                 }
2175         }
2176         else if(current < regenstable)
2177         {
2178                 if(regenframetime > 0)
2179                 {
2180                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2181                         current = min(regenstable, current + regenlinear * regenframetime);
2182                 }
2183         }
2184
2185         if(current > limit)
2186                 current = limit;
2187
2188         return current;
2189 }
2190
2191 void player_regen (void)
2192 {
2193         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2194         maxh = autocvar_g_balance_health_rotstable;
2195         maxa = autocvar_g_balance_armor_rotstable;
2196         maxf = autocvar_g_balance_fuel_rotstable;
2197         minh = autocvar_g_balance_health_regenstable;
2198         mina = autocvar_g_balance_armor_regenstable;
2199         minf = autocvar_g_balance_fuel_regenstable;
2200         limith = autocvar_g_balance_health_limit;
2201         limita = autocvar_g_balance_armor_limit;
2202         limitf = autocvar_g_balance_fuel_limit;
2203
2204         max_mod = regen_mod = rot_mod = limit_mod = 1;
2205
2206         if (self.runes & RUNE_REGEN)
2207         {
2208                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2209                 {
2210                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2211                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2212                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2213                 }
2214                 else
2215                 {
2216                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2217                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2218                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2219                 }
2220         }
2221         else if (self.runes & CURSE_VENOM)
2222         {
2223                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2224                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2225                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2226                 else
2227                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2228                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2229                 //if (!self.runes & RUNE_REGEN)
2230                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2231         }
2232         maxh = maxh * max_mod;
2233         //maxa = maxa * max_mod;
2234         //maxf = maxf * max_mod;
2235         minh = minh * max_mod;
2236         //mina = mina * max_mod;
2237         //minf = minf * max_mod;
2238         limith = limith * limit_mod;
2239         limita = limita * limit_mod;
2240         //limitf = limitf * limit_mod;
2241
2242         if(g_lms && g_ca)
2243                 rot_mod = 0;
2244
2245         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2246         {
2247                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2248                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2249
2250                 // if player rotted to death...  die!
2251                 if(self.health < 1)
2252                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2253         }
2254
2255         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2256                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2257 }
2258
2259 float zoomstate_set;
2260 void SetZoomState(float z)
2261 {
2262         if(z != self.zoomstate)
2263         {
2264                 self.zoomstate = z;
2265                 ClientData_Touch(self);
2266         }
2267         zoomstate_set = 1;
2268 }
2269
2270 void GetPressedKeys(void) {
2271         MUTATOR_CALLHOOK(GetPressedKeys);
2272         if (self.movement_x > 0) // get if movement keys are pressed
2273         {       // forward key pressed
2274                 self.pressedkeys |= KEY_FORWARD;
2275                 self.pressedkeys &~= KEY_BACKWARD;
2276         }
2277         else if (self.movement_x < 0)
2278         {       // backward key pressed
2279                 self.pressedkeys |= KEY_BACKWARD;
2280                 self.pressedkeys &~= KEY_FORWARD;
2281         }
2282         else
2283         {       // no x input
2284                 self.pressedkeys &~= KEY_FORWARD;
2285                 self.pressedkeys &~= KEY_BACKWARD;
2286         }
2287
2288         if (self.movement_y > 0)
2289         {       // right key pressed
2290                 self.pressedkeys |= KEY_RIGHT;
2291                 self.pressedkeys &~= KEY_LEFT;
2292         }
2293         else if (self.movement_y < 0)
2294         {       // left key pressed
2295                 self.pressedkeys |= KEY_LEFT;
2296                 self.pressedkeys &~= KEY_RIGHT;
2297         }
2298         else
2299         {       // no y input
2300                 self.pressedkeys &~= KEY_RIGHT;
2301                 self.pressedkeys &~= KEY_LEFT;
2302         }
2303
2304         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2305                 self.pressedkeys |= KEY_JUMP;
2306         else
2307                 self.pressedkeys &~= KEY_JUMP;
2308         if (self.BUTTON_CROUCH)
2309                 self.pressedkeys |= KEY_CROUCH;
2310         else
2311                 self.pressedkeys &~= KEY_CROUCH;
2312 }
2313
2314 /*
2315 ======================
2316 spectate mode routines
2317 ======================
2318 */
2319
2320 void SpectateCopy(entity spectatee) {
2321         other = spectatee;
2322         MUTATOR_CALLHOOK(SpectateCopy);
2323         self.armortype = spectatee.armortype;
2324         self.armorvalue = spectatee.armorvalue;
2325         self.ammo_cells = spectatee.ammo_cells;
2326         self.ammo_shells = spectatee.ammo_shells;
2327         self.ammo_nails = spectatee.ammo_nails;
2328         self.ammo_rockets = spectatee.ammo_rockets;
2329         self.ammo_fuel = spectatee.ammo_fuel;
2330         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2331         self.health = spectatee.health;
2332         self.impulse = 0;
2333         self.items = spectatee.items;
2334         self.last_pickup = spectatee.last_pickup;
2335         self.metertime = spectatee.metertime;
2336         self.strength_finished = spectatee.strength_finished;
2337         self.invincible_finished = spectatee.invincible_finished;
2338         self.pressedkeys = spectatee.pressedkeys;
2339         self.weapons = spectatee.weapons;
2340         self.switchweapon = spectatee.switchweapon;
2341         self.weapon = spectatee.weapon;
2342         self.punchangle = spectatee.punchangle;
2343         self.view_ofs = spectatee.view_ofs;
2344         self.v_angle = spectatee.v_angle;
2345         self.velocity = spectatee.velocity;
2346         self.dmg_take = spectatee.dmg_take;
2347         self.dmg_save = spectatee.dmg_save;
2348         self.dmg_inflictor = spectatee.dmg_inflictor;
2349         self.angles = spectatee.v_angle;
2350         self.fixangle = TRUE;
2351         setorigin(self, spectatee.origin);
2352         setsize(self, spectatee.mins, spectatee.maxs);
2353         SetZoomState(spectatee.zoomstate);
2354
2355         anticheat_spectatecopy(spectatee);
2356 }
2357
2358 float SpectateUpdate() {
2359         if(!self.enemy)
2360                 return 0;
2361
2362         if (self == self.enemy)
2363                 return 0;
2364
2365         if(self.enemy.classname != "player")
2366                 return 0;
2367
2368         SpectateCopy(self.enemy);
2369
2370         return 1;
2371 }
2372
2373 float SpectateNext() {
2374         other = find(self.enemy, classname, "player");
2375
2376         if (!other)
2377                 other = find(other, classname, "player");
2378
2379         if (other)
2380                 self.enemy = other;
2381
2382         if(self.enemy.classname == "player") {
2383                 msg_entity = self;
2384                 WriteByte(MSG_ONE, SVC_SETVIEW);
2385                 WriteEntity(MSG_ONE, self.enemy);
2386                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2387                 self.movetype = MOVETYPE_NONE;
2388                 accuracy_resend(self);
2389
2390                 if(!SpectateUpdate())
2391                         PutObserverInServer();
2392
2393                 return 1;
2394         } else {
2395                 return 0;
2396         }
2397 }
2398
2399 /*
2400 =============
2401 ShowRespawnCountdown()
2402
2403 Update a respawn countdown display.
2404 =============
2405 */
2406 void ShowRespawnCountdown()
2407 {
2408         float number;
2409         if(self.deadflag == DEAD_NO) // just respawned?
2410                 return;
2411         else
2412         {
2413                 number = ceil(self.death_time - time);
2414                 if(number <= 0)
2415                         return;
2416                 if(number <= self.respawn_countdown)
2417                 {
2418                         self.respawn_countdown = number - 1;
2419                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2420                                 AnnounceTo(self, strcat(ftos(number), ""));
2421                 }
2422         }
2423 }
2424
2425 void LeaveSpectatorMode()
2426 {
2427         if(isJoinAllowed()) {
2428                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2429                         self.classname = "player";
2430
2431                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2432                                 JoinBestTeam(self, FALSE, TRUE);
2433
2434                         if(autocvar_g_campaign)
2435                                 campaign_bots_may_start = 1;
2436
2437                         PutClientInServer();
2438
2439                         if(self.classname == "player")
2440                                 bprint ("^4", self.netname, "^4 is playing now\n");
2441
2442                         if(!autocvar_g_campaign)
2443                                 centerprint(self,""); // clear MOTD
2444
2445                         return;
2446                 } else {
2447                         if (g_ca && self.caplayer) {
2448                         }       // do nothing
2449                         else
2450                                 stuffcmd(self,"menu_showteamselect\n");
2451                         return;
2452                 }
2453         }
2454         else {
2455                 //player may not join because of g_maxplayers is set
2456                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2457         }
2458 }
2459
2460 /**
2461  * Determines whether the player is allowed to join. This depends on cvar
2462  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2463  * it checks whether the number of currently playing players exceeds g_maxplayers.
2464  * @return bool TRUE if the player is allowed to join, false otherwise
2465  */
2466 float isJoinAllowed() {
2467         if(self.team_forced < 0)
2468                 return FALSE; // forced spectators can never join
2469
2470         if (!autocvar_g_maxplayers)
2471                 return TRUE;
2472
2473         local entity e;
2474         local float currentlyPlaying;
2475         FOR_EACH_REALPLAYER(e) {
2476                 if(e.classname == "player")
2477                         currentlyPlaying += 1;
2478         }
2479         if(currentlyPlaying < autocvar_g_maxplayers)
2480                 return TRUE;
2481
2482         return FALSE;
2483 }
2484
2485 /**
2486  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2487  * g_maxplayers_spectator_blocktime seconds
2488  */
2489 void checkSpectatorBlock() {
2490         if(self.classname == "spectator" || self.classname == "observer") {
2491                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2492                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2493                         dropclient(self);
2494                 }
2495         }
2496 }
2497
2498 void ObserverThink()
2499 {
2500         if (self.flags & FL_JUMPRELEASED) {
2501                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2502                         self.welcomemessage_time = 0;
2503                         self.flags &~= FL_JUMPRELEASED;
2504                         self.flags |= FL_SPAWNING;
2505                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2506                         self.welcomemessage_time = 0;
2507                         self.flags &~= FL_JUMPRELEASED;
2508                         if(SpectateNext() == 1) {
2509                                 self.classname = "spectator";
2510                         }
2511                 }
2512         } else {
2513                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2514                         self.flags |= FL_JUMPRELEASED;
2515                         if(self.flags & FL_SPAWNING)
2516                         {
2517                                 self.flags &~= FL_SPAWNING;
2518                                 LeaveSpectatorMode();
2519                                 return;
2520                         }
2521                 }
2522         }
2523         PrintWelcomeMessage(self);
2524 }
2525
2526 void SpectatorThink()
2527 {
2528         if (self.flags & FL_JUMPRELEASED) {
2529                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2530                         self.welcomemessage_time = 0;
2531                         self.flags &~= FL_JUMPRELEASED;
2532                         self.flags |= FL_SPAWNING;
2533                 } else if(self.BUTTON_ATCK) {
2534                         self.welcomemessage_time = 0;
2535                         self.flags &~= FL_JUMPRELEASED;
2536                         if(SpectateNext() == 1) {
2537                                 self.classname = "spectator";
2538                         } else {
2539                                 self.classname = "observer";
2540                                 PutClientInServer();
2541                         }
2542                 } else if (self.BUTTON_ATCK2) {
2543                         self.welcomemessage_time = 0;
2544                         self.flags &~= FL_JUMPRELEASED;
2545                         self.classname = "observer";
2546                         PutClientInServer();
2547                 } else {
2548                         if(!SpectateUpdate())
2549                                 PutObserverInServer();
2550                 }
2551         } else {
2552                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2553                         self.flags |= FL_JUMPRELEASED;
2554                         if(self.flags & FL_SPAWNING)
2555                         {
2556                                 self.flags &~= FL_SPAWNING;
2557                                 LeaveSpectatorMode();
2558                                 return;
2559                         }
2560                 }
2561         }
2562
2563         PrintWelcomeMessage(self);
2564         self.flags |= FL_CLIENT | FL_NOTARGET;
2565 }
2566
2567 .float touchexplode_time;
2568
2569 /*
2570 =============
2571 PlayerPreThink
2572
2573 Called every frame for each client before the physics are run
2574 =============
2575 */
2576 void() ctf_setstatus;
2577 void() nexball_setstatus;
2578 .float items_added;
2579 void PlayerPreThink (void)
2580 {
2581         self.stat_game_starttime = game_starttime;
2582         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2583         self.stat_leadlimit = autocvar_leadlimit;
2584
2585         if(frametime)
2586         {
2587                 // physics frames: update anticheat stuff
2588                 anticheat_prethink();
2589         }
2590
2591         if(blockSpectators && frametime)
2592                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2593                 checkSpectatorBlock();
2594
2595         zoomstate_set = 0;
2596
2597         if(self.netname_previous != self.netname)
2598         {
2599                 if(autocvar_sv_eventlog)
2600                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2601                 if(self.netname_previous)
2602                         strunzone(self.netname_previous);
2603                 self.netname_previous = strzone(self.netname);
2604         }
2605
2606         // version nagging
2607         if(self.version_nagtime)
2608                 if(self.cvar_g_xonoticversion)
2609                         if(time > self.version_nagtime)
2610                         {
2611                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2612                                 {
2613                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2614                                         {
2615                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2616                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2617                                         }
2618                                         else
2619                                         {
2620                                                 float r;
2621                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2622                                                 if(r < 0)
2623                                                 {
2624                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2625                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2626                                                 }
2627                                                 else if(r > 0)
2628                                                 {
2629                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2630                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2631                                                 }
2632                                         }
2633                                 }
2634                                 self.version_nagtime = 0;
2635                         }
2636
2637         // GOD MODE info
2638         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2639         {
2640                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2641                 self.max_armorvalue = 0;
2642         }
2643
2644 #ifdef TETRIS
2645         if (TetrisPreFrame())
2646                 return;
2647 #endif
2648
2649         MUTATOR_CALLHOOK(PlayerPreThink);
2650
2651         if(self.classname == "player") {
2652 //              if(self.netname == "Wazat")
2653 //                      bprint(self.classname, "\n");
2654
2655                 CheckRules_Player();
2656
2657                 PrintWelcomeMessage(self);
2658
2659                 if (intermission_running)
2660                 {
2661                         IntermissionThink ();   // otherwise a button could be missed between
2662                         return;                                 // the think tics
2663                 }
2664
2665                 if(self.teleport_time)
2666                 if(time > self.teleport_time)
2667                 {
2668                         self.teleport_time = 0;
2669                         self.effects = self.effects - (self.effects & EF_NODRAW);
2670                 }
2671
2672                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2673                         UpdateSelectedPlayer();
2674
2675                 //don't allow the player to turn around while game is paused!
2676                 if(timeoutStatus == 2) {
2677                         self.v_angle = self.lastV_angle;
2678                         self.angles = self.lastV_angle;
2679                         self.fixangle = TRUE;
2680                 }
2681
2682                 if(frametime)
2683                 {
2684                         if(self.health <= 0 && autocvar_g_deathglow)
2685                         {
2686                                 if(self.glowmod_x > 0)
2687                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2688                                 else
2689                                         self.glowmod_x = -1;
2690                                 if(self.glowmod_y > 0)
2691                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2692                                 else
2693                                         self.glowmod_y = -1;
2694                                 if(self.glowmod_z > 0)
2695                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2696                                 else
2697                                         self.glowmod_z = -1;
2698                         }
2699                         else
2700                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2701                         player_powerups();
2702                 }
2703
2704                 if (self.deadflag != DEAD_NO)
2705                 {
2706                         float button_pressed, force_respawn;
2707                         if(self.personal && g_race_qualifying)
2708                         {
2709                                 if(time > self.death_time)
2710                                 {
2711                                         self.death_time = time + 1; // only retry once a second
2712                                         respawn();
2713                                         self.impulse = 141;
2714                                 }
2715                         }
2716                         else
2717                         {
2718                                 if(frametime)
2719                                         player_anim();
2720                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2721                                 force_respawn = (g_lms || (g_ca) || autocvar_g_forced_respawn);
2722                                 if (self.deadflag == DEAD_DYING)
2723                                 {
2724                                         if(force_respawn)
2725                                                 self.deadflag = DEAD_RESPAWNING;
2726                                         else if(!button_pressed)
2727                                                 self.deadflag = DEAD_DEAD;
2728                                 }
2729                                 else if (self.deadflag == DEAD_DEAD)
2730                                 {
2731                                         if(button_pressed)
2732                                                 self.deadflag = DEAD_RESPAWNABLE;
2733                                 }
2734                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2735                                 {
2736                                         if(!button_pressed)
2737                                                 self.deadflag = DEAD_RESPAWNING;
2738                                 }
2739                                 else if (self.deadflag == DEAD_RESPAWNING)
2740                                 {
2741                                         if(time > self.death_time)
2742                                         {
2743                                                 self.death_time = time + 1; // only retry once a second
2744                                                 respawn();
2745                                         }
2746                                 }
2747                                 ShowRespawnCountdown();
2748                         }
2749                         return;
2750                 }
2751
2752                 if(g_touchexplode)
2753                 if(time > self.touchexplode_time)
2754                 if(self.classname == "player")
2755                 if(self.deadflag == DEAD_NO)
2756                 if not(IS_INDEPENDENT_PLAYER(self))
2757                 FOR_EACH_PLAYER(other) if(self != other)
2758                 {
2759                         if(time > other.touchexplode_time)
2760                         if(other.deadflag == DEAD_NO)
2761                         if not(IS_INDEPENDENT_PLAYER(other))
2762                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2763                         {
2764                                 PlayerTouchExplode(self, other);
2765                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2766                         }
2767                 }
2768
2769                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2770                 {
2771                         vector dist;
2772
2773                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2774                         dist = self.prevorigin - self.origin;
2775                         dist_z = 0;
2776                         self.lms_traveled_distance += fabs(vlen(dist));
2777
2778                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2779                         {
2780                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2781                                 self.lms_traveled_distance = 0;
2782                         }
2783
2784                         if(time > self.lms_nextcheck)
2785                         {
2786                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2787                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2788                                 {
2789                                         centerprint(self, autocvar_g_lms_campcheck_message);
2790                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2791                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2792                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2793                                 }
2794                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2795                                 self.lms_traveled_distance = 0;
2796                         }
2797                 }
2798
2799                 self.prevorigin = self.origin;
2800
2801                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2802                 {
2803                         if (!self.crouch)
2804                         {
2805                                 self.crouch = TRUE;
2806                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2807                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2808                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2809                         }
2810                 }
2811                 else
2812                 {
2813                         if (self.crouch)
2814                         {
2815                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2816                                 if (!trace_startsolid)
2817                                 {
2818                                         self.crouch = FALSE;
2819                                         self.view_ofs = PL_VIEW_OFS;
2820                                         setsize (self, PL_MIN, PL_MAX);
2821                                 }
2822                         }
2823                 }
2824
2825                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2826                 {
2827                         if(self.bloodloss_timer < time)
2828                         {
2829                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2830                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2831                         }
2832                 }
2833
2834                 FixPlayermodel();
2835
2836                 GrapplingHookFrame();
2837
2838                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2839                 //if(frametime)
2840                 {
2841                         self.items &~= self.items_added;
2842
2843                         W_WeaponFrame();
2844
2845                         self.items_added = 0;
2846                         if(self.items & IT_JETPACK)
2847                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2848                                         self.items_added |= IT_FUEL;
2849
2850                         self.items |= self.items_added;
2851                 }
2852
2853                 player_regen();
2854
2855                 // rot nex charge to the charge limit
2856                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2857                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2858
2859                 if(frametime)
2860                         player_anim();
2861
2862                 if (g_minstagib)
2863                         minstagib_ammocheck();
2864
2865                 if(g_ctf)
2866                         ctf_setstatus();
2867
2868                 if(g_nexball)
2869                         nexball_setstatus();
2870
2871                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2872
2873                 //self.angles_y=self.v_angle_y + 90;   // temp
2874         } else if(gameover) {
2875                 if (intermission_running)
2876                         IntermissionThink ();   // otherwise a button could be missed between
2877                 return;
2878         } else if(self.classname == "observer") {
2879                 ObserverThink();
2880         } else if(self.classname == "spectator") {
2881                 SpectatorThink();
2882         }
2883
2884         if(!zoomstate_set)
2885                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && autocvar_g_balance_campingrifle_secondary == 0));
2886
2887         float oldspectatee_status;
2888         oldspectatee_status = self.spectatee_status;
2889         if(self.classname == "spectator")
2890                 self.spectatee_status = num_for_edict(self.enemy);
2891         else if(self.classname == "observer")
2892                 self.spectatee_status = num_for_edict(self);
2893         else
2894                 self.spectatee_status = 0;
2895         if(self.spectatee_status != oldspectatee_status)
2896         {
2897                 ClientData_Touch(self);
2898                 if(g_race || g_cts)
2899                         race_InitSpectator();
2900         }
2901
2902         if(self.teamkill_soundtime)
2903         if(time > self.teamkill_soundtime)
2904         {
2905                 self.teamkill_soundtime = 0;
2906
2907                 entity oldpusher, oldself;
2908
2909                 oldself = self; self = self.teamkill_soundsource;
2910                 oldpusher = self.pusher; self.pusher = oldself;
2911
2912                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2913
2914                 self.pusher = oldpusher;
2915                 self = oldself;
2916         }
2917
2918         if(self.taunt_soundtime)
2919         if(time > self.taunt_soundtime)
2920         {
2921                 self.taunt_soundtime = 0;
2922                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2923         }
2924
2925         target_voicescript_next(self);
2926 }
2927
2928 float isInvisibleString(string s)
2929 {
2930         float i, n, c;
2931         s = strdecolorize(s);
2932         for((i = 0), (n = strlen(s)); i < n; ++i)
2933         {
2934                 c = str2chr(s, i);
2935                 switch(c)
2936                 {
2937                         case 0:
2938                         case 32: // space
2939                                 break;
2940                         case 192: // charmap space
2941                                 if (!autocvar_utf8_enable)
2942                                         break;
2943                                 return FALSE;
2944                         case 160: // space in unicode fonts
2945                         case 0xE000 + 192: // utf8 charmap space
2946                                 if (autocvar_utf8_enable)
2947                                         break;
2948                         default:
2949                                 return FALSE;
2950                 }
2951         }
2952         return TRUE;
2953 }
2954
2955 /*
2956 =============
2957 PlayerPostThink
2958
2959 Called every frame for each client after the physics are run
2960 =============
2961 */
2962 .float idlekick_lasttimeleft;
2963 .entity showheadshotbbox;
2964 void showheadshotbbox_think()
2965 {
2966         if(self.owner.showheadshotbbox != self)
2967         {
2968                 remove(self);
2969                 return;
2970         }
2971         self.nextthink = time;
2972         setorigin(self, self.owner.origin);
2973         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2974 }
2975 void PlayerPostThink (void)
2976 {
2977         // Savage: Check for nameless players
2978         if (isInvisibleString(self.netname)) {
2979                 self.netname = "Player";
2980                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2981         }
2982
2983         if(sv_maxidle && frametime)
2984         {
2985                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2986                 float timeleft;
2987                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2988                 if(timeleft <= 0)
2989                 {
2990                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2991                         AnnounceTo(self, "terminated");
2992                         dropclient(self);
2993                         return;
2994                 }
2995                 else if(timeleft <= 10)
2996                 {
2997                         if(timeleft != self.idlekick_lasttimeleft)
2998                         {
2999                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3000                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3001                         }
3002                 }
3003                 else
3004                 {
3005                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3006                 }
3007                 self.idlekick_lasttimeleft = timeleft;
3008         }
3009
3010 #ifdef TETRIS
3011         if(self.impulse == 100)
3012                 ImpulseCommands();
3013         if (TetrisPostFrame())
3014                 return;
3015 #endif
3016
3017         CheatFrame();
3018
3019         if(self.classname == "player") {
3020                 CheckRules_Player();
3021                 UpdateChatBubble();
3022                 UpdateTeamBubble();
3023                 if (self.impulse)
3024                         ImpulseCommands();
3025                 if (intermission_running)
3026                         return;         // intermission or finale
3027                 GetPressedKeys();
3028         } else if (self.classname == "observer") {
3029                 //do nothing
3030         } else if (self.classname == "spectator") {
3031                 //do nothing
3032         }
3033
3034         /*
3035         float i;
3036         for(i = 0; i < 1000; ++i)
3037         {
3038                 vector end;
3039                 end = self.origin + '0 0 1024' + 512 * randomvec();
3040                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3041                 if(trace_fraction < 1)
3042                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3043                 {
3044                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3045                         break;
3046                 }
3047         }
3048         */
3049
3050         Arena_Warmup();
3051
3052         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3053
3054         if(self.waypointsprite_attachedforcarrier)
3055                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3056
3057         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3058         {
3059                 if(!self.showheadshotbbox)
3060                 {
3061                         self.showheadshotbbox = spawn();
3062                         self.showheadshotbbox.classname = "headshotbbox";
3063                         self.showheadshotbbox.owner = self;
3064                         self.showheadshotbbox.think = showheadshotbbox_think;
3065                         self.showheadshotbbox.nextthink = time;
3066                         self = self.showheadshotbbox;
3067                         self.think();
3068                         self = self.owner;
3069                 }
3070         }
3071         else
3072         {
3073                 if(self.showheadshotbbox)
3074                         remove(self.showheadshotbbox);
3075         }
3076
3077         playerdemo_write();
3078
3079         if((g_cts || g_race) && self.cvar_cl_allow_uid2name == 1)
3080         {
3081                 if(!self.stored_netname)
3082                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3083                 if(self.stored_netname != self.netname)
3084                 {
3085                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3086                         strunzone(self.stored_netname);
3087                         self.stored_netname = strzone(self.netname);
3088                 }
3089         }
3090
3091         /*
3092         if(g_race)
3093                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3094         */
3095 }