qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         float teamcheck;
 321         entity firstspot_new;
 322         entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         if (g_minstagib)
 618                 minstagib_stop_countdown();
 619
 620         Portal_ClearAll(self);
 621
 622         if(self.alivetime)
 623         {
 624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                 self.alivetime = 0;
 626         }
 627
 628         if(self.vehicle)
 629             vehicles_exit(VHEF_RELESE);
 630
 631         if(self.flagcarried)
 632                 DropFlag(self.flagcarried, world, world);
 633
 634         WaypointSprite_PlayerDead();
 635
 636         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 637                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 638
 639         if(self.killcount != -666) {
 640                 if(g_lms) {
 641                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 642                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 643                         else
 644                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 645                 } else
 646                         bprint ("^4", self.netname, "^4 is spectating now\n");
 647
 648                 if(self.just_joined == FALSE) {
 649                         LogTeamchange(self.playerid, -1, 4);
 650                 } else
 651                         self.just_joined = FALSE;
 652         }
 653
 654         PlayerScore_Clear(self); // clear scores when needed
 655
 656         accuracy_resend(self);
 657
 658         self.spectatortime = time;
 659
 660         self.classname = "observer";
 661         self.iscreature = FALSE;
 662         self.damagedbycontents = FALSE;
 663         self.health = -666;
 664         self.takedamage = DAMAGE_NO;
 665         self.solid = SOLID_NOT;
 666         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 667         self.flags = FL_CLIENT | FL_NOTARGET;
 668         self.armorvalue = 666;
 669         self.effects = 0;
 670         self.armorvalue = autocvar_g_balance_armor_start;
 671         self.pauserotarmor_finished = 0;
 672         self.pauserothealth_finished = 0;
 673         self.pauseregen_finished = 0;
 674         self.damageforcescale = 0;
 675         self.death_time = 0;
 676         self.dead_frame = 0;
 677         self.alpha = 0;
 678         self.scale = 0;
 679         self.fade_time = 0;
 680         self.pain_frame = 0;
 681         self.pain_finished = 0;
 682         self.strength_finished = 0;
 683         self.invincible_finished = 0;
 684         self.pushltime = 0;
 685         self.think = SUB_Null;
 686         self.nextthink = 0;
 687         self.hook_time = 0;
 688         self.runes = 0;
 689         self.deadflag = DEAD_NO;
 690         self.angles = spot.angles;
 691         self.angles_z = 0;
 692         self.fixangle = TRUE;
 693         self.crouch = FALSE;
 694
 695         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 696         setorigin (self, spot.origin);
 697         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 698         self.prevorigin = self.origin;
 699         self.items = 0;
 700         self.weapons = 0;
 701         self.model = "";
 702         FixPlayermodel();
 703         self.model = "";
 704         self.modelindex = 0;
 705         self.weapon = 0;
 706         self.weaponname = "";
 707         self.switchingweapon = 0;
 708         self.weaponmodel = "";
 709         self.weaponentity = world;
 710         self.exteriorweaponentity = world;
 711         self.killcount = -666;
 712         self.velocity = '0 0 0';
 713         self.avelocity = '0 0 0';
 714         self.punchangle = '0 0 0';
 715         self.punchvector = '0 0 0';
 716         self.oldvelocity = self.velocity;
 717         self.fire_endtime = -1;
 718
 719         if(sv_loddistance1)
 720                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 721
 722         if(g_arena)
 723         {
 724                 if(self.version_mismatch)
 725                 {
 726                         Spawnqueue_Unmark(self);
 727                         Spawnqueue_Remove(self);
 728                 }
 729                 else
 730                 {
 731                         Spawnqueue_Insert(self);
 732                 }
 733         }
 734         else if(g_lms)
 735         {
 736                 // Only if the player cannot play at all
 737                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 738                         self.frags = FRAGS_SPECTATOR;
 739                 else
 740                         self.frags = FRAGS_LMS_LOSER;
 741         }
 742         else if(g_ca)
 743         {
 744                 if(self.caplayer)
 745                         self.frags = FRAGS_LMS_LOSER;
 746                 else
 747                         self.frags = FRAGS_SPECTATOR;
 748         }
 749         else
 750                 self.frags = FRAGS_SPECTATOR;
 751 }
 752
 753 void FixPlayermodel()
 754 {
 755         string defaultmodel;
 756         float defaultskin, chmdl, oldskin;
 757         vector m1, m2;
 758
 759         defaultmodel = "";
 760
 761         if(autocvar_sv_defaultcharacter == 1) {
 762                 defaultskin = 0;
 763
 764                 if(teamplay)
 765                 {
 766                         string s;
 767                         s = Team_ColorNameLowerCase(self.team);
 768                         if(s != "neutral")
 769                         {
 770                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 771                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 772                         }
 773                 }
 774
 775                 if(defaultmodel == "")
 776                 {
 777                         defaultmodel = autocvar_sv_defaultplayermodel;
 778                         defaultskin = autocvar_sv_defaultplayerskin;
 779                 }
 780         }
 781
 782         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 783         {
 784                 if(self.model != "")
 785                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 786                 self.model = ""; // force the != checks to return true
 787         }
 788
 789         if(defaultmodel != "")
 790         {
 791                 if (defaultmodel != self.model)
 792                 {
 793                         m1 = self.mins;
 794                         m2 = self.maxs;
 795                         setmodel_lod (self, defaultmodel);
 796                         setsize (self, m1, m2);
 797                         chmdl = TRUE;
 798                 }
 799
 800                 oldskin = self.skinindex;
 801                 self.skinindex = defaultskin;
 802         } else {
 803                 if (self.playermodel != self.model || self.playermodel == "")
 804                 {
 805                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 806                         m1 = self.mins;
 807                         m2 = self.maxs;
 808                         setmodel_lod (self, self.playermodel);
 809                         setsize (self, m1, m2);
 810                         chmdl = TRUE;
 811                 }
 812
 813                 oldskin = self.skinindex;
 814                 self.skinindex = stof(self.playerskin);
 815         }
 816
 817         if(chmdl || oldskin != self.skinindex)
 818                 self.species = player_getspecies(); // model or skin has changed
 819
 820         if(!teamplay)
 821                 if(strlen(autocvar_sv_defaultplayercolors))
 822                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 823                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 824 }
 825
 826 void PlayerTouchExplode(entity p1, entity p2)
 827 {
 828         vector org;
 829         org = (p1.origin + p2.origin) * 0.5;
 830         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 831
 832         te_explosion(org);
 833
 834         entity e;
 835         e = spawn();
 836         setorigin(e, org);
 837         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 838         remove(e);
 839 }
 840
 841 /*
 842 =============
 843 PutClientInServer
 844
 845 Called when a client spawns in the server
 846 =============
 847 */
 848 //void() ctf_playerchanged;
 849 void PutClientInServer (void)
 850 {
 851         if(clienttype(self) == CLIENTTYPE_BOT)
 852         {
 853                 self.classname = "player";
 854         }
 855         else if(clienttype(self) == CLIENTTYPE_REAL)
 856         {
 857                 msg_entity = self;
 858                 WriteByte(MSG_ONE, SVC_SETVIEW);
 859                 WriteEntity(MSG_ONE, self);
 860         }
 861
 862         // reset player keys
 863         self.itemkeys = 0;
 864
 865         // player is dead and becomes observer
 866         // FIXME fix LMS scoring for new system
 867         if(g_lms)
 868         {
 869                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 870                         self.classname = "observer";
 871         }
 872
 873         if(g_arena || (g_ca && !allowed_to_spawn))
 874         if(!self.spawned)
 875                 self.classname = "observer";
 876
 877         if(gameover)
 878                 self.classname = "observer";
 879
 880         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 881                 entity spot, oldself;
 882                 float j;
 883
 884                 accuracy_resend(self);
 885
 886                 if(self.team < 0)
 887                         JoinBestTeam(self, FALSE, TRUE);
 888
 889                 race_PreSpawn();
 890
 891                 spot = SelectSpawnPoint (FALSE);
 892                 if(!spot)
 893                 {
 894                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 895                         return; // spawn failed
 896                 }
 897
 898                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 899
 900                 self.classname = "player";
 901                 self.wasplayer = TRUE;
 902                 self.iscreature = TRUE;
 903                 self.damagedbycontents = TRUE;
 904                 self.movetype = MOVETYPE_WALK;
 905                 self.solid = SOLID_SLIDEBOX;
 906                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 907                 if(autocvar_g_playerclip_collisions)
 908                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 909                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 910                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 911                 self.frags = FRAGS_PLAYER;
 912                 if(INDEPENDENT_PLAYERS)
 913                         MAKE_INDEPENDENT_PLAYER(self);
 914                 self.flags = FL_CLIENT;
 915                 self.takedamage = DAMAGE_AIM;
 916                 if(g_minstagib)
 917                         self.effects = EF_FULLBRIGHT;
 918                 else
 919                         self.effects = 0;
 920                 self.air_finished = time + 12;
 921                 self.dmg = 2;
 922                 if(autocvar_g_balance_nex_charge)
 923                 {
 924                         if(autocvar_g_balance_nex_secondary_chargepool)
 925                                 self.nex_chargepool_ammo = 1;
 926                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 927                 }
 928
 929                 if(inWarmupStage)
 930                 {
 931                         self.ammo_shells = warmup_start_ammo_shells;
 932                         self.ammo_nails = warmup_start_ammo_nails;
 933                         self.ammo_rockets = warmup_start_ammo_rockets;
 934                         self.ammo_cells = warmup_start_ammo_cells;
 935                         self.ammo_fuel = warmup_start_ammo_fuel;
 936                         self.health = warmup_start_health;
 937                         self.armorvalue = warmup_start_armorvalue;
 938                         self.weapons = warmup_start_weapons;
 939                 }
 940                 else
 941                 {
 942                         self.ammo_shells = start_ammo_shells;
 943                         self.ammo_nails = start_ammo_nails;
 944                         self.ammo_rockets = start_ammo_rockets;
 945                         self.ammo_cells = start_ammo_cells;
 946                         self.ammo_fuel = start_ammo_fuel;
 947                         self.health = start_health;
 948                         self.armorvalue = start_armorvalue;
 949                         self.weapons = start_weapons;
 950                 }
 951
 952                 if(g_weaponarena_random)
 953                 {
 954                         if(g_weaponarena_random_with_laser)
 955                                 self.weapons &~= WEPBIT_LASER;
 956                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 957                         if(g_weaponarena_random_with_laser)
 958                                 self.weapons |= WEPBIT_LASER;
 959                 }
 960
 961                 self.items = start_items;
 962                 self.jump_interval = time;
 963
 964                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 965                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 966                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 967                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 968                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 969                 //extend the pause of rotting if client was reset at the beginning of the countdown
 970                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 971                         self.spawnshieldtime += game_starttime - time;
 972                         self.pauserotarmor_finished += game_starttime - time;
 973                         self.pauserothealth_finished += game_starttime - time;
 974                         self.pauseregen_finished += game_starttime - time;
 975                 }
 976                 self.damageforcescale = 2;
 977                 self.death_time = 0;
 978                 self.dead_frame = 0;
 979                 self.alpha = 0;
 980                 self.scale = 0;
 981                 self.fade_time = 0;
 982                 self.pain_frame = 0;
 983                 self.pain_finished = 0;
 984                 self.strength_finished = 0;
 985                 self.invincible_finished = 0;
 986                 self.pushltime = 0;
 987                 // players have no think function
 988                 self.think = SUB_Null;
 989                 self.nextthink = 0;
 990                 self.hook_time = 0;
 991                 self.dmg_team = 0;
 992                 self.ballistics_density = autocvar_g_ballistics_density_player;
 993
 994                 self.metertime = 0;
 995
 996                 self.runes = 0;
 997
 998                 self.deadflag = DEAD_NO;
 999
1000                 self.angles = spot.angles;
1001
1002                 self.angles_z = 0; // never spawn tilted even if the spot says to
1003                 self.fixangle = TRUE; // turn this way immediately
1004                 self.velocity = '0 0 0';
1005                 self.avelocity = '0 0 0';
1006                 self.punchangle = '0 0 0';
1007                 self.punchvector = '0 0 0';
1008                 self.oldvelocity = self.velocity;
1009                 self.fire_endtime = -1;
1010
1011                 msg_entity = self;
1012                 WRITESPECTATABLE_MSG_ONE({
1013                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1014                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1015                 });
1016
1017                 if(sv_loddistance1)
1018                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1019
1020                 self.model = "";
1021                 FixPlayermodel();
1022
1023                 self.crouch = FALSE;
1024                 self.view_ofs = PL_VIEW_OFS;
1025                 setsize (self, PL_MIN, PL_MAX);
1026                 self.spawnorigin = spot.origin;
1027                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1028                 // don't reset back to last position, even if new position is stuck in solid
1029                 self.oldorigin = self.origin;
1030                 self.prevorigin = self.origin;
1031                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1032                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1033
1034                 if(g_arena)
1035                 {
1036                         Spawnqueue_Remove(self);
1037                         Spawnqueue_Mark(self);
1038                 }
1039
1040                 else if(g_ca)
1041                         self.caplayer = 1;
1042
1043                 self.event_damage = PlayerDamage;
1044
1045                 self.bot_attack = TRUE;
1046
1047                 self.statdraintime = time + 5;
1048                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1049
1050                 if(self.killcount == -666) {
1051                         PlayerScore_Clear(self);
1052                         self.killcount = 0;
1053                 }
1054
1055                 CL_SpawnWeaponentity();
1056                 self.alpha = default_player_alpha;
1057                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1058                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1059
1060                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1061                 self.lms_traveled_distance = 0;
1062                 self.speedrunning = FALSE;
1063
1064                 race_PostSpawn(spot);
1065
1066                 if(autocvar_spawn_debug)
1067                 {
1068                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1069                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1070                 }
1071
1072                 //stuffcmd(self, "chase_active 0");
1073                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1074
1075                 if (autocvar_g_spawnsound)
1076                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1077
1078                 if(g_assault) {
1079                         if(self.team == assault_attacker_team)
1080                                 centerprint(self, "You are attacking!");
1081                         else
1082                                 centerprint(self, "You are defending!");
1083                 }
1084
1085                 target_voicescript_clear(self);
1086
1087                 // reset fields the weapons may use
1088                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1089                 {
1090                         weapon_action(j, WR_RESETPLAYER);
1091
1092                         // all weapons must be fully loaded when we spawn
1093                         entity e;
1094                         e = get_weaponinfo(j);
1095                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1096                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1097                 }
1098
1099                 oldself = self;
1100                 self = spot;
1101                         activator = oldself;
1102                                 string s;
1103                                 s = self.target;
1104                                 self.target = string_null;
1105                                 SUB_UseTargets();
1106                                 self.target = s;
1107                         activator = world;
1108                 self = oldself;
1109
1110                 MUTATOR_CALLHOOK(PlayerSpawn);
1111
1112                 self.switchweapon = w_getbestweapon(self);
1113                 self.cnt = -1; // W_LastWeapon will not complain
1114                 self.weapon = 0;
1115                 self.weaponname = "";
1116                 self.switchingweapon = 0;
1117
1118                 if(!self.alivetime)
1119                         self.alivetime = time;
1120         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1121                 PutObserverInServer ();
1122         }
1123
1124         //if(g_ctf)
1125         //      ctf_playerchanged();
1126 }
1127
1128 .float ebouncefactor, ebouncestop; // electro's values
1129 // TODO do we need all these fields, or should we stop autodetecting runtime
1130 // changes and just have a console command to update this?
1131 float ClientInit_SendEntity(entity to, float sf)
1132 {
1133         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1134         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1135         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1136         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1137         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1138         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1139         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1140         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1141         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1142         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1143         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1144         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1145         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1146         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1147         if(sv_foginterval && world.fog != "")
1148                 WriteString(MSG_ENTITY, world.fog);
1149         else
1150                 WriteString(MSG_ENTITY, "");
1151         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1152         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1153         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1154         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1155         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1156         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1157         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1158         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1159         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1160         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1161         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1162         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1163         return TRUE;
1164 }
1165
1166 void ClientInit_CheckUpdate()
1167 {
1168         self.nextthink = time;
1169         if(self.count != autocvar_g_balance_armor_blockpercent)
1170         {
1171                 self.count = autocvar_g_balance_armor_blockpercent;
1172                 self.SendFlags |= 1;
1173         }
1174         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1175         {
1176                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1177                 self.SendFlags |= 1;
1178         }
1179         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1180         {
1181                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1182                 self.SendFlags |= 1;
1183         }
1184         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1185         {
1186                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1187                 self.SendFlags |= 1;
1188         }
1189         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1190         {
1191                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1192                 self.SendFlags |= 1;
1193         }
1194         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1195         {
1196                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1197                 self.SendFlags |= 1;
1198         }
1199 }
1200
1201 void ClientInit_Spawn()
1202 {
1203         entity o;
1204         entity e;
1205         e = spawn();
1206         e.classname = "clientinit";
1207         e.think = ClientInit_CheckUpdate;
1208         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1209
1210         o = self;
1211         self = e;
1212         ClientInit_CheckUpdate();
1213         self = o;
1214 }
1215
1216 /*
1217 =============
1218 SetNewParms
1219 =============
1220 */
1221 void SetNewParms (void)
1222 {
1223         // initialize parms for a new player
1224         parm1 = -(86400 * 366);
1225 }
1226
1227 /*
1228 =============
1229 SetChangeParms
1230 =============
1231 */
1232 void SetChangeParms (void)
1233 {
1234         // save parms for level change
1235         parm1 = self.parm_idlesince - time;
1236 }
1237
1238 /*
1239 =============
1240 DecodeLevelParms
1241 =============
1242 */
1243 void DecodeLevelParms (void)
1244 {
1245         // load parms
1246         self.parm_idlesince = parm1;
1247         if(self.parm_idlesince == -(86400 * 366))
1248                 self.parm_idlesince = time;
1249
1250         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1251         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1252 }
1253
1254 /*
1255 =============
1256 ClientKill
1257
1258 Called when a client types 'kill' in the console
1259 =============
1260 */
1261
1262 .float clientkill_nexttime;
1263 void ClientKill_Now_TeamChange()
1264 {
1265         if(self.killindicator_teamchange == -1)
1266         {
1267                 self.team = -1;
1268                 JoinBestTeam( self, FALSE, FALSE );
1269         }
1270         else if(self.killindicator_teamchange == -2)
1271         {
1272                 if(g_ca)
1273                         self.caplayer = 0;
1274                 if(blockSpectators)
1275                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1276                 PutObserverInServer();
1277         }
1278         else
1279                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1280 }
1281
1282 void ClientKill_Now()
1283 {
1284         if(self.vehicle)
1285         {
1286             vehicles_exit(VHEF_RELESE);
1287             if(!self.killindicator_teamchange)
1288             {
1289             self.vehicle_health = -1;
1290             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1291             }
1292         }
1293
1294         if(self.killindicator && !wasfreed(self.killindicator))
1295                 remove(self.killindicator);
1296
1297         self.killindicator = world;
1298
1299         if(self.killindicator_teamchange)
1300                 ClientKill_Now_TeamChange();
1301
1302         // in any case:
1303         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1304
1305         // now I am sure the player IS dead
1306 }
1307 void KillIndicator_Think()
1308 {
1309         if (gameover)
1310         {
1311                 self.owner.killindicator = world;
1312                 remove(self);
1313                 return;
1314         }
1315
1316         if (!self.owner.modelindex)
1317         {
1318                 self.owner.killindicator = world;
1319                 remove(self);
1320                 return;
1321         }
1322
1323         if(self.cnt <= 0)
1324         {
1325                 self = self.owner;
1326                 ClientKill_Now(); // no oldself needed
1327                 return;
1328         }
1329     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1330     {
1331         self.nextthink = time + 1;
1332         self.cnt -= 1;
1333     }
1334         else
1335         {
1336                 if(self.cnt <= 10)
1337                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1338                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1339                 {
1340                         if(self.cnt <= 10)
1341                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1342                 }
1343                 self.nextthink = time + 1;
1344                 self.cnt -= 1;
1345         }
1346 }
1347
1348 float clientkilltime;
1349 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1350 {
1351         float killtime;
1352         float starttime;
1353         entity e;
1354
1355         if (gameover)
1356                 return;
1357
1358         killtime = autocvar_g_balance_kill_delay;
1359
1360         if(g_race_qualifying || g_cts)
1361                 killtime = 0;
1362
1363     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1364     {
1365                 remove(self.killindicator);
1366                 self.killindicator = world;
1367
1368         ClientKill_Now(); // allow instant kill in this case
1369         return;
1370     }
1371
1372         self.killindicator_teamchange = targetteam;
1373
1374     if(!self.killindicator)
1375         {
1376                 if(self.modelindex && self.deadflag == DEAD_NO)
1377                 {
1378                         killtime = max(killtime, self.clientkill_nexttime - time);
1379                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1380                 }
1381
1382                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1383                 {
1384                         ClientKill_Now();
1385                 }
1386                 else
1387                 {
1388                         starttime = max(time, clientkilltime);
1389
1390                         self.killindicator = spawn();
1391                         self.killindicator.owner = self;
1392                         self.killindicator.scale = 0.5;
1393                         setattachment(self.killindicator, self, "");
1394                         setorigin(self.killindicator, '0 0 52');
1395                         self.killindicator.think = KillIndicator_Think;
1396                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1397                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1398                         self.killindicator.cnt = ceil(killtime);
1399                         self.killindicator.count = bound(0, ceil(killtime), 10);
1400                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1401
1402                         for(e = world; (e = find(e, classname, "body")) != world; )
1403                         {
1404                                 if(e.enemy != self)
1405                                         continue;
1406                                 e.killindicator = spawn();
1407                                 e.killindicator.owner = e;
1408                                 e.killindicator.scale = 0.5;
1409                                 setattachment(e.killindicator, e, "");
1410                                 setorigin(e.killindicator, '0 0 52');
1411                                 e.killindicator.think = KillIndicator_Think;
1412                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1413                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1414                                 e.killindicator.cnt = ceil(killtime);
1415                         }
1416                         self.lip = 0;
1417                 }
1418         }
1419         if(self.killindicator)
1420         {
1421                 if(targetteam == 0) // just die
1422                 {
1423                         self.killindicator.colormod = '0 0 0';
1424                         if(clienttype(self) == CLIENTTYPE_REAL)
1425                         if(self.killindicator.cnt > 0)
1426                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1427                 }
1428                 else if(targetteam == -1) // auto
1429                 {
1430                         self.killindicator.colormod = '0 1 0';
1431                         if(clienttype(self) == CLIENTTYPE_REAL)
1432                         if(self.killindicator.cnt > 0)
1433                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1434                 }
1435                 else if(targetteam == -2) // spectate
1436                 {
1437                         self.killindicator.colormod = '0.5 0.5 0.5';
1438                         if(clienttype(self) == CLIENTTYPE_REAL)
1439                         if(self.killindicator.cnt > 0)
1440                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1441                 }
1442                 else
1443                 {
1444                         self.killindicator.colormod = TeamColor(targetteam);
1445                         if(clienttype(self) == CLIENTTYPE_REAL)
1446                         if(self.killindicator.cnt > 0)
1447                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1448                 }
1449         }
1450
1451 }
1452
1453 void ClientKill (void)
1454 {
1455         if (gameover)
1456                 return;
1457
1458         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1459         {
1460                 // do nothing
1461         }
1462     else if(self.freezetag_frozen)
1463     {
1464         // do nothing
1465     }
1466         else
1467                 ClientKill_TeamChange(0);
1468 }
1469
1470 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1471 {
1472     e.killindicator = spawn();
1473     e.killindicator.owner = e;
1474     e.killindicator.think = KillIndicator_Think;
1475     e.killindicator.nextthink = time + (e.lip) * 0.05;
1476     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1477     e.killindicator.health = 1; // this is used to indicate that it should be silent
1478     e.lip = 0;
1479 }
1480
1481 void FixClientCvars(entity e)
1482 {
1483         // send prediction settings to the client
1484         stuffcmd(e, "\nin_bindmap 0 0\n");
1485         if(g_race || g_cts)
1486                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1487         if(autocvar_g_antilag == 3) // client side hitscan
1488                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1489         if(sv_gentle)
1490                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1491         /*
1492          * we no longer need to stuff this. Remove this comment block if you feel
1493          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1494         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1495         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1496         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1497         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1498         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1499         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1500         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1501         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1502         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1503         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1504         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1505         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1506         stuffcmd(e, "cl_movement_edgefriction 1\n");
1507          */
1508 }
1509
1510 float PlayerInIDList(entity p, string idlist)
1511 {
1512         float n, i;
1513         string s;
1514
1515         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1516         if not(p.crypto_idfp)
1517                 return 0;
1518
1519         // this function allows abbreviated player IDs too!
1520         n = tokenize_console(idlist);
1521         for(i = 0; i < n; ++i)
1522         {
1523                 s = argv(i);
1524                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1525                         return 1;
1526         }
1527
1528         return 0;
1529 }
1530
1531 /*
1532 =============
1533 ClientConnect
1534
1535 Called when a client connects to the server
1536 =============
1537 */
1538 //void ctf_clientconnect();
1539 string ColoredTeamName(float t);
1540 void DecodeLevelParms (void);
1541 //void dom_player_join_team(entity pl);
1542 void set_dom_state(entity e);
1543 void ClientConnect (void)
1544 {
1545         float t;
1546
1547         if(self.flags & FL_CLIENT)
1548         {
1549                 print("Warning: ClientConnect, but already connected!\n");
1550                 return;
1551         }
1552
1553         if(Ban_MaybeEnforceBan(self))
1554                 return;
1555
1556         DecodeLevelParms();
1557
1558 #ifdef WATERMARK
1559         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1560 #endif
1561
1562         self.classname = "player_joining";
1563
1564         self.flags = FL_CLIENT;
1565         self.version_nagtime = time + 10 + random() * 10;
1566
1567         if(player_count<0)
1568         {
1569                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1570                 player_count = 0;
1571         }
1572
1573         PlayerScore_Attach(self);
1574         ClientData_Attach();
1575         accuracy_init(self);
1576
1577         bot_clientconnect();
1578
1579         playerdemo_init();
1580
1581         anticheat_init();
1582
1583         race_PreSpawnObserver();
1584
1585         //if(g_domination)
1586         //      dom_player_join_team(self);
1587
1588         // identify the right forced team
1589         if(autocvar_g_campaign)
1590         {
1591                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1592                 {
1593                         switch(autocvar_g_campaign_forceteam)
1594                         {
1595                                 case 1: self.team_forced = COLOR_TEAM1; break;
1596                                 case 2: self.team_forced = COLOR_TEAM2; break;
1597                                 case 3: self.team_forced = COLOR_TEAM3; break;
1598                                 case 4: self.team_forced = COLOR_TEAM4; break;
1599                                 default: self.team_forced = 0;
1600                         }
1601                 }
1602         }
1603         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1604                 self.team_forced = COLOR_TEAM1;
1605         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1606                 self.team_forced = COLOR_TEAM2;
1607         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1608                 self.team_forced = COLOR_TEAM3;
1609         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1610                 self.team_forced = COLOR_TEAM4;
1611         else if(autocvar_g_forced_team_otherwise == "red")
1612                 self.team_forced = COLOR_TEAM1;
1613         else if(autocvar_g_forced_team_otherwise == "blue")
1614                 self.team_forced = COLOR_TEAM2;
1615         else if(autocvar_g_forced_team_otherwise == "yellow")
1616                 self.team_forced = COLOR_TEAM3;
1617         else if(autocvar_g_forced_team_otherwise == "pink")
1618                 self.team_forced = COLOR_TEAM4;
1619         else if(autocvar_g_forced_team_otherwise == "spectate")
1620                 self.team_forced = -1;
1621         else if(autocvar_g_forced_team_otherwise == "spectator")
1622                 self.team_forced = -1;
1623         else
1624                 self.team_forced = 0;
1625
1626         if(!teamplay)
1627                 if(self.team_forced > 0)
1628                         self.team_forced = 0;
1629
1630         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1631
1632         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1633                 self.classname = "observer";
1634         } else {
1635                 if(teamplay)
1636                 {
1637                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1638                         {
1639                                 self.classname = "player";
1640                                 campaign_bots_may_start = 1;
1641                         }
1642                         else
1643                         {
1644                                 self.classname = "observer"; // do it anyway
1645                         }
1646                 }
1647                 else
1648                 {
1649                         self.classname = "player";
1650                         campaign_bots_may_start = 1;
1651                 }
1652         }
1653
1654         self.playerid = (playerid_last = playerid_last + 1);
1655
1656         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1657
1658     if(clienttype(self) == CLIENTTYPE_BOT)
1659         PlayerStats_AddPlayer(self);
1660
1661         if(autocvar_sv_eventlog)
1662                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1663
1664         LogTeamchange(self.playerid, self.team, 1);
1665
1666         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1667
1668         self.netname_previous = strzone(self.netname);
1669
1670         bprint("^4", self.netname, "^4 connected");
1671
1672         if(self.classname != "observer" && (g_domination || g_ctf))
1673                 bprint(" and joined the ", ColoredTeamName(self.team));
1674
1675         bprint("\n");
1676
1677         stuffcmd(self, strcat(clientstuff, "\n"));
1678         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1679
1680         FixClientCvars(self);
1681
1682         // spawnfunc_waypoint sprites
1683         WaypointSprite_InitClient(self);
1684
1685         // Wazat's grappling hook
1686         SetGrappleHookBindings();
1687
1688         // get autoswitch state from player when he toggles it
1689         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1690
1691         // get version info from player
1692         stuffcmd(self, "cmd clientversion $gameversion\n");
1693
1694         // get other cvars from player
1695         GetCvars(0);
1696
1697         // notify about available teams
1698         if(teamplay)
1699         {
1700                 CheckAllowedTeams(self);
1701                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1702                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1703         }
1704         else
1705                 stuffcmd(self, "set _teams_available 0\n");
1706
1707         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1708
1709         if(g_arena || g_ca)
1710         {
1711                 self.classname = "observer";
1712                 if(g_arena)
1713                         Spawnqueue_Insert(self);
1714         }
1715         /*else if(g_ctf)
1716         {
1717                 ctf_clientconnect();
1718         }*/
1719
1720         attach_entcs();
1721
1722         bot_relinkplayerlist();
1723
1724         self.spectatortime = time;
1725         if(blockSpectators)
1726         {
1727                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1728         }
1729
1730         self.jointime = time;
1731         self.allowedTimeouts = autocvar_sv_timeout_number;
1732
1733         if(clienttype(self) == CLIENTTYPE_REAL)
1734         {
1735                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1736                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1737         }
1738
1739         if(g_lms)
1740         {
1741                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1742                 {
1743                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1744                         self.frags = FRAGS_SPECTATOR;
1745                 }
1746         }
1747
1748         if(!sv_foginterval && world.fog != "")
1749                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1750
1751         SoundEntity_Attach(self);
1752
1753         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1754         {
1755                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1756                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1757         }
1758         else
1759                 self.hitplotfh = -1;
1760
1761         if(g_race || g_cts) {
1762                 string rr;
1763                 if(g_cts)
1764                         rr = CTS_RECORD;
1765                 else
1766                         rr = RACE_RECORD;
1767                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1768
1769                 msg_entity = self;
1770                 race_send_recordtime(MSG_ONE);
1771                 race_send_speedaward(MSG_ONE);
1772
1773                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1774                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1775                 race_send_speedaward_alltimebest(MSG_ONE);
1776
1777                 float i;
1778                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1779                         race_SendRankings(i, 0, 0, MSG_ONE);
1780                 }
1781         }
1782         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1783                 send_CSQC_teamnagger();
1784
1785         if (g_domination)
1786                 set_dom_state(self);
1787
1788         CheatInitClient();
1789
1790         if(!autocvar_g_campaign)
1791                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1792 }
1793
1794 /*
1795 =============
1796 ClientDisconnect
1797
1798 Called when a client disconnects from the server
1799 =============
1800 */
1801 .entity chatbubbleentity;
1802 void ReadyCount();
1803 void ClientDisconnect (void)
1804 {
1805         if(self.vehicle)
1806             vehicles_exit(VHEF_RELESE);
1807
1808         if not(self.flags & FL_CLIENT)
1809         {
1810                 print("Warning: ClientDisconnect without ClientConnect\n");
1811                 return;
1812         }
1813
1814         PlayerStats_AddGlobalInfo(self);
1815
1816         CheatShutdownClient();
1817
1818         if(self.hitplotfh >= 0)
1819         {
1820                 fclose(self.hitplotfh);
1821                 self.hitplotfh = -1;
1822         }
1823
1824         anticheat_report();
1825         anticheat_shutdown();
1826
1827         playerdemo_shutdown();
1828
1829         bot_clientdisconnect();
1830
1831         if(self.entcs)
1832                 detach_entcs();
1833
1834         if(autocvar_sv_eventlog)
1835                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1836         bprint ("^4",self.netname);
1837         bprint ("^4 disconnected\n");
1838
1839         SoundEntity_Detach(self);
1840
1841         DropAllRunes(self);
1842         MUTATOR_CALLHOOK(ClientDisconnect);
1843
1844         Portal_ClearAll(self);
1845
1846         RemoveGrapplingHook(self);
1847         if(self.flagcarried)
1848                 DropFlag(self.flagcarried, world, world);
1849
1850         // Here, everything has been done that requires this player to be a client.
1851
1852         self.flags &~= FL_CLIENT;
1853
1854         if (self.chatbubbleentity)
1855                 remove (self.chatbubbleentity);
1856
1857         if (self.killindicator)
1858                 remove (self.killindicator);
1859
1860         WaypointSprite_PlayerGone();
1861
1862         bot_relinkplayerlist();
1863
1864         if(g_arena)
1865         {
1866                 Spawnqueue_Unmark(self);
1867                 Spawnqueue_Remove(self);
1868         }
1869
1870         accuracy_free(self);
1871         ClientData_Detach();
1872         PlayerScore_Detach(self);
1873
1874         if(self.netname_previous)
1875                 strunzone(self.netname_previous);
1876         if(self.clientstatus)
1877                 strunzone(self.clientstatus);
1878         if(self.weaponorder_byimpulse)
1879                 strunzone(self.weaponorder_byimpulse);
1880
1881         ClearPlayerSounds();
1882
1883         if(self.personal)
1884                 remove(self.personal);
1885
1886         self.playerid = 0;
1887         ReadyCount();
1888
1889         // free cvars
1890         GetCvars(-1);
1891 }
1892
1893 .float BUTTON_CHAT;
1894 void ChatBubbleThink()
1895 {
1896         self.nextthink = time;
1897         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1898         {
1899                 if(self.owner) // but why can that ever be world?
1900                         self.owner.chatbubbleentity = world;
1901                 remove(self);
1902                 return;
1903         }
1904         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1905 #ifdef TETRIS
1906                 || self.owner.tetris_on
1907 #endif
1908         )
1909                 self.model = self.mdl;
1910         else
1911                 self.model = "";
1912 }
1913
1914 void UpdateChatBubble()
1915 {
1916         if (!self.modelindex)
1917                 return;
1918         // spawn a chatbubble entity if needed
1919         if (!self.chatbubbleentity)
1920         {
1921                 self.chatbubbleentity = spawn();
1922                 self.chatbubbleentity.owner = self;
1923                 self.chatbubbleentity.exteriormodeltoclient = self;
1924                 self.chatbubbleentity.think = ChatBubbleThink;
1925                 self.chatbubbleentity.nextthink = time;
1926                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1927                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1928                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1929                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1930                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1931                 self.chatbubbleentity.model = "";
1932                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1933         }
1934 }
1935
1936
1937 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1938 // added to the model skins
1939 /*void UpdateColorModHack()
1940 {
1941         float c;
1942         c = self.clientcolors & 15;
1943         // LordHavoc: only bothering to support white, green, red, yellow, blue
1944              if (!teamplay) self.colormod = '0 0 0';
1945         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1946         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1947         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1948         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1949         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1950         else self.colormod = '1 1 1';
1951 }*/
1952
1953 .float oldcolormap;
1954 void respawn(void)
1955 {
1956         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1957         {
1958                 self.solid = SOLID_NOT;
1959                 self.takedamage = DAMAGE_NO;
1960                 self.movetype = MOVETYPE_FLY;
1961                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1962                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1963                 self.effects |= EF_ADDITIVE;
1964                 self.oldcolormap = self.colormap;
1965                 self.colormap = 512;
1966                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1967                 if(autocvar_g_respawn_ghosts_maxtime)
1968                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1969         }
1970
1971         CopyBody(1);
1972         self.effects |= EF_NODRAW; // prevent another CopyBody
1973         if(self.oldcolormap)
1974         {
1975                 self.colormap = self.oldcolormap;
1976                 self.oldcolormap = 0;
1977         }
1978         PutClientInServer();
1979 }
1980
1981 void play_countdown(float finished, string samp)
1982 {
1983         if(clienttype(self) == CLIENTTYPE_REAL)
1984                 if(floor(finished - time - frametime) != floor(finished - time))
1985                         if(finished - time < 6)
1986                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1987 }
1988
1989 void player_powerups (void)
1990 {
1991         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1992         olditems = self.items;
1993
1994         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1995         {
1996                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1997                 self.modelflags |= MF_ROCKET;
1998         }
1999         else
2000         {
2001                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
2002                 self.modelflags &~= MF_ROCKET;
2003         }
2004
2005         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2006
2007         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2008                 return;
2009
2010         Fire_ApplyDamage(self);
2011         Fire_ApplyEffect(self);
2012
2013         if (g_minstagib)
2014         {
2015                 self.effects |= EF_FULLBRIGHT;
2016
2017                 if (self.items & IT_STRENGTH)
2018                 {
2019                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2020                         if (time > self.strength_finished)
2021                         {
2022                                 self.alpha = default_player_alpha;
2023                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2024                                 self.items &~= IT_STRENGTH;
2025                                 sprint(self, "^3Invisibility has worn off\n");
2026                         }
2027                 }
2028                 else
2029                 {
2030                         if (time < self.strength_finished)
2031                         {
2032                                 self.alpha = g_minstagib_invis_alpha;
2033                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2034                                 self.items |= IT_STRENGTH;
2035                                 sprint(self, "^3You are invisible\n");
2036                         }
2037                 }
2038
2039                 if (self.items & IT_INVINCIBLE)
2040                 {
2041                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2042                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2043                         {
2044                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2045                                 sprint(self, "^3Speed has worn off\n");
2046                         }
2047                 }
2048                 else
2049                 {
2050                         if (time < self.invincible_finished)
2051                         {
2052                                 self.items = self.items | IT_INVINCIBLE;
2053                                 sprint(self, "^3You are on speed\n");
2054                         }
2055                 }
2056         }
2057         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2058         {
2059                 if (self.items & IT_STRENGTH)
2060                 {
2061                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2062                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2063                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2064                         {
2065                                 self.items = self.items - (self.items & IT_STRENGTH);
2066                                 sprint(self, "^3Strength has worn off\n");
2067                         }
2068                 }
2069                 else
2070                 {
2071                         if (time < self.strength_finished)
2072                         {
2073                                 self.items = self.items | IT_STRENGTH;
2074                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2075                         }
2076                 }
2077                 if (self.items & IT_INVINCIBLE)
2078                 {
2079                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2080                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2081                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2082                         {
2083                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2084                                 sprint(self, "^3Shield has worn off\n");
2085                         }
2086                 }
2087                 else
2088                 {
2089                         if (time < self.invincible_finished)
2090                         {
2091                                 self.items = self.items | IT_INVINCIBLE;
2092                                 sprint(self, "^3Shield surrounds you\n");
2093                         }
2094                 }
2095
2096                 if(autocvar_g_nodepthtestplayers)
2097                         self.effects = self.effects | EF_NODEPTHTEST;
2098
2099                 if(autocvar_g_fullbrightplayers)
2100                         self.effects = self.effects | EF_FULLBRIGHT;
2101
2102                 // midair gamemode: damage only while in the air
2103                 // if in midair mode, being on ground grants temporary invulnerability
2104                 // (this is so that multishot weapon don't clear the ground flag on the
2105                 // first damage in the frame, leaving the player vulnerable to the
2106                 // remaining hits in the same frame)
2107                 if (self.flags & FL_ONGROUND)
2108                 if (g_midair)
2109                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2110
2111                 if (time >= game_starttime)
2112                 if (time < self.spawnshieldtime)
2113                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2114         }
2115
2116         MUTATOR_CALLHOOK(PlayerPowerups);
2117 }
2118
2119 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2120 {
2121         if(current > stable)
2122                 return current;
2123         else if(current > stable - 0.25) // when close enough, "snap"
2124                 return stable;
2125         else
2126                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2127 }
2128
2129 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2130 {
2131         if(current < stable)
2132                 return current;
2133         else if(current < stable + 0.25) // when close enough, "snap"
2134                 return stable;
2135         else
2136                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2137 }
2138
2139 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2140 {
2141         if(current > rotstable)
2142         {
2143                 if(rotframetime > 0)
2144                 {
2145                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2146                         current = max(rotstable, current - rotlinear * rotframetime);
2147                 }
2148         }
2149         else if(current < regenstable)
2150         {
2151                 if(regenframetime > 0)
2152                 {
2153                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2154                         current = min(regenstable, current + regenlinear * regenframetime);
2155                 }
2156         }
2157
2158         if(current > limit)
2159                 current = limit;
2160
2161         return current;
2162 }
2163
2164 void player_regen (void)
2165 {
2166         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2167         maxh = autocvar_g_balance_health_rotstable;
2168         maxa = autocvar_g_balance_armor_rotstable;
2169         maxf = autocvar_g_balance_fuel_rotstable;
2170         minh = autocvar_g_balance_health_regenstable;
2171         mina = autocvar_g_balance_armor_regenstable;
2172         minf = autocvar_g_balance_fuel_regenstable;
2173         limith = autocvar_g_balance_health_limit;
2174         limita = autocvar_g_balance_armor_limit;
2175         limitf = autocvar_g_balance_fuel_limit;
2176
2177         max_mod = regen_mod = rot_mod = limit_mod = 1;
2178
2179         if (self.runes & RUNE_REGEN)
2180         {
2181                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2182                 {
2183                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2184                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2185                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2186                 }
2187                 else
2188                 {
2189                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2190                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2191                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2192                 }
2193         }
2194         else if (self.runes & CURSE_VENOM)
2195         {
2196                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2197                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2198                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2199                 else
2200                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2201                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2202                 //if (!self.runes & RUNE_REGEN)
2203                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2204         }
2205         maxh = maxh * max_mod;
2206         //maxa = maxa * max_mod;
2207         //maxf = maxf * max_mod;
2208         minh = minh * max_mod;
2209         //mina = mina * max_mod;
2210         //minf = minf * max_mod;
2211         limith = limith * limit_mod;
2212         limita = limita * limit_mod;
2213         //limitf = limitf * limit_mod;
2214
2215         if(g_lms && g_ca)
2216                 rot_mod = 0;
2217
2218         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2219         {
2220                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2221                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2222
2223                 // if player rotted to death...  die!
2224                 if(self.health < 1)
2225                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2226         }
2227
2228         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2229                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2230 }
2231
2232 float zoomstate_set;
2233 void SetZoomState(float z)
2234 {
2235         if(z != self.zoomstate)
2236         {
2237                 self.zoomstate = z;
2238                 ClientData_Touch(self);
2239         }
2240         zoomstate_set = 1;
2241 }
2242
2243 void GetPressedKeys(void) {
2244         MUTATOR_CALLHOOK(GetPressedKeys);
2245         if (self.movement_x > 0) // get if movement keys are pressed
2246         {       // forward key pressed
2247                 self.pressedkeys |= KEY_FORWARD;
2248                 self.pressedkeys &~= KEY_BACKWARD;
2249         }
2250         else if (self.movement_x < 0)
2251         {       // backward key pressed
2252                 self.pressedkeys |= KEY_BACKWARD;
2253                 self.pressedkeys &~= KEY_FORWARD;
2254         }
2255         else
2256         {       // no x input
2257                 self.pressedkeys &~= KEY_FORWARD;
2258                 self.pressedkeys &~= KEY_BACKWARD;
2259         }
2260
2261         if (self.movement_y > 0)
2262         {       // right key pressed
2263                 self.pressedkeys |= KEY_RIGHT;
2264                 self.pressedkeys &~= KEY_LEFT;
2265         }
2266         else if (self.movement_y < 0)
2267         {       // left key pressed
2268                 self.pressedkeys |= KEY_LEFT;
2269                 self.pressedkeys &~= KEY_RIGHT;
2270         }
2271         else
2272         {       // no y input
2273                 self.pressedkeys &~= KEY_RIGHT;
2274                 self.pressedkeys &~= KEY_LEFT;
2275         }
2276
2277         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2278                 self.pressedkeys |= KEY_JUMP;
2279         else
2280                 self.pressedkeys &~= KEY_JUMP;
2281         if (self.BUTTON_CROUCH)
2282                 self.pressedkeys |= KEY_CROUCH;
2283         else
2284                 self.pressedkeys &~= KEY_CROUCH;
2285 }
2286
2287 /*
2288 ======================
2289 spectate mode routines
2290 ======================
2291 */
2292
2293 void SpectateCopy(entity spectatee) {
2294         other = spectatee;
2295         MUTATOR_CALLHOOK(SpectateCopy);
2296         self.armortype = spectatee.armortype;
2297         self.armorvalue = spectatee.armorvalue;
2298         self.ammo_cells = spectatee.ammo_cells;
2299         self.ammo_shells = spectatee.ammo_shells;
2300         self.ammo_nails = spectatee.ammo_nails;
2301         self.ammo_rockets = spectatee.ammo_rockets;
2302         self.ammo_fuel = spectatee.ammo_fuel;
2303         self.clip_load = spectatee.clip_load;
2304         self.clip_size = spectatee.clip_size;
2305         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2306         self.health = spectatee.health;
2307         self.impulse = 0;
2308         self.items = spectatee.items;
2309         self.last_pickup = spectatee.last_pickup;
2310         self.hit_time = spectatee.hit_time;
2311         self.metertime = spectatee.metertime;
2312         self.strength_finished = spectatee.strength_finished;
2313         self.invincible_finished = spectatee.invincible_finished;
2314         self.pressedkeys = spectatee.pressedkeys;
2315         self.weapons = spectatee.weapons;
2316         self.switchweapon = spectatee.switchweapon;
2317         self.switchingweapon = spectatee.switchingweapon;
2318         self.weapon = spectatee.weapon;
2319         self.nex_charge = spectatee.nex_charge;
2320         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2321         self.hagar_load = spectatee.hagar_load;
2322         self.minelayer_mines = spectatee.minelayer_mines;
2323         self.punchangle = spectatee.punchangle;
2324         self.view_ofs = spectatee.view_ofs;
2325         self.v_angle = spectatee.v_angle;
2326         self.velocity = spectatee.velocity;
2327         self.dmg_take = spectatee.dmg_take;
2328         self.dmg_save = spectatee.dmg_save;
2329         self.dmg_inflictor = spectatee.dmg_inflictor;
2330         self.angles = spectatee.v_angle;
2331         if(!self.BUTTON_USE)
2332                 self.fixangle = TRUE;
2333         setorigin(self, spectatee.origin);
2334         setsize(self, spectatee.mins, spectatee.maxs);
2335         SetZoomState(spectatee.zoomstate);
2336
2337         anticheat_spectatecopy(spectatee);
2338
2339         //self.vehicle = spectatee.vehicle;
2340
2341         self.hud = spectatee.hud;
2342         if(spectatee.vehicle)
2343     {
2344         setorigin(self, spectatee.origin);
2345         self.velocity = spectatee.vehicle.velocity;
2346         self.v_angle += spectatee.vehicle.angles;
2347         //self.v_angle_x *= -1;
2348         self.vehicle_health = spectatee.vehicle_health;
2349         self.vehicle_shield = spectatee.vehicle_shield;
2350         self.vehicle_energy = spectatee.vehicle_energy;
2351         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2352         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2353         self.vehicle_reload1 = spectatee.vehicle_reload1;
2354         self.vehicle_reload2 = spectatee.vehicle_reload2;
2355
2356         msg_entity = self;
2357         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2358         WriteEntity(MSG_ONE, spectatee);
2359         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2360     }
2361 }
2362
2363 float SpectateUpdate() {
2364         if(!self.enemy)
2365             return 0;
2366
2367         if (self == self.enemy)
2368                 return 0;
2369
2370         if(self.enemy.classname != "player")
2371                 return 0;
2372
2373         SpectateCopy(self.enemy);
2374
2375         return 1;
2376 }
2377
2378
2379 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2380 entity CA_SpectateNext(entity start) {
2381         if (start.team == self.team) {
2382                 return start;
2383         }
2384
2385         other = start;
2386         // continue from current player
2387         while(other && other.team != self.team) {
2388                 other = find(other, classname, "player");
2389         }
2390
2391         if (!other) {
2392                 // restart from begining
2393                 other = find(other, classname, "player");
2394                 while(other && other.team != self.team) {
2395                         other = find(other, classname, "player");
2396                 }
2397         }
2398
2399         return other;
2400 }
2401
2402 float SpectateNext() {
2403         other = find(self.enemy, classname, "player");
2404         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2405                 // CA and ca players when spectating enemies is forbidden
2406                 other = CA_SpectateNext(other);
2407         } else {
2408                 // other modes and ca spectators or spectating enemies is allowed
2409                 if (!other)
2410                         other = find(other, classname, "player");
2411         }
2412
2413         if (other)
2414                 self.enemy = other;
2415
2416         if(self.enemy.classname == "player") {
2417             if(self.enemy.vehicle)
2418             {
2419             msg_entity = self;
2420             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2421             WriteEntity(MSG_ONE, self.enemy);
2422             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2423             self.movetype = MOVETYPE_NONE;
2424             accuracy_resend(self);
2425             }
2426             else
2427             {
2428             msg_entity = self;
2429             WriteByte(MSG_ONE, SVC_SETVIEW);
2430             WriteEntity(MSG_ONE, self.enemy);
2431             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2432             self.movetype = MOVETYPE_NONE;
2433             accuracy_resend(self);
2434
2435             if(!SpectateUpdate())
2436                 PutObserverInServer();
2437         }
2438         return 1;
2439         } else {
2440                 return 0;
2441         }
2442 }
2443
2444 /*
2445 =============
2446 ShowRespawnCountdown()
2447
2448 Update a respawn countdown display.
2449 =============
2450 */
2451 void ShowRespawnCountdown()
2452 {
2453         float number;
2454         if(self.deadflag == DEAD_NO) // just respawned?
2455                 return;
2456         else
2457         {
2458                 number = ceil(self.death_time - time);
2459                 if(number <= 0)
2460                         return;
2461                 if(number <= self.respawn_countdown)
2462                 {
2463                         self.respawn_countdown = number - 1;
2464                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2465                                 AnnounceTo(self, strcat(ftos(number), ""));
2466                 }
2467         }
2468 }
2469
2470 .float prevent_join_msgtime;
2471 void LeaveSpectatorMode()
2472 {
2473         if(nJoinAllowed(1)) {
2474                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2475                         self.classname = "player";
2476
2477                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2478                                 JoinBestTeam(self, FALSE, TRUE);
2479
2480                         if(autocvar_g_campaign)
2481                                 campaign_bots_may_start = 1;
2482
2483                         PutClientInServer();
2484
2485                         if(self.classname == "player")
2486                                 bprint ("^4", self.netname, "^4 is playing now\n");
2487
2488                         if(!autocvar_g_campaign)
2489                         if (time < self.jointime + autocvar_welcome_message_time)
2490                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2491
2492                         if (self.prevent_join_msgtime)
2493                         {
2494                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2495                                 self.prevent_join_msgtime = 0;
2496                         }
2497
2498                         return;
2499                 } else {
2500                         if (g_ca && self.caplayer) {
2501                         }       // do nothing
2502                         else
2503                                 stuffcmd(self,"menu_showteamselect\n");
2504                         return;
2505                 }
2506         }
2507         else {
2508                 //player may not join because of g_maxplayers is set
2509                 if (time - self.prevent_join_msgtime > 2)
2510                 {
2511                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2512                         self.prevent_join_msgtime = time;
2513                 }
2514         }
2515 }
2516
2517 /**
2518  * Determines whether the player is allowed to join. This depends on cvar
2519  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2520  * it checks whether the number of currently playing players exceeds g_maxplayers.
2521  * @return int number of free slots for players, 0 if none
2522  */
2523 float nJoinAllowed(float includeMe) {
2524         if(self.team_forced < 0)
2525                 return FALSE; // forced spectators can never join
2526
2527         // TODO simplify this
2528         entity e;
2529
2530         float totalClients;
2531         FOR_EACH_CLIENT(e)
2532                 totalClients += 1;
2533
2534         if (!autocvar_g_maxplayers)
2535                 return maxclients - totalClients + includeMe;
2536
2537         float currentlyPlaying;
2538         FOR_EACH_REALPLAYER(e)
2539                 currentlyPlaying += 1;
2540
2541         if(currentlyPlaying < autocvar_g_maxplayers)
2542                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2543
2544         return 0;
2545 }
2546
2547 /**
2548  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2549  * g_maxplayers_spectator_blocktime seconds
2550  */
2551 void checkSpectatorBlock() {
2552         if(self.classname == "spectator" || self.classname == "observer") {
2553                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2554                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2555                         dropclient(self);
2556                 }
2557         }
2558 }
2559
2560 .float motd_actived_time; // used for both motd and campaign_message
2561 void PrintWelcomeMessage()
2562 {
2563         if (self.motd_actived_time == 0) { // is there already a message showing?
2564                 if (autocvar_g_campaign) {
2565                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2566                                 self.motd_actived_time = time;
2567                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2568                         }
2569                 } else {
2570                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2571                                 self.motd_actived_time = time;
2572                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2573                         }
2574                 }
2575         } else { // showing MOTD or campaign message
2576                 if (autocvar_g_campaign) {
2577                         if (self.BUTTON_INFO)
2578                                 self.motd_actived_time = time;
2579                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2580                                 self.motd_actived_time = 0;
2581                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2582                         }
2583                 } else {
2584                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2585                                 if (self.BUTTON_INFO)
2586                                         self.motd_actived_time = time;
2587                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2588                                         self.motd_actived_time = 0;
2589                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2590                                 }
2591                         }
2592                 }
2593         }
2594 }
2595
2596 void ObserverThink()
2597 {
2598         float prefered_movetype;
2599         if (self.flags & FL_JUMPRELEASED) {
2600                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2601                         self.flags &~= FL_JUMPRELEASED;
2602                         self.flags |= FL_SPAWNING;
2603                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2604                         self.flags &~= FL_JUMPRELEASED;
2605                         if(SpectateNext() == 1) {
2606                                 self.classname = "spectator";
2607                         }
2608                 } else {
2609                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2610                         if (self.movetype != prefered_movetype)
2611                                 self.movetype = prefered_movetype;
2612                 }
2613         } else {
2614                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2615                         self.flags |= FL_JUMPRELEASED;
2616                         if(self.flags & FL_SPAWNING)
2617                         {
2618                                 self.flags &~= FL_SPAWNING;
2619                                 LeaveSpectatorMode();
2620                                 return;
2621                         }
2622                 }
2623         }
2624
2625         PrintWelcomeMessage();
2626 }
2627
2628 void SpectatorThink()
2629 {
2630         if (self.flags & FL_JUMPRELEASED) {
2631                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2632                         self.flags &~= FL_JUMPRELEASED;
2633                         self.flags |= FL_SPAWNING;
2634                 } else if(self.BUTTON_ATCK) {
2635                         self.flags &~= FL_JUMPRELEASED;
2636                         if(SpectateNext() == 1) {
2637                                 self.classname = "spectator";
2638                         } else {
2639                                 self.classname = "observer";
2640                                 PutClientInServer();
2641                         }
2642                 } else if (self.BUTTON_ATCK2) {
2643                         self.flags &~= FL_JUMPRELEASED;
2644                         self.classname = "observer";
2645                         PutClientInServer();
2646                 } else {
2647                         if(!SpectateUpdate())
2648                                 PutObserverInServer();
2649                 }
2650         } else {
2651                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2652                         self.flags |= FL_JUMPRELEASED;
2653                         if(self.flags & FL_SPAWNING)
2654                         {
2655                                 self.flags &~= FL_SPAWNING;
2656                                 LeaveSpectatorMode();
2657                                 return;
2658                         }
2659                 }
2660                 if(!SpectateUpdate())
2661                         PutObserverInServer();
2662         }
2663
2664         PrintWelcomeMessage();
2665         self.flags |= FL_CLIENT | FL_NOTARGET;
2666 }
2667
2668 float ctf_usekey();
2669 void PlayerUseKey()
2670 {
2671         if(self.classname != "player")
2672                 return;
2673
2674         if(self.vehicle)
2675         {
2676         vehicles_exit(VHEF_NORMAL);
2677         return;
2678         }
2679
2680         // a use key was pressed; call handlers
2681         if(ctf_usekey())
2682                 return;
2683
2684         MUTATOR_CALLHOOK(PlayerUseKey);
2685 }
2686
2687 .float touchexplode_time;
2688
2689 /*
2690 =============
2691 PlayerPreThink
2692
2693 Called every frame for each client before the physics are run
2694 =============
2695 */
2696 .float usekeypressed;
2697 void() ctf_setstatus;
2698 void() nexball_setstatus;
2699 .float items_added;
2700 void PlayerPreThink (void)
2701 {
2702         WarpZone_PlayerPhysics_FixVAngle();
2703
2704         self.stat_game_starttime = game_starttime;
2705         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2706         self.stat_leadlimit = autocvar_leadlimit;
2707
2708         if(frametime)
2709         {
2710                 // physics frames: update anticheat stuff
2711                 anticheat_prethink();
2712         }
2713
2714         if(blockSpectators && frametime)
2715                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2716                 checkSpectatorBlock();
2717
2718         zoomstate_set = 0;
2719
2720         if(self.netname_previous != self.netname)
2721         {
2722                 if(autocvar_sv_eventlog)
2723                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2724                 if(self.netname_previous)
2725                         strunzone(self.netname_previous);
2726                 self.netname_previous = strzone(self.netname);
2727         }
2728
2729         // version nagging
2730         if(self.version_nagtime)
2731                 if(self.cvar_g_xonoticversion)
2732                         if(time > self.version_nagtime)
2733                         {
2734                                 // don't notify git users
2735                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2736                                 {
2737                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2738                                         {
2739                                                 // notify release users if connecting to git
2740                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2741                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2742                                         }
2743                                         else
2744                                         {
2745                                                 float r;
2746                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2747                                                 if(r < 0)
2748                                                 {
2749                                                         // give users new version
2750                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2751                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2752                                                 }
2753                                                 else if(r > 0)
2754                                                 {
2755                                                         // notify users about old server version
2756                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2757                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2758                                                 }
2759                                         }
2760                                 }
2761                                 self.version_nagtime = 0;
2762                         }
2763
2764         // GOD MODE info
2765         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2766         {
2767                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2768                 self.max_armorvalue = 0;
2769         }
2770
2771 #ifdef TETRIS
2772         if (TetrisPreFrame())
2773                 return;
2774 #endif
2775
2776         MUTATOR_CALLHOOK(PlayerPreThink);
2777
2778         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2779         {
2780                 if(self.BUTTON_USE && !self.usekeypressed)
2781                         PlayerUseKey();
2782                 self.usekeypressed = self.BUTTON_USE;
2783         }
2784
2785         PrintWelcomeMessage();
2786
2787         if(self.classname == "player") {
2788 //              if(self.netname == "Wazat")
2789 //                      bprint(self.classname, "\n");
2790
2791                 CheckRules_Player();
2792
2793                 if (intermission_running)
2794                 {
2795                         IntermissionThink ();   // otherwise a button could be missed between
2796                         return;                                 // the think tics
2797                 }
2798
2799                 //don't allow the player to turn around while game is paused!
2800                 if(timeoutStatus == 2) {
2801                         // FIXME turn this into CSQC stuff
2802                         self.v_angle = self.lastV_angle;
2803                         self.angles = self.lastV_angle;
2804                         self.fixangle = TRUE;
2805                 }
2806
2807                 if(frametime)
2808                 {
2809                         if(self.health <= 0 && autocvar_g_deathglow)
2810                         {
2811                                 if(self.glowmod_x > 0)
2812                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2813                                 else
2814                                         self.glowmod_x = -1;
2815                                 if(self.glowmod_y > 0)
2816                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2817                                 else
2818                                         self.glowmod_y = -1;
2819                                 if(self.glowmod_z > 0)
2820                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2821                                 else
2822                                         self.glowmod_z = -1;
2823                         }
2824                         else
2825                         {
2826                                 // set weapon and player glowmod
2827                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2828
2829                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2830                                 {
2831                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2832                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2833                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2834
2835                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2836                                         {
2837                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2838                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2839                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2840                                         }
2841                                 }
2842                                 else
2843                                         self.weaponentity_glowmod = self.glowmod;
2844                         }
2845                         player_powerups();
2846                 }
2847
2848                 if (g_minstagib)
2849                         minstagib_ammocheck();
2850
2851                 if (self.deadflag != DEAD_NO)
2852                 {
2853                         float button_pressed, force_respawn;
2854                         if(self.personal && g_race_qualifying)
2855                         {
2856                                 if(time > self.death_time)
2857                                 {
2858                                         self.death_time = time + 1; // only retry once a second
2859                                         respawn();
2860                                         self.impulse = 141;
2861                                 }
2862                         }
2863                         else
2864                         {
2865                                 if(frametime)
2866                                         player_anim();
2867                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2868                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2869                                 if (self.deadflag == DEAD_DYING)
2870                                 {
2871                                         if(force_respawn)
2872                                                 self.deadflag = DEAD_RESPAWNING;
2873                                         else if(!button_pressed)
2874                                                 self.deadflag = DEAD_DEAD;
2875                                 }
2876                                 else if (self.deadflag == DEAD_DEAD)
2877                                 {
2878                                         if(button_pressed)
2879                                                 self.deadflag = DEAD_RESPAWNABLE;
2880                                 }
2881                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2882                                 {
2883                                         if(!button_pressed)
2884                                                 self.deadflag = DEAD_RESPAWNING;
2885                                 }
2886                                 else if (self.deadflag == DEAD_RESPAWNING)
2887                                 {
2888                                         if(time > self.death_time)
2889                                         {
2890                                                 self.death_time = time + 1; // only retry once a second
2891                                                 respawn();
2892                                         }
2893                                 }
2894                                 ShowRespawnCountdown();
2895                         }
2896                         return;
2897                 }
2898                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2899                 // so (self.deadflag == DEAD_NO) is always true in the code below
2900
2901                 if(g_touchexplode)
2902                 if(time > self.touchexplode_time)
2903                 if(self.classname == "player")
2904                 if(self.deadflag == DEAD_NO)
2905                 if not(IS_INDEPENDENT_PLAYER(self))
2906                 FOR_EACH_PLAYER(other) if(self != other)
2907                 {
2908                         if(time > other.touchexplode_time)
2909                         if(other.deadflag == DEAD_NO)
2910                         if not(IS_INDEPENDENT_PLAYER(other))
2911                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2912                         {
2913                                 PlayerTouchExplode(self, other);
2914                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2915                         }
2916                 }
2917
2918                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2919                 {
2920                         vector dist;
2921
2922                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2923                         dist = self.prevorigin - self.origin;
2924                         dist_z = 0;
2925                         self.lms_traveled_distance += fabs(vlen(dist));
2926
2927                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2928                         {
2929                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2930                                 self.lms_traveled_distance = 0;
2931                         }
2932
2933                         if(time > self.lms_nextcheck)
2934                         {
2935                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2936                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2937                                 {
2938                                         centerprint(self, autocvar_g_lms_campcheck_message);
2939                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2940                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2941                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2942                                 }
2943                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2944                                 self.lms_traveled_distance = 0;
2945                         }
2946                 }
2947
2948                 self.prevorigin = self.origin;
2949
2950                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2951                 {
2952                         if (!self.crouch)
2953                         {
2954                                 self.crouch = TRUE;
2955                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2956                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2957                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2958                         }
2959                 }
2960                 else
2961                 {
2962                         if (self.crouch)
2963                         {
2964                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2965                                 if (!trace_startsolid)
2966                                 {
2967                                         self.crouch = FALSE;
2968                                         self.view_ofs = PL_VIEW_OFS;
2969                                         setsize (self, PL_MIN, PL_MAX);
2970                                 }
2971                         }
2972                 }
2973
2974                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2975                 {
2976                         if(self.bloodloss_timer < time)
2977                         {
2978                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2979                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2980                         }
2981                 }
2982
2983                 FixPlayermodel();
2984
2985                 GrapplingHookFrame();
2986
2987                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2988                 //if(frametime)
2989                 {
2990                         self.items &~= self.items_added;
2991
2992                         W_WeaponFrame();
2993
2994                         self.items_added = 0;
2995                         if(self.items & IT_JETPACK)
2996                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2997                                         self.items_added |= IT_FUEL;
2998
2999                         self.items |= self.items_added;
3000                 }
3001
3002                 player_regen();
3003
3004                 // rot nex charge to the charge limit
3005                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
3006                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
3007
3008                 if(frametime)
3009                         player_anim();
3010
3011                 if(g_ctf)
3012                         ctf_setstatus();
3013
3014                 if(g_nexball)
3015                         nexball_setstatus();
3016
3017                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
3018
3019                 //self.angles_y=self.v_angle_y + 90;   // temp
3020         } else if(gameover) {
3021                 if (intermission_running)
3022                         IntermissionThink ();   // otherwise a button could be missed between
3023                 return;
3024         } else if(self.classname == "observer") {
3025                 ObserverThink();
3026         } else if(self.classname == "spectator") {
3027                 SpectatorThink();
3028         }
3029
3030         if(!zoomstate_set)
3031                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
3032
3033         float oldspectatee_status;
3034         oldspectatee_status = self.spectatee_status;
3035         if(self.classname == "spectator")
3036                 self.spectatee_status = num_for_edict(self.enemy);
3037         else if(self.classname == "observer")
3038                 self.spectatee_status = num_for_edict(self);
3039         else
3040                 self.spectatee_status = 0;
3041         if(self.spectatee_status != oldspectatee_status)
3042         {
3043                 ClientData_Touch(self);
3044                 if(g_race || g_cts)
3045                         race_InitSpectator();
3046         }
3047
3048         if(self.teamkill_soundtime)
3049         if(time > self.teamkill_soundtime)
3050         {
3051                 self.teamkill_soundtime = 0;
3052
3053                 entity oldpusher, oldself;
3054
3055                 oldself = self; self = self.teamkill_soundsource;
3056                 oldpusher = self.pusher; self.pusher = oldself;
3057
3058                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3059
3060                 self.pusher = oldpusher;
3061                 self = oldself;
3062         }
3063
3064         if(self.taunt_soundtime)
3065         if(time > self.taunt_soundtime)
3066         {
3067                 self.taunt_soundtime = 0;
3068                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
3069         }
3070
3071         target_voicescript_next(self);
3072
3073         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3074         if(!self.weapon)
3075                 self.clip_load = self.clip_size = 0;
3076 }
3077
3078 float isInvisibleString(string s)
3079 {
3080         float i, n, c;
3081         s = strdecolorize(s);
3082         for((i = 0), (n = strlen(s)); i < n; ++i)
3083         {
3084                 c = str2chr(s, i);
3085                 switch(c)
3086                 {
3087                         case 0:
3088                         case 32: // space
3089                                 break;
3090                         case 192: // charmap space
3091                                 if (!autocvar_utf8_enable)
3092                                         break;
3093                                 return FALSE;
3094                         case 160: // space in unicode fonts
3095                         case 0xE000 + 192: // utf8 charmap space
3096                                 if (autocvar_utf8_enable)
3097                                         break;
3098                         default:
3099                                 return FALSE;
3100                 }
3101         }
3102         return TRUE;
3103 }
3104
3105 /*
3106 =============
3107 PlayerPostThink
3108
3109 Called every frame for each client after the physics are run
3110 =============
3111 */
3112 .float idlekick_lasttimeleft;
3113 .entity showheadshotbbox;
3114 void showheadshotbbox_think()
3115 {
3116         if(self.owner.showheadshotbbox != self)
3117         {
3118                 remove(self);
3119                 return;
3120         }
3121         self.nextthink = time;
3122         setorigin(self, self.owner.origin);
3123         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3124 }
3125 void PlayerPostThink (void)
3126 {
3127         // Savage: Check for nameless players
3128         if (isInvisibleString(self.netname)) {
3129                 self.netname = "Player";
3130                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3131         }
3132
3133         if(sv_maxidle && frametime)
3134         {
3135                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3136                 float timeleft;
3137                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
3138                 {
3139                         if(self.idlekick_lasttimeleft)
3140                         {
3141                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
3142                                 self.idlekick_lasttimeleft = 0;
3143                         }
3144                         return;
3145                 }
3146                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3147                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3148                 {
3149                         if(!self.idlekick_lasttimeleft)
3150                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3151                 }
3152                 if(timeleft <= 0)
3153                 {
3154                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3155                         AnnounceTo(self, "terminated");
3156                         dropclient(self);
3157                         return;
3158                 }
3159                 else if(timeleft <= 10)
3160                 {
3161                         if(timeleft != self.idlekick_lasttimeleft)
3162                                 AnnounceTo(self, ftos(timeleft));
3163                         self.idlekick_lasttimeleft = timeleft;
3164                 }
3165         }
3166
3167 #ifdef TETRIS
3168         if(self.impulse == 100)
3169                 ImpulseCommands();
3170         if (TetrisPostFrame())
3171                 return;
3172 #endif
3173
3174         CheatFrame();
3175
3176         //CheckPlayerJump();
3177
3178         if(self.classname == "player") {
3179                 CheckRules_Player();
3180                 UpdateChatBubble();
3181                 if (self.impulse)
3182                         ImpulseCommands();
3183                 if (intermission_running)
3184                         return;         // intermission or finale
3185                 GetPressedKeys();
3186         } else if (self.classname == "observer") {
3187                 //do nothing
3188         } else if (self.classname == "spectator") {
3189                 //do nothing
3190         }
3191
3192         /*
3193         float i;
3194         for(i = 0; i < 1000; ++i)
3195         {
3196                 vector end;
3197                 end = self.origin + '0 0 1024' + 512 * randomvec();
3198                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3199                 if(trace_fraction < 1)
3200                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3201                 {
3202                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3203                         break;
3204                 }
3205         }
3206         */
3207
3208         Arena_Warmup();
3209
3210         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3211
3212         if(self.waypointsprite_attachedforcarrier)
3213                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3214
3215         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3216         {
3217                 if(!self.showheadshotbbox)
3218                 {
3219                         self.showheadshotbbox = spawn();
3220                         self.showheadshotbbox.classname = "headshotbbox";
3221                         self.showheadshotbbox.owner = self;
3222                         self.showheadshotbbox.think = showheadshotbbox_think;
3223                         self.showheadshotbbox.nextthink = time;
3224                         self = self.showheadshotbbox;
3225                         self.think();
3226                         self = self.owner;
3227                 }
3228         }
3229         else
3230         {
3231                 if(self.showheadshotbbox)
3232                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3233                 remove(self.showheadshotbbox);
3234         }
3235
3236         playerdemo_write();
3237
3238         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3239         {
3240                 if(!self.stored_netname)
3241                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3242                 if(self.stored_netname != self.netname)
3243                 {
3244                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3245                         strunzone(self.stored_netname);
3246                         self.stored_netname = strzone(self.netname);
3247                 }
3248         }
3249
3250         /*
3251         if(g_race)
3252                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3253         */
3254 }