qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest < mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap();
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         if (g_minstagib)
 408                 minstagib_stop_countdown();
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419             vehicles_exit(VHEF_RELESE);
 420
 421         if(self.flagcarried)
 422                 DropFlag(self.flagcarried, world, world);
 423
 424         if(self.ballcarried && g_nexball)
 425                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 426
 427         WaypointSprite_PlayerDead();
 428
 429         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 430                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 431
 432         if(self.killcount != -666) {
 433                 if(g_lms) {
 434                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 435                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 436                         else
 437                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 438                 } else
 439                         bprint ("^4", self.netname, "^4 is spectating now\n");
 440
 441                 if(self.just_joined == FALSE) {
 442                         LogTeamchange(self.playerid, -1, 4);
 443                 } else
 444                         self.just_joined = FALSE;
 445         }
 446
 447         PlayerScore_Clear(self); // clear scores when needed
 448
 449         accuracy_resend(self);
 450
 451         self.spectatortime = time;
 452
 453         self.classname = "observer";
 454         self.iscreature = FALSE;
 455         self.damagedbycontents = FALSE;
 456         self.health = -666;
 457         self.takedamage = DAMAGE_NO;
 458         self.solid = SOLID_NOT;
 459         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 460         self.flags = FL_CLIENT | FL_NOTARGET;
 461         self.armorvalue = 666;
 462         self.effects = 0;
 463         self.armorvalue = autocvar_g_balance_armor_start;
 464         self.pauserotarmor_finished = 0;
 465         self.pauserothealth_finished = 0;
 466         self.pauseregen_finished = 0;
 467         self.damageforcescale = 0;
 468         self.death_time = 0;
 469         self.dead_frame = 0;
 470         self.alpha = 0;
 471         self.scale = 0;
 472         self.fade_time = 0;
 473         self.pain_frame = 0;
 474         self.pain_finished = 0;
 475         self.strength_finished = 0;
 476         self.invincible_finished = 0;
 477         self.pushltime = 0;
 478         self.think = SUB_Null;
 479         self.nextthink = 0;
 480         self.hook_time = 0;
 481         self.runes = 0;
 482         self.deadflag = DEAD_NO;
 483         self.angles = spot.angles;
 484         self.angles_z = 0;
 485         self.fixangle = TRUE;
 486         self.crouch = FALSE;
 487
 488         setorigin (self, spot.origin);
 489         self.prevorigin = self.origin;
 490         self.items = 0;
 491         self.weapons = 0;
 492         self.model = "";
 493         FixPlayermodel();
 494         setmodel(self, "null");
 495         self.drawonlytoclient = self;
 496
 497         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 498         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 499
 500         self.weapon = 0;
 501         self.weaponname = "";
 502         self.switchingweapon = 0;
 503         self.weaponmodel = "";
 504         self.weaponentity = world;
 505         self.exteriorweaponentity = world;
 506         self.killcount = -666;
 507         self.velocity = '0 0 0';
 508         self.avelocity = '0 0 0';
 509         self.punchangle = '0 0 0';
 510         self.punchvector = '0 0 0';
 511         self.oldvelocity = self.velocity;
 512         self.fire_endtime = -1;
 513
 514         if(g_arena)
 515         {
 516                 if(self.version_mismatch)
 517                 {
 518                         Spawnqueue_Unmark(self);
 519                         Spawnqueue_Remove(self);
 520                 }
 521                 else
 522                 {
 523                         Spawnqueue_Insert(self);
 524                 }
 525         }
 526         else if(g_lms)
 527         {
 528                 // Only if the player cannot play at all
 529                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 530                         self.frags = FRAGS_SPECTATOR;
 531                 else
 532                         self.frags = FRAGS_LMS_LOSER;
 533         }
 534         else if(g_ca)
 535         {
 536                 if(self.caplayer)
 537                         self.frags = FRAGS_LMS_LOSER;
 538                 else
 539                         self.frags = FRAGS_SPECTATOR;
 540         }
 541         else
 542                 self.frags = FRAGS_SPECTATOR;
 543 }
 544
 545 .float model_randomizer;
 546 void FixPlayermodel()
 547 {
 548         string defaultmodel;
 549         float defaultskin, chmdl, oldskin, n, i;
 550         vector m1, m2;
 551
 552         defaultmodel = "";
 553
 554         if(autocvar_sv_defaultcharacter == 1)
 555         {
 556                 defaultskin = 0;
 557
 558                 if(teamplay)
 559                 {
 560                         string s;
 561                         s = Team_ColorNameLowerCase(self.team);
 562                         if(s != "neutral")
 563                         {
 564                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 565                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 566                         }
 567                 }
 568
 569                 if(defaultmodel == "")
 570                 {
 571                         defaultmodel = autocvar_sv_defaultplayermodel;
 572                         defaultskin = autocvar_sv_defaultplayerskin;
 573                 }
 574
 575                 n = tokenize_console(defaultmodel);
 576                 if(n > 0)
 577                         defaultmodel = argv(floor(n * self.model_randomizer));
 578
 579                 i = strstrofs(defaultmodel, ":", 0);
 580                 if(i >= 0)
 581                 {
 582                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 583                         defaultmodel = substring(defaultmodel, 0, i);
 584                 }
 585         }
 586
 587         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 588         {
 589                 if(self.model != "")
 590                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 591                 self.model = ""; // force the != checks to return true
 592         }
 593
 594         if(defaultmodel != "")
 595         {
 596                 if (defaultmodel != self.model)
 597                 {
 598                         m1 = self.mins;
 599                         m2 = self.maxs;
 600                         setplayermodel (self, defaultmodel);
 601                         setsize (self, m1, m2);
 602                         chmdl = TRUE;
 603                 }
 604
 605                 oldskin = self.skin;
 606                 self.skin = defaultskin;
 607         } else {
 608                 if (self.playermodel != self.model || self.playermodel == "")
 609                 {
 610                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 611                         m1 = self.mins;
 612                         m2 = self.maxs;
 613                         setplayermodel (self, self.playermodel);
 614                         setsize (self, m1, m2);
 615                         chmdl = TRUE;
 616                 }
 617
 618                 oldskin = self.skin;
 619                 self.skin = stof(self.playerskin);
 620         }
 621
 622         if(chmdl || oldskin != self.skin)
 623                 self.species = player_getspecies(); // model or skin has changed
 624
 625         if(!teamplay)
 626                 if(strlen(autocvar_sv_defaultplayercolors))
 627                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 628                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 629 }
 630
 631 void PlayerTouchExplode(entity p1, entity p2)
 632 {
 633         vector org;
 634         org = (p1.origin + p2.origin) * 0.5;
 635         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 636
 637         te_explosion(org);
 638
 639         entity e;
 640         e = spawn();
 641         setorigin(e, org);
 642         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 643         remove(e);
 644 }
 645
 646 /*
 647 =============
 648 PutClientInServer
 649
 650 Called when a client spawns in the server
 651 =============
 652 */
 653 //void() ctf_playerchanged;
 654 void PutClientInServer (void)
 655 {
 656         if(clienttype(self) == CLIENTTYPE_BOT)
 657         {
 658                 self.classname = "player";
 659         }
 660         else if(clienttype(self) == CLIENTTYPE_REAL)
 661         {
 662                 msg_entity = self;
 663                 WriteByte(MSG_ONE, SVC_SETVIEW);
 664                 WriteEntity(MSG_ONE, self);
 665         }
 666
 667         // reset player keys
 668         self.itemkeys = 0;
 669
 670         // player is dead and becomes observer
 671         // FIXME fix LMS scoring for new system
 672         if(g_lms)
 673         {
 674                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 675                         self.classname = "observer";
 676         }
 677
 678         if(g_arena || (g_ca && !allowed_to_spawn))
 679         if(!self.spawned)
 680                 self.classname = "observer";
 681
 682         if(gameover)
 683                 self.classname = "observer";
 684
 685         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 686                 entity spot, oldself;
 687                 float j;
 688
 689                 accuracy_resend(self);
 690
 691                 if(self.team < 0)
 692                         JoinBestTeam(self, FALSE, TRUE);
 693
 694                 race_PreSpawn();
 695
 696                 spot = SelectSpawnPoint (FALSE);
 697                 if(!spot)
 698                 {
 699                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 700                         return; // spawn failed
 701                 }
 702
 703                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 704
 705                 self.classname = "player";
 706                 self.wasplayer = TRUE;
 707                 self.iscreature = TRUE;
 708                 self.damagedbycontents = TRUE;
 709                 self.movetype = MOVETYPE_WALK;
 710                 self.solid = SOLID_SLIDEBOX;
 711                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 712                 if(autocvar_g_playerclip_collisions)
 713                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 714                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 715                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 716                 self.frags = FRAGS_PLAYER;
 717                 if(INDEPENDENT_PLAYERS)
 718                         MAKE_INDEPENDENT_PLAYER(self);
 719                 self.flags = FL_CLIENT;
 720                 if(autocvar__notarget)
 721                         self.flags |= FL_NOTARGET;
 722                 self.takedamage = DAMAGE_AIM;
 723                 if(g_minstagib)
 724                         self.effects = EF_FULLBRIGHT;
 725                 else
 726                         self.effects = 0;
 727                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 728                 self.air_finished = time + 12;
 729                 self.dmg = 2;
 730                 if(autocvar_g_balance_nex_charge)
 731                 {
 732                         if(autocvar_g_balance_nex_secondary_chargepool)
 733                                 self.nex_chargepool_ammo = 1;
 734                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 735                 }
 736
 737                 if(inWarmupStage)
 738                 {
 739                         self.ammo_shells = warmup_start_ammo_shells;
 740                         self.ammo_nails = warmup_start_ammo_nails;
 741                         self.ammo_rockets = warmup_start_ammo_rockets;
 742                         self.ammo_cells = warmup_start_ammo_cells;
 743                         self.ammo_fuel = warmup_start_ammo_fuel;
 744                         self.health = warmup_start_health;
 745                         self.armorvalue = warmup_start_armorvalue;
 746                         self.weapons = warmup_start_weapons;
 747                 }
 748                 else
 749                 {
 750                         self.ammo_shells = start_ammo_shells;
 751                         self.ammo_nails = start_ammo_nails;
 752                         self.ammo_rockets = start_ammo_rockets;
 753                         self.ammo_cells = start_ammo_cells;
 754                         self.ammo_fuel = start_ammo_fuel;
 755                         self.health = start_health;
 756                         self.armorvalue = start_armorvalue;
 757                         self.weapons = start_weapons;
 758                 }
 759
 760                 if(g_weaponarena_random)
 761                 {
 762                         if(g_weaponarena_random_with_laser)
 763                                 self.weapons &~= WEPBIT_LASER;
 764                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 765                         if(g_weaponarena_random_with_laser)
 766                                 self.weapons |= WEPBIT_LASER;
 767                 }
 768
 769                 self.items = start_items;
 770                 self.jump_interval = time;
 771
 772                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 773                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 774                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 775                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 776                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 777                 //extend the pause of rotting if client was reset at the beginning of the countdown
 778                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 779                         self.spawnshieldtime += game_starttime - time;
 780                         self.pauserotarmor_finished += game_starttime - time;
 781                         self.pauserothealth_finished += game_starttime - time;
 782                         self.pauseregen_finished += game_starttime - time;
 783                 }
 784                 self.damageforcescale = 2;
 785                 self.death_time = 0;
 786                 self.dead_frame = 0;
 787                 self.alpha = 0;
 788                 self.scale = 0;
 789                 self.fade_time = 0;
 790                 self.pain_frame = 0;
 791                 self.pain_finished = 0;
 792                 self.strength_finished = 0;
 793                 self.invincible_finished = 0;
 794                 self.pushltime = 0;
 795                 // players have no think function
 796                 self.think = SUB_Null;
 797                 self.nextthink = 0;
 798                 self.hook_time = 0;
 799                 self.dmg_team = 0;
 800                 self.ballistics_density = autocvar_g_ballistics_density_player;
 801
 802                 self.metertime = 0;
 803
 804                 self.runes = 0;
 805
 806                 self.deadflag = DEAD_NO;
 807
 808                 self.angles = spot.angles;
 809
 810                 self.angles_z = 0; // never spawn tilted even if the spot says to
 811                 self.fixangle = TRUE; // turn this way immediately
 812                 self.velocity = '0 0 0';
 813                 self.avelocity = '0 0 0';
 814                 self.punchangle = '0 0 0';
 815                 self.punchvector = '0 0 0';
 816                 self.oldvelocity = self.velocity;
 817                 self.fire_endtime = -1;
 818
 819                 msg_entity = self;
 820                 WRITESPECTATABLE_MSG_ONE({
 821                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 822                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 823                 });
 824
 825                 self.model = "";
 826                 FixPlayermodel();
 827                 self.drawonlytoclient = world;
 828
 829                 self.crouch = FALSE;
 830                 self.view_ofs = PL_VIEW_OFS;
 831                 setsize (self, PL_MIN, PL_MAX);
 832                 self.spawnorigin = spot.origin;
 833                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 834                 // don't reset back to last position, even if new position is stuck in solid
 835                 self.oldorigin = self.origin;
 836                 self.prevorigin = self.origin;
 837                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 838                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 839         self.hud = HUD_NORMAL;
 840
 841                 if(g_arena)
 842                 {
 843                         Spawnqueue_Remove(self);
 844                         Spawnqueue_Mark(self);
 845                 }
 846
 847                 else if(g_ca)
 848                         self.caplayer = 1;
 849
 850                 self.event_damage = PlayerDamage;
 851
 852                 self.bot_attack = TRUE;
 853
 854                 self.statdraintime = time + 5;
 855                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 856
 857                 if(self.killcount == -666) {
 858                         PlayerScore_Clear(self);
 859                         self.killcount = 0;
 860                 }
 861
 862                 CL_SpawnWeaponentity();
 863                 self.alpha = default_player_alpha;
 864                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 865                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 866
 867                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 868                 self.lms_traveled_distance = 0;
 869                 self.speedrunning = FALSE;
 870
 871                 race_PostSpawn(spot);
 872
 873                 //stuffcmd(self, "chase_active 0");
 874                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 875
 876                 if (autocvar_g_spawnsound)
 877                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 878
 879                 if(g_assault) {
 880                         if(self.team == assault_attacker_team)
 881                                 centerprint(self, "You are attacking!");
 882                         else
 883                                 centerprint(self, "You are defending!");
 884                 }
 885
 886                 target_voicescript_clear(self);
 887
 888                 // reset fields the weapons may use
 889                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 890                 {
 891                         weapon_action(j, WR_RESETPLAYER);
 892
 893                         // all weapons must be fully loaded when we spawn
 894                         entity e;
 895                         e = get_weaponinfo(j);
 896                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 897                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 898                 }
 899
 900                 oldself = self;
 901                 self = spot;
 902                         activator = oldself;
 903                                 string s;
 904                                 s = self.target;
 905                                 self.target = string_null;
 906                                 SUB_UseTargets();
 907                                 self.target = s;
 908                         activator = world;
 909                 self = oldself;
 910
 911                 spawn_spot = spot;
 912                 MUTATOR_CALLHOOK(PlayerSpawn);
 913
 914                 if(autocvar_spawn_debug)
 915                 {
 916                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 917                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 918                 }
 919
 920                 self.switchweapon = w_getbestweapon(self);
 921                 self.cnt = -1; // W_LastWeapon will not complain
 922                 self.weapon = 0;
 923                 self.weaponname = "";
 924                 self.switchingweapon = 0;
 925
 926                 if(!self.alivetime)
 927                         self.alivetime = time;
 928         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
 929                 PutObserverInServer ();
 930         }
 931
 932         //if(g_ctf)
 933         //      ctf_playerchanged();
 934 }
 935
 936 .float ebouncefactor, ebouncestop; // electro's values
 937 // TODO do we need all these fields, or should we stop autodetecting runtime
 938 // changes and just have a console command to update this?
 939 float ClientInit_SendEntity(entity to, float sf)
 940 {
 941         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 942         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 951         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 952         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 953         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 954         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 955         if(sv_foginterval && world.fog != "")
 956                 WriteString(MSG_ENTITY, world.fog);
 957         else
 958                 WriteString(MSG_ENTITY, "");
 959         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 960         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 961         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 962         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 963         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 964         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 965         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 966         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 967         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 968         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 969         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 970         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 971         return TRUE;
 972 }
 973
 974 void ClientInit_CheckUpdate()
 975 {
 976         self.nextthink = time;
 977         if(self.count != autocvar_g_balance_armor_blockpercent)
 978         {
 979                 self.count = autocvar_g_balance_armor_blockpercent;
 980                 self.SendFlags |= 1;
 981         }
 982         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 983         {
 984                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 985                 self.SendFlags |= 1;
 986         }
 987         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 988         {
 989                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 990                 self.SendFlags |= 1;
 991         }
 992         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 993         {
 994                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 995                 self.SendFlags |= 1;
 996         }
 997         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 998         {
 999                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1000                 self.SendFlags |= 1;
1001         }
1002         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1003         {
1004                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1005                 self.SendFlags |= 1;
1006         }
1007 }
1008
1009 void ClientInit_Spawn()
1010 {
1011         entity o;
1012         entity e;
1013         e = spawn();
1014         e.classname = "clientinit";
1015         e.think = ClientInit_CheckUpdate;
1016         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1017
1018         o = self;
1019         self = e;
1020         ClientInit_CheckUpdate();
1021         self = o;
1022 }
1023
1024 /*
1025 =============
1026 SetNewParms
1027 =============
1028 */
1029 void SetNewParms (void)
1030 {
1031         // initialize parms for a new player
1032         parm1 = -(86400 * 366);
1033 }
1034
1035 /*
1036 =============
1037 SetChangeParms
1038 =============
1039 */
1040 void SetChangeParms (void)
1041 {
1042         // save parms for level change
1043         parm1 = self.parm_idlesince - time;
1044 }
1045
1046 /*
1047 =============
1048 DecodeLevelParms
1049 =============
1050 */
1051 void DecodeLevelParms (void)
1052 {
1053         // load parms
1054         self.parm_idlesince = parm1;
1055         if(self.parm_idlesince == -(86400 * 366))
1056                 self.parm_idlesince = time;
1057
1058         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1059         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1060 }
1061
1062 /*
1063 =============
1064 ClientKill
1065
1066 Called when a client types 'kill' in the console
1067 =============
1068 */
1069
1070 .float clientkill_nexttime;
1071 void ClientKill_Now_TeamChange()
1072 {
1073         if(self.killindicator_teamchange == -1)
1074         {
1075                 self.team = -1;
1076                 JoinBestTeam( self, FALSE, FALSE );
1077         }
1078         else if(self.killindicator_teamchange == -2)
1079         {
1080                 if(g_ca)
1081                         self.caplayer = 0;
1082                 if(blockSpectators)
1083                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1084                 PutObserverInServer();
1085         }
1086         else
1087                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1088 }
1089
1090 void ClientKill_Now()
1091 {
1092         if(self.vehicle)
1093         {
1094             vehicles_exit(VHEF_RELESE);
1095             if(!self.killindicator_teamchange)
1096             {
1097             self.vehicle_health = -1;
1098             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1099             }
1100         }
1101
1102         if(self.killindicator && !wasfreed(self.killindicator))
1103                 remove(self.killindicator);
1104
1105         self.killindicator = world;
1106
1107         if(self.killindicator_teamchange)
1108                 ClientKill_Now_TeamChange();
1109
1110         // in any case:
1111         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1112
1113         // now I am sure the player IS dead
1114 }
1115 void KillIndicator_Think()
1116 {
1117         if (gameover)
1118         {
1119                 self.owner.killindicator = world;
1120                 remove(self);
1121                 return;
1122         }
1123
1124         if (!self.owner.modelindex)
1125         {
1126                 self.owner.killindicator = world;
1127                 remove(self);
1128                 return;
1129         }
1130
1131         if(self.cnt <= 0)
1132         {
1133                 self = self.owner;
1134                 ClientKill_Now(); // no oldself needed
1135                 return;
1136         }
1137     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1138     {
1139         self.nextthink = time + 1;
1140         self.cnt -= 1;
1141     }
1142         else
1143         {
1144                 if(self.cnt <= 10)
1145                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1146                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1147                 {
1148                         if(self.cnt <= 10)
1149                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1150                 }
1151                 self.nextthink = time + 1;
1152                 self.cnt -= 1;
1153         }
1154 }
1155
1156 float clientkilltime;
1157 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1158 {
1159         float killtime;
1160         float starttime;
1161         entity e;
1162
1163         if (gameover)
1164                 return;
1165
1166         killtime = autocvar_g_balance_kill_delay;
1167
1168         if(g_race_qualifying || g_cts)
1169                 killtime = 0;
1170
1171     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1172     {
1173                 remove(self.killindicator);
1174                 self.killindicator = world;
1175
1176         ClientKill_Now(); // allow instant kill in this case
1177         return;
1178     }
1179
1180         self.killindicator_teamchange = targetteam;
1181
1182     if(!self.killindicator)
1183         {
1184                 if(self.modelindex && self.deadflag == DEAD_NO)
1185                 {
1186                         killtime = max(killtime, self.clientkill_nexttime - time);
1187                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1188                 }
1189
1190                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1191                 {
1192                         ClientKill_Now();
1193                 }
1194                 else
1195                 {
1196                         starttime = max(time, clientkilltime);
1197
1198                         self.killindicator = spawn();
1199                         self.killindicator.owner = self;
1200                         self.killindicator.scale = 0.5;
1201                         setattachment(self.killindicator, self, "");
1202                         setorigin(self.killindicator, '0 0 52');
1203                         self.killindicator.think = KillIndicator_Think;
1204                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1205                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1206                         self.killindicator.cnt = ceil(killtime);
1207                         self.killindicator.count = bound(0, ceil(killtime), 10);
1208                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1209
1210                         for(e = world; (e = find(e, classname, "body")) != world; )
1211                         {
1212                                 if(e.enemy != self)
1213                                         continue;
1214                                 e.killindicator = spawn();
1215                                 e.killindicator.owner = e;
1216                                 e.killindicator.scale = 0.5;
1217                                 setattachment(e.killindicator, e, "");
1218                                 setorigin(e.killindicator, '0 0 52');
1219                                 e.killindicator.think = KillIndicator_Think;
1220                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1221                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1222                                 e.killindicator.cnt = ceil(killtime);
1223                         }
1224                         self.lip = 0;
1225                 }
1226         }
1227         if(self.killindicator)
1228         {
1229                 if(targetteam == 0) // just die
1230                 {
1231                         self.killindicator.colormod = '0 0 0';
1232                         if(clienttype(self) == CLIENTTYPE_REAL)
1233                         if(self.killindicator.cnt > 0)
1234                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1235                 }
1236                 else if(targetteam == -1) // auto
1237                 {
1238                         self.killindicator.colormod = '0 1 0';
1239                         if(clienttype(self) == CLIENTTYPE_REAL)
1240                         if(self.killindicator.cnt > 0)
1241                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1242                 }
1243                 else if(targetteam == -2) // spectate
1244                 {
1245                         self.killindicator.colormod = '0.5 0.5 0.5';
1246                         if(clienttype(self) == CLIENTTYPE_REAL)
1247                         if(self.killindicator.cnt > 0)
1248                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1249                 }
1250                 else
1251                 {
1252                         self.killindicator.colormod = TeamColor(targetteam);
1253                         if(clienttype(self) == CLIENTTYPE_REAL)
1254                         if(self.killindicator.cnt > 0)
1255                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1256                 }
1257         }
1258
1259 }
1260
1261 void ClientKill (void)
1262 {
1263         if (gameover)
1264                 return;
1265
1266         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1267         {
1268                 // do nothing
1269         }
1270     else if(self.freezetag_frozen)
1271     {
1272         // do nothing
1273     }
1274         else
1275                 ClientKill_TeamChange(0);
1276 }
1277
1278 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1279 {
1280     e.killindicator = spawn();
1281     e.killindicator.owner = e;
1282     e.killindicator.think = KillIndicator_Think;
1283     e.killindicator.nextthink = time + (e.lip) * 0.05;
1284     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1285     e.killindicator.health = 1; // this is used to indicate that it should be silent
1286     e.lip = 0;
1287 }
1288
1289 void FixClientCvars(entity e)
1290 {
1291         // send prediction settings to the client
1292         stuffcmd(e, "\nin_bindmap 0 0\n");
1293         if(g_race || g_cts)
1294                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1295         if(autocvar_g_antilag == 3) // client side hitscan
1296                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1297         if(sv_gentle)
1298                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1299         /*
1300          * we no longer need to stuff this. Remove this comment block if you feel
1301          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1302         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1303         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1304         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1305         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1306         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1307         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1308         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1309         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1310         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1311         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1312         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1313         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1314         stuffcmd(e, "cl_movement_edgefriction 1\n");
1315          */
1316 }
1317
1318 float PlayerInIDList(entity p, string idlist)
1319 {
1320         float n, i;
1321         string s;
1322
1323         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1324         if not(p.crypto_idfp)
1325                 return 0;
1326
1327         // this function allows abbreviated player IDs too!
1328         n = tokenize_console(idlist);
1329         for(i = 0; i < n; ++i)
1330         {
1331                 s = argv(i);
1332                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1333                         return 1;
1334         }
1335
1336         return 0;
1337 }
1338
1339 /*
1340 =============
1341 ClientConnect
1342
1343 Called when a client connects to the server
1344 =============
1345 */
1346 //void ctf_clientconnect();
1347 string ColoredTeamName(float t);
1348 void DecodeLevelParms (void);
1349 //void dom_player_join_team(entity pl);
1350 void set_dom_state(entity e);
1351 void ClientConnect (void)
1352 {
1353         float t;
1354
1355         if(self.flags & FL_CLIENT)
1356         {
1357                 print("Warning: ClientConnect, but already connected!\n");
1358                 return;
1359         }
1360
1361         if(Ban_MaybeEnforceBan(self))
1362                 return;
1363
1364         DecodeLevelParms();
1365
1366 #ifdef WATERMARK
1367         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1368 #endif
1369
1370         self.classname = "player_joining";
1371
1372         self.flags = FL_CLIENT;
1373         self.version_nagtime = time + 10 + random() * 10;
1374
1375         if(player_count<0)
1376         {
1377                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1378                 player_count = 0;
1379         }
1380
1381         PlayerScore_Attach(self);
1382         ClientData_Attach();
1383         accuracy_init(self);
1384
1385         bot_clientconnect();
1386
1387         playerdemo_init();
1388
1389         anticheat_init();
1390
1391         race_PreSpawnObserver();
1392
1393         //if(g_domination)
1394         //      dom_player_join_team(self);
1395
1396         // identify the right forced team
1397         if(autocvar_g_campaign)
1398         {
1399                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1400                 {
1401                         switch(autocvar_g_campaign_forceteam)
1402                         {
1403                                 case 1: self.team_forced = COLOR_TEAM1; break;
1404                                 case 2: self.team_forced = COLOR_TEAM2; break;
1405                                 case 3: self.team_forced = COLOR_TEAM3; break;
1406                                 case 4: self.team_forced = COLOR_TEAM4; break;
1407                                 default: self.team_forced = 0;
1408                         }
1409                 }
1410         }
1411         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1412                 self.team_forced = COLOR_TEAM1;
1413         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1414                 self.team_forced = COLOR_TEAM2;
1415         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1416                 self.team_forced = COLOR_TEAM3;
1417         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1418                 self.team_forced = COLOR_TEAM4;
1419         else if(autocvar_g_forced_team_otherwise == "red")
1420                 self.team_forced = COLOR_TEAM1;
1421         else if(autocvar_g_forced_team_otherwise == "blue")
1422                 self.team_forced = COLOR_TEAM2;
1423         else if(autocvar_g_forced_team_otherwise == "yellow")
1424                 self.team_forced = COLOR_TEAM3;
1425         else if(autocvar_g_forced_team_otherwise == "pink")
1426                 self.team_forced = COLOR_TEAM4;
1427         else if(autocvar_g_forced_team_otherwise == "spectate")
1428                 self.team_forced = -1;
1429         else if(autocvar_g_forced_team_otherwise == "spectator")
1430                 self.team_forced = -1;
1431         else
1432                 self.team_forced = 0;
1433
1434         if(!teamplay)
1435                 if(self.team_forced > 0)
1436                         self.team_forced = 0;
1437
1438         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1439
1440         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1441                 self.classname = "observer";
1442         } else {
1443                 if(teamplay)
1444                 {
1445                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1446                         {
1447                                 self.classname = "player";
1448                                 campaign_bots_may_start = 1;
1449                         }
1450                         else
1451                         {
1452                                 self.classname = "observer"; // do it anyway
1453                         }
1454                 }
1455                 else
1456                 {
1457                         self.classname = "player";
1458                         campaign_bots_may_start = 1;
1459                 }
1460         }
1461
1462         self.playerid = (playerid_last = playerid_last + 1);
1463
1464         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1465
1466     if(clienttype(self) == CLIENTTYPE_BOT)
1467         PlayerStats_AddPlayer(self);
1468
1469         if(autocvar_sv_eventlog)
1470                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1471
1472         LogTeamchange(self.playerid, self.team, 1);
1473
1474         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1475
1476         self.netname_previous = strzone(self.netname);
1477
1478         bprint("^4", self.netname, "^4 connected");
1479
1480         if(self.classname != "observer" && (g_domination || g_ctf))
1481                 bprint(" and joined the ", ColoredTeamName(self.team));
1482
1483         bprint("\n");
1484
1485         stuffcmd(self, strcat(clientstuff, "\n"));
1486         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1487
1488         FixClientCvars(self);
1489
1490         // spawnfunc_waypoint sprites
1491         WaypointSprite_InitClient(self);
1492
1493         // Wazat's grappling hook
1494         SetGrappleHookBindings();
1495
1496         // get version info from player
1497         stuffcmd(self, "cmd clientversion $gameversion\n");
1498
1499         // get other cvars from player
1500         GetCvars(0);
1501
1502         // notify about available teams
1503         if(teamplay)
1504         {
1505                 CheckAllowedTeams(self);
1506                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1507                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1508         }
1509         else
1510                 stuffcmd(self, "set _teams_available 0\n");
1511
1512         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1513
1514         if(g_arena || g_ca)
1515         {
1516                 self.classname = "observer";
1517                 if(g_arena)
1518                         Spawnqueue_Insert(self);
1519         }
1520         /*else if(g_ctf)
1521         {
1522                 ctf_clientconnect();
1523         }*/
1524
1525         attach_entcs();
1526
1527         bot_relinkplayerlist();
1528
1529         self.spectatortime = time;
1530         if(blockSpectators)
1531         {
1532                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1533         }
1534
1535         self.jointime = time;
1536         self.allowedTimeouts = autocvar_sv_timeout_number;
1537
1538         if(clienttype(self) == CLIENTTYPE_REAL)
1539         {
1540                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1541                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1542         }
1543
1544         if(g_lms)
1545         {
1546                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1547                 {
1548                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1549                         self.frags = FRAGS_SPECTATOR;
1550                 }
1551         }
1552
1553         if(!sv_foginterval && world.fog != "")
1554                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1555
1556         SoundEntity_Attach(self);
1557
1558         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1559         {
1560                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1561                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1562         }
1563         else
1564                 self.hitplotfh = -1;
1565
1566         if(g_race || g_cts) {
1567                 string rr;
1568                 if(g_cts)
1569                         rr = CTS_RECORD;
1570                 else
1571                         rr = RACE_RECORD;
1572                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1573
1574                 msg_entity = self;
1575                 race_send_recordtime(MSG_ONE);
1576                 race_send_speedaward(MSG_ONE);
1577
1578                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1579                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1580                 race_send_speedaward_alltimebest(MSG_ONE);
1581
1582                 float i;
1583                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1584                         race_SendRankings(i, 0, 0, MSG_ONE);
1585                 }
1586         }
1587         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1588                 send_CSQC_teamnagger();
1589
1590         if (g_domination)
1591                 set_dom_state(self);
1592
1593         CheatInitClient();
1594
1595         if(!autocvar_g_campaign)
1596                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1597
1598         CSQCMODEL_AUTOINIT();
1599
1600         self.model_randomizer = random();
1601 }
1602
1603 /*
1604 =============
1605 ClientDisconnect
1606
1607 Called when a client disconnects from the server
1608 =============
1609 */
1610 .entity chatbubbleentity;
1611 void ReadyCount();
1612 void ClientDisconnect (void)
1613 {
1614         if(self.vehicle)
1615             vehicles_exit(VHEF_RELESE);
1616
1617         if not(self.flags & FL_CLIENT)
1618         {
1619                 print("Warning: ClientDisconnect without ClientConnect\n");
1620                 return;
1621         }
1622
1623         PlayerStats_AddGlobalInfo(self);
1624
1625         CheatShutdownClient();
1626
1627         if(self.hitplotfh >= 0)
1628         {
1629                 fclose(self.hitplotfh);
1630                 self.hitplotfh = -1;
1631         }
1632
1633         anticheat_report();
1634         anticheat_shutdown();
1635
1636         playerdemo_shutdown();
1637
1638         bot_clientdisconnect();
1639
1640         if(self.entcs)
1641                 detach_entcs();
1642
1643         if(autocvar_sv_eventlog)
1644                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1645         bprint ("^4",self.netname);
1646         bprint ("^4 disconnected\n");
1647
1648         SoundEntity_Detach(self);
1649
1650         DropAllRunes(self);
1651         MUTATOR_CALLHOOK(ClientDisconnect);
1652
1653         Portal_ClearAll(self);
1654
1655         RemoveGrapplingHook(self);
1656         if(self.flagcarried)
1657                 DropFlag(self.flagcarried, world, world);
1658         if(self.ballcarried && g_nexball)
1659                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1660
1661         // Here, everything has been done that requires this player to be a client.
1662
1663         self.flags &~= FL_CLIENT;
1664
1665         if (self.chatbubbleentity)
1666                 remove (self.chatbubbleentity);
1667
1668         if (self.killindicator)
1669                 remove (self.killindicator);
1670
1671         WaypointSprite_PlayerGone();
1672
1673         bot_relinkplayerlist();
1674
1675         if(g_arena)
1676         {
1677                 Spawnqueue_Unmark(self);
1678                 Spawnqueue_Remove(self);
1679         }
1680
1681         accuracy_free(self);
1682         ClientData_Detach();
1683         PlayerScore_Detach(self);
1684
1685         if(self.netname_previous)
1686                 strunzone(self.netname_previous);
1687         if(self.clientstatus)
1688                 strunzone(self.clientstatus);
1689         if(self.weaponorder_byimpulse)
1690                 strunzone(self.weaponorder_byimpulse);
1691
1692         ClearPlayerSounds();
1693
1694         if(self.personal)
1695                 remove(self.personal);
1696
1697         self.playerid = 0;
1698         ReadyCount();
1699
1700         // free cvars
1701         GetCvars(-1);
1702 }
1703
1704 .float BUTTON_CHAT;
1705 void ChatBubbleThink()
1706 {
1707         self.nextthink = time;
1708         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1709         {
1710                 if(self.owner) // but why can that ever be world?
1711                         self.owner.chatbubbleentity = world;
1712                 remove(self);
1713                 return;
1714         }
1715         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1716 #ifdef TETRIS
1717                 || self.owner.tetris_on
1718 #endif
1719         )
1720                 self.model = self.mdl;
1721         else
1722                 self.model = "";
1723 }
1724
1725 void UpdateChatBubble()
1726 {
1727         if (!self.modelindex)
1728                 return;
1729         // spawn a chatbubble entity if needed
1730         if (!self.chatbubbleentity)
1731         {
1732                 self.chatbubbleentity = spawn();
1733                 self.chatbubbleentity.owner = self;
1734                 self.chatbubbleentity.exteriormodeltoclient = self;
1735                 self.chatbubbleentity.think = ChatBubbleThink;
1736                 self.chatbubbleentity.nextthink = time;
1737                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1738                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1739                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1740                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1741                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1742                 self.chatbubbleentity.model = "";
1743                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1744         }
1745 }
1746
1747
1748 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1749 // added to the model skins
1750 /*void UpdateColorModHack()
1751 {
1752         float c;
1753         c = self.clientcolors & 15;
1754         // LordHavoc: only bothering to support white, green, red, yellow, blue
1755              if (!teamplay) self.colormod = '0 0 0';
1756         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1757         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1758         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1759         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1760         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1761         else self.colormod = '1 1 1';
1762 }*/
1763
1764 .float oldcolormap;
1765 void respawn(void)
1766 {
1767         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1768         {
1769                 self.solid = SOLID_NOT;
1770                 self.takedamage = DAMAGE_NO;
1771                 self.movetype = MOVETYPE_FLY;
1772                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1773                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1774                 self.effects |= EF_ADDITIVE;
1775                 self.oldcolormap = self.colormap;
1776                 self.colormap = 0; // this originally was 512, but raises a warning in the engine, so get rid of it
1777                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1778                 if(autocvar_g_respawn_ghosts_maxtime)
1779                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1780         }
1781
1782         CopyBody(1);
1783         self.effects |= EF_NODRAW; // prevent another CopyBody
1784         if(self.oldcolormap)
1785         {
1786                 self.colormap = self.oldcolormap;
1787                 self.oldcolormap = 0;
1788         }
1789         PutClientInServer();
1790 }
1791
1792 void play_countdown(float finished, string samp)
1793 {
1794         if(clienttype(self) == CLIENTTYPE_REAL)
1795                 if(floor(finished - time - frametime) != floor(finished - time))
1796                         if(finished - time < 6)
1797                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1798 }
1799
1800 void player_powerups (void)
1801 {
1802         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1803         olditems = self.items;
1804
1805         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1806         {
1807                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1808                 self.modelflags |= MF_ROCKET;
1809         }
1810         else
1811         {
1812                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1813                 self.modelflags &~= MF_ROCKET;
1814         }
1815
1816         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1817
1818         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1819                 return;
1820
1821         Fire_ApplyDamage(self);
1822         Fire_ApplyEffect(self);
1823
1824         if (g_minstagib)
1825         {
1826                 self.effects |= EF_FULLBRIGHT;
1827
1828                 if (self.items & IT_STRENGTH)
1829                 {
1830                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1831                         if (time > self.strength_finished)
1832                         {
1833                                 self.alpha = default_player_alpha;
1834                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1835                                 self.items &~= IT_STRENGTH;
1836                                 sprint(self, "^3Invisibility has worn off\n");
1837                         }
1838                 }
1839                 else
1840                 {
1841                         if (time < self.strength_finished)
1842                         {
1843                                 self.alpha = g_minstagib_invis_alpha;
1844                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1845                                 self.items |= IT_STRENGTH;
1846                                 sprint(self, "^3You are invisible\n");
1847                         }
1848                 }
1849
1850                 if (self.items & IT_INVINCIBLE)
1851                 {
1852                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1853                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
1854                         {
1855                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1856                                 sprint(self, "^3Speed has worn off\n");
1857                         }
1858                 }
1859                 else
1860                 {
1861                         if (time < self.invincible_finished)
1862                         {
1863                                 self.items = self.items | IT_INVINCIBLE;
1864                                 sprint(self, "^3You are on speed\n");
1865                         }
1866                 }
1867         }
1868         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1869         {
1870                 if (self.items & IT_STRENGTH)
1871                 {
1872                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1873                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1874                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
1875                         {
1876                                 self.items = self.items - (self.items & IT_STRENGTH);
1877                                 sprint(self, "^3Strength has worn off\n");
1878                         }
1879                 }
1880                 else
1881                 {
1882                         if (time < self.strength_finished)
1883                         {
1884                                 self.items = self.items | IT_STRENGTH;
1885                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1886                         }
1887                 }
1888                 if (self.items & IT_INVINCIBLE)
1889                 {
1890                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1891                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1892                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
1893                         {
1894                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1895                                 sprint(self, "^3Shield has worn off\n");
1896                         }
1897                 }
1898                 else
1899                 {
1900                         if (time < self.invincible_finished)
1901                         {
1902                                 self.items = self.items | IT_INVINCIBLE;
1903                                 sprint(self, "^3Shield surrounds you\n");
1904                         }
1905                 }
1906
1907                 if(autocvar_g_nodepthtestplayers)
1908                         self.effects = self.effects | EF_NODEPTHTEST;
1909
1910                 if(autocvar_g_fullbrightplayers)
1911                         self.effects = self.effects | EF_FULLBRIGHT;
1912
1913                 // midair gamemode: damage only while in the air
1914                 // if in midair mode, being on ground grants temporary invulnerability
1915                 // (this is so that multishot weapon don't clear the ground flag on the
1916                 // first damage in the frame, leaving the player vulnerable to the
1917                 // remaining hits in the same frame)
1918                 if (self.flags & FL_ONGROUND)
1919                 if (g_midair)
1920                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1921
1922                 if (time >= game_starttime)
1923                 if (time < self.spawnshieldtime)
1924                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1925         }
1926
1927         MUTATOR_CALLHOOK(PlayerPowerups);
1928 }
1929
1930 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1931 {
1932         if(current > stable)
1933                 return current;
1934         else if(current > stable - 0.25) // when close enough, "snap"
1935                 return stable;
1936         else
1937                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1938 }
1939
1940 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1941 {
1942         if(current < stable)
1943                 return current;
1944         else if(current < stable + 0.25) // when close enough, "snap"
1945                 return stable;
1946         else
1947                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1948 }
1949
1950 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1951 {
1952         if(current > rotstable)
1953         {
1954                 if(rotframetime > 0)
1955                 {
1956                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1957                         current = max(rotstable, current - rotlinear * rotframetime);
1958                 }
1959         }
1960         else if(current < regenstable)
1961         {
1962                 if(regenframetime > 0)
1963                 {
1964                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1965                         current = min(regenstable, current + regenlinear * regenframetime);
1966                 }
1967         }
1968
1969         if(current > limit)
1970                 current = limit;
1971
1972         return current;
1973 }
1974
1975 void player_regen (void)
1976 {
1977         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1978         maxh = autocvar_g_balance_health_rotstable;
1979         maxa = autocvar_g_balance_armor_rotstable;
1980         maxf = autocvar_g_balance_fuel_rotstable;
1981         minh = autocvar_g_balance_health_regenstable;
1982         mina = autocvar_g_balance_armor_regenstable;
1983         minf = autocvar_g_balance_fuel_regenstable;
1984         limith = autocvar_g_balance_health_limit;
1985         limita = autocvar_g_balance_armor_limit;
1986         limitf = autocvar_g_balance_fuel_limit;
1987
1988         max_mod = regen_mod = rot_mod = limit_mod = 1;
1989
1990         if (self.runes & RUNE_REGEN)
1991         {
1992                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1993                 {
1994                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1995                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1996                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1997                 }
1998                 else
1999                 {
2000                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2001                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2002                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2003                 }
2004         }
2005         else if (self.runes & CURSE_VENOM)
2006         {
2007                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2008                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2009                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2010                 else
2011                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2012                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2013                 //if (!self.runes & RUNE_REGEN)
2014                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2015         }
2016         maxh = maxh * max_mod;
2017         //maxa = maxa * max_mod;
2018         //maxf = maxf * max_mod;
2019         minh = minh * max_mod;
2020         //mina = mina * max_mod;
2021         //minf = minf * max_mod;
2022         limith = limith * limit_mod;
2023         limita = limita * limit_mod;
2024         //limitf = limitf * limit_mod;
2025
2026         if(g_lms && g_ca)
2027                 rot_mod = 0;
2028
2029         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2030         {
2031                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2032                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2033
2034                 // if player rotted to death...  die!
2035                 if(self.health < 1)
2036                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2037         }
2038
2039         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2040                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2041 }
2042
2043 float zoomstate_set;
2044 void SetZoomState(float z)
2045 {
2046         if(z != self.zoomstate)
2047         {
2048                 self.zoomstate = z;
2049                 ClientData_Touch(self);
2050         }
2051         zoomstate_set = 1;
2052 }
2053
2054 void GetPressedKeys(void) {
2055         MUTATOR_CALLHOOK(GetPressedKeys);
2056         if (self.movement_x > 0) // get if movement keys are pressed
2057         {       // forward key pressed
2058                 self.pressedkeys |= KEY_FORWARD;
2059                 self.pressedkeys &~= KEY_BACKWARD;
2060         }
2061         else if (self.movement_x < 0)
2062         {       // backward key pressed
2063                 self.pressedkeys |= KEY_BACKWARD;
2064                 self.pressedkeys &~= KEY_FORWARD;
2065         }
2066         else
2067         {       // no x input
2068                 self.pressedkeys &~= KEY_FORWARD;
2069                 self.pressedkeys &~= KEY_BACKWARD;
2070         }
2071
2072         if (self.movement_y > 0)
2073         {       // right key pressed
2074                 self.pressedkeys |= KEY_RIGHT;
2075                 self.pressedkeys &~= KEY_LEFT;
2076         }
2077         else if (self.movement_y < 0)
2078         {       // left key pressed
2079                 self.pressedkeys |= KEY_LEFT;
2080                 self.pressedkeys &~= KEY_RIGHT;
2081         }
2082         else
2083         {       // no y input
2084                 self.pressedkeys &~= KEY_RIGHT;
2085                 self.pressedkeys &~= KEY_LEFT;
2086         }
2087
2088         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2089                 self.pressedkeys |= KEY_JUMP;
2090         else
2091                 self.pressedkeys &~= KEY_JUMP;
2092         if (self.BUTTON_CROUCH)
2093                 self.pressedkeys |= KEY_CROUCH;
2094         else
2095                 self.pressedkeys &~= KEY_CROUCH;
2096 }
2097
2098 /*
2099 ======================
2100 spectate mode routines
2101 ======================
2102 */
2103
2104 void SpectateCopy(entity spectatee) {
2105         other = spectatee;
2106         MUTATOR_CALLHOOK(SpectateCopy);
2107         self.armortype = spectatee.armortype;
2108         self.armorvalue = spectatee.armorvalue;
2109         self.ammo_cells = spectatee.ammo_cells;
2110         self.ammo_shells = spectatee.ammo_shells;
2111         self.ammo_nails = spectatee.ammo_nails;
2112         self.ammo_rockets = spectatee.ammo_rockets;
2113         self.ammo_fuel = spectatee.ammo_fuel;
2114         self.clip_load = spectatee.clip_load;
2115         self.clip_size = spectatee.clip_size;
2116         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2117         self.health = spectatee.health;
2118         self.impulse = 0;
2119         self.items = spectatee.items;
2120         self.last_pickup = spectatee.last_pickup;
2121         self.hit_time = spectatee.hit_time;
2122         self.metertime = spectatee.metertime;
2123         self.strength_finished = spectatee.strength_finished;
2124         self.invincible_finished = spectatee.invincible_finished;
2125         self.pressedkeys = spectatee.pressedkeys;
2126         self.weapons = spectatee.weapons;
2127         self.switchweapon = spectatee.switchweapon;
2128         self.switchingweapon = spectatee.switchingweapon;
2129         self.weapon = spectatee.weapon;
2130         self.nex_charge = spectatee.nex_charge;
2131         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2132         self.hagar_load = spectatee.hagar_load;
2133         self.minelayer_mines = spectatee.minelayer_mines;
2134         self.punchangle = spectatee.punchangle;
2135         self.view_ofs = spectatee.view_ofs;
2136         self.v_angle = spectatee.v_angle;
2137         self.velocity = spectatee.velocity;
2138         self.dmg_take = spectatee.dmg_take;
2139         self.dmg_save = spectatee.dmg_save;
2140         self.dmg_inflictor = spectatee.dmg_inflictor;
2141         self.angles = spectatee.v_angle;
2142         if(!self.BUTTON_USE)
2143                 self.fixangle = TRUE;
2144         setorigin(self, spectatee.origin);
2145         setsize(self, spectatee.mins, spectatee.maxs);
2146         SetZoomState(spectatee.zoomstate);
2147
2148         anticheat_spectatecopy(spectatee);
2149
2150         //self.vehicle = spectatee.vehicle;
2151
2152         self.hud = spectatee.hud;
2153         if(spectatee.vehicle)
2154     {
2155         setorigin(self, spectatee.origin);
2156         self.velocity = spectatee.vehicle.velocity;
2157         self.v_angle += spectatee.vehicle.angles;
2158         //self.v_angle_x *= -1;
2159         self.vehicle_health = spectatee.vehicle_health;
2160         self.vehicle_shield = spectatee.vehicle_shield;
2161         self.vehicle_energy = spectatee.vehicle_energy;
2162         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2163         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2164         self.vehicle_reload1 = spectatee.vehicle_reload1;
2165         self.vehicle_reload2 = spectatee.vehicle_reload2;
2166
2167         msg_entity = self;
2168         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2169         WriteEntity(MSG_ONE, spectatee);
2170         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2171     }
2172 }
2173
2174 float SpectateUpdate() {
2175         if(!self.enemy)
2176             return 0;
2177
2178         if (self == self.enemy)
2179                 return 0;
2180
2181         if(self.enemy.classname != "player")
2182                 return 0;
2183
2184         SpectateCopy(self.enemy);
2185
2186         return 1;
2187 }
2188
2189
2190 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2191 entity CA_SpectateNext(entity start) {
2192         if (start.team == self.team) {
2193                 return start;
2194         }
2195
2196         other = start;
2197         // continue from current player
2198         while(other && other.team != self.team) {
2199                 other = find(other, classname, "player");
2200         }
2201
2202         if (!other) {
2203                 // restart from begining
2204                 other = find(other, classname, "player");
2205                 while(other && other.team != self.team) {
2206                         other = find(other, classname, "player");
2207                 }
2208         }
2209
2210         return other;
2211 }
2212
2213 float SpectateNext() {
2214         other = find(self.enemy, classname, "player");
2215         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2216                 // CA and ca players when spectating enemies is forbidden
2217                 other = CA_SpectateNext(other);
2218         } else {
2219                 // other modes and ca spectators or spectating enemies is allowed
2220                 if (!other)
2221                         other = find(other, classname, "player");
2222         }
2223
2224         if (other)
2225                 self.enemy = other;
2226
2227         if(self.enemy.classname == "player") {
2228             if(self.enemy.vehicle)
2229             {
2230             msg_entity = self;
2231             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2232             WriteEntity(MSG_ONE, self.enemy);
2233             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2234             self.movetype = MOVETYPE_NONE;
2235             accuracy_resend(self);
2236             }
2237             else
2238             {
2239             msg_entity = self;
2240             WriteByte(MSG_ONE, SVC_SETVIEW);
2241             WriteEntity(MSG_ONE, self.enemy);
2242             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2243             self.movetype = MOVETYPE_NONE;
2244             accuracy_resend(self);
2245
2246             if(!SpectateUpdate())
2247                 PutObserverInServer();
2248         }
2249         return 1;
2250         } else {
2251                 return 0;
2252         }
2253 }
2254
2255 /*
2256 =============
2257 ShowRespawnCountdown()
2258
2259 Update a respawn countdown display.
2260 =============
2261 */
2262 void ShowRespawnCountdown()
2263 {
2264         float number;
2265         if(self.deadflag == DEAD_NO) // just respawned?
2266                 return;
2267         else
2268         {
2269                 number = ceil(self.death_time - time);
2270                 if(number <= 0)
2271                         return;
2272                 if(number <= self.respawn_countdown)
2273                 {
2274                         self.respawn_countdown = number - 1;
2275                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2276                                 AnnounceTo(self, strcat(ftos(number), ""));
2277                 }
2278         }
2279 }
2280
2281 .float prevent_join_msgtime;
2282 void LeaveSpectatorMode()
2283 {
2284         if(nJoinAllowed(1)) {
2285                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2286                         self.classname = "player";
2287
2288                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2289                                 JoinBestTeam(self, FALSE, TRUE);
2290
2291                         if(autocvar_g_campaign)
2292                                 campaign_bots_may_start = 1;
2293
2294                         PutClientInServer();
2295
2296                         if(self.classname == "player")
2297                                 bprint ("^4", self.netname, "^4 is playing now\n");
2298
2299                         if(!autocvar_g_campaign)
2300                         if (time < self.jointime + autocvar_welcome_message_time)
2301                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2302
2303                         if (self.prevent_join_msgtime)
2304                         {
2305                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2306                                 self.prevent_join_msgtime = 0;
2307                         }
2308
2309                         return;
2310                 } else {
2311                         if (g_ca && self.caplayer) {
2312                         }       // do nothing
2313                         else
2314                                 stuffcmd(self,"menu_showteamselect\n");
2315                         return;
2316                 }
2317         }
2318         else {
2319                 //player may not join because of g_maxplayers is set
2320                 if (time - self.prevent_join_msgtime > 2)
2321                 {
2322                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2323                         self.prevent_join_msgtime = time;
2324                 }
2325         }
2326 }
2327
2328 /**
2329  * Determines whether the player is allowed to join. This depends on cvar
2330  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2331  * it checks whether the number of currently playing players exceeds g_maxplayers.
2332  * @return int number of free slots for players, 0 if none
2333  */
2334 float nJoinAllowed(float includeMe) {
2335         if(self.team_forced < 0)
2336                 return FALSE; // forced spectators can never join
2337
2338         // TODO simplify this
2339         entity e;
2340
2341         float totalClients;
2342         FOR_EACH_CLIENT(e)
2343                 totalClients += 1;
2344
2345         if (!autocvar_g_maxplayers)
2346                 return maxclients - totalClients + includeMe;
2347
2348         float currentlyPlaying;
2349         FOR_EACH_REALPLAYER(e)
2350                 currentlyPlaying += 1;
2351
2352         if(currentlyPlaying < autocvar_g_maxplayers)
2353                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2354
2355         return 0;
2356 }
2357
2358 /**
2359  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2360  * g_maxplayers_spectator_blocktime seconds
2361  */
2362 void checkSpectatorBlock() {
2363         if(self.classname == "spectator" || self.classname == "observer") {
2364                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2365                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2366                         dropclient(self);
2367                 }
2368         }
2369 }
2370
2371 .float motd_actived_time; // used for both motd and campaign_message
2372 void PrintWelcomeMessage()
2373 {
2374         if (self.motd_actived_time == 0) { // is there already a message showing?
2375                 if (autocvar_g_campaign) {
2376                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2377                                 self.motd_actived_time = time;
2378                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2379                         }
2380                 } else {
2381                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2382                                 self.motd_actived_time = time;
2383                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2384                         }
2385                 }
2386         } else { // showing MOTD or campaign message
2387                 if (autocvar_g_campaign) {
2388                         if (self.BUTTON_INFO)
2389                                 self.motd_actived_time = time;
2390                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2391                                 self.motd_actived_time = 0;
2392                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2393                         }
2394                 } else {
2395                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2396                                 if (self.BUTTON_INFO)
2397                                         self.motd_actived_time = time;
2398                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2399                                         self.motd_actived_time = 0;
2400                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2401                                 }
2402                         }
2403                 }
2404         }
2405 }
2406
2407 void ObserverThink()
2408 {
2409         float prefered_movetype;
2410         if (self.flags & FL_JUMPRELEASED) {
2411                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2412                         self.flags &~= FL_JUMPRELEASED;
2413                         self.flags |= FL_SPAWNING;
2414                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2415                         self.flags &~= FL_JUMPRELEASED;
2416                         if(SpectateNext() == 1) {
2417                                 self.classname = "spectator";
2418                         }
2419                 } else {
2420                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2421                         if (self.movetype != prefered_movetype)
2422                                 self.movetype = prefered_movetype;
2423                 }
2424         } else {
2425                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2426                         self.flags |= FL_JUMPRELEASED;
2427                         if(self.flags & FL_SPAWNING)
2428                         {
2429                                 self.flags &~= FL_SPAWNING;
2430                                 LeaveSpectatorMode();
2431                                 return;
2432                         }
2433                 }
2434         }
2435
2436         PrintWelcomeMessage();
2437 }
2438
2439 void SpectatorThink()
2440 {
2441         if (self.flags & FL_JUMPRELEASED) {
2442                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2443                         self.flags &~= FL_JUMPRELEASED;
2444                         self.flags |= FL_SPAWNING;
2445                 } else if(self.BUTTON_ATCK) {
2446                         self.flags &~= FL_JUMPRELEASED;
2447                         if(SpectateNext() == 1) {
2448                                 self.classname = "spectator";
2449                         } else {
2450                                 self.classname = "observer";
2451                                 PutClientInServer();
2452                         }
2453                 } else if (self.BUTTON_ATCK2) {
2454                         self.flags &~= FL_JUMPRELEASED;
2455                         self.classname = "observer";
2456                         PutClientInServer();
2457                 } else {
2458                         if(!SpectateUpdate())
2459                                 PutObserverInServer();
2460                 }
2461         } else {
2462                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2463                         self.flags |= FL_JUMPRELEASED;
2464                         if(self.flags & FL_SPAWNING)
2465                         {
2466                                 self.flags &~= FL_SPAWNING;
2467                                 LeaveSpectatorMode();
2468                                 return;
2469                         }
2470                 }
2471                 if(!SpectateUpdate())
2472                         PutObserverInServer();
2473         }
2474
2475         PrintWelcomeMessage();
2476         self.flags |= FL_CLIENT | FL_NOTARGET;
2477 }
2478
2479 float ctf_usekey();
2480 void PlayerUseKey()
2481 {
2482         if(self.classname != "player")
2483                 return;
2484
2485         if(self.vehicle)
2486         {
2487         vehicles_exit(VHEF_NORMAL);
2488         return;
2489         }
2490
2491         // a use key was pressed; call handlers
2492         if(ctf_usekey())
2493                 return;
2494
2495         MUTATOR_CALLHOOK(PlayerUseKey);
2496 }
2497
2498 .float touchexplode_time;
2499
2500 /*
2501 =============
2502 PlayerPreThink
2503
2504 Called every frame for each client before the physics are run
2505 =============
2506 */
2507 .float usekeypressed;
2508 void() ctf_setstatus;
2509 void() nexball_setstatus;
2510 .float items_added;
2511 void PlayerPreThink (void)
2512 {
2513         WarpZone_PlayerPhysics_FixVAngle();
2514
2515         self.stat_game_starttime = game_starttime;
2516         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2517         self.stat_leadlimit = autocvar_leadlimit;
2518
2519         if(frametime)
2520         {
2521                 // physics frames: update anticheat stuff
2522                 anticheat_prethink();
2523         }
2524
2525         if(blockSpectators && frametime)
2526                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2527                 checkSpectatorBlock();
2528
2529         zoomstate_set = 0;
2530
2531         if(self.netname_previous != self.netname)
2532         {
2533                 if(autocvar_sv_eventlog)
2534                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2535                 if(self.netname_previous)
2536                         strunzone(self.netname_previous);
2537                 self.netname_previous = strzone(self.netname);
2538         }
2539
2540         // version nagging
2541         if(self.version_nagtime)
2542                 if(self.cvar_g_xonoticversion)
2543                         if(time > self.version_nagtime)
2544                         {
2545                                 // don't notify git users
2546                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2547                                 {
2548                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2549                                         {
2550                                                 // notify release users if connecting to git
2551                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2552                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2553                                         }
2554                                         else
2555                                         {
2556                                                 float r;
2557                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2558                                                 if(r < 0)
2559                                                 {
2560                                                         // give users new version
2561                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2562                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2563                                                 }
2564                                                 else if(r > 0)
2565                                                 {
2566                                                         // notify users about old server version
2567                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2568                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2569                                                 }
2570                                         }
2571                                 }
2572                                 self.version_nagtime = 0;
2573                         }
2574
2575         // GOD MODE info
2576         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2577         {
2578                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2579                 self.max_armorvalue = 0;
2580         }
2581
2582 #ifdef TETRIS
2583         if (TetrisPreFrame())
2584                 return;
2585 #endif
2586
2587         MUTATOR_CALLHOOK(PlayerPreThink);
2588
2589         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2590         {
2591                 if(self.BUTTON_USE && !self.usekeypressed)
2592                         PlayerUseKey();
2593                 self.usekeypressed = self.BUTTON_USE;
2594         }
2595
2596         PrintWelcomeMessage();
2597
2598         if(self.classname == "player") {
2599 //              if(self.netname == "Wazat")
2600 //                      bprint(self.classname, "\n");
2601
2602                 CheckRules_Player();
2603
2604                 if (intermission_running)
2605                 {
2606                         IntermissionThink ();   // otherwise a button could be missed between
2607                         return;                                 // the think tics
2608                 }
2609
2610                 //don't allow the player to turn around while game is paused!
2611                 if(timeoutStatus == 2) {
2612                         // FIXME turn this into CSQC stuff
2613                         self.v_angle = self.lastV_angle;
2614                         self.angles = self.lastV_angle;
2615                         self.fixangle = TRUE;
2616                 }
2617
2618                 if(frametime)
2619                 {
2620 #ifndef NO_LEGACY_NETWORKING
2621                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2622 #endif
2623
2624                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2625                         {
2626                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2627                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2628                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2629
2630                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2631                                 {
2632                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2633                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2634                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2635                                 }
2636                         }
2637                         else
2638                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2639
2640                         player_powerups();
2641                 }
2642
2643                 if (g_minstagib)
2644                         minstagib_ammocheck();
2645
2646                 if (self.deadflag != DEAD_NO)
2647                 {
2648                         float button_pressed, force_respawn;
2649                         if(self.personal && g_race_qualifying)
2650                         {
2651                                 if(time > self.death_time)
2652                                 {
2653                                         self.death_time = time + 1; // only retry once a second
2654                                         respawn();
2655                                         self.impulse = 141;
2656                                 }
2657                         }
2658                         else
2659                         {
2660                                 if(frametime)
2661                                         player_anim();
2662                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2663                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2664                                 if (self.deadflag == DEAD_DYING)
2665                                 {
2666                                         if(force_respawn)
2667                                                 self.deadflag = DEAD_RESPAWNING;
2668                                         else if(!button_pressed)
2669                                                 self.deadflag = DEAD_DEAD;
2670                                 }
2671                                 else if (self.deadflag == DEAD_DEAD)
2672                                 {
2673                                         if(button_pressed)
2674                                                 self.deadflag = DEAD_RESPAWNABLE;
2675                                 }
2676                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2677                                 {
2678                                         if(!button_pressed)
2679                                                 self.deadflag = DEAD_RESPAWNING;
2680                                 }
2681                                 else if (self.deadflag == DEAD_RESPAWNING)
2682                                 {
2683                                         if(time > self.death_time)
2684                                         {
2685                                                 self.death_time = time + 1; // only retry once a second
2686                                                 respawn();
2687                                         }
2688                                 }
2689                                 ShowRespawnCountdown();
2690                         }
2691                         return;
2692                 }
2693                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2694                 // so (self.deadflag == DEAD_NO) is always true in the code below
2695
2696                 if(g_touchexplode)
2697                 if(time > self.touchexplode_time)
2698                 if(self.classname == "player")
2699                 if(self.deadflag == DEAD_NO)
2700                 if not(IS_INDEPENDENT_PLAYER(self))
2701                 FOR_EACH_PLAYER(other) if(self != other)
2702                 {
2703                         if(time > other.touchexplode_time)
2704                         if(other.deadflag == DEAD_NO)
2705                         if not(IS_INDEPENDENT_PLAYER(other))
2706                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2707                         {
2708                                 PlayerTouchExplode(self, other);
2709                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2710                         }
2711                 }
2712
2713                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2714                 {
2715                         vector dist;
2716
2717                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2718                         dist = self.prevorigin - self.origin;
2719                         dist_z = 0;
2720                         self.lms_traveled_distance += fabs(vlen(dist));
2721
2722                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2723                         {
2724                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2725                                 self.lms_traveled_distance = 0;
2726                         }
2727
2728                         if(time > self.lms_nextcheck)
2729                         {
2730                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2731                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2732                                 {
2733                                         centerprint(self, autocvar_g_lms_campcheck_message);
2734                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2735                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2736                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2737                                 }
2738                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2739                                 self.lms_traveled_distance = 0;
2740                         }
2741                 }
2742
2743                 self.prevorigin = self.origin;
2744
2745                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2746                 {
2747                         if (!self.crouch)
2748                         {
2749                                 self.crouch = TRUE;
2750                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2751                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2752                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2753                         }
2754                 }
2755                 else
2756                 {
2757                         if (self.crouch)
2758                         {
2759                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2760                                 if (!trace_startsolid)
2761                                 {
2762                                         self.crouch = FALSE;
2763                                         self.view_ofs = PL_VIEW_OFS;
2764                                         setsize (self, PL_MIN, PL_MAX);
2765                                 }
2766                         }
2767                 }
2768
2769                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2770                 {
2771                         if(self.bloodloss_timer < time)
2772                         {
2773                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2774                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2775                         }
2776                 }
2777
2778                 FixPlayermodel();
2779
2780                 GrapplingHookFrame();
2781
2782                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2783                 //if(frametime)
2784                 {
2785                         self.items &~= self.items_added;
2786
2787                         W_WeaponFrame();
2788
2789                         self.items_added = 0;
2790                         if(self.items & IT_JETPACK)
2791                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2792                                         self.items_added |= IT_FUEL;
2793
2794                         self.items |= self.items_added;
2795                 }
2796
2797                 player_regen();
2798
2799                 // rot nex charge to the charge limit
2800                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2801                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2802
2803                 if(frametime)
2804                         player_anim();
2805
2806                 if(g_ctf)
2807                         ctf_setstatus();
2808
2809                 if(g_nexball)
2810                         nexball_setstatus();
2811
2812                 // secret status
2813                 secrets_setstatus();
2814
2815                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2816
2817                 //self.angles_y=self.v_angle_y + 90;   // temp
2818         } else if(gameover) {
2819                 if (intermission_running)
2820                         IntermissionThink ();   // otherwise a button could be missed between
2821                 return;
2822         } else if(self.classname == "observer") {
2823                 ObserverThink();
2824         } else if(self.classname == "spectator") {
2825                 SpectatorThink();
2826         }
2827
2828         if(!zoomstate_set)
2829                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2830
2831         float oldspectatee_status;
2832         oldspectatee_status = self.spectatee_status;
2833         if(self.classname == "spectator")
2834                 self.spectatee_status = num_for_edict(self.enemy);
2835         else if(self.classname == "observer")
2836                 self.spectatee_status = num_for_edict(self);
2837         else
2838                 self.spectatee_status = 0;
2839         if(self.spectatee_status != oldspectatee_status)
2840         {
2841                 ClientData_Touch(self);
2842                 if(g_race || g_cts)
2843                         race_InitSpectator();
2844         }
2845
2846         if(self.teamkill_soundtime)
2847         if(time > self.teamkill_soundtime)
2848         {
2849                 self.teamkill_soundtime = 0;
2850
2851                 entity oldpusher, oldself;
2852
2853                 oldself = self; self = self.teamkill_soundsource;
2854                 oldpusher = self.pusher; self.pusher = oldself;
2855
2856                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2857
2858                 self.pusher = oldpusher;
2859                 self = oldself;
2860         }
2861
2862         if(self.taunt_soundtime)
2863         if(time > self.taunt_soundtime)
2864         {
2865                 self.taunt_soundtime = 0;
2866                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2867         }
2868
2869         target_voicescript_next(self);
2870
2871         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2872         if(!self.weapon)
2873                 self.clip_load = self.clip_size = 0;
2874 }
2875
2876 float isInvisibleString(string s)
2877 {
2878         float i, n, c;
2879         s = strdecolorize(s);
2880         for((i = 0), (n = strlen(s)); i < n; ++i)
2881         {
2882                 c = str2chr(s, i);
2883                 switch(c)
2884                 {
2885                         case 0:
2886                         case 32: // space
2887                                 break;
2888                         case 192: // charmap space
2889                                 if (!autocvar_utf8_enable)
2890                                         break;
2891                                 return FALSE;
2892                         case 160: // space in unicode fonts
2893                         case 0xE000 + 192: // utf8 charmap space
2894                                 if (autocvar_utf8_enable)
2895                                         break;
2896                         default:
2897                                 return FALSE;
2898                 }
2899         }
2900         return TRUE;
2901 }
2902
2903 /*
2904 =============
2905 PlayerPostThink
2906
2907 Called every frame for each client after the physics are run
2908 =============
2909 */
2910 .float idlekick_lasttimeleft;
2911 .entity showheadshotbbox;
2912 void showheadshotbbox_think()
2913 {
2914         if(self.owner.showheadshotbbox != self)
2915         {
2916                 remove(self);
2917                 return;
2918         }
2919         self.nextthink = time;
2920         setorigin(self, self.owner.origin);
2921         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2922 }
2923 void PlayerPostThink (void)
2924 {
2925         // Savage: Check for nameless players
2926         if (isInvisibleString(self.netname)) {
2927                 self.netname = "Player";
2928                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2929         }
2930
2931         if(sv_maxidle && frametime)
2932         {
2933                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2934                 float timeleft;
2935                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2936                 {
2937                         if(self.idlekick_lasttimeleft)
2938                         {
2939                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2940                                 self.idlekick_lasttimeleft = 0;
2941                         }
2942                         return;
2943                 }
2944                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2945                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2946                 {
2947                         if(!self.idlekick_lasttimeleft)
2948                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2949                 }
2950                 if(timeleft <= 0)
2951                 {
2952                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2953                         AnnounceTo(self, "terminated");
2954                         dropclient(self);
2955                         return;
2956                 }
2957                 else if(timeleft <= 10)
2958                 {
2959                         if(timeleft != self.idlekick_lasttimeleft)
2960                                 AnnounceTo(self, ftos(timeleft));
2961                         self.idlekick_lasttimeleft = timeleft;
2962                 }
2963         }
2964
2965 #ifdef TETRIS
2966         if(self.impulse == 100)
2967                 ImpulseCommands();
2968         if (TetrisPostFrame())
2969                 return;
2970 #endif
2971
2972         CheatFrame();
2973
2974         //CheckPlayerJump();
2975
2976         if(self.classname == "player") {
2977                 CheckRules_Player();
2978                 UpdateChatBubble();
2979                 if (self.impulse)
2980                         ImpulseCommands();
2981                 if (intermission_running)
2982                         return;         // intermission or finale
2983                 GetPressedKeys();
2984         } else if (self.classname == "observer") {
2985                 //do nothing
2986         } else if (self.classname == "spectator") {
2987                 //do nothing
2988         }
2989
2990         /*
2991         float i;
2992         for(i = 0; i < 1000; ++i)
2993         {
2994                 vector end;
2995                 end = self.origin + '0 0 1024' + 512 * randomvec();
2996                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2997                 if(trace_fraction < 1)
2998                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2999                 {
3000                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3001                         break;
3002                 }
3003         }
3004         */
3005
3006         Arena_Warmup();
3007
3008         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3009
3010         if(self.waypointsprite_attachedforcarrier)
3011                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3012
3013         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3014         {
3015                 if(!self.showheadshotbbox)
3016                 {
3017                         self.showheadshotbbox = spawn();
3018                         self.showheadshotbbox.classname = "headshotbbox";
3019                         self.showheadshotbbox.owner = self;
3020                         self.showheadshotbbox.think = showheadshotbbox_think;
3021                         self.showheadshotbbox.nextthink = time;
3022                         self = self.showheadshotbbox;
3023                         self.think();
3024                         self = self.owner;
3025                 }
3026         }
3027         else
3028         {
3029                 if(self.showheadshotbbox)
3030                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3031                 remove(self.showheadshotbbox);
3032         }
3033
3034         playerdemo_write();
3035
3036         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3037         {
3038                 if(!self.stored_netname)
3039                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3040                 if(self.stored_netname != self.netname)
3041                 {
3042                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3043                         strunzone(self.stored_netname);
3044                         self.stored_netname = strzone(self.netname);
3045                 }
3046         }
3047
3048         /*
3049         if(g_race)
3050                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3051         */
3052
3053         CSQCMODEL_AUTOUPDATE();
3054 }