qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(cvar("spawn_debugview"))
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > cvar("g_spawn_furthest"))
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(cvar("spawn_debugview"))
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(cvar("spawn_debug"))
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel = "models/player/marine.zym";
 402 string CheckPlayerModel(string plyermodel) {
 403         if(strlen(plyermodel) < 4)
 404                 return FallbackPlayerModel;
 405         if( substring(plyermodel,0,14) != "models/player/")
 406                 return FallbackPlayerModel;
 407         else if(cvar("sv_servermodelsonly"))
 408         {
 409                 if(substring(plyermodel,-4,4) != ".zym")
 410                 if(substring(plyermodel,-4,4) != ".dpm")
 411                 if(substring(plyermodel,-4,4) != ".iqm")
 412                 if(substring(plyermodel,-4,4) != ".md3")
 413                 if(substring(plyermodel,-4,4) != ".psk")
 414                         return FallbackPlayerModel;
 415                 // forbid the LOD models
 416                 if(substring(plyermodel, -9,5) == "_lod1")
 417                         return FallbackPlayerModel;
 418                 if(substring(plyermodel, -9,5) == "_lod2")
 419                         return FallbackPlayerModel;
 420                 if(plyermodel != strtolower(plyermodel))
 421                         return FallbackPlayerModel;
 422                 if(!fexists(plyermodel))
 423                         return FallbackPlayerModel;
 424         }
 425         return plyermodel;
 426 }
 427
 428 /*
 429 =============
 430 Client_customizeentityforclient
 431
 432 LOD reduction
 433 =============
 434 */
 435 void Client_uncustomizeentityforclient()
 436 {
 437         if(self.modelindex == 0) // no need to uncustomize then
 438                 return;
 439         self.modelindex = self.modelindex_lod0;
 440         self.skin = self.skinindex;
 441 }
 442
 443 float Client_customizeentityforclient()
 444 {
 445         entity modelsource;
 446
 447         if(self.modelindex == 0)
 448                 return TRUE;
 449
 450         // forcemodel stuff
 451
 452 #ifdef PROFILING
 453         float t0;
 454         t0 = gettime(GETTIME_HIRES); // reference
 455 #endif
 456
 457         modelsource = self;
 458
 459 #ifdef ALLOW_FORCEMODELS
 460         if(other.cvar_cl_forceplayermodelsfromxonotic)
 461                 if not(self.modelindex_lod0_from_xonotic)
 462                         modelsource = other;
 463         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 464                 modelsource = other;
 465 #endif
 466
 467         self.skin = modelsource.skinindex;
 468
 469 #if 0
 470         if(modelsource == self)
 471                 self.skin = modelsource.skinindex;
 472         else
 473                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 474 #endif
 475
 476         // self: me
 477         // other: the player viewing me
 478         float distance;
 479         float f;
 480
 481         if(other.cvar_cl_playerdetailreduction <= 0)
 482         {
 483                 if(other.cvar_cl_playerdetailreduction <= -2)
 484                         self.modelindex = modelsource.modelindex_lod2;
 485                 else if(other.cvar_cl_playerdetailreduction <= -1)
 486                         self.modelindex = modelsource.modelindex_lod1;
 487                 else
 488                         self.modelindex = modelsource.modelindex_lod0;
 489         }
 490         else
 491         {
 492                 distance = vlen(self.origin - other.origin);
 493                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 494                 if(f > sv_loddistance2)
 495                         self.modelindex = modelsource.modelindex_lod2;
 496                 else if(f > sv_loddistance1)
 497                         self.modelindex = modelsource.modelindex_lod1;
 498                 else
 499                         self.modelindex = modelsource.modelindex_lod0;
 500         }
 501
 502 #ifdef PROFILING
 503         float t1;
 504         t1 = gettime(GETTIME_HIRES); // reference
 505         client_cefc_accumulator += (t1 - t0);
 506 #endif
 507
 508         return TRUE;
 509 }
 510
 511 void UpdatePlayerSounds();
 512 void setmodel_lod(entity e, string modelname)
 513 {
 514         string s;
 515
 516         if(sv_loddistance1)
 517         {
 518                 // FIXME: this only supports 3-letter extensions
 519                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 520                 if(fexists(s))
 521                 {
 522                         setmodel(e, s); // players have high precision
 523                         self.modelindex_lod1 = self.modelindex;
 524                 }
 525                 else
 526                         self.modelindex_lod1 = -1;
 527
 528                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 529                 if(fexists(s))
 530                 {
 531                         setmodel(e, s); // players have high precision
 532                         self.modelindex_lod2 = self.modelindex;
 533                 }
 534                 else
 535                         self.modelindex_lod2 = -1;
 536
 537                 precache_model(modelname);
 538                 setmodel(e, modelname); // players have high precision
 539                 self.modelindex_lod0 = self.modelindex;
 540
 541                 if(self.modelindex_lod1 < 0)
 542                         self.modelindex_lod1 = self.modelindex;
 543
 544                 if(self.modelindex_lod2 < 0)
 545                         self.modelindex_lod2 = self.modelindex;
 546         }
 547         else
 548         {
 549                 precache_model(modelname);
 550                 setmodel(e, modelname); // players have high precision
 551                 self.modelindex_lod0 = self.modelindex;
 552                         // save it for possible player model forcing
 553         }
 554
 555         s = whichpack(self.model);
 556         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 557
 558         player_setupanimsformodel();
 559         UpdatePlayerSounds();
 560 }
 561
 562 /*
 563 =============
 564 PutObserverInServer
 565
 566 putting a client as observer in the server
 567 =============
 568 */
 569 void FixPlayermodel();
 570 void PutObserverInServer (void)
 571 {
 572         entity  spot;
 573
 574         race_PreSpawnObserver();
 575
 576         spot = SelectSpawnPoint (TRUE);
 577         if(!spot)
 578                 error("No spawnpoints for observers?!?\n");
 579         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 580
 581         if(clienttype(self) == CLIENTTYPE_REAL)
 582         {
 583                 msg_entity = self;
 584                 WriteByte(MSG_ONE, SVC_SETVIEW);
 585                 WriteEntity(MSG_ONE, self);
 586         }
 587
 588         DropAllRunes(self);
 589
 590         Portal_ClearAll(self);
 591
 592         if(self.flagcarried)
 593                 DropFlag(self.flagcarried, world, world);
 594
 595         if(self.ballcarried)
 596                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 597
 598         WaypointSprite_PlayerDead();
 599
 600         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 601                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 602
 603         if(self.killcount != -666) {
 604                 if(g_lms) {
 605                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 606                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 607                         else
 608                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 609                 } else
 610                         bprint ("^4", self.netname, "^4 is spectating now\n");
 611
 612                 if(self.just_joined == FALSE) {
 613                         LogTeamchange(self.playerid, -1, 4);
 614                 } else
 615                         self.just_joined = FALSE;
 616         }
 617
 618         PlayerScore_Clear(self); // clear scores when needed
 619
 620         self.spectatortime = time;
 621
 622         self.classname = "observer";
 623         self.iscreature = FALSE;
 624         self.health = -666;
 625         self.takedamage = DAMAGE_NO;
 626         self.solid = SOLID_NOT;
 627         self.movetype = MOVETYPE_NOCLIP;
 628         self.flags = FL_CLIENT | FL_NOTARGET;
 629         self.armorvalue = 666;
 630         self.effects = 0;
 631         self.armorvalue = cvar("g_balance_armor_start");
 632         self.pauserotarmor_finished = 0;
 633         self.pauserothealth_finished = 0;
 634         self.pauseregen_finished = 0;
 635         self.damageforcescale = 0;
 636         self.death_time = 0;
 637         self.dead_frame = 0;
 638         self.alpha = 0;
 639         self.scale = 0;
 640         self.fade_time = 0;
 641         self.pain_frame = 0;
 642         self.pain_finished = 0;
 643         self.strength_finished = 0;
 644         self.invincible_finished = 0;
 645         self.pushltime = 0;
 646         self.think = SUB_Null;
 647         self.nextthink = 0;
 648         self.hook_time = 0;
 649         self.runes = 0;
 650         self.deadflag = DEAD_NO;
 651         self.angles = spot.angles;
 652         self.angles_z = 0;
 653         self.fixangle = TRUE;
 654         self.crouch = FALSE;
 655
 656         self.view_ofs = PL_VIEW_OFS;
 657         setorigin (self, spot.origin);
 658         setsize (self, '0 0 0', '0 0 0');
 659         self.prevorigin = self.origin;
 660         self.items = 0;
 661         self.weapons = 0;
 662         self.model = "";
 663         FixPlayermodel();
 664         self.model = "";
 665         self.modelindex = 0;
 666         self.weapon = 0;
 667         self.weaponmodel = "";
 668         self.weaponentity = world;
 669         self.exteriorweaponentity = world;
 670         self.killcount = -666;
 671         self.velocity = '0 0 0';
 672         self.avelocity = '0 0 0';
 673         self.punchangle = '0 0 0';
 674         self.punchvector = '0 0 0';
 675         self.oldvelocity = self.velocity;
 676         self.fire_endtime = -1;
 677
 678         if(sv_loddistance1)
 679                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 680
 681         if(g_arena)
 682         {
 683                 if(self.version_mismatch)
 684                 {
 685                         Spawnqueue_Unmark(self);
 686                         Spawnqueue_Remove(self);
 687                 }
 688                 else
 689                 {
 690                         Spawnqueue_Insert(self);
 691                 }
 692         }
 693         else if(g_lms)
 694         {
 695                 // Only if the player cannot play at all
 696                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 697                         self.frags = FRAGS_SPECTATOR;
 698                 else
 699                         self.frags = FRAGS_LMS_LOSER;
 700         }
 701         else
 702                 self.frags = FRAGS_SPECTATOR;
 703
 704         MUTATOR_CALLHOOK(MakePlayerObserver);
 705 }
 706
 707 float RestrictSkin(float s)
 708 {
 709         if(!teams_matter)
 710                 return s;
 711         if(s == 6)
 712                 return 6;
 713         return mod(s, 3);
 714 }
 715
 716 void FixPlayermodel()
 717 {
 718         local string defaultmodel;
 719         local float defaultskin, chmdl, oldskin;
 720         local vector m1, m2;
 721
 722         defaultmodel = "";
 723
 724         if(cvar("sv_defaultcharacter") == 1) {
 725                 defaultskin = 0;
 726
 727                 if(teams_matter)
 728                 {
 729                         string s;
 730                         s = Team_ColorNameLowerCase(self.team);
 731                         if(s != "neutral")
 732                         {
 733                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 734                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 735                         }
 736                 }
 737
 738                 if(defaultmodel == "")
 739                 {
 740                         defaultmodel = cvar_string("sv_defaultplayermodel");
 741                         defaultskin = cvar("sv_defaultplayerskin");
 742                 }
 743         }
 744
 745         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 746         {
 747                 if(self.model != "")
 748                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 749                 self.model = ""; // force the != checks to return true
 750         }
 751
 752         if(defaultmodel != "")
 753         {
 754                 if (defaultmodel != self.model)
 755                 {
 756                         m1 = self.mins;
 757                         m2 = self.maxs;
 758                         setmodel_lod (self, defaultmodel);
 759                         setsize (self, m1, m2);
 760                         chmdl = TRUE;
 761                 }
 762
 763                 oldskin = self.skinindex;
 764                 self.skinindex = defaultskin;
 765         } else {
 766                 if (self.playermodel != self.model || self.playermodel == "")
 767                 {
 768                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 769                         m1 = self.mins;
 770                         m2 = self.maxs;
 771                         setmodel_lod (self, self.playermodel);
 772                         setsize (self, m1, m2);
 773                         chmdl = TRUE;
 774                 }
 775
 776                 oldskin = self.skinindex;
 777                 self.skinindex = RestrictSkin(stof(self.playerskin));
 778         }
 779
 780         if(chmdl || oldskin != self.skinindex)
 781                 self.species = player_getspecies(); // model or skin has changed
 782
 783         if(!teams_matter)
 784                 if(strlen(cvar_string("sv_defaultplayercolors")))
 785                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 786                                 setcolor(self, cvar("sv_defaultplayercolors"));
 787 }
 788
 789 void PlayerTouchExplode(entity p1, entity p2)
 790 {
 791         vector org;
 792         org = (p1.origin + p2.origin) * 0.5;
 793         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 794
 795         te_explosion(org);
 796
 797         entity e;
 798         e = spawn();
 799         setorigin(e, org);
 800         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 801         remove(e);
 802 }
 803
 804 /*
 805 =============
 806 PutClientInServer
 807
 808 Called when a client spawns in the server
 809 =============
 810 */
 811 //void() ctf_playerchanged;
 812 void PutClientInServer (void)
 813 {
 814         if(clienttype(self) == CLIENTTYPE_BOT)
 815         {
 816                 self.classname = "player";
 817         }
 818         else if(clienttype(self) == CLIENTTYPE_REAL)
 819         {
 820                 msg_entity = self;
 821                 WriteByte(MSG_ONE, SVC_SETVIEW);
 822                 WriteEntity(MSG_ONE, self);
 823         }
 824
 825         // player is dead and becomes observer
 826         // FIXME fix LMS scoring for new system
 827         if(g_lms)
 828         {
 829                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 830                         self.classname = "observer";
 831         }
 832
 833         if(g_arena || (g_ca && !allowed_to_spawn))
 834         if(!self.spawned)
 835                 self.classname = "observer";
 836
 837         if(gameover)
 838                 self.classname = "observer";
 839
 840         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 841                 entity spot, oldself;
 842                 float j;
 843
 844                 if(self.team < 0)
 845                         JoinBestTeam(self, FALSE, TRUE);
 846
 847                 race_PreSpawn();
 848
 849                 spot = SelectSpawnPoint (FALSE);
 850                 if(!spot)
 851                 {
 852                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 853                         return; // spawn failed
 854                 }
 855
 856                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 857
 858                 self.classname = "player";
 859                 self.wasplayer = TRUE;
 860                 self.iscreature = TRUE;
 861                 self.movetype = MOVETYPE_WALK;
 862                 self.solid = SOLID_SLIDEBOX;
 863                 if(cvar("g_playerclip_collisions"))
 864                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 865                 else
 866                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 867                 self.frags = FRAGS_PLAYER;
 868                 if(independent_players)
 869                         MAKE_INDEPENDENT_PLAYER(self);
 870                 self.flags = FL_CLIENT;
 871                 self.takedamage = DAMAGE_AIM;
 872                 if(g_minstagib)
 873                         self.effects = EF_FULLBRIGHT;
 874                 else
 875                         self.effects = 0;
 876                 self.air_finished = time + 12;
 877                 self.dmg = 2;
 878
 879                 if(inWarmupStage)
 880                 {
 881                         self.ammo_shells = warmup_start_ammo_shells;
 882                         self.ammo_nails = warmup_start_ammo_nails;
 883                         self.ammo_rockets = warmup_start_ammo_rockets;
 884                         self.ammo_cells = warmup_start_ammo_cells;
 885                         self.ammo_fuel = warmup_start_ammo_fuel;
 886                         self.health = warmup_start_health;
 887                         self.armorvalue = warmup_start_armorvalue;
 888                         self.weapons = warmup_start_weapons;
 889                 }
 890                 else
 891                 {
 892                         self.ammo_shells = start_ammo_shells;
 893                         self.ammo_nails = start_ammo_nails;
 894                         self.ammo_rockets = start_ammo_rockets;
 895                         self.ammo_cells = start_ammo_cells;
 896                         self.ammo_fuel = start_ammo_fuel;
 897                         self.health = start_health;
 898                         self.armorvalue = start_armorvalue;
 899                         self.weapons = start_weapons;
 900                 }
 901
 902                 if(g_weaponarena_random)
 903                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 904
 905                 self.items = start_items;
 906                 self.jump_interval = time;
 907
 908                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 909                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 910                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 911                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 912                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 913                 //extend the pause of rotting if client was reset at the beginning of the countdown
 914                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 915                         self.spawnshieldtime += game_starttime - time;
 916                         self.pauserotarmor_finished += game_starttime - time;
 917                         self.pauserothealth_finished += game_starttime - time;
 918                         self.pauseregen_finished += game_starttime - time;
 919                 }
 920                 self.damageforcescale = 2;
 921                 self.death_time = 0;
 922                 self.dead_frame = 0;
 923                 self.alpha = 0;
 924                 self.scale = 0;
 925                 self.fade_time = 0;
 926                 self.pain_frame = 0;
 927                 self.pain_finished = 0;
 928                 self.strength_finished = 0;
 929                 self.invincible_finished = 0;
 930                 self.pushltime = 0;
 931                 // players have no think function
 932                 self.think = SUB_Null;
 933                 self.nextthink = 0;
 934                 self.hook_time = 0;
 935                 self.dmg_team = 0;
 936
 937                 self.metertime = 0;
 938
 939                 self.runes = 0;
 940
 941                 self.deadflag = DEAD_NO;
 942
 943                 self.angles = spot.angles;
 944
 945                 self.angles_z = 0; // never spawn tilted even if the spot says to
 946                 self.fixangle = TRUE; // turn this way immediately
 947                 self.velocity = '0 0 0';
 948                 self.avelocity = '0 0 0';
 949                 self.punchangle = '0 0 0';
 950                 self.punchvector = '0 0 0';
 951                 self.oldvelocity = self.velocity;
 952                 self.fire_endtime = -1;
 953
 954                 msg_entity = self;
 955                 WRITESPECTATABLE_MSG_ONE({
 956                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 957                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 958                 });
 959
 960                 if(sv_loddistance1)
 961                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 962
 963                 self.model = "";
 964                 FixPlayermodel();
 965
 966                 self.crouch = FALSE;
 967                 self.view_ofs = PL_VIEW_OFS;
 968                 setsize (self, PL_MIN, PL_MAX);
 969                 self.spawnorigin = spot.origin;
 970                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 971                 // don't reset back to last position, even if new position is stuck in solid
 972                 self.oldorigin = self.origin;
 973                 self.prevorigin = self.origin;
 974                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 975
 976                 if(g_arena)
 977                 {
 978                         Spawnqueue_Remove(self);
 979                         Spawnqueue_Mark(self);
 980                 }
 981
 982                 else if(g_ca)
 983                         self.caplayer = 1;
 984
 985                 self.event_damage = PlayerDamage;
 986
 987                 self.bot_attack = TRUE;
 988
 989                 self.statdraintime = time + 5;
 990                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 991
 992                 if(self.killcount == -666) {
 993                         PlayerScore_Clear(self);
 994                         self.killcount = 0;
 995                 }
 996
 997                 self.cnt = WEP_LASER;
 998
 999                 CL_SpawnWeaponentity();
1000                 self.alpha = default_player_alpha;
1001                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1002                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1003
1004                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1005                 self.lms_traveled_distance = 0;
1006                 self.speedrunning = FALSE;
1007
1008                 race_PostSpawn(spot);
1009
1010                 if(cvar("spawn_debug"))
1011                 {
1012                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1013                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1014                 }
1015
1016                 //stuffcmd(self, "chase_active 0");
1017                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1018
1019                 if (cvar("g_spawnsound"))
1020                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1021
1022                 if(g_assault) {
1023                         if(self.team == assault_attacker_team)
1024                                 centerprint(self, "You are attacking!");
1025                         else
1026                                 centerprint(self, "You are defending!");
1027                 }
1028
1029                 target_voicescript_clear(self);
1030
1031                 // reset fields the weapons may use
1032                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1033                         weapon_action(j, WR_RESETPLAYER);
1034
1035                 oldself = self;
1036                 self = spot;
1037                         activator = oldself;
1038                                 SUB_UseTargets();
1039                         activator = world;
1040                 self = oldself;
1041
1042                 MUTATOR_CALLHOOK(PlayerSpawn);
1043
1044                 self.switchweapon = w_getbestweapon(self);
1045                 self.cnt = self.switchweapon;
1046                 self.weapon = 0;
1047         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1048                 PutObserverInServer ();
1049         }
1050
1051         //if(g_ctf)
1052         //      ctf_playerchanged();
1053 }
1054
1055 float ClientInit_SendEntity(entity to, float sf)
1056 {
1057         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1058         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1059         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1060         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1061         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1062
1063         if(sv_foginterval && world.fog != "")
1064                 WriteString(MSG_ENTITY, world.fog);
1065         else
1066                 WriteString(MSG_ENTITY, "");
1067         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1068         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1069         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1070         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1071         return TRUE;
1072 }
1073
1074 void ClientInit_CheckUpdate()
1075 {
1076         self.nextthink = time;
1077         if(self.count != cvar("g_balance_armor_blockpercent"))
1078         {
1079                 self.count = cvar("g_balance_armor_blockpercent");
1080                 self.SendFlags |= 1;
1081         }
1082         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1083         {
1084                 self.cnt = cvar("g_balance_weaponswitchdelay");
1085                 self.SendFlags |= 1;
1086         }
1087         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1088         {
1089                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1090                 self.SendFlags |= 1;
1091         }
1092         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1093         {
1094                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1095                 self.SendFlags |= 1;
1096         }
1097 }
1098
1099 void ClientInit_Spawn()
1100 {
1101         entity o;
1102         entity e;
1103         e.classname = "clientinit";
1104         e.think = ClientInit_CheckUpdate;
1105         e.nextthink = time;
1106         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1107         o = self;
1108         self = e;
1109         ClientInit_CheckUpdate();
1110         self = o;
1111 }
1112
1113 /*
1114 =============
1115 SetNewParms
1116 =============
1117 */
1118 void SetNewParms (void)
1119 {
1120         // initialize parms for a new player
1121         parm1 = -(86400 * 366);
1122 }
1123
1124 /*
1125 =============
1126 SetChangeParms
1127 =============
1128 */
1129 void SetChangeParms (void)
1130 {
1131         // save parms for level change
1132         parm1 = self.parm_idlesince - time;
1133 }
1134
1135 /*
1136 =============
1137 DecodeLevelParms
1138 =============
1139 */
1140 void DecodeLevelParms (void)
1141 {
1142         // load parms
1143         self.parm_idlesince = parm1;
1144         if(self.parm_idlesince == -(86400 * 366))
1145                 self.parm_idlesince = time;
1146
1147         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1148         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1149 }
1150
1151 /*
1152 =============
1153 ClientKill
1154
1155 Called when a client types 'kill' in the console
1156 =============
1157 */
1158
1159 void ClientKill_Now_TeamChange()
1160 {
1161         if(self.killindicator_teamchange == -1)
1162         {
1163                 self.team = -1;
1164                 JoinBestTeam( self, FALSE, FALSE );
1165         }
1166         else
1167                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1168 }
1169
1170 void ClientKill_Now()
1171 {
1172         if(self.killindicator_teamchange)
1173                 ClientKill_Now_TeamChange();
1174
1175         // in any case:
1176         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1177
1178         if(self.killindicator)
1179         {
1180                 dprint("Cleaned up after a leaked kill indicator.\n");
1181                 remove(self.killindicator);
1182                 self.killindicator = world;
1183         }
1184 }
1185 void KillIndicator_Think()
1186 {
1187         if (!self.owner.modelindex)
1188         {
1189                 self.owner.killindicator = world;
1190                 remove(self);
1191                 return;
1192         }
1193
1194         if(self.cnt <= 0)
1195         {
1196                 self = self.owner;
1197                 ClientKill_Now(); // no oldself needed
1198                 return;
1199         }
1200         else
1201         {
1202                 if(self.cnt <= 10)
1203                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1204                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1205                 {
1206                         if(self.cnt <= 10)
1207                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1208                         if(self.owner.killindicator_teamchange)
1209                         {
1210                                 if(self.owner.killindicator_teamchange == -1)
1211                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1212                                 else
1213                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1214                         }
1215                         else
1216                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1217                 }
1218                 self.nextthink = time + 1;
1219                 self.cnt -= 1;
1220         }
1221 }
1222
1223 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1224 {
1225         float killtime;
1226         entity e;
1227         killtime = cvar("g_balance_kill_delay");
1228
1229         if(g_race_qualifying)
1230                 killtime = 0;
1231
1232         self.killindicator_teamchange = targetteam;
1233
1234         if(!self.killindicator)
1235         {
1236                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1237                 {
1238                         ClientKill_Now();
1239                 }
1240                 else
1241                 {
1242                         self.killindicator = spawn();
1243                         self.killindicator.owner = self;
1244                         self.killindicator.scale = 0.5;
1245                         setattachment(self.killindicator, self, "");
1246                         setorigin(self.killindicator, '0 0 52');
1247                         self.killindicator.think = KillIndicator_Think;
1248                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1249                         self.killindicator.cnt = ceil(killtime);
1250                         self.killindicator.count = bound(0, ceil(killtime), 10);
1251                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1252
1253                         for(e = world; (e = find(e, classname, "body")) != world; )
1254                         {
1255                                 if(e.enemy != self)
1256                                         continue;
1257                                 e.killindicator = spawn();
1258                                 e.killindicator.owner = e;
1259                                 e.killindicator.scale = 0.5;
1260                                 setattachment(e.killindicator, e, "");
1261                                 setorigin(e.killindicator, '0 0 52');
1262                                 e.killindicator.think = KillIndicator_Think;
1263                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1264                                 e.killindicator.cnt = ceil(killtime);
1265                         }
1266                         self.lip = 0;
1267                 }
1268         }
1269         if(self.killindicator)
1270         {
1271                 if(targetteam)
1272                         self.killindicator.colormod = TeamColor(targetteam);
1273                 else
1274                         self.killindicator.colormod = '0 0 0';
1275         }
1276 }
1277
1278 void ClientKill (void)
1279 {
1280         ClientKill_TeamChange(0);
1281 }
1282
1283 void DoTeamChange(float destteam)
1284 {
1285         float t, c0;
1286         if(!teams_matter)
1287         {
1288                 if(destteam >= 0)
1289                         SetPlayerColors(self, destteam);
1290                 return;
1291         }
1292         if(self.classname == "player")
1293         if(destteam == -1)
1294         {
1295                 CheckAllowedTeams(self);
1296                 t = FindSmallestTeam(self, TRUE);
1297                 switch(self.team)
1298                 {
1299                         case COLOR_TEAM1: c0 = c1; break;
1300                         case COLOR_TEAM2: c0 = c2; break;
1301                         case COLOR_TEAM3: c0 = c3; break;
1302                         case COLOR_TEAM4: c0 = c4; break;
1303                         default:          c0 = 999;
1304                 }
1305                 switch(t)
1306                 {
1307                         case 1:
1308                                 if(c0 > c1)
1309                                         destteam = COLOR_TEAM1;
1310                                 break;
1311                         case 2:
1312                                 if(c0 > c2)
1313                                         destteam = COLOR_TEAM2;
1314                                 break;
1315                         case 3:
1316                                 if(c0 > c3)
1317                                         destteam = COLOR_TEAM3;
1318                                 break;
1319                         case 4:
1320                                 if(c0 > c4)
1321                                         destteam = COLOR_TEAM4;
1322                                 break;
1323                 }
1324                 if(destteam == -1)
1325                         return;
1326         }
1327         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1328                 return;
1329         ClientKill_TeamChange(destteam);
1330 }
1331
1332 void FixClientCvars(entity e)
1333 {
1334         // send prediction settings to the client
1335         stuffcmd(e, "\nin_bindmap 0 0\n");
1336         if(g_race || g_cts)
1337                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1338         if(cvar("g_antilag") == 3) // client side hitscan
1339                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1340                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1341         /*
1342          * we no longer need to stuff this. Remove this comment block if you feel
1343          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1344         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1345         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1346         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1347         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1348         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1349         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1350         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1351         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1352         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1353         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1354         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1355         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1356         stuffcmd(e, "cl_movement_edgefriction 1\n");
1357          */
1358 }
1359
1360 /*
1361 =============
1362 ClientConnect
1363
1364 Called when a client connects to the server
1365 =============
1366 */
1367 //void ctf_clientconnect();
1368 string ColoredTeamName(float t);
1369 void DecodeLevelParms (void);
1370 //void dom_player_join_team(entity pl);
1371 #ifdef UID
1372 .float uid_kicktime;
1373 .string uid;
1374 #endif
1375 void ClientConnect (void)
1376 {
1377         float t;
1378
1379         if(self.flags & FL_CLIENT)
1380         {
1381                 print("Warning: ClientConnect, but already connected!\n");
1382                 return;
1383         }
1384
1385         if(Ban_MaybeEnforceBan(self))
1386                 return;
1387
1388         DecodeLevelParms();
1389
1390         self.classname = "player_joining";
1391
1392         self.flags = FL_CLIENT;
1393         self.version_nagtime = time + 10 + random() * 10;
1394
1395         if(player_count<0)
1396         {
1397                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1398                 player_count = 0;
1399         }
1400
1401         PlayerScore_Attach(self);
1402         ClientData_Attach();
1403
1404         bot_clientconnect();
1405
1406         playerdemo_init();
1407
1408         anticheat_init();
1409
1410         race_PreSpawnObserver();
1411
1412         //if(g_domination)
1413         //      dom_player_join_team(self);
1414
1415         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1416
1417         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1418                 self.classname = "observer";
1419         } else {
1420                 if(teams_matter)
1421                 {
1422                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1423                         {
1424                                 self.classname = "player";
1425                                 campaign_bots_may_start = 1;
1426                         }
1427                         else
1428                         {
1429                                 self.classname = "observer"; // do it anyway
1430                         }
1431                 }
1432                 else
1433                 {
1434                         self.classname = "player";
1435                         campaign_bots_may_start = 1;
1436                 }
1437         }
1438
1439         self.playerid = (playerid_last = playerid_last + 1);
1440
1441         if(cvar("sv_eventlog"))
1442                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1443
1444         LogTeamchange(self.playerid, self.team, 1);
1445
1446         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1447
1448         self.netname_previous = strzone(self.netname);
1449
1450         bprint("^4", self.netname, "^4 connected");
1451
1452         if(self.classname != "observer" && (g_domination || g_ctf))
1453                 bprint(" and joined the ", ColoredTeamName(self.team));
1454
1455         bprint("\n");
1456
1457         self.welcomemessage_time = 0;
1458
1459         stuffcmd(self, strcat(clientstuff, "\n"));
1460         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1461         stuffcmd(self, "cl_particles_reloadeffects\n");
1462
1463         FixClientCvars(self);
1464
1465         // spawnfunc_waypoint sprites
1466         WaypointSprite_InitClient(self);
1467
1468         // Wazat's grappling hook
1469         SetGrappleHookBindings();
1470
1471         // get autoswitch state from player when he toggles it
1472         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1473
1474         // get version info from player
1475         stuffcmd(self, "cmd clientversion $gameversion\n");
1476
1477         // get other cvars from player
1478         GetCvars(0);
1479
1480         // set cvar for team scoreboard
1481         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1482
1483         // notify about available teams
1484         if(teams_matter)
1485         {
1486                 CheckAllowedTeams(self);
1487                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1488                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1489         }
1490         else
1491                 stuffcmd(self, "set _teams_available 0\n");
1492
1493         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1494
1495         if(g_arena || g_ca)
1496         {
1497                 self.classname = "observer";
1498                 if(g_arena)
1499                         Spawnqueue_Insert(self);
1500         }
1501         /*else if(g_ctf)
1502         {
1503                 ctf_clientconnect();
1504         }*/
1505
1506         if(teams_matter || radar_showennemies)
1507                 attach_entcs();
1508
1509         bot_relinkplayerlist();
1510
1511         self.spectatortime = time;
1512         if(blockSpectators)
1513         {
1514                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1515         }
1516
1517         self.jointime = time;
1518         self.allowedTimeouts = cvar("sv_timeout_number");
1519
1520         if(clienttype(self) == CLIENTTYPE_REAL)
1521         {
1522                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1523                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1524         }
1525
1526         if(g_lms)
1527         {
1528                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1529                 {
1530                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1531                         self.frags = FRAGS_SPECTATOR;
1532                 }
1533         }
1534
1535         if(!sv_foginterval && world.fog != "")
1536                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1537
1538         SoundEntity_Attach(self);
1539
1540         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1541         {
1542                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1543                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1544         }
1545         else
1546                 self.hitplotfh = -1;
1547
1548 #ifdef UID
1549         if(clienttype(self) == CLIENTTYPE_REAL)
1550         if not(self.uid)
1551                 self.uid_kicktime = time + 60;
1552 #endif
1553
1554         if(g_race || g_cts) {
1555                 string rr;
1556                 if(g_cts)
1557                         rr = CTS_RECORD;
1558                 else
1559                         rr = RACE_RECORD;
1560                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1561
1562                 race_send_recordtime(MSG_ONE);
1563                 race_send_speedaward(MSG_ONE);
1564
1565                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1566                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1567                 race_send_speedaward_alltimebest(MSG_ONE);
1568
1569                 float i;
1570                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1571                         race_SendRankings(i, 0, 0, MSG_ONE);
1572                 }
1573         }
1574         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1575                 send_CSQC_teamnagger();
1576
1577         CheatInitClient();
1578 }
1579
1580 /*
1581 =============
1582 ClientDisconnect
1583
1584 Called when a client disconnects from the server
1585 =============
1586 */
1587 .entity chatbubbleentity;
1588 .entity teambubbleentity;
1589 void ReadyCount();
1590 void ClientDisconnect (void)
1591 {
1592         if not(self.flags & FL_CLIENT)
1593         {
1594                 print("Warning: ClientDisconnect without ClientConnect\n");
1595                 return;
1596         }
1597
1598         CheatShutdownClient();
1599
1600         if(self.hitplotfh >= 0)
1601         {
1602                 fclose(self.hitplotfh);
1603                 self.hitplotfh = -1;
1604         }
1605
1606         anticheat_report();
1607         anticheat_shutdown();
1608
1609         playerdemo_shutdown();
1610
1611         bot_clientdisconnect();
1612
1613         if(self.entcs)
1614                 detach_entcs();
1615
1616         if(cvar("sv_eventlog"))
1617                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1618         bprint ("^4",self.netname);
1619         bprint ("^4 disconnected\n");
1620
1621         SoundEntity_Detach(self);
1622
1623         DropAllRunes(self);
1624         MUTATOR_CALLHOOK(ClientDisconnect);
1625
1626         Portal_ClearAll(self);
1627
1628         if(self.flagcarried)
1629                 DropFlag(self.flagcarried, world, world);
1630         if(self.ballcarried)
1631                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1632
1633         // Here, everything has been done that requires this player to be a client.
1634
1635         self.flags &~= FL_CLIENT;
1636
1637         if (self.chatbubbleentity)
1638                 remove (self.chatbubbleentity);
1639
1640         if (self.teambubbleentity)
1641                 remove (self.teambubbleentity);
1642
1643         if (self.killindicator)
1644                 remove (self.killindicator);
1645
1646         WaypointSprite_PlayerGone();
1647
1648         bot_relinkplayerlist();
1649
1650         // remove laserdot
1651         if(self.weaponentity)
1652                 if(self.weaponentity.lasertarget)
1653                         remove(self.weaponentity.lasertarget);
1654
1655         if(g_arena)
1656         {
1657                 Spawnqueue_Unmark(self);
1658                 Spawnqueue_Remove(self);
1659         }
1660
1661         ClientData_Detach();
1662         PlayerScore_Detach(self);
1663
1664         if(self.netname_previous)
1665                 strunzone(self.netname_previous);
1666         if(self.clientstatus)
1667                 strunzone(self.clientstatus);
1668
1669         ClearPlayerSounds();
1670
1671         if(self.personal)
1672                 remove(self.personal);
1673
1674         self.playerid = 0;
1675         ReadyCount();
1676
1677         // free cvars
1678         GetCvars(-1);
1679 }
1680
1681 .float BUTTON_CHAT;
1682 void ChatBubbleThink()
1683 {
1684         self.nextthink = time;
1685         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1686         {
1687                 if(self.owner) // but why can that ever be world?
1688                         self.owner.chatbubbleentity = world;
1689                 remove(self);
1690                 return;
1691         }
1692         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1693 #ifdef TETRIS
1694                 || self.owner.tetris_on
1695 #endif
1696         )
1697                 self.model = self.mdl;
1698         else
1699                 self.model = "";
1700 };
1701
1702 void UpdateChatBubble()
1703 {
1704         if (!self.modelindex)
1705                 return;
1706         // spawn a chatbubble entity if needed
1707         if (!self.chatbubbleentity)
1708         {
1709                 self.chatbubbleentity = spawn();
1710                 self.chatbubbleentity.owner = self;
1711                 self.chatbubbleentity.exteriormodeltoclient = self;
1712                 self.chatbubbleentity.think = ChatBubbleThink;
1713                 self.chatbubbleentity.nextthink = time;
1714                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1715                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1716                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1717                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1718                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1719                 self.chatbubbleentity.model = "";
1720                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1721         }
1722 }
1723
1724
1725 void TeamBubbleThink()
1726 {
1727         self.nextthink = time;
1728         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1729         {
1730                 if(self.owner) // but why can that ever be world?
1731                         self.owner.teambubbleentity = world;
1732                 remove(self);
1733                 return;
1734         }
1735 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1736         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1737                 self.model = "";
1738         else
1739                 self.model = self.mdl;
1740
1741 };
1742
1743 float TeamBubble_customizeentityforclient()
1744 {
1745         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1746 }
1747
1748 void UpdateTeamBubble()
1749 {
1750         if (!self.modelindex || !teams_matter)
1751                 return;
1752         // spawn a teambubble entity if needed
1753         if (!self.teambubbleentity && teams_matter)
1754         {
1755                 self.teambubbleentity = spawn();
1756                 self.teambubbleentity.owner = self;
1757                 self.teambubbleentity.exteriormodeltoclient = self;
1758                 self.teambubbleentity.think = TeamBubbleThink;
1759                 self.teambubbleentity.nextthink = time;
1760                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1761 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1762                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1763                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1764                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1765                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1766                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1767                 self.teambubbleentity.effects = EF_LOWPRECISION;
1768         }
1769 }
1770
1771 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1772 // added to the model skins
1773 /*void UpdateColorModHack()
1774 {
1775         local float c;
1776         c = self.clientcolors & 15;
1777         // LordHavoc: only bothering to support white, green, red, yellow, blue
1778              if (!teams_matter) self.colormod = '0 0 0';
1779         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1780         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1781         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1782         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1783         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1784         else self.colormod = '1 1 1';
1785 };*/
1786
1787 .float oldcolormap;
1788 void respawn(void)
1789 {
1790         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1791         {
1792                 self.solid = SOLID_NOT;
1793                 self.takedamage = DAMAGE_NO;
1794                 self.movetype = MOVETYPE_FLY;
1795                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1796                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1797                 self.effects |= EF_ADDITIVE;
1798                 self.oldcolormap = self.colormap;
1799                 self.colormap = 512;
1800                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1801                 if(cvar("g_respawn_ghosts_maxtime"))
1802                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1803         }
1804
1805         CopyBody(1);
1806         self.effects |= EF_NODRAW; // prevent another CopyBody
1807         if(self.oldcolormap)
1808         {
1809                 self.colormap = self.oldcolormap;
1810                 self.oldcolormap = 0;
1811         }
1812         PutClientInServer();
1813 }
1814
1815 void play_countdown(float finished, string samp)
1816 {
1817         if(clienttype(self) == CLIENTTYPE_REAL)
1818                 if(floor(finished - time - frametime) != floor(finished - time))
1819                         if(finished - time < 6)
1820                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1821 }
1822
1823 /**
1824  * When sv_timeout is used this function returs strings like
1825  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1826  * Called by centerprint functions
1827  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1828  */
1829 string getTimeoutText(float addOneSecond) {
1830         if (!cvar("sv_timeout") || !timeoutStatus)
1831                 return "";
1832
1833         local string retStr;
1834         if (timeoutStatus == 1) {
1835                 if (addOneSecond == 1) {
1836                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1837                 }
1838                 else {
1839                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1840                 }
1841                 return retStr;
1842         }
1843         else if (timeoutStatus == 2) {
1844                 if (addOneSecond) {
1845                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1846                         //don't show messages like "Timeout ends in 0 seconds"...
1847                         if ((remainingTimeoutTime + 1) > 0)
1848                                 return retStr;
1849                         else
1850                                 return "";
1851                 }
1852                 else {
1853                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1854                         //don't show messages like "Timeout ends in 0 seconds"...
1855                         if (remainingTimeoutTime > 0)
1856                                 return retStr;
1857                         else
1858                                 return "";
1859                 }
1860         }
1861         else return "";
1862 }
1863
1864 void player_powerups (void)
1865 {
1866         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1867         {
1868                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1869                 self.modelflags |= MF_ROCKET;
1870         }
1871         else
1872         {
1873                 SoundEntity_StopSound(self, CHAN_PLAYER);
1874                 self.modelflags &~= MF_ROCKET;
1875         }
1876
1877         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1878
1879         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1880                 return;
1881
1882         Fire_ApplyDamage(self);
1883         Fire_ApplyEffect(self);
1884
1885         if (g_minstagib)
1886         {
1887                 self.effects |= EF_FULLBRIGHT;
1888
1889                 if (self.items & IT_STRENGTH)
1890                 {
1891                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1892                         if (time > self.strength_finished)
1893                         {
1894                                 self.alpha = default_player_alpha;
1895                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1896                                 self.items &~= IT_STRENGTH;
1897                                 sprint(self, "^3Invisibility has worn off\n");
1898                         }
1899                 }
1900                 else
1901                 {
1902                         if (time < self.strength_finished)
1903                         {
1904                                 self.alpha = g_minstagib_invis_alpha;
1905                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1906                                 self.items |= IT_STRENGTH;
1907                                 sprint(self, "^3You are invisible\n");
1908                         }
1909                 }
1910
1911                 if (self.items & IT_INVINCIBLE)
1912                 {
1913                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1914                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1915                         {
1916                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1917                                 sprint(self, "^3Speed has worn off\n");
1918                         }
1919                 }
1920                 else
1921                 {
1922                         if (time < self.invincible_finished)
1923                         {
1924                                 self.items = self.items | IT_INVINCIBLE;
1925                                 sprint(self, "^3You are on speed\n");
1926                         }
1927                 }
1928                 return;
1929         }
1930
1931         if (self.items & IT_STRENGTH)
1932         {
1933                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1934                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1935                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1936                 {
1937                         self.items = self.items - (self.items & IT_STRENGTH);
1938                         sprint(self, "^3Strength has worn off\n");
1939                 }
1940         }
1941         else
1942         {
1943                 if (time < self.strength_finished)
1944                 {
1945                         self.items = self.items | IT_STRENGTH;
1946                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1947                 }
1948         }
1949         if (self.items & IT_INVINCIBLE)
1950         {
1951                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1952                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1953                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1954                 {
1955                         self.items = self.items - (self.items & IT_INVINCIBLE);
1956                         sprint(self, "^3Shield has worn off\n");
1957                 }
1958         }
1959         else
1960         {
1961                 if (time < self.invincible_finished)
1962                 {
1963                         self.items = self.items | IT_INVINCIBLE;
1964                         sprint(self, "^3Shield surrounds you\n");
1965                 }
1966         }
1967
1968         if(cvar("g_nodepthtestplayers"))
1969                 self.effects = self.effects | EF_NODEPTHTEST;
1970
1971         if(cvar("g_fullbrightplayers"))
1972                 self.effects = self.effects | EF_FULLBRIGHT;
1973
1974         // midair gamemode: damage only while in the air
1975         // if in midair mode, being on ground grants temporary invulnerability
1976         // (this is so that multishot weapon don't clear the ground flag on the
1977         // first damage in the frame, leaving the player vulnerable to the
1978         // remaining hits in the same frame)
1979         if (self.flags & FL_ONGROUND)
1980         if (g_midair)
1981                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1982
1983         if (time >= game_starttime)
1984         if (time < self.spawnshieldtime)
1985                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1986 }
1987
1988 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1989 {
1990         if(current > stable)
1991                 return current;
1992         else if(current > stable - 0.25) // when close enough, "snap"
1993                 return stable;
1994         else
1995                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1996 }
1997
1998 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1999 {
2000         if(current < stable)
2001                 return current;
2002         else if(current < stable + 0.25) // when close enough, "snap"
2003                 return stable;
2004         else
2005                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2006 }
2007
2008 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2009 {
2010         if(current > rotstable)
2011         {
2012                 if(rotframetime > 0)
2013                 {
2014                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2015                         current = max(rotstable, current - rotlinear * rotframetime);
2016                 }
2017         }
2018         else if(current < regenstable)
2019         {
2020                 if(regenframetime > 0)
2021                 {
2022                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2023                         current = min(regenstable, current + regenlinear * regenframetime);
2024                 }
2025         }
2026
2027         if(current > limit)
2028                 current = limit;
2029
2030         return current;
2031 }
2032
2033 void player_regen (void)
2034 {
2035         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2036         maxh = cvar("g_balance_health_rotstable");
2037         maxa = cvar("g_balance_armor_rotstable");
2038         maxf = cvar("g_balance_fuel_rotstable");
2039         minh = cvar("g_balance_health_regenstable");
2040         mina = cvar("g_balance_armor_regenstable");
2041         minf = cvar("g_balance_fuel_regenstable");
2042         limith = cvar("g_balance_health_limit");
2043         limita = cvar("g_balance_armor_limit");
2044         limitf = cvar("g_balance_fuel_limit");
2045
2046         max_mod = regen_mod = rot_mod = limit_mod = 1;
2047
2048         if (self.runes & RUNE_REGEN)
2049         {
2050                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2051                 {
2052                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2053                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2054                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2055                 }
2056                 else
2057                 {
2058                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2059                         max_mod = cvar("g_balance_rune_regen_hpmod");
2060                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2061                 }
2062         }
2063         else if (self.runes & CURSE_VENOM)
2064         {
2065                 max_mod = cvar("g_balance_curse_venom_hpmod");
2066                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2067                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2068                 else
2069                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2070                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2071                 //if (!self.runes & RUNE_REGEN)
2072                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2073         }
2074         maxh = maxh * max_mod;
2075         //maxa = maxa * max_mod;
2076         //maxf = maxf * max_mod;
2077         minh = minh * max_mod;
2078         //mina = mina * max_mod;
2079         //minf = minf * max_mod;
2080         limith = limith * limit_mod;
2081         limita = limita * limit_mod;
2082         //limitf = limitf * limit_mod;
2083
2084         if(g_lms && g_ca)
2085                 rot_mod = 0;
2086
2087         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2088         {
2089                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2090                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2091
2092                 // if player rotted to death...  die!
2093                 if(self.health < 1)
2094                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2095         }
2096
2097         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2098                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2099 }
2100
2101 float zoomstate_set;
2102 void SetZoomState(float z)
2103 {
2104         if(z != self.zoomstate)
2105         {
2106                 self.zoomstate = z;
2107                 ClientData_Touch(self);
2108         }
2109         zoomstate_set = 1;
2110 }
2111
2112 void GetPressedKeys(void) {
2113         MUTATOR_CALLHOOK(GetPressedKeys);
2114         if (self.movement_x > 0) // get if movement keys are pressed
2115         {       // forward key pressed
2116                 self.pressedkeys |= KEY_FORWARD;
2117                 self.pressedkeys &~= KEY_BACKWARD;
2118         }
2119         else if (self.movement_x < 0)
2120         {       // backward key pressed
2121                 self.pressedkeys |= KEY_BACKWARD;
2122                 self.pressedkeys &~= KEY_FORWARD;
2123         }
2124         else
2125         {       // no x input
2126                 self.pressedkeys &~= KEY_FORWARD;
2127                 self.pressedkeys &~= KEY_BACKWARD;
2128         }
2129
2130         if (self.movement_y > 0)
2131         {       // right key pressed
2132                 self.pressedkeys |= KEY_RIGHT;
2133                 self.pressedkeys &~= KEY_LEFT;
2134         }
2135         else if (self.movement_y < 0)
2136         {       // left key pressed
2137                 self.pressedkeys |= KEY_LEFT;
2138                 self.pressedkeys &~= KEY_RIGHT;
2139         }
2140         else
2141         {       // no y input
2142                 self.pressedkeys &~= KEY_RIGHT;
2143                 self.pressedkeys &~= KEY_LEFT;
2144         }
2145
2146         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2147                 self.pressedkeys |= KEY_JUMP;
2148         else
2149                 self.pressedkeys &~= KEY_JUMP;
2150         if (self.BUTTON_CROUCH)
2151                 self.pressedkeys |= KEY_CROUCH;
2152         else
2153                 self.pressedkeys &~= KEY_CROUCH;
2154 }
2155
2156 void update_stats (float number, float hit, float fired) {
2157 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2158 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2159
2160         if(number) {
2161                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2162                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2163         } else {
2164                 self.stat_hit = hit * sv_accuracy_data_share;
2165                 self.stat_fired = fired * sv_accuracy_data_share;
2166         }
2167 }
2168
2169 /*
2170 ======================
2171 spectate mode routines
2172 ======================
2173 */
2174
2175 .float weapon_count;
2176 void SpectateCopy(entity spectatee) {
2177         if(spectatee.weapon_count < WEP_LAST) {
2178                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2179                 spectatee.weapon_count ++;
2180         } else
2181                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2182
2183         other = spectatee;
2184         MUTATOR_CALLHOOK(SpectateCopy);
2185         self.armortype = spectatee.armortype;
2186         self.armorvalue = spectatee.armorvalue;
2187         self.ammo_cells = spectatee.ammo_cells;
2188         self.ammo_shells = spectatee.ammo_shells;
2189         self.ammo_nails = spectatee.ammo_nails;
2190         self.ammo_rockets = spectatee.ammo_rockets;
2191         self.ammo_fuel = spectatee.ammo_fuel;
2192         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2193         self.health = spectatee.health;
2194         self.impulse = 0;
2195         self.items = spectatee.items;
2196         self.metertime = spectatee.metertime;
2197         self.strength_finished = spectatee.strength_finished;
2198         self.invincible_finished = spectatee.invincible_finished;
2199         self.pressedkeys = spectatee.pressedkeys;
2200         self.weapons = spectatee.weapons;
2201         self.switchweapon = spectatee.switchweapon;
2202         self.weapon = spectatee.weapon;
2203         self.punchangle = spectatee.punchangle;
2204         self.view_ofs = spectatee.view_ofs;
2205         self.v_angle = spectatee.v_angle;
2206         self.velocity = spectatee.velocity;
2207         self.dmg_take = spectatee.dmg_take;
2208         self.dmg_save = spectatee.dmg_save;
2209         self.dmg_inflictor = spectatee.dmg_inflictor;
2210         self.angles = spectatee.v_angle;
2211         self.fixangle = TRUE;
2212         setorigin(self, spectatee.origin);
2213         setsize(self, spectatee.mins, spectatee.maxs);
2214         SetZoomState(spectatee.zoomstate);
2215
2216         anticheat_spectatecopy(spectatee);
2217 }
2218
2219 float SpectateUpdate() {
2220         if(!self.enemy)
2221                 return 0;
2222
2223         if (self == self.enemy)
2224                 return 0;
2225
2226         if(self.enemy.classname != "player")
2227                 return 0;
2228
2229         SpectateCopy(self.enemy);
2230
2231         return 1;
2232 }
2233
2234 float SpectateNext() {
2235         other = find(self.enemy, classname, "player");
2236
2237         if (!other)
2238                 other = find(other, classname, "player");
2239
2240         if (other)
2241                 self.enemy = other;
2242
2243         if(self.enemy.classname == "player") {
2244                 msg_entity = self;
2245                 WriteByte(MSG_ONE, SVC_SETVIEW);
2246                 WriteEntity(MSG_ONE, self.enemy);
2247                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2248                 self.movetype = MOVETYPE_NONE;
2249
2250                 self.enemy.weapon_count = 0;
2251
2252                 if(!SpectateUpdate())
2253                         PutObserverInServer();
2254
2255                 return 1;
2256         } else {
2257                 return 0;
2258         }
2259 }
2260
2261 /*
2262 =============
2263 ShowRespawnCountdown()
2264
2265 Update a respawn countdown display.
2266 =============
2267 */
2268 void ShowRespawnCountdown()
2269 {
2270         float number;
2271         if(self.deadflag == DEAD_NO) // just respawned?
2272                 return;
2273         else
2274         {
2275                 number = ceil(self.death_time - time);
2276                 if(number <= 0)
2277                         return;
2278                 if(number <= self.respawn_countdown)
2279                 {
2280                         self.respawn_countdown = number - 1;
2281                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2282                                 AnnounceTo(self, strcat(ftos(number), ""));
2283                 }
2284         }
2285 }
2286
2287 void LeaveSpectatorMode()
2288 {
2289         if(isJoinAllowed()) {
2290                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2291                         self.classname = "player";
2292
2293                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2294                                 JoinBestTeam(self, FALSE, TRUE);
2295
2296                         if(cvar("g_campaign"))
2297                                 campaign_bots_may_start = 1;
2298
2299                         self.stat_count = WEP_LAST;
2300
2301                         PutClientInServer();
2302
2303                         if(self.classname == "player")
2304                                 bprint ("^4", self.netname, "^4 is playing now\n");
2305
2306                         if(!cvar("g_campaign"))
2307                                 centerprint(self,""); // clear MOTD
2308
2309                         return;
2310                 } else {
2311                         if (g_ca && self.caplayer) {
2312                         }       // do nothing
2313                         else
2314                                 stuffcmd(self,"menu_showteamselect\n");
2315                         return;
2316                 }
2317         }
2318         else {
2319                 //player may not join because of g_maxplayers is set
2320                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2321         }
2322 }
2323
2324 /**
2325  * Determines whether the player is allowed to join. This depends on cvar
2326  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2327  * it checks whether the number of currently playing players exceeds g_maxplayers.
2328  * @return bool TRUE if the player is allowed to join, false otherwise
2329  */
2330 float isJoinAllowed() {
2331         if (!cvar("g_maxplayers"))
2332                 return TRUE;
2333
2334         local entity e;
2335         local float currentlyPlaying;
2336         FOR_EACH_REALPLAYER(e) {
2337                 if(e.classname == "player")
2338                         currentlyPlaying += 1;
2339         }
2340         if(currentlyPlaying < cvar("g_maxplayers"))
2341                 return TRUE;
2342
2343         return FALSE;
2344 }
2345
2346 /**
2347  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2348  * g_maxplayers_spectator_blocktime seconds
2349  */
2350 void checkSpectatorBlock() {
2351         if(self.classname == "spectator" || self.classname == "observer") {
2352                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2353                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2354                         dropclient(self);
2355                 }
2356         }
2357 }
2358
2359 float vercmp_recursive(string v1, string v2)
2360 {
2361         float dot1, dot2;
2362         string s1, s2;
2363         float r;
2364
2365         dot1 = strstrofs(v1, ".", 0);
2366         dot2 = strstrofs(v2, ".", 0);
2367         if(dot1 == -1)
2368                 s1 = v1;
2369         else
2370                 s1 = substring(v1, 0, dot1);
2371         if(dot2 == -1)
2372                 s2 = v2;
2373         else
2374                 s2 = substring(v2, 0, dot2);
2375
2376         r = stof(s1) - stof(s2);
2377         if(r != 0)
2378                 return r;
2379
2380         r = strcasecmp(s1, s2);
2381         if(r != 0)
2382                 return r;
2383
2384         if(dot1 == -1)
2385                 if(dot2 == -1)
2386                         return 0;
2387                 else
2388                         return -1;
2389         else
2390                 if(dot2 == -1)
2391                         return 1;
2392                 else
2393                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2394 }
2395
2396 float vercmp(string v1, string v2)
2397 {
2398         if(strcasecmp(v1, v2) == 0) // early out check
2399                 return 0;
2400         return vercmp_recursive(v1, v2);
2401 }
2402
2403 void ObserverThink()
2404 {
2405         if (self.flags & FL_JUMPRELEASED) {
2406                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2407                         self.welcomemessage_time = 0;
2408                         self.flags &~= FL_JUMPRELEASED;
2409                         self.flags |= FL_SPAWNING;
2410                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2411                         self.welcomemessage_time = 0;
2412                         self.flags &~= FL_JUMPRELEASED;
2413                         if(SpectateNext() == 1) {
2414                                 self.classname = "spectator";
2415                         }
2416                 }
2417         } else {
2418                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2419                         self.flags |= FL_JUMPRELEASED;
2420                         if(self.flags & FL_SPAWNING)
2421                         {
2422                                 self.flags &~= FL_SPAWNING;
2423                                 LeaveSpectatorMode();
2424                                 return;
2425                         }
2426                 }
2427         }
2428         PrintWelcomeMessage(self);
2429 }
2430
2431 void SpectatorThink()
2432 {
2433         if (self.flags & FL_JUMPRELEASED) {
2434                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2435                         self.welcomemessage_time = 0;
2436                         self.flags &~= FL_JUMPRELEASED;
2437                         self.flags |= FL_SPAWNING;
2438                 } else if(self.BUTTON_ATCK) {
2439                         self.welcomemessage_time = 0;
2440                         self.flags &~= FL_JUMPRELEASED;
2441                         if(SpectateNext() == 1) {
2442                                 self.classname = "spectator";
2443                         } else {
2444                                 self.classname = "observer";
2445                                 self.stat_count = WEP_LAST;
2446                                 PutClientInServer();
2447                         }
2448                 } else if (self.BUTTON_ATCK2) {
2449                         self.welcomemessage_time = 0;
2450                         self.flags &~= FL_JUMPRELEASED;
2451                         self.classname = "observer";
2452                         self.stat_count = WEP_LAST;
2453                         PutClientInServer();
2454                 } else {
2455                         if(!SpectateUpdate())
2456                                 PutObserverInServer();
2457                 }
2458         } else {
2459                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2460                         self.flags |= FL_JUMPRELEASED;
2461                         if(self.flags & FL_SPAWNING)
2462                         {
2463                                 self.flags &~= FL_SPAWNING;
2464                                 LeaveSpectatorMode();
2465                                 return;
2466                         }
2467                 }
2468         }
2469
2470         PrintWelcomeMessage(self);
2471         self.flags |= FL_CLIENT | FL_NOTARGET;
2472 }
2473
2474 .float touchexplode_time;
2475
2476 /*
2477 =============
2478 PlayerPreThink
2479
2480 Called every frame for each client before the physics are run
2481 =============
2482 */
2483 void() ctf_setstatus;
2484 void() nexball_setstatus;
2485 .float items_added;
2486 void PlayerPreThink (void)
2487 {
2488         self.stat_game_starttime = game_starttime;
2489         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2490         self.stat_leadlimit = cvar("leadlimit");
2491
2492         if(frametime)
2493         {
2494                 // physics frames: update anticheat stuff
2495                 anticheat_prethink();
2496         }
2497
2498         if(blockSpectators && frametime)
2499                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2500                 checkSpectatorBlock();
2501
2502         zoomstate_set = 0;
2503
2504         if(self.netname_previous != self.netname)
2505         {
2506                 if(cvar("sv_eventlog"))
2507                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2508                 if(self.netname_previous)
2509                         strunzone(self.netname_previous);
2510                 self.netname_previous = strzone(self.netname);
2511         }
2512
2513         // version nagging
2514         if(self.version_nagtime)
2515                 if(self.cvar_g_xonoticversion)
2516                         if(time > self.version_nagtime)
2517                         {
2518                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2519                                 {
2520                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2521                                         {
2522                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2523                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2524                                         }
2525                                         else
2526                                         {
2527                                                 float r;
2528                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2529                                                 if(r < 0)
2530                                                 {
2531                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2532                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2533                                                 }
2534                                                 else if(r > 0)
2535                                                 {
2536                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2537                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2538                                                 }
2539                                         }
2540                                 }
2541                                 self.version_nagtime = 0;
2542                         }
2543
2544         // GOD MODE info
2545         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2546         {
2547                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2548                 self.max_armorvalue = 0;
2549         }
2550
2551 #ifdef TETRIS
2552         if (TetrisPreFrame())
2553                 return;
2554 #endif
2555
2556         MUTATOR_CALLHOOK(PlayerPreThink);
2557
2558         if(self.classname == "player") {
2559 //              if(self.netname == "Wazat")
2560 //                      bprint(self.classname, "\n");
2561
2562                 CheckRules_Player();
2563
2564                 PrintWelcomeMessage(self);
2565
2566                 if (intermission_running)
2567                 {
2568                         IntermissionThink ();   // otherwise a button could be missed between
2569                         return;                                 // the think tics
2570                 }
2571
2572                 if(self.teleport_time)
2573                 if(time > self.teleport_time)
2574                 {
2575                         self.teleport_time = 0;
2576                         self.effects = self.effects - (self.effects & EF_NODRAW);
2577                 }
2578
2579                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2580                         UpdateSelectedPlayer();
2581
2582                 //don't allow the player to turn around while game is paused!
2583                 if(timeoutStatus == 2) {
2584                         self.v_angle = self.lastV_angle;
2585                         self.angles = self.lastV_angle;
2586                         self.fixangle = TRUE;
2587                 }
2588
2589                 if(frametime)
2590                 {
2591                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2592                         player_powerups();
2593                 }
2594
2595                 if (self.deadflag != DEAD_NO)
2596                 {
2597                         float button_pressed, force_respawn;
2598                         if(self.personal && g_race_qualifying)
2599                         {
2600                                 if(time > self.death_time)
2601                                 {
2602                                         self.death_time = time + 1; // only retry once a second
2603                                         respawn();
2604                                         self.impulse = 141;
2605                                 }
2606                         }
2607                         else
2608                         {
2609                                 if(frametime)
2610                                         player_anim();
2611                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2612                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2613                                 if (self.deadflag == DEAD_DYING)
2614                                 {
2615                                         if(force_respawn)
2616                                                 self.deadflag = DEAD_RESPAWNING;
2617                                         else if(!button_pressed)
2618                                                 self.deadflag = DEAD_DEAD;
2619                                 }
2620                                 else if (self.deadflag == DEAD_DEAD)
2621                                 {
2622                                         if(button_pressed)
2623                                                 self.deadflag = DEAD_RESPAWNABLE;
2624                                 }
2625                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2626                                 {
2627                                         if(!button_pressed)
2628                                                 self.deadflag = DEAD_RESPAWNING;
2629                                 }
2630                                 else if (self.deadflag == DEAD_RESPAWNING)
2631                                 {
2632                                         if(time > self.death_time)
2633                                         {
2634                                                 self.death_time = time + 1; // only retry once a second
2635                                                 respawn();
2636                                         }
2637                                 }
2638                                 ShowRespawnCountdown();
2639                         }
2640                         return;
2641                 }
2642
2643                 if(g_touchexplode)
2644                 if(time > self.touchexplode_time)
2645                 if(self.classname == "player")
2646                 if(self.deadflag == DEAD_NO)
2647                 if not(IS_INDEPENDENT_PLAYER(self))
2648                 FOR_EACH_PLAYER(other) if(self != other)
2649                 {
2650                         if(time > other.touchexplode_time)
2651                         if(other.classname == "player")
2652                         if(other.deadflag == DEAD_NO)
2653                         if not(IS_INDEPENDENT_PLAYER(other))
2654                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2655                         {
2656                                 PlayerTouchExplode(self, other);
2657                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2658                         }
2659                 }
2660
2661                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2662                 {
2663                         vector dist;
2664
2665                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2666                         dist = self.prevorigin - self.origin;
2667                         dist_z = 0;
2668                         self.lms_traveled_distance += fabs(vlen(dist));
2669
2670                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2671                         {
2672                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2673                                 self.lms_traveled_distance = 0;
2674                         }
2675
2676                         if(time > self.lms_nextcheck)
2677                         {
2678                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2679                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2680                                 {
2681                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2682                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2683                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2684                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2685                                 }
2686                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2687                                 self.lms_traveled_distance = 0;
2688                         }
2689                 }
2690
2691                 self.prevorigin = self.origin;
2692
2693                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2694                 {
2695                         if (!self.crouch)
2696                         {
2697                                 self.crouch = TRUE;
2698                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2699                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2700                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2701                         }
2702                 }
2703                 else
2704                 {
2705                         if (self.crouch)
2706                         {
2707                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2708                                 if (!trace_startsolid)
2709                                 {
2710                                         self.crouch = FALSE;
2711                                         self.view_ofs = PL_VIEW_OFS;
2712                                         setsize (self, PL_MIN, PL_MAX);
2713                                 }
2714                         }
2715                 }
2716
2717                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2718                 {
2719                         if(self.bloodloss_timer < time)
2720                         {
2721                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2722                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2723                         }
2724                 }
2725
2726                 FixPlayermodel();
2727
2728                 GrapplingHookFrame();
2729
2730                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2731                 //if(frametime)
2732                 {
2733                         self.items &~= self.items_added;
2734
2735                         W_WeaponFrame();
2736
2737                         self.items_added = 0;
2738                         if(self.items & IT_JETPACK)
2739                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2740                                         self.items_added |= IT_FUEL;
2741
2742                         self.items |= self.items_added;
2743                 }
2744
2745                 player_regen();
2746                 if(frametime)
2747                         player_anim();
2748
2749                 if (g_minstagib)
2750                         minstagib_ammocheck();
2751
2752                 ctf_setstatus();
2753                 nexball_setstatus();
2754
2755                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2756
2757                 //self.angles_y=self.v_angle_y + 90;   // temp
2758         } else if(gameover) {
2759                 if (intermission_running)
2760                         IntermissionThink ();   // otherwise a button could be missed between
2761                 return;
2762         } else if(self.classname == "observer") {
2763                 ObserverThink();
2764         } else if(self.classname == "spectator") {
2765                 SpectatorThink();
2766         }
2767
2768         if(!zoomstate_set)
2769                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2770
2771         float oldspectatee_status;
2772         oldspectatee_status = self.spectatee_status;
2773         if(self.classname == "spectator")
2774                 self.spectatee_status = num_for_edict(self.enemy);
2775         else if(self.classname == "observer")
2776                 self.spectatee_status = num_for_edict(self);
2777         else
2778                 self.spectatee_status = 0;
2779         if(self.spectatee_status != oldspectatee_status)
2780         {
2781                 ClientData_Touch(self);
2782                 if(g_race || g_cts)
2783                         race_InitSpectator();
2784         }
2785
2786         if(self.teamkill_soundtime)
2787         if(time > self.teamkill_soundtime)
2788         {
2789                 self.teamkill_soundtime = 0;
2790
2791                 entity oldpusher, oldself;
2792
2793                 oldself = self; self = self.teamkill_soundsource;
2794                 oldpusher = self.pusher; self.pusher = oldself;
2795
2796                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2797
2798                 self.pusher = oldpusher;
2799                 self = oldself;
2800         }
2801
2802         if(self.taunt_soundtime)
2803         if(time > self.taunt_soundtime)
2804         {
2805                 self.taunt_soundtime = 0;
2806                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2807         }
2808
2809         target_voicescript_next(self);
2810 }
2811
2812 float isInvisibleString(string s)
2813 {
2814         float i, n, c;
2815         s = strdecolorize(s);
2816         for((i = 0), (n = strlen(s)); i < n; ++i)
2817         {
2818                 c = str2chr(s, i);
2819                 switch(c)
2820                 {
2821                         case 0:
2822                         case 32:
2823                         case 160:
2824                                 break;
2825                         default:
2826                                 return FALSE;
2827                 }
2828         }
2829         return TRUE;
2830 }
2831
2832 /*
2833 =============
2834 PlayerPostThink
2835
2836 Called every frame for each client after the physics are run
2837 =============
2838 */
2839 .float idlekick_lasttimeleft;
2840 void PlayerPostThink (void)
2841 {
2842         // Savage: Check for nameless players
2843         if (isInvisibleString(self.netname)) {
2844                 self.netname = "Player";
2845                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2846         }
2847
2848         // send the clients accuracy stats to the client
2849         if(self.stat_count > 0)
2850         if(frametime)
2851         {
2852                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2853                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2854                 self.stat_count -= 1;
2855         }
2856
2857 #ifdef UID
2858         if(self.uid_kicktime)
2859         if(time > self.uid_kicktime)
2860         {
2861                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2862                 dropclient(self);
2863                 return;
2864         }
2865 #endif
2866
2867         if(sv_maxidle && frametime)
2868         {
2869                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2870                 float timeleft;
2871                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2872                 if(timeleft <= 0)
2873                 {
2874                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2875                         AnnounceTo(self, "terminated");
2876                         dropclient(self);
2877                         return;
2878                 }
2879                 else if(timeleft <= 10)
2880                 {
2881                         if(timeleft != self.idlekick_lasttimeleft)
2882                         {
2883                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2884                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2885                         }
2886                 }
2887                 else
2888                 {
2889                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2890                 }
2891                 self.idlekick_lasttimeleft = timeleft;
2892         }
2893
2894 #ifdef TETRIS
2895         if(self.impulse == 100)
2896                 ImpulseCommands();
2897         if (TetrisPostFrame())
2898                 return;
2899 #endif
2900
2901         CheatFrame();
2902
2903         if(self.classname == "player") {
2904                 CheckRules_Player();
2905                 UpdateChatBubble();
2906                 UpdateTeamBubble();
2907                 if (self.impulse)
2908                         ImpulseCommands();
2909                 if (intermission_running)
2910                         return;         // intermission or finale
2911                 GetPressedKeys();
2912         } else if (self.classname == "observer") {
2913                 //do nothing
2914         } else if (self.classname == "spectator") {
2915                 //do nothing
2916         }
2917
2918         /*
2919         float i;
2920         for(i = 0; i < 1000; ++i)
2921         {
2922                 vector end;
2923                 end = self.origin + '0 0 1024' + 512 * randomvec();
2924                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2925                 if(trace_fraction < 1)
2926                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2927                 {
2928                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2929                         break;
2930                 }
2931         }
2932         */
2933
2934         Arena_Warmup();
2935
2936         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2937
2938         if(self.waypointsprite_attachedforcarrier)
2939                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2940
2941         playerdemo_write();
2942
2943         /*
2944         if(g_race)
2945                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2946         */
2947 }