Merge remote branch 'remotes/origin/terencehill/newpanelhud-dom_points' into terenceh...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void Announce(string snd) {
10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
12         WriteString(MSG_ALL, snd);
13 }
14
15 void AnnounceTo(entity e, string snd) {
16         if (clienttype(e) == CLIENTTYPE_REAL)
17         {
18                 msg_entity = e;
19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
21                 WriteString(MSG_ONE, snd);
22         }
23 }
24
25 float ClientData_Send(entity to, float sf)
26 {
27         if(to != self.owner)
28         {
29                 error("wtf");
30                 return FALSE;
31         }
32
33         entity e;
34
35         e = to;
36         if(to.classname == "spectator")
37                 e = to.enemy;
38
39         sf = 0;
40
41         if(e.race_completed)
42                 sf |= 1; // forced scoreboard
43         if(to.spectatee_status)
44                 sf |= 2; // spectator ent number follows
45         if(e.zoomstate)
46                 sf |= 4; // zoomed
47         if(e.porto_v_angle_held)
48                 sf |= 8; // angles held
49
50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
51         WriteByte(MSG_ENTITY, sf);
52
53         if(sf & 2)
54                 WriteByte(MSG_ENTITY, to.spectatee_status);
55
56         if(sf & 8)
57         {
58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
60         }
61
62         return TRUE;
63 }
64
65 void ClientData_Attach()
66 {
67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
68         self.clientdata.drawonlytoclient = self;
69         self.clientdata.owner = self;
70 }
71
72 void ClientData_Detach()
73 {
74         remove(self.clientdata);
75         self.clientdata = world;
76 }
77
78 void ClientData_Touch(entity e)
79 {
80         e.clientdata.SendFlags = 1;
81
82         // make it spectatable
83         entity e2;
84         FOR_EACH_REALCLIENT(e2)
85         {
86                 if(e2 != e)
87                         if(e2.classname == "spectator")
88                                 if(e2.enemy == e)
89                                         e2.clientdata.SendFlags = 1;
90         }
91 }
92
93
94 .vector spawnpoint_score;
95 .string netname_previous;
96
97 void spawnfunc_info_player_survivor (void)
98 {
99         spawnfunc_info_player_deathmatch();
100 }
101
102 void spawnfunc_info_player_start (void)
103 {
104         spawnfunc_info_player_deathmatch();
105 }
106
107 void spawnfunc_info_player_deathmatch (void)
108 {
109         self.classname = "info_player_deathmatch";
110         relocate_spawnpoint();
111 }
112
113 void spawnpoint_use()
114 {
115         if(teams_matter)
116         if(have_team_spawns > 0)
117         {
118                 self.team = activator.team;
119                 some_spawn_has_been_used = 1;
120         }
121 };
122
123 // Returns:
124 //   _x: prio (-1 if unusable)
125 //   _y: weight
126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
127 {
128         float shortest, thisdist;
129         float prio;
130         entity player;
131
132         prio = 0;
133
134         // filter out spots for the wrong team
135         if(teamcheck)
136         if(spot.team != teamcheck)
137                 return '-1 0 0';
138
139         if(race_spawns)
140                 if(spot.target == "")
141                         return '-1 0 0';
142
143         if(clienttype(self) == CLIENTTYPE_REAL)
144         {
145                 if(spot.restriction == 1)
146                         return '-1 0 0';
147         }
148         else
149         {
150                 if(spot.restriction == 2)
151                         return '-1 0 0';
152         }
153
154         // filter out spots for assault
155         if(spot.target != "") {
156                 local entity ent;
157                 float good, found;
158                 ent = find(world, targetname, spot.target);
159
160                 while(ent) {
161                         if(ent.classname == "target_objective")
162                         {
163                                 found = 1;
164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
165                                         return '-1 0 0';
166                                 good = 1;
167                         }
168                         else if(ent.classname == "trigger_race_checkpoint")
169                         {
170                                 found = 1;
171                                 if(!anypoint) // spectators may spawn everywhere
172
173                                 {
174                                         if(g_race_qualifying)
175                                         {
176                                                 // spawn at first
177                                                 if(ent.race_checkpoint != 0)
178                                                         return '-1 0 0';
179                                                 if(spot.race_place != race_lowest_place_spawn)
180                                                         return '-1 0 0';
181                                         }
182                                         else
183                                         {
184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
185                                                         return '-1 0 0';
186                                                 // try reusing the previous spawn
187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
188                                                         prio += 1;
189                                                 if(ent.race_checkpoint == 0)
190                                                 {
191                                                         float pl;
192                                                         pl = self.race_place;
193                                                         if(pl > race_highest_place_spawn)
194                                                                 pl = 0;
195                                                         if(pl == 0 && !self.race_started)
196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
197                                                         if(spot.race_place != pl)
198                                                                 return '-1 0 0';
199                                                 }
200                                         }
201                                 }
202                                 good = 1;
203                         }
204                         ent = find(ent, targetname, spot.target);
205                 }
206
207                 if(found && !good)
208                         return '-1 0 0';
209         }
210
211         player = playerlist;
212         shortest = vlen(world.maxs - world.mins);
213         for(player = playerlist; player; player = player.chain)
214                 if (player != self)
215                 {
216                         thisdist = vlen(player.origin - spot.origin);
217                         if (thisdist < shortest)
218                                 shortest = thisdist;
219                 }
220         return prio * '1 0 0' + shortest * '0 1 0';
221 }
222
223 float spawn_allbad;
224 float spawn_allgood;
225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
226 {
227         local entity spot, spotlist, spotlistend;
228         spawn_allgood = TRUE;
229         spawn_allbad = TRUE;
230
231         spotlist = world;
232         spotlistend = world;
233
234         for(spot = firstspot; spot; spot = spot.chain)
235         {
236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
237
238                 if(cvar("spawn_debugview"))
239                 {
240                         setmodel(spot, "models/runematch/rune.mdl");
241                         if(spot.spawnpoint_score_y < mindist)
242                         {
243                                 spot.colormod = '1 0 0';
244                                 spot.scale = 1;
245                         }
246                         else
247                         {
248                                 spot.colormod = '0 1 0';
249                                 spot.scale = spot.spawnpoint_score_y / mindist;
250                         }
251                 }
252
253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
254                 {
255                         if(spot.spawnpoint_score_y < mindist)
256                         {
257                                 // too short distance
258                                 spawn_allgood = FALSE;
259                         }
260                         else
261                         {
262                                 // perfect
263                                 spawn_allbad = FALSE;
264
265                                 if(spotlistend)
266                                         spotlistend.chain = spot;
267                                 spotlistend = spot;
268                                 if(!spotlist)
269                                         spotlist = spot;
270
271                                 /*
272                                 if(teamcheck)
273                                 if(spot.team != teamcheck)
274                                         error("invalid spawn added");
275
276                                 print("added ", etos(spot), "\n");
277                                 */
278                         }
279                 }
280         }
281         if(spotlistend)
282                 spotlistend.chain = world;
283
284         /*
285                 entity e;
286                 if(teamcheck)
287                         for(e = spotlist; e; e = e.chain)
288                         {
289                                 print("seen ", etos(e), "\n");
290                                 if(e.team != teamcheck)
291                                         error("invalid spawn found");
292                         }
293         */
294
295         return spotlist;
296 }
297
298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
299 {
300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
302         local entity spot;
303
304         RandomSelection_Init();
305         for(spot = firstspot; spot; spot = spot.chain)
306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
307
308         return RandomSelection_chosen_ent;
309 }
310
311 /*
312 =============
313 SelectSpawnPoint
314
315 Finds a point to respawn
316 =============
317 */
318 entity SelectSpawnPoint (float anypoint)
319 {
320         local float teamcheck;
321         local entity firstspot_new;
322         local entity spot, firstspot, playerlist;
323
324         spot = find (world, classname, "testplayerstart");
325         if (spot)
326                 return spot;
327
328         teamcheck = 0;
329
330         if(!anypoint && have_team_spawns > 0)
331                 teamcheck = self.team;
332
333         // get the list of players
334         playerlist = findchain(classname, "player");
335         // get the entire list of spots
336         firstspot = findchain(classname, "info_player_deathmatch");
337         // filter out the bad ones
338         // (note this returns the original list if none survived)
339         if(anypoint)
340         {
341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
342         }
343         else
344         {
345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
346                 if(!firstspot_new)
347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
348                 firstspot = firstspot_new;
349
350                 // there is 50/50 chance of choosing a random spot or the furthest spot
351                 // (this means that roughly every other spawn will be furthest, so you
352                 // usually won't get fragged at spawn twice in a row)
353                 if (arena_roundbased && !g_ca)
354                 {
355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
356                         if(firstspot_new)
357                                 firstspot = firstspot_new;
358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
359                 }
360                 else if (random() > cvar("g_spawn_furthest"))
361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
362                 else
363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
364         }
365
366         if(cvar("spawn_debugview"))
367         {
368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
369
370                 entity e;
371                 if(teamcheck)
372                         for(e = firstspot; e; e = e.chain)
373                                 if(e.team != teamcheck)
374                                         error("invalid spawn found");
375         }
376
377         if (!spot)
378         {
379                 if(cvar("spawn_debug"))
380                         GotoNextMap();
381                 else
382                 {
383                         if(some_spawn_has_been_used)
384                                 return world; // team can't spawn any more, because of actions of other team
385                         else
386                                 error("Cannot find a spawn point - please fix the map!");
387                 }
388         }
389
390         return spot;
391 }
392
393 /*
394 =============
395 CheckPlayerModel
396
397 Checks if the argument string can be a valid playermodel.
398 Returns a valid one in doubt.
399 =============
400 */
401 string FallbackPlayerModel;
402 string CheckPlayerModel(string plyermodel) {
403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
404         {
405                 // note: we cannot summon Don Strunzone here, some player may
406                 // still have the model string set. In case anyone manages how
407                 // to change a cvar default, we'll have a small leak here.
408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
409         }
410         if(strlen(plyermodel) < 4)
411                 return FallbackPlayerModel;
412         if( substring(plyermodel,0,14) != "models/player/")
413                 return FallbackPlayerModel;
414         else if(cvar("sv_servermodelsonly"))
415         {
416                 if(substring(plyermodel,-4,4) != ".zym")
417                 if(substring(plyermodel,-4,4) != ".dpm")
418                 if(substring(plyermodel,-4,4) != ".iqm")
419                 if(substring(plyermodel,-4,4) != ".md3")
420                 if(substring(plyermodel,-4,4) != ".psk")
421                         return FallbackPlayerModel;
422                 // forbid the LOD models
423                 if(substring(plyermodel, -9,5) == "_lod1")
424                         return FallbackPlayerModel;
425                 if(substring(plyermodel, -9,5) == "_lod2")
426                         return FallbackPlayerModel;
427                 if(plyermodel != strtolower(plyermodel))
428                         return FallbackPlayerModel;
429                 if(!fexists(plyermodel))
430                         return FallbackPlayerModel;
431         }
432         return plyermodel;
433 }
434
435 /*
436 =============
437 Client_customizeentityforclient
438
439 LOD reduction
440 =============
441 */
442 void Client_uncustomizeentityforclient()
443 {
444         if(self.modelindex == 0) // no need to uncustomize then
445                 return;
446         self.modelindex = self.modelindex_lod0;
447         self.skin = self.skinindex;
448 }
449
450 float Client_customizeentityforclient()
451 {
452         entity modelsource;
453
454         if(self.modelindex == 0)
455                 return TRUE;
456
457         // forcemodel stuff
458
459 #ifdef PROFILING
460         float t0;
461         t0 = gettime(GETTIME_HIRES); // reference
462 #endif
463
464         modelsource = self;
465
466 #ifdef ALLOW_FORCEMODELS
467         if(other.cvar_cl_forceplayermodelsfromxonotic)
468                 if not(self.modelindex_lod0_from_xonotic)
469                         modelsource = other;
470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
471                 modelsource = other;
472 #endif
473
474         self.skin = modelsource.skinindex;
475
476 #if 0
477         if(modelsource == self)
478                 self.skin = modelsource.skinindex;
479         else
480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
481 #endif
482
483         // self: me
484         // other: the player viewing me
485         float distance;
486         float f;
487
488         if(other.cvar_cl_playerdetailreduction <= 0)
489         {
490                 if(other.cvar_cl_playerdetailreduction <= -2)
491                         self.modelindex = modelsource.modelindex_lod2;
492                 else if(other.cvar_cl_playerdetailreduction <= -1)
493                         self.modelindex = modelsource.modelindex_lod1;
494                 else
495                         self.modelindex = modelsource.modelindex_lod0;
496         }
497         else
498         {
499                 distance = vlen(self.origin - other.origin);
500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
501                 if(f > sv_loddistance2)
502                         self.modelindex = modelsource.modelindex_lod2;
503                 else if(f > sv_loddistance1)
504                         self.modelindex = modelsource.modelindex_lod1;
505                 else
506                         self.modelindex = modelsource.modelindex_lod0;
507         }
508
509 #ifdef PROFILING
510         float t1;
511         t1 = gettime(GETTIME_HIRES); // reference
512         client_cefc_accumulator += (t1 - t0);
513 #endif
514
515         return TRUE;
516 }
517
518 void setmodel_lod(entity e, string modelname)
519 {
520         string s;
521
522         if(sv_loddistance1)
523         {
524                 // FIXME: this only supports 3-letter extensions
525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
526                 if(fexists(s))
527                 {
528                         setmodel(e, s); // players have high precision
529                         self.modelindex_lod1 = self.modelindex;
530                 }
531                 else
532                         self.modelindex_lod1 = -1;
533
534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
535                 if(fexists(s))
536                 {
537                         setmodel(e, s); // players have high precision
538                         self.modelindex_lod2 = self.modelindex;
539                 }
540                 else
541                         self.modelindex_lod2 = -1;
542
543                 precache_model(modelname);
544                 setmodel(e, modelname); // players have high precision
545                 self.modelindex_lod0 = self.modelindex;
546
547                 if(self.modelindex_lod1 < 0)
548                         self.modelindex_lod1 = self.modelindex;
549
550                 if(self.modelindex_lod2 < 0)
551                         self.modelindex_lod2 = self.modelindex;
552         }
553         else
554         {
555                 precache_model(modelname);
556                 setmodel(e, modelname); // players have high precision
557                 self.modelindex_lod0 = self.modelindex;
558                         // save it for possible player model forcing
559         }
560
561         s = whichpack(self.model);
562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
563
564         player_setupanimsformodel();
565         UpdatePlayerSounds();
566 }
567
568 /*
569 =============
570 PutObserverInServer
571
572 putting a client as observer in the server
573 =============
574 */
575 void FixPlayermodel();
576 void PutObserverInServer (void)
577 {
578         entity  spot;
579
580         race_PreSpawnObserver();
581
582         spot = SelectSpawnPoint (TRUE);
583         if(!spot)
584                 error("No spawnpoints for observers?!?\n");
585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
586
587         if(clienttype(self) == CLIENTTYPE_REAL)
588         {
589                 msg_entity = self;
590                 WriteByte(MSG_ONE, SVC_SETVIEW);
591                 WriteEntity(MSG_ONE, self);
592         }
593
594         DropAllRunes(self);
595
596         Portal_ClearAll(self);
597
598         if(self.flagcarried)
599                 DropFlag(self.flagcarried, world, world);
600
601         if(self.ballcarried)
602                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
603
604         WaypointSprite_PlayerDead();
605
606         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
607                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
608
609         if(self.killcount != -666) {
610                 if(g_lms) {
611                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
612                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
613                         else
614                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
615                 } else
616                         bprint ("^4", self.netname, "^4 is spectating now\n");
617
618                 if(self.just_joined == FALSE) {
619                         LogTeamchange(self.playerid, -1, 4);
620                 } else
621                         self.just_joined = FALSE;
622         }
623
624         PlayerScore_Clear(self); // clear scores when needed
625
626         self.spectatortime = time;
627
628         self.classname = "observer";
629         self.iscreature = FALSE;
630         self.health = -666;
631         self.takedamage = DAMAGE_NO;
632         self.solid = SOLID_NOT;
633         self.movetype = MOVETYPE_NOCLIP;
634         self.flags = FL_CLIENT | FL_NOTARGET;
635         self.armorvalue = 666;
636         self.effects = 0;
637         self.armorvalue = cvar("g_balance_armor_start");
638         self.pauserotarmor_finished = 0;
639         self.pauserothealth_finished = 0;
640         self.pauseregen_finished = 0;
641         self.damageforcescale = 0;
642         self.death_time = 0;
643         self.dead_frame = 0;
644         self.alpha = 0;
645         self.scale = 0;
646         self.fade_time = 0;
647         self.pain_frame = 0;
648         self.pain_finished = 0;
649         self.strength_finished = 0;
650         self.invincible_finished = 0;
651         self.pushltime = 0;
652         self.think = SUB_Null;
653         self.nextthink = 0;
654         self.hook_time = 0;
655         self.runes = 0;
656         self.deadflag = DEAD_NO;
657         self.angles = spot.angles;
658         self.angles_z = 0;
659         self.fixangle = TRUE;
660         self.crouch = FALSE;
661
662         self.view_ofs = PL_VIEW_OFS;
663         setorigin (self, spot.origin);
664         setsize (self, '0 0 0', '0 0 0');
665         self.prevorigin = self.origin;
666         self.items = 0;
667         self.weapons = 0;
668         self.model = "";
669         FixPlayermodel();
670         self.model = "";
671         self.modelindex = 0;
672         self.weapon = 0;
673         self.weaponmodel = "";
674         self.weaponentity = world;
675         self.exteriorweaponentity = world;
676         self.killcount = -666;
677         self.velocity = '0 0 0';
678         self.avelocity = '0 0 0';
679         self.punchangle = '0 0 0';
680         self.punchvector = '0 0 0';
681         self.oldvelocity = self.velocity;
682         self.fire_endtime = -1;
683
684         if(sv_loddistance1)
685                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
686
687         if(g_arena)
688         {
689                 if(self.version_mismatch)
690                 {
691                         Spawnqueue_Unmark(self);
692                         Spawnqueue_Remove(self);
693                 }
694                 else
695                 {
696                         Spawnqueue_Insert(self);
697                 }
698         }
699         else if(g_lms)
700         {
701                 // Only if the player cannot play at all
702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
703                         self.frags = FRAGS_SPECTATOR;
704                 else
705                         self.frags = FRAGS_LMS_LOSER;
706         }
707         else
708                 self.frags = FRAGS_SPECTATOR;
709
710         MUTATOR_CALLHOOK(MakePlayerObserver);
711 }
712
713 float RestrictSkin(float s)
714 {
715         if(!teams_matter)
716                 return s;
717         if(s == 6)
718                 return 6;
719         return mod(s, 3);
720 }
721
722 void FixPlayermodel()
723 {
724         local string defaultmodel;
725         local float defaultskin, chmdl, oldskin;
726         local vector m1, m2;
727
728         defaultmodel = "";
729
730         if(cvar("sv_defaultcharacter") == 1) {
731                 defaultskin = 0;
732
733                 if(teams_matter)
734                 {
735                         string s;
736                         s = Team_ColorNameLowerCase(self.team);
737                         if(s != "neutral")
738                         {
739                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
740                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
741                         }
742                 }
743
744                 if(defaultmodel == "")
745                 {
746                         defaultmodel = cvar_string("sv_defaultplayermodel");
747                         defaultskin = cvar("sv_defaultplayerskin");
748                 }
749         }
750
751         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
752         {
753                 if(self.model != "")
754                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
755                 self.model = ""; // force the != checks to return true
756         }
757
758         if(defaultmodel != "")
759         {
760                 if (defaultmodel != self.model)
761                 {
762                         m1 = self.mins;
763                         m2 = self.maxs;
764                         setmodel_lod (self, defaultmodel);
765                         setsize (self, m1, m2);
766                         chmdl = TRUE;
767                 }
768
769                 oldskin = self.skinindex;
770                 self.skinindex = defaultskin;
771         } else {
772                 if (self.playermodel != self.model || self.playermodel == "")
773                 {
774                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
775                         m1 = self.mins;
776                         m2 = self.maxs;
777                         setmodel_lod (self, self.playermodel);
778                         setsize (self, m1, m2);
779                         chmdl = TRUE;
780                 }
781
782                 oldskin = self.skinindex;
783                 self.skinindex = RestrictSkin(stof(self.playerskin));
784         }
785
786         if(chmdl || oldskin != self.skinindex)
787                 self.species = player_getspecies(); // model or skin has changed
788
789         if(!teams_matter)
790                 if(strlen(cvar_string("sv_defaultplayercolors")))
791                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
792                                 setcolor(self, cvar("sv_defaultplayercolors"));
793 }
794
795 void PlayerTouchExplode(entity p1, entity p2)
796 {
797         vector org;
798         org = (p1.origin + p2.origin) * 0.5;
799         org_z += (p1.mins_z + p2.mins_z) * 0.5;
800
801         te_explosion(org);
802
803         entity e;
804         e = spawn();
805         setorigin(e, org);
806         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
807         remove(e);
808 }
809
810 /*
811 =============
812 PutClientInServer
813
814 Called when a client spawns in the server
815 =============
816 */
817 //void() ctf_playerchanged;
818 void PutClientInServer (void)
819 {
820         if(clienttype(self) == CLIENTTYPE_BOT)
821         {
822                 self.classname = "player";
823         }
824         else if(clienttype(self) == CLIENTTYPE_REAL)
825         {
826                 msg_entity = self;
827                 WriteByte(MSG_ONE, SVC_SETVIEW);
828                 WriteEntity(MSG_ONE, self);
829         }
830
831         // player is dead and becomes observer
832         // FIXME fix LMS scoring for new system
833         if(g_lms)
834         {
835                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
836                         self.classname = "observer";
837         }
838
839         if(g_arena || (g_ca && !allowed_to_spawn))
840         if(!self.spawned)
841                 self.classname = "observer";
842
843         if(gameover)
844                 self.classname = "observer";
845
846         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
847                 entity spot, oldself;
848                 float j;
849
850                 if(self.team < 0)
851                         JoinBestTeam(self, FALSE, TRUE);
852
853                 race_PreSpawn();
854
855                 spot = SelectSpawnPoint (FALSE);
856                 if(!spot)
857                 {
858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
859                         return; // spawn failed
860                 }
861
862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
863
864                 self.classname = "player";
865                 self.wasplayer = TRUE;
866                 self.iscreature = TRUE;
867                 self.movetype = MOVETYPE_WALK;
868                 self.solid = SOLID_SLIDEBOX;
869                 if(cvar("g_playerclip_collisions"))
870                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
871                 else
872                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
873                 self.frags = FRAGS_PLAYER;
874                 if(independent_players)
875                         MAKE_INDEPENDENT_PLAYER(self);
876                 self.flags = FL_CLIENT;
877                 self.takedamage = DAMAGE_AIM;
878                 if(g_minstagib)
879                         self.effects = EF_FULLBRIGHT;
880                 else
881                         self.effects = 0;
882                 self.air_finished = time + 12;
883                 self.dmg = 2;
884
885                 if(inWarmupStage)
886                 {
887                         self.ammo_shells = warmup_start_ammo_shells;
888                         self.ammo_nails = warmup_start_ammo_nails;
889                         self.ammo_rockets = warmup_start_ammo_rockets;
890                         self.ammo_cells = warmup_start_ammo_cells;
891                         self.ammo_fuel = warmup_start_ammo_fuel;
892                         self.health = warmup_start_health;
893                         self.armorvalue = warmup_start_armorvalue;
894                         self.weapons = warmup_start_weapons;
895                 }
896                 else
897                 {
898                         self.ammo_shells = start_ammo_shells;
899                         self.ammo_nails = start_ammo_nails;
900                         self.ammo_rockets = start_ammo_rockets;
901                         self.ammo_cells = start_ammo_cells;
902                         self.ammo_fuel = start_ammo_fuel;
903                         self.health = start_health;
904                         self.armorvalue = start_armorvalue;
905                         self.weapons = start_weapons;
906                 }
907
908                 if(g_weaponarena_random)
909                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
910
911                 self.items = start_items;
912                 self.jump_interval = time;
913
914                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
915                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
916                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
917                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
918                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
919                 //extend the pause of rotting if client was reset at the beginning of the countdown
920                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
921                         self.spawnshieldtime += game_starttime - time;
922                         self.pauserotarmor_finished += game_starttime - time;
923                         self.pauserothealth_finished += game_starttime - time;
924                         self.pauseregen_finished += game_starttime - time;
925                 }
926                 self.damageforcescale = 2;
927                 self.death_time = 0;
928                 self.dead_frame = 0;
929                 self.alpha = 0;
930                 self.scale = 0;
931                 self.fade_time = 0;
932                 self.pain_frame = 0;
933                 self.pain_finished = 0;
934                 self.strength_finished = 0;
935                 self.invincible_finished = 0;
936                 self.pushltime = 0;
937                 // players have no think function
938                 self.think = SUB_Null;
939                 self.nextthink = 0;
940                 self.hook_time = 0;
941                 self.dmg_team = 0;
942                 self.ballistics_density = cvar("g_ballistics_density_player");
943
944                 self.metertime = 0;
945
946                 self.runes = 0;
947
948                 self.deadflag = DEAD_NO;
949
950                 self.angles = spot.angles;
951
952                 self.angles_z = 0; // never spawn tilted even if the spot says to
953                 self.fixangle = TRUE; // turn this way immediately
954                 self.velocity = '0 0 0';
955                 self.avelocity = '0 0 0';
956                 self.punchangle = '0 0 0';
957                 self.punchvector = '0 0 0';
958                 self.oldvelocity = self.velocity;
959                 self.fire_endtime = -1;
960
961                 msg_entity = self;
962                 WRITESPECTATABLE_MSG_ONE({
963                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
964                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
965                 });
966
967                 if(sv_loddistance1)
968                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
969
970                 self.model = "";
971                 FixPlayermodel();
972
973                 self.crouch = FALSE;
974                 self.view_ofs = PL_VIEW_OFS;
975                 setsize (self, PL_MIN, PL_MAX);
976                 self.spawnorigin = spot.origin;
977                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
978                 // don't reset back to last position, even if new position is stuck in solid
979                 self.oldorigin = self.origin;
980                 self.prevorigin = self.origin;
981                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
982
983                 if(g_arena)
984                 {
985                         Spawnqueue_Remove(self);
986                         Spawnqueue_Mark(self);
987                 }
988
989                 else if(g_ca)
990                         self.caplayer = 1;
991
992                 self.event_damage = PlayerDamage;
993
994                 self.bot_attack = TRUE;
995
996                 self.statdraintime = time + 5;
997                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
998
999                 if(self.killcount == -666) {
1000                         PlayerScore_Clear(self);
1001                         self.killcount = 0;
1002                 }
1003
1004                 self.cnt = WEP_LASER;
1005
1006                 CL_SpawnWeaponentity();
1007                 self.alpha = default_player_alpha;
1008                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1009                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1010
1011                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1012                 self.lms_traveled_distance = 0;
1013                 self.speedrunning = FALSE;
1014
1015                 race_PostSpawn(spot);
1016
1017                 if(cvar("spawn_debug"))
1018                 {
1019                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1020                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1021                 }
1022
1023                 //stuffcmd(self, "chase_active 0");
1024                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1025
1026                 if (cvar("g_spawnsound"))
1027                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1028
1029                 if(g_assault) {
1030                         if(self.team == assault_attacker_team)
1031                                 centerprint(self, "You are attacking!");
1032                         else
1033                                 centerprint(self, "You are defending!");
1034                 }
1035
1036                 target_voicescript_clear(self);
1037
1038                 // reset fields the weapons may use
1039                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1040                         weapon_action(j, WR_RESETPLAYER);
1041
1042                 oldself = self;
1043                 self = spot;
1044                         activator = oldself;
1045                                 SUB_UseTargets();
1046                         activator = world;
1047                 self = oldself;
1048
1049                 MUTATOR_CALLHOOK(PlayerSpawn);
1050
1051                 self.switchweapon = w_getbestweapon(self);
1052                 self.cnt = self.switchweapon;
1053                 self.weapon = 0;
1054         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1055                 PutObserverInServer ();
1056         }
1057
1058         //if(g_ctf)
1059         //      ctf_playerchanged();
1060 }
1061
1062 float ClientInit_SendEntity(entity to, float sf)
1063 {
1064         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1065         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1066         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1067         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1068         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1069         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1070         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1071         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1072         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1073         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1074         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1075         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1078         if(sv_foginterval && world.fog != "")
1079                 WriteString(MSG_ENTITY, world.fog);
1080         else
1081                 WriteString(MSG_ENTITY, "");
1082         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1083         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1084         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1085         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1086         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1087         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1088         return TRUE;
1089 }
1090
1091 void ClientInit_CheckUpdate()
1092 {
1093         self.nextthink = time;
1094         if(self.count != cvar("g_balance_armor_blockpercent"))
1095         {
1096                 self.count = cvar("g_balance_armor_blockpercent");
1097                 self.SendFlags |= 1;
1098         }
1099         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1100         {
1101                 self.cnt = cvar("g_balance_weaponswitchdelay");
1102                 self.SendFlags |= 1;
1103         }
1104         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1105         {
1106                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1107                 self.SendFlags |= 1;
1108         }
1109         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1110         {
1111                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1112                 self.SendFlags |= 1;
1113         }
1114 }
1115
1116 void ClientInit_Spawn()
1117 {
1118         entity o;
1119         entity e;
1120         e = spawn();
1121         e.classname = "clientinit";
1122         e.think = ClientInit_CheckUpdate;
1123         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1124
1125         o = self;
1126         self = e;
1127         ClientInit_CheckUpdate();
1128         self = o;
1129 }
1130
1131 /*
1132 =============
1133 SetNewParms
1134 =============
1135 */
1136 void SetNewParms (void)
1137 {
1138         // initialize parms for a new player
1139         parm1 = -(86400 * 366);
1140 }
1141
1142 /*
1143 =============
1144 SetChangeParms
1145 =============
1146 */
1147 void SetChangeParms (void)
1148 {
1149         // save parms for level change
1150         parm1 = self.parm_idlesince - time;
1151 }
1152
1153 /*
1154 =============
1155 DecodeLevelParms
1156 =============
1157 */
1158 void DecodeLevelParms (void)
1159 {
1160         // load parms
1161         self.parm_idlesince = parm1;
1162         if(self.parm_idlesince == -(86400 * 366))
1163                 self.parm_idlesince = time;
1164
1165         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1166         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1167 }
1168
1169 /*
1170 =============
1171 ClientKill
1172
1173 Called when a client types 'kill' in the console
1174 =============
1175 */
1176
1177 void ClientKill_Now_TeamChange()
1178 {
1179         if(self.killindicator_teamchange == -1)
1180         {
1181                 self.team = -1;
1182                 JoinBestTeam( self, FALSE, FALSE );
1183         }
1184         else
1185                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1186 }
1187
1188 void ClientKill_Now()
1189 {
1190         if(self.killindicator_teamchange)
1191                 ClientKill_Now_TeamChange();
1192
1193         // in any case:
1194         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1195
1196         if(self.killindicator)
1197         {
1198                 dprint("Cleaned up after a leaked kill indicator.\n");
1199                 remove(self.killindicator);
1200                 self.killindicator = world;
1201         }
1202 }
1203 void KillIndicator_Think()
1204 {
1205         if (!self.owner.modelindex)
1206         {
1207                 self.owner.killindicator = world;
1208                 remove(self);
1209                 return;
1210         }
1211
1212         if(self.cnt <= 0)
1213         {
1214                 self = self.owner;
1215                 ClientKill_Now(); // no oldself needed
1216                 return;
1217         }
1218         else
1219         {
1220                 if(self.cnt <= 10)
1221                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1222                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1223                 {
1224                         if(self.cnt <= 10)
1225                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1226                         if(self.owner.killindicator_teamchange)
1227                         {
1228                                 if(self.owner.killindicator_teamchange == -1)
1229                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1230                                 else
1231                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1232                         }
1233                         else
1234                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1235                 }
1236                 self.nextthink = time + 1;
1237                 self.cnt -= 1;
1238         }
1239 }
1240
1241 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1242 {
1243         float killtime;
1244         entity e;
1245         killtime = cvar("g_balance_kill_delay");
1246
1247         if(g_race_qualifying)
1248                 killtime = 0;
1249
1250         self.killindicator_teamchange = targetteam;
1251
1252         if(!self.killindicator)
1253         {
1254                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1255                 {
1256                         ClientKill_Now();
1257                 }
1258                 else
1259                 {
1260                         self.killindicator = spawn();
1261                         self.killindicator.owner = self;
1262                         self.killindicator.scale = 0.5;
1263                         setattachment(self.killindicator, self, "");
1264                         setorigin(self.killindicator, '0 0 52');
1265                         self.killindicator.think = KillIndicator_Think;
1266                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1267                         self.killindicator.cnt = ceil(killtime);
1268                         self.killindicator.count = bound(0, ceil(killtime), 10);
1269                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1270
1271                         for(e = world; (e = find(e, classname, "body")) != world; )
1272                         {
1273                                 if(e.enemy != self)
1274                                         continue;
1275                                 e.killindicator = spawn();
1276                                 e.killindicator.owner = e;
1277                                 e.killindicator.scale = 0.5;
1278                                 setattachment(e.killindicator, e, "");
1279                                 setorigin(e.killindicator, '0 0 52');
1280                                 e.killindicator.think = KillIndicator_Think;
1281                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1282                                 e.killindicator.cnt = ceil(killtime);
1283                         }
1284                         self.lip = 0;
1285                 }
1286         }
1287         if(self.killindicator)
1288         {
1289                 if(targetteam)
1290                         self.killindicator.colormod = TeamColor(targetteam);
1291                 else
1292                         self.killindicator.colormod = '0 0 0';
1293         }
1294 }
1295
1296 void ClientKill (void)
1297 {
1298         ClientKill_TeamChange(0);
1299 }
1300
1301 void DoTeamChange(float destteam)
1302 {
1303         float t, c0;
1304         if(!teams_matter)
1305         {
1306                 if(destteam >= 0)
1307                         SetPlayerColors(self, destteam);
1308                 return;
1309         }
1310         if(self.classname == "player")
1311         if(destteam == -1)
1312         {
1313                 CheckAllowedTeams(self);
1314                 t = FindSmallestTeam(self, TRUE);
1315                 switch(self.team)
1316                 {
1317                         case COLOR_TEAM1: c0 = c1; break;
1318                         case COLOR_TEAM2: c0 = c2; break;
1319                         case COLOR_TEAM3: c0 = c3; break;
1320                         case COLOR_TEAM4: c0 = c4; break;
1321                         default:          c0 = 999;
1322                 }
1323                 switch(t)
1324                 {
1325                         case 1:
1326                                 if(c0 > c1)
1327                                         destteam = COLOR_TEAM1;
1328                                 break;
1329                         case 2:
1330                                 if(c0 > c2)
1331                                         destteam = COLOR_TEAM2;
1332                                 break;
1333                         case 3:
1334                                 if(c0 > c3)
1335                                         destteam = COLOR_TEAM3;
1336                                 break;
1337                         case 4:
1338                                 if(c0 > c4)
1339                                         destteam = COLOR_TEAM4;
1340                                 break;
1341                 }
1342                 if(destteam == -1)
1343                         return;
1344         }
1345         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1346                 return;
1347         ClientKill_TeamChange(destteam);
1348 }
1349
1350 void FixClientCvars(entity e)
1351 {
1352         // send prediction settings to the client
1353         stuffcmd(e, "\nin_bindmap 0 0\n");
1354         if(g_race || g_cts)
1355                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1356         if(cvar("g_antilag") == 3) // client side hitscan
1357                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1358                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1359         /*
1360          * we no longer need to stuff this. Remove this comment block if you feel
1361          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1362         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1363         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1364         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1365         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1366         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1367         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1368         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1369         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1370         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1371         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1372         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1373         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1374         stuffcmd(e, "cl_movement_edgefriction 1\n");
1375          */
1376 }
1377
1378 /*
1379 =============
1380 ClientConnect
1381
1382 Called when a client connects to the server
1383 =============
1384 */
1385 //void ctf_clientconnect();
1386 string ColoredTeamName(float t);
1387 void DecodeLevelParms (void);
1388 //void dom_player_join_team(entity pl);
1389 #ifdef UID
1390 .float uid_kicktime;
1391 .string uid;
1392 #endif
1393 void set_dom_state(entity e, float connecting);
1394 void ClientConnect (void)
1395 {
1396         float t;
1397
1398         if(self.flags & FL_CLIENT)
1399         {
1400                 print("Warning: ClientConnect, but already connected!\n");
1401                 return;
1402         }
1403
1404         if(Ban_MaybeEnforceBan(self))
1405                 return;
1406
1407         DecodeLevelParms();
1408
1409 #ifdef WATERMARK
1410         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1411 #endif
1412
1413         self.classname = "player_joining";
1414
1415         self.flags = FL_CLIENT;
1416         self.version_nagtime = time + 10 + random() * 10;
1417
1418         if(player_count<0)
1419         {
1420                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1421                 player_count = 0;
1422         }
1423
1424         PlayerScore_Attach(self);
1425         ClientData_Attach();
1426
1427         bot_clientconnect();
1428
1429         playerdemo_init();
1430
1431         anticheat_init();
1432         
1433         race_PreSpawnObserver();
1434
1435         //if(g_domination)
1436         //      dom_player_join_team(self);
1437
1438         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1439
1440         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1441                 self.classname = "observer";
1442         } else {
1443                 if(teams_matter)
1444                 {
1445                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1446                         {
1447                                 self.classname = "player";
1448                                 campaign_bots_may_start = 1;
1449                         }
1450                         else
1451                         {
1452                                 self.classname = "observer"; // do it anyway
1453                         }
1454                 }
1455                 else
1456                 {
1457                         self.classname = "player";
1458                         campaign_bots_may_start = 1;
1459                 }
1460         }
1461
1462         self.playerid = (playerid_last = playerid_last + 1);
1463
1464         if(cvar("sv_eventlog"))
1465                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1466
1467         LogTeamchange(self.playerid, self.team, 1);
1468
1469         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1470
1471         self.netname_previous = strzone(self.netname);
1472
1473         bprint("^4", self.netname, "^4 connected");
1474
1475         if(self.classname != "observer" && (g_domination || g_ctf))
1476                 bprint(" and joined the ", ColoredTeamName(self.team));
1477
1478         bprint("\n");
1479
1480         self.welcomemessage_time = 0;
1481
1482         stuffcmd(self, strcat(clientstuff, "\n"));
1483         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1484         stuffcmd(self, "cl_particles_reloadeffects\n");
1485
1486         FixClientCvars(self);
1487
1488         // spawnfunc_waypoint sprites
1489         WaypointSprite_InitClient(self);
1490
1491         // Wazat's grappling hook
1492         SetGrappleHookBindings();
1493
1494         // get autoswitch state from player when he toggles it
1495         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1496
1497         // get version info from player
1498         stuffcmd(self, "cmd clientversion $gameversion\n");
1499
1500         // get other cvars from player
1501         GetCvars(0);
1502
1503         // set cvar for team scoreboard
1504         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1505
1506         // notify about available teams
1507         if(teams_matter)
1508         {
1509                 CheckAllowedTeams(self);
1510                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1511                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1512         }
1513         else
1514                 stuffcmd(self, "set _teams_available 0\n");
1515
1516         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1517
1518         if(g_arena || g_ca)
1519         {
1520                 self.classname = "observer";
1521                 if(g_arena)
1522                         Spawnqueue_Insert(self);
1523         }
1524         /*else if(g_ctf)
1525         {
1526                 ctf_clientconnect();
1527         }*/
1528
1529         if(teams_matter || radar_showennemies)
1530                 attach_entcs();
1531
1532         bot_relinkplayerlist();
1533
1534         self.spectatortime = time;
1535         if(blockSpectators)
1536         {
1537                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1538         }
1539
1540         self.jointime = time;
1541         self.allowedTimeouts = cvar("sv_timeout_number");
1542
1543         if(clienttype(self) == CLIENTTYPE_REAL)
1544         {
1545                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1546                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1547         }
1548
1549         if(g_lms)
1550         {
1551                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1552                 {
1553                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1554                         self.frags = FRAGS_SPECTATOR;
1555                 }
1556         }
1557
1558         if(!sv_foginterval && world.fog != "")
1559                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1560
1561         SoundEntity_Attach(self);
1562
1563         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1564         {
1565                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1566                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1567         }
1568         else
1569                 self.hitplotfh = -1;
1570
1571 #ifdef UID
1572         if(clienttype(self) == CLIENTTYPE_REAL)
1573         if not(self.uid)
1574                 self.uid_kicktime = time + 60;
1575 #endif
1576
1577         if(g_race || g_cts) {
1578                 string rr;
1579                 if(g_cts)
1580                         rr = CTS_RECORD;
1581                 else
1582                         rr = RACE_RECORD;
1583                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1584
1585                 race_send_recordtime(MSG_ONE);
1586                 race_send_speedaward(MSG_ONE);
1587
1588                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1589                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1590                 race_send_speedaward_alltimebest(MSG_ONE);
1591
1592                 float i;
1593                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1594                         race_SendRankings(i, 0, 0, MSG_ONE);
1595                 }
1596         }
1597         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1598                 send_CSQC_teamnagger();
1599
1600         if (g_domination)
1601                 set_dom_state(self, TRUE);
1602
1603         CheatInitClient();
1604 }
1605
1606 /*
1607 =============
1608 ClientDisconnect
1609
1610 Called when a client disconnects from the server
1611 =============
1612 */
1613 .entity chatbubbleentity;
1614 .entity teambubbleentity;
1615 void ReadyCount();
1616 void ClientDisconnect (void)
1617 {
1618         if not(self.flags & FL_CLIENT)
1619         {
1620                 print("Warning: ClientDisconnect without ClientConnect\n");
1621                 return;
1622         }
1623
1624         CheatShutdownClient();
1625
1626         if(self.hitplotfh >= 0)
1627         {
1628                 fclose(self.hitplotfh);
1629                 self.hitplotfh = -1;
1630         }
1631
1632         anticheat_report();
1633         anticheat_shutdown();
1634
1635         playerdemo_shutdown();
1636
1637         bot_clientdisconnect();
1638
1639         if(self.entcs)
1640                 detach_entcs();
1641
1642         if(cvar("sv_eventlog"))
1643                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1644         bprint ("^4",self.netname);
1645         bprint ("^4 disconnected\n");
1646
1647         SoundEntity_Detach(self);
1648
1649         DropAllRunes(self);
1650         MUTATOR_CALLHOOK(ClientDisconnect);
1651
1652         Portal_ClearAll(self);
1653
1654         if(self.flagcarried)
1655                 DropFlag(self.flagcarried, world, world);
1656         if(self.ballcarried)
1657                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1658
1659         // Here, everything has been done that requires this player to be a client.
1660
1661         self.flags &~= FL_CLIENT;
1662
1663         if (self.chatbubbleentity)
1664                 remove (self.chatbubbleentity);
1665
1666         if (self.teambubbleentity)
1667                 remove (self.teambubbleentity);
1668
1669         if (self.killindicator)
1670                 remove (self.killindicator);
1671
1672         WaypointSprite_PlayerGone();
1673
1674         bot_relinkplayerlist();
1675
1676         // remove laserdot
1677         if(self.weaponentity)
1678                 if(self.weaponentity.lasertarget)
1679                         remove(self.weaponentity.lasertarget);
1680
1681         if(g_arena)
1682         {
1683                 Spawnqueue_Unmark(self);
1684                 Spawnqueue_Remove(self);
1685         }
1686
1687         ClientData_Detach();
1688         PlayerScore_Detach(self);
1689
1690         if(self.netname_previous)
1691                 strunzone(self.netname_previous);
1692         if(self.clientstatus)
1693                 strunzone(self.clientstatus);
1694
1695         ClearPlayerSounds();
1696
1697         if(self.personal)
1698                 remove(self.personal);
1699
1700         self.playerid = 0;
1701         ReadyCount();
1702
1703         // free cvars
1704         GetCvars(-1);
1705 }
1706
1707 .float BUTTON_CHAT;
1708 void ChatBubbleThink()
1709 {
1710         self.nextthink = time;
1711         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1712         {
1713                 if(self.owner) // but why can that ever be world?
1714                         self.owner.chatbubbleentity = world;
1715                 remove(self);
1716                 return;
1717         }
1718         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1719 #ifdef TETRIS
1720                 || self.owner.tetris_on
1721 #endif
1722         )
1723                 self.model = self.mdl;
1724         else
1725                 self.model = "";
1726 };
1727
1728 void UpdateChatBubble()
1729 {
1730         if (!self.modelindex)
1731                 return;
1732         // spawn a chatbubble entity if needed
1733         if (!self.chatbubbleentity)
1734         {
1735                 self.chatbubbleentity = spawn();
1736                 self.chatbubbleentity.owner = self;
1737                 self.chatbubbleentity.exteriormodeltoclient = self;
1738                 self.chatbubbleentity.think = ChatBubbleThink;
1739                 self.chatbubbleentity.nextthink = time;
1740                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1741                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1742                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1743                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1744                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1745                 self.chatbubbleentity.model = "";
1746                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1747         }
1748 }
1749
1750
1751 void TeamBubbleThink()
1752 {
1753         self.nextthink = time;
1754         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1755         {
1756                 if(self.owner) // but why can that ever be world?
1757                         self.owner.teambubbleentity = world;
1758                 remove(self);
1759                 return;
1760         }
1761 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1762         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1763                 self.model = "";
1764         else
1765                 self.model = self.mdl;
1766
1767 };
1768
1769 float TeamBubble_customizeentityforclient()
1770 {
1771         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1772 }
1773
1774 void UpdateTeamBubble()
1775 {
1776         if (!self.modelindex || !teams_matter)
1777                 return;
1778         // spawn a teambubble entity if needed
1779         if (!self.teambubbleentity && teams_matter)
1780         {
1781                 self.teambubbleentity = spawn();
1782                 self.teambubbleentity.owner = self;
1783                 self.teambubbleentity.exteriormodeltoclient = self;
1784                 self.teambubbleentity.think = TeamBubbleThink;
1785                 self.teambubbleentity.nextthink = time;
1786                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1787 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1788                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1789                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1790                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1791                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1792                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1793                 self.teambubbleentity.effects = EF_LOWPRECISION;
1794         }
1795 }
1796
1797 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1798 // added to the model skins
1799 /*void UpdateColorModHack()
1800 {
1801         local float c;
1802         c = self.clientcolors & 15;
1803         // LordHavoc: only bothering to support white, green, red, yellow, blue
1804              if (!teams_matter) self.colormod = '0 0 0';
1805         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1806         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1807         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1808         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1809         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1810         else self.colormod = '1 1 1';
1811 };*/
1812
1813 .float oldcolormap;
1814 void respawn(void)
1815 {
1816         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1817         {
1818                 self.solid = SOLID_NOT;
1819                 self.takedamage = DAMAGE_NO;
1820                 self.movetype = MOVETYPE_FLY;
1821                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1822                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1823                 self.effects |= EF_ADDITIVE;
1824                 self.oldcolormap = self.colormap;
1825                 self.colormap = 512;
1826                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1827                 if(cvar("g_respawn_ghosts_maxtime"))
1828                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1829         }
1830
1831         CopyBody(1);
1832         self.effects |= EF_NODRAW; // prevent another CopyBody
1833         if(self.oldcolormap)
1834         {
1835                 self.colormap = self.oldcolormap;
1836                 self.oldcolormap = 0;
1837         }
1838         PutClientInServer();
1839 }
1840
1841 void play_countdown(float finished, string samp)
1842 {
1843         if(clienttype(self) == CLIENTTYPE_REAL)
1844                 if(floor(finished - time - frametime) != floor(finished - time))
1845                         if(finished - time < 6)
1846                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1847 }
1848
1849 /**
1850  * When sv_timeout is used this function returs strings like
1851  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1852  * Called by centerprint functions
1853  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1854  */
1855 string getTimeoutText(float addOneSecond) {
1856         if (!cvar("sv_timeout") || !timeoutStatus)
1857                 return "";
1858
1859         local string retStr;
1860         if (timeoutStatus == 1) {
1861                 if (addOneSecond == 1) {
1862                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1863                 }
1864                 else {
1865                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1866                 }
1867                 return retStr;
1868         }
1869         else if (timeoutStatus == 2) {
1870                 if (addOneSecond) {
1871                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1872                         //don't show messages like "Timeout ends in 0 seconds"...
1873                         if ((remainingTimeoutTime + 1) > 0)
1874                                 return retStr;
1875                         else
1876                                 return "";
1877                 }
1878                 else {
1879                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1880                         //don't show messages like "Timeout ends in 0 seconds"...
1881                         if (remainingTimeoutTime > 0)
1882                                 return retStr;
1883                         else
1884                                 return "";
1885                 }
1886         }
1887         else return "";
1888 }
1889
1890 void player_powerups (void)
1891 {
1892         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1893         {
1894                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1895                 self.modelflags |= MF_ROCKET;
1896         }
1897         else
1898         {
1899                 SoundEntity_StopSound(self, CHAN_PLAYER);
1900                 self.modelflags &~= MF_ROCKET;
1901         }
1902
1903         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1904
1905         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1906                 return;
1907         
1908         Fire_ApplyDamage(self);
1909         Fire_ApplyEffect(self);
1910
1911         if (g_minstagib)
1912         {
1913                 self.effects |= EF_FULLBRIGHT;
1914
1915                 if (self.items & IT_STRENGTH)
1916                 {
1917                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1918                         if (time > self.strength_finished)
1919                         {
1920                                 self.alpha = default_player_alpha;
1921                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1922                                 self.items &~= IT_STRENGTH;
1923                                 sprint(self, "^3Invisibility has worn off\n");
1924                         }
1925                 }
1926                 else
1927                 {
1928                         if (time < self.strength_finished)
1929                         {
1930                                 self.alpha = g_minstagib_invis_alpha;
1931                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1932                                 self.items |= IT_STRENGTH;
1933                                 sprint(self, "^3You are invisible\n");
1934                         }
1935                 }
1936
1937                 if (self.items & IT_INVINCIBLE)
1938                 {
1939                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1940                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1941                         {
1942                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1943                                 sprint(self, "^3Speed has worn off\n");
1944                         }
1945                 }
1946                 else
1947                 {
1948                         if (time < self.invincible_finished)
1949                         {
1950                                 self.items = self.items | IT_INVINCIBLE;
1951                                 sprint(self, "^3You are on speed\n");
1952                         }
1953                 }
1954                 return;
1955         }
1956
1957         if (self.items & IT_STRENGTH)
1958         {
1959                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1960                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1961                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1962                 {
1963                         self.items = self.items - (self.items & IT_STRENGTH);
1964                         sprint(self, "^3Strength has worn off\n");
1965                 }
1966         }
1967         else
1968         {
1969                 if (time < self.strength_finished)
1970                 {
1971                         self.items = self.items | IT_STRENGTH;
1972                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1973                 }
1974         }
1975         if (self.items & IT_INVINCIBLE)
1976         {
1977                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1978                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1979                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1980                 {
1981                         self.items = self.items - (self.items & IT_INVINCIBLE);
1982                         sprint(self, "^3Shield has worn off\n");
1983                 }
1984         }
1985         else
1986         {
1987                 if (time < self.invincible_finished)
1988                 {
1989                         self.items = self.items | IT_INVINCIBLE;
1990                         sprint(self, "^3Shield surrounds you\n");
1991                 }
1992         }
1993
1994         if(cvar("g_nodepthtestplayers"))
1995                 self.effects = self.effects | EF_NODEPTHTEST;
1996
1997         if(cvar("g_fullbrightplayers"))
1998                 self.effects = self.effects | EF_FULLBRIGHT;
1999
2000         // midair gamemode: damage only while in the air
2001         // if in midair mode, being on ground grants temporary invulnerability
2002         // (this is so that multishot weapon don't clear the ground flag on the
2003         // first damage in the frame, leaving the player vulnerable to the
2004         // remaining hits in the same frame)
2005         if (self.flags & FL_ONGROUND)
2006         if (g_midair)
2007                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2008
2009         if (time >= game_starttime)
2010         if (time < self.spawnshieldtime)
2011                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2012 }
2013
2014 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2015 {
2016         if(current > stable)
2017                 return current;
2018         else if(current > stable - 0.25) // when close enough, "snap"
2019                 return stable;
2020         else
2021                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2022 }
2023
2024 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2025 {
2026         if(current < stable)
2027                 return current;
2028         else if(current < stable + 0.25) // when close enough, "snap"
2029                 return stable;
2030         else
2031                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2032 }
2033
2034 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2035 {
2036         if(current > rotstable)
2037         {
2038                 if(rotframetime > 0)
2039                 {
2040                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2041                         current = max(rotstable, current - rotlinear * rotframetime);
2042                 }
2043         }
2044         else if(current < regenstable)
2045         {
2046                 if(regenframetime > 0)
2047                 {
2048                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2049                         current = min(regenstable, current + regenlinear * regenframetime);
2050                 }
2051         }
2052
2053         if(current > limit)
2054                 current = limit;
2055
2056         return current;
2057 }
2058
2059 void player_regen (void)
2060 {
2061         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2062         maxh = cvar("g_balance_health_rotstable");
2063         maxa = cvar("g_balance_armor_rotstable");
2064         maxf = cvar("g_balance_fuel_rotstable");
2065         minh = cvar("g_balance_health_regenstable");
2066         mina = cvar("g_balance_armor_regenstable");
2067         minf = cvar("g_balance_fuel_regenstable");
2068         limith = cvar("g_balance_health_limit");
2069         limita = cvar("g_balance_armor_limit");
2070         limitf = cvar("g_balance_fuel_limit");
2071
2072         max_mod = regen_mod = rot_mod = limit_mod = 1;
2073
2074         if (self.runes & RUNE_REGEN)
2075         {
2076                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2077                 {
2078                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2079                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2080                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2081                 }
2082                 else
2083                 {
2084                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2085                         max_mod = cvar("g_balance_rune_regen_hpmod");
2086                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2087                 }
2088         }
2089         else if (self.runes & CURSE_VENOM)
2090         {
2091                 max_mod = cvar("g_balance_curse_venom_hpmod");
2092                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2093                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2094                 else
2095                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2096                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2097                 //if (!self.runes & RUNE_REGEN)
2098                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2099         }
2100         maxh = maxh * max_mod;
2101         //maxa = maxa * max_mod;
2102         //maxf = maxf * max_mod;
2103         minh = minh * max_mod;
2104         //mina = mina * max_mod;
2105         //minf = minf * max_mod;
2106         limith = limith * limit_mod;
2107         limita = limita * limit_mod;
2108         //limitf = limitf * limit_mod;
2109
2110         if(g_lms && g_ca)
2111                 rot_mod = 0;
2112
2113         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2114         {
2115                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2116                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2117
2118                 // if player rotted to death...  die!
2119                 if(self.health < 1)
2120                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2121         }
2122
2123         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2124                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2125 }
2126
2127 float zoomstate_set;
2128 void SetZoomState(float z)
2129 {
2130         if(z != self.zoomstate)
2131         {
2132                 self.zoomstate = z;
2133                 ClientData_Touch(self);
2134         }
2135         zoomstate_set = 1;
2136 }
2137
2138 void GetPressedKeys(void) {
2139         MUTATOR_CALLHOOK(GetPressedKeys);
2140         if (self.movement_x > 0) // get if movement keys are pressed
2141         {       // forward key pressed
2142                 self.pressedkeys |= KEY_FORWARD;
2143                 self.pressedkeys &~= KEY_BACKWARD;
2144         }
2145         else if (self.movement_x < 0)
2146         {       // backward key pressed
2147                 self.pressedkeys |= KEY_BACKWARD;
2148                 self.pressedkeys &~= KEY_FORWARD;
2149         }
2150         else
2151         {       // no x input
2152                 self.pressedkeys &~= KEY_FORWARD;
2153                 self.pressedkeys &~= KEY_BACKWARD;
2154         }
2155
2156         if (self.movement_y > 0)
2157         {       // right key pressed
2158                 self.pressedkeys |= KEY_RIGHT;
2159                 self.pressedkeys &~= KEY_LEFT;
2160         }
2161         else if (self.movement_y < 0)
2162         {       // left key pressed
2163                 self.pressedkeys |= KEY_LEFT;
2164                 self.pressedkeys &~= KEY_RIGHT;
2165         }
2166         else
2167         {       // no y input
2168                 self.pressedkeys &~= KEY_RIGHT;
2169                 self.pressedkeys &~= KEY_LEFT;
2170         }
2171
2172         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2173                 self.pressedkeys |= KEY_JUMP;
2174         else
2175                 self.pressedkeys &~= KEY_JUMP;
2176         if (self.BUTTON_CROUCH)
2177                 self.pressedkeys |= KEY_CROUCH;
2178         else
2179                 self.pressedkeys &~= KEY_CROUCH;
2180 }
2181
2182 void update_stats (float number, float hit, float fired) {
2183 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2184 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2185
2186         if(number) {
2187                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2188                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2189         } else {
2190                 self.stat_hit = hit * sv_accuracy_data_share;
2191                 self.stat_fired = fired * sv_accuracy_data_share;
2192         }
2193 }
2194
2195 /*
2196 ======================
2197 spectate mode routines
2198 ======================
2199 */
2200
2201 .float weapon_count;
2202 void SpectateCopy(entity spectatee) {
2203         if(spectatee.weapon_count < WEP_LAST) {
2204                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2205                 spectatee.weapon_count ++;
2206         } else
2207                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2208
2209         other = spectatee;
2210         MUTATOR_CALLHOOK(SpectateCopy);
2211         self.armortype = spectatee.armortype;
2212         self.armorvalue = spectatee.armorvalue;
2213         self.ammo_cells = spectatee.ammo_cells;
2214         self.ammo_shells = spectatee.ammo_shells;
2215         self.ammo_nails = spectatee.ammo_nails;
2216         self.ammo_rockets = spectatee.ammo_rockets;
2217         self.ammo_fuel = spectatee.ammo_fuel;
2218         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2219         self.health = spectatee.health;
2220         self.impulse = 0;
2221         self.items = spectatee.items;
2222         self.metertime = spectatee.metertime;
2223         self.strength_finished = spectatee.strength_finished;
2224         self.invincible_finished = spectatee.invincible_finished;
2225         self.pressedkeys = spectatee.pressedkeys;
2226         self.weapons = spectatee.weapons;
2227         self.switchweapon = spectatee.switchweapon;
2228         self.weapon = spectatee.weapon;
2229         self.punchangle = spectatee.punchangle;
2230         self.view_ofs = spectatee.view_ofs;
2231         self.v_angle = spectatee.v_angle;
2232         self.velocity = spectatee.velocity;
2233         self.dmg_take = spectatee.dmg_take;
2234         self.dmg_save = spectatee.dmg_save;
2235         self.dmg_inflictor = spectatee.dmg_inflictor;
2236         self.angles = spectatee.v_angle;
2237         self.fixangle = TRUE;
2238         setorigin(self, spectatee.origin);
2239         setsize(self, spectatee.mins, spectatee.maxs);
2240         SetZoomState(spectatee.zoomstate);
2241
2242         anticheat_spectatecopy(spectatee);
2243 }
2244
2245 float SpectateUpdate() {
2246         if(!self.enemy)
2247                 return 0;
2248
2249         if (self == self.enemy)
2250                 return 0;
2251
2252         if(self.enemy.classname != "player")
2253                 return 0;
2254
2255         SpectateCopy(self.enemy);
2256
2257         return 1;
2258 }
2259
2260 float SpectateNext() {
2261         other = find(self.enemy, classname, "player");
2262
2263         if (!other)
2264                 other = find(other, classname, "player");
2265
2266         if (other)
2267                 self.enemy = other;
2268
2269         if(self.enemy.classname == "player") {
2270                 msg_entity = self;
2271                 WriteByte(MSG_ONE, SVC_SETVIEW);
2272                 WriteEntity(MSG_ONE, self.enemy);
2273                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2274                 self.movetype = MOVETYPE_NONE;
2275
2276                 self.enemy.weapon_count = 0;
2277
2278                 if(!SpectateUpdate())
2279                         PutObserverInServer();
2280
2281                 return 1;
2282         } else {
2283                 return 0;
2284         }
2285 }
2286
2287 /*
2288 =============
2289 ShowRespawnCountdown()
2290
2291 Update a respawn countdown display.
2292 =============
2293 */
2294 void ShowRespawnCountdown()
2295 {
2296         float number;
2297         if(self.deadflag == DEAD_NO) // just respawned?
2298                 return;
2299         else
2300         {
2301                 number = ceil(self.death_time - time);
2302                 if(number <= 0)
2303                         return;
2304                 if(number <= self.respawn_countdown)
2305                 {
2306                         self.respawn_countdown = number - 1;
2307                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2308                                 AnnounceTo(self, strcat(ftos(number), ""));
2309                 }
2310         }
2311 }
2312
2313 void LeaveSpectatorMode()
2314 {
2315         if(isJoinAllowed()) {
2316                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2317                         self.classname = "player";
2318
2319                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2320                                 JoinBestTeam(self, FALSE, TRUE);
2321
2322                         if(cvar("g_campaign"))
2323                                 campaign_bots_may_start = 1;
2324
2325                         self.stat_count = WEP_LAST;
2326
2327                         PutClientInServer();
2328
2329                         if(self.classname == "player")
2330                                 bprint ("^4", self.netname, "^4 is playing now\n");
2331
2332                         if(!cvar("g_campaign"))
2333                                 centerprint(self,""); // clear MOTD
2334
2335                         return;
2336                 } else {
2337                         if (g_ca && self.caplayer) {
2338                         }       // do nothing
2339                         else
2340                                 stuffcmd(self,"menu_showteamselect\n");
2341                         return;
2342                 }
2343         }
2344         else {
2345                 //player may not join because of g_maxplayers is set
2346                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2347         }
2348 }
2349
2350 /**
2351  * Determines whether the player is allowed to join. This depends on cvar
2352  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2353  * it checks whether the number of currently playing players exceeds g_maxplayers.
2354  * @return bool TRUE if the player is allowed to join, false otherwise
2355  */
2356 float isJoinAllowed() {
2357         if (!cvar("g_maxplayers"))
2358                 return TRUE;
2359
2360         local entity e;
2361         local float currentlyPlaying;
2362         FOR_EACH_REALPLAYER(e) {
2363                 if(e.classname == "player")
2364                         currentlyPlaying += 1;
2365         }
2366         if(currentlyPlaying < cvar("g_maxplayers"))
2367                 return TRUE;
2368
2369         return FALSE;
2370 }
2371
2372 /**
2373  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2374  * g_maxplayers_spectator_blocktime seconds
2375  */
2376 void checkSpectatorBlock() {
2377         if(self.classname == "spectator" || self.classname == "observer") {
2378                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2379                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2380                         dropclient(self);
2381                 }
2382         }
2383 }
2384
2385 float vercmp_recursive(string v1, string v2)
2386 {
2387         float dot1, dot2;
2388         string s1, s2;
2389         float r;
2390
2391         dot1 = strstrofs(v1, ".", 0);
2392         dot2 = strstrofs(v2, ".", 0);
2393         if(dot1 == -1)
2394                 s1 = v1;
2395         else
2396                 s1 = substring(v1, 0, dot1);
2397         if(dot2 == -1)
2398                 s2 = v2;
2399         else
2400                 s2 = substring(v2, 0, dot2);
2401
2402         r = stof(s1) - stof(s2);
2403         if(r != 0)
2404                 return r;
2405
2406         r = strcasecmp(s1, s2);
2407         if(r != 0)
2408                 return r;
2409
2410         if(dot1 == -1)
2411                 if(dot2 == -1)
2412                         return 0;
2413                 else
2414                         return -1;
2415         else
2416                 if(dot2 == -1)
2417                         return 1;
2418                 else
2419                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2420 }
2421
2422 float vercmp(string v1, string v2)
2423 {
2424         if(strcasecmp(v1, v2) == 0) // early out check
2425                 return 0;
2426         return vercmp_recursive(v1, v2);
2427 }
2428
2429 void ObserverThink()
2430 {
2431         if (self.flags & FL_JUMPRELEASED) {
2432                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2433                         self.welcomemessage_time = 0;
2434                         self.flags &~= FL_JUMPRELEASED;
2435                         self.flags |= FL_SPAWNING;
2436                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2437                         self.welcomemessage_time = 0;
2438                         self.flags &~= FL_JUMPRELEASED;
2439                         if(SpectateNext() == 1) {
2440                                 self.classname = "spectator";
2441                         }
2442                 }
2443         } else {
2444                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2445                         self.flags |= FL_JUMPRELEASED;
2446                         if(self.flags & FL_SPAWNING)
2447                         {
2448                                 self.flags &~= FL_SPAWNING;
2449                                 LeaveSpectatorMode();
2450                                 return;
2451                         }
2452                 }
2453         }
2454         PrintWelcomeMessage(self);
2455 }
2456
2457 void SpectatorThink()
2458 {
2459         if (self.flags & FL_JUMPRELEASED) {
2460                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2461                         self.welcomemessage_time = 0;
2462                         self.flags &~= FL_JUMPRELEASED;
2463                         self.flags |= FL_SPAWNING;
2464                 } else if(self.BUTTON_ATCK) {
2465                         self.welcomemessage_time = 0;
2466                         self.flags &~= FL_JUMPRELEASED;
2467                         if(SpectateNext() == 1) {
2468                                 self.classname = "spectator";
2469                         } else {
2470                                 self.classname = "observer";
2471                                 self.stat_count = WEP_LAST;
2472                                 PutClientInServer();
2473                         }
2474                 } else if (self.BUTTON_ATCK2) {
2475                         self.welcomemessage_time = 0;
2476                         self.flags &~= FL_JUMPRELEASED;
2477                         self.classname = "observer";
2478                         self.stat_count = WEP_LAST;
2479                         PutClientInServer();
2480                 } else {
2481                         if(!SpectateUpdate())
2482                                 PutObserverInServer();
2483                 }
2484         } else {
2485                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2486                         self.flags |= FL_JUMPRELEASED;
2487                         if(self.flags & FL_SPAWNING)
2488                         {
2489                                 self.flags &~= FL_SPAWNING;
2490                                 LeaveSpectatorMode();
2491                                 return;
2492                         }
2493                 }
2494         }
2495
2496         PrintWelcomeMessage(self);
2497         self.flags |= FL_CLIENT | FL_NOTARGET;
2498 }
2499
2500 .float touchexplode_time;
2501
2502 /*
2503 =============
2504 PlayerPreThink
2505
2506 Called every frame for each client before the physics are run
2507 =============
2508 */
2509 void() ctf_setstatus;
2510 void() nexball_setstatus;
2511 .float items_added;
2512 void PlayerPreThink (void)
2513 {
2514         self.stat_game_starttime = game_starttime;
2515         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2516         self.stat_leadlimit = cvar("leadlimit");
2517
2518         if(frametime)
2519         {
2520                 // physics frames: update anticheat stuff
2521                 anticheat_prethink();
2522         }
2523
2524         if(blockSpectators && frametime)
2525                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2526                 checkSpectatorBlock();
2527
2528         zoomstate_set = 0;
2529
2530         if(self.netname_previous != self.netname)
2531         {
2532                 if(cvar("sv_eventlog"))
2533                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2534                 if(self.netname_previous)
2535                         strunzone(self.netname_previous);
2536                 self.netname_previous = strzone(self.netname);
2537         }
2538
2539         // version nagging
2540         if(self.version_nagtime)
2541                 if(self.cvar_g_xonoticversion)
2542                         if(time > self.version_nagtime)
2543                         {
2544                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2545                                 {
2546                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2547                                         {
2548                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2549                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2550                                         }
2551                                         else
2552                                         {
2553                                                 float r;
2554                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2555                                                 if(r < 0)
2556                                                 {
2557                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2558                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2559                                                 }
2560                                                 else if(r > 0)
2561                                                 {
2562                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2563                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2564                                                 }
2565                                         }
2566                                 }
2567                                 self.version_nagtime = 0;
2568                         }
2569
2570         // GOD MODE info
2571         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2572         {
2573                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2574                 self.max_armorvalue = 0;
2575         }
2576
2577 #ifdef TETRIS
2578         if (TetrisPreFrame())
2579                 return;
2580 #endif
2581
2582         MUTATOR_CALLHOOK(PlayerPreThink);
2583
2584         if(self.classname == "player") {
2585 //              if(self.netname == "Wazat")
2586 //                      bprint(self.classname, "\n");
2587
2588                 CheckRules_Player();
2589
2590                 PrintWelcomeMessage(self);
2591
2592                 if (intermission_running)
2593                 {
2594                         IntermissionThink ();   // otherwise a button could be missed between
2595                         return;                                 // the think tics
2596                 }
2597
2598                 if(self.teleport_time)
2599                 if(time > self.teleport_time)
2600                 {
2601                         self.teleport_time = 0;
2602                         self.effects = self.effects - (self.effects & EF_NODRAW);
2603                 }
2604
2605                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2606                         UpdateSelectedPlayer();
2607
2608                 //don't allow the player to turn around while game is paused!
2609                 if(timeoutStatus == 2) {
2610                         self.v_angle = self.lastV_angle;
2611                         self.angles = self.lastV_angle;
2612                         self.fixangle = TRUE;
2613                 }
2614
2615                 if(frametime)
2616                 {
2617                         if(self.health <= 0 && cvar("g_deathglow"))
2618                         {
2619                                 if(self.glowmod_x > 0)
2620                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2621                                 else
2622                                         self.glowmod_x = -1;
2623                                 if(self.glowmod_y > 0)
2624                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2625                                 else
2626                                         self.glowmod_y = -1;
2627                                 if(self.glowmod_z > 0)
2628                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2629                                 else
2630                                         self.glowmod_z = -1;
2631                         }
2632                         else
2633                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2634                         player_powerups();
2635                 }
2636
2637                 if (self.deadflag != DEAD_NO)
2638                 {
2639                         float button_pressed, force_respawn;
2640                         if(self.personal && g_race_qualifying)
2641                         {
2642                                 if(time > self.death_time)
2643                                 {
2644                                         self.death_time = time + 1; // only retry once a second
2645                                         respawn();
2646                                         self.impulse = 141;
2647                                 }
2648                         }
2649                         else
2650                         {
2651                                 if(frametime)
2652                                         player_anim();
2653                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2654                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2655                                 if (self.deadflag == DEAD_DYING)
2656                                 {
2657                                         if(force_respawn)
2658                                                 self.deadflag = DEAD_RESPAWNING;
2659                                         else if(!button_pressed)
2660                                                 self.deadflag = DEAD_DEAD;
2661                                 }
2662                                 else if (self.deadflag == DEAD_DEAD)
2663                                 {
2664                                         if(button_pressed)
2665                                                 self.deadflag = DEAD_RESPAWNABLE;
2666                                 }
2667                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2668                                 {
2669                                         if(!button_pressed)
2670                                                 self.deadflag = DEAD_RESPAWNING;
2671                                 }
2672                                 else if (self.deadflag == DEAD_RESPAWNING)
2673                                 {
2674                                         if(time > self.death_time)
2675                                         {
2676                                                 self.death_time = time + 1; // only retry once a second
2677                                                 respawn();
2678                                         }
2679                                 }
2680                                 ShowRespawnCountdown();
2681                         }
2682                         return;
2683                 }
2684
2685                 if(g_touchexplode)
2686                 if(time > self.touchexplode_time)
2687                 if(self.classname == "player")
2688                 if(self.deadflag == DEAD_NO)
2689                 if not(IS_INDEPENDENT_PLAYER(self))
2690                 FOR_EACH_PLAYER(other) if(self != other)
2691                 {
2692                         if(time > other.touchexplode_time)
2693                         if(other.deadflag == DEAD_NO)
2694                         if not(IS_INDEPENDENT_PLAYER(other))
2695                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2696                         {
2697                                 PlayerTouchExplode(self, other);
2698                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2699                         }
2700                 }
2701
2702                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2703                 {
2704                         vector dist;
2705
2706                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2707                         dist = self.prevorigin - self.origin;
2708                         dist_z = 0;
2709                         self.lms_traveled_distance += fabs(vlen(dist));
2710
2711                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2712                         {
2713                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2714                                 self.lms_traveled_distance = 0;
2715                         }
2716
2717                         if(time > self.lms_nextcheck)
2718                         {
2719                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2720                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2721                                 {
2722                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2723                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2724                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2725                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2726                                 }
2727                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2728                                 self.lms_traveled_distance = 0;
2729                         }
2730                 }
2731
2732                 self.prevorigin = self.origin;
2733
2734                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2735                 {
2736                         if (!self.crouch)
2737                         {
2738                                 self.crouch = TRUE;
2739                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2740                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2741                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2742                         }
2743                 }
2744                 else
2745                 {
2746                         if (self.crouch)
2747                         {
2748                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2749                                 if (!trace_startsolid)
2750                                 {
2751                                         self.crouch = FALSE;
2752                                         self.view_ofs = PL_VIEW_OFS;
2753                                         setsize (self, PL_MIN, PL_MAX);
2754                                 }
2755                         }
2756                 }
2757
2758                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2759                 {
2760                         if(self.bloodloss_timer < time)
2761                         {
2762                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2763                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2764                         }
2765                 }
2766
2767                 FixPlayermodel();
2768
2769                 GrapplingHookFrame();
2770
2771                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2772                 //if(frametime)
2773                 {
2774                         self.items &~= self.items_added;
2775
2776                         W_WeaponFrame();
2777
2778                         self.items_added = 0;
2779                         if(self.items & IT_JETPACK)
2780                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2781                                         self.items_added |= IT_FUEL;
2782
2783                         self.items |= self.items_added;
2784                 }
2785
2786                 player_regen();
2787                 if(frametime)
2788                         player_anim();
2789
2790                 if (g_minstagib)
2791                         minstagib_ammocheck();
2792
2793                 ctf_setstatus();
2794                 nexball_setstatus();
2795
2796                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2797
2798                 //self.angles_y=self.v_angle_y + 90;   // temp
2799         } else if(gameover) {
2800                 if (intermission_running)
2801                         IntermissionThink ();   // otherwise a button could be missed between
2802                 return;
2803         } else if(self.classname == "observer") {
2804                 ObserverThink();
2805         } else if(self.classname == "spectator") {
2806                 SpectatorThink();
2807         }
2808
2809         if(!zoomstate_set)
2810                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2811
2812         float oldspectatee_status;
2813         oldspectatee_status = self.spectatee_status;
2814         if(self.classname == "spectator")
2815                 self.spectatee_status = num_for_edict(self.enemy);
2816         else if(self.classname == "observer")
2817                 self.spectatee_status = num_for_edict(self);
2818         else
2819                 self.spectatee_status = 0;
2820         if(self.spectatee_status != oldspectatee_status)
2821         {
2822                 ClientData_Touch(self);
2823                 if(g_race || g_cts)
2824                         race_InitSpectator();
2825         }
2826
2827         if(self.teamkill_soundtime)
2828         if(time > self.teamkill_soundtime)
2829         {
2830                 self.teamkill_soundtime = 0;
2831
2832                 entity oldpusher, oldself;
2833
2834                 oldself = self; self = self.teamkill_soundsource;
2835                 oldpusher = self.pusher; self.pusher = oldself;
2836
2837                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2838
2839                 self.pusher = oldpusher;
2840                 self = oldself;
2841         }
2842
2843         if(self.taunt_soundtime)
2844         if(time > self.taunt_soundtime)
2845         {
2846                 self.taunt_soundtime = 0;
2847                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2848         }
2849
2850         target_voicescript_next(self);
2851 }
2852
2853 float isInvisibleString(string s)
2854 {
2855         float i, n, c;
2856         s = strdecolorize(s);
2857         for((i = 0), (n = strlen(s)); i < n; ++i)
2858         {
2859                 c = str2chr(s, i);
2860                 switch(c)
2861                 {
2862                         case 0:
2863                         case 32:
2864                         case 160:
2865                                 break;
2866                         default:
2867                                 return FALSE;
2868                 }
2869         }
2870         return TRUE;
2871 }
2872
2873 /*
2874 =============
2875 PlayerPostThink
2876
2877 Called every frame for each client after the physics are run
2878 =============
2879 */
2880 .float idlekick_lasttimeleft;
2881 .entity showheadshotbbox;
2882 void showheadshotbbox_think()
2883 {
2884         if(self.owner.showheadshotbbox != self)
2885         {
2886                 remove(self);
2887                 return;
2888         }
2889         self.nextthink = time;
2890         setorigin(self, self.owner.origin);
2891         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2892 }
2893 void PlayerPostThink (void)
2894 {
2895         // Savage: Check for nameless players
2896         if (isInvisibleString(self.netname)) {
2897                 self.netname = "Player";
2898                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2899         }
2900
2901         // send the clients accuracy stats to the client
2902         if(self.stat_count > 0)
2903         if(frametime)
2904         {
2905                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2906                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2907                 self.stat_count -= 1;
2908         }
2909
2910 #ifdef UID
2911         if(self.uid_kicktime)
2912         if(time > self.uid_kicktime)
2913         {
2914                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2915                 dropclient(self);
2916                 return;
2917         }
2918 #endif
2919
2920         if(sv_maxidle && frametime)
2921         {
2922                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2923                 float timeleft;
2924                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2925                 if(timeleft <= 0)
2926                 {
2927                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2928                         AnnounceTo(self, "terminated");
2929                         dropclient(self);
2930                         return;
2931                 }
2932                 else if(timeleft <= 10)
2933                 {
2934                         if(timeleft != self.idlekick_lasttimeleft)
2935                         {
2936                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2937                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2938                         }
2939                 }
2940                 else
2941                 {
2942                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2943                 }
2944                 self.idlekick_lasttimeleft = timeleft;
2945         }
2946
2947 #ifdef TETRIS
2948         if(self.impulse == 100)
2949                 ImpulseCommands();
2950         if (TetrisPostFrame())
2951                 return;
2952 #endif
2953
2954         CheatFrame();
2955
2956         if(self.classname == "player") {
2957                 CheckRules_Player();
2958                 UpdateChatBubble();
2959                 UpdateTeamBubble();
2960                 if (self.impulse)
2961                         ImpulseCommands();
2962                 if (intermission_running)
2963                         return;         // intermission or finale
2964                 GetPressedKeys();
2965         } else if (self.classname == "observer") {
2966                 //do nothing
2967         } else if (self.classname == "spectator") {
2968                 //do nothing
2969         }
2970
2971         /*
2972         float i;
2973         for(i = 0; i < 1000; ++i)
2974         {
2975                 vector end;
2976                 end = self.origin + '0 0 1024' + 512 * randomvec();
2977                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2978                 if(trace_fraction < 1)
2979                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2980                 {
2981                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2982                         break;
2983                 }
2984         }
2985         */
2986
2987         Arena_Warmup();
2988
2989         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2990
2991         if(self.waypointsprite_attachedforcarrier)
2992                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2993         
2994         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
2995         {
2996                 if(!self.showheadshotbbox)
2997                 {
2998                         self.showheadshotbbox = spawn();
2999                         self.showheadshotbbox.classname = "headshotbbox";
3000                         self.showheadshotbbox.owner = self;
3001                         self.showheadshotbbox.think = showheadshotbbox_think;
3002                         self.showheadshotbbox.nextthink = time;
3003                         self = self.showheadshotbbox;
3004                         self.think();
3005                         self = self.owner;
3006                 }
3007         }
3008         else
3009         {
3010                 if(self.showheadshotbbox)
3011                         remove(self.showheadshotbbox);
3012         }
3013
3014         playerdemo_write();
3015
3016         /*
3017         if(g_race)
3018                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3019         */
3020 }