qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(cvar("spawn_debugview"))
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > cvar("g_spawn_furthest"))
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(cvar("spawn_debugview"))
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(cvar("spawn_debug"))
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(cvar("sv_servermodelsonly"))
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595
 596         Portal_ClearAll(self);
 597
 598         if(self.flagcarried)
 599                 DropFlag(self.flagcarried, world, world);
 600
 601         if(self.ballcarried)
 602                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 603
 604         WaypointSprite_PlayerDead();
 605
 606         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 607                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 608
 609         if(self.killcount != -666) {
 610                 if(g_lms) {
 611                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 612                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 613                         else
 614                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 615                 } else
 616                         bprint ("^4", self.netname, "^4 is spectating now\n");
 617
 618                 if(self.just_joined == FALSE) {
 619                         LogTeamchange(self.playerid, -1, 4);
 620                 } else
 621                         self.just_joined = FALSE;
 622         }
 623
 624         PlayerScore_Clear(self); // clear scores when needed
 625
 626         self.spectatortime = time;
 627
 628         self.classname = "observer";
 629         self.iscreature = FALSE;
 630         self.health = -666;
 631         self.takedamage = DAMAGE_NO;
 632         self.solid = SOLID_NOT;
 633         self.movetype = MOVETYPE_NOCLIP;
 634         self.flags = FL_CLIENT | FL_NOTARGET;
 635         self.armorvalue = 666;
 636         self.effects = 0;
 637         self.armorvalue = cvar("g_balance_armor_start");
 638         self.pauserotarmor_finished = 0;
 639         self.pauserothealth_finished = 0;
 640         self.pauseregen_finished = 0;
 641         self.damageforcescale = 0;
 642         self.death_time = 0;
 643         self.dead_frame = 0;
 644         self.alpha = 0;
 645         self.scale = 0;
 646         self.fade_time = 0;
 647         self.pain_frame = 0;
 648         self.pain_finished = 0;
 649         self.strength_finished = 0;
 650         self.invincible_finished = 0;
 651         self.pushltime = 0;
 652         self.think = SUB_Null;
 653         self.nextthink = 0;
 654         self.hook_time = 0;
 655         self.runes = 0;
 656         self.deadflag = DEAD_NO;
 657         self.angles = spot.angles;
 658         self.angles_z = 0;
 659         self.fixangle = TRUE;
 660         self.crouch = FALSE;
 661
 662         self.view_ofs = PL_VIEW_OFS;
 663         setorigin (self, spot.origin);
 664         setsize (self, '0 0 0', '0 0 0');
 665         self.prevorigin = self.origin;
 666         self.items = 0;
 667         self.weapons = 0;
 668         self.model = "";
 669         FixPlayermodel();
 670         self.model = "";
 671         self.modelindex = 0;
 672         self.weapon = 0;
 673         self.weaponmodel = "";
 674         self.weaponentity = world;
 675         self.exteriorweaponentity = world;
 676         self.killcount = -666;
 677         self.velocity = '0 0 0';
 678         self.avelocity = '0 0 0';
 679         self.punchangle = '0 0 0';
 680         self.punchvector = '0 0 0';
 681         self.oldvelocity = self.velocity;
 682         self.fire_endtime = -1;
 683
 684         if(sv_loddistance1)
 685                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 686
 687         if(g_arena)
 688         {
 689                 if(self.version_mismatch)
 690                 {
 691                         Spawnqueue_Unmark(self);
 692                         Spawnqueue_Remove(self);
 693                 }
 694                 else
 695                 {
 696                         Spawnqueue_Insert(self);
 697                 }
 698         }
 699         else if(g_lms)
 700         {
 701                 // Only if the player cannot play at all
 702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 703                         self.frags = FRAGS_SPECTATOR;
 704                 else
 705                         self.frags = FRAGS_LMS_LOSER;
 706         }
 707         else
 708                 self.frags = FRAGS_SPECTATOR;
 709
 710         MUTATOR_CALLHOOK(MakePlayerObserver);
 711 }
 712
 713 float RestrictSkin(float s)
 714 {
 715         if(!teams_matter)
 716                 return s;
 717         if(s == 6)
 718                 return 6;
 719         return mod(s, 3);
 720 }
 721
 722 void FixPlayermodel()
 723 {
 724         local string defaultmodel;
 725         local float defaultskin, chmdl, oldskin;
 726         local vector m1, m2;
 727
 728         defaultmodel = "";
 729
 730         if(cvar("sv_defaultcharacter") == 1) {
 731                 defaultskin = 0;
 732
 733                 if(teams_matter)
 734                 {
 735                         string s;
 736                         s = Team_ColorNameLowerCase(self.team);
 737                         if(s != "neutral")
 738                         {
 739                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 740                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 741                         }
 742                 }
 743
 744                 if(defaultmodel == "")
 745                 {
 746                         defaultmodel = cvar_string("sv_defaultplayermodel");
 747                         defaultskin = cvar("sv_defaultplayerskin");
 748                 }
 749         }
 750
 751         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 752         {
 753                 if(self.model != "")
 754                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 755                 self.model = ""; // force the != checks to return true
 756         }
 757
 758         if(defaultmodel != "")
 759         {
 760                 if (defaultmodel != self.model)
 761                 {
 762                         m1 = self.mins;
 763                         m2 = self.maxs;
 764                         setmodel_lod (self, defaultmodel);
 765                         setsize (self, m1, m2);
 766                         chmdl = TRUE;
 767                 }
 768
 769                 oldskin = self.skinindex;
 770                 self.skinindex = defaultskin;
 771         } else {
 772                 if (self.playermodel != self.model || self.playermodel == "")
 773                 {
 774                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 775                         m1 = self.mins;
 776                         m2 = self.maxs;
 777                         setmodel_lod (self, self.playermodel);
 778                         setsize (self, m1, m2);
 779                         chmdl = TRUE;
 780                 }
 781
 782                 oldskin = self.skinindex;
 783                 self.skinindex = RestrictSkin(stof(self.playerskin));
 784         }
 785
 786         if(chmdl || oldskin != self.skinindex)
 787                 self.species = player_getspecies(); // model or skin has changed
 788
 789         if(!teams_matter)
 790                 if(strlen(cvar_string("sv_defaultplayercolors")))
 791                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 792                                 setcolor(self, cvar("sv_defaultplayercolors"));
 793 }
 794
 795 void PlayerTouchExplode(entity p1, entity p2)
 796 {
 797         vector org;
 798         org = (p1.origin + p2.origin) * 0.5;
 799         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 800
 801         te_explosion(org);
 802
 803         entity e;
 804         e = spawn();
 805         setorigin(e, org);
 806         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 807         remove(e);
 808 }
 809
 810 /*
 811 =============
 812 PutClientInServer
 813
 814 Called when a client spawns in the server
 815 =============
 816 */
 817 //void() ctf_playerchanged;
 818 void PutClientInServer (void)
 819 {
 820         if(clienttype(self) == CLIENTTYPE_BOT)
 821         {
 822                 self.classname = "player";
 823         }
 824         else if(clienttype(self) == CLIENTTYPE_REAL)
 825         {
 826                 msg_entity = self;
 827                 WriteByte(MSG_ONE, SVC_SETVIEW);
 828                 WriteEntity(MSG_ONE, self);
 829         }
 830
 831         // player is dead and becomes observer
 832         // FIXME fix LMS scoring for new system
 833         if(g_lms)
 834         {
 835                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 836                         self.classname = "observer";
 837         }
 838
 839         if(g_arena || (g_ca && !allowed_to_spawn))
 840         if(!self.spawned)
 841                 self.classname = "observer";
 842
 843         if(gameover)
 844                 self.classname = "observer";
 845
 846         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 847                 entity spot, oldself;
 848                 float j;
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 if(cvar("g_playerclip_collisions"))
 870                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 871                 else
 872                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 873                 self.frags = FRAGS_PLAYER;
 874                 if(independent_players)
 875                         MAKE_INDEPENDENT_PLAYER(self);
 876                 self.flags = FL_CLIENT;
 877                 self.takedamage = DAMAGE_AIM;
 878                 if(g_minstagib)
 879                         self.effects = EF_FULLBRIGHT;
 880                 else
 881                         self.effects = 0;
 882                 self.air_finished = time + 12;
 883                 self.dmg = 2;
 884
 885                 if(inWarmupStage)
 886                 {
 887                         self.ammo_shells = warmup_start_ammo_shells;
 888                         self.ammo_nails = warmup_start_ammo_nails;
 889                         self.ammo_rockets = warmup_start_ammo_rockets;
 890                         self.ammo_cells = warmup_start_ammo_cells;
 891                         self.ammo_fuel = warmup_start_ammo_fuel;
 892                         self.health = warmup_start_health;
 893                         self.armorvalue = warmup_start_armorvalue;
 894                         self.weapons = warmup_start_weapons;
 895                 }
 896                 else
 897                 {
 898                         self.ammo_shells = start_ammo_shells;
 899                         self.ammo_nails = start_ammo_nails;
 900                         self.ammo_rockets = start_ammo_rockets;
 901                         self.ammo_cells = start_ammo_cells;
 902                         self.ammo_fuel = start_ammo_fuel;
 903                         self.health = start_health;
 904                         self.armorvalue = start_armorvalue;
 905                         self.weapons = start_weapons;
 906                 }
 907
 908                 if(g_weaponarena_random)
 909                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 910
 911                 self.items = start_items;
 912                 self.jump_interval = time;
 913
 914                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 915                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 916                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 917                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 918                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 919                 //extend the pause of rotting if client was reset at the beginning of the countdown
 920                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 921                         self.spawnshieldtime += game_starttime - time;
 922                         self.pauserotarmor_finished += game_starttime - time;
 923                         self.pauserothealth_finished += game_starttime - time;
 924                         self.pauseregen_finished += game_starttime - time;
 925                 }
 926                 self.damageforcescale = 2;
 927                 self.death_time = 0;
 928                 self.dead_frame = 0;
 929                 self.alpha = 0;
 930                 self.scale = 0;
 931                 self.fade_time = 0;
 932                 self.pain_frame = 0;
 933                 self.pain_finished = 0;
 934                 self.strength_finished = 0;
 935                 self.invincible_finished = 0;
 936                 self.pushltime = 0;
 937                 // players have no think function
 938                 self.think = SUB_Null;
 939                 self.nextthink = 0;
 940                 self.hook_time = 0;
 941                 self.dmg_team = 0;
 942
 943                 self.metertime = 0;
 944
 945                 self.runes = 0;
 946
 947                 self.deadflag = DEAD_NO;
 948
 949                 self.angles = spot.angles;
 950
 951                 self.angles_z = 0; // never spawn tilted even if the spot says to
 952                 self.fixangle = TRUE; // turn this way immediately
 953                 self.velocity = '0 0 0';
 954                 self.avelocity = '0 0 0';
 955                 self.punchangle = '0 0 0';
 956                 self.punchvector = '0 0 0';
 957                 self.oldvelocity = self.velocity;
 958                 self.fire_endtime = -1;
 959
 960                 msg_entity = self;
 961                 WRITESPECTATABLE_MSG_ONE({
 962                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 963                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 964                 });
 965
 966                 if(sv_loddistance1)
 967                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 968
 969                 self.model = "";
 970                 FixPlayermodel();
 971
 972                 self.crouch = FALSE;
 973                 self.view_ofs = PL_VIEW_OFS;
 974                 setsize (self, PL_MIN, PL_MAX);
 975                 self.spawnorigin = spot.origin;
 976                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 977                 // don't reset back to last position, even if new position is stuck in solid
 978                 self.oldorigin = self.origin;
 979                 self.prevorigin = self.origin;
 980                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 981
 982                 if(g_arena)
 983                 {
 984                         Spawnqueue_Remove(self);
 985                         Spawnqueue_Mark(self);
 986                 }
 987
 988                 else if(g_ca)
 989                         self.caplayer = 1;
 990
 991                 self.event_damage = PlayerDamage;
 992
 993                 self.bot_attack = TRUE;
 994
 995                 self.statdraintime = time + 5;
 996                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 997
 998                 if(self.killcount == -666) {
 999                         PlayerScore_Clear(self);
1000                         self.killcount = 0;
1001                 }
1002
1003                 self.cnt = WEP_LASER;
1004
1005                 CL_SpawnWeaponentity();
1006                 self.alpha = default_player_alpha;
1007                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1008                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1009
1010                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1011                 self.lms_traveled_distance = 0;
1012                 self.speedrunning = FALSE;
1013
1014                 race_PostSpawn(spot);
1015
1016                 if(cvar("spawn_debug"))
1017                 {
1018                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1019                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1020                 }
1021
1022                 //stuffcmd(self, "chase_active 0");
1023                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1024
1025                 if (cvar("g_spawnsound"))
1026                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1027
1028                 if(g_assault) {
1029                         if(self.team == assault_attacker_team)
1030                                 centerprint(self, "You are attacking!");
1031                         else
1032                                 centerprint(self, "You are defending!");
1033                 }
1034
1035                 target_voicescript_clear(self);
1036
1037                 // reset fields the weapons may use
1038                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1039                         weapon_action(j, WR_RESETPLAYER);
1040
1041                 oldself = self;
1042                 self = spot;
1043                         activator = oldself;
1044                                 SUB_UseTargets();
1045                         activator = world;
1046                 self = oldself;
1047
1048                 MUTATOR_CALLHOOK(PlayerSpawn);
1049
1050                 self.switchweapon = w_getbestweapon(self);
1051                 self.cnt = self.switchweapon;
1052                 self.weapon = 0;
1053         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1054                 PutObserverInServer ();
1055         }
1056
1057         //if(g_ctf)
1058         //      ctf_playerchanged();
1059 }
1060
1061 float ClientInit_SendEntity(entity to, float sf)
1062 {
1063         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1064         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1065         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1066         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1067         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1068         if(sv_foginterval && world.fog != "")
1069                 WriteString(MSG_ENTITY, world.fog);
1070         else
1071                 WriteString(MSG_ENTITY, "");
1072         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1073         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1074         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1075         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1076         return TRUE;
1077 }
1078
1079 void ClientInit_CheckUpdate()
1080 {
1081         self.nextthink = time;
1082         if(self.count != cvar("g_balance_armor_blockpercent"))
1083         {
1084                 self.count = cvar("g_balance_armor_blockpercent");
1085                 self.SendFlags |= 1;
1086         }
1087         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1088         {
1089                 self.cnt = cvar("g_balance_weaponswitchdelay");
1090                 self.SendFlags |= 1;
1091         }
1092         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1093         {
1094                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1095                 self.SendFlags |= 1;
1096         }
1097         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1098         {
1099                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1100                 self.SendFlags |= 1;
1101         }
1102 }
1103
1104 void ClientInit_Spawn()
1105 {
1106         entity o;
1107         entity e;
1108         e = spawn();
1109         e.classname = "clientinit";
1110         e.think = ClientInit_CheckUpdate;
1111         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1112
1113         o = self;
1114         self = e;
1115         ClientInit_CheckUpdate();
1116         self = o;
1117 }
1118
1119 /*
1120 =============
1121 SetNewParms
1122 =============
1123 */
1124 void SetNewParms (void)
1125 {
1126         // initialize parms for a new player
1127         parm1 = -(86400 * 366);
1128 }
1129
1130 /*
1131 =============
1132 SetChangeParms
1133 =============
1134 */
1135 void SetChangeParms (void)
1136 {
1137         // save parms for level change
1138         parm1 = self.parm_idlesince - time;
1139 }
1140
1141 /*
1142 =============
1143 DecodeLevelParms
1144 =============
1145 */
1146 void DecodeLevelParms (void)
1147 {
1148         // load parms
1149         self.parm_idlesince = parm1;
1150         if(self.parm_idlesince == -(86400 * 366))
1151                 self.parm_idlesince = time;
1152
1153         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1154         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1155 }
1156
1157 /*
1158 =============
1159 ClientKill
1160
1161 Called when a client types 'kill' in the console
1162 =============
1163 */
1164
1165 void ClientKill_Now_TeamChange()
1166 {
1167         if(self.killindicator_teamchange == -1)
1168         {
1169                 self.team = -1;
1170                 JoinBestTeam( self, FALSE, FALSE );
1171         }
1172         else
1173                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1174 }
1175
1176 void ClientKill_Now()
1177 {
1178         if(self.killindicator_teamchange)
1179                 ClientKill_Now_TeamChange();
1180
1181         // in any case:
1182         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1183
1184         if(self.killindicator)
1185         {
1186                 dprint("Cleaned up after a leaked kill indicator.\n");
1187                 remove(self.killindicator);
1188                 self.killindicator = world;
1189         }
1190 }
1191 void KillIndicator_Think()
1192 {
1193         if (!self.owner.modelindex)
1194         {
1195                 self.owner.killindicator = world;
1196                 remove(self);
1197                 return;
1198         }
1199
1200         if(self.cnt <= 0)
1201         {
1202                 self = self.owner;
1203                 ClientKill_Now(); // no oldself needed
1204                 return;
1205         }
1206         else
1207         {
1208                 if(self.cnt <= 10)
1209                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1210                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1211                 {
1212                         if(self.cnt <= 10)
1213                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1214                         if(self.owner.killindicator_teamchange)
1215                         {
1216                                 if(self.owner.killindicator_teamchange == -1)
1217                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1218                                 else
1219                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1220                         }
1221                         else
1222                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1223                 }
1224                 self.nextthink = time + 1;
1225                 self.cnt -= 1;
1226         }
1227 }
1228
1229 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1230 {
1231         float killtime;
1232         entity e;
1233         killtime = cvar("g_balance_kill_delay");
1234
1235         if(g_race_qualifying)
1236                 killtime = 0;
1237
1238         self.killindicator_teamchange = targetteam;
1239
1240         if(!self.killindicator)
1241         {
1242                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1243                 {
1244                         ClientKill_Now();
1245                 }
1246                 else
1247                 {
1248                         self.killindicator = spawn();
1249                         self.killindicator.owner = self;
1250                         self.killindicator.scale = 0.5;
1251                         setattachment(self.killindicator, self, "");
1252                         setorigin(self.killindicator, '0 0 52');
1253                         self.killindicator.think = KillIndicator_Think;
1254                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1255                         self.killindicator.cnt = ceil(killtime);
1256                         self.killindicator.count = bound(0, ceil(killtime), 10);
1257                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1258
1259                         for(e = world; (e = find(e, classname, "body")) != world; )
1260                         {
1261                                 if(e.enemy != self)
1262                                         continue;
1263                                 e.killindicator = spawn();
1264                                 e.killindicator.owner = e;
1265                                 e.killindicator.scale = 0.5;
1266                                 setattachment(e.killindicator, e, "");
1267                                 setorigin(e.killindicator, '0 0 52');
1268                                 e.killindicator.think = KillIndicator_Think;
1269                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1270                                 e.killindicator.cnt = ceil(killtime);
1271                         }
1272                         self.lip = 0;
1273                 }
1274         }
1275         if(self.killindicator)
1276         {
1277                 if(targetteam)
1278                         self.killindicator.colormod = TeamColor(targetteam);
1279                 else
1280                         self.killindicator.colormod = '0 0 0';
1281         }
1282 }
1283
1284 void ClientKill (void)
1285 {
1286         ClientKill_TeamChange(0);
1287 }
1288
1289 void DoTeamChange(float destteam)
1290 {
1291         float t, c0;
1292         if(!teams_matter)
1293         {
1294                 if(destteam >= 0)
1295                         SetPlayerColors(self, destteam);
1296                 return;
1297         }
1298         if(self.classname == "player")
1299         if(destteam == -1)
1300         {
1301                 CheckAllowedTeams(self);
1302                 t = FindSmallestTeam(self, TRUE);
1303                 switch(self.team)
1304                 {
1305                         case COLOR_TEAM1: c0 = c1; break;
1306                         case COLOR_TEAM2: c0 = c2; break;
1307                         case COLOR_TEAM3: c0 = c3; break;
1308                         case COLOR_TEAM4: c0 = c4; break;
1309                         default:          c0 = 999;
1310                 }
1311                 switch(t)
1312                 {
1313                         case 1:
1314                                 if(c0 > c1)
1315                                         destteam = COLOR_TEAM1;
1316                                 break;
1317                         case 2:
1318                                 if(c0 > c2)
1319                                         destteam = COLOR_TEAM2;
1320                                 break;
1321                         case 3:
1322                                 if(c0 > c3)
1323                                         destteam = COLOR_TEAM3;
1324                                 break;
1325                         case 4:
1326                                 if(c0 > c4)
1327                                         destteam = COLOR_TEAM4;
1328                                 break;
1329                 }
1330                 if(destteam == -1)
1331                         return;
1332         }
1333         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1334                 return;
1335         ClientKill_TeamChange(destteam);
1336 }
1337
1338 void FixClientCvars(entity e)
1339 {
1340         // send prediction settings to the client
1341         stuffcmd(e, "\nin_bindmap 0 0\n");
1342         if(g_race || g_cts)
1343                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1344         if(cvar("g_antilag") == 3) // client side hitscan
1345                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1346                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1347         /*
1348          * we no longer need to stuff this. Remove this comment block if you feel
1349          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1350         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1351         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1352         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1353         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1354         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1355         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1356         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1357         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1358         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1359         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1360         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1361         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1362         stuffcmd(e, "cl_movement_edgefriction 1\n");
1363          */
1364 }
1365
1366 /*
1367 =============
1368 ClientConnect
1369
1370 Called when a client connects to the server
1371 =============
1372 */
1373 //void ctf_clientconnect();
1374 string ColoredTeamName(float t);
1375 void DecodeLevelParms (void);
1376 //void dom_player_join_team(entity pl);
1377 #ifdef UID
1378 .float uid_kicktime;
1379 .string uid;
1380 #endif
1381 void ClientConnect (void)
1382 {
1383         float t;
1384
1385         if(self.flags & FL_CLIENT)
1386         {
1387                 print("Warning: ClientConnect, but already connected!\n");
1388                 return;
1389         }
1390
1391         if(Ban_MaybeEnforceBan(self))
1392                 return;
1393
1394         DecodeLevelParms();
1395
1396 #ifdef WATERMARK
1397         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1398 #endif
1399
1400         self.classname = "player_joining";
1401
1402         self.flags = FL_CLIENT;
1403         self.version_nagtime = time + 10 + random() * 10;
1404
1405         if(player_count<0)
1406         {
1407                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1408                 player_count = 0;
1409         }
1410
1411         PlayerScore_Attach(self);
1412         ClientData_Attach();
1413
1414         bot_clientconnect();
1415
1416         playerdemo_init();
1417
1418         anticheat_init();
1419
1420         race_PreSpawnObserver();
1421
1422         //if(g_domination)
1423         //      dom_player_join_team(self);
1424
1425         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1426
1427         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1428                 self.classname = "observer";
1429         } else {
1430                 if(teams_matter)
1431                 {
1432                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1433                         {
1434                                 self.classname = "player";
1435                                 campaign_bots_may_start = 1;
1436                         }
1437                         else
1438                         {
1439                                 self.classname = "observer"; // do it anyway
1440                         }
1441                 }
1442                 else
1443                 {
1444                         self.classname = "player";
1445                         campaign_bots_may_start = 1;
1446                 }
1447         }
1448
1449         self.playerid = (playerid_last = playerid_last + 1);
1450
1451         if(cvar("sv_eventlog"))
1452                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1453
1454         LogTeamchange(self.playerid, self.team, 1);
1455
1456         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1457
1458         self.netname_previous = strzone(self.netname);
1459
1460         bprint("^4", self.netname, "^4 connected");
1461
1462         if(self.classname != "observer" && (g_domination || g_ctf))
1463                 bprint(" and joined the ", ColoredTeamName(self.team));
1464
1465         bprint("\n");
1466
1467         self.welcomemessage_time = 0;
1468
1469         stuffcmd(self, strcat(clientstuff, "\n"));
1470         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1471         stuffcmd(self, "cl_particles_reloadeffects\n");
1472
1473         FixClientCvars(self);
1474
1475         // spawnfunc_waypoint sprites
1476         WaypointSprite_InitClient(self);
1477
1478         // Wazat's grappling hook
1479         SetGrappleHookBindings();
1480
1481         // get autoswitch state from player when he toggles it
1482         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1483
1484         // get version info from player
1485         stuffcmd(self, "cmd clientversion $gameversion\n");
1486
1487         // get other cvars from player
1488         GetCvars(0);
1489
1490         // set cvar for team scoreboard
1491         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1492
1493         // notify about available teams
1494         if(teams_matter)
1495         {
1496                 CheckAllowedTeams(self);
1497                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1498                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1499         }
1500         else
1501                 stuffcmd(self, "set _teams_available 0\n");
1502
1503         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1504
1505         if(g_arena || g_ca)
1506         {
1507                 self.classname = "observer";
1508                 if(g_arena)
1509                         Spawnqueue_Insert(self);
1510         }
1511         /*else if(g_ctf)
1512         {
1513                 ctf_clientconnect();
1514         }*/
1515
1516         if(teams_matter || radar_showennemies)
1517                 attach_entcs();
1518
1519         bot_relinkplayerlist();
1520
1521         self.spectatortime = time;
1522         if(blockSpectators)
1523         {
1524                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1525         }
1526
1527         self.jointime = time;
1528         self.allowedTimeouts = cvar("sv_timeout_number");
1529
1530         if(clienttype(self) == CLIENTTYPE_REAL)
1531         {
1532                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1533                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1534         }
1535
1536         if(g_lms)
1537         {
1538                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1539                 {
1540                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1541                         self.frags = FRAGS_SPECTATOR;
1542                 }
1543         }
1544
1545         if(!sv_foginterval && world.fog != "")
1546                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1547
1548         SoundEntity_Attach(self);
1549
1550         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1551         {
1552                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1553                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1554         }
1555         else
1556                 self.hitplotfh = -1;
1557
1558 #ifdef UID
1559         if(clienttype(self) == CLIENTTYPE_REAL)
1560         if not(self.uid)
1561                 self.uid_kicktime = time + 60;
1562 #endif
1563
1564         if(g_race || g_cts) {
1565                 string rr;
1566                 if(g_cts)
1567                         rr = CTS_RECORD;
1568                 else
1569                         rr = RACE_RECORD;
1570                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1571
1572                 race_send_recordtime(MSG_ONE);
1573                 race_send_speedaward(MSG_ONE);
1574
1575                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1576                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1577                 race_send_speedaward_alltimebest(MSG_ONE);
1578
1579                 float i;
1580                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1581                         race_SendRankings(i, 0, 0, MSG_ONE);
1582                 }
1583         }
1584         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1585                 send_CSQC_teamnagger();
1586
1587         CheatInitClient();
1588 }
1589
1590 /*
1591 =============
1592 ClientDisconnect
1593
1594 Called when a client disconnects from the server
1595 =============
1596 */
1597 .entity chatbubbleentity;
1598 .entity teambubbleentity;
1599 void ReadyCount();
1600 void ClientDisconnect (void)
1601 {
1602         if not(self.flags & FL_CLIENT)
1603         {
1604                 print("Warning: ClientDisconnect without ClientConnect\n");
1605                 return;
1606         }
1607
1608         CheatShutdownClient();
1609
1610         if(self.hitplotfh >= 0)
1611         {
1612                 fclose(self.hitplotfh);
1613                 self.hitplotfh = -1;
1614         }
1615
1616         anticheat_report();
1617         anticheat_shutdown();
1618
1619         playerdemo_shutdown();
1620
1621         bot_clientdisconnect();
1622
1623         if(self.entcs)
1624                 detach_entcs();
1625
1626         if(cvar("sv_eventlog"))
1627                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1628         bprint ("^4",self.netname);
1629         bprint ("^4 disconnected\n");
1630
1631         SoundEntity_Detach(self);
1632
1633         DropAllRunes(self);
1634         MUTATOR_CALLHOOK(ClientDisconnect);
1635
1636         Portal_ClearAll(self);
1637
1638         if(self.flagcarried)
1639                 DropFlag(self.flagcarried, world, world);
1640         if(self.ballcarried)
1641                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1642
1643         // Here, everything has been done that requires this player to be a client.
1644
1645         self.flags &~= FL_CLIENT;
1646
1647         if (self.chatbubbleentity)
1648                 remove (self.chatbubbleentity);
1649
1650         if (self.teambubbleentity)
1651                 remove (self.teambubbleentity);
1652
1653         if (self.killindicator)
1654                 remove (self.killindicator);
1655
1656         WaypointSprite_PlayerGone();
1657
1658         bot_relinkplayerlist();
1659
1660         // remove laserdot
1661         if(self.weaponentity)
1662                 if(self.weaponentity.lasertarget)
1663                         remove(self.weaponentity.lasertarget);
1664
1665         if(g_arena)
1666         {
1667                 Spawnqueue_Unmark(self);
1668                 Spawnqueue_Remove(self);
1669         }
1670
1671         ClientData_Detach();
1672         PlayerScore_Detach(self);
1673
1674         if(self.netname_previous)
1675                 strunzone(self.netname_previous);
1676         if(self.clientstatus)
1677                 strunzone(self.clientstatus);
1678
1679         ClearPlayerSounds();
1680
1681         if(self.personal)
1682                 remove(self.personal);
1683
1684         self.playerid = 0;
1685         ReadyCount();
1686
1687         // free cvars
1688         GetCvars(-1);
1689 }
1690
1691 .float BUTTON_CHAT;
1692 void ChatBubbleThink()
1693 {
1694         self.nextthink = time;
1695         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1696         {
1697                 if(self.owner) // but why can that ever be world?
1698                         self.owner.chatbubbleentity = world;
1699                 remove(self);
1700                 return;
1701         }
1702         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1703 #ifdef TETRIS
1704                 || self.owner.tetris_on
1705 #endif
1706         )
1707                 self.model = self.mdl;
1708         else
1709                 self.model = "";
1710 };
1711
1712 void UpdateChatBubble()
1713 {
1714         if (!self.modelindex)
1715                 return;
1716         // spawn a chatbubble entity if needed
1717         if (!self.chatbubbleentity)
1718         {
1719                 self.chatbubbleentity = spawn();
1720                 self.chatbubbleentity.owner = self;
1721                 self.chatbubbleentity.exteriormodeltoclient = self;
1722                 self.chatbubbleentity.think = ChatBubbleThink;
1723                 self.chatbubbleentity.nextthink = time;
1724                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1725                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1726                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1727                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1728                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1729                 self.chatbubbleentity.model = "";
1730                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1731         }
1732 }
1733
1734
1735 void TeamBubbleThink()
1736 {
1737         self.nextthink = time;
1738         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1739         {
1740                 if(self.owner) // but why can that ever be world?
1741                         self.owner.teambubbleentity = world;
1742                 remove(self);
1743                 return;
1744         }
1745 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1746         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1747                 self.model = "";
1748         else
1749                 self.model = self.mdl;
1750
1751 };
1752
1753 float TeamBubble_customizeentityforclient()
1754 {
1755         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1756 }
1757
1758 void UpdateTeamBubble()
1759 {
1760         if (!self.modelindex || !teams_matter)
1761                 return;
1762         // spawn a teambubble entity if needed
1763         if (!self.teambubbleentity && teams_matter)
1764         {
1765                 self.teambubbleentity = spawn();
1766                 self.teambubbleentity.owner = self;
1767                 self.teambubbleentity.exteriormodeltoclient = self;
1768                 self.teambubbleentity.think = TeamBubbleThink;
1769                 self.teambubbleentity.nextthink = time;
1770                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1771 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1772                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1773                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1774                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1775                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1776                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1777                 self.teambubbleentity.effects = EF_LOWPRECISION;
1778         }
1779 }
1780
1781 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1782 // added to the model skins
1783 /*void UpdateColorModHack()
1784 {
1785         local float c;
1786         c = self.clientcolors & 15;
1787         // LordHavoc: only bothering to support white, green, red, yellow, blue
1788              if (!teams_matter) self.colormod = '0 0 0';
1789         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1790         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1791         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1792         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1793         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1794         else self.colormod = '1 1 1';
1795 };*/
1796
1797 .float oldcolormap;
1798 void respawn(void)
1799 {
1800         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1801         {
1802                 self.solid = SOLID_NOT;
1803                 self.takedamage = DAMAGE_NO;
1804                 self.movetype = MOVETYPE_FLY;
1805                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1806                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1807                 self.effects |= EF_ADDITIVE;
1808                 self.oldcolormap = self.colormap;
1809                 self.colormap = 512;
1810                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1811                 if(cvar("g_respawn_ghosts_maxtime"))
1812                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1813         }
1814
1815         CopyBody(1);
1816         self.effects |= EF_NODRAW; // prevent another CopyBody
1817         if(self.oldcolormap)
1818         {
1819                 self.colormap = self.oldcolormap;
1820                 self.oldcolormap = 0;
1821         }
1822         PutClientInServer();
1823 }
1824
1825 void play_countdown(float finished, string samp)
1826 {
1827         if(clienttype(self) == CLIENTTYPE_REAL)
1828                 if(floor(finished - time - frametime) != floor(finished - time))
1829                         if(finished - time < 6)
1830                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1831 }
1832
1833 /**
1834  * When sv_timeout is used this function returs strings like
1835  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1836  * Called by centerprint functions
1837  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1838  */
1839 string getTimeoutText(float addOneSecond) {
1840         if (!cvar("sv_timeout") || !timeoutStatus)
1841                 return "";
1842
1843         local string retStr;
1844         if (timeoutStatus == 1) {
1845                 if (addOneSecond == 1) {
1846                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1847                 }
1848                 else {
1849                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1850                 }
1851                 return retStr;
1852         }
1853         else if (timeoutStatus == 2) {
1854                 if (addOneSecond) {
1855                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1856                         //don't show messages like "Timeout ends in 0 seconds"...
1857                         if ((remainingTimeoutTime + 1) > 0)
1858                                 return retStr;
1859                         else
1860                                 return "";
1861                 }
1862                 else {
1863                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1864                         //don't show messages like "Timeout ends in 0 seconds"...
1865                         if (remainingTimeoutTime > 0)
1866                                 return retStr;
1867                         else
1868                                 return "";
1869                 }
1870         }
1871         else return "";
1872 }
1873
1874 void player_powerups (void)
1875 {
1876         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1877         {
1878                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1879                 self.modelflags |= MF_ROCKET;
1880         }
1881         else
1882         {
1883                 SoundEntity_StopSound(self, CHAN_PLAYER);
1884                 self.modelflags &~= MF_ROCKET;
1885         }
1886
1887         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1888
1889         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1890                 return;
1891
1892         Fire_ApplyDamage(self);
1893         Fire_ApplyEffect(self);
1894
1895         if (g_minstagib)
1896         {
1897                 self.effects |= EF_FULLBRIGHT;
1898
1899                 if (self.items & IT_STRENGTH)
1900                 {
1901                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1902                         if (time > self.strength_finished)
1903                         {
1904                                 self.alpha = default_player_alpha;
1905                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1906                                 self.items &~= IT_STRENGTH;
1907                                 sprint(self, "^3Invisibility has worn off\n");
1908                         }
1909                 }
1910                 else
1911                 {
1912                         if (time < self.strength_finished)
1913                         {
1914                                 self.alpha = g_minstagib_invis_alpha;
1915                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1916                                 self.items |= IT_STRENGTH;
1917                                 sprint(self, "^3You are invisible\n");
1918                         }
1919                 }
1920
1921                 if (self.items & IT_INVINCIBLE)
1922                 {
1923                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1924                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1925                         {
1926                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1927                                 sprint(self, "^3Speed has worn off\n");
1928                         }
1929                 }
1930                 else
1931                 {
1932                         if (time < self.invincible_finished)
1933                         {
1934                                 self.items = self.items | IT_INVINCIBLE;
1935                                 sprint(self, "^3You are on speed\n");
1936                         }
1937                 }
1938                 return;
1939         }
1940
1941         if (self.items & IT_STRENGTH)
1942         {
1943                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1944                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1945                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1946                 {
1947                         self.items = self.items - (self.items & IT_STRENGTH);
1948                         sprint(self, "^3Strength has worn off\n");
1949                 }
1950         }
1951         else
1952         {
1953                 if (time < self.strength_finished)
1954                 {
1955                         self.items = self.items | IT_STRENGTH;
1956                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1957                 }
1958         }
1959         if (self.items & IT_INVINCIBLE)
1960         {
1961                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1962                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1963                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1964                 {
1965                         self.items = self.items - (self.items & IT_INVINCIBLE);
1966                         sprint(self, "^3Shield has worn off\n");
1967                 }
1968         }
1969         else
1970         {
1971                 if (time < self.invincible_finished)
1972                 {
1973                         self.items = self.items | IT_INVINCIBLE;
1974                         sprint(self, "^3Shield surrounds you\n");
1975                 }
1976         }
1977
1978         if(cvar("g_nodepthtestplayers"))
1979                 self.effects = self.effects | EF_NODEPTHTEST;
1980
1981         if(cvar("g_fullbrightplayers"))
1982                 self.effects = self.effects | EF_FULLBRIGHT;
1983
1984         // midair gamemode: damage only while in the air
1985         // if in midair mode, being on ground grants temporary invulnerability
1986         // (this is so that multishot weapon don't clear the ground flag on the
1987         // first damage in the frame, leaving the player vulnerable to the
1988         // remaining hits in the same frame)
1989         if (self.flags & FL_ONGROUND)
1990         if (g_midair)
1991                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1992
1993         if (time >= game_starttime)
1994         if (time < self.spawnshieldtime)
1995                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1996 }
1997
1998 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1999 {
2000         if(current > stable)
2001                 return current;
2002         else if(current > stable - 0.25) // when close enough, "snap"
2003                 return stable;
2004         else
2005                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2006 }
2007
2008 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2009 {
2010         if(current < stable)
2011                 return current;
2012         else if(current < stable + 0.25) // when close enough, "snap"
2013                 return stable;
2014         else
2015                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2016 }
2017
2018 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2019 {
2020         if(current > rotstable)
2021         {
2022                 if(rotframetime > 0)
2023                 {
2024                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2025                         current = max(rotstable, current - rotlinear * rotframetime);
2026                 }
2027         }
2028         else if(current < regenstable)
2029         {
2030                 if(regenframetime > 0)
2031                 {
2032                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2033                         current = min(regenstable, current + regenlinear * regenframetime);
2034                 }
2035         }
2036
2037         if(current > limit)
2038                 current = limit;
2039
2040         return current;
2041 }
2042
2043 void player_regen (void)
2044 {
2045         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2046         maxh = cvar("g_balance_health_rotstable");
2047         maxa = cvar("g_balance_armor_rotstable");
2048         maxf = cvar("g_balance_fuel_rotstable");
2049         minh = cvar("g_balance_health_regenstable");
2050         mina = cvar("g_balance_armor_regenstable");
2051         minf = cvar("g_balance_fuel_regenstable");
2052         limith = cvar("g_balance_health_limit");
2053         limita = cvar("g_balance_armor_limit");
2054         limitf = cvar("g_balance_fuel_limit");
2055
2056         max_mod = regen_mod = rot_mod = limit_mod = 1;
2057
2058         if (self.runes & RUNE_REGEN)
2059         {
2060                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2061                 {
2062                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2063                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2064                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2065                 }
2066                 else
2067                 {
2068                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2069                         max_mod = cvar("g_balance_rune_regen_hpmod");
2070                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2071                 }
2072         }
2073         else if (self.runes & CURSE_VENOM)
2074         {
2075                 max_mod = cvar("g_balance_curse_venom_hpmod");
2076                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2077                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2078                 else
2079                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2080                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2081                 //if (!self.runes & RUNE_REGEN)
2082                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2083         }
2084         maxh = maxh * max_mod;
2085         //maxa = maxa * max_mod;
2086         //maxf = maxf * max_mod;
2087         minh = minh * max_mod;
2088         //mina = mina * max_mod;
2089         //minf = minf * max_mod;
2090         limith = limith * limit_mod;
2091         limita = limita * limit_mod;
2092         //limitf = limitf * limit_mod;
2093
2094         if(g_lms && g_ca)
2095                 rot_mod = 0;
2096
2097         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2098         {
2099                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2100                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2101
2102                 // if player rotted to death...  die!
2103                 if(self.health < 1)
2104                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2105         }
2106
2107         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2108                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2109 }
2110
2111 float zoomstate_set;
2112 void SetZoomState(float z)
2113 {
2114         if(z != self.zoomstate)
2115         {
2116                 self.zoomstate = z;
2117                 ClientData_Touch(self);
2118         }
2119         zoomstate_set = 1;
2120 }
2121
2122 void GetPressedKeys(void) {
2123         MUTATOR_CALLHOOK(GetPressedKeys);
2124         if (self.movement_x > 0) // get if movement keys are pressed
2125         {       // forward key pressed
2126                 self.pressedkeys |= KEY_FORWARD;
2127                 self.pressedkeys &~= KEY_BACKWARD;
2128         }
2129         else if (self.movement_x < 0)
2130         {       // backward key pressed
2131                 self.pressedkeys |= KEY_BACKWARD;
2132                 self.pressedkeys &~= KEY_FORWARD;
2133         }
2134         else
2135         {       // no x input
2136                 self.pressedkeys &~= KEY_FORWARD;
2137                 self.pressedkeys &~= KEY_BACKWARD;
2138         }
2139
2140         if (self.movement_y > 0)
2141         {       // right key pressed
2142                 self.pressedkeys |= KEY_RIGHT;
2143                 self.pressedkeys &~= KEY_LEFT;
2144         }
2145         else if (self.movement_y < 0)
2146         {       // left key pressed
2147                 self.pressedkeys |= KEY_LEFT;
2148                 self.pressedkeys &~= KEY_RIGHT;
2149         }
2150         else
2151         {       // no y input
2152                 self.pressedkeys &~= KEY_RIGHT;
2153                 self.pressedkeys &~= KEY_LEFT;
2154         }
2155
2156         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2157                 self.pressedkeys |= KEY_JUMP;
2158         else
2159                 self.pressedkeys &~= KEY_JUMP;
2160         if (self.BUTTON_CROUCH)
2161                 self.pressedkeys |= KEY_CROUCH;
2162         else
2163                 self.pressedkeys &~= KEY_CROUCH;
2164 }
2165
2166 void update_stats (float number, float hit, float fired) {
2167 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2168 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2169
2170         if(number) {
2171                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2172                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2173         } else {
2174                 self.stat_hit = hit * sv_accuracy_data_share;
2175                 self.stat_fired = fired * sv_accuracy_data_share;
2176         }
2177 }
2178
2179 /*
2180 ======================
2181 spectate mode routines
2182 ======================
2183 */
2184
2185 .float weapon_count;
2186 void SpectateCopy(entity spectatee) {
2187         if(spectatee.weapon_count < WEP_LAST) {
2188                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2189                 spectatee.weapon_count ++;
2190         } else
2191                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2192
2193         other = spectatee;
2194         MUTATOR_CALLHOOK(SpectateCopy);
2195         self.armortype = spectatee.armortype;
2196         self.armorvalue = spectatee.armorvalue;
2197         self.ammo_cells = spectatee.ammo_cells;
2198         self.ammo_shells = spectatee.ammo_shells;
2199         self.ammo_nails = spectatee.ammo_nails;
2200         self.ammo_rockets = spectatee.ammo_rockets;
2201         self.ammo_fuel = spectatee.ammo_fuel;
2202         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2203         self.health = spectatee.health;
2204         self.impulse = 0;
2205         self.items = spectatee.items;
2206         self.metertime = spectatee.metertime;
2207         self.strength_finished = spectatee.strength_finished;
2208         self.invincible_finished = spectatee.invincible_finished;
2209         self.pressedkeys = spectatee.pressedkeys;
2210         self.weapons = spectatee.weapons;
2211         self.switchweapon = spectatee.switchweapon;
2212         self.weapon = spectatee.weapon;
2213         self.punchangle = spectatee.punchangle;
2214         self.view_ofs = spectatee.view_ofs;
2215         self.v_angle = spectatee.v_angle;
2216         self.velocity = spectatee.velocity;
2217         self.dmg_take = spectatee.dmg_take;
2218         self.dmg_save = spectatee.dmg_save;
2219         self.dmg_inflictor = spectatee.dmg_inflictor;
2220         self.angles = spectatee.v_angle;
2221         self.fixangle = TRUE;
2222         setorigin(self, spectatee.origin);
2223         setsize(self, spectatee.mins, spectatee.maxs);
2224         SetZoomState(spectatee.zoomstate);
2225
2226         anticheat_spectatecopy(spectatee);
2227 }
2228
2229 float SpectateUpdate() {
2230         if(!self.enemy)
2231                 return 0;
2232
2233         if (self == self.enemy)
2234                 return 0;
2235
2236         if(self.enemy.classname != "player")
2237                 return 0;
2238
2239         SpectateCopy(self.enemy);
2240
2241         return 1;
2242 }
2243
2244 float SpectateNext() {
2245         other = find(self.enemy, classname, "player");
2246
2247         if (!other)
2248                 other = find(other, classname, "player");
2249
2250         if (other)
2251                 self.enemy = other;
2252
2253         if(self.enemy.classname == "player") {
2254                 msg_entity = self;
2255                 WriteByte(MSG_ONE, SVC_SETVIEW);
2256                 WriteEntity(MSG_ONE, self.enemy);
2257                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2258                 self.movetype = MOVETYPE_NONE;
2259
2260                 self.enemy.weapon_count = 0;
2261
2262                 if(!SpectateUpdate())
2263                         PutObserverInServer();
2264
2265                 return 1;
2266         } else {
2267                 return 0;
2268         }
2269 }
2270
2271 /*
2272 =============
2273 ShowRespawnCountdown()
2274
2275 Update a respawn countdown display.
2276 =============
2277 */
2278 void ShowRespawnCountdown()
2279 {
2280         float number;
2281         if(self.deadflag == DEAD_NO) // just respawned?
2282                 return;
2283         else
2284         {
2285                 number = ceil(self.death_time - time);
2286                 if(number <= 0)
2287                         return;
2288                 if(number <= self.respawn_countdown)
2289                 {
2290                         self.respawn_countdown = number - 1;
2291                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2292                                 AnnounceTo(self, strcat(ftos(number), ""));
2293                 }
2294         }
2295 }
2296
2297 void LeaveSpectatorMode()
2298 {
2299         if(isJoinAllowed()) {
2300                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2301                         self.classname = "player";
2302
2303                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2304                                 JoinBestTeam(self, FALSE, TRUE);
2305
2306                         if(cvar("g_campaign"))
2307                                 campaign_bots_may_start = 1;
2308
2309                         self.stat_count = WEP_LAST;
2310
2311                         PutClientInServer();
2312
2313                         if(self.classname == "player")
2314                                 bprint ("^4", self.netname, "^4 is playing now\n");
2315
2316                         if(!cvar("g_campaign"))
2317                                 centerprint(self,""); // clear MOTD
2318
2319                         return;
2320                 } else {
2321                         if (g_ca && self.caplayer) {
2322                         }       // do nothing
2323                         else
2324                                 stuffcmd(self,"menu_showteamselect\n");
2325                         return;
2326                 }
2327         }
2328         else {
2329                 //player may not join because of g_maxplayers is set
2330                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2331         }
2332 }
2333
2334 /**
2335  * Determines whether the player is allowed to join. This depends on cvar
2336  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2337  * it checks whether the number of currently playing players exceeds g_maxplayers.
2338  * @return bool TRUE if the player is allowed to join, false otherwise
2339  */
2340 float isJoinAllowed() {
2341         if (!cvar("g_maxplayers"))
2342                 return TRUE;
2343
2344         local entity e;
2345         local float currentlyPlaying;
2346         FOR_EACH_REALPLAYER(e) {
2347                 if(e.classname == "player")
2348                         currentlyPlaying += 1;
2349         }
2350         if(currentlyPlaying < cvar("g_maxplayers"))
2351                 return TRUE;
2352
2353         return FALSE;
2354 }
2355
2356 /**
2357  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2358  * g_maxplayers_spectator_blocktime seconds
2359  */
2360 void checkSpectatorBlock() {
2361         if(self.classname == "spectator" || self.classname == "observer") {
2362                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2363                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2364                         dropclient(self);
2365                 }
2366         }
2367 }
2368
2369 float vercmp_recursive(string v1, string v2)
2370 {
2371         float dot1, dot2;
2372         string s1, s2;
2373         float r;
2374
2375         dot1 = strstrofs(v1, ".", 0);
2376         dot2 = strstrofs(v2, ".", 0);
2377         if(dot1 == -1)
2378                 s1 = v1;
2379         else
2380                 s1 = substring(v1, 0, dot1);
2381         if(dot2 == -1)
2382                 s2 = v2;
2383         else
2384                 s2 = substring(v2, 0, dot2);
2385
2386         r = stof(s1) - stof(s2);
2387         if(r != 0)
2388                 return r;
2389
2390         r = strcasecmp(s1, s2);
2391         if(r != 0)
2392                 return r;
2393
2394         if(dot1 == -1)
2395                 if(dot2 == -1)
2396                         return 0;
2397                 else
2398                         return -1;
2399         else
2400                 if(dot2 == -1)
2401                         return 1;
2402                 else
2403                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2404 }
2405
2406 float vercmp(string v1, string v2)
2407 {
2408         if(strcasecmp(v1, v2) == 0) // early out check
2409                 return 0;
2410         return vercmp_recursive(v1, v2);
2411 }
2412
2413 void ObserverThink()
2414 {
2415         if (self.flags & FL_JUMPRELEASED) {
2416                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2417                         self.welcomemessage_time = 0;
2418                         self.flags &~= FL_JUMPRELEASED;
2419                         self.flags |= FL_SPAWNING;
2420                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2421                         self.welcomemessage_time = 0;
2422                         self.flags &~= FL_JUMPRELEASED;
2423                         if(SpectateNext() == 1) {
2424                                 self.classname = "spectator";
2425                         }
2426                 }
2427         } else {
2428                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2429                         self.flags |= FL_JUMPRELEASED;
2430                         if(self.flags & FL_SPAWNING)
2431                         {
2432                                 self.flags &~= FL_SPAWNING;
2433                                 LeaveSpectatorMode();
2434                                 return;
2435                         }
2436                 }
2437         }
2438         PrintWelcomeMessage(self);
2439 }
2440
2441 void SpectatorThink()
2442 {
2443         if (self.flags & FL_JUMPRELEASED) {
2444                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2445                         self.welcomemessage_time = 0;
2446                         self.flags &~= FL_JUMPRELEASED;
2447                         self.flags |= FL_SPAWNING;
2448                 } else if(self.BUTTON_ATCK) {
2449                         self.welcomemessage_time = 0;
2450                         self.flags &~= FL_JUMPRELEASED;
2451                         if(SpectateNext() == 1) {
2452                                 self.classname = "spectator";
2453                         } else {
2454                                 self.classname = "observer";
2455                                 self.stat_count = WEP_LAST;
2456                                 PutClientInServer();
2457                         }
2458                 } else if (self.BUTTON_ATCK2) {
2459                         self.welcomemessage_time = 0;
2460                         self.flags &~= FL_JUMPRELEASED;
2461                         self.classname = "observer";
2462                         self.stat_count = WEP_LAST;
2463                         PutClientInServer();
2464                 } else {
2465                         if(!SpectateUpdate())
2466                                 PutObserverInServer();
2467                 }
2468         } else {
2469                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2470                         self.flags |= FL_JUMPRELEASED;
2471                         if(self.flags & FL_SPAWNING)
2472                         {
2473                                 self.flags &~= FL_SPAWNING;
2474                                 LeaveSpectatorMode();
2475                                 return;
2476                         }
2477                 }
2478         }
2479
2480         PrintWelcomeMessage(self);
2481         self.flags |= FL_CLIENT | FL_NOTARGET;
2482 }
2483
2484 .float touchexplode_time;
2485
2486 /*
2487 =============
2488 PlayerPreThink
2489
2490 Called every frame for each client before the physics are run
2491 =============
2492 */
2493 void() ctf_setstatus;
2494 void() nexball_setstatus;
2495 .float items_added;
2496 void PlayerPreThink (void)
2497 {
2498         self.stat_game_starttime = game_starttime;
2499         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2500         self.stat_leadlimit = cvar("leadlimit");
2501
2502         if(frametime)
2503         {
2504                 // physics frames: update anticheat stuff
2505                 anticheat_prethink();
2506         }
2507
2508         if(blockSpectators && frametime)
2509                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2510                 checkSpectatorBlock();
2511
2512         zoomstate_set = 0;
2513
2514         if(self.netname_previous != self.netname)
2515         {
2516                 if(cvar("sv_eventlog"))
2517                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2518                 if(self.netname_previous)
2519                         strunzone(self.netname_previous);
2520                 self.netname_previous = strzone(self.netname);
2521         }
2522
2523         // version nagging
2524         if(self.version_nagtime)
2525                 if(self.cvar_g_xonoticversion)
2526                         if(time > self.version_nagtime)
2527                         {
2528                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2529                                 {
2530                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2531                                         {
2532                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2533                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2534                                         }
2535                                         else
2536                                         {
2537                                                 float r;
2538                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2539                                                 if(r < 0)
2540                                                 {
2541                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2542                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2543                                                 }
2544                                                 else if(r > 0)
2545                                                 {
2546                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2547                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2548                                                 }
2549                                         }
2550                                 }
2551                                 self.version_nagtime = 0;
2552                         }
2553
2554         // GOD MODE info
2555         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2556         {
2557                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2558                 self.max_armorvalue = 0;
2559         }
2560
2561 #ifdef TETRIS
2562         if (TetrisPreFrame())
2563                 return;
2564 #endif
2565
2566         MUTATOR_CALLHOOK(PlayerPreThink);
2567
2568         if(self.classname == "player") {
2569 //              if(self.netname == "Wazat")
2570 //                      bprint(self.classname, "\n");
2571
2572                 CheckRules_Player();
2573
2574                 PrintWelcomeMessage(self);
2575
2576                 if (intermission_running)
2577                 {
2578                         IntermissionThink ();   // otherwise a button could be missed between
2579                         return;                                 // the think tics
2580                 }
2581
2582                 if(self.teleport_time)
2583                 if(time > self.teleport_time)
2584                 {
2585                         self.teleport_time = 0;
2586                         self.effects = self.effects - (self.effects & EF_NODRAW);
2587                 }
2588
2589                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2590                         UpdateSelectedPlayer();
2591
2592                 //don't allow the player to turn around while game is paused!
2593                 if(timeoutStatus == 2) {
2594                         self.v_angle = self.lastV_angle;
2595                         self.angles = self.lastV_angle;
2596                         self.fixangle = TRUE;
2597                 }
2598
2599                 if(frametime)
2600                 {
2601                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2602                         player_powerups();
2603                 }
2604
2605                 if (self.deadflag != DEAD_NO)
2606                 {
2607                         float button_pressed, force_respawn;
2608                         if(self.personal && g_race_qualifying)
2609                         {
2610                                 if(time > self.death_time)
2611                                 {
2612                                         self.death_time = time + 1; // only retry once a second
2613                                         respawn();
2614                                         self.impulse = 141;
2615                                 }
2616                         }
2617                         else
2618                         {
2619                                 if(frametime)
2620                                         player_anim();
2621                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2622                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2623                                 if (self.deadflag == DEAD_DYING)
2624                                 {
2625                                         if(force_respawn)
2626                                                 self.deadflag = DEAD_RESPAWNING;
2627                                         else if(!button_pressed)
2628                                                 self.deadflag = DEAD_DEAD;
2629                                 }
2630                                 else if (self.deadflag == DEAD_DEAD)
2631                                 {
2632                                         if(button_pressed)
2633                                                 self.deadflag = DEAD_RESPAWNABLE;
2634                                 }
2635                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2636                                 {
2637                                         if(!button_pressed)
2638                                                 self.deadflag = DEAD_RESPAWNING;
2639                                 }
2640                                 else if (self.deadflag == DEAD_RESPAWNING)
2641                                 {
2642                                         if(time > self.death_time)
2643                                         {
2644                                                 self.death_time = time + 1; // only retry once a second
2645                                                 respawn();
2646                                         }
2647                                 }
2648                                 ShowRespawnCountdown();
2649                         }
2650                         return;
2651                 }
2652
2653                 if(g_touchexplode)
2654                 if(time > self.touchexplode_time)
2655                 if(self.classname == "player")
2656                 if(self.deadflag == DEAD_NO)
2657                 if not(IS_INDEPENDENT_PLAYER(self))
2658                 FOR_EACH_PLAYER(other) if(self != other)
2659                 {
2660                         if(time > other.touchexplode_time)
2661                         if(other.classname == "player")
2662                         if(other.deadflag == DEAD_NO)
2663                         if not(IS_INDEPENDENT_PLAYER(other))
2664                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2665                         {
2666                                 PlayerTouchExplode(self, other);
2667                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2668                         }
2669                 }
2670
2671                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2672                 {
2673                         vector dist;
2674
2675                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2676                         dist = self.prevorigin - self.origin;
2677                         dist_z = 0;
2678                         self.lms_traveled_distance += fabs(vlen(dist));
2679
2680                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2681                         {
2682                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2683                                 self.lms_traveled_distance = 0;
2684                         }
2685
2686                         if(time > self.lms_nextcheck)
2687                         {
2688                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2689                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2690                                 {
2691                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2692                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2693                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2694                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2695                                 }
2696                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2697                                 self.lms_traveled_distance = 0;
2698                         }
2699                 }
2700
2701                 self.prevorigin = self.origin;
2702
2703                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2704                 {
2705                         if (!self.crouch)
2706                         {
2707                                 self.crouch = TRUE;
2708                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2709                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2710                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2711                         }
2712                 }
2713                 else
2714                 {
2715                         if (self.crouch)
2716                         {
2717                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2718                                 if (!trace_startsolid)
2719                                 {
2720                                         self.crouch = FALSE;
2721                                         self.view_ofs = PL_VIEW_OFS;
2722                                         setsize (self, PL_MIN, PL_MAX);
2723                                 }
2724                         }
2725                 }
2726
2727                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2728                 {
2729                         if(self.bloodloss_timer < time)
2730                         {
2731                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2732                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2733                         }
2734                 }
2735
2736                 FixPlayermodel();
2737
2738                 GrapplingHookFrame();
2739
2740                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2741                 //if(frametime)
2742                 {
2743                         self.items &~= self.items_added;
2744
2745                         W_WeaponFrame();
2746
2747                         self.items_added = 0;
2748                         if(self.items & IT_JETPACK)
2749                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2750                                         self.items_added |= IT_FUEL;
2751
2752                         self.items |= self.items_added;
2753                 }
2754
2755                 player_regen();
2756                 if(frametime)
2757                         player_anim();
2758
2759                 if (g_minstagib)
2760                         minstagib_ammocheck();
2761
2762                 ctf_setstatus();
2763                 nexball_setstatus();
2764
2765                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2766
2767                 //self.angles_y=self.v_angle_y + 90;   // temp
2768         } else if(gameover) {
2769                 if (intermission_running)
2770                         IntermissionThink ();   // otherwise a button could be missed between
2771                 return;
2772         } else if(self.classname == "observer") {
2773                 ObserverThink();
2774         } else if(self.classname == "spectator") {
2775                 SpectatorThink();
2776         }
2777
2778         if(!zoomstate_set)
2779                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2780
2781         float oldspectatee_status;
2782         oldspectatee_status = self.spectatee_status;
2783         if(self.classname == "spectator")
2784                 self.spectatee_status = num_for_edict(self.enemy);
2785         else if(self.classname == "observer")
2786                 self.spectatee_status = num_for_edict(self);
2787         else
2788                 self.spectatee_status = 0;
2789         if(self.spectatee_status != oldspectatee_status)
2790         {
2791                 ClientData_Touch(self);
2792                 if(g_race || g_cts)
2793                         race_InitSpectator();
2794         }
2795
2796         if(self.teamkill_soundtime)
2797         if(time > self.teamkill_soundtime)
2798         {
2799                 self.teamkill_soundtime = 0;
2800
2801                 entity oldpusher, oldself;
2802
2803                 oldself = self; self = self.teamkill_soundsource;
2804                 oldpusher = self.pusher; self.pusher = oldself;
2805
2806                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2807
2808                 self.pusher = oldpusher;
2809                 self = oldself;
2810         }
2811
2812         if(self.taunt_soundtime)
2813         if(time > self.taunt_soundtime)
2814         {
2815                 self.taunt_soundtime = 0;
2816                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2817         }
2818
2819         target_voicescript_next(self);
2820 }
2821
2822 float isInvisibleString(string s)
2823 {
2824         float i, n, c;
2825         s = strdecolorize(s);
2826         for((i = 0), (n = strlen(s)); i < n; ++i)
2827         {
2828                 c = str2chr(s, i);
2829                 switch(c)
2830                 {
2831                         case 0:
2832                         case 32:
2833                         case 160:
2834                                 break;
2835                         default:
2836                                 return FALSE;
2837                 }
2838         }
2839         return TRUE;
2840 }
2841
2842 /*
2843 =============
2844 PlayerPostThink
2845
2846 Called every frame for each client after the physics are run
2847 =============
2848 */
2849 .float idlekick_lasttimeleft;
2850 .entity showheadshotbbox;
2851 void showheadshotbbox_think()
2852 {
2853         if(self.owner.showheadshotbbox != self)
2854         {
2855                 remove(self);
2856                 return;
2857         }
2858         self.nextthink = time;
2859         setorigin(self, self.owner.origin);
2860         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2861 }
2862 void PlayerPostThink (void)
2863 {
2864         // Savage: Check for nameless players
2865         if (isInvisibleString(self.netname)) {
2866                 self.netname = "Player";
2867                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2868         }
2869
2870         // send the clients accuracy stats to the client
2871         if(self.stat_count > 0)
2872         if(frametime)
2873         {
2874                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2875                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2876                 self.stat_count -= 1;
2877         }
2878
2879 #ifdef UID
2880         if(self.uid_kicktime)
2881         if(time > self.uid_kicktime)
2882         {
2883                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2884                 dropclient(self);
2885                 return;
2886         }
2887 #endif
2888
2889         if(sv_maxidle && frametime)
2890         {
2891                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2892                 float timeleft;
2893                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2894                 if(timeleft <= 0)
2895                 {
2896                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2897                         AnnounceTo(self, "terminated");
2898                         dropclient(self);
2899                         return;
2900                 }
2901                 else if(timeleft <= 10)
2902                 {
2903                         if(timeleft != self.idlekick_lasttimeleft)
2904                         {
2905                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2906                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2907                         }
2908                 }
2909                 else
2910                 {
2911                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2912                 }
2913                 self.idlekick_lasttimeleft = timeleft;
2914         }
2915
2916 #ifdef TETRIS
2917         if(self.impulse == 100)
2918                 ImpulseCommands();
2919         if (TetrisPostFrame())
2920                 return;
2921 #endif
2922
2923         CheatFrame();
2924
2925         if(self.classname == "player") {
2926                 CheckRules_Player();
2927                 UpdateChatBubble();
2928                 UpdateTeamBubble();
2929                 if (self.impulse)
2930                         ImpulseCommands();
2931                 if (intermission_running)
2932                         return;         // intermission or finale
2933                 GetPressedKeys();
2934         } else if (self.classname == "observer") {
2935                 //do nothing
2936         } else if (self.classname == "spectator") {
2937                 //do nothing
2938         }
2939
2940         /*
2941         float i;
2942         for(i = 0; i < 1000; ++i)
2943         {
2944                 vector end;
2945                 end = self.origin + '0 0 1024' + 512 * randomvec();
2946                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2947                 if(trace_fraction < 1)
2948                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2949                 {
2950                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2951                         break;
2952                 }
2953         }
2954         */
2955
2956         Arena_Warmup();
2957
2958         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2959
2960         if(self.waypointsprite_attachedforcarrier)
2961                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2962
2963         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
2964         {
2965                 if(!self.showheadshotbbox)
2966                 {
2967                         self.showheadshotbbox = spawn();
2968                         self.showheadshotbbox.classname = "headshotbbox";
2969                         self.showheadshotbbox.owner = self;
2970                         self.showheadshotbbox.think = showheadshotbbox_think;
2971                         self.showheadshotbbox.nextthink = time;
2972                         self = self.showheadshotbbox;
2973                         self.think();
2974                         self = self.owner;
2975                 }
2976         }
2977         else
2978         {
2979                 if(self.showheadshotbbox)
2980                         remove(self.showheadshotbbox);
2981         }
2982
2983         playerdemo_write();
2984
2985         /*
2986         if(g_race)
2987                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2988         */
2989 }