qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         Portal_ClearAll(self);
 618
 619         if(self.alivetime)
 620         {
 621                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 622                 self.alivetime = 0;
 623         }
 624
 625         if(self.vehicle)
 626             vehicles_exit(VHEF_RELESE);
 627
 628         if(self.flagcarried)
 629                 DropFlag(self.flagcarried, world, world);
 630
 631         if(self.ballcarried && g_nexball)
 632                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 633
 634         WaypointSprite_PlayerDead();
 635
 636         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 637                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 638
 639         if(self.killcount != -666) {
 640                 if(g_lms) {
 641                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 642                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 643                         else
 644                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 645                 } else
 646                         bprint ("^4", self.netname, "^4 is spectating now\n");
 647
 648                 if(self.just_joined == FALSE) {
 649                         LogTeamchange(self.playerid, -1, 4);
 650                 } else
 651                         self.just_joined = FALSE;
 652         }
 653
 654         PlayerScore_Clear(self); // clear scores when needed
 655
 656         accuracy_resend(self);
 657
 658         self.spectatortime = time;
 659
 660         self.classname = "observer";
 661         self.iscreature = FALSE;
 662         self.health = -666;
 663         self.takedamage = DAMAGE_NO;
 664         self.solid = SOLID_NOT;
 665         self.movetype = MOVETYPE_NOCLIP;
 666         self.flags = FL_CLIENT | FL_NOTARGET;
 667         self.armorvalue = 666;
 668         self.effects = 0;
 669         self.armorvalue = autocvar_g_balance_armor_start;
 670         self.pauserotarmor_finished = 0;
 671         self.pauserothealth_finished = 0;
 672         self.pauseregen_finished = 0;
 673         self.damageforcescale = 0;
 674         self.death_time = 0;
 675         self.dead_frame = 0;
 676         self.alpha = 0;
 677         self.scale = 0;
 678         self.fade_time = 0;
 679         self.pain_frame = 0;
 680         self.pain_finished = 0;
 681         self.strength_finished = 0;
 682         self.invincible_finished = 0;
 683         self.pushltime = 0;
 684         self.think = SUB_Null;
 685         self.nextthink = 0;
 686         self.hook_time = 0;
 687         self.runes = 0;
 688         self.deadflag = DEAD_NO;
 689         self.angles = spot.angles;
 690         self.angles_z = 0;
 691         self.fixangle = TRUE;
 692         self.crouch = FALSE;
 693
 694         self.view_ofs = PL_VIEW_OFS;
 695         setorigin (self, spot.origin);
 696         setsize (self, '0 0 0', '0 0 0');
 697         self.prevorigin = self.origin;
 698         self.items = 0;
 699         self.weapons = 0;
 700         self.model = "";
 701         FixPlayermodel();
 702         self.model = "";
 703         self.modelindex = 0;
 704         self.weapon = 0;
 705         self.weaponmodel = "";
 706         self.weaponentity = world;
 707         self.exteriorweaponentity = world;
 708         self.killcount = -666;
 709         self.velocity = '0 0 0';
 710         self.avelocity = '0 0 0';
 711         self.punchangle = '0 0 0';
 712         self.punchvector = '0 0 0';
 713         self.oldvelocity = self.velocity;
 714         self.fire_endtime = -1;
 715
 716         if(sv_loddistance1)
 717                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 718
 719         if(g_arena)
 720         {
 721                 if(self.version_mismatch)
 722                 {
 723                         Spawnqueue_Unmark(self);
 724                         Spawnqueue_Remove(self);
 725                 }
 726                 else
 727                 {
 728                         Spawnqueue_Insert(self);
 729                 }
 730         }
 731         else if(g_lms)
 732         {
 733                 // Only if the player cannot play at all
 734                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 735                         self.frags = FRAGS_SPECTATOR;
 736                 else
 737                         self.frags = FRAGS_LMS_LOSER;
 738         }
 739         else
 740                 self.frags = FRAGS_SPECTATOR;
 741 }
 742
 743 void FixPlayermodel()
 744 {
 745         local string defaultmodel;
 746         local float defaultskin, chmdl, oldskin;
 747         local vector m1, m2;
 748
 749         defaultmodel = "";
 750
 751         if(autocvar_sv_defaultcharacter == 1) {
 752                 defaultskin = 0;
 753
 754                 if(teamplay)
 755                 {
 756                         string s;
 757                         s = Team_ColorNameLowerCase(self.team);
 758                         if(s != "neutral")
 759                         {
 760                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 761                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 762                         }
 763                 }
 764
 765                 if(defaultmodel == "")
 766                 {
 767                         defaultmodel = autocvar_sv_defaultplayermodel;
 768                         defaultskin = autocvar_sv_defaultplayerskin;
 769                 }
 770         }
 771
 772         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 773         {
 774                 if(self.model != "")
 775                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 776                 self.model = ""; // force the != checks to return true
 777         }
 778
 779         if(defaultmodel != "")
 780         {
 781                 if (defaultmodel != self.model)
 782                 {
 783                         m1 = self.mins;
 784                         m2 = self.maxs;
 785                         setmodel_lod (self, defaultmodel);
 786                         setsize (self, m1, m2);
 787                         chmdl = TRUE;
 788                 }
 789
 790                 oldskin = self.skinindex;
 791                 self.skinindex = defaultskin;
 792         } else {
 793                 if (self.playermodel != self.model || self.playermodel == "")
 794                 {
 795                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 796                         m1 = self.mins;
 797                         m2 = self.maxs;
 798                         setmodel_lod (self, self.playermodel);
 799                         setsize (self, m1, m2);
 800                         chmdl = TRUE;
 801                 }
 802
 803                 oldskin = self.skinindex;
 804                 self.skinindex = stof(self.playerskin);
 805         }
 806
 807         if(chmdl || oldskin != self.skinindex)
 808                 self.species = player_getspecies(); // model or skin has changed
 809
 810         if(!teamplay)
 811                 if(strlen(autocvar_sv_defaultplayercolors))
 812                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 813                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 814 }
 815
 816 void PlayerTouchExplode(entity p1, entity p2)
 817 {
 818         vector org;
 819         org = (p1.origin + p2.origin) * 0.5;
 820         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 821
 822         te_explosion(org);
 823
 824         entity e;
 825         e = spawn();
 826         setorigin(e, org);
 827         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 828         remove(e);
 829 }
 830
 831 /*
 832 =============
 833 PutClientInServer
 834
 835 Called when a client spawns in the server
 836 =============
 837 */
 838 //void() ctf_playerchanged;
 839 void PutClientInServer (void)
 840 {
 841         if(clienttype(self) == CLIENTTYPE_BOT)
 842         {
 843                 self.classname = "player";
 844         }
 845         else if(clienttype(self) == CLIENTTYPE_REAL)
 846         {
 847                 msg_entity = self;
 848                 WriteByte(MSG_ONE, SVC_SETVIEW);
 849                 WriteEntity(MSG_ONE, self);
 850         }
 851
 852         // player is dead and becomes observer
 853         // FIXME fix LMS scoring for new system
 854         if(g_lms)
 855         {
 856                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 857                         self.classname = "observer";
 858         }
 859
 860         if(g_arena || (g_ca && !allowed_to_spawn))
 861         if(!self.spawned)
 862                 self.classname = "observer";
 863
 864         if(gameover)
 865                 self.classname = "observer";
 866
 867         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 868                 entity spot, oldself;
 869                 float j;
 870
 871                 accuracy_resend(self);
 872
 873                 if(self.team < 0)
 874                         JoinBestTeam(self, FALSE, TRUE);
 875
 876                 race_PreSpawn();
 877
 878                 spot = SelectSpawnPoint (FALSE);
 879                 if(!spot)
 880                 {
 881                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 882                         return; // spawn failed
 883                 }
 884
 885                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 886
 887                 self.classname = "player";
 888                 self.wasplayer = TRUE;
 889                 self.iscreature = TRUE;
 890                 self.movetype = MOVETYPE_WALK;
 891                 self.solid = SOLID_SLIDEBOX;
 892                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 893                 if(autocvar_g_playerclip_collisions)
 894                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 895                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 896                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 897                 self.frags = FRAGS_PLAYER;
 898                 if(independent_players)
 899                         MAKE_INDEPENDENT_PLAYER(self);
 900                 self.flags = FL_CLIENT;
 901                 self.takedamage = DAMAGE_AIM;
 902                 if(g_minstagib)
 903                         self.effects = EF_FULLBRIGHT;
 904                 else
 905                         self.effects = 0;
 906                 self.air_finished = time + 12;
 907                 self.dmg = 2;
 908                 if(autocvar_g_balance_nex_charge)
 909                 {
 910                         if(autocvar_g_balance_nex_secondary_chargepool)
 911                                 self.nex_chargepool_ammo = 1;
 912                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 913                 }
 914
 915                 if(inWarmupStage)
 916                 {
 917                         self.ammo_shells = warmup_start_ammo_shells;
 918                         self.ammo_nails = warmup_start_ammo_nails;
 919                         self.ammo_rockets = warmup_start_ammo_rockets;
 920                         self.ammo_cells = warmup_start_ammo_cells;
 921                         self.ammo_fuel = warmup_start_ammo_fuel;
 922                         self.health = warmup_start_health;
 923                         self.armorvalue = warmup_start_armorvalue;
 924                         self.weapons = warmup_start_weapons;
 925                 }
 926                 else
 927                 {
 928                         self.ammo_shells = start_ammo_shells;
 929                         self.ammo_nails = start_ammo_nails;
 930                         self.ammo_rockets = start_ammo_rockets;
 931                         self.ammo_cells = start_ammo_cells;
 932                         self.ammo_fuel = start_ammo_fuel;
 933                         self.health = start_health;
 934                         self.armorvalue = start_armorvalue;
 935                         self.weapons = start_weapons;
 936                 }
 937
 938                 if(g_weaponarena_random)
 939                 {
 940                         if(g_weaponarena_random_with_laser)
 941                                 self.weapons &~= WEPBIT_LASER;
 942                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 943                         if(g_weaponarena_random_with_laser)
 944                                 self.weapons |= WEPBIT_LASER;
 945                 }
 946
 947                 self.items = start_items;
 948                 self.jump_interval = time;
 949
 950                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 951                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 952                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 953                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 954                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 955                 //extend the pause of rotting if client was reset at the beginning of the countdown
 956                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 957                         self.spawnshieldtime += game_starttime - time;
 958                         self.pauserotarmor_finished += game_starttime - time;
 959                         self.pauserothealth_finished += game_starttime - time;
 960                         self.pauseregen_finished += game_starttime - time;
 961                 }
 962                 self.damageforcescale = 2;
 963                 self.death_time = 0;
 964                 self.dead_frame = 0;
 965                 self.alpha = 0;
 966                 self.scale = 0;
 967                 self.fade_time = 0;
 968                 self.pain_frame = 0;
 969                 self.pain_finished = 0;
 970                 self.strength_finished = 0;
 971                 self.invincible_finished = 0;
 972                 self.pushltime = 0;
 973                 // players have no think function
 974                 self.think = SUB_Null;
 975                 self.nextthink = 0;
 976                 self.hook_time = 0;
 977                 self.dmg_team = 0;
 978                 self.ballistics_density = autocvar_g_ballistics_density_player;
 979
 980                 self.metertime = 0;
 981
 982                 self.runes = 0;
 983
 984                 self.deadflag = DEAD_NO;
 985
 986                 self.angles = spot.angles;
 987
 988                 self.angles_z = 0; // never spawn tilted even if the spot says to
 989                 self.fixangle = TRUE; // turn this way immediately
 990                 self.velocity = '0 0 0';
 991                 self.avelocity = '0 0 0';
 992                 self.punchangle = '0 0 0';
 993                 self.punchvector = '0 0 0';
 994                 self.oldvelocity = self.velocity;
 995                 self.fire_endtime = -1;
 996
 997                 msg_entity = self;
 998                 WRITESPECTATABLE_MSG_ONE({
 999                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1000                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1001                 });
1002
1003                 if(sv_loddistance1)
1004                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1005
1006                 self.model = "";
1007                 FixPlayermodel();
1008
1009                 self.crouch = FALSE;
1010                 self.view_ofs = PL_VIEW_OFS;
1011                 setsize (self, PL_MIN, PL_MAX);
1012                 self.spawnorigin = spot.origin;
1013                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1014                 // don't reset back to last position, even if new position is stuck in solid
1015                 self.oldorigin = self.origin;
1016                 self.prevorigin = self.origin;
1017                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1018                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1019
1020                 if(g_arena)
1021                 {
1022                         Spawnqueue_Remove(self);
1023                         Spawnqueue_Mark(self);
1024                 }
1025
1026                 else if(g_ca)
1027                         self.caplayer = 1;
1028
1029                 self.event_damage = PlayerDamage;
1030
1031                 self.bot_attack = TRUE;
1032
1033                 self.statdraintime = time + 5;
1034                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1035
1036                 if(self.killcount == -666) {
1037                         PlayerScore_Clear(self);
1038                         self.killcount = 0;
1039                 }
1040
1041                 self.cnt = WEP_LASER;
1042
1043                 CL_SpawnWeaponentity();
1044                 self.alpha = default_player_alpha;
1045                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1046                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1047
1048                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1049                 self.lms_traveled_distance = 0;
1050                 self.speedrunning = FALSE;
1051
1052                 race_PostSpawn(spot);
1053
1054                 if(autocvar_spawn_debug)
1055                 {
1056                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1057                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1058                 }
1059
1060                 //stuffcmd(self, "chase_active 0");
1061                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1062
1063                 if (autocvar_g_spawnsound)
1064                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1065
1066                 if(g_assault) {
1067                         if(self.team == assault_attacker_team)
1068                                 centerprint(self, "You are attacking!");
1069                         else
1070                                 centerprint(self, "You are defending!");
1071                 }
1072
1073                 target_voicescript_clear(self);
1074
1075                 // reset fields the weapons may use
1076                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1077                 {
1078                         weapon_action(j, WR_RESETPLAYER);
1079
1080                         // all weapons must be fully loaded when we spawn
1081                         entity e;
1082                         e = get_weaponinfo(j);
1083                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1084                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1085                 }
1086                 self.weapon_forbidchange = FALSE;
1087
1088                 oldself = self;
1089                 self = spot;
1090                         activator = oldself;
1091                                 string s;
1092                                 s = self.target;
1093                                 self.target = string_null;
1094                                 SUB_UseTargets();
1095                                 self.target = s;
1096                         activator = world;
1097                 self = oldself;
1098
1099                 MUTATOR_CALLHOOK(PlayerSpawn);
1100
1101                 self.switchweapon = w_getbestweapon(self);
1102                 self.cnt = self.switchweapon;
1103                 self.weapon = 0;
1104
1105                 if(!self.alivetime)
1106                         self.alivetime = time;
1107         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1108                 PutObserverInServer ();
1109         }
1110
1111         //if(g_ctf)
1112         //      ctf_playerchanged();
1113 }
1114
1115 .float ebouncefactor, ebouncestop; // electro's values
1116 // TODO do we need all these fields, or should we stop autodetecting runtime
1117 // changes and just have a console command to update this?
1118 float ClientInit_SendEntity(entity to, float sf)
1119 {
1120         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1121         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1122         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1123         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1124         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1125         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1126         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1127         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1128         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1129         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1130         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1131         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1132         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1133         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1134         if(sv_foginterval && world.fog != "")
1135                 WriteString(MSG_ENTITY, world.fog);
1136         else
1137                 WriteString(MSG_ENTITY, "");
1138         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1139         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1140         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1141         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1142         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1143         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1144         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1145         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1146         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1147         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1148         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1149         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1150         return TRUE;
1151 }
1152
1153 void ClientInit_CheckUpdate()
1154 {
1155         self.nextthink = time;
1156         if(self.count != autocvar_g_balance_armor_blockpercent)
1157         {
1158                 self.count = autocvar_g_balance_armor_blockpercent;
1159                 self.SendFlags |= 1;
1160         }
1161         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1162         {
1163                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1164                 self.SendFlags |= 1;
1165         }
1166         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1167         {
1168                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1169                 self.SendFlags |= 1;
1170         }
1171         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1172         {
1173                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1174                 self.SendFlags |= 1;
1175         }
1176         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1177         {
1178                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1179                 self.SendFlags |= 1;
1180         }
1181         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1182         {
1183                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1184                 self.SendFlags |= 1;
1185         }
1186 }
1187
1188 void ClientInit_Spawn()
1189 {
1190         entity o;
1191         entity e;
1192         e = spawn();
1193         e.classname = "clientinit";
1194         e.think = ClientInit_CheckUpdate;
1195         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1196
1197         o = self;
1198         self = e;
1199         ClientInit_CheckUpdate();
1200         self = o;
1201 }
1202
1203 /*
1204 =============
1205 SetNewParms
1206 =============
1207 */
1208 void SetNewParms (void)
1209 {
1210         // initialize parms for a new player
1211         parm1 = -(86400 * 366);
1212 }
1213
1214 /*
1215 =============
1216 SetChangeParms
1217 =============
1218 */
1219 void SetChangeParms (void)
1220 {
1221         // save parms for level change
1222         parm1 = self.parm_idlesince - time;
1223 }
1224
1225 /*
1226 =============
1227 DecodeLevelParms
1228 =============
1229 */
1230 void DecodeLevelParms (void)
1231 {
1232         // load parms
1233         self.parm_idlesince = parm1;
1234         if(self.parm_idlesince == -(86400 * 366))
1235                 self.parm_idlesince = time;
1236
1237         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1238         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1239 }
1240
1241 /*
1242 =============
1243 ClientKill
1244
1245 Called when a client types 'kill' in the console
1246 =============
1247 */
1248
1249 .float clientkill_nexttime;
1250 void ClientKill_Now_TeamChange()
1251 {
1252         if(self.killindicator_teamchange == -1)
1253         {
1254                 self.team = -1;
1255                 JoinBestTeam( self, FALSE, FALSE );
1256         }
1257         else if(self.killindicator_teamchange == -2)
1258         {
1259                 if(g_ca)
1260                         self.caplayer = 0;
1261                 if(blockSpectators)
1262                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1263                 PutObserverInServer();
1264         }
1265         else
1266                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1267 }
1268
1269 void ClientKill_Now()
1270 {
1271         if(self.vehicle)
1272         {
1273             vehicles_exit(VHEF_RELESE);
1274             if(!self.killindicator_teamchange)
1275             {
1276             self.vehicle_health = -1;
1277             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1278             }
1279         }
1280
1281         if(self.killindicator && !wasfreed(self.killindicator))
1282                 remove(self.killindicator);
1283
1284         self.killindicator = world;
1285
1286         if(self.killindicator_teamchange)
1287                 ClientKill_Now_TeamChange();
1288
1289         // in any case:
1290         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1291
1292         // now I am sure the player IS dead
1293 }
1294 void KillIndicator_Think()
1295 {
1296         if (gameover)
1297         {
1298                 self.owner.killindicator = world;
1299                 remove(self);
1300                 return;
1301         }
1302
1303         if (!self.owner.modelindex)
1304         {
1305                 self.owner.killindicator = world;
1306                 remove(self);
1307                 return;
1308         }
1309
1310         if(self.cnt <= 0)
1311         {
1312                 self = self.owner;
1313                 ClientKill_Now(); // no oldself needed
1314                 return;
1315         }
1316     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1317     {
1318         self.nextthink = time + 1;
1319         self.cnt -= 1;
1320     }
1321         else
1322         {
1323                 if(self.cnt <= 10)
1324                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1325                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1326                 {
1327                         if(self.cnt <= 10)
1328                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1329                         if(self.owner.killindicator_teamchange)
1330                         {
1331                                 if(self.owner.killindicator_teamchange == -1)
1332                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1333                                 else if(self.owner.killindicator_teamchange == -2)
1334                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1335                                 else
1336                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1337                         }
1338                         else
1339                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1340                 }
1341                 self.nextthink = time + 1;
1342                 self.cnt -= 1;
1343         }
1344 }
1345
1346 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1347 {
1348         float killtime;
1349         entity e;
1350
1351         if (gameover)
1352                 return;
1353
1354         killtime = autocvar_g_balance_kill_delay;
1355
1356         if(g_race_qualifying || g_cts)
1357                 killtime = 0;
1358
1359     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1360     {
1361                 remove(self.killindicator);
1362                 self.killindicator = world;
1363
1364         ClientKill_Now(); // allow instant kill in this case
1365         return;
1366     }
1367
1368         self.killindicator_teamchange = targetteam;
1369
1370     if(!self.killindicator)
1371         {
1372                 if(self.modelindex && self.deadflag == DEAD_NO)
1373                 {
1374                         killtime = max(killtime, self.clientkill_nexttime - time);
1375                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1376                 }
1377
1378                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1379                 {
1380                         ClientKill_Now();
1381                 }
1382                 else
1383                 {
1384                         self.killindicator = spawn();
1385                         self.killindicator.owner = self;
1386                         self.killindicator.scale = 0.5;
1387                         setattachment(self.killindicator, self, "");
1388                         setorigin(self.killindicator, '0 0 52');
1389                         self.killindicator.think = KillIndicator_Think;
1390                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1391                         self.killindicator.cnt = ceil(killtime);
1392                         self.killindicator.count = bound(0, ceil(killtime), 10);
1393                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1394
1395                         for(e = world; (e = find(e, classname, "body")) != world; )
1396                         {
1397                                 if(e.enemy != self)
1398                                         continue;
1399                                 e.killindicator = spawn();
1400                                 e.killindicator.owner = e;
1401                                 e.killindicator.scale = 0.5;
1402                                 setattachment(e.killindicator, e, "");
1403                                 setorigin(e.killindicator, '0 0 52');
1404                                 e.killindicator.think = KillIndicator_Think;
1405                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1406                                 e.killindicator.cnt = ceil(killtime);
1407                         }
1408                         self.lip = 0;
1409                 }
1410         }
1411         if(self.killindicator)
1412         {
1413                 if(targetteam == 0) // just die
1414                         self.killindicator.colormod = '0 0 0';
1415                 else if(targetteam == -1) // auto
1416                         self.killindicator.colormod = '0 1 0';
1417                 else if(targetteam == -2) // spectate
1418                         self.killindicator.colormod = '0.5 0.5 0.5';
1419                 else
1420                         self.killindicator.colormod = TeamColor(targetteam);
1421         }
1422 }
1423
1424 void ClientKill (void)
1425 {
1426         if (gameover)
1427                 return;
1428
1429         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1430         {
1431                 // do nothing
1432         }
1433     else if(self.freezetag_frozen)
1434     {
1435         // do nothing
1436     }
1437         else
1438                 ClientKill_TeamChange(0);
1439 }
1440
1441 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1442 {
1443     e.killindicator = spawn();
1444     e.killindicator.owner = e;
1445     e.killindicator.think = KillIndicator_Think;
1446     e.killindicator.nextthink = time + (e.lip) * 0.05;
1447     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1448     e.killindicator.health = 1; // this is used to indicate that it should be silent
1449     e.lip = 0;
1450 }
1451
1452 void FixClientCvars(entity e)
1453 {
1454         // send prediction settings to the client
1455         stuffcmd(e, "\nin_bindmap 0 0\n");
1456         if(g_race || g_cts)
1457                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1458         if(autocvar_g_antilag == 3) // client side hitscan
1459                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1460         if(sv_gentle)
1461                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1462         /*
1463          * we no longer need to stuff this. Remove this comment block if you feel
1464          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1465         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1466         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1467         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1468         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1469         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1470         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1471         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1472         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1473         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1474         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1475         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1476         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1477         stuffcmd(e, "cl_movement_edgefriction 1\n");
1478          */
1479 }
1480
1481 float PlayerInIDList(entity p, string idlist)
1482 {
1483         float n, i;
1484         string s;
1485
1486         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1487         if not(p.crypto_idfp)
1488                 return 0;
1489
1490         // this function allows abbreviated player IDs too!
1491         n = tokenize_console(idlist);
1492         for(i = 0; i < n; ++i)
1493         {
1494                 s = argv(i);
1495                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1496                         return 1;
1497         }
1498
1499         return 0;
1500 }
1501
1502 /*
1503 =============
1504 ClientConnect
1505
1506 Called when a client connects to the server
1507 =============
1508 */
1509 //void ctf_clientconnect();
1510 string ColoredTeamName(float t);
1511 void DecodeLevelParms (void);
1512 //void dom_player_join_team(entity pl);
1513 void set_dom_state(entity e);
1514 void ClientConnect (void)
1515 {
1516         float t;
1517
1518         if(self.flags & FL_CLIENT)
1519         {
1520                 print("Warning: ClientConnect, but already connected!\n");
1521                 return;
1522         }
1523
1524         if(Ban_MaybeEnforceBan(self))
1525                 return;
1526
1527         DecodeLevelParms();
1528
1529 #ifdef WATERMARK
1530         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1531 #endif
1532
1533         self.classname = "player_joining";
1534
1535         self.flags = FL_CLIENT;
1536         self.version_nagtime = time + 10 + random() * 10;
1537
1538         if(player_count<0)
1539         {
1540                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1541                 player_count = 0;
1542         }
1543
1544         PlayerScore_Attach(self);
1545         ClientData_Attach();
1546         accuracy_init(self);
1547
1548         bot_clientconnect();
1549
1550         playerdemo_init();
1551
1552         anticheat_init();
1553
1554         race_PreSpawnObserver();
1555
1556         //if(g_domination)
1557         //      dom_player_join_team(self);
1558
1559         // identify the right forced team
1560         if(autocvar_g_campaign)
1561         {
1562                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1563                 {
1564                         switch(autocvar_g_campaign_forceteam)
1565                         {
1566                                 case 1: self.team_forced = COLOR_TEAM1; break;
1567                                 case 2: self.team_forced = COLOR_TEAM2; break;
1568                                 case 3: self.team_forced = COLOR_TEAM3; break;
1569                                 case 4: self.team_forced = COLOR_TEAM4; break;
1570                                 default: self.team_forced = 0;
1571                         }
1572                 }
1573         }
1574         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1575                 self.team_forced = COLOR_TEAM1;
1576         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1577                 self.team_forced = COLOR_TEAM2;
1578         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1579                 self.team_forced = COLOR_TEAM3;
1580         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1581                 self.team_forced = COLOR_TEAM4;
1582         else if(autocvar_g_forced_team_otherwise == "red")
1583                 self.team_forced = COLOR_TEAM1;
1584         else if(autocvar_g_forced_team_otherwise == "blue")
1585                 self.team_forced = COLOR_TEAM2;
1586         else if(autocvar_g_forced_team_otherwise == "yellow")
1587                 self.team_forced = COLOR_TEAM3;
1588         else if(autocvar_g_forced_team_otherwise == "pink")
1589                 self.team_forced = COLOR_TEAM4;
1590         else if(autocvar_g_forced_team_otherwise == "spectate")
1591                 self.team_forced = -1;
1592         else if(autocvar_g_forced_team_otherwise == "spectator")
1593                 self.team_forced = -1;
1594         else
1595                 self.team_forced = 0;
1596
1597         if(!teamplay)
1598                 if(self.team_forced > 0)
1599                         self.team_forced = 0;
1600
1601         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1602
1603         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1604                 self.classname = "observer";
1605         } else {
1606                 if(teamplay)
1607                 {
1608                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1609                         {
1610                                 self.classname = "player";
1611                                 campaign_bots_may_start = 1;
1612                         }
1613                         else
1614                         {
1615                                 self.classname = "observer"; // do it anyway
1616                         }
1617                 }
1618                 else
1619                 {
1620                         self.classname = "player";
1621                         campaign_bots_may_start = 1;
1622                 }
1623         }
1624
1625         self.playerid = (playerid_last = playerid_last + 1);
1626
1627     if(clienttype(self) == CLIENTTYPE_BOT)
1628         PlayerStats_AddPlayer(self);
1629
1630         if(autocvar_sv_eventlog)
1631                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1632
1633         LogTeamchange(self.playerid, self.team, 1);
1634
1635         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1636
1637         self.netname_previous = strzone(self.netname);
1638
1639         bprint("^4", self.netname, "^4 connected");
1640
1641         if(self.classname != "observer" && (g_domination || g_ctf))
1642                 bprint(" and joined the ", ColoredTeamName(self.team));
1643
1644         bprint("\n");
1645
1646         self.welcomemessage_time = 0;
1647
1648         stuffcmd(self, strcat(clientstuff, "\n"));
1649         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1650         stuffcmd(self, "cl_particles_reloadeffects\n");
1651
1652         FixClientCvars(self);
1653
1654         // spawnfunc_waypoint sprites
1655         WaypointSprite_InitClient(self);
1656
1657         // Wazat's grappling hook
1658         SetGrappleHookBindings();
1659
1660         // get autoswitch state from player when he toggles it
1661         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1662
1663         // get version info from player
1664         stuffcmd(self, "cmd clientversion $gameversion\n");
1665
1666         // get other cvars from player
1667         GetCvars(0);
1668
1669         // notify about available teams
1670         if(teamplay)
1671         {
1672                 CheckAllowedTeams(self);
1673                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1674                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1675         }
1676         else
1677                 stuffcmd(self, "set _teams_available 0\n");
1678
1679         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1680
1681         if(g_arena || g_ca)
1682         {
1683                 self.classname = "observer";
1684                 if(g_arena)
1685                         Spawnqueue_Insert(self);
1686         }
1687         /*else if(g_ctf)
1688         {
1689                 ctf_clientconnect();
1690         }*/
1691
1692         attach_entcs();
1693
1694         bot_relinkplayerlist();
1695
1696         self.spectatortime = time;
1697         if(blockSpectators)
1698         {
1699                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1700         }
1701
1702         self.jointime = time;
1703         self.allowedTimeouts = autocvar_sv_timeout_number;
1704
1705         if(clienttype(self) == CLIENTTYPE_REAL)
1706         {
1707                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1708                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1709         }
1710
1711         if(g_lms)
1712         {
1713                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1714                 {
1715                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1716                         self.frags = FRAGS_SPECTATOR;
1717                 }
1718         }
1719
1720         if(!sv_foginterval && world.fog != "")
1721                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1722
1723         SoundEntity_Attach(self);
1724
1725         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1726         {
1727                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1728                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1729         }
1730         else
1731                 self.hitplotfh = -1;
1732
1733         if(g_race || g_cts) {
1734                 string rr;
1735                 if(g_cts)
1736                         rr = CTS_RECORD;
1737                 else
1738                         rr = RACE_RECORD;
1739                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1740
1741                 msg_entity = self;
1742                 race_send_recordtime(MSG_ONE);
1743                 race_send_speedaward(MSG_ONE);
1744
1745                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1746                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1747                 race_send_speedaward_alltimebest(MSG_ONE);
1748
1749                 float i;
1750                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1751                         race_SendRankings(i, 0, 0, MSG_ONE);
1752                 }
1753         }
1754         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1755                 send_CSQC_teamnagger();
1756
1757         if (g_domination)
1758                 set_dom_state(self);
1759
1760         CheatInitClient();
1761 }
1762
1763 /*
1764 =============
1765 ClientDisconnect
1766
1767 Called when a client disconnects from the server
1768 =============
1769 */
1770 .entity chatbubbleentity;
1771 void ReadyCount();
1772 void ClientDisconnect (void)
1773 {
1774         if(self.vehicle)
1775             vehicles_exit(VHEF_RELESE);
1776
1777         if not(self.flags & FL_CLIENT)
1778         {
1779                 print("Warning: ClientDisconnect without ClientConnect\n");
1780                 return;
1781         }
1782
1783         PlayerStats_AddGlobalInfo(self);
1784
1785         CheatShutdownClient();
1786
1787         if(self.hitplotfh >= 0)
1788         {
1789                 fclose(self.hitplotfh);
1790                 self.hitplotfh = -1;
1791         }
1792
1793         anticheat_report();
1794         anticheat_shutdown();
1795
1796         playerdemo_shutdown();
1797
1798         bot_clientdisconnect();
1799
1800         if(self.entcs)
1801                 detach_entcs();
1802
1803         if(autocvar_sv_eventlog)
1804                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1805         bprint ("^4",self.netname);
1806         bprint ("^4 disconnected\n");
1807
1808         SoundEntity_Detach(self);
1809
1810         DropAllRunes(self);
1811         MUTATOR_CALLHOOK(ClientDisconnect);
1812
1813         Portal_ClearAll(self);
1814
1815         if(self.flagcarried)
1816                 DropFlag(self.flagcarried, world, world);
1817         if(self.ballcarried && g_nexball)
1818                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1819
1820         // Here, everything has been done that requires this player to be a client.
1821
1822         self.flags &~= FL_CLIENT;
1823
1824         if (self.chatbubbleentity)
1825                 remove (self.chatbubbleentity);
1826
1827         if (self.killindicator)
1828                 remove (self.killindicator);
1829
1830         WaypointSprite_PlayerGone();
1831
1832         bot_relinkplayerlist();
1833
1834         if(g_arena)
1835         {
1836                 Spawnqueue_Unmark(self);
1837                 Spawnqueue_Remove(self);
1838         }
1839
1840         accuracy_free(self);
1841         ClientData_Detach();
1842         PlayerScore_Detach(self);
1843
1844         if(self.netname_previous)
1845                 strunzone(self.netname_previous);
1846         if(self.clientstatus)
1847                 strunzone(self.clientstatus);
1848         if(self.weaponorder_byimpulse)
1849                 strunzone(self.weaponorder_byimpulse);
1850
1851         ClearPlayerSounds();
1852
1853         if(self.personal)
1854                 remove(self.personal);
1855
1856         self.playerid = 0;
1857         ReadyCount();
1858
1859         // free cvars
1860         GetCvars(-1);
1861 }
1862
1863 .float BUTTON_CHAT;
1864 void ChatBubbleThink()
1865 {
1866         self.nextthink = time;
1867         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1868         {
1869                 if(self.owner) // but why can that ever be world?
1870                         self.owner.chatbubbleentity = world;
1871                 remove(self);
1872                 return;
1873         }
1874         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1875 #ifdef TETRIS
1876                 || self.owner.tetris_on
1877 #endif
1878         )
1879                 self.model = self.mdl;
1880         else
1881                 self.model = "";
1882 };
1883
1884 void UpdateChatBubble()
1885 {
1886         if (!self.modelindex)
1887                 return;
1888         // spawn a chatbubble entity if needed
1889         if (!self.chatbubbleentity)
1890         {
1891                 self.chatbubbleentity = spawn();
1892                 self.chatbubbleentity.owner = self;
1893                 self.chatbubbleentity.exteriormodeltoclient = self;
1894                 self.chatbubbleentity.think = ChatBubbleThink;
1895                 self.chatbubbleentity.nextthink = time;
1896                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1897                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1898                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1899                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1900                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1901                 self.chatbubbleentity.model = "";
1902                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1903         }
1904 }
1905
1906
1907 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1908 // added to the model skins
1909 /*void UpdateColorModHack()
1910 {
1911         local float c;
1912         c = self.clientcolors & 15;
1913         // LordHavoc: only bothering to support white, green, red, yellow, blue
1914              if (!teamplay) self.colormod = '0 0 0';
1915         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1916         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1917         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1918         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1919         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1920         else self.colormod = '1 1 1';
1921 };*/
1922
1923 .float oldcolormap;
1924 void respawn(void)
1925 {
1926         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1927         {
1928                 self.solid = SOLID_NOT;
1929                 self.takedamage = DAMAGE_NO;
1930                 self.movetype = MOVETYPE_FLY;
1931                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1932                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1933                 self.effects |= EF_ADDITIVE;
1934                 self.oldcolormap = self.colormap;
1935                 self.colormap = 512;
1936                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1937                 if(autocvar_g_respawn_ghosts_maxtime)
1938                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1939         }
1940
1941         CopyBody(1);
1942         self.effects |= EF_NODRAW; // prevent another CopyBody
1943         if(self.oldcolormap)
1944         {
1945                 self.colormap = self.oldcolormap;
1946                 self.oldcolormap = 0;
1947         }
1948         PutClientInServer();
1949 }
1950
1951 void play_countdown(float finished, string samp)
1952 {
1953         if(clienttype(self) == CLIENTTYPE_REAL)
1954                 if(floor(finished - time - frametime) != floor(finished - time))
1955                         if(finished - time < 6)
1956                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1957 }
1958
1959 /**
1960  * When sv_timeout is used this function returs strings like
1961  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1962  * Called by centerprint functions
1963  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1964  */
1965 string getTimeoutText(float addOneSecond) {
1966         if (!autocvar_sv_timeout || !timeoutStatus)
1967                 return "";
1968
1969         local string retStr;
1970         if (timeoutStatus == 1) {
1971                 if (addOneSecond == 1) {
1972                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1973                 }
1974                 else {
1975                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1976                 }
1977                 return retStr;
1978         }
1979         else if (timeoutStatus == 2) {
1980                 if (addOneSecond) {
1981                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1982                         //don't show messages like "Timeout ends in 0 seconds"...
1983                         if ((remainingTimeoutTime + 1) > 0)
1984                                 return retStr;
1985                         else
1986                                 return "";
1987                 }
1988                 else {
1989                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1990                         //don't show messages like "Timeout ends in 0 seconds"...
1991                         if (remainingTimeoutTime > 0)
1992                                 return retStr;
1993                         else
1994                                 return "";
1995                 }
1996         }
1997         else return "";
1998 }
1999
2000 void player_powerups (void)
2001 {
2002         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2003         olditems = self.items;
2004
2005         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2006         {
2007                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2008                 self.modelflags |= MF_ROCKET;
2009         }
2010         else
2011         {
2012                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
2013                 self.modelflags &~= MF_ROCKET;
2014         }
2015
2016         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2017
2018         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2019                 return;
2020
2021         Fire_ApplyDamage(self);
2022         Fire_ApplyEffect(self);
2023
2024         if (g_minstagib)
2025         {
2026                 self.effects |= EF_FULLBRIGHT;
2027
2028                 if (self.items & IT_STRENGTH)
2029                 {
2030                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2031                         if (time > self.strength_finished)
2032                         {
2033                                 self.alpha = default_player_alpha;
2034                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2035                                 self.items &~= IT_STRENGTH;
2036                                 sprint(self, "^3Invisibility has worn off\n");
2037                         }
2038                 }
2039                 else
2040                 {
2041                         if (time < self.strength_finished)
2042                         {
2043                                 self.alpha = g_minstagib_invis_alpha;
2044                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2045                                 self.items |= IT_STRENGTH;
2046                                 sprint(self, "^3You are invisible\n");
2047                         }
2048                 }
2049
2050                 if (self.items & IT_INVINCIBLE)
2051                 {
2052                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2053                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2054                         {
2055                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2056                                 sprint(self, "^3Speed has worn off\n");
2057                         }
2058                 }
2059                 else
2060                 {
2061                         if (time < self.invincible_finished)
2062                         {
2063                                 self.items = self.items | IT_INVINCIBLE;
2064                                 sprint(self, "^3You are on speed\n");
2065                         }
2066                 }
2067         }
2068         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2069         {
2070                 if (self.items & IT_STRENGTH)
2071                 {
2072                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2073                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2074                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2075                         {
2076                                 self.items = self.items - (self.items & IT_STRENGTH);
2077                                 sprint(self, "^3Strength has worn off\n");
2078                         }
2079                 }
2080                 else
2081                 {
2082                         if (time < self.strength_finished)
2083                         {
2084                                 self.items = self.items | IT_STRENGTH;
2085                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2086                         }
2087                 }
2088                 if (self.items & IT_INVINCIBLE)
2089                 {
2090                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2091                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2092                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2093                         {
2094                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2095                                 sprint(self, "^3Shield has worn off\n");
2096                         }
2097                 }
2098                 else
2099                 {
2100                         if (time < self.invincible_finished)
2101                         {
2102                                 self.items = self.items | IT_INVINCIBLE;
2103                                 sprint(self, "^3Shield surrounds you\n");
2104                         }
2105                 }
2106
2107                 if(autocvar_g_nodepthtestplayers)
2108                         self.effects = self.effects | EF_NODEPTHTEST;
2109
2110                 if(autocvar_g_fullbrightplayers)
2111                         self.effects = self.effects | EF_FULLBRIGHT;
2112
2113                 // midair gamemode: damage only while in the air
2114                 // if in midair mode, being on ground grants temporary invulnerability
2115                 // (this is so that multishot weapon don't clear the ground flag on the
2116                 // first damage in the frame, leaving the player vulnerable to the
2117                 // remaining hits in the same frame)
2118                 if (self.flags & FL_ONGROUND)
2119                 if (g_midair)
2120                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2121
2122                 if (time >= game_starttime)
2123                 if (time < self.spawnshieldtime)
2124                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2125         }
2126
2127         MUTATOR_CALLHOOK(PlayerPowerups);
2128 }
2129
2130 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2131 {
2132         if(current > stable)
2133                 return current;
2134         else if(current > stable - 0.25) // when close enough, "snap"
2135                 return stable;
2136         else
2137                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2138 }
2139
2140 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2141 {
2142         if(current < stable)
2143                 return current;
2144         else if(current < stable + 0.25) // when close enough, "snap"
2145                 return stable;
2146         else
2147                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2148 }
2149
2150 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2151 {
2152         if(current > rotstable)
2153         {
2154                 if(rotframetime > 0)
2155                 {
2156                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2157                         current = max(rotstable, current - rotlinear * rotframetime);
2158                 }
2159         }
2160         else if(current < regenstable)
2161         {
2162                 if(regenframetime > 0)
2163                 {
2164                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2165                         current = min(regenstable, current + regenlinear * regenframetime);
2166                 }
2167         }
2168
2169         if(current > limit)
2170                 current = limit;
2171
2172         return current;
2173 }
2174
2175 void player_regen (void)
2176 {
2177         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2178         maxh = autocvar_g_balance_health_rotstable;
2179         maxa = autocvar_g_balance_armor_rotstable;
2180         maxf = autocvar_g_balance_fuel_rotstable;
2181         minh = autocvar_g_balance_health_regenstable;
2182         mina = autocvar_g_balance_armor_regenstable;
2183         minf = autocvar_g_balance_fuel_regenstable;
2184         limith = autocvar_g_balance_health_limit;
2185         limita = autocvar_g_balance_armor_limit;
2186         limitf = autocvar_g_balance_fuel_limit;
2187
2188         max_mod = regen_mod = rot_mod = limit_mod = 1;
2189
2190         if (self.runes & RUNE_REGEN)
2191         {
2192                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2193                 {
2194                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2195                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2196                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2197                 }
2198                 else
2199                 {
2200                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2201                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2202                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2203                 }
2204         }
2205         else if (self.runes & CURSE_VENOM)
2206         {
2207                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2208                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2209                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2210                 else
2211                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2212                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2213                 //if (!self.runes & RUNE_REGEN)
2214                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2215         }
2216         maxh = maxh * max_mod;
2217         //maxa = maxa * max_mod;
2218         //maxf = maxf * max_mod;
2219         minh = minh * max_mod;
2220         //mina = mina * max_mod;
2221         //minf = minf * max_mod;
2222         limith = limith * limit_mod;
2223         limita = limita * limit_mod;
2224         //limitf = limitf * limit_mod;
2225
2226         if(g_lms && g_ca)
2227                 rot_mod = 0;
2228
2229         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2230         {
2231                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2232                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2233
2234                 // if player rotted to death...  die!
2235                 if(self.health < 1)
2236                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2237         }
2238
2239         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2240                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2241 }
2242
2243 float zoomstate_set;
2244 void SetZoomState(float z)
2245 {
2246         if(z != self.zoomstate)
2247         {
2248                 self.zoomstate = z;
2249                 ClientData_Touch(self);
2250         }
2251         zoomstate_set = 1;
2252 }
2253
2254 void GetPressedKeys(void) {
2255         MUTATOR_CALLHOOK(GetPressedKeys);
2256         if (self.movement_x > 0) // get if movement keys are pressed
2257         {       // forward key pressed
2258                 self.pressedkeys |= KEY_FORWARD;
2259                 self.pressedkeys &~= KEY_BACKWARD;
2260         }
2261         else if (self.movement_x < 0)
2262         {       // backward key pressed
2263                 self.pressedkeys |= KEY_BACKWARD;
2264                 self.pressedkeys &~= KEY_FORWARD;
2265         }
2266         else
2267         {       // no x input
2268                 self.pressedkeys &~= KEY_FORWARD;
2269                 self.pressedkeys &~= KEY_BACKWARD;
2270         }
2271
2272         if (self.movement_y > 0)
2273         {       // right key pressed
2274                 self.pressedkeys |= KEY_RIGHT;
2275                 self.pressedkeys &~= KEY_LEFT;
2276         }
2277         else if (self.movement_y < 0)
2278         {       // left key pressed
2279                 self.pressedkeys |= KEY_LEFT;
2280                 self.pressedkeys &~= KEY_RIGHT;
2281         }
2282         else
2283         {       // no y input
2284                 self.pressedkeys &~= KEY_RIGHT;
2285                 self.pressedkeys &~= KEY_LEFT;
2286         }
2287
2288         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2289                 self.pressedkeys |= KEY_JUMP;
2290         else
2291                 self.pressedkeys &~= KEY_JUMP;
2292         if (self.BUTTON_CROUCH)
2293                 self.pressedkeys |= KEY_CROUCH;
2294         else
2295                 self.pressedkeys &~= KEY_CROUCH;
2296 }
2297
2298 /*
2299 ======================
2300 spectate mode routines
2301 ======================
2302 */
2303
2304 void SpectateCopy(entity spectatee) {
2305         other = spectatee;
2306         MUTATOR_CALLHOOK(SpectateCopy);
2307         self.armortype = spectatee.armortype;
2308         self.armorvalue = spectatee.armorvalue;
2309         self.ammo_cells = spectatee.ammo_cells;
2310         self.ammo_shells = spectatee.ammo_shells;
2311         self.ammo_nails = spectatee.ammo_nails;
2312         self.ammo_rockets = spectatee.ammo_rockets;
2313         self.ammo_fuel = spectatee.ammo_fuel;
2314         self.clip_load = spectatee.clip_load;
2315         self.clip_size = spectatee.clip_size;
2316         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2317         self.health = spectatee.health;
2318         self.impulse = 0;
2319         self.items = spectatee.items;
2320         self.last_pickup = spectatee.last_pickup;
2321         self.hit_time = spectatee.hit_time;
2322         self.metertime = spectatee.metertime;
2323         self.strength_finished = spectatee.strength_finished;
2324         self.invincible_finished = spectatee.invincible_finished;
2325         self.pressedkeys = spectatee.pressedkeys;
2326         self.weapons = spectatee.weapons;
2327         self.switchweapon = spectatee.switchweapon;
2328         self.weapon = spectatee.weapon;
2329         self.nex_charge = spectatee.nex_charge;
2330         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2331         self.hagar_load = spectatee.hagar_load;
2332         self.minelayer_mines = spectatee.minelayer_mines;
2333         self.punchangle = spectatee.punchangle;
2334         self.view_ofs = spectatee.view_ofs;
2335         self.v_angle = spectatee.v_angle;
2336         self.velocity = spectatee.velocity;
2337         self.dmg_take = spectatee.dmg_take;
2338         self.dmg_save = spectatee.dmg_save;
2339         self.dmg_inflictor = spectatee.dmg_inflictor;
2340         self.angles = spectatee.v_angle;
2341         self.fixangle = TRUE;
2342         setorigin(self, spectatee.origin);
2343         setsize(self, spectatee.mins, spectatee.maxs);
2344         SetZoomState(spectatee.zoomstate);
2345
2346         anticheat_spectatecopy(spectatee);
2347
2348         //self.vehicle = spectatee.vehicle;
2349
2350         self.hud = spectatee.hud;
2351         if(spectatee.vehicle)
2352     {
2353         setorigin(self, spectatee.origin);
2354         self.velocity = spectatee.vehicle.velocity;
2355         self.v_angle += spectatee.vehicle.angles;
2356         //self.v_angle_x *= -1;
2357         self.vehicle_health = spectatee.vehicle_health;
2358         self.vehicle_shield = spectatee.vehicle_shield;
2359         self.vehicle_energy = spectatee.vehicle_energy;
2360         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2361         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2362         self.vehicle_reload1 = spectatee.vehicle_reload1;
2363         self.vehicle_reload2 = spectatee.vehicle_reload2;
2364
2365         msg_entity = self;
2366         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2367         WriteEntity(MSG_ONE, spectatee);
2368         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2369     }
2370 }
2371
2372 float SpectateUpdate() {
2373         if(!self.enemy)
2374             return 0;
2375
2376         if (self == self.enemy)
2377                 return 0;
2378
2379         if(self.enemy.classname != "player")
2380                 return 0;
2381
2382         SpectateCopy(self.enemy);
2383
2384         return 1;
2385 }
2386
2387 float SpectateNext() {
2388         other = find(self.enemy, classname, "player");
2389
2390         if (!other)
2391                 other = find(other, classname, "player");
2392
2393         if (other)
2394                 self.enemy = other;
2395
2396         if(self.enemy.classname == "player") {
2397             if(self.enemy.vehicle)
2398             {
2399             msg_entity = self;
2400             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2401             WriteEntity(MSG_ONE, self.enemy);
2402             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2403             self.movetype = MOVETYPE_NONE;
2404             accuracy_resend(self);
2405             }
2406             else
2407             {
2408             msg_entity = self;
2409             WriteByte(MSG_ONE, SVC_SETVIEW);
2410             WriteEntity(MSG_ONE, self.enemy);
2411             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2412             self.movetype = MOVETYPE_NONE;
2413             accuracy_resend(self);
2414
2415             if(!SpectateUpdate())
2416                 PutObserverInServer();
2417         }
2418         return 1;
2419         } else {
2420                 return 0;
2421         }
2422 }
2423
2424 /*
2425 =============
2426 ShowRespawnCountdown()
2427
2428 Update a respawn countdown display.
2429 =============
2430 */
2431 void ShowRespawnCountdown()
2432 {
2433         float number;
2434         if(self.deadflag == DEAD_NO) // just respawned?
2435                 return;
2436         else
2437         {
2438                 number = ceil(self.death_time - time);
2439                 if(number <= 0)
2440                         return;
2441                 if(number <= self.respawn_countdown)
2442                 {
2443                         self.respawn_countdown = number - 1;
2444                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2445                                 AnnounceTo(self, strcat(ftos(number), ""));
2446                 }
2447         }
2448 }
2449
2450 void LeaveSpectatorMode()
2451 {
2452         if(nJoinAllowed(1)) {
2453                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2454                         self.classname = "player";
2455
2456                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2457                                 JoinBestTeam(self, FALSE, TRUE);
2458
2459                         if(autocvar_g_campaign)
2460                                 campaign_bots_may_start = 1;
2461
2462                         PutClientInServer();
2463
2464                         if(self.classname == "player")
2465                                 bprint ("^4", self.netname, "^4 is playing now\n");
2466
2467                         if(!autocvar_g_campaign)
2468                                 centerprint(self,""); // clear MOTD
2469
2470                         return;
2471                 } else {
2472                         if (g_ca && self.caplayer) {
2473                         }       // do nothing
2474                         else
2475                                 stuffcmd(self,"menu_showteamselect\n");
2476                         return;
2477                 }
2478         }
2479         else {
2480                 //player may not join because of g_maxplayers is set
2481                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2482         }
2483 }
2484
2485 /**
2486  * Determines whether the player is allowed to join. This depends on cvar
2487  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2488  * it checks whether the number of currently playing players exceeds g_maxplayers.
2489  * @return int number of free slots for players, 0 if none
2490  */
2491 float nJoinAllowed(float includeMe) {
2492         if(self.team_forced < 0)
2493                 return FALSE; // forced spectators can never join
2494
2495         // TODO simplify this
2496         local entity e;
2497
2498         local float totalClients;
2499         FOR_EACH_CLIENT(e)
2500                 totalClients += 1;
2501
2502         if (!autocvar_g_maxplayers)
2503                 return maxclients - totalClients + includeMe;
2504
2505         local float currentlyPlaying;
2506         FOR_EACH_REALPLAYER(e)
2507                 currentlyPlaying += 1;
2508
2509         if(currentlyPlaying < autocvar_g_maxplayers)
2510                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2511
2512         return 0;
2513 }
2514
2515 /**
2516  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2517  * g_maxplayers_spectator_blocktime seconds
2518  */
2519 void checkSpectatorBlock() {
2520         if(self.classname == "spectator" || self.classname == "observer") {
2521                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2522                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2523                         dropclient(self);
2524                 }
2525         }
2526 }
2527
2528 void ObserverThink()
2529 {
2530         if (self.flags & FL_JUMPRELEASED) {
2531                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2532                         self.welcomemessage_time = 0;
2533                         self.flags &~= FL_JUMPRELEASED;
2534                         self.flags |= FL_SPAWNING;
2535                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2536                         self.welcomemessage_time = 0;
2537                         self.flags &~= FL_JUMPRELEASED;
2538                         if(SpectateNext() == 1) {
2539                                 self.classname = "spectator";
2540                         }
2541                 }
2542         } else {
2543                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2544                         self.flags |= FL_JUMPRELEASED;
2545                         if(self.flags & FL_SPAWNING)
2546                         {
2547                                 self.flags &~= FL_SPAWNING;
2548                                 LeaveSpectatorMode();
2549                                 return;
2550                         }
2551                 }
2552         }
2553         PrintWelcomeMessage(self);
2554 }
2555
2556 void SpectatorThink()
2557 {
2558         if (self.flags & FL_JUMPRELEASED) {
2559                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2560                         self.welcomemessage_time = 0;
2561                         self.flags &~= FL_JUMPRELEASED;
2562                         self.flags |= FL_SPAWNING;
2563                 } else if(self.BUTTON_ATCK) {
2564                         self.welcomemessage_time = 0;
2565                         self.flags &~= FL_JUMPRELEASED;
2566                         if(SpectateNext() == 1) {
2567                                 self.classname = "spectator";
2568                         } else {
2569                                 self.classname = "observer";
2570                                 PutClientInServer();
2571                         }
2572                 } else if (self.BUTTON_ATCK2) {
2573                         self.welcomemessage_time = 0;
2574                         self.flags &~= FL_JUMPRELEASED;
2575                         self.classname = "observer";
2576                         PutClientInServer();
2577                 } else {
2578                         if(!SpectateUpdate())
2579                                 PutObserverInServer();
2580                 }
2581         } else {
2582                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2583                         self.flags |= FL_JUMPRELEASED;
2584                         if(self.flags & FL_SPAWNING)
2585                         {
2586                                 self.flags &~= FL_SPAWNING;
2587                                 LeaveSpectatorMode();
2588                                 return;
2589                         }
2590                 }
2591                 if(!SpectateUpdate())
2592                         PutObserverInServer();
2593         }
2594
2595         PrintWelcomeMessage(self);
2596         self.flags |= FL_CLIENT | FL_NOTARGET;
2597 }
2598
2599 float ctf_usekey();
2600 void PlayerUseKey()
2601 {
2602         if(self.classname != "player")
2603                 return;
2604
2605         if(self.vehicle)
2606         {
2607         vehicles_exit(VHEF_NORMAL);
2608         return;
2609         }
2610
2611         // a use key was pressed; call handlers
2612         if(ctf_usekey())
2613                 return;
2614
2615         MUTATOR_CALLHOOK(PlayerUseKey);
2616 }
2617
2618 .float touchexplode_time;
2619
2620 /*
2621 =============
2622 PlayerPreThink
2623
2624 Called every frame for each client before the physics are run
2625 =============
2626 */
2627 .float usekeypressed;
2628 void() ctf_setstatus;
2629 void() nexball_setstatus;
2630 .float items_added;
2631 void PlayerPreThink (void)
2632 {
2633         WarpZone_PlayerPhysics_FixVAngle();
2634
2635         self.stat_game_starttime = game_starttime;
2636         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2637         self.stat_leadlimit = autocvar_leadlimit;
2638
2639         if(frametime)
2640         {
2641                 // physics frames: update anticheat stuff
2642                 anticheat_prethink();
2643         }
2644
2645         if(blockSpectators && frametime)
2646                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2647                 checkSpectatorBlock();
2648
2649         zoomstate_set = 0;
2650
2651         if(self.netname_previous != self.netname)
2652         {
2653                 if(autocvar_sv_eventlog)
2654                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2655                 if(self.netname_previous)
2656                         strunzone(self.netname_previous);
2657                 self.netname_previous = strzone(self.netname);
2658         }
2659
2660         // version nagging
2661         if(self.version_nagtime)
2662                 if(self.cvar_g_xonoticversion)
2663                         if(time > self.version_nagtime)
2664                         {
2665                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2666                                 {
2667                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2668                                         {
2669                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2670                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2671                                         }
2672                                         else
2673                                         {
2674                                                 float r;
2675                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2676                                                 if(r < 0)
2677                                                 {
2678                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2679                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2680                                                 }
2681                                                 else if(r > 0)
2682                                                 {
2683                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2684                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2685                                                 }
2686                                         }
2687                                 }
2688                                 self.version_nagtime = 0;
2689                         }
2690
2691         // GOD MODE info
2692         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2693         {
2694                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2695                 self.max_armorvalue = 0;
2696         }
2697
2698 #ifdef TETRIS
2699         if (TetrisPreFrame())
2700                 return;
2701 #endif
2702
2703         MUTATOR_CALLHOOK(PlayerPreThink);
2704
2705         if(self.BUTTON_USE && !self.usekeypressed)
2706                 PlayerUseKey();
2707         self.usekeypressed = self.BUTTON_USE;
2708
2709         if(self.classname == "player") {
2710 //              if(self.netname == "Wazat")
2711 //                      bprint(self.classname, "\n");
2712
2713                 CheckRules_Player();
2714
2715                 PrintWelcomeMessage(self);
2716
2717                 if (intermission_running)
2718                 {
2719                         IntermissionThink ();   // otherwise a button could be missed between
2720                         return;                                 // the think tics
2721                 }
2722
2723                 //don't allow the player to turn around while game is paused!
2724                 if(timeoutStatus == 2) {
2725                         // FIXME turn this into CSQC stuff
2726                         self.v_angle = self.lastV_angle;
2727                         self.angles = self.lastV_angle;
2728                         self.fixangle = TRUE;
2729                 }
2730
2731                 if(frametime)
2732                 {
2733                         if(self.health <= 0 && autocvar_g_deathglow)
2734                         {
2735                                 if(self.glowmod_x > 0)
2736                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2737                                 else
2738                                         self.glowmod_x = -1;
2739                                 if(self.glowmod_y > 0)
2740                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2741                                 else
2742                                         self.glowmod_y = -1;
2743                                 if(self.glowmod_z > 0)
2744                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2745                                 else
2746                                         self.glowmod_z = -1;
2747                         }
2748                         else
2749                         {
2750                                 // set weapon and player glowmod
2751                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2752
2753                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2754                                 {
2755                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2756                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2757                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2758
2759                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2760                                         {
2761                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2762                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2763                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2764                                         }
2765                                 }
2766                                 else
2767                                         self.weaponentity_glowmod = self.glowmod;
2768                         }
2769                         player_powerups();
2770                 }
2771
2772                 if (self.deadflag != DEAD_NO)
2773                 {
2774                         float button_pressed, force_respawn;
2775                         if(self.personal && g_race_qualifying)
2776                         {
2777                                 if(time > self.death_time)
2778                                 {
2779                                         self.death_time = time + 1; // only retry once a second
2780                                         respawn();
2781                                         self.impulse = 141;
2782                                 }
2783                         }
2784                         else
2785                         {
2786                                 if(frametime)
2787                                         player_anim();
2788                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2789                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2790                                 if (self.deadflag == DEAD_DYING)
2791                                 {
2792                                         if(force_respawn)
2793                                                 self.deadflag = DEAD_RESPAWNING;
2794                                         else if(!button_pressed)
2795                                                 self.deadflag = DEAD_DEAD;
2796                                 }
2797                                 else if (self.deadflag == DEAD_DEAD)
2798                                 {
2799                                         if(button_pressed)
2800                                                 self.deadflag = DEAD_RESPAWNABLE;
2801                                 }
2802                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2803                                 {
2804                                         if(!button_pressed)
2805                                                 self.deadflag = DEAD_RESPAWNING;
2806                                 }
2807                                 else if (self.deadflag == DEAD_RESPAWNING)
2808                                 {
2809                                         if(time > self.death_time)
2810                                         {
2811                                                 self.death_time = time + 1; // only retry once a second
2812                                                 respawn();
2813                                         }
2814                                 }
2815                                 ShowRespawnCountdown();
2816                         }
2817                         return;
2818                 }
2819
2820                 if(g_touchexplode)
2821                 if(time > self.touchexplode_time)
2822                 if(self.classname == "player")
2823                 if(self.deadflag == DEAD_NO)
2824                 if not(IS_INDEPENDENT_PLAYER(self))
2825                 FOR_EACH_PLAYER(other) if(self != other)
2826                 {
2827                         if(time > other.touchexplode_time)
2828                         if(other.deadflag == DEAD_NO)
2829                         if not(IS_INDEPENDENT_PLAYER(other))
2830                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2831                         {
2832                                 PlayerTouchExplode(self, other);
2833                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2834                         }
2835                 }
2836
2837                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2838                 {
2839                         vector dist;
2840
2841                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2842                         dist = self.prevorigin - self.origin;
2843                         dist_z = 0;
2844                         self.lms_traveled_distance += fabs(vlen(dist));
2845
2846                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2847                         {
2848                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2849                                 self.lms_traveled_distance = 0;
2850                         }
2851
2852                         if(time > self.lms_nextcheck)
2853                         {
2854                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2855                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2856                                 {
2857                                         centerprint(self, autocvar_g_lms_campcheck_message);
2858                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2859                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2860                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2861                                 }
2862                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2863                                 self.lms_traveled_distance = 0;
2864                         }
2865                 }
2866
2867                 self.prevorigin = self.origin;
2868
2869                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2870                 {
2871                         if (!self.crouch)
2872                         {
2873                                 self.crouch = TRUE;
2874                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2875                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2876                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2877                         }
2878                 }
2879                 else
2880                 {
2881                         if (self.crouch)
2882                         {
2883                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2884                                 if (!trace_startsolid)
2885                                 {
2886                                         self.crouch = FALSE;
2887                                         self.view_ofs = PL_VIEW_OFS;
2888                                         setsize (self, PL_MIN, PL_MAX);
2889                                 }
2890                         }
2891                 }
2892
2893                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2894                 {
2895                         if(self.bloodloss_timer < time)
2896                         {
2897                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2898                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2899                         }
2900                 }
2901
2902                 FixPlayermodel();
2903
2904                 GrapplingHookFrame();
2905
2906                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2907                 //if(frametime)
2908                 {
2909                         self.items &~= self.items_added;
2910
2911                         W_WeaponFrame();
2912
2913                         self.items_added = 0;
2914                         if(self.items & IT_JETPACK)
2915                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2916                                         self.items_added |= IT_FUEL;
2917
2918                         self.items |= self.items_added;
2919                 }
2920
2921                 player_regen();
2922
2923                 // rot nex charge to the charge limit
2924                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2925                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2926
2927                 if(frametime)
2928                         player_anim();
2929
2930                 if (g_minstagib)
2931                         minstagib_ammocheck();
2932
2933                 if(g_ctf)
2934                         ctf_setstatus();
2935
2936                 if(g_nexball)
2937                         nexball_setstatus();
2938
2939                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2940
2941                 //self.angles_y=self.v_angle_y + 90;   // temp
2942         } else if(gameover) {
2943                 if (intermission_running)
2944                         IntermissionThink ();   // otherwise a button could be missed between
2945                 return;
2946         } else if(self.classname == "observer") {
2947                 ObserverThink();
2948         } else if(self.classname == "spectator") {
2949                 SpectatorThink();
2950         }
2951
2952         if(!zoomstate_set)
2953                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2954
2955         float oldspectatee_status;
2956         oldspectatee_status = self.spectatee_status;
2957         if(self.classname == "spectator")
2958                 self.spectatee_status = num_for_edict(self.enemy);
2959         else if(self.classname == "observer")
2960                 self.spectatee_status = num_for_edict(self);
2961         else
2962                 self.spectatee_status = 0;
2963         if(self.spectatee_status != oldspectatee_status)
2964         {
2965                 ClientData_Touch(self);
2966                 if(g_race || g_cts)
2967                         race_InitSpectator();
2968         }
2969
2970         if(self.teamkill_soundtime)
2971         if(time > self.teamkill_soundtime)
2972         {
2973                 self.teamkill_soundtime = 0;
2974
2975                 entity oldpusher, oldself;
2976
2977                 oldself = self; self = self.teamkill_soundsource;
2978                 oldpusher = self.pusher; self.pusher = oldself;
2979
2980                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2981
2982                 self.pusher = oldpusher;
2983                 self = oldself;
2984         }
2985
2986         if(self.taunt_soundtime)
2987         if(time > self.taunt_soundtime)
2988         {
2989                 self.taunt_soundtime = 0;
2990                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2991         }
2992
2993         target_voicescript_next(self);
2994
2995         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2996         if(!self.weapon)
2997                 self.clip_load = self.clip_size = 0;
2998 }
2999
3000 float isInvisibleString(string s)
3001 {
3002         float i, n, c;
3003         s = strdecolorize(s);
3004         for((i = 0), (n = strlen(s)); i < n; ++i)
3005         {
3006                 c = str2chr(s, i);
3007                 switch(c)
3008                 {
3009                         case 0:
3010                         case 32: // space
3011                                 break;
3012                         case 192: // charmap space
3013                                 if (!autocvar_utf8_enable)
3014                                         break;
3015                                 return FALSE;
3016                         case 160: // space in unicode fonts
3017                         case 0xE000 + 192: // utf8 charmap space
3018                                 if (autocvar_utf8_enable)
3019                                         break;
3020                         default:
3021                                 return FALSE;
3022                 }
3023         }
3024         return TRUE;
3025 }
3026
3027 /*
3028 =============
3029 PlayerPostThink
3030
3031 Called every frame for each client after the physics are run
3032 =============
3033 */
3034 .float idlekick_lasttimeleft;
3035 .entity showheadshotbbox;
3036 void showheadshotbbox_think()
3037 {
3038         if(self.owner.showheadshotbbox != self)
3039         {
3040                 remove(self);
3041                 return;
3042         }
3043         self.nextthink = time;
3044         setorigin(self, self.owner.origin);
3045         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3046 }
3047 void PlayerPostThink (void)
3048 {
3049         // Savage: Check for nameless players
3050         if (isInvisibleString(self.netname)) {
3051                 self.netname = "Player";
3052                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3053         }
3054
3055         if(sv_maxidle && frametime)
3056         {
3057                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3058                 float timeleft;
3059                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3060                 if(timeleft <= 0)
3061                 {
3062                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3063                         AnnounceTo(self, "terminated");
3064                         dropclient(self);
3065                         return;
3066                 }
3067                 else if(timeleft <= 10)
3068                 {
3069                         if(timeleft != self.idlekick_lasttimeleft)
3070                         {
3071                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3072                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3073                         }
3074                 }
3075                 else
3076                 {
3077                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3078                 }
3079                 self.idlekick_lasttimeleft = timeleft;
3080         }
3081
3082 #ifdef TETRIS
3083         if(self.impulse == 100)
3084                 ImpulseCommands();
3085         if (TetrisPostFrame())
3086                 return;
3087 #endif
3088
3089         CheatFrame();
3090
3091         if(self.classname == "player") {
3092                 CheckRules_Player();
3093                 UpdateChatBubble();
3094                 if (self.impulse)
3095                         ImpulseCommands();
3096                 if (intermission_running)
3097                         return;         // intermission or finale
3098                 GetPressedKeys();
3099         } else if (self.classname == "observer") {
3100                 //do nothing
3101         } else if (self.classname == "spectator") {
3102                 //do nothing
3103         }
3104
3105         /*
3106         float i;
3107         for(i = 0; i < 1000; ++i)
3108         {
3109                 vector end;
3110                 end = self.origin + '0 0 1024' + 512 * randomvec();
3111                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3112                 if(trace_fraction < 1)
3113                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3114                 {
3115                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3116                         break;
3117                 }
3118         }
3119         */
3120
3121         Arena_Warmup();
3122
3123         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3124
3125         if(self.waypointsprite_attachedforcarrier)
3126                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3127
3128         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3129         {
3130                 if(!self.showheadshotbbox)
3131                 {
3132                         self.showheadshotbbox = spawn();
3133                         self.showheadshotbbox.classname = "headshotbbox";
3134                         self.showheadshotbbox.owner = self;
3135                         self.showheadshotbbox.think = showheadshotbbox_think;
3136                         self.showheadshotbbox.nextthink = time;
3137                         self = self.showheadshotbbox;
3138                         self.think();
3139                         self = self.owner;
3140                 }
3141         }
3142         else
3143         {
3144                 if(self.showheadshotbbox)
3145                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3146                 remove(self.showheadshotbbox);
3147         }
3148
3149         playerdemo_write();
3150
3151         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3152         {
3153                 if(!self.stored_netname)
3154                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3155                 if(self.stored_netname != self.netname)
3156                 {
3157                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3158                         strunzone(self.stored_netname);
3159                         self.stored_netname = strzone(self.netname);
3160                 }
3161         }
3162
3163         /*
3164         if(g_race)
3165                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3166         */
3167 }