qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         Portal_ClearAll(self);
 618
 619         if(self.alivetime)
 620         {
 621                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 622                 self.alivetime = 0;
 623         }
 624
 625         if(self.vehicle)
 626             vehicles_exit(VHEF_RELESE);
 627
 628         if(self.flagcarried)
 629                 DropFlag(self.flagcarried, world, world);
 630
 631         if(self.ballcarried && g_nexball)
 632                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 633
 634         WaypointSprite_PlayerDead();
 635
 636         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 637                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 638
 639         if(self.killcount != -666) {
 640                 if(g_lms) {
 641                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 642                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 643                         else
 644                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 645                 } else
 646                         bprint ("^4", self.netname, "^4 is spectating now\n");
 647
 648                 if(self.just_joined == FALSE) {
 649                         LogTeamchange(self.playerid, -1, 4);
 650                 } else
 651                         self.just_joined = FALSE;
 652         }
 653
 654         PlayerScore_Clear(self); // clear scores when needed
 655
 656         accuracy_resend(self);
 657
 658         self.spectatortime = time;
 659
 660         self.classname = "observer";
 661         self.iscreature = FALSE;
 662         self.health = -666;
 663         self.takedamage = DAMAGE_NO;
 664         self.solid = SOLID_NOT;
 665         self.movetype = MOVETYPE_NOCLIP;
 666         self.flags = FL_CLIENT | FL_NOTARGET;
 667         self.armorvalue = 666;
 668         self.effects = 0;
 669         self.armorvalue = autocvar_g_balance_armor_start;
 670         self.pauserotarmor_finished = 0;
 671         self.pauserothealth_finished = 0;
 672         self.pauseregen_finished = 0;
 673         self.damageforcescale = 0;
 674         self.death_time = 0;
 675         self.dead_frame = 0;
 676         self.alpha = 0;
 677         self.scale = 0;
 678         self.fade_time = 0;
 679         self.pain_frame = 0;
 680         self.pain_finished = 0;
 681         self.strength_finished = 0;
 682         self.invincible_finished = 0;
 683         self.pushltime = 0;
 684         self.think = SUB_Null;
 685         self.nextthink = 0;
 686         self.hook_time = 0;
 687         self.runes = 0;
 688         self.deadflag = DEAD_NO;
 689         self.angles = spot.angles;
 690         self.angles_z = 0;
 691         self.fixangle = TRUE;
 692         self.crouch = FALSE;
 693
 694         self.view_ofs = PL_VIEW_OFS;
 695         setorigin (self, spot.origin);
 696         setsize (self, '0 0 0', '0 0 0');
 697         self.prevorigin = self.origin;
 698         self.items = 0;
 699         self.weapons = 0;
 700         self.model = "";
 701         FixPlayermodel();
 702         self.model = "";
 703         self.modelindex = 0;
 704         self.weapon = 0;
 705         self.weaponmodel = "";
 706         self.weaponentity = world;
 707         self.exteriorweaponentity = world;
 708         self.killcount = -666;
 709         self.velocity = '0 0 0';
 710         self.avelocity = '0 0 0';
 711         self.punchangle = '0 0 0';
 712         self.punchvector = '0 0 0';
 713         self.oldvelocity = self.velocity;
 714         self.fire_endtime = -1;
 715
 716         if(sv_loddistance1)
 717                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 718
 719         if(g_arena)
 720         {
 721                 if(self.version_mismatch)
 722                 {
 723                         Spawnqueue_Unmark(self);
 724                         Spawnqueue_Remove(self);
 725                 }
 726                 else
 727                 {
 728                         Spawnqueue_Insert(self);
 729                 }
 730         }
 731         else if(g_lms)
 732         {
 733                 // Only if the player cannot play at all
 734                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 735                         self.frags = FRAGS_SPECTATOR;
 736                 else
 737                         self.frags = FRAGS_LMS_LOSER;
 738         }
 739         else
 740                 self.frags = FRAGS_SPECTATOR;
 741 }
 742
 743 void FixPlayermodel()
 744 {
 745         local string defaultmodel;
 746         local float defaultskin, chmdl, oldskin;
 747         local vector m1, m2;
 748
 749         defaultmodel = "";
 750
 751         if(autocvar_sv_defaultcharacter == 1) {
 752                 defaultskin = 0;
 753
 754                 if(teamplay)
 755                 {
 756                         string s;
 757                         s = Team_ColorNameLowerCase(self.team);
 758                         if(s != "neutral")
 759                         {
 760                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 761                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 762                         }
 763                 }
 764
 765                 if(defaultmodel == "")
 766                 {
 767                         defaultmodel = autocvar_sv_defaultplayermodel;
 768                         defaultskin = autocvar_sv_defaultplayerskin;
 769                 }
 770         }
 771
 772         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 773         {
 774                 if(self.model != "")
 775                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 776                 self.model = ""; // force the != checks to return true
 777         }
 778
 779         if(defaultmodel != "")
 780         {
 781                 if (defaultmodel != self.model)
 782                 {
 783                         m1 = self.mins;
 784                         m2 = self.maxs;
 785                         setmodel_lod (self, defaultmodel);
 786                         setsize (self, m1, m2);
 787                         chmdl = TRUE;
 788                 }
 789
 790                 oldskin = self.skinindex;
 791                 self.skinindex = defaultskin;
 792         } else {
 793                 if (self.playermodel != self.model || self.playermodel == "")
 794                 {
 795                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 796                         m1 = self.mins;
 797                         m2 = self.maxs;
 798                         setmodel_lod (self, self.playermodel);
 799                         setsize (self, m1, m2);
 800                         chmdl = TRUE;
 801                 }
 802
 803                 oldskin = self.skinindex;
 804                 self.skinindex = stof(self.playerskin);
 805         }
 806
 807         if(chmdl || oldskin != self.skinindex)
 808                 self.species = player_getspecies(); // model or skin has changed
 809
 810         if(!teamplay)
 811                 if(strlen(autocvar_sv_defaultplayercolors))
 812                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 813                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 814 }
 815
 816 void PlayerTouchExplode(entity p1, entity p2)
 817 {
 818         vector org;
 819         org = (p1.origin + p2.origin) * 0.5;
 820         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 821
 822         te_explosion(org);
 823
 824         entity e;
 825         e = spawn();
 826         setorigin(e, org);
 827         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 828         remove(e);
 829 }
 830
 831 /*
 832 =============
 833 PutClientInServer
 834
 835 Called when a client spawns in the server
 836 =============
 837 */
 838 //void() ctf_playerchanged;
 839 void PutClientInServer (void)
 840 {
 841         if(clienttype(self) == CLIENTTYPE_BOT)
 842         {
 843                 self.classname = "player";
 844         }
 845         else if(clienttype(self) == CLIENTTYPE_REAL)
 846         {
 847                 msg_entity = self;
 848                 WriteByte(MSG_ONE, SVC_SETVIEW);
 849                 WriteEntity(MSG_ONE, self);
 850         }
 851
 852         // player is dead and becomes observer
 853         // FIXME fix LMS scoring for new system
 854         if(g_lms)
 855         {
 856                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 857                         self.classname = "observer";
 858         }
 859
 860         if(g_arena || (g_ca && !allowed_to_spawn))
 861         if(!self.spawned)
 862                 self.classname = "observer";
 863
 864         if(gameover)
 865                 self.classname = "observer";
 866
 867         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 868                 entity spot, oldself;
 869                 float j;
 870
 871                 accuracy_resend(self);
 872
 873                 if(self.team < 0)
 874                         JoinBestTeam(self, FALSE, TRUE);
 875
 876                 race_PreSpawn();
 877
 878                 spot = SelectSpawnPoint (FALSE);
 879                 if(!spot)
 880                 {
 881                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 882                         return; // spawn failed
 883                 }
 884
 885                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 886
 887                 self.classname = "player";
 888                 self.wasplayer = TRUE;
 889                 self.iscreature = TRUE;
 890                 self.movetype = MOVETYPE_WALK;
 891                 self.solid = SOLID_SLIDEBOX;
 892                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 893                 if(autocvar_g_playerclip_collisions)
 894                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 895                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 896                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 897                 self.frags = FRAGS_PLAYER;
 898                 if(independent_players)
 899                         MAKE_INDEPENDENT_PLAYER(self);
 900                 self.flags = FL_CLIENT;
 901                 self.takedamage = DAMAGE_AIM;
 902                 if(g_minstagib)
 903                         self.effects = EF_FULLBRIGHT;
 904                 else
 905                         self.effects = 0;
 906                 self.air_finished = time + 12;
 907                 self.dmg = 2;
 908                 if(autocvar_g_balance_nex_charge)
 909                 {
 910                         if(autocvar_g_balance_nex_secondary_chargepool)
 911                                 self.nex_chargepool_ammo = 1;
 912                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 913                 }
 914
 915                 if(inWarmupStage)
 916                 {
 917                         self.ammo_shells = warmup_start_ammo_shells;
 918                         self.ammo_nails = warmup_start_ammo_nails;
 919                         self.ammo_rockets = warmup_start_ammo_rockets;
 920                         self.ammo_cells = warmup_start_ammo_cells;
 921                         self.ammo_fuel = warmup_start_ammo_fuel;
 922                         self.health = warmup_start_health;
 923                         self.armorvalue = warmup_start_armorvalue;
 924                         self.weapons = warmup_start_weapons;
 925                 }
 926                 else
 927                 {
 928                         self.ammo_shells = start_ammo_shells;
 929                         self.ammo_nails = start_ammo_nails;
 930                         self.ammo_rockets = start_ammo_rockets;
 931                         self.ammo_cells = start_ammo_cells;
 932                         self.ammo_fuel = start_ammo_fuel;
 933                         self.health = start_health;
 934                         self.armorvalue = start_armorvalue;
 935                         self.weapons = start_weapons;
 936                 }
 937
 938                 if(g_weaponarena_random)
 939                 {
 940                         if(g_weaponarena_random_with_laser)
 941                                 self.weapons &~= WEPBIT_LASER;
 942                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 943                         if(g_weaponarena_random_with_laser)
 944                                 self.weapons |= WEPBIT_LASER;
 945                 }
 946
 947                 self.items = start_items;
 948                 self.jump_interval = time;
 949
 950                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 951                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 952                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 953                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 954                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 955                 //extend the pause of rotting if client was reset at the beginning of the countdown
 956                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 957                         self.spawnshieldtime += game_starttime - time;
 958                         self.pauserotarmor_finished += game_starttime - time;
 959                         self.pauserothealth_finished += game_starttime - time;
 960                         self.pauseregen_finished += game_starttime - time;
 961                 }
 962                 self.damageforcescale = 2;
 963                 self.death_time = 0;
 964                 self.dead_frame = 0;
 965                 self.alpha = 0;
 966                 self.scale = 0;
 967                 self.fade_time = 0;
 968                 self.pain_frame = 0;
 969                 self.pain_finished = 0;
 970                 self.strength_finished = 0;
 971                 self.invincible_finished = 0;
 972                 self.pushltime = 0;
 973                 // players have no think function
 974                 self.think = SUB_Null;
 975                 self.nextthink = 0;
 976                 self.hook_time = 0;
 977                 self.dmg_team = 0;
 978                 self.ballistics_density = autocvar_g_ballistics_density_player;
 979
 980                 self.metertime = 0;
 981
 982                 self.runes = 0;
 983
 984                 self.deadflag = DEAD_NO;
 985
 986                 self.angles = spot.angles;
 987
 988                 self.angles_z = 0; // never spawn tilted even if the spot says to
 989                 self.fixangle = TRUE; // turn this way immediately
 990                 self.velocity = '0 0 0';
 991                 self.avelocity = '0 0 0';
 992                 self.punchangle = '0 0 0';
 993                 self.punchvector = '0 0 0';
 994                 self.oldvelocity = self.velocity;
 995                 self.fire_endtime = -1;
 996
 997                 msg_entity = self;
 998                 WRITESPECTATABLE_MSG_ONE({
 999                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1000                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1001                 });
1002
1003                 if(sv_loddistance1)
1004                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1005
1006                 self.model = "";
1007                 FixPlayermodel();
1008
1009                 self.crouch = FALSE;
1010                 self.view_ofs = PL_VIEW_OFS;
1011                 setsize (self, PL_MIN, PL_MAX);
1012                 self.spawnorigin = spot.origin;
1013                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1014                 // don't reset back to last position, even if new position is stuck in solid
1015                 self.oldorigin = self.origin;
1016                 self.prevorigin = self.origin;
1017                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1018                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1019
1020                 if(g_arena)
1021                 {
1022                         Spawnqueue_Remove(self);
1023                         Spawnqueue_Mark(self);
1024                 }
1025
1026                 else if(g_ca)
1027                         self.caplayer = 1;
1028
1029                 self.event_damage = PlayerDamage;
1030
1031                 self.bot_attack = TRUE;
1032
1033                 self.statdraintime = time + 5;
1034                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1035
1036                 if(self.killcount == -666) {
1037                         PlayerScore_Clear(self);
1038                         self.killcount = 0;
1039                 }
1040
1041                 self.cnt = WEP_LASER;
1042
1043                 CL_SpawnWeaponentity();
1044                 self.alpha = default_player_alpha;
1045                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1046                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1047
1048                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1049                 self.lms_traveled_distance = 0;
1050                 self.speedrunning = FALSE;
1051
1052                 race_PostSpawn(spot);
1053
1054                 if(autocvar_spawn_debug)
1055                 {
1056                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1057                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1058                 }
1059
1060                 //stuffcmd(self, "chase_active 0");
1061                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1062
1063                 if (autocvar_g_spawnsound)
1064                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1065
1066                 if(g_assault) {
1067                         if(self.team == assault_attacker_team)
1068                                 centerprint(self, "You are attacking!");
1069                         else
1070                                 centerprint(self, "You are defending!");
1071                 }
1072
1073                 target_voicescript_clear(self);
1074
1075                 // reset fields the weapons may use
1076                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1077                 {
1078                         weapon_action(j, WR_RESETPLAYER);
1079
1080                         // all weapons must be fully loaded when we spawn
1081                         entity e;
1082                         e = get_weaponinfo(j);
1083                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1084                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1085                 }
1086                 self.weapon_forbidchange = FALSE;
1087
1088                 oldself = self;
1089                 self = spot;
1090                         activator = oldself;
1091                                 string s;
1092                                 s = self.target;
1093                                 self.target = string_null;
1094                                 SUB_UseTargets();
1095                                 self.target = s;
1096                         activator = world;
1097                 self = oldself;
1098
1099                 MUTATOR_CALLHOOK(PlayerSpawn);
1100
1101                 self.switchweapon = w_getbestweapon(self);
1102                 self.cnt = self.switchweapon;
1103                 self.weapon = 0;
1104
1105                 if(!self.alivetime)
1106                         self.alivetime = time;
1107         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1108                 PutObserverInServer ();
1109         }
1110
1111         //if(g_ctf)
1112         //      ctf_playerchanged();
1113 }
1114
1115 .float ebouncefactor, ebouncestop; // electro's values
1116 // TODO do we need all these fields, or should we stop autodetecting runtime
1117 // changes and just have a console command to update this?
1118 float ClientInit_SendEntity(entity to, float sf)
1119 {
1120         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1121         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1122         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1123         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1124         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1125         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1126         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1127         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1128         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1129         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1130         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1131         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1132         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1133         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1134         if(sv_foginterval && world.fog != "")
1135                 WriteString(MSG_ENTITY, world.fog);
1136         else
1137                 WriteString(MSG_ENTITY, "");
1138         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1139         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1140         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1141         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1142         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1143         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1144         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1145         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1146         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1147         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1148         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1149         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1150         return TRUE;
1151 }
1152
1153 void ClientInit_CheckUpdate()
1154 {
1155         self.nextthink = time;
1156         if(self.count != autocvar_g_balance_armor_blockpercent)
1157         {
1158                 self.count = autocvar_g_balance_armor_blockpercent;
1159                 self.SendFlags |= 1;
1160         }
1161         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1162         {
1163                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1164                 self.SendFlags |= 1;
1165         }
1166         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1167         {
1168                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1169                 self.SendFlags |= 1;
1170         }
1171         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1172         {
1173                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1174                 self.SendFlags |= 1;
1175         }
1176         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1177         {
1178                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1179                 self.SendFlags |= 1;
1180         }
1181         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1182         {
1183                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1184                 self.SendFlags |= 1;
1185         }
1186 }
1187
1188 void ClientInit_Spawn()
1189 {
1190         entity o;
1191         entity e;
1192         e = spawn();
1193         e.classname = "clientinit";
1194         e.think = ClientInit_CheckUpdate;
1195         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1196
1197         o = self;
1198         self = e;
1199         ClientInit_CheckUpdate();
1200         self = o;
1201 }
1202
1203 /*
1204 =============
1205 SetNewParms
1206 =============
1207 */
1208 void SetNewParms (void)
1209 {
1210         // initialize parms for a new player
1211         parm1 = -(86400 * 366);
1212 }
1213
1214 /*
1215 =============
1216 SetChangeParms
1217 =============
1218 */
1219 void SetChangeParms (void)
1220 {
1221         // save parms for level change
1222         parm1 = self.parm_idlesince - time;
1223 }
1224
1225 /*
1226 =============
1227 DecodeLevelParms
1228 =============
1229 */
1230 void DecodeLevelParms (void)
1231 {
1232         // load parms
1233         self.parm_idlesince = parm1;
1234         if(self.parm_idlesince == -(86400 * 366))
1235                 self.parm_idlesince = time;
1236
1237         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1238         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1239 }
1240
1241 /*
1242 =============
1243 ClientKill
1244
1245 Called when a client types 'kill' in the console
1246 =============
1247 */
1248
1249 .float clientkill_nexttime;
1250 void ClientKill_Now_TeamChange()
1251 {
1252         if(self.killindicator_teamchange == -1)
1253         {
1254                 self.team = -1;
1255                 JoinBestTeam( self, FALSE, FALSE );
1256         }
1257         else if(self.killindicator_teamchange == -2)
1258         {
1259                 if(g_ca)
1260                         self.caplayer = 0;
1261                 if(blockSpectators)
1262                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1263                 PutObserverInServer();
1264         }
1265         else
1266                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1267 }
1268
1269 void ClientKill_Now()
1270 {
1271         if(self.vehicle)
1272         {
1273             vehicles_exit(VHEF_RELESE);
1274             if(!self.killindicator_teamchange)
1275             {
1276             self.vehicle_health = -1;
1277             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1278             }
1279         }
1280
1281         if(self.killindicator && !wasfreed(self.killindicator))
1282         remove(self.killindicator);
1283
1284         self.killindicator = world;
1285
1286         if(self.killindicator_teamchange)
1287                 ClientKill_Now_TeamChange();
1288
1289         // in any case:
1290         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1291
1292         // now I am sure the player IS dead
1293 }
1294 void KillIndicator_Think()
1295 {
1296         if (!self.owner.modelindex)
1297         {
1298                 self.owner.killindicator = world;
1299                 remove(self);
1300                 return;
1301         }
1302
1303         if(self.cnt <= 0)
1304         {
1305                 self = self.owner;
1306                 ClientKill_Now(); // no oldself needed
1307                 return;
1308         }
1309     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1310     {
1311         self.nextthink = time + 1;
1312         self.cnt -= 1;
1313     }
1314         else
1315         {
1316                 if(self.cnt <= 10)
1317                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1318                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1319                 {
1320                         if(self.cnt <= 10)
1321                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1322                         if(self.owner.killindicator_teamchange)
1323                         {
1324                                 if(self.owner.killindicator_teamchange == -1)
1325                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1326                                 else if(self.owner.killindicator_teamchange == -2)
1327                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1328                                 else
1329                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1330                         }
1331                         else
1332                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1333                 }
1334                 self.nextthink = time + 1;
1335                 self.cnt -= 1;
1336         }
1337 }
1338
1339 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1340 {
1341         float killtime;
1342         entity e;
1343         killtime = autocvar_g_balance_kill_delay;
1344
1345         if(g_race_qualifying || g_cts)
1346                 killtime = 0;
1347
1348     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1349     {
1350                 remove(self.killindicator);
1351                 self.killindicator = world;
1352
1353         ClientKill_Now(); // allow instant kill in this case
1354         return;
1355     }
1356
1357         self.killindicator_teamchange = targetteam;
1358
1359     if(!self.killindicator)
1360         {
1361                 if(self.modelindex && self.deadflag == DEAD_NO)
1362                 {
1363                         killtime = max(killtime, self.clientkill_nexttime - time);
1364                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1365                 }
1366
1367                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1368                 {
1369                         ClientKill_Now();
1370                 }
1371                 else
1372                 {
1373                         self.killindicator = spawn();
1374                         self.killindicator.owner = self;
1375                         self.killindicator.scale = 0.5;
1376                         setattachment(self.killindicator, self, "");
1377                         setorigin(self.killindicator, '0 0 52');
1378                         self.killindicator.think = KillIndicator_Think;
1379                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1380                         self.killindicator.cnt = ceil(killtime);
1381                         self.killindicator.count = bound(0, ceil(killtime), 10);
1382                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1383
1384                         for(e = world; (e = find(e, classname, "body")) != world; )
1385                         {
1386                                 if(e.enemy != self)
1387                                         continue;
1388                                 e.killindicator = spawn();
1389                                 e.killindicator.owner = e;
1390                                 e.killindicator.scale = 0.5;
1391                                 setattachment(e.killindicator, e, "");
1392                                 setorigin(e.killindicator, '0 0 52');
1393                                 e.killindicator.think = KillIndicator_Think;
1394                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1395                                 e.killindicator.cnt = ceil(killtime);
1396                         }
1397                         self.lip = 0;
1398                 }
1399         }
1400         if(self.killindicator)
1401         {
1402                 if(targetteam == 0) // just die
1403                         self.killindicator.colormod = '0 0 0';
1404                 else if(targetteam == -1) // auto
1405                         self.killindicator.colormod = '0 1 0';
1406                 else if(targetteam == -2) // spectate
1407                         self.killindicator.colormod = '0.5 0.5 0.5';
1408                 else
1409                         self.killindicator.colormod = TeamColor(targetteam);
1410         }
1411 }
1412
1413 void ClientKill (void)
1414 {
1415         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1416         {
1417                 // do nothing
1418         }
1419     else if(self.freezetag_frozen)
1420     {
1421         // do nothing
1422     }
1423         else
1424                 ClientKill_TeamChange(0);
1425 }
1426
1427 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1428 {
1429     e.killindicator = spawn();
1430     e.killindicator.owner = e;
1431     e.killindicator.think = KillIndicator_Think;
1432     e.killindicator.nextthink = time + (e.lip) * 0.05;
1433     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1434     e.killindicator.health = 1; // this is used to indicate that it should be silent
1435     e.lip = 0;
1436 }
1437
1438 void DoTeamChange(float destteam)
1439 {
1440         float t, c0;
1441         if(!teamplay)
1442         {
1443                 if(destteam >= 0)
1444                         SetPlayerColors(self, destteam);
1445                 return;
1446         }
1447         if(self.classname == "player")
1448         if(destteam == -1)
1449         {
1450                 CheckAllowedTeams(self);
1451                 t = FindSmallestTeam(self, TRUE);
1452                 switch(self.team)
1453                 {
1454                         case COLOR_TEAM1: c0 = c1; break;
1455                         case COLOR_TEAM2: c0 = c2; break;
1456                         case COLOR_TEAM3: c0 = c3; break;
1457                         case COLOR_TEAM4: c0 = c4; break;
1458                         default:          c0 = 999;
1459                 }
1460                 switch(t)
1461                 {
1462                         case 1:
1463                                 if(c0 > c1)
1464                                         destteam = COLOR_TEAM1;
1465                                 break;
1466                         case 2:
1467                                 if(c0 > c2)
1468                                         destteam = COLOR_TEAM2;
1469                                 break;
1470                         case 3:
1471                                 if(c0 > c3)
1472                                         destteam = COLOR_TEAM3;
1473                                 break;
1474                         case 4:
1475                                 if(c0 > c4)
1476                                         destteam = COLOR_TEAM4;
1477                                 break;
1478                 }
1479                 if(destteam == -1)
1480                         return;
1481         }
1482         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1483                 return;
1484         ClientKill_TeamChange(destteam);
1485 }
1486
1487 void FixClientCvars(entity e)
1488 {
1489         // send prediction settings to the client
1490         stuffcmd(e, "\nin_bindmap 0 0\n");
1491         if(g_race || g_cts)
1492                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1493         if(autocvar_g_antilag == 3) // client side hitscan
1494                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1495         if(sv_gentle)
1496                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1497         /*
1498          * we no longer need to stuff this. Remove this comment block if you feel
1499          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1500         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1501         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1502         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1503         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1504         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1505         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1506         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1507         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1508         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1509         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1510         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1511         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1512         stuffcmd(e, "cl_movement_edgefriction 1\n");
1513          */
1514 }
1515
1516 float PlayerInIDList(entity p, string idlist)
1517 {
1518         float n, i;
1519         string s;
1520
1521         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1522         if not(p.crypto_idfp)
1523                 return 0;
1524
1525         // this function allows abbreviated player IDs too!
1526         n = tokenize_console(idlist);
1527         for(i = 0; i < n; ++i)
1528         {
1529                 s = argv(i);
1530                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1531                         return 1;
1532         }
1533
1534         return 0;
1535 }
1536
1537 /*
1538 =============
1539 ClientConnect
1540
1541 Called when a client connects to the server
1542 =============
1543 */
1544 //void ctf_clientconnect();
1545 string ColoredTeamName(float t);
1546 void DecodeLevelParms (void);
1547 //void dom_player_join_team(entity pl);
1548 void set_dom_state(entity e);
1549 void ClientConnect (void)
1550 {
1551         float t;
1552
1553         if(self.flags & FL_CLIENT)
1554         {
1555                 print("Warning: ClientConnect, but already connected!\n");
1556                 return;
1557         }
1558
1559         if(Ban_MaybeEnforceBan(self))
1560                 return;
1561
1562         DecodeLevelParms();
1563
1564 #ifdef WATERMARK
1565         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1566 #endif
1567
1568         self.classname = "player_joining";
1569
1570         self.flags = FL_CLIENT;
1571         self.version_nagtime = time + 10 + random() * 10;
1572
1573         if(player_count<0)
1574         {
1575                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1576                 player_count = 0;
1577         }
1578
1579         PlayerScore_Attach(self);
1580         ClientData_Attach();
1581         accuracy_init(self);
1582
1583         bot_clientconnect();
1584
1585         playerdemo_init();
1586
1587         anticheat_init();
1588
1589         race_PreSpawnObserver();
1590
1591         //if(g_domination)
1592         //      dom_player_join_team(self);
1593
1594         // identify the right forced team
1595         if(autocvar_g_campaign)
1596         {
1597                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1598                 {
1599                         switch(autocvar_g_campaign_forceteam)
1600                         {
1601                                 case 1: self.team_forced = COLOR_TEAM1; break;
1602                                 case 2: self.team_forced = COLOR_TEAM2; break;
1603                                 case 3: self.team_forced = COLOR_TEAM3; break;
1604                                 case 4: self.team_forced = COLOR_TEAM4; break;
1605                                 default: self.team_forced = 0;
1606                         }
1607                 }
1608         }
1609         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1610                 self.team_forced = COLOR_TEAM1;
1611         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1612                 self.team_forced = COLOR_TEAM2;
1613         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1614                 self.team_forced = COLOR_TEAM3;
1615         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1616                 self.team_forced = COLOR_TEAM4;
1617         else if(autocvar_g_forced_team_otherwise == "red")
1618                 self.team_forced = COLOR_TEAM1;
1619         else if(autocvar_g_forced_team_otherwise == "blue")
1620                 self.team_forced = COLOR_TEAM2;
1621         else if(autocvar_g_forced_team_otherwise == "yellow")
1622                 self.team_forced = COLOR_TEAM3;
1623         else if(autocvar_g_forced_team_otherwise == "pink")
1624                 self.team_forced = COLOR_TEAM4;
1625         else if(autocvar_g_forced_team_otherwise == "spectate")
1626                 self.team_forced = -1;
1627         else if(autocvar_g_forced_team_otherwise == "spectator")
1628                 self.team_forced = -1;
1629         else
1630                 self.team_forced = 0;
1631
1632         if(!teamplay)
1633                 if(self.team_forced > 0)
1634                         self.team_forced = 0;
1635
1636         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1637
1638         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1639                 self.classname = "observer";
1640         } else {
1641                 if(teamplay)
1642                 {
1643                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1644                         {
1645                                 self.classname = "player";
1646                                 campaign_bots_may_start = 1;
1647                         }
1648                         else
1649                         {
1650                                 self.classname = "observer"; // do it anyway
1651                         }
1652                 }
1653                 else
1654                 {
1655                         self.classname = "player";
1656                         campaign_bots_may_start = 1;
1657                 }
1658         }
1659
1660         self.playerid = (playerid_last = playerid_last + 1);
1661
1662     if(clienttype(self) == CLIENTTYPE_BOT)
1663         PlayerStats_AddPlayer(self);
1664
1665         if(autocvar_sv_eventlog)
1666                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1667
1668         LogTeamchange(self.playerid, self.team, 1);
1669
1670         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1671
1672         self.netname_previous = strzone(self.netname);
1673
1674         bprint("^4", self.netname, "^4 connected");
1675
1676         if(self.classname != "observer" && (g_domination || g_ctf))
1677                 bprint(" and joined the ", ColoredTeamName(self.team));
1678
1679         bprint("\n");
1680
1681         self.welcomemessage_time = 0;
1682
1683         stuffcmd(self, strcat(clientstuff, "\n"));
1684         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1685         stuffcmd(self, "cl_particles_reloadeffects\n");
1686
1687         FixClientCvars(self);
1688
1689         // spawnfunc_waypoint sprites
1690         WaypointSprite_InitClient(self);
1691
1692         // Wazat's grappling hook
1693         SetGrappleHookBindings();
1694
1695         // get autoswitch state from player when he toggles it
1696         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1697
1698         // get version info from player
1699         stuffcmd(self, "cmd clientversion $gameversion\n");
1700
1701         // get other cvars from player
1702         GetCvars(0);
1703
1704         // notify about available teams
1705         if(teamplay)
1706         {
1707                 CheckAllowedTeams(self);
1708                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1709                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1710         }
1711         else
1712                 stuffcmd(self, "set _teams_available 0\n");
1713
1714         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1715
1716         if(g_arena || g_ca)
1717         {
1718                 self.classname = "observer";
1719                 if(g_arena)
1720                         Spawnqueue_Insert(self);
1721         }
1722         /*else if(g_ctf)
1723         {
1724                 ctf_clientconnect();
1725         }*/
1726
1727         attach_entcs();
1728
1729         bot_relinkplayerlist();
1730
1731         self.spectatortime = time;
1732         if(blockSpectators)
1733         {
1734                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1735         }
1736
1737         self.jointime = time;
1738         self.allowedTimeouts = autocvar_sv_timeout_number;
1739
1740         if(clienttype(self) == CLIENTTYPE_REAL)
1741         {
1742                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1743                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1744         }
1745
1746         if(g_lms)
1747         {
1748                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1749                 {
1750                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1751                         self.frags = FRAGS_SPECTATOR;
1752                 }
1753         }
1754
1755         if(!sv_foginterval && world.fog != "")
1756                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1757
1758         SoundEntity_Attach(self);
1759
1760         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1761         {
1762                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1763                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1764         }
1765         else
1766                 self.hitplotfh = -1;
1767
1768         if(g_race || g_cts) {
1769                 string rr;
1770                 if(g_cts)
1771                         rr = CTS_RECORD;
1772                 else
1773                         rr = RACE_RECORD;
1774                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1775
1776                 msg_entity = self;
1777                 race_send_recordtime(MSG_ONE);
1778                 race_send_speedaward(MSG_ONE);
1779
1780                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1781                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1782                 race_send_speedaward_alltimebest(MSG_ONE);
1783
1784                 float i;
1785                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1786                         race_SendRankings(i, 0, 0, MSG_ONE);
1787                 }
1788         }
1789         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1790                 send_CSQC_teamnagger();
1791
1792         if (g_domination)
1793                 set_dom_state(self);
1794
1795         CheatInitClient();
1796 }
1797
1798 /*
1799 =============
1800 ClientDisconnect
1801
1802 Called when a client disconnects from the server
1803 =============
1804 */
1805 .entity chatbubbleentity;
1806 void ReadyCount();
1807 void ClientDisconnect (void)
1808 {
1809         if(self.vehicle)
1810             vehicles_exit(VHEF_RELESE);
1811
1812         if not(self.flags & FL_CLIENT)
1813         {
1814                 print("Warning: ClientDisconnect without ClientConnect\n");
1815                 return;
1816         }
1817
1818         PlayerStats_AddGlobalInfo(self);
1819
1820         CheatShutdownClient();
1821
1822         if(self.hitplotfh >= 0)
1823         {
1824                 fclose(self.hitplotfh);
1825                 self.hitplotfh = -1;
1826         }
1827
1828         anticheat_report();
1829         anticheat_shutdown();
1830
1831         playerdemo_shutdown();
1832
1833         bot_clientdisconnect();
1834
1835         if(self.entcs)
1836                 detach_entcs();
1837
1838         if(autocvar_sv_eventlog)
1839                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1840         bprint ("^4",self.netname);
1841         bprint ("^4 disconnected\n");
1842
1843         SoundEntity_Detach(self);
1844
1845         DropAllRunes(self);
1846         MUTATOR_CALLHOOK(ClientDisconnect);
1847
1848         Portal_ClearAll(self);
1849
1850         if(self.flagcarried)
1851                 DropFlag(self.flagcarried, world, world);
1852         if(self.ballcarried && g_nexball)
1853                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1854
1855         // Here, everything has been done that requires this player to be a client.
1856
1857         self.flags &~= FL_CLIENT;
1858
1859         if (self.chatbubbleentity)
1860                 remove (self.chatbubbleentity);
1861
1862         if (self.killindicator)
1863                 remove (self.killindicator);
1864
1865         WaypointSprite_PlayerGone();
1866
1867         bot_relinkplayerlist();
1868
1869         if(g_arena)
1870         {
1871                 Spawnqueue_Unmark(self);
1872                 Spawnqueue_Remove(self);
1873         }
1874
1875         accuracy_free(self);
1876         ClientData_Detach();
1877         PlayerScore_Detach(self);
1878
1879         if(self.netname_previous)
1880                 strunzone(self.netname_previous);
1881         if(self.clientstatus)
1882                 strunzone(self.clientstatus);
1883         if(self.weaponorder_byimpulse)
1884                 strunzone(self.weaponorder_byimpulse);
1885
1886         ClearPlayerSounds();
1887
1888         if(self.personal)
1889                 remove(self.personal);
1890
1891         self.playerid = 0;
1892         ReadyCount();
1893
1894         // free cvars
1895         GetCvars(-1);
1896 }
1897
1898 .float BUTTON_CHAT;
1899 void ChatBubbleThink()
1900 {
1901         self.nextthink = time;
1902         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1903         {
1904                 if(self.owner) // but why can that ever be world?
1905                         self.owner.chatbubbleentity = world;
1906                 remove(self);
1907                 return;
1908         }
1909         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1910 #ifdef TETRIS
1911                 || self.owner.tetris_on
1912 #endif
1913         )
1914                 self.model = self.mdl;
1915         else
1916                 self.model = "";
1917 };
1918
1919 void UpdateChatBubble()
1920 {
1921         if (!self.modelindex)
1922                 return;
1923         // spawn a chatbubble entity if needed
1924         if (!self.chatbubbleentity)
1925         {
1926                 self.chatbubbleentity = spawn();
1927                 self.chatbubbleentity.owner = self;
1928                 self.chatbubbleentity.exteriormodeltoclient = self;
1929                 self.chatbubbleentity.think = ChatBubbleThink;
1930                 self.chatbubbleentity.nextthink = time;
1931                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1932                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1933                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1934                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1935                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1936                 self.chatbubbleentity.model = "";
1937                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1938         }
1939 }
1940
1941
1942 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1943 // added to the model skins
1944 /*void UpdateColorModHack()
1945 {
1946         local float c;
1947         c = self.clientcolors & 15;
1948         // LordHavoc: only bothering to support white, green, red, yellow, blue
1949              if (!teamplay) self.colormod = '0 0 0';
1950         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1951         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1952         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1953         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1954         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1955         else self.colormod = '1 1 1';
1956 };*/
1957
1958 .float oldcolormap;
1959 void respawn(void)
1960 {
1961         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1962         {
1963                 self.solid = SOLID_NOT;
1964                 self.takedamage = DAMAGE_NO;
1965                 self.movetype = MOVETYPE_FLY;
1966                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1967                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1968                 self.effects |= EF_ADDITIVE;
1969                 self.oldcolormap = self.colormap;
1970                 self.colormap = 512;
1971                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1972                 if(autocvar_g_respawn_ghosts_maxtime)
1973                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1974         }
1975
1976         CopyBody(1);
1977         self.effects |= EF_NODRAW; // prevent another CopyBody
1978         if(self.oldcolormap)
1979         {
1980                 self.colormap = self.oldcolormap;
1981                 self.oldcolormap = 0;
1982         }
1983         PutClientInServer();
1984 }
1985
1986 void play_countdown(float finished, string samp)
1987 {
1988         if(clienttype(self) == CLIENTTYPE_REAL)
1989                 if(floor(finished - time - frametime) != floor(finished - time))
1990                         if(finished - time < 6)
1991                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1992 }
1993
1994 /**
1995  * When sv_timeout is used this function returs strings like
1996  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1997  * Called by centerprint functions
1998  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1999  */
2000 string getTimeoutText(float addOneSecond) {
2001         if (!autocvar_sv_timeout || !timeoutStatus)
2002                 return "";
2003
2004         local string retStr;
2005         if (timeoutStatus == 1) {
2006                 if (addOneSecond == 1) {
2007                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2008                 }
2009                 else {
2010                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2011                 }
2012                 return retStr;
2013         }
2014         else if (timeoutStatus == 2) {
2015                 if (addOneSecond) {
2016                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2017                         //don't show messages like "Timeout ends in 0 seconds"...
2018                         if ((remainingTimeoutTime + 1) > 0)
2019                                 return retStr;
2020                         else
2021                                 return "";
2022                 }
2023                 else {
2024                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2025                         //don't show messages like "Timeout ends in 0 seconds"...
2026                         if (remainingTimeoutTime > 0)
2027                                 return retStr;
2028                         else
2029                                 return "";
2030                 }
2031         }
2032         else return "";
2033 }
2034
2035 void player_powerups (void)
2036 {
2037         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2038         olditems = self.items;
2039
2040         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2041         {
2042                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2043                 self.modelflags |= MF_ROCKET;
2044         }
2045         else
2046         {
2047                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
2048                 self.modelflags &~= MF_ROCKET;
2049         }
2050
2051         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2052
2053         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2054                 return;
2055
2056         Fire_ApplyDamage(self);
2057         Fire_ApplyEffect(self);
2058
2059         if (g_minstagib)
2060         {
2061                 self.effects |= EF_FULLBRIGHT;
2062
2063                 if (self.items & IT_STRENGTH)
2064                 {
2065                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2066                         if (time > self.strength_finished)
2067                         {
2068                                 self.alpha = default_player_alpha;
2069                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2070                                 self.items &~= IT_STRENGTH;
2071                                 sprint(self, "^3Invisibility has worn off\n");
2072                         }
2073                 }
2074                 else
2075                 {
2076                         if (time < self.strength_finished)
2077                         {
2078                                 self.alpha = g_minstagib_invis_alpha;
2079                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2080                                 self.items |= IT_STRENGTH;
2081                                 sprint(self, "^3You are invisible\n");
2082                         }
2083                 }
2084
2085                 if (self.items & IT_INVINCIBLE)
2086                 {
2087                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2088                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2089                         {
2090                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2091                                 sprint(self, "^3Speed has worn off\n");
2092                         }
2093                 }
2094                 else
2095                 {
2096                         if (time < self.invincible_finished)
2097                         {
2098                                 self.items = self.items | IT_INVINCIBLE;
2099                                 sprint(self, "^3You are on speed\n");
2100                         }
2101                 }
2102         }
2103         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2104         {
2105                 if (self.items & IT_STRENGTH)
2106                 {
2107                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2108                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2109                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2110                         {
2111                                 self.items = self.items - (self.items & IT_STRENGTH);
2112                                 sprint(self, "^3Strength has worn off\n");
2113                         }
2114                 }
2115                 else
2116                 {
2117                         if (time < self.strength_finished)
2118                         {
2119                                 self.items = self.items | IT_STRENGTH;
2120                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2121                         }
2122                 }
2123                 if (self.items & IT_INVINCIBLE)
2124                 {
2125                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2126                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2127                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2128                         {
2129                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2130                                 sprint(self, "^3Shield has worn off\n");
2131                         }
2132                 }
2133                 else
2134                 {
2135                         if (time < self.invincible_finished)
2136                         {
2137                                 self.items = self.items | IT_INVINCIBLE;
2138                                 sprint(self, "^3Shield surrounds you\n");
2139                         }
2140                 }
2141
2142                 if(autocvar_g_nodepthtestplayers)
2143                         self.effects = self.effects | EF_NODEPTHTEST;
2144
2145                 if(autocvar_g_fullbrightplayers)
2146                         self.effects = self.effects | EF_FULLBRIGHT;
2147
2148                 // midair gamemode: damage only while in the air
2149                 // if in midair mode, being on ground grants temporary invulnerability
2150                 // (this is so that multishot weapon don't clear the ground flag on the
2151                 // first damage in the frame, leaving the player vulnerable to the
2152                 // remaining hits in the same frame)
2153                 if (self.flags & FL_ONGROUND)
2154                 if (g_midair)
2155                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2156
2157                 if (time >= game_starttime)
2158                 if (time < self.spawnshieldtime)
2159                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2160         }
2161
2162         MUTATOR_CALLHOOK(PlayerPowerups);
2163 }
2164
2165 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2166 {
2167         if(current > stable)
2168                 return current;
2169         else if(current > stable - 0.25) // when close enough, "snap"
2170                 return stable;
2171         else
2172                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2173 }
2174
2175 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2176 {
2177         if(current < stable)
2178                 return current;
2179         else if(current < stable + 0.25) // when close enough, "snap"
2180                 return stable;
2181         else
2182                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2183 }
2184
2185 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2186 {
2187         if(current > rotstable)
2188         {
2189                 if(rotframetime > 0)
2190                 {
2191                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2192                         current = max(rotstable, current - rotlinear * rotframetime);
2193                 }
2194         }
2195         else if(current < regenstable)
2196         {
2197                 if(regenframetime > 0)
2198                 {
2199                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2200                         current = min(regenstable, current + regenlinear * regenframetime);
2201                 }
2202         }
2203
2204         if(current > limit)
2205                 current = limit;
2206
2207         return current;
2208 }
2209
2210 void player_regen (void)
2211 {
2212         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2213         maxh = autocvar_g_balance_health_rotstable;
2214         maxa = autocvar_g_balance_armor_rotstable;
2215         maxf = autocvar_g_balance_fuel_rotstable;
2216         minh = autocvar_g_balance_health_regenstable;
2217         mina = autocvar_g_balance_armor_regenstable;
2218         minf = autocvar_g_balance_fuel_regenstable;
2219         limith = autocvar_g_balance_health_limit;
2220         limita = autocvar_g_balance_armor_limit;
2221         limitf = autocvar_g_balance_fuel_limit;
2222
2223         max_mod = regen_mod = rot_mod = limit_mod = 1;
2224
2225         if (self.runes & RUNE_REGEN)
2226         {
2227                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2228                 {
2229                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2230                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2231                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2232                 }
2233                 else
2234                 {
2235                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2236                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2237                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2238                 }
2239         }
2240         else if (self.runes & CURSE_VENOM)
2241         {
2242                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2243                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2244                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2245                 else
2246                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2247                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2248                 //if (!self.runes & RUNE_REGEN)
2249                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2250         }
2251         maxh = maxh * max_mod;
2252         //maxa = maxa * max_mod;
2253         //maxf = maxf * max_mod;
2254         minh = minh * max_mod;
2255         //mina = mina * max_mod;
2256         //minf = minf * max_mod;
2257         limith = limith * limit_mod;
2258         limita = limita * limit_mod;
2259         //limitf = limitf * limit_mod;
2260
2261         if(g_lms && g_ca)
2262                 rot_mod = 0;
2263
2264         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2265         {
2266                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2267                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2268
2269                 // if player rotted to death...  die!
2270                 if(self.health < 1)
2271                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2272         }
2273
2274         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2275                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2276 }
2277
2278 float zoomstate_set;
2279 void SetZoomState(float z)
2280 {
2281         if(z != self.zoomstate)
2282         {
2283                 self.zoomstate = z;
2284                 ClientData_Touch(self);
2285         }
2286         zoomstate_set = 1;
2287 }
2288
2289 void GetPressedKeys(void) {
2290         MUTATOR_CALLHOOK(GetPressedKeys);
2291         if (self.movement_x > 0) // get if movement keys are pressed
2292         {       // forward key pressed
2293                 self.pressedkeys |= KEY_FORWARD;
2294                 self.pressedkeys &~= KEY_BACKWARD;
2295         }
2296         else if (self.movement_x < 0)
2297         {       // backward key pressed
2298                 self.pressedkeys |= KEY_BACKWARD;
2299                 self.pressedkeys &~= KEY_FORWARD;
2300         }
2301         else
2302         {       // no x input
2303                 self.pressedkeys &~= KEY_FORWARD;
2304                 self.pressedkeys &~= KEY_BACKWARD;
2305         }
2306
2307         if (self.movement_y > 0)
2308         {       // right key pressed
2309                 self.pressedkeys |= KEY_RIGHT;
2310                 self.pressedkeys &~= KEY_LEFT;
2311         }
2312         else if (self.movement_y < 0)
2313         {       // left key pressed
2314                 self.pressedkeys |= KEY_LEFT;
2315                 self.pressedkeys &~= KEY_RIGHT;
2316         }
2317         else
2318         {       // no y input
2319                 self.pressedkeys &~= KEY_RIGHT;
2320                 self.pressedkeys &~= KEY_LEFT;
2321         }
2322
2323         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2324                 self.pressedkeys |= KEY_JUMP;
2325         else
2326                 self.pressedkeys &~= KEY_JUMP;
2327         if (self.BUTTON_CROUCH)
2328                 self.pressedkeys |= KEY_CROUCH;
2329         else
2330                 self.pressedkeys &~= KEY_CROUCH;
2331 }
2332
2333 /*
2334 ======================
2335 spectate mode routines
2336 ======================
2337 */
2338
2339 void SpectateCopy(entity spectatee) {
2340         other = spectatee;
2341         MUTATOR_CALLHOOK(SpectateCopy);
2342         self.armortype = spectatee.armortype;
2343         self.armorvalue = spectatee.armorvalue;
2344         self.ammo_cells = spectatee.ammo_cells;
2345         self.ammo_shells = spectatee.ammo_shells;
2346         self.ammo_nails = spectatee.ammo_nails;
2347         self.ammo_rockets = spectatee.ammo_rockets;
2348         self.ammo_fuel = spectatee.ammo_fuel;
2349         self.clip_load = spectatee.clip_load;
2350         self.clip_size = spectatee.clip_size;
2351         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2352         self.health = spectatee.health;
2353         self.impulse = 0;
2354         self.items = spectatee.items;
2355         self.last_pickup = spectatee.last_pickup;
2356         self.hit_time = spectatee.hit_time;
2357         self.metertime = spectatee.metertime;
2358         self.strength_finished = spectatee.strength_finished;
2359         self.invincible_finished = spectatee.invincible_finished;
2360         self.pressedkeys = spectatee.pressedkeys;
2361         self.weapons = spectatee.weapons;
2362         self.switchweapon = spectatee.switchweapon;
2363         self.weapon = spectatee.weapon;
2364         self.nex_charge = spectatee.nex_charge;
2365         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2366         self.hagar_load = spectatee.hagar_load;
2367         self.minelayer_mines = spectatee.minelayer_mines;
2368         self.punchangle = spectatee.punchangle;
2369         self.view_ofs = spectatee.view_ofs;
2370         self.v_angle = spectatee.v_angle;
2371         self.velocity = spectatee.velocity;
2372         self.dmg_take = spectatee.dmg_take;
2373         self.dmg_save = spectatee.dmg_save;
2374         self.dmg_inflictor = spectatee.dmg_inflictor;
2375         self.angles = spectatee.v_angle;
2376         self.fixangle = TRUE;
2377         setorigin(self, spectatee.origin);
2378         setsize(self, spectatee.mins, spectatee.maxs);
2379         SetZoomState(spectatee.zoomstate);
2380
2381         anticheat_spectatecopy(spectatee);
2382
2383         //self.vehicle = spectatee.vehicle;
2384
2385         self.hud = spectatee.hud;
2386         if(spectatee.vehicle)
2387     {
2388         setorigin(self, spectatee.origin);
2389         self.velocity = spectatee.vehicle.velocity;
2390         self.v_angle += spectatee.vehicle.angles;
2391         //self.v_angle_x *= -1;
2392         self.vehicle_health = spectatee.vehicle_health;
2393         self.vehicle_shield = spectatee.vehicle_shield;
2394         self.vehicle_energy = spectatee.vehicle_energy;
2395         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2396         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2397         self.vehicle_reload1 = spectatee.vehicle_reload1;
2398         self.vehicle_reload2 = spectatee.vehicle_reload2;
2399
2400         msg_entity = self;
2401         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2402         WriteEntity(MSG_ONE, spectatee);
2403         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2404     }
2405 }
2406
2407 float SpectateUpdate() {
2408         if(!self.enemy)
2409             return 0;
2410
2411         if (self == self.enemy)
2412                 return 0;
2413
2414         if(self.enemy.classname != "player")
2415                 return 0;
2416
2417         SpectateCopy(self.enemy);
2418
2419         return 1;
2420 }
2421
2422 float SpectateNext() {
2423         other = find(self.enemy, classname, "player");
2424
2425         if (!other)
2426                 other = find(other, classname, "player");
2427
2428         if (other)
2429                 self.enemy = other;
2430
2431         if(self.enemy.classname == "player") {
2432             if(self.enemy.vehicle)
2433             {
2434             msg_entity = self;
2435             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2436             WriteEntity(MSG_ONE, self.enemy);
2437             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2438             self.movetype = MOVETYPE_NONE;
2439             accuracy_resend(self);
2440             }
2441             else
2442             {
2443             msg_entity = self;
2444             WriteByte(MSG_ONE, SVC_SETVIEW);
2445             WriteEntity(MSG_ONE, self.enemy);
2446             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2447             self.movetype = MOVETYPE_NONE;
2448             accuracy_resend(self);
2449
2450             if(!SpectateUpdate())
2451                 PutObserverInServer();
2452         }
2453         return 1;
2454         } else {
2455                 return 0;
2456         }
2457 }
2458
2459 /*
2460 =============
2461 ShowRespawnCountdown()
2462
2463 Update a respawn countdown display.
2464 =============
2465 */
2466 void ShowRespawnCountdown()
2467 {
2468         float number;
2469         if(self.deadflag == DEAD_NO) // just respawned?
2470                 return;
2471         else
2472         {
2473                 number = ceil(self.death_time - time);
2474                 if(number <= 0)
2475                         return;
2476                 if(number <= self.respawn_countdown)
2477                 {
2478                         self.respawn_countdown = number - 1;
2479                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2480                                 AnnounceTo(self, strcat(ftos(number), ""));
2481                 }
2482         }
2483 }
2484
2485 void LeaveSpectatorMode()
2486 {
2487         if(nJoinAllowed(1)) {
2488                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2489                         self.classname = "player";
2490
2491                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2492                                 JoinBestTeam(self, FALSE, TRUE);
2493
2494                         if(autocvar_g_campaign)
2495                                 campaign_bots_may_start = 1;
2496
2497                         PutClientInServer();
2498
2499                         if(self.classname == "player")
2500                                 bprint ("^4", self.netname, "^4 is playing now\n");
2501
2502                         if(!autocvar_g_campaign)
2503                                 centerprint(self,""); // clear MOTD
2504
2505                         return;
2506                 } else {
2507                         if (g_ca && self.caplayer) {
2508                         }       // do nothing
2509                         else
2510                                 stuffcmd(self,"menu_showteamselect\n");
2511                         return;
2512                 }
2513         }
2514         else {
2515                 //player may not join because of g_maxplayers is set
2516                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2517         }
2518 }
2519
2520 /**
2521  * Determines whether the player is allowed to join. This depends on cvar
2522  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2523  * it checks whether the number of currently playing players exceeds g_maxplayers.
2524  * @return int number of free slots for players, 0 if none
2525  */
2526 float nJoinAllowed(float includeMe) {
2527         if(self.team_forced < 0)
2528                 return FALSE; // forced spectators can never join
2529
2530         // TODO simplify this
2531         local entity e;
2532
2533         local float totalClients;
2534         FOR_EACH_CLIENT(e)
2535                 totalClients += 1;
2536
2537         if (!autocvar_g_maxplayers)
2538                 return maxclients - totalClients + includeMe;
2539
2540         local float currentlyPlaying;
2541         FOR_EACH_REALPLAYER(e)
2542                 currentlyPlaying += 1;
2543
2544         if(currentlyPlaying < autocvar_g_maxplayers)
2545                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2546
2547         return 0;
2548 }
2549
2550 /**
2551  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2552  * g_maxplayers_spectator_blocktime seconds
2553  */
2554 void checkSpectatorBlock() {
2555         if(self.classname == "spectator" || self.classname == "observer") {
2556                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2557                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2558                         dropclient(self);
2559                 }
2560         }
2561 }
2562
2563 void ObserverThink()
2564 {
2565         if (self.flags & FL_JUMPRELEASED) {
2566                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2567                         self.welcomemessage_time = 0;
2568                         self.flags &~= FL_JUMPRELEASED;
2569                         self.flags |= FL_SPAWNING;
2570                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2571                         self.welcomemessage_time = 0;
2572                         self.flags &~= FL_JUMPRELEASED;
2573                         if(SpectateNext() == 1) {
2574                                 self.classname = "spectator";
2575                         }
2576                 }
2577         } else {
2578                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2579                         self.flags |= FL_JUMPRELEASED;
2580                         if(self.flags & FL_SPAWNING)
2581                         {
2582                                 self.flags &~= FL_SPAWNING;
2583                                 LeaveSpectatorMode();
2584                                 return;
2585                         }
2586                 }
2587         }
2588         PrintWelcomeMessage(self);
2589 }
2590
2591 void SpectatorThink()
2592 {
2593         if (self.flags & FL_JUMPRELEASED) {
2594                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2595                         self.welcomemessage_time = 0;
2596                         self.flags &~= FL_JUMPRELEASED;
2597                         self.flags |= FL_SPAWNING;
2598                 } else if(self.BUTTON_ATCK) {
2599                         self.welcomemessage_time = 0;
2600                         self.flags &~= FL_JUMPRELEASED;
2601                         if(SpectateNext() == 1) {
2602                                 self.classname = "spectator";
2603                         } else {
2604                                 self.classname = "observer";
2605                                 PutClientInServer();
2606                         }
2607                 } else if (self.BUTTON_ATCK2) {
2608                         self.welcomemessage_time = 0;
2609                         self.flags &~= FL_JUMPRELEASED;
2610                         self.classname = "observer";
2611                         PutClientInServer();
2612                 } else {
2613                         if(!SpectateUpdate())
2614                                 PutObserverInServer();
2615                 }
2616         } else {
2617                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2618                         self.flags |= FL_JUMPRELEASED;
2619                         if(self.flags & FL_SPAWNING)
2620                         {
2621                                 self.flags &~= FL_SPAWNING;
2622                                 LeaveSpectatorMode();
2623                                 return;
2624                         }
2625                 }
2626                 if(!SpectateUpdate())
2627                         PutObserverInServer();
2628         }
2629
2630         PrintWelcomeMessage(self);
2631         self.flags |= FL_CLIENT | FL_NOTARGET;
2632 }
2633
2634 float ctf_usekey();
2635 void PlayerUseKey()
2636 {
2637         if(self.classname != "player")
2638                 return;
2639
2640         if(self.vehicle)
2641         {
2642         vehicles_exit(VHEF_NORMAL);
2643         return;
2644         }
2645
2646         // a use key was pressed; call handlers
2647         if(ctf_usekey())
2648                 return;
2649
2650         MUTATOR_CALLHOOK(PlayerUseKey);
2651 }
2652
2653 .float touchexplode_time;
2654
2655 /*
2656 =============
2657 PlayerPreThink
2658
2659 Called every frame for each client before the physics are run
2660 =============
2661 */
2662 .float usekeypressed;
2663 void() ctf_setstatus;
2664 void() nexball_setstatus;
2665 .float items_added;
2666 void PlayerPreThink (void)
2667 {
2668         WarpZone_PlayerPhysics_FixVAngle();
2669
2670         self.stat_game_starttime = game_starttime;
2671         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2672         self.stat_leadlimit = autocvar_leadlimit;
2673
2674         if(frametime)
2675         {
2676                 // physics frames: update anticheat stuff
2677                 anticheat_prethink();
2678         }
2679
2680         if(blockSpectators && frametime)
2681                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2682                 checkSpectatorBlock();
2683
2684         zoomstate_set = 0;
2685
2686         if(self.netname_previous != self.netname)
2687         {
2688                 if(autocvar_sv_eventlog)
2689                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2690                 if(self.netname_previous)
2691                         strunzone(self.netname_previous);
2692                 self.netname_previous = strzone(self.netname);
2693         }
2694
2695         // version nagging
2696         if(self.version_nagtime)
2697                 if(self.cvar_g_xonoticversion)
2698                         if(time > self.version_nagtime)
2699                         {
2700                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2701                                 {
2702                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2703                                         {
2704                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2705                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2706                                         }
2707                                         else
2708                                         {
2709                                                 float r;
2710                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2711                                                 if(r < 0)
2712                                                 {
2713                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2714                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2715                                                 }
2716                                                 else if(r > 0)
2717                                                 {
2718                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2719                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2720                                                 }
2721                                         }
2722                                 }
2723                                 self.version_nagtime = 0;
2724                         }
2725
2726         // GOD MODE info
2727         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2728         {
2729                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2730                 self.max_armorvalue = 0;
2731         }
2732
2733 #ifdef TETRIS
2734         if (TetrisPreFrame())
2735                 return;
2736 #endif
2737
2738         MUTATOR_CALLHOOK(PlayerPreThink);
2739
2740         if(self.BUTTON_USE && !self.usekeypressed)
2741                 PlayerUseKey();
2742         self.usekeypressed = self.BUTTON_USE;
2743
2744         if(self.classname == "player") {
2745 //              if(self.netname == "Wazat")
2746 //                      bprint(self.classname, "\n");
2747
2748                 CheckRules_Player();
2749
2750                 PrintWelcomeMessage(self);
2751
2752                 if (intermission_running)
2753                 {
2754                         IntermissionThink ();   // otherwise a button could be missed between
2755                         return;                                 // the think tics
2756                 }
2757
2758                 //don't allow the player to turn around while game is paused!
2759                 if(timeoutStatus == 2) {
2760                         // FIXME turn this into CSQC stuff
2761                         self.v_angle = self.lastV_angle;
2762                         self.angles = self.lastV_angle;
2763                         self.fixangle = TRUE;
2764                 }
2765
2766                 if(frametime)
2767                 {
2768                         if(self.health <= 0 && autocvar_g_deathglow)
2769                         {
2770                                 if(self.glowmod_x > 0)
2771                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2772                                 else
2773                                         self.glowmod_x = -1;
2774                                 if(self.glowmod_y > 0)
2775                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2776                                 else
2777                                         self.glowmod_y = -1;
2778                                 if(self.glowmod_z > 0)
2779                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2780                                 else
2781                                         self.glowmod_z = -1;
2782                         }
2783                         else
2784                         {
2785                                 // set weapon and player glowmod
2786                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2787
2788                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2789                                 {
2790                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2791                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2792                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2793
2794                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2795                                         {
2796                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2797                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2798                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2799                                         }
2800                                 }
2801                                 else
2802                                         self.weaponentity_glowmod = self.glowmod;
2803                         }
2804                         player_powerups();
2805                 }
2806
2807                 if (self.deadflag != DEAD_NO)
2808                 {
2809                         float button_pressed, force_respawn;
2810                         if(self.personal && g_race_qualifying)
2811                         {
2812                                 if(time > self.death_time)
2813                                 {
2814                                         self.death_time = time + 1; // only retry once a second
2815                                         respawn();
2816                                         self.impulse = 141;
2817                                 }
2818                         }
2819                         else
2820                         {
2821                                 if(frametime)
2822                                         player_anim();
2823                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2824                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2825                                 if (self.deadflag == DEAD_DYING)
2826                                 {
2827                                         if(force_respawn)
2828                                                 self.deadflag = DEAD_RESPAWNING;
2829                                         else if(!button_pressed)
2830                                                 self.deadflag = DEAD_DEAD;
2831                                 }
2832                                 else if (self.deadflag == DEAD_DEAD)
2833                                 {
2834                                         if(button_pressed)
2835                                                 self.deadflag = DEAD_RESPAWNABLE;
2836                                 }
2837                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2838                                 {
2839                                         if(!button_pressed)
2840                                                 self.deadflag = DEAD_RESPAWNING;
2841                                 }
2842                                 else if (self.deadflag == DEAD_RESPAWNING)
2843                                 {
2844                                         if(time > self.death_time)
2845                                         {
2846                                                 self.death_time = time + 1; // only retry once a second
2847                                                 respawn();
2848                                         }
2849                                 }
2850                                 ShowRespawnCountdown();
2851                         }
2852                         return;
2853                 }
2854
2855                 if(g_touchexplode)
2856                 if(time > self.touchexplode_time)
2857                 if(self.classname == "player")
2858                 if(self.deadflag == DEAD_NO)
2859                 if not(IS_INDEPENDENT_PLAYER(self))
2860                 FOR_EACH_PLAYER(other) if(self != other)
2861                 {
2862                         if(time > other.touchexplode_time)
2863                         if(other.deadflag == DEAD_NO)
2864                         if not(IS_INDEPENDENT_PLAYER(other))
2865                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2866                         {
2867                                 PlayerTouchExplode(self, other);
2868                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2869                         }
2870                 }
2871
2872                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2873                 {
2874                         vector dist;
2875
2876                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2877                         dist = self.prevorigin - self.origin;
2878                         dist_z = 0;
2879                         self.lms_traveled_distance += fabs(vlen(dist));
2880
2881                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2882                         {
2883                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2884                                 self.lms_traveled_distance = 0;
2885                         }
2886
2887                         if(time > self.lms_nextcheck)
2888                         {
2889                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2890                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2891                                 {
2892                                         centerprint(self, autocvar_g_lms_campcheck_message);
2893                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2894                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2895                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2896                                 }
2897                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2898                                 self.lms_traveled_distance = 0;
2899                         }
2900                 }
2901
2902                 self.prevorigin = self.origin;
2903
2904                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2905                 {
2906                         if (!self.crouch)
2907                         {
2908                                 self.crouch = TRUE;
2909                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2910                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2911                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2912                         }
2913                 }
2914                 else
2915                 {
2916                         if (self.crouch)
2917                         {
2918                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2919                                 if (!trace_startsolid)
2920                                 {
2921                                         self.crouch = FALSE;
2922                                         self.view_ofs = PL_VIEW_OFS;
2923                                         setsize (self, PL_MIN, PL_MAX);
2924                                 }
2925                         }
2926                 }
2927
2928                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2929                 {
2930                         if(self.bloodloss_timer < time)
2931                         {
2932                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2933                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2934                         }
2935                 }
2936
2937                 FixPlayermodel();
2938
2939                 GrapplingHookFrame();
2940
2941                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2942                 //if(frametime)
2943                 {
2944                         self.items &~= self.items_added;
2945
2946                         W_WeaponFrame();
2947
2948                         self.items_added = 0;
2949                         if(self.items & IT_JETPACK)
2950                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2951                                         self.items_added |= IT_FUEL;
2952
2953                         self.items |= self.items_added;
2954                 }
2955
2956                 player_regen();
2957
2958                 // rot nex charge to the charge limit
2959                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2960                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2961
2962                 if(frametime)
2963                         player_anim();
2964
2965                 if (g_minstagib)
2966                         minstagib_ammocheck();
2967
2968                 if(g_ctf)
2969                         ctf_setstatus();
2970
2971                 if(g_nexball)
2972                         nexball_setstatus();
2973
2974                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2975
2976                 //self.angles_y=self.v_angle_y + 90;   // temp
2977         } else if(gameover) {
2978                 if (intermission_running)
2979                         IntermissionThink ();   // otherwise a button could be missed between
2980                 return;
2981         } else if(self.classname == "observer") {
2982                 ObserverThink();
2983         } else if(self.classname == "spectator") {
2984                 SpectatorThink();
2985         }
2986
2987         if(!zoomstate_set)
2988                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2989
2990         float oldspectatee_status;
2991         oldspectatee_status = self.spectatee_status;
2992         if(self.classname == "spectator")
2993                 self.spectatee_status = num_for_edict(self.enemy);
2994         else if(self.classname == "observer")
2995                 self.spectatee_status = num_for_edict(self);
2996         else
2997                 self.spectatee_status = 0;
2998         if(self.spectatee_status != oldspectatee_status)
2999         {
3000                 ClientData_Touch(self);
3001                 if(g_race || g_cts)
3002                         race_InitSpectator();
3003         }
3004
3005         if(self.teamkill_soundtime)
3006         if(time > self.teamkill_soundtime)
3007         {
3008                 self.teamkill_soundtime = 0;
3009
3010                 entity oldpusher, oldself;
3011
3012                 oldself = self; self = self.teamkill_soundsource;
3013                 oldpusher = self.pusher; self.pusher = oldself;
3014
3015                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3016
3017                 self.pusher = oldpusher;
3018                 self = oldself;
3019         }
3020
3021         if(self.taunt_soundtime)
3022         if(time > self.taunt_soundtime)
3023         {
3024                 self.taunt_soundtime = 0;
3025                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
3026         }
3027
3028         target_voicescript_next(self);
3029
3030         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3031         if(!self.weapon)
3032                 self.clip_load = self.clip_size = 0;
3033 }
3034
3035 float isInvisibleString(string s)
3036 {
3037         float i, n, c;
3038         s = strdecolorize(s);
3039         for((i = 0), (n = strlen(s)); i < n; ++i)
3040         {
3041                 c = str2chr(s, i);
3042                 switch(c)
3043                 {
3044                         case 0:
3045                         case 32: // space
3046                                 break;
3047                         case 192: // charmap space
3048                                 if (!autocvar_utf8_enable)
3049                                         break;
3050                                 return FALSE;
3051                         case 160: // space in unicode fonts
3052                         case 0xE000 + 192: // utf8 charmap space
3053                                 if (autocvar_utf8_enable)
3054                                         break;
3055                         default:
3056                                 return FALSE;
3057                 }
3058         }
3059         return TRUE;
3060 }
3061
3062 /*
3063 =============
3064 PlayerPostThink
3065
3066 Called every frame for each client after the physics are run
3067 =============
3068 */
3069 .float idlekick_lasttimeleft;
3070 .entity showheadshotbbox;
3071 void showheadshotbbox_think()
3072 {
3073         if(self.owner.showheadshotbbox != self)
3074         {
3075                 remove(self);
3076                 return;
3077         }
3078         self.nextthink = time;
3079         setorigin(self, self.owner.origin);
3080         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3081 }
3082 void PlayerPostThink (void)
3083 {
3084         // Savage: Check for nameless players
3085         if (isInvisibleString(self.netname)) {
3086                 self.netname = "Player";
3087                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3088         }
3089
3090         if(sv_maxidle && frametime)
3091         {
3092                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3093                 float timeleft;
3094                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3095                 if(timeleft <= 0)
3096                 {
3097                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3098                         AnnounceTo(self, "terminated");
3099                         dropclient(self);
3100                         return;
3101                 }
3102                 else if(timeleft <= 10)
3103                 {
3104                         if(timeleft != self.idlekick_lasttimeleft)
3105                         {
3106                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3107                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3108                         }
3109                 }
3110                 else
3111                 {
3112                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3113                 }
3114                 self.idlekick_lasttimeleft = timeleft;
3115         }
3116
3117 #ifdef TETRIS
3118         if(self.impulse == 100)
3119                 ImpulseCommands();
3120         if (TetrisPostFrame())
3121                 return;
3122 #endif
3123
3124         CheatFrame();
3125
3126         if(self.classname == "player") {
3127                 CheckRules_Player();
3128                 UpdateChatBubble();
3129                 if (self.impulse)
3130                         ImpulseCommands();
3131                 if (intermission_running)
3132                         return;         // intermission or finale
3133                 GetPressedKeys();
3134         } else if (self.classname == "observer") {
3135                 //do nothing
3136         } else if (self.classname == "spectator") {
3137                 //do nothing
3138         }
3139
3140         /*
3141         float i;
3142         for(i = 0; i < 1000; ++i)
3143         {
3144                 vector end;
3145                 end = self.origin + '0 0 1024' + 512 * randomvec();
3146                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3147                 if(trace_fraction < 1)
3148                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3149                 {
3150                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3151                         break;
3152                 }
3153         }
3154         */
3155
3156         Arena_Warmup();
3157
3158         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3159
3160         if(self.waypointsprite_attachedforcarrier)
3161                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3162
3163         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3164         {
3165                 if(!self.showheadshotbbox)
3166                 {
3167                         self.showheadshotbbox = spawn();
3168                         self.showheadshotbbox.classname = "headshotbbox";
3169                         self.showheadshotbbox.owner = self;
3170                         self.showheadshotbbox.think = showheadshotbbox_think;
3171                         self.showheadshotbbox.nextthink = time;
3172                         self = self.showheadshotbbox;
3173                         self.think();
3174                         self = self.owner;
3175                 }
3176         }
3177         else
3178         {
3179                 if(self.showheadshotbbox)
3180                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3181                 remove(self.showheadshotbbox);
3182         }
3183
3184         playerdemo_write();
3185
3186         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3187         {
3188                 if(!self.stored_netname)
3189                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3190                 if(self.stored_netname != self.netname)
3191                 {
3192                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3193                         strunzone(self.stored_netname);
3194                         self.stored_netname = strzone(self.netname);
3195                 }
3196         }
3197
3198         /*
3199         if(g_race)
3200                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3201         */
3202 }