qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         if (g_minstagib)
 618                 minstagib_stop_countdown();
 619
 620         Portal_ClearAll(self);
 621
 622         if(self.alivetime)
 623         {
 624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                 self.alivetime = 0;
 626         }
 627
 628         if(self.vehicle)
 629             vehicles_exit(VHEF_RELESE);
 630
 631         if(self.flagcarried)
 632                 DropFlag(self.flagcarried, world, world);
 633
 634         if(self.ballcarried && g_nexball)
 635                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 636
 637         WaypointSprite_PlayerDead();
 638
 639         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 640                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 641
 642         if(self.killcount != -666) {
 643                 if(g_lms) {
 644                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 645                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 646                         else
 647                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 648                 } else
 649                         bprint ("^4", self.netname, "^4 is spectating now\n");
 650
 651                 if(self.just_joined == FALSE) {
 652                         LogTeamchange(self.playerid, -1, 4);
 653                 } else
 654                         self.just_joined = FALSE;
 655         }
 656
 657         PlayerScore_Clear(self); // clear scores when needed
 658
 659         accuracy_resend(self);
 660
 661         self.spectatortime = time;
 662
 663         self.classname = "observer";
 664         self.iscreature = FALSE;
 665         self.health = -666;
 666         self.takedamage = DAMAGE_NO;
 667         self.solid = SOLID_NOT;
 668         self.movetype = MOVETYPE_NOCLIP;
 669         self.flags = FL_CLIENT | FL_NOTARGET;
 670         self.armorvalue = 666;
 671         self.effects = 0;
 672         self.armorvalue = autocvar_g_balance_armor_start;
 673         self.pauserotarmor_finished = 0;
 674         self.pauserothealth_finished = 0;
 675         self.pauseregen_finished = 0;
 676         self.damageforcescale = 0;
 677         self.death_time = 0;
 678         self.dead_frame = 0;
 679         self.alpha = 0;
 680         self.scale = 0;
 681         self.fade_time = 0;
 682         self.pain_frame = 0;
 683         self.pain_finished = 0;
 684         self.strength_finished = 0;
 685         self.invincible_finished = 0;
 686         self.pushltime = 0;
 687         self.think = SUB_Null;
 688         self.nextthink = 0;
 689         self.hook_time = 0;
 690         self.runes = 0;
 691         self.deadflag = DEAD_NO;
 692         self.angles = spot.angles;
 693         self.angles_z = 0;
 694         self.fixangle = TRUE;
 695         self.crouch = FALSE;
 696
 697         self.view_ofs = PL_VIEW_OFS;
 698         setorigin (self, spot.origin);
 699         setsize (self, '0 0 0', '0 0 0');
 700         self.prevorigin = self.origin;
 701         self.items = 0;
 702         self.weapons = 0;
 703         self.model = "";
 704         FixPlayermodel();
 705         self.model = "";
 706         self.modelindex = 0;
 707         self.weapon = 0;
 708         self.weaponmodel = "";
 709         self.weaponentity = world;
 710         self.exteriorweaponentity = world;
 711         self.killcount = -666;
 712         self.velocity = '0 0 0';
 713         self.avelocity = '0 0 0';
 714         self.punchangle = '0 0 0';
 715         self.punchvector = '0 0 0';
 716         self.oldvelocity = self.velocity;
 717         self.fire_endtime = -1;
 718
 719         if(sv_loddistance1)
 720                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 721
 722         if(g_arena)
 723         {
 724                 if(self.version_mismatch)
 725                 {
 726                         Spawnqueue_Unmark(self);
 727                         Spawnqueue_Remove(self);
 728                 }
 729                 else
 730                 {
 731                         Spawnqueue_Insert(self);
 732                 }
 733         }
 734         else if(g_lms)
 735         {
 736                 // Only if the player cannot play at all
 737                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 738                         self.frags = FRAGS_SPECTATOR;
 739                 else
 740                         self.frags = FRAGS_LMS_LOSER;
 741         }
 742         else
 743                 self.frags = FRAGS_SPECTATOR;
 744 }
 745
 746 void FixPlayermodel()
 747 {
 748         local string defaultmodel;
 749         local float defaultskin, chmdl, oldskin;
 750         local vector m1, m2;
 751
 752         defaultmodel = "";
 753
 754         if(autocvar_sv_defaultcharacter == 1) {
 755                 defaultskin = 0;
 756
 757                 if(teamplay)
 758                 {
 759                         string s;
 760                         s = Team_ColorNameLowerCase(self.team);
 761                         if(s != "neutral")
 762                         {
 763                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 764                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 765                         }
 766                 }
 767
 768                 if(defaultmodel == "")
 769                 {
 770                         defaultmodel = autocvar_sv_defaultplayermodel;
 771                         defaultskin = autocvar_sv_defaultplayerskin;
 772                 }
 773         }
 774
 775         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 776         {
 777                 if(self.model != "")
 778                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 779                 self.model = ""; // force the != checks to return true
 780         }
 781
 782         if(defaultmodel != "")
 783         {
 784                 if (defaultmodel != self.model)
 785                 {
 786                         m1 = self.mins;
 787                         m2 = self.maxs;
 788                         setmodel_lod (self, defaultmodel);
 789                         setsize (self, m1, m2);
 790                         chmdl = TRUE;
 791                 }
 792
 793                 oldskin = self.skinindex;
 794                 self.skinindex = defaultskin;
 795         } else {
 796                 if (self.playermodel != self.model || self.playermodel == "")
 797                 {
 798                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 799                         m1 = self.mins;
 800                         m2 = self.maxs;
 801                         setmodel_lod (self, self.playermodel);
 802                         setsize (self, m1, m2);
 803                         chmdl = TRUE;
 804                 }
 805
 806                 oldskin = self.skinindex;
 807                 self.skinindex = stof(self.playerskin);
 808         }
 809
 810         if(chmdl || oldskin != self.skinindex)
 811                 self.species = player_getspecies(); // model or skin has changed
 812
 813         if(!teamplay)
 814                 if(strlen(autocvar_sv_defaultplayercolors))
 815                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 816                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 817 }
 818
 819 void PlayerTouchExplode(entity p1, entity p2)
 820 {
 821         vector org;
 822         org = (p1.origin + p2.origin) * 0.5;
 823         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 824
 825         te_explosion(org);
 826
 827         entity e;
 828         e = spawn();
 829         setorigin(e, org);
 830         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 831         remove(e);
 832 }
 833
 834 /*
 835 =============
 836 PutClientInServer
 837
 838 Called when a client spawns in the server
 839 =============
 840 */
 841 //void() ctf_playerchanged;
 842 void PutClientInServer (void)
 843 {
 844         if(clienttype(self) == CLIENTTYPE_BOT)
 845         {
 846                 self.classname = "player";
 847         }
 848         else if(clienttype(self) == CLIENTTYPE_REAL)
 849         {
 850                 msg_entity = self;
 851                 WriteByte(MSG_ONE, SVC_SETVIEW);
 852                 WriteEntity(MSG_ONE, self);
 853         }
 854
 855         // player is dead and becomes observer
 856         // FIXME fix LMS scoring for new system
 857         if(g_lms)
 858         {
 859                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 860                         self.classname = "observer";
 861         }
 862
 863         if(g_arena || (g_ca && !allowed_to_spawn))
 864         if(!self.spawned)
 865                 self.classname = "observer";
 866
 867         if(gameover)
 868                 self.classname = "observer";
 869
 870         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 871                 entity spot, oldself;
 872                 float j;
 873
 874                 accuracy_resend(self);
 875
 876                 if(self.team < 0)
 877                         JoinBestTeam(self, FALSE, TRUE);
 878
 879                 race_PreSpawn();
 880
 881                 spot = SelectSpawnPoint (FALSE);
 882                 if(!spot)
 883                 {
 884                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 885                         return; // spawn failed
 886                 }
 887
 888                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 889
 890                 self.classname = "player";
 891                 self.wasplayer = TRUE;
 892                 self.iscreature = TRUE;
 893                 self.movetype = MOVETYPE_WALK;
 894                 self.solid = SOLID_SLIDEBOX;
 895                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 896                 if(autocvar_g_playerclip_collisions)
 897                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 898                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 899                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 900                 self.frags = FRAGS_PLAYER;
 901                 if(independent_players)
 902                         MAKE_INDEPENDENT_PLAYER(self);
 903                 self.flags = FL_CLIENT;
 904                 self.takedamage = DAMAGE_AIM;
 905                 if(g_minstagib)
 906                         self.effects = EF_FULLBRIGHT;
 907                 else
 908                         self.effects = 0;
 909                 self.air_finished = time + 12;
 910                 self.dmg = 2;
 911                 if(autocvar_g_balance_nex_charge)
 912                 {
 913                         if(autocvar_g_balance_nex_secondary_chargepool)
 914                                 self.nex_chargepool_ammo = 1;
 915                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 916                 }
 917
 918                 if(inWarmupStage)
 919                 {
 920                         self.ammo_shells = warmup_start_ammo_shells;
 921                         self.ammo_nails = warmup_start_ammo_nails;
 922                         self.ammo_rockets = warmup_start_ammo_rockets;
 923                         self.ammo_cells = warmup_start_ammo_cells;
 924                         self.ammo_fuel = warmup_start_ammo_fuel;
 925                         self.health = warmup_start_health;
 926                         self.armorvalue = warmup_start_armorvalue;
 927                         self.weapons = warmup_start_weapons;
 928                 }
 929                 else
 930                 {
 931                         self.ammo_shells = start_ammo_shells;
 932                         self.ammo_nails = start_ammo_nails;
 933                         self.ammo_rockets = start_ammo_rockets;
 934                         self.ammo_cells = start_ammo_cells;
 935                         self.ammo_fuel = start_ammo_fuel;
 936                         self.health = start_health;
 937                         self.armorvalue = start_armorvalue;
 938                         self.weapons = start_weapons;
 939                 }
 940
 941                 if(g_weaponarena_random)
 942                 {
 943                         if(g_weaponarena_random_with_laser)
 944                                 self.weapons &~= WEPBIT_LASER;
 945                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 946                         if(g_weaponarena_random_with_laser)
 947                                 self.weapons |= WEPBIT_LASER;
 948                 }
 949
 950                 self.items = start_items;
 951                 self.jump_interval = time;
 952
 953                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 954                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 955                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 956                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 957                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 958                 //extend the pause of rotting if client was reset at the beginning of the countdown
 959                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 960                         self.spawnshieldtime += game_starttime - time;
 961                         self.pauserotarmor_finished += game_starttime - time;
 962                         self.pauserothealth_finished += game_starttime - time;
 963                         self.pauseregen_finished += game_starttime - time;
 964                 }
 965                 self.damageforcescale = 2;
 966                 self.death_time = 0;
 967                 self.dead_frame = 0;
 968                 self.alpha = 0;
 969                 self.scale = 0;
 970                 self.fade_time = 0;
 971                 self.pain_frame = 0;
 972                 self.pain_finished = 0;
 973                 self.strength_finished = 0;
 974                 self.invincible_finished = 0;
 975                 self.pushltime = 0;
 976                 // players have no think function
 977                 self.think = SUB_Null;
 978                 self.nextthink = 0;
 979                 self.hook_time = 0;
 980                 self.dmg_team = 0;
 981                 self.ballistics_density = autocvar_g_ballistics_density_player;
 982
 983                 self.metertime = 0;
 984
 985                 self.runes = 0;
 986
 987                 self.deadflag = DEAD_NO;
 988
 989                 self.angles = spot.angles;
 990
 991                 self.angles_z = 0; // never spawn tilted even if the spot says to
 992                 self.fixangle = TRUE; // turn this way immediately
 993                 self.velocity = '0 0 0';
 994                 self.avelocity = '0 0 0';
 995                 self.punchangle = '0 0 0';
 996                 self.punchvector = '0 0 0';
 997                 self.oldvelocity = self.velocity;
 998                 self.fire_endtime = -1;
 999
1000                 msg_entity = self;
1001                 WRITESPECTATABLE_MSG_ONE({
1002                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1003                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1004                 });
1005
1006                 if(sv_loddistance1)
1007                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1008
1009                 self.model = "";
1010                 FixPlayermodel();
1011
1012                 self.crouch = FALSE;
1013                 self.view_ofs = PL_VIEW_OFS;
1014                 setsize (self, PL_MIN, PL_MAX);
1015                 self.spawnorigin = spot.origin;
1016                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1017                 // don't reset back to last position, even if new position is stuck in solid
1018                 self.oldorigin = self.origin;
1019                 self.prevorigin = self.origin;
1020                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1021
1022                 if(g_arena)
1023                 {
1024                         Spawnqueue_Remove(self);
1025                         Spawnqueue_Mark(self);
1026                 }
1027
1028                 else if(g_ca)
1029                         self.caplayer = 1;
1030
1031                 self.event_damage = PlayerDamage;
1032
1033                 self.bot_attack = TRUE;
1034
1035                 self.statdraintime = time + 5;
1036                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1037
1038                 if(self.killcount == -666) {
1039                         PlayerScore_Clear(self);
1040                         self.killcount = 0;
1041                 }
1042
1043                 self.cnt = WEP_LASER;
1044
1045                 CL_SpawnWeaponentity();
1046                 self.alpha = default_player_alpha;
1047                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1048                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1049
1050                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1051                 self.lms_traveled_distance = 0;
1052                 self.speedrunning = FALSE;
1053
1054                 race_PostSpawn(spot);
1055
1056                 if(autocvar_spawn_debug)
1057                 {
1058                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1059                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1060                 }
1061
1062                 //stuffcmd(self, "chase_active 0");
1063                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1064
1065                 if (autocvar_g_spawnsound)
1066                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1067
1068                 if(g_assault) {
1069                         if(self.team == assault_attacker_team)
1070                                 centerprint(self, "You are attacking!");
1071                         else
1072                                 centerprint(self, "You are defending!");
1073                 }
1074
1075                 target_voicescript_clear(self);
1076
1077                 // reset fields the weapons may use
1078                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1079                 {
1080                         weapon_action(j, WR_RESETPLAYER);
1081
1082                         // all weapons must be fully loaded when we spawn
1083                         entity e;
1084                         e = get_weaponinfo(j);
1085                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1086                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1087                 }
1088                 self.weapon_forbidchange = FALSE;
1089
1090                 oldself = self;
1091                 self = spot;
1092                         activator = oldself;
1093                                 string s;
1094                                 s = self.target;
1095                                 self.target = string_null;
1096                                 SUB_UseTargets();
1097                                 self.target = s;
1098                         activator = world;
1099                 self = oldself;
1100
1101                 MUTATOR_CALLHOOK(PlayerSpawn);
1102
1103                 self.switchweapon = w_getbestweapon(self);
1104                 self.cnt = self.switchweapon;
1105                 self.weapon = 0;
1106
1107                 if(!self.alivetime)
1108                         self.alivetime = time;
1109         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1110                 PutObserverInServer ();
1111         }
1112
1113         //if(g_ctf)
1114         //      ctf_playerchanged();
1115 }
1116
1117 .float ebouncefactor, ebouncestop; // electro's values
1118 // TODO do we need all these fields, or should we stop autodetecting runtime
1119 // changes and just have a console command to update this?
1120 float ClientInit_SendEntity(entity to, float sf)
1121 {
1122         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1123         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1124         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1125         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1126         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1127         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1128         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1129         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1130         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1131         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1132         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1133         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1134         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1135         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1136         if(sv_foginterval && world.fog != "")
1137                 WriteString(MSG_ENTITY, world.fog);
1138         else
1139                 WriteString(MSG_ENTITY, "");
1140         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1141         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1142         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1143         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1144         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1145         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1146         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1147         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1148         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1149         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1150         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1151         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1152         return TRUE;
1153 }
1154
1155 void ClientInit_CheckUpdate()
1156 {
1157         self.nextthink = time;
1158         if(self.count != autocvar_g_balance_armor_blockpercent)
1159         {
1160                 self.count = autocvar_g_balance_armor_blockpercent;
1161                 self.SendFlags |= 1;
1162         }
1163         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1164         {
1165                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1166                 self.SendFlags |= 1;
1167         }
1168         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1169         {
1170                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1171                 self.SendFlags |= 1;
1172         }
1173         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1174         {
1175                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1176                 self.SendFlags |= 1;
1177         }
1178         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1179         {
1180                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1181                 self.SendFlags |= 1;
1182         }
1183         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1184         {
1185                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1186                 self.SendFlags |= 1;
1187         }
1188 }
1189
1190 void ClientInit_Spawn()
1191 {
1192         entity o;
1193         entity e;
1194         e = spawn();
1195         e.classname = "clientinit";
1196         e.think = ClientInit_CheckUpdate;
1197         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1198
1199         o = self;
1200         self = e;
1201         ClientInit_CheckUpdate();
1202         self = o;
1203 }
1204
1205 /*
1206 =============
1207 SetNewParms
1208 =============
1209 */
1210 void SetNewParms (void)
1211 {
1212         // initialize parms for a new player
1213         parm1 = -(86400 * 366);
1214 }
1215
1216 /*
1217 =============
1218 SetChangeParms
1219 =============
1220 */
1221 void SetChangeParms (void)
1222 {
1223         // save parms for level change
1224         parm1 = self.parm_idlesince - time;
1225 }
1226
1227 /*
1228 =============
1229 DecodeLevelParms
1230 =============
1231 */
1232 void DecodeLevelParms (void)
1233 {
1234         // load parms
1235         self.parm_idlesince = parm1;
1236         if(self.parm_idlesince == -(86400 * 366))
1237                 self.parm_idlesince = time;
1238
1239         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1240         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1241 }
1242
1243 /*
1244 =============
1245 ClientKill
1246
1247 Called when a client types 'kill' in the console
1248 =============
1249 */
1250
1251 .float clientkill_nexttime;
1252 void ClientKill_Now_TeamChange()
1253 {
1254         if(self.killindicator_teamchange == -1)
1255         {
1256                 self.team = -1;
1257                 JoinBestTeam( self, FALSE, FALSE );
1258         }
1259         else if(self.killindicator_teamchange == -2)
1260         {
1261                 if(g_ca)
1262                         self.caplayer = 0;
1263                 if(blockSpectators)
1264                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1265                 PutObserverInServer();
1266         }
1267         else
1268                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1269 }
1270
1271 void ClientKill_Now()
1272 {
1273         if(self.vehicle)
1274         {
1275             vehicles_exit(VHEF_RELESE);
1276             if(!self.killindicator_teamchange)
1277             {
1278             self.vehicle_health = -1;
1279             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1280             }
1281         }
1282
1283         remove(self.killindicator);
1284         self.killindicator = world;
1285
1286         if(self.killindicator_teamchange)
1287                 ClientKill_Now_TeamChange();
1288
1289         // in any case:
1290         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1291
1292         // now I am sure the player IS dead
1293 }
1294 void KillIndicator_Think()
1295 {
1296         if (!self.owner.modelindex)
1297         {
1298                 self.owner.killindicator = world;
1299                 remove(self);
1300                 return;
1301         }
1302
1303         if(self.cnt <= 0)
1304         {
1305                 self = self.owner;
1306                 ClientKill_Now(); // no oldself needed
1307                 return;
1308         }
1309     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1310     {
1311         self.nextthink = time + 1;
1312         self.cnt -= 1;
1313     }
1314         else
1315         {
1316                 if(self.cnt <= 10)
1317                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1318                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1319                 {
1320                         if(self.cnt <= 10)
1321                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1322                 }
1323                 self.nextthink = time + 1;
1324                 self.cnt -= 1;
1325         }
1326 }
1327
1328 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1329 {
1330         float killtime;
1331         entity e;
1332         killtime = autocvar_g_balance_kill_delay;
1333
1334         if(g_race_qualifying || g_cts)
1335                 killtime = 0;
1336
1337     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1338     {
1339                 remove(self.killindicator);
1340                 self.killindicator = world;
1341
1342         ClientKill_Now(); // allow instant kill in this case
1343         return;
1344     }
1345
1346         self.killindicator_teamchange = targetteam;
1347
1348     if(!self.killindicator)
1349         {
1350                 if(self.modelindex && self.deadflag == DEAD_NO)
1351                 {
1352                         killtime = max(killtime, self.clientkill_nexttime - time);
1353                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1354                 }
1355
1356                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1357                 {
1358                         ClientKill_Now();
1359                 }
1360                 else
1361                 {
1362                         self.killindicator = spawn();
1363                         self.killindicator.owner = self;
1364                         self.killindicator.scale = 0.5;
1365                         setattachment(self.killindicator, self, "");
1366                         setorigin(self.killindicator, '0 0 52');
1367                         self.killindicator.think = KillIndicator_Think;
1368                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1369                         self.killindicator.cnt = ceil(killtime);
1370                         self.killindicator.count = bound(0, ceil(killtime), 10);
1371                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1372
1373                         for(e = world; (e = find(e, classname, "body")) != world; )
1374                         {
1375                                 if(e.enemy != self)
1376                                         continue;
1377                                 e.killindicator = spawn();
1378                                 e.killindicator.owner = e;
1379                                 e.killindicator.scale = 0.5;
1380                                 setattachment(e.killindicator, e, "");
1381                                 setorigin(e.killindicator, '0 0 52');
1382                                 e.killindicator.think = KillIndicator_Think;
1383                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1384                                 e.killindicator.cnt = ceil(killtime);
1385                         }
1386                         self.lip = 0;
1387                 }
1388         }
1389         if(self.killindicator)
1390         {
1391                 if(targetteam == 0) // just die
1392                 {
1393                         self.killindicator.colormod = '0 0 0';
1394                         if(clienttype(self) == CLIENTTYPE_REAL)
1395                                 Send_CSQC_Centerprint_Generic(self, CPID_KILL, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1396                 }
1397                 else if(targetteam == -1) // auto
1398                 {
1399                         self.killindicator.colormod = '0 1 0';
1400                         if(clienttype(self) == CLIENTTYPE_REAL)
1401                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1402                 }
1403                 else if(targetteam == -2) // spectate
1404                 {
1405                         self.killindicator.colormod = '0.5 0.5 0.5';
1406                         if(clienttype(self) == CLIENTTYPE_REAL)
1407                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1408                 }
1409                 else
1410                 {
1411                         self.killindicator.colormod = TeamColor(targetteam);
1412                         if(clienttype(self) == CLIENTTYPE_REAL)
1413                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1414                 }
1415         }
1416
1417 }
1418
1419 void ClientKill (void)
1420 {
1421         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1422         {
1423                 // do nothing
1424         }
1425     else if(self.freezetag_frozen)
1426     {
1427         // do nothing
1428     }
1429         else
1430                 ClientKill_TeamChange(0);
1431 }
1432
1433 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1434 {
1435     e.killindicator = spawn();
1436     e.killindicator.owner = e;
1437     e.killindicator.think = KillIndicator_Think;
1438     e.killindicator.nextthink = time + (e.lip) * 0.05;
1439     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1440     e.killindicator.health = 1; // this is used to indicate that it should be silent
1441     e.lip = 0;
1442 }
1443
1444 void DoTeamChange(float destteam)
1445 {
1446         float t, c0;
1447         if(!teamplay)
1448         {
1449                 if(destteam >= 0)
1450                         SetPlayerColors(self, destteam);
1451                 return;
1452         }
1453         if(self.classname == "player")
1454         if(destteam == -1)
1455         {
1456                 CheckAllowedTeams(self);
1457                 t = FindSmallestTeam(self, TRUE);
1458                 switch(self.team)
1459                 {
1460                         case COLOR_TEAM1: c0 = c1; break;
1461                         case COLOR_TEAM2: c0 = c2; break;
1462                         case COLOR_TEAM3: c0 = c3; break;
1463                         case COLOR_TEAM4: c0 = c4; break;
1464                         default:          c0 = 999;
1465                 }
1466                 switch(t)
1467                 {
1468                         case 1:
1469                                 if(c0 > c1)
1470                                         destteam = COLOR_TEAM1;
1471                                 break;
1472                         case 2:
1473                                 if(c0 > c2)
1474                                         destteam = COLOR_TEAM2;
1475                                 break;
1476                         case 3:
1477                                 if(c0 > c3)
1478                                         destteam = COLOR_TEAM3;
1479                                 break;
1480                         case 4:
1481                                 if(c0 > c4)
1482                                         destteam = COLOR_TEAM4;
1483                                 break;
1484                 }
1485                 if(destteam == -1)
1486                         return;
1487         }
1488         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1489                 return;
1490         ClientKill_TeamChange(destteam);
1491 }
1492
1493 void FixClientCvars(entity e)
1494 {
1495         // send prediction settings to the client
1496         stuffcmd(e, "\nin_bindmap 0 0\n");
1497         if(g_race || g_cts)
1498                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1499         if(autocvar_g_antilag == 3) // client side hitscan
1500                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1501         if(sv_gentle)
1502                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1503         /*
1504          * we no longer need to stuff this. Remove this comment block if you feel
1505          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1506         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1507         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1508         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1509         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1510         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1511         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1512         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1513         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1514         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1515         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1516         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1517         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1518         stuffcmd(e, "cl_movement_edgefriction 1\n");
1519          */
1520 }
1521
1522 float PlayerInIDList(entity p, string idlist)
1523 {
1524         float n, i;
1525         string s;
1526
1527         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1528         if not(p.crypto_idfp)
1529                 return 0;
1530
1531         // this function allows abbreviated player IDs too!
1532         n = tokenize_console(idlist);
1533         for(i = 0; i < n; ++i)
1534         {
1535                 s = argv(i);
1536                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1537                         return 1;
1538         }
1539
1540         return 0;
1541 }
1542
1543 /*
1544 =============
1545 ClientConnect
1546
1547 Called when a client connects to the server
1548 =============
1549 */
1550 //void ctf_clientconnect();
1551 string ColoredTeamName(float t);
1552 void DecodeLevelParms (void);
1553 //void dom_player_join_team(entity pl);
1554 void set_dom_state(entity e);
1555 void ClientConnect (void)
1556 {
1557         float t;
1558
1559         if(self.flags & FL_CLIENT)
1560         {
1561                 print("Warning: ClientConnect, but already connected!\n");
1562                 return;
1563         }
1564
1565         if(Ban_MaybeEnforceBan(self))
1566                 return;
1567
1568         DecodeLevelParms();
1569
1570 #ifdef WATERMARK
1571         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1572 #endif
1573
1574         self.classname = "player_joining";
1575
1576         self.flags = FL_CLIENT;
1577         self.version_nagtime = time + 10 + random() * 10;
1578
1579         if(player_count<0)
1580         {
1581                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1582                 player_count = 0;
1583         }
1584
1585         PlayerScore_Attach(self);
1586         ClientData_Attach();
1587         accuracy_init(self);
1588
1589         bot_clientconnect();
1590
1591         playerdemo_init();
1592
1593         anticheat_init();
1594
1595         race_PreSpawnObserver();
1596
1597         //if(g_domination)
1598         //      dom_player_join_team(self);
1599
1600         // identify the right forced team
1601         if(autocvar_g_campaign)
1602         {
1603                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1604                 {
1605                         switch(autocvar_g_campaign_forceteam)
1606                         {
1607                                 case 1: self.team_forced = COLOR_TEAM1; break;
1608                                 case 2: self.team_forced = COLOR_TEAM2; break;
1609                                 case 3: self.team_forced = COLOR_TEAM3; break;
1610                                 case 4: self.team_forced = COLOR_TEAM4; break;
1611                                 default: self.team_forced = 0;
1612                         }
1613                 }
1614         }
1615         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1616                 self.team_forced = COLOR_TEAM1;
1617         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1618                 self.team_forced = COLOR_TEAM2;
1619         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1620                 self.team_forced = COLOR_TEAM3;
1621         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1622                 self.team_forced = COLOR_TEAM4;
1623         else if(autocvar_g_forced_team_otherwise == "red")
1624                 self.team_forced = COLOR_TEAM1;
1625         else if(autocvar_g_forced_team_otherwise == "blue")
1626                 self.team_forced = COLOR_TEAM2;
1627         else if(autocvar_g_forced_team_otherwise == "yellow")
1628                 self.team_forced = COLOR_TEAM3;
1629         else if(autocvar_g_forced_team_otherwise == "pink")
1630                 self.team_forced = COLOR_TEAM4;
1631         else if(autocvar_g_forced_team_otherwise == "spectate")
1632                 self.team_forced = -1;
1633         else if(autocvar_g_forced_team_otherwise == "spectator")
1634                 self.team_forced = -1;
1635         else
1636                 self.team_forced = 0;
1637
1638         if(!teamplay)
1639                 if(self.team_forced > 0)
1640                         self.team_forced = 0;
1641
1642         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1643
1644         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1645                 self.classname = "observer";
1646         } else {
1647                 if(teamplay)
1648                 {
1649                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1650                         {
1651                                 self.classname = "player";
1652                                 campaign_bots_may_start = 1;
1653                         }
1654                         else
1655                         {
1656                                 self.classname = "observer"; // do it anyway
1657                         }
1658                 }
1659                 else
1660                 {
1661                         self.classname = "player";
1662                         campaign_bots_may_start = 1;
1663                 }
1664         }
1665
1666         self.playerid = (playerid_last = playerid_last + 1);
1667
1668     if(clienttype(self) == CLIENTTYPE_BOT)
1669         PlayerStats_AddPlayer(self);
1670
1671         if(autocvar_sv_eventlog)
1672                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1673
1674         LogTeamchange(self.playerid, self.team, 1);
1675
1676         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1677
1678         self.netname_previous = strzone(self.netname);
1679
1680         bprint("^4", self.netname, "^4 connected");
1681
1682         if(self.classname != "observer" && (g_domination || g_ctf))
1683                 bprint(" and joined the ", ColoredTeamName(self.team));
1684
1685         bprint("\n");
1686
1687         stuffcmd(self, strcat(clientstuff, "\n"));
1688         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1689         stuffcmd(self, "cl_particles_reloadeffects\n");
1690
1691         FixClientCvars(self);
1692
1693         // spawnfunc_waypoint sprites
1694         WaypointSprite_InitClient(self);
1695
1696         // Wazat's grappling hook
1697         SetGrappleHookBindings();
1698
1699         // get autoswitch state from player when he toggles it
1700         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1701
1702         // get version info from player
1703         stuffcmd(self, "cmd clientversion $gameversion\n");
1704
1705         // get other cvars from player
1706         GetCvars(0);
1707
1708         // notify about available teams
1709         if(teamplay)
1710         {
1711                 CheckAllowedTeams(self);
1712                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1713                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1714         }
1715         else
1716                 stuffcmd(self, "set _teams_available 0\n");
1717
1718         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1719
1720         if(g_arena || g_ca)
1721         {
1722                 self.classname = "observer";
1723                 if(g_arena)
1724                         Spawnqueue_Insert(self);
1725         }
1726         /*else if(g_ctf)
1727         {
1728                 ctf_clientconnect();
1729         }*/
1730
1731         attach_entcs();
1732
1733         bot_relinkplayerlist();
1734
1735         self.spectatortime = time;
1736         if(blockSpectators)
1737         {
1738                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1739         }
1740
1741         self.jointime = time;
1742         self.allowedTimeouts = autocvar_sv_timeout_number;
1743
1744         if(clienttype(self) == CLIENTTYPE_REAL)
1745         {
1746                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1747                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1748         }
1749
1750         if(g_lms)
1751         {
1752                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1753                 {
1754                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1755                         self.frags = FRAGS_SPECTATOR;
1756                 }
1757         }
1758
1759         if(!sv_foginterval && world.fog != "")
1760                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1761
1762         SoundEntity_Attach(self);
1763
1764         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1765         {
1766                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1767                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1768         }
1769         else
1770                 self.hitplotfh = -1;
1771
1772         if(g_race || g_cts) {
1773                 string rr;
1774                 if(g_cts)
1775                         rr = CTS_RECORD;
1776                 else
1777                         rr = RACE_RECORD;
1778                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1779
1780                 msg_entity = self;
1781                 race_send_recordtime(MSG_ONE);
1782                 race_send_speedaward(MSG_ONE);
1783
1784                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1785                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1786                 race_send_speedaward_alltimebest(MSG_ONE);
1787
1788                 float i;
1789                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1790                         race_SendRankings(i, 0, 0, MSG_ONE);
1791                 }
1792         }
1793         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1794                 send_CSQC_teamnagger();
1795
1796         if (g_domination)
1797                 set_dom_state(self);
1798
1799         CheatInitClient();
1800
1801         if(!autocvar_g_campaign)
1802                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1803 }
1804
1805 /*
1806 =============
1807 ClientDisconnect
1808
1809 Called when a client disconnects from the server
1810 =============
1811 */
1812 .entity chatbubbleentity;
1813 void ReadyCount();
1814 void ClientDisconnect (void)
1815 {
1816         if(self.vehicle)
1817             vehicles_exit(VHEF_RELESE);
1818
1819         if not(self.flags & FL_CLIENT)
1820         {
1821                 print("Warning: ClientDisconnect without ClientConnect\n");
1822                 return;
1823         }
1824
1825         PlayerStats_AddGlobalInfo(self);
1826
1827         CheatShutdownClient();
1828
1829         if(self.hitplotfh >= 0)
1830         {
1831                 fclose(self.hitplotfh);
1832                 self.hitplotfh = -1;
1833         }
1834
1835         anticheat_report();
1836         anticheat_shutdown();
1837
1838         playerdemo_shutdown();
1839
1840         bot_clientdisconnect();
1841
1842         if(self.entcs)
1843                 detach_entcs();
1844
1845         if(autocvar_sv_eventlog)
1846                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1847         bprint ("^4",self.netname);
1848         bprint ("^4 disconnected\n");
1849
1850         SoundEntity_Detach(self);
1851
1852         DropAllRunes(self);
1853         MUTATOR_CALLHOOK(ClientDisconnect);
1854
1855         Portal_ClearAll(self);
1856
1857         if(self.flagcarried)
1858                 DropFlag(self.flagcarried, world, world);
1859         if(self.ballcarried && g_nexball)
1860                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1861
1862         // Here, everything has been done that requires this player to be a client.
1863
1864         self.flags &~= FL_CLIENT;
1865
1866         if (self.chatbubbleentity)
1867                 remove (self.chatbubbleentity);
1868
1869         if (self.killindicator)
1870                 remove (self.killindicator);
1871
1872         WaypointSprite_PlayerGone();
1873
1874         bot_relinkplayerlist();
1875
1876         if(g_arena)
1877         {
1878                 Spawnqueue_Unmark(self);
1879                 Spawnqueue_Remove(self);
1880         }
1881
1882         accuracy_free(self);
1883         ClientData_Detach();
1884         PlayerScore_Detach(self);
1885
1886         if(self.netname_previous)
1887                 strunzone(self.netname_previous);
1888         if(self.clientstatus)
1889                 strunzone(self.clientstatus);
1890         if(self.weaponorder_byimpulse)
1891                 strunzone(self.weaponorder_byimpulse);
1892
1893         ClearPlayerSounds();
1894
1895         if(self.personal)
1896                 remove(self.personal);
1897
1898         self.playerid = 0;
1899         ReadyCount();
1900
1901         // free cvars
1902         GetCvars(-1);
1903 }
1904
1905 .float BUTTON_CHAT;
1906 void ChatBubbleThink()
1907 {
1908         self.nextthink = time;
1909         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1910         {
1911                 if(self.owner) // but why can that ever be world?
1912                         self.owner.chatbubbleentity = world;
1913                 remove(self);
1914                 return;
1915         }
1916         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1917 #ifdef TETRIS
1918                 || self.owner.tetris_on
1919 #endif
1920         )
1921                 self.model = self.mdl;
1922         else
1923                 self.model = "";
1924 };
1925
1926 void UpdateChatBubble()
1927 {
1928         if (!self.modelindex)
1929                 return;
1930         // spawn a chatbubble entity if needed
1931         if (!self.chatbubbleentity)
1932         {
1933                 self.chatbubbleentity = spawn();
1934                 self.chatbubbleentity.owner = self;
1935                 self.chatbubbleentity.exteriormodeltoclient = self;
1936                 self.chatbubbleentity.think = ChatBubbleThink;
1937                 self.chatbubbleentity.nextthink = time;
1938                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1939                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1940                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1941                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1942                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1943                 self.chatbubbleentity.model = "";
1944                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1945         }
1946 }
1947
1948
1949 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1950 // added to the model skins
1951 /*void UpdateColorModHack()
1952 {
1953         local float c;
1954         c = self.clientcolors & 15;
1955         // LordHavoc: only bothering to support white, green, red, yellow, blue
1956              if (!teamplay) self.colormod = '0 0 0';
1957         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1958         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1959         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1960         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1961         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1962         else self.colormod = '1 1 1';
1963 };*/
1964
1965 .float oldcolormap;
1966 void respawn(void)
1967 {
1968         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1969         {
1970                 self.solid = SOLID_NOT;
1971                 self.takedamage = DAMAGE_NO;
1972                 self.movetype = MOVETYPE_FLY;
1973                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1974                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1975                 self.effects |= EF_ADDITIVE;
1976                 self.oldcolormap = self.colormap;
1977                 self.colormap = 512;
1978                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1979                 if(autocvar_g_respawn_ghosts_maxtime)
1980                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1981         }
1982
1983         CopyBody(1);
1984         self.effects |= EF_NODRAW; // prevent another CopyBody
1985         if(self.oldcolormap)
1986         {
1987                 self.colormap = self.oldcolormap;
1988                 self.oldcolormap = 0;
1989         }
1990         PutClientInServer();
1991 }
1992
1993 void play_countdown(float finished, string samp)
1994 {
1995         if(clienttype(self) == CLIENTTYPE_REAL)
1996                 if(floor(finished - time - frametime) != floor(finished - time))
1997                         if(finished - time < 6)
1998                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1999 }
2000
2001 void player_powerups (void)
2002 {
2003         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2004         olditems = self.items;
2005
2006         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2007         {
2008                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2009                 self.modelflags |= MF_ROCKET;
2010         }
2011         else
2012         {
2013                 SoundEntity_StopSound(self, CHAN_PLAYER);
2014                 self.modelflags &~= MF_ROCKET;
2015         }
2016
2017         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2018
2019         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2020                 return;
2021
2022         Fire_ApplyDamage(self);
2023         Fire_ApplyEffect(self);
2024
2025         if (g_minstagib)
2026         {
2027                 self.effects |= EF_FULLBRIGHT;
2028
2029                 if (self.items & IT_STRENGTH)
2030                 {
2031                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2032                         if (time > self.strength_finished)
2033                         {
2034                                 self.alpha = default_player_alpha;
2035                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2036                                 self.items &~= IT_STRENGTH;
2037                                 sprint(self, "^3Invisibility has worn off\n");
2038                         }
2039                 }
2040                 else
2041                 {
2042                         if (time < self.strength_finished)
2043                         {
2044                                 self.alpha = g_minstagib_invis_alpha;
2045                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2046                                 self.items |= IT_STRENGTH;
2047                                 sprint(self, "^3You are invisible\n");
2048                         }
2049                 }
2050
2051                 if (self.items & IT_INVINCIBLE)
2052                 {
2053                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2054                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2055                         {
2056                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2057                                 sprint(self, "^3Speed has worn off\n");
2058                         }
2059                 }
2060                 else
2061                 {
2062                         if (time < self.invincible_finished)
2063                         {
2064                                 self.items = self.items | IT_INVINCIBLE;
2065                                 sprint(self, "^3You are on speed\n");
2066                         }
2067                 }
2068         }
2069         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2070         {
2071                 if (self.items & IT_STRENGTH)
2072                 {
2073                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2074                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2075                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2076                         {
2077                                 self.items = self.items - (self.items & IT_STRENGTH);
2078                                 sprint(self, "^3Strength has worn off\n");
2079                         }
2080                 }
2081                 else
2082                 {
2083                         if (time < self.strength_finished)
2084                         {
2085                                 self.items = self.items | IT_STRENGTH;
2086                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2087                         }
2088                 }
2089                 if (self.items & IT_INVINCIBLE)
2090                 {
2091                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2092                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2093                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2094                         {
2095                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2096                                 sprint(self, "^3Shield has worn off\n");
2097                         }
2098                 }
2099                 else
2100                 {
2101                         if (time < self.invincible_finished)
2102                         {
2103                                 self.items = self.items | IT_INVINCIBLE;
2104                                 sprint(self, "^3Shield surrounds you\n");
2105                         }
2106                 }
2107
2108                 if(autocvar_g_nodepthtestplayers)
2109                         self.effects = self.effects | EF_NODEPTHTEST;
2110
2111                 if(autocvar_g_fullbrightplayers)
2112                         self.effects = self.effects | EF_FULLBRIGHT;
2113
2114                 // midair gamemode: damage only while in the air
2115                 // if in midair mode, being on ground grants temporary invulnerability
2116                 // (this is so that multishot weapon don't clear the ground flag on the
2117                 // first damage in the frame, leaving the player vulnerable to the
2118                 // remaining hits in the same frame)
2119                 if (self.flags & FL_ONGROUND)
2120                 if (g_midair)
2121                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2122
2123                 if (time >= game_starttime)
2124                 if (time < self.spawnshieldtime)
2125                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2126         }
2127
2128         MUTATOR_CALLHOOK(PlayerPowerups);
2129 }
2130
2131 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2132 {
2133         if(current > stable)
2134                 return current;
2135         else if(current > stable - 0.25) // when close enough, "snap"
2136                 return stable;
2137         else
2138                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2139 }
2140
2141 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2142 {
2143         if(current < stable)
2144                 return current;
2145         else if(current < stable + 0.25) // when close enough, "snap"
2146                 return stable;
2147         else
2148                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2149 }
2150
2151 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2152 {
2153         if(current > rotstable)
2154         {
2155                 if(rotframetime > 0)
2156                 {
2157                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2158                         current = max(rotstable, current - rotlinear * rotframetime);
2159                 }
2160         }
2161         else if(current < regenstable)
2162         {
2163                 if(regenframetime > 0)
2164                 {
2165                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2166                         current = min(regenstable, current + regenlinear * regenframetime);
2167                 }
2168         }
2169
2170         if(current > limit)
2171                 current = limit;
2172
2173         return current;
2174 }
2175
2176 void player_regen (void)
2177 {
2178         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2179         maxh = autocvar_g_balance_health_rotstable;
2180         maxa = autocvar_g_balance_armor_rotstable;
2181         maxf = autocvar_g_balance_fuel_rotstable;
2182         minh = autocvar_g_balance_health_regenstable;
2183         mina = autocvar_g_balance_armor_regenstable;
2184         minf = autocvar_g_balance_fuel_regenstable;
2185         limith = autocvar_g_balance_health_limit;
2186         limita = autocvar_g_balance_armor_limit;
2187         limitf = autocvar_g_balance_fuel_limit;
2188
2189         max_mod = regen_mod = rot_mod = limit_mod = 1;
2190
2191         if (self.runes & RUNE_REGEN)
2192         {
2193                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2194                 {
2195                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2196                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2197                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2198                 }
2199                 else
2200                 {
2201                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2202                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2203                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2204                 }
2205         }
2206         else if (self.runes & CURSE_VENOM)
2207         {
2208                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2209                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2210                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2211                 else
2212                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2213                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2214                 //if (!self.runes & RUNE_REGEN)
2215                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2216         }
2217         maxh = maxh * max_mod;
2218         //maxa = maxa * max_mod;
2219         //maxf = maxf * max_mod;
2220         minh = minh * max_mod;
2221         //mina = mina * max_mod;
2222         //minf = minf * max_mod;
2223         limith = limith * limit_mod;
2224         limita = limita * limit_mod;
2225         //limitf = limitf * limit_mod;
2226
2227         if(g_lms && g_ca)
2228                 rot_mod = 0;
2229
2230         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2231         {
2232                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2233                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2234
2235                 // if player rotted to death...  die!
2236                 if(self.health < 1)
2237                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2238         }
2239
2240         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2241                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2242 }
2243
2244 float zoomstate_set;
2245 void SetZoomState(float z)
2246 {
2247         if(z != self.zoomstate)
2248         {
2249                 self.zoomstate = z;
2250                 ClientData_Touch(self);
2251         }
2252         zoomstate_set = 1;
2253 }
2254
2255 void GetPressedKeys(void) {
2256         MUTATOR_CALLHOOK(GetPressedKeys);
2257         if (self.movement_x > 0) // get if movement keys are pressed
2258         {       // forward key pressed
2259                 self.pressedkeys |= KEY_FORWARD;
2260                 self.pressedkeys &~= KEY_BACKWARD;
2261         }
2262         else if (self.movement_x < 0)
2263         {       // backward key pressed
2264                 self.pressedkeys |= KEY_BACKWARD;
2265                 self.pressedkeys &~= KEY_FORWARD;
2266         }
2267         else
2268         {       // no x input
2269                 self.pressedkeys &~= KEY_FORWARD;
2270                 self.pressedkeys &~= KEY_BACKWARD;
2271         }
2272
2273         if (self.movement_y > 0)
2274         {       // right key pressed
2275                 self.pressedkeys |= KEY_RIGHT;
2276                 self.pressedkeys &~= KEY_LEFT;
2277         }
2278         else if (self.movement_y < 0)
2279         {       // left key pressed
2280                 self.pressedkeys |= KEY_LEFT;
2281                 self.pressedkeys &~= KEY_RIGHT;
2282         }
2283         else
2284         {       // no y input
2285                 self.pressedkeys &~= KEY_RIGHT;
2286                 self.pressedkeys &~= KEY_LEFT;
2287         }
2288
2289         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2290                 self.pressedkeys |= KEY_JUMP;
2291         else
2292                 self.pressedkeys &~= KEY_JUMP;
2293         if (self.BUTTON_CROUCH)
2294                 self.pressedkeys |= KEY_CROUCH;
2295         else
2296                 self.pressedkeys &~= KEY_CROUCH;
2297 }
2298
2299 /*
2300 ======================
2301 spectate mode routines
2302 ======================
2303 */
2304
2305 void SpectateCopy(entity spectatee) {
2306         other = spectatee;
2307         MUTATOR_CALLHOOK(SpectateCopy);
2308         self.armortype = spectatee.armortype;
2309         self.armorvalue = spectatee.armorvalue;
2310         self.ammo_cells = spectatee.ammo_cells;
2311         self.ammo_shells = spectatee.ammo_shells;
2312         self.ammo_nails = spectatee.ammo_nails;
2313         self.ammo_rockets = spectatee.ammo_rockets;
2314         self.ammo_fuel = spectatee.ammo_fuel;
2315         self.clip_load = spectatee.clip_load;
2316         self.clip_size = spectatee.clip_size;
2317         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2318         self.health = spectatee.health;
2319         self.impulse = 0;
2320         self.items = spectatee.items;
2321         self.last_pickup = spectatee.last_pickup;
2322         self.hit_time = spectatee.hit_time;
2323         self.metertime = spectatee.metertime;
2324         self.strength_finished = spectatee.strength_finished;
2325         self.invincible_finished = spectatee.invincible_finished;
2326         self.pressedkeys = spectatee.pressedkeys;
2327         self.weapons = spectatee.weapons;
2328         self.switchweapon = spectatee.switchweapon;
2329         self.weapon = spectatee.weapon;
2330         self.nex_charge = spectatee.nex_charge;
2331         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2332         self.hagar_load = spectatee.hagar_load;
2333         self.minelayer_mines = spectatee.minelayer_mines;
2334         self.punchangle = spectatee.punchangle;
2335         self.view_ofs = spectatee.view_ofs;
2336         self.v_angle = spectatee.v_angle;
2337         self.velocity = spectatee.velocity;
2338         self.dmg_take = spectatee.dmg_take;
2339         self.dmg_save = spectatee.dmg_save;
2340         self.dmg_inflictor = spectatee.dmg_inflictor;
2341         self.angles = spectatee.v_angle;
2342         self.fixangle = TRUE;
2343         setorigin(self, spectatee.origin);
2344         setsize(self, spectatee.mins, spectatee.maxs);
2345         SetZoomState(spectatee.zoomstate);
2346
2347         anticheat_spectatecopy(spectatee);
2348
2349         //self.vehicle = spectatee.vehicle;
2350
2351         self.hud = spectatee.hud;
2352         if(spectatee.vehicle)
2353     {
2354         setorigin(self, spectatee.origin);
2355         self.velocity = spectatee.vehicle.velocity;
2356         self.v_angle += spectatee.vehicle.angles;
2357         //self.v_angle_x *= -1;
2358         self.vehicle_health = spectatee.vehicle_health;
2359         self.vehicle_shield = spectatee.vehicle_shield;
2360         self.vehicle_energy = spectatee.vehicle_energy;
2361         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2362         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2363         self.vehicle_reload1 = spectatee.vehicle_reload1;
2364         self.vehicle_reload2 = spectatee.vehicle_reload2;
2365
2366         msg_entity = self;
2367         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2368         WriteEntity(MSG_ONE, spectatee);
2369         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2370     }
2371 }
2372
2373 float SpectateUpdate() {
2374         if(!self.enemy)
2375             return 0;
2376
2377         if (self == self.enemy)
2378                 return 0;
2379
2380         if(self.enemy.classname != "player")
2381                 return 0;
2382
2383         SpectateCopy(self.enemy);
2384
2385         return 1;
2386 }
2387
2388 float SpectateNext() {
2389         other = find(self.enemy, classname, "player");
2390
2391         if (!other)
2392                 other = find(other, classname, "player");
2393
2394         if (other)
2395                 self.enemy = other;
2396
2397         if(self.enemy.classname == "player") {
2398             if(self.enemy.vehicle)
2399             {
2400             msg_entity = self;
2401             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2402             WriteEntity(MSG_ONE, self.enemy);
2403             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2404             self.movetype = MOVETYPE_NONE;
2405             accuracy_resend(self);
2406             }
2407             else
2408             {
2409             msg_entity = self;
2410             WriteByte(MSG_ONE, SVC_SETVIEW);
2411             WriteEntity(MSG_ONE, self.enemy);
2412             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2413             self.movetype = MOVETYPE_NONE;
2414             accuracy_resend(self);
2415
2416             if(!SpectateUpdate())
2417                 PutObserverInServer();
2418         }
2419         return 1;
2420         } else {
2421                 return 0;
2422         }
2423 }
2424
2425 /*
2426 =============
2427 ShowRespawnCountdown()
2428
2429 Update a respawn countdown display.
2430 =============
2431 */
2432 void ShowRespawnCountdown()
2433 {
2434         float number;
2435         if(self.deadflag == DEAD_NO) // just respawned?
2436                 return;
2437         else
2438         {
2439                 number = ceil(self.death_time - time);
2440                 if(number <= 0)
2441                         return;
2442                 if(number <= self.respawn_countdown)
2443                 {
2444                         self.respawn_countdown = number - 1;
2445                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2446                                 AnnounceTo(self, strcat(ftos(number), ""));
2447                 }
2448         }
2449 }
2450
2451 void LeaveSpectatorMode()
2452 {
2453         if(nJoinAllowed(1)) {
2454                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2455                         self.classname = "player";
2456
2457                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2458                                 JoinBestTeam(self, FALSE, TRUE);
2459
2460                         if(autocvar_g_campaign)
2461                                 campaign_bots_may_start = 1;
2462
2463                         PutClientInServer();
2464
2465                         if(self.classname == "player")
2466                                 bprint ("^4", self.netname, "^4 is playing now\n");
2467
2468                         if(!autocvar_g_campaign)
2469                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2470
2471                         return;
2472                 } else {
2473                         if (g_ca && self.caplayer) {
2474                         }       // do nothing
2475                         else
2476                                 stuffcmd(self,"menu_showteamselect\n");
2477                         return;
2478                 }
2479         }
2480         else {
2481                 //player may not join because of g_maxplayers is set
2482                 centerprint(self, PREVENT_JOIN_TEXT);
2483         }
2484 }
2485
2486 /**
2487  * Determines whether the player is allowed to join. This depends on cvar
2488  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2489  * it checks whether the number of currently playing players exceeds g_maxplayers.
2490  * @return int number of free slots for players, 0 if none
2491  */
2492 float nJoinAllowed(float includeMe) {
2493         if(self.team_forced < 0)
2494                 return FALSE; // forced spectators can never join
2495
2496         // TODO simplify this
2497         local entity e;
2498
2499         local float totalClients;
2500         FOR_EACH_CLIENT(e)
2501                 totalClients += 1;
2502
2503         if (!autocvar_g_maxplayers)
2504                 return maxclients - totalClients + includeMe;
2505
2506         local float currentlyPlaying;
2507         FOR_EACH_REALPLAYER(e)
2508                 currentlyPlaying += 1;
2509
2510         if(currentlyPlaying < autocvar_g_maxplayers)
2511                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2512
2513         return 0;
2514 }
2515
2516 /**
2517  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2518  * g_maxplayers_spectator_blocktime seconds
2519  */
2520 void checkSpectatorBlock() {
2521         if(self.classname == "spectator" || self.classname == "observer") {
2522                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2523                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2524                         dropclient(self);
2525                 }
2526         }
2527 }
2528
2529 void ObserverThink()
2530 {
2531         if (self.flags & FL_JUMPRELEASED) {
2532                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2533                         self.flags &~= FL_JUMPRELEASED;
2534                         self.flags |= FL_SPAWNING;
2535                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2536                         self.flags &~= FL_JUMPRELEASED;
2537                         if(SpectateNext() == 1) {
2538                                 self.classname = "spectator";
2539                         }
2540                 }
2541         } else {
2542                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2543                         self.flags |= FL_JUMPRELEASED;
2544                         if(self.flags & FL_SPAWNING)
2545                         {
2546                                 self.flags &~= FL_SPAWNING;
2547                                 LeaveSpectatorMode();
2548                                 return;
2549                         }
2550                 }
2551         }
2552 }
2553
2554 void SpectatorThink()
2555 {
2556         if (self.flags & FL_JUMPRELEASED) {
2557                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2558                         self.flags &~= FL_JUMPRELEASED;
2559                         self.flags |= FL_SPAWNING;
2560                 } else if(self.BUTTON_ATCK) {
2561                         self.flags &~= FL_JUMPRELEASED;
2562                         if(SpectateNext() == 1) {
2563                                 self.classname = "spectator";
2564                         } else {
2565                                 self.classname = "observer";
2566                                 PutClientInServer();
2567                         }
2568                 } else if (self.BUTTON_ATCK2) {
2569                         self.flags &~= FL_JUMPRELEASED;
2570                         self.classname = "observer";
2571                         PutClientInServer();
2572                 } else {
2573                         if(!SpectateUpdate())
2574                                 PutObserverInServer();
2575                 }
2576         } else {
2577                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2578                         self.flags |= FL_JUMPRELEASED;
2579                         if(self.flags & FL_SPAWNING)
2580                         {
2581                                 self.flags &~= FL_SPAWNING;
2582                                 LeaveSpectatorMode();
2583                                 return;
2584                         }
2585                 }
2586                 if(!SpectateUpdate())
2587                         PutObserverInServer();
2588         }
2589
2590         self.flags |= FL_CLIENT | FL_NOTARGET;
2591 }
2592
2593 float ctf_usekey();
2594 void PlayerUseKey()
2595 {
2596         if(self.classname != "player")
2597                 return;
2598
2599         if(self.vehicle)
2600         {
2601         vehicles_exit(VHEF_NORMAL);
2602         return;
2603         }
2604
2605         // a use key was pressed; call handlers
2606         if(ctf_usekey())
2607                 return;
2608
2609         MUTATOR_CALLHOOK(PlayerUseKey);
2610 }
2611
2612 .float touchexplode_time;
2613
2614 /*
2615 =============
2616 PlayerPreThink
2617
2618 Called every frame for each client before the physics are run
2619 =============
2620 */
2621 .float usekeypressed;
2622 void() ctf_setstatus;
2623 void() nexball_setstatus;
2624 .float items_added;
2625 .float motd_actived_time; // used for both motd and campaign_message
2626 void PlayerPreThink (void)
2627 {
2628         WarpZone_PlayerPhysics_FixVAngle();
2629
2630         self.stat_game_starttime = game_starttime;
2631         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2632         self.stat_leadlimit = autocvar_leadlimit;
2633
2634         if(frametime)
2635         {
2636                 // physics frames: update anticheat stuff
2637                 anticheat_prethink();
2638         }
2639
2640         if(blockSpectators && frametime)
2641                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2642                 checkSpectatorBlock();
2643
2644         zoomstate_set = 0;
2645
2646         if(self.netname_previous != self.netname)
2647         {
2648                 if(autocvar_sv_eventlog)
2649                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2650                 if(self.netname_previous)
2651                         strunzone(self.netname_previous);
2652                 self.netname_previous = strzone(self.netname);
2653         }
2654
2655         // version nagging
2656         if(self.version_nagtime)
2657                 if(self.cvar_g_xonoticversion)
2658                         if(time > self.version_nagtime)
2659                         {
2660                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2661                                 {
2662                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2663                                         {
2664                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2665                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2666                                         }
2667                                         else
2668                                         {
2669                                                 float r;
2670                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2671                                                 if(r < 0)
2672                                                 {
2673                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2674                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2675                                                 }
2676                                                 else if(r > 0)
2677                                                 {
2678                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2679                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2680                                                 }
2681                                         }
2682                                 }
2683                                 self.version_nagtime = 0;
2684                         }
2685
2686         // GOD MODE info
2687         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2688         {
2689                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2690                 self.max_armorvalue = 0;
2691         }
2692
2693 #ifdef TETRIS
2694         if (TetrisPreFrame())
2695                 return;
2696 #endif
2697
2698         MUTATOR_CALLHOOK(PlayerPreThink);
2699
2700         if(self.BUTTON_USE && !self.usekeypressed)
2701                 PlayerUseKey();
2702         self.usekeypressed = self.BUTTON_USE;
2703
2704         if (self.motd_actived_time == 0) {
2705                 if (autocvar_g_campaign) {
2706                         if (self.classname == "player" && self.BUTTON_INFO) {
2707                                 self.motd_actived_time = time;
2708                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2709                         }
2710                 } else {
2711                         if ((self.classname == "player" || time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2712                                 self.motd_actived_time = time;
2713                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2714                         }
2715                 }
2716         } else { // showing MOTD or campaign message
2717                 if (autocvar_g_campaign) {
2718                         if (self.classname == "player") {
2719                                 if (self.BUTTON_INFO)
2720                                         self.motd_actived_time = time;
2721                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2722                                         self.motd_actived_time = 0;
2723                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2724                                 }
2725                         }
2726                 } else {
2727                         if (self.classname == "player" || (time - self.jointime) > autocvar_welcome_message_time) {
2728                                 if (self.BUTTON_INFO)
2729                                         self.motd_actived_time = time;
2730                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2731                                         self.motd_actived_time = 0;
2732                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2733                                 }
2734                         }
2735                 }
2736         }
2737
2738         if(self.classname == "player") {
2739 //              if(self.netname == "Wazat")
2740 //                      bprint(self.classname, "\n");
2741
2742                 CheckRules_Player();
2743
2744                 if (intermission_running)
2745                 {
2746                         IntermissionThink ();   // otherwise a button could be missed between
2747                         return;                                 // the think tics
2748                 }
2749
2750                 //don't allow the player to turn around while game is paused!
2751                 if(timeoutStatus == 2) {
2752                         // FIXME turn this into CSQC stuff
2753                         self.v_angle = self.lastV_angle;
2754                         self.angles = self.lastV_angle;
2755                         self.fixangle = TRUE;
2756                 }
2757
2758                 if(frametime)
2759                 {
2760                         if(self.health <= 0 && autocvar_g_deathglow)
2761                         {
2762                                 if(self.glowmod_x > 0)
2763                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2764                                 else
2765                                         self.glowmod_x = -1;
2766                                 if(self.glowmod_y > 0)
2767                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2768                                 else
2769                                         self.glowmod_y = -1;
2770                                 if(self.glowmod_z > 0)
2771                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2772                                 else
2773                                         self.glowmod_z = -1;
2774                         }
2775                         else
2776                         {
2777                                 // set weapon and player glowmod
2778                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2779
2780                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2781                                 {
2782                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2783                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2784                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2785
2786                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2787                                         {
2788                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2789                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2790                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2791                                         }
2792                                 }
2793                                 else
2794                                         self.weaponentity_glowmod = self.glowmod;
2795                         }
2796                         player_powerups();
2797                 }
2798
2799                 if (g_minstagib)
2800                         minstagib_ammocheck();
2801
2802                 if (self.deadflag != DEAD_NO)
2803                 {
2804                         float button_pressed, force_respawn;
2805                         if(self.personal && g_race_qualifying)
2806                         {
2807                                 if(time > self.death_time)
2808                                 {
2809                                         self.death_time = time + 1; // only retry once a second
2810                                         respawn();
2811                                         self.impulse = 141;
2812                                 }
2813                         }
2814                         else
2815                         {
2816                                 if(frametime)
2817                                         player_anim();
2818                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2819                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2820                                 if (self.deadflag == DEAD_DYING)
2821                                 {
2822                                         if(force_respawn)
2823                                                 self.deadflag = DEAD_RESPAWNING;
2824                                         else if(!button_pressed)
2825                                                 self.deadflag = DEAD_DEAD;
2826                                 }
2827                                 else if (self.deadflag == DEAD_DEAD)
2828                                 {
2829                                         if(button_pressed)
2830                                                 self.deadflag = DEAD_RESPAWNABLE;
2831                                 }
2832                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2833                                 {
2834                                         if(!button_pressed)
2835                                                 self.deadflag = DEAD_RESPAWNING;
2836                                 }
2837                                 else if (self.deadflag == DEAD_RESPAWNING)
2838                                 {
2839                                         if(time > self.death_time)
2840                                         {
2841                                                 self.death_time = time + 1; // only retry once a second
2842                                                 respawn();
2843                                         }
2844                                 }
2845                                 ShowRespawnCountdown();
2846                         }
2847                         return;
2848                 }
2849                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2850                 // so (self.deadflag == DEAD_NO) is always true in the code below
2851
2852                 if(g_touchexplode)
2853                 if(time > self.touchexplode_time)
2854                 if(self.classname == "player")
2855                 if(self.deadflag == DEAD_NO)
2856                 if not(IS_INDEPENDENT_PLAYER(self))
2857                 FOR_EACH_PLAYER(other) if(self != other)
2858                 {
2859                         if(time > other.touchexplode_time)
2860                         if(other.deadflag == DEAD_NO)
2861                         if not(IS_INDEPENDENT_PLAYER(other))
2862                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2863                         {
2864                                 PlayerTouchExplode(self, other);
2865                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2866                         }
2867                 }
2868
2869                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2870                 {
2871                         vector dist;
2872
2873                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2874                         dist = self.prevorigin - self.origin;
2875                         dist_z = 0;
2876                         self.lms_traveled_distance += fabs(vlen(dist));
2877
2878                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2879                         {
2880                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2881                                 self.lms_traveled_distance = 0;
2882                         }
2883
2884                         if(time > self.lms_nextcheck)
2885                         {
2886                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2887                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2888                                 {
2889                                         centerprint(self, autocvar_g_lms_campcheck_message);
2890                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2891                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2892                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2893                                 }
2894                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2895                                 self.lms_traveled_distance = 0;
2896                         }
2897                 }
2898
2899                 self.prevorigin = self.origin;
2900
2901                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2902                 {
2903                         if (!self.crouch)
2904                         {
2905                                 self.crouch = TRUE;
2906                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2907                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2908                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2909                         }
2910                 }
2911                 else
2912                 {
2913                         if (self.crouch)
2914                         {
2915                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2916                                 if (!trace_startsolid)
2917                                 {
2918                                         self.crouch = FALSE;
2919                                         self.view_ofs = PL_VIEW_OFS;
2920                                         setsize (self, PL_MIN, PL_MAX);
2921                                 }
2922                         }
2923                 }
2924
2925                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2926                 {
2927                         if(self.bloodloss_timer < time)
2928                         {
2929                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2930                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2931                         }
2932                 }
2933
2934                 FixPlayermodel();
2935
2936                 GrapplingHookFrame();
2937
2938                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2939                 //if(frametime)
2940                 {
2941                         self.items &~= self.items_added;
2942
2943                         W_WeaponFrame();
2944
2945                         self.items_added = 0;
2946                         if(self.items & IT_JETPACK)
2947                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2948                                         self.items_added |= IT_FUEL;
2949
2950                         self.items |= self.items_added;
2951                 }
2952
2953                 player_regen();
2954
2955                 // rot nex charge to the charge limit
2956                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2957                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2958
2959                 if(frametime)
2960                         player_anim();
2961
2962                 if(g_ctf)
2963                         ctf_setstatus();
2964
2965                 if(g_nexball)
2966                         nexball_setstatus();
2967
2968                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2969
2970                 //self.angles_y=self.v_angle_y + 90;   // temp
2971         } else if(gameover) {
2972                 if (intermission_running)
2973                         IntermissionThink ();   // otherwise a button could be missed between
2974                 return;
2975         } else if(self.classname == "observer") {
2976                 ObserverThink();
2977         } else if(self.classname == "spectator") {
2978                 SpectatorThink();
2979         }
2980
2981         if(!zoomstate_set)
2982                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2983
2984         float oldspectatee_status;
2985         oldspectatee_status = self.spectatee_status;
2986         if(self.classname == "spectator")
2987                 self.spectatee_status = num_for_edict(self.enemy);
2988         else if(self.classname == "observer")
2989                 self.spectatee_status = num_for_edict(self);
2990         else
2991                 self.spectatee_status = 0;
2992         if(self.spectatee_status != oldspectatee_status)
2993         {
2994                 ClientData_Touch(self);
2995                 if(g_race || g_cts)
2996                         race_InitSpectator();
2997         }
2998
2999         if(self.teamkill_soundtime)
3000         if(time > self.teamkill_soundtime)
3001         {
3002                 self.teamkill_soundtime = 0;
3003
3004                 entity oldpusher, oldself;
3005
3006                 oldself = self; self = self.teamkill_soundsource;
3007                 oldpusher = self.pusher; self.pusher = oldself;
3008
3009                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3010
3011                 self.pusher = oldpusher;
3012                 self = oldself;
3013         }
3014
3015         if(self.taunt_soundtime)
3016         if(time > self.taunt_soundtime)
3017         {
3018                 self.taunt_soundtime = 0;
3019                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
3020         }
3021
3022         target_voicescript_next(self);
3023
3024         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3025         if(!self.weapon)
3026                 self.clip_load = self.clip_size = 0;
3027 }
3028
3029 float isInvisibleString(string s)
3030 {
3031         float i, n, c;
3032         s = strdecolorize(s);
3033         for((i = 0), (n = strlen(s)); i < n; ++i)
3034         {
3035                 c = str2chr(s, i);
3036                 switch(c)
3037                 {
3038                         case 0:
3039                         case 32: // space
3040                                 break;
3041                         case 192: // charmap space
3042                                 if (!autocvar_utf8_enable)
3043                                         break;
3044                                 return FALSE;
3045                         case 160: // space in unicode fonts
3046                         case 0xE000 + 192: // utf8 charmap space
3047                                 if (autocvar_utf8_enable)
3048                                         break;
3049                         default:
3050                                 return FALSE;
3051                 }
3052         }
3053         return TRUE;
3054 }
3055
3056 /*
3057 =============
3058 PlayerPostThink
3059
3060 Called every frame for each client after the physics are run
3061 =============
3062 */
3063 .float idlekick_lasttimeleft;
3064 .entity showheadshotbbox;
3065 void showheadshotbbox_think()
3066 {
3067         if(self.owner.showheadshotbbox != self)
3068         {
3069                 remove(self);
3070                 return;
3071         }
3072         self.nextthink = time;
3073         setorigin(self, self.owner.origin);
3074         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3075 }
3076 void PlayerPostThink (void)
3077 {
3078         // Savage: Check for nameless players
3079         if (isInvisibleString(self.netname)) {
3080                 self.netname = "Player";
3081                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3082         }
3083
3084         if(sv_maxidle && frametime)
3085         {
3086                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3087                 float timeleft;
3088                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
3089                 {
3090                         if(self.idlekick_lasttimeleft)
3091                         {
3092                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
3093                                 self.idlekick_lasttimeleft = 0;
3094                         }
3095                         return;
3096                 }
3097                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3098                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3099                 {
3100                         if(!self.idlekick_lasttimeleft)
3101                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3102                 }
3103                 if(timeleft <= 0)
3104                 {
3105                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3106                         AnnounceTo(self, "terminated");
3107                         dropclient(self);
3108                         return;
3109                 }
3110                 else if(timeleft <= 10)
3111                 {
3112                         if(timeleft != self.idlekick_lasttimeleft)
3113                                 AnnounceTo(self, ftos(timeleft));
3114                         self.idlekick_lasttimeleft = timeleft;
3115                 }
3116         }
3117
3118 #ifdef TETRIS
3119         if(self.impulse == 100)
3120                 ImpulseCommands();
3121         if (TetrisPostFrame())
3122                 return;
3123 #endif
3124
3125         CheatFrame();
3126
3127         if(self.classname == "player") {
3128                 CheckRules_Player();
3129                 UpdateChatBubble();
3130                 if (self.impulse)
3131                         ImpulseCommands();
3132                 if (intermission_running)
3133                         return;         // intermission or finale
3134                 GetPressedKeys();
3135         } else if (self.classname == "observer") {
3136                 //do nothing
3137         } else if (self.classname == "spectator") {
3138                 //do nothing
3139         }
3140
3141         /*
3142         float i;
3143         for(i = 0; i < 1000; ++i)
3144         {
3145                 vector end;
3146                 end = self.origin + '0 0 1024' + 512 * randomvec();
3147                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3148                 if(trace_fraction < 1)
3149                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3150                 {
3151                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3152                         break;
3153                 }
3154         }
3155         */
3156
3157         Arena_Warmup();
3158
3159         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3160
3161         if(self.waypointsprite_attachedforcarrier)
3162                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3163
3164         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3165         {
3166                 if(!self.showheadshotbbox)
3167                 {
3168                         self.showheadshotbbox = spawn();
3169                         self.showheadshotbbox.classname = "headshotbbox";
3170                         self.showheadshotbbox.owner = self;
3171                         self.showheadshotbbox.think = showheadshotbbox_think;
3172                         self.showheadshotbbox.nextthink = time;
3173                         self = self.showheadshotbbox;
3174                         self.think();
3175                         self = self.owner;
3176                 }
3177         }
3178         else
3179         {
3180                 if(self.showheadshotbbox)
3181                         remove(self.showheadshotbbox);
3182         }
3183
3184         playerdemo_write();
3185
3186         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3187         {
3188                 if(!self.stored_netname)
3189                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3190                 if(self.stored_netname != self.netname)
3191                 {
3192                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3193                         strunzone(self.stored_netname);
3194                         self.stored_netname = strzone(self.netname);
3195                 }
3196         }
3197
3198         /*
3199         if(g_race)
3200                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3201         */
3202 }