qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         if (g_minstagib)
 408                 minstagib_stop_countdown();
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419             vehicles_exit(VHEF_RELESE);
 420
 421         if(self.flagcarried)
 422                 DropFlag(self.flagcarried, world, world);
 423
 424         if(self.ballcarried && g_nexball)
 425                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 426
 427         WaypointSprite_PlayerDead();
 428
 429         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 430                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 431
 432         if(self.killcount != -666) {
 433                 if(g_lms) {
 434                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 435                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 436                         else
 437                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 438                 } else
 439                         bprint ("^4", self.netname, "^4 is spectating now\n");
 440
 441                 if(self.just_joined == FALSE) {
 442                         LogTeamchange(self.playerid, -1, 4);
 443                 } else
 444                         self.just_joined = FALSE;
 445         }
 446
 447         PlayerScore_Clear(self); // clear scores when needed
 448
 449         accuracy_resend(self);
 450
 451         self.spectatortime = time;
 452
 453         self.classname = "observer";
 454         self.iscreature = FALSE;
 455         self.damagedbycontents = FALSE;
 456         self.health = -666;
 457         self.takedamage = DAMAGE_NO;
 458         self.solid = SOLID_NOT;
 459         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 460         self.flags = FL_CLIENT | FL_NOTARGET;
 461         self.armorvalue = 666;
 462         self.effects = 0;
 463         self.armorvalue = autocvar_g_balance_armor_start;
 464         self.pauserotarmor_finished = 0;
 465         self.pauserothealth_finished = 0;
 466         self.pauseregen_finished = 0;
 467         self.damageforcescale = 0;
 468         self.death_time = 0;
 469         self.respawn_time = 0;
 470         self.alpha = 0;
 471         self.scale = 0;
 472         self.fade_time = 0;
 473         self.pain_frame = 0;
 474         self.pain_finished = 0;
 475         self.strength_finished = 0;
 476         self.invincible_finished = 0;
 477         self.pushltime = 0;
 478         self.think = SUB_Null;
 479         self.nextthink = 0;
 480         self.hook_time = 0;
 481         self.runes = 0;
 482         self.deadflag = DEAD_NO;
 483         self.angles = spot.angles;
 484         self.angles_z = 0;
 485         self.fixangle = TRUE;
 486         self.crouch = FALSE;
 487
 488         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 489         self.prevorigin = self.origin;
 490         self.items = 0;
 491         self.weapons = 0;
 492         self.model = "";
 493         FixPlayermodel();
 494         setmodel(self, "null");
 495         self.drawonlytoclient = self;
 496
 497         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 498         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 499
 500         self.weapon = 0;
 501         self.weaponname = "";
 502         self.switchingweapon = 0;
 503         self.weaponmodel = "";
 504         self.weaponentity = world;
 505         self.exteriorweaponentity = world;
 506         self.killcount = -666;
 507         self.velocity = '0 0 0';
 508         self.avelocity = '0 0 0';
 509         self.punchangle = '0 0 0';
 510         self.punchvector = '0 0 0';
 511         self.oldvelocity = self.velocity;
 512         self.fire_endtime = -1;
 513
 514         if(g_arena)
 515         {
 516                 if(self.version_mismatch)
 517                 {
 518                         Spawnqueue_Unmark(self);
 519                         Spawnqueue_Remove(self);
 520                 }
 521                 else
 522                 {
 523                         Spawnqueue_Insert(self);
 524                 }
 525         }
 526         else if(g_lms)
 527         {
 528                 // Only if the player cannot play at all
 529                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 530                         self.frags = FRAGS_SPECTATOR;
 531                 else
 532                         self.frags = FRAGS_LMS_LOSER;
 533         }
 534         else if(g_ca)
 535         {
 536                 if(self.caplayer)
 537                         self.frags = FRAGS_LMS_LOSER;
 538                 else
 539                         self.frags = FRAGS_SPECTATOR;
 540         }
 541         else
 542                 self.frags = FRAGS_SPECTATOR;
 543 }
 544
 545 .float model_randomizer;
 546 void FixPlayermodel()
 547 {
 548         string defaultmodel;
 549         float defaultskin, chmdl, oldskin, n, i;
 550         vector m1, m2;
 551
 552         defaultmodel = "";
 553
 554         if(autocvar_sv_defaultcharacter == 1)
 555         {
 556                 defaultskin = 0;
 557
 558                 if(teamplay)
 559                 {
 560                         string s;
 561                         s = Team_ColorNameLowerCase(self.team);
 562                         if(s != "neutral")
 563                         {
 564                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 565                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 566                         }
 567                 }
 568
 569                 if(defaultmodel == "")
 570                 {
 571                         defaultmodel = autocvar_sv_defaultplayermodel;
 572                         defaultskin = autocvar_sv_defaultplayerskin;
 573                 }
 574
 575                 n = tokenize_console(defaultmodel);
 576                 if(n > 0)
 577                         defaultmodel = argv(floor(n * self.model_randomizer));
 578
 579                 i = strstrofs(defaultmodel, ":", 0);
 580                 if(i >= 0)
 581                 {
 582                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 583                         defaultmodel = substring(defaultmodel, 0, i);
 584                 }
 585         }
 586
 587         if(defaultmodel != "")
 588         {
 589                 if (defaultmodel != self.model)
 590                 {
 591                         m1 = self.mins;
 592                         m2 = self.maxs;
 593                         setplayermodel (self, defaultmodel);
 594                         setsize (self, m1, m2);
 595                         chmdl = TRUE;
 596                 }
 597
 598                 oldskin = self.skin;
 599                 self.skin = defaultskin;
 600         } else {
 601                 if (self.playermodel != self.model || self.playermodel == "")
 602                 {
 603                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 604                         m1 = self.mins;
 605                         m2 = self.maxs;
 606                         setplayermodel (self, self.playermodel);
 607                         setsize (self, m1, m2);
 608                         chmdl = TRUE;
 609                 }
 610
 611                 oldskin = self.skin;
 612                 self.skin = stof(self.playerskin);
 613         }
 614
 615         if(chmdl || oldskin != self.skin)
 616                 self.species = player_getspecies(); // model or skin has changed
 617
 618         if(!teamplay)
 619                 if(strlen(autocvar_sv_defaultplayercolors))
 620                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 621                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 622 }
 623
 624 void PlayerTouchExplode(entity p1, entity p2)
 625 {
 626         vector org;
 627         org = (p1.origin + p2.origin) * 0.5;
 628         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 629
 630         te_explosion(org);
 631
 632         entity e;
 633         e = spawn();
 634         setorigin(e, org);
 635         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 636         remove(e);
 637 }
 638
 639 /*
 640 =============
 641 PutClientInServer
 642
 643 Called when a client spawns in the server
 644 =============
 645 */
 646 //void() ctf_playerchanged;
 647 void PutClientInServer (void)
 648 {
 649         if(clienttype(self) == CLIENTTYPE_BOT)
 650         {
 651                 self.classname = "player";
 652         }
 653         else if(clienttype(self) == CLIENTTYPE_REAL)
 654         {
 655                 msg_entity = self;
 656                 WriteByte(MSG_ONE, SVC_SETVIEW);
 657                 WriteEntity(MSG_ONE, self);
 658         }
 659
 660         // reset player keys
 661         self.itemkeys = 0;
 662
 663         // player is dead and becomes observer
 664         // FIXME fix LMS scoring for new system
 665         if(g_lms)
 666         {
 667                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 668                         self.classname = "observer";
 669         }
 670
 671         if(g_arena || (g_ca && !allowed_to_spawn))
 672         if(!self.spawned)
 673                 self.classname = "observer";
 674
 675         if(gameover)
 676                 self.classname = "observer";
 677
 678         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 679                 entity spot, oldself;
 680                 float j;
 681
 682                 accuracy_resend(self);
 683
 684                 if(self.team < 0)
 685                         JoinBestTeam(self, FALSE, TRUE);
 686
 687                 race_PreSpawn();
 688
 689                 spot = SelectSpawnPoint (FALSE);
 690                 if(!spot)
 691                 {
 692                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 693                         return; // spawn failed
 694                 }
 695
 696                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 697
 698                 self.classname = "player";
 699                 self.wasplayer = TRUE;
 700                 self.iscreature = TRUE;
 701                 self.damagedbycontents = TRUE;
 702                 self.movetype = MOVETYPE_WALK;
 703                 self.solid = SOLID_SLIDEBOX;
 704                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 705                 if(autocvar_g_playerclip_collisions)
 706                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 707                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 708                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 709                 self.frags = FRAGS_PLAYER;
 710                 if(INDEPENDENT_PLAYERS)
 711                         MAKE_INDEPENDENT_PLAYER(self);
 712                 self.flags = FL_CLIENT;
 713                 if(autocvar__notarget)
 714                         self.flags |= FL_NOTARGET;
 715                 self.takedamage = DAMAGE_AIM;
 716                 if(g_minstagib)
 717                         self.effects = EF_FULLBRIGHT;
 718                 else
 719                         self.effects = 0;
 720                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 721                 self.air_finished = time + 12;
 722                 self.dmg = 2;
 723                 if(autocvar_g_balance_nex_charge)
 724                 {
 725                         if(autocvar_g_balance_nex_secondary_chargepool)
 726                                 self.nex_chargepool_ammo = 1;
 727                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 728                 }
 729
 730                 if(inWarmupStage)
 731                 {
 732                         self.ammo_shells = warmup_start_ammo_shells;
 733                         self.ammo_nails = warmup_start_ammo_nails;
 734                         self.ammo_rockets = warmup_start_ammo_rockets;
 735                         self.ammo_cells = warmup_start_ammo_cells;
 736                         self.ammo_fuel = warmup_start_ammo_fuel;
 737                         self.health = warmup_start_health;
 738                         self.armorvalue = warmup_start_armorvalue;
 739                         self.weapons = warmup_start_weapons;
 740                 }
 741                 else
 742                 {
 743                         self.ammo_shells = start_ammo_shells;
 744                         self.ammo_nails = start_ammo_nails;
 745                         self.ammo_rockets = start_ammo_rockets;
 746                         self.ammo_cells = start_ammo_cells;
 747                         self.ammo_fuel = start_ammo_fuel;
 748                         self.health = start_health;
 749                         self.armorvalue = start_armorvalue;
 750                         self.weapons = start_weapons;
 751                 }
 752
 753                 if(g_weaponarena_random)
 754                 {
 755                         if(g_weaponarena_random_with_laser)
 756                                 self.weapons &~= WEPBIT_LASER;
 757                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 758                         if(g_weaponarena_random_with_laser)
 759                                 self.weapons |= WEPBIT_LASER;
 760                 }
 761
 762                 self.items = start_items;
 763
 764                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 765                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 766                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 767                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 768                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 769                 //extend the pause of rotting if client was reset at the beginning of the countdown
 770                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 771                         self.spawnshieldtime += game_starttime - time;
 772                         self.pauserotarmor_finished += game_starttime - time;
 773                         self.pauserothealth_finished += game_starttime - time;
 774                         self.pauseregen_finished += game_starttime - time;
 775                 }
 776                 self.damageforcescale = 2;
 777                 self.death_time = 0;
 778                 self.respawn_time = 0;
 779                 self.scale = 0;
 780                 self.fade_time = 0;
 781                 self.pain_frame = 0;
 782                 self.pain_finished = 0;
 783                 self.strength_finished = 0;
 784                 self.invincible_finished = 0;
 785                 self.pushltime = 0;
 786                 // players have no think function
 787                 self.think = SUB_Null;
 788                 self.nextthink = 0;
 789                 self.hook_time = 0;
 790                 self.dmg_team = 0;
 791                 self.ballistics_density = autocvar_g_ballistics_density_player;
 792
 793                 self.metertime = 0;
 794
 795                 self.runes = 0;
 796
 797                 self.deadflag = DEAD_NO;
 798
 799                 self.angles = spot.angles;
 800
 801                 self.angles_z = 0; // never spawn tilted even if the spot says to
 802                 self.fixangle = TRUE; // turn this way immediately
 803                 self.velocity = '0 0 0';
 804                 self.avelocity = '0 0 0';
 805                 self.punchangle = '0 0 0';
 806                 self.punchvector = '0 0 0';
 807                 self.oldvelocity = self.velocity;
 808                 self.fire_endtime = -1;
 809
 810                 msg_entity = self;
 811                 WRITESPECTATABLE_MSG_ONE({
 812                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 813                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 814                 });
 815
 816                 self.model = "";
 817                 FixPlayermodel();
 818                 self.drawonlytoclient = world;
 819
 820                 self.crouch = FALSE;
 821                 self.view_ofs = PL_VIEW_OFS;
 822                 setsize (self, PL_MIN, PL_MAX);
 823                 self.spawnorigin = spot.origin;
 824                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 825                 // don't reset back to last position, even if new position is stuck in solid
 826                 self.oldorigin = self.origin;
 827                 self.prevorigin = self.origin;
 828                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 829                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 830         self.hud = HUD_NORMAL;
 831
 832                 if(g_arena)
 833                 {
 834                         Spawnqueue_Remove(self);
 835                         Spawnqueue_Mark(self);
 836                 }
 837
 838                 else if(g_ca)
 839                         self.caplayer = 1;
 840
 841                 self.event_damage = PlayerDamage;
 842
 843                 self.bot_attack = TRUE;
 844
 845                 self.statdraintime = time + 5;
 846                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 847
 848                 if(self.killcount == -666) {
 849                         PlayerScore_Clear(self);
 850                         self.killcount = 0;
 851                 }
 852
 853                 CL_SpawnWeaponentity();
 854                 self.alpha = default_player_alpha;
 855                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 856                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 857
 858                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 859                 self.lms_traveled_distance = 0;
 860                 self.speedrunning = FALSE;
 861
 862                 race_PostSpawn(spot);
 863
 864                 //stuffcmd(self, "chase_active 0");
 865                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 866
 867                 if (autocvar_g_spawnsound)
 868                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 869
 870                 if(g_assault) {
 871                         if(self.team == assault_attacker_team)
 872                                 centerprint(self, "You are attacking!");
 873                         else
 874                                 centerprint(self, "You are defending!");
 875                 }
 876
 877                 target_voicescript_clear(self);
 878
 879                 // reset fields the weapons may use
 880                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 881                 {
 882                         weapon_action(j, WR_RESETPLAYER);
 883
 884                         // all weapons must be fully loaded when we spawn
 885                         entity e;
 886                         e = get_weaponinfo(j);
 887                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 888                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 889                 }
 890
 891                 oldself = self;
 892                 self = spot;
 893                         activator = oldself;
 894                                 string s;
 895                                 s = self.target;
 896                                 self.target = string_null;
 897                                 SUB_UseTargets();
 898                                 self.target = s;
 899                         activator = world;
 900                 self = oldself;
 901
 902                 spawn_spot = spot;
 903                 MUTATOR_CALLHOOK(PlayerSpawn);
 904
 905                 if(autocvar_spawn_debug)
 906                 {
 907                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 908                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 909                 }
 910
 911                 self.switchweapon = w_getbestweapon(self);
 912                 self.cnt = -1; // W_LastWeapon will not complain
 913                 self.weapon = 0;
 914                 self.weaponname = "";
 915                 self.switchingweapon = 0;
 916
 917                 if(!self.alivetime)
 918                         self.alivetime = time;
 919
 920                 antilag_clear(self);
 921         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
 922                 PutObserverInServer ();
 923         }
 924
 925         //if(g_ctf)
 926         //      ctf_playerchanged();
 927 }
 928
 929 .float ebouncefactor, ebouncestop; // electro's values
 930 // TODO do we need all these fields, or should we stop autodetecting runtime
 931 // changes and just have a console command to update this?
 932 float ClientInit_SendEntity(entity to, float sf)
 933 {
 934         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 935         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 936         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 948         if(sv_foginterval && world.fog != "")
 949                 WriteString(MSG_ENTITY, world.fog);
 950         else
 951                 WriteString(MSG_ENTITY, "");
 952         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 953         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 954         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 955         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 956         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 957         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 958         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 959         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 960         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 961         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 962         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 963         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 964         return TRUE;
 965 }
 966
 967 void ClientInit_CheckUpdate()
 968 {
 969         self.nextthink = time;
 970         if(self.count != autocvar_g_balance_armor_blockpercent)
 971         {
 972                 self.count = autocvar_g_balance_armor_blockpercent;
 973                 self.SendFlags |= 1;
 974         }
 975         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 976         {
 977                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 978                 self.SendFlags |= 1;
 979         }
 980         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 981         {
 982                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 983                 self.SendFlags |= 1;
 984         }
 985         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 986         {
 987                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 988                 self.SendFlags |= 1;
 989         }
 990         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 991         {
 992                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 993                 self.SendFlags |= 1;
 994         }
 995         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 996         {
 997                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 998                 self.SendFlags |= 1;
 999         }
1000 }
1001
1002 void ClientInit_Spawn()
1003 {
1004         entity o;
1005         entity e;
1006         e = spawn();
1007         e.classname = "clientinit";
1008         e.think = ClientInit_CheckUpdate;
1009         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1010
1011         o = self;
1012         self = e;
1013         ClientInit_CheckUpdate();
1014         self = o;
1015 }
1016
1017 /*
1018 =============
1019 SetNewParms
1020 =============
1021 */
1022 void SetNewParms (void)
1023 {
1024         // initialize parms for a new player
1025         parm1 = -(86400 * 366);
1026 }
1027
1028 /*
1029 =============
1030 SetChangeParms
1031 =============
1032 */
1033 void SetChangeParms (void)
1034 {
1035         // save parms for level change
1036         parm1 = self.parm_idlesince - time;
1037 }
1038
1039 /*
1040 =============
1041 DecodeLevelParms
1042 =============
1043 */
1044 void DecodeLevelParms (void)
1045 {
1046         // load parms
1047         self.parm_idlesince = parm1;
1048         if(self.parm_idlesince == -(86400 * 366))
1049                 self.parm_idlesince = time;
1050
1051         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1052         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1053 }
1054
1055 /*
1056 =============
1057 ClientKill
1058
1059 Called when a client types 'kill' in the console
1060 =============
1061 */
1062
1063 .float clientkill_nexttime;
1064 void ClientKill_Now_TeamChange()
1065 {
1066         if(self.killindicator_teamchange == -1)
1067         {
1068                 self.team = -1;
1069                 JoinBestTeam( self, FALSE, FALSE );
1070         }
1071         else if(self.killindicator_teamchange == -2)
1072         {
1073                 if(g_ca)
1074                         self.caplayer = 0;
1075                 if(blockSpectators)
1076                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1077                 PutObserverInServer();
1078         }
1079         else
1080                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1081 }
1082
1083 void ClientKill_Now()
1084 {
1085         if(self.vehicle)
1086         {
1087             vehicles_exit(VHEF_RELESE);
1088             if(!self.killindicator_teamchange)
1089             {
1090             self.vehicle_health = -1;
1091             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1092             }
1093         }
1094
1095         if(self.killindicator && !wasfreed(self.killindicator))
1096                 remove(self.killindicator);
1097
1098         self.killindicator = world;
1099
1100         if(self.killindicator_teamchange)
1101                 ClientKill_Now_TeamChange();
1102
1103         // in any case:
1104         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1105
1106         // now I am sure the player IS dead
1107 }
1108 void KillIndicator_Think()
1109 {
1110         if (gameover)
1111         {
1112                 self.owner.killindicator = world;
1113                 remove(self);
1114                 return;
1115         }
1116
1117         if (self.owner.alpha < 0)
1118         {
1119                 self.owner.killindicator = world;
1120                 remove(self);
1121                 return;
1122         }
1123
1124         if(self.cnt <= 0)
1125         {
1126                 self = self.owner;
1127                 ClientKill_Now(); // no oldself needed
1128                 return;
1129         }
1130     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1131     {
1132         self.nextthink = time + 1;
1133         self.cnt -= 1;
1134     }
1135         else
1136         {
1137                 if(self.cnt <= 10)
1138                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1139                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1140                 {
1141                         if(self.cnt <= 10)
1142                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1143                 }
1144                 self.nextthink = time + 1;
1145                 self.cnt -= 1;
1146         }
1147 }
1148
1149 float clientkilltime;
1150 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1151 {
1152         float killtime;
1153         float starttime;
1154         entity e;
1155
1156         if (gameover)
1157                 return;
1158
1159         killtime = autocvar_g_balance_kill_delay;
1160
1161         if(g_race_qualifying || g_cts)
1162                 killtime = 0;
1163
1164     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1165     {
1166                 remove(self.killindicator);
1167                 self.killindicator = world;
1168
1169         ClientKill_Now(); // allow instant kill in this case
1170         return;
1171     }
1172
1173         self.killindicator_teamchange = targetteam;
1174
1175     if(!self.killindicator)
1176         {
1177                 if(self.deadflag == DEAD_NO)
1178                 {
1179                         killtime = max(killtime, self.clientkill_nexttime - time);
1180                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1181                 }
1182
1183                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1184                 {
1185                         ClientKill_Now();
1186                 }
1187                 else
1188                 {
1189                         starttime = max(time, clientkilltime);
1190
1191                         self.killindicator = spawn();
1192                         self.killindicator.owner = self;
1193                         self.killindicator.scale = 0.5;
1194                         setattachment(self.killindicator, self, "");
1195                         setorigin(self.killindicator, '0 0 52');
1196                         self.killindicator.think = KillIndicator_Think;
1197                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1198                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1199                         self.killindicator.cnt = ceil(killtime);
1200                         self.killindicator.count = bound(0, ceil(killtime), 10);
1201                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1202
1203                         for(e = world; (e = find(e, classname, "body")) != world; )
1204                         {
1205                                 if(e.enemy != self)
1206                                         continue;
1207                                 e.killindicator = spawn();
1208                                 e.killindicator.owner = e;
1209                                 e.killindicator.scale = 0.5;
1210                                 setattachment(e.killindicator, e, "");
1211                                 setorigin(e.killindicator, '0 0 52');
1212                                 e.killindicator.think = KillIndicator_Think;
1213                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1214                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1215                                 e.killindicator.cnt = ceil(killtime);
1216                         }
1217                         self.lip = 0;
1218                 }
1219         }
1220         if(self.killindicator)
1221         {
1222                 if(targetteam == 0) // just die
1223                 {
1224                         self.killindicator.colormod = '0 0 0';
1225                         if(clienttype(self) == CLIENTTYPE_REAL)
1226                         if(self.killindicator.cnt > 0)
1227                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1228                 }
1229                 else if(targetteam == -1) // auto
1230                 {
1231                         self.killindicator.colormod = '0 1 0';
1232                         if(clienttype(self) == CLIENTTYPE_REAL)
1233                         if(self.killindicator.cnt > 0)
1234                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1235                 }
1236                 else if(targetteam == -2) // spectate
1237                 {
1238                         self.killindicator.colormod = '0.5 0.5 0.5';
1239                         if(clienttype(self) == CLIENTTYPE_REAL)
1240                         if(self.killindicator.cnt > 0)
1241                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1242                 }
1243                 else
1244                 {
1245                         self.killindicator.colormod = TeamColor(targetteam);
1246                         if(clienttype(self) == CLIENTTYPE_REAL)
1247                         if(self.killindicator.cnt > 0)
1248                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1249                 }
1250         }
1251
1252 }
1253
1254 void ClientKill (void)
1255 {
1256         if (gameover)
1257                 return;
1258
1259         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1260         {
1261                 // do nothing
1262         }
1263     else if(self.freezetag_frozen)
1264     {
1265         // do nothing
1266     }
1267         else
1268                 ClientKill_TeamChange(0);
1269 }
1270
1271 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1272 {
1273     e.killindicator = spawn();
1274     e.killindicator.owner = e;
1275     e.killindicator.think = KillIndicator_Think;
1276     e.killindicator.nextthink = time + (e.lip) * 0.05;
1277     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1278     e.killindicator.health = 1; // this is used to indicate that it should be silent
1279     e.lip = 0;
1280 }
1281
1282 void FixClientCvars(entity e)
1283 {
1284         // send prediction settings to the client
1285         stuffcmd(e, "\nin_bindmap 0 0\n");
1286         if(g_race || g_cts)
1287                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1288         if(autocvar_g_antilag == 3) // client side hitscan
1289                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1290         if(sv_gentle)
1291                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1292         /*
1293          * we no longer need to stuff this. Remove this comment block if you feel
1294          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1295         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1296         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1297         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1298         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1299         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1300         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1301         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1302         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1303         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1304         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1305         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1306         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1307         stuffcmd(e, "cl_movement_edgefriction 1\n");
1308          */
1309 }
1310
1311 float PlayerInIDList(entity p, string idlist)
1312 {
1313         float n, i;
1314         string s;
1315
1316         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1317         if not(p.crypto_idfp)
1318                 return 0;
1319
1320         // this function allows abbreviated player IDs too!
1321         n = tokenize_console(idlist);
1322         for(i = 0; i < n; ++i)
1323         {
1324                 s = argv(i);
1325                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1326                         return 1;
1327         }
1328
1329         return 0;
1330 }
1331
1332 /*
1333 =============
1334 ClientConnect
1335
1336 Called when a client connects to the server
1337 =============
1338 */
1339 //void ctf_clientconnect();
1340 string ColoredTeamName(float t);
1341 void DecodeLevelParms (void);
1342 //void dom_player_join_team(entity pl);
1343 void set_dom_state(entity e);
1344 void ClientConnect (void)
1345 {
1346         float t;
1347
1348         if(self.flags & FL_CLIENT)
1349         {
1350                 print("Warning: ClientConnect, but already connected!\n");
1351                 return;
1352         }
1353
1354         if(Ban_MaybeEnforceBan(self))
1355                 return;
1356
1357         DecodeLevelParms();
1358
1359 #ifdef WATERMARK
1360         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1361 #endif
1362
1363         self.classname = "player_joining";
1364
1365         self.flags = FL_CLIENT;
1366         self.version_nagtime = time + 10 + random() * 10;
1367
1368         if(player_count<0)
1369         {
1370                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1371                 player_count = 0;
1372         }
1373
1374         PlayerScore_Attach(self);
1375         ClientData_Attach();
1376         accuracy_init(self);
1377
1378         bot_clientconnect();
1379
1380         playerdemo_init();
1381
1382         anticheat_init();
1383
1384         race_PreSpawnObserver();
1385
1386         //if(g_domination)
1387         //      dom_player_join_team(self);
1388
1389         // identify the right forced team
1390         if(autocvar_g_campaign)
1391         {
1392                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1393                 {
1394                         switch(autocvar_g_campaign_forceteam)
1395                         {
1396                                 case 1: self.team_forced = COLOR_TEAM1; break;
1397                                 case 2: self.team_forced = COLOR_TEAM2; break;
1398                                 case 3: self.team_forced = COLOR_TEAM3; break;
1399                                 case 4: self.team_forced = COLOR_TEAM4; break;
1400                                 default: self.team_forced = 0;
1401                         }
1402                 }
1403         }
1404         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1405                 self.team_forced = COLOR_TEAM1;
1406         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1407                 self.team_forced = COLOR_TEAM2;
1408         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1409                 self.team_forced = COLOR_TEAM3;
1410         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1411                 self.team_forced = COLOR_TEAM4;
1412         else if(autocvar_g_forced_team_otherwise == "red")
1413                 self.team_forced = COLOR_TEAM1;
1414         else if(autocvar_g_forced_team_otherwise == "blue")
1415                 self.team_forced = COLOR_TEAM2;
1416         else if(autocvar_g_forced_team_otherwise == "yellow")
1417                 self.team_forced = COLOR_TEAM3;
1418         else if(autocvar_g_forced_team_otherwise == "pink")
1419                 self.team_forced = COLOR_TEAM4;
1420         else if(autocvar_g_forced_team_otherwise == "spectate")
1421                 self.team_forced = -1;
1422         else if(autocvar_g_forced_team_otherwise == "spectator")
1423                 self.team_forced = -1;
1424         else
1425                 self.team_forced = 0;
1426
1427         if(!teamplay)
1428                 if(self.team_forced > 0)
1429                         self.team_forced = 0;
1430
1431         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1432
1433         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1434                 self.classname = "observer";
1435         } else {
1436                 if(teamplay)
1437                 {
1438                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1439                         {
1440                                 self.classname = "player";
1441                                 campaign_bots_may_start = 1;
1442                         }
1443                         else
1444                         {
1445                                 self.classname = "observer"; // do it anyway
1446                         }
1447                 }
1448                 else
1449                 {
1450                         self.classname = "player";
1451                         campaign_bots_may_start = 1;
1452                 }
1453         }
1454
1455         self.playerid = (playerid_last = playerid_last + 1);
1456
1457         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1458
1459     if(clienttype(self) == CLIENTTYPE_BOT)
1460         PlayerStats_AddPlayer(self);
1461
1462         if(autocvar_sv_eventlog)
1463                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1464
1465         LogTeamchange(self.playerid, self.team, 1);
1466
1467         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1468
1469         self.netname_previous = strzone(self.netname);
1470
1471         bprint("^4", self.netname, "^4 connected");
1472
1473         if(self.classname != "observer" && (g_domination || g_ctf))
1474                 bprint(" and joined the ", ColoredTeamName(self.team));
1475
1476         bprint("\n");
1477
1478         stuffcmd(self, strcat(clientstuff, "\n"));
1479         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1480
1481         FixClientCvars(self);
1482
1483         // spawnfunc_waypoint sprites
1484         WaypointSprite_InitClient(self);
1485
1486         // Wazat's grappling hook
1487         SetGrappleHookBindings();
1488
1489         // get version info from player
1490         stuffcmd(self, "cmd clientversion $gameversion\n");
1491
1492         // get other cvars from player
1493         GetCvars(0);
1494
1495         // notify about available teams
1496         if(teamplay)
1497         {
1498                 CheckAllowedTeams(self);
1499                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1500                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1501         }
1502         else
1503                 stuffcmd(self, "set _teams_available 0\n");
1504
1505         if(g_arena || g_ca)
1506         {
1507                 self.classname = "observer";
1508                 if(g_arena)
1509                         Spawnqueue_Insert(self);
1510         }
1511         /*else if(g_ctf)
1512         {
1513                 ctf_clientconnect();
1514         }*/
1515
1516         attach_entcs();
1517
1518         bot_relinkplayerlist();
1519
1520         self.spectatortime = time;
1521         if(blockSpectators)
1522         {
1523                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1524         }
1525
1526         self.jointime = time;
1527         self.allowed_timeouts = autocvar_sv_timeout_number;
1528
1529         if(clienttype(self) == CLIENTTYPE_REAL)
1530         {
1531                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1532                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1533         }
1534
1535         if(g_lms)
1536         {
1537                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1538                 {
1539                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1540                         self.frags = FRAGS_SPECTATOR;
1541                 }
1542         }
1543
1544         if(!sv_foginterval && world.fog != "")
1545                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1546
1547         SoundEntity_Attach(self);
1548
1549         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1550         {
1551                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1552                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1553         }
1554         else
1555                 self.hitplotfh = -1;
1556
1557         if(g_race || g_cts) {
1558                 string rr;
1559                 if(g_cts)
1560                         rr = CTS_RECORD;
1561                 else
1562                         rr = RACE_RECORD;
1563                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1564
1565                 msg_entity = self;
1566                 race_send_recordtime(MSG_ONE);
1567                 race_send_speedaward(MSG_ONE);
1568
1569                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1570                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1571                 race_send_speedaward_alltimebest(MSG_ONE);
1572
1573                 float i;
1574                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1575                         race_SendRankings(i, 0, 0, MSG_ONE);
1576                 }
1577         }
1578         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1579                 send_CSQC_teamnagger();
1580
1581         if (g_domination)
1582                 set_dom_state(self);
1583
1584         CheatInitClient();
1585
1586         if(!autocvar_g_campaign)
1587                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1588
1589         CSQCMODEL_AUTOINIT();
1590
1591         self.model_randomizer = random();
1592 }
1593
1594 /*
1595 =============
1596 ClientDisconnect
1597
1598 Called when a client disconnects from the server
1599 =============
1600 */
1601 .entity chatbubbleentity;
1602 void ReadyCount();
1603 void ClientDisconnect (void)
1604 {
1605         if(self.vehicle)
1606             vehicles_exit(VHEF_RELESE);
1607
1608         if not(self.flags & FL_CLIENT)
1609         {
1610                 print("Warning: ClientDisconnect without ClientConnect\n");
1611                 return;
1612         }
1613
1614         PlayerStats_AddGlobalInfo(self);
1615
1616         CheatShutdownClient();
1617
1618         if(self.hitplotfh >= 0)
1619         {
1620                 fclose(self.hitplotfh);
1621                 self.hitplotfh = -1;
1622         }
1623
1624         anticheat_report();
1625         anticheat_shutdown();
1626
1627         playerdemo_shutdown();
1628
1629         bot_clientdisconnect();
1630
1631         if(self.entcs)
1632                 detach_entcs();
1633
1634         if(autocvar_sv_eventlog)
1635                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1636         bprint ("^4",self.netname);
1637         bprint ("^4 disconnected\n");
1638
1639         SoundEntity_Detach(self);
1640
1641         DropAllRunes(self);
1642         MUTATOR_CALLHOOK(ClientDisconnect);
1643
1644         Portal_ClearAll(self);
1645
1646         RemoveGrapplingHook(self);
1647         if(self.flagcarried)
1648                 DropFlag(self.flagcarried, world, world);
1649         if(self.ballcarried && g_nexball)
1650                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1651
1652         // Here, everything has been done that requires this player to be a client.
1653
1654         self.flags &~= FL_CLIENT;
1655
1656         if (self.chatbubbleentity)
1657                 remove (self.chatbubbleentity);
1658
1659         if (self.killindicator)
1660                 remove (self.killindicator);
1661
1662         WaypointSprite_PlayerGone();
1663
1664         bot_relinkplayerlist();
1665
1666         if(g_arena)
1667         {
1668                 Spawnqueue_Unmark(self);
1669                 Spawnqueue_Remove(self);
1670         }
1671
1672         accuracy_free(self);
1673         ClientData_Detach();
1674         PlayerScore_Detach(self);
1675
1676         if(self.netname_previous)
1677                 strunzone(self.netname_previous);
1678         if(self.clientstatus)
1679                 strunzone(self.clientstatus);
1680         if(self.weaponorder_byimpulse)
1681                 strunzone(self.weaponorder_byimpulse);
1682
1683         ClearPlayerSounds();
1684
1685         if(self.personal)
1686                 remove(self.personal);
1687
1688         self.playerid = 0;
1689         ReadyCount();
1690
1691         // free cvars
1692         GetCvars(-1);
1693 }
1694
1695 .float BUTTON_CHAT;
1696 void ChatBubbleThink()
1697 {
1698         self.nextthink = time;
1699         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1700         {
1701                 if(self.owner) // but why can that ever be world?
1702                         self.owner.chatbubbleentity = world;
1703                 remove(self);
1704                 return;
1705         }
1706         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1707 #ifdef TETRIS
1708                 || self.owner.tetris_on
1709 #endif
1710         )
1711                 self.model = self.mdl;
1712         else
1713                 self.model = "";
1714 }
1715
1716 void UpdateChatBubble()
1717 {
1718         if (self.alpha < 0)
1719                 return;
1720         // spawn a chatbubble entity if needed
1721         if (!self.chatbubbleentity)
1722         {
1723                 self.chatbubbleentity = spawn();
1724                 self.chatbubbleentity.owner = self;
1725                 self.chatbubbleentity.exteriormodeltoclient = self;
1726                 self.chatbubbleentity.think = ChatBubbleThink;
1727                 self.chatbubbleentity.nextthink = time;
1728                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1729                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1730                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1731                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1732                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1733                 self.chatbubbleentity.model = "";
1734                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1735         }
1736 }
1737
1738
1739 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1740 // added to the model skins
1741 /*void UpdateColorModHack()
1742 {
1743         float c;
1744         c = self.clientcolors & 15;
1745         // LordHavoc: only bothering to support white, green, red, yellow, blue
1746              if (!teamplay) self.colormod = '0 0 0';
1747         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1748         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1749         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1750         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1751         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1752         else self.colormod = '1 1 1';
1753 }*/
1754
1755 void respawn(void)
1756 {
1757         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1758         {
1759                 self.solid = SOLID_NOT;
1760                 self.takedamage = DAMAGE_NO;
1761                 self.movetype = MOVETYPE_FLY;
1762                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1763                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1764                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1765                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1766                 if(autocvar_g_respawn_ghosts_maxtime)
1767                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1768         }
1769
1770         CopyBody(1);
1771
1772         self.effects |= EF_NODRAW; // prevent another CopyBody
1773         PutClientInServer();
1774 }
1775
1776 void play_countdown(float finished, string samp)
1777 {
1778         if(clienttype(self) == CLIENTTYPE_REAL)
1779                 if(floor(finished - time - frametime) != floor(finished - time))
1780                         if(finished - time < 6)
1781                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1782 }
1783
1784 void player_powerups (void)
1785 {
1786         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1787         olditems = self.items;
1788
1789         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1790         {
1791                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1792                 self.modelflags |= MF_ROCKET;
1793         }
1794         else
1795         {
1796                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1797                 self.modelflags &~= MF_ROCKET;
1798         }
1799
1800         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1801
1802         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1803                 return;
1804
1805         Fire_ApplyDamage(self);
1806         Fire_ApplyEffect(self);
1807
1808         if (g_minstagib)
1809         {
1810                 self.effects |= EF_FULLBRIGHT;
1811
1812                 if (self.items & IT_STRENGTH)
1813                 {
1814                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1815                         if (time > self.strength_finished)
1816                         {
1817                                 self.alpha = default_player_alpha;
1818                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1819                                 self.items &~= IT_STRENGTH;
1820                                 sprint(self, "^3Invisibility has worn off\n");
1821                         }
1822                 }
1823                 else
1824                 {
1825                         if (time < self.strength_finished)
1826                         {
1827                                 self.alpha = g_minstagib_invis_alpha;
1828                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1829                                 self.items |= IT_STRENGTH;
1830                                 sprint(self, "^3You are invisible\n");
1831                         }
1832                 }
1833
1834                 if (self.items & IT_INVINCIBLE)
1835                 {
1836                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1837                         if (time > self.invincible_finished)
1838                         {
1839                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1840                                 sprint(self, "^3Speed has worn off\n");
1841                         }
1842                 }
1843                 else
1844                 {
1845                         if (time < self.invincible_finished)
1846                         {
1847                                 self.items = self.items | IT_INVINCIBLE;
1848                                 sprint(self, "^3You are on speed\n");
1849                         }
1850                 }
1851         }
1852         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1853         {
1854                 if (self.items & IT_STRENGTH)
1855                 {
1856                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1857                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1858                         if (time > self.strength_finished)
1859                         {
1860                                 self.items = self.items - (self.items & IT_STRENGTH);
1861                                 sprint(self, "^3Strength has worn off\n");
1862                         }
1863                 }
1864                 else
1865                 {
1866                         if (time < self.strength_finished)
1867                         {
1868                                 self.items = self.items | IT_STRENGTH;
1869                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1870                         }
1871                 }
1872                 if (self.items & IT_INVINCIBLE)
1873                 {
1874                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1875                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1876                         if (time > self.invincible_finished)
1877                         {
1878                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1879                                 sprint(self, "^3Shield has worn off\n");
1880                         }
1881                 }
1882                 else
1883                 {
1884                         if (time < self.invincible_finished)
1885                         {
1886                                 self.items = self.items | IT_INVINCIBLE;
1887                                 sprint(self, "^3Shield surrounds you\n");
1888                         }
1889                 }
1890         }
1891
1892         if(autocvar_g_nodepthtestplayers)
1893                 self.effects = self.effects | EF_NODEPTHTEST;
1894
1895         if(autocvar_g_fullbrightplayers)
1896                 self.effects = self.effects | EF_FULLBRIGHT;
1897
1898         // midair gamemode: damage only while in the air
1899         // if in midair mode, being on ground grants temporary invulnerability
1900         // (this is so that multishot weapon don't clear the ground flag on the
1901         // first damage in the frame, leaving the player vulnerable to the
1902         // remaining hits in the same frame)
1903         if (self.flags & FL_ONGROUND)
1904         if (g_midair)
1905                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1906
1907         if (time >= game_starttime)
1908         if (time < self.spawnshieldtime)
1909                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1910
1911         MUTATOR_CALLHOOK(PlayerPowerups);
1912 }
1913
1914 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1915 {
1916         if(current > stable)
1917                 return current;
1918         else if(current > stable - 0.25) // when close enough, "snap"
1919                 return stable;
1920         else
1921                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1922 }
1923
1924 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1925 {
1926         if(current < stable)
1927                 return current;
1928         else if(current < stable + 0.25) // when close enough, "snap"
1929                 return stable;
1930         else
1931                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1932 }
1933
1934 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1935 {
1936         if(current > rotstable)
1937         {
1938                 if(rotframetime > 0)
1939                 {
1940                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1941                         current = max(rotstable, current - rotlinear * rotframetime);
1942                 }
1943         }
1944         else if(current < regenstable)
1945         {
1946                 if(regenframetime > 0)
1947                 {
1948                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1949                         current = min(regenstable, current + regenlinear * regenframetime);
1950                 }
1951         }
1952
1953         if(current > limit)
1954                 current = limit;
1955
1956         return current;
1957 }
1958
1959 void player_regen (void)
1960 {
1961         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1962         maxh = autocvar_g_balance_health_rotstable;
1963         maxa = autocvar_g_balance_armor_rotstable;
1964         maxf = autocvar_g_balance_fuel_rotstable;
1965         minh = autocvar_g_balance_health_regenstable;
1966         mina = autocvar_g_balance_armor_regenstable;
1967         minf = autocvar_g_balance_fuel_regenstable;
1968         limith = autocvar_g_balance_health_limit;
1969         limita = autocvar_g_balance_armor_limit;
1970         limitf = autocvar_g_balance_fuel_limit;
1971
1972         max_mod = regen_mod = rot_mod = limit_mod = 1;
1973
1974         if (self.runes & RUNE_REGEN)
1975         {
1976                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1977                 {
1978                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1979                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1980                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1981                 }
1982                 else
1983                 {
1984                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
1985                         max_mod = autocvar_g_balance_rune_regen_hpmod;
1986                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
1987                 }
1988         }
1989         else if (self.runes & CURSE_VENOM)
1990         {
1991                 max_mod = autocvar_g_balance_curse_venom_hpmod;
1992                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1993                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
1994                 else
1995                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
1996                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
1997                 //if (!self.runes & RUNE_REGEN)
1998                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
1999         }
2000         maxh = maxh * max_mod;
2001         //maxa = maxa * max_mod;
2002         //maxf = maxf * max_mod;
2003         minh = minh * max_mod;
2004         //mina = mina * max_mod;
2005         //minf = minf * max_mod;
2006         limith = limith * limit_mod;
2007         limita = limita * limit_mod;
2008         //limitf = limitf * limit_mod;
2009
2010         if(g_lms && g_ca)
2011                 rot_mod = 0;
2012
2013         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2014         {
2015                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2016                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2017
2018                 // if player rotted to death...  die!
2019                 if(self.health < 1)
2020                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2021         }
2022
2023         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2024                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2025 }
2026
2027 float zoomstate_set;
2028 void SetZoomState(float z)
2029 {
2030         if(z != self.zoomstate)
2031         {
2032                 self.zoomstate = z;
2033                 ClientData_Touch(self);
2034         }
2035         zoomstate_set = 1;
2036 }
2037
2038 void GetPressedKeys(void) {
2039         MUTATOR_CALLHOOK(GetPressedKeys);
2040         if (self.movement_x > 0) // get if movement keys are pressed
2041         {       // forward key pressed
2042                 self.pressedkeys |= KEY_FORWARD;
2043                 self.pressedkeys &~= KEY_BACKWARD;
2044         }
2045         else if (self.movement_x < 0)
2046         {       // backward key pressed
2047                 self.pressedkeys |= KEY_BACKWARD;
2048                 self.pressedkeys &~= KEY_FORWARD;
2049         }
2050         else
2051         {       // no x input
2052                 self.pressedkeys &~= KEY_FORWARD;
2053                 self.pressedkeys &~= KEY_BACKWARD;
2054         }
2055
2056         if (self.movement_y > 0)
2057         {       // right key pressed
2058                 self.pressedkeys |= KEY_RIGHT;
2059                 self.pressedkeys &~= KEY_LEFT;
2060         }
2061         else if (self.movement_y < 0)
2062         {       // left key pressed
2063                 self.pressedkeys |= KEY_LEFT;
2064                 self.pressedkeys &~= KEY_RIGHT;
2065         }
2066         else
2067         {       // no y input
2068                 self.pressedkeys &~= KEY_RIGHT;
2069                 self.pressedkeys &~= KEY_LEFT;
2070         }
2071
2072         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2073                 self.pressedkeys |= KEY_JUMP;
2074         else
2075                 self.pressedkeys &~= KEY_JUMP;
2076         if (self.BUTTON_CROUCH)
2077                 self.pressedkeys |= KEY_CROUCH;
2078         else
2079                 self.pressedkeys &~= KEY_CROUCH;
2080 }
2081
2082 /*
2083 ======================
2084 spectate mode routines
2085 ======================
2086 */
2087
2088 void SpectateCopy(entity spectatee) {
2089         other = spectatee;
2090         MUTATOR_CALLHOOK(SpectateCopy);
2091         self.armortype = spectatee.armortype;
2092         self.armorvalue = spectatee.armorvalue;
2093         self.ammo_cells = spectatee.ammo_cells;
2094         self.ammo_shells = spectatee.ammo_shells;
2095         self.ammo_nails = spectatee.ammo_nails;
2096         self.ammo_rockets = spectatee.ammo_rockets;
2097         self.ammo_fuel = spectatee.ammo_fuel;
2098         self.clip_load = spectatee.clip_load;
2099         self.clip_size = spectatee.clip_size;
2100         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2101         self.health = spectatee.health;
2102         self.impulse = 0;
2103         self.items = spectatee.items;
2104         self.last_pickup = spectatee.last_pickup;
2105         self.hit_time = spectatee.hit_time;
2106         self.metertime = spectatee.metertime;
2107         self.strength_finished = spectatee.strength_finished;
2108         self.invincible_finished = spectatee.invincible_finished;
2109         self.pressedkeys = spectatee.pressedkeys;
2110         self.weapons = spectatee.weapons;
2111         self.switchweapon = spectatee.switchweapon;
2112         self.switchingweapon = spectatee.switchingweapon;
2113         self.weapon = spectatee.weapon;
2114         self.nex_charge = spectatee.nex_charge;
2115         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2116         self.hagar_load = spectatee.hagar_load;
2117         self.minelayer_mines = spectatee.minelayer_mines;
2118         self.punchangle = spectatee.punchangle;
2119         self.view_ofs = spectatee.view_ofs;
2120         self.v_angle = spectatee.v_angle;
2121         self.velocity = spectatee.velocity;
2122         self.dmg_take = spectatee.dmg_take;
2123         self.dmg_save = spectatee.dmg_save;
2124         self.dmg_inflictor = spectatee.dmg_inflictor;
2125         self.angles = spectatee.v_angle;
2126         if(!self.BUTTON_USE)
2127                 self.fixangle = TRUE;
2128         setorigin(self, spectatee.origin);
2129         setsize(self, spectatee.mins, spectatee.maxs);
2130         SetZoomState(spectatee.zoomstate);
2131
2132         anticheat_spectatecopy(spectatee);
2133
2134         //self.vehicle = spectatee.vehicle;
2135
2136         self.hud = spectatee.hud;
2137         if(spectatee.vehicle)
2138     {
2139         setorigin(self, spectatee.origin);
2140         self.velocity = spectatee.vehicle.velocity;
2141         self.v_angle += spectatee.vehicle.angles;
2142         //self.v_angle_x *= -1;
2143         self.vehicle_health = spectatee.vehicle_health;
2144         self.vehicle_shield = spectatee.vehicle_shield;
2145         self.vehicle_energy = spectatee.vehicle_energy;
2146         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2147         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2148         self.vehicle_reload1 = spectatee.vehicle_reload1;
2149         self.vehicle_reload2 = spectatee.vehicle_reload2;
2150
2151         msg_entity = self;
2152         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2153         WriteEntity(MSG_ONE, spectatee);
2154         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2155     }
2156 }
2157
2158 float SpectateUpdate() {
2159         if(!self.enemy)
2160             return 0;
2161
2162         if (self == self.enemy)
2163                 return 0;
2164
2165         if(self.enemy.classname != "player")
2166                 return 0;
2167
2168         SpectateCopy(self.enemy);
2169
2170         return 1;
2171 }
2172
2173
2174 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2175 entity CA_SpectateNext(entity start) {
2176         if (start.team == self.team) {
2177                 return start;
2178         }
2179
2180         other = start;
2181         // continue from current player
2182         while(other && other.team != self.team) {
2183                 other = find(other, classname, "player");
2184         }
2185
2186         if (!other) {
2187                 // restart from begining
2188                 other = find(other, classname, "player");
2189                 while(other && other.team != self.team) {
2190                         other = find(other, classname, "player");
2191                 }
2192         }
2193
2194         return other;
2195 }
2196
2197 float SpectateNext() {
2198         other = find(self.enemy, classname, "player");
2199         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2200                 // CA and ca players when spectating enemies is forbidden
2201                 other = CA_SpectateNext(other);
2202         } else {
2203                 // other modes and ca spectators or spectating enemies is allowed
2204                 if (!other)
2205                         other = find(other, classname, "player");
2206         }
2207
2208         if (other)
2209                 self.enemy = other;
2210
2211         if(self.enemy.classname == "player") {
2212             if(self.enemy.vehicle)
2213             {
2214             msg_entity = self;
2215             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2216             WriteEntity(MSG_ONE, self.enemy);
2217             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2218             self.movetype = MOVETYPE_NONE;
2219             accuracy_resend(self);
2220             }
2221             else
2222             {
2223             msg_entity = self;
2224             WriteByte(MSG_ONE, SVC_SETVIEW);
2225             WriteEntity(MSG_ONE, self.enemy);
2226             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2227             self.movetype = MOVETYPE_NONE;
2228             accuracy_resend(self);
2229
2230             if(!SpectateUpdate())
2231                 PutObserverInServer();
2232         }
2233         return 1;
2234         } else {
2235                 return 0;
2236         }
2237 }
2238
2239 /*
2240 =============
2241 ShowRespawnCountdown()
2242
2243 Update a respawn countdown display.
2244 =============
2245 */
2246 void ShowRespawnCountdown()
2247 {
2248         float number;
2249         if(self.deadflag == DEAD_NO) // just respawned?
2250                 return;
2251         else
2252         {
2253                 number = ceil(self.respawn_time - time);
2254                 if(number <= 0)
2255                         return;
2256                 if(number <= self.respawn_countdown)
2257                 {
2258                         self.respawn_countdown = number - 1;
2259                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2260                                 AnnounceTo(self, strcat(ftos(number), ""));
2261                 }
2262         }
2263 }
2264
2265 .float prevent_join_msgtime;
2266 void LeaveSpectatorMode()
2267 {
2268         if(nJoinAllowed(1)) {
2269                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2270                         self.classname = "player";
2271
2272                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2273                                 JoinBestTeam(self, FALSE, TRUE);
2274
2275                         if(autocvar_g_campaign)
2276                                 campaign_bots_may_start = 1;
2277
2278                         PutClientInServer();
2279
2280                         if(self.classname == "player")
2281                                 bprint ("^4", self.netname, "^4 is playing now\n");
2282
2283                         if(!autocvar_g_campaign)
2284                         if (time < self.jointime + autocvar_welcome_message_time)
2285                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2286
2287                         if (self.prevent_join_msgtime)
2288                         {
2289                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2290                                 self.prevent_join_msgtime = 0;
2291                         }
2292
2293                         return;
2294                 } else {
2295                         if (g_ca && self.caplayer) {
2296                         }       // do nothing
2297                         else
2298                                 stuffcmd(self,"menu_showteamselect\n");
2299                         return;
2300                 }
2301         }
2302         else {
2303                 //player may not join because of g_maxplayers is set
2304                 if (time - self.prevent_join_msgtime > 2)
2305                 {
2306                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2307                         self.prevent_join_msgtime = time;
2308                 }
2309         }
2310 }
2311
2312 /**
2313  * Determines whether the player is allowed to join. This depends on cvar
2314  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2315  * it checks whether the number of currently playing players exceeds g_maxplayers.
2316  * @return int number of free slots for players, 0 if none
2317  */
2318 float nJoinAllowed(float includeMe) {
2319         if(self.team_forced < 0)
2320                 return FALSE; // forced spectators can never join
2321
2322         // TODO simplify this
2323         entity e;
2324
2325         float totalClients;
2326         FOR_EACH_CLIENT(e)
2327                 totalClients += 1;
2328
2329         if (!autocvar_g_maxplayers)
2330                 return maxclients - totalClients + includeMe;
2331
2332         float currentlyPlaying;
2333         FOR_EACH_REALPLAYER(e)
2334                 currentlyPlaying += 1;
2335
2336         if(currentlyPlaying < autocvar_g_maxplayers)
2337                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2338
2339         return 0;
2340 }
2341
2342 /**
2343  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2344  * g_maxplayers_spectator_blocktime seconds
2345  */
2346 void checkSpectatorBlock() {
2347         if(self.classname == "spectator" || self.classname == "observer") {
2348                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2349                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2350                         dropclient(self);
2351                 }
2352         }
2353 }
2354
2355 .float motd_actived_time; // used for both motd and campaign_message
2356 void PrintWelcomeMessage()
2357 {
2358         if (self.motd_actived_time == 0) { // is there already a message showing?
2359                 if (autocvar_g_campaign) {
2360                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2361                                 self.motd_actived_time = time;
2362                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2363                         }
2364                 } else {
2365                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2366                                 self.motd_actived_time = time;
2367                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2368                         }
2369                 }
2370         } else { // showing MOTD or campaign message
2371                 if (autocvar_g_campaign) {
2372                         if (self.BUTTON_INFO)
2373                                 self.motd_actived_time = time;
2374                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2375                                 self.motd_actived_time = 0;
2376                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2377                         }
2378                 } else {
2379                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2380                                 if (self.BUTTON_INFO)
2381                                         self.motd_actived_time = time;
2382                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2383                                         self.motd_actived_time = 0;
2384                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2385                                 }
2386                         }
2387                 }
2388         }
2389 }
2390
2391 void ObserverThink()
2392 {
2393         float prefered_movetype;
2394         if (self.flags & FL_JUMPRELEASED) {
2395                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2396                         self.flags &~= FL_JUMPRELEASED;
2397                         self.flags |= FL_SPAWNING;
2398                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2399                         self.flags &~= FL_JUMPRELEASED;
2400                         if(SpectateNext() == 1) {
2401                                 self.classname = "spectator";
2402                         }
2403                 } else {
2404                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2405                         if (self.movetype != prefered_movetype)
2406                                 self.movetype = prefered_movetype;
2407                 }
2408         } else {
2409                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2410                         self.flags |= FL_JUMPRELEASED;
2411                         if(self.flags & FL_SPAWNING)
2412                         {
2413                                 self.flags &~= FL_SPAWNING;
2414                                 LeaveSpectatorMode();
2415                                 return;
2416                         }
2417                 }
2418         }
2419
2420         PrintWelcomeMessage();
2421 }
2422
2423 void SpectatorThink()
2424 {
2425         if (self.flags & FL_JUMPRELEASED) {
2426                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2427                         self.flags &~= FL_JUMPRELEASED;
2428                         self.flags |= FL_SPAWNING;
2429                 } else if(self.BUTTON_ATCK) {
2430                         self.flags &~= FL_JUMPRELEASED;
2431                         if(SpectateNext() == 1) {
2432                                 self.classname = "spectator";
2433                         } else {
2434                                 self.classname = "observer";
2435                                 PutClientInServer();
2436                         }
2437                 } else if (self.BUTTON_ATCK2) {
2438                         self.flags &~= FL_JUMPRELEASED;
2439                         self.classname = "observer";
2440                         PutClientInServer();
2441                 } else {
2442                         if(!SpectateUpdate())
2443                                 PutObserverInServer();
2444                 }
2445         } else {
2446                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2447                         self.flags |= FL_JUMPRELEASED;
2448                         if(self.flags & FL_SPAWNING)
2449                         {
2450                                 self.flags &~= FL_SPAWNING;
2451                                 LeaveSpectatorMode();
2452                                 return;
2453                         }
2454                 }
2455                 if(!SpectateUpdate())
2456                         PutObserverInServer();
2457         }
2458
2459         PrintWelcomeMessage();
2460         self.flags |= FL_CLIENT | FL_NOTARGET;
2461 }
2462
2463 float ctf_usekey();
2464 void PlayerUseKey()
2465 {
2466         if(self.classname != "player")
2467                 return;
2468
2469         if(self.vehicle)
2470         {
2471         vehicles_exit(VHEF_NORMAL);
2472         return;
2473         }
2474
2475         // a use key was pressed; call handlers
2476         if(ctf_usekey())
2477                 return;
2478
2479         MUTATOR_CALLHOOK(PlayerUseKey);
2480 }
2481
2482 .float touchexplode_time;
2483
2484 /*
2485 =============
2486 PlayerPreThink
2487
2488 Called every frame for each client before the physics are run
2489 =============
2490 */
2491 .float usekeypressed;
2492 void() ctf_setstatus;
2493 void() nexball_setstatus;
2494 .float items_added;
2495 void PlayerPreThink (void)
2496 {
2497         WarpZone_PlayerPhysics_FixVAngle();
2498
2499         self.stat_game_starttime = game_starttime;
2500         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2501         self.stat_leadlimit = autocvar_leadlimit;
2502
2503         if(frametime)
2504         {
2505                 // physics frames: update anticheat stuff
2506                 anticheat_prethink();
2507         }
2508
2509         if(blockSpectators && frametime)
2510                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2511                 checkSpectatorBlock();
2512
2513         zoomstate_set = 0;
2514
2515         if(self.netname_previous != self.netname)
2516         {
2517                 if(autocvar_sv_eventlog)
2518                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2519                 if(self.netname_previous)
2520                         strunzone(self.netname_previous);
2521                 self.netname_previous = strzone(self.netname);
2522         }
2523
2524         // version nagging
2525         if(self.version_nagtime)
2526                 if(self.cvar_g_xonoticversion)
2527                         if(time > self.version_nagtime)
2528                         {
2529                                 // don't notify git users
2530                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2531                                 {
2532                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2533                                         {
2534                                                 // notify release users if connecting to git
2535                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2536                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2537                                         }
2538                                         else
2539                                         {
2540                                                 float r;
2541                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2542                                                 if(r < 0)
2543                                                 {
2544                                                         // give users new version
2545                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2546                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2547                                                 }
2548                                                 else if(r > 0)
2549                                                 {
2550                                                         // notify users about old server version
2551                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2552                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2553                                                 }
2554                                         }
2555                                 }
2556                                 self.version_nagtime = 0;
2557                         }
2558
2559         // GOD MODE info
2560         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2561         {
2562                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2563                 self.max_armorvalue = 0;
2564         }
2565
2566 #ifdef TETRIS
2567         if (TetrisPreFrame())
2568                 return;
2569 #endif
2570
2571         MUTATOR_CALLHOOK(PlayerPreThink);
2572
2573         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2574         {
2575                 if(self.BUTTON_USE && !self.usekeypressed)
2576                         PlayerUseKey();
2577                 self.usekeypressed = self.BUTTON_USE;
2578         }
2579
2580         PrintWelcomeMessage();
2581
2582         if(self.classname == "player") {
2583 //              if(self.netname == "Wazat")
2584 //                      bprint(self.classname, "\n");
2585
2586                 CheckRules_Player();
2587
2588                 if (intermission_running)
2589                 {
2590                         IntermissionThink ();   // otherwise a button could be missed between
2591                         return;                                 // the think tics
2592                 }
2593
2594                 //don't allow the player to turn around while game is paused!
2595                 if(timeout_status == TIMEOUT_ACTIVE) {
2596                         // FIXME turn this into CSQC stuff
2597                         self.v_angle = self.lastV_angle;
2598                         self.angles = self.lastV_angle;
2599                         self.fixangle = TRUE;
2600                 }
2601
2602                 if(frametime)
2603                 {
2604 #ifndef NO_LEGACY_NETWORKING
2605                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2606 #endif
2607
2608                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2609                         {
2610                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2611                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2612                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2613
2614                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2615                                 {
2616                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2617                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2618                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2619                                 }
2620                         }
2621                         else
2622                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2623
2624                         player_powerups();
2625                 }
2626
2627                 if (g_minstagib)
2628                         minstagib_ammocheck();
2629
2630                 if (self.deadflag != DEAD_NO)
2631                 {
2632                         float button_pressed, force_respawn;
2633                         if(self.personal && g_race_qualifying)
2634                         {
2635                                 if(time > self.respawn_time)
2636                                 {
2637                                         self.respawn_time = time + 1; // only retry once a second
2638                                         respawn();
2639                                         self.impulse = 141;
2640                                 }
2641                         }
2642                         else
2643                         {
2644                                 if(frametime)
2645                                         player_anim();
2646                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2647                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2648                                 if (self.deadflag == DEAD_DYING)
2649                                 {
2650                                         if(force_respawn)
2651                                                 self.deadflag = DEAD_RESPAWNING;
2652                                         else if(!button_pressed)
2653                                                 self.deadflag = DEAD_DEAD;
2654                                 }
2655                                 else if (self.deadflag == DEAD_DEAD)
2656                                 {
2657                                         if(button_pressed)
2658                                                 self.deadflag = DEAD_RESPAWNABLE;
2659                                 }
2660                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2661                                 {
2662                                         if(!button_pressed)
2663                                                 self.deadflag = DEAD_RESPAWNING;
2664                                 }
2665                                 else if (self.deadflag == DEAD_RESPAWNING)
2666                                 {
2667                                         if(time > self.respawn_time)
2668                                         {
2669                                                 self.respawn_time = time + 1; // only retry once a second
2670                                                 respawn();
2671                                         }
2672                                 }
2673                                 ShowRespawnCountdown();
2674                         }
2675                         return;
2676                 }
2677                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2678                 // so (self.deadflag == DEAD_NO) is always true in the code below
2679
2680                 if(g_touchexplode)
2681                 if(time > self.touchexplode_time)
2682                 if(self.classname == "player")
2683                 if(self.deadflag == DEAD_NO)
2684                 if not(IS_INDEPENDENT_PLAYER(self))
2685                 FOR_EACH_PLAYER(other) if(self != other)
2686                 {
2687                         if(time > other.touchexplode_time)
2688                         if(other.deadflag == DEAD_NO)
2689                         if not(IS_INDEPENDENT_PLAYER(other))
2690                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2691                         {
2692                                 PlayerTouchExplode(self, other);
2693                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2694                         }
2695                 }
2696
2697                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2698                 {
2699                         vector dist;
2700
2701                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2702                         dist = self.prevorigin - self.origin;
2703                         dist_z = 0;
2704                         self.lms_traveled_distance += fabs(vlen(dist));
2705
2706                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2707                         {
2708                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2709                                 self.lms_traveled_distance = 0;
2710                         }
2711
2712                         if(time > self.lms_nextcheck)
2713                         {
2714                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2715                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2716                                 {
2717                                         centerprint(self, autocvar_g_lms_campcheck_message);
2718                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2719                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2720                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2721                                 }
2722                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2723                                 self.lms_traveled_distance = 0;
2724                         }
2725                 }
2726
2727                 self.prevorigin = self.origin;
2728
2729                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2730                 {
2731                         if (!self.crouch)
2732                         {
2733                                 self.crouch = TRUE;
2734                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2735                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2736                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2737                         }
2738                 }
2739                 else
2740                 {
2741                         if (self.crouch)
2742                         {
2743                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2744                                 if (!trace_startsolid)
2745                                 {
2746                                         self.crouch = FALSE;
2747                                         self.view_ofs = PL_VIEW_OFS;
2748                                         setsize (self, PL_MIN, PL_MAX);
2749                                 }
2750                         }
2751                 }
2752
2753                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2754                 {
2755                         if(self.bloodloss_timer < time)
2756                         {
2757                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2758                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2759                         }
2760                 }
2761
2762                 FixPlayermodel();
2763
2764                 GrapplingHookFrame();
2765
2766                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2767                 //if(frametime)
2768                 {
2769                         self.items &~= self.items_added;
2770
2771                         W_WeaponFrame();
2772
2773                         self.items_added = 0;
2774                         if(self.items & IT_JETPACK)
2775                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2776                                         self.items_added |= IT_FUEL;
2777
2778                         self.items |= self.items_added;
2779                 }
2780
2781                 player_regen();
2782
2783                 // rot nex charge to the charge limit
2784                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2785                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2786
2787                 if(frametime)
2788                         player_anim();
2789
2790                 if(g_ctf)
2791                         ctf_setstatus();
2792
2793                 if(g_nexball)
2794                         nexball_setstatus();
2795
2796                 // secret status
2797                 secrets_setstatus();
2798
2799                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2800
2801                 //self.angles_y=self.v_angle_y + 90;   // temp
2802         } else if(gameover) {
2803                 if (intermission_running)
2804                         IntermissionThink ();   // otherwise a button could be missed between
2805                 return;
2806         } else if(self.classname == "observer") {
2807                 ObserverThink();
2808         } else if(self.classname == "spectator") {
2809                 SpectatorThink();
2810         }
2811
2812         if(!zoomstate_set)
2813                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2814
2815         float oldspectatee_status;
2816         oldspectatee_status = self.spectatee_status;
2817         if(self.classname == "spectator")
2818                 self.spectatee_status = num_for_edict(self.enemy);
2819         else if(self.classname == "observer")
2820                 self.spectatee_status = num_for_edict(self);
2821         else
2822                 self.spectatee_status = 0;
2823         if(self.spectatee_status != oldspectatee_status)
2824         {
2825                 ClientData_Touch(self);
2826                 if(g_race || g_cts)
2827                         race_InitSpectator();
2828         }
2829
2830         if(self.teamkill_soundtime)
2831         if(time > self.teamkill_soundtime)
2832         {
2833                 self.teamkill_soundtime = 0;
2834
2835                 entity oldpusher, oldself;
2836
2837                 oldself = self; self = self.teamkill_soundsource;
2838                 oldpusher = self.pusher; self.pusher = oldself;
2839
2840                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2841
2842                 self.pusher = oldpusher;
2843                 self = oldself;
2844         }
2845
2846         if(self.taunt_soundtime)
2847         if(time > self.taunt_soundtime)
2848         {
2849                 self.taunt_soundtime = 0;
2850                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2851         }
2852
2853         target_voicescript_next(self);
2854
2855         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2856         if(!self.weapon)
2857                 self.clip_load = self.clip_size = 0;
2858 }
2859
2860 float isInvisibleString(string s)
2861 {
2862         float i, n, c;
2863         s = strdecolorize(s);
2864         for((i = 0), (n = strlen(s)); i < n; ++i)
2865         {
2866                 c = str2chr(s, i);
2867                 switch(c)
2868                 {
2869                         case 0:
2870                         case 32: // space
2871                                 break;
2872                         case 192: // charmap space
2873                                 if (!autocvar_utf8_enable)
2874                                         break;
2875                                 return FALSE;
2876                         case 160: // space in unicode fonts
2877                         case 0xE000 + 192: // utf8 charmap space
2878                                 if (autocvar_utf8_enable)
2879                                         break;
2880                         default:
2881                                 return FALSE;
2882                 }
2883         }
2884         return TRUE;
2885 }
2886
2887 /*
2888 =============
2889 PlayerPostThink
2890
2891 Called every frame for each client after the physics are run
2892 =============
2893 */
2894 .float idlekick_lasttimeleft;
2895 .entity showheadshotbbox;
2896 void showheadshotbbox_think()
2897 {
2898         if(self.owner.showheadshotbbox != self)
2899         {
2900                 remove(self);
2901                 return;
2902         }
2903         self.nextthink = time;
2904         setorigin(self, self.owner.origin);
2905         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2906 }
2907 void PlayerPostThink (void)
2908 {
2909         // Savage: Check for nameless players
2910         if (isInvisibleString(self.netname)) {
2911                 self.netname = "Player";
2912                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2913         }
2914
2915         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2916         {
2917                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2918                 {
2919                         if(self.idlekick_lasttimeleft)
2920                         {
2921                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2922                                 self.idlekick_lasttimeleft = 0;
2923                         }
2924                 }
2925                 else
2926                 {
2927                         float timeleft;
2928                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2929                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2930                         {
2931                                 if(!self.idlekick_lasttimeleft)
2932                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2933                         }
2934                         if(timeleft <= 0)
2935                         {
2936                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2937                                 AnnounceTo(self, "terminated");
2938                                 dropclient(self);
2939                                 return;
2940                         }
2941                         else if(timeleft <= 10)
2942                         {
2943                                 if(timeleft != self.idlekick_lasttimeleft)
2944                                         AnnounceTo(self, ftos(timeleft));
2945                                 self.idlekick_lasttimeleft = timeleft;
2946                         }
2947                 }
2948         }
2949
2950 #ifdef TETRIS
2951         if(self.impulse == 100)
2952                 ImpulseCommands();
2953         if (!TetrisPostFrame())
2954         {
2955 #endif
2956
2957         CheatFrame();
2958
2959         //CheckPlayerJump();
2960
2961         if(self.classname == "player") {
2962                 CheckRules_Player();
2963                 UpdateChatBubble();
2964                 if (self.impulse)
2965                         ImpulseCommands();
2966                 if (intermission_running)
2967                         return;         // intermission or finale
2968                 GetPressedKeys();
2969         } else if (self.classname == "observer") {
2970                 //do nothing
2971         } else if (self.classname == "spectator") {
2972                 //do nothing
2973         }
2974
2975 #ifdef TETRIS
2976         }
2977 #endif
2978
2979         /*
2980         float i;
2981         for(i = 0; i < 1000; ++i)
2982         {
2983                 vector end;
2984                 end = self.origin + '0 0 1024' + 512 * randomvec();
2985                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2986                 if(trace_fraction < 1)
2987                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2988                 {
2989                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2990                         break;
2991                 }
2992         }
2993         */
2994
2995         Arena_Warmup();
2996
2997         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2998
2999         if(self.waypointsprite_attachedforcarrier)
3000                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3001
3002         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3003         {
3004                 if(!self.showheadshotbbox)
3005                 {
3006                         self.showheadshotbbox = spawn();
3007                         self.showheadshotbbox.classname = "headshotbbox";
3008                         self.showheadshotbbox.owner = self;
3009                         self.showheadshotbbox.think = showheadshotbbox_think;
3010                         self.showheadshotbbox.nextthink = time;
3011                         self = self.showheadshotbbox;
3012                         self.think();
3013                         self = self.owner;
3014                 }
3015         }
3016         else
3017         {
3018                 if(self.showheadshotbbox)
3019                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3020                 remove(self.showheadshotbbox);
3021         }
3022
3023         playerdemo_write();
3024
3025         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3026         {
3027                 if(!self.stored_netname)
3028                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3029                 if(self.stored_netname != self.netname)
3030                 {
3031                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3032                         strunzone(self.stored_netname);
3033                         self.stored_netname = strzone(self.netname);
3034                 }
3035         }
3036
3037         /*
3038         if(g_race)
3039                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3040         */
3041
3042         CSQCMODEL_AUTOUPDATE();
3043 }