qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         if (g_minstagib)
 618                 minstagib_stop_countdown();
 619
 620         Portal_ClearAll(self);
 621
 622         if(self.alivetime)
 623         {
 624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                 self.alivetime = 0;
 626         }
 627
 628         if(self.vehicle)
 629             vehicles_exit(VHEF_RELESE);
 630
 631         if(self.flagcarried)
 632                 DropFlag(self.flagcarried, world, world);
 633
 634         if(self.ballcarried && g_nexball)
 635                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 636
 637         WaypointSprite_PlayerDead();
 638
 639         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 640                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 641
 642         if(self.killcount != -666) {
 643                 if(g_lms) {
 644                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 645                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 646                         else
 647                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 648                 } else
 649                         bprint ("^4", self.netname, "^4 is spectating now\n");
 650
 651                 if(self.just_joined == FALSE) {
 652                         LogTeamchange(self.playerid, -1, 4);
 653                 } else
 654                         self.just_joined = FALSE;
 655         }
 656
 657         PlayerScore_Clear(self); // clear scores when needed
 658
 659         accuracy_resend(self);
 660
 661         self.spectatortime = time;
 662
 663         self.classname = "observer";
 664         self.iscreature = FALSE;
 665         self.health = -666;
 666         self.takedamage = DAMAGE_NO;
 667         self.solid = SOLID_NOT;
 668         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 669         self.flags = FL_CLIENT | FL_NOTARGET;
 670         self.armorvalue = 666;
 671         self.effects = 0;
 672         self.armorvalue = autocvar_g_balance_armor_start;
 673         self.pauserotarmor_finished = 0;
 674         self.pauserothealth_finished = 0;
 675         self.pauseregen_finished = 0;
 676         self.damageforcescale = 0;
 677         self.death_time = 0;
 678         self.dead_frame = 0;
 679         self.alpha = 0;
 680         self.scale = 0;
 681         self.fade_time = 0;
 682         self.pain_frame = 0;
 683         self.pain_finished = 0;
 684         self.strength_finished = 0;
 685         self.invincible_finished = 0;
 686         self.pushltime = 0;
 687         self.think = SUB_Null;
 688         self.nextthink = 0;
 689         self.hook_time = 0;
 690         self.runes = 0;
 691         self.deadflag = DEAD_NO;
 692         self.angles = spot.angles;
 693         self.angles_z = 0;
 694         self.fixangle = TRUE;
 695         self.crouch = FALSE;
 696
 697         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 698         setorigin (self, spot.origin);
 699         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 700         self.prevorigin = self.origin;
 701         self.items = 0;
 702         self.weapons = 0;
 703         self.model = "";
 704         FixPlayermodel();
 705         self.model = "";
 706         self.modelindex = 0;
 707         self.weapon = 0;
 708         self.weaponname = "";
 709         self.switchingweapon = 0;
 710         self.weaponmodel = "";
 711         self.weaponentity = world;
 712         self.exteriorweaponentity = world;
 713         self.killcount = -666;
 714         self.velocity = '0 0 0';
 715         self.avelocity = '0 0 0';
 716         self.punchangle = '0 0 0';
 717         self.punchvector = '0 0 0';
 718         self.oldvelocity = self.velocity;
 719         self.fire_endtime = -1;
 720
 721         if(sv_loddistance1)
 722                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 723
 724         if(g_arena)
 725         {
 726                 if(self.version_mismatch)
 727                 {
 728                         Spawnqueue_Unmark(self);
 729                         Spawnqueue_Remove(self);
 730                 }
 731                 else
 732                 {
 733                         Spawnqueue_Insert(self);
 734                 }
 735         }
 736         else if(g_lms)
 737         {
 738                 // Only if the player cannot play at all
 739                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 740                         self.frags = FRAGS_SPECTATOR;
 741                 else
 742                         self.frags = FRAGS_LMS_LOSER;
 743         }
 744         else if(g_ca)
 745         {
 746                 if(self.caplayer)
 747                         self.frags = FRAGS_LMS_LOSER;
 748                 else
 749                         self.frags = FRAGS_SPECTATOR;
 750         }
 751         else
 752                 self.frags = FRAGS_SPECTATOR;
 753 }
 754
 755 void FixPlayermodel()
 756 {
 757         local string defaultmodel;
 758         local float defaultskin, chmdl, oldskin;
 759         local vector m1, m2;
 760
 761         defaultmodel = "";
 762
 763         if(autocvar_sv_defaultcharacter == 1) {
 764                 defaultskin = 0;
 765
 766                 if(teamplay)
 767                 {
 768                         string s;
 769                         s = Team_ColorNameLowerCase(self.team);
 770                         if(s != "neutral")
 771                         {
 772                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 773                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 774                         }
 775                 }
 776
 777                 if(defaultmodel == "")
 778                 {
 779                         defaultmodel = autocvar_sv_defaultplayermodel;
 780                         defaultskin = autocvar_sv_defaultplayerskin;
 781                 }
 782         }
 783
 784         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 785         {
 786                 if(self.model != "")
 787                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 788                 self.model = ""; // force the != checks to return true
 789         }
 790
 791         if(defaultmodel != "")
 792         {
 793                 if (defaultmodel != self.model)
 794                 {
 795                         m1 = self.mins;
 796                         m2 = self.maxs;
 797                         setmodel_lod (self, defaultmodel);
 798                         setsize (self, m1, m2);
 799                         chmdl = TRUE;
 800                 }
 801
 802                 oldskin = self.skinindex;
 803                 self.skinindex = defaultskin;
 804         } else {
 805                 if (self.playermodel != self.model || self.playermodel == "")
 806                 {
 807                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 808                         m1 = self.mins;
 809                         m2 = self.maxs;
 810                         setmodel_lod (self, self.playermodel);
 811                         setsize (self, m1, m2);
 812                         chmdl = TRUE;
 813                 }
 814
 815                 oldskin = self.skinindex;
 816                 self.skinindex = stof(self.playerskin);
 817         }
 818
 819         if(chmdl || oldskin != self.skinindex)
 820                 self.species = player_getspecies(); // model or skin has changed
 821
 822         if(!teamplay)
 823                 if(strlen(autocvar_sv_defaultplayercolors))
 824                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 825                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 826 }
 827
 828 void PlayerTouchExplode(entity p1, entity p2)
 829 {
 830         vector org;
 831         org = (p1.origin + p2.origin) * 0.5;
 832         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 833
 834         te_explosion(org);
 835
 836         entity e;
 837         e = spawn();
 838         setorigin(e, org);
 839         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 840         remove(e);
 841 }
 842
 843 /*
 844 =============
 845 PutClientInServer
 846
 847 Called when a client spawns in the server
 848 =============
 849 */
 850 //void() ctf_playerchanged;
 851 void PutClientInServer (void)
 852 {
 853         if(clienttype(self) == CLIENTTYPE_BOT)
 854         {
 855                 self.classname = "player";
 856         }
 857         else if(clienttype(self) == CLIENTTYPE_REAL)
 858         {
 859                 msg_entity = self;
 860                 WriteByte(MSG_ONE, SVC_SETVIEW);
 861                 WriteEntity(MSG_ONE, self);
 862         }
 863
 864         // reset player keys
 865         self.itemkeys = 0;
 866
 867         // player is dead and becomes observer
 868         // FIXME fix LMS scoring for new system
 869         if(g_lms)
 870         {
 871                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 872                         self.classname = "observer";
 873         }
 874
 875         if(g_arena || (g_ca && !allowed_to_spawn))
 876         if(!self.spawned)
 877                 self.classname = "observer";
 878
 879         if(gameover)
 880                 self.classname = "observer";
 881
 882         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 883                 entity spot, oldself;
 884                 float j;
 885
 886                 accuracy_resend(self);
 887
 888                 if(self.team < 0)
 889                         JoinBestTeam(self, FALSE, TRUE);
 890
 891                 race_PreSpawn();
 892
 893                 spot = SelectSpawnPoint (FALSE);
 894                 if(!spot)
 895                 {
 896                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 897                         return; // spawn failed
 898                 }
 899
 900                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 901
 902                 self.classname = "player";
 903                 self.wasplayer = TRUE;
 904                 self.iscreature = TRUE;
 905                 self.movetype = MOVETYPE_WALK;
 906                 self.solid = SOLID_SLIDEBOX;
 907                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 908                 if(autocvar_g_playerclip_collisions)
 909                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 910                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 911                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 912                 self.frags = FRAGS_PLAYER;
 913                 if(INDEPENDENT_PLAYERS)
 914                         MAKE_INDEPENDENT_PLAYER(self);
 915                 self.flags = FL_CLIENT;
 916                 self.takedamage = DAMAGE_AIM;
 917                 if(g_minstagib)
 918                         self.effects = EF_FULLBRIGHT;
 919                 else
 920                         self.effects = 0;
 921                 self.air_finished = time + 12;
 922                 self.dmg = 2;
 923                 if(autocvar_g_balance_nex_charge)
 924                 {
 925                         if(autocvar_g_balance_nex_secondary_chargepool)
 926                                 self.nex_chargepool_ammo = 1;
 927                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 928                 }
 929
 930                 if(inWarmupStage)
 931                 {
 932                         self.ammo_shells = warmup_start_ammo_shells;
 933                         self.ammo_nails = warmup_start_ammo_nails;
 934                         self.ammo_rockets = warmup_start_ammo_rockets;
 935                         self.ammo_cells = warmup_start_ammo_cells;
 936                         self.ammo_fuel = warmup_start_ammo_fuel;
 937                         self.health = warmup_start_health;
 938                         self.armorvalue = warmup_start_armorvalue;
 939                         self.weapons = warmup_start_weapons;
 940                 }
 941                 else
 942                 {
 943                         self.ammo_shells = start_ammo_shells;
 944                         self.ammo_nails = start_ammo_nails;
 945                         self.ammo_rockets = start_ammo_rockets;
 946                         self.ammo_cells = start_ammo_cells;
 947                         self.ammo_fuel = start_ammo_fuel;
 948                         self.health = start_health;
 949                         self.armorvalue = start_armorvalue;
 950                         self.weapons = start_weapons;
 951                 }
 952
 953                 if(g_weaponarena_random)
 954                 {
 955                         if(g_weaponarena_random_with_laser)
 956                                 self.weapons &~= WEPBIT_LASER;
 957                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 958                         if(g_weaponarena_random_with_laser)
 959                                 self.weapons |= WEPBIT_LASER;
 960                 }
 961
 962                 self.items = start_items;
 963                 self.jump_interval = time;
 964
 965                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 966                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 967                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 968                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 969                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 970                 //extend the pause of rotting if client was reset at the beginning of the countdown
 971                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 972                         self.spawnshieldtime += game_starttime - time;
 973                         self.pauserotarmor_finished += game_starttime - time;
 974                         self.pauserothealth_finished += game_starttime - time;
 975                         self.pauseregen_finished += game_starttime - time;
 976                 }
 977                 self.damageforcescale = 2;
 978                 self.death_time = 0;
 979                 self.dead_frame = 0;
 980                 self.alpha = 0;
 981                 self.scale = 0;
 982                 self.fade_time = 0;
 983                 self.pain_frame = 0;
 984                 self.pain_finished = 0;
 985                 self.strength_finished = 0;
 986                 self.invincible_finished = 0;
 987                 self.pushltime = 0;
 988                 // players have no think function
 989                 self.think = SUB_Null;
 990                 self.nextthink = 0;
 991                 self.hook_time = 0;
 992                 self.dmg_team = 0;
 993                 self.ballistics_density = autocvar_g_ballistics_density_player;
 994
 995                 self.metertime = 0;
 996
 997                 self.runes = 0;
 998
 999                 self.deadflag = DEAD_NO;
1000
1001                 self.angles = spot.angles;
1002
1003                 self.angles_z = 0; // never spawn tilted even if the spot says to
1004                 self.fixangle = TRUE; // turn this way immediately
1005                 self.velocity = '0 0 0';
1006                 self.avelocity = '0 0 0';
1007                 self.punchangle = '0 0 0';
1008                 self.punchvector = '0 0 0';
1009                 self.oldvelocity = self.velocity;
1010                 self.fire_endtime = -1;
1011
1012                 msg_entity = self;
1013                 WRITESPECTATABLE_MSG_ONE({
1014                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1015                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1016                 });
1017
1018                 if(sv_loddistance1)
1019                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1020
1021                 self.model = "";
1022                 FixPlayermodel();
1023
1024                 self.crouch = FALSE;
1025                 self.view_ofs = PL_VIEW_OFS;
1026                 setsize (self, PL_MIN, PL_MAX);
1027                 self.spawnorigin = spot.origin;
1028                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1029                 // don't reset back to last position, even if new position is stuck in solid
1030                 self.oldorigin = self.origin;
1031                 self.prevorigin = self.origin;
1032                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1033                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1034
1035                 if(g_arena)
1036                 {
1037                         Spawnqueue_Remove(self);
1038                         Spawnqueue_Mark(self);
1039                 }
1040
1041                 else if(g_ca)
1042                         self.caplayer = 1;
1043
1044                 self.event_damage = PlayerDamage;
1045
1046                 self.bot_attack = TRUE;
1047
1048                 self.statdraintime = time + 5;
1049                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1050
1051                 if(self.killcount == -666) {
1052                         PlayerScore_Clear(self);
1053                         self.killcount = 0;
1054                 }
1055
1056                 CL_SpawnWeaponentity();
1057                 self.alpha = default_player_alpha;
1058                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1059                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1060
1061                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1062                 self.lms_traveled_distance = 0;
1063                 self.speedrunning = FALSE;
1064
1065                 race_PostSpawn(spot);
1066
1067                 if(autocvar_spawn_debug)
1068                 {
1069                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1070                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1071                 }
1072
1073                 //stuffcmd(self, "chase_active 0");
1074                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1075
1076                 if (autocvar_g_spawnsound)
1077                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1078
1079                 if(g_assault) {
1080                         if(self.team == assault_attacker_team)
1081                                 centerprint(self, "You are attacking!");
1082                         else
1083                                 centerprint(self, "You are defending!");
1084                 }
1085
1086                 target_voicescript_clear(self);
1087
1088                 // reset fields the weapons may use
1089                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1090                 {
1091                         weapon_action(j, WR_RESETPLAYER);
1092
1093                         // all weapons must be fully loaded when we spawn
1094                         entity e;
1095                         e = get_weaponinfo(j);
1096                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1097                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1098                 }
1099
1100                 oldself = self;
1101                 self = spot;
1102                         activator = oldself;
1103                                 string s;
1104                                 s = self.target;
1105                                 self.target = string_null;
1106                                 SUB_UseTargets();
1107                                 self.target = s;
1108                         activator = world;
1109                 self = oldself;
1110
1111                 MUTATOR_CALLHOOK(PlayerSpawn);
1112
1113                 self.switchweapon = w_getbestweapon(self);
1114                 self.cnt = -1; // W_LastWeapon will not complain
1115                 self.weapon = 0;
1116                 self.weaponname = "";
1117                 self.switchingweapon = 0;
1118
1119                 if(!self.alivetime)
1120                         self.alivetime = time;
1121         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1122                 PutObserverInServer ();
1123         }
1124
1125         //if(g_ctf)
1126         //      ctf_playerchanged();
1127 }
1128
1129 .float ebouncefactor, ebouncestop; // electro's values
1130 // TODO do we need all these fields, or should we stop autodetecting runtime
1131 // changes and just have a console command to update this?
1132 float ClientInit_SendEntity(entity to, float sf)
1133 {
1134         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1135         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1136         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1137         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1138         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1139         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1140         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1141         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1142         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1143         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1144         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1145         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1146         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1147         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1148         if(sv_foginterval && world.fog != "")
1149                 WriteString(MSG_ENTITY, world.fog);
1150         else
1151                 WriteString(MSG_ENTITY, "");
1152         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1153         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1154         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1155         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1156         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1157         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1158         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1159         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1160         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1161         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1162         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1163         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1164         return TRUE;
1165 }
1166
1167 void ClientInit_CheckUpdate()
1168 {
1169         self.nextthink = time;
1170         if(self.count != autocvar_g_balance_armor_blockpercent)
1171         {
1172                 self.count = autocvar_g_balance_armor_blockpercent;
1173                 self.SendFlags |= 1;
1174         }
1175         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1176         {
1177                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1178                 self.SendFlags |= 1;
1179         }
1180         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1181         {
1182                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1183                 self.SendFlags |= 1;
1184         }
1185         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1186         {
1187                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1188                 self.SendFlags |= 1;
1189         }
1190         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1191         {
1192                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1193                 self.SendFlags |= 1;
1194         }
1195         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1196         {
1197                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1198                 self.SendFlags |= 1;
1199         }
1200 }
1201
1202 void ClientInit_Spawn()
1203 {
1204         entity o;
1205         entity e;
1206         e = spawn();
1207         e.classname = "clientinit";
1208         e.think = ClientInit_CheckUpdate;
1209         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1210
1211         o = self;
1212         self = e;
1213         ClientInit_CheckUpdate();
1214         self = o;
1215 }
1216
1217 /*
1218 =============
1219 SetNewParms
1220 =============
1221 */
1222 void SetNewParms (void)
1223 {
1224         // initialize parms for a new player
1225         parm1 = -(86400 * 366);
1226 }
1227
1228 /*
1229 =============
1230 SetChangeParms
1231 =============
1232 */
1233 void SetChangeParms (void)
1234 {
1235         // save parms for level change
1236         parm1 = self.parm_idlesince - time;
1237 }
1238
1239 /*
1240 =============
1241 DecodeLevelParms
1242 =============
1243 */
1244 void DecodeLevelParms (void)
1245 {
1246         // load parms
1247         self.parm_idlesince = parm1;
1248         if(self.parm_idlesince == -(86400 * 366))
1249                 self.parm_idlesince = time;
1250
1251         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1252         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1253 }
1254
1255 /*
1256 =============
1257 ClientKill
1258
1259 Called when a client types 'kill' in the console
1260 =============
1261 */
1262
1263 .float clientkill_nexttime;
1264 void ClientKill_Now_TeamChange()
1265 {
1266         if(self.killindicator_teamchange == -1)
1267         {
1268                 self.team = -1;
1269                 JoinBestTeam( self, FALSE, FALSE );
1270         }
1271         else if(self.killindicator_teamchange == -2)
1272         {
1273                 if(g_ca)
1274                         self.caplayer = 0;
1275                 if(blockSpectators)
1276                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1277                 PutObserverInServer();
1278         }
1279         else
1280                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1281 }
1282
1283 void ClientKill_Now()
1284 {
1285         if(self.vehicle)
1286         {
1287             vehicles_exit(VHEF_RELESE);
1288             if(!self.killindicator_teamchange)
1289             {
1290             self.vehicle_health = -1;
1291             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1292             }
1293         }
1294
1295         if(self.killindicator && !wasfreed(self.killindicator))
1296                 remove(self.killindicator);
1297
1298         self.killindicator = world;
1299
1300         if(self.killindicator_teamchange)
1301                 ClientKill_Now_TeamChange();
1302
1303         // in any case:
1304         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1305
1306         // now I am sure the player IS dead
1307 }
1308 void KillIndicator_Think()
1309 {
1310         if (gameover)
1311         {
1312                 self.owner.killindicator = world;
1313                 remove(self);
1314                 return;
1315         }
1316
1317         if (!self.owner.modelindex)
1318         {
1319                 self.owner.killindicator = world;
1320                 remove(self);
1321                 return;
1322         }
1323
1324         if(self.cnt <= 0)
1325         {
1326                 self = self.owner;
1327                 ClientKill_Now(); // no oldself needed
1328                 return;
1329         }
1330     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1331     {
1332         self.nextthink = time + 1;
1333         self.cnt -= 1;
1334     }
1335         else
1336         {
1337                 if(self.cnt <= 10)
1338                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1339                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1340                 {
1341                         if(self.cnt <= 10)
1342                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1343                 }
1344                 self.nextthink = time + 1;
1345                 self.cnt -= 1;
1346         }
1347 }
1348
1349 float clientkilltime;
1350 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1351 {
1352         float killtime;
1353         float starttime;
1354         entity e;
1355
1356         if (gameover)
1357                 return;
1358
1359         killtime = autocvar_g_balance_kill_delay;
1360
1361         if(g_race_qualifying || g_cts)
1362                 killtime = 0;
1363
1364     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1365     {
1366                 remove(self.killindicator);
1367                 self.killindicator = world;
1368
1369         ClientKill_Now(); // allow instant kill in this case
1370         return;
1371     }
1372
1373         self.killindicator_teamchange = targetteam;
1374
1375     if(!self.killindicator)
1376         {
1377                 if(self.modelindex && self.deadflag == DEAD_NO)
1378                 {
1379                         killtime = max(killtime, self.clientkill_nexttime - time);
1380                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1381                 }
1382
1383                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1384                 {
1385                         ClientKill_Now();
1386                 }
1387                 else
1388                 {
1389                         starttime = max(time, clientkilltime);
1390
1391                         self.killindicator = spawn();
1392                         self.killindicator.owner = self;
1393                         self.killindicator.scale = 0.5;
1394                         setattachment(self.killindicator, self, "");
1395                         setorigin(self.killindicator, '0 0 52');
1396                         self.killindicator.think = KillIndicator_Think;
1397                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1398                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1399                         self.killindicator.cnt = ceil(killtime);
1400                         self.killindicator.count = bound(0, ceil(killtime), 10);
1401                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1402
1403                         for(e = world; (e = find(e, classname, "body")) != world; )
1404                         {
1405                                 if(e.enemy != self)
1406                                         continue;
1407                                 e.killindicator = spawn();
1408                                 e.killindicator.owner = e;
1409                                 e.killindicator.scale = 0.5;
1410                                 setattachment(e.killindicator, e, "");
1411                                 setorigin(e.killindicator, '0 0 52');
1412                                 e.killindicator.think = KillIndicator_Think;
1413                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1414                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1415                                 e.killindicator.cnt = ceil(killtime);
1416                         }
1417                         self.lip = 0;
1418                 }
1419         }
1420         if(self.killindicator)
1421         {
1422                 if(targetteam == 0) // just die
1423                 {
1424                         self.killindicator.colormod = '0 0 0';
1425                         if(clienttype(self) == CLIENTTYPE_REAL)
1426                         if(self.killindicator.cnt > 0)
1427                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1428                 }
1429                 else if(targetteam == -1) // auto
1430                 {
1431                         self.killindicator.colormod = '0 1 0';
1432                         if(clienttype(self) == CLIENTTYPE_REAL)
1433                         if(self.killindicator.cnt > 0)
1434                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1435                 }
1436                 else if(targetteam == -2) // spectate
1437                 {
1438                         self.killindicator.colormod = '0.5 0.5 0.5';
1439                         if(clienttype(self) == CLIENTTYPE_REAL)
1440                         if(self.killindicator.cnt > 0)
1441                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1442                 }
1443                 else
1444                 {
1445                         self.killindicator.colormod = TeamColor(targetteam);
1446                         if(clienttype(self) == CLIENTTYPE_REAL)
1447                         if(self.killindicator.cnt > 0)
1448                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1449                 }
1450         }
1451
1452 }
1453
1454 void ClientKill (void)
1455 {
1456         if (gameover)
1457                 return;
1458
1459         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1460         {
1461                 // do nothing
1462         }
1463     else if(self.freezetag_frozen)
1464     {
1465         // do nothing
1466     }
1467         else
1468                 ClientKill_TeamChange(0);
1469 }
1470
1471 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1472 {
1473     e.killindicator = spawn();
1474     e.killindicator.owner = e;
1475     e.killindicator.think = KillIndicator_Think;
1476     e.killindicator.nextthink = time + (e.lip) * 0.05;
1477     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1478     e.killindicator.health = 1; // this is used to indicate that it should be silent
1479     e.lip = 0;
1480 }
1481
1482 void FixClientCvars(entity e)
1483 {
1484         // send prediction settings to the client
1485         stuffcmd(e, "\nin_bindmap 0 0\n");
1486         if(g_race || g_cts)
1487                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1488         if(autocvar_g_antilag == 3) // client side hitscan
1489                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1490         if(sv_gentle)
1491                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1492         /*
1493          * we no longer need to stuff this. Remove this comment block if you feel
1494          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1495         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1496         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1497         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1498         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1499         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1500         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1501         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1502         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1503         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1504         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1505         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1506         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1507         stuffcmd(e, "cl_movement_edgefriction 1\n");
1508          */
1509 }
1510
1511 float PlayerInIDList(entity p, string idlist)
1512 {
1513         float n, i;
1514         string s;
1515
1516         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1517         if not(p.crypto_idfp)
1518                 return 0;
1519
1520         // this function allows abbreviated player IDs too!
1521         n = tokenize_console(idlist);
1522         for(i = 0; i < n; ++i)
1523         {
1524                 s = argv(i);
1525                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1526                         return 1;
1527         }
1528
1529         return 0;
1530 }
1531
1532 /*
1533 =============
1534 ClientConnect
1535
1536 Called when a client connects to the server
1537 =============
1538 */
1539 //void ctf_clientconnect();
1540 string ColoredTeamName(float t);
1541 void DecodeLevelParms (void);
1542 //void dom_player_join_team(entity pl);
1543 void set_dom_state(entity e);
1544 void ClientConnect (void)
1545 {
1546         float t;
1547
1548         if(self.flags & FL_CLIENT)
1549         {
1550                 print("Warning: ClientConnect, but already connected!\n");
1551                 return;
1552         }
1553
1554         if(Ban_MaybeEnforceBan(self))
1555                 return;
1556
1557         DecodeLevelParms();
1558
1559 #ifdef WATERMARK
1560         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1561 #endif
1562
1563         self.classname = "player_joining";
1564
1565         self.flags = FL_CLIENT;
1566         self.version_nagtime = time + 10 + random() * 10;
1567
1568         if(player_count<0)
1569         {
1570                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1571                 player_count = 0;
1572         }
1573
1574         PlayerScore_Attach(self);
1575         ClientData_Attach();
1576         accuracy_init(self);
1577
1578         bot_clientconnect();
1579
1580         playerdemo_init();
1581
1582         anticheat_init();
1583
1584         race_PreSpawnObserver();
1585
1586         //if(g_domination)
1587         //      dom_player_join_team(self);
1588
1589         // identify the right forced team
1590         if(autocvar_g_campaign)
1591         {
1592                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1593                 {
1594                         switch(autocvar_g_campaign_forceteam)
1595                         {
1596                                 case 1: self.team_forced = COLOR_TEAM1; break;
1597                                 case 2: self.team_forced = COLOR_TEAM2; break;
1598                                 case 3: self.team_forced = COLOR_TEAM3; break;
1599                                 case 4: self.team_forced = COLOR_TEAM4; break;
1600                                 default: self.team_forced = 0;
1601                         }
1602                 }
1603         }
1604         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1605                 self.team_forced = COLOR_TEAM1;
1606         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1607                 self.team_forced = COLOR_TEAM2;
1608         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1609                 self.team_forced = COLOR_TEAM3;
1610         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1611                 self.team_forced = COLOR_TEAM4;
1612         else if(autocvar_g_forced_team_otherwise == "red")
1613                 self.team_forced = COLOR_TEAM1;
1614         else if(autocvar_g_forced_team_otherwise == "blue")
1615                 self.team_forced = COLOR_TEAM2;
1616         else if(autocvar_g_forced_team_otherwise == "yellow")
1617                 self.team_forced = COLOR_TEAM3;
1618         else if(autocvar_g_forced_team_otherwise == "pink")
1619                 self.team_forced = COLOR_TEAM4;
1620         else if(autocvar_g_forced_team_otherwise == "spectate")
1621                 self.team_forced = -1;
1622         else if(autocvar_g_forced_team_otherwise == "spectator")
1623                 self.team_forced = -1;
1624         else
1625                 self.team_forced = 0;
1626
1627         if(!teamplay)
1628                 if(self.team_forced > 0)
1629                         self.team_forced = 0;
1630
1631         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1632
1633         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1634                 self.classname = "observer";
1635         } else {
1636                 if(teamplay)
1637                 {
1638                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1639                         {
1640                                 self.classname = "player";
1641                                 campaign_bots_may_start = 1;
1642                         }
1643                         else
1644                         {
1645                                 self.classname = "observer"; // do it anyway
1646                         }
1647                 }
1648                 else
1649                 {
1650                         self.classname = "player";
1651                         campaign_bots_may_start = 1;
1652                 }
1653         }
1654
1655         self.playerid = (playerid_last = playerid_last + 1);
1656
1657         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1658
1659     if(clienttype(self) == CLIENTTYPE_BOT)
1660         PlayerStats_AddPlayer(self);
1661
1662         if(autocvar_sv_eventlog)
1663                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1664
1665         LogTeamchange(self.playerid, self.team, 1);
1666
1667         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1668
1669         self.netname_previous = strzone(self.netname);
1670
1671         bprint("^4", self.netname, "^4 connected");
1672
1673         if(self.classname != "observer" && (g_domination || g_ctf))
1674                 bprint(" and joined the ", ColoredTeamName(self.team));
1675
1676         bprint("\n");
1677
1678         stuffcmd(self, strcat(clientstuff, "\n"));
1679         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1680
1681         FixClientCvars(self);
1682
1683         // spawnfunc_waypoint sprites
1684         WaypointSprite_InitClient(self);
1685
1686         // Wazat's grappling hook
1687         SetGrappleHookBindings();
1688
1689         // get autoswitch state from player when he toggles it
1690         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1691
1692         // get version info from player
1693         stuffcmd(self, "cmd clientversion $gameversion\n");
1694
1695         // get other cvars from player
1696         GetCvars(0);
1697
1698         // notify about available teams
1699         if(teamplay)
1700         {
1701                 CheckAllowedTeams(self);
1702                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1703                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1704         }
1705         else
1706                 stuffcmd(self, "set _teams_available 0\n");
1707
1708         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1709
1710         if(g_arena || g_ca)
1711         {
1712                 self.classname = "observer";
1713                 if(g_arena)
1714                         Spawnqueue_Insert(self);
1715         }
1716         /*else if(g_ctf)
1717         {
1718                 ctf_clientconnect();
1719         }*/
1720
1721         attach_entcs();
1722
1723         bot_relinkplayerlist();
1724
1725         self.spectatortime = time;
1726         if(blockSpectators)
1727         {
1728                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1729         }
1730
1731         self.jointime = time;
1732         self.allowedTimeouts = autocvar_sv_timeout_number;
1733
1734         if(clienttype(self) == CLIENTTYPE_REAL)
1735         {
1736                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1737                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1738         }
1739
1740         if(g_lms)
1741         {
1742                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1743                 {
1744                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1745                         self.frags = FRAGS_SPECTATOR;
1746                 }
1747         }
1748
1749         if(!sv_foginterval && world.fog != "")
1750                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1751
1752         SoundEntity_Attach(self);
1753
1754         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1755         {
1756                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1757                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1758         }
1759         else
1760                 self.hitplotfh = -1;
1761
1762         if(g_race || g_cts) {
1763                 string rr;
1764                 if(g_cts)
1765                         rr = CTS_RECORD;
1766                 else
1767                         rr = RACE_RECORD;
1768                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1769
1770                 msg_entity = self;
1771                 race_send_recordtime(MSG_ONE);
1772                 race_send_speedaward(MSG_ONE);
1773
1774                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1775                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1776                 race_send_speedaward_alltimebest(MSG_ONE);
1777
1778                 float i;
1779                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1780                         race_SendRankings(i, 0, 0, MSG_ONE);
1781                 }
1782         }
1783         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1784                 send_CSQC_teamnagger();
1785
1786         if (g_domination)
1787                 set_dom_state(self);
1788
1789         CheatInitClient();
1790
1791         if(!autocvar_g_campaign)
1792                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1793 }
1794
1795 /*
1796 =============
1797 ClientDisconnect
1798
1799 Called when a client disconnects from the server
1800 =============
1801 */
1802 .entity chatbubbleentity;
1803 void ReadyCount();
1804 void ClientDisconnect (void)
1805 {
1806         if(self.vehicle)
1807             vehicles_exit(VHEF_RELESE);
1808
1809         if not(self.flags & FL_CLIENT)
1810         {
1811                 print("Warning: ClientDisconnect without ClientConnect\n");
1812                 return;
1813         }
1814
1815         PlayerStats_AddGlobalInfo(self);
1816
1817         CheatShutdownClient();
1818
1819         if(self.hitplotfh >= 0)
1820         {
1821                 fclose(self.hitplotfh);
1822                 self.hitplotfh = -1;
1823         }
1824
1825         anticheat_report();
1826         anticheat_shutdown();
1827
1828         playerdemo_shutdown();
1829
1830         bot_clientdisconnect();
1831
1832         if(self.entcs)
1833                 detach_entcs();
1834
1835         if(autocvar_sv_eventlog)
1836                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1837         bprint ("^4",self.netname);
1838         bprint ("^4 disconnected\n");
1839
1840         SoundEntity_Detach(self);
1841
1842         DropAllRunes(self);
1843         MUTATOR_CALLHOOK(ClientDisconnect);
1844
1845         Portal_ClearAll(self);
1846
1847         if(self.flagcarried)
1848                 DropFlag(self.flagcarried, world, world);
1849         if(self.ballcarried && g_nexball)
1850                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1851
1852         // Here, everything has been done that requires this player to be a client.
1853
1854         self.flags &~= FL_CLIENT;
1855
1856         if (self.chatbubbleentity)
1857                 remove (self.chatbubbleentity);
1858
1859         if (self.killindicator)
1860                 remove (self.killindicator);
1861
1862         WaypointSprite_PlayerGone();
1863
1864         bot_relinkplayerlist();
1865
1866         if(g_arena)
1867         {
1868                 Spawnqueue_Unmark(self);
1869                 Spawnqueue_Remove(self);
1870         }
1871
1872         accuracy_free(self);
1873         ClientData_Detach();
1874         PlayerScore_Detach(self);
1875
1876         if(self.netname_previous)
1877                 strunzone(self.netname_previous);
1878         if(self.clientstatus)
1879                 strunzone(self.clientstatus);
1880         if(self.weaponorder_byimpulse)
1881                 strunzone(self.weaponorder_byimpulse);
1882
1883         ClearPlayerSounds();
1884
1885         if(self.personal)
1886                 remove(self.personal);
1887
1888         self.playerid = 0;
1889         ReadyCount();
1890
1891         // free cvars
1892         GetCvars(-1);
1893 }
1894
1895 .float BUTTON_CHAT;
1896 void ChatBubbleThink()
1897 {
1898         self.nextthink = time;
1899         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1900         {
1901                 if(self.owner) // but why can that ever be world?
1902                         self.owner.chatbubbleentity = world;
1903                 remove(self);
1904                 return;
1905         }
1906         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1907 #ifdef TETRIS
1908                 || self.owner.tetris_on
1909 #endif
1910         )
1911                 self.model = self.mdl;
1912         else
1913                 self.model = "";
1914 };
1915
1916 void UpdateChatBubble()
1917 {
1918         if (!self.modelindex)
1919                 return;
1920         // spawn a chatbubble entity if needed
1921         if (!self.chatbubbleentity)
1922         {
1923                 self.chatbubbleentity = spawn();
1924                 self.chatbubbleentity.owner = self;
1925                 self.chatbubbleentity.exteriormodeltoclient = self;
1926                 self.chatbubbleentity.think = ChatBubbleThink;
1927                 self.chatbubbleentity.nextthink = time;
1928                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1929                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1930                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1931                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1932                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1933                 self.chatbubbleentity.model = "";
1934                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1935         }
1936 }
1937
1938
1939 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1940 // added to the model skins
1941 /*void UpdateColorModHack()
1942 {
1943         local float c;
1944         c = self.clientcolors & 15;
1945         // LordHavoc: only bothering to support white, green, red, yellow, blue
1946              if (!teamplay) self.colormod = '0 0 0';
1947         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1948         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1949         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1950         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1951         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1952         else self.colormod = '1 1 1';
1953 };*/
1954
1955 .float oldcolormap;
1956 void respawn(void)
1957 {
1958         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1959         {
1960                 self.solid = SOLID_NOT;
1961                 self.takedamage = DAMAGE_NO;
1962                 self.movetype = MOVETYPE_FLY;
1963                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1964                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1965                 self.effects |= EF_ADDITIVE;
1966                 self.oldcolormap = self.colormap;
1967                 self.colormap = 512;
1968                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1969                 if(autocvar_g_respawn_ghosts_maxtime)
1970                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1971         }
1972
1973         CopyBody(1);
1974         self.effects |= EF_NODRAW; // prevent another CopyBody
1975         if(self.oldcolormap)
1976         {
1977                 self.colormap = self.oldcolormap;
1978                 self.oldcolormap = 0;
1979         }
1980         PutClientInServer();
1981 }
1982
1983 void play_countdown(float finished, string samp)
1984 {
1985         if(clienttype(self) == CLIENTTYPE_REAL)
1986                 if(floor(finished - time - frametime) != floor(finished - time))
1987                         if(finished - time < 6)
1988                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1989 }
1990
1991 void player_powerups (void)
1992 {
1993         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1994         olditems = self.items;
1995
1996         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1997         {
1998                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1999                 self.modelflags |= MF_ROCKET;
2000         }
2001         else
2002         {
2003                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
2004                 self.modelflags &~= MF_ROCKET;
2005         }
2006
2007         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2008
2009         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2010                 return;
2011
2012         Fire_ApplyDamage(self);
2013         Fire_ApplyEffect(self);
2014
2015         if (g_minstagib)
2016         {
2017                 self.effects |= EF_FULLBRIGHT;
2018
2019                 if (self.items & IT_STRENGTH)
2020                 {
2021                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2022                         if (time > self.strength_finished)
2023                         {
2024                                 self.alpha = default_player_alpha;
2025                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2026                                 self.items &~= IT_STRENGTH;
2027                                 sprint(self, "^3Invisibility has worn off\n");
2028                         }
2029                 }
2030                 else
2031                 {
2032                         if (time < self.strength_finished)
2033                         {
2034                                 self.alpha = g_minstagib_invis_alpha;
2035                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2036                                 self.items |= IT_STRENGTH;
2037                                 sprint(self, "^3You are invisible\n");
2038                         }
2039                 }
2040
2041                 if (self.items & IT_INVINCIBLE)
2042                 {
2043                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2044                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2045                         {
2046                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2047                                 sprint(self, "^3Speed has worn off\n");
2048                         }
2049                 }
2050                 else
2051                 {
2052                         if (time < self.invincible_finished)
2053                         {
2054                                 self.items = self.items | IT_INVINCIBLE;
2055                                 sprint(self, "^3You are on speed\n");
2056                         }
2057                 }
2058         }
2059         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2060         {
2061                 if (self.items & IT_STRENGTH)
2062                 {
2063                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2064                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2065                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2066                         {
2067                                 self.items = self.items - (self.items & IT_STRENGTH);
2068                                 sprint(self, "^3Strength has worn off\n");
2069                         }
2070                 }
2071                 else
2072                 {
2073                         if (time < self.strength_finished)
2074                         {
2075                                 self.items = self.items | IT_STRENGTH;
2076                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2077                         }
2078                 }
2079                 if (self.items & IT_INVINCIBLE)
2080                 {
2081                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2082                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2083                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2084                         {
2085                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2086                                 sprint(self, "^3Shield has worn off\n");
2087                         }
2088                 }
2089                 else
2090                 {
2091                         if (time < self.invincible_finished)
2092                         {
2093                                 self.items = self.items | IT_INVINCIBLE;
2094                                 sprint(self, "^3Shield surrounds you\n");
2095                         }
2096                 }
2097
2098                 if(autocvar_g_nodepthtestplayers)
2099                         self.effects = self.effects | EF_NODEPTHTEST;
2100
2101                 if(autocvar_g_fullbrightplayers)
2102                         self.effects = self.effects | EF_FULLBRIGHT;
2103
2104                 // midair gamemode: damage only while in the air
2105                 // if in midair mode, being on ground grants temporary invulnerability
2106                 // (this is so that multishot weapon don't clear the ground flag on the
2107                 // first damage in the frame, leaving the player vulnerable to the
2108                 // remaining hits in the same frame)
2109                 if (self.flags & FL_ONGROUND)
2110                 if (g_midair)
2111                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2112
2113                 if (time >= game_starttime)
2114                 if (time < self.spawnshieldtime)
2115                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2116         }
2117
2118         MUTATOR_CALLHOOK(PlayerPowerups);
2119 }
2120
2121 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2122 {
2123         if(current > stable)
2124                 return current;
2125         else if(current > stable - 0.25) // when close enough, "snap"
2126                 return stable;
2127         else
2128                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2129 }
2130
2131 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2132 {
2133         if(current < stable)
2134                 return current;
2135         else if(current < stable + 0.25) // when close enough, "snap"
2136                 return stable;
2137         else
2138                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2139 }
2140
2141 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2142 {
2143         if(current > rotstable)
2144         {
2145                 if(rotframetime > 0)
2146                 {
2147                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2148                         current = max(rotstable, current - rotlinear * rotframetime);
2149                 }
2150         }
2151         else if(current < regenstable)
2152         {
2153                 if(regenframetime > 0)
2154                 {
2155                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2156                         current = min(regenstable, current + regenlinear * regenframetime);
2157                 }
2158         }
2159
2160         if(current > limit)
2161                 current = limit;
2162
2163         return current;
2164 }
2165
2166 void player_regen (void)
2167 {
2168         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2169         maxh = autocvar_g_balance_health_rotstable;
2170         maxa = autocvar_g_balance_armor_rotstable;
2171         maxf = autocvar_g_balance_fuel_rotstable;
2172         minh = autocvar_g_balance_health_regenstable;
2173         mina = autocvar_g_balance_armor_regenstable;
2174         minf = autocvar_g_balance_fuel_regenstable;
2175         limith = autocvar_g_balance_health_limit;
2176         limita = autocvar_g_balance_armor_limit;
2177         limitf = autocvar_g_balance_fuel_limit;
2178
2179         max_mod = regen_mod = rot_mod = limit_mod = 1;
2180
2181         if (self.runes & RUNE_REGEN)
2182         {
2183                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2184                 {
2185                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2186                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2187                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2188                 }
2189                 else
2190                 {
2191                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2192                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2193                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2194                 }
2195         }
2196         else if (self.runes & CURSE_VENOM)
2197         {
2198                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2199                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2200                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2201                 else
2202                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2203                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2204                 //if (!self.runes & RUNE_REGEN)
2205                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2206         }
2207         maxh = maxh * max_mod;
2208         //maxa = maxa * max_mod;
2209         //maxf = maxf * max_mod;
2210         minh = minh * max_mod;
2211         //mina = mina * max_mod;
2212         //minf = minf * max_mod;
2213         limith = limith * limit_mod;
2214         limita = limita * limit_mod;
2215         //limitf = limitf * limit_mod;
2216
2217         if(g_lms && g_ca)
2218                 rot_mod = 0;
2219
2220         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2221         {
2222                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2223                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2224
2225                 // if player rotted to death...  die!
2226                 if(self.health < 1)
2227                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2228         }
2229
2230         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2231                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2232 }
2233
2234 float zoomstate_set;
2235 void SetZoomState(float z)
2236 {
2237         if(z != self.zoomstate)
2238         {
2239                 self.zoomstate = z;
2240                 ClientData_Touch(self);
2241         }
2242         zoomstate_set = 1;
2243 }
2244
2245 void GetPressedKeys(void) {
2246         MUTATOR_CALLHOOK(GetPressedKeys);
2247         if (self.movement_x > 0) // get if movement keys are pressed
2248         {       // forward key pressed
2249                 self.pressedkeys |= KEY_FORWARD;
2250                 self.pressedkeys &~= KEY_BACKWARD;
2251         }
2252         else if (self.movement_x < 0)
2253         {       // backward key pressed
2254                 self.pressedkeys |= KEY_BACKWARD;
2255                 self.pressedkeys &~= KEY_FORWARD;
2256         }
2257         else
2258         {       // no x input
2259                 self.pressedkeys &~= KEY_FORWARD;
2260                 self.pressedkeys &~= KEY_BACKWARD;
2261         }
2262
2263         if (self.movement_y > 0)
2264         {       // right key pressed
2265                 self.pressedkeys |= KEY_RIGHT;
2266                 self.pressedkeys &~= KEY_LEFT;
2267         }
2268         else if (self.movement_y < 0)
2269         {       // left key pressed
2270                 self.pressedkeys |= KEY_LEFT;
2271                 self.pressedkeys &~= KEY_RIGHT;
2272         }
2273         else
2274         {       // no y input
2275                 self.pressedkeys &~= KEY_RIGHT;
2276                 self.pressedkeys &~= KEY_LEFT;
2277         }
2278
2279         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2280                 self.pressedkeys |= KEY_JUMP;
2281         else
2282                 self.pressedkeys &~= KEY_JUMP;
2283         if (self.BUTTON_CROUCH)
2284                 self.pressedkeys |= KEY_CROUCH;
2285         else
2286                 self.pressedkeys &~= KEY_CROUCH;
2287 }
2288
2289 /*
2290 ======================
2291 spectate mode routines
2292 ======================
2293 */
2294
2295 void SpectateCopy(entity spectatee) {
2296         other = spectatee;
2297         MUTATOR_CALLHOOK(SpectateCopy);
2298         self.armortype = spectatee.armortype;
2299         self.armorvalue = spectatee.armorvalue;
2300         self.ammo_cells = spectatee.ammo_cells;
2301         self.ammo_shells = spectatee.ammo_shells;
2302         self.ammo_nails = spectatee.ammo_nails;
2303         self.ammo_rockets = spectatee.ammo_rockets;
2304         self.ammo_fuel = spectatee.ammo_fuel;
2305         self.clip_load = spectatee.clip_load;
2306         self.clip_size = spectatee.clip_size;
2307         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2308         self.health = spectatee.health;
2309         self.impulse = 0;
2310         self.items = spectatee.items;
2311         self.last_pickup = spectatee.last_pickup;
2312         self.hit_time = spectatee.hit_time;
2313         self.metertime = spectatee.metertime;
2314         self.strength_finished = spectatee.strength_finished;
2315         self.invincible_finished = spectatee.invincible_finished;
2316         self.pressedkeys = spectatee.pressedkeys;
2317         self.weapons = spectatee.weapons;
2318         self.switchweapon = spectatee.switchweapon;
2319         self.switchingweapon = spectatee.switchingweapon;
2320         self.weapon = spectatee.weapon;
2321         self.nex_charge = spectatee.nex_charge;
2322         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2323         self.hagar_load = spectatee.hagar_load;
2324         self.minelayer_mines = spectatee.minelayer_mines;
2325         self.punchangle = spectatee.punchangle;
2326         self.view_ofs = spectatee.view_ofs;
2327         self.v_angle = spectatee.v_angle;
2328         self.velocity = spectatee.velocity;
2329         self.dmg_take = spectatee.dmg_take;
2330         self.dmg_save = spectatee.dmg_save;
2331         self.dmg_inflictor = spectatee.dmg_inflictor;
2332         self.angles = spectatee.v_angle;
2333         if(!self.BUTTON_USE)
2334                 self.fixangle = TRUE;
2335         setorigin(self, spectatee.origin);
2336         setsize(self, spectatee.mins, spectatee.maxs);
2337         SetZoomState(spectatee.zoomstate);
2338
2339         anticheat_spectatecopy(spectatee);
2340
2341         //self.vehicle = spectatee.vehicle;
2342
2343         self.hud = spectatee.hud;
2344         if(spectatee.vehicle)
2345     {
2346         setorigin(self, spectatee.origin);
2347         self.velocity = spectatee.vehicle.velocity;
2348         self.v_angle += spectatee.vehicle.angles;
2349         //self.v_angle_x *= -1;
2350         self.vehicle_health = spectatee.vehicle_health;
2351         self.vehicle_shield = spectatee.vehicle_shield;
2352         self.vehicle_energy = spectatee.vehicle_energy;
2353         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2354         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2355         self.vehicle_reload1 = spectatee.vehicle_reload1;
2356         self.vehicle_reload2 = spectatee.vehicle_reload2;
2357
2358         msg_entity = self;
2359         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2360         WriteEntity(MSG_ONE, spectatee);
2361         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2362     }
2363 }
2364
2365 float SpectateUpdate() {
2366         if(!self.enemy)
2367             return 0;
2368
2369         if (self == self.enemy)
2370                 return 0;
2371
2372         if(self.enemy.classname != "player")
2373                 return 0;
2374
2375         SpectateCopy(self.enemy);
2376
2377         return 1;
2378 }
2379
2380
2381 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2382 entity CA_SpectateNext(entity start) {
2383         if (start.team == self.team) {
2384                 return start;
2385         }
2386
2387         other = start;
2388         // continue from current player
2389         while(other && other.team != self.team) {
2390                 other = find(other, classname, "player");
2391         }
2392
2393         if (!other) {
2394                 // restart from begining
2395                 other = find(other, classname, "player");
2396                 while(other && other.team != self.team) {
2397                         other = find(other, classname, "player");
2398                 }
2399         }
2400
2401         return other;
2402 }
2403
2404 float SpectateNext() {
2405         other = find(self.enemy, classname, "player");
2406         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2407                 // CA and ca players when spectating enemies is forbidden
2408                 other = CA_SpectateNext(other);
2409         } else {
2410                 // other modes and ca spectators or spectating enemies is allowed
2411                 if (!other)
2412                         other = find(other, classname, "player");
2413         }
2414
2415         if (other)
2416                 self.enemy = other;
2417
2418         if(self.enemy.classname == "player") {
2419             if(self.enemy.vehicle)
2420             {
2421             msg_entity = self;
2422             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2423             WriteEntity(MSG_ONE, self.enemy);
2424             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2425             self.movetype = MOVETYPE_NONE;
2426             accuracy_resend(self);
2427             }
2428             else
2429             {
2430             msg_entity = self;
2431             WriteByte(MSG_ONE, SVC_SETVIEW);
2432             WriteEntity(MSG_ONE, self.enemy);
2433             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2434             self.movetype = MOVETYPE_NONE;
2435             accuracy_resend(self);
2436
2437             if(!SpectateUpdate())
2438                 PutObserverInServer();
2439         }
2440         return 1;
2441         } else {
2442                 return 0;
2443         }
2444 }
2445
2446 /*
2447 =============
2448 ShowRespawnCountdown()
2449
2450 Update a respawn countdown display.
2451 =============
2452 */
2453 void ShowRespawnCountdown()
2454 {
2455         float number;
2456         if(self.deadflag == DEAD_NO) // just respawned?
2457                 return;
2458         else
2459         {
2460                 number = ceil(self.death_time - time);
2461                 if(number <= 0)
2462                         return;
2463                 if(number <= self.respawn_countdown)
2464                 {
2465                         self.respawn_countdown = number - 1;
2466                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2467                                 AnnounceTo(self, strcat(ftos(number), ""));
2468                 }
2469         }
2470 }
2471
2472 .float prevent_join_msgtime;
2473 void LeaveSpectatorMode()
2474 {
2475         if(nJoinAllowed(1)) {
2476                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2477                         self.classname = "player";
2478
2479                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2480                                 JoinBestTeam(self, FALSE, TRUE);
2481
2482                         if(autocvar_g_campaign)
2483                                 campaign_bots_may_start = 1;
2484
2485                         PutClientInServer();
2486
2487                         if(self.classname == "player")
2488                                 bprint ("^4", self.netname, "^4 is playing now\n");
2489
2490                         if(!autocvar_g_campaign)
2491                         if (time < self.jointime + autocvar_welcome_message_time)
2492                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2493
2494                         if (self.prevent_join_msgtime)
2495                         {
2496                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2497                                 self.prevent_join_msgtime = 0;
2498                         }
2499
2500                         return;
2501                 } else {
2502                         if (g_ca && self.caplayer) {
2503                         }       // do nothing
2504                         else
2505                                 stuffcmd(self,"menu_showteamselect\n");
2506                         return;
2507                 }
2508         }
2509         else {
2510                 //player may not join because of g_maxplayers is set
2511                 if (time - self.prevent_join_msgtime > 2)
2512                 {
2513                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2514                         self.prevent_join_msgtime = time;
2515                 }
2516         }
2517 }
2518
2519 /**
2520  * Determines whether the player is allowed to join. This depends on cvar
2521  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2522  * it checks whether the number of currently playing players exceeds g_maxplayers.
2523  * @return int number of free slots for players, 0 if none
2524  */
2525 float nJoinAllowed(float includeMe) {
2526         if(self.team_forced < 0)
2527                 return FALSE; // forced spectators can never join
2528
2529         // TODO simplify this
2530         local entity e;
2531
2532         local float totalClients;
2533         FOR_EACH_CLIENT(e)
2534                 totalClients += 1;
2535
2536         if (!autocvar_g_maxplayers)
2537                 return maxclients - totalClients + includeMe;
2538
2539         local float currentlyPlaying;
2540         FOR_EACH_REALPLAYER(e)
2541                 currentlyPlaying += 1;
2542
2543         if(currentlyPlaying < autocvar_g_maxplayers)
2544                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2545
2546         return 0;
2547 }
2548
2549 /**
2550  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2551  * g_maxplayers_spectator_blocktime seconds
2552  */
2553 void checkSpectatorBlock() {
2554         if(self.classname == "spectator" || self.classname == "observer") {
2555                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2556                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2557                         dropclient(self);
2558                 }
2559         }
2560 }
2561
2562 .float motd_actived_time; // used for both motd and campaign_message
2563 void PrintWelcomeMessage()
2564 {
2565         if (self.motd_actived_time == 0) { // is there already a message showing?
2566                 if (autocvar_g_campaign) {
2567                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2568                                 self.motd_actived_time = time;
2569                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2570                         }
2571                 } else {
2572                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2573                                 self.motd_actived_time = time;
2574                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2575                         }
2576                 }
2577         } else { // showing MOTD or campaign message
2578                 if (autocvar_g_campaign) {
2579                         if (self.BUTTON_INFO)
2580                                 self.motd_actived_time = time;
2581                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2582                                 self.motd_actived_time = 0;
2583                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2584                         }
2585                 } else {
2586                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2587                                 if (self.BUTTON_INFO)
2588                                         self.motd_actived_time = time;
2589                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2590                                         self.motd_actived_time = 0;
2591                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2592                                 }
2593                         }
2594                 }
2595         }
2596 }
2597
2598 void ObserverThink()
2599 {
2600         float prefered_movetype;
2601         if (self.flags & FL_JUMPRELEASED) {
2602                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2603                         self.flags &~= FL_JUMPRELEASED;
2604                         self.flags |= FL_SPAWNING;
2605                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2606                         self.flags &~= FL_JUMPRELEASED;
2607                         if(SpectateNext() == 1) {
2608                                 self.classname = "spectator";
2609                         }
2610                 } else {
2611                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2612                         if (self.movetype != prefered_movetype)
2613                                 self.movetype = prefered_movetype;
2614                 }
2615         } else {
2616                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2617                         self.flags |= FL_JUMPRELEASED;
2618                         if(self.flags & FL_SPAWNING)
2619                         {
2620                                 self.flags &~= FL_SPAWNING;
2621                                 LeaveSpectatorMode();
2622                                 return;
2623                         }
2624                 }
2625         }
2626
2627         PrintWelcomeMessage();
2628 }
2629
2630 void SpectatorThink()
2631 {
2632         if (self.flags & FL_JUMPRELEASED) {
2633                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2634                         self.flags &~= FL_JUMPRELEASED;
2635                         self.flags |= FL_SPAWNING;
2636                 } else if(self.BUTTON_ATCK) {
2637                         self.flags &~= FL_JUMPRELEASED;
2638                         if(SpectateNext() == 1) {
2639                                 self.classname = "spectator";
2640                         } else {
2641                                 self.classname = "observer";
2642                                 PutClientInServer();
2643                         }
2644                 } else if (self.BUTTON_ATCK2) {
2645                         self.flags &~= FL_JUMPRELEASED;
2646                         self.classname = "observer";
2647                         PutClientInServer();
2648                 } else {
2649                         if(!SpectateUpdate())
2650                                 PutObserverInServer();
2651                 }
2652         } else {
2653                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2654                         self.flags |= FL_JUMPRELEASED;
2655                         if(self.flags & FL_SPAWNING)
2656                         {
2657                                 self.flags &~= FL_SPAWNING;
2658                                 LeaveSpectatorMode();
2659                                 return;
2660                         }
2661                 }
2662                 if(!SpectateUpdate())
2663                         PutObserverInServer();
2664         }
2665
2666         PrintWelcomeMessage();
2667         self.flags |= FL_CLIENT | FL_NOTARGET;
2668 }
2669
2670 float ctf_usekey();
2671 void PlayerUseKey()
2672 {
2673         if(self.classname != "player")
2674                 return;
2675
2676         if(self.vehicle)
2677         {
2678         vehicles_exit(VHEF_NORMAL);
2679         return;
2680         }
2681
2682         // a use key was pressed; call handlers
2683         if(ctf_usekey())
2684                 return;
2685
2686         MUTATOR_CALLHOOK(PlayerUseKey);
2687 }
2688
2689 .float touchexplode_time;
2690
2691 /*
2692 =============
2693 PlayerPreThink
2694
2695 Called every frame for each client before the physics are run
2696 =============
2697 */
2698 .float usekeypressed;
2699 void() ctf_setstatus;
2700 void() nexball_setstatus;
2701 .float items_added;
2702 void PlayerPreThink (void)
2703 {
2704         WarpZone_PlayerPhysics_FixVAngle();
2705
2706         self.stat_game_starttime = game_starttime;
2707         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2708         self.stat_leadlimit = autocvar_leadlimit;
2709
2710         if(frametime)
2711         {
2712                 // physics frames: update anticheat stuff
2713                 anticheat_prethink();
2714         }
2715
2716         if(blockSpectators && frametime)
2717                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2718                 checkSpectatorBlock();
2719
2720         zoomstate_set = 0;
2721
2722         if(self.netname_previous != self.netname)
2723         {
2724                 if(autocvar_sv_eventlog)
2725                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2726                 if(self.netname_previous)
2727                         strunzone(self.netname_previous);
2728                 self.netname_previous = strzone(self.netname);
2729         }
2730
2731         // version nagging
2732         if(self.version_nagtime)
2733                 if(self.cvar_g_xonoticversion)
2734                         if(time > self.version_nagtime)
2735                         {
2736                                 // don't notify git users
2737                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2738                                 {
2739                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2740                                         {
2741                                                 // notify release users if connecting to git
2742                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2743                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2744                                         }
2745                                         else
2746                                         {
2747                                                 float r;
2748                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2749                                                 if(r < 0)
2750                                                 {
2751                                                         // give users new version
2752                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2753                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2754                                                 }
2755                                                 else if(r > 0)
2756                                                 {
2757                                                         // notify users about old server version
2758                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2759                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2760                                                 }
2761                                         }
2762                                 }
2763                                 self.version_nagtime = 0;
2764                         }
2765
2766         // GOD MODE info
2767         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2768         {
2769                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2770                 self.max_armorvalue = 0;
2771         }
2772
2773 #ifdef TETRIS
2774         if (TetrisPreFrame())
2775                 return;
2776 #endif
2777
2778         MUTATOR_CALLHOOK(PlayerPreThink);
2779
2780         if(!self.cvar_cl_newusekeysupported)
2781         {
2782                 if(self.BUTTON_USE && !self.usekeypressed)
2783                         PlayerUseKey();
2784                 self.usekeypressed = self.BUTTON_USE;
2785         }
2786
2787         PrintWelcomeMessage();
2788
2789         if(self.classname == "player") {
2790 //              if(self.netname == "Wazat")
2791 //                      bprint(self.classname, "\n");
2792
2793                 CheckRules_Player();
2794
2795                 if (intermission_running)
2796                 {
2797                         IntermissionThink ();   // otherwise a button could be missed between
2798                         return;                                 // the think tics
2799                 }
2800
2801                 //don't allow the player to turn around while game is paused!
2802                 if(timeoutStatus == 2) {
2803                         // FIXME turn this into CSQC stuff
2804                         self.v_angle = self.lastV_angle;
2805                         self.angles = self.lastV_angle;
2806                         self.fixangle = TRUE;
2807                 }
2808
2809                 if(frametime)
2810                 {
2811                         if(self.health <= 0 && autocvar_g_deathglow)
2812                         {
2813                                 if(self.glowmod_x > 0)
2814                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2815                                 else
2816                                         self.glowmod_x = -1;
2817                                 if(self.glowmod_y > 0)
2818                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2819                                 else
2820                                         self.glowmod_y = -1;
2821                                 if(self.glowmod_z > 0)
2822                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2823                                 else
2824                                         self.glowmod_z = -1;
2825                         }
2826                         else
2827                         {
2828                                 // set weapon and player glowmod
2829                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2830
2831                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2832                                 {
2833                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2834                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2835                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2836
2837                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2838                                         {
2839                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2840                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2841                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2842                                         }
2843                                 }
2844                                 else
2845                                         self.weaponentity_glowmod = self.glowmod;
2846                         }
2847                         player_powerups();
2848                 }
2849
2850                 if (g_minstagib)
2851                         minstagib_ammocheck();
2852
2853                 if (self.deadflag != DEAD_NO)
2854                 {
2855                         float button_pressed, force_respawn;
2856                         if(self.personal && g_race_qualifying)
2857                         {
2858                                 if(time > self.death_time)
2859                                 {
2860                                         self.death_time = time + 1; // only retry once a second
2861                                         respawn();
2862                                         self.impulse = 141;
2863                                 }
2864                         }
2865                         else
2866                         {
2867                                 if(frametime)
2868                                         player_anim();
2869                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2870                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2871                                 if (self.deadflag == DEAD_DYING)
2872                                 {
2873                                         if(force_respawn)
2874                                                 self.deadflag = DEAD_RESPAWNING;
2875                                         else if(!button_pressed)
2876                                                 self.deadflag = DEAD_DEAD;
2877                                 }
2878                                 else if (self.deadflag == DEAD_DEAD)
2879                                 {
2880                                         if(button_pressed)
2881                                                 self.deadflag = DEAD_RESPAWNABLE;
2882                                 }
2883                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2884                                 {
2885                                         if(!button_pressed)
2886                                                 self.deadflag = DEAD_RESPAWNING;
2887                                 }
2888                                 else if (self.deadflag == DEAD_RESPAWNING)
2889                                 {
2890                                         if(time > self.death_time)
2891                                         {
2892                                                 self.death_time = time + 1; // only retry once a second
2893                                                 respawn();
2894                                         }
2895                                 }
2896                                 ShowRespawnCountdown();
2897                         }
2898                         return;
2899                 }
2900                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2901                 // so (self.deadflag == DEAD_NO) is always true in the code below
2902
2903                 if(g_touchexplode)
2904                 if(time > self.touchexplode_time)
2905                 if(self.classname == "player")
2906                 if(self.deadflag == DEAD_NO)
2907                 if not(IS_INDEPENDENT_PLAYER(self))
2908                 FOR_EACH_PLAYER(other) if(self != other)
2909                 {
2910                         if(time > other.touchexplode_time)
2911                         if(other.deadflag == DEAD_NO)
2912                         if not(IS_INDEPENDENT_PLAYER(other))
2913                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2914                         {
2915                                 PlayerTouchExplode(self, other);
2916                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2917                         }
2918                 }
2919
2920                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2921                 {
2922                         vector dist;
2923
2924                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2925                         dist = self.prevorigin - self.origin;
2926                         dist_z = 0;
2927                         self.lms_traveled_distance += fabs(vlen(dist));
2928
2929                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2930                         {
2931                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2932                                 self.lms_traveled_distance = 0;
2933                         }
2934
2935                         if(time > self.lms_nextcheck)
2936                         {
2937                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2938                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2939                                 {
2940                                         centerprint(self, autocvar_g_lms_campcheck_message);
2941                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2942                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2943                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2944                                 }
2945                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2946                                 self.lms_traveled_distance = 0;
2947                         }
2948                 }
2949
2950                 self.prevorigin = self.origin;
2951
2952                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2953                 {
2954                         if (!self.crouch)
2955                         {
2956                                 self.crouch = TRUE;
2957                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2958                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2959                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2960                         }
2961                 }
2962                 else
2963                 {
2964                         if (self.crouch)
2965                         {
2966                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2967                                 if (!trace_startsolid)
2968                                 {
2969                                         self.crouch = FALSE;
2970                                         self.view_ofs = PL_VIEW_OFS;
2971                                         setsize (self, PL_MIN, PL_MAX);
2972                                 }
2973                         }
2974                 }
2975
2976                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2977                 {
2978                         if(self.bloodloss_timer < time)
2979                         {
2980                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2981                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2982                         }
2983                 }
2984
2985                 FixPlayermodel();
2986
2987                 GrapplingHookFrame();
2988
2989                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2990                 //if(frametime)
2991                 {
2992                         self.items &~= self.items_added;
2993
2994                         W_WeaponFrame();
2995
2996                         self.items_added = 0;
2997                         if(self.items & IT_JETPACK)
2998                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2999                                         self.items_added |= IT_FUEL;
3000
3001                         self.items |= self.items_added;
3002                 }
3003
3004                 player_regen();
3005
3006                 // rot nex charge to the charge limit
3007                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
3008                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
3009
3010                 if(frametime)
3011                         player_anim();
3012
3013                 if(g_ctf)
3014                         ctf_setstatus();
3015
3016                 if(g_nexball)
3017                         nexball_setstatus();
3018
3019                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
3020
3021                 //self.angles_y=self.v_angle_y + 90;   // temp
3022         } else if(gameover) {
3023                 if (intermission_running)
3024                         IntermissionThink ();   // otherwise a button could be missed between
3025                 return;
3026         } else if(self.classname == "observer") {
3027                 ObserverThink();
3028         } else if(self.classname == "spectator") {
3029                 SpectatorThink();
3030         }
3031
3032         if(!zoomstate_set)
3033                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
3034
3035         float oldspectatee_status;
3036         oldspectatee_status = self.spectatee_status;
3037         if(self.classname == "spectator")
3038                 self.spectatee_status = num_for_edict(self.enemy);
3039         else if(self.classname == "observer")
3040                 self.spectatee_status = num_for_edict(self);
3041         else
3042                 self.spectatee_status = 0;
3043         if(self.spectatee_status != oldspectatee_status)
3044         {
3045                 ClientData_Touch(self);
3046                 if(g_race || g_cts)
3047                         race_InitSpectator();
3048         }
3049
3050         if(self.teamkill_soundtime)
3051         if(time > self.teamkill_soundtime)
3052         {
3053                 self.teamkill_soundtime = 0;
3054
3055                 entity oldpusher, oldself;
3056
3057                 oldself = self; self = self.teamkill_soundsource;
3058                 oldpusher = self.pusher; self.pusher = oldself;
3059
3060                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3061
3062                 self.pusher = oldpusher;
3063                 self = oldself;
3064         }
3065
3066         if(self.taunt_soundtime)
3067         if(time > self.taunt_soundtime)
3068         {
3069                 self.taunt_soundtime = 0;
3070                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
3071         }
3072
3073         target_voicescript_next(self);
3074
3075         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3076         if(!self.weapon)
3077                 self.clip_load = self.clip_size = 0;
3078 }
3079
3080 float isInvisibleString(string s)
3081 {
3082         float i, n, c;
3083         s = strdecolorize(s);
3084         for((i = 0), (n = strlen(s)); i < n; ++i)
3085         {
3086                 c = str2chr(s, i);
3087                 switch(c)
3088                 {
3089                         case 0:
3090                         case 32: // space
3091                                 break;
3092                         case 192: // charmap space
3093                                 if (!autocvar_utf8_enable)
3094                                         break;
3095                                 return FALSE;
3096                         case 160: // space in unicode fonts
3097                         case 0xE000 + 192: // utf8 charmap space
3098                                 if (autocvar_utf8_enable)
3099                                         break;
3100                         default:
3101                                 return FALSE;
3102                 }
3103         }
3104         return TRUE;
3105 }
3106
3107 /*
3108 =============
3109 PlayerPostThink
3110
3111 Called every frame for each client after the physics are run
3112 =============
3113 */
3114 .float idlekick_lasttimeleft;
3115 .entity showheadshotbbox;
3116 void showheadshotbbox_think()
3117 {
3118         if(self.owner.showheadshotbbox != self)
3119         {
3120                 remove(self);
3121                 return;
3122         }
3123         self.nextthink = time;
3124         setorigin(self, self.owner.origin);
3125         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3126 }
3127 void PlayerPostThink (void)
3128 {
3129         // Savage: Check for nameless players
3130         if (isInvisibleString(self.netname)) {
3131                 self.netname = "Player";
3132                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3133         }
3134
3135         if(sv_maxidle && frametime)
3136         {
3137                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3138                 float timeleft;
3139                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
3140                 {
3141                         if(self.idlekick_lasttimeleft)
3142                         {
3143                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
3144                                 self.idlekick_lasttimeleft = 0;
3145                         }
3146                         return;
3147                 }
3148                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3149                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3150                 {
3151                         if(!self.idlekick_lasttimeleft)
3152                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3153                 }
3154                 if(timeleft <= 0)
3155                 {
3156                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3157                         AnnounceTo(self, "terminated");
3158                         dropclient(self);
3159                         return;
3160                 }
3161                 else if(timeleft <= 10)
3162                 {
3163                         if(timeleft != self.idlekick_lasttimeleft)
3164                                 AnnounceTo(self, ftos(timeleft));
3165                         self.idlekick_lasttimeleft = timeleft;
3166                 }
3167         }
3168
3169 #ifdef TETRIS
3170         if(self.impulse == 100)
3171                 ImpulseCommands();
3172         if (TetrisPostFrame())
3173                 return;
3174 #endif
3175
3176         CheatFrame();
3177
3178         //CheckPlayerJump();
3179
3180         if(self.classname == "player") {
3181                 CheckRules_Player();
3182                 UpdateChatBubble();
3183                 if (self.impulse)
3184                         ImpulseCommands();
3185                 if (intermission_running)
3186                         return;         // intermission or finale
3187                 GetPressedKeys();
3188         } else if (self.classname == "observer") {
3189                 //do nothing
3190         } else if (self.classname == "spectator") {
3191                 //do nothing
3192         }
3193
3194         /*
3195         float i;
3196         for(i = 0; i < 1000; ++i)
3197         {
3198                 vector end;
3199                 end = self.origin + '0 0 1024' + 512 * randomvec();
3200                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3201                 if(trace_fraction < 1)
3202                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3203                 {
3204                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3205                         break;
3206                 }
3207         }
3208         */
3209
3210         Arena_Warmup();
3211
3212         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3213
3214         if(self.waypointsprite_attachedforcarrier)
3215                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3216
3217         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3218         {
3219                 if(!self.showheadshotbbox)
3220                 {
3221                         self.showheadshotbbox = spawn();
3222                         self.showheadshotbbox.classname = "headshotbbox";
3223                         self.showheadshotbbox.owner = self;
3224                         self.showheadshotbbox.think = showheadshotbbox_think;
3225                         self.showheadshotbbox.nextthink = time;
3226                         self = self.showheadshotbbox;
3227                         self.think();
3228                         self = self.owner;
3229                 }
3230         }
3231         else
3232         {
3233                 if(self.showheadshotbbox)
3234                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3235                 remove(self.showheadshotbbox);
3236         }
3237
3238         playerdemo_write();
3239
3240         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3241         {
3242                 if(!self.stored_netname)
3243                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3244                 if(self.stored_netname != self.netname)
3245                 {
3246                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3247                         strunzone(self.stored_netname);
3248                         self.stored_netname = strzone(self.netname);
3249                 }
3250         }
3251
3252         /*
3253         if(g_race)
3254                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3255         */
3256 }