c1005d0036b9cd18f67eb3598956a4dd80a5fc23
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void send_CSQC_cr_maxbullets(entity e) {
10         msg_entity = e;
11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
13         WriteByte(MSG_ONE, autocvar_g_balance_campingrifle_magazinecapacity);
14 }
15
16 void Announce(string snd) {
17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
19         WriteString(MSG_ALL, snd);
20 }
21
22 void AnnounceTo(entity e, string snd) {
23         if (clienttype(e) == CLIENTTYPE_REAL)
24         {
25                 msg_entity = e;
26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
28                 WriteString(MSG_ONE, snd);
29         }
30 }
31
32 float ClientData_Send(entity to, float sf)
33 {
34         if(to != self.owner)
35         {
36                 error("wtf");
37                 return FALSE;
38         }
39
40         entity e;
41
42         e = to;
43         if(to.classname == "spectator")
44                 e = to.enemy;
45
46         sf = 0;
47
48         if(e.race_completed)
49                 sf |= 1; // forced scoreboard
50         if(to.spectatee_status)
51                 sf |= 2; // spectator ent number follows
52         if(e.zoomstate)
53                 sf |= 4; // zoomed
54         if(e.porto_v_angle_held)
55                 sf |= 8; // angles held
56
57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
58         WriteByte(MSG_ENTITY, sf);
59
60         if(sf & 2)
61                 WriteByte(MSG_ENTITY, to.spectatee_status);
62
63         if(sf & 8)
64         {
65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
67         }
68
69         return TRUE;
70 }
71
72 void ClientData_Attach()
73 {
74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
75         self.clientdata.drawonlytoclient = self;
76         self.clientdata.owner = self;
77 }
78
79 void ClientData_Detach()
80 {
81         remove(self.clientdata);
82         self.clientdata = world;
83 }
84
85 void ClientData_Touch(entity e)
86 {
87         e.clientdata.SendFlags = 1;
88
89         // make it spectatable
90         entity e2;
91         FOR_EACH_REALCLIENT(e2)
92         {
93                 if(e2 != e)
94                         if(e2.classname == "spectator")
95                                 if(e2.enemy == e)
96                                         e2.clientdata.SendFlags = 1;
97         }
98 }
99
100
101 .vector spawnpoint_score;
102 .string netname_previous;
103
104 void spawnfunc_info_player_survivor (void)
105 {
106         spawnfunc_info_player_deathmatch();
107 }
108
109 void spawnfunc_info_player_start (void)
110 {
111         spawnfunc_info_player_deathmatch();
112 }
113
114 void spawnfunc_info_player_deathmatch (void)
115 {
116         self.classname = "info_player_deathmatch";
117         relocate_spawnpoint();
118 }
119
120 void spawnpoint_use()
121 {
122         if(teams_matter)
123         if(have_team_spawns > 0)
124         {
125                 self.team = activator.team;
126                 some_spawn_has_been_used = 1;
127         }
128 };
129
130 // Returns:
131 //   _x: prio (-1 if unusable)
132 //   _y: weight
133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
134 {
135         float shortest, thisdist;
136         float prio;
137         entity player;
138
139         prio = 0;
140
141         // filter out spots for the wrong team
142         if(teamcheck)
143         if(spot.team != teamcheck)
144                 return '-1 0 0';
145
146         if(race_spawns)
147                 if(spot.target == "")
148                         return '-1 0 0';
149
150         if(clienttype(self) == CLIENTTYPE_REAL)
151         {
152                 if(spot.restriction == 1)
153                         return '-1 0 0';
154         }
155         else
156         {
157                 if(spot.restriction == 2)
158                         return '-1 0 0';
159         }
160
161         // filter out spots for assault
162         if(spot.target != "") {
163                 local entity ent;
164                 float good, found;
165                 ent = find(world, targetname, spot.target);
166
167                 while(ent) {
168                         if(ent.classname == "target_objective")
169                         {
170                                 found = 1;
171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
172                                         return '-1 0 0';
173                                 good = 1;
174                         }
175                         else if(ent.classname == "trigger_race_checkpoint")
176                         {
177                                 found = 1;
178                                 if(!anypoint) // spectators may spawn everywhere
179
180                                 {
181                                         if(g_race_qualifying)
182                                         {
183                                                 // spawn at first
184                                                 if(ent.race_checkpoint != 0)
185                                                         return '-1 0 0';
186                                                 if(spot.race_place != race_lowest_place_spawn)
187                                                         return '-1 0 0';
188                                         }
189                                         else
190                                         {
191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
192                                                         return '-1 0 0';
193                                                 // try reusing the previous spawn
194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
195                                                         prio += 1;
196                                                 if(ent.race_checkpoint == 0)
197                                                 {
198                                                         float pl;
199                                                         pl = self.race_place;
200                                                         if(pl > race_highest_place_spawn)
201                                                                 pl = 0;
202                                                         if(pl == 0 && !self.race_started)
203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
204                                                         if(spot.race_place != pl)
205                                                                 return '-1 0 0';
206                                                 }
207                                         }
208                                 }
209                                 good = 1;
210                         }
211                         ent = find(ent, targetname, spot.target);
212                 }
213
214                 if(found && !good)
215                         return '-1 0 0';
216         }
217
218         player = playerlist;
219         shortest = vlen(world.maxs - world.mins);
220         for(player = playerlist; player; player = player.chain)
221                 if (player != self)
222                 {
223                         thisdist = vlen(player.origin - spot.origin);
224                         if (thisdist < shortest)
225                                 shortest = thisdist;
226                 }
227         return prio * '1 0 0' + shortest * '0 1 0';
228 }
229
230 float spawn_allbad;
231 float spawn_allgood;
232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
233 {
234         local entity spot, spotlist, spotlistend;
235         spawn_allgood = TRUE;
236         spawn_allbad = TRUE;
237
238         spotlist = world;
239         spotlistend = world;
240
241         for(spot = firstspot; spot; spot = spot.chain)
242         {
243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
244
245                 if(autocvar_spawn_debugview)
246                 {
247                         setmodel(spot, "models/runematch/rune.mdl");
248                         if(spot.spawnpoint_score_y < mindist)
249                         {
250                                 spot.colormod = '1 0 0';
251                                 spot.scale = 1;
252                         }
253                         else
254                         {
255                                 spot.colormod = '0 1 0';
256                                 spot.scale = spot.spawnpoint_score_y / mindist;
257                         }
258                 }
259
260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
261                 {
262                         if(spot.spawnpoint_score_y < mindist)
263                         {
264                                 // too short distance
265                                 spawn_allgood = FALSE;
266                         }
267                         else
268                         {
269                                 // perfect
270                                 spawn_allbad = FALSE;
271
272                                 if(spotlistend)
273                                         spotlistend.chain = spot;
274                                 spotlistend = spot;
275                                 if(!spotlist)
276                                         spotlist = spot;
277
278                                 /*
279                                 if(teamcheck)
280                                 if(spot.team != teamcheck)
281                                         error("invalid spawn added");
282
283                                 print("added ", etos(spot), "\n");
284                                 */
285                         }
286                 }
287         }
288         if(spotlistend)
289                 spotlistend.chain = world;
290
291         /*
292                 entity e;
293                 if(teamcheck)
294                         for(e = spotlist; e; e = e.chain)
295                         {
296                                 print("seen ", etos(e), "\n");
297                                 if(e.team != teamcheck)
298                                         error("invalid spawn found");
299                         }
300         */
301
302         return spotlist;
303 }
304
305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
306 {
307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
309         local entity spot;
310
311         RandomSelection_Init();
312         for(spot = firstspot; spot; spot = spot.chain)
313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
314
315         return RandomSelection_chosen_ent;
316 }
317
318 /*
319 =============
320 SelectSpawnPoint
321
322 Finds a point to respawn
323 =============
324 */
325 entity SelectSpawnPoint (float anypoint)
326 {
327         local float teamcheck;
328         local entity firstspot_new;
329         local entity spot, firstspot, playerlist;
330
331         spot = find (world, classname, "testplayerstart");
332         if (spot)
333                 return spot;
334
335         teamcheck = 0;
336
337         if(!anypoint && have_team_spawns > 0)
338                 teamcheck = self.team;
339
340         // get the list of players
341         playerlist = findchain(classname, "player");
342         // get the entire list of spots
343         firstspot = findchain(classname, "info_player_deathmatch");
344         // filter out the bad ones
345         // (note this returns the original list if none survived)
346         if(anypoint)
347         {
348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
349         }
350         else
351         {
352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
353                 if(!firstspot_new)
354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
355                 firstspot = firstspot_new;
356
357                 // there is 50/50 chance of choosing a random spot or the furthest spot
358                 // (this means that roughly every other spawn will be furthest, so you
359                 // usually won't get fragged at spawn twice in a row)
360                 if (arena_roundbased && !g_ca)
361                 {
362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
363                         if(firstspot_new)
364                                 firstspot = firstspot_new;
365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
366                 }
367                 else if (random() > autocvar_g_spawn_furthest)
368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
369                 else
370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
371         }
372
373         if(autocvar_spawn_debugview)
374         {
375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
376
377                 entity e;
378                 if(teamcheck)
379                         for(e = firstspot; e; e = e.chain)
380                                 if(e.team != teamcheck)
381                                         error("invalid spawn found");
382         }
383
384         if (!spot)
385         {
386                 if(autocvar_spawn_debug)
387                         GotoNextMap();
388                 else
389                 {
390                         if(some_spawn_has_been_used)
391                                 return world; // team can't spawn any more, because of actions of other team
392                         else
393                                 error("Cannot find a spawn point - please fix the map!");
394                 }
395         }
396
397         return spot;
398 }
399
400 /*
401 =============
402 CheckPlayerModel
403
404 Checks if the argument string can be a valid playermodel.
405 Returns a valid one in doubt.
406 =============
407 */
408 string FallbackPlayerModel;
409 string CheckPlayerModel(string plyermodel) {
410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
411         {
412                 // note: we cannot summon Don Strunzone here, some player may
413                 // still have the model string set. In case anyone manages how
414                 // to change a cvar default, we'll have a small leak here.
415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
416         }
417         if(strlen(plyermodel) < 4)
418                 return FallbackPlayerModel;
419         if( substring(plyermodel,0,14) != "models/player/")
420                 return FallbackPlayerModel;
421         else if(autocvar_sv_servermodelsonly)
422         {
423                 if(substring(plyermodel,-4,4) != ".zym")
424                 if(substring(plyermodel,-4,4) != ".dpm")
425                 if(substring(plyermodel,-4,4) != ".iqm")
426                 if(substring(plyermodel,-4,4) != ".md3")
427                 if(substring(plyermodel,-4,4) != ".psk")
428                         return FallbackPlayerModel;
429                 // forbid the LOD models
430                 if(substring(plyermodel, -9,5) == "_lod1")
431                         return FallbackPlayerModel;
432                 if(substring(plyermodel, -9,5) == "_lod2")
433                         return FallbackPlayerModel;
434                 if(plyermodel != strtolower(plyermodel))
435                         return FallbackPlayerModel;
436                 if(!fexists(plyermodel))
437                         return FallbackPlayerModel;
438         }
439         return plyermodel;
440 }
441
442 /*
443 =============
444 Client_customizeentityforclient
445
446 LOD reduction
447 =============
448 */
449 void Client_uncustomizeentityforclient()
450 {
451         if(self.modelindex == 0) // no need to uncustomize then
452                 return;
453         self.modelindex = self.modelindex_lod0;
454         self.skin = self.skinindex;
455 }
456
457 float Client_customizeentityforclient()
458 {
459         entity modelsource;
460
461         if(self.modelindex == 0)
462                 return TRUE;
463
464         // forcemodel stuff
465
466 #ifdef PROFILING
467         float t0;
468         t0 = gettime(GETTIME_HIRES); // reference
469 #endif
470
471         modelsource = self;
472
473 #ifdef ALLOW_FORCEMODELS
474         if(other.cvar_cl_forceplayermodelsfromxonotic)
475                 if not(self.modelindex_lod0_from_xonotic)
476                         modelsource = other;
477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
478                 modelsource = other;
479 #endif
480
481         self.skin = modelsource.skinindex;
482
483 #if 0
484         if(modelsource == self)
485                 self.skin = modelsource.skinindex;
486         else
487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
488 #endif
489
490         // self: me
491         // other: the player viewing me
492         float distance;
493         float f;
494
495         if(other.cvar_cl_playerdetailreduction <= 0)
496         {
497                 if(other.cvar_cl_playerdetailreduction <= -2)
498                         self.modelindex = modelsource.modelindex_lod2;
499                 else if(other.cvar_cl_playerdetailreduction <= -1)
500                         self.modelindex = modelsource.modelindex_lod1;
501                 else
502                         self.modelindex = modelsource.modelindex_lod0;
503         }
504         else
505         {
506                 distance = vlen(self.origin - other.origin);
507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
508                 if(f > sv_loddistance2)
509                         self.modelindex = modelsource.modelindex_lod2;
510                 else if(f > sv_loddistance1)
511                         self.modelindex = modelsource.modelindex_lod1;
512                 else
513                         self.modelindex = modelsource.modelindex_lod0;
514         }
515
516 #ifdef PROFILING
517         float t1;
518         t1 = gettime(GETTIME_HIRES); // reference
519         client_cefc_accumulator += (t1 - t0);
520 #endif
521
522         return TRUE;
523 }
524
525 void setmodel_lod(entity e, string modelname)
526 {
527         string s;
528
529         if(sv_loddistance1)
530         {
531                 // FIXME: this only supports 3-letter extensions
532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
533                 if(fexists(s))
534                 {
535                         setmodel(e, s); // players have high precision
536                         self.modelindex_lod1 = self.modelindex;
537                 }
538                 else
539                         self.modelindex_lod1 = -1;
540
541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
542                 if(fexists(s))
543                 {
544                         setmodel(e, s); // players have high precision
545                         self.modelindex_lod2 = self.modelindex;
546                 }
547                 else
548                         self.modelindex_lod2 = -1;
549
550                 precache_model(modelname);
551                 setmodel(e, modelname); // players have high precision
552                 self.modelindex_lod0 = self.modelindex;
553
554                 if(self.modelindex_lod1 < 0)
555                         self.modelindex_lod1 = self.modelindex;
556
557                 if(self.modelindex_lod2 < 0)
558                         self.modelindex_lod2 = self.modelindex;
559         }
560         else
561         {
562                 precache_model(modelname);
563                 setmodel(e, modelname); // players have high precision
564                 self.modelindex_lod0 = self.modelindex;
565                         // save it for possible player model forcing
566         }
567
568         s = whichpack(self.model);
569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
570
571         player_setupanimsformodel();
572         UpdatePlayerSounds();
573 }
574
575 /*
576 =============
577 PutObserverInServer
578
579 putting a client as observer in the server
580 =============
581 */
582 void FixPlayermodel();
583 void PutObserverInServer (void)
584 {
585         entity  spot;
586
587         race_PreSpawnObserver();
588
589         spot = SelectSpawnPoint (TRUE);
590         if(!spot)
591                 error("No spawnpoints for observers?!?\n");
592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
593
594         if(clienttype(self) == CLIENTTYPE_REAL)
595         {
596                 msg_entity = self;
597                 WriteByte(MSG_ONE, SVC_SETVIEW);
598                 WriteEntity(MSG_ONE, self);
599         }
600
601         DropAllRunes(self);
602         MUTATOR_CALLHOOK(MakePlayerObserver);
603
604         Portal_ClearAll(self);
605
606         if(self.alivetime)
607         {
608                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
609                 self.alivetime = 0;
610         }
611
612         if(self.flagcarried)
613                 DropFlag(self.flagcarried, world, world);
614
615         if(self.ballcarried && g_nexball)
616                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
617
618         WaypointSprite_PlayerDead();
619
620         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
621                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
622
623         if(self.killcount != -666) {
624                 if(g_lms) {
625                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
626                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
627                         else
628                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
629                 } else
630                         bprint ("^4", self.netname, "^4 is spectating now\n");
631
632                 if(self.just_joined == FALSE) {
633                         LogTeamchange(self.playerid, -1, 4);
634                 } else
635                         self.just_joined = FALSE;
636         }
637
638         PlayerScore_Clear(self); // clear scores when needed
639
640         accuracy_resend(self);
641
642         self.spectatortime = time;
643
644         self.classname = "observer";
645         self.iscreature = FALSE;
646         self.health = -666;
647         self.takedamage = DAMAGE_NO;
648         self.solid = SOLID_NOT;
649         self.movetype = MOVETYPE_NOCLIP;
650         self.flags = FL_CLIENT | FL_NOTARGET;
651         self.armorvalue = 666;
652         self.effects = 0;
653         self.armorvalue = autocvar_g_balance_armor_start;
654         self.pauserotarmor_finished = 0;
655         self.pauserothealth_finished = 0;
656         self.pauseregen_finished = 0;
657         self.damageforcescale = 0;
658         self.death_time = 0;
659         self.dead_frame = 0;
660         self.alpha = 0;
661         self.scale = 0;
662         self.fade_time = 0;
663         self.pain_frame = 0;
664         self.pain_finished = 0;
665         self.strength_finished = 0;
666         self.invincible_finished = 0;
667         self.pushltime = 0;
668         self.think = SUB_Null;
669         self.nextthink = 0;
670         self.hook_time = 0;
671         self.runes = 0;
672         self.deadflag = DEAD_NO;
673         self.angles = spot.angles;
674         self.angles_z = 0;
675         self.fixangle = TRUE;
676         self.crouch = FALSE;
677
678         self.view_ofs = PL_VIEW_OFS;
679         setorigin (self, spot.origin);
680         setsize (self, '0 0 0', '0 0 0');
681         self.prevorigin = self.origin;
682         self.items = 0;
683         self.weapons = 0;
684         self.model = "";
685         FixPlayermodel();
686         self.model = "";
687         self.modelindex = 0;
688         self.weapon = 0;
689         self.weaponmodel = "";
690         self.weaponentity = world;
691         self.exteriorweaponentity = world;
692         self.killcount = -666;
693         self.velocity = '0 0 0';
694         self.avelocity = '0 0 0';
695         self.punchangle = '0 0 0';
696         self.punchvector = '0 0 0';
697         self.oldvelocity = self.velocity;
698         self.fire_endtime = -1;
699
700         if(sv_loddistance1)
701                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
702
703         if(g_arena)
704         {
705                 if(self.version_mismatch)
706                 {
707                         Spawnqueue_Unmark(self);
708                         Spawnqueue_Remove(self);
709                 }
710                 else
711                 {
712                         Spawnqueue_Insert(self);
713                 }
714         }
715         else if(g_lms)
716         {
717                 // Only if the player cannot play at all
718                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
719                         self.frags = FRAGS_SPECTATOR;
720                 else
721                         self.frags = FRAGS_LMS_LOSER;
722         }
723         else
724                 self.frags = FRAGS_SPECTATOR;
725 }
726
727 float RestrictSkin(float s)
728 {
729         if(!teams_matter)
730                 return s;
731         if(s == 6)
732                 return 6;
733         return mod(s, 3);
734 }
735
736 void FixPlayermodel()
737 {
738         local string defaultmodel;
739         local float defaultskin, chmdl, oldskin;
740         local vector m1, m2;
741
742         defaultmodel = "";
743
744         if(autocvar_sv_defaultcharacter == 1) {
745                 defaultskin = 0;
746
747                 if(teams_matter)
748                 {
749                         string s;
750                         s = Team_ColorNameLowerCase(self.team);
751                         if(s != "neutral")
752                         {
753                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
754                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
755                         }
756                 }
757
758                 if(defaultmodel == "")
759                 {
760                         defaultmodel = autocvar_sv_defaultplayermodel;
761                         defaultskin = autocvar_sv_defaultplayerskin;
762                 }
763         }
764
765         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
766         {
767                 if(self.model != "")
768                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
769                 self.model = ""; // force the != checks to return true
770         }
771
772         if(defaultmodel != "")
773         {
774                 if (defaultmodel != self.model)
775                 {
776                         m1 = self.mins;
777                         m2 = self.maxs;
778                         setmodel_lod (self, defaultmodel);
779                         setsize (self, m1, m2);
780                         chmdl = TRUE;
781                 }
782
783                 oldskin = self.skinindex;
784                 self.skinindex = defaultskin;
785         } else {
786                 if (self.playermodel != self.model || self.playermodel == "")
787                 {
788                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
789                         m1 = self.mins;
790                         m2 = self.maxs;
791                         setmodel_lod (self, self.playermodel);
792                         setsize (self, m1, m2);
793                         chmdl = TRUE;
794                 }
795
796                 oldskin = self.skinindex;
797                 self.skinindex = RestrictSkin(stof(self.playerskin));
798         }
799
800         if(chmdl || oldskin != self.skinindex)
801                 self.species = player_getspecies(); // model or skin has changed
802
803         if(!teams_matter)
804                 if(strlen(autocvar_sv_defaultplayercolors))
805                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
806                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
807 }
808
809 void PlayerTouchExplode(entity p1, entity p2)
810 {
811         vector org;
812         org = (p1.origin + p2.origin) * 0.5;
813         org_z += (p1.mins_z + p2.mins_z) * 0.5;
814
815         te_explosion(org);
816
817         entity e;
818         e = spawn();
819         setorigin(e, org);
820         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
821         remove(e);
822 }
823
824 /*
825 =============
826 PutClientInServer
827
828 Called when a client spawns in the server
829 =============
830 */
831 //void() ctf_playerchanged;
832 void PutClientInServer (void)
833 {
834         if(clienttype(self) == CLIENTTYPE_BOT)
835         {
836                 self.classname = "player";
837         }
838         else if(clienttype(self) == CLIENTTYPE_REAL)
839         {
840                 msg_entity = self;
841                 WriteByte(MSG_ONE, SVC_SETVIEW);
842                 WriteEntity(MSG_ONE, self);
843         }
844
845         // player is dead and becomes observer
846         // FIXME fix LMS scoring for new system
847         if(g_lms)
848         {
849                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
850                         self.classname = "observer";
851         }
852
853         if(g_arena || (g_ca && !allowed_to_spawn))
854         if(!self.spawned)
855                 self.classname = "observer";
856
857         if(gameover)
858                 self.classname = "observer";
859
860         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
861                 entity spot, oldself;
862                 float j;
863
864                 accuracy_resend(self);
865
866                 if(self.team < 0)
867                         JoinBestTeam(self, FALSE, TRUE);
868
869                 race_PreSpawn();
870
871                 spot = SelectSpawnPoint (FALSE);
872                 if(!spot)
873                 {
874                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
875                         return; // spawn failed
876                 }
877
878                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
879
880                 self.classname = "player";
881                 self.wasplayer = TRUE;
882                 self.iscreature = TRUE;
883                 self.movetype = MOVETYPE_WALK;
884                 self.solid = SOLID_SLIDEBOX;
885                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
886                 if(autocvar_g_playerclip_collisions)
887                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
888                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
889                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
890                 self.frags = FRAGS_PLAYER;
891                 if(independent_players)
892                         MAKE_INDEPENDENT_PLAYER(self);
893                 self.flags = FL_CLIENT;
894                 self.takedamage = DAMAGE_AIM;
895                 if(g_minstagib)
896                         self.effects = EF_FULLBRIGHT;
897                 else
898                         self.effects = 0;
899                 self.air_finished = time + 12;
900                 self.dmg = 2;
901                 if(autocvar_g_balance_nex_charge)
902                 {
903                         if(autocvar_g_balance_nex_secondary_chargepool)
904                                 self.nex_chargepool_ammo = 1;
905                         self.nex_charge = autocvar_g_balance_nex_charge_start;
906                 }
907
908                 if(inWarmupStage)
909                 {
910                         self.ammo_shells = warmup_start_ammo_shells;
911                         self.ammo_nails = warmup_start_ammo_nails;
912                         self.ammo_rockets = warmup_start_ammo_rockets;
913                         self.ammo_cells = warmup_start_ammo_cells;
914                         self.ammo_fuel = warmup_start_ammo_fuel;
915                         self.health = warmup_start_health;
916                         self.armorvalue = warmup_start_armorvalue;
917                         self.weapons = warmup_start_weapons;
918                 }
919                 else
920                 {
921                         self.ammo_shells = start_ammo_shells;
922                         self.ammo_nails = start_ammo_nails;
923                         self.ammo_rockets = start_ammo_rockets;
924                         self.ammo_cells = start_ammo_cells;
925                         self.ammo_fuel = start_ammo_fuel;
926                         self.health = start_health;
927                         self.armorvalue = start_armorvalue;
928                         self.weapons = start_weapons;
929                 }
930
931                 if(g_weaponarena_random)
932                 {
933                         if(g_weaponarena_random_with_laser)
934                                 self.weapons &~= WEPBIT_LASER;
935                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
936                         if(g_weaponarena_random_with_laser)
937                                 self.weapons |= WEPBIT_LASER;
938                 }
939
940                 self.items = start_items;
941                 self.jump_interval = time;
942
943                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
944                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
945                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
946                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
947                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
948                 //extend the pause of rotting if client was reset at the beginning of the countdown
949                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
950                         self.spawnshieldtime += game_starttime - time;
951                         self.pauserotarmor_finished += game_starttime - time;
952                         self.pauserothealth_finished += game_starttime - time;
953                         self.pauseregen_finished += game_starttime - time;
954                 }
955                 self.damageforcescale = 2;
956                 self.death_time = 0;
957                 self.dead_frame = 0;
958                 self.alpha = 0;
959                 self.scale = 0;
960                 self.fade_time = 0;
961                 self.pain_frame = 0;
962                 self.pain_finished = 0;
963                 self.strength_finished = 0;
964                 self.invincible_finished = 0;
965                 self.pushltime = 0;
966                 // players have no think function
967                 self.think = SUB_Null;
968                 self.nextthink = 0;
969                 self.hook_time = 0;
970                 self.dmg_team = 0;
971                 self.ballistics_density = autocvar_g_ballistics_density_player;
972
973                 self.metertime = 0;
974
975                 self.runes = 0;
976
977                 self.deadflag = DEAD_NO;
978
979                 self.angles = spot.angles;
980
981                 self.angles_z = 0; // never spawn tilted even if the spot says to
982                 self.fixangle = TRUE; // turn this way immediately
983                 self.velocity = '0 0 0';
984                 self.avelocity = '0 0 0';
985                 self.punchangle = '0 0 0';
986                 self.punchvector = '0 0 0';
987                 self.oldvelocity = self.velocity;
988                 self.fire_endtime = -1;
989
990                 msg_entity = self;
991                 WRITESPECTATABLE_MSG_ONE({
992                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
993                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
994                 });
995
996                 if(sv_loddistance1)
997                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
998
999                 self.model = "";
1000                 FixPlayermodel();
1001
1002                 self.crouch = FALSE;
1003                 self.view_ofs = PL_VIEW_OFS;
1004                 setsize (self, PL_MIN, PL_MAX);
1005                 self.spawnorigin = spot.origin;
1006                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1007                 // don't reset back to last position, even if new position is stuck in solid
1008                 self.oldorigin = self.origin;
1009                 self.prevorigin = self.origin;
1010                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1011
1012                 if(g_arena)
1013                 {
1014                         Spawnqueue_Remove(self);
1015                         Spawnqueue_Mark(self);
1016                 }
1017
1018                 else if(g_ca)
1019                         self.caplayer = 1;
1020
1021                 self.event_damage = PlayerDamage;
1022
1023                 self.bot_attack = TRUE;
1024
1025                 self.statdraintime = time + 5;
1026                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1027
1028                 if(self.killcount == -666) {
1029                         PlayerScore_Clear(self);
1030                         self.killcount = 0;
1031                 }
1032
1033                 self.cnt = WEP_LASER;
1034
1035                 CL_SpawnWeaponentity();
1036                 self.alpha = default_player_alpha;
1037                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1038                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1039
1040                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1041                 self.lms_traveled_distance = 0;
1042                 self.speedrunning = FALSE;
1043
1044                 race_PostSpawn(spot);
1045
1046                 if(autocvar_spawn_debug)
1047                 {
1048                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1049                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1050                 }
1051
1052                 //stuffcmd(self, "chase_active 0");
1053                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1054
1055                 if (autocvar_g_spawnsound)
1056                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1057
1058                 if(g_assault) {
1059                         if(self.team == assault_attacker_team)
1060                                 centerprint(self, "You are attacking!");
1061                         else
1062                                 centerprint(self, "You are defending!");
1063                 }
1064
1065                 target_voicescript_clear(self);
1066
1067                 // reset fields the weapons may use
1068                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1069                         weapon_action(j, WR_RESETPLAYER);
1070
1071                 oldself = self;
1072                 self = spot;
1073                         activator = oldself;
1074                                 SUB_UseTargets();
1075                         activator = world;
1076                 self = oldself;
1077
1078                 MUTATOR_CALLHOOK(PlayerSpawn);
1079
1080                 self.switchweapon = w_getbestweapon(self);
1081                 self.cnt = self.switchweapon;
1082                 self.weapon = 0;
1083
1084                 if(!self.alivetime)
1085                         self.alivetime = time;
1086         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1087                 PutObserverInServer ();
1088         }
1089
1090         //if(g_ctf)
1091         //      ctf_playerchanged();
1092 }
1093
1094 .float ebouncefactor, ebouncestop; // electro's values
1095 // TODO do we need all these fields, or should we stop autodetecting runtime
1096 // changes and just have a console command to update this?
1097 float ClientInit_SendEntity(entity to, float sf)
1098 {
1099         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1100         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1110         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1111         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1112         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1113         if(sv_foginterval && world.fog != "")
1114                 WriteString(MSG_ENTITY, world.fog);
1115         else
1116                 WriteString(MSG_ENTITY, "");
1117         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1118         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1119         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1120         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1121         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1122         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1123         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1124         WriteByte(MSG_ENTITY, autocvar_g_balance_campingrifle_secondary); // client has to know if it should zoom or not
1125         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1126         return TRUE;
1127 }
1128
1129 void ClientInit_CheckUpdate()
1130 {
1131         self.nextthink = time;
1132         if(self.count != autocvar_g_balance_armor_blockpercent)
1133         {
1134                 self.count = autocvar_g_balance_armor_blockpercent;
1135                 self.SendFlags |= 1;
1136         }
1137         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1138         {
1139                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1140                 self.SendFlags |= 1;
1141         }
1142         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1143         {
1144                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1145                 self.SendFlags |= 1;
1146         }
1147         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1148         {
1149                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1150                 self.SendFlags |= 1;
1151         }
1152         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1153         {
1154                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1155                 self.SendFlags |= 1;
1156         }
1157         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1158         {
1159                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1160                 self.SendFlags |= 1;
1161         }
1162 }
1163
1164 void ClientInit_Spawn()
1165 {
1166         entity o;
1167         entity e;
1168         e = spawn();
1169         e.classname = "clientinit";
1170         e.think = ClientInit_CheckUpdate;
1171         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1172
1173         o = self;
1174         self = e;
1175         ClientInit_CheckUpdate();
1176         self = o;
1177 }
1178
1179 /*
1180 =============
1181 SetNewParms
1182 =============
1183 */
1184 void SetNewParms (void)
1185 {
1186         // initialize parms for a new player
1187         parm1 = -(86400 * 366);
1188 }
1189
1190 /*
1191 =============
1192 SetChangeParms
1193 =============
1194 */
1195 void SetChangeParms (void)
1196 {
1197         // save parms for level change
1198         parm1 = self.parm_idlesince - time;
1199 }
1200
1201 /*
1202 =============
1203 DecodeLevelParms
1204 =============
1205 */
1206 void DecodeLevelParms (void)
1207 {
1208         // load parms
1209         self.parm_idlesince = parm1;
1210         if(self.parm_idlesince == -(86400 * 366))
1211                 self.parm_idlesince = time;
1212
1213         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1214         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1215 }
1216
1217 /*
1218 =============
1219 ClientKill
1220
1221 Called when a client types 'kill' in the console
1222 =============
1223 */
1224
1225 void ClientKill_Now_TeamChange()
1226 {
1227         if(self.killindicator_teamchange == -1)
1228         {
1229                 self.team = -1;
1230                 JoinBestTeam( self, FALSE, FALSE );
1231         }
1232         else
1233                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1234 }
1235
1236 void ClientKill_Now()
1237 {
1238         if(self.killindicator_teamchange)
1239                 ClientKill_Now_TeamChange();
1240
1241         // in any case:
1242         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1243
1244         if(self.killindicator)
1245         {
1246                 dprint("Cleaned up after a leaked kill indicator.\n");
1247                 remove(self.killindicator);
1248                 self.killindicator = world;
1249         }
1250 }
1251 void KillIndicator_Think()
1252 {
1253         if (!self.owner.modelindex)
1254         {
1255                 self.owner.killindicator = world;
1256                 remove(self);
1257                 return;
1258         }
1259
1260         if(self.cnt <= 0)
1261         {
1262                 self = self.owner;
1263                 ClientKill_Now(); // no oldself needed
1264                 return;
1265         }
1266     else if(g_cts)
1267     {
1268         self.nextthink = time + 1;
1269         self.cnt -= 1;
1270     }
1271         else
1272         {
1273                 if(self.cnt <= 10)
1274                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1275                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1276                 {
1277                         if(self.cnt <= 10)
1278                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1279                         if(self.owner.killindicator_teamchange)
1280                         {
1281                                 if(self.owner.killindicator_teamchange == -1)
1282                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1283                                 else
1284                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1285                         }
1286                         else
1287                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1288                 }
1289                 self.nextthink = time + 1;
1290                 self.cnt -= 1;
1291         }
1292 }
1293
1294 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1295 {
1296         float killtime;
1297         entity e;
1298         killtime = autocvar_g_balance_kill_delay;
1299
1300         if(g_race_qualifying)
1301                 killtime = 0;
1302
1303         self.killindicator_teamchange = targetteam;
1304
1305     if(g_cts) // allow an instant kill in CTS
1306     {
1307         ClientKill_Now();
1308         return;
1309     }
1310
1311     else if(!self.killindicator)
1312         {
1313                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1314                 {
1315                         ClientKill_Now();
1316                 }
1317                 else
1318                 {
1319                         self.killindicator = spawn();
1320                         self.killindicator.owner = self;
1321                         self.killindicator.scale = 0.5;
1322                         setattachment(self.killindicator, self, "");
1323                         setorigin(self.killindicator, '0 0 52');
1324                         self.killindicator.think = KillIndicator_Think;
1325                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1326                         self.killindicator.cnt = ceil(killtime);
1327                         self.killindicator.count = bound(0, ceil(killtime), 10);
1328                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1329
1330                         for(e = world; (e = find(e, classname, "body")) != world; )
1331                         {
1332                                 if(e.enemy != self)
1333                                         continue;
1334                                 e.killindicator = spawn();
1335                                 e.killindicator.owner = e;
1336                                 e.killindicator.scale = 0.5;
1337                                 setattachment(e.killindicator, e, "");
1338                                 setorigin(e.killindicator, '0 0 52');
1339                                 e.killindicator.think = KillIndicator_Think;
1340                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1341                                 e.killindicator.cnt = ceil(killtime);
1342                         }
1343                         self.lip = 0;
1344                 }
1345         }
1346         if(self.killindicator)
1347         {
1348                 if(targetteam)
1349                         self.killindicator.colormod = TeamColor(targetteam);
1350                 else
1351                         self.killindicator.colormod = '0 0 0';
1352         }
1353 }
1354
1355 void ClientKill (void)
1356 {
1357         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1358         {
1359                 // do nothing
1360         }
1361     else if(g_freezetag && self.freezetag_frozen == 1)
1362     {
1363         // do nothing
1364     }
1365         else
1366                 ClientKill_TeamChange(0);
1367 }
1368
1369 void CTS_ClientKill (entity e) // silent version of ClientKill
1370 {
1371     e.killindicator = spawn();
1372     e.killindicator.owner = e;
1373     e.killindicator.think = KillIndicator_Think;
1374     e.killindicator.nextthink = time + (e.lip) * 0.05;
1375     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1376     e.lip = 0;
1377 }
1378
1379 void DoTeamChange(float destteam)
1380 {
1381         float t, c0;
1382         if(!teams_matter)
1383         {
1384                 if(destteam >= 0)
1385                         SetPlayerColors(self, destteam);
1386                 return;
1387         }
1388         if(self.classname == "player")
1389         if(destteam == -1)
1390         {
1391                 CheckAllowedTeams(self);
1392                 t = FindSmallestTeam(self, TRUE);
1393                 switch(self.team)
1394                 {
1395                         case COLOR_TEAM1: c0 = c1; break;
1396                         case COLOR_TEAM2: c0 = c2; break;
1397                         case COLOR_TEAM3: c0 = c3; break;
1398                         case COLOR_TEAM4: c0 = c4; break;
1399                         default:          c0 = 999;
1400                 }
1401                 switch(t)
1402                 {
1403                         case 1:
1404                                 if(c0 > c1)
1405                                         destteam = COLOR_TEAM1;
1406                                 break;
1407                         case 2:
1408                                 if(c0 > c2)
1409                                         destteam = COLOR_TEAM2;
1410                                 break;
1411                         case 3:
1412                                 if(c0 > c3)
1413                                         destteam = COLOR_TEAM3;
1414                                 break;
1415                         case 4:
1416                                 if(c0 > c4)
1417                                         destteam = COLOR_TEAM4;
1418                                 break;
1419                 }
1420                 if(destteam == -1)
1421                         return;
1422         }
1423         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1424                 return;
1425         ClientKill_TeamChange(destteam);
1426 }
1427
1428 void FixClientCvars(entity e)
1429 {
1430         // send prediction settings to the client
1431         stuffcmd(e, "\nin_bindmap 0 0\n");
1432         if(g_race || g_cts)
1433                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1434         if(autocvar_g_antilag == 3) // client side hitscan
1435                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1436         if(sv_gentle)
1437                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1438         /*
1439          * we no longer need to stuff this. Remove this comment block if you feel
1440          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1441         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1442         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1443         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1444         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1445         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1446         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1447         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1448         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1449         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1450         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1451         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1452         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1453         stuffcmd(e, "cl_movement_edgefriction 1\n");
1454          */
1455 }
1456
1457 float PlayerInIDList(entity p, string idlist)
1458 {
1459         float n, i;
1460         string s;
1461
1462         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1463         if not(p.crypto_idfp)
1464                 return 0;
1465
1466         // this function allows abbreviated player IDs too!
1467         n = tokenize_console(idlist);
1468         for(i = 0; i < n; ++i)
1469         {
1470                 s = argv(i);
1471                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1472                         return 1;
1473         }
1474
1475         return 0;
1476 }
1477
1478 /*
1479 =============
1480 ClientConnect
1481
1482 Called when a client connects to the server
1483 =============
1484 */
1485 //void ctf_clientconnect();
1486 string ColoredTeamName(float t);
1487 void DecodeLevelParms (void);
1488 //void dom_player_join_team(entity pl);
1489 void ClientConnect (void)
1490 {
1491         float t;
1492
1493         if(self.flags & FL_CLIENT)
1494         {
1495                 print("Warning: ClientConnect, but already connected!\n");
1496                 return;
1497         }
1498
1499         if(Ban_MaybeEnforceBan(self))
1500                 return;
1501
1502         DecodeLevelParms();
1503
1504 #ifdef WATERMARK
1505         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1506 #endif
1507
1508         self.classname = "player_joining";
1509
1510         self.flags = FL_CLIENT;
1511         self.version_nagtime = time + 10 + random() * 10;
1512
1513         if(player_count<0)
1514         {
1515                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1516                 player_count = 0;
1517         }
1518
1519         PlayerScore_Attach(self);
1520         ClientData_Attach();
1521         accuracy_init(self);
1522
1523         bot_clientconnect();
1524
1525         playerdemo_init();
1526
1527         anticheat_init();
1528         
1529         race_PreSpawnObserver();
1530
1531         //if(g_domination)
1532         //      dom_player_join_team(self);
1533
1534         // identify the right forced team
1535         if(autocvar_g_campaign)
1536         {
1537                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1538                 {
1539                         switch(autocvar_g_campaign_forceteam)
1540                         {
1541                                 case 1: self.team_forced = COLOR_TEAM1; break;
1542                                 case 2: self.team_forced = COLOR_TEAM2; break;
1543                                 case 3: self.team_forced = COLOR_TEAM3; break;
1544                                 case 4: self.team_forced = COLOR_TEAM4; break;
1545                                 default: self.team_forced = 0;
1546                         }
1547                 }
1548         }
1549         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1550                 self.team_forced = COLOR_TEAM1;
1551         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1552                 self.team_forced = COLOR_TEAM2;
1553         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1554                 self.team_forced = COLOR_TEAM3;
1555         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1556                 self.team_forced = COLOR_TEAM4;
1557         else if(autocvar_g_forced_team_otherwise == "red")
1558                 self.team_forced = COLOR_TEAM1;
1559         else if(autocvar_g_forced_team_otherwise == "blue")
1560                 self.team_forced = COLOR_TEAM2;
1561         else if(autocvar_g_forced_team_otherwise == "yellow")
1562                 self.team_forced = COLOR_TEAM3;
1563         else if(autocvar_g_forced_team_otherwise == "pink")
1564                 self.team_forced = COLOR_TEAM4;
1565         else if(autocvar_g_forced_team_otherwise == "spectate")
1566                 self.team_forced = -1;
1567         else if(autocvar_g_forced_team_otherwise == "spectator")
1568                 self.team_forced = -1;
1569         else
1570                 self.team_forced = 0;
1571
1572         if(!teams_matter)
1573                 if(self.team_forced > 0)
1574                         self.team_forced = 0;
1575
1576         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1577
1578         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1579                 self.classname = "observer";
1580         } else {
1581                 if(teams_matter)
1582                 {
1583                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1584                         {
1585                                 self.classname = "player";
1586                                 campaign_bots_may_start = 1;
1587                         }
1588                         else
1589                         {
1590                                 self.classname = "observer"; // do it anyway
1591                         }
1592                 }
1593                 else
1594                 {
1595                         self.classname = "player";
1596                         campaign_bots_may_start = 1;
1597                 }
1598         }
1599
1600         self.playerid = (playerid_last = playerid_last + 1);
1601
1602         if(autocvar_sv_eventlog)
1603                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1604
1605         LogTeamchange(self.playerid, self.team, 1);
1606
1607         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1608
1609         self.netname_previous = strzone(self.netname);
1610
1611         bprint("^4", self.netname, "^4 connected");
1612
1613         if(self.classname != "observer" && (g_domination || g_ctf))
1614                 bprint(" and joined the ", ColoredTeamName(self.team));
1615
1616         bprint("\n");
1617
1618         self.welcomemessage_time = 0;
1619
1620         stuffcmd(self, strcat(clientstuff, "\n"));
1621         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1622         stuffcmd(self, "cl_particles_reloadeffects\n");
1623
1624         FixClientCvars(self);
1625
1626         // spawnfunc_waypoint sprites
1627         WaypointSprite_InitClient(self);
1628
1629         // Wazat's grappling hook
1630         SetGrappleHookBindings();
1631
1632         // get autoswitch state from player when he toggles it
1633         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1634
1635         // get version info from player
1636         stuffcmd(self, "cmd clientversion $gameversion\n");
1637
1638         // get other cvars from player
1639         GetCvars(0);
1640
1641         // notify about available teams
1642         if(teams_matter)
1643         {
1644                 CheckAllowedTeams(self);
1645                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1646                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1647         }
1648         else
1649                 stuffcmd(self, "set _teams_available 0\n");
1650
1651         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1652
1653         if(g_arena || g_ca)
1654         {
1655                 self.classname = "observer";
1656                 if(g_arena)
1657                         Spawnqueue_Insert(self);
1658         }
1659         /*else if(g_ctf)
1660         {
1661                 ctf_clientconnect();
1662         }*/
1663
1664         if(teams_matter || radar_showennemies)
1665                 attach_entcs();
1666
1667         bot_relinkplayerlist();
1668
1669         self.spectatortime = time;
1670         if(blockSpectators)
1671         {
1672                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1673         }
1674
1675         self.jointime = time;
1676         self.allowedTimeouts = autocvar_sv_timeout_number;
1677
1678         if(clienttype(self) == CLIENTTYPE_REAL)
1679         {
1680                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1681                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1682         }
1683
1684         if(g_lms)
1685         {
1686                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1687                 {
1688                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1689                         self.frags = FRAGS_SPECTATOR;
1690                 }
1691         }
1692
1693         if(!sv_foginterval && world.fog != "")
1694                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1695
1696         SoundEntity_Attach(self);
1697
1698         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1699         {
1700                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1701                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1702         }
1703         else
1704                 self.hitplotfh = -1;
1705
1706         if(g_race || g_cts) {
1707                 string rr;
1708                 if(g_cts)
1709                         rr = CTS_RECORD;
1710                 else
1711                         rr = RACE_RECORD;
1712                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1713
1714                 msg_entity = self;
1715                 race_send_recordtime(MSG_ONE);
1716                 race_send_speedaward(MSG_ONE);
1717
1718                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1719                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1720                 race_send_speedaward_alltimebest(MSG_ONE);
1721
1722                 float i;
1723                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1724                         race_SendRankings(i, 0, 0, MSG_ONE);
1725                 }
1726         }
1727         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1728                 send_CSQC_teamnagger();
1729
1730         send_CSQC_cr_maxbullets(self);
1731
1732         CheatInitClient();
1733
1734         PlayerStats_AddPlayer(self);
1735 }
1736
1737 /*
1738 =============
1739 ClientDisconnect
1740
1741 Called when a client disconnects from the server
1742 =============
1743 */
1744 .entity chatbubbleentity;
1745 .entity teambubbleentity;
1746 void ReadyCount();
1747 void ClientDisconnect (void)
1748 {
1749         if not(self.flags & FL_CLIENT)
1750         {
1751                 print("Warning: ClientDisconnect without ClientConnect\n");
1752                 return;
1753         }
1754
1755         PlayerStats_AddGlobalInfo(self);
1756
1757         CheatShutdownClient();
1758
1759         if(self.hitplotfh >= 0)
1760         {
1761                 fclose(self.hitplotfh);
1762                 self.hitplotfh = -1;
1763         }
1764
1765         anticheat_report();
1766         anticheat_shutdown();
1767
1768         playerdemo_shutdown();
1769
1770         bot_clientdisconnect();
1771
1772         if(self.entcs)
1773                 detach_entcs();
1774
1775         if(autocvar_sv_eventlog)
1776                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1777         bprint ("^4",self.netname);
1778         bprint ("^4 disconnected\n");
1779
1780         SoundEntity_Detach(self);
1781
1782         DropAllRunes(self);
1783         MUTATOR_CALLHOOK(ClientDisconnect);
1784
1785         Portal_ClearAll(self);
1786
1787         if(self.flagcarried)
1788                 DropFlag(self.flagcarried, world, world);
1789         if(self.ballcarried && g_nexball)
1790                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1791
1792         // Here, everything has been done that requires this player to be a client.
1793
1794         self.flags &~= FL_CLIENT;
1795
1796         if (self.chatbubbleentity)
1797                 remove (self.chatbubbleentity);
1798
1799         if (self.teambubbleentity)
1800                 remove (self.teambubbleentity);
1801
1802         if (self.killindicator)
1803                 remove (self.killindicator);
1804
1805         WaypointSprite_PlayerGone();
1806
1807         bot_relinkplayerlist();
1808
1809         if(g_arena)
1810         {
1811                 Spawnqueue_Unmark(self);
1812                 Spawnqueue_Remove(self);
1813         }
1814
1815         accuracy_free(self);
1816         ClientData_Detach();
1817         PlayerScore_Detach(self);
1818
1819         if(self.netname_previous)
1820                 strunzone(self.netname_previous);
1821         if(self.clientstatus)
1822                 strunzone(self.clientstatus);
1823         if(self.weaponorder_byimpulse)
1824                 strunzone(self.weaponorder_byimpulse);
1825
1826         ClearPlayerSounds();
1827
1828         if(self.personal)
1829                 remove(self.personal);
1830
1831         self.playerid = 0;
1832         ReadyCount();
1833
1834         // free cvars
1835         GetCvars(-1);
1836 }
1837
1838 .float BUTTON_CHAT;
1839 void ChatBubbleThink()
1840 {
1841         self.nextthink = time;
1842         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1843         {
1844                 if(self.owner) // but why can that ever be world?
1845                         self.owner.chatbubbleentity = world;
1846                 remove(self);
1847                 return;
1848         }
1849         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1850 #ifdef TETRIS
1851                 || self.owner.tetris_on
1852 #endif
1853         )
1854                 self.model = self.mdl;
1855         else
1856                 self.model = "";
1857 };
1858
1859 void UpdateChatBubble()
1860 {
1861         if (!self.modelindex)
1862                 return;
1863         // spawn a chatbubble entity if needed
1864         if (!self.chatbubbleentity)
1865         {
1866                 self.chatbubbleentity = spawn();
1867                 self.chatbubbleentity.owner = self;
1868                 self.chatbubbleentity.exteriormodeltoclient = self;
1869                 self.chatbubbleentity.think = ChatBubbleThink;
1870                 self.chatbubbleentity.nextthink = time;
1871                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1872                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1873                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1874                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1875                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1876                 self.chatbubbleentity.model = "";
1877                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1878         }
1879 }
1880
1881
1882 void TeamBubbleThink()
1883 {
1884         self.nextthink = time;
1885         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1886         {
1887                 if(self.owner) // but why can that ever be world?
1888                         self.owner.teambubbleentity = world;
1889                 remove(self);
1890                 return;
1891         }
1892 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1893         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1894                 self.model = "";
1895         else
1896                 self.model = self.mdl;
1897
1898 };
1899
1900 float TeamBubble_customizeentityforclient()
1901 {
1902         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1903 }
1904
1905 void UpdateTeamBubble()
1906 {
1907         if (!self.modelindex || !teams_matter)
1908                 return;
1909         // spawn a teambubble entity if needed
1910         if (!self.teambubbleentity && teams_matter)
1911         {
1912                 self.teambubbleentity = spawn();
1913                 self.teambubbleentity.owner = self;
1914                 self.teambubbleentity.exteriormodeltoclient = self;
1915                 self.teambubbleentity.think = TeamBubbleThink;
1916                 self.teambubbleentity.nextthink = time;
1917                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1918 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1919                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1920                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1921                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1922                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1923                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1924                 self.teambubbleentity.effects = EF_LOWPRECISION;
1925         }
1926 }
1927
1928 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1929 // added to the model skins
1930 /*void UpdateColorModHack()
1931 {
1932         local float c;
1933         c = self.clientcolors & 15;
1934         // LordHavoc: only bothering to support white, green, red, yellow, blue
1935              if (!teams_matter) self.colormod = '0 0 0';
1936         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1937         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1938         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1939         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1940         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1941         else self.colormod = '1 1 1';
1942 };*/
1943
1944 .float oldcolormap;
1945 void respawn(void)
1946 {
1947         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1948         {
1949                 self.solid = SOLID_NOT;
1950                 self.takedamage = DAMAGE_NO;
1951                 self.movetype = MOVETYPE_FLY;
1952                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1953                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1954                 self.effects |= EF_ADDITIVE;
1955                 self.oldcolormap = self.colormap;
1956                 self.colormap = 512;
1957                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1958                 if(autocvar_g_respawn_ghosts_maxtime)
1959                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1960         }
1961
1962         CopyBody(1);
1963         self.effects |= EF_NODRAW; // prevent another CopyBody
1964         if(self.oldcolormap)
1965         {
1966                 self.colormap = self.oldcolormap;
1967                 self.oldcolormap = 0;
1968         }
1969         PutClientInServer();
1970 }
1971
1972 void play_countdown(float finished, string samp)
1973 {
1974         if(clienttype(self) == CLIENTTYPE_REAL)
1975                 if(floor(finished - time - frametime) != floor(finished - time))
1976                         if(finished - time < 6)
1977                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1978 }
1979
1980 /**
1981  * When sv_timeout is used this function returs strings like
1982  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1983  * Called by centerprint functions
1984  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1985  */
1986 string getTimeoutText(float addOneSecond) {
1987         if (!autocvar_sv_timeout || !timeoutStatus)
1988                 return "";
1989
1990         local string retStr;
1991         if (timeoutStatus == 1) {
1992                 if (addOneSecond == 1) {
1993                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1994                 }
1995                 else {
1996                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1997                 }
1998                 return retStr;
1999         }
2000         else if (timeoutStatus == 2) {
2001                 if (addOneSecond) {
2002                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2003                         //don't show messages like "Timeout ends in 0 seconds"...
2004                         if ((remainingTimeoutTime + 1) > 0)
2005                                 return retStr;
2006                         else
2007                                 return "";
2008                 }
2009                 else {
2010                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2011                         //don't show messages like "Timeout ends in 0 seconds"...
2012                         if (remainingTimeoutTime > 0)
2013                                 return retStr;
2014                         else
2015                                 return "";
2016                 }
2017         }
2018         else return "";
2019 }
2020
2021 void player_powerups (void)
2022 {
2023         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2024         olditems = self.items;
2025         
2026         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2027         {
2028                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2029                 self.modelflags |= MF_ROCKET;
2030         }
2031         else
2032         {
2033                 SoundEntity_StopSound(self, CHAN_PLAYER);
2034                 self.modelflags &~= MF_ROCKET;
2035         }
2036
2037         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2038
2039         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2040                 return;
2041         
2042         Fire_ApplyDamage(self);
2043         Fire_ApplyEffect(self);
2044
2045         if (g_minstagib)
2046         {
2047                 self.effects |= EF_FULLBRIGHT;
2048
2049                 if (self.items & IT_STRENGTH)
2050                 {
2051                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2052                         if (time > self.strength_finished)
2053                         {
2054                                 self.alpha = default_player_alpha;
2055                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2056                                 self.items &~= IT_STRENGTH;
2057                                 sprint(self, "^3Invisibility has worn off\n");
2058                         }
2059                 }
2060                 else
2061                 {
2062                         if (time < self.strength_finished)
2063                         {
2064                                 self.alpha = g_minstagib_invis_alpha;
2065                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2066                                 self.items |= IT_STRENGTH;
2067                                 sprint(self, "^3You are invisible\n");
2068                         }
2069                 }
2070
2071                 if (self.items & IT_INVINCIBLE)
2072                 {
2073                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2074                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2075                         {
2076                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2077                                 sprint(self, "^3Speed has worn off\n");
2078                         }
2079                 }
2080                 else
2081                 {
2082                         if (time < self.invincible_finished)
2083                         {
2084                                 self.items = self.items | IT_INVINCIBLE;
2085                                 sprint(self, "^3You are on speed\n");
2086                         }
2087                 }
2088         }
2089         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2090         {
2091                 if (self.items & IT_STRENGTH)
2092                 {
2093                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2094                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2095                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2096                         {
2097                                 self.items = self.items - (self.items & IT_STRENGTH);
2098                                 sprint(self, "^3Strength has worn off\n");
2099                         }
2100                 }
2101                 else
2102                 {
2103                         if (time < self.strength_finished)
2104                         {
2105                                 self.items = self.items | IT_STRENGTH;
2106                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2107                         }
2108                 }
2109                 if (self.items & IT_INVINCIBLE)
2110                 {
2111                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2112                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2113                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2114                         {
2115                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2116                                 sprint(self, "^3Shield has worn off\n");
2117                         }
2118                 }
2119                 else
2120                 {
2121                         if (time < self.invincible_finished)
2122                         {
2123                                 self.items = self.items | IT_INVINCIBLE;
2124                                 sprint(self, "^3Shield surrounds you\n");
2125                         }
2126                 }
2127
2128                 if(autocvar_g_nodepthtestplayers)
2129                         self.effects = self.effects | EF_NODEPTHTEST;
2130
2131                 if(autocvar_g_fullbrightplayers)
2132                         self.effects = self.effects | EF_FULLBRIGHT;
2133
2134                 // midair gamemode: damage only while in the air
2135                 // if in midair mode, being on ground grants temporary invulnerability
2136                 // (this is so that multishot weapon don't clear the ground flag on the
2137                 // first damage in the frame, leaving the player vulnerable to the
2138                 // remaining hits in the same frame)
2139                 if (self.flags & FL_ONGROUND)
2140                 if (g_midair)
2141                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2142
2143                 if (time >= game_starttime)
2144                 if (time < self.spawnshieldtime)
2145                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2146         }
2147         
2148         MUTATOR_CALLHOOK(PlayerPowerups);
2149 }
2150
2151 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2152 {
2153         if(current > stable)
2154                 return current;
2155         else if(current > stable - 0.25) // when close enough, "snap"
2156                 return stable;
2157         else
2158                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2159 }
2160
2161 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2162 {
2163         if(current < stable)
2164                 return current;
2165         else if(current < stable + 0.25) // when close enough, "snap"
2166                 return stable;
2167         else
2168                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2169 }
2170
2171 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2172 {
2173         if(current > rotstable)
2174         {
2175                 if(rotframetime > 0)
2176                 {
2177                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2178                         current = max(rotstable, current - rotlinear * rotframetime);
2179                 }
2180         }
2181         else if(current < regenstable)
2182         {
2183                 if(regenframetime > 0)
2184                 {
2185                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2186                         current = min(regenstable, current + regenlinear * regenframetime);
2187                 }
2188         }
2189
2190         if(current > limit)
2191                 current = limit;
2192
2193         return current;
2194 }
2195
2196 void player_regen (void)
2197 {
2198         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2199         maxh = autocvar_g_balance_health_rotstable;
2200         maxa = autocvar_g_balance_armor_rotstable;
2201         maxf = autocvar_g_balance_fuel_rotstable;
2202         minh = autocvar_g_balance_health_regenstable;
2203         mina = autocvar_g_balance_armor_regenstable;
2204         minf = autocvar_g_balance_fuel_regenstable;
2205         limith = autocvar_g_balance_health_limit;
2206         limita = autocvar_g_balance_armor_limit;
2207         limitf = autocvar_g_balance_fuel_limit;
2208
2209         max_mod = regen_mod = rot_mod = limit_mod = 1;
2210
2211         if (self.runes & RUNE_REGEN)
2212         {
2213                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2214                 {
2215                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2216                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2217                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2218                 }
2219                 else
2220                 {
2221                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2222                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2223                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2224                 }
2225         }
2226         else if (self.runes & CURSE_VENOM)
2227         {
2228                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2229                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2230                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2231                 else
2232                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2233                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2234                 //if (!self.runes & RUNE_REGEN)
2235                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2236         }
2237         maxh = maxh * max_mod;
2238         //maxa = maxa * max_mod;
2239         //maxf = maxf * max_mod;
2240         minh = minh * max_mod;
2241         //mina = mina * max_mod;
2242         //minf = minf * max_mod;
2243         limith = limith * limit_mod;
2244         limita = limita * limit_mod;
2245         //limitf = limitf * limit_mod;
2246
2247         if(g_lms && g_ca)
2248                 rot_mod = 0;
2249
2250         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2251         {
2252                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2253                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2254
2255                 // if player rotted to death...  die!
2256                 if(self.health < 1)
2257                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2258         }
2259
2260         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2261                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2262 }
2263
2264 float zoomstate_set;
2265 void SetZoomState(float z)
2266 {
2267         if(z != self.zoomstate)
2268         {
2269                 self.zoomstate = z;
2270                 ClientData_Touch(self);
2271         }
2272         zoomstate_set = 1;
2273 }
2274
2275 void GetPressedKeys(void) {
2276         MUTATOR_CALLHOOK(GetPressedKeys);
2277         if (self.movement_x > 0) // get if movement keys are pressed
2278         {       // forward key pressed
2279                 self.pressedkeys |= KEY_FORWARD;
2280                 self.pressedkeys &~= KEY_BACKWARD;
2281         }
2282         else if (self.movement_x < 0)
2283         {       // backward key pressed
2284                 self.pressedkeys |= KEY_BACKWARD;
2285                 self.pressedkeys &~= KEY_FORWARD;
2286         }
2287         else
2288         {       // no x input
2289                 self.pressedkeys &~= KEY_FORWARD;
2290                 self.pressedkeys &~= KEY_BACKWARD;
2291         }
2292
2293         if (self.movement_y > 0)
2294         {       // right key pressed
2295                 self.pressedkeys |= KEY_RIGHT;
2296                 self.pressedkeys &~= KEY_LEFT;
2297         }
2298         else if (self.movement_y < 0)
2299         {       // left key pressed
2300                 self.pressedkeys |= KEY_LEFT;
2301                 self.pressedkeys &~= KEY_RIGHT;
2302         }
2303         else
2304         {       // no y input
2305                 self.pressedkeys &~= KEY_RIGHT;
2306                 self.pressedkeys &~= KEY_LEFT;
2307         }
2308
2309         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2310                 self.pressedkeys |= KEY_JUMP;
2311         else
2312                 self.pressedkeys &~= KEY_JUMP;
2313         if (self.BUTTON_CROUCH)
2314                 self.pressedkeys |= KEY_CROUCH;
2315         else
2316                 self.pressedkeys &~= KEY_CROUCH;
2317 }
2318
2319 /*
2320 ======================
2321 spectate mode routines
2322 ======================
2323 */
2324
2325 void SpectateCopy(entity spectatee) {
2326         other = spectatee;
2327         MUTATOR_CALLHOOK(SpectateCopy);
2328         self.armortype = spectatee.armortype;
2329         self.armorvalue = spectatee.armorvalue;
2330         self.ammo_cells = spectatee.ammo_cells;
2331         self.ammo_shells = spectatee.ammo_shells;
2332         self.ammo_nails = spectatee.ammo_nails;
2333         self.ammo_rockets = spectatee.ammo_rockets;
2334         self.ammo_fuel = spectatee.ammo_fuel;
2335         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2336         self.health = spectatee.health;
2337         self.impulse = 0;
2338         self.items = spectatee.items;
2339         self.last_pickup = spectatee.last_pickup;
2340         self.metertime = spectatee.metertime;
2341         self.strength_finished = spectatee.strength_finished;
2342         self.invincible_finished = spectatee.invincible_finished;
2343         self.pressedkeys = spectatee.pressedkeys;
2344         self.weapons = spectatee.weapons;
2345         self.switchweapon = spectatee.switchweapon;
2346         self.weapon = spectatee.weapon;
2347         self.punchangle = spectatee.punchangle;
2348         self.view_ofs = spectatee.view_ofs;
2349         self.v_angle = spectatee.v_angle;
2350         self.velocity = spectatee.velocity;
2351         self.dmg_take = spectatee.dmg_take;
2352         self.dmg_save = spectatee.dmg_save;
2353         self.dmg_inflictor = spectatee.dmg_inflictor;
2354         self.angles = spectatee.v_angle;
2355         self.fixangle = TRUE;
2356         setorigin(self, spectatee.origin);
2357         setsize(self, spectatee.mins, spectatee.maxs);
2358         SetZoomState(spectatee.zoomstate);
2359
2360         anticheat_spectatecopy(spectatee);
2361 }
2362
2363 float SpectateUpdate() {
2364         if(!self.enemy)
2365                 return 0;
2366
2367         if (self == self.enemy)
2368                 return 0;
2369
2370         if(self.enemy.classname != "player")
2371                 return 0;
2372
2373         SpectateCopy(self.enemy);
2374
2375         return 1;
2376 }
2377
2378 float SpectateNext() {
2379         other = find(self.enemy, classname, "player");
2380
2381         if (!other)
2382                 other = find(other, classname, "player");
2383
2384         if (other)
2385                 self.enemy = other;
2386
2387         if(self.enemy.classname == "player") {
2388                 msg_entity = self;
2389                 WriteByte(MSG_ONE, SVC_SETVIEW);
2390                 WriteEntity(MSG_ONE, self.enemy);
2391                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2392                 self.movetype = MOVETYPE_NONE;
2393                 accuracy_resend(self);
2394
2395                 if(!SpectateUpdate())
2396                         PutObserverInServer();
2397
2398                 return 1;
2399         } else {
2400                 return 0;
2401         }
2402 }
2403
2404 /*
2405 =============
2406 ShowRespawnCountdown()
2407
2408 Update a respawn countdown display.
2409 =============
2410 */
2411 void ShowRespawnCountdown()
2412 {
2413         float number;
2414         if(self.deadflag == DEAD_NO) // just respawned?
2415                 return;
2416         else
2417         {
2418                 number = ceil(self.death_time - time);
2419                 if(number <= 0)
2420                         return;
2421                 if(number <= self.respawn_countdown)
2422                 {
2423                         self.respawn_countdown = number - 1;
2424                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2425                                 AnnounceTo(self, strcat(ftos(number), ""));
2426                 }
2427         }
2428 }
2429
2430 void LeaveSpectatorMode()
2431 {
2432         if(isJoinAllowed()) {
2433                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2434                         self.classname = "player";
2435
2436                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2437                                 JoinBestTeam(self, FALSE, TRUE);
2438
2439                         if(autocvar_g_campaign)
2440                                 campaign_bots_may_start = 1;
2441
2442                         PutClientInServer();
2443
2444                         if(self.classname == "player")
2445                                 bprint ("^4", self.netname, "^4 is playing now\n");
2446
2447                         if(!autocvar_g_campaign)
2448                                 centerprint(self,""); // clear MOTD
2449
2450                         return;
2451                 } else {
2452                         if (g_ca && self.caplayer) {
2453                         }       // do nothing
2454                         else
2455                                 stuffcmd(self,"menu_showteamselect\n");
2456                         return;
2457                 }
2458         }
2459         else {
2460                 //player may not join because of g_maxplayers is set
2461                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2462         }
2463 }
2464
2465 /**
2466  * Determines whether the player is allowed to join. This depends on cvar
2467  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2468  * it checks whether the number of currently playing players exceeds g_maxplayers.
2469  * @return bool TRUE if the player is allowed to join, false otherwise
2470  */
2471 float isJoinAllowed() {
2472         if(self.team_forced < 0)
2473                 return FALSE; // forced spectators can never join
2474
2475         if (!autocvar_g_maxplayers)
2476                 return TRUE;
2477
2478         local entity e;
2479         local float currentlyPlaying;
2480         FOR_EACH_REALPLAYER(e) {
2481                 if(e.classname == "player")
2482                         currentlyPlaying += 1;
2483         }
2484         if(currentlyPlaying < autocvar_g_maxplayers)
2485                 return TRUE;
2486
2487         return FALSE;
2488 }
2489
2490 /**
2491  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2492  * g_maxplayers_spectator_blocktime seconds
2493  */
2494 void checkSpectatorBlock() {
2495         if(self.classname == "spectator" || self.classname == "observer") {
2496                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2497                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2498                         dropclient(self);
2499                 }
2500         }
2501 }
2502
2503 void ObserverThink()
2504 {
2505         if (self.flags & FL_JUMPRELEASED) {
2506                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2507                         self.welcomemessage_time = 0;
2508                         self.flags &~= FL_JUMPRELEASED;
2509                         self.flags |= FL_SPAWNING;
2510                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2511                         self.welcomemessage_time = 0;
2512                         self.flags &~= FL_JUMPRELEASED;
2513                         if(SpectateNext() == 1) {
2514                                 self.classname = "spectator";
2515                         }
2516                 }
2517         } else {
2518                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2519                         self.flags |= FL_JUMPRELEASED;
2520                         if(self.flags & FL_SPAWNING)
2521                         {
2522                                 self.flags &~= FL_SPAWNING;
2523                                 LeaveSpectatorMode();
2524                                 return;
2525                         }
2526                 }
2527         }
2528         PrintWelcomeMessage(self);
2529 }
2530
2531 void SpectatorThink()
2532 {
2533         if (self.flags & FL_JUMPRELEASED) {
2534                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2535                         self.welcomemessage_time = 0;
2536                         self.flags &~= FL_JUMPRELEASED;
2537                         self.flags |= FL_SPAWNING;
2538                 } else if(self.BUTTON_ATCK) {
2539                         self.welcomemessage_time = 0;
2540                         self.flags &~= FL_JUMPRELEASED;
2541                         if(SpectateNext() == 1) {
2542                                 self.classname = "spectator";
2543                         } else {
2544                                 self.classname = "observer";
2545                                 PutClientInServer();
2546                         }
2547                 } else if (self.BUTTON_ATCK2) {
2548                         self.welcomemessage_time = 0;
2549                         self.flags &~= FL_JUMPRELEASED;
2550                         self.classname = "observer";
2551                         PutClientInServer();
2552                 } else {
2553                         if(!SpectateUpdate())
2554                                 PutObserverInServer();
2555                 }
2556         } else {
2557                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2558                         self.flags |= FL_JUMPRELEASED;
2559                         if(self.flags & FL_SPAWNING)
2560                         {
2561                                 self.flags &~= FL_SPAWNING;
2562                                 LeaveSpectatorMode();
2563                                 return;
2564                         }
2565                 }
2566         }
2567
2568         PrintWelcomeMessage(self);
2569         self.flags |= FL_CLIENT | FL_NOTARGET;
2570 }
2571
2572 .float touchexplode_time;
2573
2574 /*
2575 =============
2576 PlayerPreThink
2577
2578 Called every frame for each client before the physics are run
2579 =============
2580 */
2581 void() ctf_setstatus;
2582 void() nexball_setstatus;
2583 .float items_added;
2584 void PlayerPreThink (void)
2585 {
2586         self.stat_game_starttime = game_starttime;
2587         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2588         self.stat_leadlimit = autocvar_leadlimit;
2589
2590         if(frametime)
2591         {
2592                 // physics frames: update anticheat stuff
2593                 anticheat_prethink();
2594         }
2595
2596         if(blockSpectators && frametime)
2597                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2598                 checkSpectatorBlock();
2599
2600         zoomstate_set = 0;
2601
2602         if(self.netname_previous != self.netname)
2603         {
2604                 if(autocvar_sv_eventlog)
2605                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2606                 if(self.netname_previous)
2607                         strunzone(self.netname_previous);
2608                 self.netname_previous = strzone(self.netname);
2609         }
2610
2611         // version nagging
2612         if(self.version_nagtime)
2613                 if(self.cvar_g_xonoticversion)
2614                         if(time > self.version_nagtime)
2615                         {
2616                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2617                                 {
2618                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2619                                         {
2620                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2621                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2622                                         }
2623                                         else
2624                                         {
2625                                                 float r;
2626                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2627                                                 if(r < 0)
2628                                                 {
2629                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2630                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2631                                                 }
2632                                                 else if(r > 0)
2633                                                 {
2634                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2635                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2636                                                 }
2637                                         }
2638                                 }
2639                                 self.version_nagtime = 0;
2640                         }
2641
2642         // GOD MODE info
2643         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2644         {
2645                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2646                 self.max_armorvalue = 0;
2647         }
2648
2649 #ifdef TETRIS
2650         if (TetrisPreFrame())
2651                 return;
2652 #endif
2653
2654         MUTATOR_CALLHOOK(PlayerPreThink);
2655
2656         if(self.classname == "player") {
2657 //              if(self.netname == "Wazat")
2658 //                      bprint(self.classname, "\n");
2659
2660                 CheckRules_Player();
2661
2662                 PrintWelcomeMessage(self);
2663
2664                 if (intermission_running)
2665                 {
2666                         IntermissionThink ();   // otherwise a button could be missed between
2667                         return;                                 // the think tics
2668                 }
2669
2670                 if(self.teleport_time)
2671                 if(time > self.teleport_time)
2672                 {
2673                         self.teleport_time = 0;
2674                         self.effects = self.effects - (self.effects & EF_NODRAW);
2675                 }
2676
2677                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2678                         UpdateSelectedPlayer();
2679
2680                 //don't allow the player to turn around while game is paused!
2681                 if(timeoutStatus == 2) {
2682                         self.v_angle = self.lastV_angle;
2683                         self.angles = self.lastV_angle;
2684                         self.fixangle = TRUE;
2685                 }
2686
2687                 if(frametime)
2688                 {
2689                         if(self.health <= 0 && autocvar_g_deathglow)
2690                         {
2691                                 if(self.glowmod_x > 0)
2692                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2693                                 else
2694                                         self.glowmod_x = -1;
2695                                 if(self.glowmod_y > 0)
2696                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2697                                 else
2698                                         self.glowmod_y = -1;
2699                                 if(self.glowmod_z > 0)
2700                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2701                                 else
2702                                         self.glowmod_z = -1;
2703                         }
2704                         else
2705                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2706                         player_powerups();
2707                 }
2708
2709                 if (self.deadflag != DEAD_NO)
2710                 {
2711                         float button_pressed, force_respawn;
2712                         if(self.personal && g_race_qualifying)
2713                         {
2714                                 if(time > self.death_time)
2715                                 {
2716                                         self.death_time = time + 1; // only retry once a second
2717                                         respawn();
2718                                         self.impulse = 141;
2719                                 }
2720                         }
2721                         else
2722                         {
2723                                 if(frametime)
2724                                         player_anim();
2725                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2726                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2727                                 if (self.deadflag == DEAD_DYING)
2728                                 {
2729                                         if(force_respawn)
2730                                                 self.deadflag = DEAD_RESPAWNING;
2731                                         else if(!button_pressed)
2732                                                 self.deadflag = DEAD_DEAD;
2733                                 }
2734                                 else if (self.deadflag == DEAD_DEAD)
2735                                 {
2736                                         if(button_pressed)
2737                                                 self.deadflag = DEAD_RESPAWNABLE;
2738                                 }
2739                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2740                                 {
2741                                         if(!button_pressed)
2742                                                 self.deadflag = DEAD_RESPAWNING;
2743                                 }
2744                                 else if (self.deadflag == DEAD_RESPAWNING)
2745                                 {
2746                                         if(time > self.death_time)
2747                                         {
2748                                                 self.death_time = time + 1; // only retry once a second
2749                                                 respawn();
2750                                         }
2751                                 }
2752                                 ShowRespawnCountdown();
2753                         }
2754                         return;
2755                 }
2756
2757                 if(g_touchexplode)
2758                 if(time > self.touchexplode_time)
2759                 if(self.classname == "player")
2760                 if(self.deadflag == DEAD_NO)
2761                 if not(IS_INDEPENDENT_PLAYER(self))
2762                 FOR_EACH_PLAYER(other) if(self != other)
2763                 {
2764                         if(time > other.touchexplode_time)
2765                         if(other.deadflag == DEAD_NO)
2766                         if not(IS_INDEPENDENT_PLAYER(other))
2767                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2768                         {
2769                                 PlayerTouchExplode(self, other);
2770                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2771                         }
2772                 }
2773
2774                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2775                 {
2776                         vector dist;
2777
2778                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2779                         dist = self.prevorigin - self.origin;
2780                         dist_z = 0;
2781                         self.lms_traveled_distance += fabs(vlen(dist));
2782
2783                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2784                         {
2785                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2786                                 self.lms_traveled_distance = 0;
2787                         }
2788
2789                         if(time > self.lms_nextcheck)
2790                         {
2791                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2792                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2793                                 {
2794                                         centerprint(self, autocvar_g_lms_campcheck_message);
2795                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2796                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2797                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2798                                 }
2799                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2800                                 self.lms_traveled_distance = 0;
2801                         }
2802                 }
2803
2804                 self.prevorigin = self.origin;
2805
2806                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2807                 {
2808                         if (!self.crouch)
2809                         {
2810                                 self.crouch = TRUE;
2811                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2812                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2813                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2814                         }
2815                 }
2816                 else
2817                 {
2818                         if (self.crouch)
2819                         {
2820                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2821                                 if (!trace_startsolid)
2822                                 {
2823                                         self.crouch = FALSE;
2824                                         self.view_ofs = PL_VIEW_OFS;
2825                                         setsize (self, PL_MIN, PL_MAX);
2826                                 }
2827                         }
2828                 }
2829
2830                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2831                 {
2832                         if(self.bloodloss_timer < time)
2833                         {
2834                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2835                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2836                         }
2837                 }
2838
2839                 FixPlayermodel();
2840
2841                 GrapplingHookFrame();
2842
2843                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2844                 //if(frametime)
2845                 {
2846                         self.items &~= self.items_added;
2847
2848                         W_WeaponFrame();
2849
2850                         self.items_added = 0;
2851                         if(self.items & IT_JETPACK)
2852                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2853                                         self.items_added |= IT_FUEL;
2854
2855                         self.items |= self.items_added;
2856                 }
2857
2858                 player_regen();
2859
2860                 // rot nex charge to the charge limit
2861                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2862                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2863
2864                 if(frametime)
2865                         player_anim();
2866
2867                 if (g_minstagib)
2868                         minstagib_ammocheck();
2869
2870                 if(g_ctf)
2871                         ctf_setstatus();
2872
2873                 if(g_nexball)
2874                         nexball_setstatus();
2875
2876                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2877
2878                 //self.angles_y=self.v_angle_y + 90;   // temp
2879         } else if(gameover) {
2880                 if (intermission_running)
2881                         IntermissionThink ();   // otherwise a button could be missed between
2882                 return;
2883         } else if(self.classname == "observer") {
2884                 ObserverThink();
2885         } else if(self.classname == "spectator") {
2886                 SpectatorThink();
2887         }
2888
2889         if(!zoomstate_set)
2890                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && autocvar_g_balance_campingrifle_secondary == 0));
2891
2892         float oldspectatee_status;
2893         oldspectatee_status = self.spectatee_status;
2894         if(self.classname == "spectator")
2895                 self.spectatee_status = num_for_edict(self.enemy);
2896         else if(self.classname == "observer")
2897                 self.spectatee_status = num_for_edict(self);
2898         else
2899                 self.spectatee_status = 0;
2900         if(self.spectatee_status != oldspectatee_status)
2901         {
2902                 ClientData_Touch(self);
2903                 if(g_race || g_cts)
2904                         race_InitSpectator();
2905         }
2906
2907         if(self.teamkill_soundtime)
2908         if(time > self.teamkill_soundtime)
2909         {
2910                 self.teamkill_soundtime = 0;
2911
2912                 entity oldpusher, oldself;
2913
2914                 oldself = self; self = self.teamkill_soundsource;
2915                 oldpusher = self.pusher; self.pusher = oldself;
2916
2917                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2918
2919                 self.pusher = oldpusher;
2920                 self = oldself;
2921         }
2922
2923         if(self.taunt_soundtime)
2924         if(time > self.taunt_soundtime)
2925         {
2926                 self.taunt_soundtime = 0;
2927                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2928         }
2929
2930         target_voicescript_next(self);
2931 }
2932
2933 float isInvisibleString(string s)
2934 {
2935         float i, n, c;
2936         s = strdecolorize(s);
2937         for((i = 0), (n = strlen(s)); i < n; ++i)
2938         {
2939                 c = str2chr(s, i);
2940                 switch(c)
2941                 {
2942                         case 0:
2943                         case 32: // space
2944                                 break;
2945                         case 192: // charmap space
2946                                 if (!autocvar_utf8_enable)
2947                                         break;
2948                                 return FALSE;
2949                         case 160: // space in unicode fonts
2950                         case 0xE000 + 192: // utf8 charmap space
2951                                 if (autocvar_utf8_enable)
2952                                         break;
2953                         default:
2954                                 return FALSE;
2955                 }
2956         }
2957         return TRUE;
2958 }
2959
2960 /*
2961 =============
2962 PlayerPostThink
2963
2964 Called every frame for each client after the physics are run
2965 =============
2966 */
2967 .float idlekick_lasttimeleft;
2968 .entity showheadshotbbox;
2969 void showheadshotbbox_think()
2970 {
2971         if(self.owner.showheadshotbbox != self)
2972         {
2973                 remove(self);
2974                 return;
2975         }
2976         self.nextthink = time;
2977         setorigin(self, self.owner.origin);
2978         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2979 }
2980 void PlayerPostThink (void)
2981 {
2982         // Savage: Check for nameless players
2983         if (isInvisibleString(self.netname)) {
2984                 self.netname = "Player";
2985                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2986         }
2987
2988         if(sv_maxidle && frametime)
2989         {
2990                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2991                 float timeleft;
2992                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2993                 if(timeleft <= 0)
2994                 {
2995                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2996                         AnnounceTo(self, "terminated");
2997                         dropclient(self);
2998                         return;
2999                 }
3000                 else if(timeleft <= 10)
3001                 {
3002                         if(timeleft != self.idlekick_lasttimeleft)
3003                         {
3004                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3005                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3006                         }
3007                 }
3008                 else
3009                 {
3010                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3011                 }
3012                 self.idlekick_lasttimeleft = timeleft;
3013         }
3014
3015 #ifdef TETRIS
3016         if(self.impulse == 100)
3017                 ImpulseCommands();
3018         if (TetrisPostFrame())
3019                 return;
3020 #endif
3021
3022         CheatFrame();
3023
3024         if(self.classname == "player") {
3025                 CheckRules_Player();
3026                 UpdateChatBubble();
3027                 UpdateTeamBubble();
3028                 if (self.impulse)
3029                         ImpulseCommands();
3030                 if (intermission_running)
3031                         return;         // intermission or finale
3032                 GetPressedKeys();
3033         } else if (self.classname == "observer") {
3034                 //do nothing
3035         } else if (self.classname == "spectator") {
3036                 //do nothing
3037         }
3038
3039         /*
3040         float i;
3041         for(i = 0; i < 1000; ++i)
3042         {
3043                 vector end;
3044                 end = self.origin + '0 0 1024' + 512 * randomvec();
3045                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3046                 if(trace_fraction < 1)
3047                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3048                 {
3049                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3050                         break;
3051                 }
3052         }
3053         */
3054
3055         Arena_Warmup();
3056
3057         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3058
3059         if(self.waypointsprite_attachedforcarrier)
3060                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3061         
3062         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3063         {
3064                 if(!self.showheadshotbbox)
3065                 {
3066                         self.showheadshotbbox = spawn();
3067                         self.showheadshotbbox.classname = "headshotbbox";
3068                         self.showheadshotbbox.owner = self;
3069                         self.showheadshotbbox.think = showheadshotbbox_think;
3070                         self.showheadshotbbox.nextthink = time;
3071                         self = self.showheadshotbbox;
3072                         self.think();
3073                         self = self.owner;
3074                 }
3075         }
3076         else
3077         {
3078                 if(self.showheadshotbbox)
3079                         remove(self.showheadshotbbox);
3080         }
3081
3082         playerdemo_write();
3083
3084         if((g_cts || g_race) && self.cvar_cl_allow_uid2name == 1)
3085         {
3086                 if(!self.stored_netname)
3087                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3088                 if(self.stored_netname != self.netname)
3089                 {
3090                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3091                         strunzone(self.stored_netname);
3092                         self.stored_netname = strzone(self.netname);
3093                 }
3094         }
3095
3096         /*
3097         if(g_race)
3098                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3099         */
3100 }