qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(cvar("spawn_debugview"))
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > cvar("g_spawn_furthest"))
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(cvar("spawn_debugview"))
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(cvar("spawn_debug"))
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(cvar("sv_servermodelsonly"))
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602         MUTATOR_CALLHOOK(MakePlayerObserver);
 603
 604         Portal_ClearAll(self);
 605
 606         if(self.flagcarried)
 607                 DropFlag(self.flagcarried, world, world);
 608
 609         if(self.ballcarried)
 610                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 611
 612         WaypointSprite_PlayerDead();
 613
 614         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 615                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 616
 617         if(self.killcount != -666) {
 618                 if(g_lms) {
 619                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 620                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 621                         else
 622                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 623                 } else
 624                         bprint ("^4", self.netname, "^4 is spectating now\n");
 625
 626                 if(self.just_joined == FALSE) {
 627                         LogTeamchange(self.playerid, -1, 4);
 628                 } else
 629                         self.just_joined = FALSE;
 630         }
 631
 632         PlayerScore_Clear(self); // clear scores when needed
 633
 634         accuracy_resend(self);
 635
 636         self.spectatortime = time;
 637
 638         self.classname = "observer";
 639         self.iscreature = FALSE;
 640         self.health = -666;
 641         self.takedamage = DAMAGE_NO;
 642         self.solid = SOLID_NOT;
 643         self.movetype = MOVETYPE_NOCLIP;
 644         self.flags = FL_CLIENT | FL_NOTARGET;
 645         self.armorvalue = 666;
 646         self.effects = 0;
 647         self.armorvalue = cvar("g_balance_armor_start");
 648         self.pauserotarmor_finished = 0;
 649         self.pauserothealth_finished = 0;
 650         self.pauseregen_finished = 0;
 651         self.damageforcescale = 0;
 652         self.death_time = 0;
 653         self.dead_frame = 0;
 654         self.alpha = 0;
 655         self.scale = 0;
 656         self.fade_time = 0;
 657         self.pain_frame = 0;
 658         self.pain_finished = 0;
 659         self.strength_finished = 0;
 660         self.invincible_finished = 0;
 661         self.pushltime = 0;
 662         self.think = SUB_Null;
 663         self.nextthink = 0;
 664         self.hook_time = 0;
 665         self.runes = 0;
 666         self.deadflag = DEAD_NO;
 667         self.angles = spot.angles;
 668         self.angles_z = 0;
 669         self.fixangle = TRUE;
 670         self.crouch = FALSE;
 671
 672         self.view_ofs = PL_VIEW_OFS;
 673         setorigin (self, spot.origin);
 674         setsize (self, '0 0 0', '0 0 0');
 675         self.prevorigin = self.origin;
 676         self.items = 0;
 677         self.weapons = 0;
 678         self.model = "";
 679         FixPlayermodel();
 680         self.model = "";
 681         self.modelindex = 0;
 682         self.weapon = 0;
 683         self.weaponmodel = "";
 684         self.weaponentity = world;
 685         self.exteriorweaponentity = world;
 686         self.killcount = -666;
 687         self.velocity = '0 0 0';
 688         self.avelocity = '0 0 0';
 689         self.punchangle = '0 0 0';
 690         self.punchvector = '0 0 0';
 691         self.oldvelocity = self.velocity;
 692         self.fire_endtime = -1;
 693
 694         if(sv_loddistance1)
 695                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 696
 697         if(g_arena)
 698         {
 699                 if(self.version_mismatch)
 700                 {
 701                         Spawnqueue_Unmark(self);
 702                         Spawnqueue_Remove(self);
 703                 }
 704                 else
 705                 {
 706                         Spawnqueue_Insert(self);
 707                 }
 708         }
 709         else if(g_lms)
 710         {
 711                 // Only if the player cannot play at all
 712                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 713                         self.frags = FRAGS_SPECTATOR;
 714                 else
 715                         self.frags = FRAGS_LMS_LOSER;
 716         }
 717         else
 718                 self.frags = FRAGS_SPECTATOR;
 719 }
 720
 721 float RestrictSkin(float s)
 722 {
 723         if(!teams_matter)
 724                 return s;
 725         if(s == 6)
 726                 return 6;
 727         return mod(s, 3);
 728 }
 729
 730 void FixPlayermodel()
 731 {
 732         local string defaultmodel;
 733         local float defaultskin, chmdl, oldskin;
 734         local vector m1, m2;
 735
 736         defaultmodel = "";
 737
 738         if(cvar("sv_defaultcharacter") == 1) {
 739                 defaultskin = 0;
 740
 741                 if(teams_matter)
 742                 {
 743                         string s;
 744                         s = Team_ColorNameLowerCase(self.team);
 745                         if(s != "neutral")
 746                         {
 747                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 748                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 749                         }
 750                 }
 751
 752                 if(defaultmodel == "")
 753                 {
 754                         defaultmodel = cvar_string("sv_defaultplayermodel");
 755                         defaultskin = cvar("sv_defaultplayerskin");
 756                 }
 757         }
 758
 759         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 760         {
 761                 if(self.model != "")
 762                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 763                 self.model = ""; // force the != checks to return true
 764         }
 765
 766         if(defaultmodel != "")
 767         {
 768                 if (defaultmodel != self.model)
 769                 {
 770                         m1 = self.mins;
 771                         m2 = self.maxs;
 772                         setmodel_lod (self, defaultmodel);
 773                         setsize (self, m1, m2);
 774                         chmdl = TRUE;
 775                 }
 776
 777                 oldskin = self.skinindex;
 778                 self.skinindex = defaultskin;
 779         } else {
 780                 if (self.playermodel != self.model || self.playermodel == "")
 781                 {
 782                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 783                         m1 = self.mins;
 784                         m2 = self.maxs;
 785                         setmodel_lod (self, self.playermodel);
 786                         setsize (self, m1, m2);
 787                         chmdl = TRUE;
 788                 }
 789
 790                 oldskin = self.skinindex;
 791                 self.skinindex = RestrictSkin(stof(self.playerskin));
 792         }
 793
 794         if(chmdl || oldskin != self.skinindex)
 795                 self.species = player_getspecies(); // model or skin has changed
 796
 797         if(!teams_matter)
 798                 if(strlen(cvar_string("sv_defaultplayercolors")))
 799                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 800                                 setcolor(self, cvar("sv_defaultplayercolors"));
 801 }
 802
 803 void PlayerTouchExplode(entity p1, entity p2)
 804 {
 805         vector org;
 806         org = (p1.origin + p2.origin) * 0.5;
 807         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 808
 809         te_explosion(org);
 810
 811         entity e;
 812         e = spawn();
 813         setorigin(e, org);
 814         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 815         remove(e);
 816 }
 817
 818 /*
 819 =============
 820 PutClientInServer
 821
 822 Called when a client spawns in the server
 823 =============
 824 */
 825 //void() ctf_playerchanged;
 826 void PutClientInServer (void)
 827 {
 828         if(clienttype(self) == CLIENTTYPE_BOT)
 829         {
 830                 self.classname = "player";
 831         }
 832         else if(clienttype(self) == CLIENTTYPE_REAL)
 833         {
 834                 msg_entity = self;
 835                 WriteByte(MSG_ONE, SVC_SETVIEW);
 836                 WriteEntity(MSG_ONE, self);
 837         }
 838
 839         // player is dead and becomes observer
 840         // FIXME fix LMS scoring for new system
 841         if(g_lms)
 842         {
 843                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 844                         self.classname = "observer";
 845         }
 846
 847         if(g_arena || (g_ca && !allowed_to_spawn))
 848         if(!self.spawned)
 849                 self.classname = "observer";
 850
 851         if(gameover)
 852                 self.classname = "observer";
 853
 854         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 855                 entity spot, oldself;
 856                 float j;
 857
 858                 accuracy_resend(self);
 859
 860                 if(self.team < 0)
 861                         JoinBestTeam(self, FALSE, TRUE);
 862
 863                 race_PreSpawn();
 864
 865                 spot = SelectSpawnPoint (FALSE);
 866                 if(!spot)
 867                 {
 868                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 869                         return; // spawn failed
 870                 }
 871
 872                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 873
 874                 self.classname = "player";
 875                 self.wasplayer = TRUE;
 876                 self.iscreature = TRUE;
 877                 self.movetype = MOVETYPE_WALK;
 878                 self.solid = SOLID_SLIDEBOX;
 879                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 880                 if(cvar("g_playerclip_collisions"))
 881                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 882                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 883                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 884                 self.frags = FRAGS_PLAYER;
 885                 if(independent_players)
 886                         MAKE_INDEPENDENT_PLAYER(self);
 887                 self.flags = FL_CLIENT;
 888                 self.takedamage = DAMAGE_AIM;
 889                 if(g_minstagib)
 890                         self.effects = EF_FULLBRIGHT;
 891                 else
 892                         self.effects = 0;
 893                 self.air_finished = time + 12;
 894                 self.dmg = 2;
 895                 if(cvar("g_balance_nex_charge"))
 896                 {
 897                         if(cvar("g_balance_nex_secondary_charge_pool"))
 898                                 self.nex_charge_pool_ammo = 1;
 899                         self.nex_charge = cvar("g_balance_nex_charge_start");
 900                 }
 901
 902                 if(inWarmupStage)
 903                 {
 904                         self.ammo_shells = warmup_start_ammo_shells;
 905                         self.ammo_nails = warmup_start_ammo_nails;
 906                         self.ammo_rockets = warmup_start_ammo_rockets;
 907                         self.ammo_cells = warmup_start_ammo_cells;
 908                         self.ammo_fuel = warmup_start_ammo_fuel;
 909                         self.health = warmup_start_health;
 910                         self.armorvalue = warmup_start_armorvalue;
 911                         self.weapons = warmup_start_weapons;
 912                 }
 913                 else
 914                 {
 915                         self.ammo_shells = start_ammo_shells;
 916                         self.ammo_nails = start_ammo_nails;
 917                         self.ammo_rockets = start_ammo_rockets;
 918                         self.ammo_cells = start_ammo_cells;
 919                         self.ammo_fuel = start_ammo_fuel;
 920                         self.health = start_health;
 921                         self.armorvalue = start_armorvalue;
 922                         self.weapons = start_weapons;
 923                 }
 924
 925                 if(g_weaponarena_random)
 926                 {
 927                         if(g_weaponarena_random_with_laser)
 928                                 self.weapons &~= WEPBIT_LASER;
 929                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 930                         if(g_weaponarena_random_with_laser)
 931                                 self.weapons |= WEPBIT_LASER;
 932                 }
 933
 934                 self.items = start_items;
 935                 self.jump_interval = time;
 936
 937                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 938                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 939                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 940                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 941                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 942                 //extend the pause of rotting if client was reset at the beginning of the countdown
 943                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 944                         self.spawnshieldtime += game_starttime - time;
 945                         self.pauserotarmor_finished += game_starttime - time;
 946                         self.pauserothealth_finished += game_starttime - time;
 947                         self.pauseregen_finished += game_starttime - time;
 948                 }
 949                 self.damageforcescale = 2;
 950                 self.death_time = 0;
 951                 self.dead_frame = 0;
 952                 self.alpha = 0;
 953                 self.scale = 0;
 954                 self.fade_time = 0;
 955                 self.pain_frame = 0;
 956                 self.pain_finished = 0;
 957                 self.strength_finished = 0;
 958                 self.invincible_finished = 0;
 959                 self.pushltime = 0;
 960                 // players have no think function
 961                 self.think = SUB_Null;
 962                 self.nextthink = 0;
 963                 self.hook_time = 0;
 964                 self.dmg_team = 0;
 965                 self.ballistics_density = cvar("g_ballistics_density_player");
 966
 967                 self.metertime = 0;
 968
 969                 self.runes = 0;
 970
 971                 self.deadflag = DEAD_NO;
 972
 973                 self.angles = spot.angles;
 974
 975                 self.angles_z = 0; // never spawn tilted even if the spot says to
 976                 self.fixangle = TRUE; // turn this way immediately
 977                 self.velocity = '0 0 0';
 978                 self.avelocity = '0 0 0';
 979                 self.punchangle = '0 0 0';
 980                 self.punchvector = '0 0 0';
 981                 self.oldvelocity = self.velocity;
 982                 self.fire_endtime = -1;
 983
 984                 msg_entity = self;
 985                 WRITESPECTATABLE_MSG_ONE({
 986                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 987                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 988                 });
 989
 990                 if(sv_loddistance1)
 991                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 992
 993                 self.model = "";
 994                 FixPlayermodel();
 995
 996                 self.crouch = FALSE;
 997                 self.view_ofs = PL_VIEW_OFS;
 998                 setsize (self, PL_MIN, PL_MAX);
 999                 self.spawnorigin = spot.origin;
1000                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1001                 // don't reset back to last position, even if new position is stuck in solid
1002                 self.oldorigin = self.origin;
1003                 self.prevorigin = self.origin;
1004                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1005
1006                 if(g_arena)
1007                 {
1008                         Spawnqueue_Remove(self);
1009                         Spawnqueue_Mark(self);
1010                 }
1011
1012                 else if(g_ca)
1013                         self.caplayer = 1;
1014
1015                 self.event_damage = PlayerDamage;
1016
1017                 self.bot_attack = TRUE;
1018
1019                 self.statdraintime = time + 5;
1020                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1021
1022                 if(self.killcount == -666) {
1023                         PlayerScore_Clear(self);
1024                         self.killcount = 0;
1025                 }
1026
1027                 self.cnt = WEP_LASER;
1028
1029                 CL_SpawnWeaponentity();
1030                 self.alpha = default_player_alpha;
1031                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1032                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1033
1034                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1035                 self.lms_traveled_distance = 0;
1036                 self.speedrunning = FALSE;
1037
1038                 race_PostSpawn(spot);
1039
1040                 if(cvar("spawn_debug"))
1041                 {
1042                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1043                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1044                 }
1045
1046                 //stuffcmd(self, "chase_active 0");
1047                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1048
1049                 if (cvar("g_spawnsound"))
1050                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1051
1052                 if(g_assault) {
1053                         if(self.team == assault_attacker_team)
1054                                 centerprint(self, "You are attacking!");
1055                         else
1056                                 centerprint(self, "You are defending!");
1057                 }
1058
1059                 target_voicescript_clear(self);
1060
1061                 // reset fields the weapons may use
1062                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1063                         weapon_action(j, WR_RESETPLAYER);
1064
1065                 oldself = self;
1066                 self = spot;
1067                         activator = oldself;
1068                                 SUB_UseTargets();
1069                         activator = world;
1070                 self = oldself;
1071
1072                 MUTATOR_CALLHOOK(PlayerSpawn);
1073
1074                 self.switchweapon = w_getbestweapon(self);
1075                 self.cnt = self.switchweapon;
1076                 self.weapon = 0;
1077         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1078                 PutObserverInServer ();
1079         }
1080
1081         //if(g_ctf)
1082         //      ctf_playerchanged();
1083 }
1084
1085 .float ebouncefactor, ebouncestop; // electro's values
1086 // TODO do we need all these fields, or should we stop autodetecting runtime
1087 // changes and just have a console command to update this?
1088 float ClientInit_SendEntity(entity to, float sf)
1089 {
1090         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1091         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1092         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1099         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1100         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1104         if(sv_foginterval && world.fog != "")
1105                 WriteString(MSG_ENTITY, world.fog);
1106         else
1107                 WriteString(MSG_ENTITY, "");
1108         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1109         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1110         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1111         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1112         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1113         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1114         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1115         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1116         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1117         return TRUE;
1118 }
1119
1120 void ClientInit_CheckUpdate()
1121 {
1122         self.nextthink = time;
1123         if(self.count != cvar("g_balance_armor_blockpercent"))
1124         {
1125                 self.count = cvar("g_balance_armor_blockpercent");
1126                 self.SendFlags |= 1;
1127         }
1128         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1129         {
1130                 self.cnt = cvar("g_balance_weaponswitchdelay");
1131                 self.SendFlags |= 1;
1132         }
1133         if(self.bouncefactor != cvar("g_balance_grenadelauncher_bouncefactor"))
1134         {
1135                 self.bouncefactor = cvar("g_balance_grenadelauncher_bouncefactor");
1136                 self.SendFlags |= 1;
1137         }
1138         if(self.bouncestop != cvar("g_balance_grenadelauncher_bouncestop"))
1139         {
1140                 self.bouncestop = cvar("g_balance_grenadelauncher_bouncestop");
1141                 self.SendFlags |= 1;
1142         }
1143         if(self.ebouncefactor != cvar("g_balance_electro_secondary_bouncefactor"))
1144         {
1145                 self.ebouncefactor = cvar("g_balance_electro_secondary_bouncefactor");
1146                 self.SendFlags |= 1;
1147         }
1148         if(self.ebouncestop != cvar("g_balance_electro_secondary_bouncestop"))
1149         {
1150                 self.ebouncestop = cvar("g_balance_electro_secondary_bouncestop");
1151                 self.SendFlags |= 1;
1152         }
1153 }
1154
1155 void ClientInit_Spawn()
1156 {
1157         entity o;
1158         entity e;
1159         e = spawn();
1160         e.classname = "clientinit";
1161         e.think = ClientInit_CheckUpdate;
1162         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1163
1164         o = self;
1165         self = e;
1166         ClientInit_CheckUpdate();
1167         self = o;
1168 }
1169
1170 /*
1171 =============
1172 SetNewParms
1173 =============
1174 */
1175 void SetNewParms (void)
1176 {
1177         // initialize parms for a new player
1178         parm1 = -(86400 * 366);
1179 }
1180
1181 /*
1182 =============
1183 SetChangeParms
1184 =============
1185 */
1186 void SetChangeParms (void)
1187 {
1188         // save parms for level change
1189         parm1 = self.parm_idlesince - time;
1190 }
1191
1192 /*
1193 =============
1194 DecodeLevelParms
1195 =============
1196 */
1197 void DecodeLevelParms (void)
1198 {
1199         // load parms
1200         self.parm_idlesince = parm1;
1201         if(self.parm_idlesince == -(86400 * 366))
1202                 self.parm_idlesince = time;
1203
1204         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1205         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1206 }
1207
1208 /*
1209 =============
1210 ClientKill
1211
1212 Called when a client types 'kill' in the console
1213 =============
1214 */
1215
1216 void ClientKill_Now_TeamChange()
1217 {
1218         if(self.killindicator_teamchange == -1)
1219         {
1220                 self.team = -1;
1221                 JoinBestTeam( self, FALSE, FALSE );
1222         }
1223         else
1224                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1225 }
1226
1227 void ClientKill_Now()
1228 {
1229         if(self.killindicator_teamchange)
1230                 ClientKill_Now_TeamChange();
1231
1232         // in any case:
1233         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1234
1235         if(self.killindicator)
1236         {
1237                 dprint("Cleaned up after a leaked kill indicator.\n");
1238                 remove(self.killindicator);
1239                 self.killindicator = world;
1240         }
1241 }
1242 void KillIndicator_Think()
1243 {
1244         if (!self.owner.modelindex)
1245         {
1246                 self.owner.killindicator = world;
1247                 remove(self);
1248                 return;
1249         }
1250
1251         if(self.cnt <= 0)
1252         {
1253                 self = self.owner;
1254                 ClientKill_Now(); // no oldself needed
1255                 return;
1256         }
1257         else
1258         {
1259                 if(self.cnt <= 10)
1260                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1261                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1262                 {
1263                         if(self.cnt <= 10)
1264                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1265                         if(self.owner.killindicator_teamchange)
1266                         {
1267                                 if(self.owner.killindicator_teamchange == -1)
1268                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1269                                 else
1270                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1271                         }
1272                         else
1273                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1274                 }
1275                 self.nextthink = time + 1;
1276                 self.cnt -= 1;
1277         }
1278 }
1279
1280 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1281 {
1282         float killtime;
1283         entity e;
1284         killtime = cvar("g_balance_kill_delay");
1285
1286         if(g_race_qualifying)
1287                 killtime = 0;
1288
1289         self.killindicator_teamchange = targetteam;
1290
1291         if(!self.killindicator)
1292         {
1293                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1294                 {
1295                         ClientKill_Now();
1296                 }
1297                 else
1298                 {
1299                         self.killindicator = spawn();
1300                         self.killindicator.owner = self;
1301                         self.killindicator.scale = 0.5;
1302                         setattachment(self.killindicator, self, "");
1303                         setorigin(self.killindicator, '0 0 52');
1304                         self.killindicator.think = KillIndicator_Think;
1305                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1306                         self.killindicator.cnt = ceil(killtime);
1307                         self.killindicator.count = bound(0, ceil(killtime), 10);
1308                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1309
1310                         for(e = world; (e = find(e, classname, "body")) != world; )
1311                         {
1312                                 if(e.enemy != self)
1313                                         continue;
1314                                 e.killindicator = spawn();
1315                                 e.killindicator.owner = e;
1316                                 e.killindicator.scale = 0.5;
1317                                 setattachment(e.killindicator, e, "");
1318                                 setorigin(e.killindicator, '0 0 52');
1319                                 e.killindicator.think = KillIndicator_Think;
1320                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1321                                 e.killindicator.cnt = ceil(killtime);
1322                         }
1323                         self.lip = 0;
1324                 }
1325         }
1326         if(self.killindicator)
1327         {
1328                 if(targetteam)
1329                         self.killindicator.colormod = TeamColor(targetteam);
1330                 else
1331                         self.killindicator.colormod = '0 0 0';
1332         }
1333 }
1334
1335 void ClientKill (void)
1336 {
1337         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1338         {
1339                 // do nothing
1340         }
1341         else
1342                 ClientKill_TeamChange(0);
1343 }
1344
1345 void CTS_ClientKill_Think (void)
1346 {
1347         self = self.owner; // set self to the player to be killed
1348         sprint(self, "^1You were killed in order to prevent cheating!");
1349         ClientKill_Now();
1350 }
1351
1352 void CTS_ClientKill (float t) // silent version of ClientKill
1353 {
1354         entity e;
1355         e = spawn();
1356         e.owner = self;
1357         e.think = CTS_ClientKill_Think;
1358         e.nextthink = t;
1359 }
1360
1361 void DoTeamChange(float destteam)
1362 {
1363         float t, c0;
1364         if(!teams_matter)
1365         {
1366                 if(destteam >= 0)
1367                         SetPlayerColors(self, destteam);
1368                 return;
1369         }
1370         if(self.classname == "player")
1371         if(destteam == -1)
1372         {
1373                 CheckAllowedTeams(self);
1374                 t = FindSmallestTeam(self, TRUE);
1375                 switch(self.team)
1376                 {
1377                         case COLOR_TEAM1: c0 = c1; break;
1378                         case COLOR_TEAM2: c0 = c2; break;
1379                         case COLOR_TEAM3: c0 = c3; break;
1380                         case COLOR_TEAM4: c0 = c4; break;
1381                         default:          c0 = 999;
1382                 }
1383                 switch(t)
1384                 {
1385                         case 1:
1386                                 if(c0 > c1)
1387                                         destteam = COLOR_TEAM1;
1388                                 break;
1389                         case 2:
1390                                 if(c0 > c2)
1391                                         destteam = COLOR_TEAM2;
1392                                 break;
1393                         case 3:
1394                                 if(c0 > c3)
1395                                         destteam = COLOR_TEAM3;
1396                                 break;
1397                         case 4:
1398                                 if(c0 > c4)
1399                                         destteam = COLOR_TEAM4;
1400                                 break;
1401                 }
1402                 if(destteam == -1)
1403                         return;
1404         }
1405         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1406                 return;
1407         ClientKill_TeamChange(destteam);
1408 }
1409
1410 void FixClientCvars(entity e)
1411 {
1412         // send prediction settings to the client
1413         stuffcmd(e, "\nin_bindmap 0 0\n");
1414         if(g_race || g_cts)
1415                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1416         if(cvar("g_antilag") == 3) // client side hitscan
1417                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1418         if(sv_gentle)
1419                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1420         /*
1421          * we no longer need to stuff this. Remove this comment block if you feel
1422          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1423         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1424         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1425         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1426         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1427         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1428         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1429         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1430         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1431         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1432         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1433         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1434         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1435         stuffcmd(e, "cl_movement_edgefriction 1\n");
1436          */
1437 }
1438
1439 float PlayerInIDList(entity p, string idlist)
1440 {
1441         float n, i;
1442         string s;
1443
1444         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1445         if not(p.crypto_idfp)
1446                 return 0;
1447
1448         // this function allows abbreviated player IDs too!
1449         n = tokenize_console(idlist);
1450         for(i = 0; i < n; ++i)
1451         {
1452                 s = argv(i);
1453                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1454                         return 1;
1455         }
1456
1457         return 0;
1458 }
1459
1460 /*
1461 =============
1462 ClientConnect
1463
1464 Called when a client connects to the server
1465 =============
1466 */
1467 //void ctf_clientconnect();
1468 string ColoredTeamName(float t);
1469 void DecodeLevelParms (void);
1470 //void dom_player_join_team(entity pl);
1471 void ClientConnect (void)
1472 {
1473         float t;
1474
1475         if(self.flags & FL_CLIENT)
1476         {
1477                 print("Warning: ClientConnect, but already connected!\n");
1478                 return;
1479         }
1480
1481         if(Ban_MaybeEnforceBan(self))
1482                 return;
1483
1484         DecodeLevelParms();
1485
1486 #ifdef WATERMARK
1487         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1488 #endif
1489
1490         self.classname = "player_joining";
1491
1492         self.flags = FL_CLIENT;
1493         self.version_nagtime = time + 10 + random() * 10;
1494
1495         if(player_count<0)
1496         {
1497                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1498                 player_count = 0;
1499         }
1500
1501         PlayerScore_Attach(self);
1502         ClientData_Attach();
1503
1504         bot_clientconnect();
1505
1506         playerdemo_init();
1507
1508         anticheat_init();
1509
1510         race_PreSpawnObserver();
1511
1512         //if(g_domination)
1513         //      dom_player_join_team(self);
1514
1515         // identify the right forced team
1516         if(PlayerInIDList(self, cvar_string("g_forced_team_red")))
1517                 self.team_forced = COLOR_TEAM1;
1518         else if(PlayerInIDList(self, cvar_string("g_forced_team_blue")))
1519                 self.team_forced = COLOR_TEAM2;
1520         else if(PlayerInIDList(self, cvar_string("g_forced_team_yellow")))
1521                 self.team_forced = COLOR_TEAM3;
1522         else if(PlayerInIDList(self, cvar_string("g_forced_team_pink")))
1523                 self.team_forced = COLOR_TEAM4;
1524         else if(cvar_string("g_forced_team_otherwise") == "red")
1525                 self.team_forced = COLOR_TEAM1;
1526         else if(cvar_string("g_forced_team_otherwise") == "blue")
1527                 self.team_forced = COLOR_TEAM2;
1528         else if(cvar_string("g_forced_team_otherwise") == "yellow")
1529                 self.team_forced = COLOR_TEAM3;
1530         else if(cvar_string("g_forced_team_otherwise") == "pink")
1531                 self.team_forced = COLOR_TEAM4;
1532         else if(cvar_string("g_forced_team_otherwise") == "spectate")
1533                 self.team_forced = -1;
1534         else if(cvar_string("g_forced_team_otherwise") == "spectator")
1535                 self.team_forced = -1;
1536         else
1537                 self.team_forced = 0;
1538
1539         if(!teams_matter)
1540                 if(self.team_forced > 0)
1541                         self.team_forced = 0;
1542
1543         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1544
1545         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign") || self.team_forced < 0) {
1546                 self.classname = "observer";
1547         } else {
1548                 if(teams_matter)
1549                 {
1550                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1551                         {
1552                                 self.classname = "player";
1553                                 campaign_bots_may_start = 1;
1554                         }
1555                         else
1556                         {
1557                                 self.classname = "observer"; // do it anyway
1558                         }
1559                 }
1560                 else
1561                 {
1562                         self.classname = "player";
1563                         campaign_bots_may_start = 1;
1564                 }
1565         }
1566
1567         self.playerid = (playerid_last = playerid_last + 1);
1568
1569         if(cvar("sv_eventlog"))
1570                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1571
1572         LogTeamchange(self.playerid, self.team, 1);
1573
1574         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1575
1576         self.netname_previous = strzone(self.netname);
1577
1578         bprint("^4", self.netname, "^4 connected");
1579
1580         if(self.classname != "observer" && (g_domination || g_ctf))
1581                 bprint(" and joined the ", ColoredTeamName(self.team));
1582
1583         bprint("\n");
1584
1585         self.welcomemessage_time = 0;
1586
1587         stuffcmd(self, strcat(clientstuff, "\n"));
1588         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1589         stuffcmd(self, "cl_particles_reloadeffects\n");
1590
1591         FixClientCvars(self);
1592
1593         // spawnfunc_waypoint sprites
1594         WaypointSprite_InitClient(self);
1595
1596         // Wazat's grappling hook
1597         SetGrappleHookBindings();
1598
1599         // get autoswitch state from player when he toggles it
1600         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1601
1602         // get version info from player
1603         stuffcmd(self, "cmd clientversion $gameversion\n");
1604
1605         // get other cvars from player
1606         GetCvars(0);
1607
1608         // set cvar for team scoreboard
1609         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1610
1611         // notify about available teams
1612         if(teams_matter)
1613         {
1614                 CheckAllowedTeams(self);
1615                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1616                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1617         }
1618         else
1619                 stuffcmd(self, "set _teams_available 0\n");
1620
1621         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1622
1623         if(g_arena || g_ca)
1624         {
1625                 self.classname = "observer";
1626                 if(g_arena)
1627                         Spawnqueue_Insert(self);
1628         }
1629         /*else if(g_ctf)
1630         {
1631                 ctf_clientconnect();
1632         }*/
1633
1634         if(teams_matter || radar_showennemies)
1635                 attach_entcs();
1636
1637         bot_relinkplayerlist();
1638
1639         self.spectatortime = time;
1640         if(blockSpectators)
1641         {
1642                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1643         }
1644
1645         self.jointime = time;
1646         self.allowedTimeouts = cvar("sv_timeout_number");
1647
1648         if(clienttype(self) == CLIENTTYPE_REAL)
1649         {
1650                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1651                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1652         }
1653
1654         if(g_lms)
1655         {
1656                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1657                 {
1658                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1659                         self.frags = FRAGS_SPECTATOR;
1660                 }
1661         }
1662
1663         if(!sv_foginterval && world.fog != "")
1664                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1665
1666         SoundEntity_Attach(self);
1667
1668         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1669         {
1670                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1671                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1672         }
1673         else
1674                 self.hitplotfh = -1;
1675
1676         if(g_race || g_cts) {
1677                 string rr;
1678                 if(g_cts)
1679                         rr = CTS_RECORD;
1680                 else
1681                         rr = RACE_RECORD;
1682                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1683
1684                 msg_entity = self;
1685                 race_send_recordtime(MSG_ONE);
1686                 race_send_speedaward(MSG_ONE);
1687
1688                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1689                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1690                 race_send_speedaward_alltimebest(MSG_ONE);
1691
1692                 float i;
1693                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1694                         race_SendRankings(i, 0, 0, MSG_ONE);
1695                 }
1696         }
1697         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1698                 send_CSQC_teamnagger();
1699
1700         send_CSQC_cr_maxbullets(self);
1701
1702         CheatInitClient();
1703 }
1704
1705 /*
1706 =============
1707 ClientDisconnect
1708
1709 Called when a client disconnects from the server
1710 =============
1711 */
1712 .entity chatbubbleentity;
1713 .entity teambubbleentity;
1714 void ReadyCount();
1715 void ClientDisconnect (void)
1716 {
1717         if not(self.flags & FL_CLIENT)
1718         {
1719                 print("Warning: ClientDisconnect without ClientConnect\n");
1720                 return;
1721         }
1722
1723         CheatShutdownClient();
1724
1725         if(self.hitplotfh >= 0)
1726         {
1727                 fclose(self.hitplotfh);
1728                 self.hitplotfh = -1;
1729         }
1730
1731         anticheat_report();
1732         anticheat_shutdown();
1733
1734         playerdemo_shutdown();
1735
1736         bot_clientdisconnect();
1737
1738         if(self.entcs)
1739                 detach_entcs();
1740
1741         if(cvar("sv_eventlog"))
1742                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1743         bprint ("^4",self.netname);
1744         bprint ("^4 disconnected\n");
1745
1746         SoundEntity_Detach(self);
1747
1748         DropAllRunes(self);
1749         MUTATOR_CALLHOOK(ClientDisconnect);
1750
1751         Portal_ClearAll(self);
1752
1753         if(self.flagcarried)
1754                 DropFlag(self.flagcarried, world, world);
1755         if(self.ballcarried)
1756                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1757
1758         // Here, everything has been done that requires this player to be a client.
1759
1760         self.flags &~= FL_CLIENT;
1761
1762         if (self.chatbubbleentity)
1763                 remove (self.chatbubbleentity);
1764
1765         if (self.teambubbleentity)
1766                 remove (self.teambubbleentity);
1767
1768         if (self.killindicator)
1769                 remove (self.killindicator);
1770
1771         WaypointSprite_PlayerGone();
1772
1773         bot_relinkplayerlist();
1774
1775         if(g_arena)
1776         {
1777                 Spawnqueue_Unmark(self);
1778                 Spawnqueue_Remove(self);
1779         }
1780
1781         ClientData_Detach();
1782         PlayerScore_Detach(self);
1783
1784         if(self.netname_previous)
1785                 strunzone(self.netname_previous);
1786         if(self.clientstatus)
1787                 strunzone(self.clientstatus);
1788         if(self.weaponorder_byimpulse)
1789                 strunzone(self.weaponorder_byimpulse);
1790
1791         ClearPlayerSounds();
1792
1793         if(self.personal)
1794                 remove(self.personal);
1795
1796         self.playerid = 0;
1797         ReadyCount();
1798
1799         // free cvars
1800         GetCvars(-1);
1801 }
1802
1803 .float BUTTON_CHAT;
1804 void ChatBubbleThink()
1805 {
1806         self.nextthink = time;
1807         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1808         {
1809                 if(self.owner) // but why can that ever be world?
1810                         self.owner.chatbubbleentity = world;
1811                 remove(self);
1812                 return;
1813         }
1814         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1815 #ifdef TETRIS
1816                 || self.owner.tetris_on
1817 #endif
1818         )
1819                 self.model = self.mdl;
1820         else
1821                 self.model = "";
1822 };
1823
1824 void UpdateChatBubble()
1825 {
1826         if (!self.modelindex)
1827                 return;
1828         // spawn a chatbubble entity if needed
1829         if (!self.chatbubbleentity)
1830         {
1831                 self.chatbubbleentity = spawn();
1832                 self.chatbubbleentity.owner = self;
1833                 self.chatbubbleentity.exteriormodeltoclient = self;
1834                 self.chatbubbleentity.think = ChatBubbleThink;
1835                 self.chatbubbleentity.nextthink = time;
1836                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1837                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1838                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1839                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1840                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1841                 self.chatbubbleentity.model = "";
1842                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1843         }
1844 }
1845
1846
1847 void TeamBubbleThink()
1848 {
1849         self.nextthink = time;
1850         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1851         {
1852                 if(self.owner) // but why can that ever be world?
1853                         self.owner.teambubbleentity = world;
1854                 remove(self);
1855                 return;
1856         }
1857 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1858         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1859                 self.model = "";
1860         else
1861                 self.model = self.mdl;
1862
1863 };
1864
1865 float TeamBubble_customizeentityforclient()
1866 {
1867         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1868 }
1869
1870 void UpdateTeamBubble()
1871 {
1872         if (!self.modelindex || !teams_matter)
1873                 return;
1874         // spawn a teambubble entity if needed
1875         if (!self.teambubbleentity && teams_matter)
1876         {
1877                 self.teambubbleentity = spawn();
1878                 self.teambubbleentity.owner = self;
1879                 self.teambubbleentity.exteriormodeltoclient = self;
1880                 self.teambubbleentity.think = TeamBubbleThink;
1881                 self.teambubbleentity.nextthink = time;
1882                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1883 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1884                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1885                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1886                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1887                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1888                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1889                 self.teambubbleentity.effects = EF_LOWPRECISION;
1890         }
1891 }
1892
1893 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1894 // added to the model skins
1895 /*void UpdateColorModHack()
1896 {
1897         local float c;
1898         c = self.clientcolors & 15;
1899         // LordHavoc: only bothering to support white, green, red, yellow, blue
1900              if (!teams_matter) self.colormod = '0 0 0';
1901         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1902         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1903         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1904         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1905         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1906         else self.colormod = '1 1 1';
1907 };*/
1908
1909 .float oldcolormap;
1910 void respawn(void)
1911 {
1912         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1913         {
1914                 self.solid = SOLID_NOT;
1915                 self.takedamage = DAMAGE_NO;
1916                 self.movetype = MOVETYPE_FLY;
1917                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1918                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1919                 self.effects |= EF_ADDITIVE;
1920                 self.oldcolormap = self.colormap;
1921                 self.colormap = 512;
1922                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1923                 if(cvar("g_respawn_ghosts_maxtime"))
1924                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1925         }
1926
1927         CopyBody(1);
1928         self.effects |= EF_NODRAW; // prevent another CopyBody
1929         if(self.oldcolormap)
1930         {
1931                 self.colormap = self.oldcolormap;
1932                 self.oldcolormap = 0;
1933         }
1934         PutClientInServer();
1935 }
1936
1937 void play_countdown(float finished, string samp)
1938 {
1939         if(clienttype(self) == CLIENTTYPE_REAL)
1940                 if(floor(finished - time - frametime) != floor(finished - time))
1941                         if(finished - time < 6)
1942                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1943 }
1944
1945 /**
1946  * When sv_timeout is used this function returs strings like
1947  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1948  * Called by centerprint functions
1949  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1950  */
1951 string getTimeoutText(float addOneSecond) {
1952         if (!cvar("sv_timeout") || !timeoutStatus)
1953                 return "";
1954
1955         local string retStr;
1956         if (timeoutStatus == 1) {
1957                 if (addOneSecond == 1) {
1958                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1959                 }
1960                 else {
1961                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1962                 }
1963                 return retStr;
1964         }
1965         else if (timeoutStatus == 2) {
1966                 if (addOneSecond) {
1967                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1968                         //don't show messages like "Timeout ends in 0 seconds"...
1969                         if ((remainingTimeoutTime + 1) > 0)
1970                                 return retStr;
1971                         else
1972                                 return "";
1973                 }
1974                 else {
1975                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1976                         //don't show messages like "Timeout ends in 0 seconds"...
1977                         if (remainingTimeoutTime > 0)
1978                                 return retStr;
1979                         else
1980                                 return "";
1981                 }
1982         }
1983         else return "";
1984 }
1985
1986 void player_powerups (void)
1987 {
1988         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1989         {
1990                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1991                 self.modelflags |= MF_ROCKET;
1992         }
1993         else
1994         {
1995                 SoundEntity_StopSound(self, CHAN_PLAYER);
1996                 self.modelflags &~= MF_ROCKET;
1997         }
1998
1999         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2000
2001         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2002                 return;
2003
2004         Fire_ApplyDamage(self);
2005         Fire_ApplyEffect(self);
2006
2007         if (g_minstagib)
2008         {
2009                 self.effects |= EF_FULLBRIGHT;
2010
2011                 if (self.items & IT_STRENGTH)
2012                 {
2013                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2014                         if (time > self.strength_finished)
2015                         {
2016                                 self.alpha = default_player_alpha;
2017                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2018                                 self.items &~= IT_STRENGTH;
2019                                 sprint(self, "^3Invisibility has worn off\n");
2020                         }
2021                 }
2022                 else
2023                 {
2024                         if (time < self.strength_finished)
2025                         {
2026                                 self.alpha = g_minstagib_invis_alpha;
2027                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2028                                 self.items |= IT_STRENGTH;
2029                                 sprint(self, "^3You are invisible\n");
2030                         }
2031                 }
2032
2033                 if (self.items & IT_INVINCIBLE)
2034                 {
2035                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2036                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2037                         {
2038                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2039                                 sprint(self, "^3Speed has worn off\n");
2040                         }
2041                 }
2042                 else
2043                 {
2044                         if (time < self.invincible_finished)
2045                         {
2046                                 self.items = self.items | IT_INVINCIBLE;
2047                                 sprint(self, "^3You are on speed\n");
2048                         }
2049                 }
2050                 return;
2051         }
2052
2053         if (self.items & IT_STRENGTH)
2054         {
2055                 play_countdown(self.strength_finished, "misc/poweroff.wav");
2056                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2057                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
2058                 {
2059                         self.items = self.items - (self.items & IT_STRENGTH);
2060                         sprint(self, "^3Strength has worn off\n");
2061                 }
2062         }
2063         else
2064         {
2065                 if (time < self.strength_finished)
2066                 {
2067                         self.items = self.items | IT_STRENGTH;
2068                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
2069                 }
2070         }
2071         if (self.items & IT_INVINCIBLE)
2072         {
2073                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
2074                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2075                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2076                 {
2077                         self.items = self.items - (self.items & IT_INVINCIBLE);
2078                         sprint(self, "^3Shield has worn off\n");
2079                 }
2080         }
2081         else
2082         {
2083                 if (time < self.invincible_finished)
2084                 {
2085                         self.items = self.items | IT_INVINCIBLE;
2086                         sprint(self, "^3Shield surrounds you\n");
2087                 }
2088         }
2089
2090         if(cvar("g_nodepthtestplayers"))
2091                 self.effects = self.effects | EF_NODEPTHTEST;
2092
2093         if(cvar("g_fullbrightplayers"))
2094                 self.effects = self.effects | EF_FULLBRIGHT;
2095
2096         // midair gamemode: damage only while in the air
2097         // if in midair mode, being on ground grants temporary invulnerability
2098         // (this is so that multishot weapon don't clear the ground flag on the
2099         // first damage in the frame, leaving the player vulnerable to the
2100         // remaining hits in the same frame)
2101         if (self.flags & FL_ONGROUND)
2102         if (g_midair)
2103                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2104
2105         if (time >= game_starttime)
2106         if (time < self.spawnshieldtime)
2107                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2108 }
2109
2110 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2111 {
2112         if(current > stable)
2113                 return current;
2114         else if(current > stable - 0.25) // when close enough, "snap"
2115                 return stable;
2116         else
2117                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2118 }
2119
2120 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2121 {
2122         if(current < stable)
2123                 return current;
2124         else if(current < stable + 0.25) // when close enough, "snap"
2125                 return stable;
2126         else
2127                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2128 }
2129
2130 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2131 {
2132         if(current > rotstable)
2133         {
2134                 if(rotframetime > 0)
2135                 {
2136                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2137                         current = max(rotstable, current - rotlinear * rotframetime);
2138                 }
2139         }
2140         else if(current < regenstable)
2141         {
2142                 if(regenframetime > 0)
2143                 {
2144                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2145                         current = min(regenstable, current + regenlinear * regenframetime);
2146                 }
2147         }
2148
2149         if(current > limit)
2150                 current = limit;
2151
2152         return current;
2153 }
2154
2155 void player_regen (void)
2156 {
2157         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2158         maxh = cvar("g_balance_health_rotstable");
2159         maxa = cvar("g_balance_armor_rotstable");
2160         maxf = cvar("g_balance_fuel_rotstable");
2161         minh = cvar("g_balance_health_regenstable");
2162         mina = cvar("g_balance_armor_regenstable");
2163         minf = cvar("g_balance_fuel_regenstable");
2164         limith = cvar("g_balance_health_limit");
2165         limita = cvar("g_balance_armor_limit");
2166         limitf = cvar("g_balance_fuel_limit");
2167
2168         max_mod = regen_mod = rot_mod = limit_mod = 1;
2169
2170         if (self.runes & RUNE_REGEN)
2171         {
2172                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2173                 {
2174                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2175                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2176                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2177                 }
2178                 else
2179                 {
2180                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2181                         max_mod = cvar("g_balance_rune_regen_hpmod");
2182                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2183                 }
2184         }
2185         else if (self.runes & CURSE_VENOM)
2186         {
2187                 max_mod = cvar("g_balance_curse_venom_hpmod");
2188                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2189                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2190                 else
2191                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2192                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2193                 //if (!self.runes & RUNE_REGEN)
2194                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2195         }
2196         maxh = maxh * max_mod;
2197         //maxa = maxa * max_mod;
2198         //maxf = maxf * max_mod;
2199         minh = minh * max_mod;
2200         //mina = mina * max_mod;
2201         //minf = minf * max_mod;
2202         limith = limith * limit_mod;
2203         limita = limita * limit_mod;
2204         //limitf = limitf * limit_mod;
2205
2206         if(g_lms && g_ca)
2207                 rot_mod = 0;
2208
2209         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2210         {
2211                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2212                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2213
2214                 // if player rotted to death...  die!
2215                 if(self.health < 1)
2216                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2217         }
2218
2219         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2220                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2221 }
2222
2223 float zoomstate_set;
2224 void SetZoomState(float z)
2225 {
2226         if(z != self.zoomstate)
2227         {
2228                 self.zoomstate = z;
2229                 ClientData_Touch(self);
2230         }
2231         zoomstate_set = 1;
2232 }
2233
2234 void GetPressedKeys(void) {
2235         MUTATOR_CALLHOOK(GetPressedKeys);
2236         if (self.movement_x > 0) // get if movement keys are pressed
2237         {       // forward key pressed
2238                 self.pressedkeys |= KEY_FORWARD;
2239                 self.pressedkeys &~= KEY_BACKWARD;
2240         }
2241         else if (self.movement_x < 0)
2242         {       // backward key pressed
2243                 self.pressedkeys |= KEY_BACKWARD;
2244                 self.pressedkeys &~= KEY_FORWARD;
2245         }
2246         else
2247         {       // no x input
2248                 self.pressedkeys &~= KEY_FORWARD;
2249                 self.pressedkeys &~= KEY_BACKWARD;
2250         }
2251
2252         if (self.movement_y > 0)
2253         {       // right key pressed
2254                 self.pressedkeys |= KEY_RIGHT;
2255                 self.pressedkeys &~= KEY_LEFT;
2256         }
2257         else if (self.movement_y < 0)
2258         {       // left key pressed
2259                 self.pressedkeys |= KEY_LEFT;
2260                 self.pressedkeys &~= KEY_RIGHT;
2261         }
2262         else
2263         {       // no y input
2264                 self.pressedkeys &~= KEY_RIGHT;
2265                 self.pressedkeys &~= KEY_LEFT;
2266         }
2267
2268         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2269                 self.pressedkeys |= KEY_JUMP;
2270         else
2271                 self.pressedkeys &~= KEY_JUMP;
2272         if (self.BUTTON_CROUCH)
2273                 self.pressedkeys |= KEY_CROUCH;
2274         else
2275                 self.pressedkeys &~= KEY_CROUCH;
2276 }
2277
2278 /*
2279 ======================
2280 spectate mode routines
2281 ======================
2282 */
2283
2284 void SpectateCopy(entity spectatee) {
2285         other = spectatee;
2286         MUTATOR_CALLHOOK(SpectateCopy);
2287         self.armortype = spectatee.armortype;
2288         self.armorvalue = spectatee.armorvalue;
2289         self.ammo_cells = spectatee.ammo_cells;
2290         self.ammo_shells = spectatee.ammo_shells;
2291         self.ammo_nails = spectatee.ammo_nails;
2292         self.ammo_rockets = spectatee.ammo_rockets;
2293         self.ammo_fuel = spectatee.ammo_fuel;
2294         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2295         self.health = spectatee.health;
2296         self.impulse = 0;
2297         self.items = spectatee.items;
2298         self.last_pickup = spectatee.last_pickup;
2299         self.metertime = spectatee.metertime;
2300         self.strength_finished = spectatee.strength_finished;
2301         self.invincible_finished = spectatee.invincible_finished;
2302         self.pressedkeys = spectatee.pressedkeys;
2303         self.weapons = spectatee.weapons;
2304         self.switchweapon = spectatee.switchweapon;
2305         self.weapon = spectatee.weapon;
2306         self.punchangle = spectatee.punchangle;
2307         self.view_ofs = spectatee.view_ofs;
2308         self.v_angle = spectatee.v_angle;
2309         self.velocity = spectatee.velocity;
2310         self.dmg_take = spectatee.dmg_take;
2311         self.dmg_save = spectatee.dmg_save;
2312         self.dmg_inflictor = spectatee.dmg_inflictor;
2313         self.angles = spectatee.v_angle;
2314         self.fixangle = TRUE;
2315         setorigin(self, spectatee.origin);
2316         setsize(self, spectatee.mins, spectatee.maxs);
2317         SetZoomState(spectatee.zoomstate);
2318
2319         anticheat_spectatecopy(spectatee);
2320 }
2321
2322 float SpectateUpdate() {
2323         if(!self.enemy)
2324                 return 0;
2325
2326         if (self == self.enemy)
2327                 return 0;
2328
2329         if(self.enemy.classname != "player")
2330                 return 0;
2331
2332         SpectateCopy(self.enemy);
2333
2334         return 1;
2335 }
2336
2337 float SpectateNext() {
2338         other = find(self.enemy, classname, "player");
2339
2340         if (!other)
2341                 other = find(other, classname, "player");
2342
2343         if (other)
2344                 self.enemy = other;
2345
2346         if(self.enemy.classname == "player") {
2347                 msg_entity = self;
2348                 WriteByte(MSG_ONE, SVC_SETVIEW);
2349                 WriteEntity(MSG_ONE, self.enemy);
2350                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2351                 self.movetype = MOVETYPE_NONE;
2352                 accuracy_resend(self);
2353
2354                 if(!SpectateUpdate())
2355                         PutObserverInServer();
2356
2357                 return 1;
2358         } else {
2359                 return 0;
2360         }
2361 }
2362
2363 /*
2364 =============
2365 ShowRespawnCountdown()
2366
2367 Update a respawn countdown display.
2368 =============
2369 */
2370 void ShowRespawnCountdown()
2371 {
2372         float number;
2373         if(self.deadflag == DEAD_NO) // just respawned?
2374                 return;
2375         else
2376         {
2377                 number = ceil(self.death_time - time);
2378                 if(number <= 0)
2379                         return;
2380                 if(number <= self.respawn_countdown)
2381                 {
2382                         self.respawn_countdown = number - 1;
2383                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2384                                 AnnounceTo(self, strcat(ftos(number), ""));
2385                 }
2386         }
2387 }
2388
2389 void LeaveSpectatorMode()
2390 {
2391         if(isJoinAllowed()) {
2392                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned")) || self.team_forced > 0) {
2393                         self.classname = "player";
2394
2395                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2396                                 JoinBestTeam(self, FALSE, TRUE);
2397
2398                         if(cvar("g_campaign"))
2399                                 campaign_bots_may_start = 1;
2400
2401                         PutClientInServer();
2402
2403                         if(self.classname == "player")
2404                                 bprint ("^4", self.netname, "^4 is playing now\n");
2405
2406                         if(!cvar("g_campaign"))
2407                                 centerprint(self,""); // clear MOTD
2408
2409                         return;
2410                 } else {
2411                         if (g_ca && self.caplayer) {
2412                         }       // do nothing
2413                         else
2414                                 stuffcmd(self,"menu_showteamselect\n");
2415                         return;
2416                 }
2417         }
2418         else {
2419                 //player may not join because of g_maxplayers is set
2420                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2421         }
2422 }
2423
2424 /**
2425  * Determines whether the player is allowed to join. This depends on cvar
2426  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2427  * it checks whether the number of currently playing players exceeds g_maxplayers.
2428  * @return bool TRUE if the player is allowed to join, false otherwise
2429  */
2430 float isJoinAllowed() {
2431         if(self.team_forced < 0)
2432                 return FALSE; // forced spectators can never join
2433
2434         if (!cvar("g_maxplayers"))
2435                 return TRUE;
2436
2437         local entity e;
2438         local float currentlyPlaying;
2439         FOR_EACH_REALPLAYER(e) {
2440                 if(e.classname == "player")
2441                         currentlyPlaying += 1;
2442         }
2443         if(currentlyPlaying < cvar("g_maxplayers"))
2444                 return TRUE;
2445
2446         return FALSE;
2447 }
2448
2449 /**
2450  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2451  * g_maxplayers_spectator_blocktime seconds
2452  */
2453 void checkSpectatorBlock() {
2454         if(self.classname == "spectator" || self.classname == "observer") {
2455                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2456                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2457                         dropclient(self);
2458                 }
2459         }
2460 }
2461
2462 void ObserverThink()
2463 {
2464         if (self.flags & FL_JUMPRELEASED) {
2465                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2466                         self.welcomemessage_time = 0;
2467                         self.flags &~= FL_JUMPRELEASED;
2468                         self.flags |= FL_SPAWNING;
2469                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2470                         self.welcomemessage_time = 0;
2471                         self.flags &~= FL_JUMPRELEASED;
2472                         if(SpectateNext() == 1) {
2473                                 self.classname = "spectator";
2474                         }
2475                 }
2476         } else {
2477                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2478                         self.flags |= FL_JUMPRELEASED;
2479                         if(self.flags & FL_SPAWNING)
2480                         {
2481                                 self.flags &~= FL_SPAWNING;
2482                                 LeaveSpectatorMode();
2483                                 return;
2484                         }
2485                 }
2486         }
2487         PrintWelcomeMessage(self);
2488 }
2489
2490 void SpectatorThink()
2491 {
2492         if (self.flags & FL_JUMPRELEASED) {
2493                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2494                         self.welcomemessage_time = 0;
2495                         self.flags &~= FL_JUMPRELEASED;
2496                         self.flags |= FL_SPAWNING;
2497                 } else if(self.BUTTON_ATCK) {
2498                         self.welcomemessage_time = 0;
2499                         self.flags &~= FL_JUMPRELEASED;
2500                         if(SpectateNext() == 1) {
2501                                 self.classname = "spectator";
2502                         } else {
2503                                 self.classname = "observer";
2504                                 PutClientInServer();
2505                         }
2506                 } else if (self.BUTTON_ATCK2) {
2507                         self.welcomemessage_time = 0;
2508                         self.flags &~= FL_JUMPRELEASED;
2509                         self.classname = "observer";
2510                         PutClientInServer();
2511                 } else {
2512                         if(!SpectateUpdate())
2513                                 PutObserverInServer();
2514                 }
2515         } else {
2516                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2517                         self.flags |= FL_JUMPRELEASED;
2518                         if(self.flags & FL_SPAWNING)
2519                         {
2520                                 self.flags &~= FL_SPAWNING;
2521                                 LeaveSpectatorMode();
2522                                 return;
2523                         }
2524                 }
2525         }
2526
2527         PrintWelcomeMessage(self);
2528         self.flags |= FL_CLIENT | FL_NOTARGET;
2529 }
2530
2531 .float touchexplode_time;
2532
2533 /*
2534 =============
2535 PlayerPreThink
2536
2537 Called every frame for each client before the physics are run
2538 =============
2539 */
2540 void() ctf_setstatus;
2541 void() nexball_setstatus;
2542 .float items_added;
2543 void PlayerPreThink (void)
2544 {
2545         self.stat_game_starttime = game_starttime;
2546         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2547         self.stat_leadlimit = cvar("leadlimit");
2548
2549         if(frametime)
2550         {
2551                 // physics frames: update anticheat stuff
2552                 anticheat_prethink();
2553         }
2554
2555         if(blockSpectators && frametime)
2556                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2557                 checkSpectatorBlock();
2558
2559         zoomstate_set = 0;
2560
2561         if(self.netname_previous != self.netname)
2562         {
2563                 if(cvar("sv_eventlog"))
2564                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2565                 if(self.netname_previous)
2566                         strunzone(self.netname_previous);
2567                 self.netname_previous = strzone(self.netname);
2568         }
2569
2570         // version nagging
2571         if(self.version_nagtime)
2572                 if(self.cvar_g_xonoticversion)
2573                         if(time > self.version_nagtime)
2574                         {
2575                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2576                                 {
2577                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2578                                         {
2579                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2580                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2581                                         }
2582                                         else
2583                                         {
2584                                                 float r;
2585                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2586                                                 if(r < 0)
2587                                                 {
2588                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2589                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2590                                                 }
2591                                                 else if(r > 0)
2592                                                 {
2593                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2594                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2595                                                 }
2596                                         }
2597                                 }
2598                                 self.version_nagtime = 0;
2599                         }
2600
2601         // GOD MODE info
2602         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2603         {
2604                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2605                 self.max_armorvalue = 0;
2606         }
2607
2608 #ifdef TETRIS
2609         if (TetrisPreFrame())
2610                 return;
2611 #endif
2612
2613         MUTATOR_CALLHOOK(PlayerPreThink);
2614
2615         if(self.classname == "player") {
2616 //              if(self.netname == "Wazat")
2617 //                      bprint(self.classname, "\n");
2618
2619                 CheckRules_Player();
2620
2621                 PrintWelcomeMessage(self);
2622
2623                 if (intermission_running)
2624                 {
2625                         IntermissionThink ();   // otherwise a button could be missed between
2626                         return;                                 // the think tics
2627                 }
2628
2629                 if(self.teleport_time)
2630                 if(time > self.teleport_time)
2631                 {
2632                         self.teleport_time = 0;
2633                         self.effects = self.effects - (self.effects & EF_NODRAW);
2634                 }
2635
2636                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2637                         UpdateSelectedPlayer();
2638
2639                 //don't allow the player to turn around while game is paused!
2640                 if(timeoutStatus == 2) {
2641                         self.v_angle = self.lastV_angle;
2642                         self.angles = self.lastV_angle;
2643                         self.fixangle = TRUE;
2644                 }
2645
2646                 if(frametime)
2647                 {
2648                         if(self.health <= 0 && cvar("g_deathglow"))
2649                         {
2650                                 if(self.glowmod_x > 0)
2651                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2652                                 else
2653                                         self.glowmod_x = -1;
2654                                 if(self.glowmod_y > 0)
2655                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2656                                 else
2657                                         self.glowmod_y = -1;
2658                                 if(self.glowmod_z > 0)
2659                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2660                                 else
2661                                         self.glowmod_z = -1;
2662                         }
2663                         else
2664                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2665                         player_powerups();
2666                 }
2667
2668                 if (self.deadflag != DEAD_NO)
2669                 {
2670                         float button_pressed, force_respawn;
2671                         if(self.personal && g_race_qualifying)
2672                         {
2673                                 if(time > self.death_time)
2674                                 {
2675                                         self.death_time = time + 1; // only retry once a second
2676                                         respawn();
2677                                         self.impulse = 141;
2678                                 }
2679                         }
2680                         else
2681                         {
2682                                 if(frametime)
2683                                         player_anim();
2684                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2685                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2686                                 if (self.deadflag == DEAD_DYING)
2687                                 {
2688                                         if(force_respawn)
2689                                                 self.deadflag = DEAD_RESPAWNING;
2690                                         else if(!button_pressed)
2691                                                 self.deadflag = DEAD_DEAD;
2692                                 }
2693                                 else if (self.deadflag == DEAD_DEAD)
2694                                 {
2695                                         if(button_pressed)
2696                                                 self.deadflag = DEAD_RESPAWNABLE;
2697                                 }
2698                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2699                                 {
2700                                         if(!button_pressed)
2701                                                 self.deadflag = DEAD_RESPAWNING;
2702                                 }
2703                                 else if (self.deadflag == DEAD_RESPAWNING)
2704                                 {
2705                                         if(time > self.death_time)
2706                                         {
2707                                                 self.death_time = time + 1; // only retry once a second
2708                                                 respawn();
2709                                         }
2710                                 }
2711                                 ShowRespawnCountdown();
2712                         }
2713                         return;
2714                 }
2715
2716                 if(g_touchexplode)
2717                 if(time > self.touchexplode_time)
2718                 if(self.classname == "player")
2719                 if(self.deadflag == DEAD_NO)
2720                 if not(IS_INDEPENDENT_PLAYER(self))
2721                 FOR_EACH_PLAYER(other) if(self != other)
2722                 {
2723                         if(time > other.touchexplode_time)
2724                         if(other.deadflag == DEAD_NO)
2725                         if not(IS_INDEPENDENT_PLAYER(other))
2726                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2727                         {
2728                                 PlayerTouchExplode(self, other);
2729                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2730                         }
2731                 }
2732
2733                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2734                 {
2735                         vector dist;
2736
2737                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2738                         dist = self.prevorigin - self.origin;
2739                         dist_z = 0;
2740                         self.lms_traveled_distance += fabs(vlen(dist));
2741
2742                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2743                         {
2744                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2745                                 self.lms_traveled_distance = 0;
2746                         }
2747
2748                         if(time > self.lms_nextcheck)
2749                         {
2750                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2751                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2752                                 {
2753                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2754                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2755                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2756                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2757                                 }
2758                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2759                                 self.lms_traveled_distance = 0;
2760                         }
2761                 }
2762
2763                 self.prevorigin = self.origin;
2764
2765                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2766                 {
2767                         if (!self.crouch)
2768                         {
2769                                 self.crouch = TRUE;
2770                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2771                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2772                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2773                         }
2774                 }
2775                 else
2776                 {
2777                         if (self.crouch)
2778                         {
2779                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2780                                 if (!trace_startsolid)
2781                                 {
2782                                         self.crouch = FALSE;
2783                                         self.view_ofs = PL_VIEW_OFS;
2784                                         setsize (self, PL_MIN, PL_MAX);
2785                                 }
2786                         }
2787                 }
2788
2789                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2790                 {
2791                         if(self.bloodloss_timer < time)
2792                         {
2793                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2794                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2795                         }
2796                 }
2797
2798                 FixPlayermodel();
2799
2800                 GrapplingHookFrame();
2801
2802                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2803                 //if(frametime)
2804                 {
2805                         self.items &~= self.items_added;
2806
2807                         W_WeaponFrame();
2808
2809                         self.items_added = 0;
2810                         if(self.items & IT_JETPACK)
2811                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2812                                         self.items_added |= IT_FUEL;
2813
2814                         self.items |= self.items_added;
2815                 }
2816
2817                 player_regen();
2818
2819                 // rot nex charge to the charge limit
2820                 if(cvar("g_balance_nex_charge_rot_rate") && self.nex_charge > cvar("g_balance_nex_charge_limit") && self.nex_charge_rottime < time)
2821                         self.nex_charge = bound(cvar("g_balance_nex_charge_limit"), self.nex_charge - cvar("g_balance_nex_charge_rot_rate") * frametime / W_TICSPERFRAME, 1);
2822
2823                 if(frametime)
2824                         player_anim();
2825
2826                 if (g_minstagib)
2827                         minstagib_ammocheck();
2828
2829                 if(g_ctf)
2830                         ctf_setstatus();
2831
2832                 if(g_nexball)
2833                         nexball_setstatus();
2834
2835                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2836
2837                 //self.angles_y=self.v_angle_y + 90;   // temp
2838         } else if(gameover) {
2839                 if (intermission_running)
2840                         IntermissionThink ();   // otherwise a button could be missed between
2841                 return;
2842         } else if(self.classname == "observer") {
2843                 ObserverThink();
2844         } else if(self.classname == "spectator") {
2845                 SpectatorThink();
2846         }
2847
2848         if(!zoomstate_set)
2849                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2850
2851         float oldspectatee_status;
2852         oldspectatee_status = self.spectatee_status;
2853         if(self.classname == "spectator")
2854                 self.spectatee_status = num_for_edict(self.enemy);
2855         else if(self.classname == "observer")
2856                 self.spectatee_status = num_for_edict(self);
2857         else
2858                 self.spectatee_status = 0;
2859         if(self.spectatee_status != oldspectatee_status)
2860         {
2861                 ClientData_Touch(self);
2862                 if(g_race || g_cts)
2863                         race_InitSpectator();
2864         }
2865
2866         if(self.teamkill_soundtime)
2867         if(time > self.teamkill_soundtime)
2868         {
2869                 self.teamkill_soundtime = 0;
2870
2871                 entity oldpusher, oldself;
2872
2873                 oldself = self; self = self.teamkill_soundsource;
2874                 oldpusher = self.pusher; self.pusher = oldself;
2875
2876                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2877
2878                 self.pusher = oldpusher;
2879                 self = oldself;
2880         }
2881
2882         if(self.taunt_soundtime)
2883         if(time > self.taunt_soundtime)
2884         {
2885                 self.taunt_soundtime = 0;
2886                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2887         }
2888
2889         target_voicescript_next(self);
2890 }
2891
2892 float isInvisibleString(string s)
2893 {
2894         float i, n, c;
2895         s = strdecolorize(s);
2896         for((i = 0), (n = strlen(s)); i < n; ++i)
2897         {
2898                 c = str2chr(s, i);
2899                 switch(c)
2900                 {
2901                         case 0:
2902                         case 32: // space
2903                                 break;
2904                         case 192: // charmap space
2905                                 if (!cvar("utf8_enable"))
2906                                         break;
2907                                 return FALSE;
2908                         case 160: // space in unicode fonts
2909                         case 0xE000 + 192: // utf8 charmap space
2910                                 if (cvar("utf8_enable"))
2911                                         break;
2912                         default:
2913                                 return FALSE;
2914                 }
2915         }
2916         return TRUE;
2917 }
2918
2919 /*
2920 =============
2921 PlayerPostThink
2922
2923 Called every frame for each client after the physics are run
2924 =============
2925 */
2926 .float idlekick_lasttimeleft;
2927 .entity showheadshotbbox;
2928 void showheadshotbbox_think()
2929 {
2930         if(self.owner.showheadshotbbox != self)
2931         {
2932                 remove(self);
2933                 return;
2934         }
2935         self.nextthink = time;
2936         setorigin(self, self.owner.origin);
2937         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2938 }
2939 void PlayerPostThink (void)
2940 {
2941         // Savage: Check for nameless players
2942         if (isInvisibleString(self.netname)) {
2943                 self.netname = "Player";
2944                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2945         }
2946
2947         if(sv_maxidle && frametime)
2948         {
2949                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2950                 float timeleft;
2951                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2952                 if(timeleft <= 0)
2953                 {
2954                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2955                         AnnounceTo(self, "terminated");
2956                         dropclient(self);
2957                         return;
2958                 }
2959                 else if(timeleft <= 10)
2960                 {
2961                         if(timeleft != self.idlekick_lasttimeleft)
2962                         {
2963                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2964                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2965                         }
2966                 }
2967                 else
2968                 {
2969                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2970                 }
2971                 self.idlekick_lasttimeleft = timeleft;
2972         }
2973
2974 #ifdef TETRIS
2975         if(self.impulse == 100)
2976                 ImpulseCommands();
2977         if (TetrisPostFrame())
2978                 return;
2979 #endif
2980
2981         CheatFrame();
2982
2983         if(self.classname == "player") {
2984                 CheckRules_Player();
2985                 UpdateChatBubble();
2986                 UpdateTeamBubble();
2987                 if (self.impulse)
2988                         ImpulseCommands();
2989                 if (intermission_running)
2990                         return;         // intermission or finale
2991                 GetPressedKeys();
2992         } else if (self.classname == "observer") {
2993                 //do nothing
2994         } else if (self.classname == "spectator") {
2995                 //do nothing
2996         }
2997
2998         /*
2999         float i;
3000         for(i = 0; i < 1000; ++i)
3001         {
3002                 vector end;
3003                 end = self.origin + '0 0 1024' + 512 * randomvec();
3004                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3005                 if(trace_fraction < 1)
3006                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3007                 {
3008                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3009                         break;
3010                 }
3011         }
3012         */
3013
3014         Arena_Warmup();
3015
3016         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3017
3018         if(self.waypointsprite_attachedforcarrier)
3019                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3020
3021         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3022         {
3023                 if(!self.showheadshotbbox)
3024                 {
3025                         self.showheadshotbbox = spawn();
3026                         self.showheadshotbbox.classname = "headshotbbox";
3027                         self.showheadshotbbox.owner = self;
3028                         self.showheadshotbbox.think = showheadshotbbox_think;
3029                         self.showheadshotbbox.nextthink = time;
3030                         self = self.showheadshotbbox;
3031                         self.think();
3032                         self = self.owner;
3033                 }
3034         }
3035         else
3036         {
3037                 if(self.showheadshotbbox)
3038                         remove(self.showheadshotbbox);
3039         }
3040
3041         playerdemo_write();
3042
3043         if((g_cts || g_race) && self.cvar_cl_allow_uid2name)
3044         {
3045                 if(!self.stored_netname)
3046                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3047                 if(self.stored_netname != self.netname)
3048                 {
3049                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3050                         strunzone(self.stored_netname);
3051                         self.stored_netname = strzone(self.netname);
3052                 }
3053         }
3054
3055         /*
3056         if(g_race)
3057                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3058         */
3059 }