forcing teams by player ID (usign cvars g_forced_team_*)
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void send_CSQC_cr_maxbullets(entity e) {
10         msg_entity = e;
11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
14 }
15
16 void Announce(string snd) {
17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
19         WriteString(MSG_ALL, snd);
20 }
21
22 void AnnounceTo(entity e, string snd) {
23         if (clienttype(e) == CLIENTTYPE_REAL)
24         {
25                 msg_entity = e;
26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
28                 WriteString(MSG_ONE, snd);
29         }
30 }
31
32 float ClientData_Send(entity to, float sf)
33 {
34         if(to != self.owner)
35         {
36                 error("wtf");
37                 return FALSE;
38         }
39
40         entity e;
41
42         e = to;
43         if(to.classname == "spectator")
44                 e = to.enemy;
45
46         sf = 0;
47
48         if(e.race_completed)
49                 sf |= 1; // forced scoreboard
50         if(to.spectatee_status)
51                 sf |= 2; // spectator ent number follows
52         if(e.zoomstate)
53                 sf |= 4; // zoomed
54         if(e.porto_v_angle_held)
55                 sf |= 8; // angles held
56
57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
58         WriteByte(MSG_ENTITY, sf);
59
60         if(sf & 2)
61                 WriteByte(MSG_ENTITY, to.spectatee_status);
62
63         if(sf & 8)
64         {
65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
67         }
68
69         return TRUE;
70 }
71
72 void ClientData_Attach()
73 {
74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
75         self.clientdata.drawonlytoclient = self;
76         self.clientdata.owner = self;
77 }
78
79 void ClientData_Detach()
80 {
81         remove(self.clientdata);
82         self.clientdata = world;
83 }
84
85 void ClientData_Touch(entity e)
86 {
87         e.clientdata.SendFlags = 1;
88
89         // make it spectatable
90         entity e2;
91         FOR_EACH_REALCLIENT(e2)
92         {
93                 if(e2 != e)
94                         if(e2.classname == "spectator")
95                                 if(e2.enemy == e)
96                                         e2.clientdata.SendFlags = 1;
97         }
98 }
99
100
101 .vector spawnpoint_score;
102 .string netname_previous;
103
104 void spawnfunc_info_player_survivor (void)
105 {
106         spawnfunc_info_player_deathmatch();
107 }
108
109 void spawnfunc_info_player_start (void)
110 {
111         spawnfunc_info_player_deathmatch();
112 }
113
114 void spawnfunc_info_player_deathmatch (void)
115 {
116         self.classname = "info_player_deathmatch";
117         relocate_spawnpoint();
118 }
119
120 void spawnpoint_use()
121 {
122         if(teams_matter)
123         if(have_team_spawns > 0)
124         {
125                 self.team = activator.team;
126                 some_spawn_has_been_used = 1;
127         }
128 };
129
130 // Returns:
131 //   _x: prio (-1 if unusable)
132 //   _y: weight
133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
134 {
135         float shortest, thisdist;
136         float prio;
137         entity player;
138
139         prio = 0;
140
141         // filter out spots for the wrong team
142         if(teamcheck)
143         if(spot.team != teamcheck)
144                 return '-1 0 0';
145
146         if(race_spawns)
147                 if(spot.target == "")
148                         return '-1 0 0';
149
150         if(clienttype(self) == CLIENTTYPE_REAL)
151         {
152                 if(spot.restriction == 1)
153                         return '-1 0 0';
154         }
155         else
156         {
157                 if(spot.restriction == 2)
158                         return '-1 0 0';
159         }
160
161         // filter out spots for assault
162         if(spot.target != "") {
163                 local entity ent;
164                 float good, found;
165                 ent = find(world, targetname, spot.target);
166
167                 while(ent) {
168                         if(ent.classname == "target_objective")
169                         {
170                                 found = 1;
171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
172                                         return '-1 0 0';
173                                 good = 1;
174                         }
175                         else if(ent.classname == "trigger_race_checkpoint")
176                         {
177                                 found = 1;
178                                 if(!anypoint) // spectators may spawn everywhere
179
180                                 {
181                                         if(g_race_qualifying)
182                                         {
183                                                 // spawn at first
184                                                 if(ent.race_checkpoint != 0)
185                                                         return '-1 0 0';
186                                                 if(spot.race_place != race_lowest_place_spawn)
187                                                         return '-1 0 0';
188                                         }
189                                         else
190                                         {
191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
192                                                         return '-1 0 0';
193                                                 // try reusing the previous spawn
194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
195                                                         prio += 1;
196                                                 if(ent.race_checkpoint == 0)
197                                                 {
198                                                         float pl;
199                                                         pl = self.race_place;
200                                                         if(pl > race_highest_place_spawn)
201                                                                 pl = 0;
202                                                         if(pl == 0 && !self.race_started)
203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
204                                                         if(spot.race_place != pl)
205                                                                 return '-1 0 0';
206                                                 }
207                                         }
208                                 }
209                                 good = 1;
210                         }
211                         ent = find(ent, targetname, spot.target);
212                 }
213
214                 if(found && !good)
215                         return '-1 0 0';
216         }
217
218         player = playerlist;
219         shortest = vlen(world.maxs - world.mins);
220         for(player = playerlist; player; player = player.chain)
221                 if (player != self)
222                 {
223                         thisdist = vlen(player.origin - spot.origin);
224                         if (thisdist < shortest)
225                                 shortest = thisdist;
226                 }
227         return prio * '1 0 0' + shortest * '0 1 0';
228 }
229
230 float spawn_allbad;
231 float spawn_allgood;
232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
233 {
234         local entity spot, spotlist, spotlistend;
235         spawn_allgood = TRUE;
236         spawn_allbad = TRUE;
237
238         spotlist = world;
239         spotlistend = world;
240
241         for(spot = firstspot; spot; spot = spot.chain)
242         {
243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
244
245                 if(cvar("spawn_debugview"))
246                 {
247                         setmodel(spot, "models/runematch/rune.mdl");
248                         if(spot.spawnpoint_score_y < mindist)
249                         {
250                                 spot.colormod = '1 0 0';
251                                 spot.scale = 1;
252                         }
253                         else
254                         {
255                                 spot.colormod = '0 1 0';
256                                 spot.scale = spot.spawnpoint_score_y / mindist;
257                         }
258                 }
259
260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
261                 {
262                         if(spot.spawnpoint_score_y < mindist)
263                         {
264                                 // too short distance
265                                 spawn_allgood = FALSE;
266                         }
267                         else
268                         {
269                                 // perfect
270                                 spawn_allbad = FALSE;
271
272                                 if(spotlistend)
273                                         spotlistend.chain = spot;
274                                 spotlistend = spot;
275                                 if(!spotlist)
276                                         spotlist = spot;
277
278                                 /*
279                                 if(teamcheck)
280                                 if(spot.team != teamcheck)
281                                         error("invalid spawn added");
282
283                                 print("added ", etos(spot), "\n");
284                                 */
285                         }
286                 }
287         }
288         if(spotlistend)
289                 spotlistend.chain = world;
290
291         /*
292                 entity e;
293                 if(teamcheck)
294                         for(e = spotlist; e; e = e.chain)
295                         {
296                                 print("seen ", etos(e), "\n");
297                                 if(e.team != teamcheck)
298                                         error("invalid spawn found");
299                         }
300         */
301
302         return spotlist;
303 }
304
305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
306 {
307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
309         local entity spot;
310
311         RandomSelection_Init();
312         for(spot = firstspot; spot; spot = spot.chain)
313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
314
315         return RandomSelection_chosen_ent;
316 }
317
318 /*
319 =============
320 SelectSpawnPoint
321
322 Finds a point to respawn
323 =============
324 */
325 entity SelectSpawnPoint (float anypoint)
326 {
327         local float teamcheck;
328         local entity firstspot_new;
329         local entity spot, firstspot, playerlist;
330
331         spot = find (world, classname, "testplayerstart");
332         if (spot)
333                 return spot;
334
335         teamcheck = 0;
336
337         if(!anypoint && have_team_spawns > 0)
338                 teamcheck = self.team;
339
340         // get the list of players
341         playerlist = findchain(classname, "player");
342         // get the entire list of spots
343         firstspot = findchain(classname, "info_player_deathmatch");
344         // filter out the bad ones
345         // (note this returns the original list if none survived)
346         if(anypoint)
347         {
348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
349         }
350         else
351         {
352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
353                 if(!firstspot_new)
354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
355                 firstspot = firstspot_new;
356
357                 // there is 50/50 chance of choosing a random spot or the furthest spot
358                 // (this means that roughly every other spawn will be furthest, so you
359                 // usually won't get fragged at spawn twice in a row)
360                 if (arena_roundbased && !g_ca)
361                 {
362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
363                         if(firstspot_new)
364                                 firstspot = firstspot_new;
365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
366                 }
367                 else if (random() > cvar("g_spawn_furthest"))
368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
369                 else
370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
371         }
372
373         if(cvar("spawn_debugview"))
374         {
375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
376
377                 entity e;
378                 if(teamcheck)
379                         for(e = firstspot; e; e = e.chain)
380                                 if(e.team != teamcheck)
381                                         error("invalid spawn found");
382         }
383
384         if (!spot)
385         {
386                 if(cvar("spawn_debug"))
387                         GotoNextMap();
388                 else
389                 {
390                         if(some_spawn_has_been_used)
391                                 return world; // team can't spawn any more, because of actions of other team
392                         else
393                                 error("Cannot find a spawn point - please fix the map!");
394                 }
395         }
396
397         return spot;
398 }
399
400 /*
401 =============
402 CheckPlayerModel
403
404 Checks if the argument string can be a valid playermodel.
405 Returns a valid one in doubt.
406 =============
407 */
408 string FallbackPlayerModel;
409 string CheckPlayerModel(string plyermodel) {
410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
411         {
412                 // note: we cannot summon Don Strunzone here, some player may
413                 // still have the model string set. In case anyone manages how
414                 // to change a cvar default, we'll have a small leak here.
415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
416         }
417         if(strlen(plyermodel) < 4)
418                 return FallbackPlayerModel;
419         if( substring(plyermodel,0,14) != "models/player/")
420                 return FallbackPlayerModel;
421         else if(cvar("sv_servermodelsonly"))
422         {
423                 if(substring(plyermodel,-4,4) != ".zym")
424                 if(substring(plyermodel,-4,4) != ".dpm")
425                 if(substring(plyermodel,-4,4) != ".iqm")
426                 if(substring(plyermodel,-4,4) != ".md3")
427                 if(substring(plyermodel,-4,4) != ".psk")
428                         return FallbackPlayerModel;
429                 // forbid the LOD models
430                 if(substring(plyermodel, -9,5) == "_lod1")
431                         return FallbackPlayerModel;
432                 if(substring(plyermodel, -9,5) == "_lod2")
433                         return FallbackPlayerModel;
434                 if(plyermodel != strtolower(plyermodel))
435                         return FallbackPlayerModel;
436                 if(!fexists(plyermodel))
437                         return FallbackPlayerModel;
438         }
439         return plyermodel;
440 }
441
442 /*
443 =============
444 Client_customizeentityforclient
445
446 LOD reduction
447 =============
448 */
449 void Client_uncustomizeentityforclient()
450 {
451         if(self.modelindex == 0) // no need to uncustomize then
452                 return;
453         self.modelindex = self.modelindex_lod0;
454         self.skin = self.skinindex;
455 }
456
457 float Client_customizeentityforclient()
458 {
459         entity modelsource;
460
461         if(self.modelindex == 0)
462                 return TRUE;
463
464         // forcemodel stuff
465
466 #ifdef PROFILING
467         float t0;
468         t0 = gettime(GETTIME_HIRES); // reference
469 #endif
470
471         modelsource = self;
472
473 #ifdef ALLOW_FORCEMODELS
474         if(other.cvar_cl_forceplayermodelsfromxonotic)
475                 if not(self.modelindex_lod0_from_xonotic)
476                         modelsource = other;
477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
478                 modelsource = other;
479 #endif
480
481         self.skin = modelsource.skinindex;
482
483 #if 0
484         if(modelsource == self)
485                 self.skin = modelsource.skinindex;
486         else
487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
488 #endif
489
490         // self: me
491         // other: the player viewing me
492         float distance;
493         float f;
494
495         if(other.cvar_cl_playerdetailreduction <= 0)
496         {
497                 if(other.cvar_cl_playerdetailreduction <= -2)
498                         self.modelindex = modelsource.modelindex_lod2;
499                 else if(other.cvar_cl_playerdetailreduction <= -1)
500                         self.modelindex = modelsource.modelindex_lod1;
501                 else
502                         self.modelindex = modelsource.modelindex_lod0;
503         }
504         else
505         {
506                 distance = vlen(self.origin - other.origin);
507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
508                 if(f > sv_loddistance2)
509                         self.modelindex = modelsource.modelindex_lod2;
510                 else if(f > sv_loddistance1)
511                         self.modelindex = modelsource.modelindex_lod1;
512                 else
513                         self.modelindex = modelsource.modelindex_lod0;
514         }
515
516 #ifdef PROFILING
517         float t1;
518         t1 = gettime(GETTIME_HIRES); // reference
519         client_cefc_accumulator += (t1 - t0);
520 #endif
521
522         return TRUE;
523 }
524
525 void setmodel_lod(entity e, string modelname)
526 {
527         string s;
528
529         if(sv_loddistance1)
530         {
531                 // FIXME: this only supports 3-letter extensions
532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
533                 if(fexists(s))
534                 {
535                         setmodel(e, s); // players have high precision
536                         self.modelindex_lod1 = self.modelindex;
537                 }
538                 else
539                         self.modelindex_lod1 = -1;
540
541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
542                 if(fexists(s))
543                 {
544                         setmodel(e, s); // players have high precision
545                         self.modelindex_lod2 = self.modelindex;
546                 }
547                 else
548                         self.modelindex_lod2 = -1;
549
550                 precache_model(modelname);
551                 setmodel(e, modelname); // players have high precision
552                 self.modelindex_lod0 = self.modelindex;
553
554                 if(self.modelindex_lod1 < 0)
555                         self.modelindex_lod1 = self.modelindex;
556
557                 if(self.modelindex_lod2 < 0)
558                         self.modelindex_lod2 = self.modelindex;
559         }
560         else
561         {
562                 precache_model(modelname);
563                 setmodel(e, modelname); // players have high precision
564                 self.modelindex_lod0 = self.modelindex;
565                         // save it for possible player model forcing
566         }
567
568         s = whichpack(self.model);
569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
570
571         player_setupanimsformodel();
572         UpdatePlayerSounds();
573 }
574
575 /*
576 =============
577 PutObserverInServer
578
579 putting a client as observer in the server
580 =============
581 */
582 void FixPlayermodel();
583 void PutObserverInServer (void)
584 {
585         entity  spot;
586
587         race_PreSpawnObserver();
588
589         spot = SelectSpawnPoint (TRUE);
590         if(!spot)
591                 error("No spawnpoints for observers?!?\n");
592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
593
594         if(clienttype(self) == CLIENTTYPE_REAL)
595         {
596                 msg_entity = self;
597                 WriteByte(MSG_ONE, SVC_SETVIEW);
598                 WriteEntity(MSG_ONE, self);
599         }
600
601         DropAllRunes(self);
602
603         Portal_ClearAll(self);
604
605         if(self.flagcarried)
606                 DropFlag(self.flagcarried, world, world);
607
608         if(self.ballcarried)
609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
610
611         WaypointSprite_PlayerDead();
612
613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
615
616         if(self.killcount != -666) {
617                 if(g_lms) {
618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
620                         else
621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
622                 } else
623                         bprint ("^4", self.netname, "^4 is spectating now\n");
624
625                 if(self.just_joined == FALSE) {
626                         LogTeamchange(self.playerid, -1, 4);
627                 } else
628                         self.just_joined = FALSE;
629         }
630
631         PlayerScore_Clear(self); // clear scores when needed
632
633         self.spectatortime = time;
634
635         self.classname = "observer";
636         self.iscreature = FALSE;
637         self.health = -666;
638         self.takedamage = DAMAGE_NO;
639         self.solid = SOLID_NOT;
640         self.movetype = MOVETYPE_NOCLIP;
641         self.flags = FL_CLIENT | FL_NOTARGET;
642         self.armorvalue = 666;
643         self.effects = 0;
644         self.armorvalue = cvar("g_balance_armor_start");
645         self.pauserotarmor_finished = 0;
646         self.pauserothealth_finished = 0;
647         self.pauseregen_finished = 0;
648         self.damageforcescale = 0;
649         self.death_time = 0;
650         self.dead_frame = 0;
651         self.alpha = 0;
652         self.scale = 0;
653         self.fade_time = 0;
654         self.pain_frame = 0;
655         self.pain_finished = 0;
656         self.strength_finished = 0;
657         self.invincible_finished = 0;
658         self.pushltime = 0;
659         self.think = SUB_Null;
660         self.nextthink = 0;
661         self.hook_time = 0;
662         self.runes = 0;
663         self.deadflag = DEAD_NO;
664         self.angles = spot.angles;
665         self.angles_z = 0;
666         self.fixangle = TRUE;
667         self.crouch = FALSE;
668
669         self.view_ofs = PL_VIEW_OFS;
670         setorigin (self, spot.origin);
671         setsize (self, '0 0 0', '0 0 0');
672         self.prevorigin = self.origin;
673         self.items = 0;
674         self.weapons = 0;
675         self.model = "";
676         FixPlayermodel();
677         self.model = "";
678         self.modelindex = 0;
679         self.weapon = 0;
680         self.weaponmodel = "";
681         self.weaponentity = world;
682         self.exteriorweaponentity = world;
683         self.killcount = -666;
684         self.velocity = '0 0 0';
685         self.avelocity = '0 0 0';
686         self.punchangle = '0 0 0';
687         self.punchvector = '0 0 0';
688         self.oldvelocity = self.velocity;
689         self.fire_endtime = -1;
690
691         if(sv_loddistance1)
692                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
693
694         if(g_arena)
695         {
696                 if(self.version_mismatch)
697                 {
698                         Spawnqueue_Unmark(self);
699                         Spawnqueue_Remove(self);
700                 }
701                 else
702                 {
703                         Spawnqueue_Insert(self);
704                 }
705         }
706         else if(g_lms)
707         {
708                 // Only if the player cannot play at all
709                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
710                         self.frags = FRAGS_SPECTATOR;
711                 else
712                         self.frags = FRAGS_LMS_LOSER;
713         }
714         else
715                 self.frags = FRAGS_SPECTATOR;
716
717         MUTATOR_CALLHOOK(MakePlayerObserver);
718 }
719
720 float RestrictSkin(float s)
721 {
722         if(!teams_matter)
723                 return s;
724         if(s == 6)
725                 return 6;
726         return mod(s, 3);
727 }
728
729 void FixPlayermodel()
730 {
731         local string defaultmodel;
732         local float defaultskin, chmdl, oldskin;
733         local vector m1, m2;
734
735         defaultmodel = "";
736
737         if(cvar("sv_defaultcharacter") == 1) {
738                 defaultskin = 0;
739
740                 if(teams_matter)
741                 {
742                         string s;
743                         s = Team_ColorNameLowerCase(self.team);
744                         if(s != "neutral")
745                         {
746                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
747                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
748                         }
749                 }
750
751                 if(defaultmodel == "")
752                 {
753                         defaultmodel = cvar_string("sv_defaultplayermodel");
754                         defaultskin = cvar("sv_defaultplayerskin");
755                 }
756         }
757
758         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
759         {
760                 if(self.model != "")
761                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
762                 self.model = ""; // force the != checks to return true
763         }
764
765         if(defaultmodel != "")
766         {
767                 if (defaultmodel != self.model)
768                 {
769                         m1 = self.mins;
770                         m2 = self.maxs;
771                         setmodel_lod (self, defaultmodel);
772                         setsize (self, m1, m2);
773                         chmdl = TRUE;
774                 }
775
776                 oldskin = self.skinindex;
777                 self.skinindex = defaultskin;
778         } else {
779                 if (self.playermodel != self.model || self.playermodel == "")
780                 {
781                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
782                         m1 = self.mins;
783                         m2 = self.maxs;
784                         setmodel_lod (self, self.playermodel);
785                         setsize (self, m1, m2);
786                         chmdl = TRUE;
787                 }
788
789                 oldskin = self.skinindex;
790                 self.skinindex = RestrictSkin(stof(self.playerskin));
791         }
792
793         if(chmdl || oldskin != self.skinindex)
794                 self.species = player_getspecies(); // model or skin has changed
795
796         if(!teams_matter)
797                 if(strlen(cvar_string("sv_defaultplayercolors")))
798                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
799                                 setcolor(self, cvar("sv_defaultplayercolors"));
800 }
801
802 void PlayerTouchExplode(entity p1, entity p2)
803 {
804         vector org;
805         org = (p1.origin + p2.origin) * 0.5;
806         org_z += (p1.mins_z + p2.mins_z) * 0.5;
807
808         te_explosion(org);
809
810         entity e;
811         e = spawn();
812         setorigin(e, org);
813         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
814         remove(e);
815 }
816
817 /*
818 =============
819 PutClientInServer
820
821 Called when a client spawns in the server
822 =============
823 */
824 //void() ctf_playerchanged;
825 void PutClientInServer (void)
826 {
827         if(clienttype(self) == CLIENTTYPE_BOT)
828         {
829                 self.classname = "player";
830         }
831         else if(clienttype(self) == CLIENTTYPE_REAL)
832         {
833                 msg_entity = self;
834                 WriteByte(MSG_ONE, SVC_SETVIEW);
835                 WriteEntity(MSG_ONE, self);
836         }
837
838         // player is dead and becomes observer
839         // FIXME fix LMS scoring for new system
840         if(g_lms)
841         {
842                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
843                         self.classname = "observer";
844         }
845
846         if(g_arena || (g_ca && !allowed_to_spawn))
847         if(!self.spawned)
848                 self.classname = "observer";
849
850         if(gameover)
851                 self.classname = "observer";
852
853         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
854                 entity spot, oldself;
855                 float j;
856
857                 if(self.team < 0)
858                         JoinBestTeam(self, FALSE, TRUE);
859
860                 race_PreSpawn();
861
862                 spot = SelectSpawnPoint (FALSE);
863                 if(!spot)
864                 {
865                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
866                         return; // spawn failed
867                 }
868
869                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
870
871                 self.classname = "player";
872                 self.wasplayer = TRUE;
873                 self.iscreature = TRUE;
874                 self.movetype = MOVETYPE_WALK;
875                 self.solid = SOLID_SLIDEBOX;
876                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
877                 if(cvar("g_playerclip_collisions"))
878                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
879                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
880                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
881                 self.frags = FRAGS_PLAYER;
882                 if(independent_players)
883                         MAKE_INDEPENDENT_PLAYER(self);
884                 self.flags = FL_CLIENT;
885                 self.takedamage = DAMAGE_AIM;
886                 if(g_minstagib)
887                         self.effects = EF_FULLBRIGHT;
888                 else
889                         self.effects = 0;
890                 self.air_finished = time + 12;
891                 self.dmg = 2;
892                 if(cvar("g_balance_nex_charge"))
893                         self.nex_charge = cvar("g_balance_nex_charge_start");
894
895                 if(inWarmupStage)
896                 {
897                         self.ammo_shells = warmup_start_ammo_shells;
898                         self.ammo_nails = warmup_start_ammo_nails;
899                         self.ammo_rockets = warmup_start_ammo_rockets;
900                         self.ammo_cells = warmup_start_ammo_cells;
901                         self.ammo_fuel = warmup_start_ammo_fuel;
902                         self.health = warmup_start_health;
903                         self.armorvalue = warmup_start_armorvalue;
904                         self.weapons = warmup_start_weapons;
905                 }
906                 else
907                 {
908                         self.ammo_shells = start_ammo_shells;
909                         self.ammo_nails = start_ammo_nails;
910                         self.ammo_rockets = start_ammo_rockets;
911                         self.ammo_cells = start_ammo_cells;
912                         self.ammo_fuel = start_ammo_fuel;
913                         self.health = start_health;
914                         self.armorvalue = start_armorvalue;
915                         self.weapons = start_weapons;
916                 }
917
918                 if(g_weaponarena_random)
919                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
920
921                 self.items = start_items;
922                 self.jump_interval = time;
923
924                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
925                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
926                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
927                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
928                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
929                 //extend the pause of rotting if client was reset at the beginning of the countdown
930                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
931                         self.spawnshieldtime += game_starttime - time;
932                         self.pauserotarmor_finished += game_starttime - time;
933                         self.pauserothealth_finished += game_starttime - time;
934                         self.pauseregen_finished += game_starttime - time;
935                 }
936                 self.damageforcescale = 2;
937                 self.death_time = 0;
938                 self.dead_frame = 0;
939                 self.alpha = 0;
940                 self.scale = 0;
941                 self.fade_time = 0;
942                 self.pain_frame = 0;
943                 self.pain_finished = 0;
944                 self.strength_finished = 0;
945                 self.invincible_finished = 0;
946                 self.pushltime = 0;
947                 // players have no think function
948                 self.think = SUB_Null;
949                 self.nextthink = 0;
950                 self.hook_time = 0;
951                 self.dmg_team = 0;
952                 self.ballistics_density = cvar("g_ballistics_density_player");
953
954                 self.metertime = 0;
955
956                 self.runes = 0;
957
958                 self.deadflag = DEAD_NO;
959
960                 self.angles = spot.angles;
961
962                 self.angles_z = 0; // never spawn tilted even if the spot says to
963                 self.fixangle = TRUE; // turn this way immediately
964                 self.velocity = '0 0 0';
965                 self.avelocity = '0 0 0';
966                 self.punchangle = '0 0 0';
967                 self.punchvector = '0 0 0';
968                 self.oldvelocity = self.velocity;
969                 self.fire_endtime = -1;
970
971                 msg_entity = self;
972                 WRITESPECTATABLE_MSG_ONE({
973                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
974                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
975                 });
976
977                 if(sv_loddistance1)
978                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
979
980                 self.model = "";
981                 FixPlayermodel();
982
983                 self.crouch = FALSE;
984                 self.view_ofs = PL_VIEW_OFS;
985                 setsize (self, PL_MIN, PL_MAX);
986                 self.spawnorigin = spot.origin;
987                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
988                 // don't reset back to last position, even if new position is stuck in solid
989                 self.oldorigin = self.origin;
990                 self.prevorigin = self.origin;
991                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
992
993                 if(g_arena)
994                 {
995                         Spawnqueue_Remove(self);
996                         Spawnqueue_Mark(self);
997                 }
998
999                 else if(g_ca)
1000                         self.caplayer = 1;
1001
1002                 self.event_damage = PlayerDamage;
1003
1004                 self.bot_attack = TRUE;
1005
1006                 self.statdraintime = time + 5;
1007                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1008
1009                 if(self.killcount == -666) {
1010                         PlayerScore_Clear(self);
1011                         self.killcount = 0;
1012                 }
1013
1014                 self.cnt = WEP_LASER;
1015
1016                 CL_SpawnWeaponentity();
1017                 self.alpha = default_player_alpha;
1018                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1019                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1020
1021                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1022                 self.lms_traveled_distance = 0;
1023                 self.speedrunning = FALSE;
1024
1025                 race_PostSpawn(spot);
1026
1027                 if(cvar("spawn_debug"))
1028                 {
1029                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1030                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1031                 }
1032
1033                 //stuffcmd(self, "chase_active 0");
1034                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1035
1036                 if (cvar("g_spawnsound"))
1037                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1038
1039                 if(g_assault) {
1040                         if(self.team == assault_attacker_team)
1041                                 centerprint(self, "You are attacking!");
1042                         else
1043                                 centerprint(self, "You are defending!");
1044                 }
1045
1046                 target_voicescript_clear(self);
1047
1048                 // reset fields the weapons may use
1049                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1050                         weapon_action(j, WR_RESETPLAYER);
1051
1052                 oldself = self;
1053                 self = spot;
1054                         activator = oldself;
1055                                 SUB_UseTargets();
1056                         activator = world;
1057                 self = oldself;
1058
1059                 MUTATOR_CALLHOOK(PlayerSpawn);
1060
1061                 self.switchweapon = w_getbestweapon(self);
1062                 self.cnt = self.switchweapon;
1063                 self.weapon = 0;
1064         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1065                 PutObserverInServer ();
1066         }
1067
1068         //if(g_ctf)
1069         //      ctf_playerchanged();
1070 }
1071
1072 float ClientInit_SendEntity(entity to, float sf)
1073 {
1074         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1075         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1078         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1079         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1080         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1081         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1082         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1083         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1084         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1085         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1086         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1088         if(sv_foginterval && world.fog != "")
1089                 WriteString(MSG_ENTITY, world.fog);
1090         else
1091                 WriteString(MSG_ENTITY, "");
1092         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1093         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1094         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1095         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1096         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1097         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1098         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1099         return TRUE;
1100 }
1101
1102 void ClientInit_CheckUpdate()
1103 {
1104         self.nextthink = time;
1105         if(self.count != cvar("g_balance_armor_blockpercent"))
1106         {
1107                 self.count = cvar("g_balance_armor_blockpercent");
1108                 self.SendFlags |= 1;
1109         }
1110         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1111         {
1112                 self.cnt = cvar("g_balance_weaponswitchdelay");
1113                 self.SendFlags |= 1;
1114         }
1115         if(self.bouncefactor != cvar("g_balance_grenadelauncher_bouncefactor"))
1116         {
1117                 self.bouncefactor = cvar("g_balance_grenadelauncher_bouncefactor");
1118                 self.SendFlags |= 1;
1119         }
1120         if(self.bouncestop != cvar("g_balance_grenadelauncher_bouncestop"))
1121         {
1122                 self.bouncestop = cvar("g_balance_grenadelauncher_bouncestop");
1123                 self.SendFlags |= 1;
1124         }
1125 }
1126
1127 void ClientInit_Spawn()
1128 {
1129         entity o;
1130         entity e;
1131         e = spawn();
1132         e.classname = "clientinit";
1133         e.think = ClientInit_CheckUpdate;
1134         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1135
1136         o = self;
1137         self = e;
1138         ClientInit_CheckUpdate();
1139         self = o;
1140 }
1141
1142 /*
1143 =============
1144 SetNewParms
1145 =============
1146 */
1147 void SetNewParms (void)
1148 {
1149         // initialize parms for a new player
1150         parm1 = -(86400 * 366);
1151 }
1152
1153 /*
1154 =============
1155 SetChangeParms
1156 =============
1157 */
1158 void SetChangeParms (void)
1159 {
1160         // save parms for level change
1161         parm1 = self.parm_idlesince - time;
1162 }
1163
1164 /*
1165 =============
1166 DecodeLevelParms
1167 =============
1168 */
1169 void DecodeLevelParms (void)
1170 {
1171         // load parms
1172         self.parm_idlesince = parm1;
1173         if(self.parm_idlesince == -(86400 * 366))
1174                 self.parm_idlesince = time;
1175
1176         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1177         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1178 }
1179
1180 /*
1181 =============
1182 ClientKill
1183
1184 Called when a client types 'kill' in the console
1185 =============
1186 */
1187
1188 void ClientKill_Now_TeamChange()
1189 {
1190         if(self.killindicator_teamchange == -1)
1191         {
1192                 self.team = -1;
1193                 JoinBestTeam( self, FALSE, FALSE );
1194         }
1195         else
1196                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1197 }
1198
1199 void ClientKill_Now()
1200 {
1201         if(self.killindicator_teamchange)
1202                 ClientKill_Now_TeamChange();
1203
1204         // in any case:
1205         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1206
1207         if(self.killindicator)
1208         {
1209                 dprint("Cleaned up after a leaked kill indicator.\n");
1210                 remove(self.killindicator);
1211                 self.killindicator = world;
1212         }
1213 }
1214 void KillIndicator_Think()
1215 {
1216         if (!self.owner.modelindex)
1217         {
1218                 self.owner.killindicator = world;
1219                 remove(self);
1220                 return;
1221         }
1222
1223         if(self.cnt <= 0)
1224         {
1225                 self = self.owner;
1226                 ClientKill_Now(); // no oldself needed
1227                 return;
1228         }
1229         else
1230         {
1231                 if(self.cnt <= 10)
1232                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1233                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1234                 {
1235                         if(self.cnt <= 10)
1236                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1237                         if(self.owner.killindicator_teamchange)
1238                         {
1239                                 if(self.owner.killindicator_teamchange == -1)
1240                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1241                                 else
1242                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1243                         }
1244                         else
1245                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1246                 }
1247                 self.nextthink = time + 1;
1248                 self.cnt -= 1;
1249         }
1250 }
1251
1252 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1253 {
1254         float killtime;
1255         entity e;
1256         killtime = cvar("g_balance_kill_delay");
1257
1258         if(g_race_qualifying)
1259                 killtime = 0;
1260
1261         self.killindicator_teamchange = targetteam;
1262
1263         if(!self.killindicator)
1264         {
1265                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1266                 {
1267                         ClientKill_Now();
1268                 }
1269                 else
1270                 {
1271                         self.killindicator = spawn();
1272                         self.killindicator.owner = self;
1273                         self.killindicator.scale = 0.5;
1274                         setattachment(self.killindicator, self, "");
1275                         setorigin(self.killindicator, '0 0 52');
1276                         self.killindicator.think = KillIndicator_Think;
1277                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1278                         self.killindicator.cnt = ceil(killtime);
1279                         self.killindicator.count = bound(0, ceil(killtime), 10);
1280                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1281
1282                         for(e = world; (e = find(e, classname, "body")) != world; )
1283                         {
1284                                 if(e.enemy != self)
1285                                         continue;
1286                                 e.killindicator = spawn();
1287                                 e.killindicator.owner = e;
1288                                 e.killindicator.scale = 0.5;
1289                                 setattachment(e.killindicator, e, "");
1290                                 setorigin(e.killindicator, '0 0 52');
1291                                 e.killindicator.think = KillIndicator_Think;
1292                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1293                                 e.killindicator.cnt = ceil(killtime);
1294                         }
1295                         self.lip = 0;
1296                 }
1297         }
1298         if(self.killindicator)
1299         {
1300                 if(targetteam)
1301                         self.killindicator.colormod = TeamColor(targetteam);
1302                 else
1303                         self.killindicator.colormod = '0 0 0';
1304         }
1305 }
1306
1307 void ClientKill (void)
1308 {
1309         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1310         {
1311                 // do nothing
1312         }
1313         else
1314                 ClientKill_TeamChange(0);
1315 }
1316
1317 void CTS_ClientKill_Think (void)
1318 {
1319         self = self.owner; // set self to the player to be killed
1320         sprint(self, "^1You were killed in order to prevent cheating!");
1321         ClientKill_Now();
1322 }
1323
1324 void CTS_ClientKill (float t) // silent version of ClientKill
1325 {
1326         entity e;
1327         e = spawn();
1328         e.owner = self;
1329         e.think = CTS_ClientKill_Think;
1330         e.nextthink = t;
1331 }
1332
1333 void DoTeamChange(float destteam)
1334 {
1335         float t, c0;
1336         if(!teams_matter)
1337         {
1338                 if(destteam >= 0)
1339                         SetPlayerColors(self, destteam);
1340                 return;
1341         }
1342         if(self.classname == "player")
1343         if(destteam == -1)
1344         {
1345                 CheckAllowedTeams(self);
1346                 t = FindSmallestTeam(self, TRUE);
1347                 switch(self.team)
1348                 {
1349                         case COLOR_TEAM1: c0 = c1; break;
1350                         case COLOR_TEAM2: c0 = c2; break;
1351                         case COLOR_TEAM3: c0 = c3; break;
1352                         case COLOR_TEAM4: c0 = c4; break;
1353                         default:          c0 = 999;
1354                 }
1355                 switch(t)
1356                 {
1357                         case 1:
1358                                 if(c0 > c1)
1359                                         destteam = COLOR_TEAM1;
1360                                 break;
1361                         case 2:
1362                                 if(c0 > c2)
1363                                         destteam = COLOR_TEAM2;
1364                                 break;
1365                         case 3:
1366                                 if(c0 > c3)
1367                                         destteam = COLOR_TEAM3;
1368                                 break;
1369                         case 4:
1370                                 if(c0 > c4)
1371                                         destteam = COLOR_TEAM4;
1372                                 break;
1373                 }
1374                 if(destteam == -1)
1375                         return;
1376         }
1377         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1378                 return;
1379         ClientKill_TeamChange(destteam);
1380 }
1381
1382 void FixClientCvars(entity e)
1383 {
1384         // send prediction settings to the client
1385         stuffcmd(e, "\nin_bindmap 0 0\n");
1386         if(g_race || g_cts)
1387                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1388         if(cvar("g_antilag") == 3) // client side hitscan
1389                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1390         if(sv_gentle)
1391                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1392         /*
1393          * we no longer need to stuff this. Remove this comment block if you feel
1394          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1395         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1396         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1397         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1398         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1399         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1400         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1401         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1402         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1403         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1404         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1405         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1406         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1407         stuffcmd(e, "cl_movement_edgefriction 1\n");
1408          */
1409 }
1410
1411 float PlayerInIDList(entity p, string idlist)
1412 {
1413         float n, i;
1414         string s;
1415
1416         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1417         if not(p.crypto_idfp)
1418                 return 0;
1419
1420         // this function allows abbreviated player IDs too!
1421         n = tokenize_console(idlist);
1422         for(i = 0; i < n; ++i)
1423         {
1424                 s = argv(i);
1425                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1426                         return 1;
1427         }
1428
1429         return 0;
1430 }
1431
1432 /*
1433 =============
1434 ClientConnect
1435
1436 Called when a client connects to the server
1437 =============
1438 */
1439 //void ctf_clientconnect();
1440 string ColoredTeamName(float t);
1441 void DecodeLevelParms (void);
1442 //void dom_player_join_team(entity pl);
1443 void ClientConnect (void)
1444 {
1445         float t;
1446
1447         if(self.flags & FL_CLIENT)
1448         {
1449                 print("Warning: ClientConnect, but already connected!\n");
1450                 return;
1451         }
1452
1453         if(Ban_MaybeEnforceBan(self))
1454                 return;
1455
1456         DecodeLevelParms();
1457
1458 #ifdef WATERMARK
1459         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1460 #endif
1461
1462         self.classname = "player_joining";
1463
1464         self.flags = FL_CLIENT;
1465         self.version_nagtime = time + 10 + random() * 10;
1466
1467         if(player_count<0)
1468         {
1469                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1470                 player_count = 0;
1471         }
1472
1473         PlayerScore_Attach(self);
1474         ClientData_Attach();
1475
1476         bot_clientconnect();
1477
1478         playerdemo_init();
1479
1480         anticheat_init();
1481         
1482         race_PreSpawnObserver();
1483
1484         //if(g_domination)
1485         //      dom_player_join_team(self);
1486
1487         // identify the right forced team
1488         if(PlayerInIDList(self, cvar_string("g_forced_team_red")))
1489                 self.team_forced = COLOR_TEAM1;
1490         else if(PlayerInIDList(self, cvar_string("g_forced_team_blue")))
1491                 self.team_forced = COLOR_TEAM2;
1492         else if(PlayerInIDList(self, cvar_string("g_forced_team_yellow")))
1493                 self.team_forced = COLOR_TEAM3;
1494         else if(PlayerInIDList(self, cvar_string("g_forced_team_pink")))
1495                 self.team_forced = COLOR_TEAM4;
1496         else if(cvar_string("g_forced_team_otherwise") == "red")
1497                 self.team_forced = COLOR_TEAM1;
1498         else if(cvar_string("g_forced_team_otherwise") == "blue")
1499                 self.team_forced = COLOR_TEAM2;
1500         else if(cvar_string("g_forced_team_otherwise") == "yellow")
1501                 self.team_forced = COLOR_TEAM3;
1502         else if(cvar_string("g_forced_team_otherwise") == "pink")
1503                 self.team_forced = COLOR_TEAM4;
1504         else if(cvar_string("g_forced_team_otherwise") == "spectate")
1505                 self.team_forced = -1;
1506         else if(cvar_string("g_forced_team_otherwise") == "spectator")
1507                 self.team_forced = -1;
1508         else
1509                 self.team_forced = 0;
1510
1511         if(!teams_matter)
1512                 if(self.team_forced > 0)
1513                         self.team_forced = 0;
1514
1515         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1516
1517         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign") || self.team_forced < 0) {
1518                 self.classname = "observer";
1519         } else {
1520                 if(teams_matter)
1521                 {
1522                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1523                         {
1524                                 self.classname = "player";
1525                                 campaign_bots_may_start = 1;
1526                         }
1527                         else
1528                         {
1529                                 self.classname = "observer"; // do it anyway
1530                         }
1531                 }
1532                 else
1533                 {
1534                         self.classname = "player";
1535                         campaign_bots_may_start = 1;
1536                 }
1537         }
1538
1539         self.playerid = (playerid_last = playerid_last + 1);
1540
1541         if(cvar("sv_eventlog"))
1542                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1543
1544         LogTeamchange(self.playerid, self.team, 1);
1545
1546         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1547
1548         self.netname_previous = strzone(self.netname);
1549
1550         bprint("^4", self.netname, "^4 connected");
1551
1552         if(self.classname != "observer" && (g_domination || g_ctf))
1553                 bprint(" and joined the ", ColoredTeamName(self.team));
1554
1555         bprint("\n");
1556
1557         self.welcomemessage_time = 0;
1558
1559         stuffcmd(self, strcat(clientstuff, "\n"));
1560         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1561         stuffcmd(self, "cl_particles_reloadeffects\n");
1562
1563         FixClientCvars(self);
1564
1565         // spawnfunc_waypoint sprites
1566         WaypointSprite_InitClient(self);
1567
1568         // Wazat's grappling hook
1569         SetGrappleHookBindings();
1570
1571         // get autoswitch state from player when he toggles it
1572         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1573
1574         // get version info from player
1575         stuffcmd(self, "cmd clientversion $gameversion\n");
1576
1577         // get other cvars from player
1578         GetCvars(0);
1579
1580         // set cvar for team scoreboard
1581         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1582
1583         // notify about available teams
1584         if(teams_matter)
1585         {
1586                 CheckAllowedTeams(self);
1587                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1588                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1589         }
1590         else
1591                 stuffcmd(self, "set _teams_available 0\n");
1592
1593         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1594
1595         if(g_arena || g_ca)
1596         {
1597                 self.classname = "observer";
1598                 if(g_arena)
1599                         Spawnqueue_Insert(self);
1600         }
1601         /*else if(g_ctf)
1602         {
1603                 ctf_clientconnect();
1604         }*/
1605
1606         if(teams_matter || radar_showennemies)
1607                 attach_entcs();
1608
1609         bot_relinkplayerlist();
1610
1611         self.spectatortime = time;
1612         if(blockSpectators)
1613         {
1614                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1615         }
1616
1617         self.jointime = time;
1618         self.allowedTimeouts = cvar("sv_timeout_number");
1619
1620         if(clienttype(self) == CLIENTTYPE_REAL)
1621         {
1622                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1623                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1624         }
1625
1626         if(g_lms)
1627         {
1628                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1629                 {
1630                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1631                         self.frags = FRAGS_SPECTATOR;
1632                 }
1633         }
1634
1635         if(!sv_foginterval && world.fog != "")
1636                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1637
1638         SoundEntity_Attach(self);
1639
1640         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1641         {
1642                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1643                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1644         }
1645         else
1646                 self.hitplotfh = -1;
1647
1648         if(g_race || g_cts) {
1649                 string rr;
1650                 if(g_cts)
1651                         rr = CTS_RECORD;
1652                 else
1653                         rr = RACE_RECORD;
1654                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1655
1656                 msg_entity = self;
1657                 race_send_recordtime(MSG_ONE);
1658                 race_send_speedaward(MSG_ONE);
1659
1660                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1661                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1662                 race_send_speedaward_alltimebest(MSG_ONE);
1663
1664                 float i;
1665                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1666                         race_SendRankings(i, 0, 0, MSG_ONE);
1667                 }
1668         }
1669         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1670                 send_CSQC_teamnagger();
1671
1672         send_CSQC_cr_maxbullets(self);
1673
1674         CheatInitClient();
1675 }
1676
1677 /*
1678 =============
1679 ClientDisconnect
1680
1681 Called when a client disconnects from the server
1682 =============
1683 */
1684 .entity chatbubbleentity;
1685 .entity teambubbleentity;
1686 void ReadyCount();
1687 void ClientDisconnect (void)
1688 {
1689         if not(self.flags & FL_CLIENT)
1690         {
1691                 print("Warning: ClientDisconnect without ClientConnect\n");
1692                 return;
1693         }
1694
1695         CheatShutdownClient();
1696
1697         if(self.hitplotfh >= 0)
1698         {
1699                 fclose(self.hitplotfh);
1700                 self.hitplotfh = -1;
1701         }
1702
1703         anticheat_report();
1704         anticheat_shutdown();
1705
1706         playerdemo_shutdown();
1707
1708         bot_clientdisconnect();
1709
1710         if(self.entcs)
1711                 detach_entcs();
1712
1713         if(cvar("sv_eventlog"))
1714                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1715         bprint ("^4",self.netname);
1716         bprint ("^4 disconnected\n");
1717
1718         SoundEntity_Detach(self);
1719
1720         DropAllRunes(self);
1721         MUTATOR_CALLHOOK(ClientDisconnect);
1722
1723         Portal_ClearAll(self);
1724
1725         if(self.flagcarried)
1726                 DropFlag(self.flagcarried, world, world);
1727         if(self.ballcarried)
1728                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1729
1730         // Here, everything has been done that requires this player to be a client.
1731
1732         self.flags &~= FL_CLIENT;
1733
1734         if (self.chatbubbleentity)
1735                 remove (self.chatbubbleentity);
1736
1737         if (self.teambubbleentity)
1738                 remove (self.teambubbleentity);
1739
1740         if (self.killindicator)
1741                 remove (self.killindicator);
1742
1743         WaypointSprite_PlayerGone();
1744
1745         bot_relinkplayerlist();
1746
1747         // remove laserdot
1748         if(self.weaponentity)
1749                 if(self.weaponentity.lasertarget)
1750                         remove(self.weaponentity.lasertarget);
1751
1752         if(g_arena)
1753         {
1754                 Spawnqueue_Unmark(self);
1755                 Spawnqueue_Remove(self);
1756         }
1757
1758         ClientData_Detach();
1759         PlayerScore_Detach(self);
1760
1761         if(self.netname_previous)
1762                 strunzone(self.netname_previous);
1763         if(self.clientstatus)
1764                 strunzone(self.clientstatus);
1765         if(self.weaponorder_byimpulse)
1766                 strunzone(self.weaponorder_byimpulse);
1767
1768         ClearPlayerSounds();
1769
1770         if(self.personal)
1771                 remove(self.personal);
1772
1773         self.playerid = 0;
1774         ReadyCount();
1775
1776         // free cvars
1777         GetCvars(-1);
1778 }
1779
1780 .float BUTTON_CHAT;
1781 void ChatBubbleThink()
1782 {
1783         self.nextthink = time;
1784         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1785         {
1786                 if(self.owner) // but why can that ever be world?
1787                         self.owner.chatbubbleentity = world;
1788                 remove(self);
1789                 return;
1790         }
1791         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1792 #ifdef TETRIS
1793                 || self.owner.tetris_on
1794 #endif
1795         )
1796                 self.model = self.mdl;
1797         else
1798                 self.model = "";
1799 };
1800
1801 void UpdateChatBubble()
1802 {
1803         if (!self.modelindex)
1804                 return;
1805         // spawn a chatbubble entity if needed
1806         if (!self.chatbubbleentity)
1807         {
1808                 self.chatbubbleentity = spawn();
1809                 self.chatbubbleentity.owner = self;
1810                 self.chatbubbleentity.exteriormodeltoclient = self;
1811                 self.chatbubbleentity.think = ChatBubbleThink;
1812                 self.chatbubbleentity.nextthink = time;
1813                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1814                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1815                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1816                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1817                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1818                 self.chatbubbleentity.model = "";
1819                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1820         }
1821 }
1822
1823
1824 void TeamBubbleThink()
1825 {
1826         self.nextthink = time;
1827         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1828         {
1829                 if(self.owner) // but why can that ever be world?
1830                         self.owner.teambubbleentity = world;
1831                 remove(self);
1832                 return;
1833         }
1834 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1835         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1836                 self.model = "";
1837         else
1838                 self.model = self.mdl;
1839
1840 };
1841
1842 float TeamBubble_customizeentityforclient()
1843 {
1844         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1845 }
1846
1847 void UpdateTeamBubble()
1848 {
1849         if (!self.modelindex || !teams_matter)
1850                 return;
1851         // spawn a teambubble entity if needed
1852         if (!self.teambubbleentity && teams_matter)
1853         {
1854                 self.teambubbleentity = spawn();
1855                 self.teambubbleentity.owner = self;
1856                 self.teambubbleentity.exteriormodeltoclient = self;
1857                 self.teambubbleentity.think = TeamBubbleThink;
1858                 self.teambubbleentity.nextthink = time;
1859                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1860 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1861                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1862                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1863                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1864                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1865                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1866                 self.teambubbleentity.effects = EF_LOWPRECISION;
1867         }
1868 }
1869
1870 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1871 // added to the model skins
1872 /*void UpdateColorModHack()
1873 {
1874         local float c;
1875         c = self.clientcolors & 15;
1876         // LordHavoc: only bothering to support white, green, red, yellow, blue
1877              if (!teams_matter) self.colormod = '0 0 0';
1878         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1879         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1880         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1881         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1882         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1883         else self.colormod = '1 1 1';
1884 };*/
1885
1886 .float oldcolormap;
1887 void respawn(void)
1888 {
1889         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1890         {
1891                 self.solid = SOLID_NOT;
1892                 self.takedamage = DAMAGE_NO;
1893                 self.movetype = MOVETYPE_FLY;
1894                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1895                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1896                 self.effects |= EF_ADDITIVE;
1897                 self.oldcolormap = self.colormap;
1898                 self.colormap = 512;
1899                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1900                 if(cvar("g_respawn_ghosts_maxtime"))
1901                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1902         }
1903
1904         CopyBody(1);
1905         self.effects |= EF_NODRAW; // prevent another CopyBody
1906         if(self.oldcolormap)
1907         {
1908                 self.colormap = self.oldcolormap;
1909                 self.oldcolormap = 0;
1910         }
1911         PutClientInServer();
1912 }
1913
1914 void play_countdown(float finished, string samp)
1915 {
1916         if(clienttype(self) == CLIENTTYPE_REAL)
1917                 if(floor(finished - time - frametime) != floor(finished - time))
1918                         if(finished - time < 6)
1919                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1920 }
1921
1922 /**
1923  * When sv_timeout is used this function returs strings like
1924  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1925  * Called by centerprint functions
1926  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1927  */
1928 string getTimeoutText(float addOneSecond) {
1929         if (!cvar("sv_timeout") || !timeoutStatus)
1930                 return "";
1931
1932         local string retStr;
1933         if (timeoutStatus == 1) {
1934                 if (addOneSecond == 1) {
1935                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1936                 }
1937                 else {
1938                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1939                 }
1940                 return retStr;
1941         }
1942         else if (timeoutStatus == 2) {
1943                 if (addOneSecond) {
1944                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1945                         //don't show messages like "Timeout ends in 0 seconds"...
1946                         if ((remainingTimeoutTime + 1) > 0)
1947                                 return retStr;
1948                         else
1949                                 return "";
1950                 }
1951                 else {
1952                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1953                         //don't show messages like "Timeout ends in 0 seconds"...
1954                         if (remainingTimeoutTime > 0)
1955                                 return retStr;
1956                         else
1957                                 return "";
1958                 }
1959         }
1960         else return "";
1961 }
1962
1963 void player_powerups (void)
1964 {
1965         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1966         {
1967                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1968                 self.modelflags |= MF_ROCKET;
1969         }
1970         else
1971         {
1972                 SoundEntity_StopSound(self, CHAN_PLAYER);
1973                 self.modelflags &~= MF_ROCKET;
1974         }
1975
1976         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1977
1978         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1979                 return;
1980         
1981         Fire_ApplyDamage(self);
1982         Fire_ApplyEffect(self);
1983
1984         if (g_minstagib)
1985         {
1986                 self.effects |= EF_FULLBRIGHT;
1987
1988                 if (self.items & IT_STRENGTH)
1989                 {
1990                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1991                         if (time > self.strength_finished)
1992                         {
1993                                 self.alpha = default_player_alpha;
1994                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1995                                 self.items &~= IT_STRENGTH;
1996                                 sprint(self, "^3Invisibility has worn off\n");
1997                         }
1998                 }
1999                 else
2000                 {
2001                         if (time < self.strength_finished)
2002                         {
2003                                 self.alpha = g_minstagib_invis_alpha;
2004                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2005                                 self.items |= IT_STRENGTH;
2006                                 sprint(self, "^3You are invisible\n");
2007                         }
2008                 }
2009
2010                 if (self.items & IT_INVINCIBLE)
2011                 {
2012                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2013                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2014                         {
2015                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2016                                 sprint(self, "^3Speed has worn off\n");
2017                         }
2018                 }
2019                 else
2020                 {
2021                         if (time < self.invincible_finished)
2022                         {
2023                                 self.items = self.items | IT_INVINCIBLE;
2024                                 sprint(self, "^3You are on speed\n");
2025                         }
2026                 }
2027                 return;
2028         }
2029
2030         if (self.items & IT_STRENGTH)
2031         {
2032                 play_countdown(self.strength_finished, "misc/poweroff.wav");
2033                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2034                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
2035                 {
2036                         self.items = self.items - (self.items & IT_STRENGTH);
2037                         sprint(self, "^3Strength has worn off\n");
2038                 }
2039         }
2040         else
2041         {
2042                 if (time < self.strength_finished)
2043                 {
2044                         self.items = self.items | IT_STRENGTH;
2045                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
2046                 }
2047         }
2048         if (self.items & IT_INVINCIBLE)
2049         {
2050                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
2051                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2052                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2053                 {
2054                         self.items = self.items - (self.items & IT_INVINCIBLE);
2055                         sprint(self, "^3Shield has worn off\n");
2056                 }
2057         }
2058         else
2059         {
2060                 if (time < self.invincible_finished)
2061                 {
2062                         self.items = self.items | IT_INVINCIBLE;
2063                         sprint(self, "^3Shield surrounds you\n");
2064                 }
2065         }
2066
2067         if(cvar("g_nodepthtestplayers"))
2068                 self.effects = self.effects | EF_NODEPTHTEST;
2069
2070         if(cvar("g_fullbrightplayers"))
2071                 self.effects = self.effects | EF_FULLBRIGHT;
2072
2073         // midair gamemode: damage only while in the air
2074         // if in midair mode, being on ground grants temporary invulnerability
2075         // (this is so that multishot weapon don't clear the ground flag on the
2076         // first damage in the frame, leaving the player vulnerable to the
2077         // remaining hits in the same frame)
2078         if (self.flags & FL_ONGROUND)
2079         if (g_midair)
2080                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2081
2082         if (time >= game_starttime)
2083         if (time < self.spawnshieldtime)
2084                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2085 }
2086
2087 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2088 {
2089         if(current > stable)
2090                 return current;
2091         else if(current > stable - 0.25) // when close enough, "snap"
2092                 return stable;
2093         else
2094                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2095 }
2096
2097 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2098 {
2099         if(current < stable)
2100                 return current;
2101         else if(current < stable + 0.25) // when close enough, "snap"
2102                 return stable;
2103         else
2104                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2105 }
2106
2107 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2108 {
2109         if(current > rotstable)
2110         {
2111                 if(rotframetime > 0)
2112                 {
2113                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2114                         current = max(rotstable, current - rotlinear * rotframetime);
2115                 }
2116         }
2117         else if(current < regenstable)
2118         {
2119                 if(regenframetime > 0)
2120                 {
2121                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2122                         current = min(regenstable, current + regenlinear * regenframetime);
2123                 }
2124         }
2125
2126         if(current > limit)
2127                 current = limit;
2128
2129         return current;
2130 }
2131
2132 void player_regen (void)
2133 {
2134         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2135         maxh = cvar("g_balance_health_rotstable");
2136         maxa = cvar("g_balance_armor_rotstable");
2137         maxf = cvar("g_balance_fuel_rotstable");
2138         minh = cvar("g_balance_health_regenstable");
2139         mina = cvar("g_balance_armor_regenstable");
2140         minf = cvar("g_balance_fuel_regenstable");
2141         limith = cvar("g_balance_health_limit");
2142         limita = cvar("g_balance_armor_limit");
2143         limitf = cvar("g_balance_fuel_limit");
2144
2145         max_mod = regen_mod = rot_mod = limit_mod = 1;
2146
2147         if (self.runes & RUNE_REGEN)
2148         {
2149                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2150                 {
2151                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2152                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2153                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2154                 }
2155                 else
2156                 {
2157                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2158                         max_mod = cvar("g_balance_rune_regen_hpmod");
2159                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2160                 }
2161         }
2162         else if (self.runes & CURSE_VENOM)
2163         {
2164                 max_mod = cvar("g_balance_curse_venom_hpmod");
2165                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2166                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2167                 else
2168                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2169                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2170                 //if (!self.runes & RUNE_REGEN)
2171                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2172         }
2173         maxh = maxh * max_mod;
2174         //maxa = maxa * max_mod;
2175         //maxf = maxf * max_mod;
2176         minh = minh * max_mod;
2177         //mina = mina * max_mod;
2178         //minf = minf * max_mod;
2179         limith = limith * limit_mod;
2180         limita = limita * limit_mod;
2181         //limitf = limitf * limit_mod;
2182
2183         if(g_lms && g_ca)
2184                 rot_mod = 0;
2185
2186         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2187         {
2188                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2189                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2190
2191                 // if player rotted to death...  die!
2192                 if(self.health < 1)
2193                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2194         }
2195
2196         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2197                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2198 }
2199
2200 float zoomstate_set;
2201 void SetZoomState(float z)
2202 {
2203         if(z != self.zoomstate)
2204         {
2205                 self.zoomstate = z;
2206                 ClientData_Touch(self);
2207         }
2208         zoomstate_set = 1;
2209 }
2210
2211 void GetPressedKeys(void) {
2212         MUTATOR_CALLHOOK(GetPressedKeys);
2213         if (self.movement_x > 0) // get if movement keys are pressed
2214         {       // forward key pressed
2215                 self.pressedkeys |= KEY_FORWARD;
2216                 self.pressedkeys &~= KEY_BACKWARD;
2217         }
2218         else if (self.movement_x < 0)
2219         {       // backward key pressed
2220                 self.pressedkeys |= KEY_BACKWARD;
2221                 self.pressedkeys &~= KEY_FORWARD;
2222         }
2223         else
2224         {       // no x input
2225                 self.pressedkeys &~= KEY_FORWARD;
2226                 self.pressedkeys &~= KEY_BACKWARD;
2227         }
2228
2229         if (self.movement_y > 0)
2230         {       // right key pressed
2231                 self.pressedkeys |= KEY_RIGHT;
2232                 self.pressedkeys &~= KEY_LEFT;
2233         }
2234         else if (self.movement_y < 0)
2235         {       // left key pressed
2236                 self.pressedkeys |= KEY_LEFT;
2237                 self.pressedkeys &~= KEY_RIGHT;
2238         }
2239         else
2240         {       // no y input
2241                 self.pressedkeys &~= KEY_RIGHT;
2242                 self.pressedkeys &~= KEY_LEFT;
2243         }
2244
2245         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2246                 self.pressedkeys |= KEY_JUMP;
2247         else
2248                 self.pressedkeys &~= KEY_JUMP;
2249         if (self.BUTTON_CROUCH)
2250                 self.pressedkeys |= KEY_CROUCH;
2251         else
2252                 self.pressedkeys &~= KEY_CROUCH;
2253 }
2254
2255 void update_stats (float number, float hit, float fired) {
2256 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2257 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2258
2259         if(number) {
2260                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2261                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2262         } else {
2263                 self.stat_hit = hit * sv_accuracy_data_share;
2264                 self.stat_fired = fired * sv_accuracy_data_share;
2265         }
2266 }
2267
2268 /*
2269 ======================
2270 spectate mode routines
2271 ======================
2272 */
2273
2274 .float weapon_count;
2275 void SpectateCopy(entity spectatee) {
2276         if(spectatee.weapon_count < WEP_LAST) {
2277                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2278                 spectatee.weapon_count ++;
2279         } else
2280                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2281
2282         other = spectatee;
2283         MUTATOR_CALLHOOK(SpectateCopy);
2284         self.armortype = spectatee.armortype;
2285         self.armorvalue = spectatee.armorvalue;
2286         self.ammo_cells = spectatee.ammo_cells;
2287         self.ammo_shells = spectatee.ammo_shells;
2288         self.ammo_nails = spectatee.ammo_nails;
2289         self.ammo_rockets = spectatee.ammo_rockets;
2290         self.ammo_fuel = spectatee.ammo_fuel;
2291         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2292         self.health = spectatee.health;
2293         self.impulse = 0;
2294         self.items = spectatee.items;
2295         self.last_pickup = spectatee.last_pickup;
2296         self.metertime = spectatee.metertime;
2297         self.strength_finished = spectatee.strength_finished;
2298         self.invincible_finished = spectatee.invincible_finished;
2299         self.pressedkeys = spectatee.pressedkeys;
2300         self.weapons = spectatee.weapons;
2301         self.switchweapon = spectatee.switchweapon;
2302         self.weapon = spectatee.weapon;
2303         self.punchangle = spectatee.punchangle;
2304         self.view_ofs = spectatee.view_ofs;
2305         self.v_angle = spectatee.v_angle;
2306         self.velocity = spectatee.velocity;
2307         self.dmg_take = spectatee.dmg_take;
2308         self.dmg_save = spectatee.dmg_save;
2309         self.dmg_inflictor = spectatee.dmg_inflictor;
2310         self.angles = spectatee.v_angle;
2311         self.fixangle = TRUE;
2312         setorigin(self, spectatee.origin);
2313         setsize(self, spectatee.mins, spectatee.maxs);
2314         SetZoomState(spectatee.zoomstate);
2315
2316         anticheat_spectatecopy(spectatee);
2317 }
2318
2319 float SpectateUpdate() {
2320         if(!self.enemy)
2321                 return 0;
2322
2323         if (self == self.enemy)
2324                 return 0;
2325
2326         if(self.enemy.classname != "player")
2327                 return 0;
2328
2329         SpectateCopy(self.enemy);
2330
2331         return 1;
2332 }
2333
2334 float SpectateNext() {
2335         other = find(self.enemy, classname, "player");
2336
2337         if (!other)
2338                 other = find(other, classname, "player");
2339
2340         if (other)
2341                 self.enemy = other;
2342
2343         if(self.enemy.classname == "player") {
2344                 msg_entity = self;
2345                 WriteByte(MSG_ONE, SVC_SETVIEW);
2346                 WriteEntity(MSG_ONE, self.enemy);
2347                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2348                 self.movetype = MOVETYPE_NONE;
2349
2350                 self.enemy.weapon_count = 0;
2351
2352                 if(!SpectateUpdate())
2353                         PutObserverInServer();
2354
2355                 return 1;
2356         } else {
2357                 return 0;
2358         }
2359 }
2360
2361 /*
2362 =============
2363 ShowRespawnCountdown()
2364
2365 Update a respawn countdown display.
2366 =============
2367 */
2368 void ShowRespawnCountdown()
2369 {
2370         float number;
2371         if(self.deadflag == DEAD_NO) // just respawned?
2372                 return;
2373         else
2374         {
2375                 number = ceil(self.death_time - time);
2376                 if(number <= 0)
2377                         return;
2378                 if(number <= self.respawn_countdown)
2379                 {
2380                         self.respawn_countdown = number - 1;
2381                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2382                                 AnnounceTo(self, strcat(ftos(number), ""));
2383                 }
2384         }
2385 }
2386
2387 void LeaveSpectatorMode()
2388 {
2389         if(isJoinAllowed()) {
2390                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2391                         self.classname = "player";
2392
2393                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2394                                 JoinBestTeam(self, FALSE, TRUE);
2395
2396                         if(cvar("g_campaign"))
2397                                 campaign_bots_may_start = 1;
2398
2399                         self.stat_count = WEP_LAST;
2400
2401                         PutClientInServer();
2402
2403                         if(self.classname == "player")
2404                                 bprint ("^4", self.netname, "^4 is playing now\n");
2405
2406                         if(!cvar("g_campaign"))
2407                                 centerprint(self,""); // clear MOTD
2408
2409                         return;
2410                 } else {
2411                         if (g_ca && self.caplayer) {
2412                         }       // do nothing
2413                         else
2414                                 stuffcmd(self,"menu_showteamselect\n");
2415                         return;
2416                 }
2417         }
2418         else {
2419                 //player may not join because of g_maxplayers is set
2420                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2421         }
2422 }
2423
2424 /**
2425  * Determines whether the player is allowed to join. This depends on cvar
2426  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2427  * it checks whether the number of currently playing players exceeds g_maxplayers.
2428  * @return bool TRUE if the player is allowed to join, false otherwise
2429  */
2430 float isJoinAllowed() {
2431         if(self.team_forced < 0)
2432                 return FALSE; // forced spectators can never join
2433
2434         if (!cvar("g_maxplayers"))
2435                 return TRUE;
2436
2437         local entity e;
2438         local float currentlyPlaying;
2439         FOR_EACH_REALPLAYER(e) {
2440                 if(e.classname == "player")
2441                         currentlyPlaying += 1;
2442         }
2443         if(currentlyPlaying < cvar("g_maxplayers"))
2444                 return TRUE;
2445
2446         return FALSE;
2447 }
2448
2449 /**
2450  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2451  * g_maxplayers_spectator_blocktime seconds
2452  */
2453 void checkSpectatorBlock() {
2454         if(self.classname == "spectator" || self.classname == "observer") {
2455                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2456                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2457                         dropclient(self);
2458                 }
2459         }
2460 }
2461
2462 float vercmp_recursive(string v1, string v2)
2463 {
2464         float dot1, dot2;
2465         string s1, s2;
2466         float r;
2467
2468         dot1 = strstrofs(v1, ".", 0);
2469         dot2 = strstrofs(v2, ".", 0);
2470         if(dot1 == -1)
2471                 s1 = v1;
2472         else
2473                 s1 = substring(v1, 0, dot1);
2474         if(dot2 == -1)
2475                 s2 = v2;
2476         else
2477                 s2 = substring(v2, 0, dot2);
2478
2479         r = stof(s1) - stof(s2);
2480         if(r != 0)
2481                 return r;
2482
2483         r = strcasecmp(s1, s2);
2484         if(r != 0)
2485                 return r;
2486
2487         if(dot1 == -1)
2488                 if(dot2 == -1)
2489                         return 0;
2490                 else
2491                         return -1;
2492         else
2493                 if(dot2 == -1)
2494                         return 1;
2495                 else
2496                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2497 }
2498
2499 float vercmp(string v1, string v2)
2500 {
2501         if(strcasecmp(v1, v2) == 0) // early out check
2502                 return 0;
2503         return vercmp_recursive(v1, v2);
2504 }
2505
2506 void ObserverThink()
2507 {
2508         if (self.flags & FL_JUMPRELEASED) {
2509                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2510                         self.welcomemessage_time = 0;
2511                         self.flags &~= FL_JUMPRELEASED;
2512                         self.flags |= FL_SPAWNING;
2513                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2514                         self.welcomemessage_time = 0;
2515                         self.flags &~= FL_JUMPRELEASED;
2516                         if(SpectateNext() == 1) {
2517                                 self.classname = "spectator";
2518                         }
2519                 }
2520         } else {
2521                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2522                         self.flags |= FL_JUMPRELEASED;
2523                         if(self.flags & FL_SPAWNING)
2524                         {
2525                                 self.flags &~= FL_SPAWNING;
2526                                 LeaveSpectatorMode();
2527                                 return;
2528                         }
2529                 }
2530         }
2531         PrintWelcomeMessage(self);
2532 }
2533
2534 void SpectatorThink()
2535 {
2536         if (self.flags & FL_JUMPRELEASED) {
2537                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2538                         self.welcomemessage_time = 0;
2539                         self.flags &~= FL_JUMPRELEASED;
2540                         self.flags |= FL_SPAWNING;
2541                 } else if(self.BUTTON_ATCK) {
2542                         self.welcomemessage_time = 0;
2543                         self.flags &~= FL_JUMPRELEASED;
2544                         if(SpectateNext() == 1) {
2545                                 self.classname = "spectator";
2546                         } else {
2547                                 self.classname = "observer";
2548                                 self.stat_count = WEP_LAST;
2549                                 PutClientInServer();
2550                         }
2551                 } else if (self.BUTTON_ATCK2) {
2552                         self.welcomemessage_time = 0;
2553                         self.flags &~= FL_JUMPRELEASED;
2554                         self.classname = "observer";
2555                         self.stat_count = WEP_LAST;
2556                         PutClientInServer();
2557                 } else {
2558                         if(!SpectateUpdate())
2559                                 PutObserverInServer();
2560                 }
2561         } else {
2562                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2563                         self.flags |= FL_JUMPRELEASED;
2564                         if(self.flags & FL_SPAWNING)
2565                         {
2566                                 self.flags &~= FL_SPAWNING;
2567                                 LeaveSpectatorMode();
2568                                 return;
2569                         }
2570                 }
2571         }
2572
2573         PrintWelcomeMessage(self);
2574         self.flags |= FL_CLIENT | FL_NOTARGET;
2575 }
2576
2577 .float touchexplode_time;
2578
2579 /*
2580 =============
2581 PlayerPreThink
2582
2583 Called every frame for each client before the physics are run
2584 =============
2585 */
2586 void() ctf_setstatus;
2587 void() nexball_setstatus;
2588 .float items_added;
2589 void PlayerPreThink (void)
2590 {
2591         self.stat_game_starttime = game_starttime;
2592         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2593         self.stat_leadlimit = cvar("leadlimit");
2594
2595         if(frametime)
2596         {
2597                 // physics frames: update anticheat stuff
2598                 anticheat_prethink();
2599         }
2600
2601         if(blockSpectators && frametime)
2602                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2603                 checkSpectatorBlock();
2604
2605         zoomstate_set = 0;
2606
2607         if(self.netname_previous != self.netname)
2608         {
2609                 if(cvar("sv_eventlog"))
2610                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2611                 if(self.netname_previous)
2612                         strunzone(self.netname_previous);
2613                 self.netname_previous = strzone(self.netname);
2614         }
2615
2616         // version nagging
2617         if(self.version_nagtime)
2618                 if(self.cvar_g_xonoticversion)
2619                         if(time > self.version_nagtime)
2620                         {
2621                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2622                                 {
2623                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2624                                         {
2625                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2626                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2627                                         }
2628                                         else
2629                                         {
2630                                                 float r;
2631                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2632                                                 if(r < 0)
2633                                                 {
2634                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2635                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2636                                                 }
2637                                                 else if(r > 0)
2638                                                 {
2639                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2640                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2641                                                 }
2642                                         }
2643                                 }
2644                                 self.version_nagtime = 0;
2645                         }
2646
2647         // GOD MODE info
2648         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2649         {
2650                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2651                 self.max_armorvalue = 0;
2652         }
2653
2654 #ifdef TETRIS
2655         if (TetrisPreFrame())
2656                 return;
2657 #endif
2658
2659         MUTATOR_CALLHOOK(PlayerPreThink);
2660
2661         if(self.classname == "player") {
2662 //              if(self.netname == "Wazat")
2663 //                      bprint(self.classname, "\n");
2664
2665                 CheckRules_Player();
2666
2667                 PrintWelcomeMessage(self);
2668
2669                 if (intermission_running)
2670                 {
2671                         IntermissionThink ();   // otherwise a button could be missed between
2672                         return;                                 // the think tics
2673                 }
2674
2675                 if(self.teleport_time)
2676                 if(time > self.teleport_time)
2677                 {
2678                         self.teleport_time = 0;
2679                         self.effects = self.effects - (self.effects & EF_NODRAW);
2680                 }
2681
2682                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2683                         UpdateSelectedPlayer();
2684
2685                 //don't allow the player to turn around while game is paused!
2686                 if(timeoutStatus == 2) {
2687                         self.v_angle = self.lastV_angle;
2688                         self.angles = self.lastV_angle;
2689                         self.fixangle = TRUE;
2690                 }
2691
2692                 if(frametime)
2693                 {
2694                         if(self.health <= 0 && cvar("g_deathglow"))
2695                         {
2696                                 if(self.glowmod_x > 0)
2697                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2698                                 else
2699                                         self.glowmod_x = -1;
2700                                 if(self.glowmod_y > 0)
2701                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2702                                 else
2703                                         self.glowmod_y = -1;
2704                                 if(self.glowmod_z > 0)
2705                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2706                                 else
2707                                         self.glowmod_z = -1;
2708                         }
2709                         else
2710                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2711                         player_powerups();
2712                 }
2713
2714                 if (self.deadflag != DEAD_NO)
2715                 {
2716                         float button_pressed, force_respawn;
2717                         if(self.personal && g_race_qualifying)
2718                         {
2719                                 if(time > self.death_time)
2720                                 {
2721                                         self.death_time = time + 1; // only retry once a second
2722                                         respawn();
2723                                         self.impulse = 141;
2724                                 }
2725                         }
2726                         else
2727                         {
2728                                 if(frametime)
2729                                         player_anim();
2730                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2731                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2732                                 if (self.deadflag == DEAD_DYING)
2733                                 {
2734                                         if(force_respawn)
2735                                                 self.deadflag = DEAD_RESPAWNING;
2736                                         else if(!button_pressed)
2737                                                 self.deadflag = DEAD_DEAD;
2738                                 }
2739                                 else if (self.deadflag == DEAD_DEAD)
2740                                 {
2741                                         if(button_pressed)
2742                                                 self.deadflag = DEAD_RESPAWNABLE;
2743                                 }
2744                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2745                                 {
2746                                         if(!button_pressed)
2747                                                 self.deadflag = DEAD_RESPAWNING;
2748                                 }
2749                                 else if (self.deadflag == DEAD_RESPAWNING)
2750                                 {
2751                                         if(time > self.death_time)
2752                                         {
2753                                                 self.death_time = time + 1; // only retry once a second
2754                                                 respawn();
2755                                         }
2756                                 }
2757                                 ShowRespawnCountdown();
2758                         }
2759                         return;
2760                 }
2761
2762                 if(g_touchexplode)
2763                 if(time > self.touchexplode_time)
2764                 if(self.classname == "player")
2765                 if(self.deadflag == DEAD_NO)
2766                 if not(IS_INDEPENDENT_PLAYER(self))
2767                 FOR_EACH_PLAYER(other) if(self != other)
2768                 {
2769                         if(time > other.touchexplode_time)
2770                         if(other.deadflag == DEAD_NO)
2771                         if not(IS_INDEPENDENT_PLAYER(other))
2772                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2773                         {
2774                                 PlayerTouchExplode(self, other);
2775                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2776                         }
2777                 }
2778
2779                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2780                 {
2781                         vector dist;
2782
2783                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2784                         dist = self.prevorigin - self.origin;
2785                         dist_z = 0;
2786                         self.lms_traveled_distance += fabs(vlen(dist));
2787
2788                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2789                         {
2790                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2791                                 self.lms_traveled_distance = 0;
2792                         }
2793
2794                         if(time > self.lms_nextcheck)
2795                         {
2796                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2797                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2798                                 {
2799                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2800                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2801                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2802                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2803                                 }
2804                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2805                                 self.lms_traveled_distance = 0;
2806                         }
2807                 }
2808
2809                 self.prevorigin = self.origin;
2810
2811                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2812                 {
2813                         if (!self.crouch)
2814                         {
2815                                 self.crouch = TRUE;
2816                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2817                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2818                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2819                         }
2820                 }
2821                 else
2822                 {
2823                         if (self.crouch)
2824                         {
2825                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2826                                 if (!trace_startsolid)
2827                                 {
2828                                         self.crouch = FALSE;
2829                                         self.view_ofs = PL_VIEW_OFS;
2830                                         setsize (self, PL_MIN, PL_MAX);
2831                                 }
2832                         }
2833                 }
2834
2835                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2836                 {
2837                         if(self.bloodloss_timer < time)
2838                         {
2839                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2840                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2841                         }
2842                 }
2843
2844                 FixPlayermodel();
2845
2846                 GrapplingHookFrame();
2847
2848                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2849                 //if(frametime)
2850                 {
2851                         self.items &~= self.items_added;
2852
2853                         W_WeaponFrame();
2854
2855                         self.items_added = 0;
2856                         if(self.items & IT_JETPACK)
2857                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2858                                         self.items_added |= IT_FUEL;
2859
2860                         self.items |= self.items_added;
2861                 }
2862
2863                 player_regen();
2864
2865                 // rot nex charge to the charge limit
2866                 if(cvar("g_balance_nex_charge_rot_rate") && self.nex_charge > cvar("g_balance_nex_charge_limit"))
2867                         self.nex_charge = bound(cvar("g_balance_nex_charge_limit"), self.nex_charge - cvar("g_balance_nex_charge_rot_rate") * frametime / W_TICSPERFRAME, 1);
2868
2869                 if(frametime)
2870                         player_anim();
2871
2872                 if (g_minstagib)
2873                         minstagib_ammocheck();
2874
2875                 ctf_setstatus();
2876                 nexball_setstatus();
2877
2878                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2879
2880                 //self.angles_y=self.v_angle_y + 90;   // temp
2881         } else if(gameover) {
2882                 if (intermission_running)
2883                         IntermissionThink ();   // otherwise a button could be missed between
2884                 return;
2885         } else if(self.classname == "observer") {
2886                 ObserverThink();
2887         } else if(self.classname == "spectator") {
2888                 SpectatorThink();
2889         }
2890
2891         if(!zoomstate_set)
2892                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2893
2894         float oldspectatee_status;
2895         oldspectatee_status = self.spectatee_status;
2896         if(self.classname == "spectator")
2897                 self.spectatee_status = num_for_edict(self.enemy);
2898         else if(self.classname == "observer")
2899                 self.spectatee_status = num_for_edict(self);
2900         else
2901                 self.spectatee_status = 0;
2902         if(self.spectatee_status != oldspectatee_status)
2903         {
2904                 ClientData_Touch(self);
2905                 if(g_race || g_cts)
2906                         race_InitSpectator();
2907         }
2908
2909         if(self.teamkill_soundtime)
2910         if(time > self.teamkill_soundtime)
2911         {
2912                 self.teamkill_soundtime = 0;
2913
2914                 entity oldpusher, oldself;
2915
2916                 oldself = self; self = self.teamkill_soundsource;
2917                 oldpusher = self.pusher; self.pusher = oldself;
2918
2919                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2920
2921                 self.pusher = oldpusher;
2922                 self = oldself;
2923         }
2924
2925         if(self.taunt_soundtime)
2926         if(time > self.taunt_soundtime)
2927         {
2928                 self.taunt_soundtime = 0;
2929                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2930         }
2931
2932         target_voicescript_next(self);
2933 }
2934
2935 float isInvisibleString(string s)
2936 {
2937         float i, n, c;
2938         s = strdecolorize(s);
2939         for((i = 0), (n = strlen(s)); i < n; ++i)
2940         {
2941                 c = str2chr(s, i);
2942                 switch(c)
2943                 {
2944                         case 0:
2945                         case 32: // space
2946                                 break;
2947                         case 192: // charmap space
2948                                 if (!cvar("utf8_enable"))
2949                                         break;
2950                                 return FALSE;
2951                         case 160: // space in unicode fonts
2952                         case 0xE000 + 192: // utf8 charmap space
2953                                 if (cvar("utf8_enable"))
2954                                         break;
2955                         default:
2956                                 return FALSE;
2957                 }
2958         }
2959         return TRUE;
2960 }
2961
2962 /*
2963 =============
2964 PlayerPostThink
2965
2966 Called every frame for each client after the physics are run
2967 =============
2968 */
2969 .float idlekick_lasttimeleft;
2970 .entity showheadshotbbox;
2971 void showheadshotbbox_think()
2972 {
2973         if(self.owner.showheadshotbbox != self)
2974         {
2975                 remove(self);
2976                 return;
2977         }
2978         self.nextthink = time;
2979         setorigin(self, self.owner.origin);
2980         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2981 }
2982 void PlayerPostThink (void)
2983 {
2984         // Savage: Check for nameless players
2985         if (isInvisibleString(self.netname)) {
2986                 self.netname = "Player";
2987                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2988         }
2989
2990         // send the clients accuracy stats to the client
2991         if(self.stat_count > 0)
2992         if(frametime)
2993         {
2994                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2995                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2996                 self.stat_count -= 1;
2997         }
2998
2999         if(sv_maxidle && frametime)
3000         {
3001                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3002                 float timeleft;
3003                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3004                 if(timeleft <= 0)
3005                 {
3006                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3007                         AnnounceTo(self, "terminated");
3008                         dropclient(self);
3009                         return;
3010                 }
3011                 else if(timeleft <= 10)
3012                 {
3013                         if(timeleft != self.idlekick_lasttimeleft)
3014                         {
3015                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3016                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3017                         }
3018                 }
3019                 else
3020                 {
3021                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3022                 }
3023                 self.idlekick_lasttimeleft = timeleft;
3024         }
3025
3026 #ifdef TETRIS
3027         if(self.impulse == 100)
3028                 ImpulseCommands();
3029         if (TetrisPostFrame())
3030                 return;
3031 #endif
3032
3033         CheatFrame();
3034
3035         if(self.classname == "player") {
3036                 CheckRules_Player();
3037                 UpdateChatBubble();
3038                 UpdateTeamBubble();
3039                 if (self.impulse)
3040                         ImpulseCommands();
3041                 if (intermission_running)
3042                         return;         // intermission or finale
3043                 GetPressedKeys();
3044         } else if (self.classname == "observer") {
3045                 //do nothing
3046         } else if (self.classname == "spectator") {
3047                 //do nothing
3048         }
3049
3050         /*
3051         float i;
3052         for(i = 0; i < 1000; ++i)
3053         {
3054                 vector end;
3055                 end = self.origin + '0 0 1024' + 512 * randomvec();
3056                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3057                 if(trace_fraction < 1)
3058                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3059                 {
3060                      &nbs