qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         Portal_ClearAll(self);
 618
 619         if(self.alivetime)
 620         {
 621                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 622                 self.alivetime = 0;
 623         }
 624
 625         if(self.vehicle)
 626             vehicles_exit(VHEF_RELESE);
 627
 628         if(self.flagcarried)
 629                 DropFlag(self.flagcarried, world, world);
 630
 631         if(self.ballcarried && g_nexball)
 632                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 633
 634         WaypointSprite_PlayerDead();
 635
 636         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 637                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 638
 639         if(self.killcount != -666) {
 640                 if(g_lms) {
 641                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 642                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 643                         else
 644                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 645                 } else
 646                         bprint ("^4", self.netname, "^4 is spectating now\n");
 647
 648                 if(self.just_joined == FALSE) {
 649                         LogTeamchange(self.playerid, -1, 4);
 650                 } else
 651                         self.just_joined = FALSE;
 652         }
 653
 654         PlayerScore_Clear(self); // clear scores when needed
 655
 656         accuracy_resend(self);
 657
 658         self.spectatortime = time;
 659
 660         self.classname = "observer";
 661         self.iscreature = FALSE;
 662         self.health = -666;
 663         self.takedamage = DAMAGE_NO;
 664         self.solid = SOLID_NOT;
 665         self.movetype = MOVETYPE_NOCLIP;
 666         self.flags = FL_CLIENT | FL_NOTARGET;
 667         self.armorvalue = 666;
 668         self.effects = 0;
 669         self.armorvalue = autocvar_g_balance_armor_start;
 670         self.pauserotarmor_finished = 0;
 671         self.pauserothealth_finished = 0;
 672         self.pauseregen_finished = 0;
 673         self.damageforcescale = 0;
 674         self.death_time = 0;
 675         self.dead_frame = 0;
 676         self.alpha = 0;
 677         self.scale = 0;
 678         self.fade_time = 0;
 679         self.pain_frame = 0;
 680         self.pain_finished = 0;
 681         self.strength_finished = 0;
 682         self.invincible_finished = 0;
 683         self.pushltime = 0;
 684         self.think = SUB_Null;
 685         self.nextthink = 0;
 686         self.hook_time = 0;
 687         self.runes = 0;
 688         self.deadflag = DEAD_NO;
 689         self.angles = spot.angles;
 690         self.angles_z = 0;
 691         self.fixangle = TRUE;
 692         self.crouch = FALSE;
 693
 694         self.view_ofs = PL_VIEW_OFS;
 695         setorigin (self, spot.origin);
 696         setsize (self, '0 0 0', '0 0 0');
 697         self.prevorigin = self.origin;
 698         self.items = 0;
 699         self.weapons = 0;
 700         self.model = "";
 701         FixPlayermodel();
 702         self.model = "";
 703         self.modelindex = 0;
 704         self.weapon = 0;
 705         self.weaponmodel = "";
 706         self.weaponentity = world;
 707         self.exteriorweaponentity = world;
 708         self.killcount = -666;
 709         self.velocity = '0 0 0';
 710         self.avelocity = '0 0 0';
 711         self.punchangle = '0 0 0';
 712         self.punchvector = '0 0 0';
 713         self.oldvelocity = self.velocity;
 714         self.fire_endtime = -1;
 715
 716         if(sv_loddistance1)
 717                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 718
 719         if(g_arena)
 720         {
 721                 if(self.version_mismatch)
 722                 {
 723                         Spawnqueue_Unmark(self);
 724                         Spawnqueue_Remove(self);
 725                 }
 726                 else
 727                 {
 728                         Spawnqueue_Insert(self);
 729                 }
 730         }
 731         else if(g_lms)
 732         {
 733                 // Only if the player cannot play at all
 734                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 735                         self.frags = FRAGS_SPECTATOR;
 736                 else
 737                         self.frags = FRAGS_LMS_LOSER;
 738         }
 739         else
 740                 self.frags = FRAGS_SPECTATOR;
 741 }
 742
 743 void FixPlayermodel()
 744 {
 745         local string defaultmodel;
 746         local float defaultskin, chmdl, oldskin;
 747         local vector m1, m2;
 748
 749         defaultmodel = "";
 750
 751         if(autocvar_sv_defaultcharacter == 1) {
 752                 defaultskin = 0;
 753
 754                 if(teamplay)
 755                 {
 756                         string s;
 757                         s = Team_ColorNameLowerCase(self.team);
 758                         if(s != "neutral")
 759                         {
 760                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 761                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 762                         }
 763                 }
 764
 765                 if(defaultmodel == "")
 766                 {
 767                         defaultmodel = autocvar_sv_defaultplayermodel;
 768                         defaultskin = autocvar_sv_defaultplayerskin;
 769                 }
 770         }
 771
 772         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 773         {
 774                 if(self.model != "")
 775                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 776                 self.model = ""; // force the != checks to return true
 777         }
 778
 779         if(defaultmodel != "")
 780         {
 781                 if (defaultmodel != self.model)
 782                 {
 783                         m1 = self.mins;
 784                         m2 = self.maxs;
 785                         setmodel_lod (self, defaultmodel);
 786                         setsize (self, m1, m2);
 787                         chmdl = TRUE;
 788                 }
 789
 790                 oldskin = self.skinindex;
 791                 self.skinindex = defaultskin;
 792         } else {
 793                 if (self.playermodel != self.model || self.playermodel == "")
 794                 {
 795                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 796                         m1 = self.mins;
 797                         m2 = self.maxs;
 798                         setmodel_lod (self, self.playermodel);
 799                         setsize (self, m1, m2);
 800                         chmdl = TRUE;
 801                 }
 802
 803                 oldskin = self.skinindex;
 804                 self.skinindex = stof(self.playerskin);
 805         }
 806
 807         if(chmdl || oldskin != self.skinindex)
 808                 self.species = player_getspecies(); // model or skin has changed
 809
 810         if(!teamplay)
 811                 if(strlen(autocvar_sv_defaultplayercolors))
 812                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 813                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 814 }
 815
 816 void PlayerTouchExplode(entity p1, entity p2)
 817 {
 818         vector org;
 819         org = (p1.origin + p2.origin) * 0.5;
 820         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 821
 822         te_explosion(org);
 823
 824         entity e;
 825         e = spawn();
 826         setorigin(e, org);
 827         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 828         remove(e);
 829 }
 830
 831 /*
 832 =============
 833 PutClientInServer
 834
 835 Called when a client spawns in the server
 836 =============
 837 */
 838 //void() ctf_playerchanged;
 839 void PutClientInServer (void)
 840 {
 841         if(clienttype(self) == CLIENTTYPE_BOT)
 842         {
 843                 self.classname = "player";
 844         }
 845         else if(clienttype(self) == CLIENTTYPE_REAL)
 846         {
 847                 msg_entity = self;
 848                 WriteByte(MSG_ONE, SVC_SETVIEW);
 849                 WriteEntity(MSG_ONE, self);
 850         }
 851
 852         // player is dead and becomes observer
 853         // FIXME fix LMS scoring for new system
 854         if(g_lms)
 855         {
 856                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 857                         self.classname = "observer";
 858         }
 859
 860         if(g_arena || (g_ca && !allowed_to_spawn))
 861         if(!self.spawned)
 862                 self.classname = "observer";
 863
 864         if(gameover)
 865                 self.classname = "observer";
 866
 867         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 868                 entity spot, oldself;
 869                 float j;
 870
 871                 accuracy_resend(self);
 872
 873                 if(self.team < 0)
 874                         JoinBestTeam(self, FALSE, TRUE);
 875
 876                 race_PreSpawn();
 877
 878                 spot = SelectSpawnPoint (FALSE);
 879                 if(!spot)
 880                 {
 881                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 882                         return; // spawn failed
 883                 }
 884
 885                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 886
 887                 self.classname = "player";
 888                 self.wasplayer = TRUE;
 889                 self.iscreature = TRUE;
 890                 self.movetype = MOVETYPE_WALK;
 891                 self.solid = SOLID_SLIDEBOX;
 892                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 893                 if(autocvar_g_playerclip_collisions)
 894                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 895                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 896                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 897                 self.frags = FRAGS_PLAYER;
 898                 if(independent_players)
 899                         MAKE_INDEPENDENT_PLAYER(self);
 900                 self.flags = FL_CLIENT;
 901                 self.takedamage = DAMAGE_AIM;
 902                 if(g_minstagib)
 903                         self.effects = EF_FULLBRIGHT;
 904                 else
 905                         self.effects = 0;
 906                 self.air_finished = time + 12;
 907                 self.dmg = 2;
 908                 if(autocvar_g_balance_nex_charge)
 909                 {
 910                         if(autocvar_g_balance_nex_secondary_chargepool)
 911                                 self.nex_chargepool_ammo = 1;
 912                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 913                 }
 914
 915                 if(inWarmupStage)
 916                 {
 917                         self.ammo_shells = warmup_start_ammo_shells;
 918                         self.ammo_nails = warmup_start_ammo_nails;
 919                         self.ammo_rockets = warmup_start_ammo_rockets;
 920                         self.ammo_cells = warmup_start_ammo_cells;
 921                         self.ammo_fuel = warmup_start_ammo_fuel;
 922                         self.health = warmup_start_health;
 923                         self.armorvalue = warmup_start_armorvalue;
 924                         self.weapons = warmup_start_weapons;
 925                 }
 926                 else
 927                 {
 928                         self.ammo_shells = start_ammo_shells;
 929                         self.ammo_nails = start_ammo_nails;
 930                         self.ammo_rockets = start_ammo_rockets;
 931                         self.ammo_cells = start_ammo_cells;
 932                         self.ammo_fuel = start_ammo_fuel;
 933                         self.health = start_health;
 934                         self.armorvalue = start_armorvalue;
 935                         self.weapons = start_weapons;
 936                 }
 937
 938                 if(g_weaponarena_random)
 939                 {
 940                         if(g_weaponarena_random_with_laser)
 941                                 self.weapons &~= WEPBIT_LASER;
 942                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 943                         if(g_weaponarena_random_with_laser)
 944                                 self.weapons |= WEPBIT_LASER;
 945                 }
 946
 947                 self.items = start_items;
 948                 self.jump_interval = time;
 949
 950                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 951                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 952                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 953                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 954                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 955                 //extend the pause of rotting if client was reset at the beginning of the countdown
 956                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 957                         self.spawnshieldtime += game_starttime - time;
 958                         self.pauserotarmor_finished += game_starttime - time;
 959                         self.pauserothealth_finished += game_starttime - time;
 960                         self.pauseregen_finished += game_starttime - time;
 961                 }
 962                 self.damageforcescale = 2;
 963                 self.death_time = 0;
 964                 self.dead_frame = 0;
 965                 self.alpha = 0;
 966                 self.scale = 0;
 967                 self.fade_time = 0;
 968                 self.pain_frame = 0;
 969                 self.pain_finished = 0;
 970                 self.strength_finished = 0;
 971                 self.invincible_finished = 0;
 972                 self.pushltime = 0;
 973                 // players have no think function
 974                 self.think = SUB_Null;
 975                 self.nextthink = 0;
 976                 self.hook_time = 0;
 977                 self.dmg_team = 0;
 978                 self.ballistics_density = autocvar_g_ballistics_density_player;
 979
 980                 self.metertime = 0;
 981
 982                 self.runes = 0;
 983
 984                 self.deadflag = DEAD_NO;
 985
 986                 self.angles = spot.angles;
 987
 988                 self.angles_z = 0; // never spawn tilted even if the spot says to
 989                 self.fixangle = TRUE; // turn this way immediately
 990                 self.velocity = '0 0 0';
 991                 self.avelocity = '0 0 0';
 992                 self.punchangle = '0 0 0';
 993                 self.punchvector = '0 0 0';
 994                 self.oldvelocity = self.velocity;
 995                 self.fire_endtime = -1;
 996
 997                 msg_entity = self;
 998                 WRITESPECTATABLE_MSG_ONE({
 999                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1000                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1001                 });
1002
1003                 if(sv_loddistance1)
1004                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1005
1006                 self.model = "";
1007                 FixPlayermodel();
1008
1009                 self.crouch = FALSE;
1010                 self.view_ofs = PL_VIEW_OFS;
1011                 setsize (self, PL_MIN, PL_MAX);
1012                 self.spawnorigin = spot.origin;
1013                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1014                 // don't reset back to last position, even if new position is stuck in solid
1015                 self.oldorigin = self.origin;
1016                 self.prevorigin = self.origin;
1017                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1018
1019                 if(g_arena)
1020                 {
1021                         Spawnqueue_Remove(self);
1022                         Spawnqueue_Mark(self);
1023                 }
1024
1025                 else if(g_ca)
1026                         self.caplayer = 1;
1027
1028                 self.event_damage = PlayerDamage;
1029
1030                 self.bot_attack = TRUE;
1031
1032                 self.statdraintime = time + 5;
1033                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1034
1035                 if(self.killcount == -666) {
1036                         PlayerScore_Clear(self);
1037                         self.killcount = 0;
1038                 }
1039
1040                 self.cnt = WEP_LASER;
1041
1042                 CL_SpawnWeaponentity();
1043                 self.alpha = default_player_alpha;
1044                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1045                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1046
1047                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1048                 self.lms_traveled_distance = 0;
1049                 self.speedrunning = FALSE;
1050
1051                 race_PostSpawn(spot);
1052
1053                 if(autocvar_spawn_debug)
1054                 {
1055                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1056                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1057                 }
1058
1059                 //stuffcmd(self, "chase_active 0");
1060                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1061
1062                 if (autocvar_g_spawnsound)
1063                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1064
1065                 if(g_assault) {
1066                         if(self.team == assault_attacker_team)
1067                                 centerprint(self, "You are attacking!");
1068                         else
1069                                 centerprint(self, "You are defending!");
1070                 }
1071
1072                 target_voicescript_clear(self);
1073
1074                 // reset fields the weapons may use
1075                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1076                 {
1077                         weapon_action(j, WR_RESETPLAYER);
1078
1079                         // all weapons must be fully loaded when we spawn
1080                         entity e;
1081                         e = get_weaponinfo(j);
1082                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1083                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1084                 }
1085                 self.weapon_forbidchange = FALSE;
1086
1087                 oldself = self;
1088                 self = spot;
1089                         activator = oldself;
1090                                 string s;
1091                                 s = self.target;
1092                                 self.target = string_null;
1093                                 SUB_UseTargets();
1094                                 self.target = s;
1095                         activator = world;
1096                 self = oldself;
1097
1098                 MUTATOR_CALLHOOK(PlayerSpawn);
1099
1100                 self.switchweapon = w_getbestweapon(self);
1101                 self.cnt = self.switchweapon;
1102                 self.weapon = 0;
1103
1104                 if(!self.alivetime)
1105                         self.alivetime = time;
1106         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1107                 PutObserverInServer ();
1108         }
1109
1110         //if(g_ctf)
1111         //      ctf_playerchanged();
1112 }
1113
1114 .float ebouncefactor, ebouncestop; // electro's values
1115 // TODO do we need all these fields, or should we stop autodetecting runtime
1116 // changes and just have a console command to update this?
1117 float ClientInit_SendEntity(entity to, float sf)
1118 {
1119         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1120         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1121         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1122         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1123         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1124         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1125         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1126         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1127         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1128         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1129         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1130         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1131         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1132         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1133         if(sv_foginterval && world.fog != "")
1134                 WriteString(MSG_ENTITY, world.fog);
1135         else
1136                 WriteString(MSG_ENTITY, "");
1137         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1138         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1139         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1140         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1141         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1142         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1143         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1144         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1145         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1146         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1147         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1148         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1149         return TRUE;
1150 }
1151
1152 void ClientInit_CheckUpdate()
1153 {
1154         self.nextthink = time;
1155         if(self.count != autocvar_g_balance_armor_blockpercent)
1156         {
1157                 self.count = autocvar_g_balance_armor_blockpercent;
1158                 self.SendFlags |= 1;
1159         }
1160         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1161         {
1162                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1163                 self.SendFlags |= 1;
1164         }
1165         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1166         {
1167                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1168                 self.SendFlags |= 1;
1169         }
1170         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1171         {
1172                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1173                 self.SendFlags |= 1;
1174         }
1175         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1176         {
1177                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1178                 self.SendFlags |= 1;
1179         }
1180         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1181         {
1182                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1183                 self.SendFlags |= 1;
1184         }
1185 }
1186
1187 void ClientInit_Spawn()
1188 {
1189         entity o;
1190         entity e;
1191         e = spawn();
1192         e.classname = "clientinit";
1193         e.think = ClientInit_CheckUpdate;
1194         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1195
1196         o = self;
1197         self = e;
1198         ClientInit_CheckUpdate();
1199         self = o;
1200 }
1201
1202 /*
1203 =============
1204 SetNewParms
1205 =============
1206 */
1207 void SetNewParms (void)
1208 {
1209         // initialize parms for a new player
1210         parm1 = -(86400 * 366);
1211 }
1212
1213 /*
1214 =============
1215 SetChangeParms
1216 =============
1217 */
1218 void SetChangeParms (void)
1219 {
1220         // save parms for level change
1221         parm1 = self.parm_idlesince - time;
1222 }
1223
1224 /*
1225 =============
1226 DecodeLevelParms
1227 =============
1228 */
1229 void DecodeLevelParms (void)
1230 {
1231         // load parms
1232         self.parm_idlesince = parm1;
1233         if(self.parm_idlesince == -(86400 * 366))
1234                 self.parm_idlesince = time;
1235
1236         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1237         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1238 }
1239
1240 /*
1241 =============
1242 ClientKill
1243
1244 Called when a client types 'kill' in the console
1245 =============
1246 */
1247
1248 .float clientkill_nexttime;
1249 void ClientKill_Now_TeamChange()
1250 {
1251         if(self.killindicator_teamchange == -1)
1252         {
1253                 self.team = -1;
1254                 JoinBestTeam( self, FALSE, FALSE );
1255         }
1256         else if(self.killindicator_teamchange == -2)
1257         {
1258                 if(g_ca)
1259                         self.caplayer = 0;
1260                 if(blockSpectators)
1261                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1262                 PutObserverInServer();
1263         }
1264         else
1265                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1266 }
1267
1268 void ClientKill_Now()
1269 {
1270         if(self.vehicle)
1271         {
1272             vehicles_exit(VHEF_RELESE);
1273             if(!self.killindicator_teamchange)
1274             {
1275             self.vehicle_health = -1;
1276             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1277             }
1278         }
1279
1280         remove(self.killindicator);
1281         self.killindicator = world;
1282
1283         if(self.killindicator_teamchange)
1284                 ClientKill_Now_TeamChange();
1285
1286         // in any case:
1287         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1288
1289         // now I am sure the player IS dead
1290 }
1291 void KillIndicator_Think()
1292 {
1293         if (!self.owner.modelindex)
1294         {
1295                 self.owner.killindicator = world;
1296                 remove(self);
1297                 return;
1298         }
1299
1300         if(self.cnt <= 0)
1301         {
1302                 self = self.owner;
1303                 ClientKill_Now(); // no oldself needed
1304                 return;
1305         }
1306     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1307     {
1308         self.nextthink = time + 1;
1309         self.cnt -= 1;
1310     }
1311         else
1312         {
1313                 if(self.cnt <= 10)
1314                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1315                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1316                 {
1317                         if(self.cnt <= 10)
1318                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1319                         if(self.owner.killindicator_teamchange)
1320                         {
1321                                 if(self.owner.killindicator_teamchange == -1)
1322                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1323                                 else if(self.owner.killindicator_teamchange == -2)
1324                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1325                                 else
1326                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1327                         }
1328                         else
1329                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1330                 }
1331                 self.nextthink = time + 1;
1332                 self.cnt -= 1;
1333         }
1334 }
1335
1336 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1337 {
1338         float killtime;
1339         entity e;
1340         killtime = autocvar_g_balance_kill_delay;
1341
1342         if(g_race_qualifying || g_cts)
1343                 killtime = 0;
1344
1345     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1346     {
1347                 remove(self.killindicator);
1348                 self.killindicator = world;
1349
1350         ClientKill_Now(); // allow instant kill in this case
1351         return;
1352     }
1353
1354         self.killindicator_teamchange = targetteam;
1355
1356     if(!self.killindicator)
1357         {
1358                 if(self.modelindex && self.deadflag == DEAD_NO)
1359                 {
1360                         killtime = max(killtime, self.clientkill_nexttime - time);
1361                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1362                 }
1363
1364                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1365                 {
1366                         ClientKill_Now();
1367                 }
1368                 else
1369                 {
1370                         self.killindicator = spawn();
1371                         self.killindicator.owner = self;
1372                         self.killindicator.scale = 0.5;
1373                         setattachment(self.killindicator, self, "");
1374                         setorigin(self.killindicator, '0 0 52');
1375                         self.killindicator.think = KillIndicator_Think;
1376                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1377                         self.killindicator.cnt = ceil(killtime);
1378                         self.killindicator.count = bound(0, ceil(killtime), 10);
1379                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1380
1381                         for(e = world; (e = find(e, classname, "body")) != world; )
1382                         {
1383                                 if(e.enemy != self)
1384                                         continue;
1385                                 e.killindicator = spawn();
1386                                 e.killindicator.owner = e;
1387                                 e.killindicator.scale = 0.5;
1388                                 setattachment(e.killindicator, e, "");
1389                                 setorigin(e.killindicator, '0 0 52');
1390                                 e.killindicator.think = KillIndicator_Think;
1391                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1392                                 e.killindicator.cnt = ceil(killtime);
1393                         }
1394                         self.lip = 0;
1395                 }
1396         }
1397         if(self.killindicator)
1398         {
1399                 if(targetteam == 0) // just die
1400                         self.killindicator.colormod = '0 0 0';
1401                 else if(targetteam == -1) // auto
1402                         self.killindicator.colormod = '0 1 0';
1403                 else if(targetteam == -2) // spectate
1404                         self.killindicator.colormod = '0.5 0.5 0.5';
1405                 else
1406                         self.killindicator.colormod = TeamColor(targetteam);
1407         }
1408 }
1409
1410 void ClientKill (void)
1411 {
1412         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1413         {
1414                 // do nothing
1415         }
1416     else if(self.freezetag_frozen)
1417     {
1418         // do nothing
1419     }
1420         else
1421                 ClientKill_TeamChange(0);
1422 }
1423
1424 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1425 {
1426     e.killindicator = spawn();
1427     e.killindicator.owner = e;
1428     e.killindicator.think = KillIndicator_Think;
1429     e.killindicator.nextthink = time + (e.lip) * 0.05;
1430     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1431     e.killindicator.health = 1; // this is used to indicate that it should be silent
1432     e.lip = 0;
1433 }
1434
1435 void DoTeamChange(float destteam)
1436 {
1437         float t, c0;
1438         if(!teamplay)
1439         {
1440                 if(destteam >= 0)
1441                         SetPlayerColors(self, destteam);
1442                 return;
1443         }
1444         if(self.classname == "player")
1445         if(destteam == -1)
1446         {
1447                 CheckAllowedTeams(self);
1448                 t = FindSmallestTeam(self, TRUE);
1449                 switch(self.team)
1450                 {
1451                         case COLOR_TEAM1: c0 = c1; break;
1452                         case COLOR_TEAM2: c0 = c2; break;
1453                         case COLOR_TEAM3: c0 = c3; break;
1454                         case COLOR_TEAM4: c0 = c4; break;
1455                         default:          c0 = 999;
1456                 }
1457                 switch(t)
1458                 {
1459                         case 1:
1460                                 if(c0 > c1)
1461                                         destteam = COLOR_TEAM1;
1462                                 break;
1463                         case 2:
1464                                 if(c0 > c2)
1465                                         destteam = COLOR_TEAM2;
1466                                 break;
1467                         case 3:
1468                                 if(c0 > c3)
1469                                         destteam = COLOR_TEAM3;
1470                                 break;
1471                         case 4:
1472                                 if(c0 > c4)
1473                                         destteam = COLOR_TEAM4;
1474                                 break;
1475                 }
1476                 if(destteam == -1)
1477                         return;
1478         }
1479         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1480                 return;
1481         ClientKill_TeamChange(destteam);
1482 }
1483
1484 void FixClientCvars(entity e)
1485 {
1486         // send prediction settings to the client
1487         stuffcmd(e, "\nin_bindmap 0 0\n");
1488         if(g_race || g_cts)
1489                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1490         if(autocvar_g_antilag == 3) // client side hitscan
1491                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1492         if(sv_gentle)
1493                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1494         /*
1495          * we no longer need to stuff this. Remove this comment block if you feel
1496          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1497         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1498         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1499         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1500         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1501         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1502         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1503         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1504         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1505         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1506         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1507         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1508         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1509         stuffcmd(e, "cl_movement_edgefriction 1\n");
1510          */
1511 }
1512
1513 float PlayerInIDList(entity p, string idlist)
1514 {
1515         float n, i;
1516         string s;
1517
1518         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1519         if not(p.crypto_idfp)
1520                 return 0;
1521
1522         // this function allows abbreviated player IDs too!
1523         n = tokenize_console(idlist);
1524         for(i = 0; i < n; ++i)
1525         {
1526                 s = argv(i);
1527                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1528                         return 1;
1529         }
1530
1531         return 0;
1532 }
1533
1534 /*
1535 =============
1536 ClientConnect
1537
1538 Called when a client connects to the server
1539 =============
1540 */
1541 //void ctf_clientconnect();
1542 string ColoredTeamName(float t);
1543 void DecodeLevelParms (void);
1544 //void dom_player_join_team(entity pl);
1545 void set_dom_state(entity e);
1546 void ClientConnect (void)
1547 {
1548         float t;
1549
1550         if(self.flags & FL_CLIENT)
1551         {
1552                 print("Warning: ClientConnect, but already connected!\n");
1553                 return;
1554         }
1555
1556         if(Ban_MaybeEnforceBan(self))
1557                 return;
1558
1559         DecodeLevelParms();
1560
1561 #ifdef WATERMARK
1562         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1563 #endif
1564
1565         self.classname = "player_joining";
1566
1567         self.flags = FL_CLIENT;
1568         self.version_nagtime = time + 10 + random() * 10;
1569
1570         if(player_count<0)
1571         {
1572                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1573                 player_count = 0;
1574         }
1575
1576         PlayerScore_Attach(self);
1577         ClientData_Attach();
1578         accuracy_init(self);
1579
1580         bot_clientconnect();
1581
1582         playerdemo_init();
1583
1584         anticheat_init();
1585
1586         race_PreSpawnObserver();
1587
1588         //if(g_domination)
1589         //      dom_player_join_team(self);
1590
1591         // identify the right forced team
1592         if(autocvar_g_campaign)
1593         {
1594                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1595                 {
1596                         switch(autocvar_g_campaign_forceteam)
1597                         {
1598                                 case 1: self.team_forced = COLOR_TEAM1; break;
1599                                 case 2: self.team_forced = COLOR_TEAM2; break;
1600                                 case 3: self.team_forced = COLOR_TEAM3; break;
1601                                 case 4: self.team_forced = COLOR_TEAM4; break;
1602                                 default: self.team_forced = 0;
1603                         }
1604                 }
1605         }
1606         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1607                 self.team_forced = COLOR_TEAM1;
1608         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1609                 self.team_forced = COLOR_TEAM2;
1610         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1611                 self.team_forced = COLOR_TEAM3;
1612         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1613                 self.team_forced = COLOR_TEAM4;
1614         else if(autocvar_g_forced_team_otherwise == "red")
1615                 self.team_forced = COLOR_TEAM1;
1616         else if(autocvar_g_forced_team_otherwise == "blue")
1617                 self.team_forced = COLOR_TEAM2;
1618         else if(autocvar_g_forced_team_otherwise == "yellow")
1619                 self.team_forced = COLOR_TEAM3;
1620         else if(autocvar_g_forced_team_otherwise == "pink")
1621                 self.team_forced = COLOR_TEAM4;
1622         else if(autocvar_g_forced_team_otherwise == "spectate")
1623                 self.team_forced = -1;
1624         else if(autocvar_g_forced_team_otherwise == "spectator")
1625                 self.team_forced = -1;
1626         else
1627                 self.team_forced = 0;
1628
1629         if(!teamplay)
1630                 if(self.team_forced > 0)
1631                         self.team_forced = 0;
1632
1633         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1634
1635         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1636                 self.classname = "observer";
1637         } else {
1638                 if(teamplay)
1639                 {
1640                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1641                         {
1642                                 self.classname = "player";
1643                                 campaign_bots_may_start = 1;
1644                         }
1645                         else
1646                         {
1647                                 self.classname = "observer"; // do it anyway
1648                         }
1649                 }
1650                 else
1651                 {
1652                         self.classname = "player";
1653                         campaign_bots_may_start = 1;
1654                 }
1655         }
1656
1657         self.playerid = (playerid_last = playerid_last + 1);
1658
1659     if(clienttype(self) == CLIENTTYPE_BOT)
1660         PlayerStats_AddPlayer(self);
1661
1662         if(autocvar_sv_eventlog)
1663                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1664
1665         LogTeamchange(self.playerid, self.team, 1);
1666
1667         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1668
1669         self.netname_previous = strzone(self.netname);
1670
1671         bprint("^4", self.netname, "^4 connected");
1672
1673         if(self.classname != "observer" && (g_domination || g_ctf))
1674                 bprint(" and joined the ", ColoredTeamName(self.team));
1675
1676         bprint("\n");
1677
1678         self.welcomemessage_time = 0;
1679
1680         stuffcmd(self, strcat(clientstuff, "\n"));
1681         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1682         stuffcmd(self, "cl_particles_reloadeffects\n");
1683
1684         FixClientCvars(self);
1685
1686         // spawnfunc_waypoint sprites
1687         WaypointSprite_InitClient(self);
1688
1689         // Wazat's grappling hook
1690         SetGrappleHookBindings();
1691
1692         // get autoswitch state from player when he toggles it
1693         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1694
1695         // get version info from player
1696         stuffcmd(self, "cmd clientversion $gameversion\n");
1697
1698         // get other cvars from player
1699         GetCvars(0);
1700
1701         // notify about available teams
1702         if(teamplay)
1703         {
1704                 CheckAllowedTeams(self);
1705                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1706                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1707         }
1708         else
1709                 stuffcmd(self, "set _teams_available 0\n");
1710
1711         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1712
1713         if(g_arena || g_ca)
1714         {
1715                 self.classname = "observer";
1716                 if(g_arena)
1717                         Spawnqueue_Insert(self);
1718         }
1719         /*else if(g_ctf)
1720         {
1721                 ctf_clientconnect();
1722         }*/
1723
1724         attach_entcs();
1725
1726         bot_relinkplayerlist();
1727
1728         self.spectatortime = time;
1729         if(blockSpectators)
1730         {
1731                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1732         }
1733
1734         self.jointime = time;
1735         self.allowedTimeouts = autocvar_sv_timeout_number;
1736
1737         if(clienttype(self) == CLIENTTYPE_REAL)
1738         {
1739                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1740                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1741         }
1742
1743         if(g_lms)
1744         {
1745                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1746                 {
1747                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1748                         self.frags = FRAGS_SPECTATOR;
1749                 }
1750         }
1751
1752         if(!sv_foginterval && world.fog != "")
1753                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1754
1755         SoundEntity_Attach(self);
1756
1757         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1758         {
1759                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1760                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1761         }
1762         else
1763                 self.hitplotfh = -1;
1764
1765         if(g_race || g_cts) {
1766                 string rr;
1767                 if(g_cts)
1768                         rr = CTS_RECORD;
1769                 else
1770                         rr = RACE_RECORD;
1771                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1772
1773                 msg_entity = self;
1774                 race_send_recordtime(MSG_ONE);
1775                 race_send_speedaward(MSG_ONE);
1776
1777                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1778                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1779                 race_send_speedaward_alltimebest(MSG_ONE);
1780
1781                 float i;
1782                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1783                         race_SendRankings(i, 0, 0, MSG_ONE);
1784                 }
1785         }
1786         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1787                 send_CSQC_teamnagger();
1788
1789         if (g_domination)
1790                 set_dom_state(self);
1791
1792         CheatInitClient();
1793 }
1794
1795 /*
1796 =============
1797 ClientDisconnect
1798
1799 Called when a client disconnects from the server
1800 =============
1801 */
1802 .entity chatbubbleentity;
1803 void ReadyCount();
1804 void ClientDisconnect (void)
1805 {
1806         if(self.vehicle)
1807             vehicles_exit(VHEF_RELESE);
1808
1809         if not(self.flags & FL_CLIENT)
1810         {
1811                 print("Warning: ClientDisconnect without ClientConnect\n");
1812                 return;
1813         }
1814
1815         PlayerStats_AddGlobalInfo(self);
1816
1817         CheatShutdownClient();
1818
1819         if(self.hitplotfh >= 0)
1820         {
1821                 fclose(self.hitplotfh);
1822                 self.hitplotfh = -1;
1823         }
1824
1825         anticheat_report();
1826         anticheat_shutdown();
1827
1828         playerdemo_shutdown();
1829
1830         bot_clientdisconnect();
1831
1832         if(self.entcs)
1833                 detach_entcs();
1834
1835         if(autocvar_sv_eventlog)
1836                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1837         bprint ("^4",self.netname);
1838         bprint ("^4 disconnected\n");
1839
1840         SoundEntity_Detach(self);
1841
1842         DropAllRunes(self);
1843         MUTATOR_CALLHOOK(ClientDisconnect);
1844
1845         Portal_ClearAll(self);
1846
1847         if(self.flagcarried)
1848                 DropFlag(self.flagcarried, world, world);
1849         if(self.ballcarried && g_nexball)
1850                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1851
1852         // Here, everything has been done that requires this player to be a client.
1853
1854         self.flags &~= FL_CLIENT;
1855
1856         if (self.chatbubbleentity)
1857                 remove (self.chatbubbleentity);
1858
1859         if (self.killindicator)
1860                 remove (self.killindicator);
1861
1862         WaypointSprite_PlayerGone();
1863
1864         bot_relinkplayerlist();
1865
1866         if(g_arena)
1867         {
1868                 Spawnqueue_Unmark(self);
1869                 Spawnqueue_Remove(self);
1870         }
1871
1872         accuracy_free(self);
1873         ClientData_Detach();
1874         PlayerScore_Detach(self);
1875
1876         if(self.netname_previous)
1877                 strunzone(self.netname_previous);
1878         if(self.clientstatus)
1879                 strunzone(self.clientstatus);
1880         if(self.weaponorder_byimpulse)
1881                 strunzone(self.weaponorder_byimpulse);
1882
1883         ClearPlayerSounds();
1884
1885         if(self.personal)
1886                 remove(self.personal);
1887
1888         self.playerid = 0;
1889         ReadyCount();
1890
1891         // free cvars
1892         GetCvars(-1);
1893 }
1894
1895 .float BUTTON_CHAT;
1896 void ChatBubbleThink()
1897 {
1898         self.nextthink = time;
1899         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1900         {
1901                 if(self.owner) // but why can that ever be world?
1902                         self.owner.chatbubbleentity = world;
1903                 remove(self);
1904                 return;
1905         }
1906         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1907 #ifdef TETRIS
1908                 || self.owner.tetris_on
1909 #endif
1910         )
1911                 self.model = self.mdl;
1912         else
1913                 self.model = "";
1914 };
1915
1916 void UpdateChatBubble()
1917 {
1918         if (!self.modelindex)
1919                 return;
1920         // spawn a chatbubble entity if needed
1921         if (!self.chatbubbleentity)
1922         {
1923                 self.chatbubbleentity = spawn();
1924                 self.chatbubbleentity.owner = self;
1925                 self.chatbubbleentity.exteriormodeltoclient = self;
1926                 self.chatbubbleentity.think = ChatBubbleThink;
1927                 self.chatbubbleentity.nextthink = time;
1928                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1929                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1930                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1931                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1932                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1933                 self.chatbubbleentity.model = "";
1934                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1935         }
1936 }
1937
1938
1939 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1940 // added to the model skins
1941 /*void UpdateColorModHack()
1942 {
1943         local float c;
1944         c = self.clientcolors & 15;
1945         // LordHavoc: only bothering to support white, green, red, yellow, blue
1946              if (!teamplay) self.colormod = '0 0 0';
1947         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1948         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1949         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1950         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1951         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1952         else self.colormod = '1 1 1';
1953 };*/
1954
1955 .float oldcolormap;
1956 void respawn(void)
1957 {
1958         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1959         {
1960                 self.solid = SOLID_NOT;
1961                 self.takedamage = DAMAGE_NO;
1962                 self.movetype = MOVETYPE_FLY;
1963                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1964                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1965                 self.effects |= EF_ADDITIVE;
1966                 self.oldcolormap = self.colormap;
1967                 self.colormap = 512;
1968                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1969                 if(autocvar_g_respawn_ghosts_maxtime)
1970                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1971         }
1972
1973         CopyBody(1);
1974         self.effects |= EF_NODRAW; // prevent another CopyBody
1975         if(self.oldcolormap)
1976         {
1977                 self.colormap = self.oldcolormap;
1978                 self.oldcolormap = 0;
1979         }
1980         PutClientInServer();
1981 }
1982
1983 void play_countdown(float finished, string samp)
1984 {
1985         if(clienttype(self) == CLIENTTYPE_REAL)
1986                 if(floor(finished - time - frametime) != floor(finished - time))
1987                         if(finished - time < 6)
1988                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1989 }
1990
1991 /**
1992  * When sv_timeout is used this function returs strings like
1993  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1994  * Called by centerprint functions
1995  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1996  */
1997 string getTimeoutText(float addOneSecond) {
1998         if (!autocvar_sv_timeout || !timeoutStatus)
1999                 return "";
2000
2001         local string retStr;
2002         if (timeoutStatus == 1) {
2003                 if (addOneSecond == 1) {
2004                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2005                 }
2006                 else {
2007                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2008                 }
2009                 return retStr;
2010         }
2011         else if (timeoutStatus == 2) {
2012                 if (addOneSecond) {
2013                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2014                         //don't show messages like "Timeout ends in 0 seconds"...
2015                         if ((remainingTimeoutTime + 1) > 0)
2016                                 return retStr;
2017                         else
2018                                 return "";
2019                 }
2020                 else {
2021                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2022                         //don't show messages like "Timeout ends in 0 seconds"...
2023                         if (remainingTimeoutTime > 0)
2024                                 return retStr;
2025                         else
2026                                 return "";
2027                 }
2028         }
2029         else return "";
2030 }
2031
2032 void player_powerups (void)
2033 {
2034         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2035         olditems = self.items;
2036
2037         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2038         {
2039                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2040                 self.modelflags |= MF_ROCKET;
2041         }
2042         else
2043         {
2044                 SoundEntity_StopSound(self, CHAN_PLAYER);
2045                 self.modelflags &~= MF_ROCKET;
2046         }
2047
2048         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2049
2050         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2051                 return;
2052
2053         Fire_ApplyDamage(self);
2054         Fire_ApplyEffect(self);
2055
2056         if (g_minstagib)
2057         {
2058                 self.effects |= EF_FULLBRIGHT;
2059
2060                 if (self.items & IT_STRENGTH)
2061                 {
2062                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2063                         if (time > self.strength_finished)
2064                         {
2065                                 self.alpha = default_player_alpha;
2066                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2067                                 self.items &~= IT_STRENGTH;
2068                                 sprint(self, "^3Invisibility has worn off\n");
2069                         }
2070                 }
2071                 else
2072                 {
2073                         if (time < self.strength_finished)
2074                         {
2075                                 self.alpha = g_minstagib_invis_alpha;
2076                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2077                                 self.items |= IT_STRENGTH;
2078                                 sprint(self, "^3You are invisible\n");
2079                         }
2080                 }
2081
2082                 if (self.items & IT_INVINCIBLE)
2083                 {
2084                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2085                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2086                         {
2087                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2088                                 sprint(self, "^3Speed has worn off\n");
2089                         }
2090                 }
2091                 else
2092                 {
2093                         if (time < self.invincible_finished)
2094                         {
2095                                 self.items = self.items | IT_INVINCIBLE;
2096                                 sprint(self, "^3You are on speed\n");
2097                         }
2098                 }
2099         }
2100         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2101         {
2102                 if (self.items & IT_STRENGTH)
2103                 {
2104                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2105                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2106                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2107                         {
2108                                 self.items = self.items - (self.items & IT_STRENGTH);
2109                                 sprint(self, "^3Strength has worn off\n");
2110                         }
2111                 }
2112                 else
2113                 {
2114                         if (time < self.strength_finished)
2115                         {
2116                                 self.items = self.items | IT_STRENGTH;
2117                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2118                         }
2119                 }
2120                 if (self.items & IT_INVINCIBLE)
2121                 {
2122                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2123                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2124                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2125                         {
2126                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2127                                 sprint(self, "^3Shield has worn off\n");
2128                         }
2129                 }
2130                 else
2131                 {
2132                         if (time < self.invincible_finished)
2133                         {
2134                                 self.items = self.items | IT_INVINCIBLE;
2135                                 sprint(self, "^3Shield surrounds you\n");
2136                         }
2137                 }
2138
2139                 if(autocvar_g_nodepthtestplayers)
2140                         self.effects = self.effects | EF_NODEPTHTEST;
2141
2142                 if(autocvar_g_fullbrightplayers)
2143                         self.effects = self.effects | EF_FULLBRIGHT;
2144
2145                 // midair gamemode: damage only while in the air
2146                 // if in midair mode, being on ground grants temporary invulnerability
2147                 // (this is so that multishot weapon don't clear the ground flag on the
2148                 // first damage in the frame, leaving the player vulnerable to the
2149                 // remaining hits in the same frame)
2150                 if (self.flags & FL_ONGROUND)
2151                 if (g_midair)
2152                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2153
2154                 if (time >= game_starttime)
2155                 if (time < self.spawnshieldtime)
2156                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2157         }
2158
2159         MUTATOR_CALLHOOK(PlayerPowerups);
2160 }
2161
2162 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2163 {
2164         if(current > stable)
2165                 return current;
2166         else if(current > stable - 0.25) // when close enough, "snap"
2167                 return stable;
2168         else
2169                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2170 }
2171
2172 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2173 {
2174         if(current < stable)
2175                 return current;
2176         else if(current < stable + 0.25) // when close enough, "snap"
2177                 return stable;
2178         else
2179                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2180 }
2181
2182 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2183 {
2184         if(current > rotstable)
2185         {
2186                 if(rotframetime > 0)
2187                 {
2188                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2189                         current = max(rotstable, current - rotlinear * rotframetime);
2190                 }
2191         }
2192         else if(current < regenstable)
2193         {
2194                 if(regenframetime > 0)
2195                 {
2196                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2197                         current = min(regenstable, current + regenlinear * regenframetime);
2198                 }
2199         }
2200
2201         if(current > limit)
2202                 current = limit;
2203
2204         return current;
2205 }
2206
2207 void player_regen (void)
2208 {
2209         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2210         maxh = autocvar_g_balance_health_rotstable;
2211         maxa = autocvar_g_balance_armor_rotstable;
2212         maxf = autocvar_g_balance_fuel_rotstable;
2213         minh = autocvar_g_balance_health_regenstable;
2214         mina = autocvar_g_balance_armor_regenstable;
2215         minf = autocvar_g_balance_fuel_regenstable;
2216         limith = autocvar_g_balance_health_limit;
2217         limita = autocvar_g_balance_armor_limit;
2218         limitf = autocvar_g_balance_fuel_limit;
2219
2220         max_mod = regen_mod = rot_mod = limit_mod = 1;
2221
2222         if (self.runes & RUNE_REGEN)
2223         {
2224                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2225                 {
2226                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2227                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2228                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2229                 }
2230                 else
2231                 {
2232                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2233                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2234                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2235                 }
2236         }
2237         else if (self.runes & CURSE_VENOM)
2238         {
2239                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2240                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2241                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2242                 else
2243                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2244                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2245                 //if (!self.runes & RUNE_REGEN)
2246                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2247         }
2248         maxh = maxh * max_mod;
2249         //maxa = maxa * max_mod;
2250         //maxf = maxf * max_mod;
2251         minh = minh * max_mod;
2252         //mina = mina * max_mod;
2253         //minf = minf * max_mod;
2254         limith = limith * limit_mod;
2255         limita = limita * limit_mod;
2256         //limitf = limitf * limit_mod;
2257
2258         if(g_lms && g_ca)
2259                 rot_mod = 0;
2260
2261         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2262         {
2263                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2264                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2265
2266                 // if player rotted to death...  die!
2267                 if(self.health < 1)
2268                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2269         }
2270
2271         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2272                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2273 }
2274
2275 float zoomstate_set;
2276 void SetZoomState(float z)
2277 {
2278         if(z != self.zoomstate)
2279         {
2280                 self.zoomstate = z;
2281                 ClientData_Touch(self);
2282         }
2283         zoomstate_set = 1;
2284 }
2285
2286 void GetPressedKeys(void) {
2287         MUTATOR_CALLHOOK(GetPressedKeys);
2288         if (self.movement_x > 0) // get if movement keys are pressed
2289         {       // forward key pressed
2290                 self.pressedkeys |= KEY_FORWARD;
2291                 self.pressedkeys &~= KEY_BACKWARD;
2292         }
2293         else if (self.movement_x < 0)
2294         {       // backward key pressed
2295                 self.pressedkeys |= KEY_BACKWARD;
2296                 self.pressedkeys &~= KEY_FORWARD;
2297         }
2298         else
2299         {       // no x input
2300                 self.pressedkeys &~= KEY_FORWARD;
2301                 self.pressedkeys &~= KEY_BACKWARD;
2302         }
2303
2304         if (self.movement_y > 0)
2305         {       // right key pressed
2306                 self.pressedkeys |= KEY_RIGHT;
2307                 self.pressedkeys &~= KEY_LEFT;
2308         }
2309         else if (self.movement_y < 0)
2310         {       // left key pressed
2311                 self.pressedkeys |= KEY_LEFT;
2312                 self.pressedkeys &~= KEY_RIGHT;
2313         }
2314         else
2315         {       // no y input
2316                 self.pressedkeys &~= KEY_RIGHT;
2317                 self.pressedkeys &~= KEY_LEFT;
2318         }
2319
2320         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2321                 self.pressedkeys |= KEY_JUMP;
2322         else
2323                 self.pressedkeys &~= KEY_JUMP;
2324         if (self.BUTTON_CROUCH)
2325                 self.pressedkeys |= KEY_CROUCH;
2326         else
2327                 self.pressedkeys &~= KEY_CROUCH;
2328 }
2329
2330 /*
2331 ======================
2332 spectate mode routines
2333 ======================
2334 */
2335
2336 void SpectateCopy(entity spectatee) {
2337         other = spectatee;
2338         MUTATOR_CALLHOOK(SpectateCopy);
2339         self.armortype = spectatee.armortype;
2340         self.armorvalue = spectatee.armorvalue;
2341         self.ammo_cells = spectatee.ammo_cells;
2342         self.ammo_shells = spectatee.ammo_shells;
2343         self.ammo_nails = spectatee.ammo_nails;
2344         self.ammo_rockets = spectatee.ammo_rockets;
2345         self.ammo_fuel = spectatee.ammo_fuel;
2346         self.clip_load = spectatee.clip_load;
2347         self.clip_size = spectatee.clip_size;
2348         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2349         self.health = spectatee.health;
2350         self.impulse = 0;
2351         self.items = spectatee.items;
2352         self.last_pickup = spectatee.last_pickup;
2353         self.hit_time = spectatee.hit_time;
2354         self.metertime = spectatee.metertime;
2355         self.strength_finished = spectatee.strength_finished;
2356         self.invincible_finished = spectatee.invincible_finished;
2357         self.pressedkeys = spectatee.pressedkeys;
2358         self.weapons = spectatee.weapons;
2359         self.switchweapon = spectatee.switchweapon;
2360         self.weapon = spectatee.weapon;
2361         self.nex_charge = spectatee.nex_charge;
2362         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2363         self.hagar_load = spectatee.hagar_load;
2364         self.minelayer_mines = spectatee.minelayer_mines;
2365         self.punchangle = spectatee.punchangle;
2366         self.view_ofs = spectatee.view_ofs;
2367         self.v_angle = spectatee.v_angle;
2368         self.velocity = spectatee.velocity;
2369         self.dmg_take = spectatee.dmg_take;
2370         self.dmg_save = spectatee.dmg_save;
2371         self.dmg_inflictor = spectatee.dmg_inflictor;
2372         self.angles = spectatee.v_angle;
2373         //self.fixangle = TRUE;
2374         setorigin(self, spectatee.origin);
2375         setsize(self, spectatee.mins, spectatee.maxs);
2376         SetZoomState(spectatee.zoomstate);
2377
2378         anticheat_spectatecopy(spectatee);
2379
2380         //self.vehicle = spectatee.vehicle;
2381
2382         self.hud = spectatee.hud;
2383         if(spectatee.vehicle)
2384     {
2385         setorigin(self, spectatee.origin);
2386         self.velocity = spectatee.vehicle.velocity;
2387         //self.v_angle += spectatee.vehicle.angles;
2388         //self.v_angle_x *= -1;
2389         self.vehicle_health = spectatee.vehicle_health;
2390         self.vehicle_shield = spectatee.vehicle_shield;
2391         self.vehicle_energy = spectatee.vehicle_energy;
2392         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2393         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2394         self.vehicle_reload1 = spectatee.vehicle_reload1;
2395         self.vehicle_reload2 = spectatee.vehicle_reload2;
2396
2397         msg_entity = self;
2398         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2399         WriteEntity(MSG_ONE, spectatee);
2400         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2401     }
2402 }
2403
2404 float SpectateUpdate() {
2405         if(!self.enemy)
2406             return 0;
2407
2408         if (self == self.enemy)
2409                 return 0;
2410
2411         if(self.enemy.classname != "player")
2412                 return 0;
2413
2414         SpectateCopy(self.enemy);
2415
2416         return 1;
2417 }
2418
2419 float SpectateNext() {
2420         other = find(self.enemy, classname, "player");
2421
2422         if (!other)
2423                 other = find(other, classname, "player");
2424
2425         if (other)
2426                 self.enemy = other;
2427
2428         if(self.enemy.classname == "player") {
2429             if(self.enemy.vehicle)
2430             {
2431             msg_entity = self;
2432             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2433             WriteEntity(MSG_ONE, self.enemy);
2434             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2435             self.movetype = MOVETYPE_NONE;
2436             accuracy_resend(self);
2437             }
2438             else
2439             {
2440             msg_entity = self;
2441             WriteByte(MSG_ONE, SVC_SETVIEW);
2442             WriteEntity(MSG_ONE, self.enemy);
2443             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2444             self.movetype = MOVETYPE_NONE;
2445             accuracy_resend(self);
2446
2447             if(!SpectateUpdate())
2448                 PutObserverInServer();
2449         }
2450         return 1;
2451         } else {
2452                 return 0;
2453         }
2454 }
2455
2456 /*
2457 =============
2458 ShowRespawnCountdown()
2459
2460 Update a respawn countdown display.
2461 =============
2462 */
2463 void ShowRespawnCountdown()
2464 {
2465         float number;
2466         if(self.deadflag == DEAD_NO) // just respawned?
2467                 return;
2468         else
2469         {
2470                 number = ceil(self.death_time - time);
2471                 if(number <= 0)
2472                         return;
2473                 if(number <= self.respawn_countdown)
2474                 {
2475                         self.respawn_countdown = number - 1;
2476                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2477                                 AnnounceTo(self, strcat(ftos(number), ""));
2478                 }
2479         }
2480 }
2481
2482 void LeaveSpectatorMode()
2483 {
2484         if(nJoinAllowed(1)) {
2485                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2486                         self.classname = "player";
2487
2488                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2489                                 JoinBestTeam(self, FALSE, TRUE);
2490
2491                         if(autocvar_g_campaign)
2492                                 campaign_bots_may_start = 1;
2493
2494                         PutClientInServer();
2495
2496                         if(self.classname == "player")
2497                                 bprint ("^4", self.netname, "^4 is playing now\n");
2498
2499                         if(!autocvar_g_campaign)
2500                                 centerprint(self,""); // clear MOTD
2501
2502                         return;
2503                 } else {
2504                         if (g_ca && self.caplayer) {
2505                         }       // do nothing
2506                         else
2507                                 stuffcmd(self,"menu_showteamselect\n");
2508                         return;
2509                 }
2510         }
2511         else {
2512                 //player may not join because of g_maxplayers is set
2513                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2514         }
2515 }
2516
2517 /**
2518  * Determines whether the player is allowed to join. This depends on cvar
2519  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2520  * it checks whether the number of currently playing players exceeds g_maxplayers.
2521  * @return int number of free slots for players, 0 if none
2522  */
2523 float nJoinAllowed(float includeMe) {
2524         if(self.team_forced < 0)
2525                 return FALSE; // forced spectators can never join
2526
2527         // TODO simplify this
2528         local entity e;
2529
2530         local float totalClients;
2531         FOR_EACH_CLIENT(e)
2532                 totalClients += 1;
2533
2534         if (!autocvar_g_maxplayers)
2535                 return maxclients - totalClients + includeMe;
2536
2537         local float currentlyPlaying;
2538         FOR_EACH_REALPLAYER(e)
2539                 currentlyPlaying += 1;
2540
2541         if(currentlyPlaying < autocvar_g_maxplayers)
2542                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2543
2544         return 0;
2545 }
2546
2547 /**
2548  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2549  * g_maxplayers_spectator_blocktime seconds
2550  */
2551 void checkSpectatorBlock() {
2552         if(self.classname == "spectator" || self.classname == "observer") {
2553                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2554                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2555                         dropclient(self);
2556                 }
2557         }
2558 }
2559
2560 void ObserverThink()
2561 {
2562         if (self.flags & FL_JUMPRELEASED) {
2563                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2564                         self.welcomemessage_time = 0;
2565                         self.flags &~= FL_JUMPRELEASED;
2566                         self.flags |= FL_SPAWNING;
2567                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2568                         self.welcomemessage_time = 0;
2569                         self.flags &~= FL_JUMPRELEASED;
2570                         if(SpectateNext() == 1) {
2571                                 self.classname = "spectator";
2572                         }
2573                 }
2574         } else {
2575                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2576                         self.flags |= FL_JUMPRELEASED;
2577                         if(self.flags & FL_SPAWNING)
2578                         {
2579                                 self.flags &~= FL_SPAWNING;
2580                                 LeaveSpectatorMode();
2581                                 return;
2582                         }
2583                 }
2584         }
2585         PrintWelcomeMessage(self);
2586 }
2587
2588 void SpectatorThink()
2589 {
2590         if (self.flags & FL_JUMPRELEASED) {
2591                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2592                         self.welcomemessage_time = 0;
2593                         self.flags &~= FL_JUMPRELEASED;
2594                         self.flags |= FL_SPAWNING;
2595                 } else if(self.BUTTON_ATCK) {
2596                         self.welcomemessage_time = 0;
2597                         self.flags &~= FL_JUMPRELEASED;
2598                         if(SpectateNext() == 1) {
2599                                 self.classname = "spectator";
2600                         } else {
2601                                 self.classname = "observer";
2602                                 PutClientInServer();
2603                         }
2604                 } else if (self.BUTTON_ATCK2) {
2605                         self.welcomemessage_time = 0;
2606                         self.flags &~= FL_JUMPRELEASED;
2607                         self.classname = "observer";
2608                         PutClientInServer();
2609                 } else {
2610                         if(!SpectateUpdate())
2611                                 PutObserverInServer();
2612                 }
2613         } else {
2614                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2615                         self.flags |= FL_JUMPRELEASED;
2616                         if(self.flags & FL_SPAWNING)
2617                         {
2618                                 self.flags &~= FL_SPAWNING;
2619                                 LeaveSpectatorMode();
2620                                 return;
2621                         }
2622                 }
2623         }
2624
2625         PrintWelcomeMessage(self);
2626         self.flags |= FL_CLIENT | FL_NOTARGET;
2627 }
2628
2629 float ctf_usekey();
2630 void PlayerUseKey()
2631 {
2632         if(self.classname != "player")
2633                 return;
2634
2635         if(self.vehicle)
2636         {
2637         vehicles_exit(VHEF_NORMAL);
2638         return;
2639         }
2640
2641         // a use key was pressed; call handlers
2642         if(ctf_usekey())
2643                 return;
2644
2645         MUTATOR_CALLHOOK(PlayerUseKey);
2646 }
2647
2648 .float touchexplode_time;
2649
2650 /*
2651 =============
2652 PlayerPreThink
2653
2654 Called every frame for each client before the physics are run
2655 =============
2656 */
2657 .float usekeypressed;
2658 void() ctf_setstatus;
2659 void() nexball_setstatus;
2660 .float items_added;
2661 void PlayerPreThink (void)
2662 {
2663         WarpZone_PlayerPhysics_FixVAngle();
2664
2665         self.stat_game_starttime = game_starttime;
2666         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2667         self.stat_leadlimit = autocvar_leadlimit;
2668
2669         if(frametime)
2670         {
2671                 // physics frames: update anticheat stuff
2672                 anticheat_prethink();
2673         }
2674
2675         if(blockSpectators && frametime)
2676                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2677                 checkSpectatorBlock();
2678
2679         zoomstate_set = 0;
2680
2681         if(self.netname_previous != self.netname)
2682         {
2683                 if(autocvar_sv_eventlog)
2684                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2685                 if(self.netname_previous)
2686                         strunzone(self.netname_previous);
2687                 self.netname_previous = strzone(self.netname);
2688         }
2689
2690         // version nagging
2691         if(self.version_nagtime)
2692                 if(self.cvar_g_xonoticversion)
2693                         if(time > self.version_nagtime)
2694                         {
2695                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2696                                 {
2697                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2698                                         {
2699                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2700                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2701                                         }
2702                                         else
2703                                         {
2704                                                 float r;
2705                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2706                                                 if(r < 0)
2707                                                 {
2708                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2709                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2710                                                 }
2711                                                 else if(r > 0)
2712                                                 {
2713                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2714                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2715                                                 }
2716                                         }
2717                                 }
2718                                 self.version_nagtime = 0;
2719                         }
2720
2721         // GOD MODE info
2722         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2723         {
2724                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2725                 self.max_armorvalue = 0;
2726         }
2727
2728 #ifdef TETRIS
2729         if (TetrisPreFrame())
2730                 return;
2731 #endif
2732
2733         MUTATOR_CALLHOOK(PlayerPreThink);
2734
2735         if(self.BUTTON_USE && !self.usekeypressed)
2736                 PlayerUseKey();
2737         self.usekeypressed = self.BUTTON_USE;
2738
2739         if(self.classname == "player") {
2740 //              if(self.netname == "Wazat")
2741 //                      bprint(self.classname, "\n");
2742
2743                 CheckRules_Player();
2744
2745                 PrintWelcomeMessage(self);
2746
2747                 if (intermission_running)
2748                 {
2749                         IntermissionThink ();   // otherwise a button could be missed between
2750                         return;                                 // the think tics
2751                 }
2752
2753                 //don't allow the player to turn around while game is paused!
2754                 if(timeoutStatus == 2) {
2755                         // FIXME turn this into CSQC stuff
2756                         self.v_angle = self.lastV_angle;
2757                         self.angles = self.lastV_angle;
2758                         self.fixangle = TRUE;
2759                 }
2760
2761                 if(frametime)
2762                 {
2763                         if(self.health <= 0 && autocvar_g_deathglow)
2764                         {
2765                                 if(self.glowmod_x > 0)
2766                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2767                                 else
2768                                         self.glowmod_x = -1;
2769                                 if(self.glowmod_y > 0)
2770                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2771                                 else
2772                                         self.glowmod_y = -1;
2773                                 if(self.glowmod_z > 0)
2774                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2775                                 else
2776                                         self.glowmod_z = -1;
2777                         }
2778                         else
2779                         {
2780                                 // set weapon and player glowmod
2781                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2782
2783                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2784                                 {
2785                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2786                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2787                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2788
2789                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2790                                         {
2791                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2792                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2793                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2794                                         }
2795                                 }
2796                                 else
2797                                         self.weaponentity_glowmod = self.glowmod;
2798                         }
2799                         player_powerups();
2800                 }
2801
2802                 if (self.deadflag != DEAD_NO)
2803                 {
2804                         float button_pressed, force_respawn;
2805                         if(self.personal && g_race_qualifying)
2806                         {
2807                                 if(time > self.death_time)
2808                                 {
2809                                         self.death_time = time + 1; // only retry once a second
2810                                         respawn();
2811                                         self.impulse = 141;
2812                                 }
2813                         }
2814                         else
2815                         {
2816                                 if(frametime)
2817                                         player_anim();
2818                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2819                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2820                                 if (self.deadflag == DEAD_DYING)
2821                                 {
2822                                         if(force_respawn)
2823                                                 self.deadflag = DEAD_RESPAWNING;
2824                                         else if(!button_pressed)
2825                                                 self.deadflag = DEAD_DEAD;
2826                                 }
2827                                 else if (self.deadflag == DEAD_DEAD)
2828                                 {
2829                                         if(button_pressed)
2830                                                 self.deadflag = DEAD_RESPAWNABLE;
2831                                 }
2832                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2833                                 {
2834                                         if(!button_pressed)
2835                                                 self.deadflag = DEAD_RESPAWNING;
2836                                 }
2837                                 else if (self.deadflag == DEAD_RESPAWNING)
2838                                 {
2839                                         if(time > self.death_time)
2840                                         {
2841                                                 self.death_time = time + 1; // only retry once a second
2842                                                 respawn();
2843                                         }
2844                                 }
2845                                 ShowRespawnCountdown();
2846                         }
2847                         return;
2848                 }
2849
2850                 if(g_touchexplode)
2851                 if(time > self.touchexplode_time)
2852                 if(self.classname == "player")
2853                 if(self.deadflag == DEAD_NO)
2854                 if not(IS_INDEPENDENT_PLAYER(self))
2855                 FOR_EACH_PLAYER(other) if(self != other)
2856                 {
2857                         if(time > other.touchexplode_time)
2858                         if(other.deadflag == DEAD_NO)
2859                         if not(IS_INDEPENDENT_PLAYER(other))
2860                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2861                         {
2862                                 PlayerTouchExplode(self, other);
2863                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2864                         }
2865                 }
2866
2867                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2868                 {
2869                         vector dist;
2870
2871                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2872                         dist = self.prevorigin - self.origin;
2873                         dist_z = 0;
2874                         self.lms_traveled_distance += fabs(vlen(dist));
2875
2876                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2877                         {
2878                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2879                                 self.lms_traveled_distance = 0;
2880                         }
2881
2882                         if(time > self.lms_nextcheck)
2883                         {
2884                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2885                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2886                                 {
2887                                         centerprint(self, autocvar_g_lms_campcheck_message);
2888                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2889                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2890                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2891                                 }
2892                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2893                                 self.lms_traveled_distance = 0;
2894                         }
2895                 }
2896
2897                 self.prevorigin = self.origin;
2898
2899                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2900                 {
2901                         if (!self.crouch)
2902                         {
2903                                 self.crouch = TRUE;
2904                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2905                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2906                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2907                         }
2908                 }
2909                 else
2910                 {
2911                         if (self.crouch)
2912                         {
2913                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2914                                 if (!trace_startsolid)
2915                                 {
2916                                         self.crouch = FALSE;
2917                                         self.view_ofs = PL_VIEW_OFS;
2918                                         setsize (self, PL_MIN, PL_MAX);
2919                                 }
2920                         }
2921                 }
2922
2923                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2924                 {
2925                         if(self.bloodloss_timer < time)
2926                         {
2927                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2928                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2929                         }
2930                 }
2931
2932                 FixPlayermodel();
2933
2934                 GrapplingHookFrame();
2935
2936                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2937                 //if(frametime)
2938                 {
2939                         self.items &~= self.items_added;
2940
2941                         W_WeaponFrame();
2942
2943                         self.items_added = 0;
2944                         if(self.items & IT_JETPACK)
2945                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2946                                         self.items_added |= IT_FUEL;
2947
2948                         self.items |= self.items_added;
2949                 }
2950
2951                 player_regen();
2952
2953                 // rot nex charge to the charge limit
2954                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2955                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2956
2957                 if(frametime)
2958                         player_anim();
2959
2960                 if (g_minstagib)
2961                         minstagib_ammocheck();
2962
2963                 if(g_ctf)
2964                         ctf_setstatus();
2965
2966                 if(g_nexball)
2967                         nexball_setstatus();
2968
2969                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2970
2971                 //self.angles_y=self.v_angle_y + 90;   // temp
2972         } else if(gameover) {
2973                 if (intermission_running)
2974                         IntermissionThink ();   // otherwise a button could be missed between
2975                 return;
2976         } else if(self.classname == "observer") {
2977                 ObserverThink();
2978         } else if(self.classname == "spectator") {
2979                 SpectatorThink();
2980         }
2981
2982         if(!zoomstate_set)
2983                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2984
2985         float oldspectatee_status;
2986         oldspectatee_status = self.spectatee_status;
2987         if(self.classname == "spectator")
2988                 self.spectatee_status = num_for_edict(self.enemy);
2989         else if(self.classname == "observer")
2990                 self.spectatee_status = num_for_edict(self);
2991         else
2992                 self.spectatee_status = 0;
2993         if(self.spectatee_status != oldspectatee_status)
2994         {
2995                 ClientData_Touch(self);
2996                 if(g_race || g_cts)
2997                         race_InitSpectator();
2998         }
2999
3000         if(self.teamkill_soundtime)
3001         if(time > self.teamkill_soundtime)
3002         {
3003                 self.teamkill_soundtime = 0;
3004
3005                 entity oldpusher, oldself;
3006
3007                 oldself = self; self = self.teamkill_soundsource;
3008                 oldpusher = self.pusher; self.pusher = oldself;
3009
3010                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3011
3012                 self.pusher = oldpusher;
3013                 self = oldself;
3014         }
3015
3016         if(self.taunt_soundtime)
3017         if(time > self.taunt_soundtime)
3018         {
3019                 self.taunt_soundtime = 0;
3020                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
3021         }
3022
3023         target_voicescript_next(self);
3024
3025         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3026         if(!self.weapon)
3027                 self.clip_load = self.clip_size = 0;
3028 }
3029
3030 float isInvisibleString(string s)
3031 {
3032         float i, n, c;
3033         s = strdecolorize(s);
3034         for((i = 0), (n = strlen(s)); i < n; ++i)
3035         {
3036                 c = str2chr(s, i);
3037                 switch(c)
3038                 {
3039                         case 0:
3040                         case 32: // space
3041                                 break;
3042                         case 192: // charmap space
3043                                 if (!autocvar_utf8_enable)
3044                                         break;
3045                                 return FALSE;
3046                         case 160: // space in unicode fonts
3047                         case 0xE000 + 192: // utf8 charmap space
3048                                 if (autocvar_utf8_enable)
3049                                         break;
3050                         default:
3051                                 return FALSE;
3052                 }
3053         }
3054         return TRUE;
3055 }
3056
3057 /*
3058 =============
3059 PlayerPostThink
3060
3061 Called every frame for each client after the physics are run
3062 =============
3063 */
3064 .float idlekick_lasttimeleft;
3065 .entity showheadshotbbox;
3066 void showheadshotbbox_think()
3067 {
3068         if(self.owner.showheadshotbbox != self)
3069         {
3070                 remove(self);
3071                 return;
3072         }
3073         self.nextthink = time;
3074         setorigin(self, self.owner.origin);
3075         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3076 }
3077 void PlayerPostThink (void)
3078 {
3079         // Savage: Check for nameless players
3080         if (isInvisibleString(self.netname)) {
3081                 self.netname = "Player";
3082                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3083         }
3084
3085         if(sv_maxidle && frametime)
3086         {
3087                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3088                 float timeleft;
3089                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3090                 if(timeleft <= 0)
3091                 {
3092                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3093                         AnnounceTo(self, "terminated");
3094                         dropclient(self);
3095                         return;
3096                 }
3097                 else if(timeleft <= 10)
3098                 {
3099                         if(timeleft != self.idlekick_lasttimeleft)
3100                         {
3101                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3102                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3103                         }
3104                 }
3105                 else
3106                 {
3107                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3108                 }
3109                 self.idlekick_lasttimeleft = timeleft;
3110         }
3111
3112 #ifdef TETRIS
3113         if(self.impulse == 100)
3114                 ImpulseCommands();
3115         if (TetrisPostFrame())
3116                 return;
3117 #endif
3118
3119         CheatFrame();
3120
3121         if(self.classname == "player") {
3122                 CheckRules_Player();
3123                 UpdateChatBubble();
3124                 if (self.impulse)
3125                         ImpulseCommands();
3126                 if (intermission_running)
3127                         return;         // intermission or finale
3128                 GetPressedKeys();
3129         } else if (self.classname == "observer") {
3130                 //do nothing
3131         } else if (self.classname == "spectator") {
3132                 //do nothing
3133         }
3134
3135         /*
3136         float i;
3137         for(i = 0; i < 1000; ++i)
3138         {
3139                 vector end;
3140                 end = self.origin + '0 0 1024' + 512 * randomvec();
3141                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3142                 if(trace_fraction < 1)
3143                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3144                 {
3145                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3146                         break;
3147                 }
3148         }
3149         */
3150
3151         Arena_Warmup();
3152
3153         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3154
3155         if(self.waypointsprite_attachedforcarrier)
3156                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3157
3158         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3159         {
3160                 if(!self.showheadshotbbox)
3161                 {
3162                         self.showheadshotbbox = spawn();
3163                         self.showheadshotbbox.classname = "headshotbbox";
3164                         self.showheadshotbbox.owner = self;
3165                         self.showheadshotbbox.think = showheadshotbbox_think;
3166                         self.showheadshotbbox.nextthink = time;
3167                         self = self.showheadshotbbox;
3168                         self.think();
3169                         self = self.owner;
3170                 }
3171         }
3172         else
3173         {
3174                 if(self.showheadshotbbox)
3175                         remove(self.showheadshotbbox);
3176         }
3177
3178         playerdemo_write();
3179
3180         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3181         {
3182                 if(!self.stored_netname)
3183                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3184                 if(self.stored_netname != self.netname)
3185                 {
3186                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3187                         strunzone(self.stored_netname);
3188                         self.stored_netname = strzone(self.netname);
3189                 }
3190         }
3191
3192         /*
3193         if(g_race)
3194                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3195         */
3196 }