qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         Portal_ClearAll(self);
 618
 619         if(self.alivetime)
 620         {
 621                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 622                 self.alivetime = 0;
 623         }
 624
 625         if(self.vehicle)
 626             vehicles_exit(VHEF_RELESE);
 627
 628         if(self.flagcarried)
 629                 DropFlag(self.flagcarried, world, world);
 630
 631         if(self.ballcarried && g_nexball)
 632                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 633
 634         WaypointSprite_PlayerDead();
 635
 636         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 637                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 638
 639         if(self.killcount != -666) {
 640                 if(g_lms) {
 641                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 642                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 643                         else
 644                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 645                 } else
 646                         bprint ("^4", self.netname, "^4 is spectating now\n");
 647
 648                 if(self.just_joined == FALSE) {
 649                         LogTeamchange(self.playerid, -1, 4);
 650                 } else
 651                         self.just_joined = FALSE;
 652         }
 653
 654         PlayerScore_Clear(self); // clear scores when needed
 655
 656         accuracy_resend(self);
 657
 658         self.spectatortime = time;
 659
 660         self.classname = "observer";
 661         self.iscreature = FALSE;
 662         self.health = -666;
 663         self.takedamage = DAMAGE_NO;
 664         self.solid = SOLID_NOT;
 665         self.movetype = MOVETYPE_NOCLIP;
 666         self.flags = FL_CLIENT | FL_NOTARGET;
 667         self.armorvalue = 666;
 668         self.effects = 0;
 669         self.armorvalue = autocvar_g_balance_armor_start;
 670         self.pauserotarmor_finished = 0;
 671         self.pauserothealth_finished = 0;
 672         self.pauseregen_finished = 0;
 673         self.damageforcescale = 0;
 674         self.death_time = 0;
 675         self.dead_frame = 0;
 676         self.alpha = 0;
 677         self.scale = 0;
 678         self.fade_time = 0;
 679         self.pain_frame = 0;
 680         self.pain_finished = 0;
 681         self.strength_finished = 0;
 682         self.invincible_finished = 0;
 683         self.pushltime = 0;
 684         self.think = SUB_Null;
 685         self.nextthink = 0;
 686         self.hook_time = 0;
 687         self.runes = 0;
 688         self.deadflag = DEAD_NO;
 689         self.angles = spot.angles;
 690         self.angles_z = 0;
 691         self.fixangle = TRUE;
 692         self.crouch = FALSE;
 693
 694         self.view_ofs = PL_VIEW_OFS;
 695         setorigin (self, spot.origin);
 696         setsize (self, '0 0 0', '0 0 0');
 697         self.prevorigin = self.origin;
 698         self.items = 0;
 699         self.weapons = 0;
 700         self.model = "";
 701         FixPlayermodel();
 702         self.model = "";
 703         self.modelindex = 0;
 704         self.weapon = 0;
 705         self.weaponmodel = "";
 706         self.weaponentity = world;
 707         self.exteriorweaponentity = world;
 708         self.killcount = -666;
 709         self.velocity = '0 0 0';
 710         self.avelocity = '0 0 0';
 711         self.punchangle = '0 0 0';
 712         self.punchvector = '0 0 0';
 713         self.oldvelocity = self.velocity;
 714         self.fire_endtime = -1;
 715
 716         if(sv_loddistance1)
 717                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 718
 719         if(g_arena)
 720         {
 721                 if(self.version_mismatch)
 722                 {
 723                         Spawnqueue_Unmark(self);
 724                         Spawnqueue_Remove(self);
 725                 }
 726                 else
 727                 {
 728                         Spawnqueue_Insert(self);
 729                 }
 730         }
 731         else if(g_lms)
 732         {
 733                 // Only if the player cannot play at all
 734                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 735                         self.frags = FRAGS_SPECTATOR;
 736                 else
 737                         self.frags = FRAGS_LMS_LOSER;
 738         }
 739         else
 740                 self.frags = FRAGS_SPECTATOR;
 741 }
 742
 743 void FixPlayermodel()
 744 {
 745         local string defaultmodel;
 746         local float defaultskin, chmdl, oldskin;
 747         local vector m1, m2;
 748
 749         defaultmodel = "";
 750
 751         if(autocvar_sv_defaultcharacter == 1) {
 752                 defaultskin = 0;
 753
 754                 if(teamplay)
 755                 {
 756                         string s;
 757                         s = Team_ColorNameLowerCase(self.team);
 758                         if(s != "neutral")
 759                         {
 760                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 761                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 762                         }
 763                 }
 764
 765                 if(defaultmodel == "")
 766                 {
 767                         defaultmodel = autocvar_sv_defaultplayermodel;
 768                         defaultskin = autocvar_sv_defaultplayerskin;
 769                 }
 770         }
 771
 772         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 773         {
 774                 if(self.model != "")
 775                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 776                 self.model = ""; // force the != checks to return true
 777         }
 778
 779         if(defaultmodel != "")
 780         {
 781                 if (defaultmodel != self.model)
 782                 {
 783                         m1 = self.mins;
 784                         m2 = self.maxs;
 785                         setmodel_lod (self, defaultmodel);
 786                         setsize (self, m1, m2);
 787                         chmdl = TRUE;
 788                 }
 789
 790                 oldskin = self.skinindex;
 791                 self.skinindex = defaultskin;
 792         } else {
 793                 if (self.playermodel != self.model || self.playermodel == "")
 794                 {
 795                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 796                         m1 = self.mins;
 797                         m2 = self.maxs;
 798                         setmodel_lod (self, self.playermodel);
 799                         setsize (self, m1, m2);
 800                         chmdl = TRUE;
 801                 }
 802
 803                 oldskin = self.skinindex;
 804                 self.skinindex = stof(self.playerskin);
 805         }
 806
 807         if(chmdl || oldskin != self.skinindex)
 808                 self.species = player_getspecies(); // model or skin has changed
 809
 810         if(!teamplay)
 811                 if(strlen(autocvar_sv_defaultplayercolors))
 812                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 813                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 814 }
 815
 816 void PlayerTouchExplode(entity p1, entity p2)
 817 {
 818         vector org;
 819         org = (p1.origin + p2.origin) * 0.5;
 820         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 821
 822         te_explosion(org);
 823
 824         entity e;
 825         e = spawn();
 826         setorigin(e, org);
 827         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 828         remove(e);
 829 }
 830
 831 /*
 832 =============
 833 PutClientInServer
 834
 835 Called when a client spawns in the server
 836 =============
 837 */
 838 //void() ctf_playerchanged;
 839 void PutClientInServer (void)
 840 {
 841         if(clienttype(self) == CLIENTTYPE_BOT)
 842         {
 843                 self.classname = "player";
 844         }
 845         else if(clienttype(self) == CLIENTTYPE_REAL)
 846         {
 847                 msg_entity = self;
 848                 WriteByte(MSG_ONE, SVC_SETVIEW);
 849                 WriteEntity(MSG_ONE, self);
 850         }
 851
 852         // player is dead and becomes observer
 853         // FIXME fix LMS scoring for new system
 854         if(g_lms)
 855         {
 856                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 857                         self.classname = "observer";
 858         }
 859
 860         if(g_arena || (g_ca && !allowed_to_spawn))
 861         if(!self.spawned)
 862                 self.classname = "observer";
 863
 864         if(gameover)
 865                 self.classname = "observer";
 866
 867         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 868                 entity spot, oldself;
 869                 float j;
 870
 871                 accuracy_resend(self);
 872
 873                 if(self.team < 0)
 874                         JoinBestTeam(self, FALSE, TRUE);
 875
 876                 race_PreSpawn();
 877
 878                 spot = SelectSpawnPoint (FALSE);
 879                 if(!spot)
 880                 {
 881                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 882                         return; // spawn failed
 883                 }
 884
 885                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 886
 887                 self.classname = "player";
 888                 self.wasplayer = TRUE;
 889                 self.iscreature = TRUE;
 890                 self.movetype = MOVETYPE_WALK;
 891                 self.solid = SOLID_SLIDEBOX;
 892                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 893                 if(autocvar_g_playerclip_collisions)
 894                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 895                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 896                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 897                 self.frags = FRAGS_PLAYER;
 898                 if(independent_players)
 899                         MAKE_INDEPENDENT_PLAYER(self);
 900                 self.flags = FL_CLIENT;
 901                 self.takedamage = DAMAGE_AIM;
 902                 if(g_minstagib)
 903                         self.effects = EF_FULLBRIGHT;
 904                 else
 905                         self.effects = 0;
 906                 self.air_finished = time + 12;
 907                 self.dmg = 2;
 908                 if(autocvar_g_balance_nex_charge)
 909                 {
 910                         if(autocvar_g_balance_nex_secondary_chargepool)
 911                                 self.nex_chargepool_ammo = 1;
 912                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 913                 }
 914
 915                 if(inWarmupStage)
 916                 {
 917                         self.ammo_shells = warmup_start_ammo_shells;
 918                         self.ammo_nails = warmup_start_ammo_nails;
 919                         self.ammo_rockets = warmup_start_ammo_rockets;
 920                         self.ammo_cells = warmup_start_ammo_cells;
 921                         self.ammo_fuel = warmup_start_ammo_fuel;
 922                         self.health = warmup_start_health;
 923                         self.armorvalue = warmup_start_armorvalue;
 924                         self.weapons = warmup_start_weapons;
 925                 }
 926                 else
 927                 {
 928                         self.ammo_shells = start_ammo_shells;
 929                         self.ammo_nails = start_ammo_nails;
 930                         self.ammo_rockets = start_ammo_rockets;
 931                         self.ammo_cells = start_ammo_cells;
 932                         self.ammo_fuel = start_ammo_fuel;
 933                         self.health = start_health;
 934                         self.armorvalue = start_armorvalue;
 935                         self.weapons = start_weapons;
 936                 }
 937
 938                 if(g_weaponarena_random)
 939                 {
 940                         if(g_weaponarena_random_with_laser)
 941                                 self.weapons &~= WEPBIT_LASER;
 942                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 943                         if(g_weaponarena_random_with_laser)
 944                                 self.weapons |= WEPBIT_LASER;
 945                 }
 946
 947                 self.items = start_items;
 948                 self.jump_interval = time;
 949
 950                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 951                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 952                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 953                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 954                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 955                 //extend the pause of rotting if client was reset at the beginning of the countdown
 956                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 957                         self.spawnshieldtime += game_starttime - time;
 958                         self.pauserotarmor_finished += game_starttime - time;
 959                         self.pauserothealth_finished += game_starttime - time;
 960                         self.pauseregen_finished += game_starttime - time;
 961                 }
 962                 self.damageforcescale = 2;
 963                 self.death_time = 0;
 964                 self.dead_frame = 0;
 965                 self.alpha = 0;
 966                 self.scale = 0;
 967                 self.fade_time = 0;
 968                 self.pain_frame = 0;
 969                 self.pain_finished = 0;
 970                 self.strength_finished = 0;
 971                 self.invincible_finished = 0;
 972                 self.pushltime = 0;
 973                 // players have no think function
 974                 self.think = SUB_Null;
 975                 self.nextthink = 0;
 976                 self.hook_time = 0;
 977                 self.dmg_team = 0;
 978                 self.ballistics_density = autocvar_g_ballistics_density_player;
 979
 980                 self.metertime = 0;
 981
 982                 self.runes = 0;
 983
 984                 self.deadflag = DEAD_NO;
 985
 986                 self.angles = spot.angles;
 987
 988                 self.angles_z = 0; // never spawn tilted even if the spot says to
 989                 self.fixangle = TRUE; // turn this way immediately
 990                 self.velocity = '0 0 0';
 991                 self.avelocity = '0 0 0';
 992                 self.punchangle = '0 0 0';
 993                 self.punchvector = '0 0 0';
 994                 self.oldvelocity = self.velocity;
 995                 self.fire_endtime = -1;
 996
 997                 msg_entity = self;
 998                 WRITESPECTATABLE_MSG_ONE({
 999                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1000                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1001                 });
1002
1003                 if(sv_loddistance1)
1004                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1005
1006                 self.model = "";
1007                 FixPlayermodel();
1008
1009                 self.crouch = FALSE;
1010                 self.view_ofs = PL_VIEW_OFS;
1011                 setsize (self, PL_MIN, PL_MAX);
1012                 self.spawnorigin = spot.origin;
1013                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1014                 // don't reset back to last position, even if new position is stuck in solid
1015                 self.oldorigin = self.origin;
1016                 self.prevorigin = self.origin;
1017                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1018
1019                 if(g_arena)
1020                 {
1021                         Spawnqueue_Remove(self);
1022                         Spawnqueue_Mark(self);
1023                 }
1024
1025                 else if(g_ca)
1026                         self.caplayer = 1;
1027
1028                 self.event_damage = PlayerDamage;
1029
1030                 self.bot_attack = TRUE;
1031
1032                 self.statdraintime = time + 5;
1033                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1034
1035                 if(self.killcount == -666) {
1036                         PlayerScore_Clear(self);
1037                         self.killcount = 0;
1038                 }
1039
1040                 self.cnt = WEP_LASER;
1041
1042                 CL_SpawnWeaponentity();
1043                 self.alpha = default_player_alpha;
1044                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1045                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1046
1047                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1048                 self.lms_traveled_distance = 0;
1049                 self.speedrunning = FALSE;
1050
1051                 race_PostSpawn(spot);
1052
1053                 if(autocvar_spawn_debug)
1054                 {
1055                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1056                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1057                 }
1058
1059                 //stuffcmd(self, "chase_active 0");
1060                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1061
1062                 if (autocvar_g_spawnsound)
1063                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1064
1065                 if(g_assault) {
1066                         if(self.team == assault_attacker_team)
1067                                 centerprint(self, "You are attacking!");
1068                         else
1069                                 centerprint(self, "You are defending!");
1070                 }
1071
1072                 target_voicescript_clear(self);
1073
1074                 // reset fields the weapons may use
1075                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1076                 {
1077                         weapon_action(j, WR_RESETPLAYER);
1078
1079                         // all weapons must be fully loaded when we spawn
1080                         entity e;
1081                         e = get_weaponinfo(j);
1082                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1083                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1084                 }
1085                 self.weapon_forbidchange = FALSE;
1086
1087                 oldself = self;
1088                 self = spot;
1089                         activator = oldself;
1090                                 string s;
1091                                 s = self.target;
1092                                 self.target = string_null;
1093                                 SUB_UseTargets();
1094                                 self.target = s;
1095                         activator = world;
1096                 self = oldself;
1097
1098                 MUTATOR_CALLHOOK(PlayerSpawn);
1099
1100                 self.switchweapon = w_getbestweapon(self);
1101                 self.cnt = self.switchweapon;
1102                 self.weapon = 0;
1103
1104                 if(!self.alivetime)
1105                         self.alivetime = time;
1106         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1107                 PutObserverInServer ();
1108         }
1109
1110         //if(g_ctf)
1111         //      ctf_playerchanged();
1112 }
1113
1114 .float ebouncefactor, ebouncestop; // electro's values
1115 // TODO do we need all these fields, or should we stop autodetecting runtime
1116 // changes and just have a console command to update this?
1117 float ClientInit_SendEntity(entity to, float sf)
1118 {
1119         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1120         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1121         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1122         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1123         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1124         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1125         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1126         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1127         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1128         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1129         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1130         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1131         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1132         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1133         if(sv_foginterval && world.fog != "")
1134                 WriteString(MSG_ENTITY, world.fog);
1135         else
1136                 WriteString(MSG_ENTITY, "");
1137         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1138         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1139         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1140         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1141         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1142         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1143         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1144         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1145         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1146         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1147         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1148         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1149         return TRUE;
1150 }
1151
1152 void ClientInit_CheckUpdate()
1153 {
1154         self.nextthink = time;
1155         if(self.count != autocvar_g_balance_armor_blockpercent)
1156         {
1157                 self.count = autocvar_g_balance_armor_blockpercent;
1158                 self.SendFlags |= 1;
1159         }
1160         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1161         {
1162                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1163                 self.SendFlags |= 1;
1164         }
1165         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1166         {
1167                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1168                 self.SendFlags |= 1;
1169         }
1170         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1171         {
1172                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1173                 self.SendFlags |= 1;
1174         }
1175         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1176         {
1177                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1178                 self.SendFlags |= 1;
1179         }
1180         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1181         {
1182                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1183                 self.SendFlags |= 1;
1184         }
1185 }
1186
1187 void ClientInit_Spawn()
1188 {
1189         entity o;
1190         entity e;
1191         e = spawn();
1192         e.classname = "clientinit";
1193         e.think = ClientInit_CheckUpdate;
1194         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1195
1196         o = self;
1197         self = e;
1198         ClientInit_CheckUpdate();
1199         self = o;
1200 }
1201
1202 /*
1203 =============
1204 SetNewParms
1205 =============
1206 */
1207 void SetNewParms (void)
1208 {
1209         // initialize parms for a new player
1210         parm1 = -(86400 * 366);
1211 }
1212
1213 /*
1214 =============
1215 SetChangeParms
1216 =============
1217 */
1218 void SetChangeParms (void)
1219 {
1220         // save parms for level change
1221         parm1 = self.parm_idlesince - time;
1222 }
1223
1224 /*
1225 =============
1226 DecodeLevelParms
1227 =============
1228 */
1229 void DecodeLevelParms (void)
1230 {
1231         // load parms
1232         self.parm_idlesince = parm1;
1233         if(self.parm_idlesince == -(86400 * 366))
1234                 self.parm_idlesince = time;
1235
1236         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1237         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1238 }
1239
1240 /*
1241 =============
1242 ClientKill
1243
1244 Called when a client types 'kill' in the console
1245 =============
1246 */
1247
1248 .float clientkill_nexttime;
1249 void ClientKill_Now_TeamChange()
1250 {
1251         if(self.killindicator_teamchange == -1)
1252         {
1253                 self.team = -1;
1254                 JoinBestTeam( self, FALSE, FALSE );
1255         }
1256         else if(self.killindicator_teamchange == -2)
1257         {
1258                 if(g_ca)
1259                         self.caplayer = 0;
1260                 if(blockSpectators)
1261                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1262                 PutObserverInServer();
1263         }
1264         else
1265                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1266 }
1267
1268 void ClientKill_Now()
1269 {
1270         if(self.vehicle)
1271         {
1272             vehicles_exit(VHEF_RELESE);
1273             if(!self.killindicator_teamchange)
1274             {
1275             self.vehicle_health = -1;
1276             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1277             }
1278         }
1279
1280         if(self.killindicator && !wasfreed(self.killindicator))
1281         remove(self.killindicator);
1282
1283         self.killindicator = world;
1284
1285         if(self.killindicator_teamchange)
1286                 ClientKill_Now_TeamChange();
1287
1288         // in any case:
1289         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1290
1291         // now I am sure the player IS dead
1292 }
1293 void KillIndicator_Think()
1294 {
1295         if (!self.owner.modelindex)
1296         {
1297                 self.owner.killindicator = world;
1298                 remove(self);
1299                 return;
1300         }
1301
1302         if(self.cnt <= 0)
1303         {
1304                 self = self.owner;
1305                 ClientKill_Now(); // no oldself needed
1306                 return;
1307         }
1308     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1309     {
1310         self.nextthink = time + 1;
1311         self.cnt -= 1;
1312     }
1313         else
1314         {
1315                 if(self.cnt <= 10)
1316                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1317                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1318                 {
1319                         if(self.cnt <= 10)
1320                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1321                         if(self.owner.killindicator_teamchange)
1322                         {
1323                                 if(self.owner.killindicator_teamchange == -1)
1324                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1325                                 else if(self.owner.killindicator_teamchange == -2)
1326                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1327                                 else
1328                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1329                         }
1330                         else
1331                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1332                 }
1333                 self.nextthink = time + 1;
1334                 self.cnt -= 1;
1335         }
1336 }
1337
1338 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1339 {
1340         float killtime;
1341         entity e;
1342         killtime = autocvar_g_balance_kill_delay;
1343
1344         if(g_race_qualifying || g_cts)
1345                 killtime = 0;
1346
1347     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1348     {
1349                 remove(self.killindicator);
1350                 self.killindicator = world;
1351
1352         ClientKill_Now(); // allow instant kill in this case
1353         return;
1354     }
1355
1356         self.killindicator_teamchange = targetteam;
1357
1358     if(!self.killindicator)
1359         {
1360                 if(self.modelindex && self.deadflag == DEAD_NO)
1361                 {
1362                         killtime = max(killtime, self.clientkill_nexttime - time);
1363                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1364                 }
1365
1366                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1367                 {
1368                         ClientKill_Now();
1369                 }
1370                 else
1371                 {
1372                         self.killindicator = spawn();
1373                         self.killindicator.owner = self;
1374                         self.killindicator.scale = 0.5;
1375                         setattachment(self.killindicator, self, "");
1376                         setorigin(self.killindicator, '0 0 52');
1377                         self.killindicator.think = KillIndicator_Think;
1378                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1379                         self.killindicator.cnt = ceil(killtime);
1380                         self.killindicator.count = bound(0, ceil(killtime), 10);
1381                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1382
1383                         for(e = world; (e = find(e, classname, "body")) != world; )
1384                         {
1385                                 if(e.enemy != self)
1386                                         continue;
1387                                 e.killindicator = spawn();
1388                                 e.killindicator.owner = e;
1389                                 e.killindicator.scale = 0.5;
1390                                 setattachment(e.killindicator, e, "");
1391                                 setorigin(e.killindicator, '0 0 52');
1392                                 e.killindicator.think = KillIndicator_Think;
1393                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1394                                 e.killindicator.cnt = ceil(killtime);
1395                         }
1396                         self.lip = 0;
1397                 }
1398         }
1399         if(self.killindicator)
1400         {
1401                 if(targetteam == 0) // just die
1402                         self.killindicator.colormod = '0 0 0';
1403                 else if(targetteam == -1) // auto
1404                         self.killindicator.colormod = '0 1 0';
1405                 else if(targetteam == -2) // spectate
1406                         self.killindicator.colormod = '0.5 0.5 0.5';
1407                 else
1408                         self.killindicator.colormod = TeamColor(targetteam);
1409         }
1410 }
1411
1412 void ClientKill (void)
1413 {
1414         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1415         {
1416                 // do nothing
1417         }
1418     else if(self.freezetag_frozen)
1419     {
1420         // do nothing
1421     }
1422         else
1423                 ClientKill_TeamChange(0);
1424 }
1425
1426 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1427 {
1428     e.killindicator = spawn();
1429     e.killindicator.owner = e;
1430     e.killindicator.think = KillIndicator_Think;
1431     e.killindicator.nextthink = time + (e.lip) * 0.05;
1432     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1433     e.killindicator.health = 1; // this is used to indicate that it should be silent
1434     e.lip = 0;
1435 }
1436
1437 void DoTeamChange(float destteam)
1438 {
1439         float t, c0;
1440         if(!teamplay)
1441         {
1442                 if(destteam >= 0)
1443                         SetPlayerColors(self, destteam);
1444                 return;
1445         }
1446         if(self.classname == "player")
1447         if(destteam == -1)
1448         {
1449                 CheckAllowedTeams(self);
1450                 t = FindSmallestTeam(self, TRUE);
1451                 switch(self.team)
1452                 {
1453                         case COLOR_TEAM1: c0 = c1; break;
1454                         case COLOR_TEAM2: c0 = c2; break;
1455                         case COLOR_TEAM3: c0 = c3; break;
1456                         case COLOR_TEAM4: c0 = c4; break;
1457                         default:          c0 = 999;
1458                 }
1459                 switch(t)
1460                 {
1461                         case 1:
1462                                 if(c0 > c1)
1463                                         destteam = COLOR_TEAM1;
1464                                 break;
1465                         case 2:
1466                                 if(c0 > c2)
1467                                         destteam = COLOR_TEAM2;
1468                                 break;
1469                         case 3:
1470                                 if(c0 > c3)
1471                                         destteam = COLOR_TEAM3;
1472                                 break;
1473                         case 4:
1474                                 if(c0 > c4)
1475                                         destteam = COLOR_TEAM4;
1476                                 break;
1477                 }
1478                 if(destteam == -1)
1479                         return;
1480         }
1481         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1482                 return;
1483         ClientKill_TeamChange(destteam);
1484 }
1485
1486 void FixClientCvars(entity e)
1487 {
1488         // send prediction settings to the client
1489         stuffcmd(e, "\nin_bindmap 0 0\n");
1490         if(g_race || g_cts)
1491                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1492         if(autocvar_g_antilag == 3) // client side hitscan
1493                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1494         if(sv_gentle)
1495                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1496         /*
1497          * we no longer need to stuff this. Remove this comment block if you feel
1498          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1499         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1500         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1501         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1502         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1503         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1504         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1505         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1506         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1507         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1508         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1509         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1510         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1511         stuffcmd(e, "cl_movement_edgefriction 1\n");
1512          */
1513 }
1514
1515 float PlayerInIDList(entity p, string idlist)
1516 {
1517         float n, i;
1518         string s;
1519
1520         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1521         if not(p.crypto_idfp)
1522                 return 0;
1523
1524         // this function allows abbreviated player IDs too!
1525         n = tokenize_console(idlist);
1526         for(i = 0; i < n; ++i)
1527         {
1528                 s = argv(i);
1529                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1530                         return 1;
1531         }
1532
1533         return 0;
1534 }
1535
1536 /*
1537 =============
1538 ClientConnect
1539
1540 Called when a client connects to the server
1541 =============
1542 */
1543 //void ctf_clientconnect();
1544 string ColoredTeamName(float t);
1545 void DecodeLevelParms (void);
1546 //void dom_player_join_team(entity pl);
1547 void set_dom_state(entity e);
1548 void ClientConnect (void)
1549 {
1550         float t;
1551
1552         if(self.flags & FL_CLIENT)
1553         {
1554                 print("Warning: ClientConnect, but already connected!\n");
1555                 return;
1556         }
1557
1558         if(Ban_MaybeEnforceBan(self))
1559                 return;
1560
1561         DecodeLevelParms();
1562
1563 #ifdef WATERMARK
1564         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1565 #endif
1566
1567         self.classname = "player_joining";
1568
1569         self.flags = FL_CLIENT;
1570         self.version_nagtime = time + 10 + random() * 10;
1571
1572         if(player_count<0)
1573         {
1574                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1575                 player_count = 0;
1576         }
1577
1578         PlayerScore_Attach(self);
1579         ClientData_Attach();
1580         accuracy_init(self);
1581
1582         bot_clientconnect();
1583
1584         playerdemo_init();
1585
1586         anticheat_init();
1587
1588         race_PreSpawnObserver();
1589
1590         //if(g_domination)
1591         //      dom_player_join_team(self);
1592
1593         // identify the right forced team
1594         if(autocvar_g_campaign)
1595         {
1596                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1597                 {
1598                         switch(autocvar_g_campaign_forceteam)
1599                         {
1600                                 case 1: self.team_forced = COLOR_TEAM1; break;
1601                                 case 2: self.team_forced = COLOR_TEAM2; break;
1602                                 case 3: self.team_forced = COLOR_TEAM3; break;
1603                                 case 4: self.team_forced = COLOR_TEAM4; break;
1604                                 default: self.team_forced = 0;
1605                         }
1606                 }
1607         }
1608         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1609                 self.team_forced = COLOR_TEAM1;
1610         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1611                 self.team_forced = COLOR_TEAM2;
1612         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1613                 self.team_forced = COLOR_TEAM3;
1614         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1615                 self.team_forced = COLOR_TEAM4;
1616         else if(autocvar_g_forced_team_otherwise == "red")
1617                 self.team_forced = COLOR_TEAM1;
1618         else if(autocvar_g_forced_team_otherwise == "blue")
1619                 self.team_forced = COLOR_TEAM2;
1620         else if(autocvar_g_forced_team_otherwise == "yellow")
1621                 self.team_forced = COLOR_TEAM3;
1622         else if(autocvar_g_forced_team_otherwise == "pink")
1623                 self.team_forced = COLOR_TEAM4;
1624         else if(autocvar_g_forced_team_otherwise == "spectate")
1625                 self.team_forced = -1;
1626         else if(autocvar_g_forced_team_otherwise == "spectator")
1627                 self.team_forced = -1;
1628         else
1629                 self.team_forced = 0;
1630
1631         if(!teamplay)
1632                 if(self.team_forced > 0)
1633                         self.team_forced = 0;
1634
1635         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1636
1637         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1638                 self.classname = "observer";
1639         } else {
1640                 if(teamplay)
1641                 {
1642                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1643                         {
1644                                 self.classname = "player";
1645                                 campaign_bots_may_start = 1;
1646                         }
1647                         else
1648                         {
1649                                 self.classname = "observer"; // do it anyway
1650                         }
1651                 }
1652                 else
1653                 {
1654                         self.classname = "player";
1655                         campaign_bots_may_start = 1;
1656                 }
1657         }
1658
1659         self.playerid = (playerid_last = playerid_last + 1);
1660
1661     if(clienttype(self) == CLIENTTYPE_BOT)
1662         PlayerStats_AddPlayer(self);
1663
1664         if(autocvar_sv_eventlog)
1665                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1666
1667         LogTeamchange(self.playerid, self.team, 1);
1668
1669         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1670
1671         self.netname_previous = strzone(self.netname);
1672
1673         bprint("^4", self.netname, "^4 connected");
1674
1675         if(self.classname != "observer" && (g_domination || g_ctf))
1676                 bprint(" and joined the ", ColoredTeamName(self.team));
1677
1678         bprint("\n");
1679
1680         self.welcomemessage_time = 0;
1681
1682         stuffcmd(self, strcat(clientstuff, "\n"));
1683         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1684         stuffcmd(self, "cl_particles_reloadeffects\n");
1685
1686         FixClientCvars(self);
1687
1688         // spawnfunc_waypoint sprites
1689         WaypointSprite_InitClient(self);
1690
1691         // Wazat's grappling hook
1692         SetGrappleHookBindings();
1693
1694         // get autoswitch state from player when he toggles it
1695         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1696
1697         // get version info from player
1698         stuffcmd(self, "cmd clientversion $gameversion\n");
1699
1700         // get other cvars from player
1701         GetCvars(0);
1702
1703         // notify about available teams
1704         if(teamplay)
1705         {
1706                 CheckAllowedTeams(self);
1707                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1708                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1709         }
1710         else
1711                 stuffcmd(self, "set _teams_available 0\n");
1712
1713         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1714
1715         if(g_arena || g_ca)
1716         {
1717                 self.classname = "observer";
1718                 if(g_arena)
1719                         Spawnqueue_Insert(self);
1720         }
1721         /*else if(g_ctf)
1722         {
1723                 ctf_clientconnect();
1724         }*/
1725
1726         attach_entcs();
1727
1728         bot_relinkplayerlist();
1729
1730         self.spectatortime = time;
1731         if(blockSpectators)
1732         {
1733                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1734         }
1735
1736         self.jointime = time;
1737         self.allowedTimeouts = autocvar_sv_timeout_number;
1738
1739         if(clienttype(self) == CLIENTTYPE_REAL)
1740         {
1741                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1742                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1743         }
1744
1745         if(g_lms)
1746         {
1747                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1748                 {
1749                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1750                         self.frags = FRAGS_SPECTATOR;
1751                 }
1752         }
1753
1754         if(!sv_foginterval && world.fog != "")
1755                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1756
1757         SoundEntity_Attach(self);
1758
1759         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1760         {
1761                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1762                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1763         }
1764         else
1765                 self.hitplotfh = -1;
1766
1767         if(g_race || g_cts) {
1768                 string rr;
1769                 if(g_cts)
1770                         rr = CTS_RECORD;
1771                 else
1772                         rr = RACE_RECORD;
1773                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1774
1775                 msg_entity = self;
1776                 race_send_recordtime(MSG_ONE);
1777                 race_send_speedaward(MSG_ONE);
1778
1779                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1780                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1781                 race_send_speedaward_alltimebest(MSG_ONE);
1782
1783                 float i;
1784                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1785                         race_SendRankings(i, 0, 0, MSG_ONE);
1786                 }
1787         }
1788         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1789                 send_CSQC_teamnagger();
1790
1791         if (g_domination)
1792                 set_dom_state(self);
1793
1794         CheatInitClient();
1795 }
1796
1797 /*
1798 =============
1799 ClientDisconnect
1800
1801 Called when a client disconnects from the server
1802 =============
1803 */
1804 .entity chatbubbleentity;
1805 void ReadyCount();
1806 void ClientDisconnect (void)
1807 {
1808         if(self.vehicle)
1809             vehicles_exit(VHEF_RELESE);
1810
1811         if not(self.flags & FL_CLIENT)
1812         {
1813                 print("Warning: ClientDisconnect without ClientConnect\n");
1814                 return;
1815         }
1816
1817         PlayerStats_AddGlobalInfo(self);
1818
1819         CheatShutdownClient();
1820
1821         if(self.hitplotfh >= 0)
1822         {
1823                 fclose(self.hitplotfh);
1824                 self.hitplotfh = -1;
1825         }
1826
1827         anticheat_report();
1828         anticheat_shutdown();
1829
1830         playerdemo_shutdown();
1831
1832         bot_clientdisconnect();
1833
1834         if(self.entcs)
1835                 detach_entcs();
1836
1837         if(autocvar_sv_eventlog)
1838                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1839         bprint ("^4",self.netname);
1840         bprint ("^4 disconnected\n");
1841
1842         SoundEntity_Detach(self);
1843
1844         DropAllRunes(self);
1845         MUTATOR_CALLHOOK(ClientDisconnect);
1846
1847         Portal_ClearAll(self);
1848
1849         if(self.flagcarried)
1850                 DropFlag(self.flagcarried, world, world);
1851         if(self.ballcarried && g_nexball)
1852                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1853
1854         // Here, everything has been done that requires this player to be a client.
1855
1856         self.flags &~= FL_CLIENT;
1857
1858         if (self.chatbubbleentity)
1859                 remove (self.chatbubbleentity);
1860
1861         if (self.killindicator)
1862                 remove (self.killindicator);
1863
1864         WaypointSprite_PlayerGone();
1865
1866         bot_relinkplayerlist();
1867
1868         if(g_arena)
1869         {
1870                 Spawnqueue_Unmark(self);
1871                 Spawnqueue_Remove(self);
1872         }
1873
1874         accuracy_free(self);
1875         ClientData_Detach();
1876         PlayerScore_Detach(self);
1877
1878         if(self.netname_previous)
1879                 strunzone(self.netname_previous);
1880         if(self.clientstatus)
1881                 strunzone(self.clientstatus);
1882         if(self.weaponorder_byimpulse)
1883                 strunzone(self.weaponorder_byimpulse);
1884
1885         ClearPlayerSounds();
1886
1887         if(self.personal)
1888                 remove(self.personal);
1889
1890         self.playerid = 0;
1891         ReadyCount();
1892
1893         // free cvars
1894         GetCvars(-1);
1895 }
1896
1897 .float BUTTON_CHAT;
1898 void ChatBubbleThink()
1899 {
1900         self.nextthink = time;
1901         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1902         {
1903                 if(self.owner) // but why can that ever be world?
1904                         self.owner.chatbubbleentity = world;
1905                 remove(self);
1906                 return;
1907         }
1908         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1909 #ifdef TETRIS
1910                 || self.owner.tetris_on
1911 #endif
1912         )
1913                 self.model = self.mdl;
1914         else
1915                 self.model = "";
1916 };
1917
1918 void UpdateChatBubble()
1919 {
1920         if (!self.modelindex)
1921                 return;
1922         // spawn a chatbubble entity if needed
1923         if (!self.chatbubbleentity)
1924         {
1925                 self.chatbubbleentity = spawn();
1926                 self.chatbubbleentity.owner = self;
1927                 self.chatbubbleentity.exteriormodeltoclient = self;
1928                 self.chatbubbleentity.think = ChatBubbleThink;
1929                 self.chatbubbleentity.nextthink = time;
1930                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1931                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1932                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1933                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1934                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1935                 self.chatbubbleentity.model = "";
1936                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1937         }
1938 }
1939
1940
1941 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1942 // added to the model skins
1943 /*void UpdateColorModHack()
1944 {
1945         local float c;
1946         c = self.clientcolors & 15;
1947         // LordHavoc: only bothering to support white, green, red, yellow, blue
1948              if (!teamplay) self.colormod = '0 0 0';
1949         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1950         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1951         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1952         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1953         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1954         else self.colormod = '1 1 1';
1955 };*/
1956
1957 .float oldcolormap;
1958 void respawn(void)
1959 {
1960         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1961         {
1962                 self.solid = SOLID_NOT;
1963                 self.takedamage = DAMAGE_NO;
1964                 self.movetype = MOVETYPE_FLY;
1965                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1966                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1967                 self.effects |= EF_ADDITIVE;
1968                 self.oldcolormap = self.colormap;
1969                 self.colormap = 512;
1970                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1971                 if(autocvar_g_respawn_ghosts_maxtime)
1972                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1973         }
1974
1975         CopyBody(1);
1976         self.effects |= EF_NODRAW; // prevent another CopyBody
1977         if(self.oldcolormap)
1978         {
1979                 self.colormap = self.oldcolormap;
1980                 self.oldcolormap = 0;
1981         }
1982         PutClientInServer();
1983 }
1984
1985 void play_countdown(float finished, string samp)
1986 {
1987         if(clienttype(self) == CLIENTTYPE_REAL)
1988                 if(floor(finished - time - frametime) != floor(finished - time))
1989                         if(finished - time < 6)
1990                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1991 }
1992
1993 /**
1994  * When sv_timeout is used this function returs strings like
1995  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1996  * Called by centerprint functions
1997  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1998  */
1999 string getTimeoutText(float addOneSecond) {
2000         if (!autocvar_sv_timeout || !timeoutStatus)
2001                 return "";
2002
2003         local string retStr;
2004         if (timeoutStatus == 1) {
2005                 if (addOneSecond == 1) {
2006                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2007                 }
2008                 else {
2009                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2010                 }
2011                 return retStr;
2012         }
2013         else if (timeoutStatus == 2) {
2014                 if (addOneSecond) {
2015                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2016                         //don't show messages like "Timeout ends in 0 seconds"...
2017                         if ((remainingTimeoutTime + 1) > 0)
2018                                 return retStr;
2019                         else
2020                                 return "";
2021                 }
2022                 else {
2023                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2024                         //don't show messages like "Timeout ends in 0 seconds"...
2025                         if (remainingTimeoutTime > 0)
2026                                 return retStr;
2027                         else
2028                                 return "";
2029                 }
2030         }
2031         else return "";
2032 }
2033
2034 void player_powerups (void)
2035 {
2036         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2037         olditems = self.items;
2038
2039         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2040         {
2041                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2042                 self.modelflags |= MF_ROCKET;
2043         }
2044         else
2045         {
2046                 SoundEntity_StopSound(self, CHAN_PLAYER);
2047                 self.modelflags &~= MF_ROCKET;
2048         }
2049
2050         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2051
2052         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2053                 return;
2054
2055         Fire_ApplyDamage(self);
2056         Fire_ApplyEffect(self);
2057
2058         if (g_minstagib)
2059         {
2060                 self.effects |= EF_FULLBRIGHT;
2061
2062                 if (self.items & IT_STRENGTH)
2063                 {
2064                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2065                         if (time > self.strength_finished)
2066                         {
2067                                 self.alpha = default_player_alpha;
2068                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2069                                 self.items &~= IT_STRENGTH;
2070                                 sprint(self, "^3Invisibility has worn off\n");
2071                         }
2072                 }
2073                 else
2074                 {
2075                         if (time < self.strength_finished)
2076                         {
2077                                 self.alpha = g_minstagib_invis_alpha;
2078                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2079                                 self.items |= IT_STRENGTH;
2080                                 sprint(self, "^3You are invisible\n");
2081                         }
2082                 }
2083
2084                 if (self.items & IT_INVINCIBLE)
2085                 {
2086                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2087                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2088                         {
2089                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2090                                 sprint(self, "^3Speed has worn off\n");
2091                         }
2092                 }
2093                 else
2094                 {
2095                         if (time < self.invincible_finished)
2096                         {
2097                                 self.items = self.items | IT_INVINCIBLE;
2098                                 sprint(self, "^3You are on speed\n");
2099                         }
2100                 }
2101         }
2102         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2103         {
2104                 if (self.items & IT_STRENGTH)
2105                 {
2106                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2107                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2108                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2109                         {
2110                                 self.items = self.items - (self.items & IT_STRENGTH);
2111                                 sprint(self, "^3Strength has worn off\n");
2112                         }
2113                 }
2114                 else
2115                 {
2116                         if (time < self.strength_finished)
2117                         {
2118                                 self.items = self.items | IT_STRENGTH;
2119                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2120                         }
2121                 }
2122                 if (self.items & IT_INVINCIBLE)
2123                 {
2124                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2125                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2126                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2127                         {
2128                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2129                                 sprint(self, "^3Shield has worn off\n");
2130                         }
2131                 }
2132                 else
2133                 {
2134                         if (time < self.invincible_finished)
2135                         {
2136                                 self.items = self.items | IT_INVINCIBLE;
2137                                 sprint(self, "^3Shield surrounds you\n");
2138                         }
2139                 }
2140
2141                 if(autocvar_g_nodepthtestplayers)
2142                         self.effects = self.effects | EF_NODEPTHTEST;
2143
2144                 if(autocvar_g_fullbrightplayers)
2145                         self.effects = self.effects | EF_FULLBRIGHT;
2146
2147                 // midair gamemode: damage only while in the air
2148                 // if in midair mode, being on ground grants temporary invulnerability
2149                 // (this is so that multishot weapon don't clear the ground flag on the
2150                 // first damage in the frame, leaving the player vulnerable to the
2151                 // remaining hits in the same frame)
2152                 if (self.flags & FL_ONGROUND)
2153                 if (g_midair)
2154                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2155
2156                 if (time >= game_starttime)
2157                 if (time < self.spawnshieldtime)
2158                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2159         }
2160
2161         MUTATOR_CALLHOOK(PlayerPowerups);
2162 }
2163
2164 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2165 {
2166         if(current > stable)
2167                 return current;
2168         else if(current > stable - 0.25) // when close enough, "snap"
2169                 return stable;
2170         else
2171                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2172 }
2173
2174 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2175 {
2176         if(current < stable)
2177                 return current;
2178         else if(current < stable + 0.25) // when close enough, "snap"
2179                 return stable;
2180         else
2181                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2182 }
2183
2184 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2185 {
2186         if(current > rotstable)
2187         {
2188                 if(rotframetime > 0)
2189                 {
2190                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2191                         current = max(rotstable, current - rotlinear * rotframetime);
2192                 }
2193         }
2194         else if(current < regenstable)
2195         {
2196                 if(regenframetime > 0)
2197                 {
2198                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2199                         current = min(regenstable, current + regenlinear * regenframetime);
2200                 }
2201         }
2202
2203         if(current > limit)
2204                 current = limit;
2205
2206         return current;
2207 }
2208
2209 void player_regen (void)
2210 {
2211         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2212         maxh = autocvar_g_balance_health_rotstable;
2213         maxa = autocvar_g_balance_armor_rotstable;
2214         maxf = autocvar_g_balance_fuel_rotstable;
2215         minh = autocvar_g_balance_health_regenstable;
2216         mina = autocvar_g_balance_armor_regenstable;
2217         minf = autocvar_g_balance_fuel_regenstable;
2218         limith = autocvar_g_balance_health_limit;
2219         limita = autocvar_g_balance_armor_limit;
2220         limitf = autocvar_g_balance_fuel_limit;
2221
2222         max_mod = regen_mod = rot_mod = limit_mod = 1;
2223
2224         if (self.runes & RUNE_REGEN)
2225         {
2226                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2227                 {
2228                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2229                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2230                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2231                 }
2232                 else
2233                 {
2234                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2235                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2236                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2237                 }
2238         }
2239         else if (self.runes & CURSE_VENOM)
2240         {
2241                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2242                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2243                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2244                 else
2245                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2246                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2247                 //if (!self.runes & RUNE_REGEN)
2248                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2249         }
2250         maxh = maxh * max_mod;
2251         //maxa = maxa * max_mod;
2252         //maxf = maxf * max_mod;
2253         minh = minh * max_mod;
2254         //mina = mina * max_mod;
2255         //minf = minf * max_mod;
2256         limith = limith * limit_mod;
2257         limita = limita * limit_mod;
2258         //limitf = limitf * limit_mod;
2259
2260         if(g_lms && g_ca)
2261                 rot_mod = 0;
2262
2263         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2264         {
2265                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2266                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2267
2268                 // if player rotted to death...  die!
2269                 if(self.health < 1)
2270                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2271         }
2272
2273         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2274                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2275 }
2276
2277 float zoomstate_set;
2278 void SetZoomState(float z)
2279 {
2280         if(z != self.zoomstate)
2281         {
2282                 self.zoomstate = z;
2283                 ClientData_Touch(self);
2284         }
2285         zoomstate_set = 1;
2286 }
2287
2288 void GetPressedKeys(void) {
2289         MUTATOR_CALLHOOK(GetPressedKeys);
2290         if (self.movement_x > 0) // get if movement keys are pressed
2291         {       // forward key pressed
2292                 self.pressedkeys |= KEY_FORWARD;
2293                 self.pressedkeys &~= KEY_BACKWARD;
2294         }
2295         else if (self.movement_x < 0)
2296         {       // backward key pressed
2297                 self.pressedkeys |= KEY_BACKWARD;
2298                 self.pressedkeys &~= KEY_FORWARD;
2299         }
2300         else
2301         {       // no x input
2302                 self.pressedkeys &~= KEY_FORWARD;
2303                 self.pressedkeys &~= KEY_BACKWARD;
2304         }
2305
2306         if (self.movement_y > 0)
2307         {       // right key pressed
2308                 self.pressedkeys |= KEY_RIGHT;
2309                 self.pressedkeys &~= KEY_LEFT;
2310         }
2311         else if (self.movement_y < 0)
2312         {       // left key pressed
2313                 self.pressedkeys |= KEY_LEFT;
2314                 self.pressedkeys &~= KEY_RIGHT;
2315         }
2316         else
2317         {       // no y input
2318                 self.pressedkeys &~= KEY_RIGHT;
2319                 self.pressedkeys &~= KEY_LEFT;
2320         }
2321
2322         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2323                 self.pressedkeys |= KEY_JUMP;
2324         else
2325                 self.pressedkeys &~= KEY_JUMP;
2326         if (self.BUTTON_CROUCH)
2327                 self.pressedkeys |= KEY_CROUCH;
2328         else
2329                 self.pressedkeys &~= KEY_CROUCH;
2330 }
2331
2332 /*
2333 ======================
2334 spectate mode routines
2335 ======================
2336 */
2337
2338 void SpectateCopy(entity spectatee) {
2339         other = spectatee;
2340         MUTATOR_CALLHOOK(SpectateCopy);
2341         self.armortype = spectatee.armortype;
2342         self.armorvalue = spectatee.armorvalue;
2343         self.ammo_cells = spectatee.ammo_cells;
2344         self.ammo_shells = spectatee.ammo_shells;
2345         self.ammo_nails = spectatee.ammo_nails;
2346         self.ammo_rockets = spectatee.ammo_rockets;
2347         self.ammo_fuel = spectatee.ammo_fuel;
2348         self.clip_load = spectatee.clip_load;
2349         self.clip_size = spectatee.clip_size;
2350         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2351         self.health = spectatee.health;
2352         self.impulse = 0;
2353         self.items = spectatee.items;
2354         self.last_pickup = spectatee.last_pickup;
2355         self.hit_time = spectatee.hit_time;
2356         self.metertime = spectatee.metertime;
2357         self.strength_finished = spectatee.strength_finished;
2358         self.invincible_finished = spectatee.invincible_finished;
2359         self.pressedkeys = spectatee.pressedkeys;
2360         self.weapons = spectatee.weapons;
2361         self.switchweapon = spectatee.switchweapon;
2362         self.weapon = spectatee.weapon;
2363         self.nex_charge = spectatee.nex_charge;
2364         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2365         self.hagar_load = spectatee.hagar_load;
2366         self.minelayer_mines = spectatee.minelayer_mines;
2367         self.punchangle = spectatee.punchangle;
2368         self.view_ofs = spectatee.view_ofs;
2369         self.v_angle = spectatee.v_angle;
2370         self.velocity = spectatee.velocity;
2371         self.dmg_take = spectatee.dmg_take;
2372         self.dmg_save = spectatee.dmg_save;
2373         self.dmg_inflictor = spectatee.dmg_inflictor;
2374         self.angles = spectatee.v_angle;
2375         self.fixangle = TRUE;
2376         setorigin(self, spectatee.origin);
2377         setsize(self, spectatee.mins, spectatee.maxs);
2378         SetZoomState(spectatee.zoomstate);
2379
2380         anticheat_spectatecopy(spectatee);
2381
2382         //self.vehicle = spectatee.vehicle;
2383
2384         self.hud = spectatee.hud;
2385         if(spectatee.vehicle)
2386     {
2387         setorigin(self, spectatee.origin);
2388         self.velocity = spectatee.vehicle.velocity;
2389         self.v_angle += spectatee.vehicle.angles;
2390         //self.v_angle_x *= -1;
2391         self.vehicle_health = spectatee.vehicle_health;
2392         self.vehicle_shield = spectatee.vehicle_shield;
2393         self.vehicle_energy = spectatee.vehicle_energy;
2394         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2395         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2396         self.vehicle_reload1 = spectatee.vehicle_reload1;
2397         self.vehicle_reload2 = spectatee.vehicle_reload2;
2398
2399         msg_entity = self;
2400         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2401         WriteEntity(MSG_ONE, spectatee);
2402         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2403     }
2404 }
2405
2406 float SpectateUpdate() {
2407         if(!self.enemy)
2408             return 0;
2409
2410         if (self == self.enemy)
2411                 return 0;
2412
2413         if(self.enemy.classname != "player")
2414                 return 0;
2415
2416         SpectateCopy(self.enemy);
2417
2418         return 1;
2419 }
2420
2421 float SpectateNext() {
2422         other = find(self.enemy, classname, "player");
2423
2424         if (!other)
2425                 other = find(other, classname, "player");
2426
2427         if (other)
2428                 self.enemy = other;
2429
2430         if(self.enemy.classname == "player") {
2431             if(self.enemy.vehicle)
2432             {
2433             msg_entity = self;
2434             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2435             WriteEntity(MSG_ONE, self.enemy);
2436             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2437             self.movetype = MOVETYPE_NONE;
2438             accuracy_resend(self);
2439             }
2440             else
2441             {
2442             msg_entity = self;
2443             WriteByte(MSG_ONE, SVC_SETVIEW);
2444             WriteEntity(MSG_ONE, self.enemy);
2445             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2446             self.movetype = MOVETYPE_NONE;
2447             accuracy_resend(self);
2448
2449             if(!SpectateUpdate())
2450                 PutObserverInServer();
2451         }
2452         return 1;
2453         } else {
2454                 return 0;
2455         }
2456 }
2457
2458 /*
2459 =============
2460 ShowRespawnCountdown()
2461
2462 Update a respawn countdown display.
2463 =============
2464 */
2465 void ShowRespawnCountdown()
2466 {
2467         float number;
2468         if(self.deadflag == DEAD_NO) // just respawned?
2469                 return;
2470         else
2471         {
2472                 number = ceil(self.death_time - time);
2473                 if(number <= 0)
2474                         return;
2475                 if(number <= self.respawn_countdown)
2476                 {
2477                         self.respawn_countdown = number - 1;
2478                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2479                                 AnnounceTo(self, strcat(ftos(number), ""));
2480                 }
2481         }
2482 }
2483
2484 void LeaveSpectatorMode()
2485 {
2486         if(nJoinAllowed(1)) {
2487                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2488                         self.classname = "player";
2489
2490                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2491                                 JoinBestTeam(self, FALSE, TRUE);
2492
2493                         if(autocvar_g_campaign)
2494                                 campaign_bots_may_start = 1;
2495
2496                         PutClientInServer();
2497
2498                         if(self.classname == "player")
2499                                 bprint ("^4", self.netname, "^4 is playing now\n");
2500
2501                         if(!autocvar_g_campaign)
2502                                 centerprint(self,""); // clear MOTD
2503
2504                         return;
2505                 } else {
2506                         if (g_ca && self.caplayer) {
2507                         }       // do nothing
2508                         else
2509                                 stuffcmd(self,"menu_showteamselect\n");
2510                         return;
2511                 }
2512         }
2513         else {
2514                 //player may not join because of g_maxplayers is set
2515                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2516         }
2517 }
2518
2519 /**
2520  * Determines whether the player is allowed to join. This depends on cvar
2521  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2522  * it checks whether the number of currently playing players exceeds g_maxplayers.
2523  * @return int number of free slots for players, 0 if none
2524  */
2525 float nJoinAllowed(float includeMe) {
2526         if(self.team_forced < 0)
2527                 return FALSE; // forced spectators can never join
2528
2529         // TODO simplify this
2530         local entity e;
2531
2532         local float totalClients;
2533         FOR_EACH_CLIENT(e)
2534                 totalClients += 1;
2535
2536         if (!autocvar_g_maxplayers)
2537                 return maxclients - totalClients + includeMe;
2538
2539         local float currentlyPlaying;
2540         FOR_EACH_REALPLAYER(e)
2541                 currentlyPlaying += 1;
2542
2543         if(currentlyPlaying < autocvar_g_maxplayers)
2544                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2545
2546         return 0;
2547 }
2548
2549 /**
2550  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2551  * g_maxplayers_spectator_blocktime seconds
2552  */
2553 void checkSpectatorBlock() {
2554         if(self.classname == "spectator" || self.classname == "observer") {
2555                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2556                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2557                         dropclient(self);
2558                 }
2559         }
2560 }
2561
2562 void ObserverThink()
2563 {
2564         if (self.flags & FL_JUMPRELEASED) {
2565                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2566                         self.welcomemessage_time = 0;
2567                         self.flags &~= FL_JUMPRELEASED;
2568                         self.flags |= FL_SPAWNING;
2569                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2570                         self.welcomemessage_time = 0;
2571                         self.flags &~= FL_JUMPRELEASED;
2572                         if(SpectateNext() == 1) {
2573                                 self.classname = "spectator";
2574                         }
2575                 }
2576         } else {
2577                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2578                         self.flags |= FL_JUMPRELEASED;
2579                         if(self.flags & FL_SPAWNING)
2580                         {
2581                                 self.flags &~= FL_SPAWNING;
2582                                 LeaveSpectatorMode();
2583                                 return;
2584                         }
2585                 }
2586         }
2587         PrintWelcomeMessage(self);
2588 }
2589
2590 void SpectatorThink()
2591 {
2592         if (self.flags & FL_JUMPRELEASED) {
2593                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2594                         self.welcomemessage_time = 0;
2595                         self.flags &~= FL_JUMPRELEASED;
2596                         self.flags |= FL_SPAWNING;
2597                 } else if(self.BUTTON_ATCK) {
2598                         self.welcomemessage_time = 0;
2599                         self.flags &~= FL_JUMPRELEASED;
2600                         if(SpectateNext() == 1) {
2601                                 self.classname = "spectator";
2602                         } else {
2603                                 self.classname = "observer";
2604                                 PutClientInServer();
2605                         }
2606                 } else if (self.BUTTON_ATCK2) {
2607                         self.welcomemessage_time = 0;
2608                         self.flags &~= FL_JUMPRELEASED;
2609                         self.classname = "observer";
2610                         PutClientInServer();
2611                 } else {
2612                         if(!SpectateUpdate())
2613                                 PutObserverInServer();
2614                 }
2615         } else {
2616                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2617                         self.flags |= FL_JUMPRELEASED;
2618                         if(self.flags & FL_SPAWNING)
2619                         {
2620                                 self.flags &~= FL_SPAWNING;
2621                                 LeaveSpectatorMode();
2622                                 return;
2623                         }
2624                 }
2625                 if(!SpectateUpdate())
2626                         PutObserverInServer();
2627         }
2628
2629         PrintWelcomeMessage(self);
2630         self.flags |= FL_CLIENT | FL_NOTARGET;
2631 }
2632
2633 float ctf_usekey();
2634 void PlayerUseKey()
2635 {
2636         if(self.classname != "player")
2637                 return;
2638
2639         if(self.vehicle)
2640         {
2641         vehicles_exit(VHEF_NORMAL);
2642         return;
2643         }
2644
2645         // a use key was pressed; call handlers
2646         if(ctf_usekey())
2647                 return;
2648
2649         MUTATOR_CALLHOOK(PlayerUseKey);
2650 }
2651
2652 .float touchexplode_time;
2653
2654 /*
2655 =============
2656 PlayerPreThink
2657
2658 Called every frame for each client before the physics are run
2659 =============
2660 */
2661 .float usekeypressed;
2662 void() ctf_setstatus;
2663 void() nexball_setstatus;
2664 .float items_added;
2665 void PlayerPreThink (void)
2666 {
2667         WarpZone_PlayerPhysics_FixVAngle();
2668
2669         self.stat_game_starttime = game_starttime;
2670         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2671         self.stat_leadlimit = autocvar_leadlimit;
2672
2673         if(frametime)
2674         {
2675                 // physics frames: update anticheat stuff
2676                 anticheat_prethink();
2677         }
2678
2679         if(blockSpectators && frametime)
2680                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2681                 checkSpectatorBlock();
2682
2683         zoomstate_set = 0;
2684
2685         if(self.netname_previous != self.netname)
2686         {
2687                 if(autocvar_sv_eventlog)
2688                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2689                 if(self.netname_previous)
2690                         strunzone(self.netname_previous);
2691                 self.netname_previous = strzone(self.netname);
2692         }
2693
2694         // version nagging
2695         if(self.version_nagtime)
2696                 if(self.cvar_g_xonoticversion)
2697                         if(time > self.version_nagtime)
2698                         {
2699                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2700                                 {
2701                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2702                                         {
2703                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2704                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2705                                         }
2706                                         else
2707                                         {
2708                                                 float r;
2709                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2710                                                 if(r < 0)
2711                                                 {
2712                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2713                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2714                                                 }
2715                                                 else if(r > 0)
2716                                                 {
2717                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2718                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2719                                                 }
2720                                         }
2721                                 }
2722                                 self.version_nagtime = 0;
2723                         }
2724
2725         // GOD MODE info
2726         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2727         {
2728                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2729                 self.max_armorvalue = 0;
2730         }
2731
2732 #ifdef TETRIS
2733         if (TetrisPreFrame())
2734                 return;
2735 #endif
2736
2737         MUTATOR_CALLHOOK(PlayerPreThink);
2738
2739         if(self.BUTTON_USE && !self.usekeypressed)
2740                 PlayerUseKey();
2741         self.usekeypressed = self.BUTTON_USE;
2742
2743         if(self.classname == "player") {
2744 //              if(self.netname == "Wazat")
2745 //                      bprint(self.classname, "\n");
2746
2747                 CheckRules_Player();
2748
2749                 PrintWelcomeMessage(self);
2750
2751                 if (intermission_running)
2752                 {
2753                         IntermissionThink ();   // otherwise a button could be missed between
2754                         return;                                 // the think tics
2755                 }
2756
2757                 //don't allow the player to turn around while game is paused!
2758                 if(timeoutStatus == 2) {
2759                         // FIXME turn this into CSQC stuff
2760                         self.v_angle = self.lastV_angle;
2761                         self.angles = self.lastV_angle;
2762                         self.fixangle = TRUE;
2763                 }
2764
2765                 if(frametime)
2766                 {
2767                         if(self.health <= 0 && autocvar_g_deathglow)
2768                         {
2769                                 if(self.glowmod_x > 0)
2770                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2771                                 else
2772                                         self.glowmod_x = -1;
2773                                 if(self.glowmod_y > 0)
2774                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2775                                 else
2776                                         self.glowmod_y = -1;
2777                                 if(self.glowmod_z > 0)
2778                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2779                                 else
2780                                         self.glowmod_z = -1;
2781                         }
2782                         else
2783                         {
2784                                 // set weapon and player glowmod
2785                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2786
2787                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2788                                 {
2789                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2790                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2791                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2792
2793                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2794                                         {
2795                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2796                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2797                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2798                                         }
2799                                 }
2800                                 else
2801                                         self.weaponentity_glowmod = self.glowmod;
2802                         }
2803                         player_powerups();
2804                 }
2805
2806                 if (self.deadflag != DEAD_NO)
2807                 {
2808                         float button_pressed, force_respawn;
2809                         if(self.personal && g_race_qualifying)
2810                         {
2811                                 if(time > self.death_time)
2812                                 {
2813                                         self.death_time = time + 1; // only retry once a second
2814                                         respawn();
2815                                         self.impulse = 141;
2816                                 }
2817                         }
2818                         else
2819                         {
2820                                 if(frametime)
2821                                         player_anim();
2822                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2823                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2824                                 if (self.deadflag == DEAD_DYING)
2825                                 {
2826                                         if(force_respawn)
2827                                                 self.deadflag = DEAD_RESPAWNING;
2828                                         else if(!button_pressed)
2829                                                 self.deadflag = DEAD_DEAD;
2830                                 }
2831                                 else if (self.deadflag == DEAD_DEAD)
2832                                 {
2833                                         if(button_pressed)
2834                                                 self.deadflag = DEAD_RESPAWNABLE;
2835                                 }
2836                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2837                                 {
2838                                         if(!button_pressed)
2839                                                 self.deadflag = DEAD_RESPAWNING;
2840                                 }
2841                                 else if (self.deadflag == DEAD_RESPAWNING)
2842                                 {
2843                                         if(time > self.death_time)
2844                                         {
2845                                                 self.death_time = time + 1; // only retry once a second
2846                                                 respawn();
2847                                         }
2848                                 }
2849                                 ShowRespawnCountdown();
2850                         }
2851                         return;
2852                 }
2853
2854                 if(g_touchexplode)
2855                 if(time > self.touchexplode_time)
2856                 if(self.classname == "player")
2857                 if(self.deadflag == DEAD_NO)
2858                 if not(IS_INDEPENDENT_PLAYER(self))
2859                 FOR_EACH_PLAYER(other) if(self != other)
2860                 {
2861                         if(time > other.touchexplode_time)
2862                         if(other.deadflag == DEAD_NO)
2863                         if not(IS_INDEPENDENT_PLAYER(other))
2864                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2865                         {
2866                                 PlayerTouchExplode(self, other);
2867                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2868                         }
2869                 }
2870
2871                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2872                 {
2873                         vector dist;
2874
2875                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2876                         dist = self.prevorigin - self.origin;
2877                         dist_z = 0;
2878                         self.lms_traveled_distance += fabs(vlen(dist));
2879
2880                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2881                         {
2882                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2883                                 self.lms_traveled_distance = 0;
2884                         }
2885
2886                         if(time > self.lms_nextcheck)
2887                         {
2888                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2889                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2890                                 {
2891                                         centerprint(self, autocvar_g_lms_campcheck_message);
2892                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2893                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2894                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2895                                 }
2896                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2897                                 self.lms_traveled_distance = 0;
2898                         }
2899                 }
2900
2901                 self.prevorigin = self.origin;
2902
2903                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2904                 {
2905                         if (!self.crouch)
2906                         {
2907                                 self.crouch = TRUE;
2908                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2909                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2910                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2911                         }
2912                 }
2913                 else
2914                 {
2915                         if (self.crouch)
2916                         {
2917                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2918                                 if (!trace_startsolid)
2919                                 {
2920                                         self.crouch = FALSE;
2921                                         self.view_ofs = PL_VIEW_OFS;
2922                                         setsize (self, PL_MIN, PL_MAX);
2923                                 }
2924                         }
2925                 }
2926
2927                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2928                 {
2929                         if(self.bloodloss_timer < time)
2930                         {
2931                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2932                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2933                         }
2934                 }
2935
2936                 FixPlayermodel();
2937
2938                 GrapplingHookFrame();
2939
2940                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2941                 //if(frametime)
2942                 {
2943                         self.items &~= self.items_added;
2944
2945                         W_WeaponFrame();
2946
2947                         self.items_added = 0;
2948                         if(self.items & IT_JETPACK)
2949                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2950                                         self.items_added |= IT_FUEL;
2951
2952                         self.items |= self.items_added;
2953                 }
2954
2955                 player_regen();
2956
2957                 // rot nex charge to the charge limit
2958                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2959                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2960
2961                 if(frametime)
2962                         player_anim();
2963
2964                 if (g_minstagib)
2965                         minstagib_ammocheck();
2966
2967                 if(g_ctf)
2968                         ctf_setstatus();
2969
2970                 if(g_nexball)
2971                         nexball_setstatus();
2972
2973                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2974
2975                 //self.angles_y=self.v_angle_y + 90;   // temp
2976         } else if(gameover) {
2977                 if (intermission_running)
2978                         IntermissionThink ();   // otherwise a button could be missed between
2979                 return;
2980         } else if(self.classname == "observer") {
2981                 ObserverThink();
2982         } else if(self.classname == "spectator") {
2983                 SpectatorThink();
2984         }
2985
2986         if(!zoomstate_set)
2987                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2988
2989         float oldspectatee_status;
2990         oldspectatee_status = self.spectatee_status;
2991         if(self.classname == "spectator")
2992                 self.spectatee_status = num_for_edict(self.enemy);
2993         else if(self.classname == "observer")
2994                 self.spectatee_status = num_for_edict(self);
2995         else
2996                 self.spectatee_status = 0;
2997         if(self.spectatee_status != oldspectatee_status)
2998         {
2999                 ClientData_Touch(self);
3000                 if(g_race || g_cts)
3001                         race_InitSpectator();
3002         }
3003
3004         if(self.teamkill_soundtime)
3005         if(time > self.teamkill_soundtime)
3006         {
3007                 self.teamkill_soundtime = 0;
3008
3009                 entity oldpusher, oldself;
3010
3011                 oldself = self; self = self.teamkill_soundsource;
3012                 oldpusher = self.pusher; self.pusher = oldself;
3013
3014                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3015
3016                 self.pusher = oldpusher;
3017                 self = oldself;
3018         }
3019
3020         if(self.taunt_soundtime)
3021         if(time > self.taunt_soundtime)
3022         {
3023                 self.taunt_soundtime = 0;
3024                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
3025         }
3026
3027         target_voicescript_next(self);
3028
3029         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3030         if(!self.weapon)
3031                 self.clip_load = self.clip_size = 0;
3032 }
3033
3034 float isInvisibleString(string s)
3035 {
3036         float i, n, c;
3037         s = strdecolorize(s);
3038         for((i = 0), (n = strlen(s)); i < n; ++i)
3039         {
3040                 c = str2chr(s, i);
3041                 switch(c)
3042                 {
3043                         case 0:
3044                         case 32: // space
3045                                 break;
3046                         case 192: // charmap space
3047                                 if (!autocvar_utf8_enable)
3048                                         break;
3049                                 return FALSE;
3050                         case 160: // space in unicode fonts
3051                         case 0xE000 + 192: // utf8 charmap space
3052                                 if (autocvar_utf8_enable)
3053                                         break;
3054                         default:
3055                                 return FALSE;
3056                 }
3057         }
3058         return TRUE;
3059 }
3060
3061 /*
3062 =============
3063 PlayerPostThink
3064
3065 Called every frame for each client after the physics are run
3066 =============
3067 */
3068 .float idlekick_lasttimeleft;
3069 .entity showheadshotbbox;
3070 void showheadshotbbox_think()
3071 {
3072         if(self.owner.showheadshotbbox != self)
3073         {
3074                 remove(self);
3075                 return;
3076         }
3077         self.nextthink = time;
3078         setorigin(self, self.owner.origin);
3079         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3080 }
3081 void PlayerPostThink (void)
3082 {
3083         // Savage: Check for nameless players
3084         if (isInvisibleString(self.netname)) {
3085                 self.netname = "Player";
3086                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3087         }
3088
3089         if(sv_maxidle && frametime)
3090         {
3091                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3092                 float timeleft;
3093                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3094                 if(timeleft <= 0)
3095                 {
3096                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3097                         AnnounceTo(self, "terminated");
3098                         dropclient(self);
3099                         return;
3100                 }
3101                 else if(timeleft <= 10)
3102                 {
3103                         if(timeleft != self.idlekick_lasttimeleft)
3104                         {
3105                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3106                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3107                         }
3108                 }
3109                 else
3110                 {
3111                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3112                 }
3113                 self.idlekick_lasttimeleft = timeleft;
3114         }
3115
3116 #ifdef TETRIS
3117         if(self.impulse == 100)
3118                 ImpulseCommands();
3119         if (TetrisPostFrame())
3120                 return;
3121 #endif
3122
3123         CheatFrame();
3124
3125         if(self.classname == "player") {
3126                 CheckRules_Player();
3127                 UpdateChatBubble();
3128                 if (self.impulse)
3129                         ImpulseCommands();
3130                 if (intermission_running)
3131                         return;         // intermission or finale
3132                 GetPressedKeys();
3133         } else if (self.classname == "observer") {
3134                 //do nothing
3135         } else if (self.classname == "spectator") {
3136                 //do nothing
3137         }
3138
3139         /*
3140         float i;
3141         for(i = 0; i < 1000; ++i)
3142         {
3143                 vector end;
3144                 end = self.origin + '0 0 1024' + 512 * randomvec();
3145                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3146                 if(trace_fraction < 1)
3147                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3148                 {
3149                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3150                         break;
3151                 }
3152         }
3153         */
3154
3155         Arena_Warmup();
3156
3157         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3158
3159         if(self.waypointsprite_attachedforcarrier)
3160                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3161
3162         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3163         {
3164                 if(!self.showheadshotbbox)
3165                 {
3166                         self.showheadshotbbox = spawn();
3167                         self.showheadshotbbox.classname = "headshotbbox";
3168                         self.showheadshotbbox.owner = self;
3169                         self.showheadshotbbox.think = showheadshotbbox_think;
3170                         self.showheadshotbbox.nextthink = time;
3171                         self = self.showheadshotbbox;
3172                         self.think();
3173                         self = self.owner;
3174                 }
3175         }
3176         else
3177         {
3178                 if(self.showheadshotbbox)
3179                         remove(self.showheadshotbbox);
3180         }
3181
3182         playerdemo_write();
3183
3184         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3185         {
3186                 if(!self.stored_netname)
3187                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3188                 if(self.stored_netname != self.netname)
3189                 {
3190                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3191                         strunzone(self.stored_netname);
3192                         self.stored_netname = strzone(self.netname);
3193                 }
3194         }
3195
3196         /*
3197         if(g_race)
3198                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3199         */
3200 }