qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(cvar("spawn_debugview"))
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > cvar("g_spawn_furthest"))
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(cvar("spawn_debugview"))
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(cvar("spawn_debug"))
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(cvar("sv_servermodelsonly"))
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602
 603         Portal_ClearAll(self);
 604
 605         if(self.flagcarried)
 606                 DropFlag(self.flagcarried, world, world);
 607
 608         if(self.ballcarried)
 609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 610
 611         WaypointSprite_PlayerDead();
 612
 613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 615
 616         if(self.killcount != -666) {
 617                 if(g_lms) {
 618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 620                         else
 621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 622                 } else
 623                         bprint ("^4", self.netname, "^4 is spectating now\n");
 624
 625                 if(self.just_joined == FALSE) {
 626                         LogTeamchange(self.playerid, -1, 4);
 627                 } else
 628                         self.just_joined = FALSE;
 629         }
 630
 631         PlayerScore_Clear(self); // clear scores when needed
 632
 633         self.spectatortime = time;
 634
 635         self.classname = "observer";
 636         self.iscreature = FALSE;
 637         self.health = -666;
 638         self.takedamage = DAMAGE_NO;
 639         self.solid = SOLID_NOT;
 640         self.movetype = MOVETYPE_NOCLIP;
 641         self.flags = FL_CLIENT | FL_NOTARGET;
 642         self.armorvalue = 666;
 643         self.effects = 0;
 644         self.armorvalue = cvar("g_balance_armor_start");
 645         self.pauserotarmor_finished = 0;
 646         self.pauserothealth_finished = 0;
 647         self.pauseregen_finished = 0;
 648         self.damageforcescale = 0;
 649         self.death_time = 0;
 650         self.dead_frame = 0;
 651         self.alpha = 0;
 652         self.scale = 0;
 653         self.fade_time = 0;
 654         self.pain_frame = 0;
 655         self.pain_finished = 0;
 656         self.strength_finished = 0;
 657         self.invincible_finished = 0;
 658         self.pushltime = 0;
 659         self.think = SUB_Null;
 660         self.nextthink = 0;
 661         self.hook_time = 0;
 662         self.runes = 0;
 663         self.deadflag = DEAD_NO;
 664         self.angles = spot.angles;
 665         self.angles_z = 0;
 666         self.fixangle = TRUE;
 667         self.crouch = FALSE;
 668
 669         self.view_ofs = PL_VIEW_OFS;
 670         setorigin (self, spot.origin);
 671         setsize (self, '0 0 0', '0 0 0');
 672         self.prevorigin = self.origin;
 673         self.items = 0;
 674         self.weapons = 0;
 675         self.model = "";
 676         FixPlayermodel();
 677         self.model = "";
 678         self.modelindex = 0;
 679         self.weapon = 0;
 680         self.weaponmodel = "";
 681         self.weaponentity = world;
 682         self.exteriorweaponentity = world;
 683         self.killcount = -666;
 684         self.velocity = '0 0 0';
 685         self.avelocity = '0 0 0';
 686         self.punchangle = '0 0 0';
 687         self.punchvector = '0 0 0';
 688         self.oldvelocity = self.velocity;
 689         self.fire_endtime = -1;
 690
 691         if(sv_loddistance1)
 692                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 693
 694         if(g_arena)
 695         {
 696                 if(self.version_mismatch)
 697                 {
 698                         Spawnqueue_Unmark(self);
 699                         Spawnqueue_Remove(self);
 700                 }
 701                 else
 702                 {
 703                         Spawnqueue_Insert(self);
 704                 }
 705         }
 706         else if(g_lms)
 707         {
 708                 // Only if the player cannot play at all
 709                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 710                         self.frags = FRAGS_SPECTATOR;
 711                 else
 712                         self.frags = FRAGS_LMS_LOSER;
 713         }
 714         else
 715                 self.frags = FRAGS_SPECTATOR;
 716
 717         MUTATOR_CALLHOOK(MakePlayerObserver);
 718 }
 719
 720 float RestrictSkin(float s)
 721 {
 722         if(!teams_matter)
 723                 return s;
 724         if(s == 6)
 725                 return 6;
 726         return mod(s, 3);
 727 }
 728
 729 void FixPlayermodel()
 730 {
 731         local string defaultmodel;
 732         local float defaultskin, chmdl, oldskin;
 733         local vector m1, m2;
 734
 735         defaultmodel = "";
 736
 737         if(cvar("sv_defaultcharacter") == 1) {
 738                 defaultskin = 0;
 739
 740                 if(teams_matter)
 741                 {
 742                         string s;
 743                         s = Team_ColorNameLowerCase(self.team);
 744                         if(s != "neutral")
 745                         {
 746                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 747                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 748                         }
 749                 }
 750
 751                 if(defaultmodel == "")
 752                 {
 753                         defaultmodel = cvar_string("sv_defaultplayermodel");
 754                         defaultskin = cvar("sv_defaultplayerskin");
 755                 }
 756         }
 757
 758         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 759         {
 760                 if(self.model != "")
 761                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 762                 self.model = ""; // force the != checks to return true
 763         }
 764
 765         if(defaultmodel != "")
 766         {
 767                 if (defaultmodel != self.model)
 768                 {
 769                         m1 = self.mins;
 770                         m2 = self.maxs;
 771                         setmodel_lod (self, defaultmodel);
 772                         setsize (self, m1, m2);
 773                         chmdl = TRUE;
 774                 }
 775
 776                 oldskin = self.skinindex;
 777                 self.skinindex = defaultskin;
 778         } else {
 779                 if (self.playermodel != self.model || self.playermodel == "")
 780                 {
 781                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 782                         m1 = self.mins;
 783                         m2 = self.maxs;
 784                         setmodel_lod (self, self.playermodel);
 785                         setsize (self, m1, m2);
 786                         chmdl = TRUE;
 787                 }
 788
 789                 oldskin = self.skinindex;
 790                 self.skinindex = RestrictSkin(stof(self.playerskin));
 791         }
 792
 793         if(chmdl || oldskin != self.skinindex)
 794                 self.species = player_getspecies(); // model or skin has changed
 795
 796         if(!teams_matter)
 797                 if(strlen(cvar_string("sv_defaultplayercolors")))
 798                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 799                                 setcolor(self, cvar("sv_defaultplayercolors"));
 800 }
 801
 802 void PlayerTouchExplode(entity p1, entity p2)
 803 {
 804         vector org;
 805         org = (p1.origin + p2.origin) * 0.5;
 806         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 807
 808         te_explosion(org);
 809
 810         entity e;
 811         e = spawn();
 812         setorigin(e, org);
 813         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 814         remove(e);
 815 }
 816
 817 /*
 818 =============
 819 PutClientInServer
 820
 821 Called when a client spawns in the server
 822 =============
 823 */
 824 //void() ctf_playerchanged;
 825 void PutClientInServer (void)
 826 {
 827         if(clienttype(self) == CLIENTTYPE_BOT)
 828         {
 829                 self.classname = "player";
 830         }
 831         else if(clienttype(self) == CLIENTTYPE_REAL)
 832         {
 833                 msg_entity = self;
 834                 WriteByte(MSG_ONE, SVC_SETVIEW);
 835                 WriteEntity(MSG_ONE, self);
 836         }
 837
 838         // player is dead and becomes observer
 839         // FIXME fix LMS scoring for new system
 840         if(g_lms)
 841         {
 842                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 843                         self.classname = "observer";
 844         }
 845
 846         if(g_arena || (g_ca && !allowed_to_spawn))
 847         if(!self.spawned)
 848                 self.classname = "observer";
 849
 850         if(gameover)
 851                 self.classname = "observer";
 852
 853         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 854                 entity spot, oldself;
 855                 float j;
 856
 857                 if(self.team < 0)
 858                         JoinBestTeam(self, FALSE, TRUE);
 859
 860                 race_PreSpawn();
 861
 862                 spot = SelectSpawnPoint (FALSE);
 863                 if(!spot)
 864                 {
 865                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 866                         return; // spawn failed
 867                 }
 868
 869                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 870
 871                 self.classname = "player";
 872                 self.wasplayer = TRUE;
 873                 self.iscreature = TRUE;
 874                 self.movetype = MOVETYPE_WALK;
 875                 self.solid = SOLID_SLIDEBOX;
 876                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 877                 if(cvar("g_playerclip_collisions"))
 878                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 879                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 880                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 881                 self.frags = FRAGS_PLAYER;
 882                 if(independent_players)
 883                         MAKE_INDEPENDENT_PLAYER(self);
 884                 self.flags = FL_CLIENT;
 885                 self.takedamage = DAMAGE_AIM;
 886                 if(g_minstagib)
 887                         self.effects = EF_FULLBRIGHT;
 888                 else
 889                         self.effects = 0;
 890                 self.air_finished = time + 12;
 891                 self.dmg = 2;
 892                 if(cvar("g_balance_nex_charge"))
 893                         self.nex_charge = cvar("g_balance_nex_charge_start");
 894
 895                 if(inWarmupStage)
 896                 {
 897                         self.ammo_shells = warmup_start_ammo_shells;
 898                         self.ammo_nails = warmup_start_ammo_nails;
 899                         self.ammo_rockets = warmup_start_ammo_rockets;
 900                         self.ammo_cells = warmup_start_ammo_cells;
 901                         self.ammo_fuel = warmup_start_ammo_fuel;
 902                         self.health = warmup_start_health;
 903                         self.armorvalue = warmup_start_armorvalue;
 904                         self.weapons = warmup_start_weapons;
 905                 }
 906                 else
 907                 {
 908                         self.ammo_shells = start_ammo_shells;
 909                         self.ammo_nails = start_ammo_nails;
 910                         self.ammo_rockets = start_ammo_rockets;
 911                         self.ammo_cells = start_ammo_cells;
 912                         self.ammo_fuel = start_ammo_fuel;
 913                         self.health = start_health;
 914                         self.armorvalue = start_armorvalue;
 915                         self.weapons = start_weapons;
 916                 }
 917
 918                 if(g_weaponarena_random)
 919                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 920
 921                 self.items = start_items;
 922                 self.jump_interval = time;
 923
 924                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 925                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 926                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 927                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 928                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 929                 //extend the pause of rotting if client was reset at the beginning of the countdown
 930                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 931                         self.spawnshieldtime += game_starttime - time;
 932                         self.pauserotarmor_finished += game_starttime - time;
 933                         self.pauserothealth_finished += game_starttime - time;
 934                         self.pauseregen_finished += game_starttime - time;
 935                 }
 936                 self.damageforcescale = 2;
 937                 self.death_time = 0;
 938                 self.dead_frame = 0;
 939                 self.alpha = 0;
 940                 self.scale = 0;
 941                 self.fade_time = 0;
 942                 self.pain_frame = 0;
 943                 self.pain_finished = 0;
 944                 self.strength_finished = 0;
 945                 self.invincible_finished = 0;
 946                 self.pushltime = 0;
 947                 // players have no think function
 948                 self.think = SUB_Null;
 949                 self.nextthink = 0;
 950                 self.hook_time = 0;
 951                 self.dmg_team = 0;
 952                 self.ballistics_density = cvar("g_ballistics_density_player");
 953
 954                 self.metertime = 0;
 955
 956                 self.runes = 0;
 957
 958                 self.deadflag = DEAD_NO;
 959
 960                 self.angles = spot.angles;
 961
 962                 self.angles_z = 0; // never spawn tilted even if the spot says to
 963                 self.fixangle = TRUE; // turn this way immediately
 964                 self.velocity = '0 0 0';
 965                 self.avelocity = '0 0 0';
 966                 self.punchangle = '0 0 0';
 967                 self.punchvector = '0 0 0';
 968                 self.oldvelocity = self.velocity;
 969                 self.fire_endtime = -1;
 970
 971                 msg_entity = self;
 972                 WRITESPECTATABLE_MSG_ONE({
 973                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 974                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 975                 });
 976
 977                 if(sv_loddistance1)
 978                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 979
 980                 self.model = "";
 981                 FixPlayermodel();
 982
 983                 self.crouch = FALSE;
 984                 self.view_ofs = PL_VIEW_OFS;
 985                 setsize (self, PL_MIN, PL_MAX);
 986                 self.spawnorigin = spot.origin;
 987                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 988                 // don't reset back to last position, even if new position is stuck in solid
 989                 self.oldorigin = self.origin;
 990                 self.prevorigin = self.origin;
 991                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 992
 993                 if(g_arena)
 994                 {
 995                         Spawnqueue_Remove(self);
 996                         Spawnqueue_Mark(self);
 997                 }
 998
 999                 else if(g_ca)
1000                         self.caplayer = 1;
1001
1002                 self.event_damage = PlayerDamage;
1003
1004                 self.bot_attack = TRUE;
1005
1006                 self.statdraintime = time + 5;
1007                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1008
1009                 if(self.killcount == -666) {
1010                         PlayerScore_Clear(self);
1011                         self.killcount = 0;
1012                 }
1013
1014                 self.cnt = WEP_LASER;
1015
1016                 CL_SpawnWeaponentity();
1017                 self.alpha = default_player_alpha;
1018                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1019                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1020
1021                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1022                 self.lms_traveled_distance = 0;
1023                 self.speedrunning = FALSE;
1024
1025                 race_PostSpawn(spot);
1026
1027                 if(cvar("spawn_debug"))
1028                 {
1029                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1030                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1031                 }
1032
1033                 //stuffcmd(self, "chase_active 0");
1034                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1035
1036                 if (cvar("g_spawnsound"))
1037                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1038
1039                 if(g_assault) {
1040                         if(self.team == assault_attacker_team)
1041                                 centerprint(self, "You are attacking!");
1042                         else
1043                                 centerprint(self, "You are defending!");
1044                 }
1045
1046                 target_voicescript_clear(self);
1047
1048                 // reset fields the weapons may use
1049                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1050                         weapon_action(j, WR_RESETPLAYER);
1051
1052                 oldself = self;
1053                 self = spot;
1054                         activator = oldself;
1055                                 SUB_UseTargets();
1056                         activator = world;
1057                 self = oldself;
1058
1059                 MUTATOR_CALLHOOK(PlayerSpawn);
1060
1061                 self.switchweapon = w_getbestweapon(self);
1062                 self.cnt = self.switchweapon;
1063                 self.weapon = 0;
1064         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1065                 PutObserverInServer ();
1066         }
1067
1068         //if(g_ctf)
1069         //      ctf_playerchanged();
1070 }
1071
1072 float ClientInit_SendEntity(entity to, float sf)
1073 {
1074         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1075         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1078         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1079         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1080         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1081         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1082         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1083         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1084         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1085         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1086         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1088         if(sv_foginterval && world.fog != "")
1089                 WriteString(MSG_ENTITY, world.fog);
1090         else
1091                 WriteString(MSG_ENTITY, "");
1092         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1093         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1094         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1095         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1096         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1097         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1098         return TRUE;
1099 }
1100
1101 void ClientInit_CheckUpdate()
1102 {
1103         self.nextthink = time;
1104         if(self.count != cvar("g_balance_armor_blockpercent"))
1105         {
1106                 self.count = cvar("g_balance_armor_blockpercent");
1107                 self.SendFlags |= 1;
1108         }
1109         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1110         {
1111                 self.cnt = cvar("g_balance_weaponswitchdelay");
1112                 self.SendFlags |= 1;
1113         }
1114         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1115         {
1116                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1117                 self.SendFlags |= 1;
1118         }
1119         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1120         {
1121                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1122                 self.SendFlags |= 1;
1123         }
1124 }
1125
1126 void ClientInit_Spawn()
1127 {
1128         entity o;
1129         entity e;
1130         e = spawn();
1131         e.classname = "clientinit";
1132         e.think = ClientInit_CheckUpdate;
1133         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1134
1135         o = self;
1136         self = e;
1137         ClientInit_CheckUpdate();
1138         self = o;
1139 }
1140
1141 /*
1142 =============
1143 SetNewParms
1144 =============
1145 */
1146 void SetNewParms (void)
1147 {
1148         // initialize parms for a new player
1149         parm1 = -(86400 * 366);
1150 }
1151
1152 /*
1153 =============
1154 SetChangeParms
1155 =============
1156 */
1157 void SetChangeParms (void)
1158 {
1159         // save parms for level change
1160         parm1 = self.parm_idlesince - time;
1161 }
1162
1163 /*
1164 =============
1165 DecodeLevelParms
1166 =============
1167 */
1168 void DecodeLevelParms (void)
1169 {
1170         // load parms
1171         self.parm_idlesince = parm1;
1172         if(self.parm_idlesince == -(86400 * 366))
1173                 self.parm_idlesince = time;
1174
1175         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1176         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1177 }
1178
1179 /*
1180 =============
1181 ClientKill
1182
1183 Called when a client types 'kill' in the console
1184 =============
1185 */
1186
1187 void ClientKill_Now_TeamChange()
1188 {
1189         if(self.killindicator_teamchange == -1)
1190         {
1191                 self.team = -1;
1192                 JoinBestTeam( self, FALSE, FALSE );
1193         }
1194         else
1195                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1196 }
1197
1198 void ClientKill_Now()
1199 {
1200         if(self.killindicator_teamchange)
1201                 ClientKill_Now_TeamChange();
1202
1203         // in any case:
1204         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1205
1206         if(self.killindicator)
1207         {
1208                 dprint("Cleaned up after a leaked kill indicator.\n");
1209                 remove(self.killindicator);
1210                 self.killindicator = world;
1211         }
1212 }
1213 void KillIndicator_Think()
1214 {
1215         if (!self.owner.modelindex)
1216         {
1217                 self.owner.killindicator = world;
1218                 remove(self);
1219                 return;
1220         }
1221
1222         if(self.cnt <= 0)
1223         {
1224                 self = self.owner;
1225                 ClientKill_Now(); // no oldself needed
1226                 return;
1227         }
1228         else
1229         {
1230                 if(self.cnt <= 10)
1231                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1232                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1233                 {
1234                         if(self.cnt <= 10)
1235                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1236                         if(self.owner.killindicator_teamchange)
1237                         {
1238                                 if(self.owner.killindicator_teamchange == -1)
1239                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1240                                 else
1241                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1242                         }
1243                         else
1244                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1245                 }
1246                 self.nextthink = time + 1;
1247                 self.cnt -= 1;
1248         }
1249 }
1250
1251 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1252 {
1253         float killtime;
1254         entity e;
1255         killtime = cvar("g_balance_kill_delay");
1256
1257         if(g_race_qualifying)
1258                 killtime = 0;
1259
1260         self.killindicator_teamchange = targetteam;
1261
1262         if(!self.killindicator)
1263         {
1264                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1265                 {
1266                         ClientKill_Now();
1267                 }
1268                 else
1269                 {
1270                         self.killindicator = spawn();
1271                         self.killindicator.owner = self;
1272                         self.killindicator.scale = 0.5;
1273                         setattachment(self.killindicator, self, "");
1274                         setorigin(self.killindicator, '0 0 52');
1275                         self.killindicator.think = KillIndicator_Think;
1276                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1277                         self.killindicator.cnt = ceil(killtime);
1278                         self.killindicator.count = bound(0, ceil(killtime), 10);
1279                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1280
1281                         for(e = world; (e = find(e, classname, "body")) != world; )
1282                         {
1283                                 if(e.enemy != self)
1284                                         continue;
1285                                 e.killindicator = spawn();
1286                                 e.killindicator.owner = e;
1287                                 e.killindicator.scale = 0.5;
1288                                 setattachment(e.killindicator, e, "");
1289                                 setorigin(e.killindicator, '0 0 52');
1290                                 e.killindicator.think = KillIndicator_Think;
1291                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1292                                 e.killindicator.cnt = ceil(killtime);
1293                         }
1294                         self.lip = 0;
1295                 }
1296         }
1297         if(self.killindicator)
1298         {
1299                 if(targetteam)
1300                         self.killindicator.colormod = TeamColor(targetteam);
1301                 else
1302                         self.killindicator.colormod = '0 0 0';
1303         }
1304 }
1305
1306 void ClientKill (void)
1307 {
1308         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1309         {
1310                 // do nothing
1311         }
1312         else
1313                 ClientKill_TeamChange(0);
1314 }
1315
1316 void DoTeamChange(float destteam)
1317 {
1318         float t, c0;
1319         if(!teams_matter)
1320         {
1321                 if(destteam >= 0)
1322                         SetPlayerColors(self, destteam);
1323                 return;
1324         }
1325         if(self.classname == "player")
1326         if(destteam == -1)
1327         {
1328                 CheckAllowedTeams(self);
1329                 t = FindSmallestTeam(self, TRUE);
1330                 switch(self.team)
1331                 {
1332                         case COLOR_TEAM1: c0 = c1; break;
1333                         case COLOR_TEAM2: c0 = c2; break;
1334                         case COLOR_TEAM3: c0 = c3; break;
1335                         case COLOR_TEAM4: c0 = c4; break;
1336                         default:          c0 = 999;
1337                 }
1338                 switch(t)
1339                 {
1340                         case 1:
1341                                 if(c0 > c1)
1342                                         destteam = COLOR_TEAM1;
1343                                 break;
1344                         case 2:
1345                                 if(c0 > c2)
1346                                         destteam = COLOR_TEAM2;
1347                                 break;
1348                         case 3:
1349                                 if(c0 > c3)
1350                                         destteam = COLOR_TEAM3;
1351                                 break;
1352                         case 4:
1353                                 if(c0 > c4)
1354                                         destteam = COLOR_TEAM4;
1355                                 break;
1356                 }
1357                 if(destteam == -1)
1358                         return;
1359         }
1360         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1361                 return;
1362         ClientKill_TeamChange(destteam);
1363 }
1364
1365 void FixClientCvars(entity e)
1366 {
1367         // send prediction settings to the client
1368         stuffcmd(e, "\nin_bindmap 0 0\n");
1369         if(g_race || g_cts)
1370                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1371         if(cvar("g_antilag") == 3) // client side hitscan
1372                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1373         if(sv_gentle)
1374                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1375         /*
1376          * we no longer need to stuff this. Remove this comment block if you feel
1377          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1378         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1379         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1380         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1381         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1382         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1383         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1384         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1385         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1386         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1387         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1388         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1389         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1390         stuffcmd(e, "cl_movement_edgefriction 1\n");
1391          */
1392 }
1393
1394 /*
1395 =============
1396 ClientConnect
1397
1398 Called when a client connects to the server
1399 =============
1400 */
1401 //void ctf_clientconnect();
1402 string ColoredTeamName(float t);
1403 void DecodeLevelParms (void);
1404 //void dom_player_join_team(entity pl);
1405 void ClientConnect (void)
1406 {
1407         float t;
1408
1409         if(self.flags & FL_CLIENT)
1410         {
1411                 print("Warning: ClientConnect, but already connected!\n");
1412                 return;
1413         }
1414
1415         if(Ban_MaybeEnforceBan(self))
1416                 return;
1417
1418         DecodeLevelParms();
1419
1420 #ifdef WATERMARK
1421         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1422 #endif
1423
1424         self.classname = "player_joining";
1425
1426         self.flags = FL_CLIENT;
1427         self.version_nagtime = time + 10 + random() * 10;
1428
1429         if(player_count<0)
1430         {
1431                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1432                 player_count = 0;
1433         }
1434
1435         PlayerScore_Attach(self);
1436         ClientData_Attach();
1437
1438         bot_clientconnect();
1439
1440         playerdemo_init();
1441
1442         anticheat_init();
1443
1444         race_PreSpawnObserver();
1445
1446         //if(g_domination)
1447         //      dom_player_join_team(self);
1448
1449         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1450
1451         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1452                 self.classname = "observer";
1453         } else {
1454                 if(teams_matter)
1455                 {
1456                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1457                         {
1458                                 self.classname = "player";
1459                                 campaign_bots_may_start = 1;
1460                         }
1461                         else
1462                         {
1463                                 self.classname = "observer"; // do it anyway
1464                         }
1465                 }
1466                 else
1467                 {
1468                         self.classname = "player";
1469                         campaign_bots_may_start = 1;
1470                 }
1471         }
1472
1473         self.playerid = (playerid_last = playerid_last + 1);
1474
1475         if(cvar("sv_eventlog"))
1476                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1477
1478         LogTeamchange(self.playerid, self.team, 1);
1479
1480         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1481
1482         self.netname_previous = strzone(self.netname);
1483
1484         bprint("^4", self.netname, "^4 connected");
1485
1486         if(self.classname != "observer" && (g_domination || g_ctf))
1487                 bprint(" and joined the ", ColoredTeamName(self.team));
1488
1489         bprint("\n");
1490
1491         self.welcomemessage_time = 0;
1492
1493         stuffcmd(self, strcat(clientstuff, "\n"));
1494         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1495         stuffcmd(self, "cl_particles_reloadeffects\n");
1496
1497         FixClientCvars(self);
1498
1499         // spawnfunc_waypoint sprites
1500         WaypointSprite_InitClient(self);
1501
1502         // Wazat's grappling hook
1503         SetGrappleHookBindings();
1504
1505         // get autoswitch state from player when he toggles it
1506         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1507
1508         // get version info from player
1509         stuffcmd(self, "cmd clientversion $gameversion\n");
1510
1511         // get other cvars from player
1512         GetCvars(0);
1513
1514         // set cvar for team scoreboard
1515         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1516
1517         // notify about available teams
1518         if(teams_matter)
1519         {
1520                 CheckAllowedTeams(self);
1521                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1522                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1523         }
1524         else
1525                 stuffcmd(self, "set _teams_available 0\n");
1526
1527         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1528
1529         if(g_arena || g_ca)
1530         {
1531                 self.classname = "observer";
1532                 if(g_arena)
1533                         Spawnqueue_Insert(self);
1534         }
1535         /*else if(g_ctf)
1536         {
1537                 ctf_clientconnect();
1538         }*/
1539
1540         if(teams_matter || radar_showennemies)
1541                 attach_entcs();
1542
1543         bot_relinkplayerlist();
1544
1545         self.spectatortime = time;
1546         if(blockSpectators)
1547         {
1548                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1549         }
1550
1551         self.jointime = time;
1552         self.allowedTimeouts = cvar("sv_timeout_number");
1553
1554         if(clienttype(self) == CLIENTTYPE_REAL)
1555         {
1556                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1557                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1558         }
1559
1560         if(g_lms)
1561         {
1562                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1563                 {
1564                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1565                         self.frags = FRAGS_SPECTATOR;
1566                 }
1567         }
1568
1569         if(!sv_foginterval && world.fog != "")
1570                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1571
1572         SoundEntity_Attach(self);
1573
1574         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1575         {
1576                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1577                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1578         }
1579         else
1580                 self.hitplotfh = -1;
1581
1582         if(g_race || g_cts) {
1583                 string rr;
1584                 if(g_cts)
1585                         rr = CTS_RECORD;
1586                 else
1587                         rr = RACE_RECORD;
1588                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1589
1590                 race_send_recordtime(MSG_ONE);
1591                 race_send_speedaward(MSG_ONE);
1592
1593                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1594                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1595                 race_send_speedaward_alltimebest(MSG_ONE);
1596
1597                 float i;
1598                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1599                         race_SendRankings(i, 0, 0, MSG_ONE);
1600                 }
1601         }
1602         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1603                 send_CSQC_teamnagger();
1604
1605         send_CSQC_cr_maxbullets(self);
1606
1607         CheatInitClient();
1608 }
1609
1610 /*
1611 =============
1612 ClientDisconnect
1613
1614 Called when a client disconnects from the server
1615 =============
1616 */
1617 .entity chatbubbleentity;
1618 .entity teambubbleentity;
1619 void ReadyCount();
1620 void ClientDisconnect (void)
1621 {
1622         if not(self.flags & FL_CLIENT)
1623         {
1624                 print("Warning: ClientDisconnect without ClientConnect\n");
1625                 return;
1626         }
1627
1628         CheatShutdownClient();
1629
1630         if(self.hitplotfh >= 0)
1631         {
1632                 fclose(self.hitplotfh);
1633                 self.hitplotfh = -1;
1634         }
1635
1636         anticheat_report();
1637         anticheat_shutdown();
1638
1639         playerdemo_shutdown();
1640
1641         bot_clientdisconnect();
1642
1643         if(self.entcs)
1644                 detach_entcs();
1645
1646         if(cvar("sv_eventlog"))
1647                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1648         bprint ("^4",self.netname);
1649         bprint ("^4 disconnected\n");
1650
1651         SoundEntity_Detach(self);
1652
1653         DropAllRunes(self);
1654         MUTATOR_CALLHOOK(ClientDisconnect);
1655
1656         Portal_ClearAll(self);
1657
1658         if(self.flagcarried)
1659                 DropFlag(self.flagcarried, world, world);
1660         if(self.ballcarried)
1661                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1662
1663         // Here, everything has been done that requires this player to be a client.
1664
1665         self.flags &~= FL_CLIENT;
1666
1667         if (self.chatbubbleentity)
1668                 remove (self.chatbubbleentity);
1669
1670         if (self.teambubbleentity)
1671                 remove (self.teambubbleentity);
1672
1673         if (self.killindicator)
1674                 remove (self.killindicator);
1675
1676         WaypointSprite_PlayerGone();
1677
1678         bot_relinkplayerlist();
1679
1680         // remove laserdot
1681         if(self.weaponentity)
1682                 if(self.weaponentity.lasertarget)
1683                         remove(self.weaponentity.lasertarget);
1684
1685         if(g_arena)
1686         {
1687                 Spawnqueue_Unmark(self);
1688                 Spawnqueue_Remove(self);
1689         }
1690
1691         ClientData_Detach();
1692         PlayerScore_Detach(self);
1693
1694         if(self.netname_previous)
1695                 strunzone(self.netname_previous);
1696         if(self.clientstatus)
1697                 strunzone(self.clientstatus);
1698         if(self.weaponorder_byimpulse)
1699                 strunzone(self.weaponorder_byimpulse);
1700
1701         ClearPlayerSounds();
1702
1703         if(self.personal)
1704                 remove(self.personal);
1705
1706         self.playerid = 0;
1707         ReadyCount();
1708
1709         // free cvars
1710         GetCvars(-1);
1711 }
1712
1713 .float BUTTON_CHAT;
1714 void ChatBubbleThink()
1715 {
1716         self.nextthink = time;
1717         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1718         {
1719                 if(self.owner) // but why can that ever be world?
1720                         self.owner.chatbubbleentity = world;
1721                 remove(self);
1722                 return;
1723         }
1724         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1725 #ifdef TETRIS
1726                 || self.owner.tetris_on
1727 #endif
1728         )
1729                 self.model = self.mdl;
1730         else
1731                 self.model = "";
1732 };
1733
1734 void UpdateChatBubble()
1735 {
1736         if (!self.modelindex)
1737                 return;
1738         // spawn a chatbubble entity if needed
1739         if (!self.chatbubbleentity)
1740         {
1741                 self.chatbubbleentity = spawn();
1742                 self.chatbubbleentity.owner = self;
1743                 self.chatbubbleentity.exteriormodeltoclient = self;
1744                 self.chatbubbleentity.think = ChatBubbleThink;
1745                 self.chatbubbleentity.nextthink = time;
1746                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1747                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1748                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1749                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1750                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1751                 self.chatbubbleentity.model = "";
1752                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1753         }
1754 }
1755
1756
1757 void TeamBubbleThink()
1758 {
1759         self.nextthink = time;
1760         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1761         {
1762                 if(self.owner) // but why can that ever be world?
1763                         self.owner.teambubbleentity = world;
1764                 remove(self);
1765                 return;
1766         }
1767 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1768         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1769                 self.model = "";
1770         else
1771                 self.model = self.mdl;
1772
1773 };
1774
1775 float TeamBubble_customizeentityforclient()
1776 {
1777         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1778 }
1779
1780 void UpdateTeamBubble()
1781 {
1782         if (!self.modelindex || !teams_matter)
1783                 return;
1784         // spawn a teambubble entity if needed
1785         if (!self.teambubbleentity && teams_matter)
1786         {
1787                 self.teambubbleentity = spawn();
1788                 self.teambubbleentity.owner = self;
1789                 self.teambubbleentity.exteriormodeltoclient = self;
1790                 self.teambubbleentity.think = TeamBubbleThink;
1791                 self.teambubbleentity.nextthink = time;
1792                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1793 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1794                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1795                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1796                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1797                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1798                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1799                 self.teambubbleentity.effects = EF_LOWPRECISION;
1800         }
1801 }
1802
1803 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1804 // added to the model skins
1805 /*void UpdateColorModHack()
1806 {
1807         local float c;
1808         c = self.clientcolors & 15;
1809         // LordHavoc: only bothering to support white, green, red, yellow, blue
1810              if (!teams_matter) self.colormod = '0 0 0';
1811         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1812         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1813         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1814         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1815         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1816         else self.colormod = '1 1 1';
1817 };*/
1818
1819 .float oldcolormap;
1820 void respawn(void)
1821 {
1822         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1823         {
1824                 self.solid = SOLID_NOT;
1825                 self.takedamage = DAMAGE_NO;
1826                 self.movetype = MOVETYPE_FLY;
1827                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1828                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1829                 self.effects |= EF_ADDITIVE;
1830                 self.oldcolormap = self.colormap;
1831                 self.colormap = 512;
1832                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1833                 if(cvar("g_respawn_ghosts_maxtime"))
1834                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1835         }
1836
1837         CopyBody(1);
1838         self.effects |= EF_NODRAW; // prevent another CopyBody
1839         if(self.oldcolormap)
1840         {
1841                 self.colormap = self.oldcolormap;
1842                 self.oldcolormap = 0;
1843         }
1844         PutClientInServer();
1845 }
1846
1847 void play_countdown(float finished, string samp)
1848 {
1849         if(clienttype(self) == CLIENTTYPE_REAL)
1850                 if(floor(finished - time - frametime) != floor(finished - time))
1851                         if(finished - time < 6)
1852                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1853 }
1854
1855 /**
1856  * When sv_timeout is used this function returs strings like
1857  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1858  * Called by centerprint functions
1859  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1860  */
1861 string getTimeoutText(float addOneSecond) {
1862         if (!cvar("sv_timeout") || !timeoutStatus)
1863                 return "";
1864
1865         local string retStr;
1866         if (timeoutStatus == 1) {
1867                 if (addOneSecond == 1) {
1868                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1869                 }
1870                 else {
1871                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1872                 }
1873                 return retStr;
1874         }
1875         else if (timeoutStatus == 2) {
1876                 if (addOneSecond) {
1877                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1878                         //don't show messages like "Timeout ends in 0 seconds"...
1879                         if ((remainingTimeoutTime + 1) > 0)
1880                                 return retStr;
1881                         else
1882                                 return "";
1883                 }
1884                 else {
1885                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1886                         //don't show messages like "Timeout ends in 0 seconds"...
1887                         if (remainingTimeoutTime > 0)
1888                                 return retStr;
1889                         else
1890                                 return "";
1891                 }
1892         }
1893         else return "";
1894 }
1895
1896 void player_powerups (void)
1897 {
1898         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1899         {
1900                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1901                 self.modelflags |= MF_ROCKET;
1902         }
1903         else
1904         {
1905                 SoundEntity_StopSound(self, CHAN_PLAYER);
1906                 self.modelflags &~= MF_ROCKET;
1907         }
1908
1909         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1910
1911         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1912                 return;
1913
1914         Fire_ApplyDamage(self);
1915         Fire_ApplyEffect(self);
1916
1917         if (g_minstagib)
1918         {
1919                 self.effects |= EF_FULLBRIGHT;
1920
1921                 if (self.items & IT_STRENGTH)
1922                 {
1923                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1924                         if (time > self.strength_finished)
1925                         {
1926                                 self.alpha = default_player_alpha;
1927                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1928                                 self.items &~= IT_STRENGTH;
1929                                 sprint(self, "^3Invisibility has worn off\n");
1930                         }
1931                 }
1932                 else
1933                 {
1934                         if (time < self.strength_finished)
1935                         {
1936                                 self.alpha = g_minstagib_invis_alpha;
1937                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1938                                 self.items |= IT_STRENGTH;
1939                                 sprint(self, "^3You are invisible\n");
1940                         }
1941                 }
1942
1943                 if (self.items & IT_INVINCIBLE)
1944                 {
1945                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1946                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1947                         {
1948                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1949                                 sprint(self, "^3Speed has worn off\n");
1950                         }
1951                 }
1952                 else
1953                 {
1954                         if (time < self.invincible_finished)
1955                         {
1956                                 self.items = self.items | IT_INVINCIBLE;
1957                                 sprint(self, "^3You are on speed\n");
1958                         }
1959                 }
1960                 return;
1961         }
1962
1963         if (self.items & IT_STRENGTH)
1964         {
1965                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1966                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1967                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1968                 {
1969                         self.items = self.items - (self.items & IT_STRENGTH);
1970                         sprint(self, "^3Strength has worn off\n");
1971                 }
1972         }
1973         else
1974         {
1975                 if (time < self.strength_finished)
1976                 {
1977                         self.items = self.items | IT_STRENGTH;
1978                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1979                 }
1980         }
1981         if (self.items & IT_INVINCIBLE)
1982         {
1983                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1984                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1985                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1986                 {
1987                         self.items = self.items - (self.items & IT_INVINCIBLE);
1988                         sprint(self, "^3Shield has worn off\n");
1989                 }
1990         }
1991         else
1992         {
1993                 if (time < self.invincible_finished)
1994                 {
1995                         self.items = self.items | IT_INVINCIBLE;
1996                         sprint(self, "^3Shield surrounds you\n");
1997                 }
1998         }
1999
2000         if(cvar("g_nodepthtestplayers"))
2001                 self.effects = self.effects | EF_NODEPTHTEST;
2002
2003         if(cvar("g_fullbrightplayers"))
2004                 self.effects = self.effects | EF_FULLBRIGHT;
2005
2006         // midair gamemode: damage only while in the air
2007         // if in midair mode, being on ground grants temporary invulnerability
2008         // (this is so that multishot weapon don't clear the ground flag on the
2009         // first damage in the frame, leaving the player vulnerable to the
2010         // remaining hits in the same frame)
2011         if (self.flags & FL_ONGROUND)
2012         if (g_midair)
2013                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2014
2015         if (time >= game_starttime)
2016         if (time < self.spawnshieldtime)
2017                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2018 }
2019
2020 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2021 {
2022         if(current > stable)
2023                 return current;
2024         else if(current > stable - 0.25) // when close enough, "snap"
2025                 return stable;
2026         else
2027                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2028 }
2029
2030 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2031 {
2032         if(current < stable)
2033                 return current;
2034         else if(current < stable + 0.25) // when close enough, "snap"
2035                 return stable;
2036         else
2037                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2038 }
2039
2040 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2041 {
2042         if(current > rotstable)
2043         {
2044                 if(rotframetime > 0)
2045                 {
2046                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2047                         current = max(rotstable, current - rotlinear * rotframetime);
2048                 }
2049         }
2050         else if(current < regenstable)
2051         {
2052                 if(regenframetime > 0)
2053                 {
2054                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2055                         current = min(regenstable, current + regenlinear * regenframetime);
2056                 }
2057         }
2058
2059         if(current > limit)
2060                 current = limit;
2061
2062         return current;
2063 }
2064
2065 void player_regen (void)
2066 {
2067         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2068         maxh = cvar("g_balance_health_rotstable");
2069         maxa = cvar("g_balance_armor_rotstable");
2070         maxf = cvar("g_balance_fuel_rotstable");
2071         minh = cvar("g_balance_health_regenstable");
2072         mina = cvar("g_balance_armor_regenstable");
2073         minf = cvar("g_balance_fuel_regenstable");
2074         limith = cvar("g_balance_health_limit");
2075         limita = cvar("g_balance_armor_limit");
2076         limitf = cvar("g_balance_fuel_limit");
2077
2078         max_mod = regen_mod = rot_mod = limit_mod = 1;
2079
2080         if (self.runes & RUNE_REGEN)
2081         {
2082                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2083                 {
2084                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2085                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2086                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2087                 }
2088                 else
2089                 {
2090                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2091                         max_mod = cvar("g_balance_rune_regen_hpmod");
2092                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2093                 }
2094         }
2095         else if (self.runes & CURSE_VENOM)
2096         {
2097                 max_mod = cvar("g_balance_curse_venom_hpmod");
2098                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2099                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2100                 else
2101                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2102                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2103                 //if (!self.runes & RUNE_REGEN)
2104                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2105         }
2106         maxh = maxh * max_mod;
2107         //maxa = maxa * max_mod;
2108         //maxf = maxf * max_mod;
2109         minh = minh * max_mod;
2110         //mina = mina * max_mod;
2111         //minf = minf * max_mod;
2112         limith = limith * limit_mod;
2113         limita = limita * limit_mod;
2114         //limitf = limitf * limit_mod;
2115
2116         if(g_lms && g_ca)
2117                 rot_mod = 0;
2118
2119         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2120         {
2121                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2122                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2123
2124                 // if player rotted to death...  die!
2125                 if(self.health < 1)
2126                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2127         }
2128
2129         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2130                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2131 }
2132
2133 float zoomstate_set;
2134 void SetZoomState(float z)
2135 {
2136         if(z != self.zoomstate)
2137         {
2138                 self.zoomstate = z;
2139                 ClientData_Touch(self);
2140         }
2141         zoomstate_set = 1;
2142 }
2143
2144 void GetPressedKeys(void) {
2145         MUTATOR_CALLHOOK(GetPressedKeys);
2146         if (self.movement_x > 0) // get if movement keys are pressed
2147         {       // forward key pressed
2148                 self.pressedkeys |= KEY_FORWARD;
2149                 self.pressedkeys &~= KEY_BACKWARD;
2150         }
2151         else if (self.movement_x < 0)
2152         {       // backward key pressed
2153                 self.pressedkeys |= KEY_BACKWARD;
2154                 self.pressedkeys &~= KEY_FORWARD;
2155         }
2156         else
2157         {       // no x input
2158                 self.pressedkeys &~= KEY_FORWARD;
2159                 self.pressedkeys &~= KEY_BACKWARD;
2160         }
2161
2162         if (self.movement_y > 0)
2163         {       // right key pressed
2164                 self.pressedkeys |= KEY_RIGHT;
2165                 self.pressedkeys &~= KEY_LEFT;
2166         }
2167         else if (self.movement_y < 0)
2168         {       // left key pressed
2169                 self.pressedkeys |= KEY_LEFT;
2170                 self.pressedkeys &~= KEY_RIGHT;
2171         }
2172         else
2173         {       // no y input
2174                 self.pressedkeys &~= KEY_RIGHT;
2175                 self.pressedkeys &~= KEY_LEFT;
2176         }
2177
2178         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2179                 self.pressedkeys |= KEY_JUMP;
2180         else
2181                 self.pressedkeys &~= KEY_JUMP;
2182         if (self.BUTTON_CROUCH)
2183                 self.pressedkeys |= KEY_CROUCH;
2184         else
2185                 self.pressedkeys &~= KEY_CROUCH;
2186 }
2187
2188 void update_stats (float number, float hit, float fired) {
2189 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2190 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2191
2192         if(number) {
2193                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2194                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2195         } else {
2196                 self.stat_hit = hit * sv_accuracy_data_share;
2197                 self.stat_fired = fired * sv_accuracy_data_share;
2198         }
2199 }
2200
2201 /*
2202 ======================
2203 spectate mode routines
2204 ======================
2205 */
2206
2207 .float weapon_count;
2208 void SpectateCopy(entity spectatee) {
2209         if(spectatee.weapon_count < WEP_LAST) {
2210                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2211                 spectatee.weapon_count ++;
2212         } else
2213                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2214
2215         other = spectatee;
2216         MUTATOR_CALLHOOK(SpectateCopy);
2217         self.armortype = spectatee.armortype;
2218         self.armorvalue = spectatee.armorvalue;
2219         self.ammo_cells = spectatee.ammo_cells;
2220         self.ammo_shells = spectatee.ammo_shells;
2221         self.ammo_nails = spectatee.ammo_nails;
2222         self.ammo_rockets = spectatee.ammo_rockets;
2223         self.ammo_fuel = spectatee.ammo_fuel;
2224         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2225         self.health = spectatee.health;
2226         self.impulse = 0;
2227         self.items = spectatee.items;
2228         self.last_pickup = spectatee.last_pickup;
2229         self.metertime = spectatee.metertime;
2230         self.strength_finished = spectatee.strength_finished;
2231         self.invincible_finished = spectatee.invincible_finished;
2232         self.pressedkeys = spectatee.pressedkeys;
2233         self.weapons = spectatee.weapons;
2234         self.switchweapon = spectatee.switchweapon;
2235         self.weapon = spectatee.weapon;
2236         self.punchangle = spectatee.punchangle;
2237         self.view_ofs = spectatee.view_ofs;
2238         self.v_angle = spectatee.v_angle;
2239         self.velocity = spectatee.velocity;
2240         self.dmg_take = spectatee.dmg_take;
2241         self.dmg_save = spectatee.dmg_save;
2242         self.dmg_inflictor = spectatee.dmg_inflictor;
2243         self.angles = spectatee.v_angle;
2244         self.fixangle = TRUE;
2245         setorigin(self, spectatee.origin);
2246         setsize(self, spectatee.mins, spectatee.maxs);
2247         SetZoomState(spectatee.zoomstate);
2248
2249         anticheat_spectatecopy(spectatee);
2250 }
2251
2252 float SpectateUpdate() {
2253         if(!self.enemy)
2254                 return 0;
2255
2256         if (self == self.enemy)
2257                 return 0;
2258
2259         if(self.enemy.classname != "player")
2260                 return 0;
2261
2262         SpectateCopy(self.enemy);
2263
2264         return 1;
2265 }
2266
2267 float SpectateNext() {
2268         other = find(self.enemy, classname, "player");
2269
2270         if (!other)
2271                 other = find(other, classname, "player");
2272
2273         if (other)
2274                 self.enemy = other;
2275
2276         if(self.enemy.classname == "player") {
2277                 msg_entity = self;
2278                 WriteByte(MSG_ONE, SVC_SETVIEW);
2279                 WriteEntity(MSG_ONE, self.enemy);
2280                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2281                 self.movetype = MOVETYPE_NONE;
2282
2283                 self.enemy.weapon_count = 0;
2284
2285                 if(!SpectateUpdate())
2286                         PutObserverInServer();
2287
2288                 return 1;
2289         } else {
2290                 return 0;
2291         }
2292 }
2293
2294 /*
2295 =============
2296 ShowRespawnCountdown()
2297
2298 Update a respawn countdown display.
2299 =============
2300 */
2301 void ShowRespawnCountdown()
2302 {
2303         float number;
2304         if(self.deadflag == DEAD_NO) // just respawned?
2305                 return;
2306         else
2307         {
2308                 number = ceil(self.death_time - time);
2309                 if(number <= 0)
2310                         return;
2311                 if(number <= self.respawn_countdown)
2312                 {
2313                         self.respawn_countdown = number - 1;
2314                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2315                                 AnnounceTo(self, strcat(ftos(number), ""));
2316                 }
2317         }
2318 }
2319
2320 void LeaveSpectatorMode()
2321 {
2322         if(isJoinAllowed()) {
2323                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2324                         self.classname = "player";
2325
2326                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2327                                 JoinBestTeam(self, FALSE, TRUE);
2328
2329                         if(cvar("g_campaign"))
2330                                 campaign_bots_may_start = 1;
2331
2332                         self.stat_count = WEP_LAST;
2333
2334                         PutClientInServer();
2335
2336                         if(self.classname == "player")
2337                                 bprint ("^4", self.netname, "^4 is playing now\n");
2338
2339                         if(!cvar("g_campaign"))
2340                                 centerprint(self,""); // clear MOTD
2341
2342                         return;
2343                 } else {
2344                         if (g_ca && self.caplayer) {
2345                         }       // do nothing
2346                         else
2347                                 stuffcmd(self,"menu_showteamselect\n");
2348                         return;
2349                 }
2350         }
2351         else {
2352                 //player may not join because of g_maxplayers is set
2353                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2354         }
2355 }
2356
2357 /**
2358  * Determines whether the player is allowed to join. This depends on cvar
2359  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2360  * it checks whether the number of currently playing players exceeds g_maxplayers.
2361  * @return bool TRUE if the player is allowed to join, false otherwise
2362  */
2363 float isJoinAllowed() {
2364         if (!cvar("g_maxplayers"))
2365                 return TRUE;
2366
2367         local entity e;
2368         local float currentlyPlaying;
2369         FOR_EACH_REALPLAYER(e) {
2370                 if(e.classname == "player")
2371                         currentlyPlaying += 1;
2372         }
2373         if(currentlyPlaying < cvar("g_maxplayers"))
2374                 return TRUE;
2375
2376         return FALSE;
2377 }
2378
2379 /**
2380  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2381  * g_maxplayers_spectator_blocktime seconds
2382  */
2383 void checkSpectatorBlock() {
2384         if(self.classname == "spectator" || self.classname == "observer") {
2385                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2386                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2387                         dropclient(self);
2388                 }
2389         }
2390 }
2391
2392 float vercmp_recursive(string v1, string v2)
2393 {
2394         float dot1, dot2;
2395         string s1, s2;
2396         float r;
2397
2398         dot1 = strstrofs(v1, ".", 0);
2399         dot2 = strstrofs(v2, ".", 0);
2400         if(dot1 == -1)
2401                 s1 = v1;
2402         else
2403                 s1 = substring(v1, 0, dot1);
2404         if(dot2 == -1)
2405                 s2 = v2;
2406         else
2407                 s2 = substring(v2, 0, dot2);
2408
2409         r = stof(s1) - stof(s2);
2410         if(r != 0)
2411                 return r;
2412
2413         r = strcasecmp(s1, s2);
2414         if(r != 0)
2415                 return r;
2416
2417         if(dot1 == -1)
2418                 if(dot2 == -1)
2419                         return 0;
2420                 else
2421                         return -1;
2422         else
2423                 if(dot2 == -1)
2424                         return 1;
2425                 else
2426                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2427 }
2428
2429 float vercmp(string v1, string v2)
2430 {
2431         if(strcasecmp(v1, v2) == 0) // early out check
2432                 return 0;
2433         return vercmp_recursive(v1, v2);
2434 }
2435
2436 void ObserverThink()
2437 {
2438         if (self.flags & FL_JUMPRELEASED) {
2439                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2440                         self.welcomemessage_time = 0;
2441                         self.flags &~= FL_JUMPRELEASED;
2442                         self.flags |= FL_SPAWNING;
2443                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2444                         self.welcomemessage_time = 0;
2445                         self.flags &~= FL_JUMPRELEASED;
2446                         if(SpectateNext() == 1) {
2447                                 self.classname = "spectator";
2448                         }
2449                 }
2450         } else {
2451                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2452                         self.flags |= FL_JUMPRELEASED;
2453                         if(self.flags & FL_SPAWNING)
2454                         {
2455                                 self.flags &~= FL_SPAWNING;
2456                                 LeaveSpectatorMode();
2457                                 return;
2458                         }
2459                 }
2460         }
2461         PrintWelcomeMessage(self);
2462 }
2463
2464 void SpectatorThink()
2465 {
2466         if (self.flags & FL_JUMPRELEASED) {
2467                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2468                         self.welcomemessage_time = 0;
2469                         self.flags &~= FL_JUMPRELEASED;
2470                         self.flags |= FL_SPAWNING;
2471                 } else if(self.BUTTON_ATCK) {
2472                         self.welcomemessage_time = 0;
2473                         self.flags &~= FL_JUMPRELEASED;
2474                         if(SpectateNext() == 1) {
2475                                 self.classname = "spectator";
2476                         } else {
2477                                 self.classname = "observer";
2478                                 self.stat_count = WEP_LAST;
2479                                 PutClientInServer();
2480                         }
2481                 } else if (self.BUTTON_ATCK2) {
2482                         self.welcomemessage_time = 0;
2483                         self.flags &~= FL_JUMPRELEASED;
2484                         self.classname = "observer";
2485                         self.stat_count = WEP_LAST;
2486                         PutClientInServer();
2487                 } else {
2488                         if(!SpectateUpdate())
2489                                 PutObserverInServer();
2490                 }
2491         } else {
2492                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2493                         self.flags |= FL_JUMPRELEASED;
2494                         if(self.flags & FL_SPAWNING)
2495                         {
2496                                 self.flags &~= FL_SPAWNING;
2497                                 LeaveSpectatorMode();
2498                                 return;
2499                         }
2500                 }
2501         }
2502
2503         PrintWelcomeMessage(self);
2504         self.flags |= FL_CLIENT | FL_NOTARGET;
2505 }
2506
2507 .float touchexplode_time;
2508
2509 /*
2510 =============
2511 PlayerPreThink
2512
2513 Called every frame for each client before the physics are run
2514 =============
2515 */
2516 void() ctf_setstatus;
2517 void() nexball_setstatus;
2518 .float items_added;
2519 void PlayerPreThink (void)
2520 {
2521         self.stat_game_starttime = game_starttime;
2522         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2523         self.stat_leadlimit = cvar("leadlimit");
2524
2525         if(frametime)
2526         {
2527                 // physics frames: update anticheat stuff
2528                 anticheat_prethink();
2529         }
2530
2531         if(blockSpectators && frametime)
2532                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2533                 checkSpectatorBlock();
2534
2535         zoomstate_set = 0;
2536
2537         if(self.netname_previous != self.netname)
2538         {
2539                 if(cvar("sv_eventlog"))
2540                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2541                 if(self.netname_previous)
2542                         strunzone(self.netname_previous);
2543                 self.netname_previous = strzone(self.netname);
2544         }
2545
2546         // version nagging
2547         if(self.version_nagtime)
2548                 if(self.cvar_g_xonoticversion)
2549                         if(time > self.version_nagtime)
2550                         {
2551                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2552                                 {
2553                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2554                                         {
2555                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2556                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2557                                         }
2558                                         else
2559                                         {
2560                                                 float r;
2561                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2562                                                 if(r < 0)
2563                                                 {
2564                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2565                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2566                                                 }
2567                                                 else if(r > 0)
2568                                                 {
2569                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2570                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2571                                                 }
2572                                         }
2573                                 }
2574                                 self.version_nagtime = 0;
2575                         }
2576
2577         // GOD MODE info
2578         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2579         {
2580                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2581                 self.max_armorvalue = 0;
2582         }
2583
2584 #ifdef TETRIS
2585         if (TetrisPreFrame())
2586                 return;
2587 #endif
2588
2589         MUTATOR_CALLHOOK(PlayerPreThink);
2590
2591         if(self.classname == "player") {
2592 //              if(self.netname == "Wazat")
2593 //                      bprint(self.classname, "\n");
2594
2595                 CheckRules_Player();
2596
2597                 PrintWelcomeMessage(self);
2598
2599                 if (intermission_running)
2600                 {
2601                         IntermissionThink ();   // otherwise a button could be missed between
2602                         return;                                 // the think tics
2603                 }
2604
2605                 if(self.teleport_time)
2606                 if(time > self.teleport_time)
2607                 {
2608                         self.teleport_time = 0;
2609                         self.effects = self.effects - (self.effects & EF_NODRAW);
2610                 }
2611
2612                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2613                         UpdateSelectedPlayer();
2614
2615                 //don't allow the player to turn around while game is paused!
2616                 if(timeoutStatus == 2) {
2617                         self.v_angle = self.lastV_angle;
2618                         self.angles = self.lastV_angle;
2619                         self.fixangle = TRUE;
2620                 }
2621
2622                 if(frametime)
2623                 {
2624                         if(self.health <= 0 && cvar("g_deathglow"))
2625                         {
2626                                 if(self.glowmod_x > 0)
2627                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2628                                 else
2629                                         self.glowmod_x = -1;
2630                                 if(self.glowmod_y > 0)
2631                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2632                                 else
2633                                         self.glowmod_y = -1;
2634                                 if(self.glowmod_z > 0)
2635                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2636                                 else
2637                                         self.glowmod_z = -1;
2638                         }
2639                         else
2640                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2641                         player_powerups();
2642                 }
2643
2644                 if (self.deadflag != DEAD_NO)
2645                 {
2646                         float button_pressed, force_respawn;
2647                         if(self.personal && g_race_qualifying)
2648                         {
2649                                 if(time > self.death_time)
2650                                 {
2651                                         self.death_time = time + 1; // only retry once a second
2652                                         respawn();
2653                                         self.impulse = 141;
2654                                 }
2655                         }
2656                         else
2657                         {
2658                                 if(frametime)
2659                                         player_anim();
2660                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2661                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2662                                 if (self.deadflag == DEAD_DYING)
2663                                 {
2664                                         if(force_respawn)
2665                                                 self.deadflag = DEAD_RESPAWNING;
2666                                         else if(!button_pressed)
2667                                                 self.deadflag = DEAD_DEAD;
2668                                 }
2669                                 else if (self.deadflag == DEAD_DEAD)
2670                                 {
2671                                         if(button_pressed)
2672                                                 self.deadflag = DEAD_RESPAWNABLE;
2673                                 }
2674                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2675                                 {
2676                                         if(!button_pressed)
2677                                                 self.deadflag = DEAD_RESPAWNING;
2678                                 }
2679                                 else if (self.deadflag == DEAD_RESPAWNING)
2680                                 {
2681                                         if(time > self.death_time)
2682                                         {
2683                                                 self.death_time = time + 1; // only retry once a second
2684                                                 respawn();
2685                                         }
2686                                 }
2687                                 ShowRespawnCountdown();
2688                         }
2689                         return;
2690                 }
2691
2692                 if(g_touchexplode)
2693                 if(time > self.touchexplode_time)
2694                 if(self.classname == "player")
2695                 if(self.deadflag == DEAD_NO)
2696                 if not(IS_INDEPENDENT_PLAYER(self))
2697                 FOR_EACH_PLAYER(other) if(self != other)
2698                 {
2699                         if(time > other.touchexplode_time)
2700                         if(other.deadflag == DEAD_NO)
2701                         if not(IS_INDEPENDENT_PLAYER(other))
2702                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2703                         {
2704                                 PlayerTouchExplode(self, other);
2705                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2706                         }
2707                 }
2708
2709                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2710                 {
2711                         vector dist;
2712
2713                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2714                         dist = self.prevorigin - self.origin;
2715                         dist_z = 0;
2716                         self.lms_traveled_distance += fabs(vlen(dist));
2717
2718                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2719                         {
2720                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2721                                 self.lms_traveled_distance = 0;
2722                         }
2723
2724                         if(time > self.lms_nextcheck)
2725                         {
2726                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2727                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2728                                 {
2729                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2730                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2731                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2732                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2733                                 }
2734                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2735                                 self.lms_traveled_distance = 0;
2736                         }
2737                 }
2738
2739                 self.prevorigin = self.origin;
2740
2741                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2742                 {
2743                         if (!self.crouch)
2744                         {
2745                                 self.crouch = TRUE;
2746                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2747                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2748                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2749                         }
2750                 }
2751                 else
2752                 {
2753                         if (self.crouch)
2754                         {
2755                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2756                                 if (!trace_startsolid)
2757                                 {
2758                                         self.crouch = FALSE;
2759                                         self.view_ofs = PL_VIEW_OFS;
2760                                         setsize (self, PL_MIN, PL_MAX);
2761                                 }
2762                         }
2763                 }
2764
2765                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2766                 {
2767                         if(self.bloodloss_timer < time)
2768                         {
2769                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2770                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2771                         }
2772                 }
2773
2774                 FixPlayermodel();
2775
2776                 GrapplingHookFrame();
2777
2778                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2779                 //if(frametime)
2780                 {
2781                         self.items &~= self.items_added;
2782
2783                         W_WeaponFrame();
2784
2785                         self.items_added = 0;
2786                         if(self.items & IT_JETPACK)
2787                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2788                                         self.items_added |= IT_FUEL;
2789
2790                         self.items |= self.items_added;
2791                 }
2792
2793                 player_regen();
2794                 if(frametime)
2795                         player_anim();
2796
2797                 if (g_minstagib)
2798                         minstagib_ammocheck();
2799
2800                 ctf_setstatus();
2801                 nexball_setstatus();
2802
2803                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2804
2805                 //self.angles_y=self.v_angle_y + 90;   // temp
2806         } else if(gameover) {
2807                 if (intermission_running)
2808                         IntermissionThink ();   // otherwise a button could be missed between
2809                 return;
2810         } else if(self.classname == "observer") {
2811                 ObserverThink();
2812         } else if(self.classname == "spectator") {
2813                 SpectatorThink();
2814         }
2815
2816         if(!zoomstate_set)
2817                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2818
2819         float oldspectatee_status;
2820         oldspectatee_status = self.spectatee_status;
2821         if(self.classname == "spectator")
2822                 self.spectatee_status = num_for_edict(self.enemy);
2823         else if(self.classname == "observer")
2824                 self.spectatee_status = num_for_edict(self);
2825         else
2826                 self.spectatee_status = 0;
2827         if(self.spectatee_status != oldspectatee_status)
2828         {
2829                 ClientData_Touch(self);
2830                 if(g_race || g_cts)
2831                         race_InitSpectator();
2832         }
2833
2834         if(self.teamkill_soundtime)
2835         if(time > self.teamkill_soundtime)
2836         {
2837                 self.teamkill_soundtime = 0;
2838
2839                 entity oldpusher, oldself;
2840
2841                 oldself = self; self = self.teamkill_soundsource;
2842                 oldpusher = self.pusher; self.pusher = oldself;
2843
2844                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2845
2846                 self.pusher = oldpusher;
2847                 self = oldself;
2848         }
2849
2850         if(self.taunt_soundtime)
2851         if(time > self.taunt_soundtime)
2852         {
2853                 self.taunt_soundtime = 0;
2854                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2855         }
2856
2857         target_voicescript_next(self);
2858 }
2859
2860 float isInvisibleString(string s)
2861 {
2862         float i, n, c;
2863         s = strdecolorize(s);
2864         for((i = 0), (n = strlen(s)); i < n; ++i)
2865         {
2866                 c = str2chr(s, i);
2867                 switch(c)
2868                 {
2869                         case 0:
2870                         case 32: // space
2871                                 break;
2872                         case 192: // charmap space
2873                                 if (!cvar("utf8_enable"))
2874                                         break;
2875                                 return FALSE;
2876                         case 160: // space in unicode fonts
2877                         case 0xE000 + 192: // utf8 charmap space
2878                                 if (cvar("utf8_enable"))
2879                                         break;
2880                         default:
2881                                 return FALSE;
2882                 }
2883         }
2884         return TRUE;
2885 }
2886
2887 /*
2888 =============
2889 PlayerPostThink
2890
2891 Called every frame for each client after the physics are run
2892 =============
2893 */
2894 .float idlekick_lasttimeleft;
2895 .entity showheadshotbbox;
2896 void showheadshotbbox_think()
2897 {
2898         if(self.owner.showheadshotbbox != self)
2899         {
2900                 remove(self);
2901                 return;
2902         }
2903         self.nextthink = time;
2904         setorigin(self, self.owner.origin);
2905         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2906 }
2907 void PlayerPostThink (void)
2908 {
2909         // Savage: Check for nameless players
2910         if (isInvisibleString(self.netname)) {
2911                 self.netname = "Player";
2912                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2913         }
2914
2915         // send the clients accuracy stats to the client
2916         if(self.stat_count > 0)
2917         if(frametime)
2918         {
2919                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2920                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2921                 self.stat_count -= 1;
2922         }
2923
2924         if(sv_maxidle && frametime)
2925         {
2926                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2927                 float timeleft;
2928                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2929                 if(timeleft <= 0)
2930                 {
2931                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2932                         AnnounceTo(self, "terminated");
2933                         dropclient(self);
2934                         return;
2935                 }
2936                 else if(timeleft <= 10)
2937                 {
2938                         if(timeleft != self.idlekick_lasttimeleft)
2939                         {
2940                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2941                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2942                         }
2943                 }
2944                 else
2945                 {
2946                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2947                 }
2948                 self.idlekick_lasttimeleft = timeleft;
2949         }
2950
2951 #ifdef TETRIS
2952         if(self.impulse == 100)
2953                 ImpulseCommands();
2954         if (TetrisPostFrame())
2955                 return;
2956 #endif
2957
2958         CheatFrame();
2959
2960         if(self.classname == "player") {
2961                 CheckRules_Player();
2962                 UpdateChatBubble();
2963                 UpdateTeamBubble();
2964                 if (self.impulse)
2965                         ImpulseCommands();
2966                 if (intermission_running)
2967                         return;         // intermission or finale
2968                 GetPressedKeys();
2969         } else if (self.classname == "observer") {
2970                 //do nothing
2971         } else if (self.classname == "spectator") {
2972                 //do nothing
2973         }
2974
2975         /*
2976         float i;
2977         for(i = 0; i < 1000; ++i)
2978         {
2979                 vector end;
2980                 end = self.origin + '0 0 1024' + 512 * randomvec();
2981                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2982                 if(trace_fraction < 1)
2983                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2984                 {
2985                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2986                         break;
2987                 }
2988         }
2989         */
2990
2991         Arena_Warmup();
2992
2993         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2994
2995         if(self.waypointsprite_attachedforcarrier)
2996                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2997
2998         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
2999         {
3000                 if(!self.showheadshotbbox)
3001                 {
3002                         self.showheadshotbbox = spawn();
3003                         self.showheadshotbbox.classname = "headshotbbox";
3004                         self.showheadshotbbox.owner = self;
3005                         self.showheadshotbbox.think = showheadshotbbox_think;
3006                         self.showheadshotbbox.nextthink = time;
3007                         self = self.showheadshotbbox;
3008                         self.think();
3009                         self = self.owner;
3010                 }
3011         }
3012         else
3013         {
3014                 if(self.showheadshotbbox)
3015                         remove(self.showheadshotbbox);
3016         }
3017
3018         playerdemo_write();
3019
3020         /*
3021         if(g_race)
3022                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3023         */
3024 }