qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         if(self.alivetime)
 172         {
 173                 if(!inWarmupStage)
 174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 175                 self.alivetime = 0;
 176         }
 177
 178         if(self.vehicle)
 179                 vehicles_exit(VHEF_RELESE);
 180
 181         WaypointSprite_PlayerDead();
 182
 183         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 185
 186         if(self.killcount != -666)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 189
 190                 if(self.just_joined == FALSE) {
 191                         LogTeamchange(self.playerid, -1, 4);
 192                 } else
 193                         self.just_joined = FALSE;
 194         }
 195
 196         PlayerScore_Clear(self); // clear scores when needed
 197
 198         accuracy_resend(self);
 199
 200         self.spectatortime = time;
 201
 202         self.classname = "observer";
 203         self.iscreature = FALSE;
 204         self.teleportable = TELEPORT_SIMPLE;
 205         self.damagedbycontents = FALSE;
 206         self.health = -666;
 207         self.takedamage = DAMAGE_NO;
 208         self.solid = SOLID_NOT;
 209         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 210         self.flags = FL_CLIENT | FL_NOTARGET;
 211         self.armorvalue = 666;
 212         self.effects = 0;
 213         self.armorvalue = autocvar_g_balance_armor_start;
 214         self.pauserotarmor_finished = 0;
 215         self.pauserothealth_finished = 0;
 216         self.pauseregen_finished = 0;
 217         self.damageforcescale = 0;
 218         self.death_time = 0;
 219         self.respawn_flags = 0;
 220         self.respawn_time = 0;
 221         self.stat_respawn_time = 0;
 222         self.alpha = 0;
 223         self.scale = 0;
 224         self.fade_time = 0;
 225         self.pain_frame = 0;
 226         self.pain_finished = 0;
 227         self.strength_finished = 0;
 228         self.invincible_finished = 0;
 229         self.superweapons_finished = 0;
 230         self.pushltime = 0;
 231         self.istypefrag = 0;
 232         self.think = func_null;
 233         self.nextthink = 0;
 234         self.hook_time = 0;
 235         self.deadflag = DEAD_NO;
 236         self.angles = spot.angles;
 237         self.angles_z = 0;
 238         self.fixangle = TRUE;
 239         self.crouch = FALSE;
 240
 241         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 242         self.prevorigin = self.origin;
 243         self.items = 0;
 244         WEPSET_CLEAR_E(self);
 245         self.model = "";
 246         FixPlayermodel();
 247         setmodel(self, "null");
 248         self.drawonlytoclient = self;
 249
 250         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 251         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 252
 253         self.weapon = 0;
 254         self.weaponname = "";
 255         self.switchingweapon = 0;
 256         self.weaponmodel = "";
 257         self.weaponentity = world;
 258         self.exteriorweaponentity = world;
 259         self.killcount = -666;
 260         self.velocity = '0 0 0';
 261         self.avelocity = '0 0 0';
 262         self.punchangle = '0 0 0';
 263         self.punchvector = '0 0 0';
 264         self.oldvelocity = self.velocity;
 265         self.fire_endtime = -1;
 266 }
 267
 268 .float model_randomizer;
 269 void FixPlayermodel()
 270 {
 271         string defaultmodel;
 272         float defaultskin, chmdl, oldskin, n, i;
 273         vector m1, m2;
 274
 275         defaultmodel = "";
 276         defaultskin = 0;
 277         chmdl = FALSE;
 278
 279         if(autocvar_sv_defaultcharacter == 1)
 280         {
 281                 if(teamplay)
 282                 {
 283                         string s;
 284                         s = Team_ColorName_Lower(self.team);
 285                         if(s != "neutral")
 286                         {
 287                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 288                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 289                         }
 290                 }
 291
 292                 if(defaultmodel == "")
 293                 {
 294                         defaultmodel = autocvar_sv_defaultplayermodel;
 295                         defaultskin = autocvar_sv_defaultplayerskin;
 296                 }
 297
 298                 n = tokenize_console(defaultmodel);
 299                 if(n > 0)
 300                         defaultmodel = argv(floor(n * self.model_randomizer));
 301
 302                 i = strstrofs(defaultmodel, ":", 0);
 303                 if(i >= 0)
 304                 {
 305                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 306                         defaultmodel = substring(defaultmodel, 0, i);
 307                 }
 308         }
 309
 310         if(defaultmodel != "")
 311         {
 312                 if (defaultmodel != self.model)
 313                 {
 314                         m1 = self.mins;
 315                         m2 = self.maxs;
 316                         setplayermodel (self, defaultmodel);
 317                         setsize (self, m1, m2);
 318                         chmdl = TRUE;
 319                 }
 320
 321                 oldskin = self.skin;
 322                 self.skin = defaultskin;
 323         } else {
 324                 if (self.playermodel != self.model || self.playermodel == "")
 325                 {
 326                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 327                         m1 = self.mins;
 328                         m2 = self.maxs;
 329                         setplayermodel (self, self.playermodel);
 330                         setsize (self, m1, m2);
 331                         chmdl = TRUE;
 332                 }
 333
 334                 oldskin = self.skin;
 335                 self.skin = stof(self.playerskin);
 336         }
 337
 338         if(chmdl || oldskin != self.skin) // model or skin has changed
 339         {
 340                 self.species = player_getspecies(); // update species
 341                 UpdatePlayerSounds(); // update skin sounds
 342         }
 343
 344         if(!teamplay)
 345                 if(strlen(autocvar_sv_defaultplayercolors))
 346                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 347                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 348 }
 349
 350 /*
 351 =============
 352 PutClientInServer
 353
 354 Called when a client spawns in the server
 355 =============
 356 */
 357 float SpawnEvent_Send(entity to, float sf);
 358 void PutClientInServer (void)
 359 {
 360         if(IS_BOT_CLIENT(self))
 361                 self.classname = "player";
 362         else if(IS_REAL_CLIENT(self))
 363         {
 364                 msg_entity = self;
 365                 WriteByte(MSG_ONE, SVC_SETVIEW);
 366                 WriteEntity(MSG_ONE, self);
 367         }
 368
 369         // reset player keys
 370         self.itemkeys = 0;
 371
 372         MUTATOR_CALLHOOK(PutClientInServer);
 373
 374         if(gameover)
 375                 self.classname = "observer";
 376
 377         if(IS_PLAYER(self))
 378         {
 379                 entity spot, oldself;
 380                 float j;
 381
 382                 accuracy_resend(self);
 383
 384                 if(self.team < 0)
 385                         JoinBestTeam(self, FALSE, TRUE);
 386
 387                 race_PreSpawn();
 388
 389                 spot = SelectSpawnPoint (FALSE);
 390                 if(!spot)
 391                 {
 392                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 393                         return; // spawn failed
 394                 }
 395
 396                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 397
 398                 self.classname = "player";
 399                 self.wasplayer = TRUE;
 400                 self.iscreature = TRUE;
 401                 self.teleportable = TELEPORT_NORMAL;
 402                 self.damagedbycontents = TRUE;
 403                 self.movetype = MOVETYPE_WALK;
 404                 self.solid = SOLID_SLIDEBOX;
 405                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 406                 if(autocvar_g_playerclip_collisions)
 407                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 408                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 409                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 410                 self.frags = FRAGS_PLAYER;
 411                 if(INDEPENDENT_PLAYERS)
 412                         MAKE_INDEPENDENT_PLAYER(self);
 413                 self.flags = FL_CLIENT;
 414                 if(autocvar__notarget)
 415                         self.flags |= FL_NOTARGET;
 416                 self.takedamage = DAMAGE_AIM;
 417                 self.effects = 0;
 418                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 419                 self.air_finished = time + 12;
 420                 self.dmg = 2;
 421                 if(autocvar_g_balance_nex_charge)
 422                 {
 423                         if(autocvar_g_balance_nex_secondary_chargepool)
 424                                 self.nex_chargepool_ammo = 1;
 425                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 426                 }
 427
 428                 if(inWarmupStage)
 429                 {
 430                         self.ammo_shells = warmup_start_ammo_shells;
 431                         self.ammo_nails = warmup_start_ammo_nails;
 432                         self.ammo_rockets = warmup_start_ammo_rockets;
 433                         self.ammo_cells = warmup_start_ammo_cells;
 434                         self.ammo_fuel = warmup_start_ammo_fuel;
 435                         self.health = warmup_start_health;
 436                         self.armorvalue = warmup_start_armorvalue;
 437                         WEPSET_COPY_EA(self, warmup_start_weapons);
 438                 }
 439                 else
 440                 {
 441                         self.ammo_shells = start_ammo_shells;
 442                         self.ammo_nails = start_ammo_nails;
 443                         self.ammo_rockets = start_ammo_rockets;
 444                         self.ammo_cells = start_ammo_cells;
 445                         self.ammo_fuel = start_ammo_fuel;
 446                         self.health = start_health;
 447                         self.armorvalue = start_armorvalue;
 448                         WEPSET_COPY_EA(self, start_weapons);
 449                 }
 450
 451                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 452                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 453                 else
 454                         self.superweapons_finished = 0;
 455
 456                 if(g_weaponarena_random)
 457                 {
 458                         if(g_weaponarena_random_with_laser)
 459                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 460                         W_RandomWeapons(self, g_weaponarena_random);
 461                         if(g_weaponarena_random_with_laser)
 462                                 WEPSET_OR_EW(self, WEP_LASER);
 463                 }
 464
 465                 self.items = start_items;
 466
 467                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 468                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 469                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 470                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 471                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 472                 //extend the pause of rotting if client was reset at the beginning of the countdown
 473                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 474                         self.spawnshieldtime += game_starttime - time;
 475                         self.pauserotarmor_finished += game_starttime - time;
 476                         self.pauserothealth_finished += game_starttime - time;
 477                         self.pauseregen_finished += game_starttime - time;
 478                 }
 479                 self.damageforcescale = 2;
 480                 self.death_time = 0;
 481                 self.respawn_flags = 0;
 482                 self.respawn_time = 0;
 483                 self.stat_respawn_time = 0;
 484                 self.scale = 0;
 485                 self.fade_time = 0;
 486                 self.pain_frame = 0;
 487                 self.pain_finished = 0;
 488                 self.strength_finished = 0;
 489                 self.invincible_finished = 0;
 490                 self.pushltime = 0;
 491                 // players have no think function
 492                 self.think = func_null;
 493                 self.nextthink = 0;
 494                 self.hook_time = 0;
 495                 self.dmg_team = 0;
 496                 self.ballistics_density = autocvar_g_ballistics_density_player;
 497
 498                 self.metertime = 0;
 499
 500                 self.deadflag = DEAD_NO;
 501
 502                 self.angles = spot.angles;
 503
 504                 self.angles_z = 0; // never spawn tilted even if the spot says to
 505                 self.fixangle = TRUE; // turn this way immediately
 506                 self.velocity = '0 0 0';
 507                 self.avelocity = '0 0 0';
 508                 self.punchangle = '0 0 0';
 509                 self.punchvector = '0 0 0';
 510                 self.oldvelocity = self.velocity;
 511                 self.fire_endtime = -1;
 512
 513                 entity spawnevent = spawn();
 514                 spawnevent.owner = self;
 515                 Net_LinkEntity(spawnevent, FALSE, 1, SpawnEvent_Send);
 516
 517                 self.model = "";
 518                 FixPlayermodel();
 519                 self.drawonlytoclient = world;
 520
 521                 self.crouch = FALSE;
 522                 self.view_ofs = PL_VIEW_OFS;
 523                 setsize (self, PL_MIN, PL_MAX);
 524                 self.spawnorigin = spot.origin;
 525                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 526                 // don't reset back to last position, even if new position is stuck in solid
 527                 self.oldorigin = self.origin;
 528                 self.prevorigin = self.origin;
 529                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 530                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 531         self.hud = HUD_NORMAL;
 532
 533                 self.event_damage = PlayerDamage;
 534
 535                 self.bot_attack = TRUE;
 536
 537                 self.statdraintime = time + 5;
 538                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 539
 540                 if(self.killcount == -666) {
 541                         PlayerScore_Clear(self);
 542                         self.killcount = 0;
 543                 }
 544
 545                 CL_SpawnWeaponentity();
 546                 self.alpha = default_player_alpha;
 547                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 548                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 549
 550                 self.speedrunning = FALSE;
 551
 552                 race_PostSpawn(spot);
 553
 554                 //stuffcmd(self, "chase_active 0");
 555                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 556
 557                 target_voicescript_clear(self);
 558
 559                 // reset fields the weapons may use
 560                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 561                 {
 562                         weapon_action(j, WR_RESETPLAYER);
 563
 564                         // all weapons must be fully loaded when we spawn
 565                         entity e;
 566                         e = get_weaponinfo(j);
 567                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 568                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 569                 }
 570
 571                 oldself = self;
 572                 self = spot;
 573                         activator = oldself;
 574                                 string s;
 575                                 s = self.target;
 576                                 self.target = string_null;
 577                                 SUB_UseTargets();
 578                                 self.target = s;
 579                         activator = world;
 580                 self = oldself;
 581
 582                 spawn_spot = spot;
 583                 MUTATOR_CALLHOOK(PlayerSpawn);
 584
 585                 if(autocvar_spawn_debug)
 586                 {
 587                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 588                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 589                 }
 590
 591                 self.switchweapon = w_getbestweapon(self);
 592                 self.cnt = -1; // W_LastWeapon will not complain
 593                 self.weapon = 0;
 594                 self.weaponname = "";
 595                 self.switchingweapon = 0;
 596
 597                 if(!inWarmupStage)
 598                         if(!self.alivetime)
 599                                 self.alivetime = time;
 600
 601                 antilag_clear(self);
 602         }
 603         else if(IS_OBSERVER(self))
 604         {
 605                 PutObserverInServer ();
 606         }
 607 }
 608
 609 .float ebouncefactor, ebouncestop; // electro's values
 610 // TODO do we need all these fields, or should we stop autodetecting runtime
 611 // changes and just have a console command to update this?
 612 float ClientInit_SendEntity(entity to, float sf)
 613 {
 614         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 615         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 616         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 617         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 618         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 619         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 620         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 628         if(sv_foginterval && world.fog != "")
 629                 WriteString(MSG_ENTITY, world.fog);
 630         else
 631                 WriteString(MSG_ENTITY, "");
 632         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 633         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 634         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 635         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 636         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 637         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 638         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 639         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 640         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 641         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 642         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 643         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 644         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 645         return TRUE;
 646 }
 647
 648 void ClientInit_CheckUpdate()
 649 {
 650         self.nextthink = time;
 651         if(self.count != autocvar_g_balance_armor_blockpercent)
 652         {
 653                 self.count = autocvar_g_balance_armor_blockpercent;
 654                 self.SendFlags |= 1;
 655         }
 656         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 657         {
 658                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 659                 self.SendFlags |= 1;
 660         }
 661         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 662         {
 663                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 664                 self.SendFlags |= 1;
 665         }
 666         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 667         {
 668                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 669                 self.SendFlags |= 1;
 670         }
 671         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 672         {
 673                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 674                 self.SendFlags |= 1;
 675         }
 676         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 677         {
 678                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 679                 self.SendFlags |= 1;
 680         }
 681 }
 682
 683 void ClientInit_Spawn()
 684 {
 685         entity o;
 686         entity e;
 687         e = spawn();
 688         e.classname = "clientinit";
 689         e.think = ClientInit_CheckUpdate;
 690         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 691
 692         o = self;
 693         self = e;
 694         ClientInit_CheckUpdate();
 695         self = o;
 696 }
 697
 698 /*
 699 =============
 700 SetNewParms
 701 =============
 702 */
 703 void SetNewParms (void)
 704 {
 705         // initialize parms for a new player
 706         parm1 = -(86400 * 366);
 707 }
 708
 709 /*
 710 =============
 711 SetChangeParms
 712 =============
 713 */
 714 void SetChangeParms (void)
 715 {
 716         // save parms for level change
 717         parm1 = self.parm_idlesince - time;
 718 }
 719
 720 /*
 721 =============
 722 DecodeLevelParms
 723 =============
 724 */
 725 void DecodeLevelParms (void)
 726 {
 727         // load parms
 728         self.parm_idlesince = parm1;
 729         if(self.parm_idlesince == -(86400 * 366))
 730                 self.parm_idlesince = time;
 731
 732         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 733         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 734 }
 735
 736 /*
 737 =============
 738 ClientKill
 739
 740 Called when a client types 'kill' in the console
 741 =============
 742 */
 743
 744 .float clientkill_nexttime;
 745 void ClientKill_Now_TeamChange()
 746 {
 747         if(self.killindicator_teamchange == -1)
 748         {
 749                 JoinBestTeam( self, FALSE, TRUE );
 750         }
 751         else if(self.killindicator_teamchange == -2)
 752         {
 753                 if(blockSpectators)
 754                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 755                 PutObserverInServer();
 756         }
 757         else
 758                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 759         self.killindicator_teamchange = 0;
 760 }
 761
 762 void ClientKill_Now()
 763 {
 764         if(self.vehicle)
 765         {
 766             vehicles_exit(VHEF_RELESE);
 767             if(!self.killindicator_teamchange)
 768             {
 769             self.vehicle_health = -1;
 770             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 771             }
 772         }
 773
 774         if(self.killindicator && !wasfreed(self.killindicator))
 775                 remove(self.killindicator);
 776
 777         self.killindicator = world;
 778
 779         if(self.killindicator_teamchange)
 780                 ClientKill_Now_TeamChange();
 781
 782         // in any case:
 783         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 784
 785         // now I am sure the player IS dead
 786 }
 787 void KillIndicator_Think()
 788 {
 789         if (gameover)
 790         {
 791                 self.owner.killindicator = world;
 792                 remove(self);
 793                 return;
 794         }
 795
 796         if (self.owner.alpha < 0 && !self.owner.vehicle)
 797         {
 798                 self.owner.killindicator = world;
 799                 remove(self);
 800                 return;
 801         }
 802
 803         if(self.cnt <= 0)
 804         {
 805                 self = self.owner;
 806                 ClientKill_Now(); // no oldself needed
 807                 return;
 808         }
 809     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 810     {
 811         self.nextthink = time + 1;
 812         self.cnt -= 1;
 813     }
 814         else
 815         {
 816                 if(self.cnt <= 10)
 817                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 818                 if(IS_REAL_CLIENT(self.owner))
 819                 {
 820                         if(self.cnt <= 10)
 821                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
 822                 }
 823                 self.nextthink = time + 1;
 824                 self.cnt -= 1;
 825         }
 826 }
 827
 828 float clientkilltime;
 829 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 830 {
 831         float killtime;
 832         float starttime;
 833         entity e;
 834
 835         if (gameover)
 836                 return;
 837
 838         killtime = autocvar_g_balance_kill_delay;
 839
 840         if(g_race_qualifying || g_cts)
 841                 killtime = 0;
 842
 843     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 844     {
 845                 remove(self.killindicator);
 846                 self.killindicator = world;
 847
 848         ClientKill_Now(); // allow instant kill in this case
 849         return;
 850     }
 851
 852         self.killindicator_teamchange = targetteam;
 853
 854     if(!self.killindicator)
 855         {
 856                 if(self.deadflag == DEAD_NO)
 857                 {
 858                         killtime = max(killtime, self.clientkill_nexttime - time);
 859                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 860                 }
 861
 862                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 863                 {
 864                         ClientKill_Now();
 865                 }
 866                 else
 867                 {
 868                         starttime = max(time, clientkilltime);
 869
 870                         self.killindicator = spawn();
 871                         self.killindicator.owner = self;
 872                         self.killindicator.scale = 0.5;
 873                         setattachment(self.killindicator, self, "");
 874                         setorigin(self.killindicator, '0 0 52');
 875                         self.killindicator.think = KillIndicator_Think;
 876                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 877                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 878                         self.killindicator.cnt = ceil(killtime);
 879                         self.killindicator.count = bound(0, ceil(killtime), 10);
 880                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 881
 882                         for(e = world; (e = find(e, classname, "body")) != world; )
 883                         {
 884                                 if(e.enemy != self)
 885                                         continue;
 886                                 e.killindicator = spawn();
 887                                 e.killindicator.owner = e;
 888                                 e.killindicator.scale = 0.5;
 889                                 setattachment(e.killindicator, e, "");
 890                                 setorigin(e.killindicator, '0 0 52');
 891                                 e.killindicator.think = KillIndicator_Think;
 892                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 893                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 894                                 e.killindicator.cnt = ceil(killtime);
 895                         }
 896                         self.lip = 0;
 897                 }
 898         }
 899         if(self.killindicator)
 900         {
 901                 if(targetteam == 0) // just die
 902                 {
 903                         self.killindicator.colormod = '0 0 0';
 904                         if(IS_REAL_CLIENT(self))
 905                         if(self.killindicator.cnt > 0)
 906                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 907                 }
 908                 else if(targetteam == -1) // auto
 909                 {
 910                         self.killindicator.colormod = '0 1 0';
 911                         if(IS_REAL_CLIENT(self))
 912                         if(self.killindicator.cnt > 0)
 913                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 914                 }
 915                 else if(targetteam == -2) // spectate
 916                 {
 917                         self.killindicator.colormod = '0.5 0.5 0.5';
 918                         if(IS_REAL_CLIENT(self))
 919                         if(self.killindicator.cnt > 0)
 920                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 921                 }
 922                 else
 923                 {
 924                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 925                         if(IS_REAL_CLIENT(self))
 926                         if(self.killindicator.cnt > 0)
 927                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 928                 }
 929         }
 930
 931 }
 932
 933 void ClientKill (void)
 934 {
 935         if(gameover) return;
 936         if(self.player_blocked) return;
 937         if(self.freezetag_frozen) return;
 938
 939         ClientKill_TeamChange(0);
 940 }
 941
 942 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 943 {
 944     e.killindicator = spawn();
 945     e.killindicator.owner = e;
 946     e.killindicator.think = KillIndicator_Think;
 947     e.killindicator.nextthink = time + (e.lip) * 0.05;
 948     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 949     e.killindicator.health = 1; // this is used to indicate that it should be silent
 950     e.lip = 0;
 951 }
 952
 953 void FixClientCvars(entity e)
 954 {
 955         // send prediction settings to the client
 956         stuffcmd(e, "\nin_bindmap 0 0\n");
 957         if(g_race || g_cts)
 958                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 959         if(autocvar_g_antilag == 3) // client side hitscan
 960                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 961         if(autocvar_sv_gentle)
 962                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 963         /*
 964          * we no longer need to stuff this. Remove this comment block if you feel
 965          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 966         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 967         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 968         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 969         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 970         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 971         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 972         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 973         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 974         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 975         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 976         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 977         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 978         stuffcmd(e, "cl_movement_edgefriction 1\n");
 979          */
 980 }
 981
 982 float PlayerInIDList(entity p, string idlist)
 983 {
 984         float n, i;
 985         string s;
 986
 987         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 988         if not(p.crypto_idfp)
 989                 return 0;
 990
 991         // this function allows abbreviated player IDs too!
 992         n = tokenize_console(idlist);
 993         for(i = 0; i < n; ++i)
 994         {
 995                 s = argv(i);
 996                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 997                         return 1;
 998         }
 999
1000         return 0;
1001 }
1002
1003 /*
1004 =============
1005 ClientConnect
1006
1007 Called when a client connects to the server
1008 =============
1009 */
1010 void DecodeLevelParms (void);
1011 //void dom_player_join_team(entity pl);
1012 void set_dom_state(entity e);
1013 void ClientConnect (void)
1014 {
1015         float t;
1016
1017         if(IS_CLIENT(self))
1018         {
1019                 print("Warning: ClientConnect, but already connected!\n");
1020                 return;
1021         }
1022
1023         if(Ban_MaybeEnforceBanOnce(self))
1024                 return;
1025
1026         DecodeLevelParms();
1027
1028 #ifdef WATERMARK
1029         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1030 #endif
1031
1032         self.classname = "player_joining";
1033
1034         self.flags = FL_CLIENT;
1035         self.version_nagtime = time + 10 + random() * 10;
1036
1037         if(player_count<0)
1038         {
1039                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1040                 player_count = 0;
1041         }
1042
1043         PlayerScore_Attach(self);
1044         ClientData_Attach();
1045         accuracy_init(self);
1046
1047         bot_clientconnect();
1048
1049         playerdemo_init();
1050
1051         anticheat_init();
1052
1053         race_PreSpawnObserver();
1054
1055         // identify the right forced team
1056         if(autocvar_g_campaign)
1057         {
1058                 if(IS_REAL_CLIENT(self)) // only players, not bots
1059                 {
1060                         switch(autocvar_g_campaign_forceteam)
1061                         {
1062                                 case 1: self.team_forced = NUM_TEAM_1; break;
1063                                 case 2: self.team_forced = NUM_TEAM_2; break;
1064                                 case 3: self.team_forced = NUM_TEAM_3; break;
1065                                 case 4: self.team_forced = NUM_TEAM_4; break;
1066                                 default: self.team_forced = 0;
1067                         }
1068                 }
1069         }
1070         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1071                 self.team_forced = NUM_TEAM_1;
1072         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1073                 self.team_forced = NUM_TEAM_2;
1074         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1075                 self.team_forced = NUM_TEAM_3;
1076         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1077                 self.team_forced = NUM_TEAM_4;
1078         else if(autocvar_g_forced_team_otherwise == "red")
1079                 self.team_forced = NUM_TEAM_1;
1080         else if(autocvar_g_forced_team_otherwise == "blue")
1081                 self.team_forced = NUM_TEAM_2;
1082         else if(autocvar_g_forced_team_otherwise == "yellow")
1083                 self.team_forced = NUM_TEAM_3;
1084         else if(autocvar_g_forced_team_otherwise == "pink")
1085                 self.team_forced = NUM_TEAM_4;
1086         else if(autocvar_g_forced_team_otherwise == "spectate")
1087                 self.team_forced = -1;
1088         else if(autocvar_g_forced_team_otherwise == "spectator")
1089                 self.team_forced = -1;
1090         else
1091                 self.team_forced = 0;
1092
1093         if(!teamplay)
1094                 if(self.team_forced > 0)
1095                         self.team_forced = 0;
1096
1097         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1098
1099         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1100                 self.classname = "observer";
1101         } else {
1102                 if(teamplay)
1103                 {
1104                         if(autocvar_g_balance_teams)
1105                         {
1106                                 self.classname = "player";
1107                                 campaign_bots_may_start = 1;
1108                         }
1109                         else
1110                         {
1111                                 self.classname = "observer"; // do it anyway
1112                         }
1113                 }
1114                 else
1115                 {
1116                         self.classname = "player";
1117                         campaign_bots_may_start = 1;
1118                 }
1119         }
1120
1121         self.playerid = (playerid_last = playerid_last + 1);
1122
1123         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1124
1125     if(IS_BOT_CLIENT(self))
1126         PlayerStats_AddPlayer(self);
1127
1128         if(autocvar_sv_eventlog)
1129                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1130
1131         LogTeamchange(self.playerid, self.team, 1);
1132
1133         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1134
1135         self.netname_previous = strzone(self.netname);
1136
1137         if(IS_PLAYER(self) && teamplay)
1138                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1139         else
1140                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1141
1142         stuffcmd(self, strcat(clientstuff, "\n"));
1143         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1144
1145         FixClientCvars(self);
1146
1147         // spawnfunc_waypoint sprites
1148         WaypointSprite_InitClient(self);
1149
1150         // Wazat's grappling hook
1151         SetGrappleHookBindings();
1152
1153         // get version info from player
1154         stuffcmd(self, "cmd clientversion $gameversion\n");
1155
1156         // get other cvars from player
1157         GetCvars(0);
1158
1159         // notify about available teams
1160         if(teamplay)
1161         {
1162                 CheckAllowedTeams(self);
1163                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1164                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1165         }
1166         else
1167                 stuffcmd(self, "set _teams_available 0\n");
1168
1169         attach_entcs();
1170
1171         bot_relinkplayerlist();
1172
1173         self.spectatortime = time;
1174         if(blockSpectators)
1175         {
1176                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1177         }
1178
1179         self.jointime = time;
1180         self.allowed_timeouts = autocvar_sv_timeout_number;
1181
1182         if(IS_REAL_CLIENT(self))
1183         {
1184                 if(!autocvar_g_campaign)
1185                 {
1186                         self.motd_actived_time = -1;
1187                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1188                 }
1189
1190                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1191                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1192         }
1193
1194         if(!sv_foginterval && world.fog != "")
1195                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1196
1197         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1198         {
1199                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1200                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1201         }
1202         else
1203                 self.hitplotfh = -1;
1204
1205         if(g_race || g_cts) {
1206                 string rr;
1207                 if(g_cts)
1208                         rr = CTS_RECORD;
1209                 else
1210                         rr = RACE_RECORD;
1211
1212                 msg_entity = self;
1213                 race_send_recordtime(MSG_ONE);
1214                 race_send_speedaward(MSG_ONE);
1215
1216                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1217                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1218                 race_send_speedaward_alltimebest(MSG_ONE);
1219
1220                 float i;
1221                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1222                         race_SendRankings(i, 0, 0, MSG_ONE);
1223                 }
1224         }
1225         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1226                 send_CSQC_teamnagger();
1227
1228         CheatInitClient();
1229
1230         CSQCMODEL_AUTOINIT();
1231
1232         self.model_randomizer = random();
1233
1234         if(IS_REAL_CLIENT(self))
1235                 sv_notice_join();
1236
1237         MUTATOR_CALLHOOK(ClientConnect);
1238 }
1239 /*
1240 =============
1241 ClientDisconnect
1242
1243 Called when a client disconnects from the server
1244 =============
1245 */
1246 .entity chatbubbleentity;
1247 void ReadyCount();
1248 void ClientDisconnect (void)
1249 {
1250         if(self.vehicle)
1251             vehicles_exit(VHEF_RELESE);
1252
1253         if not(IS_CLIENT(self))
1254         {
1255                 print("Warning: ClientDisconnect without ClientConnect\n");
1256                 return;
1257         }
1258
1259         PlayerStats_AddGlobalInfo(self);
1260
1261         CheatShutdownClient();
1262
1263         if(self.hitplotfh >= 0)
1264         {
1265                 fclose(self.hitplotfh);
1266                 self.hitplotfh = -1;
1267         }
1268
1269         anticheat_report();
1270         anticheat_shutdown();
1271
1272         playerdemo_shutdown();
1273
1274         bot_clientdisconnect();
1275
1276         if(self.entcs)
1277                 detach_entcs();
1278
1279         if(autocvar_sv_eventlog)
1280                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1281
1282         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1283
1284         MUTATOR_CALLHOOK(ClientDisconnect);
1285
1286         Portal_ClearAll(self);
1287
1288         RemoveGrapplingHook(self);
1289
1290         // Here, everything has been done that requires this player to be a client.
1291
1292         self.flags &~= FL_CLIENT;
1293
1294         if (self.chatbubbleentity)
1295                 remove (self.chatbubbleentity);
1296
1297         if (self.killindicator)
1298                 remove (self.killindicator);
1299
1300         WaypointSprite_PlayerGone();
1301
1302         bot_relinkplayerlist();
1303
1304         accuracy_free(self);
1305         ClientData_Detach();
1306         PlayerScore_Detach(self);
1307
1308         if(self.netname_previous)
1309                 strunzone(self.netname_previous);
1310         if(self.clientstatus)
1311                 strunzone(self.clientstatus);
1312         if(self.weaponorder_byimpulse)
1313                 strunzone(self.weaponorder_byimpulse);
1314
1315         ClearPlayerSounds();
1316
1317         if(self.personal)
1318                 remove(self.personal);
1319
1320         self.playerid = 0;
1321         ReadyCount();
1322
1323         // free cvars
1324         GetCvars(-1);
1325 }
1326
1327 .float BUTTON_CHAT;
1328 void ChatBubbleThink()
1329 {
1330         self.nextthink = time;
1331         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1332         {
1333                 if(self.owner) // but why can that ever be world?
1334                         self.owner.chatbubbleentity = world;
1335                 remove(self);
1336                 return;
1337         }
1338         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1339 #ifdef TETRIS
1340                 || self.owner.tetris_on
1341 #endif
1342         )
1343                 self.model = self.mdl;
1344         else
1345                 self.model = "";
1346 }
1347
1348 void UpdateChatBubble()
1349 {
1350         if (self.alpha < 0)
1351                 return;
1352         // spawn a chatbubble entity if needed
1353         if (!self.chatbubbleentity)
1354         {
1355                 self.chatbubbleentity = spawn();
1356                 self.chatbubbleentity.owner = self;
1357                 self.chatbubbleentity.exteriormodeltoclient = self;
1358                 self.chatbubbleentity.think = ChatBubbleThink;
1359                 self.chatbubbleentity.nextthink = time;
1360                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1361                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1362                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1363                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1364                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1365                 self.chatbubbleentity.model = "";
1366                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1367         }
1368 }
1369
1370
1371 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1372 // added to the model skins
1373 /*void UpdateColorModHack()
1374 {
1375         float c;
1376         c = self.clientcolors & 15;
1377         // LordHavoc: only bothering to support white, green, red, yellow, blue
1378              if (!teamplay) self.colormod = '0 0 0';
1379         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1380         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1381         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1382         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1383         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1384         else self.colormod = '1 1 1';
1385 }*/
1386
1387 void respawn(void)
1388 {
1389         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1390         {
1391                 self.solid = SOLID_NOT;
1392                 self.takedamage = DAMAGE_NO;
1393                 self.movetype = MOVETYPE_FLY;
1394                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1395                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1396                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1397                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1398                 if(autocvar_g_respawn_ghosts_maxtime)
1399                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1400         }
1401
1402         CopyBody(1);
1403
1404         self.effects |= EF_NODRAW; // prevent another CopyBody
1405         PutClientInServer();
1406 }
1407
1408 void play_countdown(float finished, string samp)
1409 {
1410         if(IS_REAL_CLIENT(self))
1411                 if(floor(finished - time - frametime) != floor(finished - time))
1412                         if(finished - time < 6)
1413                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1414 }
1415
1416 void player_powerups (void)
1417 {
1418         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1419         olditems = self.items;
1420
1421         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1422                 self.modelflags |= MF_ROCKET;
1423         else
1424                 self.modelflags &~= MF_ROCKET;
1425
1426         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1427
1428         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1429                 return;
1430
1431         Fire_ApplyDamage(self);
1432         Fire_ApplyEffect(self);
1433
1434         if not(g_minstagib)
1435         {
1436                 if (self.items & IT_STRENGTH)
1437                 {
1438                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1439                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1440                         if (time > self.strength_finished)
1441                         {
1442                                 self.items = self.items - (self.items & IT_STRENGTH);
1443                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1444                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1445                         }
1446                 }
1447                 else
1448                 {
1449                         if (time < self.strength_finished)
1450                         {
1451                                 self.items = self.items | IT_STRENGTH;
1452                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1453                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1454                         }
1455                 }
1456                 if (self.items & IT_INVINCIBLE)
1457                 {
1458                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1459                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1460                         if (time > self.invincible_finished)
1461                         {
1462                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1463                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1464                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1465                         }
1466                 }
1467                 else
1468                 {
1469                         if (time < self.invincible_finished)
1470                         {
1471                                 self.items = self.items | IT_INVINCIBLE;
1472                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1473                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1474                         }
1475                 }
1476                 if (self.items & IT_SUPERWEAPON)
1477                 {
1478                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1479                         {
1480                                 self.superweapons_finished = 0;
1481                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1482                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1483                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1484                         }
1485                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1486                         {
1487                                 // don't let them run out
1488                         }
1489                         else
1490                         {
1491                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1492                                 if (time > self.superweapons_finished)
1493                                 {
1494                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1495                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1496                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1497                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1498                                 }
1499                         }
1500                 }
1501                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1502                 {
1503                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1504                         {
1505                                 self.items = self.items | IT_SUPERWEAPON;
1506                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1507                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1508                         }
1509                         else
1510                         {
1511                                 self.superweapons_finished = 0;
1512                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1513                         }
1514                 }
1515                 else
1516                 {
1517                         self.superweapons_finished = 0;
1518                 }
1519         }
1520
1521         if(autocvar_g_nodepthtestplayers)
1522                 self.effects = self.effects | EF_NODEPTHTEST;
1523
1524         if(autocvar_g_fullbrightplayers)
1525                 self.effects = self.effects | EF_FULLBRIGHT;
1526
1527         // midair gamemode: damage only while in the air
1528         // if in midair mode, being on ground grants temporary invulnerability
1529         // (this is so that multishot weapon don't clear the ground flag on the
1530         // first damage in the frame, leaving the player vulnerable to the
1531         // remaining hits in the same frame)
1532         if (self.flags & FL_ONGROUND)
1533         if (g_midair)
1534                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1535
1536         if (time >= game_starttime)
1537         if (time < self.spawnshieldtime)
1538                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1539
1540         MUTATOR_CALLHOOK(PlayerPowerups);
1541 }
1542
1543 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1544 {
1545         if(current > stable)
1546                 return current;
1547         else if(current > stable - 0.25) // when close enough, "snap"
1548                 return stable;
1549         else
1550                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1551 }
1552
1553 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1554 {
1555         if(current < stable)
1556                 return current;
1557         else if(current < stable + 0.25) // when close enough, "snap"
1558                 return stable;
1559         else
1560                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1561 }
1562
1563 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1564 {
1565         if(current > rotstable)
1566         {
1567                 if(rotframetime > 0)
1568                 {
1569                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1570                         current = max(rotstable, current - rotlinear * rotframetime);
1571                 }
1572         }
1573         else if(current < regenstable)
1574         {
1575                 if(regenframetime > 0)
1576                 {
1577                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1578                         current = min(regenstable, current + regenlinear * regenframetime);
1579                 }
1580         }
1581
1582         if(current > limit)
1583                 current = limit;
1584
1585         return current;
1586 }
1587
1588 void player_regen (void)
1589 {
1590         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1591         maxh = autocvar_g_balance_health_rotstable;
1592         maxa = autocvar_g_balance_armor_rotstable;
1593         maxf = autocvar_g_balance_fuel_rotstable;
1594         minh = autocvar_g_balance_health_regenstable;
1595         mina = autocvar_g_balance_armor_regenstable;
1596         minf = autocvar_g_balance_fuel_regenstable;
1597         limith = autocvar_g_balance_health_limit;
1598         limita = autocvar_g_balance_armor_limit;
1599         limitf = autocvar_g_balance_fuel_limit;
1600
1601         max_mod = regen_mod = rot_mod = limit_mod = 1;
1602
1603         maxh = maxh * max_mod;
1604         //maxa = maxa * max_mod;
1605         //maxf = maxf * max_mod;
1606         minh = minh * max_mod;
1607         //mina = mina * max_mod;
1608         //minf = minf * max_mod;
1609         limith = limith * limit_mod;
1610         limita = limita * limit_mod;
1611         //limitf = limitf * limit_mod;
1612
1613         if(g_ca)
1614                 rot_mod = 0;
1615
1616         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1617         {
1618                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1619                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1620
1621                 // if player rotted to death...  die!
1622                 if(self.health < 1)
1623                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1624         }
1625
1626         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1627                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1628 }
1629
1630 float zoomstate_set;
1631 void SetZoomState(float z)
1632 {
1633         if(z != self.zoomstate)
1634         {
1635                 self.zoomstate = z;
1636                 ClientData_Touch(self);
1637         }
1638         zoomstate_set = 1;
1639 }
1640
1641 void GetPressedKeys(void) {
1642         MUTATOR_CALLHOOK(GetPressedKeys);
1643         if (self.movement_x > 0) // get if movement keys are pressed
1644         {       // forward key pressed
1645                 self.pressedkeys |= KEY_FORWARD;
1646                 self.pressedkeys &~= KEY_BACKWARD;
1647         }
1648         else if (self.movement_x < 0)
1649         {       // backward key pressed
1650                 self.pressedkeys |= KEY_BACKWARD;
1651                 self.pressedkeys &~= KEY_FORWARD;
1652         }
1653         else
1654         {       // no x input
1655                 self.pressedkeys &~= KEY_FORWARD;
1656                 self.pressedkeys &~= KEY_BACKWARD;
1657         }
1658
1659         if (self.movement_y > 0)
1660         {       // right key pressed
1661                 self.pressedkeys |= KEY_RIGHT;
1662                 self.pressedkeys &~= KEY_LEFT;
1663         }
1664         else if (self.movement_y < 0)
1665         {       // left key pressed
1666                 self.pressedkeys |= KEY_LEFT;
1667                 self.pressedkeys &~= KEY_RIGHT;
1668         }
1669         else
1670         {       // no y input
1671                 self.pressedkeys &~= KEY_RIGHT;
1672                 self.pressedkeys &~= KEY_LEFT;
1673         }
1674
1675         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1676                 self.pressedkeys |= KEY_JUMP;
1677         else
1678                 self.pressedkeys &~= KEY_JUMP;
1679         if (self.BUTTON_CROUCH)
1680                 self.pressedkeys |= KEY_CROUCH;
1681         else
1682                 self.pressedkeys &~= KEY_CROUCH;
1683
1684         if (self.BUTTON_ATCK)
1685                 self.pressedkeys |= KEY_ATCK;
1686         else
1687                 self.pressedkeys &~= KEY_ATCK;
1688         if (self.BUTTON_ATCK2)
1689                 self.pressedkeys |= KEY_ATCK2;
1690         else
1691                 self.pressedkeys &~= KEY_ATCK2;
1692 }
1693
1694 /*
1695 ======================
1696 spectate mode routines
1697 ======================
1698 */
1699
1700 void SpectateCopy(entity spectatee) {
1701         other = spectatee;
1702         MUTATOR_CALLHOOK(SpectateCopy);
1703         self.armortype = spectatee.armortype;
1704         self.armorvalue = spectatee.armorvalue;
1705         self.ammo_cells = spectatee.ammo_cells;
1706         self.ammo_shells = spectatee.ammo_shells;
1707         self.ammo_nails = spectatee.ammo_nails;
1708         self.ammo_rockets = spectatee.ammo_rockets;
1709         self.ammo_fuel = spectatee.ammo_fuel;
1710         self.clip_load = spectatee.clip_load;
1711         self.clip_size = spectatee.clip_size;
1712         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1713         self.health = spectatee.health;
1714         self.impulse = 0;
1715         self.items = spectatee.items;
1716         self.last_pickup = spectatee.last_pickup;
1717         self.hit_time = spectatee.hit_time;
1718         self.metertime = spectatee.metertime;
1719         self.strength_finished = spectatee.strength_finished;
1720         self.invincible_finished = spectatee.invincible_finished;
1721         self.pressedkeys = spectatee.pressedkeys;
1722         WEPSET_COPY_EE(self, spectatee);
1723         self.switchweapon = spectatee.switchweapon;
1724         self.switchingweapon = spectatee.switchingweapon;
1725         self.weapon = spectatee.weapon;
1726         self.nex_charge = spectatee.nex_charge;
1727         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1728         self.hagar_load = spectatee.hagar_load;
1729         self.minelayer_mines = spectatee.minelayer_mines;
1730         self.punchangle = spectatee.punchangle;
1731         self.view_ofs = spectatee.view_ofs;
1732         self.velocity = spectatee.velocity;
1733         self.dmg_take = spectatee.dmg_take;
1734         self.dmg_save = spectatee.dmg_save;
1735         self.dmg_inflictor = spectatee.dmg_inflictor;
1736         self.v_angle = spectatee.v_angle;
1737         self.angles = spectatee.v_angle;
1738         if(!self.BUTTON_USE)
1739                 self.fixangle = TRUE;
1740         setorigin(self, spectatee.origin);
1741         setsize(self, spectatee.mins, spectatee.maxs);
1742         SetZoomState(spectatee.zoomstate);
1743
1744     anticheat_spectatecopy(spectatee);
1745         self.hud = spectatee.hud;
1746         if(spectatee.vehicle)
1747     {
1748         self.fixangle = FALSE;
1749         //self.velocity = spectatee.vehicle.velocity;
1750         self.vehicle_health = spectatee.vehicle_health;
1751         self.vehicle_shield = spectatee.vehicle_shield;
1752         self.vehicle_energy = spectatee.vehicle_energy;
1753         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1754         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1755         self.vehicle_reload1 = spectatee.vehicle_reload1;
1756         self.vehicle_reload2 = spectatee.vehicle_reload2;
1757
1758         msg_entity = self;
1759
1760         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1761             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1762             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1763             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1764
1765         //WriteByte (MSG_ONE, SVC_SETVIEW);
1766         //    WriteEntity(MSG_ONE, self);
1767         //makevectors(spectatee.v_angle);
1768         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1769     }
1770 }
1771
1772 float SpectateUpdate() {
1773         if(!self.enemy)
1774             return 0;
1775
1776         if (self == self.enemy)
1777                 return 0;
1778
1779         if not(IS_PLAYER(self.enemy))
1780                 return 0;
1781
1782         SpectateCopy(self.enemy);
1783
1784         return 1;
1785 }
1786
1787
1788 float SpectateSet()
1789 {
1790         if(self.enemy.classname != "player")
1791                 return FALSE;
1792         /*if(self.enemy.vehicle)
1793         {
1794
1795                 msg_entity = self;
1796                 WriteByte(MSG_ONE, SVC_SETVIEW);
1797                 WriteEntity(MSG_ONE, self.enemy);
1798                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1799
1800                 self.movetype = MOVETYPE_NONE;
1801                 accuracy_resend(self);
1802         }
1803         else
1804         {*/
1805                 msg_entity = self;
1806                 WriteByte(MSG_ONE, SVC_SETVIEW);
1807                 WriteEntity(MSG_ONE, self.enemy);
1808                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1809                 self.movetype = MOVETYPE_NONE;
1810                 accuracy_resend(self);
1811
1812                 if(!SpectateUpdate())
1813                         PutObserverInServer();
1814         //}
1815         return TRUE;
1816 }
1817
1818 float Spectate(entity pl)
1819 {
1820         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1821         if(pl.team != self.team)
1822                 return 0;
1823
1824         self.enemy = pl;
1825         return SpectateSet();
1826 }
1827
1828 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1829 entity CA_SpectateNext(entity start) {
1830         if (start.team == self.team) {
1831                 return start;
1832         }
1833
1834         other = start;
1835         // continue from current player
1836         while(other && other.team != self.team) {
1837                 other = find(other, classname, "player");
1838         }
1839
1840         if (!other) {
1841                 // restart from begining
1842                 other = find(other, classname, "player");
1843                 while(other && other.team != self.team) {
1844                         other = find(other, classname, "player");
1845                 }
1846         }
1847
1848         return other;
1849 }
1850
1851 float SpectateNext()
1852 {
1853         other = find(self.enemy, classname, "player");
1854
1855         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1856                 // CA and ca players when spectating enemies is forbidden
1857                 other = CA_SpectateNext(other);
1858         } else {
1859                 // other modes and ca spectators or spectating enemies is allowed
1860                 if (!other)
1861                         other = find(other, classname, "player");
1862         }
1863
1864         if (other)
1865                 self.enemy = other;
1866
1867         return SpectateSet();
1868 }
1869
1870 float SpectatePrev()
1871 {
1872         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1873         other = findchain(classname, "player");
1874         if not(other) // no player
1875                 return FALSE;
1876
1877         entity first = other;
1878         // skip players until current spectated player
1879         if(self.enemy)
1880         while(other && other != self.enemy)
1881                 other = other.chain;
1882
1883         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1884         {
1885                 do { other = other.chain; }
1886                 while(other && other.team != self.team);
1887
1888                 if not(other)
1889                 {
1890                         other = first;
1891                         while(other.team != self.team)
1892                                 other = other.chain;
1893                         if(other == self.enemy)
1894                                 return TRUE;
1895                 }
1896         }
1897         else
1898         {
1899                 if(other.chain)
1900                         other = other.chain;
1901                 else
1902                         other = first;
1903         }
1904         self.enemy = other;
1905         return SpectateSet();
1906 }
1907
1908 /*
1909 =============
1910 ShowRespawnCountdown()
1911
1912 Update a respawn countdown display.
1913 =============
1914 */
1915 void ShowRespawnCountdown()
1916 {
1917         float number;
1918         if(self.deadflag == DEAD_NO) // just respawned?
1919                 return;
1920         else
1921         {
1922                 number = ceil(self.respawn_time - time);
1923                 if(number <= 0)
1924                         return;
1925                 if(number <= self.respawn_countdown)
1926                 {
1927                         self.respawn_countdown = number - 1;
1928                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1929                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
1930                 }
1931         }
1932 }
1933
1934 void LeaveSpectatorMode()
1935 {
1936         if(self.caplayer)
1937                 return;
1938         if(nJoinAllowed(self))
1939         {
1940                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1941                 {
1942                         self.classname = "player";
1943
1944                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1945                                 { JoinBestTeam(self, FALSE, TRUE); }
1946
1947                         if(autocvar_g_campaign)
1948                                 { campaign_bots_may_start = 1; }
1949
1950                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1951
1952                         PutClientInServer();
1953
1954                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1955                 }
1956                 else
1957                         stuffcmd(self, "menu_showteamselect\n");
1958         }
1959         else
1960         {
1961                 // Player may not join because g_maxplayers is set
1962                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1963         }
1964 }
1965
1966 /**
1967  * Determines whether the player is allowed to join. This depends on cvar
1968  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1969  * it checks whether the number of currently playing players exceeds g_maxplayers.
1970  * @return int number of free slots for players, 0 if none
1971  */
1972 float nJoinAllowed(entity ignore) {
1973         if(!ignore)
1974         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1975         // so report 0 free slots if restricted
1976         {
1977                 if(autocvar_g_forced_team_otherwise == "spectate")
1978                         return 0;
1979                 if(autocvar_g_forced_team_otherwise == "spectator")
1980                         return 0;
1981         }
1982
1983         if(self.team_forced < 0)
1984                 return 0; // forced spectators can never join
1985
1986         // TODO simplify this
1987         entity e;
1988         float totalClients = 0;
1989         FOR_EACH_CLIENT(e)
1990                 if(e != ignore)
1991                         totalClients += 1;
1992
1993         if (!autocvar_g_maxplayers)
1994                 return maxclients - totalClients;
1995
1996         float currentlyPlaying = 0;
1997         FOR_EACH_REALCLIENT(e)
1998                 if(IS_PLAYER(e) || e.caplayer == 1)
1999                         currentlyPlaying += 1;
2000
2001         if(currentlyPlaying < autocvar_g_maxplayers)
2002                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2003
2004         return 0;
2005 }
2006
2007 /**
2008  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2009  * g_maxplayers_spectator_blocktime seconds
2010  */
2011 void checkSpectatorBlock() {
2012         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2013                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2014                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2015                         dropclient(self);
2016                 }
2017         }
2018 }
2019
2020 void PrintWelcomeMessage()
2021 {
2022         if(self.motd_actived_time == 0)
2023         {
2024                 if (autocvar_g_campaign) {
2025                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2026                                 self.motd_actived_time = time;
2027                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2028                         }
2029                 } else {
2030                         if (self.BUTTON_INFO) {
2031                                 self.motd_actived_time = time;
2032                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2033                         }
2034                 }
2035         }
2036         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2037         {
2038                 if (autocvar_g_campaign) {
2039                         if (self.BUTTON_INFO)
2040                                 self.motd_actived_time = time;
2041                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2042                                 self.motd_actived_time = 0;
2043                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2044                         }
2045                 } else {
2046                         if (self.BUTTON_INFO)
2047                                 self.motd_actived_time = time;
2048                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2049                                 self.motd_actived_time = 0;
2050                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2051                         }
2052                 }
2053         }
2054         else //if(self.motd_actived_time < 0) // just connected, motd is active
2055         {
2056                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2057                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2058                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2059                 {
2060                         // instanctly hide MOTD
2061                         self.motd_actived_time = 0;
2062                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2063                 }
2064         }
2065 }
2066
2067 void ObserverThink()
2068 {
2069         float prefered_movetype;
2070         if (self.flags & FL_JUMPRELEASED) {
2071                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2072                         self.flags &~= FL_JUMPRELEASED;
2073                         self.flags |= FL_SPAWNING;
2074                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2075                         self.flags &~= FL_JUMPRELEASED;
2076                         if(SpectateNext()) {
2077                                 self.classname = "spectator";
2078                         }
2079                 } else {
2080                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2081                         if (self.movetype != prefered_movetype)
2082                                 self.movetype = prefered_movetype;
2083                 }
2084         } else {
2085                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2086                         self.flags |= FL_JUMPRELEASED;
2087                         if(self.flags & FL_SPAWNING)
2088                         {
2089                                 self.flags &~= FL_SPAWNING;
2090                                 LeaveSpectatorMode();
2091                                 return;
2092                         }
2093                 }
2094         }
2095 }
2096
2097 void SpectatorThink()
2098 {
2099         if (self.flags & FL_JUMPRELEASED) {
2100                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2101                         self.flags &~= FL_JUMPRELEASED;
2102                         self.flags |= FL_SPAWNING;
2103                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209) {
2104                         self.flags &~= FL_JUMPRELEASED;
2105                         if(SpectateNext()) {
2106                                 self.classname = "spectator";
2107                         } else {
2108                                 self.classname = "observer";
2109                                 PutClientInServer();
2110                         }
2111                         self.impulse = 0;
2112                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229) {
2113                         self.flags &~= FL_JUMPRELEASED;
2114                         if(SpectatePrev()) {
2115                                 self.classname = "spectator";
2116                         } else {
2117                                 self.classname = "observer";
2118                                 PutClientInServer();
2119                         }
2120                         self.impulse = 0;
2121                 } else if (self.BUTTON_ATCK2) {
2122                         self.flags &~= FL_JUMPRELEASED;
2123                         self.classname = "observer";
2124                         PutClientInServer();
2125                 } else {
2126                         if(!SpectateUpdate())
2127                                 PutObserverInServer();
2128                 }
2129         } else {
2130                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2131                         self.flags |= FL_JUMPRELEASED;
2132                         if(self.flags & FL_SPAWNING)
2133                         {
2134                                 self.flags &~= FL_SPAWNING;
2135                                 LeaveSpectatorMode();
2136                                 return;
2137                         }
2138                 }
2139                 if(!SpectateUpdate())
2140                         PutObserverInServer();
2141         }
2142
2143         self.flags |= FL_CLIENT | FL_NOTARGET;
2144 }
2145
2146 void PlayerUseKey()
2147 {
2148         if not(IS_PLAYER(self))
2149                 return;
2150
2151         if(self.vehicle)
2152         {
2153         vehicles_exit(VHEF_NORMAL);
2154         return;
2155         }
2156
2157         // a use key was pressed; call handlers
2158         MUTATOR_CALLHOOK(PlayerUseKey);
2159 }
2160
2161 /*
2162 =============
2163 PlayerPreThink
2164
2165 Called every frame for each client before the physics are run
2166 =============
2167 */
2168 .float usekeypressed;
2169 void() nexball_setstatus;
2170 .float items_added;
2171 void PlayerPreThink (void)
2172 {
2173         WarpZone_PlayerPhysics_FixVAngle();
2174
2175         self.stat_game_starttime = game_starttime;
2176         self.stat_round_starttime = round_starttime;
2177         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2178         self.stat_leadlimit = autocvar_leadlimit;
2179
2180         if(frametime)
2181         {
2182                 // physics frames: update anticheat stuff
2183                 anticheat_prethink();
2184         }
2185
2186         if(blockSpectators && frametime)
2187                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2188                 checkSpectatorBlock();
2189
2190         zoomstate_set = 0;
2191
2192         if(self.netname_previous != self.netname)
2193         {
2194                 if(autocvar_sv_eventlog)
2195                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2196                 if(self.netname_previous)
2197                         strunzone(self.netname_previous);
2198                 self.netname_previous = strzone(self.netname);
2199         }
2200
2201         // version nagging
2202         if(self.version_nagtime)
2203                 if(self.cvar_g_xonoticversion)
2204                         if(time > self.version_nagtime)
2205                         {
2206                                 // don't notify git users
2207                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2208                                 {
2209                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2210                                         {
2211                                                 // notify release users if connecting to git
2212                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2213                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2214                                         }
2215                                         else
2216                                         {
2217                                                 float r;
2218                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2219                                                 if(r < 0)
2220                                                 {
2221                                                         // give users new version
2222                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2223                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2224                                                 }
2225                                                 else if(r > 0)
2226                                                 {
2227                                                         // notify users about old server version
2228                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2229                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2230                                                 }
2231                                         }
2232                                 }
2233                                 self.version_nagtime = 0;
2234                         }
2235
2236         // GOD MODE info
2237         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2238         {
2239                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2240                 self.max_armorvalue = 0;
2241         }
2242
2243 #ifdef TETRIS
2244         if (TetrisPreFrame())
2245                 return;
2246 #endif
2247
2248         MUTATOR_CALLHOOK(PlayerPreThink);
2249
2250         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2251         {
2252                 if(self.BUTTON_USE && !self.usekeypressed)
2253                         PlayerUseKey();
2254                 self.usekeypressed = self.BUTTON_USE;
2255         }
2256
2257         if(IS_REAL_CLIENT(self))
2258                 PrintWelcomeMessage();
2259
2260         if(IS_PLAYER(self))
2261         {
2262
2263                 CheckRules_Player();
2264
2265                 if (intermission_running)
2266                 {
2267                         IntermissionThink ();   // otherwise a button could be missed between
2268                         return;                                 // the think tics
2269                 }
2270
2271                 //don't allow the player to turn around while game is paused!
2272                 if(timeout_status == TIMEOUT_ACTIVE) {
2273                         // FIXME turn this into CSQC stuff
2274                         self.v_angle = self.lastV_angle;
2275                         self.angles = self.lastV_angle;
2276                         self.fixangle = TRUE;
2277                 }
2278
2279                 if(frametime)
2280                 {
2281                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2282                         {
2283                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2284                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2285                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2286
2287                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2288                                 {
2289                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2290                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2291                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2292                                 }
2293                         }
2294                         else
2295                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2296
2297                         player_powerups();
2298                 }
2299
2300                 if (self.deadflag != DEAD_NO)
2301                 {
2302                         if(self.personal && g_race_qualifying)
2303                         {
2304                                 if(time > self.respawn_time)
2305                                 {
2306                                         self.respawn_time = time + 1; // only retry once a second
2307                                         self.stat_respawn_time = self.respawn_time;
2308                                         respawn();
2309                                         self.impulse = 141;
2310                                 }
2311                         }
2312                         else
2313                         {
2314                                 float button_pressed;
2315                                 if(frametime)
2316                                         player_anim();
2317                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2318
2319                                 if (self.deadflag == DEAD_DYING)
2320                                 {
2321                                         if(self.respawn_flags & RESPAWN_FORCE)
2322                                                 self.deadflag = DEAD_RESPAWNING;
2323                                         else if(!button_pressed)
2324                                                 self.deadflag = DEAD_DEAD;
2325                                 }
2326                                 else if (self.deadflag == DEAD_DEAD)
2327                                 {
2328                                         if(button_pressed)
2329                                                 self.deadflag = DEAD_RESPAWNABLE;
2330                                 }
2331                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2332                                 {
2333                                         if(!button_pressed)
2334                                                 self.deadflag = DEAD_RESPAWNING;
2335                                 }
2336                                 else if (self.deadflag == DEAD_RESPAWNING)
2337                                 {
2338                                         if(time > self.respawn_time)
2339                                         {
2340                                                 self.respawn_time = time + 1; // only retry once a second
2341                                                 respawn();
2342                                         }
2343                                 }
2344
2345                                 ShowRespawnCountdown();
2346
2347                                 if(self.respawn_flags & RESPAWN_SILENT)
2348                                         self.stat_respawn_time = 0;
2349                                 else
2350                                         self.stat_respawn_time = self.respawn_time;
2351                         }
2352
2353                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2354                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2355                                 self.stat_respawn_time *= -1;
2356
2357                         return;
2358                 }
2359
2360                 self.prevorigin = self.origin;
2361
2362                 float do_crouch = self.BUTTON_CROUCH;
2363                 if(self.hook.state)
2364                         do_crouch = 0;
2365                 if(self.health <= g_bloodloss)
2366                         do_crouch = 1;
2367                 if(self.vehicle)
2368                         do_crouch = 0;
2369                 if(self.freezetag_frozen)
2370                         do_crouch = 0;
2371                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2372                         do_crouch = 0;
2373
2374                 if (do_crouch)
2375                 {
2376                         if (!self.crouch)
2377                         {
2378                                 self.crouch = TRUE;
2379                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2380                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2381                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2382                         }
2383                 }
2384                 else
2385                 {
2386                         if (self.crouch)
2387                         {
2388                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2389                                 if (!trace_startsolid)
2390                                 {
2391                                         self.crouch = FALSE;
2392                                         self.view_ofs = PL_VIEW_OFS;
2393                                         setsize (self, PL_MIN, PL_MAX);
2394                                 }
2395                         }
2396                 }
2397
2398                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2399                 {
2400                         if(self.bloodloss_timer < time)
2401                         {
2402                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2403                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2404                         }
2405                 }
2406
2407                 FixPlayermodel();
2408
2409                 GrapplingHookFrame();
2410
2411                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2412                 //if(frametime)
2413                 {
2414                         self.items &~= self.items_added;
2415
2416                         W_WeaponFrame();
2417
2418                         self.items_added = 0;
2419                         if(self.items & IT_JETPACK)
2420                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2421                                         self.items_added |= IT_FUEL;
2422
2423                         self.items |= self.items_added;
2424                 }
2425
2426                 player_regen();
2427
2428                 // rot nex charge to the charge limit
2429                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2430                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2431
2432                 if(frametime)
2433                         player_anim();
2434
2435                 if(g_nexball)
2436                         nexball_setstatus();
2437
2438                 // secret status
2439                 secrets_setstatus();
2440
2441                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2442
2443                 //self.angles_y=self.v_angle_y + 90;   // temp
2444         } else if(gameover) {
2445                 if (intermission_running)
2446                         IntermissionThink ();   // otherwise a button could be missed between
2447                 return;
2448         } else if(IS_OBSERVER(self)) {
2449                 ObserverThink();
2450         } else if(IS_SPEC(self)) {
2451                 SpectatorThink();
2452         }
2453
2454         if(!zoomstate_set)
2455                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2456
2457         float oldspectatee_status;
2458         oldspectatee_status = self.spectatee_status;
2459         if(IS_SPEC(self))
2460                 self.spectatee_status = num_for_edict(self.enemy);
2461         else if(IS_OBSERVER(self))
2462                 self.spectatee_status = num_for_edict(self);
2463         else
2464                 self.spectatee_status = 0;
2465         if(self.spectatee_status != oldspectatee_status)
2466         {
2467                 ClientData_Touch(self);
2468                 if(g_race || g_cts)
2469                         race_InitSpectator();
2470         }
2471
2472         if(self.teamkill_soundtime)
2473         if(time > self.teamkill_soundtime)
2474         {
2475                 self.teamkill_soundtime = 0;
2476
2477                 entity oldpusher, oldself;
2478
2479                 oldself = self; self = self.teamkill_soundsource;
2480                 oldpusher = self.pusher; self.pusher = oldself;
2481
2482                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2483
2484                 self.pusher = oldpusher;
2485                 self = oldself;
2486         }
2487
2488         if(self.taunt_soundtime)
2489         if(time > self.taunt_soundtime)
2490         {
2491                 self.taunt_soundtime = 0;
2492                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2493         }
2494
2495         target_voicescript_next(self);
2496
2497         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2498         if(!self.weapon)
2499                 self.clip_load = self.clip_size = 0;
2500 }
2501
2502 float isInvisibleString(string s)
2503 {
2504         float i, n, c;
2505         s = strdecolorize(s);
2506         for((i = 0), (n = strlen(s)); i < n; ++i)
2507         {
2508                 c = str2chr(s, i);
2509                 switch(c)
2510                 {
2511                         case 0:
2512                         case 32: // space
2513                                 break;
2514                         case 192: // charmap space
2515                                 if (!autocvar_utf8_enable)
2516                                         break;
2517                                 return FALSE;
2518                         case 160: // space in unicode fonts
2519                         case 0xE000 + 192: // utf8 charmap space
2520                                 if (autocvar_utf8_enable)
2521                                         break;
2522                         default:
2523                                 return FALSE;
2524                 }
2525         }
2526         return TRUE;
2527 }
2528
2529 /*
2530 =============
2531 PlayerPostThink
2532
2533 Called every frame for each client after the physics are run
2534 =============
2535 */
2536 .float idlekick_lasttimeleft;
2537 void PlayerPostThink (void)
2538 {
2539         // Savage: Check for nameless players
2540         if (isInvisibleString(self.netname)) {
2541                 self.netname = "Player";
2542                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2543         }
2544
2545         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2546         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2547         {
2548                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2549                 {
2550                         if(self.idlekick_lasttimeleft)
2551                         {
2552                                 self.idlekick_lasttimeleft = 0;
2553                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2554                         }
2555                 }
2556                 else
2557                 {
2558                         float timeleft;
2559                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2560                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2561                         {
2562                                 if(!self.idlekick_lasttimeleft)
2563                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2564                         }
2565                         if(timeleft <= 0)
2566                         {
2567                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2568                                 dropclient(self);
2569                                 return;
2570                         }
2571                         else if(timeleft <= 10)
2572                         {
2573                                 if(timeleft != self.idlekick_lasttimeleft)
2574                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2575                                 self.idlekick_lasttimeleft = timeleft;
2576                         }
2577                 }
2578         }
2579
2580 #ifdef TETRIS
2581         if(self.impulse == 100)
2582                 ImpulseCommands();
2583         if (!TetrisPostFrame())
2584         {
2585 #endif
2586
2587         CheatFrame();
2588
2589         //CheckPlayerJump();
2590
2591         if(IS_PLAYER(self)) {
2592                 CheckRules_Player();
2593                 UpdateChatBubble();
2594                 if (self.impulse)
2595                         ImpulseCommands();
2596                 if (intermission_running)
2597                         return;         // intermission or finale
2598                 GetPressedKeys();
2599         }
2600
2601 #ifdef TETRIS
2602         }
2603 #endif
2604
2605         /*
2606         float i;
2607         for(i = 0; i < 1000; ++i)
2608         {
2609                 vector end;
2610                 end = self.origin + '0 0 1024' + 512 * randomvec();
2611                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2612                 if(trace_fraction < 1)
2613                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2614                 {
2615                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2616                         break;
2617                 }
2618         }
2619         */
2620
2621         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2622
2623         if(self.waypointsprite_attachedforcarrier)
2624                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2625
2626         playerdemo_write();
2627
2628         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2629         {
2630                 if not(self.stored_netname)
2631                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2632                 if(self.stored_netname != self.netname)
2633                 {
2634                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2635                         strunzone(self.stored_netname);
2636                         self.stored_netname = strzone(self.netname);
2637                 }
2638         }
2639
2640         /*
2641         if(g_race)
2642                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2643         */
2644
2645         CSQCMODEL_AUTOUPDATE();
2646 }