qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(cvar("spawn_debugview"))
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > cvar("g_spawn_furthest"))
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(cvar("spawn_debugview"))
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(cvar("spawn_debug"))
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel = "models/player/marine.zym";
 402 string CheckPlayerModel(string plyermodel) {
 403         if(strlen(plyermodel) < 4)
 404                 return FallbackPlayerModel;
 405         if( substring(plyermodel,0,14) != "models/player/")
 406                 return FallbackPlayerModel;
 407         else if(cvar("sv_servermodelsonly"))
 408         {
 409                 if(substring(plyermodel,-4,4) != ".zym")
 410                 if(substring(plyermodel,-4,4) != ".dpm")
 411                 if(substring(plyermodel,-4,4) != ".md3")
 412                 if(substring(plyermodel,-4,4) != ".psk")
 413                         return FallbackPlayerModel;
 414                 // forbid the LOD models
 415                 if(substring(plyermodel, -9,5) == "_lod1")
 416                         return FallbackPlayerModel;
 417                 if(substring(plyermodel, -9,5) == "_lod2")
 418                         return FallbackPlayerModel;
 419                 if(plyermodel != strtolower(plyermodel))
 420                         return FallbackPlayerModel;
 421                 if(!fexists(plyermodel))
 422                         return FallbackPlayerModel;
 423         }
 424         return plyermodel;
 425 }
 426
 427 /*
 428 =============
 429 Client_customizeentityforclient
 430
 431 LOD reduction
 432 =============
 433 */
 434 void Client_uncustomizeentityforclient()
 435 {
 436         if(self.modelindex == 0) // no need to uncustomize then
 437                 return;
 438         self.modelindex = self.modelindex_lod0;
 439         self.skin = self.skinindex;
 440 }
 441
 442 float Client_customizeentityforclient()
 443 {
 444         entity modelsource;
 445
 446         if(self.modelindex == 0)
 447                 return TRUE;
 448
 449         // forcemodel stuff
 450
 451 #ifdef PROFILING
 452         float t0;
 453         t0 = gettime(GETTIME_HIRES); // reference
 454 #endif
 455
 456         modelsource = self;
 457
 458 #ifdef ALLOW_FORCEMODELS
 459         if(other.cvar_cl_forceplayermodelsfromxonotic)
 460                 if not(self.modelindex_lod0_from_xonotic)
 461                         modelsource = other;
 462         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 463                 modelsource = other;
 464 #endif
 465
 466         self.skin = modelsource.skinindex;
 467
 468 #if 0
 469         if(modelsource == self)
 470                 self.skin = modelsource.skinindex;
 471         else
 472                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 473 #endif
 474
 475         // self: me
 476         // other: the player viewing me
 477         float distance;
 478         float f;
 479
 480         if(other.cvar_cl_playerdetailreduction <= 0)
 481         {
 482                 if(other.cvar_cl_playerdetailreduction <= -2)
 483                         self.modelindex = modelsource.modelindex_lod2;
 484                 else if(other.cvar_cl_playerdetailreduction <= -1)
 485                         self.modelindex = modelsource.modelindex_lod1;
 486                 else
 487                         self.modelindex = modelsource.modelindex_lod0;
 488         }
 489         else
 490         {
 491                 distance = vlen(self.origin - other.origin);
 492                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 493                 if(f > sv_loddistance2)
 494                         self.modelindex = modelsource.modelindex_lod2;
 495                 else if(f > sv_loddistance1)
 496                         self.modelindex = modelsource.modelindex_lod1;
 497                 else
 498                         self.modelindex = modelsource.modelindex_lod0;
 499         }
 500
 501 #ifdef PROFILING
 502         float t1;
 503         t1 = gettime(GETTIME_HIRES); // reference
 504         client_cefc_accumulator += (t1 - t0);
 505 #endif
 506
 507         return TRUE;
 508 }
 509
 510 void UpdatePlayerSounds();
 511 void setmodel_lod(entity e, string modelname)
 512 {
 513         string s;
 514
 515         if(sv_loddistance1)
 516         {
 517                 // FIXME: this only supports 3-letter extensions
 518                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 519                 if(fexists(s))
 520                 {
 521                         setmodel(e, s); // players have high precision
 522                         self.modelindex_lod1 = self.modelindex;
 523                 }
 524                 else
 525                         self.modelindex_lod1 = -1;
 526
 527                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 528                 if(fexists(s))
 529                 {
 530                         setmodel(e, s); // players have high precision
 531                         self.modelindex_lod2 = self.modelindex;
 532                 }
 533                 else
 534                         self.modelindex_lod2 = -1;
 535
 536                 precache_model(modelname);
 537                 setmodel(e, modelname); // players have high precision
 538                 self.modelindex_lod0 = self.modelindex;
 539
 540                 if(self.modelindex_lod1 < 0)
 541                         self.modelindex_lod1 = self.modelindex;
 542
 543                 if(self.modelindex_lod2 < 0)
 544                         self.modelindex_lod2 = self.modelindex;
 545         }
 546         else
 547         {
 548                 precache_model(modelname);
 549                 setmodel(e, modelname); // players have high precision
 550                 self.modelindex_lod0 = self.modelindex;
 551                         // save it for possible player model forcing
 552         }
 553
 554         s = whichpack(self.model);
 555         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 556
 557         player_setupanimsformodel();
 558         UpdatePlayerSounds();
 559 }
 560
 561 /*
 562 =============
 563 PutObserverInServer
 564
 565 putting a client as observer in the server
 566 =============
 567 */
 568 void FixPlayermodel();
 569 void PutObserverInServer (void)
 570 {
 571         entity  spot;
 572
 573         race_PreSpawnObserver();
 574
 575         spot = SelectSpawnPoint (TRUE);
 576         if(!spot)
 577                 error("No spawnpoints for observers?!?\n");
 578         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 579
 580         if(clienttype(self) == CLIENTTYPE_REAL)
 581         {
 582                 msg_entity = self;
 583                 WriteByte(MSG_ONE, SVC_SETVIEW);
 584                 WriteEntity(MSG_ONE, self);
 585         }
 586
 587         DropAllRunes(self);
 588
 589         Portal_ClearAll(self);
 590
 591         if(self.flagcarried)
 592                 DropFlag(self.flagcarried, world, world);
 593
 594         if(self.ballcarried)
 595                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 596
 597         WaypointSprite_PlayerDead();
 598
 599         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 600                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 601
 602         if(self.killcount != -666) {
 603                 if(g_lms) {
 604                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 605                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 606                         else
 607                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 608                 } else
 609                         bprint ("^4", self.netname, "^4 is spectating now\n");
 610
 611                 if(self.just_joined == FALSE) {
 612                         LogTeamchange(self.playerid, -1, 4);
 613                 } else
 614                         self.just_joined = FALSE;
 615         }
 616
 617         PlayerScore_Clear(self); // clear scores when needed
 618
 619         self.spectatortime = time;
 620
 621         self.classname = "observer";
 622         self.iscreature = FALSE;
 623         self.health = -666;
 624         self.takedamage = DAMAGE_NO;
 625         self.solid = SOLID_NOT;
 626         self.movetype = MOVETYPE_NOCLIP;
 627         self.flags = FL_CLIENT | FL_NOTARGET;
 628         self.armorvalue = 666;
 629         self.effects = 0;
 630         self.armorvalue = cvar("g_balance_armor_start");
 631         self.pauserotarmor_finished = 0;
 632         self.pauserothealth_finished = 0;
 633         self.pauseregen_finished = 0;
 634         self.damageforcescale = 0;
 635         self.death_time = 0;
 636         self.dead_frame = 0;
 637         self.alpha = 0;
 638         self.scale = 0;
 639         self.fade_time = 0;
 640         self.pain_frame = 0;
 641         self.pain_finished = 0;
 642         self.strength_finished = 0;
 643         self.invincible_finished = 0;
 644         self.pushltime = 0;
 645         self.think = SUB_Null;
 646         self.nextthink = 0;
 647         self.hook_time = 0;
 648         self.runes = 0;
 649         self.deadflag = DEAD_NO;
 650         self.angles = spot.angles;
 651         self.angles_z = 0;
 652         self.fixangle = TRUE;
 653         self.crouch = FALSE;
 654
 655         self.view_ofs = PL_VIEW_OFS;
 656         setorigin (self, spot.origin);
 657         setsize (self, '0 0 0', '0 0 0');
 658         self.prevorigin = self.origin;
 659         self.items = 0;
 660         self.weapons = 0;
 661         self.model = "";
 662         FixPlayermodel();
 663         self.model = "";
 664         self.modelindex = 0;
 665         self.weapon = 0;
 666         self.weaponmodel = "";
 667         self.weaponentity = world;
 668         self.exteriorweaponentity = world;
 669         self.killcount = -666;
 670         self.velocity = '0 0 0';
 671         self.avelocity = '0 0 0';
 672         self.punchangle = '0 0 0';
 673         self.punchvector = '0 0 0';
 674         self.oldvelocity = self.velocity;
 675         self.fire_endtime = -1;
 676
 677         if(sv_loddistance1)
 678                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 679
 680         if(g_arena)
 681         {
 682                 if(self.version_mismatch)
 683                 {
 684                         Spawnqueue_Unmark(self);
 685                         Spawnqueue_Remove(self);
 686                 }
 687                 else
 688                 {
 689                         Spawnqueue_Insert(self);
 690                 }
 691         }
 692         else if(g_lms)
 693         {
 694                 // Only if the player cannot play at all
 695                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 696                         self.frags = FRAGS_SPECTATOR;
 697                 else
 698                         self.frags = FRAGS_LMS_LOSER;
 699         }
 700         else
 701                 self.frags = FRAGS_SPECTATOR;
 702
 703         MUTATOR_CALLHOOK(MakePlayerObserver);
 704 }
 705
 706 float RestrictSkin(float s)
 707 {
 708         if(!teams_matter)
 709                 return s;
 710         if(s == 6)
 711                 return 6;
 712         return mod(s, 3);
 713 }
 714
 715 void FixPlayermodel()
 716 {
 717         local string defaultmodel;
 718         local float defaultskin, chmdl, oldskin;
 719         local vector m1, m2;
 720
 721         defaultmodel = "";
 722
 723         if(cvar("sv_defaultcharacter") == 1) {
 724                 defaultskin = 0;
 725
 726                 if(teams_matter)
 727                 {
 728                         string s;
 729                         s = Team_ColorNameLowerCase(self.team);
 730                         if(s != "neutral")
 731                         {
 732                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 733                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 734                         }
 735                 }
 736
 737                 if(defaultmodel == "")
 738                 {
 739                         defaultmodel = cvar_string("sv_defaultplayermodel");
 740                         defaultskin = cvar("sv_defaultplayerskin");
 741                 }
 742         }
 743
 744         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 745         {
 746                 if(self.model != "")
 747                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 748                 self.model = ""; // force the != checks to return true
 749         }
 750
 751         if(defaultmodel != "")
 752         {
 753                 if (defaultmodel != self.model)
 754                 {
 755                         m1 = self.mins;
 756                         m2 = self.maxs;
 757                         setmodel_lod (self, defaultmodel);
 758                         setsize (self, m1, m2);
 759                         chmdl = TRUE;
 760                 }
 761
 762                 oldskin = self.skinindex;
 763                 self.skinindex = defaultskin;
 764         } else {
 765                 if (self.playermodel != self.model || self.playermodel == "")
 766                 {
 767                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 768                         m1 = self.mins;
 769                         m2 = self.maxs;
 770                         setmodel_lod (self, self.playermodel);
 771                         setsize (self, m1, m2);
 772                         chmdl = TRUE;
 773                 }
 774
 775                 oldskin = self.skinindex;
 776                 self.skinindex = RestrictSkin(stof(self.playerskin));
 777         }
 778
 779         if(chmdl || oldskin != self.skinindex)
 780                 self.species = player_getspecies(); // model or skin has changed
 781
 782         if(!teams_matter)
 783                 if(strlen(cvar_string("sv_defaultplayercolors")))
 784                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 785                                 setcolor(self, cvar("sv_defaultplayercolors"));
 786 }
 787
 788 void PlayerTouchExplode(entity p1, entity p2)
 789 {
 790         vector org;
 791         org = (p1.origin + p2.origin) * 0.5;
 792         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 793
 794         te_explosion(org);
 795
 796         entity e;
 797         e = spawn();
 798         setorigin(e, org);
 799         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 800         remove(e);
 801 }
 802
 803 /*
 804 =============
 805 PutClientInServer
 806
 807 Called when a client spawns in the server
 808 =============
 809 */
 810 //void() ctf_playerchanged;
 811 void PutClientInServer (void)
 812 {
 813         if(clienttype(self) == CLIENTTYPE_BOT)
 814         {
 815                 self.classname = "player";
 816         }
 817         else if(clienttype(self) == CLIENTTYPE_REAL)
 818         {
 819                 msg_entity = self;
 820                 WriteByte(MSG_ONE, SVC_SETVIEW);
 821                 WriteEntity(MSG_ONE, self);
 822         }
 823
 824         // player is dead and becomes observer
 825         // FIXME fix LMS scoring for new system
 826         if(g_lms)
 827         {
 828                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 829                         self.classname = "observer";
 830         }
 831
 832         if(g_arena || (g_ca && !allowed_to_spawn))
 833         if(!self.spawned)
 834                 self.classname = "observer";
 835
 836         if(gameover)
 837                 self.classname = "observer";
 838
 839         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 840                 entity spot, oldself;
 841                 float j;
 842
 843                 if(self.team < 0)
 844                         JoinBestTeam(self, FALSE, TRUE);
 845
 846                 race_PreSpawn();
 847
 848                 spot = SelectSpawnPoint (FALSE);
 849                 if(!spot)
 850                 {
 851                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 852                         return; // spawn failed
 853                 }
 854
 855                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 856
 857                 self.classname = "player";
 858                 self.wasplayer = TRUE;
 859                 self.iscreature = TRUE;
 860                 self.movetype = MOVETYPE_WALK;
 861                 self.solid = SOLID_SLIDEBOX;
 862                 if(cvar("g_playerclip_collisions"))
 863                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 864                 else
 865                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 866                 self.frags = FRAGS_PLAYER;
 867                 if(independent_players)
 868                         MAKE_INDEPENDENT_PLAYER(self);
 869                 self.flags = FL_CLIENT;
 870                 self.takedamage = DAMAGE_AIM;
 871                 if(g_minstagib)
 872                         self.effects = EF_FULLBRIGHT;
 873                 else
 874                         self.effects = 0;
 875                 self.air_finished = time + 12;
 876                 self.dmg = 2;
 877
 878                 if(inWarmupStage)
 879                 {
 880                         self.ammo_shells = warmup_start_ammo_shells;
 881                         self.ammo_nails = warmup_start_ammo_nails;
 882                         self.ammo_rockets = warmup_start_ammo_rockets;
 883                         self.ammo_cells = warmup_start_ammo_cells;
 884                         self.ammo_fuel = warmup_start_ammo_fuel;
 885                         self.health = warmup_start_health;
 886                         self.armorvalue = warmup_start_armorvalue;
 887                         self.weapons = warmup_start_weapons;
 888                 }
 889                 else
 890                 {
 891                         self.ammo_shells = start_ammo_shells;
 892                         self.ammo_nails = start_ammo_nails;
 893                         self.ammo_rockets = start_ammo_rockets;
 894                         self.ammo_cells = start_ammo_cells;
 895                         self.ammo_fuel = start_ammo_fuel;
 896                         self.health = start_health;
 897                         self.armorvalue = start_armorvalue;
 898                         self.weapons = start_weapons;
 899                 }
 900
 901                 if(g_weaponarena_random)
 902                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 903
 904                 self.items = start_items;
 905                 self.jump_interval = time;
 906
 907                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 908                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 909                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 910                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 911                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 912                 //extend the pause of rotting if client was reset at the beginning of the countdown
 913                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 914                         self.spawnshieldtime += game_starttime - time;
 915                         self.pauserotarmor_finished += game_starttime - time;
 916                         self.pauserothealth_finished += game_starttime - time;
 917                         self.pauseregen_finished += game_starttime - time;
 918                 }
 919                 self.damageforcescale = 2;
 920                 self.death_time = 0;
 921                 self.dead_frame = 0;
 922                 self.alpha = 0;
 923                 self.scale = 0;
 924                 self.fade_time = 0;
 925                 self.pain_frame = 0;
 926                 self.pain_finished = 0;
 927                 self.strength_finished = 0;
 928                 self.invincible_finished = 0;
 929                 self.pushltime = 0;
 930                 // players have no think function
 931                 self.think = SUB_Null;
 932                 self.nextthink = 0;
 933                 self.hook_time = 0;
 934                 self.dmg_team = 0;
 935
 936                 self.metertime = 0;
 937
 938                 self.runes = 0;
 939
 940                 self.deadflag = DEAD_NO;
 941
 942                 self.angles = spot.angles;
 943
 944                 self.angles_z = 0; // never spawn tilted even if the spot says to
 945                 self.fixangle = TRUE; // turn this way immediately
 946                 self.velocity = '0 0 0';
 947                 self.avelocity = '0 0 0';
 948                 self.punchangle = '0 0 0';
 949                 self.punchvector = '0 0 0';
 950                 self.oldvelocity = self.velocity;
 951                 self.fire_endtime = -1;
 952
 953                 msg_entity = self;
 954                 WRITESPECTATABLE_MSG_ONE({
 955                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 956                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 957                 });
 958
 959                 if(sv_loddistance1)
 960                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 961
 962                 self.model = "";
 963                 FixPlayermodel();
 964
 965                 self.crouch = FALSE;
 966                 self.view_ofs = PL_VIEW_OFS;
 967                 setsize (self, PL_MIN, PL_MAX);
 968                 self.spawnorigin = spot.origin;
 969                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 970                 // don't reset back to last position, even if new position is stuck in solid
 971                 self.oldorigin = self.origin;
 972                 self.prevorigin = self.origin;
 973                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 974
 975                 if(g_arena)
 976                 {
 977                         Spawnqueue_Remove(self);
 978                         Spawnqueue_Mark(self);
 979                 }
 980
 981                 else if(g_ca)
 982                         self.caplayer = 1;
 983
 984                 self.event_damage = PlayerDamage;
 985
 986                 self.bot_attack = TRUE;
 987
 988                 self.statdraintime = time + 5;
 989                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 990
 991                 if(self.killcount == -666) {
 992                         PlayerScore_Clear(self);
 993                         self.killcount = 0;
 994                 }
 995
 996                 self.cnt = WEP_LASER;
 997
 998                 CL_SpawnWeaponentity();
 999                 self.alpha = default_player_alpha;
1000                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1001                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1002
1003                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1004                 self.lms_traveled_distance = 0;
1005                 self.speedrunning = FALSE;
1006
1007                 race_PostSpawn(spot);
1008
1009                 if(cvar("spawn_debug"))
1010                 {
1011                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1012                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1013                 }
1014
1015                 //stuffcmd(self, "chase_active 0");
1016                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1017
1018                 if (cvar("g_spawnsound"))
1019                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1020
1021                 if(g_assault) {
1022                         if(self.team == assault_attacker_team)
1023                                 centerprint(self, "You are attacking!");
1024                         else
1025                                 centerprint(self, "You are defending!");
1026                 }
1027
1028                 target_voicescript_clear(self);
1029
1030                 // reset fields the weapons may use
1031                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1032                         weapon_action(j, WR_RESETPLAYER);
1033
1034                 oldself = self;
1035                 self = spot;
1036                         activator = oldself;
1037                                 SUB_UseTargets();
1038                         activator = world;
1039                 self = oldself;
1040
1041                 MUTATOR_CALLHOOK(PlayerSpawn);
1042
1043                 self.switchweapon = w_getbestweapon(self);
1044                 self.cnt = self.switchweapon;
1045                 self.weapon = 0;
1046         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1047                 PutObserverInServer ();
1048         }
1049
1050         //if(g_ctf)
1051         //      ctf_playerchanged();
1052 }
1053
1054 float ClientInit_SendEntity(entity to, float sf)
1055 {
1056         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1057         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1058         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1059         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1060         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1061
1062         if(sv_foginterval && world.fog != "")
1063                 WriteString(MSG_ENTITY, world.fog);
1064         else
1065                 WriteString(MSG_ENTITY, "");
1066         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1067         WriteByte(MSG_ENTITY, cvar("g_balance_weaponswitchdelay") * 255.0);
1068         return TRUE;
1069 }
1070
1071 void ClientInit_Spawn()
1072 {
1073         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1074 }
1075
1076 /*
1077 =============
1078 SetNewParms
1079 =============
1080 */
1081 void SetNewParms (void)
1082 {
1083         // initialize parms for a new player
1084         parm1 = -(86400 * 366);
1085 }
1086
1087 /*
1088 =============
1089 SetChangeParms
1090 =============
1091 */
1092 void SetChangeParms (void)
1093 {
1094         // save parms for level change
1095         parm1 = self.parm_idlesince - time;
1096 }
1097
1098 /*
1099 =============
1100 DecodeLevelParms
1101 =============
1102 */
1103 void DecodeLevelParms (void)
1104 {
1105         // load parms
1106         self.parm_idlesince = parm1;
1107         if(self.parm_idlesince == -(86400 * 366))
1108                 self.parm_idlesince = time;
1109
1110         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1111         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1112 }
1113
1114 /*
1115 =============
1116 ClientKill
1117
1118 Called when a client types 'kill' in the console
1119 =============
1120 */
1121
1122 void ClientKill_Now_TeamChange()
1123 {
1124         if(self.killindicator_teamchange == -1)
1125         {
1126                 self.team = -1;
1127                 JoinBestTeam( self, FALSE, FALSE );
1128         }
1129         else
1130                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1131 }
1132
1133 void ClientKill_Now()
1134 {
1135         if(self.killindicator_teamchange)
1136                 ClientKill_Now_TeamChange();
1137
1138         // in any case:
1139         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1140
1141         if(self.killindicator)
1142         {
1143                 dprint("Cleaned up after a leaked kill indicator.\n");
1144                 remove(self.killindicator);
1145                 self.killindicator = world;
1146         }
1147 }
1148 void KillIndicator_Think()
1149 {
1150         if (!self.owner.modelindex)
1151         {
1152                 self.owner.killindicator = world;
1153                 remove(self);
1154                 return;
1155         }
1156
1157         if(self.cnt <= 0)
1158         {
1159                 self = self.owner;
1160                 ClientKill_Now(); // no oldself needed
1161                 return;
1162         }
1163         else
1164         {
1165                 if(self.cnt <= 10)
1166                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1167                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1168                 {
1169                         if(self.cnt <= 10)
1170                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1171                         if(self.owner.killindicator_teamchange)
1172                         {
1173                                 if(self.owner.killindicator_teamchange == -1)
1174                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1175                                 else
1176                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1177                         }
1178                         else
1179                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1180                 }
1181                 self.nextthink = time + 1;
1182                 self.cnt -= 1;
1183         }
1184 }
1185
1186 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1187 {
1188         float killtime;
1189         entity e;
1190         killtime = cvar("g_balance_kill_delay");
1191
1192         if(g_race_qualifying)
1193                 killtime = 0;
1194
1195         self.killindicator_teamchange = targetteam;
1196
1197         if(!self.killindicator)
1198         {
1199                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1200                 {
1201                         ClientKill_Now();
1202                 }
1203                 else
1204                 {
1205                         self.killindicator = spawn();
1206                         self.killindicator.owner = self;
1207                         self.killindicator.scale = 0.5;
1208                         setattachment(self.killindicator, self, "");
1209                         setorigin(self.killindicator, '0 0 52');
1210                         self.killindicator.think = KillIndicator_Think;
1211                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1212                         self.killindicator.cnt = ceil(killtime);
1213                         self.killindicator.count = bound(0, ceil(killtime), 10);
1214                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1215
1216                         for(e = world; (e = find(e, classname, "body")) != world; )
1217                         {
1218                                 if(e.enemy != self)
1219                                         continue;
1220                                 e.killindicator = spawn();
1221                                 e.killindicator.owner = e;
1222                                 e.killindicator.scale = 0.5;
1223                                 setattachment(e.killindicator, e, "");
1224                                 setorigin(e.killindicator, '0 0 52');
1225                                 e.killindicator.think = KillIndicator_Think;
1226                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1227                                 e.killindicator.cnt = ceil(killtime);
1228                         }
1229                         self.lip = 0;
1230                 }
1231         }
1232         if(self.killindicator)
1233         {
1234                 if(targetteam)
1235                         self.killindicator.colormod = TeamColor(targetteam);
1236                 else
1237                         self.killindicator.colormod = '0 0 0';
1238         }
1239 }
1240
1241 void ClientKill (void)
1242 {
1243         ClientKill_TeamChange(0);
1244 }
1245
1246 void DoTeamChange(float destteam)
1247 {
1248         float t, c0;
1249         if(!teams_matter)
1250         {
1251                 if(destteam >= 0)
1252                         SetPlayerColors(self, destteam);
1253                 return;
1254         }
1255         if(self.classname == "player")
1256         if(destteam == -1)
1257         {
1258                 CheckAllowedTeams(self);
1259                 t = FindSmallestTeam(self, TRUE);
1260                 switch(self.team)
1261                 {
1262                         case COLOR_TEAM1: c0 = c1; break;
1263                         case COLOR_TEAM2: c0 = c2; break;
1264                         case COLOR_TEAM3: c0 = c3; break;
1265                         case COLOR_TEAM4: c0 = c4; break;
1266                         default:          c0 = 999;
1267                 }
1268                 switch(t)
1269                 {
1270                         case 1:
1271                                 if(c0 > c1)
1272                                         destteam = COLOR_TEAM1;
1273                                 break;
1274                         case 2:
1275                                 if(c0 > c2)
1276                                         destteam = COLOR_TEAM2;
1277                                 break;
1278                         case 3:
1279                                 if(c0 > c3)
1280                                         destteam = COLOR_TEAM3;
1281                                 break;
1282                         case 4:
1283                                 if(c0 > c4)
1284                                         destteam = COLOR_TEAM4;
1285                                 break;
1286                 }
1287                 if(destteam == -1)
1288                         return;
1289         }
1290         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1291                 return;
1292         ClientKill_TeamChange(destteam);
1293 }
1294
1295 void FixClientCvars(entity e)
1296 {
1297         // send prediction settings to the client
1298         stuffcmd(e, "\nin_bindmap 0 0\n");
1299         if(g_race || g_cts)
1300                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1301         if(cvar("g_antilag") == 3) // client side hitscan
1302                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1303                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1304         /*
1305          * we no longer need to stuff this. Remove this comment block if you feel
1306          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1307         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1308         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1309         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1310         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1311         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1312         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1313         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1314         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1315         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1316         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1317         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1318         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1319         stuffcmd(e, "cl_movement_edgefriction 1\n");
1320          */
1321 }
1322
1323 /*
1324 =============
1325 ClientConnect
1326
1327 Called when a client connects to the server
1328 =============
1329 */
1330 //void ctf_clientconnect();
1331 string ColoredTeamName(float t);
1332 void DecodeLevelParms (void);
1333 //void dom_player_join_team(entity pl);
1334 #ifdef UID
1335 .float uid_kicktime;
1336 .string uid;
1337 #endif
1338 void ClientConnect (void)
1339 {
1340         float t;
1341
1342         if(self.flags & FL_CLIENT)
1343         {
1344                 print("Warning: ClientConnect, but already connected!\n");
1345                 return;
1346         }
1347
1348         if(Ban_MaybeEnforceBan(self))
1349                 return;
1350
1351         DecodeLevelParms();
1352
1353         self.classname = "player_joining";
1354
1355         self.flags = FL_CLIENT;
1356         self.version_nagtime = time + 10 + random() * 10;
1357
1358         if(player_count<0)
1359         {
1360                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1361                 player_count = 0;
1362         }
1363
1364         PlayerScore_Attach(self);
1365         ClientData_Attach();
1366
1367         bot_clientconnect();
1368
1369         playerdemo_init();
1370
1371         anticheat_init();
1372
1373         race_PreSpawnObserver();
1374
1375         //if(g_domination)
1376         //      dom_player_join_team(self);
1377
1378         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1379
1380         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1381                 self.classname = "observer";
1382         } else {
1383                 if(teams_matter)
1384                 {
1385                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1386                         {
1387                                 self.classname = "player";
1388                                 campaign_bots_may_start = 1;
1389                         }
1390                         else
1391                         {
1392                                 self.classname = "observer"; // do it anyway
1393                         }
1394                 }
1395                 else
1396                 {
1397                         self.classname = "player";
1398                         campaign_bots_may_start = 1;
1399                 }
1400         }
1401
1402         self.playerid = (playerid_last = playerid_last + 1);
1403
1404         if(cvar("sv_eventlog"))
1405                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1406
1407         LogTeamchange(self.playerid, self.team, 1);
1408
1409         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1410
1411         self.netname_previous = strzone(self.netname);
1412
1413         bprint("^4", self.netname, "^4 connected");
1414
1415         if(self.classname != "observer" && (g_domination || g_ctf))
1416                 bprint(" and joined the ", ColoredTeamName(self.team));
1417
1418         bprint("\n");
1419
1420         self.welcomemessage_time = 0;
1421
1422         stuffcmd(self, strcat(clientstuff, "\n"));
1423         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1424         stuffcmd(self, "cl_particles_reloadeffects\n");
1425
1426         FixClientCvars(self);
1427
1428         // spawnfunc_waypoint sprites
1429         WaypointSprite_InitClient(self);
1430
1431         // Wazat's grappling hook
1432         SetGrappleHookBindings();
1433
1434         // get autoswitch state from player when he toggles it
1435         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1436
1437         // get version info from player
1438         stuffcmd(self, "cmd clientversion $gameversion\n");
1439
1440         // get other cvars from player
1441         GetCvars(0);
1442
1443         // set cvar for team scoreboard
1444         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1445
1446         // notify about available teams
1447         if(teams_matter)
1448         {
1449                 CheckAllowedTeams(self);
1450                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1451                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1452         }
1453         else
1454                 stuffcmd(self, "set _teams_available 0\n");
1455
1456         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1457
1458         if(g_arena || g_ca)
1459         {
1460                 self.classname = "observer";
1461                 if(g_arena)
1462                         Spawnqueue_Insert(self);
1463         }
1464         /*else if(g_ctf)
1465         {
1466                 ctf_clientconnect();
1467         }*/
1468
1469         if(teams_matter || radar_showennemies)
1470                 attach_entcs();
1471
1472         bot_relinkplayerlist();
1473
1474         self.spectatortime = time;
1475         if(blockSpectators)
1476         {
1477                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1478         }
1479
1480         self.jointime = time;
1481         self.allowedTimeouts = cvar("sv_timeout_number");
1482
1483         if(clienttype(self) == CLIENTTYPE_REAL)
1484         {
1485                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1486                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1487         }
1488
1489         if(g_lms)
1490         {
1491                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1492                 {
1493                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1494                         self.frags = FRAGS_SPECTATOR;
1495                 }
1496         }
1497
1498         if(!sv_foginterval && world.fog != "")
1499                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1500
1501         SoundEntity_Attach(self);
1502
1503         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1504         {
1505                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1506                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1507         }
1508         else
1509                 self.hitplotfh = -1;
1510
1511 #ifdef UID
1512         if(clienttype(self) == CLIENTTYPE_REAL)
1513         if not(self.uid)
1514                 self.uid_kicktime = time + 60;
1515 #endif
1516
1517         if(g_race || g_cts) {
1518                 string rr;
1519                 if(g_cts)
1520                         rr = CTS_RECORD;
1521                 else
1522                         rr = RACE_RECORD;
1523                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1524
1525                 race_send_recordtime(MSG_ONE);
1526                 race_send_speedaward(MSG_ONE);
1527
1528                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1529                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1530                 race_send_speedaward_alltimebest(MSG_ONE);
1531
1532                 float i;
1533                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1534                         race_SendRankings(i, 0, 0, MSG_ONE);
1535                 }
1536         }
1537         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1538                 send_CSQC_teamnagger();
1539
1540         CheatInitClient();
1541 }
1542
1543 /*
1544 =============
1545 ClientDisconnect
1546
1547 Called when a client disconnects from the server
1548 =============
1549 */
1550 .entity chatbubbleentity;
1551 .entity teambubbleentity;
1552 void ReadyCount();
1553 void ClientDisconnect (void)
1554 {
1555         if not(self.flags & FL_CLIENT)
1556         {
1557                 print("Warning: ClientDisconnect without ClientConnect\n");
1558                 return;
1559         }
1560
1561         CheatShutdownClient();
1562
1563         if(self.hitplotfh >= 0)
1564         {
1565                 fclose(self.hitplotfh);
1566                 self.hitplotfh = -1;
1567         }
1568
1569         anticheat_report();
1570         anticheat_shutdown();
1571
1572         playerdemo_shutdown();
1573
1574         bot_clientdisconnect();
1575
1576         if(self.entcs)
1577                 detach_entcs();
1578
1579         if(cvar("sv_eventlog"))
1580                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1581         bprint ("^4",self.netname);
1582         bprint ("^4 disconnected\n");
1583
1584         SoundEntity_Detach(self);
1585
1586         DropAllRunes(self);
1587         MUTATOR_CALLHOOK(ClientDisconnect);
1588
1589         Portal_ClearAll(self);
1590
1591         if(self.flagcarried)
1592                 DropFlag(self.flagcarried, world, world);
1593         if(self.ballcarried)
1594                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1595
1596         // Here, everything has been done that requires this player to be a client.
1597
1598         self.flags &~= FL_CLIENT;
1599
1600         if (self.chatbubbleentity)
1601                 remove (self.chatbubbleentity);
1602
1603         if (self.teambubbleentity)
1604                 remove (self.teambubbleentity);
1605
1606         if (self.killindicator)
1607                 remove (self.killindicator);
1608
1609         WaypointSprite_PlayerGone();
1610
1611         bot_relinkplayerlist();
1612
1613         // remove laserdot
1614         if(self.weaponentity)
1615                 if(self.weaponentity.lasertarget)
1616                         remove(self.weaponentity.lasertarget);
1617
1618         if(g_arena)
1619         {
1620                 Spawnqueue_Unmark(self);
1621                 Spawnqueue_Remove(self);
1622         }
1623
1624         ClientData_Detach();
1625         PlayerScore_Detach(self);
1626
1627         if(self.netname_previous)
1628                 strunzone(self.netname_previous);
1629         if(self.clientstatus)
1630                 strunzone(self.clientstatus);
1631
1632         ClearPlayerSounds();
1633
1634         if(self.personal)
1635                 remove(self.personal);
1636
1637         self.playerid = 0;
1638         ReadyCount();
1639
1640         // free cvars
1641         GetCvars(-1);
1642 }
1643
1644 .float BUTTON_CHAT;
1645 void ChatBubbleThink()
1646 {
1647         self.nextthink = time;
1648         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1649         {
1650                 if(self.owner) // but why can that ever be world?
1651                         self.owner.chatbubbleentity = world;
1652                 remove(self);
1653                 return;
1654         }
1655         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1656 #ifdef TETRIS
1657                 || self.owner.tetris_on
1658 #endif
1659         )
1660                 self.model = self.mdl;
1661         else
1662                 self.model = "";
1663 };
1664
1665 void UpdateChatBubble()
1666 {
1667         if (!self.modelindex)
1668                 return;
1669         // spawn a chatbubble entity if needed
1670         if (!self.chatbubbleentity)
1671         {
1672                 self.chatbubbleentity = spawn();
1673                 self.chatbubbleentity.owner = self;
1674                 self.chatbubbleentity.exteriormodeltoclient = self;
1675                 self.chatbubbleentity.think = ChatBubbleThink;
1676                 self.chatbubbleentity.nextthink = time;
1677                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1678                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1679                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1680                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1681                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1682                 self.chatbubbleentity.model = "";
1683                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1684         }
1685 }
1686
1687
1688 void TeamBubbleThink()
1689 {
1690         self.nextthink = time;
1691         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1692         {
1693                 if(self.owner) // but why can that ever be world?
1694                         self.owner.teambubbleentity = world;
1695                 remove(self);
1696                 return;
1697         }
1698 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1699         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1700                 self.model = "";
1701         else
1702                 self.model = self.mdl;
1703
1704 };
1705
1706 float TeamBubble_customizeentityforclient()
1707 {
1708         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1709 }
1710
1711 void UpdateTeamBubble()
1712 {
1713         if (!self.modelindex || !teams_matter)
1714                 return;
1715         // spawn a teambubble entity if needed
1716         if (!self.teambubbleentity && teams_matter)
1717         {
1718                 self.teambubbleentity = spawn();
1719                 self.teambubbleentity.owner = self;
1720                 self.teambubbleentity.exteriormodeltoclient = self;
1721                 self.teambubbleentity.think = TeamBubbleThink;
1722                 self.teambubbleentity.nextthink = time;
1723                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1724 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1725                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1726                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1727                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1728                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1729                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1730                 self.teambubbleentity.effects = EF_LOWPRECISION;
1731         }
1732 }
1733
1734 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1735 // added to the model skins
1736 /*void UpdateColorModHack()
1737 {
1738         local float c;
1739         c = self.clientcolors & 15;
1740         // LordHavoc: only bothering to support white, green, red, yellow, blue
1741              if (!teams_matter) self.colormod = '0 0 0';
1742         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1743         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1744         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1745         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1746         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1747         else self.colormod = '1 1 1';
1748 };*/
1749
1750 void respawn(void)
1751 {
1752         CopyBody(1);
1753         self.effects |= EF_NODRAW; // prevent another CopyBody
1754         PutClientInServer();
1755 }
1756
1757 void play_countdown(float finished, string samp)
1758 {
1759         if(clienttype(self) == CLIENTTYPE_REAL)
1760                 if(floor(finished - time - frametime) != floor(finished - time))
1761                         if(finished - time < 6)
1762                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1763 }
1764
1765 /**
1766  * When sv_timeout is used this function returs strings like
1767  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1768  * Called by centerprint functions
1769  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1770  */
1771 string getTimeoutText(float addOneSecond) {
1772         if (!cvar("sv_timeout") || !timeoutStatus)
1773                 return "";
1774
1775         local string retStr;
1776         if (timeoutStatus == 1) {
1777                 if (addOneSecond == 1) {
1778                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1779                 }
1780                 else {
1781                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1782                 }
1783                 return retStr;
1784         }
1785         else if (timeoutStatus == 2) {
1786                 if (addOneSecond) {
1787                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1788                         //don't show messages like "Timeout ends in 0 seconds"...
1789                         if ((remainingTimeoutTime + 1) > 0)
1790                                 return retStr;
1791                         else
1792                                 return "";
1793                 }
1794                 else {
1795                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1796                         //don't show messages like "Timeout ends in 0 seconds"...
1797                         if (remainingTimeoutTime > 0)
1798                                 return retStr;
1799                         else
1800                                 return "";
1801                 }
1802         }
1803         else return "";
1804 }
1805
1806 void player_powerups (void)
1807 {
1808         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1809         {
1810                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1811                 self.modelflags |= MF_ROCKET;
1812         }
1813         else
1814         {
1815                 SoundEntity_StopSound(self, CHAN_PLAYER);
1816                 self.modelflags &~= MF_ROCKET;
1817         }
1818
1819         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1820
1821         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1822                 return;
1823
1824         Fire_ApplyDamage(self);
1825         Fire_ApplyEffect(self);
1826
1827         if (g_minstagib)
1828         {
1829                 self.effects |= EF_FULLBRIGHT;
1830
1831                 if (self.items & IT_STRENGTH)
1832                 {
1833                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1834                         if (time > self.strength_finished)
1835                         {
1836                                 self.alpha = default_player_alpha;
1837                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1838                                 self.items &~= IT_STRENGTH;
1839                                 sprint(self, "^3Invisibility has worn off\n");
1840                         }
1841                 }
1842                 else
1843                 {
1844                         if (time < self.strength_finished)
1845                         {
1846                                 self.alpha = g_minstagib_invis_alpha;
1847                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1848                                 self.items |= IT_STRENGTH;
1849                                 sprint(self, "^3You are invisible\n");
1850                         }
1851                 }
1852
1853                 if (self.items & IT_INVINCIBLE)
1854                 {
1855                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1856                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1857                         {
1858                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1859                                 sprint(self, "^3Speed has worn off\n");
1860                         }
1861                 }
1862                 else
1863                 {
1864                         if (time < self.invincible_finished)
1865                         {
1866                                 self.items = self.items | IT_INVINCIBLE;
1867                                 sprint(self, "^3You are on speed\n");
1868                         }
1869                 }
1870                 return;
1871         }
1872
1873         if (self.items & IT_STRENGTH)
1874         {
1875                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1876                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1877                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1878                 {
1879                         self.items = self.items - (self.items & IT_STRENGTH);
1880                         sprint(self, "^3Strength has worn off\n");
1881                 }
1882         }
1883         else
1884         {
1885                 if (time < self.strength_finished)
1886                 {
1887                         self.items = self.items | IT_STRENGTH;
1888                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1889                 }
1890         }
1891         if (self.items & IT_INVINCIBLE)
1892         {
1893                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1894                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1895                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1896                 {
1897                         self.items = self.items - (self.items & IT_INVINCIBLE);
1898                         sprint(self, "^3Shield has worn off\n");
1899                 }
1900         }
1901         else
1902         {
1903                 if (time < self.invincible_finished)
1904                 {
1905                         self.items = self.items | IT_INVINCIBLE;
1906                         sprint(self, "^3Shield surrounds you\n");
1907                 }
1908         }
1909
1910         if(cvar("g_nodepthtestplayers"))
1911                 self.effects = self.effects | EF_NODEPTHTEST;
1912
1913         if(cvar("g_fullbrightplayers"))
1914                 self.effects = self.effects | EF_FULLBRIGHT;
1915
1916         // midair gamemode: damage only while in the air
1917         // if in midair mode, being on ground grants temporary invulnerability
1918         // (this is so that multishot weapon don't clear the ground flag on the
1919         // first damage in the frame, leaving the player vulnerable to the
1920         // remaining hits in the same frame)
1921         if (self.flags & FL_ONGROUND)
1922         if (g_midair)
1923                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1924
1925         if (time >= game_starttime)
1926         if (time < self.spawnshieldtime)
1927                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1928 }
1929
1930 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1931 {
1932         if(current > stable)
1933                 return current;
1934         else if(current > stable - 0.25) // when close enough, "snap"
1935                 return stable;
1936         else
1937                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1938 }
1939
1940 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1941 {
1942         if(current < stable)
1943                 return current;
1944         else if(current < stable + 0.25) // when close enough, "snap"
1945                 return stable;
1946         else
1947                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1948 }
1949
1950 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1951 {
1952         if(current > rotstable)
1953         {
1954                 if(rotframetime > 0)
1955                 {
1956                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1957                         current = max(rotstable, current - rotlinear * rotframetime);
1958                 }
1959         }
1960         else if(current < regenstable)
1961         {
1962                 if(regenframetime > 0)
1963                 {
1964                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1965                         current = min(regenstable, current + regenlinear * regenframetime);
1966                 }
1967         }
1968
1969         if(current > limit)
1970                 current = limit;
1971
1972         return current;
1973 }
1974
1975 void player_regen (void)
1976 {
1977         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1978         maxh = cvar("g_balance_health_rotstable");
1979         maxa = cvar("g_balance_armor_rotstable");
1980         maxf = cvar("g_balance_fuel_rotstable");
1981         minh = cvar("g_balance_health_regenstable");
1982         mina = cvar("g_balance_armor_regenstable");
1983         minf = cvar("g_balance_fuel_regenstable");
1984         limith = cvar("g_balance_health_limit");
1985         limita = cvar("g_balance_armor_limit");
1986         limitf = cvar("g_balance_fuel_limit");
1987
1988         max_mod = regen_mod = rot_mod = limit_mod = 1;
1989
1990         if (self.runes & RUNE_REGEN)
1991         {
1992                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1993                 {
1994                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1995                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1996                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1997                 }
1998                 else
1999                 {
2000                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2001                         max_mod = cvar("g_balance_rune_regen_hpmod");
2002                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2003                 }
2004         }
2005         else if (self.runes & CURSE_VENOM)
2006         {
2007                 max_mod = cvar("g_balance_curse_venom_hpmod");
2008                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2009                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2010                 else
2011                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2012                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2013                 //if (!self.runes & RUNE_REGEN)
2014                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2015         }
2016         maxh = maxh * max_mod;
2017         //maxa = maxa * max_mod;
2018         //maxf = maxf * max_mod;
2019         minh = minh * max_mod;
2020         //mina = mina * max_mod;
2021         //minf = minf * max_mod;
2022         limith = limith * limit_mod;
2023         limita = limita * limit_mod;
2024         //limitf = limitf * limit_mod;
2025
2026         if(g_lms && g_ca)
2027                 rot_mod = 0;
2028
2029         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2030         {
2031                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2032                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2033
2034                 // if player rotted to death...  die!
2035                 if(self.health < 1)
2036                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2037         }
2038
2039         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2040                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2041 }
2042
2043 float zoomstate_set;
2044 void SetZoomState(float z)
2045 {
2046         if(z != self.zoomstate)
2047         {
2048                 self.zoomstate = z;
2049                 ClientData_Touch(self);
2050         }
2051         zoomstate_set = 1;
2052 }
2053
2054 void GetPressedKeys(void) {
2055         MUTATOR_CALLHOOK(GetPressedKeys);
2056         if (self.movement_x > 0) // get if movement keys are pressed
2057         {       // forward key pressed
2058                 self.pressedkeys |= KEY_FORWARD;
2059                 self.pressedkeys &~= KEY_BACKWARD;
2060         }
2061         else if (self.movement_x < 0)
2062         {       // backward key pressed
2063                 self.pressedkeys |= KEY_BACKWARD;
2064                 self.pressedkeys &~= KEY_FORWARD;
2065         }
2066         else
2067         {       // no x input
2068                 self.pressedkeys &~= KEY_FORWARD;
2069                 self.pressedkeys &~= KEY_BACKWARD;
2070         }
2071
2072         if (self.movement_y > 0)
2073         {       // right key pressed
2074                 self.pressedkeys |= KEY_RIGHT;
2075                 self.pressedkeys &~= KEY_LEFT;
2076         }
2077         else if (self.movement_y < 0)
2078         {       // left key pressed
2079                 self.pressedkeys |= KEY_LEFT;
2080                 self.pressedkeys &~= KEY_RIGHT;
2081         }
2082         else
2083         {       // no y input
2084                 self.pressedkeys &~= KEY_RIGHT;
2085                 self.pressedkeys &~= KEY_LEFT;
2086         }
2087
2088         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2089                 self.pressedkeys |= KEY_JUMP;
2090         else
2091                 self.pressedkeys &~= KEY_JUMP;
2092         if (self.BUTTON_CROUCH)
2093                 self.pressedkeys |= KEY_CROUCH;
2094         else
2095                 self.pressedkeys &~= KEY_CROUCH;
2096 }
2097
2098 void update_stats (float number, float hit, float fired) {
2099 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2100 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2101
2102         if(number) {
2103                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2104                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2105         } else {
2106                 self.stat_hit = hit * sv_accuracy_data_share;
2107                 self.stat_fired = fired * sv_accuracy_data_share;
2108         }
2109 }
2110
2111 /*
2112 ======================
2113 spectate mode routines
2114 ======================
2115 */
2116
2117 .float weapon_count;
2118 void SpectateCopy(entity spectatee) {
2119         if(spectatee.weapon_count < WEP_LAST) {
2120                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2121                 spectatee.weapon_count ++;
2122         } else
2123                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2124
2125         other = spectatee;
2126         MUTATOR_CALLHOOK(SpectateCopy);
2127         self.armortype = spectatee.armortype;
2128         self.armorvalue = spectatee.armorvalue;
2129         self.ammo_cells = spectatee.ammo_cells;
2130         self.ammo_shells = spectatee.ammo_shells;
2131         self.ammo_nails = spectatee.ammo_nails;
2132         self.ammo_rockets = spectatee.ammo_rockets;
2133         self.ammo_fuel = spectatee.ammo_fuel;
2134         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2135         self.health = spectatee.health;
2136         self.impulse = 0;
2137         self.items = spectatee.items;
2138         self.metertime = spectatee.metertime;
2139         self.strength_finished = spectatee.strength_finished;
2140         self.invincible_finished = spectatee.invincible_finished;
2141         self.pressedkeys = spectatee.pressedkeys;
2142         self.weapons = spectatee.weapons;
2143         self.switchweapon = spectatee.switchweapon;
2144         self.weapon = spectatee.weapon;
2145         self.punchangle = spectatee.punchangle;
2146         self.view_ofs = spectatee.view_ofs;
2147         self.v_angle = spectatee.v_angle;
2148         self.velocity = spectatee.velocity;
2149         self.dmg_take = spectatee.dmg_take;
2150         self.dmg_save = spectatee.dmg_save;
2151         self.dmg_inflictor = spectatee.dmg_inflictor;
2152         self.angles = spectatee.v_angle;
2153         self.fixangle = TRUE;
2154         setorigin(self, spectatee.origin);
2155         setsize(self, spectatee.mins, spectatee.maxs);
2156         SetZoomState(spectatee.zoomstate);
2157
2158         anticheat_spectatecopy(spectatee);
2159 }
2160
2161 float SpectateUpdate() {
2162         if(!self.enemy)
2163                 return 0;
2164
2165         if (self == self.enemy)
2166                 return 0;
2167
2168         if(self.enemy.classname != "player")
2169                 return 0;
2170
2171         SpectateCopy(self.enemy);
2172
2173         return 1;
2174 }
2175
2176 float SpectateNext() {
2177         other = find(self.enemy, classname, "player");
2178
2179         if (!other)
2180                 other = find(other, classname, "player");
2181
2182         if (other)
2183                 self.enemy = other;
2184
2185         if(self.enemy.classname == "player") {
2186                 msg_entity = self;
2187                 WriteByte(MSG_ONE, SVC_SETVIEW);
2188                 WriteEntity(MSG_ONE, self.enemy);
2189                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2190                 self.movetype = MOVETYPE_NONE;
2191
2192                 self.enemy.weapon_count = 0;
2193
2194                 if(!SpectateUpdate())
2195                         PutObserverInServer();
2196
2197                 return 1;
2198         } else {
2199                 return 0;
2200         }
2201 }
2202
2203 /*
2204 =============
2205 ShowRespawnCountdown()
2206
2207 Update a respawn countdown display.
2208 =============
2209 */
2210 void ShowRespawnCountdown()
2211 {
2212         float number;
2213         if(self.deadflag == DEAD_NO) // just respawned?
2214                 return;
2215         else
2216         {
2217                 number = ceil(self.death_time - time);
2218                 if(number <= 0)
2219                         return;
2220                 if(number <= self.respawn_countdown)
2221                 {
2222                         self.respawn_countdown = number - 1;
2223                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2224                                 AnnounceTo(self, strcat(ftos(number), ""));
2225                 }
2226         }
2227 }
2228
2229 void LeaveSpectatorMode()
2230 {
2231         if(isJoinAllowed()) {
2232                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2233                         self.classname = "player";
2234
2235                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2236                                 JoinBestTeam(self, FALSE, TRUE);
2237
2238                         if(cvar("g_campaign"))
2239                                 campaign_bots_may_start = 1;
2240
2241                         self.stat_count = WEP_LAST;
2242
2243                         PutClientInServer();
2244
2245                         if(self.classname == "player")
2246                                 bprint ("^4", self.netname, "^4 is playing now\n");
2247
2248                         if(!cvar("g_campaign"))
2249                                 centerprint(self,""); // clear MOTD
2250
2251                         return;
2252                 } else {
2253                         if (g_ca && self.caplayer) {
2254                         }       // do nothing
2255                         else
2256                                 stuffcmd(self,"menu_showteamselect\n");
2257                         return;
2258                 }
2259         }
2260         else {
2261                 //player may not join because of g_maxplayers is set
2262                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2263         }
2264 }
2265
2266 /**
2267  * Determines whether the player is allowed to join. This depends on cvar
2268  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2269  * it checks whether the number of currently playing players exceeds g_maxplayers.
2270  * @return bool TRUE if the player is allowed to join, false otherwise
2271  */
2272 float isJoinAllowed() {
2273         if (!cvar("g_maxplayers"))
2274                 return TRUE;
2275
2276         local entity e;
2277         local float currentlyPlaying;
2278         FOR_EACH_REALPLAYER(e) {
2279                 if(e.classname == "player")
2280                         currentlyPlaying += 1;
2281         }
2282         if(currentlyPlaying < cvar("g_maxplayers"))
2283                 return TRUE;
2284
2285         return FALSE;
2286 }
2287
2288 /**
2289  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2290  * g_maxplayers_spectator_blocktime seconds
2291  */
2292 void checkSpectatorBlock() {
2293         if(self.classname == "spectator" || self.classname == "observer") {
2294                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2295                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2296                         dropclient(self);
2297                 }
2298         }
2299 }
2300
2301 float vercmp_recursive(string v1, string v2)
2302 {
2303         float dot1, dot2;
2304         string s1, s2;
2305         float r;
2306
2307         dot1 = strstrofs(v1, ".", 0);
2308         dot2 = strstrofs(v2, ".", 0);
2309         if(dot1 == -1)
2310                 s1 = v1;
2311         else
2312                 s1 = substring(v1, 0, dot1);
2313         if(dot2 == -1)
2314                 s2 = v2;
2315         else
2316                 s2 = substring(v2, 0, dot2);
2317
2318         r = stof(s1) - stof(s2);
2319         if(r != 0)
2320                 return r;
2321
2322         r = strcasecmp(s1, s2);
2323         if(r != 0)
2324                 return r;
2325
2326         if(dot1 == -1)
2327                 if(dot2 == -1)
2328                         return 0;
2329                 else
2330                         return -1;
2331         else
2332                 if(dot2 == -1)
2333                         return 1;
2334                 else
2335                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2336 }
2337
2338 float vercmp(string v1, string v2)
2339 {
2340         if(strcasecmp(v1, v2) == 0) // early out check
2341                 return 0;
2342         return vercmp_recursive(v1, v2);
2343 }
2344
2345 void ObserverThink()
2346 {
2347         if (self.flags & FL_JUMPRELEASED) {
2348                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2349                         self.welcomemessage_time = 0;
2350                         self.flags &~= FL_JUMPRELEASED;
2351                         self.flags |= FL_SPAWNING;
2352                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2353                         self.welcomemessage_time = 0;
2354                         self.flags &~= FL_JUMPRELEASED;
2355                         if(SpectateNext() == 1) {
2356                                 self.classname = "spectator";
2357                         }
2358                 }
2359         } else {
2360                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2361                         self.flags |= FL_JUMPRELEASED;
2362                         if(self.flags & FL_SPAWNING)
2363                         {
2364                                 self.flags &~= FL_SPAWNING;
2365                                 LeaveSpectatorMode();
2366                                 return;
2367                         }
2368                 }
2369         }
2370         PrintWelcomeMessage(self);
2371 }
2372
2373 void SpectatorThink()
2374 {
2375         if (self.flags & FL_JUMPRELEASED) {
2376                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2377                         self.welcomemessage_time = 0;
2378                         self.flags &~= FL_JUMPRELEASED;
2379                         self.flags |= FL_SPAWNING;
2380                 } else if(self.BUTTON_ATCK) {
2381                         self.welcomemessage_time = 0;
2382                         self.flags &~= FL_JUMPRELEASED;
2383                         if(SpectateNext() == 1) {
2384                                 self.classname = "spectator";
2385                         } else {
2386                                 self.classname = "observer";
2387                                 self.stat_count = WEP_LAST;
2388                                 PutClientInServer();
2389                         }
2390                 } else if (self.BUTTON_ATCK2) {
2391                         self.welcomemessage_time = 0;
2392                         self.flags &~= FL_JUMPRELEASED;
2393                         self.classname = "observer";
2394                         self.stat_count = WEP_LAST;
2395                         PutClientInServer();
2396                 } else {
2397                         if(!SpectateUpdate())
2398                                 PutObserverInServer();
2399                 }
2400         } else {
2401                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2402                         self.flags |= FL_JUMPRELEASED;
2403                         if(self.flags & FL_SPAWNING)
2404                         {
2405                                 self.flags &~= FL_SPAWNING;
2406                                 LeaveSpectatorMode();
2407                                 return;
2408                         }
2409                 }
2410         }
2411
2412         PrintWelcomeMessage(self);
2413         self.flags |= FL_CLIENT | FL_NOTARGET;
2414 }
2415
2416 .float touchexplode_time;
2417
2418 /*
2419 =============
2420 PlayerPreThink
2421
2422 Called every frame for each client before the physics are run
2423 =============
2424 */
2425 void() ctf_setstatus;
2426 void() nexball_setstatus;
2427 .float items_added;
2428 void PlayerPreThink (void)
2429 {
2430         self.stat_game_starttime = game_starttime;
2431         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2432         self.stat_leadlimit = cvar("leadlimit");
2433
2434         if(frametime)
2435         {
2436                 // physics frames: update anticheat stuff
2437                 anticheat_prethink();
2438         }
2439
2440         if(blockSpectators && frametime)
2441                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2442                 checkSpectatorBlock();
2443
2444         zoomstate_set = 0;
2445
2446         if(self.netname_previous != self.netname)
2447         {
2448                 if(cvar("sv_eventlog"))
2449                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2450                 if(self.netname_previous)
2451                         strunzone(self.netname_previous);
2452                 self.netname_previous = strzone(self.netname);
2453         }
2454
2455         // version nagging
2456         if(self.version_nagtime)
2457                 if(self.cvar_g_xonoticversion)
2458                         if(time > self.version_nagtime)
2459                         {
2460                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2461                                 {
2462                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2463                                         {
2464                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2465                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2466                                         }
2467                                         else
2468                                         {
2469                                                 float r;
2470                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2471                                                 if(r < 0)
2472                                                 {
2473                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2474                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2475                                                 }
2476                                                 else if(r > 0)
2477                                                 {
2478                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2479                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2480                                                 }
2481                                         }
2482                                 }
2483                                 self.version_nagtime = 0;
2484                         }
2485
2486         // GOD MODE info
2487         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2488         {
2489                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2490                 self.max_armorvalue = 0;
2491         }
2492
2493 #ifdef TETRIS
2494         if (TetrisPreFrame())
2495                 return;
2496 #endif
2497
2498         MUTATOR_CALLHOOK(PlayerPreThink);
2499
2500         if(self.classname == "player") {
2501 //              if(self.netname == "Wazat")
2502 //                      bprint(self.classname, "\n");
2503
2504                 CheckRules_Player();
2505
2506                 PrintWelcomeMessage(self);
2507
2508                 if (intermission_running)
2509                 {
2510                         IntermissionThink ();   // otherwise a button could be missed between
2511                         return;                                 // the think tics
2512                 }
2513
2514                 if(self.teleport_time)
2515                 if(time > self.teleport_time)
2516                 {
2517                         self.teleport_time = 0;
2518                         self.effects = self.effects - (self.effects & EF_NODRAW);
2519                 }
2520
2521                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2522                         UpdateSelectedPlayer();
2523
2524                 //don't allow the player to turn around while game is paused!
2525                 if(timeoutStatus == 2) {
2526                         self.v_angle = self.lastV_angle;
2527                         self.angles = self.lastV_angle;
2528                         self.fixangle = TRUE;
2529                 }
2530
2531                 if(frametime)
2532                 {
2533                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2534                         player_powerups();
2535                 }
2536
2537                 if (self.deadflag != DEAD_NO)
2538                 {
2539                         float button_pressed, force_respawn;
2540                         if(self.personal && g_race_qualifying)
2541                         {
2542                                 if(time > self.death_time)
2543                                 {
2544                                         self.death_time = time + 1; // only retry once a second
2545                                         respawn();
2546                                         self.impulse = 141;
2547                                 }
2548                         }
2549                         else
2550                         {
2551                                 if(frametime)
2552                                         player_anim();
2553                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2554                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2555                                 if (self.deadflag == DEAD_DYING)
2556                                 {
2557                                         if(force_respawn)
2558                                                 self.deadflag = DEAD_RESPAWNING;
2559                                         else if(!button_pressed)
2560                                                 self.deadflag = DEAD_DEAD;
2561                                 }
2562                                 else if (self.deadflag == DEAD_DEAD)
2563                                 {
2564                                         if(button_pressed)
2565                                                 self.deadflag = DEAD_RESPAWNABLE;
2566                                 }
2567                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2568                                 {
2569                                         if(!button_pressed)
2570                                                 self.deadflag = DEAD_RESPAWNING;
2571                                 }
2572                                 else if (self.deadflag == DEAD_RESPAWNING)
2573                                 {
2574                                         if(time > self.death_time)
2575                                         {
2576                                                 self.death_time = time + 1; // only retry once a second
2577                                                 respawn();
2578                                         }
2579                                 }
2580                                 ShowRespawnCountdown();
2581                         }
2582                         return;
2583                 }
2584
2585                 if(g_touchexplode)
2586                 if(time > self.touchexplode_time)
2587                 if(self.classname == "player")
2588                 if(self.deadflag == DEAD_NO)
2589                 if not(IS_INDEPENDENT_PLAYER(self))
2590                 FOR_EACH_PLAYER(other) if(self != other)
2591                 {
2592                         if(time > other.touchexplode_time)
2593                         if(other.classname == "player")
2594                         if(other.deadflag == DEAD_NO)
2595                         if not(IS_INDEPENDENT_PLAYER(other))
2596                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2597                         {
2598                                 PlayerTouchExplode(self, other);
2599                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2600                         }
2601                 }
2602
2603                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2604                 {
2605                         vector dist;
2606
2607                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2608                         dist = self.prevorigin - self.origin;
2609                         dist_z = 0;
2610                         self.lms_traveled_distance += fabs(vlen(dist));
2611
2612                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2613                         {
2614                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2615                                 self.lms_traveled_distance = 0;
2616                         }
2617
2618                         if(time > self.lms_nextcheck)
2619                         {
2620                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2621                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2622                                 {
2623                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2624                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2625                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2626                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2627                                 }
2628                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2629                                 self.lms_traveled_distance = 0;
2630                         }
2631                 }
2632
2633                 self.prevorigin = self.origin;
2634
2635                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2636                 {
2637                         if (!self.crouch)
2638                         {
2639                                 self.crouch = TRUE;
2640                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2641                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2642                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2643                         }
2644                 }
2645                 else
2646                 {
2647                         if (self.crouch)
2648                         {
2649                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2650                                 if (!trace_startsolid)
2651                                 {
2652                                         self.crouch = FALSE;
2653                                         self.view_ofs = PL_VIEW_OFS;
2654                                         setsize (self, PL_MIN, PL_MAX);
2655                                 }
2656                         }
2657                 }
2658
2659                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2660                 {
2661                         if(self.bloodloss_timer < time)
2662                         {
2663                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2664                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2665                         }
2666                 }
2667
2668                 FixPlayermodel();
2669
2670                 GrapplingHookFrame();
2671
2672                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2673                 //if(frametime)
2674                 {
2675                         self.items &~= self.items_added;
2676
2677                         W_WeaponFrame();
2678
2679                         self.items_added = 0;
2680                         if(self.items & IT_JETPACK)
2681                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2682                                         self.items_added |= IT_FUEL;
2683
2684                         self.items |= self.items_added;
2685                 }
2686
2687                 player_regen();
2688                 if(frametime)
2689                         player_anim();
2690
2691                 if (g_minstagib)
2692                         minstagib_ammocheck();
2693
2694                 ctf_setstatus();
2695                 nexball_setstatus();
2696
2697                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2698
2699                 //self.angles_y=self.v_angle_y + 90;   // temp
2700         } else if(gameover) {
2701                 if (intermission_running)
2702                         IntermissionThink ();   // otherwise a button could be missed between
2703                 return;
2704         } else if(self.classname == "observer") {
2705                 ObserverThink();
2706         } else if(self.classname == "spectator") {
2707                 SpectatorThink();
2708         }
2709
2710         if(!zoomstate_set)
2711                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2712
2713         float oldspectatee_status;
2714         oldspectatee_status = self.spectatee_status;
2715         if(self.classname == "spectator")
2716                 self.spectatee_status = num_for_edict(self.enemy);
2717         else if(self.classname == "observer")
2718                 self.spectatee_status = num_for_edict(self);
2719         else
2720                 self.spectatee_status = 0;
2721         if(self.spectatee_status != oldspectatee_status)
2722         {
2723                 ClientData_Touch(self);
2724                 if(g_race || g_cts)
2725                         race_InitSpectator();
2726         }
2727
2728         if(self.teamkill_soundtime)
2729         if(time > self.teamkill_soundtime)
2730         {
2731                 self.teamkill_soundtime = 0;
2732
2733                 entity oldpusher, oldself;
2734
2735                 oldself = self; self = self.teamkill_soundsource;
2736                 oldpusher = self.pusher; self.pusher = oldself;
2737
2738                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2739
2740                 self.pusher = oldpusher;
2741                 self = oldself;
2742         }
2743
2744         if(self.taunt_soundtime)
2745         if(time > self.taunt_soundtime)
2746         {
2747                 self.taunt_soundtime = 0;
2748                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2749         }
2750
2751         target_voicescript_next(self);
2752 }
2753
2754 float isInvisibleString(string s)
2755 {
2756         float i, n, c;
2757         s = strdecolorize(s);
2758         for((i = 0), (n = strlen(s)); i < n; ++i)
2759         {
2760                 c = str2chr(s, i);
2761                 switch(c)
2762                 {
2763                         case 0:
2764                         case 32:
2765                         case 160:
2766                                 break;
2767                         default:
2768                                 return FALSE;
2769                 }
2770         }
2771         return TRUE;
2772 }
2773
2774 /*
2775 =============
2776 PlayerPostThink
2777
2778 Called every frame for each client after the physics are run
2779 =============
2780 */
2781 .float idlekick_lasttimeleft;
2782 void PlayerPostThink (void)
2783 {
2784         // Savage: Check for nameless players
2785         if (isInvisibleString(self.netname)) {
2786                 self.netname = "Player";
2787                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2788         }
2789
2790         // send the clients accuracy stats to the client
2791         if(self.stat_count > 0)
2792         if(frametime)
2793         {
2794                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2795                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2796                 self.stat_count -= 1;
2797         }
2798
2799 #ifdef UID
2800         if(self.uid_kicktime)
2801         if(time > self.uid_kicktime)
2802         {
2803                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2804                 dropclient(self);
2805                 return;
2806         }
2807 #endif
2808
2809         if(sv_maxidle && frametime)
2810         {
2811                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2812                 float timeleft;
2813                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2814                 if(timeleft <= 0)
2815                 {
2816                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2817                         AnnounceTo(self, "terminated");
2818                         dropclient(self);
2819                         return;
2820                 }
2821                 else if(timeleft <= 10)
2822                 {
2823                         if(timeleft != self.idlekick_lasttimeleft)
2824                         {
2825                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2826                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2827                         }
2828                 }
2829                 else
2830                 {
2831                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2832                 }
2833                 self.idlekick_lasttimeleft = timeleft;
2834         }
2835
2836 #ifdef TETRIS
2837         if(self.impulse == 100)
2838                 ImpulseCommands();
2839         if (TetrisPostFrame())
2840                 return;
2841 #endif
2842
2843         CheatFrame();
2844
2845         if(self.classname == "player") {
2846                 CheckRules_Player();
2847                 UpdateChatBubble();
2848                 UpdateTeamBubble();
2849                 if (self.impulse)
2850                         ImpulseCommands();
2851                 if (intermission_running)
2852                         return;         // intermission or finale
2853                 GetPressedKeys();
2854         } else if (self.classname == "observer") {
2855                 //do nothing
2856         } else if (self.classname == "spectator") {
2857                 //do nothing
2858         }
2859
2860         /*
2861         float i;
2862         for(i = 0; i < 1000; ++i)
2863         {
2864                 vector end;
2865                 end = self.origin + '0 0 1024' + 512 * randomvec();
2866                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2867                 if(trace_fraction < 1)
2868                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2869                 {
2870                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2871                         break;
2872                 }
2873         }
2874         */
2875
2876         Arena_Warmup();
2877
2878         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2879
2880         if(self.waypointsprite_attachedforcarrier)
2881                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2882
2883         playerdemo_write();
2884
2885         /*
2886         if(g_race)
2887                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2888         */
2889 }