qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(to.classname == "spectator")
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(e2.classname == "spectator")
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         minstagib_stop_countdown(self);
 170
 171         Portal_ClearAll(self);
 172
 173         if(self.alivetime)
 174         {
 175                 if(!inWarmupStage)
 176                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 177                 self.alivetime = 0;
 178         }
 179
 180         if(self.vehicle)
 181                 vehicles_exit(VHEF_RELESE);
 182
 183         WaypointSprite_PlayerDead();
 184
 185         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 186                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 187
 188         if(self.killcount != -666)
 189         {
 190                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 191
 192                 if(self.just_joined == FALSE) {
 193                         LogTeamchange(self.playerid, -1, 4);
 194                 } else
 195                         self.just_joined = FALSE;
 196         }
 197
 198         PlayerScore_Clear(self); // clear scores when needed
 199
 200         accuracy_resend(self);
 201
 202         self.spectatortime = time;
 203
 204         self.classname = "observer";
 205         self.iscreature = FALSE;
 206         self.teleportable = TELEPORT_SIMPLE;
 207         self.damagedbycontents = FALSE;
 208         self.health = -666;
 209         self.takedamage = DAMAGE_NO;
 210         self.solid = SOLID_NOT;
 211         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 212         self.flags = FL_CLIENT | FL_NOTARGET;
 213         self.armorvalue = 666;
 214         self.effects = 0;
 215         self.armorvalue = autocvar_g_balance_armor_start;
 216         self.pauserotarmor_finished = 0;
 217         self.pauserothealth_finished = 0;
 218         self.pauseregen_finished = 0;
 219         self.damageforcescale = 0;
 220         self.death_time = 0;
 221         self.respawn_flags = 0;
 222         self.respawn_time = 0;
 223         self.stat_respawn_time = 0;
 224         self.alpha = 0;
 225         self.scale = 0;
 226         self.fade_time = 0;
 227         self.pain_frame = 0;
 228         self.pain_finished = 0;
 229         self.strength_finished = 0;
 230         self.invincible_finished = 0;
 231         self.superweapons_finished = 0;
 232         self.pushltime = 0;
 233         self.istypefrag = 0;
 234         self.think = func_null;
 235         self.nextthink = 0;
 236         self.hook_time = 0;
 237         self.deadflag = DEAD_NO;
 238         self.angles = spot.angles;
 239         self.angles_z = 0;
 240         self.fixangle = TRUE;
 241         self.crouch = FALSE;
 242
 243         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 244         self.prevorigin = self.origin;
 245         self.items = 0;
 246         WEPSET_CLEAR_E(self);
 247         self.model = "";
 248         FixPlayermodel();
 249         setmodel(self, "null");
 250         self.drawonlytoclient = self;
 251
 252         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 253         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 254
 255         self.weapon = 0;
 256         self.weaponname = "";
 257         self.switchingweapon = 0;
 258         self.weaponmodel = "";
 259         self.weaponentity = world;
 260         self.exteriorweaponentity = world;
 261         self.killcount = -666;
 262         self.velocity = '0 0 0';
 263         self.avelocity = '0 0 0';
 264         self.punchangle = '0 0 0';
 265         self.punchvector = '0 0 0';
 266         self.oldvelocity = self.velocity;
 267         self.fire_endtime = -1;
 268 }
 269
 270 .float model_randomizer;
 271 void FixPlayermodel()
 272 {
 273         string defaultmodel;
 274         float defaultskin, chmdl, oldskin, n, i;
 275         vector m1, m2;
 276
 277         defaultmodel = "";
 278         defaultskin = 0;
 279         chmdl = FALSE;
 280
 281         if(autocvar_sv_defaultcharacter == 1)
 282         {
 283                 if(teamplay)
 284                 {
 285                         string s;
 286                         s = Team_ColorName_Lower(self.team);
 287                         if(s != "neutral")
 288                         {
 289                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 290                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 291                         }
 292                 }
 293
 294                 if(defaultmodel == "")
 295                 {
 296                         defaultmodel = autocvar_sv_defaultplayermodel;
 297                         defaultskin = autocvar_sv_defaultplayerskin;
 298                 }
 299
 300                 n = tokenize_console(defaultmodel);
 301                 if(n > 0)
 302                         defaultmodel = argv(floor(n * self.model_randomizer));
 303
 304                 i = strstrofs(defaultmodel, ":", 0);
 305                 if(i >= 0)
 306                 {
 307                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 308                         defaultmodel = substring(defaultmodel, 0, i);
 309                 }
 310         }
 311
 312         if(defaultmodel != "")
 313         {
 314                 if (defaultmodel != self.model)
 315                 {
 316                         m1 = self.mins;
 317                         m2 = self.maxs;
 318                         setplayermodel (self, defaultmodel);
 319                         setsize (self, m1, m2);
 320                         chmdl = TRUE;
 321                 }
 322
 323                 oldskin = self.skin;
 324                 self.skin = defaultskin;
 325         } else {
 326                 if (self.playermodel != self.model || self.playermodel == "")
 327                 {
 328                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 329                         m1 = self.mins;
 330                         m2 = self.maxs;
 331                         setplayermodel (self, self.playermodel);
 332                         setsize (self, m1, m2);
 333                         chmdl = TRUE;
 334                 }
 335
 336                 oldskin = self.skin;
 337                 self.skin = stof(self.playerskin);
 338         }
 339
 340         if(chmdl || oldskin != self.skin) // model or skin has changed
 341         {
 342                 self.species = player_getspecies(); // update species
 343                 UpdatePlayerSounds(); // update skin sounds
 344         }
 345
 346         if(!teamplay)
 347                 if(strlen(autocvar_sv_defaultplayercolors))
 348                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 349                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 350 }
 351
 352 /*
 353 =============
 354 PutClientInServer
 355
 356 Called when a client spawns in the server
 357 =============
 358 */
 359
 360 void PutClientInServer (void)
 361 {
 362         if(clienttype(self) == CLIENTTYPE_BOT)
 363                 self.classname = "player";
 364         else if(clienttype(self) == CLIENTTYPE_REAL)
 365         {
 366                 msg_entity = self;
 367                 WriteByte(MSG_ONE, SVC_SETVIEW);
 368                 WriteEntity(MSG_ONE, self);
 369         }
 370
 371         // reset player keys
 372         self.itemkeys = 0;
 373
 374         MUTATOR_CALLHOOK(PutClientInServer);
 375
 376         if(gameover)
 377                 self.classname = "observer";
 378
 379         if(self.classname == "player") {
 380                 entity spot, oldself;
 381                 float j;
 382
 383                 accuracy_resend(self);
 384
 385                 if(self.team < 0)
 386                         JoinBestTeam(self, FALSE, TRUE);
 387
 388                 race_PreSpawn();
 389
 390                 spot = SelectSpawnPoint (FALSE);
 391                 if(!spot)
 392                 {
 393                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 394                         return; // spawn failed
 395                 }
 396
 397                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 398
 399                 self.classname = "player";
 400                 self.wasplayer = TRUE;
 401                 self.iscreature = TRUE;
 402                 self.teleportable = TELEPORT_NORMAL;
 403                 self.damagedbycontents = TRUE;
 404                 self.movetype = MOVETYPE_WALK;
 405                 self.solid = SOLID_SLIDEBOX;
 406                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 407                 if(autocvar_g_playerclip_collisions)
 408                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 409                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 410                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 411                 self.frags = FRAGS_PLAYER;
 412                 if(INDEPENDENT_PLAYERS)
 413                         MAKE_INDEPENDENT_PLAYER(self);
 414                 self.flags = FL_CLIENT;
 415                 if(autocvar__notarget)
 416                         self.flags |= FL_NOTARGET;
 417                 self.takedamage = DAMAGE_AIM;
 418                 if(g_minstagib)
 419                         self.effects = EF_FULLBRIGHT;
 420                 else
 421                         self.effects = 0;
 422                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 423                 self.air_finished = time + 12;
 424                 self.dmg = 2;
 425                 if(autocvar_g_balance_nex_charge)
 426                 {
 427                         if(autocvar_g_balance_nex_secondary_chargepool)
 428                                 self.nex_chargepool_ammo = 1;
 429                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 430                 }
 431
 432                 if(inWarmupStage)
 433                 {
 434                         self.ammo_shells = warmup_start_ammo_shells;
 435                         self.ammo_nails = warmup_start_ammo_nails;
 436                         self.ammo_rockets = warmup_start_ammo_rockets;
 437                         self.ammo_cells = warmup_start_ammo_cells;
 438                         self.ammo_fuel = warmup_start_ammo_fuel;
 439                         self.health = warmup_start_health;
 440                         self.armorvalue = warmup_start_armorvalue;
 441                         WEPSET_COPY_EA(self, warmup_start_weapons);
 442                 }
 443                 else
 444                 {
 445                         self.ammo_shells = start_ammo_shells;
 446                         self.ammo_nails = start_ammo_nails;
 447                         self.ammo_rockets = start_ammo_rockets;
 448                         self.ammo_cells = start_ammo_cells;
 449                         self.ammo_fuel = start_ammo_fuel;
 450                         self.health = start_health;
 451                         self.armorvalue = start_armorvalue;
 452                         WEPSET_COPY_EA(self, start_weapons);
 453                 }
 454
 455                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 456                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 457                 else
 458                         self.superweapons_finished = 0;
 459
 460                 if(g_weaponarena_random)
 461                 {
 462                         if(g_weaponarena_random_with_laser)
 463                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 464                         W_RandomWeapons(self, g_weaponarena_random);
 465                         if(g_weaponarena_random_with_laser)
 466                                 WEPSET_OR_EW(self, WEP_LASER);
 467                 }
 468
 469                 self.items = start_items;
 470
 471                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 472                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 473                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 474                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 475                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 476                 //extend the pause of rotting if client was reset at the beginning of the countdown
 477                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 478                         self.spawnshieldtime += game_starttime - time;
 479                         self.pauserotarmor_finished += game_starttime - time;
 480                         self.pauserothealth_finished += game_starttime - time;
 481                         self.pauseregen_finished += game_starttime - time;
 482                 }
 483                 self.damageforcescale = 2;
 484                 self.death_time = 0;
 485                 self.respawn_flags = 0;
 486                 self.respawn_time = 0;
 487                 self.stat_respawn_time = 0;
 488                 self.scale = 0;
 489                 self.fade_time = 0;
 490                 self.pain_frame = 0;
 491                 self.pain_finished = 0;
 492                 self.strength_finished = 0;
 493                 self.invincible_finished = 0;
 494                 self.pushltime = 0;
 495                 // players have no think function
 496                 self.think = func_null;
 497                 self.nextthink = 0;
 498                 self.hook_time = 0;
 499                 self.dmg_team = 0;
 500                 self.ballistics_density = autocvar_g_ballistics_density_player;
 501
 502                 self.metertime = 0;
 503
 504                 self.deadflag = DEAD_NO;
 505
 506                 self.angles = spot.angles;
 507
 508                 self.angles_z = 0; // never spawn tilted even if the spot says to
 509                 self.fixangle = TRUE; // turn this way immediately
 510                 self.velocity = '0 0 0';
 511                 self.avelocity = '0 0 0';
 512                 self.punchangle = '0 0 0';
 513                 self.punchvector = '0 0 0';
 514                 self.oldvelocity = self.velocity;
 515                 self.fire_endtime = -1;
 516
 517                 msg_entity = self;
 518                 WRITESPECTATABLE_MSG_ONE({
 519                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 520                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 521                 });
 522
 523                 self.model = "";
 524                 FixPlayermodel();
 525                 self.drawonlytoclient = world;
 526
 527                 self.crouch = FALSE;
 528                 self.view_ofs = PL_VIEW_OFS;
 529                 setsize (self, PL_MIN, PL_MAX);
 530                 self.spawnorigin = spot.origin;
 531                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 532                 // don't reset back to last position, even if new position is stuck in solid
 533                 self.oldorigin = self.origin;
 534                 self.prevorigin = self.origin;
 535                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 536                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 537         self.hud = HUD_NORMAL;
 538
 539                 self.event_damage = PlayerDamage;
 540
 541                 self.bot_attack = TRUE;
 542
 543                 self.statdraintime = time + 5;
 544                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 545
 546                 if(self.killcount == -666) {
 547                         PlayerScore_Clear(self);
 548                         self.killcount = 0;
 549                 }
 550
 551                 CL_SpawnWeaponentity();
 552                 self.alpha = default_player_alpha;
 553                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 554                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 555
 556                 self.speedrunning = FALSE;
 557
 558                 race_PostSpawn(spot);
 559
 560                 //stuffcmd(self, "chase_active 0");
 561                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 562
 563                 target_voicescript_clear(self);
 564
 565                 // reset fields the weapons may use
 566                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 567                 {
 568                         weapon_action(j, WR_RESETPLAYER);
 569
 570                         // all weapons must be fully loaded when we spawn
 571                         entity e;
 572                         e = get_weaponinfo(j);
 573                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 574                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 575                 }
 576
 577                 oldself = self;
 578                 self = spot;
 579                         activator = oldself;
 580                                 string s;
 581                                 s = self.target;
 582                                 self.target = string_null;
 583                                 SUB_UseTargets();
 584                                 self.target = s;
 585                         activator = world;
 586                 self = oldself;
 587
 588                 spawn_spot = spot;
 589                 MUTATOR_CALLHOOK(PlayerSpawn);
 590
 591                 if(autocvar_spawn_debug)
 592                 {
 593                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 594                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 595                 }
 596
 597                 self.switchweapon = w_getbestweapon(self);
 598                 self.cnt = -1; // W_LastWeapon will not complain
 599                 self.weapon = 0;
 600                 self.weaponname = "";
 601                 self.switchingweapon = 0;
 602
 603                 if(!inWarmupStage)
 604                         if(!self.alivetime)
 605                                 self.alivetime = time;
 606
 607                 antilag_clear(self);
 608
 609                 if (autocvar_g_spawnsound)
 610                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 611         } else if(self.classname == "observer") {
 612                 PutObserverInServer ();
 613         }
 614 }
 615
 616 .float ebouncefactor, ebouncestop; // electro's values
 617 // TODO do we need all these fields, or should we stop autodetecting runtime
 618 // changes and just have a console command to update this?
 619 float ClientInit_SendEntity(entity to, float sf)
 620 {
 621         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 622         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 635         if(sv_foginterval && world.fog != "")
 636                 WriteString(MSG_ENTITY, world.fog);
 637         else
 638                 WriteString(MSG_ENTITY, "");
 639         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 640         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 641         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 642         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 643         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 644         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 645         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 646         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 647         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 648         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 649         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 650         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 651         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 652         return TRUE;
 653 }
 654
 655 void ClientInit_CheckUpdate()
 656 {
 657         self.nextthink = time;
 658         if(self.count != autocvar_g_balance_armor_blockpercent)
 659         {
 660                 self.count = autocvar_g_balance_armor_blockpercent;
 661                 self.SendFlags |= 1;
 662         }
 663         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 664         {
 665                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 666                 self.SendFlags |= 1;
 667         }
 668         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 669         {
 670                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 671                 self.SendFlags |= 1;
 672         }
 673         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 674         {
 675                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 676                 self.SendFlags |= 1;
 677         }
 678         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 679         {
 680                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 681                 self.SendFlags |= 1;
 682         }
 683         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 684         {
 685                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 686                 self.SendFlags |= 1;
 687         }
 688 }
 689
 690 void ClientInit_Spawn()
 691 {
 692         entity o;
 693         entity e;
 694         e = spawn();
 695         e.classname = "clientinit";
 696         e.think = ClientInit_CheckUpdate;
 697         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 698
 699         o = self;
 700         self = e;
 701         ClientInit_CheckUpdate();
 702         self = o;
 703 }
 704
 705 /*
 706 =============
 707 SetNewParms
 708 =============
 709 */
 710 void SetNewParms (void)
 711 {
 712         // initialize parms for a new player
 713         parm1 = -(86400 * 366);
 714 }
 715
 716 /*
 717 =============
 718 SetChangeParms
 719 =============
 720 */
 721 void SetChangeParms (void)
 722 {
 723         // save parms for level change
 724         parm1 = self.parm_idlesince - time;
 725 }
 726
 727 /*
 728 =============
 729 DecodeLevelParms
 730 =============
 731 */
 732 void DecodeLevelParms (void)
 733 {
 734         // load parms
 735         self.parm_idlesince = parm1;
 736         if(self.parm_idlesince == -(86400 * 366))
 737                 self.parm_idlesince = time;
 738
 739         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 740         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 741 }
 742
 743 /*
 744 =============
 745 ClientKill
 746
 747 Called when a client types 'kill' in the console
 748 =============
 749 */
 750
 751 .float clientkill_nexttime;
 752 void ClientKill_Now_TeamChange()
 753 {
 754         if(self.killindicator_teamchange == -1)
 755         {
 756                 JoinBestTeam( self, FALSE, TRUE );
 757         }
 758         else if(self.killindicator_teamchange == -2)
 759         {
 760                 if(blockSpectators)
 761                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 762                 PutObserverInServer();
 763         }
 764         else
 765                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 766         self.killindicator_teamchange = 0;
 767 }
 768
 769 void ClientKill_Now()
 770 {
 771         if(self.vehicle)
 772         {
 773             vehicles_exit(VHEF_RELESE);
 774             if(!self.killindicator_teamchange)
 775             {
 776             self.vehicle_health = -1;
 777             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 778             }
 779         }
 780
 781         if(self.killindicator && !wasfreed(self.killindicator))
 782                 remove(self.killindicator);
 783
 784         self.killindicator = world;
 785
 786         if(self.killindicator_teamchange)
 787                 ClientKill_Now_TeamChange();
 788
 789         // in any case:
 790         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 791
 792         // now I am sure the player IS dead
 793 }
 794 void KillIndicator_Think()
 795 {
 796         if (gameover)
 797         {
 798                 self.owner.killindicator = world;
 799                 remove(self);
 800                 return;
 801         }
 802
 803         if (self.owner.alpha < 0 && !self.owner.vehicle)
 804         {
 805                 self.owner.killindicator = world;
 806                 remove(self);
 807                 return;
 808         }
 809
 810         if(self.cnt <= 0)
 811         {
 812                 self = self.owner;
 813                 ClientKill_Now(); // no oldself needed
 814                 return;
 815         }
 816     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 817     {
 818         self.nextthink = time + 1;
 819         self.cnt -= 1;
 820     }
 821         else
 822         {
 823                 if(self.cnt <= 10)
 824                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 825                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 826                 {
 827                         if(self.cnt <= 10)
 828                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
 829                 }
 830                 self.nextthink = time + 1;
 831                 self.cnt -= 1;
 832         }
 833 }
 834
 835 float clientkilltime;
 836 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 837 {
 838         float killtime;
 839         float starttime;
 840         entity e;
 841
 842         if (gameover)
 843                 return;
 844
 845         killtime = autocvar_g_balance_kill_delay;
 846
 847         if(g_race_qualifying || g_cts)
 848                 killtime = 0;
 849
 850     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 851     {
 852                 remove(self.killindicator);
 853                 self.killindicator = world;
 854
 855         ClientKill_Now(); // allow instant kill in this case
 856         return;
 857     }
 858
 859         self.killindicator_teamchange = targetteam;
 860
 861     if(!self.killindicator)
 862         {
 863                 if(self.deadflag == DEAD_NO)
 864                 {
 865                         killtime = max(killtime, self.clientkill_nexttime - time);
 866                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 867                 }
 868
 869                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
 870                 {
 871                         ClientKill_Now();
 872                 }
 873                 else
 874                 {
 875                         starttime = max(time, clientkilltime);
 876
 877                         self.killindicator = spawn();
 878                         self.killindicator.owner = self;
 879                         self.killindicator.scale = 0.5;
 880                         setattachment(self.killindicator, self, "");
 881                         setorigin(self.killindicator, '0 0 52');
 882                         self.killindicator.think = KillIndicator_Think;
 883                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 884                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 885                         self.killindicator.cnt = ceil(killtime);
 886                         self.killindicator.count = bound(0, ceil(killtime), 10);
 887                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 888
 889                         for(e = world; (e = find(e, classname, "body")) != world; )
 890                         {
 891                                 if(e.enemy != self)
 892                                         continue;
 893                                 e.killindicator = spawn();
 894                                 e.killindicator.owner = e;
 895                                 e.killindicator.scale = 0.5;
 896                                 setattachment(e.killindicator, e, "");
 897                                 setorigin(e.killindicator, '0 0 52');
 898                                 e.killindicator.think = KillIndicator_Think;
 899                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 900                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 901                                 e.killindicator.cnt = ceil(killtime);
 902                         }
 903                         self.lip = 0;
 904                 }
 905         }
 906         if(self.killindicator)
 907         {
 908                 if(targetteam == 0) // just die
 909                 {
 910                         self.killindicator.colormod = '0 0 0';
 911                         if(clienttype(self) == CLIENTTYPE_REAL)
 912                         if(self.killindicator.cnt > 0)
 913                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 914                 }
 915                 else if(targetteam == -1) // auto
 916                 {
 917                         self.killindicator.colormod = '0 1 0';
 918                         if(clienttype(self) == CLIENTTYPE_REAL)
 919                         if(self.killindicator.cnt > 0)
 920                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 921                 }
 922                 else if(targetteam == -2) // spectate
 923                 {
 924                         self.killindicator.colormod = '0.5 0.5 0.5';
 925                         if(clienttype(self) == CLIENTTYPE_REAL)
 926                         if(self.killindicator.cnt > 0)
 927                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 928                 }
 929                 else
 930                 {
 931                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 932                         if(clienttype(self) == CLIENTTYPE_REAL)
 933                         if(self.killindicator.cnt > 0)
 934                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 935                 }
 936         }
 937
 938 }
 939
 940 void ClientKill (void)
 941 {
 942         if(gameover) return;
 943         if(self.player_blocked) return;
 944         if(self.freezetag_frozen) return;
 945
 946         ClientKill_TeamChange(0);
 947 }
 948
 949 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 950 {
 951     e.killindicator = spawn();
 952     e.killindicator.owner = e;
 953     e.killindicator.think = KillIndicator_Think;
 954     e.killindicator.nextthink = time + (e.lip) * 0.05;
 955     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 956     e.killindicator.health = 1; // this is used to indicate that it should be silent
 957     e.lip = 0;
 958 }
 959
 960 void FixClientCvars(entity e)
 961 {
 962         // send prediction settings to the client
 963         stuffcmd(e, "\nin_bindmap 0 0\n");
 964         if(g_race || g_cts)
 965                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 966         if(autocvar_g_antilag == 3) // client side hitscan
 967                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 968         if(autocvar_sv_gentle)
 969                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 970         /*
 971          * we no longer need to stuff this. Remove this comment block if you feel
 972          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 973         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 974         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 975         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 976         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 977         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 978         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 979         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 980         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 981         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 982         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 983         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 984         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 985         stuffcmd(e, "cl_movement_edgefriction 1\n");
 986          */
 987 }
 988
 989 float PlayerInIDList(entity p, string idlist)
 990 {
 991         float n, i;
 992         string s;
 993
 994         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 995         if not(p.crypto_idfp)
 996                 return 0;
 997
 998         // this function allows abbreviated player IDs too!
 999         n = tokenize_console(idlist);
1000         for(i = 0; i < n; ++i)
1001         {
1002                 s = argv(i);
1003                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1004                         return 1;
1005         }
1006
1007         return 0;
1008 }
1009
1010 /*
1011 =============
1012 ClientConnect
1013
1014 Called when a client connects to the server
1015 =============
1016 */
1017 void DecodeLevelParms (void);
1018 //void dom_player_join_team(entity pl);
1019 void set_dom_state(entity e);
1020 void ClientConnect (void)
1021 {
1022         float t;
1023
1024         if(self.flags & FL_CLIENT)
1025         {
1026                 print("Warning: ClientConnect, but already connected!\n");
1027                 return;
1028         }
1029
1030         if(Ban_MaybeEnforceBanOnce(self))
1031                 return;
1032
1033         DecodeLevelParms();
1034
1035 #ifdef WATERMARK
1036         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1037 #endif
1038
1039         self.classname = "player_joining";
1040
1041         self.flags = FL_CLIENT;
1042         self.version_nagtime = time + 10 + random() * 10;
1043
1044         if(player_count<0)
1045         {
1046                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1047                 player_count = 0;
1048         }
1049
1050         PlayerScore_Attach(self);
1051         ClientData_Attach();
1052         accuracy_init(self);
1053
1054         bot_clientconnect();
1055
1056         playerdemo_init();
1057
1058         anticheat_init();
1059
1060         race_PreSpawnObserver();
1061
1062         // identify the right forced team
1063         if(autocvar_g_campaign)
1064         {
1065                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1066                 {
1067                         switch(autocvar_g_campaign_forceteam)
1068                         {
1069                                 case 1: self.team_forced = NUM_TEAM_1; break;
1070                                 case 2: self.team_forced = NUM_TEAM_2; break;
1071                                 case 3: self.team_forced = NUM_TEAM_3; break;
1072                                 case 4: self.team_forced = NUM_TEAM_4; break;
1073                                 default: self.team_forced = 0;
1074                         }
1075                 }
1076         }
1077         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1078                 self.team_forced = NUM_TEAM_1;
1079         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1080                 self.team_forced = NUM_TEAM_2;
1081         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1082                 self.team_forced = NUM_TEAM_3;
1083         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1084                 self.team_forced = NUM_TEAM_4;
1085         else if(autocvar_g_forced_team_otherwise == "red")
1086                 self.team_forced = NUM_TEAM_1;
1087         else if(autocvar_g_forced_team_otherwise == "blue")
1088                 self.team_forced = NUM_TEAM_2;
1089         else if(autocvar_g_forced_team_otherwise == "yellow")
1090                 self.team_forced = NUM_TEAM_3;
1091         else if(autocvar_g_forced_team_otherwise == "pink")
1092                 self.team_forced = NUM_TEAM_4;
1093         else if(autocvar_g_forced_team_otherwise == "spectate")
1094                 self.team_forced = -1;
1095         else if(autocvar_g_forced_team_otherwise == "spectator")
1096                 self.team_forced = -1;
1097         else
1098                 self.team_forced = 0;
1099
1100         if(!teamplay)
1101                 if(self.team_forced > 0)
1102                         self.team_forced = 0;
1103
1104         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1105
1106         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1107                 self.classname = "observer";
1108         } else {
1109                 if(teamplay)
1110                 {
1111                         if(autocvar_g_balance_teams)
1112                         {
1113                                 self.classname = "player";
1114                                 campaign_bots_may_start = 1;
1115                         }
1116                         else
1117                         {
1118                                 self.classname = "observer"; // do it anyway
1119                         }
1120                 }
1121                 else
1122                 {
1123                         self.classname = "player";
1124                         campaign_bots_may_start = 1;
1125                 }
1126         }
1127
1128         self.playerid = (playerid_last = playerid_last + 1);
1129
1130         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1131
1132     if(clienttype(self) == CLIENTTYPE_BOT)
1133         PlayerStats_AddPlayer(self);
1134
1135         if(autocvar_sv_eventlog)
1136                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1137
1138         LogTeamchange(self.playerid, self.team, 1);
1139
1140         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1141
1142         self.netname_previous = strzone(self.netname);
1143
1144         if((self.classname == STR_PLAYER && teamplay))
1145                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1146         else
1147                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1148
1149         stuffcmd(self, strcat(clientstuff, "\n"));
1150         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1151
1152         FixClientCvars(self);
1153
1154         // spawnfunc_waypoint sprites
1155         WaypointSprite_InitClient(self);
1156
1157         // Wazat's grappling hook
1158         SetGrappleHookBindings();
1159
1160         // get version info from player
1161         stuffcmd(self, "cmd clientversion $gameversion\n");
1162
1163         // get other cvars from player
1164         GetCvars(0);
1165
1166         // notify about available teams
1167         if(teamplay)
1168         {
1169                 CheckAllowedTeams(self);
1170                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1171                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1172         }
1173         else
1174                 stuffcmd(self, "set _teams_available 0\n");
1175
1176         attach_entcs();
1177
1178         bot_relinkplayerlist();
1179
1180         self.spectatortime = time;
1181         if(blockSpectators)
1182         {
1183                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1184         }
1185
1186         self.jointime = time;
1187         self.allowed_timeouts = autocvar_sv_timeout_number;
1188
1189         if(clienttype(self) == CLIENTTYPE_REAL)
1190         {
1191                 if(!autocvar_g_campaign)
1192                 {
1193                         self.motd_actived_time = -1;
1194                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1195                 }
1196
1197                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1198                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1199         }
1200
1201         if(!sv_foginterval && world.fog != "")
1202                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1203
1204         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1205         {
1206                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1207                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1208         }
1209         else
1210                 self.hitplotfh = -1;
1211
1212         if(g_race || g_cts) {
1213                 string rr;
1214                 if(g_cts)
1215                         rr = CTS_RECORD;
1216                 else
1217                         rr = RACE_RECORD;
1218
1219                 msg_entity = self;
1220                 race_send_recordtime(MSG_ONE);
1221                 race_send_speedaward(MSG_ONE);
1222
1223                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1224                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1225                 race_send_speedaward_alltimebest(MSG_ONE);
1226
1227                 float i;
1228                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1229                         race_SendRankings(i, 0, 0, MSG_ONE);
1230                 }
1231         }
1232         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1233                 send_CSQC_teamnagger();
1234
1235         CheatInitClient();
1236
1237         CSQCMODEL_AUTOINIT();
1238
1239         self.model_randomizer = random();
1240
1241         if(clienttype(self) == CLIENTTYPE_REAL)
1242                 sv_notice_join();
1243
1244         MUTATOR_CALLHOOK(ClientConnect);
1245 }
1246 /*
1247 =============
1248 ClientDisconnect
1249
1250 Called when a client disconnects from the server
1251 =============
1252 */
1253 .entity chatbubbleentity;
1254 void ReadyCount();
1255 void ClientDisconnect (void)
1256 {
1257         if(self.vehicle)
1258             vehicles_exit(VHEF_RELESE);
1259
1260         if not(self.flags & FL_CLIENT)
1261         {
1262                 print("Warning: ClientDisconnect without ClientConnect\n");
1263                 return;
1264         }
1265
1266         PlayerStats_AddGlobalInfo(self);
1267
1268         CheatShutdownClient();
1269
1270         if(self.hitplotfh >= 0)
1271         {
1272                 fclose(self.hitplotfh);
1273                 self.hitplotfh = -1;
1274         }
1275
1276         anticheat_report();
1277         anticheat_shutdown();
1278
1279         playerdemo_shutdown();
1280
1281         bot_clientdisconnect();
1282
1283         if(self.entcs)
1284                 detach_entcs();
1285
1286         if(autocvar_sv_eventlog)
1287                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1288
1289         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1290
1291         MUTATOR_CALLHOOK(ClientDisconnect);
1292
1293         Portal_ClearAll(self);
1294
1295         RemoveGrapplingHook(self);
1296
1297         // Here, everything has been done that requires this player to be a client.
1298
1299         self.flags &~= FL_CLIENT;
1300
1301         if (self.chatbubbleentity)
1302                 remove (self.chatbubbleentity);
1303
1304         if (self.killindicator)
1305                 remove (self.killindicator);
1306
1307         WaypointSprite_PlayerGone();
1308
1309         bot_relinkplayerlist();
1310
1311         accuracy_free(self);
1312         ClientData_Detach();
1313         PlayerScore_Detach(self);
1314
1315         if(self.netname_previous)
1316                 strunzone(self.netname_previous);
1317         if(self.clientstatus)
1318                 strunzone(self.clientstatus);
1319         if(self.weaponorder_byimpulse)
1320                 strunzone(self.weaponorder_byimpulse);
1321
1322         ClearPlayerSounds();
1323
1324         if(self.personal)
1325                 remove(self.personal);
1326
1327         self.playerid = 0;
1328         ReadyCount();
1329
1330         // free cvars
1331         GetCvars(-1);
1332 }
1333
1334 .float BUTTON_CHAT;
1335 void ChatBubbleThink()
1336 {
1337         self.nextthink = time;
1338         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1339         {
1340                 if(self.owner) // but why can that ever be world?
1341                         self.owner.chatbubbleentity = world;
1342                 remove(self);
1343                 return;
1344         }
1345         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1346 #ifdef TETRIS
1347                 || self.owner.tetris_on
1348 #endif
1349         )
1350                 self.model = self.mdl;
1351         else
1352                 self.model = "";
1353 }
1354
1355 void UpdateChatBubble()
1356 {
1357         if (self.alpha < 0)
1358                 return;
1359         // spawn a chatbubble entity if needed
1360         if (!self.chatbubbleentity)
1361         {
1362                 self.chatbubbleentity = spawn();
1363                 self.chatbubbleentity.owner = self;
1364                 self.chatbubbleentity.exteriormodeltoclient = self;
1365                 self.chatbubbleentity.think = ChatBubbleThink;
1366                 self.chatbubbleentity.nextthink = time;
1367                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1368                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1369                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1370                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1371                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1372                 self.chatbubbleentity.model = "";
1373                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1374         }
1375 }
1376
1377
1378 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1379 // added to the model skins
1380 /*void UpdateColorModHack()
1381 {
1382         float c;
1383         c = self.clientcolors & 15;
1384         // LordHavoc: only bothering to support white, green, red, yellow, blue
1385              if (!teamplay) self.colormod = '0 0 0';
1386         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1387         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1388         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1389         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1390         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1391         else self.colormod = '1 1 1';
1392 }*/
1393
1394 void respawn(void)
1395 {
1396         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1397         {
1398                 self.solid = SOLID_NOT;
1399                 self.takedamage = DAMAGE_NO;
1400                 self.movetype = MOVETYPE_FLY;
1401                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1402                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1403                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1404                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1405                 if(autocvar_g_respawn_ghosts_maxtime)
1406                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1407         }
1408
1409         CopyBody(1);
1410
1411         self.effects |= EF_NODRAW; // prevent another CopyBody
1412         PutClientInServer();
1413 }
1414
1415 void play_countdown(float finished, string samp)
1416 {
1417         if(clienttype(self) == CLIENTTYPE_REAL)
1418                 if(floor(finished - time - frametime) != floor(finished - time))
1419                         if(finished - time < 6)
1420                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1421 }
1422
1423 void player_powerups (void)
1424 {
1425         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1426         olditems = self.items;
1427
1428         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1429                 self.modelflags |= MF_ROCKET;
1430         else
1431                 self.modelflags &~= MF_ROCKET;
1432
1433         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1434
1435         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1436                 return;
1437
1438         Fire_ApplyDamage(self);
1439         Fire_ApplyEffect(self);
1440
1441         if (g_minstagib)
1442         {
1443                 self.effects |= EF_FULLBRIGHT;
1444
1445                 if (self.items & IT_STRENGTH)
1446                 {
1447                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1448                         if (time > self.strength_finished)
1449                         {
1450                                 self.alpha = default_player_alpha;
1451                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1452                                 self.items &~= IT_STRENGTH;
1453                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1454                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1455                         }
1456                 }
1457                 else
1458                 {
1459                         if (time < self.strength_finished)
1460                         {
1461                                 self.alpha = g_minstagib_invis_alpha;
1462                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1463                                 self.items |= IT_STRENGTH;
1464                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1465                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1466                         }
1467                 }
1468
1469                 if (self.items & IT_INVINCIBLE)
1470                 {
1471                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1472                         if (time > self.invincible_finished)
1473                         {
1474                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1475                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1476                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1477                         }
1478                 }
1479                 else
1480                 {
1481                         if (time < self.invincible_finished)
1482                         {
1483                                 self.items = self.items | IT_INVINCIBLE;
1484                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1485                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1486                         }
1487                 }
1488         }
1489         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1490         {
1491                 if (self.items & IT_STRENGTH)
1492                 {
1493                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1494                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1495                         if (time > self.strength_finished)
1496                         {
1497                                 self.items = self.items - (self.items & IT_STRENGTH);
1498                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1499                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1500                         }
1501                 }
1502                 else
1503                 {
1504                         if (time < self.strength_finished)
1505                         {
1506                                 self.items = self.items | IT_STRENGTH;
1507                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1508                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1509                         }
1510                 }
1511                 if (self.items & IT_INVINCIBLE)
1512                 {
1513                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1514                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1515                         if (time > self.invincible_finished)
1516                         {
1517                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1518                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1519                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1520                         }
1521                 }
1522                 else
1523                 {
1524                         if (time < self.invincible_finished)
1525                         {
1526                                 self.items = self.items | IT_INVINCIBLE;
1527                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1528                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1529                         }
1530                 }
1531                 if (self.items & IT_SUPERWEAPON)
1532                 {
1533                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1534                         {
1535                                 self.superweapons_finished = 0;
1536                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1537                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1538                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1539                         }
1540                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1541                         {
1542                                 // don't let them run out
1543                         }
1544                         else
1545                         {
1546                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1547                                 if (time > self.superweapons_finished)
1548                                 {
1549                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1550                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1551                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1552                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1553                                 }
1554                         }
1555                 }
1556                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1557                 {
1558                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1559                         {
1560                                 self.items = self.items | IT_SUPERWEAPON;
1561                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1562                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1563                         }
1564                         else
1565                         {
1566                                 self.superweapons_finished = 0;
1567                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1568                         }
1569                 }
1570                 else
1571                 {
1572                         self.superweapons_finished = 0;
1573                 }
1574         }
1575
1576         if(autocvar_g_nodepthtestplayers)
1577                 self.effects = self.effects | EF_NODEPTHTEST;
1578
1579         if(autocvar_g_fullbrightplayers)
1580                 self.effects = self.effects | EF_FULLBRIGHT;
1581
1582         // midair gamemode: damage only while in the air
1583         // if in midair mode, being on ground grants temporary invulnerability
1584         // (this is so that multishot weapon don't clear the ground flag on the
1585         // first damage in the frame, leaving the player vulnerable to the
1586         // remaining hits in the same frame)
1587         if (self.flags & FL_ONGROUND)
1588         if (g_midair)
1589                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1590
1591         if (time >= game_starttime)
1592         if (time < self.spawnshieldtime)
1593                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1594
1595         MUTATOR_CALLHOOK(PlayerPowerups);
1596 }
1597
1598 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1599 {
1600         if(current > stable)
1601                 return current;
1602         else if(current > stable - 0.25) // when close enough, "snap"
1603                 return stable;
1604         else
1605                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1606 }
1607
1608 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1609 {
1610         if(current < stable)
1611                 return current;
1612         else if(current < stable + 0.25) // when close enough, "snap"
1613                 return stable;
1614         else
1615                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1616 }
1617
1618 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1619 {
1620         if(current > rotstable)
1621         {
1622                 if(rotframetime > 0)
1623                 {
1624                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1625                         current = max(rotstable, current - rotlinear * rotframetime);
1626                 }
1627         }
1628         else if(current < regenstable)
1629         {
1630                 if(regenframetime > 0)
1631                 {
1632                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1633                         current = min(regenstable, current + regenlinear * regenframetime);
1634                 }
1635         }
1636
1637         if(current > limit)
1638                 current = limit;
1639
1640         return current;
1641 }
1642
1643 void player_regen (void)
1644 {
1645         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1646         maxh = autocvar_g_balance_health_rotstable;
1647         maxa = autocvar_g_balance_armor_rotstable;
1648         maxf = autocvar_g_balance_fuel_rotstable;
1649         minh = autocvar_g_balance_health_regenstable;
1650         mina = autocvar_g_balance_armor_regenstable;
1651         minf = autocvar_g_balance_fuel_regenstable;
1652         limith = autocvar_g_balance_health_limit;
1653         limita = autocvar_g_balance_armor_limit;
1654         limitf = autocvar_g_balance_fuel_limit;
1655
1656         max_mod = regen_mod = rot_mod = limit_mod = 1;
1657
1658         maxh = maxh * max_mod;
1659         //maxa = maxa * max_mod;
1660         //maxf = maxf * max_mod;
1661         minh = minh * max_mod;
1662         //mina = mina * max_mod;
1663         //minf = minf * max_mod;
1664         limith = limith * limit_mod;
1665         limita = limita * limit_mod;
1666         //limitf = limitf * limit_mod;
1667
1668         if(g_ca)
1669                 rot_mod = 0;
1670
1671         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1672         {
1673                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1674                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1675
1676                 // if player rotted to death...  die!
1677                 if(self.health < 1)
1678                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1679         }
1680
1681         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1682                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1683 }
1684
1685 float zoomstate_set;
1686 void SetZoomState(float z)
1687 {
1688         if(z != self.zoomstate)
1689         {
1690                 self.zoomstate = z;
1691                 ClientData_Touch(self);
1692         }
1693         zoomstate_set = 1;
1694 }
1695
1696 void GetPressedKeys(void) {
1697         MUTATOR_CALLHOOK(GetPressedKeys);
1698         if (self.movement_x > 0) // get if movement keys are pressed
1699         {       // forward key pressed
1700                 self.pressedkeys |= KEY_FORWARD;
1701                 self.pressedkeys &~= KEY_BACKWARD;
1702         }
1703         else if (self.movement_x < 0)
1704         {       // backward key pressed
1705                 self.pressedkeys |= KEY_BACKWARD;
1706                 self.pressedkeys &~= KEY_FORWARD;
1707         }
1708         else
1709         {       // no x input
1710                 self.pressedkeys &~= KEY_FORWARD;
1711                 self.pressedkeys &~= KEY_BACKWARD;
1712         }
1713
1714         if (self.movement_y > 0)
1715         {       // right key pressed
1716                 self.pressedkeys |= KEY_RIGHT;
1717                 self.pressedkeys &~= KEY_LEFT;
1718         }
1719         else if (self.movement_y < 0)
1720         {       // left key pressed
1721                 self.pressedkeys |= KEY_LEFT;
1722                 self.pressedkeys &~= KEY_RIGHT;
1723         }
1724         else
1725         {       // no y input
1726                 self.pressedkeys &~= KEY_RIGHT;
1727                 self.pressedkeys &~= KEY_LEFT;
1728         }
1729
1730         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1731                 self.pressedkeys |= KEY_JUMP;
1732         else
1733                 self.pressedkeys &~= KEY_JUMP;
1734         if (self.BUTTON_CROUCH)
1735                 self.pressedkeys |= KEY_CROUCH;
1736         else
1737                 self.pressedkeys &~= KEY_CROUCH;
1738
1739         if (self.BUTTON_ATCK)
1740                 self.pressedkeys |= KEY_ATCK;
1741         else
1742                 self.pressedkeys &~= KEY_ATCK;
1743         if (self.BUTTON_ATCK2)
1744                 self.pressedkeys |= KEY_ATCK2;
1745         else
1746                 self.pressedkeys &~= KEY_ATCK2;
1747 }
1748
1749 /*
1750 ======================
1751 spectate mode routines
1752 ======================
1753 */
1754
1755 void SpectateCopy(entity spectatee) {
1756         other = spectatee;
1757         MUTATOR_CALLHOOK(SpectateCopy);
1758         self.armortype = spectatee.armortype;
1759         self.armorvalue = spectatee.armorvalue;
1760         self.ammo_cells = spectatee.ammo_cells;
1761         self.ammo_shells = spectatee.ammo_shells;
1762         self.ammo_nails = spectatee.ammo_nails;
1763         self.ammo_rockets = spectatee.ammo_rockets;
1764         self.ammo_fuel = spectatee.ammo_fuel;
1765         self.clip_load = spectatee.clip_load;
1766         self.clip_size = spectatee.clip_size;
1767         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1768         self.health = spectatee.health;
1769         self.impulse = 0;
1770         self.items = spectatee.items;
1771         self.last_pickup = spectatee.last_pickup;
1772         self.hit_time = spectatee.hit_time;
1773         self.metertime = spectatee.metertime;
1774         self.strength_finished = spectatee.strength_finished;
1775         self.invincible_finished = spectatee.invincible_finished;
1776         self.pressedkeys = spectatee.pressedkeys;
1777         WEPSET_COPY_EE(self, spectatee);
1778         self.switchweapon = spectatee.switchweapon;
1779         self.switchingweapon = spectatee.switchingweapon;
1780         self.weapon = spectatee.weapon;
1781         self.nex_charge = spectatee.nex_charge;
1782         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1783         self.hagar_load = spectatee.hagar_load;
1784         self.minelayer_mines = spectatee.minelayer_mines;
1785         self.punchangle = spectatee.punchangle;
1786         self.view_ofs = spectatee.view_ofs;
1787         self.velocity = spectatee.velocity;
1788         self.dmg_take = spectatee.dmg_take;
1789         self.dmg_save = spectatee.dmg_save;
1790         self.dmg_inflictor = spectatee.dmg_inflictor;
1791         self.v_angle = spectatee.v_angle;
1792         self.angles = spectatee.v_angle;
1793         if(!self.BUTTON_USE)
1794                 self.fixangle = TRUE;
1795         setorigin(self, spectatee.origin);
1796         setsize(self, spectatee.mins, spectatee.maxs);
1797         SetZoomState(spectatee.zoomstate);
1798
1799     anticheat_spectatecopy(spectatee);
1800         self.hud = spectatee.hud;
1801         if(spectatee.vehicle)
1802     {
1803         self.fixangle = FALSE;
1804         //self.velocity = spectatee.vehicle.velocity;
1805         self.vehicle_health = spectatee.vehicle_health;
1806         self.vehicle_shield = spectatee.vehicle_shield;
1807         self.vehicle_energy = spectatee.vehicle_energy;
1808         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1809         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1810         self.vehicle_reload1 = spectatee.vehicle_reload1;
1811         self.vehicle_reload2 = spectatee.vehicle_reload2;
1812
1813         msg_entity = self;
1814
1815         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1816             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1817             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1818             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1819
1820         //WriteByte (MSG_ONE, SVC_SETVIEW);
1821         //    WriteEntity(MSG_ONE, self);
1822         //makevectors(spectatee.v_angle);
1823         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1824     }
1825 }
1826
1827 float SpectateUpdate() {
1828         if(!self.enemy)
1829             return 0;
1830
1831         if (self == self.enemy)
1832                 return 0;
1833
1834         if(self.enemy.classname != "player")
1835                 return 0;
1836
1837         SpectateCopy(self.enemy);
1838
1839         return 1;
1840 }
1841
1842
1843 float SpectateSet()
1844 {
1845         if(self.enemy.classname != "player")
1846                 return FALSE;
1847         /*if(self.enemy.vehicle)
1848         {
1849
1850                 msg_entity = self;
1851                 WriteByte(MSG_ONE, SVC_SETVIEW);
1852                 WriteEntity(MSG_ONE, self.enemy);
1853                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1854
1855                 self.movetype = MOVETYPE_NONE;
1856                 accuracy_resend(self);
1857         }
1858         else
1859         {*/
1860                 msg_entity = self;
1861                 WriteByte(MSG_ONE, SVC_SETVIEW);
1862                 WriteEntity(MSG_ONE, self.enemy);
1863                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1864                 self.movetype = MOVETYPE_NONE;
1865                 accuracy_resend(self);
1866
1867                 if(!SpectateUpdate())
1868                         PutObserverInServer();
1869         //}
1870         return TRUE;
1871 }
1872
1873 float Spectate(entity pl)
1874 {
1875         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1876         if(pl.team != self.team)
1877                 return 0;
1878
1879         self.enemy = pl;
1880         return SpectateSet();
1881 }
1882
1883 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1884 entity CA_SpectateNext(entity start) {
1885         if (start.team == self.team) {
1886                 return start;
1887         }
1888
1889         other = start;
1890         // continue from current player
1891         while(other && other.team != self.team) {
1892                 other = find(other, classname, "player");
1893         }
1894
1895         if (!other) {
1896                 // restart from begining
1897                 other = find(other, classname, "player");
1898                 while(other && other.team != self.team) {
1899                         other = find(other, classname, "player");
1900                 }
1901         }
1902
1903         return other;
1904 }
1905
1906 float SpectateNext()
1907 {
1908         other = find(self.enemy, classname, "player");
1909
1910         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1911                 // CA and ca players when spectating enemies is forbidden
1912                 other = CA_SpectateNext(other);
1913         } else {
1914                 // other modes and ca spectators or spectating enemies is allowed
1915                 if (!other)
1916                         other = find(other, classname, "player");
1917         }
1918
1919         if (other)
1920                 self.enemy = other;
1921
1922         return SpectateSet();
1923 }
1924
1925 float SpectatePrev()
1926 {
1927         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1928         other = findchain(classname, "player");
1929         if not(other) // no player
1930                 return FALSE;
1931
1932         entity first = other;
1933         // skip players until current spectated player
1934         if(self.enemy)
1935         while(other && other != self.enemy)
1936                 other = other.chain;
1937
1938         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1939         {
1940                 do { other = other.chain; }
1941                 while(other && other.team != self.team);
1942
1943                 if not(other)
1944                 {
1945                         other = first;
1946                         while(other.team != self.team)
1947                                 other = other.chain;
1948                         if(other == self.enemy)
1949                                 return TRUE;
1950                 }
1951         }
1952         else
1953         {
1954                 if(other.chain)
1955                         other = other.chain;
1956                 else
1957                         other = first;
1958         }
1959         self.enemy = other;
1960         return SpectateSet();
1961 }
1962
1963 /*
1964 =============
1965 ShowRespawnCountdown()
1966
1967 Update a respawn countdown display.
1968 =============
1969 */
1970 void ShowRespawnCountdown()
1971 {
1972         float number;
1973         if(self.deadflag == DEAD_NO) // just respawned?
1974                 return;
1975         else
1976         {
1977                 number = ceil(self.respawn_time - time);
1978                 if(number <= 0)
1979                         return;
1980                 if(number <= self.respawn_countdown)
1981                 {
1982                         self.respawn_countdown = number - 1;
1983                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1984                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
1985                 }
1986         }
1987 }
1988
1989 void LeaveSpectatorMode()
1990 {
1991         if(self.caplayer)
1992                 return;
1993         if(nJoinAllowed(self))
1994         {
1995                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1996                 {
1997                         self.classname = "player";
1998
1999                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2000                                 { JoinBestTeam(self, FALSE, TRUE); }
2001
2002                         if(autocvar_g_campaign)
2003                                 { campaign_bots_may_start = 1; }
2004
2005                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2006
2007                         PutClientInServer();
2008
2009                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2010                 }
2011                 else
2012                         stuffcmd(self, "menu_showteamselect\n");
2013         }
2014         else
2015         {
2016                 // Player may not join because g_maxplayers is set
2017                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2018         }
2019 }
2020
2021 /**
2022  * Determines whether the player is allowed to join. This depends on cvar
2023  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2024  * it checks whether the number of currently playing players exceeds g_maxplayers.
2025  * @return int number of free slots for players, 0 if none
2026  */
2027 float nJoinAllowed(entity ignore) {
2028         if(!ignore)
2029         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2030         // so report 0 free slots if restricted
2031         {
2032                 if(autocvar_g_forced_team_otherwise == "spectate")
2033                         return 0;
2034                 if(autocvar_g_forced_team_otherwise == "spectator")
2035                         return 0;
2036         }
2037
2038         if(self.team_forced < 0)
2039                 return 0; // forced spectators can never join
2040
2041         // TODO simplify this
2042         entity e;
2043         float totalClients = 0;
2044         FOR_EACH_CLIENT(e)
2045                 if(e != ignore)
2046                         totalClients += 1;
2047
2048         if (!autocvar_g_maxplayers)
2049                 return maxclients - totalClients;
2050
2051         float currentlyPlaying = 0;
2052         FOR_EACH_REALCLIENT(e)
2053                 if(e.classname == "player" || e.caplayer == 1)
2054                         currentlyPlaying += 1;
2055
2056         if(currentlyPlaying < autocvar_g_maxplayers)
2057                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2058
2059         return 0;
2060 }
2061
2062 /**
2063  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2064  * g_maxplayers_spectator_blocktime seconds
2065  */
2066 void checkSpectatorBlock() {
2067         if(self.classname == "spectator" || self.classname == "observer") {
2068                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2069                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2070                         dropclient(self);
2071                 }
2072         }
2073 }
2074
2075 void PrintWelcomeMessage()
2076 {
2077         if(self.motd_actived_time == 0)
2078         {
2079                 if (autocvar_g_campaign) {
2080                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2081                                 self.motd_actived_time = time;
2082                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2083                         }
2084                 } else {
2085                         if (self.BUTTON_INFO) {
2086                                 self.motd_actived_time = time;
2087                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2088                         }
2089                 }
2090         }
2091         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2092         {
2093                 if (autocvar_g_campaign) {
2094                         if (self.BUTTON_INFO)
2095                                 self.motd_actived_time = time;
2096                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2097                                 self.motd_actived_time = 0;
2098                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2099                         }
2100                 } else {
2101                         if (self.BUTTON_INFO)
2102                                 self.motd_actived_time = time;
2103                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2104                                 self.motd_actived_time = 0;
2105                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2106                         }
2107                 }
2108         }
2109         else //if(self.motd_actived_time < 0) // just connected, motd is active
2110         {
2111                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2112                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2113                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2114                 {
2115                         // instanctly hide MOTD
2116                         self.motd_actived_time = 0;
2117                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2118                 }
2119         }
2120 }
2121
2122 void ObserverThink()
2123 {
2124         float prefered_movetype;
2125         if (self.flags & FL_JUMPRELEASED) {
2126                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2127                         self.flags &~= FL_JUMPRELEASED;
2128                         self.flags |= FL_SPAWNING;
2129                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2130                         self.flags &~= FL_JUMPRELEASED;
2131                         if(SpectateNext()) {
2132                                 self.classname = "spectator";
2133                         }
2134                 } else {
2135                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2136                         if (self.movetype != prefered_movetype)
2137                                 self.movetype = prefered_movetype;
2138                 }
2139         } else {
2140                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2141                         self.flags |= FL_JUMPRELEASED;
2142                         if(self.flags & FL_SPAWNING)
2143                         {
2144                                 self.flags &~= FL_SPAWNING;
2145                                 LeaveSpectatorMode();
2146                                 return;
2147                         }
2148                 }
2149         }
2150 }
2151
2152 void SpectatorThink()
2153 {
2154         if (self.flags & FL_JUMPRELEASED) {
2155                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2156                         self.flags &~= FL_JUMPRELEASED;
2157                         self.flags |= FL_SPAWNING;
2158                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209) {
2159                         self.flags &~= FL_JUMPRELEASED;
2160                         if(SpectateNext()) {
2161                                 self.classname = "spectator";
2162                         } else {
2163                                 self.classname = "observer";
2164                                 PutClientInServer();
2165                         }
2166                         self.impulse = 0;
2167                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229) {
2168                         self.flags &~= FL_JUMPRELEASED;
2169                         if(SpectatePrev()) {
2170                                 self.classname = "spectator";
2171                         } else {
2172                                 self.classname = "observer";
2173                                 PutClientInServer();
2174                         }
2175                         self.impulse = 0;
2176                 } else if (self.BUTTON_ATCK2) {
2177                         self.flags &~= FL_JUMPRELEASED;
2178                         self.classname = "observer";
2179                         PutClientInServer();
2180                 } else {
2181                         if(!SpectateUpdate())
2182                                 PutObserverInServer();
2183                 }
2184         } else {
2185                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2186                         self.flags |= FL_JUMPRELEASED;
2187                         if(self.flags & FL_SPAWNING)
2188                         {
2189                                 self.flags &~= FL_SPAWNING;
2190                                 LeaveSpectatorMode();
2191                                 return;
2192                         }
2193                 }
2194                 if(!SpectateUpdate())
2195                         PutObserverInServer();
2196         }
2197
2198         self.flags |= FL_CLIENT | FL_NOTARGET;
2199 }
2200
2201 void PlayerUseKey()
2202 {
2203         if(self.classname != "player")
2204                 return;
2205
2206         if(self.vehicle)
2207         {
2208         vehicles_exit(VHEF_NORMAL);
2209         return;
2210         }
2211
2212         // a use key was pressed; call handlers
2213         MUTATOR_CALLHOOK(PlayerUseKey);
2214 }
2215
2216 /*
2217 =============
2218 PlayerPreThink
2219
2220 Called every frame for each client before the physics are run
2221 =============
2222 */
2223 .float usekeypressed;
2224 void() nexball_setstatus;
2225 .float items_added;
2226 void PlayerPreThink (void)
2227 {
2228         WarpZone_PlayerPhysics_FixVAngle();
2229
2230         self.stat_game_starttime = game_starttime;
2231         self.stat_round_starttime = round_starttime;
2232         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2233         self.stat_leadlimit = autocvar_leadlimit;
2234
2235         if(frametime)
2236         {
2237                 // physics frames: update anticheat stuff
2238                 anticheat_prethink();
2239         }
2240
2241         if(blockSpectators && frametime)
2242                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2243                 checkSpectatorBlock();
2244
2245         zoomstate_set = 0;
2246
2247         if(self.netname_previous != self.netname)
2248         {
2249                 if(autocvar_sv_eventlog)
2250                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2251                 if(self.netname_previous)
2252                         strunzone(self.netname_previous);
2253                 self.netname_previous = strzone(self.netname);
2254         }
2255
2256         // version nagging
2257         if(self.version_nagtime)
2258                 if(self.cvar_g_xonoticversion)
2259                         if(time > self.version_nagtime)
2260                         {
2261                                 // don't notify git users
2262                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2263                                 {
2264                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2265                                         {
2266                                                 // notify release users if connecting to git
2267                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2268                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2269                                         }
2270                                         else
2271                                         {
2272                                                 float r;
2273                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2274                                                 if(r < 0)
2275                                                 {
2276                                                         // give users new version
2277                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2278                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2279                                                 }
2280                                                 else if(r > 0)
2281                                                 {
2282                                                         // notify users about old server version
2283                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2284                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2285                                                 }
2286                                         }
2287                                 }
2288                                 self.version_nagtime = 0;
2289                         }
2290
2291         // GOD MODE info
2292         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2293         {
2294                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2295                 self.max_armorvalue = 0;
2296         }
2297
2298 #ifdef TETRIS
2299         if (TetrisPreFrame())
2300                 return;
2301 #endif
2302
2303         MUTATOR_CALLHOOK(PlayerPreThink);
2304
2305         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2306         {
2307                 if(self.BUTTON_USE && !self.usekeypressed)
2308                         PlayerUseKey();
2309                 self.usekeypressed = self.BUTTON_USE;
2310         }
2311
2312         if(clienttype(self) == CLIENTTYPE_REAL)
2313                 PrintWelcomeMessage();
2314
2315         if(self.classname == "player") {
2316
2317                 CheckRules_Player();
2318
2319                 if (intermission_running)
2320                 {
2321                         IntermissionThink ();   // otherwise a button could be missed between
2322                         return;                                 // the think tics
2323                 }
2324
2325                 //don't allow the player to turn around while game is paused!
2326                 if(timeout_status == TIMEOUT_ACTIVE) {
2327                         // FIXME turn this into CSQC stuff
2328                         self.v_angle = self.lastV_angle;
2329                         self.angles = self.lastV_angle;
2330                         self.fixangle = TRUE;
2331                 }
2332
2333                 if(frametime)
2334                 {
2335                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2336                         {
2337                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2338                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2339                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2340
2341                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2342                                 {
2343                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2344                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2345                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2346                                 }
2347                         }
2348                         else
2349                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2350
2351                         player_powerups();
2352                 }
2353
2354                 if (g_minstagib)
2355                         minstagib_ammocheck();
2356
2357                 if (self.deadflag != DEAD_NO)
2358                 {
2359                         if(self.personal && g_race_qualifying)
2360                         {
2361                                 if(time > self.respawn_time)
2362                                 {
2363                                         self.respawn_time = time + 1; // only retry once a second
2364                                         self.stat_respawn_time = self.respawn_time;
2365                                         respawn();
2366                                         self.impulse = 141;
2367                                 }
2368                         }
2369                         else
2370                         {
2371                                 float button_pressed;
2372                                 if(frametime)
2373                                         player_anim();
2374                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2375
2376                                 if (self.deadflag == DEAD_DYING)
2377                                 {
2378                                         if(self.respawn_flags & RESPAWN_FORCE)
2379                                                 self.deadflag = DEAD_RESPAWNING;
2380                                         else if(!button_pressed)
2381                                                 self.deadflag = DEAD_DEAD;
2382                                 }
2383                                 else if (self.deadflag == DEAD_DEAD)
2384                                 {
2385                                         if(button_pressed)
2386                                                 self.deadflag = DEAD_RESPAWNABLE;
2387                                 }
2388                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2389                                 {
2390                                         if(!button_pressed)
2391                                                 self.deadflag = DEAD_RESPAWNING;
2392                                 }
2393                                 else if (self.deadflag == DEAD_RESPAWNING)
2394                                 {
2395                                         if(time > self.respawn_time)
2396                                         {
2397                                                 self.respawn_time = time + 1; // only retry once a second
2398                                                 respawn();
2399                                         }
2400                                 }
2401
2402                                 ShowRespawnCountdown();
2403
2404                                 if(self.respawn_flags & RESPAWN_SILENT)
2405                                         self.stat_respawn_time = 0;
2406                                 else
2407                                         self.stat_respawn_time = self.respawn_time;
2408                         }
2409
2410                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2411                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2412                                 self.stat_respawn_time *= -1;
2413
2414                         return;
2415                 }
2416
2417                 self.prevorigin = self.origin;
2418
2419                 float do_crouch = self.BUTTON_CROUCH;
2420                 if(self.hook.state)
2421                         do_crouch = 0;
2422                 if(self.health <= g_bloodloss)
2423                         do_crouch = 1;
2424                 if(self.vehicle)
2425                         do_crouch = 0;
2426                 if(self.freezetag_frozen)
2427                         do_crouch = 0;
2428                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2429                         do_crouch = 0;
2430
2431                 if (do_crouch)
2432                 {
2433                         if (!self.crouch)
2434                         {
2435                                 self.crouch = TRUE;
2436                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2437                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2438                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2439                         }
2440                 }
2441                 else
2442                 {
2443                         if (self.crouch)
2444                         {
2445                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2446                                 if (!trace_startsolid)
2447                                 {
2448                                         self.crouch = FALSE;
2449                                         self.view_ofs = PL_VIEW_OFS;
2450                                         setsize (self, PL_MIN, PL_MAX);
2451                                 }
2452                         }
2453                 }
2454
2455                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2456                 {
2457                         if(self.bloodloss_timer < time)
2458                         {
2459                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2460                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2461                         }
2462                 }
2463
2464                 FixPlayermodel();
2465
2466                 GrapplingHookFrame();
2467
2468                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2469                 //if(frametime)
2470                 {
2471                         self.items &~= self.items_added;
2472
2473                         W_WeaponFrame();
2474
2475                         self.items_added = 0;
2476                         if(self.items & IT_JETPACK)
2477                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2478                                         self.items_added |= IT_FUEL;
2479
2480                         self.items |= self.items_added;
2481                 }
2482
2483                 player_regen();
2484
2485                 // rot nex charge to the charge limit
2486                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2487                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2488
2489                 if(frametime)
2490                         player_anim();
2491
2492                 if(g_nexball)
2493                         nexball_setstatus();
2494
2495                 // secret status
2496                 secrets_setstatus();
2497
2498                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2499
2500                 //self.angles_y=self.v_angle_y + 90;   // temp
2501         } else if(gameover) {
2502                 if (intermission_running)
2503                         IntermissionThink ();   // otherwise a button could be missed between
2504                 return;
2505         } else if(self.classname == "observer") {
2506                 ObserverThink();
2507         } else if(self.classname == "spectator") {
2508                 SpectatorThink();
2509         }
2510
2511         if(!zoomstate_set)
2512                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2513
2514         float oldspectatee_status;
2515         oldspectatee_status = self.spectatee_status;
2516         if(self.classname == "spectator")
2517                 self.spectatee_status = num_for_edict(self.enemy);
2518         else if(self.classname == "observer")
2519                 self.spectatee_status = num_for_edict(self);
2520         else
2521                 self.spectatee_status = 0;
2522         if(self.spectatee_status != oldspectatee_status)
2523         {
2524                 ClientData_Touch(self);
2525                 if(g_race || g_cts)
2526                         race_InitSpectator();
2527         }
2528
2529         if(self.teamkill_soundtime)
2530         if(time > self.teamkill_soundtime)
2531         {
2532                 self.teamkill_soundtime = 0;
2533
2534                 entity oldpusher, oldself;
2535
2536                 oldself = self; self = self.teamkill_soundsource;
2537                 oldpusher = self.pusher; self.pusher = oldself;
2538
2539                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2540
2541                 self.pusher = oldpusher;
2542                 self = oldself;
2543         }
2544
2545         if(self.taunt_soundtime)
2546         if(time > self.taunt_soundtime)
2547         {
2548                 self.taunt_soundtime = 0;
2549                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2550         }
2551
2552         target_voicescript_next(self);
2553
2554         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2555         if(!self.weapon)
2556                 self.clip_load = self.clip_size = 0;
2557 }
2558
2559 float isInvisibleString(string s)
2560 {
2561         float i, n, c;
2562         s = strdecolorize(s);
2563         for((i = 0), (n = strlen(s)); i < n; ++i)
2564         {
2565                 c = str2chr(s, i);
2566                 switch(c)
2567                 {
2568                         case 0:
2569                         case 32: // space
2570                                 break;
2571                         case 192: // charmap space
2572                                 if (!autocvar_utf8_enable)
2573                                         break;
2574                                 return FALSE;
2575                         case 160: // space in unicode fonts
2576                         case 0xE000 + 192: // utf8 charmap space
2577                                 if (autocvar_utf8_enable)
2578                                         break;
2579                         default:
2580                                 return FALSE;
2581                 }
2582         }
2583         return TRUE;
2584 }
2585
2586 /*
2587 =============
2588 PlayerPostThink
2589
2590 Called every frame for each client after the physics are run
2591 =============
2592 */
2593 .float idlekick_lasttimeleft;
2594 void PlayerPostThink (void)
2595 {
2596         // Savage: Check for nameless players
2597         if (isInvisibleString(self.netname)) {
2598                 self.netname = "Player";
2599                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2600         }
2601
2602         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2603         {
2604                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2605                 {
2606                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2607                 }
2608                 else
2609                 {
2610                         float timeleft;
2611                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2612                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2613                         {
2614                                 if(!self.idlekick_lasttimeleft)
2615                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2616                         }
2617                         if(timeleft <= 0)
2618                         {
2619                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2620                                 dropclient(self);
2621                                 return;
2622                         }
2623                         else if(timeleft <= 10)
2624                         {
2625                                 if(timeleft != self.idlekick_lasttimeleft)
2626                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2627                                 self.idlekick_lasttimeleft = timeleft;
2628                         }
2629                 }
2630         }
2631
2632 #ifdef TETRIS
2633         if(self.impulse == 100)
2634                 ImpulseCommands();
2635         if (!TetrisPostFrame())
2636         {
2637 #endif
2638
2639         CheatFrame();
2640
2641         //CheckPlayerJump();
2642
2643         if(self.classname == "player") {
2644                 CheckRules_Player();
2645                 UpdateChatBubble();
2646                 if (self.impulse)
2647                         ImpulseCommands();
2648                 if (intermission_running)
2649                         return;         // intermission or finale
2650                 GetPressedKeys();
2651         }
2652
2653 #ifdef TETRIS
2654         }
2655 #endif
2656
2657         /*
2658         float i;
2659         for(i = 0; i < 1000; ++i)
2660         {
2661                 vector end;
2662                 end = self.origin + '0 0 1024' + 512 * randomvec();
2663                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2664                 if(trace_fraction < 1)
2665                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2666                 {
2667                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2668                         break;
2669                 }
2670         }
2671         */
2672
2673         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2674
2675         if(self.waypointsprite_attachedforcarrier)
2676                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2677
2678         playerdemo_write();
2679
2680         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2681         {
2682                 if not(self.stored_netname)
2683                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2684                 if(self.stored_netname != self.netname)
2685                 {
2686                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2687                         strunzone(self.stored_netname);
2688                         self.stored_netname = strzone(self.netname);
2689                 }
2690         }
2691
2692         /*
2693         if(g_race)
2694                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2695         */
2696
2697         CSQCMODEL_AUTOUPDATE();
2698 }