qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         if (g_minstagib)
 618                 minstagib_stop_countdown();
 619
 620         Portal_ClearAll(self);
 621
 622         if(self.alivetime)
 623         {
 624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                 self.alivetime = 0;
 626         }
 627
 628         if(self.flagcarried)
 629                 DropFlag(self.flagcarried, world, world);
 630
 631         if(self.ballcarried && g_nexball)
 632                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 633
 634         WaypointSprite_PlayerDead();
 635
 636         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 637                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 638
 639         if(self.killcount != -666) {
 640                 if(g_lms) {
 641                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 642                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 643                         else
 644                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 645                 } else
 646                         bprint ("^4", self.netname, "^4 is spectating now\n");
 647
 648                 if(self.just_joined == FALSE) {
 649                         LogTeamchange(self.playerid, -1, 4);
 650                 } else
 651                         self.just_joined = FALSE;
 652         }
 653
 654         PlayerScore_Clear(self); // clear scores when needed
 655
 656         accuracy_resend(self);
 657
 658         self.spectatortime = time;
 659
 660         self.classname = "observer";
 661         self.iscreature = FALSE;
 662         self.health = -666;
 663         self.takedamage = DAMAGE_NO;
 664         self.solid = SOLID_NOT;
 665         self.movetype = MOVETYPE_NOCLIP;
 666         self.flags = FL_CLIENT | FL_NOTARGET;
 667         self.armorvalue = 666;
 668         self.effects = 0;
 669         self.armorvalue = autocvar_g_balance_armor_start;
 670         self.pauserotarmor_finished = 0;
 671         self.pauserothealth_finished = 0;
 672         self.pauseregen_finished = 0;
 673         self.damageforcescale = 0;
 674         self.death_time = 0;
 675         self.dead_frame = 0;
 676         self.alpha = 0;
 677         self.scale = 0;
 678         self.fade_time = 0;
 679         self.pain_frame = 0;
 680         self.pain_finished = 0;
 681         self.strength_finished = 0;
 682         self.invincible_finished = 0;
 683         self.pushltime = 0;
 684         self.think = SUB_Null;
 685         self.nextthink = 0;
 686         self.hook_time = 0;
 687         self.runes = 0;
 688         self.deadflag = DEAD_NO;
 689         self.angles = spot.angles;
 690         self.angles_z = 0;
 691         self.fixangle = TRUE;
 692         self.crouch = FALSE;
 693
 694         self.view_ofs = PL_VIEW_OFS;
 695         setorigin (self, spot.origin);
 696         setsize (self, '0 0 0', '0 0 0');
 697         self.prevorigin = self.origin;
 698         self.items = 0;
 699         self.weapons = 0;
 700         self.model = "";
 701         FixPlayermodel();
 702         self.model = "";
 703         self.modelindex = 0;
 704         self.weapon = 0;
 705         self.weaponmodel = "";
 706         self.weaponentity = world;
 707         self.exteriorweaponentity = world;
 708         self.killcount = -666;
 709         self.velocity = '0 0 0';
 710         self.avelocity = '0 0 0';
 711         self.punchangle = '0 0 0';
 712         self.punchvector = '0 0 0';
 713         self.oldvelocity = self.velocity;
 714         self.fire_endtime = -1;
 715
 716         if(sv_loddistance1)
 717                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 718
 719         if(g_arena)
 720         {
 721                 if(self.version_mismatch)
 722                 {
 723                         Spawnqueue_Unmark(self);
 724                         Spawnqueue_Remove(self);
 725                 }
 726                 else
 727                 {
 728                         Spawnqueue_Insert(self);
 729                 }
 730         }
 731         else if(g_lms)
 732         {
 733                 // Only if the player cannot play at all
 734                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 735                         self.frags = FRAGS_SPECTATOR;
 736                 else
 737                         self.frags = FRAGS_LMS_LOSER;
 738         }
 739         else
 740                 self.frags = FRAGS_SPECTATOR;
 741 }
 742
 743 void FixPlayermodel()
 744 {
 745         local string defaultmodel;
 746         local float defaultskin, chmdl, oldskin;
 747         local vector m1, m2;
 748
 749         defaultmodel = "";
 750
 751         if(autocvar_sv_defaultcharacter == 1) {
 752                 defaultskin = 0;
 753
 754                 if(teams_matter)
 755                 {
 756                         string s;
 757                         s = Team_ColorNameLowerCase(self.team);
 758                         if(s != "neutral")
 759                         {
 760                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 761                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 762                         }
 763                 }
 764
 765                 if(defaultmodel == "")
 766                 {
 767                         defaultmodel = autocvar_sv_defaultplayermodel;
 768                         defaultskin = autocvar_sv_defaultplayerskin;
 769                 }
 770         }
 771
 772         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 773         {
 774                 if(self.model != "")
 775                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 776                 self.model = ""; // force the != checks to return true
 777         }
 778
 779         if(defaultmodel != "")
 780         {
 781                 if (defaultmodel != self.model)
 782                 {
 783                         m1 = self.mins;
 784                         m2 = self.maxs;
 785                         setmodel_lod (self, defaultmodel);
 786                         setsize (self, m1, m2);
 787                         chmdl = TRUE;
 788                 }
 789
 790                 oldskin = self.skinindex;
 791                 self.skinindex = defaultskin;
 792         } else {
 793                 if (self.playermodel != self.model || self.playermodel == "")
 794                 {
 795                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 796                         m1 = self.mins;
 797                         m2 = self.maxs;
 798                         setmodel_lod (self, self.playermodel);
 799                         setsize (self, m1, m2);
 800                         chmdl = TRUE;
 801                 }
 802
 803                 oldskin = self.skinindex;
 804                 self.skinindex = stof(self.playerskin);
 805         }
 806
 807         if(chmdl || oldskin != self.skinindex)
 808                 self.species = player_getspecies(); // model or skin has changed
 809
 810         if(!teams_matter)
 811                 if(strlen(autocvar_sv_defaultplayercolors))
 812                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 813                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 814 }
 815
 816 void PlayerTouchExplode(entity p1, entity p2)
 817 {
 818         vector org;
 819         org = (p1.origin + p2.origin) * 0.5;
 820         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 821
 822         te_explosion(org);
 823
 824         entity e;
 825         e = spawn();
 826         setorigin(e, org);
 827         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 828         remove(e);
 829 }
 830
 831 /*
 832 =============
 833 PutClientInServer
 834
 835 Called when a client spawns in the server
 836 =============
 837 */
 838 //void() ctf_playerchanged;
 839 void PutClientInServer (void)
 840 {
 841         if(clienttype(self) == CLIENTTYPE_BOT)
 842         {
 843                 self.classname = "player";
 844         }
 845         else if(clienttype(self) == CLIENTTYPE_REAL)
 846         {
 847                 msg_entity = self;
 848                 WriteByte(MSG_ONE, SVC_SETVIEW);
 849                 WriteEntity(MSG_ONE, self);
 850         }
 851
 852         // player is dead and becomes observer
 853         // FIXME fix LMS scoring for new system
 854         if(g_lms)
 855         {
 856                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 857                         self.classname = "observer";
 858         }
 859
 860         if(g_arena || (g_ca && !allowed_to_spawn))
 861         if(!self.spawned)
 862                 self.classname = "observer";
 863
 864         if(gameover)
 865                 self.classname = "observer";
 866
 867         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 868                 entity spot, oldself;
 869                 float j;
 870
 871                 accuracy_resend(self);
 872
 873                 if(self.team < 0)
 874                         JoinBestTeam(self, FALSE, TRUE);
 875
 876                 race_PreSpawn();
 877
 878                 spot = SelectSpawnPoint (FALSE);
 879                 if(!spot)
 880                 {
 881                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 882                         return; // spawn failed
 883                 }
 884
 885                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 886
 887                 self.classname = "player";
 888                 self.wasplayer = TRUE;
 889                 self.iscreature = TRUE;
 890                 self.movetype = MOVETYPE_WALK;
 891                 self.solid = SOLID_SLIDEBOX;
 892                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 893                 if(autocvar_g_playerclip_collisions)
 894                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 895                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 896                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 897                 self.frags = FRAGS_PLAYER;
 898                 if(independent_players)
 899                         MAKE_INDEPENDENT_PLAYER(self);
 900                 self.flags = FL_CLIENT;
 901                 self.takedamage = DAMAGE_AIM;
 902                 if(g_minstagib)
 903                         self.effects = EF_FULLBRIGHT;
 904                 else
 905                         self.effects = 0;
 906                 self.air_finished = time + 12;
 907                 self.dmg = 2;
 908                 if(autocvar_g_balance_nex_charge)
 909                 {
 910                         if(autocvar_g_balance_nex_secondary_chargepool)
 911                                 self.nex_chargepool_ammo = 1;
 912                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 913                 }
 914
 915                 if(inWarmupStage)
 916                 {
 917                         self.ammo_shells = warmup_start_ammo_shells;
 918                         self.ammo_nails = warmup_start_ammo_nails;
 919                         self.ammo_rockets = warmup_start_ammo_rockets;
 920                         self.ammo_cells = warmup_start_ammo_cells;
 921                         self.ammo_fuel = warmup_start_ammo_fuel;
 922                         self.health = warmup_start_health;
 923                         self.armorvalue = warmup_start_armorvalue;
 924                         self.weapons = warmup_start_weapons;
 925                 }
 926                 else
 927                 {
 928                         self.ammo_shells = start_ammo_shells;
 929                         self.ammo_nails = start_ammo_nails;
 930                         self.ammo_rockets = start_ammo_rockets;
 931                         self.ammo_cells = start_ammo_cells;
 932                         self.ammo_fuel = start_ammo_fuel;
 933                         self.health = start_health;
 934                         self.armorvalue = start_armorvalue;
 935                         self.weapons = start_weapons;
 936                 }
 937
 938                 if(g_weaponarena_random)
 939                 {
 940                         if(g_weaponarena_random_with_laser)
 941                                 self.weapons &~= WEPBIT_LASER;
 942                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 943                         if(g_weaponarena_random_with_laser)
 944                                 self.weapons |= WEPBIT_LASER;
 945                 }
 946
 947                 self.items = start_items;
 948                 self.jump_interval = time;
 949
 950                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 951                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 952                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 953                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 954                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 955                 //extend the pause of rotting if client was reset at the beginning of the countdown
 956                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 957                         self.spawnshieldtime += game_starttime - time;
 958                         self.pauserotarmor_finished += game_starttime - time;
 959                         self.pauserothealth_finished += game_starttime - time;
 960                         self.pauseregen_finished += game_starttime - time;
 961                 }
 962                 self.damageforcescale = 2;
 963                 self.death_time = 0;
 964                 self.dead_frame = 0;
 965                 self.alpha = 0;
 966                 self.scale = 0;
 967                 self.fade_time = 0;
 968                 self.pain_frame = 0;
 969                 self.pain_finished = 0;
 970                 self.strength_finished = 0;
 971                 self.invincible_finished = 0;
 972                 self.pushltime = 0;
 973                 // players have no think function
 974                 self.think = SUB_Null;
 975                 self.nextthink = 0;
 976                 self.hook_time = 0;
 977                 self.dmg_team = 0;
 978                 self.ballistics_density = autocvar_g_ballistics_density_player;
 979
 980                 self.metertime = 0;
 981
 982                 self.runes = 0;
 983
 984                 self.deadflag = DEAD_NO;
 985
 986                 self.angles = spot.angles;
 987
 988                 self.angles_z = 0; // never spawn tilted even if the spot says to
 989                 self.fixangle = TRUE; // turn this way immediately
 990                 self.velocity = '0 0 0';
 991                 self.avelocity = '0 0 0';
 992                 self.punchangle = '0 0 0';
 993                 self.punchvector = '0 0 0';
 994                 self.oldvelocity = self.velocity;
 995                 self.fire_endtime = -1;
 996
 997                 msg_entity = self;
 998                 WRITESPECTATABLE_MSG_ONE({
 999                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1000                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1001                 });
1002
1003                 if(sv_loddistance1)
1004                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1005
1006                 self.model = "";
1007                 FixPlayermodel();
1008
1009                 self.crouch = FALSE;
1010                 self.view_ofs = PL_VIEW_OFS;
1011                 setsize (self, PL_MIN, PL_MAX);
1012                 self.spawnorigin = spot.origin;
1013                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1014                 // don't reset back to last position, even if new position is stuck in solid
1015                 self.oldorigin = self.origin;
1016                 self.prevorigin = self.origin;
1017                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1018
1019                 if(g_arena)
1020                 {
1021                         Spawnqueue_Remove(self);
1022                         Spawnqueue_Mark(self);
1023                 }
1024
1025                 else if(g_ca)
1026                         self.caplayer = 1;
1027
1028                 self.event_damage = PlayerDamage;
1029
1030                 self.bot_attack = TRUE;
1031
1032                 self.statdraintime = time + 5;
1033                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1034
1035                 if(self.killcount == -666) {
1036                         PlayerScore_Clear(self);
1037                         self.killcount = 0;
1038                 }
1039
1040                 self.cnt = WEP_LASER;
1041
1042                 CL_SpawnWeaponentity();
1043                 self.alpha = default_player_alpha;
1044                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1045                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1046
1047                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1048                 self.lms_traveled_distance = 0;
1049                 self.speedrunning = FALSE;
1050
1051                 race_PostSpawn(spot);
1052
1053                 if(autocvar_spawn_debug)
1054                 {
1055                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1056                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1057                 }
1058
1059                 //stuffcmd(self, "chase_active 0");
1060                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1061
1062                 if (autocvar_g_spawnsound)
1063                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1064
1065                 if(g_assault) {
1066                         if(self.team == assault_attacker_team)
1067                                 centerprint(self, "You are attacking!");
1068                         else
1069                                 centerprint(self, "You are defending!");
1070                 }
1071
1072                 target_voicescript_clear(self);
1073
1074                 // reset fields the weapons may use
1075                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1076                 {
1077                         weapon_action(j, WR_RESETPLAYER);
1078
1079                         // all weapons must be fully loaded when we spawn
1080                         entity e;
1081                         e = get_weaponinfo(j);
1082                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1083                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1084                 }
1085                 self.weapon_forbidchange = FALSE;
1086
1087                 oldself = self;
1088                 self = spot;
1089                         activator = oldself;
1090                                 SUB_UseTargets();
1091                         activator = world;
1092                 self = oldself;
1093
1094                 MUTATOR_CALLHOOK(PlayerSpawn);
1095
1096                 self.switchweapon = w_getbestweapon(self);
1097                 self.cnt = self.switchweapon;
1098                 self.weapon = 0;
1099
1100                 if(!self.alivetime)
1101                         self.alivetime = time;
1102         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1103                 PutObserverInServer ();
1104         }
1105
1106         //if(g_ctf)
1107         //      ctf_playerchanged();
1108 }
1109
1110 .float ebouncefactor, ebouncestop; // electro's values
1111 // TODO do we need all these fields, or should we stop autodetecting runtime
1112 // changes and just have a console command to update this?
1113 float ClientInit_SendEntity(entity to, float sf)
1114 {
1115         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1116         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1117         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1118         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1119         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1120         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1121         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1122         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1123         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1124         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1125         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1126         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1127         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1128         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1129         if(sv_foginterval && world.fog != "")
1130                 WriteString(MSG_ENTITY, world.fog);
1131         else
1132                 WriteString(MSG_ENTITY, "");
1133         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1134         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1135         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1136         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1137         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1138         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1139         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1140         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1141         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1142         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1143         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1144         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1145         return TRUE;
1146 }
1147
1148 void ClientInit_CheckUpdate()
1149 {
1150         self.nextthink = time;
1151         if(self.count != autocvar_g_balance_armor_blockpercent)
1152         {
1153                 self.count = autocvar_g_balance_armor_blockpercent;
1154                 self.SendFlags |= 1;
1155         }
1156         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1157         {
1158                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1159                 self.SendFlags |= 1;
1160         }
1161         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1162         {
1163                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1164                 self.SendFlags |= 1;
1165         }
1166         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1167         {
1168                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1169                 self.SendFlags |= 1;
1170         }
1171         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1172         {
1173                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1174                 self.SendFlags |= 1;
1175         }
1176         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1177         {
1178                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1179                 self.SendFlags |= 1;
1180         }
1181 }
1182
1183 void ClientInit_Spawn()
1184 {
1185         entity o;
1186         entity e;
1187         e = spawn();
1188         e.classname = "clientinit";
1189         e.think = ClientInit_CheckUpdate;
1190         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1191
1192         o = self;
1193         self = e;
1194         ClientInit_CheckUpdate();
1195         self = o;
1196 }
1197
1198 /*
1199 =============
1200 SetNewParms
1201 =============
1202 */
1203 void SetNewParms (void)
1204 {
1205         // initialize parms for a new player
1206         parm1 = -(86400 * 366);
1207 }
1208
1209 /*
1210 =============
1211 SetChangeParms
1212 =============
1213 */
1214 void SetChangeParms (void)
1215 {
1216         // save parms for level change
1217         parm1 = self.parm_idlesince - time;
1218 }
1219
1220 /*
1221 =============
1222 DecodeLevelParms
1223 =============
1224 */
1225 void DecodeLevelParms (void)
1226 {
1227         // load parms
1228         self.parm_idlesince = parm1;
1229         if(self.parm_idlesince == -(86400 * 366))
1230                 self.parm_idlesince = time;
1231
1232         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1233         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1234 }
1235
1236 /*
1237 =============
1238 ClientKill
1239
1240 Called when a client types 'kill' in the console
1241 =============
1242 */
1243
1244 .float clientkill_nexttime;
1245 void ClientKill_Now_TeamChange()
1246 {
1247         if(self.killindicator_teamchange == -1)
1248         {
1249                 self.team = -1;
1250                 JoinBestTeam( self, FALSE, FALSE );
1251         }
1252         else if(self.killindicator_teamchange == -2)
1253         {
1254                 if(g_ca)
1255                         self.caplayer = 0;
1256                 if(blockSpectators)
1257                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1258                 PutObserverInServer();
1259         }
1260         else
1261                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1262 }
1263
1264 void ClientKill_Now()
1265 {
1266         remove(self.killindicator);
1267         self.killindicator = world;
1268
1269         if(self.killindicator_teamchange)
1270                 ClientKill_Now_TeamChange();
1271
1272         // in any case:
1273         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1274
1275         // now I am sure the player IS dead
1276 }
1277 void KillIndicator_Think()
1278 {
1279         if (!self.owner.modelindex)
1280         {
1281                 self.owner.killindicator = world;
1282                 remove(self);
1283                 return;
1284         }
1285
1286         if(self.cnt <= 0)
1287         {
1288                 self = self.owner;
1289                 ClientKill_Now(); // no oldself needed
1290                 return;
1291         }
1292     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1293     {
1294         self.nextthink = time + 1;
1295         self.cnt -= 1;
1296     }
1297         else
1298         {
1299                 if(self.cnt <= 10)
1300                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1301                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1302                 {
1303                         if(self.cnt <= 10)
1304                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1305                         // TODO: Send_CSQC_Centerprint_Generic only once
1306                         if(self.owner.killindicator_teamchange)
1307                         {
1308                                 if(self.owner.killindicator_teamchange == -1)
1309                                         Send_CSQC_Centerprint_Generic(self.owner, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.cnt);
1310                                 else if(self.owner.killindicator_teamchange == -2)
1311                                         Send_CSQC_Centerprint_Generic(self.owner, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.cnt);
1312                                 else
1313                                         Send_CSQC_Centerprint_Generic(self.owner, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in %d seconds"), 1, self.cnt);
1314                         }
1315                         else
1316                                 Send_CSQC_Centerprint_Generic(self.owner, CPID_KILL, "^1Suicide in %d seconds", 1, self.cnt);
1317                 }
1318                 self.nextthink = time + 1;
1319                 self.cnt -= 1;
1320         }
1321 }
1322
1323 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1324 {
1325         float killtime;
1326         entity e;
1327         killtime = autocvar_g_balance_kill_delay;
1328
1329         if(g_race_qualifying || g_cts)
1330                 killtime = 0;
1331
1332     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1333     {
1334                 remove(self.killindicator);
1335                 self.killindicator = world;
1336
1337         ClientKill_Now(); // allow instant kill in this case
1338         return;
1339     }
1340
1341         self.killindicator_teamchange = targetteam;
1342
1343     if(!self.killindicator)
1344         {
1345                 if(self.modelindex && self.deadflag == DEAD_NO)
1346                 {
1347                         killtime = max(killtime, self.clientkill_nexttime - time);
1348                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1349                 }
1350
1351                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1352                 {
1353                         ClientKill_Now();
1354                 }
1355                 else
1356                 {
1357                         self.killindicator = spawn();
1358                         self.killindicator.owner = self;
1359                         self.killindicator.scale = 0.5;
1360                         setattachment(self.killindicator, self, "");
1361                         setorigin(self.killindicator, '0 0 52');
1362                         self.killindicator.think = KillIndicator_Think;
1363                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1364                         self.killindicator.cnt = ceil(killtime);
1365                         self.killindicator.count = bound(0, ceil(killtime), 10);
1366                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1367
1368                         for(e = world; (e = find(e, classname, "body")) != world; )
1369                         {
1370                                 if(e.enemy != self)
1371                                         continue;
1372                                 e.killindicator = spawn();
1373                                 e.killindicator.owner = e;
1374                                 e.killindicator.scale = 0.5;
1375                                 setattachment(e.killindicator, e, "");
1376                                 setorigin(e.killindicator, '0 0 52');
1377                                 e.killindicator.think = KillIndicator_Think;
1378                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1379                                 e.killindicator.cnt = ceil(killtime);
1380                         }
1381                         self.lip = 0;
1382                 }
1383         }
1384         if(self.killindicator)
1385         {
1386                 if(targetteam == 0) // just die
1387                         self.killindicator.colormod = '0 0 0';
1388                 else if(targetteam == -1) // auto
1389                         self.killindicator.colormod = '0 1 0';
1390                 else if(targetteam == -2) // spectate
1391                         self.killindicator.colormod = '0.5 0.5 0.5';
1392                 else
1393                         self.killindicator.colormod = TeamColor(targetteam);
1394         }
1395 }
1396
1397 void ClientKill (void)
1398 {
1399         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1400         {
1401                 // do nothing
1402         }
1403     else if(self.freezetag_frozen)
1404     {
1405         // do nothing
1406     }
1407         else
1408                 ClientKill_TeamChange(0);
1409 }
1410
1411 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1412 {
1413     e.killindicator = spawn();
1414     e.killindicator.owner = e;
1415     e.killindicator.think = KillIndicator_Think;
1416     e.killindicator.nextthink = time + (e.lip) * 0.05;
1417     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1418     e.killindicator.health = 1; // this is used to indicate that it should be silent
1419     e.lip = 0;
1420 }
1421
1422 void DoTeamChange(float destteam)
1423 {
1424         float t, c0;
1425         if(!teams_matter)
1426         {
1427                 if(destteam >= 0)
1428                         SetPlayerColors(self, destteam);
1429                 return;
1430         }
1431         if(self.classname == "player")
1432         if(destteam == -1)
1433         {
1434                 CheckAllowedTeams(self);
1435                 t = FindSmallestTeam(self, TRUE);
1436                 switch(self.team)
1437                 {
1438                         case COLOR_TEAM1: c0 = c1; break;
1439                         case COLOR_TEAM2: c0 = c2; break;
1440                         case COLOR_TEAM3: c0 = c3; break;
1441                         case COLOR_TEAM4: c0 = c4; break;
1442                         default:          c0 = 999;
1443                 }
1444                 switch(t)
1445                 {
1446                         case 1:
1447                                 if(c0 > c1)
1448                                         destteam = COLOR_TEAM1;
1449                                 break;
1450                         case 2:
1451                                 if(c0 > c2)
1452                                         destteam = COLOR_TEAM2;
1453                                 break;
1454                         case 3:
1455                                 if(c0 > c3)
1456                                         destteam = COLOR_TEAM3;
1457                                 break;
1458                         case 4:
1459                                 if(c0 > c4)
1460                                         destteam = COLOR_TEAM4;
1461                                 break;
1462                 }
1463                 if(destteam == -1)
1464                         return;
1465         }
1466         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1467                 return;
1468         ClientKill_TeamChange(destteam);
1469 }
1470
1471 void FixClientCvars(entity e)
1472 {
1473         // send prediction settings to the client
1474         stuffcmd(e, "\nin_bindmap 0 0\n");
1475         if(g_race || g_cts)
1476                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1477         if(autocvar_g_antilag == 3) // client side hitscan
1478                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1479         if(sv_gentle)
1480                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1481         /*
1482          * we no longer need to stuff this. Remove this comment block if you feel
1483          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1484         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1485         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1486         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1487         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1488         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1489         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1490         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1491         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1492         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1493         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1494         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1495         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1496         stuffcmd(e, "cl_movement_edgefriction 1\n");
1497          */
1498 }
1499
1500 float PlayerInIDList(entity p, string idlist)
1501 {
1502         float n, i;
1503         string s;
1504
1505         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1506         if not(p.crypto_idfp)
1507                 return 0;
1508
1509         // this function allows abbreviated player IDs too!
1510         n = tokenize_console(idlist);
1511         for(i = 0; i < n; ++i)
1512         {
1513                 s = argv(i);
1514                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1515                         return 1;
1516         }
1517
1518         return 0;
1519 }
1520
1521 /*
1522 =============
1523 ClientConnect
1524
1525 Called when a client connects to the server
1526 =============
1527 */
1528 //void ctf_clientconnect();
1529 string ColoredTeamName(float t);
1530 void DecodeLevelParms (void);
1531 //void dom_player_join_team(entity pl);
1532 void set_dom_state(entity e);
1533 void ClientConnect (void)
1534 {
1535         float t;
1536
1537         if(self.flags & FL_CLIENT)
1538         {
1539                 print("Warning: ClientConnect, but already connected!\n");
1540                 return;
1541         }
1542
1543         if(Ban_MaybeEnforceBan(self))
1544                 return;
1545
1546         DecodeLevelParms();
1547
1548 #ifdef WATERMARK
1549         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1550 #endif
1551
1552         self.classname = "player_joining";
1553
1554         self.flags = FL_CLIENT;
1555         self.version_nagtime = time + 10 + random() * 10;
1556
1557         if(player_count<0)
1558         {
1559                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1560                 player_count = 0;
1561         }
1562
1563         PlayerScore_Attach(self);
1564         ClientData_Attach();
1565         accuracy_init(self);
1566
1567         bot_clientconnect();
1568
1569         playerdemo_init();
1570
1571         anticheat_init();
1572
1573         race_PreSpawnObserver();
1574
1575         //if(g_domination)
1576         //      dom_player_join_team(self);
1577
1578         // identify the right forced team
1579         if(autocvar_g_campaign)
1580         {
1581                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1582                 {
1583                         switch(autocvar_g_campaign_forceteam)
1584                         {
1585                                 case 1: self.team_forced = COLOR_TEAM1; break;
1586                                 case 2: self.team_forced = COLOR_TEAM2; break;
1587                                 case 3: self.team_forced = COLOR_TEAM3; break;
1588                                 case 4: self.team_forced = COLOR_TEAM4; break;
1589                                 default: self.team_forced = 0;
1590                         }
1591                 }
1592         }
1593         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1594                 self.team_forced = COLOR_TEAM1;
1595         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1596                 self.team_forced = COLOR_TEAM2;
1597         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1598                 self.team_forced = COLOR_TEAM3;
1599         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1600                 self.team_forced = COLOR_TEAM4;
1601         else if(autocvar_g_forced_team_otherwise == "red")
1602                 self.team_forced = COLOR_TEAM1;
1603         else if(autocvar_g_forced_team_otherwise == "blue")
1604                 self.team_forced = COLOR_TEAM2;
1605         else if(autocvar_g_forced_team_otherwise == "yellow")
1606                 self.team_forced = COLOR_TEAM3;
1607         else if(autocvar_g_forced_team_otherwise == "pink")
1608                 self.team_forced = COLOR_TEAM4;
1609         else if(autocvar_g_forced_team_otherwise == "spectate")
1610                 self.team_forced = -1;
1611         else if(autocvar_g_forced_team_otherwise == "spectator")
1612                 self.team_forced = -1;
1613         else
1614                 self.team_forced = 0;
1615
1616         if(!teams_matter)
1617                 if(self.team_forced > 0)
1618                         self.team_forced = 0;
1619
1620         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1621
1622         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1623                 self.classname = "observer";
1624         } else {
1625                 if(teams_matter)
1626                 {
1627                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1628                         {
1629                                 self.classname = "player";
1630                                 campaign_bots_may_start = 1;
1631                         }
1632                         else
1633                         {
1634                                 self.classname = "observer"; // do it anyway
1635                         }
1636                 }
1637                 else
1638                 {
1639                         self.classname = "player";
1640                         campaign_bots_may_start = 1;
1641                 }
1642         }
1643
1644         self.playerid = (playerid_last = playerid_last + 1);
1645
1646     if(clienttype(self) == CLIENTTYPE_BOT)
1647         PlayerStats_AddPlayer(self);
1648
1649         if(autocvar_sv_eventlog)
1650                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1651
1652         LogTeamchange(self.playerid, self.team, 1);
1653
1654         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1655
1656         self.netname_previous = strzone(self.netname);
1657
1658         bprint("^4", self.netname, "^4 connected");
1659
1660         if(self.classname != "observer" && (g_domination || g_ctf))
1661                 bprint(" and joined the ", ColoredTeamName(self.team));
1662
1663         bprint("\n");
1664
1665         stuffcmd(self, strcat(clientstuff, "\n"));
1666         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1667         stuffcmd(self, "cl_particles_reloadeffects\n");
1668
1669         FixClientCvars(self);
1670
1671         // spawnfunc_waypoint sprites
1672         WaypointSprite_InitClient(self);
1673
1674         // Wazat's grappling hook
1675         SetGrappleHookBindings();
1676
1677         // get autoswitch state from player when he toggles it
1678         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1679
1680         // get version info from player
1681         stuffcmd(self, "cmd clientversion $gameversion\n");
1682
1683         // get other cvars from player
1684         GetCvars(0);
1685
1686         // notify about available teams
1687         if(teams_matter)
1688         {
1689                 CheckAllowedTeams(self);
1690                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1691                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1692         }
1693         else
1694                 stuffcmd(self, "set _teams_available 0\n");
1695
1696         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1697
1698         if(g_arena || g_ca)
1699         {
1700                 self.classname = "observer";
1701                 if(g_arena)
1702                         Spawnqueue_Insert(self);
1703         }
1704         /*else if(g_ctf)
1705         {
1706                 ctf_clientconnect();
1707         }*/
1708
1709         attach_entcs();
1710
1711         bot_relinkplayerlist();
1712
1713         self.spectatortime = time;
1714         if(blockSpectators)
1715         {
1716                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1717         }
1718
1719         self.jointime = time;
1720         self.allowedTimeouts = autocvar_sv_timeout_number;
1721
1722         if(clienttype(self) == CLIENTTYPE_REAL)
1723         {
1724                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1725                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1726         }
1727
1728         if(g_lms)
1729         {
1730                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1731                 {
1732                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1733                         self.frags = FRAGS_SPECTATOR;
1734                 }
1735         }
1736
1737         if(!sv_foginterval && world.fog != "")
1738                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1739
1740         SoundEntity_Attach(self);
1741
1742         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1743         {
1744                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1745                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1746         }
1747         else
1748                 self.hitplotfh = -1;
1749
1750         if(g_race || g_cts) {
1751                 string rr;
1752                 if(g_cts)
1753                         rr = CTS_RECORD;
1754                 else
1755                         rr = RACE_RECORD;
1756                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1757
1758                 msg_entity = self;
1759                 race_send_recordtime(MSG_ONE);
1760                 race_send_speedaward(MSG_ONE);
1761
1762                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1763                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1764                 race_send_speedaward_alltimebest(MSG_ONE);
1765
1766                 float i;
1767                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1768                         race_SendRankings(i, 0, 0, MSG_ONE);
1769                 }
1770         }
1771         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1772                 send_CSQC_teamnagger();
1773
1774         if (g_domination)
1775                 set_dom_state(self);
1776
1777         CheatInitClient();
1778
1779         // FIXME: .BUTTON_INFO in PrintWelcomeMessage must be checked at every frame, not just here
1780         PrintWelcomeMessage(self);
1781 }
1782
1783 /*
1784 =============
1785 ClientDisconnect
1786
1787 Called when a client disconnects from the server
1788 =============
1789 */
1790 .entity chatbubbleentity;
1791 void ReadyCount();
1792 void ClientDisconnect (void)
1793 {
1794         if not(self.flags & FL_CLIENT)
1795         {
1796                 print("Warning: ClientDisconnect without ClientConnect\n");
1797                 return;
1798         }
1799
1800         PlayerStats_AddGlobalInfo(self);
1801
1802         CheatShutdownClient();
1803
1804         if(self.hitplotfh >= 0)
1805         {
1806                 fclose(self.hitplotfh);
1807                 self.hitplotfh = -1;
1808         }
1809
1810         anticheat_report();
1811         anticheat_shutdown();
1812
1813         playerdemo_shutdown();
1814
1815         bot_clientdisconnect();
1816
1817         if(self.entcs)
1818                 detach_entcs();
1819
1820         if(autocvar_sv_eventlog)
1821                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1822         bprint ("^4",self.netname);
1823         bprint ("^4 disconnected\n");
1824
1825         SoundEntity_Detach(self);
1826
1827         DropAllRunes(self);
1828         MUTATOR_CALLHOOK(ClientDisconnect);
1829
1830         Portal_ClearAll(self);
1831
1832         if(self.flagcarried)
1833                 DropFlag(self.flagcarried, world, world);
1834         if(self.ballcarried && g_nexball)
1835                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1836
1837         // Here, everything has been done that requires this player to be a client.
1838
1839         self.flags &~= FL_CLIENT;
1840
1841         if (self.chatbubbleentity)
1842                 remove (self.chatbubbleentity);
1843
1844         if (self.killindicator)
1845                 remove (self.killindicator);
1846
1847         WaypointSprite_PlayerGone();
1848
1849         bot_relinkplayerlist();
1850
1851         if(g_arena)
1852         {
1853                 Spawnqueue_Unmark(self);
1854                 Spawnqueue_Remove(self);
1855         }
1856
1857         accuracy_free(self);
1858         ClientData_Detach();
1859         PlayerScore_Detach(self);
1860
1861         if(self.netname_previous)
1862                 strunzone(self.netname_previous);
1863         if(self.clientstatus)
1864                 strunzone(self.clientstatus);
1865         if(self.weaponorder_byimpulse)
1866                 strunzone(self.weaponorder_byimpulse);
1867
1868         ClearPlayerSounds();
1869
1870         if(self.personal)
1871                 remove(self.personal);
1872
1873         self.playerid = 0;
1874         ReadyCount();
1875
1876         // free cvars
1877         GetCvars(-1);
1878 }
1879
1880 .float BUTTON_CHAT;
1881 void ChatBubbleThink()
1882 {
1883         self.nextthink = time;
1884         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1885         {
1886                 if(self.owner) // but why can that ever be world?
1887                         self.owner.chatbubbleentity = world;
1888                 remove(self);
1889                 return;
1890         }
1891         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1892 #ifdef TETRIS
1893                 || self.owner.tetris_on
1894 #endif
1895         )
1896                 self.model = self.mdl;
1897         else
1898                 self.model = "";
1899 };
1900
1901 void UpdateChatBubble()
1902 {
1903         if (!self.modelindex)
1904                 return;
1905         // spawn a chatbubble entity if needed
1906         if (!self.chatbubbleentity)
1907         {
1908                 self.chatbubbleentity = spawn();
1909                 self.chatbubbleentity.owner = self;
1910                 self.chatbubbleentity.exteriormodeltoclient = self;
1911                 self.chatbubbleentity.think = ChatBubbleThink;
1912                 self.chatbubbleentity.nextthink = time;
1913                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1914                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1915                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1916                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1917                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1918                 self.chatbubbleentity.model = "";
1919                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1920         }
1921 }
1922
1923
1924 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1925 // added to the model skins
1926 /*void UpdateColorModHack()
1927 {
1928         local float c;
1929         c = self.clientcolors & 15;
1930         // LordHavoc: only bothering to support white, green, red, yellow, blue
1931              if (!teams_matter) self.colormod = '0 0 0';
1932         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1933         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1934         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1935         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1936         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1937         else self.colormod = '1 1 1';
1938 };*/
1939
1940 .float oldcolormap;
1941 void respawn(void)
1942 {
1943         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1944         {
1945                 self.solid = SOLID_NOT;
1946                 self.takedamage = DAMAGE_NO;
1947                 self.movetype = MOVETYPE_FLY;
1948                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1949                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1950                 self.effects |= EF_ADDITIVE;
1951                 self.oldcolormap = self.colormap;
1952                 self.colormap = 512;
1953                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1954                 if(autocvar_g_respawn_ghosts_maxtime)
1955                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1956         }
1957
1958         CopyBody(1);
1959         self.effects |= EF_NODRAW; // prevent another CopyBody
1960         if(self.oldcolormap)
1961         {
1962                 self.colormap = self.oldcolormap;
1963                 self.oldcolormap = 0;
1964         }
1965         PutClientInServer();
1966 }
1967
1968 void play_countdown(float finished, string samp)
1969 {
1970         if(clienttype(self) == CLIENTTYPE_REAL)
1971                 if(floor(finished - time - frametime) != floor(finished - time))
1972                         if(finished - time < 6)
1973                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1974 }
1975
1976 /**
1977  * When sv_timeout is used this function returs strings like
1978  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1979  * Called by centerprint functions
1980  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1981  */
1982 string getTimeoutText(float addOneSecond) {
1983         if (!autocvar_sv_timeout || !timeoutStatus)
1984                 return "";
1985
1986         local string retStr;
1987         if (timeoutStatus == 1) {
1988                 if (addOneSecond == 1) {
1989                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1990                 }
1991                 else {
1992                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1993                 }
1994                 return retStr;
1995         }
1996         else if (timeoutStatus == 2) {
1997                 if (addOneSecond) {
1998                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1999                         //don't show messages like "Timeout ends in 0 seconds"...
2000                         if ((remainingTimeoutTime + 1) > 0)
2001                                 return retStr;
2002                         else
2003                                 return "";
2004                 }
2005                 else {
2006                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2007                         //don't show messages like "Timeout ends in 0 seconds"...
2008                         if ((remainingTimeoutTime) > 0)
2009                                 return retStr;
2010                         else
2011                                 return "";
2012                 }
2013         }
2014         else return "";
2015 }
2016
2017 void player_powerups (void)
2018 {
2019         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2020         olditems = self.items;
2021
2022         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2023         {
2024                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2025                 self.modelflags |= MF_ROCKET;
2026         }
2027         else
2028         {
2029                 SoundEntity_StopSound(self, CHAN_PLAYER);
2030                 self.modelflags &~= MF_ROCKET;
2031         }
2032
2033         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2034
2035         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2036                 return;
2037
2038         Fire_ApplyDamage(self);
2039         Fire_ApplyEffect(self);
2040
2041         if (g_minstagib)
2042         {
2043                 self.effects |= EF_FULLBRIGHT;
2044
2045                 if (self.items & IT_STRENGTH)
2046                 {
2047                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2048                         if (time > self.strength_finished)
2049                         {
2050                                 self.alpha = default_player_alpha;
2051                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2052                                 self.items &~= IT_STRENGTH;
2053                                 sprint(self, "^3Invisibility has worn off\n");
2054                         }
2055                 }
2056                 else
2057                 {
2058                         if (time < self.strength_finished)
2059                         {
2060                                 self.alpha = g_minstagib_invis_alpha;
2061                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2062                                 self.items |= IT_STRENGTH;
2063                                 sprint(self, "^3You are invisible\n");
2064                         }
2065                 }
2066
2067                 if (self.items & IT_INVINCIBLE)
2068                 {
2069                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2070                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2071                         {
2072                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2073                                 sprint(self, "^3Speed has worn off\n");
2074                         }
2075                 }
2076                 else
2077                 {
2078                         if (time < self.invincible_finished)
2079                         {
2080                                 self.items = self.items | IT_INVINCIBLE;
2081                                 sprint(self, "^3You are on speed\n");
2082                         }
2083                 }
2084         }
2085         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2086         {
2087                 if (self.items & IT_STRENGTH)
2088                 {
2089                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2090                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2091                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2092                         {
2093                                 self.items = self.items - (self.items & IT_STRENGTH);
2094                                 sprint(self, "^3Strength has worn off\n");
2095                         }
2096                 }
2097                 else
2098                 {
2099                         if (time < self.strength_finished)
2100                         {
2101                                 self.items = self.items | IT_STRENGTH;
2102                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2103                         }
2104                 }
2105                 if (self.items & IT_INVINCIBLE)
2106                 {
2107                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2108                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2109                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2110                         {
2111                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2112                                 sprint(self, "^3Shield has worn off\n");
2113                         }
2114                 }
2115                 else
2116                 {
2117                         if (time < self.invincible_finished)
2118                         {
2119                                 self.items = self.items | IT_INVINCIBLE;
2120                                 sprint(self, "^3Shield surrounds you\n");
2121                         }
2122                 }
2123
2124                 if(autocvar_g_nodepthtestplayers)
2125                         self.effects = self.effects | EF_NODEPTHTEST;
2126
2127                 if(autocvar_g_fullbrightplayers)
2128                         self.effects = self.effects | EF_FULLBRIGHT;
2129
2130                 // midair gamemode: damage only while in the air
2131                 // if in midair mode, being on ground grants temporary invulnerability
2132                 // (this is so that multishot weapon don't clear the ground flag on the
2133                 // first damage in the frame, leaving the player vulnerable to the
2134                 // remaining hits in the same frame)
2135                 if (self.flags & FL_ONGROUND)
2136                 if (g_midair)
2137                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2138
2139                 if (time >= game_starttime)
2140                 if (time < self.spawnshieldtime)
2141                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2142         }
2143
2144         MUTATOR_CALLHOOK(PlayerPowerups);
2145 }
2146
2147 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2148 {
2149         if(current > stable)
2150                 return current;
2151         else if(current > stable - 0.25) // when close enough, "snap"
2152                 return stable;
2153         else
2154                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2155 }
2156
2157 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2158 {
2159         if(current < stable)
2160                 return current;
2161         else if(current < stable + 0.25) // when close enough, "snap"
2162                 return stable;
2163         else
2164                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2165 }
2166
2167 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2168 {
2169         if(current > rotstable)
2170         {
2171                 if(rotframetime > 0)
2172                 {
2173                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2174                         current = max(rotstable, current - rotlinear * rotframetime);
2175                 }
2176         }
2177         else if(current < regenstable)
2178         {
2179                 if(regenframetime > 0)
2180                 {
2181                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2182                         current = min(regenstable, current + regenlinear * regenframetime);
2183                 }
2184         }
2185
2186         if(current > limit)
2187                 current = limit;
2188
2189         return current;
2190 }
2191
2192 void player_regen (void)
2193 {
2194         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2195         maxh = autocvar_g_balance_health_rotstable;
2196         maxa = autocvar_g_balance_armor_rotstable;
2197         maxf = autocvar_g_balance_fuel_rotstable;
2198         minh = autocvar_g_balance_health_regenstable;
2199         mina = autocvar_g_balance_armor_regenstable;
2200         minf = autocvar_g_balance_fuel_regenstable;
2201         limith = autocvar_g_balance_health_limit;
2202         limita = autocvar_g_balance_armor_limit;
2203         limitf = autocvar_g_balance_fuel_limit;
2204
2205         max_mod = regen_mod = rot_mod = limit_mod = 1;
2206
2207         if (self.runes & RUNE_REGEN)
2208         {
2209                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2210                 {
2211                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2212                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2213                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2214                 }
2215                 else
2216                 {
2217                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2218                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2219                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2220                 }
2221         }
2222         else if (self.runes & CURSE_VENOM)
2223         {
2224                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2225                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2226                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2227                 else
2228                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2229                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2230                 //if (!self.runes & RUNE_REGEN)
2231                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2232         }
2233         maxh = maxh * max_mod;
2234         //maxa = maxa * max_mod;
2235         //maxf = maxf * max_mod;
2236         minh = minh * max_mod;
2237         //mina = mina * max_mod;
2238         //minf = minf * max_mod;
2239         limith = limith * limit_mod;
2240         limita = limita * limit_mod;
2241         //limitf = limitf * limit_mod;
2242
2243         if(g_lms && g_ca)
2244                 rot_mod = 0;
2245
2246         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2247         {
2248                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2249                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2250
2251                 // if player rotted to death...  die!
2252                 if(self.health < 1)
2253                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2254         }
2255
2256         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2257                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2258 }
2259
2260 float zoomstate_set;
2261 void SetZoomState(float z)
2262 {
2263         if(z != self.zoomstate)
2264         {
2265                 self.zoomstate = z;
2266                 ClientData_Touch(self);
2267         }
2268         zoomstate_set = 1;
2269 }
2270
2271 void GetPressedKeys(void) {
2272         MUTATOR_CALLHOOK(GetPressedKeys);
2273         if (self.movement_x > 0) // get if movement keys are pressed
2274         {       // forward key pressed
2275                 self.pressedkeys |= KEY_FORWARD;
2276                 self.pressedkeys &~= KEY_BACKWARD;
2277         }
2278         else if (self.movement_x < 0)
2279         {       // backward key pressed
2280                 self.pressedkeys |= KEY_BACKWARD;
2281                 self.pressedkeys &~= KEY_FORWARD;
2282         }
2283         else
2284         {       // no x input
2285                 self.pressedkeys &~= KEY_FORWARD;
2286                 self.pressedkeys &~= KEY_BACKWARD;
2287         }
2288
2289         if (self.movement_y > 0)
2290         {       // right key pressed
2291                 self.pressedkeys |= KEY_RIGHT;
2292                 self.pressedkeys &~= KEY_LEFT;
2293         }
2294         else if (self.movement_y < 0)
2295         {       // left key pressed
2296                 self.pressedkeys |= KEY_LEFT;
2297                 self.pressedkeys &~= KEY_RIGHT;
2298         }
2299         else
2300         {       // no y input
2301                 self.pressedkeys &~= KEY_RIGHT;
2302                 self.pressedkeys &~= KEY_LEFT;
2303         }
2304
2305         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2306                 self.pressedkeys |= KEY_JUMP;
2307         else
2308                 self.pressedkeys &~= KEY_JUMP;
2309         if (self.BUTTON_CROUCH)
2310                 self.pressedkeys |= KEY_CROUCH;
2311         else
2312                 self.pressedkeys &~= KEY_CROUCH;
2313 }
2314
2315 /*
2316 ======================
2317 spectate mode routines
2318 ======================
2319 */
2320
2321 void SpectateCopy(entity spectatee) {
2322         other = spectatee;
2323         MUTATOR_CALLHOOK(SpectateCopy);
2324         self.armortype = spectatee.armortype;
2325         self.armorvalue = spectatee.armorvalue;
2326         self.ammo_cells = spectatee.ammo_cells;
2327         self.ammo_shells = spectatee.ammo_shells;
2328         self.ammo_nails = spectatee.ammo_nails;
2329         self.ammo_rockets = spectatee.ammo_rockets;
2330         self.ammo_fuel = spectatee.ammo_fuel;
2331         self.clip_load = spectatee.clip_load;
2332         self.clip_size = spectatee.clip_size;
2333         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2334         self.health = spectatee.health;
2335         self.impulse = 0;
2336         self.items = spectatee.items;
2337         self.last_pickup = spectatee.last_pickup;
2338         self.hit_time = spectatee.hit_time;
2339         self.metertime = spectatee.metertime;
2340         self.strength_finished = spectatee.strength_finished;
2341         self.invincible_finished = spectatee.invincible_finished;
2342         self.pressedkeys = spectatee.pressedkeys;
2343         self.weapons = spectatee.weapons;
2344         self.switchweapon = spectatee.switchweapon;
2345         self.weapon = spectatee.weapon;
2346         self.nex_charge = spectatee.nex_charge;
2347         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2348         self.hagar_load = spectatee.hagar_load;
2349         self.minelayer_mines = spectatee.minelayer_mines;
2350         self.punchangle = spectatee.punchangle;
2351         self.view_ofs = spectatee.view_ofs;
2352         self.v_angle = spectatee.v_angle;
2353         self.velocity = spectatee.velocity;
2354         self.dmg_take = spectatee.dmg_take;
2355         self.dmg_save = spectatee.dmg_save;
2356         self.dmg_inflictor = spectatee.dmg_inflictor;
2357         self.angles = spectatee.v_angle;
2358         self.fixangle = TRUE;
2359         setorigin(self, spectatee.origin);
2360         setsize(self, spectatee.mins, spectatee.maxs);
2361         SetZoomState(spectatee.zoomstate);
2362
2363         anticheat_spectatecopy(spectatee);
2364 }
2365
2366 float SpectateUpdate() {
2367         if(!self.enemy)
2368                 return 0;
2369
2370         if (self == self.enemy)
2371                 return 0;
2372
2373         if(self.enemy.classname != "player")
2374                 return 0;
2375
2376         SpectateCopy(self.enemy);
2377
2378         return 1;
2379 }
2380
2381 float SpectateNext() {
2382         other = find(self.enemy, classname, "player");
2383
2384         if (!other)
2385                 other = find(other, classname, "player");
2386
2387         if (other)
2388                 self.enemy = other;
2389
2390         if(self.enemy.classname == "player") {
2391                 msg_entity = self;
2392                 WriteByte(MSG_ONE, SVC_SETVIEW);
2393                 WriteEntity(MSG_ONE, self.enemy);
2394                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2395                 self.movetype = MOVETYPE_NONE;
2396                 accuracy_resend(self);
2397
2398                 if(!SpectateUpdate())
2399                         PutObserverInServer();
2400
2401                 return 1;
2402         } else {
2403                 return 0;
2404         }
2405 }
2406
2407 /*
2408 =============
2409 ShowRespawnCountdown()
2410
2411 Update a respawn countdown display.
2412 =============
2413 */
2414 void ShowRespawnCountdown()
2415 {
2416         float number;
2417         if(self.deadflag == DEAD_NO) // just respawned?
2418                 return;
2419         else
2420         {
2421                 number = ceil(self.death_time - time);
2422                 if(number <= 0)
2423                         return;
2424                 if(number <= self.respawn_countdown)
2425                 {
2426                         self.respawn_countdown = number - 1;
2427                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2428                                 AnnounceTo(self, strcat(ftos(number), ""));
2429                 }
2430         }
2431 }
2432
2433 void LeaveSpectatorMode()
2434 {
2435         if(nJoinAllowed(1)) {
2436                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2437                         self.classname = "player";
2438
2439                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2440                                 JoinBestTeam(self, FALSE, TRUE);
2441
2442                         if(autocvar_g_campaign)
2443                                 campaign_bots_may_start = 1;
2444
2445                         PutClientInServer();
2446
2447                         if(self.classname == "player")
2448                                 bprint ("^4", self.netname, "^4 is playing now\n");
2449
2450                         if(!autocvar_g_campaign)
2451                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, "", 1, 0); // clear MOTD
2452
2453                         return;
2454                 } else {
2455                         if (g_ca && self.caplayer) {
2456                         }       // do nothing
2457                         else
2458                                 stuffcmd(self,"menu_showteamselect\n");
2459                         return;
2460                 }
2461         }
2462         else {
2463                 //player may not join because of g_maxplayers is set
2464                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2465         }
2466 }
2467
2468 /**
2469  * Determines whether the player is allowed to join. This depends on cvar
2470  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2471  * it checks whether the number of currently playing players exceeds g_maxplayers.
2472  * @return int number of free slots for players, 0 if none
2473  */
2474 float nJoinAllowed(float includeMe) {
2475         if(self.team_forced < 0)
2476                 return FALSE; // forced spectators can never join
2477
2478         // TODO simplify this
2479         local entity e;
2480
2481         local float totalClients;
2482         FOR_EACH_CLIENT(e)
2483                 totalClients += 1;
2484
2485         if (!autocvar_g_maxplayers)
2486                 return maxclients - totalClients + includeMe;
2487
2488         local float currentlyPlaying;
2489         FOR_EACH_REALPLAYER(e)
2490                 currentlyPlaying += 1;
2491
2492         if(currentlyPlaying < autocvar_g_maxplayers)
2493                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2494
2495         return 0;
2496 }
2497
2498 /**
2499  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2500  * g_maxplayers_spectator_blocktime seconds
2501  */
2502 void checkSpectatorBlock() {
2503         if(self.classname == "spectator" || self.classname == "observer") {
2504                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2505                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2506                         dropclient(self);
2507                 }
2508         }
2509 }
2510
2511 void ObserverThink()
2512 {
2513         if (self.flags & FL_JUMPRELEASED) {
2514                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2515                         self.welcomemessage_time = 0;
2516                         self.flags &~= FL_JUMPRELEASED;
2517                         self.flags |= FL_SPAWNING;
2518                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2519                         self.welcomemessage_time = 0;
2520                         self.flags &~= FL_JUMPRELEASED;
2521                         if(SpectateNext() == 1) {
2522                                 self.classname = "spectator";
2523                         }
2524                 }
2525         } else {
2526                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2527                         self.flags |= FL_JUMPRELEASED;
2528                         if(self.flags & FL_SPAWNING)
2529                         {
2530                                 self.flags &~= FL_SPAWNING;
2531                                 LeaveSpectatorMode();
2532                                 return;
2533                         }
2534                 }
2535         }
2536 }
2537
2538 void SpectatorThink()
2539 {
2540         if (self.flags & FL_JUMPRELEASED) {
2541                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2542                         self.welcomemessage_time = 0;
2543                         self.flags &~= FL_JUMPRELEASED;
2544                         self.flags |= FL_SPAWNING;
2545                 } else if(self.BUTTON_ATCK) {
2546                         self.welcomemessage_time = 0;
2547                         self.flags &~= FL_JUMPRELEASED;
2548                         if(SpectateNext() == 1) {
2549                                 self.classname = "spectator";
2550                         } else {
2551                                 self.classname = "observer";
2552                                 PutClientInServer();
2553                         }
2554                 } else if (self.BUTTON_ATCK2) {
2555                         self.welcomemessage_time = 0;
2556                         self.flags &~= FL_JUMPRELEASED;
2557                         self.classname = "observer";
2558                         PutClientInServer();
2559                 } else {
2560                         if(!SpectateUpdate())
2561                                 PutObserverInServer();
2562                 }
2563         } else {
2564                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2565                         self.flags |= FL_JUMPRELEASED;
2566                         if(self.flags & FL_SPAWNING)
2567                         {
2568                                 self.flags &~= FL_SPAWNING;
2569                                 LeaveSpectatorMode();
2570                                 return;
2571                         }
2572                 }
2573         }
2574
2575         self.flags |= FL_CLIENT | FL_NOTARGET;
2576 }
2577
2578 .float touchexplode_time;
2579
2580 /*
2581 =============
2582 PlayerPreThink
2583
2584 Called every frame for each client before the physics are run
2585 =============
2586 */
2587 void() ctf_setstatus;
2588 void() nexball_setstatus;
2589 .float items_added;
2590 void PlayerPreThink (void)
2591 {
2592         WarpZone_PlayerPhysics_FixVAngle();
2593
2594         self.stat_game_starttime = game_starttime;
2595         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2596         self.stat_leadlimit = autocvar_leadlimit;
2597
2598         if(frametime)
2599         {
2600                 // physics frames: update anticheat stuff
2601                 anticheat_prethink();
2602         }
2603
2604         if(blockSpectators && frametime)
2605                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2606                 checkSpectatorBlock();
2607
2608         zoomstate_set = 0;
2609
2610         if(self.netname_previous != self.netname)
2611         {
2612                 if(autocvar_sv_eventlog)
2613                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2614                 if(self.netname_previous)
2615                         strunzone(self.netname_previous);
2616                 self.netname_previous = strzone(self.netname);
2617         }
2618
2619         // version nagging
2620         if(self.version_nagtime)
2621                 if(self.cvar_g_xonoticversion)
2622                         if(time > self.version_nagtime)
2623                         {
2624                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2625                                 {
2626                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2627                                         {
2628                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2629                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2630                                         }
2631                                         else
2632                                         {
2633                                                 float r;
2634                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2635                                                 if(r < 0)
2636                                                 {
2637                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2638                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2639                                                 }
2640                                                 else if(r > 0)
2641                                                 {
2642                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2643                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2644                                                 }
2645                                         }
2646                                 }
2647                                 self.version_nagtime = 0;
2648                         }
2649
2650         // GOD MODE info
2651         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2652         {
2653                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2654                 self.max_armorvalue = 0;
2655         }
2656
2657 #ifdef TETRIS
2658         if (TetrisPreFrame())
2659                 return;
2660 #endif
2661
2662         MUTATOR_CALLHOOK(PlayerPreThink);
2663
2664         if(self.classname == "player") {
2665 //              if(self.netname == "Wazat")
2666 //                      bprint(self.classname, "\n");
2667
2668                 CheckRules_Player();
2669
2670                 if (intermission_running)
2671                 {
2672                         IntermissionThink ();   // otherwise a button could be missed between
2673                         return;                                 // the think tics
2674                 }
2675
2676                 //don't allow the player to turn around while game is paused!
2677                 if(timeoutStatus == 2) {
2678                         // FIXME turn this into CSQC stuff
2679                         self.v_angle = self.lastV_angle;
2680                         self.angles = self.lastV_angle;
2681                         self.fixangle = TRUE;
2682                 }
2683
2684                 if(frametime)
2685                 {
2686                         if(self.health <= 0 && autocvar_g_deathglow)
2687                         {
2688                                 if(self.glowmod_x > 0)
2689                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2690                                 else
2691                                         self.glowmod_x = -1;
2692                                 if(self.glowmod_y > 0)
2693                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2694                                 else
2695                                         self.glowmod_y = -1;
2696                                 if(self.glowmod_z > 0)
2697                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2698                                 else
2699                                         self.glowmod_z = -1;
2700                         }
2701                         else
2702                         {
2703                                 // set weapon and player glowmod
2704                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2705
2706                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2707                                 {
2708                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2709                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2710                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2711
2712                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2713                                         {
2714                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2715                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2716                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2717                                         }
2718                                 }
2719                                 else
2720                                         self.weaponentity_glowmod = self.glowmod;
2721                         }
2722                         player_powerups();
2723                 }
2724
2725                 if (g_minstagib)
2726                         minstagib_ammocheck();
2727
2728                 if (self.deadflag != DEAD_NO)
2729                 {
2730                         float button_pressed, force_respawn;
2731                         if(self.personal && g_race_qualifying)
2732                         {
2733                                 if(time > self.death_time)
2734                                 {
2735                                         self.death_time = time + 1; // only retry once a second
2736                                         respawn();
2737                                         self.impulse = 141;
2738                                 }
2739                         }
2740                         else
2741                         {
2742                                 if(frametime)
2743                                         player_anim();
2744                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2745                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2746                                 if (self.deadflag == DEAD_DYING)
2747                                 {
2748                                         if(force_respawn)
2749                                                 self.deadflag = DEAD_RESPAWNING;
2750                                         else if(!button_pressed)
2751                                                 self.deadflag = DEAD_DEAD;
2752                                 }
2753                                 else if (self.deadflag == DEAD_DEAD)
2754                                 {
2755                                         if(button_pressed)
2756                                                 self.deadflag = DEAD_RESPAWNABLE;
2757                                 }
2758                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2759                                 {
2760                                         if(!button_pressed)
2761                                                 self.deadflag = DEAD_RESPAWNING;
2762                                 }
2763                                 else if (self.deadflag == DEAD_RESPAWNING)
2764                                 {
2765                                         if(time > self.death_time)
2766                                         {
2767                                                 self.death_time = time + 1; // only retry once a second
2768                                                 respawn();
2769                                         }
2770                                 }
2771                                 ShowRespawnCountdown();
2772                         }
2773                         return;
2774                 }
2775                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2776                 // so (self.deadflag == DEAD_NO) is always true in the code below
2777
2778                 if(g_touchexplode)
2779                 if(time > self.touchexplode_time)
2780                 if(self.classname == "player")
2781                 if(self.deadflag == DEAD_NO)
2782                 if not(IS_INDEPENDENT_PLAYER(self))
2783                 FOR_EACH_PLAYER(other) if(self != other)
2784                 {
2785                         if(time > other.touchexplode_time)
2786                         if(other.deadflag == DEAD_NO)
2787                         if not(IS_INDEPENDENT_PLAYER(other))
2788                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2789                         {
2790                                 PlayerTouchExplode(self, other);
2791                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2792                         }
2793                 }
2794
2795                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2796                 {
2797                         vector dist;
2798
2799                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2800                         dist = self.prevorigin - self.origin;
2801                         dist_z = 0;
2802                         self.lms_traveled_distance += fabs(vlen(dist));
2803
2804                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2805                         {
2806                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2807                                 self.lms_traveled_distance = 0;
2808                         }
2809
2810                         if(time > self.lms_nextcheck)
2811                         {
2812                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2813                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2814                                 {
2815                                         centerprint(self, autocvar_g_lms_campcheck_message);
2816                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2817                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2818                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2819                                 }
2820                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2821                                 self.lms_traveled_distance = 0;
2822                         }
2823                 }
2824
2825                 self.prevorigin = self.origin;
2826
2827                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2828                 {
2829                         if (!self.crouch)
2830                         {
2831                                 self.crouch = TRUE;
2832                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2833                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2834                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2835                         }
2836                 }
2837                 else
2838                 {
2839                         if (self.crouch)
2840                         {
2841                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2842                                 if (!trace_startsolid)
2843                                 {
2844                                         self.crouch = FALSE;
2845                                         self.view_ofs = PL_VIEW_OFS;
2846                                         setsize (self, PL_MIN, PL_MAX);
2847                                 }
2848                         }
2849                 }
2850
2851                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2852                 {
2853                         if(self.bloodloss_timer < time)
2854                         {
2855                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2856                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2857                         }
2858                 }
2859
2860                 FixPlayermodel();
2861
2862                 GrapplingHookFrame();
2863
2864                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2865                 //if(frametime)
2866                 {
2867                         self.items &~= self.items_added;
2868
2869                         W_WeaponFrame();
2870
2871                         self.items_added = 0;
2872                         if(self.items & IT_JETPACK)
2873                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2874                                         self.items_added |= IT_FUEL;
2875
2876                         self.items |= self.items_added;
2877                 }
2878
2879                 player_regen();
2880
2881                 // rot nex charge to the charge limit
2882                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2883                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2884
2885                 if(frametime)
2886                         player_anim();
2887
2888                 if(g_ctf)
2889                         ctf_setstatus();
2890
2891                 if(g_nexball)
2892                         nexball_setstatus();
2893
2894                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2895
2896                 //self.angles_y=self.v_angle_y + 90;   // temp
2897         } else if(gameover) {
2898                 if (intermission_running)
2899                         IntermissionThink ();   // otherwise a button could be missed between
2900                 return;
2901         } else if(self.classname == "observer") {
2902                 ObserverThink();
2903         } else if(self.classname == "spectator") {
2904                 SpectatorThink();
2905         }
2906
2907         if(!zoomstate_set)
2908                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2909
2910         float oldspectatee_status;
2911         oldspectatee_status = self.spectatee_status;
2912         if(self.classname == "spectator")
2913                 self.spectatee_status = num_for_edict(self.enemy);
2914         else if(self.classname == "observer")
2915                 self.spectatee_status = num_for_edict(self);
2916         else
2917                 self.spectatee_status = 0;
2918         if(self.spectatee_status != oldspectatee_status)
2919         {
2920                 ClientData_Touch(self);
2921                 if(g_race || g_cts)
2922                         race_InitSpectator();
2923         }
2924
2925         if(self.teamkill_soundtime)
2926         if(time > self.teamkill_soundtime)
2927         {
2928                 self.teamkill_soundtime = 0;
2929
2930                 entity oldpusher, oldself;
2931
2932                 oldself = self; self = self.teamkill_soundsource;
2933                 oldpusher = self.pusher; self.pusher = oldself;
2934
2935                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2936
2937                 self.pusher = oldpusher;
2938                 self = oldself;
2939         }
2940
2941         if(self.taunt_soundtime)
2942         if(time > self.taunt_soundtime)
2943         {
2944                 self.taunt_soundtime = 0;
2945                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2946         }
2947
2948         target_voicescript_next(self);
2949
2950         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2951         if(!self.weapon)
2952                 self.clip_load = self.clip_size = 0;
2953 }
2954
2955 float isInvisibleString(string s)
2956 {
2957         float i, n, c;
2958         s = strdecolorize(s);
2959         for((i = 0), (n = strlen(s)); i < n; ++i)
2960         {
2961                 c = str2chr(s, i);
2962                 switch(c)
2963                 {
2964                         case 0:
2965                         case 32: // space
2966                                 break;
2967                         case 192: // charmap space
2968                                 if (!autocvar_utf8_enable)
2969                                         break;
2970                                 return FALSE;
2971                         case 160: // space in unicode fonts
2972                         case 0xE000 + 192: // utf8 charmap space
2973                                 if (autocvar_utf8_enable)
2974                                         break;
2975                         default:
2976                                 return FALSE;
2977                 }
2978         }
2979         return TRUE;
2980 }
2981
2982 /*
2983 =============
2984 PlayerPostThink
2985
2986 Called every frame for each client after the physics are run
2987 =============
2988 */
2989 .float idlekick_lasttimeleft;
2990 .entity showheadshotbbox;
2991 void showheadshotbbox_think()
2992 {
2993         if(self.owner.showheadshotbbox != self)
2994         {
2995                 remove(self);
2996                 return;
2997         }
2998         self.nextthink = time;
2999         setorigin(self, self.owner.origin);
3000         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3001 }
3002 void PlayerPostThink (void)
3003 {
3004         // Savage: Check for nameless players
3005         if (isInvisibleString(self.netname)) {
3006                 self.netname = "Player";
3007                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3008         }
3009
3010         if(sv_maxidle && frametime)
3011         {
3012                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3013                 float timeleft;
3014                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3015                 if(timeleft <= 0)
3016                 {
3017                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3018                         AnnounceTo(self, "terminated");
3019                         dropclient(self);
3020                         return;
3021                 }
3022                 else if(timeleft <= 10)
3023                 {
3024                         if(timeleft != self.idlekick_lasttimeleft)
3025                         {
3026                                 // TODO: send this msg only once
3027                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3028                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3029                         }
3030                 }
3031                 else
3032                 {
3033                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "", 1, timeleft);
3034                 }
3035                 self.idlekick_lasttimeleft = timeleft;
3036         }
3037
3038 #ifdef TETRIS
3039         if(self.impulse == 100)
3040                 ImpulseCommands();
3041         if (TetrisPostFrame())
3042                 return;
3043 #endif
3044
3045         CheatFrame();
3046
3047         if(self.classname == "player") {
3048                 CheckRules_Player();
3049                 UpdateChatBubble();
3050                 if (self.impulse)
3051                         ImpulseCommands();
3052                 if (intermission_running)
3053                         return;         // intermission or finale
3054                 GetPressedKeys();
3055         } else if (self.classname == "observer") {
3056                 //do nothing
3057         } else if (self.classname == "spectator") {
3058                 //do nothing
3059         }
3060
3061         /*
3062         float i;
3063         for(i = 0; i < 1000; ++i)
3064         {
3065                 vector end;
3066                 end = self.origin + '0 0 1024' + 512 * randomvec();
3067                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3068                 if(trace_fraction < 1)
3069                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3070                 {
3071                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3072                         break;
3073                 }
3074         }
3075         */
3076
3077         Arena_Warmup();
3078
3079         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3080
3081         if(self.waypointsprite_attachedforcarrier)
3082                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3083
3084         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3085         {
3086                 if(!self.showheadshotbbox)
3087                 {
3088                         self.showheadshotbbox = spawn();
3089                         self.showheadshotbbox.classname = "headshotbbox";
3090                         self.showheadshotbbox.owner = self;
3091                         self.showheadshotbbox.think = showheadshotbbox_think;
3092                         self.showheadshotbbox.nextthink = time;
3093                         self = self.showheadshotbbox;
3094                         self.think();
3095                         self = self.owner;
3096                 }
3097         }
3098         else
3099         {
3100                 if(self.showheadshotbbox)
3101                         remove(self.showheadshotbbox);
3102         }
3103
3104         playerdemo_write();
3105
3106         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3107         {
3108                 if(!self.stored_netname)
3109                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3110                 if(self.stored_netname != self.netname)
3111                 {
3112                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3113                         strunzone(self.stored_netname);
3114                         self.stored_netname = strzone(self.netname);
3115                 }
3116         }
3117
3118         /*
3119         if(g_race)
3120                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3121         */
3122 }