qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_nexvelocity(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_NEX_VELOCITY);
  13         WriteShort(MSG_ONE, cvar("g_balance_nex_velocitydependent_minspeed"));
  14         WriteShort(MSG_ONE, cvar("g_balance_nex_velocitydependent_maxspeed"));
  15 }
  16
  17 void Announce(string snd) {
  18         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  19         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  20         WriteString(MSG_ALL, snd);
  21 }
  22
  23 void AnnounceTo(entity e, string snd) {
  24         if (clienttype(e) == CLIENTTYPE_REAL)
  25         {
  26                 msg_entity = e;
  27                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  28                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  29                 WriteString(MSG_ONE, snd);
  30         }
  31 }
  32
  33 float ClientData_Send(entity to, float sf)
  34 {
  35         if(to != self.owner)
  36         {
  37                 error("wtf");
  38                 return FALSE;
  39         }
  40
  41         entity e;
  42
  43         e = to;
  44         if(to.classname == "spectator")
  45                 e = to.enemy;
  46
  47         sf = 0;
  48
  49         if(e.race_completed)
  50                 sf |= 1; // forced scoreboard
  51         if(to.spectatee_status)
  52                 sf |= 2; // spectator ent number follows
  53         if(e.zoomstate)
  54                 sf |= 4; // zoomed
  55         if(e.porto_v_angle_held)
  56                 sf |= 8; // angles held
  57
  58         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  59         WriteByte(MSG_ENTITY, sf);
  60
  61         if(sf & 2)
  62                 WriteByte(MSG_ENTITY, to.spectatee_status);
  63
  64         if(sf & 8)
  65         {
  66                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  67                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  68         }
  69
  70         return TRUE;
  71 }
  72
  73 void ClientData_Attach()
  74 {
  75         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  76         self.clientdata.drawonlytoclient = self;
  77         self.clientdata.owner = self;
  78 }
  79
  80 void ClientData_Detach()
  81 {
  82         remove(self.clientdata);
  83         self.clientdata = world;
  84 }
  85
  86 void ClientData_Touch(entity e)
  87 {
  88         e.clientdata.SendFlags = 1;
  89
  90         // make it spectatable
  91         entity e2;
  92         FOR_EACH_REALCLIENT(e2)
  93         {
  94                 if(e2 != e)
  95                         if(e2.classname == "spectator")
  96                                 if(e2.enemy == e)
  97                                         e2.clientdata.SendFlags = 1;
  98         }
  99 }
 100
 101
 102 .vector spawnpoint_score;
 103 .string netname_previous;
 104
 105 void spawnfunc_info_player_survivor (void)
 106 {
 107         spawnfunc_info_player_deathmatch();
 108 }
 109
 110 void spawnfunc_info_player_start (void)
 111 {
 112         spawnfunc_info_player_deathmatch();
 113 }
 114
 115 void spawnfunc_info_player_deathmatch (void)
 116 {
 117         self.classname = "info_player_deathmatch";
 118         relocate_spawnpoint();
 119 }
 120
 121 void spawnpoint_use()
 122 {
 123         if(teams_matter)
 124         if(have_team_spawns > 0)
 125         {
 126                 self.team = activator.team;
 127                 some_spawn_has_been_used = 1;
 128         }
 129 };
 130
 131 // Returns:
 132 //   _x: prio (-1 if unusable)
 133 //   _y: weight
 134 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 135 {
 136         float shortest, thisdist;
 137         float prio;
 138         entity player;
 139
 140         prio = 0;
 141
 142         // filter out spots for the wrong team
 143         if(teamcheck)
 144         if(spot.team != teamcheck)
 145                 return '-1 0 0';
 146
 147         if(race_spawns)
 148                 if(spot.target == "")
 149                         return '-1 0 0';
 150
 151         if(clienttype(self) == CLIENTTYPE_REAL)
 152         {
 153                 if(spot.restriction == 1)
 154                         return '-1 0 0';
 155         }
 156         else
 157         {
 158                 if(spot.restriction == 2)
 159                         return '-1 0 0';
 160         }
 161
 162         // filter out spots for assault
 163         if(spot.target != "") {
 164                 local entity ent;
 165                 float good, found;
 166                 ent = find(world, targetname, spot.target);
 167
 168                 while(ent) {
 169                         if(ent.classname == "target_objective")
 170                         {
 171                                 found = 1;
 172                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 173                                         return '-1 0 0';
 174                                 good = 1;
 175                         }
 176                         else if(ent.classname == "trigger_race_checkpoint")
 177                         {
 178                                 found = 1;
 179                                 if(!anypoint) // spectators may spawn everywhere
 180
 181                                 {
 182                                         if(g_race_qualifying)
 183                                         {
 184                                                 // spawn at first
 185                                                 if(ent.race_checkpoint != 0)
 186                                                         return '-1 0 0';
 187                                                 if(spot.race_place != race_lowest_place_spawn)
 188                                                         return '-1 0 0';
 189                                         }
 190                                         else
 191                                         {
 192                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 193                                                         return '-1 0 0';
 194                                                 // try reusing the previous spawn
 195                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 196                                                         prio += 1;
 197                                                 if(ent.race_checkpoint == 0)
 198                                                 {
 199                                                         float pl;
 200                                                         pl = self.race_place;
 201                                                         if(pl > race_highest_place_spawn)
 202                                                                 pl = 0;
 203                                                         if(pl == 0 && !self.race_started)
 204                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 205                                                         if(spot.race_place != pl)
 206                                                                 return '-1 0 0';
 207                                                 }
 208                                         }
 209                                 }
 210                                 good = 1;
 211                         }
 212                         ent = find(ent, targetname, spot.target);
 213                 }
 214
 215                 if(found && !good)
 216                         return '-1 0 0';
 217         }
 218
 219         player = playerlist;
 220         shortest = vlen(world.maxs - world.mins);
 221         for(player = playerlist; player; player = player.chain)
 222                 if (player != self)
 223                 {
 224                         thisdist = vlen(player.origin - spot.origin);
 225                         if (thisdist < shortest)
 226                                 shortest = thisdist;
 227                 }
 228         return prio * '1 0 0' + shortest * '0 1 0';
 229 }
 230
 231 float spawn_allbad;
 232 float spawn_allgood;
 233 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 234 {
 235         local entity spot, spotlist, spotlistend;
 236         spawn_allgood = TRUE;
 237         spawn_allbad = TRUE;
 238
 239         spotlist = world;
 240         spotlistend = world;
 241
 242         for(spot = firstspot; spot; spot = spot.chain)
 243         {
 244                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 245
 246                 if(cvar("spawn_debugview"))
 247                 {
 248                         setmodel(spot, "models/runematch/rune.mdl");
 249                         if(spot.spawnpoint_score_y < mindist)
 250                         {
 251                                 spot.colormod = '1 0 0';
 252                                 spot.scale = 1;
 253                         }
 254                         else
 255                         {
 256                                 spot.colormod = '0 1 0';
 257                                 spot.scale = spot.spawnpoint_score_y / mindist;
 258                         }
 259                 }
 260
 261                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 262                 {
 263                         if(spot.spawnpoint_score_y < mindist)
 264                         {
 265                                 // too short distance
 266                                 spawn_allgood = FALSE;
 267                         }
 268                         else
 269                         {
 270                                 // perfect
 271                                 spawn_allbad = FALSE;
 272
 273                                 if(spotlistend)
 274                                         spotlistend.chain = spot;
 275                                 spotlistend = spot;
 276                                 if(!spotlist)
 277                                         spotlist = spot;
 278
 279                                 /*
 280                                 if(teamcheck)
 281                                 if(spot.team != teamcheck)
 282                                         error("invalid spawn added");
 283
 284                                 print("added ", etos(spot), "\n");
 285                                 */
 286                         }
 287                 }
 288         }
 289         if(spotlistend)
 290                 spotlistend.chain = world;
 291
 292         /*
 293                 entity e;
 294                 if(teamcheck)
 295                         for(e = spotlist; e; e = e.chain)
 296                         {
 297                                 print("seen ", etos(e), "\n");
 298                                 if(e.team != teamcheck)
 299                                         error("invalid spawn found");
 300                         }
 301         */
 302
 303         return spotlist;
 304 }
 305
 306 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 307 {
 308         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 309         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 310         local entity spot;
 311
 312         RandomSelection_Init();
 313         for(spot = firstspot; spot; spot = spot.chain)
 314                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 315
 316         return RandomSelection_chosen_ent;
 317 }
 318
 319 /*
 320 =============
 321 SelectSpawnPoint
 322
 323 Finds a point to respawn
 324 =============
 325 */
 326 entity SelectSpawnPoint (float anypoint)
 327 {
 328         local float teamcheck;
 329         local entity firstspot_new;
 330         local entity spot, firstspot, playerlist;
 331
 332         spot = find (world, classname, "testplayerstart");
 333         if (spot)
 334                 return spot;
 335
 336         teamcheck = 0;
 337
 338         if(!anypoint && have_team_spawns > 0)
 339                 teamcheck = self.team;
 340
 341         // get the list of players
 342         playerlist = findchain(classname, "player");
 343         // get the entire list of spots
 344         firstspot = findchain(classname, "info_player_deathmatch");
 345         // filter out the bad ones
 346         // (note this returns the original list if none survived)
 347         if(anypoint)
 348         {
 349                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 350         }
 351         else
 352         {
 353                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 354                 if(!firstspot_new)
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 356                 firstspot = firstspot_new;
 357
 358                 // there is 50/50 chance of choosing a random spot or the furthest spot
 359                 // (this means that roughly every other spawn will be furthest, so you
 360                 // usually won't get fragged at spawn twice in a row)
 361                 if (arena_roundbased && !g_ca)
 362                 {
 363                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 364                         if(firstspot_new)
 365                                 firstspot = firstspot_new;
 366                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 367                 }
 368                 else if (random() > cvar("g_spawn_furthest"))
 369                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 370                 else
 371                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 372         }
 373
 374         if(cvar("spawn_debugview"))
 375         {
 376                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 377
 378                 entity e;
 379                 if(teamcheck)
 380                         for(e = firstspot; e; e = e.chain)
 381                                 if(e.team != teamcheck)
 382                                         error("invalid spawn found");
 383         }
 384
 385         if (!spot)
 386         {
 387                 if(cvar("spawn_debug"))
 388                         GotoNextMap();
 389                 else
 390                 {
 391                         if(some_spawn_has_been_used)
 392                                 return world; // team can't spawn any more, because of actions of other team
 393                         else
 394                                 error("Cannot find a spawn point - please fix the map!");
 395                 }
 396         }
 397
 398         return spot;
 399 }
 400
 401 /*
 402 =============
 403 CheckPlayerModel
 404
 405 Checks if the argument string can be a valid playermodel.
 406 Returns a valid one in doubt.
 407 =============
 408 */
 409 string FallbackPlayerModel;
 410 string CheckPlayerModel(string plyermodel) {
 411         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 412         {
 413                 // note: we cannot summon Don Strunzone here, some player may
 414                 // still have the model string set. In case anyone manages how
 415                 // to change a cvar default, we'll have a small leak here.
 416                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 417         }
 418         if(strlen(plyermodel) < 4)
 419                 return FallbackPlayerModel;
 420         if( substring(plyermodel,0,14) != "models/player/")
 421                 return FallbackPlayerModel;
 422         else if(cvar("sv_servermodelsonly"))
 423         {
 424                 if(substring(plyermodel,-4,4) != ".zym")
 425                 if(substring(plyermodel,-4,4) != ".dpm")
 426                 if(substring(plyermodel,-4,4) != ".iqm")
 427                 if(substring(plyermodel,-4,4) != ".md3")
 428                 if(substring(plyermodel,-4,4) != ".psk")
 429                         return FallbackPlayerModel;
 430                 // forbid the LOD models
 431                 if(substring(plyermodel, -9,5) == "_lod1")
 432                         return FallbackPlayerModel;
 433                 if(substring(plyermodel, -9,5) == "_lod2")
 434                         return FallbackPlayerModel;
 435                 if(plyermodel != strtolower(plyermodel))
 436                         return FallbackPlayerModel;
 437                 if(!fexists(plyermodel))
 438                         return FallbackPlayerModel;
 439         }
 440         return plyermodel;
 441 }
 442
 443 /*
 444 =============
 445 Client_customizeentityforclient
 446
 447 LOD reduction
 448 =============
 449 */
 450 void Client_uncustomizeentityforclient()
 451 {
 452         if(self.modelindex == 0) // no need to uncustomize then
 453                 return;
 454         self.modelindex = self.modelindex_lod0;
 455         self.skin = self.skinindex;
 456 }
 457
 458 float Client_customizeentityforclient()
 459 {
 460         entity modelsource;
 461
 462         if(self.modelindex == 0)
 463                 return TRUE;
 464
 465         // forcemodel stuff
 466
 467 #ifdef PROFILING
 468         float t0;
 469         t0 = gettime(GETTIME_HIRES); // reference
 470 #endif
 471
 472         modelsource = self;
 473
 474 #ifdef ALLOW_FORCEMODELS
 475         if(other.cvar_cl_forceplayermodelsfromxonotic)
 476                 if not(self.modelindex_lod0_from_xonotic)
 477                         modelsource = other;
 478         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 479                 modelsource = other;
 480 #endif
 481
 482         self.skin = modelsource.skinindex;
 483
 484 #if 0
 485         if(modelsource == self)
 486                 self.skin = modelsource.skinindex;
 487         else
 488                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 489 #endif
 490
 491         // self: me
 492         // other: the player viewing me
 493         float distance;
 494         float f;
 495
 496         if(other.cvar_cl_playerdetailreduction <= 0)
 497         {
 498                 if(other.cvar_cl_playerdetailreduction <= -2)
 499                         self.modelindex = modelsource.modelindex_lod2;
 500                 else if(other.cvar_cl_playerdetailreduction <= -1)
 501                         self.modelindex = modelsource.modelindex_lod1;
 502                 else
 503                         self.modelindex = modelsource.modelindex_lod0;
 504         }
 505         else
 506         {
 507                 distance = vlen(self.origin - other.origin);
 508                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 509                 if(f > sv_loddistance2)
 510                         self.modelindex = modelsource.modelindex_lod2;
 511                 else if(f > sv_loddistance1)
 512                         self.modelindex = modelsource.modelindex_lod1;
 513                 else
 514                         self.modelindex = modelsource.modelindex_lod0;
 515         }
 516
 517 #ifdef PROFILING
 518         float t1;
 519         t1 = gettime(GETTIME_HIRES); // reference
 520         client_cefc_accumulator += (t1 - t0);
 521 #endif
 522
 523         return TRUE;
 524 }
 525
 526 void setmodel_lod(entity e, string modelname)
 527 {
 528         string s;
 529
 530         if(sv_loddistance1)
 531         {
 532                 // FIXME: this only supports 3-letter extensions
 533                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 534                 if(fexists(s))
 535                 {
 536                         setmodel(e, s); // players have high precision
 537                         self.modelindex_lod1 = self.modelindex;
 538                 }
 539                 else
 540                         self.modelindex_lod1 = -1;
 541
 542                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 543                 if(fexists(s))
 544                 {
 545                         setmodel(e, s); // players have high precision
 546                         self.modelindex_lod2 = self.modelindex;
 547                 }
 548                 else
 549                         self.modelindex_lod2 = -1;
 550
 551                 precache_model(modelname);
 552                 setmodel(e, modelname); // players have high precision
 553                 self.modelindex_lod0 = self.modelindex;
 554
 555                 if(self.modelindex_lod1 < 0)
 556                         self.modelindex_lod1 = self.modelindex;
 557
 558                 if(self.modelindex_lod2 < 0)
 559                         self.modelindex_lod2 = self.modelindex;
 560         }
 561         else
 562         {
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566                         // save it for possible player model forcing
 567         }
 568
 569         s = whichpack(self.model);
 570         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 571
 572         player_setupanimsformodel();
 573         UpdatePlayerSounds();
 574 }
 575
 576 /*
 577 =============
 578 PutObserverInServer
 579
 580 putting a client as observer in the server
 581 =============
 582 */
 583 void FixPlayermodel();
 584 void PutObserverInServer (void)
 585 {
 586         entity  spot;
 587
 588         race_PreSpawnObserver();
 589
 590         spot = SelectSpawnPoint (TRUE);
 591         if(!spot)
 592                 error("No spawnpoints for observers?!?\n");
 593         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 594
 595         if(clienttype(self) == CLIENTTYPE_REAL)
 596         {
 597                 msg_entity = self;
 598                 WriteByte(MSG_ONE, SVC_SETVIEW);
 599                 WriteEntity(MSG_ONE, self);
 600         }
 601
 602         DropAllRunes(self);
 603
 604         Portal_ClearAll(self);
 605
 606         if(self.flagcarried)
 607                 DropFlag(self.flagcarried, world, world);
 608
 609         if(self.ballcarried)
 610                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 611
 612         WaypointSprite_PlayerDead();
 613
 614         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 615                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 616
 617         if(self.killcount != -666) {
 618                 if(g_lms) {
 619                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 620                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 621                         else
 622                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 623                 } else
 624                         bprint ("^4", self.netname, "^4 is spectating now\n");
 625
 626                 if(self.just_joined == FALSE) {
 627                         LogTeamchange(self.playerid, -1, 4);
 628                 } else
 629                         self.just_joined = FALSE;
 630         }
 631
 632         PlayerScore_Clear(self); // clear scores when needed
 633
 634         self.spectatortime = time;
 635
 636         self.classname = "observer";
 637         self.iscreature = FALSE;
 638         self.health = -666;
 639         self.takedamage = DAMAGE_NO;
 640         self.solid = SOLID_NOT;
 641         self.movetype = MOVETYPE_NOCLIP;
 642         self.flags = FL_CLIENT | FL_NOTARGET;
 643         self.armorvalue = 666;
 644         self.effects = 0;
 645         self.armorvalue = cvar("g_balance_armor_start");
 646         self.pauserotarmor_finished = 0;
 647         self.pauserothealth_finished = 0;
 648         self.pauseregen_finished = 0;
 649         self.damageforcescale = 0;
 650         self.death_time = 0;
 651         self.dead_frame = 0;
 652         self.alpha = 0;
 653         self.scale = 0;
 654         self.fade_time = 0;
 655         self.pain_frame = 0;
 656         self.pain_finished = 0;
 657         self.strength_finished = 0;
 658         self.invincible_finished = 0;
 659         self.pushltime = 0;
 660         self.think = SUB_Null;
 661         self.nextthink = 0;
 662         self.hook_time = 0;
 663         self.runes = 0;
 664         self.deadflag = DEAD_NO;
 665         self.angles = spot.angles;
 666         self.angles_z = 0;
 667         self.fixangle = TRUE;
 668         self.crouch = FALSE;
 669
 670         self.view_ofs = PL_VIEW_OFS;
 671         setorigin (self, spot.origin);
 672         setsize (self, '0 0 0', '0 0 0');
 673         self.prevorigin = self.origin;
 674         self.items = 0;
 675         self.weapons = 0;
 676         self.model = "";
 677         FixPlayermodel();
 678         self.model = "";
 679         self.modelindex = 0;
 680         self.weapon = 0;
 681         self.weaponmodel = "";
 682         self.weaponentity = world;
 683         self.exteriorweaponentity = world;
 684         self.killcount = -666;
 685         self.velocity = '0 0 0';
 686         self.avelocity = '0 0 0';
 687         self.punchangle = '0 0 0';
 688         self.punchvector = '0 0 0';
 689         self.oldvelocity = self.velocity;
 690         self.fire_endtime = -1;
 691
 692         if(sv_loddistance1)
 693                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 694
 695         if(g_arena)
 696         {
 697                 if(self.version_mismatch)
 698                 {
 699                         Spawnqueue_Unmark(self);
 700                         Spawnqueue_Remove(self);
 701                 }
 702                 else
 703                 {
 704                         Spawnqueue_Insert(self);
 705                 }
 706         }
 707         else if(g_lms)
 708         {
 709                 // Only if the player cannot play at all
 710                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 711                         self.frags = FRAGS_SPECTATOR;
 712                 else
 713                         self.frags = FRAGS_LMS_LOSER;
 714         }
 715         else
 716                 self.frags = FRAGS_SPECTATOR;
 717
 718         MUTATOR_CALLHOOK(MakePlayerObserver);
 719 }
 720
 721 float RestrictSkin(float s)
 722 {
 723         if(!teams_matter)
 724                 return s;
 725         if(s == 6)
 726                 return 6;
 727         return mod(s, 3);
 728 }
 729
 730 void FixPlayermodel()
 731 {
 732         local string defaultmodel;
 733         local float defaultskin, chmdl, oldskin;
 734         local vector m1, m2;
 735
 736         defaultmodel = "";
 737
 738         if(cvar("sv_defaultcharacter") == 1) {
 739                 defaultskin = 0;
 740
 741                 if(teams_matter)
 742                 {
 743                         string s;
 744                         s = Team_ColorNameLowerCase(self.team);
 745                         if(s != "neutral")
 746                         {
 747                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 748                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 749                         }
 750                 }
 751
 752                 if(defaultmodel == "")
 753                 {
 754                         defaultmodel = cvar_string("sv_defaultplayermodel");
 755                         defaultskin = cvar("sv_defaultplayerskin");
 756                 }
 757         }
 758
 759         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 760         {
 761                 if(self.model != "")
 762                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 763                 self.model = ""; // force the != checks to return true
 764         }
 765
 766         if(defaultmodel != "")
 767         {
 768                 if (defaultmodel != self.model)
 769                 {
 770                         m1 = self.mins;
 771                         m2 = self.maxs;
 772                         setmodel_lod (self, defaultmodel);
 773                         setsize (self, m1, m2);
 774                         chmdl = TRUE;
 775                 }
 776
 777                 oldskin = self.skinindex;
 778                 self.skinindex = defaultskin;
 779         } else {
 780                 if (self.playermodel != self.model || self.playermodel == "")
 781                 {
 782                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 783                         m1 = self.mins;
 784                         m2 = self.maxs;
 785                         setmodel_lod (self, self.playermodel);
 786                         setsize (self, m1, m2);
 787                         chmdl = TRUE;
 788                 }
 789
 790                 oldskin = self.skinindex;
 791                 self.skinindex = RestrictSkin(stof(self.playerskin));
 792         }
 793
 794         if(chmdl || oldskin != self.skinindex)
 795                 self.species = player_getspecies(); // model or skin has changed
 796
 797         if(!teams_matter)
 798                 if(strlen(cvar_string("sv_defaultplayercolors")))
 799                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 800                                 setcolor(self, cvar("sv_defaultplayercolors"));
 801 }
 802
 803 void PlayerTouchExplode(entity p1, entity p2)
 804 {
 805         vector org;
 806         org = (p1.origin + p2.origin) * 0.5;
 807         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 808
 809         te_explosion(org);
 810
 811         entity e;
 812         e = spawn();
 813         setorigin(e, org);
 814         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 815         remove(e);
 816 }
 817
 818 /*
 819 =============
 820 PutClientInServer
 821
 822 Called when a client spawns in the server
 823 =============
 824 */
 825 //void() ctf_playerchanged;
 826 void PutClientInServer (void)
 827 {
 828         if(clienttype(self) == CLIENTTYPE_BOT)
 829         {
 830                 self.classname = "player";
 831         }
 832         else if(clienttype(self) == CLIENTTYPE_REAL)
 833         {
 834                 msg_entity = self;
 835                 WriteByte(MSG_ONE, SVC_SETVIEW);
 836                 WriteEntity(MSG_ONE, self);
 837         }
 838
 839         // player is dead and becomes observer
 840         // FIXME fix LMS scoring for new system
 841         if(g_lms)
 842         {
 843                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 844                         self.classname = "observer";
 845         }
 846
 847         if(g_arena || (g_ca && !allowed_to_spawn))
 848         if(!self.spawned)
 849                 self.classname = "observer";
 850
 851         if(gameover)
 852                 self.classname = "observer";
 853
 854         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 855                 entity spot, oldself;
 856                 float j;
 857
 858                 if(self.team < 0)
 859                         JoinBestTeam(self, FALSE, TRUE);
 860
 861                 race_PreSpawn();
 862
 863                 spot = SelectSpawnPoint (FALSE);
 864                 if(!spot)
 865                 {
 866                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 867                         return; // spawn failed
 868                 }
 869
 870                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 871
 872                 self.classname = "player";
 873                 self.wasplayer = TRUE;
 874                 self.iscreature = TRUE;
 875                 self.movetype = MOVETYPE_WALK;
 876                 self.solid = SOLID_SLIDEBOX;
 877                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 878                 if(cvar("g_playerclip_collisions"))
 879                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 880                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 881                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 882                 self.frags = FRAGS_PLAYER;
 883                 if(independent_players)
 884                         MAKE_INDEPENDENT_PLAYER(self);
 885                 self.flags = FL_CLIENT;
 886                 self.takedamage = DAMAGE_AIM;
 887                 if(g_minstagib)
 888                         self.effects = EF_FULLBRIGHT;
 889                 else
 890                         self.effects = 0;
 891                 self.air_finished = time + 12;
 892                 self.dmg = 2;
 893
 894                 if(inWarmupStage)
 895                 {
 896                         self.ammo_shells = warmup_start_ammo_shells;
 897                         self.ammo_nails = warmup_start_ammo_nails;
 898                         self.ammo_rockets = warmup_start_ammo_rockets;
 899                         self.ammo_cells = warmup_start_ammo_cells;
 900                         self.ammo_fuel = warmup_start_ammo_fuel;
 901                         self.health = warmup_start_health;
 902                         self.armorvalue = warmup_start_armorvalue;
 903                         self.weapons = warmup_start_weapons;
 904                 }
 905                 else
 906                 {
 907                         self.ammo_shells = start_ammo_shells;
 908                         self.ammo_nails = start_ammo_nails;
 909                         self.ammo_rockets = start_ammo_rockets;
 910                         self.ammo_cells = start_ammo_cells;
 911                         self.ammo_fuel = start_ammo_fuel;
 912                         self.health = start_health;
 913                         self.armorvalue = start_armorvalue;
 914                         self.weapons = start_weapons;
 915                 }
 916
 917                 if(g_weaponarena_random)
 918                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 919
 920                 self.items = start_items;
 921                 self.jump_interval = time;
 922
 923                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 924                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 925                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 926                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 927                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 928                 //extend the pause of rotting if client was reset at the beginning of the countdown
 929                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 930                         self.spawnshieldtime += game_starttime - time;
 931                         self.pauserotarmor_finished += game_starttime - time;
 932                         self.pauserothealth_finished += game_starttime - time;
 933                         self.pauseregen_finished += game_starttime - time;
 934                 }
 935                 self.damageforcescale = 2;
 936                 self.death_time = 0;
 937                 self.dead_frame = 0;
 938                 self.alpha = 0;
 939                 self.scale = 0;
 940                 self.fade_time = 0;
 941                 self.pain_frame = 0;
 942                 self.pain_finished = 0;
 943                 self.strength_finished = 0;
 944                 self.invincible_finished = 0;
 945                 self.pushltime = 0;
 946                 // players have no think function
 947                 self.think = SUB_Null;
 948                 self.nextthink = 0;
 949                 self.hook_time = 0;
 950                 self.dmg_team = 0;
 951                 self.ballistics_density = cvar("g_ballistics_density_player");
 952
 953                 self.metertime = 0;
 954
 955                 self.runes = 0;
 956
 957                 self.deadflag = DEAD_NO;
 958
 959                 self.angles = spot.angles;
 960
 961                 self.angles_z = 0; // never spawn tilted even if the spot says to
 962                 self.fixangle = TRUE; // turn this way immediately
 963                 self.velocity = '0 0 0';
 964                 self.avelocity = '0 0 0';
 965                 self.punchangle = '0 0 0';
 966                 self.punchvector = '0 0 0';
 967                 self.oldvelocity = self.velocity;
 968                 self.fire_endtime = -1;
 969
 970                 msg_entity = self;
 971                 WRITESPECTATABLE_MSG_ONE({
 972                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 973                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 974                 });
 975
 976                 if(sv_loddistance1)
 977                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 978
 979                 self.model = "";
 980                 FixPlayermodel();
 981
 982                 self.crouch = FALSE;
 983                 self.view_ofs = PL_VIEW_OFS;
 984                 setsize (self, PL_MIN, PL_MAX);
 985                 self.spawnorigin = spot.origin;
 986                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 987                 // don't reset back to last position, even if new position is stuck in solid
 988                 self.oldorigin = self.origin;
 989                 self.prevorigin = self.origin;
 990                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 991
 992                 if(g_arena)
 993                 {
 994                         Spawnqueue_Remove(self);
 995                         Spawnqueue_Mark(self);
 996                 }
 997
 998                 else if(g_ca)
 999                         self.caplayer = 1;
1000
1001                 self.event_damage = PlayerDamage;
1002
1003                 self.bot_attack = TRUE;
1004
1005                 self.statdraintime = time + 5;
1006                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1007
1008                 if(self.killcount == -666) {
1009                         PlayerScore_Clear(self);
1010                         self.killcount = 0;
1011                 }
1012
1013                 self.cnt = WEP_LASER;
1014
1015                 CL_SpawnWeaponentity();
1016                 self.alpha = default_player_alpha;
1017                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1018                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1019
1020                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1021                 self.lms_traveled_distance = 0;
1022                 self.speedrunning = FALSE;
1023
1024                 race_PostSpawn(spot);
1025
1026                 if(cvar("spawn_debug"))
1027                 {
1028                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1029                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1030                 }
1031
1032                 //stuffcmd(self, "chase_active 0");
1033                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1034
1035                 if (cvar("g_spawnsound"))
1036                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1037
1038                 if(g_assault) {
1039                         if(self.team == assault_attacker_team)
1040                                 centerprint(self, "You are attacking!");
1041                         else
1042                                 centerprint(self, "You are defending!");
1043                 }
1044
1045                 target_voicescript_clear(self);
1046
1047                 // reset fields the weapons may use
1048                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1049                         weapon_action(j, WR_RESETPLAYER);
1050
1051                 oldself = self;
1052                 self = spot;
1053                         activator = oldself;
1054                                 SUB_UseTargets();
1055                         activator = world;
1056                 self = oldself;
1057
1058                 MUTATOR_CALLHOOK(PlayerSpawn);
1059
1060                 self.switchweapon = w_getbestweapon(self);
1061                 self.cnt = self.switchweapon;
1062                 self.weapon = 0;
1063         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1064                 PutObserverInServer ();
1065         }
1066
1067         //if(g_ctf)
1068         //      ctf_playerchanged();
1069 }
1070
1071 float ClientInit_SendEntity(entity to, float sf)
1072 {
1073         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1074         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1075         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1078         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1079         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1080         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1081         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1082         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1083         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1084         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1085         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1086         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1087         if(sv_foginterval && world.fog != "")
1088                 WriteString(MSG_ENTITY, world.fog);
1089         else
1090                 WriteString(MSG_ENTITY, "");
1091         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1092         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1093         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1094         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1095         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1096         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1097         return TRUE;
1098 }
1099
1100 void ClientInit_CheckUpdate()
1101 {
1102         self.nextthink = time;
1103         if(self.count != cvar("g_balance_armor_blockpercent"))
1104         {
1105                 self.count = cvar("g_balance_armor_blockpercent");
1106                 self.SendFlags |= 1;
1107         }
1108         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1109         {
1110                 self.cnt = cvar("g_balance_weaponswitchdelay");
1111                 self.SendFlags |= 1;
1112         }
1113         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1114         {
1115                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1116                 self.SendFlags |= 1;
1117         }
1118         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1119         {
1120                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1121                 self.SendFlags |= 1;
1122         }
1123 }
1124
1125 void ClientInit_Spawn()
1126 {
1127         entity o;
1128         entity e;
1129         e = spawn();
1130         e.classname = "clientinit";
1131         e.think = ClientInit_CheckUpdate;
1132         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1133
1134         o = self;
1135         self = e;
1136         ClientInit_CheckUpdate();
1137         self = o;
1138 }
1139
1140 /*
1141 =============
1142 SetNewParms
1143 =============
1144 */
1145 void SetNewParms (void)
1146 {
1147         // initialize parms for a new player
1148         parm1 = -(86400 * 366);
1149 }
1150
1151 /*
1152 =============
1153 SetChangeParms
1154 =============
1155 */
1156 void SetChangeParms (void)
1157 {
1158         // save parms for level change
1159         parm1 = self.parm_idlesince - time;
1160 }
1161
1162 /*
1163 =============
1164 DecodeLevelParms
1165 =============
1166 */
1167 void DecodeLevelParms (void)
1168 {
1169         // load parms
1170         self.parm_idlesince = parm1;
1171         if(self.parm_idlesince == -(86400 * 366))
1172                 self.parm_idlesince = time;
1173
1174         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1175         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1176 }
1177
1178 /*
1179 =============
1180 ClientKill
1181
1182 Called when a client types 'kill' in the console
1183 =============
1184 */
1185
1186 void ClientKill_Now_TeamChange()
1187 {
1188         if(self.killindicator_teamchange == -1)
1189         {
1190                 self.team = -1;
1191                 JoinBestTeam( self, FALSE, FALSE );
1192         }
1193         else
1194                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1195 }
1196
1197 void ClientKill_Now()
1198 {
1199         if(self.killindicator_teamchange)
1200                 ClientKill_Now_TeamChange();
1201
1202         // in any case:
1203         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1204
1205         if(self.killindicator)
1206         {
1207                 dprint("Cleaned up after a leaked kill indicator.\n");
1208                 remove(self.killindicator);
1209                 self.killindicator = world;
1210         }
1211 }
1212 void KillIndicator_Think()
1213 {
1214         if (!self.owner.modelindex)
1215         {
1216                 self.owner.killindicator = world;
1217                 remove(self);
1218                 return;
1219         }
1220
1221         if(self.cnt <= 0)
1222         {
1223                 self = self.owner;
1224                 ClientKill_Now(); // no oldself needed
1225                 return;
1226         }
1227         else
1228         {
1229                 if(self.cnt <= 10)
1230                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1231                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1232                 {
1233                         if(self.cnt <= 10)
1234                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1235                         if(self.owner.killindicator_teamchange)
1236                         {
1237                                 if(self.owner.killindicator_teamchange == -1)
1238                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1239                                 else
1240                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1241                         }
1242                         else
1243                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1244                 }
1245                 self.nextthink = time + 1;
1246                 self.cnt -= 1;
1247         }
1248 }
1249
1250 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1251 {
1252         float killtime;
1253         entity e;
1254         killtime = cvar("g_balance_kill_delay");
1255
1256         if(g_race_qualifying)
1257                 killtime = 0;
1258
1259         self.killindicator_teamchange = targetteam;
1260
1261         if(!self.killindicator)
1262         {
1263                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1264                 {
1265                         ClientKill_Now();
1266                 }
1267                 else
1268                 {
1269                         self.killindicator = spawn();
1270                         self.killindicator.owner = self;
1271                         self.killindicator.scale = 0.5;
1272                         setattachment(self.killindicator, self, "");
1273                         setorigin(self.killindicator, '0 0 52');
1274                         self.killindicator.think = KillIndicator_Think;
1275                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1276                         self.killindicator.cnt = ceil(killtime);
1277                         self.killindicator.count = bound(0, ceil(killtime), 10);
1278                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1279
1280                         for(e = world; (e = find(e, classname, "body")) != world; )
1281                         {
1282                                 if(e.enemy != self)
1283                                         continue;
1284                                 e.killindicator = spawn();
1285                                 e.killindicator.owner = e;
1286                                 e.killindicator.scale = 0.5;
1287                                 setattachment(e.killindicator, e, "");
1288                                 setorigin(e.killindicator, '0 0 52');
1289                                 e.killindicator.think = KillIndicator_Think;
1290                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1291                                 e.killindicator.cnt = ceil(killtime);
1292                         }
1293                         self.lip = 0;
1294                 }
1295         }
1296         if(self.killindicator)
1297         {
1298                 if(targetteam)
1299                         self.killindicator.colormod = TeamColor(targetteam);
1300                 else
1301                         self.killindicator.colormod = '0 0 0';
1302         }
1303 }
1304
1305 void ClientKill (void)
1306 {
1307         ClientKill_TeamChange(0);
1308 }
1309
1310 void DoTeamChange(float destteam)
1311 {
1312         float t, c0;
1313         if(!teams_matter)
1314         {
1315                 if(destteam >= 0)
1316                         SetPlayerColors(self, destteam);
1317                 return;
1318         }
1319         if(self.classname == "player")
1320         if(destteam == -1)
1321         {
1322                 CheckAllowedTeams(self);
1323                 t = FindSmallestTeam(self, TRUE);
1324                 switch(self.team)
1325                 {
1326                         case COLOR_TEAM1: c0 = c1; break;
1327                         case COLOR_TEAM2: c0 = c2; break;
1328                         case COLOR_TEAM3: c0 = c3; break;
1329                         case COLOR_TEAM4: c0 = c4; break;
1330                         default:          c0 = 999;
1331                 }
1332                 switch(t)
1333                 {
1334                         case 1:
1335                                 if(c0 > c1)
1336                                         destteam = COLOR_TEAM1;
1337                                 break;
1338                         case 2:
1339                                 if(c0 > c2)
1340                                         destteam = COLOR_TEAM2;
1341                                 break;
1342                         case 3:
1343                                 if(c0 > c3)
1344                                         destteam = COLOR_TEAM3;
1345                                 break;
1346                         case 4:
1347                                 if(c0 > c4)
1348                                         destteam = COLOR_TEAM4;
1349                                 break;
1350                 }
1351                 if(destteam == -1)
1352                         return;
1353         }
1354         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1355                 return;
1356         ClientKill_TeamChange(destteam);
1357 }
1358
1359 void FixClientCvars(entity e)
1360 {
1361         // send prediction settings to the client
1362         stuffcmd(e, "\nin_bindmap 0 0\n");
1363         if(g_race || g_cts)
1364                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1365         if(cvar("g_antilag") == 3) // client side hitscan
1366                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1367         if(sv_gentle)
1368                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1369         /*
1370          * we no longer need to stuff this. Remove this comment block if you feel
1371          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1372         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1373         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1374         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1375         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1376         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1377         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1378         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1379         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1380         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1381         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1382         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1383         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1384         stuffcmd(e, "cl_movement_edgefriction 1\n");
1385          */
1386 }
1387
1388 /*
1389 =============
1390 ClientConnect
1391
1392 Called when a client connects to the server
1393 =============
1394 */
1395 //void ctf_clientconnect();
1396 string ColoredTeamName(float t);
1397 void DecodeLevelParms (void);
1398 //void dom_player_join_team(entity pl);
1399 #ifdef UID
1400 .float uid_kicktime;
1401 .string uid;
1402 #endif
1403 void ClientConnect (void)
1404 {
1405         float t;
1406
1407         if(self.flags & FL_CLIENT)
1408         {
1409                 print("Warning: ClientConnect, but already connected!\n");
1410                 return;
1411         }
1412
1413         if(Ban_MaybeEnforceBan(self))
1414                 return;
1415
1416         DecodeLevelParms();
1417
1418 #ifdef WATERMARK
1419         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1420 #endif
1421
1422         self.classname = "player_joining";
1423
1424         self.flags = FL_CLIENT;
1425         self.version_nagtime = time + 10 + random() * 10;
1426
1427         if(player_count<0)
1428         {
1429                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1430                 player_count = 0;
1431         }
1432
1433         PlayerScore_Attach(self);
1434         ClientData_Attach();
1435
1436         bot_clientconnect();
1437
1438         playerdemo_init();
1439
1440         anticheat_init();
1441
1442         race_PreSpawnObserver();
1443
1444         //if(g_domination)
1445         //      dom_player_join_team(self);
1446
1447         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1448
1449         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1450                 self.classname = "observer";
1451         } else {
1452                 if(teams_matter)
1453                 {
1454                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1455                         {
1456                                 self.classname = "player";
1457                                 campaign_bots_may_start = 1;
1458                         }
1459                         else
1460                         {
1461                                 self.classname = "observer"; // do it anyway
1462                         }
1463                 }
1464                 else
1465                 {
1466                         self.classname = "player";
1467                         campaign_bots_may_start = 1;
1468                 }
1469         }
1470
1471         self.playerid = (playerid_last = playerid_last + 1);
1472
1473         if(cvar("sv_eventlog"))
1474                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1475
1476         LogTeamchange(self.playerid, self.team, 1);
1477
1478         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1479
1480         self.netname_previous = strzone(self.netname);
1481
1482         bprint("^4", self.netname, "^4 connected");
1483
1484         if(self.classname != "observer" && (g_domination || g_ctf))
1485                 bprint(" and joined the ", ColoredTeamName(self.team));
1486
1487         bprint("\n");
1488
1489         self.welcomemessage_time = 0;
1490
1491         stuffcmd(self, strcat(clientstuff, "\n"));
1492         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1493         stuffcmd(self, "cl_particles_reloadeffects\n");
1494
1495         FixClientCvars(self);
1496
1497         // spawnfunc_waypoint sprites
1498         WaypointSprite_InitClient(self);
1499
1500         // Wazat's grappling hook
1501         SetGrappleHookBindings();
1502
1503         // get autoswitch state from player when he toggles it
1504         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1505
1506         // get version info from player
1507         stuffcmd(self, "cmd clientversion $gameversion\n");
1508
1509         // get other cvars from player
1510         GetCvars(0);
1511
1512         // set cvar for team scoreboard
1513         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1514
1515         // notify about available teams
1516         if(teams_matter)
1517         {
1518                 CheckAllowedTeams(self);
1519                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1520                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1521         }
1522         else
1523                 stuffcmd(self, "set _teams_available 0\n");
1524
1525         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1526
1527         if(g_arena || g_ca)
1528         {
1529                 self.classname = "observer";
1530                 if(g_arena)
1531                         Spawnqueue_Insert(self);
1532         }
1533         /*else if(g_ctf)
1534         {
1535                 ctf_clientconnect();
1536         }*/
1537
1538         if(teams_matter || radar_showennemies)
1539                 attach_entcs();
1540
1541         bot_relinkplayerlist();
1542
1543         self.spectatortime = time;
1544         if(blockSpectators)
1545         {
1546                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1547         }
1548
1549         self.jointime = time;
1550         self.allowedTimeouts = cvar("sv_timeout_number");
1551
1552         if(clienttype(self) == CLIENTTYPE_REAL)
1553         {
1554                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1555                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1556         }
1557
1558         if(g_lms)
1559         {
1560                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1561                 {
1562                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1563                         self.frags = FRAGS_SPECTATOR;
1564                 }
1565         }
1566
1567         if(!sv_foginterval && world.fog != "")
1568                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1569
1570         SoundEntity_Attach(self);
1571
1572         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1573         {
1574                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1575                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1576         }
1577         else
1578                 self.hitplotfh = -1;
1579
1580 #ifdef UID
1581         if(clienttype(self) == CLIENTTYPE_REAL)
1582         if not(self.uid)
1583                 self.uid_kicktime = time + 60;
1584 #endif
1585
1586         if(g_race || g_cts) {
1587                 string rr;
1588                 if(g_cts)
1589                         rr = CTS_RECORD;
1590                 else
1591                         rr = RACE_RECORD;
1592                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1593
1594                 race_send_recordtime(MSG_ONE);
1595                 race_send_speedaward(MSG_ONE);
1596
1597                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1598                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1599                 race_send_speedaward_alltimebest(MSG_ONE);
1600
1601                 float i;
1602                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1603                         race_SendRankings(i, 0, 0, MSG_ONE);
1604                 }
1605         }
1606         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1607                 send_CSQC_teamnagger();
1608
1609         send_CSQC_nexvelocity(self);
1610
1611         CheatInitClient();
1612 }
1613
1614 /*
1615 =============
1616 ClientDisconnect
1617
1618 Called when a client disconnects from the server
1619 =============
1620 */
1621 .entity chatbubbleentity;
1622 .entity teambubbleentity;
1623 void ReadyCount();
1624 void ClientDisconnect (void)
1625 {
1626         if not(self.flags & FL_CLIENT)
1627         {
1628                 print("Warning: ClientDisconnect without ClientConnect\n");
1629                 return;
1630         }
1631
1632         CheatShutdownClient();
1633
1634         if(self.hitplotfh >= 0)
1635         {
1636                 fclose(self.hitplotfh);
1637                 self.hitplotfh = -1;
1638         }
1639
1640         anticheat_report();
1641         anticheat_shutdown();
1642
1643         playerdemo_shutdown();
1644
1645         bot_clientdisconnect();
1646
1647         if(self.entcs)
1648                 detach_entcs();
1649
1650         if(cvar("sv_eventlog"))
1651                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1652         bprint ("^4",self.netname);
1653         bprint ("^4 disconnected\n");
1654
1655         SoundEntity_Detach(self);
1656
1657         DropAllRunes(self);
1658         MUTATOR_CALLHOOK(ClientDisconnect);
1659
1660         Portal_ClearAll(self);
1661
1662         if(self.flagcarried)
1663                 DropFlag(self.flagcarried, world, world);
1664         if(self.ballcarried)
1665                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1666
1667         // Here, everything has been done that requires this player to be a client.
1668
1669         self.flags &~= FL_CLIENT;
1670
1671         if (self.chatbubbleentity)
1672                 remove (self.chatbubbleentity);
1673
1674         if (self.teambubbleentity)
1675                 remove (self.teambubbleentity);
1676
1677         if (self.killindicator)
1678                 remove (self.killindicator);
1679
1680         WaypointSprite_PlayerGone();
1681
1682         bot_relinkplayerlist();
1683
1684         // remove laserdot
1685         if(self.weaponentity)
1686                 if(self.weaponentity.lasertarget)
1687                         remove(self.weaponentity.lasertarget);
1688
1689         if(g_arena)
1690         {
1691                 Spawnqueue_Unmark(self);
1692                 Spawnqueue_Remove(self);
1693         }
1694
1695         ClientData_Detach();
1696         PlayerScore_Detach(self);
1697
1698         if(self.netname_previous)
1699                 strunzone(self.netname_previous);
1700         if(self.clientstatus)
1701                 strunzone(self.clientstatus);
1702
1703         ClearPlayerSounds();
1704
1705         if(self.personal)
1706                 remove(self.personal);
1707
1708         self.playerid = 0;
1709         ReadyCount();
1710
1711         // free cvars
1712         GetCvars(-1);
1713 }
1714
1715 .float BUTTON_CHAT;
1716 void ChatBubbleThink()
1717 {
1718         self.nextthink = time;
1719         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1720         {
1721                 if(self.owner) // but why can that ever be world?
1722                         self.owner.chatbubbleentity = world;
1723                 remove(self);
1724                 return;
1725         }
1726         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1727 #ifdef TETRIS
1728                 || self.owner.tetris_on
1729 #endif
1730         )
1731                 self.model = self.mdl;
1732         else
1733                 self.model = "";
1734 };
1735
1736 void UpdateChatBubble()
1737 {
1738         if (!self.modelindex)
1739                 return;
1740         // spawn a chatbubble entity if needed
1741         if (!self.chatbubbleentity)
1742         {
1743                 self.chatbubbleentity = spawn();
1744                 self.chatbubbleentity.owner = self;
1745                 self.chatbubbleentity.exteriormodeltoclient = self;
1746                 self.chatbubbleentity.think = ChatBubbleThink;
1747                 self.chatbubbleentity.nextthink = time;
1748                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1749                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1750                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1751                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1752                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1753                 self.chatbubbleentity.model = "";
1754                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1755         }
1756 }
1757
1758
1759 void TeamBubbleThink()
1760 {
1761         self.nextthink = time;
1762         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1763         {
1764                 if(self.owner) // but why can that ever be world?
1765                         self.owner.teambubbleentity = world;
1766                 remove(self);
1767                 return;
1768         }
1769 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1770         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1771                 self.model = "";
1772         else
1773                 self.model = self.mdl;
1774
1775 };
1776
1777 float TeamBubble_customizeentityforclient()
1778 {
1779         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1780 }
1781
1782 void UpdateTeamBubble()
1783 {
1784         if (!self.modelindex || !teams_matter)
1785                 return;
1786         // spawn a teambubble entity if needed
1787         if (!self.teambubbleentity && teams_matter)
1788         {
1789                 self.teambubbleentity = spawn();
1790                 self.teambubbleentity.owner = self;
1791                 self.teambubbleentity.exteriormodeltoclient = self;
1792                 self.teambubbleentity.think = TeamBubbleThink;
1793                 self.teambubbleentity.nextthink = time;
1794                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1795 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1796                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1797                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1798                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1799                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1800                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1801                 self.teambubbleentity.effects = EF_LOWPRECISION;
1802         }
1803 }
1804
1805 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1806 // added to the model skins
1807 /*void UpdateColorModHack()
1808 {
1809         local float c;
1810         c = self.clientcolors & 15;
1811         // LordHavoc: only bothering to support white, green, red, yellow, blue
1812              if (!teams_matter) self.colormod = '0 0 0';
1813         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1814         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1815         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1816         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1817         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1818         else self.colormod = '1 1 1';
1819 };*/
1820
1821 .float oldcolormap;
1822 void respawn(void)
1823 {
1824         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1825         {
1826                 self.solid = SOLID_NOT;
1827                 self.takedamage = DAMAGE_NO;
1828                 self.movetype = MOVETYPE_FLY;
1829                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1830                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1831                 self.effects |= EF_ADDITIVE;
1832                 self.oldcolormap = self.colormap;
1833                 self.colormap = 512;
1834                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1835                 if(cvar("g_respawn_ghosts_maxtime"))
1836                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1837         }
1838
1839         CopyBody(1);
1840         self.effects |= EF_NODRAW; // prevent another CopyBody
1841         if(self.oldcolormap)
1842         {
1843                 self.colormap = self.oldcolormap;
1844                 self.oldcolormap = 0;
1845         }
1846         PutClientInServer();
1847 }
1848
1849 void play_countdown(float finished, string samp)
1850 {
1851         if(clienttype(self) == CLIENTTYPE_REAL)
1852                 if(floor(finished - time - frametime) != floor(finished - time))
1853                         if(finished - time < 6)
1854                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1855 }
1856
1857 /**
1858  * When sv_timeout is used this function returs strings like
1859  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1860  * Called by centerprint functions
1861  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1862  */
1863 string getTimeoutText(float addOneSecond) {
1864         if (!cvar("sv_timeout") || !timeoutStatus)
1865                 return "";
1866
1867         local string retStr;
1868         if (timeoutStatus == 1) {
1869                 if (addOneSecond == 1) {
1870                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1871                 }
1872                 else {
1873                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1874                 }
1875                 return retStr;
1876         }
1877         else if (timeoutStatus == 2) {
1878                 if (addOneSecond) {
1879                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1880                         //don't show messages like "Timeout ends in 0 seconds"...
1881                         if ((remainingTimeoutTime + 1) > 0)
1882                                 return retStr;
1883                         else
1884                                 return "";
1885                 }
1886                 else {
1887                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1888                         //don't show messages like "Timeout ends in 0 seconds"...
1889                         if (remainingTimeoutTime > 0)
1890                                 return retStr;
1891                         else
1892                                 return "";
1893                 }
1894         }
1895         else return "";
1896 }
1897
1898 void player_powerups (void)
1899 {
1900         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1901         {
1902                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1903                 self.modelflags |= MF_ROCKET;
1904         }
1905         else
1906         {
1907                 SoundEntity_StopSound(self, CHAN_PLAYER);
1908                 self.modelflags &~= MF_ROCKET;
1909         }
1910
1911         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1912
1913         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1914                 return;
1915
1916         Fire_ApplyDamage(self);
1917         Fire_ApplyEffect(self);
1918
1919         if (g_minstagib)
1920         {
1921                 self.effects |= EF_FULLBRIGHT;
1922
1923                 if (self.items & IT_STRENGTH)
1924                 {
1925                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1926                         if (time > self.strength_finished)
1927                         {
1928                                 self.alpha = default_player_alpha;
1929                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1930                                 self.items &~= IT_STRENGTH;
1931                                 sprint(self, "^3Invisibility has worn off\n");
1932                         }
1933                 }
1934                 else
1935                 {
1936                         if (time < self.strength_finished)
1937                         {
1938                                 self.alpha = g_minstagib_invis_alpha;
1939                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1940                                 self.items |= IT_STRENGTH;
1941                                 sprint(self, "^3You are invisible\n");
1942                         }
1943                 }
1944
1945                 if (self.items & IT_INVINCIBLE)
1946                 {
1947                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1948                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1949                         {
1950                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1951                                 sprint(self, "^3Speed has worn off\n");
1952                         }
1953                 }
1954                 else
1955                 {
1956                         if (time < self.invincible_finished)
1957                         {
1958                                 self.items = self.items | IT_INVINCIBLE;
1959                                 sprint(self, "^3You are on speed\n");
1960                         }
1961                 }
1962                 return;
1963         }
1964
1965         if (self.items & IT_STRENGTH)
1966         {
1967                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1968                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1969                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1970                 {
1971                         self.items = self.items - (self.items & IT_STRENGTH);
1972                         sprint(self, "^3Strength has worn off\n");
1973                 }
1974         }
1975         else
1976         {
1977                 if (time < self.strength_finished)
1978                 {
1979                         self.items = self.items | IT_STRENGTH;
1980                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1981                 }
1982         }
1983         if (self.items & IT_INVINCIBLE)
1984         {
1985                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1986                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1987                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1988                 {
1989                         self.items = self.items - (self.items & IT_INVINCIBLE);
1990                         sprint(self, "^3Shield has worn off\n");
1991                 }
1992         }
1993         else
1994         {
1995                 if (time < self.invincible_finished)
1996                 {
1997                         self.items = self.items | IT_INVINCIBLE;
1998                         sprint(self, "^3Shield surrounds you\n");
1999                 }
2000         }
2001
2002         if(cvar("g_nodepthtestplayers"))
2003                 self.effects = self.effects | EF_NODEPTHTEST;
2004
2005         if(cvar("g_fullbrightplayers"))
2006                 self.effects = self.effects | EF_FULLBRIGHT;
2007
2008         // midair gamemode: damage only while in the air
2009         // if in midair mode, being on ground grants temporary invulnerability
2010         // (this is so that multishot weapon don't clear the ground flag on the
2011         // first damage in the frame, leaving the player vulnerable to the
2012         // remaining hits in the same frame)
2013         if (self.flags & FL_ONGROUND)
2014         if (g_midair)
2015                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2016
2017         if (time >= game_starttime)
2018         if (time < self.spawnshieldtime)
2019                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2020 }
2021
2022 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2023 {
2024         if(current > stable)
2025                 return current;
2026         else if(current > stable - 0.25) // when close enough, "snap"
2027                 return stable;
2028         else
2029                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2030 }
2031
2032 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2033 {
2034         if(current < stable)
2035                 return current;
2036         else if(current < stable + 0.25) // when close enough, "snap"
2037                 return stable;
2038         else
2039                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2040 }
2041
2042 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2043 {
2044         if(current > rotstable)
2045         {
2046                 if(rotframetime > 0)
2047                 {
2048                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2049                         current = max(rotstable, current - rotlinear * rotframetime);
2050                 }
2051         }
2052         else if(current < regenstable)
2053         {
2054                 if(regenframetime > 0)
2055                 {
2056                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2057                         current = min(regenstable, current + regenlinear * regenframetime);
2058                 }
2059         }
2060
2061         if(current > limit)
2062                 current = limit;
2063
2064         return current;
2065 }
2066
2067 void player_regen (void)
2068 {
2069         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2070         maxh = cvar("g_balance_health_rotstable");
2071         maxa = cvar("g_balance_armor_rotstable");
2072         maxf = cvar("g_balance_fuel_rotstable");
2073         minh = cvar("g_balance_health_regenstable");
2074         mina = cvar("g_balance_armor_regenstable");
2075         minf = cvar("g_balance_fuel_regenstable");
2076         limith = cvar("g_balance_health_limit");
2077         limita = cvar("g_balance_armor_limit");
2078         limitf = cvar("g_balance_fuel_limit");
2079
2080         max_mod = regen_mod = rot_mod = limit_mod = 1;
2081
2082         if (self.runes & RUNE_REGEN)
2083         {
2084                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2085                 {
2086                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2087                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2088                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2089                 }
2090                 else
2091                 {
2092                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2093                         max_mod = cvar("g_balance_rune_regen_hpmod");
2094                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2095                 }
2096         }
2097         else if (self.runes & CURSE_VENOM)
2098         {
2099                 max_mod = cvar("g_balance_curse_venom_hpmod");
2100                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2101                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2102                 else
2103                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2104                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2105                 //if (!self.runes & RUNE_REGEN)
2106                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2107         }
2108         maxh = maxh * max_mod;
2109         //maxa = maxa * max_mod;
2110         //maxf = maxf * max_mod;
2111         minh = minh * max_mod;
2112         //mina = mina * max_mod;
2113         //minf = minf * max_mod;
2114         limith = limith * limit_mod;
2115         limita = limita * limit_mod;
2116         //limitf = limitf * limit_mod;
2117
2118         if(g_lms && g_ca)
2119                 rot_mod = 0;
2120
2121         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2122         {
2123                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2124                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2125
2126                 // if player rotted to death...  die!
2127                 if(self.health < 1)
2128                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2129         }
2130
2131         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2132                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2133 }
2134
2135 float zoomstate_set;
2136 void SetZoomState(float z)
2137 {
2138         if(z != self.zoomstate)
2139         {
2140                 self.zoomstate = z;
2141                 ClientData_Touch(self);
2142         }
2143         zoomstate_set = 1;
2144 }
2145
2146 void GetPressedKeys(void) {
2147         MUTATOR_CALLHOOK(GetPressedKeys);
2148         if (self.movement_x > 0) // get if movement keys are pressed
2149         {       // forward key pressed
2150                 self.pressedkeys |= KEY_FORWARD;
2151                 self.pressedkeys &~= KEY_BACKWARD;
2152         }
2153         else if (self.movement_x < 0)
2154         {       // backward key pressed
2155                 self.pressedkeys |= KEY_BACKWARD;
2156                 self.pressedkeys &~= KEY_FORWARD;
2157         }
2158         else
2159         {       // no x input
2160                 self.pressedkeys &~= KEY_FORWARD;
2161                 self.pressedkeys &~= KEY_BACKWARD;
2162         }
2163
2164         if (self.movement_y > 0)
2165         {       // right key pressed
2166                 self.pressedkeys |= KEY_RIGHT;
2167                 self.pressedkeys &~= KEY_LEFT;
2168         }
2169         else if (self.movement_y < 0)
2170         {       // left key pressed
2171                 self.pressedkeys |= KEY_LEFT;
2172                 self.pressedkeys &~= KEY_RIGHT;
2173         }
2174         else
2175         {       // no y input
2176                 self.pressedkeys &~= KEY_RIGHT;
2177                 self.pressedkeys &~= KEY_LEFT;
2178         }
2179
2180         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2181                 self.pressedkeys |= KEY_JUMP;
2182         else
2183                 self.pressedkeys &~= KEY_JUMP;
2184         if (self.BUTTON_CROUCH)
2185                 self.pressedkeys |= KEY_CROUCH;
2186         else
2187                 self.pressedkeys &~= KEY_CROUCH;
2188 }
2189
2190 void update_stats (float number, float hit, float fired) {
2191 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2192 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2193
2194         if(number) {
2195                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2196                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2197         } else {
2198                 self.stat_hit = hit * sv_accuracy_data_share;
2199                 self.stat_fired = fired * sv_accuracy_data_share;
2200         }
2201 }
2202
2203 /*
2204 ======================
2205 spectate mode routines
2206 ======================
2207 */
2208
2209 .float weapon_count;
2210 void SpectateCopy(entity spectatee) {
2211         if(spectatee.weapon_count < WEP_LAST) {
2212                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2213                 spectatee.weapon_count ++;
2214         } else
2215                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2216
2217         other = spectatee;
2218         MUTATOR_CALLHOOK(SpectateCopy);
2219         self.armortype = spectatee.armortype;
2220         self.armorvalue = spectatee.armorvalue;
2221         self.ammo_cells = spectatee.ammo_cells;
2222         self.ammo_shells = spectatee.ammo_shells;
2223         self.ammo_nails = spectatee.ammo_nails;
2224         self.ammo_rockets = spectatee.ammo_rockets;
2225         self.ammo_fuel = spectatee.ammo_fuel;
2226         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2227         self.health = spectatee.health;
2228         self.impulse = 0;
2229         self.items = spectatee.items;
2230         self.metertime = spectatee.metertime;
2231         self.strength_finished = spectatee.strength_finished;
2232         self.invincible_finished = spectatee.invincible_finished;
2233         self.pressedkeys = spectatee.pressedkeys;
2234         self.weapons = spectatee.weapons;
2235         self.switchweapon = spectatee.switchweapon;
2236         self.weapon = spectatee.weapon;
2237         self.punchangle = spectatee.punchangle;
2238         self.view_ofs = spectatee.view_ofs;
2239         self.v_angle = spectatee.v_angle;
2240         self.velocity = spectatee.velocity;
2241         self.dmg_take = spectatee.dmg_take;
2242         self.dmg_save = spectatee.dmg_save;
2243         self.dmg_inflictor = spectatee.dmg_inflictor;
2244         self.angles = spectatee.v_angle;
2245         self.fixangle = TRUE;
2246         setorigin(self, spectatee.origin);
2247         setsize(self, spectatee.mins, spectatee.maxs);
2248         SetZoomState(spectatee.zoomstate);
2249
2250         anticheat_spectatecopy(spectatee);
2251 }
2252
2253 float SpectateUpdate() {
2254         if(!self.enemy)
2255                 return 0;
2256
2257         if (self == self.enemy)
2258                 return 0;
2259
2260         if(self.enemy.classname != "player")
2261                 return 0;
2262
2263         SpectateCopy(self.enemy);
2264
2265         return 1;
2266 }
2267
2268 float SpectateNext() {
2269         other = find(self.enemy, classname, "player");
2270
2271         if (!other)
2272                 other = find(other, classname, "player");
2273
2274         if (other)
2275                 self.enemy = other;
2276
2277         if(self.enemy.classname == "player") {
2278                 msg_entity = self;
2279                 WriteByte(MSG_ONE, SVC_SETVIEW);
2280                 WriteEntity(MSG_ONE, self.enemy);
2281                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2282                 self.movetype = MOVETYPE_NONE;
2283
2284                 self.enemy.weapon_count = 0;
2285
2286                 if(!SpectateUpdate())
2287                         PutObserverInServer();
2288
2289                 return 1;
2290         } else {
2291                 return 0;
2292         }
2293 }
2294
2295 /*
2296 =============
2297 ShowRespawnCountdown()
2298
2299 Update a respawn countdown display.
2300 =============
2301 */
2302 void ShowRespawnCountdown()
2303 {
2304         float number;
2305         if(self.deadflag == DEAD_NO) // just respawned?
2306                 return;
2307         else
2308         {
2309                 number = ceil(self.death_time - time);
2310                 if(number <= 0)
2311                         return;
2312                 if(number <= self.respawn_countdown)
2313                 {
2314                         self.respawn_countdown = number - 1;
2315                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2316                                 AnnounceTo(self, strcat(ftos(number), ""));
2317                 }
2318         }
2319 }
2320
2321 void LeaveSpectatorMode()
2322 {
2323         if(isJoinAllowed()) {
2324                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2325                         self.classname = "player";
2326
2327                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2328                                 JoinBestTeam(self, FALSE, TRUE);
2329
2330                         if(cvar("g_campaign"))
2331                                 campaign_bots_may_start = 1;
2332
2333                         self.stat_count = WEP_LAST;
2334
2335                         PutClientInServer();
2336
2337                         if(self.classname == "player")
2338                                 bprint ("^4", self.netname, "^4 is playing now\n");
2339
2340                         if(!cvar("g_campaign"))
2341                                 centerprint(self,""); // clear MOTD
2342
2343                         return;
2344                 } else {
2345                         if (g_ca && self.caplayer) {
2346                         }       // do nothing
2347                         else
2348                                 stuffcmd(self,"menu_showteamselect\n");
2349                         return;
2350                 }
2351         }
2352         else {
2353                 //player may not join because of g_maxplayers is set
2354                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2355         }
2356 }
2357
2358 /**
2359  * Determines whether the player is allowed to join. This depends on cvar
2360  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2361  * it checks whether the number of currently playing players exceeds g_maxplayers.
2362  * @return bool TRUE if the player is allowed to join, false otherwise
2363  */
2364 float isJoinAllowed() {
2365         if (!cvar("g_maxplayers"))
2366                 return TRUE;
2367
2368         local entity e;
2369         local float currentlyPlaying;
2370         FOR_EACH_REALPLAYER(e) {
2371                 if(e.classname == "player")
2372                         currentlyPlaying += 1;
2373         }
2374         if(currentlyPlaying < cvar("g_maxplayers"))
2375                 return TRUE;
2376
2377         return FALSE;
2378 }
2379
2380 /**
2381  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2382  * g_maxplayers_spectator_blocktime seconds
2383  */
2384 void checkSpectatorBlock() {
2385         if(self.classname == "spectator" || self.classname == "observer") {
2386                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2387                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2388                         dropclient(self);
2389                 }
2390         }
2391 }
2392
2393 float vercmp_recursive(string v1, string v2)
2394 {
2395         float dot1, dot2;
2396         string s1, s2;
2397         float r;
2398
2399         dot1 = strstrofs(v1, ".", 0);
2400         dot2 = strstrofs(v2, ".", 0);
2401         if(dot1 == -1)
2402                 s1 = v1;
2403         else
2404                 s1 = substring(v1, 0, dot1);
2405         if(dot2 == -1)
2406                 s2 = v2;
2407         else
2408                 s2 = substring(v2, 0, dot2);
2409
2410         r = stof(s1) - stof(s2);
2411         if(r != 0)
2412                 return r;
2413
2414         r = strcasecmp(s1, s2);
2415         if(r != 0)
2416                 return r;
2417
2418         if(dot1 == -1)
2419                 if(dot2 == -1)
2420                         return 0;
2421                 else
2422                         return -1;
2423         else
2424                 if(dot2 == -1)
2425                         return 1;
2426                 else
2427                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2428 }
2429
2430 float vercmp(string v1, string v2)
2431 {
2432         if(strcasecmp(v1, v2) == 0) // early out check
2433                 return 0;
2434         return vercmp_recursive(v1, v2);
2435 }
2436
2437 void ObserverThink()
2438 {
2439         if (self.flags & FL_JUMPRELEASED) {
2440                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2441                         self.welcomemessage_time = 0;
2442                         self.flags &~= FL_JUMPRELEASED;
2443                         self.flags |= FL_SPAWNING;
2444                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2445                         self.welcomemessage_time = 0;
2446                         self.flags &~= FL_JUMPRELEASED;
2447                         if(SpectateNext() == 1) {
2448                                 self.classname = "spectator";
2449                         }
2450                 }
2451         } else {
2452                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2453                         self.flags |= FL_JUMPRELEASED;
2454                         if(self.flags & FL_SPAWNING)
2455                         {
2456                                 self.flags &~= FL_SPAWNING;
2457                                 LeaveSpectatorMode();
2458                                 return;
2459                         }
2460                 }
2461         }
2462         PrintWelcomeMessage(self);
2463 }
2464
2465 void SpectatorThink()
2466 {
2467         if (self.flags & FL_JUMPRELEASED) {
2468                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2469                         self.welcomemessage_time = 0;
2470                         self.flags &~= FL_JUMPRELEASED;
2471                         self.flags |= FL_SPAWNING;
2472                 } else if(self.BUTTON_ATCK) {
2473                         self.welcomemessage_time = 0;
2474                         self.flags &~= FL_JUMPRELEASED;
2475                         if(SpectateNext() == 1) {
2476                                 self.classname = "spectator";
2477                         } else {
2478                                 self.classname = "observer";
2479                                 self.stat_count = WEP_LAST;
2480                                 PutClientInServer();
2481                         }
2482                 } else if (self.BUTTON_ATCK2) {
2483                         self.welcomemessage_time = 0;
2484                         self.flags &~= FL_JUMPRELEASED;
2485                         self.classname = "observer";
2486                         self.stat_count = WEP_LAST;
2487                         PutClientInServer();
2488                 } else {
2489                         if(!SpectateUpdate())
2490                                 PutObserverInServer();
2491                 }
2492         } else {
2493                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2494                         self.flags |= FL_JUMPRELEASED;
2495                         if(self.flags & FL_SPAWNING)
2496                         {
2497                                 self.flags &~= FL_SPAWNING;
2498                                 LeaveSpectatorMode();
2499                                 return;
2500                         }
2501                 }
2502         }
2503
2504         PrintWelcomeMessage(self);
2505         self.flags |= FL_CLIENT | FL_NOTARGET;
2506 }
2507
2508 .float touchexplode_time;
2509
2510 /*
2511 =============
2512 PlayerPreThink
2513
2514 Called every frame for each client before the physics are run
2515 =============
2516 */
2517 void() ctf_setstatus;
2518 void() nexball_setstatus;
2519 .float items_added;
2520 void PlayerPreThink (void)
2521 {
2522         self.stat_game_starttime = game_starttime;
2523         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2524         self.stat_leadlimit = cvar("leadlimit");
2525
2526         if(frametime)
2527         {
2528                 // physics frames: update anticheat stuff
2529                 anticheat_prethink();
2530         }
2531
2532         if(blockSpectators && frametime)
2533                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2534                 checkSpectatorBlock();
2535
2536         zoomstate_set = 0;
2537
2538         if(self.netname_previous != self.netname)
2539         {
2540                 if(cvar("sv_eventlog"))
2541                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2542                 if(self.netname_previous)
2543                         strunzone(self.netname_previous);
2544                 self.netname_previous = strzone(self.netname);
2545         }
2546
2547         // version nagging
2548         if(self.version_nagtime)
2549                 if(self.cvar_g_xonoticversion)
2550                         if(time > self.version_nagtime)
2551                         {
2552                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2553                                 {
2554                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2555                                         {
2556                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2557                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2558                                         }
2559                                         else
2560                                         {
2561                                                 float r;
2562                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2563                                                 if(r < 0)
2564                                                 {
2565                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2566                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2567                                                 }
2568                                                 else if(r > 0)
2569                                                 {
2570                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2571                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2572                                                 }
2573                                         }
2574                                 }
2575                                 self.version_nagtime = 0;
2576                         }
2577
2578         // GOD MODE info
2579         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2580         {
2581                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2582                 self.max_armorvalue = 0;
2583         }
2584
2585 #ifdef TETRIS
2586         if (TetrisPreFrame())
2587                 return;
2588 #endif
2589
2590         MUTATOR_CALLHOOK(PlayerPreThink);
2591
2592         if(self.classname == "player") {
2593 //              if(self.netname == "Wazat")
2594 //                      bprint(self.classname, "\n");
2595
2596                 CheckRules_Player();
2597
2598                 PrintWelcomeMessage(self);
2599
2600                 if (intermission_running)
2601                 {
2602                         IntermissionThink ();   // otherwise a button could be missed between
2603                         return;                                 // the think tics
2604                 }
2605
2606                 if(self.teleport_time)
2607                 if(time > self.teleport_time)
2608                 {
2609                         self.teleport_time = 0;
2610                         self.effects = self.effects - (self.effects & EF_NODRAW);
2611                 }
2612
2613                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2614                         UpdateSelectedPlayer();
2615
2616                 //don't allow the player to turn around while game is paused!
2617                 if(timeoutStatus == 2) {
2618                         self.v_angle = self.lastV_angle;
2619                         self.angles = self.lastV_angle;
2620                         self.fixangle = TRUE;
2621                 }
2622
2623                 if(frametime)
2624                 {
2625                         if(self.health <= 0 && cvar("g_deathglow"))
2626                         {
2627                                 if(self.glowmod_x > 0)
2628                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2629                                 else
2630                                         self.glowmod_x = -1;
2631                                 if(self.glowmod_y > 0)
2632                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2633                                 else
2634                                         self.glowmod_y = -1;
2635                                 if(self.glowmod_z > 0)
2636                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2637                                 else
2638                                         self.glowmod_z = -1;
2639                         }
2640                         else
2641                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2642                         player_powerups();
2643                 }
2644
2645                 if (self.deadflag != DEAD_NO)
2646                 {
2647                         float button_pressed, force_respawn;
2648                         if(self.personal && g_race_qualifying)
2649                         {
2650                                 if(time > self.death_time)
2651                                 {
2652                                         self.death_time = time + 1; // only retry once a second
2653                                         respawn();
2654                                         self.impulse = 141;
2655                                 }
2656                         }
2657                         else
2658                         {
2659                                 if(frametime)
2660                                         player_anim();
2661                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2662                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2663                                 if (self.deadflag == DEAD_DYING)
2664                                 {
2665                                         if(force_respawn)
2666                                                 self.deadflag = DEAD_RESPAWNING;
2667                                         else if(!button_pressed)
2668                                                 self.deadflag = DEAD_DEAD;
2669                                 }
2670                                 else if (self.deadflag == DEAD_DEAD)
2671                                 {
2672                                         if(button_pressed)
2673                                                 self.deadflag = DEAD_RESPAWNABLE;
2674                                 }
2675                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2676                                 {
2677                                         if(!button_pressed)
2678                                                 self.deadflag = DEAD_RESPAWNING;
2679                                 }
2680                                 else if (self.deadflag == DEAD_RESPAWNING)
2681                                 {
2682                                         if(time > self.death_time)
2683                                         {
2684                                                 self.death_time = time + 1; // only retry once a second
2685                                                 respawn();
2686                                         }
2687                                 }
2688                                 ShowRespawnCountdown();
2689                         }
2690                         return;
2691                 }
2692
2693                 if(g_touchexplode)
2694                 if(time > self.touchexplode_time)
2695                 if(self.classname == "player")
2696                 if(self.deadflag == DEAD_NO)
2697                 if not(IS_INDEPENDENT_PLAYER(self))
2698                 FOR_EACH_PLAYER(other) if(self != other)
2699                 {
2700                         if(time > other.touchexplode_time)
2701                         if(other.deadflag == DEAD_NO)
2702                         if not(IS_INDEPENDENT_PLAYER(other))
2703                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2704                         {
2705                                 PlayerTouchExplode(self, other);
2706                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2707                         }
2708                 }
2709
2710                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2711                 {
2712                         vector dist;
2713
2714                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2715                         dist = self.prevorigin - self.origin;
2716                         dist_z = 0;
2717                         self.lms_traveled_distance += fabs(vlen(dist));
2718
2719                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2720                         {
2721                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2722                                 self.lms_traveled_distance = 0;
2723                         }
2724
2725                         if(time > self.lms_nextcheck)
2726                         {
2727                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2728                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2729                                 {
2730                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2731                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2732                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2733                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2734                                 }
2735                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2736                                 self.lms_traveled_distance = 0;
2737                         }
2738                 }
2739
2740                 self.prevorigin = self.origin;
2741
2742                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2743                 {
2744                         if (!self.crouch)
2745                         {
2746                                 self.crouch = TRUE;
2747                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2748                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2749                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2750                         }
2751                 }
2752                 else
2753                 {
2754                         if (self.crouch)
2755                         {
2756                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2757                                 if (!trace_startsolid)
2758                                 {
2759                                         self.crouch = FALSE;
2760                                         self.view_ofs = PL_VIEW_OFS;
2761                                         setsize (self, PL_MIN, PL_MAX);
2762                                 }
2763                         }
2764                 }
2765
2766                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2767                 {
2768                         if(self.bloodloss_timer < time)
2769                         {
2770                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2771                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2772                         }
2773                 }
2774
2775                 FixPlayermodel();
2776
2777                 GrapplingHookFrame();
2778
2779                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2780                 //if(frametime)
2781                 {
2782                         self.items &~= self.items_added;
2783
2784                         W_WeaponFrame();
2785
2786                         self.items_added = 0;
2787                         if(self.items & IT_JETPACK)
2788                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2789                                         self.items_added |= IT_FUEL;
2790
2791                         self.items |= self.items_added;
2792                 }
2793
2794                 player_regen();
2795                 if(frametime)
2796                         player_anim();
2797
2798                 if (g_minstagib)
2799                         minstagib_ammocheck();
2800
2801                 ctf_setstatus();
2802                 nexball_setstatus();
2803
2804                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2805
2806                 //self.angles_y=self.v_angle_y + 90;   // temp
2807         } else if(gameover) {
2808                 if (intermission_running)
2809                         IntermissionThink ();   // otherwise a button could be missed between
2810                 return;
2811         } else if(self.classname == "observer") {
2812                 ObserverThink();
2813         } else if(self.classname == "spectator") {
2814                 SpectatorThink();
2815         }
2816
2817         if(!zoomstate_set)
2818                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2819
2820         float oldspectatee_status;
2821         oldspectatee_status = self.spectatee_status;
2822         if(self.classname == "spectator")
2823                 self.spectatee_status = num_for_edict(self.enemy);
2824         else if(self.classname == "observer")
2825                 self.spectatee_status = num_for_edict(self);
2826         else
2827                 self.spectatee_status = 0;
2828         if(self.spectatee_status != oldspectatee_status)
2829         {
2830                 ClientData_Touch(self);
2831                 if(g_race || g_cts)
2832                         race_InitSpectator();
2833         }
2834
2835         if(self.teamkill_soundtime)
2836         if(time > self.teamkill_soundtime)
2837         {
2838                 self.teamkill_soundtime = 0;
2839
2840                 entity oldpusher, oldself;
2841
2842                 oldself = self; self = self.teamkill_soundsource;
2843                 oldpusher = self.pusher; self.pusher = oldself;
2844
2845                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2846
2847                 self.pusher = oldpusher;
2848                 self = oldself;
2849         }
2850
2851         if(self.taunt_soundtime)
2852         if(time > self.taunt_soundtime)
2853         {
2854                 self.taunt_soundtime = 0;
2855                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2856         }
2857
2858         target_voicescript_next(self);
2859 }
2860
2861 float isInvisibleString(string s)
2862 {
2863         float i, n, c;
2864         s = strdecolorize(s);
2865         for((i = 0), (n = strlen(s)); i < n; ++i)
2866         {
2867                 c = str2chr(s, i);
2868                 switch(c)
2869                 {
2870                         case 0:
2871                         case 32: // space
2872                                 break;
2873                         case 192: // charmap space
2874                                 if (!cvar("utf8_enable"))
2875                                         break;
2876                                 return FALSE;
2877                         case 160: // space in unicode fonts
2878                         case 0xE000 + 192: // utf8 charmap space
2879                                 if (cvar("utf8_enable"))
2880                                         break;
2881                         default:
2882                                 return FALSE;
2883                 }
2884         }
2885         return TRUE;
2886 }
2887
2888 /*
2889 =============
2890 PlayerPostThink
2891
2892 Called every frame for each client after the physics are run
2893 =============
2894 */
2895 .float idlekick_lasttimeleft;
2896 .entity showheadshotbbox;
2897 void showheadshotbbox_think()
2898 {
2899         if(self.owner.showheadshotbbox != self)
2900         {
2901                 remove(self);
2902                 return;
2903         }
2904         self.nextthink = time;
2905         setorigin(self, self.owner.origin);
2906         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2907 }
2908 void PlayerPostThink (void)
2909 {
2910         // Savage: Check for nameless players
2911         if (isInvisibleString(self.netname)) {
2912                 self.netname = "Player";
2913                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2914         }
2915
2916         // send the clients accuracy stats to the client
2917         if(self.stat_count > 0)
2918         if(frametime)
2919         {
2920                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2921                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2922                 self.stat_count -= 1;
2923         }
2924
2925 #ifdef UID
2926         if(self.uid_kicktime)
2927         if(time > self.uid_kicktime)
2928         {
2929                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2930                 dropclient(self);
2931                 return;
2932         }
2933 #endif
2934
2935         if(sv_maxidle && frametime)
2936         {
2937                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2938                 float timeleft;
2939                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2940                 if(timeleft <= 0)
2941                 {
2942                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2943                         AnnounceTo(self, "terminated");
2944                         dropclient(self);
2945                         return;
2946                 }
2947                 else if(timeleft <= 10)
2948                 {
2949                         if(timeleft != self.idlekick_lasttimeleft)
2950                         {
2951                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2952                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2953                         }
2954                 }
2955                 else
2956                 {
2957                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2958                 }
2959                 self.idlekick_lasttimeleft = timeleft;
2960         }
2961
2962 #ifdef TETRIS
2963         if(self.impulse == 100)
2964                 ImpulseCommands();
2965         if (TetrisPostFrame())
2966                 return;
2967 #endif
2968
2969         CheatFrame();
2970
2971         if(self.classname == "player") {
2972                 CheckRules_Player();
2973                 UpdateChatBubble();
2974                 UpdateTeamBubble();
2975                 if (self.impulse)
2976                         ImpulseCommands();
2977                 if (intermission_running)
2978                         return;         // intermission or finale
2979                 GetPressedKeys();
2980         } else if (self.classname == "observer") {
2981                 //do nothing
2982         } else if (self.classname == "spectator") {
2983                 //do nothing
2984         }
2985
2986         /*
2987         float i;
2988         for(i = 0; i < 1000; ++i)
2989         {
2990                 vector end;
2991                 end = self.origin + '0 0 1024' + 512 * randomvec();
2992                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2993                 if(trace_fraction < 1)
2994                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2995                 {
2996                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2997                         break;
2998                 }
2999         }
3000         */
3001
3002         Arena_Warmup();
3003
3004         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3005
3006         if(self.waypointsprite_attachedforcarrier)
3007                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3008
3009         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3010         {
3011                 if(!self.showheadshotbbox)
3012                 {
3013                         self.showheadshotbbox = spawn();
3014                         self.showheadshotbbox.classname = "headshotbbox";
3015                         self.showheadshotbbox.owner = self;
3016                         self.showheadshotbbox.think = showheadshotbbox_think;
3017                         self.showheadshotbbox.nextthink = time;
3018                         self = self.showheadshotbbox;
3019                         self.think();
3020                         self = self.owner;
3021                 }
3022         }
3023         else
3024         {
3025                 if(self.showheadshotbbox)
3026                         remove(self.showheadshotbbox);
3027         }
3028
3029         playerdemo_write();
3030
3031         /*
3032         if(g_race)
3033                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3034         */
3035 }