qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418                 vehicles_exit(VHEF_RELESE);
 419
 420         WaypointSprite_PlayerDead();
 421
 422         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 423                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 424
 425         if(self.killcount != -666) {
 426                 if(g_lms) {
 427                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 428                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 429                         else
 430                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 431                 } else
 432                         bprint ("^4", self.netname, "^4 is spectating now\n");
 433
 434                 if(self.just_joined == FALSE) {
 435                         LogTeamchange(self.playerid, -1, 4);
 436                 } else
 437                         self.just_joined = FALSE;
 438         }
 439
 440         PlayerScore_Clear(self); // clear scores when needed
 441
 442         accuracy_resend(self);
 443
 444         self.spectatortime = time;
 445
 446         self.classname = "observer";
 447         self.iscreature = FALSE;
 448         self.teleportable = TELEPORT_SIMPLE;
 449         self.damagedbycontents = FALSE;
 450         self.health = -666;
 451         self.takedamage = DAMAGE_NO;
 452         self.solid = SOLID_NOT;
 453         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 454         self.flags = FL_CLIENT | FL_NOTARGET;
 455         self.armorvalue = 666;
 456         self.effects = 0;
 457         self.armorvalue = autocvar_g_balance_armor_start;
 458         self.pauserotarmor_finished = 0;
 459         self.pauserothealth_finished = 0;
 460         self.pauseregen_finished = 0;
 461         self.damageforcescale = 0;
 462         self.death_time = 0;
 463         self.respawn_time = 0;
 464         self.alpha = 0;
 465         self.scale = 0;
 466         self.fade_time = 0;
 467         self.pain_frame = 0;
 468         self.pain_finished = 0;
 469         self.strength_finished = 0;
 470         self.invincible_finished = 0;
 471         self.superweapons_finished = 0;
 472         self.pushltime = 0;
 473         self.istypefrag = 0;
 474         self.think = func_null;
 475         self.nextthink = 0;
 476         self.hook_time = 0;
 477         self.runes = 0;
 478         self.deadflag = DEAD_NO;
 479         self.angles = spot.angles;
 480         self.angles_z = 0;
 481         self.fixangle = TRUE;
 482         self.crouch = FALSE;
 483
 484         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 485         self.prevorigin = self.origin;
 486         self.items = 0;
 487         WEPSET_CLEAR_E(self);
 488         self.model = "";
 489         FixPlayermodel();
 490         setmodel(self, "null");
 491         self.drawonlytoclient = self;
 492
 493         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 494         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 495
 496         self.weapon = 0;
 497         self.weaponname = "";
 498         self.switchingweapon = 0;
 499         self.weaponmodel = "";
 500         self.weaponentity = world;
 501         self.exteriorweaponentity = world;
 502         self.killcount = -666;
 503         self.velocity = '0 0 0';
 504         self.avelocity = '0 0 0';
 505         self.punchangle = '0 0 0';
 506         self.punchvector = '0 0 0';
 507         self.oldvelocity = self.velocity;
 508         self.fire_endtime = -1;
 509
 510         if(g_arena)
 511         {
 512                 if(self.version_mismatch)
 513                 {
 514                         Spawnqueue_Unmark(self);
 515                         Spawnqueue_Remove(self);
 516                 }
 517                 else
 518                 {
 519                         Spawnqueue_Insert(self);
 520                 }
 521         }
 522         else if(g_lms)
 523         {
 524                 // Only if the player cannot play at all
 525                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 526                         self.frags = FRAGS_SPECTATOR;
 527                 else
 528                         self.frags = FRAGS_LMS_LOSER;
 529         }
 530         else if(g_ca)
 531         {
 532                 if(self.caplayer)
 533                         self.frags = FRAGS_LMS_LOSER;
 534                 else
 535                         self.frags = FRAGS_SPECTATOR;
 536         }
 537         else
 538                 self.frags = FRAGS_SPECTATOR;
 539 }
 540
 541 .float model_randomizer;
 542 void FixPlayermodel()
 543 {
 544         string defaultmodel;
 545         float defaultskin, chmdl, oldskin, n, i;
 546         vector m1, m2;
 547
 548         defaultmodel = "";
 549         defaultskin = 0;
 550         chmdl = FALSE;
 551
 552         if(autocvar_sv_defaultcharacter == 1)
 553         {
 554                 if(teamplay)
 555                 {
 556                         string s;
 557                         s = Team_ColorName_Lower(self.team);
 558                         if(s != "neutral")
 559                         {
 560                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 561                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 562                         }
 563                 }
 564
 565                 if(defaultmodel == "")
 566                 {
 567                         defaultmodel = autocvar_sv_defaultplayermodel;
 568                         defaultskin = autocvar_sv_defaultplayerskin;
 569                 }
 570
 571                 n = tokenize_console(defaultmodel);
 572                 if(n > 0)
 573                         defaultmodel = argv(floor(n * self.model_randomizer));
 574
 575                 i = strstrofs(defaultmodel, ":", 0);
 576                 if(i >= 0)
 577                 {
 578                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 579                         defaultmodel = substring(defaultmodel, 0, i);
 580                 }
 581         }
 582
 583         if(defaultmodel != "")
 584         {
 585                 if (defaultmodel != self.model)
 586                 {
 587                         m1 = self.mins;
 588                         m2 = self.maxs;
 589                         setplayermodel (self, defaultmodel);
 590                         setsize (self, m1, m2);
 591                         chmdl = TRUE;
 592                 }
 593
 594                 oldskin = self.skin;
 595                 self.skin = defaultskin;
 596         } else {
 597                 if (self.playermodel != self.model || self.playermodel == "")
 598                 {
 599                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 600                         m1 = self.mins;
 601                         m2 = self.maxs;
 602                         setplayermodel (self, self.playermodel);
 603                         setsize (self, m1, m2);
 604                         chmdl = TRUE;
 605                 }
 606
 607                 oldskin = self.skin;
 608                 self.skin = stof(self.playerskin);
 609         }
 610
 611         if(chmdl || oldskin != self.skin)
 612                 self.species = player_getspecies(); // model or skin has changed
 613
 614         if(!teamplay)
 615                 if(strlen(autocvar_sv_defaultplayercolors))
 616                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 617                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 618 }
 619
 620 void PlayerTouchExplode(entity p1, entity p2)
 621 {
 622         vector org;
 623         org = (p1.origin + p2.origin) * 0.5;
 624         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 625
 626         te_explosion(org);
 627
 628         entity e;
 629         e = spawn();
 630         setorigin(e, org);
 631         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 632         remove(e);
 633 }
 634
 635 /*
 636 =============
 637 PutClientInServer
 638
 639 Called when a client spawns in the server
 640 =============
 641 */
 642
 643 void PutClientInServer (void)
 644 {
 645         if(clienttype(self) == CLIENTTYPE_BOT)
 646         {
 647                 self.classname = "player";
 648                 if(g_ca)
 649                         self.caplayer = 1;
 650         }
 651         else if(clienttype(self) == CLIENTTYPE_REAL)
 652         {
 653                 msg_entity = self;
 654                 WriteByte(MSG_ONE, SVC_SETVIEW);
 655                 WriteEntity(MSG_ONE, self);
 656         }
 657
 658         // reset player keys
 659         self.itemkeys = 0;
 660
 661         // player is dead and becomes observer
 662         // FIXME fix LMS scoring for new system
 663         if(g_lms)
 664         {
 665                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 666                         self.classname = "observer";
 667         }
 668
 669         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 670                 self.classname = "observer";
 671
 672         if(gameover)
 673                 self.classname = "observer";
 674
 675         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 676                 entity spot, oldself;
 677                 float j;
 678
 679                 accuracy_resend(self);
 680
 681                 if(self.team < 0)
 682                         JoinBestTeam(self, FALSE, TRUE);
 683
 684                 race_PreSpawn();
 685
 686                 spot = SelectSpawnPoint (FALSE);
 687                 if(!spot)
 688                 {
 689                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 690                         return; // spawn failed
 691                 }
 692
 693                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 694
 695                 self.classname = "player";
 696                 self.wasplayer = TRUE;
 697                 self.iscreature = TRUE;
 698                 self.teleportable = TELEPORT_NORMAL;
 699                 self.damagedbycontents = TRUE;
 700                 self.movetype = MOVETYPE_WALK;
 701                 self.solid = SOLID_SLIDEBOX;
 702                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 703                 if(autocvar_g_playerclip_collisions)
 704                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 705                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 706                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 707                 self.frags = FRAGS_PLAYER;
 708                 if(INDEPENDENT_PLAYERS)
 709                         MAKE_INDEPENDENT_PLAYER(self);
 710                 self.flags = FL_CLIENT;
 711                 if(autocvar__notarget)
 712                         self.flags |= FL_NOTARGET;
 713                 self.takedamage = DAMAGE_AIM;
 714                 if(g_minstagib)
 715                         self.effects = EF_FULLBRIGHT;
 716                 else
 717                         self.effects = 0;
 718                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 719                 self.air_finished = time + 12;
 720                 self.dmg = 2;
 721                 if(autocvar_g_balance_nex_charge)
 722                 {
 723                         if(autocvar_g_balance_nex_secondary_chargepool)
 724                                 self.nex_chargepool_ammo = 1;
 725                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 726                 }
 727
 728                 if(inWarmupStage)
 729                 {
 730                         self.ammo_shells = warmup_start_ammo_shells;
 731                         self.ammo_nails = warmup_start_ammo_nails;
 732                         self.ammo_rockets = warmup_start_ammo_rockets;
 733                         self.ammo_cells = warmup_start_ammo_cells;
 734                         self.ammo_fuel = warmup_start_ammo_fuel;
 735                         self.health = warmup_start_health;
 736                         self.armorvalue = warmup_start_armorvalue;
 737                         WEPSET_COPY_EA(self, warmup_start_weapons);
 738                 }
 739                 else
 740                 {
 741                         self.ammo_shells = start_ammo_shells;
 742                         self.ammo_nails = start_ammo_nails;
 743                         self.ammo_rockets = start_ammo_rockets;
 744                         self.ammo_cells = start_ammo_cells;
 745                         self.ammo_fuel = start_ammo_fuel;
 746                         self.health = start_health;
 747                         self.armorvalue = start_armorvalue;
 748                         WEPSET_COPY_EA(self, start_weapons);
 749                 }
 750
 751                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 752                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 753                 else
 754                         self.superweapons_finished = 0;
 755
 756                 if(g_weaponarena_random)
 757                 {
 758                         if(g_weaponarena_random_with_laser)
 759                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 760                         W_RandomWeapons(self, g_weaponarena_random);
 761                         if(g_weaponarena_random_with_laser)
 762                                 WEPSET_OR_EW(self, WEP_LASER);
 763                 }
 764
 765                 self.items = start_items;
 766
 767                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 768                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 769                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 770                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 771                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 772                 //extend the pause of rotting if client was reset at the beginning of the countdown
 773                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 774                         self.spawnshieldtime += game_starttime - time;
 775                         self.pauserotarmor_finished += game_starttime - time;
 776                         self.pauserothealth_finished += game_starttime - time;
 777                         self.pauseregen_finished += game_starttime - time;
 778                 }
 779                 self.damageforcescale = 2;
 780                 self.death_time = 0;
 781                 self.respawn_time = 0;
 782                 self.scale = 0;
 783                 self.fade_time = 0;
 784                 self.pain_frame = 0;
 785                 self.pain_finished = 0;
 786                 self.strength_finished = 0;
 787                 self.invincible_finished = 0;
 788                 self.pushltime = 0;
 789                 // players have no think function
 790                 self.think = func_null;
 791                 self.nextthink = 0;
 792                 self.hook_time = 0;
 793                 self.dmg_team = 0;
 794                 self.ballistics_density = autocvar_g_ballistics_density_player;
 795
 796                 self.metertime = 0;
 797
 798                 self.runes = 0;
 799
 800                 self.deadflag = DEAD_NO;
 801
 802                 self.angles = spot.angles;
 803
 804                 self.angles_z = 0; // never spawn tilted even if the spot says to
 805                 self.fixangle = TRUE; // turn this way immediately
 806                 self.velocity = '0 0 0';
 807                 self.avelocity = '0 0 0';
 808                 self.punchangle = '0 0 0';
 809                 self.punchvector = '0 0 0';
 810                 self.oldvelocity = self.velocity;
 811                 self.fire_endtime = -1;
 812
 813                 msg_entity = self;
 814                 WRITESPECTATABLE_MSG_ONE({
 815                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 816                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 817                 });
 818
 819                 self.model = "";
 820                 FixPlayermodel();
 821                 self.drawonlytoclient = world;
 822
 823                 self.crouch = FALSE;
 824                 self.view_ofs = PL_VIEW_OFS;
 825                 setsize (self, PL_MIN, PL_MAX);
 826                 self.spawnorigin = spot.origin;
 827                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 828                 // don't reset back to last position, even if new position is stuck in solid
 829                 self.oldorigin = self.origin;
 830                 self.prevorigin = self.origin;
 831                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 832                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 833         self.hud = HUD_NORMAL;
 834
 835                 if(g_arena)
 836                 {
 837                         Spawnqueue_Remove(self);
 838                         Spawnqueue_Mark(self);
 839                 }
 840                 else if(g_ca)
 841                         self.caplayer = 1;
 842
 843                 self.event_damage = PlayerDamage;
 844
 845                 self.bot_attack = TRUE;
 846
 847                 self.statdraintime = time + 5;
 848                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 849
 850                 if(self.killcount == -666) {
 851                         PlayerScore_Clear(self);
 852                         self.killcount = 0;
 853                 }
 854
 855                 CL_SpawnWeaponentity();
 856                 self.alpha = default_player_alpha;
 857                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 858                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 859
 860                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 861                 self.lms_traveled_distance = 0;
 862                 self.speedrunning = FALSE;
 863
 864                 race_PostSpawn(spot);
 865
 866                 //stuffcmd(self, "chase_active 0");
 867                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 868
 869                 if(g_assault) {
 870                         if(self.team == assault_attacker_team)
 871                                 centerprint(self, "You are attacking!");
 872                         else
 873                                 centerprint(self, "You are defending!");
 874                 }
 875
 876                 target_voicescript_clear(self);
 877
 878                 // reset fields the weapons may use
 879                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 880                 {
 881                         weapon_action(j, WR_RESETPLAYER);
 882
 883                         // all weapons must be fully loaded when we spawn
 884                         entity e;
 885                         e = get_weaponinfo(j);
 886                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 887                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 888                 }
 889
 890                 oldself = self;
 891                 self = spot;
 892                         activator = oldself;
 893                                 string s;
 894                                 s = self.target;
 895                                 self.target = string_null;
 896                                 SUB_UseTargets();
 897                                 self.target = s;
 898                         activator = world;
 899                 self = oldself;
 900
 901                 spawn_spot = spot;
 902                 MUTATOR_CALLHOOK(PlayerSpawn);
 903
 904                 if(autocvar_spawn_debug)
 905                 {
 906                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 907                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 908                 }
 909
 910                 self.switchweapon = w_getbestweapon(self);
 911                 self.cnt = -1; // W_LastWeapon will not complain
 912                 self.weapon = 0;
 913                 self.weaponname = "";
 914                 self.switchingweapon = 0;
 915
 916                 if(!self.alivetime)
 917                         self.alivetime = time;
 918
 919                 antilag_clear(self);
 920
 921                 if (autocvar_g_spawnsound)
 922                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 923         } else if(self.classname == "observer") {
 924                 PutObserverInServer ();
 925         }
 926 }
 927
 928 .float ebouncefactor, ebouncestop; // electro's values
 929 // TODO do we need all these fields, or should we stop autodetecting runtime
 930 // changes and just have a console command to update this?
 931 float ClientInit_SendEntity(entity to, float sf)
 932 {
 933         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 934         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 935         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 936         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 947         if(sv_foginterval && world.fog != "")
 948                 WriteString(MSG_ENTITY, world.fog);
 949         else
 950                 WriteString(MSG_ENTITY, "");
 951         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 952         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 953         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 954         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 955         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 956         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 957         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 958         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 959         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 960         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 961         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 962         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 963         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 964         return TRUE;
 965 }
 966
 967 void ClientInit_CheckUpdate()
 968 {
 969         self.nextthink = time;
 970         if(self.count != autocvar_g_balance_armor_blockpercent)
 971         {
 972                 self.count = autocvar_g_balance_armor_blockpercent;
 973                 self.SendFlags |= 1;
 974         }
 975         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 976         {
 977                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 978                 self.SendFlags |= 1;
 979         }
 980         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 981         {
 982                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 983                 self.SendFlags |= 1;
 984         }
 985         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 986         {
 987                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 988                 self.SendFlags |= 1;
 989         }
 990         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 991         {
 992                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 993                 self.SendFlags |= 1;
 994         }
 995         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 996         {
 997                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 998                 self.SendFlags |= 1;
 999         }
1000 }
1001
1002 void ClientInit_Spawn()
1003 {
1004         entity o;
1005         entity e;
1006         e = spawn();
1007         e.classname = "clientinit";
1008         e.think = ClientInit_CheckUpdate;
1009         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1010
1011         o = self;
1012         self = e;
1013         ClientInit_CheckUpdate();
1014         self = o;
1015 }
1016
1017 /*
1018 =============
1019 SetNewParms
1020 =============
1021 */
1022 void SetNewParms (void)
1023 {
1024         // initialize parms for a new player
1025         parm1 = -(86400 * 366);
1026 }
1027
1028 /*
1029 =============
1030 SetChangeParms
1031 =============
1032 */
1033 void SetChangeParms (void)
1034 {
1035         // save parms for level change
1036         parm1 = self.parm_idlesince - time;
1037 }
1038
1039 /*
1040 =============
1041 DecodeLevelParms
1042 =============
1043 */
1044 void DecodeLevelParms (void)
1045 {
1046         // load parms
1047         self.parm_idlesince = parm1;
1048         if(self.parm_idlesince == -(86400 * 366))
1049                 self.parm_idlesince = time;
1050
1051         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1052         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1053 }
1054
1055 /*
1056 =============
1057 ClientKill
1058
1059 Called when a client types 'kill' in the console
1060 =============
1061 */
1062
1063 .float clientkill_nexttime;
1064 void ClientKill_Now_TeamChange()
1065 {
1066         if(self.killindicator_teamchange == -1)
1067         {
1068                 JoinBestTeam( self, FALSE, TRUE );
1069         }
1070         else if(self.killindicator_teamchange == -2)
1071         {
1072                 if(g_ca)
1073                         self.caplayer = 0;
1074                 if(blockSpectators)
1075                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1076                 PutObserverInServer();
1077         }
1078         else
1079                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1080 }
1081
1082 void ClientKill_Now()
1083 {
1084         if(self.vehicle)
1085         {
1086             vehicles_exit(VHEF_RELESE);
1087             if(!self.killindicator_teamchange)
1088             {
1089             self.vehicle_health = -1;
1090             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1091             }
1092         }
1093
1094         if(self.killindicator && !wasfreed(self.killindicator))
1095                 remove(self.killindicator);
1096
1097         self.killindicator = world;
1098
1099         if(self.killindicator_teamchange)
1100                 ClientKill_Now_TeamChange();
1101
1102         // in any case:
1103         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1104
1105         // now I am sure the player IS dead
1106 }
1107 void KillIndicator_Think()
1108 {
1109         if (gameover)
1110         {
1111                 self.owner.killindicator = world;
1112                 remove(self);
1113                 return;
1114         }
1115
1116         if (self.owner.alpha < 0 && !self.owner.vehicle)
1117         {
1118                 self.owner.killindicator = world;
1119                 remove(self);
1120                 return;
1121         }
1122
1123         if(self.cnt <= 0)
1124         {
1125                 self = self.owner;
1126                 ClientKill_Now(); // no oldself needed
1127                 return;
1128         }
1129     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1130     {
1131         self.nextthink = time + 1;
1132         self.cnt -= 1;
1133     }
1134         else
1135         {
1136                 if(self.cnt <= 10)
1137                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1138                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1139                 {
1140                         if(self.cnt <= 10)
1141                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1142                 }
1143                 self.nextthink = time + 1;
1144                 self.cnt -= 1;
1145         }
1146 }
1147
1148 float clientkilltime;
1149 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1150 {
1151         float killtime;
1152         float starttime;
1153         entity e;
1154
1155         if (gameover)
1156                 return;
1157
1158         killtime = autocvar_g_balance_kill_delay;
1159
1160         if(g_race_qualifying || g_cts)
1161                 killtime = 0;
1162
1163     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1164     {
1165                 remove(self.killindicator);
1166                 self.killindicator = world;
1167
1168         ClientKill_Now(); // allow instant kill in this case
1169         return;
1170     }
1171
1172         self.killindicator_teamchange = targetteam;
1173
1174     if(!self.killindicator)
1175         {
1176                 if(self.deadflag == DEAD_NO)
1177                 {
1178                         killtime = max(killtime, self.clientkill_nexttime - time);
1179                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1180                 }
1181
1182                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1183                 {
1184                         ClientKill_Now();
1185                 }
1186                 else
1187                 {
1188                         starttime = max(time, clientkilltime);
1189
1190                         self.killindicator = spawn();
1191                         self.killindicator.owner = self;
1192                         self.killindicator.scale = 0.5;
1193                         setattachment(self.killindicator, self, "");
1194                         setorigin(self.killindicator, '0 0 52');
1195                         self.killindicator.think = KillIndicator_Think;
1196                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1197                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1198                         self.killindicator.cnt = ceil(killtime);
1199                         self.killindicator.count = bound(0, ceil(killtime), 10);
1200                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1201
1202                         for(e = world; (e = find(e, classname, "body")) != world; )
1203                         {
1204                                 if(e.enemy != self)
1205                                         continue;
1206                                 e.killindicator = spawn();
1207                                 e.killindicator.owner = e;
1208                                 e.killindicator.scale = 0.5;
1209                                 setattachment(e.killindicator, e, "");
1210                                 setorigin(e.killindicator, '0 0 52');
1211                                 e.killindicator.think = KillIndicator_Think;
1212                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1213                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1214                                 e.killindicator.cnt = ceil(killtime);
1215                         }
1216                         self.lip = 0;
1217                 }
1218         }
1219         if(self.killindicator)
1220         {
1221                 if(targetteam == 0) // just die
1222                 {
1223                         self.killindicator.colormod = '0 0 0';
1224                         if(clienttype(self) == CLIENTTYPE_REAL)
1225                         if(self.killindicator.cnt > 0)
1226                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1227                 }
1228                 else if(targetteam == -1) // auto
1229                 {
1230                         self.killindicator.colormod = '0 1 0';
1231                         if(clienttype(self) == CLIENTTYPE_REAL)
1232                         if(self.killindicator.cnt > 0)
1233                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1234                 }
1235                 else if(targetteam == -2) // spectate
1236                 {
1237                         self.killindicator.colormod = '0.5 0.5 0.5';
1238                         if(clienttype(self) == CLIENTTYPE_REAL)
1239                         if(self.killindicator.cnt > 0)
1240                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1241                 }
1242                 else
1243                 {
1244                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1245                         if(clienttype(self) == CLIENTTYPE_REAL)
1246                         if(self.killindicator.cnt > 0)
1247                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("^7Changing to ", Team_ColoredFullName(targetteam), "^7 in %d seconds"), 1, self.killindicator.cnt);
1248                 }
1249         }
1250
1251 }
1252
1253 void ClientKill (void)
1254 {
1255         if (gameover)
1256                 return;
1257
1258         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1259         {
1260                 // do nothing
1261         }
1262     else if(self.freezetag_frozen)
1263     {
1264         // do nothing
1265     }
1266         else
1267                 ClientKill_TeamChange(0);
1268 }
1269
1270 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1271 {
1272     e.killindicator = spawn();
1273     e.killindicator.owner = e;
1274     e.killindicator.think = KillIndicator_Think;
1275     e.killindicator.nextthink = time + (e.lip) * 0.05;
1276     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1277     e.killindicator.health = 1; // this is used to indicate that it should be silent
1278     e.lip = 0;
1279 }
1280
1281 void FixClientCvars(entity e)
1282 {
1283         // send prediction settings to the client
1284         stuffcmd(e, "\nin_bindmap 0 0\n");
1285         if(g_race || g_cts)
1286                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1287         if(autocvar_g_antilag == 3) // client side hitscan
1288                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1289         if(autocvar_sv_gentle)
1290                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1291         /*
1292          * we no longer need to stuff this. Remove this comment block if you feel
1293          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1294         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1295         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1296         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1297         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1298         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1299         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1300         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1301         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1302         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1303         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1304         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1305         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1306         stuffcmd(e, "cl_movement_edgefriction 1\n");
1307          */
1308 }
1309
1310 float PlayerInIDList(entity p, string idlist)
1311 {
1312         float n, i;
1313         string s;
1314
1315         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1316         if not(p.crypto_idfp)
1317                 return 0;
1318
1319         // this function allows abbreviated player IDs too!
1320         n = tokenize_console(idlist);
1321         for(i = 0; i < n; ++i)
1322         {
1323                 s = argv(i);
1324                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1325                         return 1;
1326         }
1327
1328         return 0;
1329 }
1330
1331 /*
1332 =============
1333 ClientConnect
1334
1335 Called when a client connects to the server
1336 =============
1337 */
1338 void DecodeLevelParms (void);
1339 //void dom_player_join_team(entity pl);
1340 void set_dom_state(entity e);
1341 void ClientConnect (void)
1342 {
1343         float t;
1344
1345         if(self.flags & FL_CLIENT)
1346         {
1347                 print("Warning: ClientConnect, but already connected!\n");
1348                 return;
1349         }
1350
1351         if(Ban_MaybeEnforceBanOnce(self))
1352                 return;
1353
1354         DecodeLevelParms();
1355
1356 #ifdef WATERMARK
1357         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK, "\n"));
1358 #endif
1359
1360         self.classname = "player_joining";
1361
1362         self.flags = FL_CLIENT;
1363         self.version_nagtime = time + 10 + random() * 10;
1364
1365         if(self.netaddress == "local")
1366         {
1367                 print("^3server is local!\n");
1368
1369                 if(server_is_local)
1370                         print("Multiple local clients???");
1371                 else
1372                         server_is_local = TRUE;
1373         }
1374
1375         if(player_count<0)
1376         {
1377                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1378                 player_count = 0;
1379         }
1380
1381         PlayerScore_Attach(self);
1382         ClientData_Attach();
1383         accuracy_init(self);
1384
1385         bot_clientconnect();
1386
1387         playerdemo_init();
1388
1389         anticheat_init();
1390
1391         race_PreSpawnObserver();
1392
1393         //if(g_domination)
1394         //      dom_player_join_team(self);
1395
1396         // identify the right forced team
1397         if(autocvar_g_campaign)
1398         {
1399                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1400                 {
1401                         switch(autocvar_g_campaign_forceteam)
1402                         {
1403                                 case 1: self.team_forced = FL_TEAM_1; break;
1404                                 case 2: self.team_forced = FL_TEAM_2; break;
1405                                 case 3: self.team_forced = FL_TEAM_3; break;
1406                                 case 4: self.team_forced = FL_TEAM_4; break;
1407                                 default: self.team_forced = 0;
1408                         }
1409                 }
1410         }
1411         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1412                 self.team_forced = FL_TEAM_1;
1413         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1414                 self.team_forced = FL_TEAM_2;
1415         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1416                 self.team_forced = FL_TEAM_3;
1417         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1418                 self.team_forced = FL_TEAM_4;
1419         else if(autocvar_g_forced_team_otherwise == "red")
1420                 self.team_forced = FL_TEAM_1;
1421         else if(autocvar_g_forced_team_otherwise == "blue")
1422                 self.team_forced = FL_TEAM_2;
1423         else if(autocvar_g_forced_team_otherwise == "yellow")
1424                 self.team_forced = FL_TEAM_3;
1425         else if(autocvar_g_forced_team_otherwise == "pink")
1426                 self.team_forced = FL_TEAM_4;
1427         else if(autocvar_g_forced_team_otherwise == "spectate")
1428                 self.team_forced = -1;
1429         else if(autocvar_g_forced_team_otherwise == "spectator")
1430                 self.team_forced = -1;
1431         else
1432                 self.team_forced = 0;
1433
1434         if(!teamplay)
1435                 if(self.team_forced > 0)
1436                         self.team_forced = 0;
1437
1438         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1439
1440         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1441                 self.classname = "observer";
1442         } else {
1443                 if(teamplay)
1444                 {
1445                         if(autocvar_g_balance_teams)
1446                         {
1447                                 self.classname = "player";
1448                                 campaign_bots_may_start = 1;
1449                         }
1450                         else
1451                         {
1452                                 self.classname = "observer"; // do it anyway
1453                         }
1454                 }
1455                 else
1456                 {
1457                         self.classname = "player";
1458                         campaign_bots_may_start = 1;
1459                 }
1460         }
1461
1462         self.playerid = (playerid_last = playerid_last + 1);
1463
1464         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1465
1466     if(clienttype(self) == CLIENTTYPE_BOT)
1467         PlayerStats_AddPlayer(self);
1468
1469         if(autocvar_sv_eventlog)
1470                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1471
1472         LogTeamchange(self.playerid, self.team, 1);
1473
1474         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1475
1476         self.netname_previous = strzone(self.netname);
1477
1478         bprint("^4", self.netname, "^4 connected");
1479
1480         if(self.classname != "observer" && (g_domination || g_ctf))
1481                 bprint(" and joined the ", Team_ColoredFullName(self.team));
1482
1483         bprint("\n");
1484
1485         stuffcmd(self, strcat(clientstuff, "\n"));
1486         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1487
1488         FixClientCvars(self);
1489
1490         // spawnfunc_waypoint sprites
1491         WaypointSprite_InitClient(self);
1492
1493         // Wazat's grappling hook
1494         SetGrappleHookBindings();
1495
1496         // get version info from player
1497         stuffcmd(self, "cmd clientversion $gameversion\n");
1498
1499         // get other cvars from player
1500         GetCvars(0);
1501
1502         // notify about available teams
1503         if(teamplay)
1504         {
1505                 CheckAllowedTeams(self);
1506                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1507                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1508         }
1509         else
1510                 stuffcmd(self, "set _teams_available 0\n");
1511
1512         if(g_arena || g_ca)
1513         {
1514                 self.classname = "observer";
1515                 if(g_arena)
1516                         Spawnqueue_Insert(self);
1517         }
1518
1519         attach_entcs();
1520
1521         bot_relinkplayerlist();
1522
1523         self.spectatortime = time;
1524         if(blockSpectators)
1525         {
1526                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1527         }
1528
1529         self.jointime = time;
1530         self.allowed_timeouts = autocvar_sv_timeout_number;
1531
1532         if(clienttype(self) == CLIENTTYPE_REAL)
1533         {
1534                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1535                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1536         }
1537
1538         if(g_lms)
1539         {
1540                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1541                 {
1542                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1543                         self.frags = FRAGS_SPECTATOR;
1544                 }
1545         }
1546
1547         if(!sv_foginterval && world.fog != "")
1548                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1549
1550         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1551         {
1552                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1553                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1554         }
1555         else
1556                 self.hitplotfh = -1;
1557
1558         if(g_race || g_cts) {
1559                 string rr;
1560                 if(g_cts)
1561                         rr = CTS_RECORD;
1562                 else
1563                         rr = RACE_RECORD;
1564
1565                 msg_entity = self;
1566                 race_send_recordtime(MSG_ONE);
1567                 race_send_speedaward(MSG_ONE);
1568
1569                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1570                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1571                 race_send_speedaward_alltimebest(MSG_ONE);
1572
1573                 float i;
1574                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1575                         race_SendRankings(i, 0, 0, MSG_ONE);
1576                 }
1577         }
1578         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1579                 send_CSQC_teamnagger();
1580
1581         if (g_domination)
1582                 set_dom_state(self);
1583
1584         CheatInitClient();
1585
1586         if(!autocvar_g_campaign)
1587                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1588
1589         CSQCMODEL_AUTOINIT();
1590
1591         self.model_randomizer = random();
1592
1593     if(clienttype(self) != CLIENTTYPE_REAL)
1594         return;
1595
1596     sv_notice_join();
1597
1598     MUTATOR_CALLHOOK(ClientConnect);
1599 }
1600 /*
1601 =============
1602 ClientDisconnect
1603
1604 Called when a client disconnects from the server
1605 =============
1606 */
1607 .entity chatbubbleentity;
1608 void ReadyCount();
1609 void ClientDisconnect (void)
1610 {
1611         if(self.vehicle)
1612             vehicles_exit(VHEF_RELESE);
1613
1614         if not(self.flags & FL_CLIENT)
1615         {
1616                 print("Warning: ClientDisconnect without ClientConnect\n");
1617                 return;
1618         }
1619
1620         PlayerStats_AddGlobalInfo(self);
1621
1622         CheatShutdownClient();
1623
1624         if(self.hitplotfh >= 0)
1625         {
1626                 fclose(self.hitplotfh);
1627                 self.hitplotfh = -1;
1628         }
1629
1630         anticheat_report();
1631         anticheat_shutdown();
1632
1633         playerdemo_shutdown();
1634
1635         bot_clientdisconnect();
1636
1637         if(self.entcs)
1638                 detach_entcs();
1639
1640         if(autocvar_sv_eventlog)
1641                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1642         bprint ("^4",self.netname);
1643         bprint ("^4 disconnected\n");
1644
1645         DropAllRunes(self);
1646         MUTATOR_CALLHOOK(ClientDisconnect);
1647
1648         Portal_ClearAll(self);
1649
1650         RemoveGrapplingHook(self);
1651
1652         // Here, everything has been done that requires this player to be a client.
1653
1654         self.flags &~= FL_CLIENT;
1655
1656         if (self.chatbubbleentity)
1657                 remove (self.chatbubbleentity);
1658
1659         if (self.killindicator)
1660                 remove (self.killindicator);
1661
1662         WaypointSprite_PlayerGone();
1663
1664         bot_relinkplayerlist();
1665
1666         if(g_arena)
1667         {
1668                 Spawnqueue_Unmark(self);
1669                 Spawnqueue_Remove(self);
1670         }
1671
1672         accuracy_free(self);
1673         ClientData_Detach();
1674         PlayerScore_Detach(self);
1675
1676         if(self.netname_previous)
1677                 strunzone(self.netname_previous);
1678         if(self.clientstatus)
1679                 strunzone(self.clientstatus);
1680         if(self.weaponorder_byimpulse)
1681                 strunzone(self.weaponorder_byimpulse);
1682
1683         ClearPlayerSounds();
1684
1685         if(self.personal)
1686                 remove(self.personal);
1687
1688         self.playerid = 0;
1689         ReadyCount();
1690
1691         // free cvars
1692         GetCvars(-1);
1693 }
1694
1695 .float BUTTON_CHAT;
1696 void ChatBubbleThink()
1697 {
1698         self.nextthink = time;
1699         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1700         {
1701                 if(self.owner) // but why can that ever be world?
1702                         self.owner.chatbubbleentity = world;
1703                 remove(self);
1704                 return;
1705         }
1706         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1707 #ifdef TETRIS
1708                 || self.owner.tetris_on
1709 #endif
1710         )
1711                 self.model = self.mdl;
1712         else
1713                 self.model = "";
1714 }
1715
1716 void UpdateChatBubble()
1717 {
1718         if (self.alpha < 0)
1719                 return;
1720         // spawn a chatbubble entity if needed
1721         if (!self.chatbubbleentity)
1722         {
1723                 self.chatbubbleentity = spawn();
1724                 self.chatbubbleentity.owner = self;
1725                 self.chatbubbleentity.exteriormodeltoclient = self;
1726                 self.chatbubbleentity.think = ChatBubbleThink;
1727                 self.chatbubbleentity.nextthink = time;
1728                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1729                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1730                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1731                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1732                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1733                 self.chatbubbleentity.model = "";
1734                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1735         }
1736 }
1737
1738
1739 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1740 // added to the model skins
1741 /*void UpdateColorModHack()
1742 {
1743         float c;
1744         c = self.clientcolors & 15;
1745         // LordHavoc: only bothering to support white, green, red, yellow, blue
1746              if (!teamplay) self.colormod = '0 0 0';
1747         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1748         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1749         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1750         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1751         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1752         else self.colormod = '1 1 1';
1753 }*/
1754
1755 void respawn(void)
1756 {
1757         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1758         {
1759                 self.solid = SOLID_NOT;
1760                 self.takedamage = DAMAGE_NO;
1761                 self.movetype = MOVETYPE_FLY;
1762                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1763                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1764                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1765                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1766                 if(autocvar_g_respawn_ghosts_maxtime)
1767                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1768         }
1769
1770         CopyBody(1);
1771
1772         self.effects |= EF_NODRAW; // prevent another CopyBody
1773         PutClientInServer();
1774 }
1775
1776 void play_countdown(float finished, string samp)
1777 {
1778         if(clienttype(self) == CLIENTTYPE_REAL)
1779                 if(floor(finished - time - frametime) != floor(finished - time))
1780                         if(finished - time < 6)
1781                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1782 }
1783
1784 void player_powerups (void)
1785 {
1786         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1787         olditems = self.items;
1788
1789         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1790                 self.modelflags |= MF_ROCKET;
1791         else
1792                 self.modelflags &~= MF_ROCKET;
1793
1794         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1795
1796         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1797                 return;
1798
1799         Fire_ApplyDamage(self);
1800         Fire_ApplyEffect(self);
1801
1802         if (g_minstagib)
1803         {
1804                 self.effects |= EF_FULLBRIGHT;
1805
1806                 if (self.items & IT_STRENGTH)
1807                 {
1808                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1809                         if (time > self.strength_finished)
1810                         {
1811                                 self.alpha = default_player_alpha;
1812                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1813                                 self.items &~= IT_STRENGTH;
1814                                 sprint(self, "^3Invisibility has worn off\n");
1815                         }
1816                 }
1817                 else
1818                 {
1819                         if (time < self.strength_finished)
1820                         {
1821                                 self.alpha = g_minstagib_invis_alpha;
1822                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1823                                 self.items |= IT_STRENGTH;
1824                                 sprint(self, "^3You are invisible\n");
1825                         }
1826                 }
1827
1828                 if (self.items & IT_INVINCIBLE)
1829                 {
1830                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1831                         if (time > self.invincible_finished)
1832                         {
1833                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1834                                 sprint(self, "^3Speed has worn off\n");
1835                         }
1836                 }
1837                 else
1838                 {
1839                         if (time < self.invincible_finished)
1840                         {
1841                                 self.items = self.items | IT_INVINCIBLE;
1842                                 sprint(self, "^3You are on speed\n");
1843                         }
1844                 }
1845         }
1846         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1847         {
1848                 if (self.items & IT_STRENGTH)
1849                 {
1850                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1851                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1852                         if (time > self.strength_finished)
1853                         {
1854                                 self.items = self.items - (self.items & IT_STRENGTH);
1855                                 sprint(self, "^3Strength has worn off\n");
1856                         }
1857                 }
1858                 else
1859                 {
1860                         if (time < self.strength_finished)
1861                         {
1862                                 self.items = self.items | IT_STRENGTH;
1863                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1864                         }
1865                 }
1866                 if (self.items & IT_INVINCIBLE)
1867                 {
1868                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1869                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1870                         if (time > self.invincible_finished)
1871                         {
1872                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1873                                 sprint(self, "^3Shield has worn off\n");
1874                         }
1875                 }
1876                 else
1877                 {
1878                         if (time < self.invincible_finished)
1879                         {
1880                                 self.items = self.items | IT_INVINCIBLE;
1881                                 sprint(self, "^3Shield surrounds you\n");
1882                         }
1883                 }
1884                 if (self.items & IT_SUPERWEAPON)
1885                 {
1886                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1887                         {
1888                                 self.superweapons_finished = 0;
1889                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1890                                 sprint(self, "^3Superweapons have been lost\n");
1891                         }
1892                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1893                         {
1894                                 // don't let them run out
1895                         }
1896                         else
1897                         {
1898                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1899                                 if (time > self.superweapons_finished)
1900                                 {
1901                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1902                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1903                                         sprint(self, "^3Superweapons have broken down\n");
1904                                 }
1905                         }
1906                 }
1907                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1908                 {
1909                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1910                         {
1911                                 self.items = self.items | IT_SUPERWEAPON;
1912                                 sprint(self, "^3You now have a superweapon\n");
1913                         }
1914                         else
1915                         {
1916                                 self.superweapons_finished = 0;
1917                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1918                         }
1919                 }
1920                 else
1921                 {
1922                         self.superweapons_finished = 0;
1923                 }
1924         }
1925
1926         if(autocvar_g_nodepthtestplayers)
1927                 self.effects = self.effects | EF_NODEPTHTEST;
1928
1929         if(autocvar_g_fullbrightplayers)
1930                 self.effects = self.effects | EF_FULLBRIGHT;
1931
1932         // midair gamemode: damage only while in the air
1933         // if in midair mode, being on ground grants temporary invulnerability
1934         // (this is so that multishot weapon don't clear the ground flag on the
1935         // first damage in the frame, leaving the player vulnerable to the
1936         // remaining hits in the same frame)
1937         if (self.flags & FL_ONGROUND)
1938         if (g_midair)
1939                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1940
1941         if (time >= game_starttime)
1942         if (time < self.spawnshieldtime)
1943                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1944
1945         MUTATOR_CALLHOOK(PlayerPowerups);
1946 }
1947
1948 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1949 {
1950         if(current > stable)
1951                 return current;
1952         else if(current > stable - 0.25) // when close enough, "snap"
1953                 return stable;
1954         else
1955                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1956 }
1957
1958 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1959 {
1960         if(current < stable)
1961                 return current;
1962         else if(current < stable + 0.25) // when close enough, "snap"
1963                 return stable;
1964         else
1965                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1966 }
1967
1968 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1969 {
1970         if(current > rotstable)
1971         {
1972                 if(rotframetime > 0)
1973                 {
1974                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1975                         current = max(rotstable, current - rotlinear * rotframetime);
1976                 }
1977         }
1978         else if(current < regenstable)
1979         {
1980                 if(regenframetime > 0)
1981                 {
1982                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1983                         current = min(regenstable, current + regenlinear * regenframetime);
1984                 }
1985         }
1986
1987         if(current > limit)
1988                 current = limit;
1989
1990         return current;
1991 }
1992
1993 void player_regen (void)
1994 {
1995         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1996         maxh = autocvar_g_balance_health_rotstable;
1997         maxa = autocvar_g_balance_armor_rotstable;
1998         maxf = autocvar_g_balance_fuel_rotstable;
1999         minh = autocvar_g_balance_health_regenstable;
2000         mina = autocvar_g_balance_armor_regenstable;
2001         minf = autocvar_g_balance_fuel_regenstable;
2002         limith = autocvar_g_balance_health_limit;
2003         limita = autocvar_g_balance_armor_limit;
2004         limitf = autocvar_g_balance_fuel_limit;
2005
2006         max_mod = regen_mod = rot_mod = limit_mod = 1;
2007
2008         if (self.runes & RUNE_REGEN)
2009         {
2010                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2011                 {
2012                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2013                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2014                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2015                 }
2016                 else
2017                 {
2018                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2019                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2020                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2021                 }
2022         }
2023         else if (self.runes & CURSE_VENOM)
2024         {
2025                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2026                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2027                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2028                 else
2029                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2030                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2031                 //if (!self.runes & RUNE_REGEN)
2032                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2033         }
2034         maxh = maxh * max_mod;
2035         //maxa = maxa * max_mod;
2036         //maxf = maxf * max_mod;
2037         minh = minh * max_mod;
2038         //mina = mina * max_mod;
2039         //minf = minf * max_mod;
2040         limith = limith * limit_mod;
2041         limita = limita * limit_mod;
2042         //limitf = limitf * limit_mod;
2043
2044         if(g_lms && g_ca)
2045                 rot_mod = 0;
2046
2047         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2048         {
2049                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2050                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2051
2052                 // if player rotted to death...  die!
2053                 if(self.health < 1)
2054                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2055         }
2056
2057         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2058                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2059 }
2060
2061 float zoomstate_set;
2062 void SetZoomState(float z)
2063 {
2064         if(z != self.zoomstate)
2065         {
2066                 self.zoomstate = z;
2067                 ClientData_Touch(self);
2068         }
2069         zoomstate_set = 1;
2070 }
2071
2072 void GetPressedKeys(void) {
2073         MUTATOR_CALLHOOK(GetPressedKeys);
2074         if (self.movement_x > 0) // get if movement keys are pressed
2075         {       // forward key pressed
2076                 self.pressedkeys |= KEY_FORWARD;
2077                 self.pressedkeys &~= KEY_BACKWARD;
2078         }
2079         else if (self.movement_x < 0)
2080         {       // backward key pressed
2081                 self.pressedkeys |= KEY_BACKWARD;
2082                 self.pressedkeys &~= KEY_FORWARD;
2083         }
2084         else
2085         {       // no x input
2086                 self.pressedkeys &~= KEY_FORWARD;
2087                 self.pressedkeys &~= KEY_BACKWARD;
2088         }
2089
2090         if (self.movement_y > 0)
2091         {       // right key pressed
2092                 self.pressedkeys |= KEY_RIGHT;
2093                 self.pressedkeys &~= KEY_LEFT;
2094         }
2095         else if (self.movement_y < 0)
2096         {       // left key pressed
2097                 self.pressedkeys |= KEY_LEFT;
2098                 self.pressedkeys &~= KEY_RIGHT;
2099         }
2100         else
2101         {       // no y input
2102                 self.pressedkeys &~= KEY_RIGHT;
2103                 self.pressedkeys &~= KEY_LEFT;
2104         }
2105
2106         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2107                 self.pressedkeys |= KEY_JUMP;
2108         else
2109                 self.pressedkeys &~= KEY_JUMP;
2110         if (self.BUTTON_CROUCH)
2111                 self.pressedkeys |= KEY_CROUCH;
2112         else
2113                 self.pressedkeys &~= KEY_CROUCH;
2114
2115         if (self.BUTTON_ATCK)
2116                 self.pressedkeys |= KEY_ATCK;
2117         else
2118                 self.pressedkeys &~= KEY_ATCK;
2119         if (self.BUTTON_ATCK2)
2120                 self.pressedkeys |= KEY_ATCK2;
2121         else
2122                 self.pressedkeys &~= KEY_ATCK2;
2123 }
2124
2125 /*
2126 ======================
2127 spectate mode routines
2128 ======================
2129 */
2130
2131 void SpectateCopy(entity spectatee) {
2132         other = spectatee;
2133         MUTATOR_CALLHOOK(SpectateCopy);
2134         self.armortype = spectatee.armortype;
2135         self.armorvalue = spectatee.armorvalue;
2136         self.ammo_cells = spectatee.ammo_cells;
2137         self.ammo_shells = spectatee.ammo_shells;
2138         self.ammo_nails = spectatee.ammo_nails;
2139         self.ammo_rockets = spectatee.ammo_rockets;
2140         self.ammo_fuel = spectatee.ammo_fuel;
2141         self.clip_load = spectatee.clip_load;
2142         self.clip_size = spectatee.clip_size;
2143         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2144         self.health = spectatee.health;
2145         self.impulse = 0;
2146         self.items = spectatee.items;
2147         self.last_pickup = spectatee.last_pickup;
2148         self.hit_time = spectatee.hit_time;
2149         self.metertime = spectatee.metertime;
2150         self.strength_finished = spectatee.strength_finished;
2151         self.invincible_finished = spectatee.invincible_finished;
2152         self.pressedkeys = spectatee.pressedkeys;
2153         WEPSET_COPY_EE(self, spectatee);
2154         self.switchweapon = spectatee.switchweapon;
2155         self.switchingweapon = spectatee.switchingweapon;
2156         self.weapon = spectatee.weapon;
2157         self.nex_charge = spectatee.nex_charge;
2158         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2159         self.hagar_load = spectatee.hagar_load;
2160         self.minelayer_mines = spectatee.minelayer_mines;
2161         self.punchangle = spectatee.punchangle;
2162         self.view_ofs = spectatee.view_ofs;
2163         self.velocity = spectatee.velocity;
2164         self.dmg_take = spectatee.dmg_take;
2165         self.dmg_save = spectatee.dmg_save;
2166         self.dmg_inflictor = spectatee.dmg_inflictor;
2167         self.v_angle = spectatee.v_angle;
2168         self.angles = spectatee.v_angle;
2169         self.stat_respawn_time = spectatee.stat_respawn_time;
2170         if(!self.BUTTON_USE)
2171                 self.fixangle = TRUE;
2172         setorigin(self, spectatee.origin);
2173         setsize(self, spectatee.mins, spectatee.maxs);
2174         SetZoomState(spectatee.zoomstate);
2175
2176     anticheat_spectatecopy(spectatee);
2177         self.hud = spectatee.hud;
2178         if(spectatee.vehicle)
2179     {
2180         self.fixangle = FALSE;
2181         //self.velocity = spectatee.vehicle.velocity;
2182         self.vehicle_health = spectatee.vehicle_health;
2183         self.vehicle_shield = spectatee.vehicle_shield;
2184         self.vehicle_energy = spectatee.vehicle_energy;
2185         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2186         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2187         self.vehicle_reload1 = spectatee.vehicle_reload1;
2188         self.vehicle_reload2 = spectatee.vehicle_reload2;
2189
2190         msg_entity = self;
2191
2192         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2193             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2194             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2195             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2196
2197         //WriteByte (MSG_ONE, SVC_SETVIEW);
2198         //    WriteEntity(MSG_ONE, self);
2199         //makevectors(spectatee.v_angle);
2200         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2201     }
2202 }
2203
2204 float SpectateUpdate() {
2205         if(!self.enemy)
2206             return 0;
2207
2208         if (self == self.enemy)
2209                 return 0;
2210
2211         if(self.enemy.classname != "player")
2212                 return 0;
2213
2214         SpectateCopy(self.enemy);
2215
2216         return 1;
2217 }
2218
2219
2220 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2221 entity CA_SpectateNext(entity start) {
2222         if (start.team == self.team) {
2223                 return start;
2224         }
2225
2226         other = start;
2227         // continue from current player
2228         while(other && other.team != self.team) {
2229                 other = find(other, classname, "player");
2230         }
2231
2232         if (!other) {
2233                 // restart from begining
2234                 other = find(other, classname, "player");
2235                 while(other && other.team != self.team) {
2236                         other = find(other, classname, "player");
2237                 }
2238         }
2239
2240         return other;
2241 }
2242
2243 float SpectateNext(entity _prefer) {
2244
2245         if(_prefer)
2246                 other = _prefer;
2247         else
2248                 other = find(self.enemy, classname, "player");
2249
2250         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2251                 // CA and ca players when spectating enemies is forbidden
2252                 other = CA_SpectateNext(other);
2253         } else {
2254                 // other modes and ca spectators or spectating enemies is allowed
2255                 if (!other)
2256                         other = find(other, classname, "player");
2257         }
2258
2259         if (other)
2260                 self.enemy = other;
2261
2262         if(self.enemy.classname == "player") {
2263             /*if(self.enemy.vehicle)
2264             {
2265
2266             msg_entity = self;
2267             WriteByte(MSG_ONE, SVC_SETVIEW);
2268             WriteEntity(MSG_ONE, self.enemy);
2269             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2270
2271             self.movetype = MOVETYPE_NONE;
2272             accuracy_resend(self);
2273             }
2274             else
2275             {*/
2276             msg_entity = self;
2277             WriteByte(MSG_ONE, SVC_SETVIEW);
2278             WriteEntity(MSG_ONE, self.enemy);
2279             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2280             self.movetype = MOVETYPE_NONE;
2281             accuracy_resend(self);
2282
2283             if(!SpectateUpdate())
2284                 PutObserverInServer();
2285         //}
2286         return 1;
2287         } else {
2288                 return 0;
2289         }
2290 }
2291
2292 /*
2293 =============
2294 ShowRespawnCountdown()
2295
2296 Update a respawn countdown display.
2297 =============
2298 */
2299 void ShowRespawnCountdown()
2300 {
2301         float number;
2302         if(self.deadflag == DEAD_NO) // just respawned?
2303                 return;
2304         else
2305         {
2306                 number = ceil(self.respawn_time - time);
2307                 if(number <= 0)
2308                         return;
2309                 if(number <= self.respawn_countdown)
2310                 {
2311                         self.respawn_countdown = number - 1;
2312                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2313                                 AnnounceTo(self, strcat(ftos(number), ""));
2314                 }
2315         }
2316 }
2317
2318 .float prevent_join_msgtime;
2319 void LeaveSpectatorMode()
2320 {
2321         if(nJoinAllowed(self)) {
2322                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2323                         self.classname = "player";
2324
2325                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2326                                 JoinBestTeam(self, FALSE, TRUE);
2327
2328                         if(autocvar_g_campaign)
2329                                 campaign_bots_may_start = 1;
2330
2331                         PutClientInServer();
2332
2333                         if(self.classname == "player")
2334                                 bprint ("^4", self.netname, "^4 is playing now\n");
2335
2336                         if(!autocvar_g_campaign)
2337                         if (time < self.jointime + autocvar_welcome_message_time)
2338                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2339
2340                         if (self.prevent_join_msgtime)
2341                         {
2342                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2343                                 self.prevent_join_msgtime = 0;
2344                         }
2345
2346                         return;
2347                 } else {
2348                         if (g_ca && self.caplayer) {
2349                         }       // do nothing
2350                         else
2351                                 stuffcmd(self,"menu_showteamselect\n");
2352                         return;
2353                 }
2354         }
2355         else {
2356                 //player may not join because of g_maxplayers is set
2357                 if (time - self.prevent_join_msgtime > 2)
2358                 {
2359                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2360                         self.prevent_join_msgtime = time;
2361                 }
2362         }
2363 }
2364
2365 /**
2366  * Determines whether the player is allowed to join. This depends on cvar
2367  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2368  * it checks whether the number of currently playing players exceeds g_maxplayers.
2369  * @return int number of free slots for players, 0 if none
2370  */
2371 float nJoinAllowed(entity ignore) {
2372         if(!ignore)
2373         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2374         // so report 0 free slots if restricted
2375         {
2376                 if(autocvar_g_forced_team_otherwise == "spectate")
2377                         return 0;
2378                 if(autocvar_g_forced_team_otherwise == "spectator")
2379                         return 0;
2380         }
2381
2382         if(self.team_forced < 0)
2383                 return 0; // forced spectators can never join
2384
2385         // TODO simplify this
2386         entity e;
2387         float totalClients = 0;
2388         FOR_EACH_CLIENT(e)
2389                 if(e != ignore)
2390                         totalClients += 1;
2391
2392         if (!autocvar_g_maxplayers)
2393                 return maxclients - totalClients;
2394
2395         float currentlyPlaying = 0;
2396         FOR_EACH_REALPLAYER(e)
2397                 currentlyPlaying += 1;
2398
2399         if(currentlyPlaying < autocvar_g_maxplayers)
2400                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2401
2402         return 0;
2403 }
2404
2405 /**
2406  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2407  * g_maxplayers_spectator_blocktime seconds
2408  */
2409 void checkSpectatorBlock() {
2410         if(self.classname == "spectator" || self.classname == "observer") {
2411                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2412                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2413                         dropclient(self);
2414                 }
2415         }
2416 }
2417
2418 .float motd_actived_time; // used for both motd and campaign_message
2419 void PrintWelcomeMessage()
2420 {
2421         if (self.motd_actived_time == 0) { // is there already a message showing?
2422                 if (autocvar_g_campaign) {
2423                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2424                                 self.motd_actived_time = time;
2425                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2426                         }
2427                 } else {
2428                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2429                                 self.motd_actived_time = time;
2430                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2431                         }
2432                 }
2433         } else { // showing MOTD or campaign message
2434                 if (autocvar_g_campaign) {
2435                         if (self.BUTTON_INFO)
2436                                 self.motd_actived_time = time;
2437                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2438                                 self.motd_actived_time = 0;
2439                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2440                         }
2441                 } else {
2442                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2443                                 if (self.BUTTON_INFO)
2444                                         self.motd_actived_time = time;
2445                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2446                                         self.motd_actived_time = 0;
2447                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2448                                 }
2449                         }
2450                 }
2451         }
2452 }
2453
2454 void ObserverThink()
2455 {
2456         float prefered_movetype;
2457         if (self.flags & FL_JUMPRELEASED) {
2458                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2459                         self.flags &~= FL_JUMPRELEASED;
2460                         self.flags |= FL_SPAWNING;
2461                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2462                         self.flags &~= FL_JUMPRELEASED;
2463                         if(SpectateNext(world) == 1) {
2464                                 self.classname = "spectator";
2465                         }
2466                 } else {
2467                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2468                         if (self.movetype != prefered_movetype)
2469                                 self.movetype = prefered_movetype;
2470                 }
2471         } else {
2472                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2473                         self.flags |= FL_JUMPRELEASED;
2474                         if(self.flags & FL_SPAWNING)
2475                         {
2476                                 self.flags &~= FL_SPAWNING;
2477                                 LeaveSpectatorMode();
2478                                 return;
2479                         }
2480                 }
2481         }
2482
2483         PrintWelcomeMessage();
2484 }
2485
2486 void SpectatorThink()
2487 {
2488         if (self.flags & FL_JUMPRELEASED) {
2489                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2490                         self.flags &~= FL_JUMPRELEASED;
2491                         self.flags |= FL_SPAWNING;
2492                 } else if(self.BUTTON_ATCK) {
2493                         self.flags &~= FL_JUMPRELEASED;
2494                         if(SpectateNext(world) == 1) {
2495                                 self.classname = "spectator";
2496                         } else {
2497                                 self.classname = "observer";
2498                                 PutClientInServer();
2499                         }
2500                 } else if (self.BUTTON_ATCK2) {
2501                         self.flags &~= FL_JUMPRELEASED;
2502                         self.classname = "observer";
2503                         PutClientInServer();
2504                 } else {
2505                         if(!SpectateUpdate())
2506                                 PutObserverInServer();
2507                 }
2508         } else {
2509                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2510                         self.flags |= FL_JUMPRELEASED;
2511                         if(self.flags & FL_SPAWNING)
2512                         {
2513                                 self.flags &~= FL_SPAWNING;
2514                                 LeaveSpectatorMode();
2515                                 return;
2516                         }
2517                 }
2518                 if(!SpectateUpdate())
2519                         PutObserverInServer();
2520         }
2521
2522         PrintWelcomeMessage();
2523         self.flags |= FL_CLIENT | FL_NOTARGET;
2524 }
2525
2526 void PlayerUseKey()
2527 {
2528         if(self.classname != "player")
2529                 return;
2530
2531         if(self.vehicle)
2532         {
2533         vehicles_exit(VHEF_NORMAL);
2534         return;
2535         }
2536
2537         // a use key was pressed; call handlers
2538         MUTATOR_CALLHOOK(PlayerUseKey);
2539 }
2540
2541 .float touchexplode_time;
2542
2543 /*
2544 =============
2545 PlayerPreThink
2546
2547 Called every frame for each client before the physics are run
2548 =============
2549 */
2550 .float usekeypressed;
2551 void() nexball_setstatus;
2552 .float items_added;
2553 void PlayerPreThink (void)
2554 {
2555         WarpZone_PlayerPhysics_FixVAngle();
2556
2557         self.stat_game_starttime = game_starttime;
2558         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2559         self.stat_leadlimit = autocvar_leadlimit;
2560
2561         if(g_arena || (g_ca && !allowed_to_spawn))
2562                 self.stat_respawn_time = 0;
2563         else
2564                 self.stat_respawn_time = self.respawn_time;
2565
2566         if(frametime)
2567         {
2568                 // physics frames: update anticheat stuff
2569                 anticheat_prethink();
2570         }
2571
2572         if(blockSpectators && frametime)
2573                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2574                 checkSpectatorBlock();
2575
2576         zoomstate_set = 0;
2577
2578         if(self.netname_previous != self.netname)
2579         {
2580                 if(autocvar_sv_eventlog)
2581                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2582                 if(self.netname_previous)
2583                         strunzone(self.netname_previous);
2584                 self.netname_previous = strzone(self.netname);
2585         }
2586
2587         // version nagging
2588         if(self.version_nagtime)
2589                 if(self.cvar_g_xonoticversion)
2590                         if(time > self.version_nagtime)
2591                         {
2592                                 // don't notify git users
2593                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2594                                 {
2595                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2596                                         {
2597                                                 // notify release users if connecting to git
2598                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2599                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2600                                         }
2601                                         else
2602                                         {
2603                                                 float r;
2604                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2605                                                 if(r < 0)
2606                                                 {
2607                                                         // give users new version
2608                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2609                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2610                                                 }
2611                                                 else if(r > 0)
2612                                                 {
2613                                                         // notify users about old server version
2614                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2615                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2616                                                 }
2617                                         }
2618                                 }
2619                                 self.version_nagtime = 0;
2620                         }
2621
2622         // GOD MODE info
2623         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2624         {
2625                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2626                 self.max_armorvalue = 0;
2627         }
2628
2629 #ifdef TETRIS
2630         if (TetrisPreFrame())
2631                 return;
2632 #endif
2633
2634         MUTATOR_CALLHOOK(PlayerPreThink);
2635
2636         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2637         {
2638                 if(self.BUTTON_USE && !self.usekeypressed)
2639                         PlayerUseKey();
2640                 self.usekeypressed = self.BUTTON_USE;
2641         }
2642
2643         PrintWelcomeMessage();
2644
2645         if(self.classname == "player") {
2646 //              if(self.netname == "Wazat")
2647 //                      bprint(self.classname, "\n");
2648
2649                 CheckRules_Player();
2650
2651                 if (intermission_running)
2652                 {
2653                         IntermissionThink ();   // otherwise a button could be missed between
2654                         return;                                 // the think tics
2655                 }
2656
2657                 //don't allow the player to turn around while game is paused!
2658                 if(timeout_status == TIMEOUT_ACTIVE) {
2659                         // FIXME turn this into CSQC stuff
2660                         self.v_angle = self.lastV_angle;
2661                         self.angles = self.lastV_angle;
2662                         self.fixangle = TRUE;
2663                 }
2664
2665                 if(frametime)
2666                 {
2667 #ifndef NO_LEGACY_NETWORKING
2668                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2669 #endif
2670
2671                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2672                         {
2673                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2674                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2675                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2676
2677                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2678                                 {
2679                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2680                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2681                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2682                                 }
2683                         }
2684                         else
2685                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2686
2687                         player_powerups();
2688                 }
2689
2690                 if (g_minstagib)
2691                         minstagib_ammocheck();
2692
2693                 if (self.deadflag != DEAD_NO)
2694                 {
2695                         float button_pressed, force_respawn;
2696                         if(self.personal && g_race_qualifying)
2697                         {
2698                                 if(time > self.respawn_time)
2699                                 {
2700                                         self.respawn_time = time + 1; // only retry once a second
2701                                         respawn();
2702                                         self.impulse = 141;
2703                                 }
2704                         }
2705                         else
2706                         {
2707                                 if(frametime)
2708                                         player_anim();
2709                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2710                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2711                                 if (self.deadflag == DEAD_DYING)
2712                                 {
2713                                         if(force_respawn)
2714                                                 self.deadflag = DEAD_RESPAWNING;
2715                                         else if(!button_pressed)
2716                                                 self.deadflag = DEAD_DEAD;
2717                                 }
2718                                 else if (self.deadflag == DEAD_DEAD)
2719                                 {
2720                                         if(button_pressed)
2721                                                 self.deadflag = DEAD_RESPAWNABLE;
2722                                 }
2723                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2724                                 {
2725                                         if(!button_pressed)
2726                                                 self.deadflag = DEAD_RESPAWNING;
2727                                 }
2728                                 else if (self.deadflag == DEAD_RESPAWNING)
2729                                 {
2730                                         if(time > self.respawn_time)
2731                                         {
2732                                                 self.respawn_time = time + 1; // only retry once a second
2733                                                 respawn();
2734                                         }
2735                                 }
2736                                 ShowRespawnCountdown();
2737                         }
2738
2739                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2740                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2741                                 self.stat_respawn_time *= -1;
2742
2743                         return;
2744                 }
2745                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2746                 // so (self.deadflag == DEAD_NO) is always true in the code below
2747
2748                 if(g_touchexplode)
2749                 if(time > self.touchexplode_time)
2750                 if(self.classname == "player")
2751                 if(self.deadflag == DEAD_NO)
2752                 if not(IS_INDEPENDENT_PLAYER(self))
2753                 FOR_EACH_PLAYER(other) if(self != other)
2754                 {
2755                         if(time > other.touchexplode_time)
2756                         if(other.deadflag == DEAD_NO)
2757                         if not(IS_INDEPENDENT_PLAYER(other))
2758                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2759                         {
2760                                 PlayerTouchExplode(self, other);
2761                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2762                         }
2763                 }
2764
2765                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2766                 {
2767                         vector dist;
2768
2769                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2770                         dist = self.prevorigin - self.origin;
2771                         dist_z = 0;
2772                         self.lms_traveled_distance += fabs(vlen(dist));
2773
2774                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2775                         {
2776                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2777                                 self.lms_traveled_distance = 0;
2778                         }
2779
2780                         if(time > self.lms_nextcheck)
2781                         {
2782                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2783                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2784                                 {
2785                                         centerprint(self, autocvar_g_lms_campcheck_message);
2786                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2787                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2788                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2789                                 }
2790                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2791                                 self.lms_traveled_distance = 0;
2792                         }
2793                 }
2794
2795                 self.prevorigin = self.origin;
2796
2797                 if (!self.vehicle)
2798                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x && !self.freezetag_frozen) // prevent crouching if using melee attack
2799                 {
2800                         if (!self.crouch)
2801                         {
2802                                 self.crouch = TRUE;
2803                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2804                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2805                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2806                         }
2807                 }
2808                 else
2809                 {
2810                         if (self.crouch)
2811                         {
2812                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2813                                 if (!trace_startsolid)
2814                                 {
2815                                         self.crouch = FALSE;
2816                                         self.view_ofs = PL_VIEW_OFS;
2817                                         setsize (self, PL_MIN, PL_MAX);
2818                                 }
2819                         }
2820                 }
2821
2822                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2823                 {
2824                         if(self.bloodloss_timer < time)
2825                         {
2826                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2827                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2828                         }
2829                 }
2830
2831                 FixPlayermodel();
2832
2833                 GrapplingHookFrame();
2834
2835                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2836                 //if(frametime)
2837                 {
2838                         self.items &~= self.items_added;
2839
2840                         W_WeaponFrame();
2841
2842                         self.items_added = 0;
2843                         if(self.items & IT_JETPACK)
2844                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2845                                         self.items_added |= IT_FUEL;
2846
2847                         self.items |= self.items_added;
2848                 }
2849
2850                 player_regen();
2851
2852                 // rot nex charge to the charge limit
2853                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2854                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2855
2856                 if(frametime)
2857                         player_anim();
2858
2859                 if(g_nexball)
2860                         nexball_setstatus();
2861
2862                 // secret status
2863                 secrets_setstatus();
2864
2865                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2866
2867                 //self.angles_y=self.v_angle_y + 90;   // temp
2868         } else if(gameover) {
2869                 if (intermission_running)
2870                         IntermissionThink ();   // otherwise a button could be missed between
2871                 return;
2872         } else if(self.classname == "observer") {
2873                 ObserverThink();
2874         } else if(self.classname == "spectator") {
2875                 SpectatorThink();
2876         }
2877
2878         if(!zoomstate_set)
2879                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2880
2881         float oldspectatee_status;
2882         oldspectatee_status = self.spectatee_status;
2883         if(self.classname == "spectator")
2884                 self.spectatee_status = num_for_edict(self.enemy);
2885         else if(self.classname == "observer")
2886                 self.spectatee_status = num_for_edict(self);
2887         else
2888                 self.spectatee_status = 0;
2889         if(self.spectatee_status != oldspectatee_status)
2890         {
2891                 ClientData_Touch(self);
2892                 if(g_race || g_cts)
2893                         race_InitSpectator();
2894         }
2895
2896         if(self.teamkill_soundtime)
2897         if(time > self.teamkill_soundtime)
2898         {
2899                 self.teamkill_soundtime = 0;
2900
2901                 entity oldpusher, oldself;
2902
2903                 oldself = self; self = self.teamkill_soundsource;
2904                 oldpusher = self.pusher; self.pusher = oldself;
2905
2906                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2907
2908                 self.pusher = oldpusher;
2909                 self = oldself;
2910         }
2911
2912         if(self.taunt_soundtime)
2913         if(time > self.taunt_soundtime)
2914         {
2915                 self.taunt_soundtime = 0;
2916                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2917         }
2918
2919         target_voicescript_next(self);
2920
2921         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2922         if(!self.weapon)
2923                 self.clip_load = self.clip_size = 0;
2924 }
2925
2926 float isInvisibleString(string s)
2927 {
2928         float i, n, c;
2929         s = strdecolorize(s);
2930         for((i = 0), (n = strlen(s)); i < n; ++i)
2931         {
2932                 c = str2chr(s, i);
2933                 switch(c)
2934                 {
2935                         case 0:
2936                         case 32: // space
2937                                 break;
2938                         case 192: // charmap space
2939                                 if (!autocvar_utf8_enable)
2940                                         break;
2941                                 return FALSE;
2942                         case 160: // space in unicode fonts
2943                         case 0xE000 + 192: // utf8 charmap space
2944                                 if (autocvar_utf8_enable)
2945                                         break;
2946                         default:
2947                                 return FALSE;
2948                 }
2949         }
2950         return TRUE;
2951 }
2952
2953 /*
2954 =============
2955 PlayerPostThink
2956
2957 Called every frame for each client after the physics are run
2958 =============
2959 */
2960 .float idlekick_lasttimeleft;
2961 .entity showheadshotbbox;
2962 void showheadshotbbox_think()
2963 {
2964         if(self.owner.showheadshotbbox != self)
2965         {
2966                 remove(self);
2967                 return;
2968         }
2969         self.nextthink = time;
2970         setorigin(self, self.owner.origin);
2971         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2972 }
2973 void PlayerPostThink (void)
2974 {
2975         // Savage: Check for nameless players
2976         if (isInvisibleString(self.netname)) {
2977                 self.netname = "Player";
2978                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2979         }
2980
2981         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2982         {
2983                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2984                 {
2985                         if(self.idlekick_lasttimeleft)
2986                         {
2987                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2988                                 self.idlekick_lasttimeleft = 0;
2989                         }
2990                 }
2991                 else
2992                 {
2993                         float timeleft;
2994                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2995                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2996                         {
2997                                 if(!self.idlekick_lasttimeleft)
2998                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2999                         }
3000                         if(timeleft <= 0)
3001                         {
3002                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
3003                                 AnnounceTo(self, "terminated");
3004                                 dropclient(self);
3005                                 return;
3006                         }
3007                         else if(timeleft <= 10)
3008                         {
3009                                 if(timeleft != self.idlekick_lasttimeleft)
3010                                         AnnounceTo(self, ftos(timeleft));
3011                                 self.idlekick_lasttimeleft = timeleft;
3012                         }
3013                 }
3014         }
3015
3016 #ifdef TETRIS
3017         if(self.impulse == 100)
3018                 ImpulseCommands();
3019         if (!TetrisPostFrame())
3020         {
3021 #endif
3022
3023         CheatFrame();
3024
3025         //CheckPlayerJump();
3026
3027         if(self.classname == "player") {
3028                 CheckRules_Player();
3029                 UpdateChatBubble();
3030                 if (self.impulse)
3031                         ImpulseCommands();
3032                 if (intermission_running)
3033                         return;         // intermission or finale
3034                 GetPressedKeys();
3035         }
3036
3037 #ifdef TETRIS
3038         }
3039 #endif
3040
3041         /*
3042         float i;
3043         for(i = 0; i < 1000; ++i)
3044         {
3045                 vector end;
3046                 end = self.origin + '0 0 1024' + 512 * randomvec();
3047                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3048                 if(trace_fraction < 1)
3049                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3050                 {
3051                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3052                         break;
3053                 }
3054         }
3055         */
3056
3057         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3058
3059         if(self.waypointsprite_attachedforcarrier)
3060                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3061
3062         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3063         {
3064                 if(!self.showheadshotbbox)
3065                 {
3066                         self.showheadshotbbox = spawn();
3067                         self.showheadshotbbox.classname = "headshotbbox";
3068                         self.showheadshotbbox.owner = self;
3069                         self.showheadshotbbox.think = showheadshotbbox_think;
3070                         self.showheadshotbbox.nextthink = time;
3071                         self = self.showheadshotbbox;
3072                         self.think();
3073                         self = self.owner;
3074                 }
3075         }
3076         else
3077         {
3078                 if(self.showheadshotbbox)
3079                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3080                 remove(self.showheadshotbbox);
3081         }
3082
3083         playerdemo_write();
3084
3085         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3086         {
3087                 if not(self.stored_netname)
3088                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3089                 if(self.stored_netname != self.netname)
3090                 {
3091                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3092                         strunzone(self.stored_netname);
3093                         self.stored_netname = strzone(self.netname);
3094                 }
3095         }
3096
3097         /*
3098         if(g_race)
3099                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3100         */
3101
3102         CSQCMODEL_AUTOUPDATE();
3103 }