qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         msg_entity = e;
  17         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  18         WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ONE, snd);
  20 }
  21
  22 float ClientData_Send(entity to, float sf)
  23 {
  24         if(to != self.owner)
  25         {
  26                 error("wtf");
  27                 return FALSE;
  28         }
  29
  30         entity e;
  31
  32         e = to;
  33         if(to.classname == "spectator")
  34                 e = to.enemy;
  35
  36         sf = 0;
  37
  38         if(e.race_completed)
  39                 sf |= 1; // forced scoreboard
  40         if(to.spectatee_status)
  41                 sf |= 2; // spectator ent number follows
  42         if(e.zoomstate)
  43                 sf |= 4; // zoomed
  44         if(e.porto_v_angle_held)
  45                 sf |= 8; // angles held
  46
  47         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  48         WriteByte(MSG_ENTITY, sf);
  49
  50         if(sf & 2)
  51                 WriteByte(MSG_ENTITY, to.spectatee_status);
  52
  53         if(sf & 8)
  54         {
  55                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  56                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  57         }
  58
  59         return TRUE;
  60 }
  61
  62 void ClientData_Attach()
  63 {
  64         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  65         self.clientdata.drawonlytoclient = self;
  66         self.clientdata.owner = self;
  67 }
  68
  69 void ClientData_Detach()
  70 {
  71         remove(self.clientdata);
  72         self.clientdata = world;
  73 }
  74
  75 void ClientData_Touch(entity e)
  76 {
  77         e.clientdata.SendFlags = 1;
  78
  79         // make it spectatable
  80         entity e2;
  81         FOR_EACH_REALCLIENT(e2)
  82         {
  83                 if(e2 != e)
  84                         if(e2.classname == "spectator")
  85                                 if(e2.enemy == e)
  86                                         e2.clientdata.SendFlags = 1;
  87         }
  88 }
  89
  90
  91 .vector spawnpoint_score;
  92 .string netname_previous;
  93
  94 void spawnfunc_info_player_survivor (void)
  95 {
  96         spawnfunc_info_player_deathmatch();
  97 }
  98
  99 void spawnfunc_info_player_start (void)
 100 {
 101         spawnfunc_info_player_deathmatch();
 102 }
 103
 104 void spawnfunc_info_player_deathmatch (void)
 105 {
 106         self.classname = "info_player_deathmatch";
 107         relocate_spawnpoint();
 108 }
 109
 110 void spawnpoint_use()
 111 {
 112         if(teams_matter)
 113         if(have_team_spawns > 0)
 114         {
 115                 self.team = activator.team;
 116                 some_spawn_has_been_used = 1;
 117         }
 118 };
 119
 120 // Returns:
 121 //   _x: prio (-1 if unusable)
 122 //   _y: weight
 123 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 124 {
 125         float shortest, thisdist;
 126         float prio;
 127         entity player;
 128
 129         prio = 0;
 130
 131         // filter out spots for the wrong team
 132         if(teamcheck)
 133         if(spot.team != teamcheck)
 134                 return '-1 0 0';
 135
 136         if(race_spawns)
 137                 if(spot.target == "")
 138                         return '-1 0 0';
 139
 140         if(clienttype(self) == CLIENTTYPE_REAL)
 141         {
 142                 if(spot.restriction == 1)
 143                         return '-1 0 0';
 144         }
 145         else
 146         {
 147                 if(spot.restriction == 2)
 148                         return '-1 0 0';
 149         }
 150
 151         // filter out spots for assault
 152         if(spot.target != "") {
 153                 local entity ent;
 154                 float good, found;
 155                 ent = find(world, targetname, spot.target);
 156
 157                 while(ent) {
 158                         if(ent.classname == "target_objective")
 159                         {
 160                                 found = 1;
 161                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 162                                         return '-1 0 0';
 163                                 good = 1;
 164                         }
 165                         else if(ent.classname == "trigger_race_checkpoint")
 166                         {
 167                                 found = 1;
 168                                 if(!anypoint) // spectators may spawn everywhere
 169
 170                                 {
 171                                         if(g_race_qualifying)
 172                                         {
 173                                                 // spawn at first
 174                                                 if(ent.race_checkpoint != 0)
 175                                                         return '-1 0 0';
 176                                                 if(spot.race_place != race_lowest_place_spawn)
 177                                                         return '-1 0 0';
 178                                         }
 179                                         else
 180                                         {
 181                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 182                                                         return '-1 0 0';
 183                                                 // try reusing the previous spawn
 184                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 185                                                         prio += 1;
 186                                                 if(ent.race_checkpoint == 0)
 187                                                 {
 188                                                         float pl;
 189                                                         pl = self.race_place;
 190                                                         if(pl > race_highest_place_spawn)
 191                                                                 pl = 0;
 192                                                         if(pl == 0 && !self.race_started)
 193                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 194                                                         if(spot.race_place != pl)
 195                                                                 return '-1 0 0';
 196                                                 }
 197                                         }
 198                                 }
 199                                 good = 1;
 200                         }
 201                         ent = find(ent, targetname, spot.target);
 202                 }
 203
 204                 if(found && !good)
 205                         return '-1 0 0';
 206         }
 207
 208         player = playerlist;
 209         shortest = vlen(world.maxs - world.mins);
 210         for(player = playerlist; player; player = player.chain)
 211                 if (player != self)
 212                 {
 213                         thisdist = vlen(player.origin - spot.origin);
 214                         if (thisdist < shortest)
 215                                 shortest = thisdist;
 216                 }
 217         return prio * '1 0 0' + shortest * '0 1 0';
 218 }
 219
 220 float spawn_allbad;
 221 float spawn_allgood;
 222 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 223 {
 224         local entity spot, spotlist, spotlistend;
 225         spawn_allgood = TRUE;
 226         spawn_allbad = TRUE;
 227
 228         spotlist = world;
 229         spotlistend = world;
 230
 231         for(spot = firstspot; spot; spot = spot.chain)
 232         {
 233                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 234
 235                 if(cvar("spawn_debugview"))
 236                 {
 237                         setmodel(spot, "models/runematch/rune.mdl");
 238                         if(spot.spawnpoint_score_y < mindist)
 239                         {
 240                                 spot.colormod = '1 0 0';
 241                                 spot.scale = 1;
 242                         }
 243                         else
 244                         {
 245                                 spot.colormod = '0 1 0';
 246                                 spot.scale = spot.spawnpoint_score_y / mindist;
 247                         }
 248                 }
 249
 250                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 251                 {
 252                         if(spot.spawnpoint_score_y < mindist)
 253                         {
 254                                 // too short distance
 255                                 spawn_allgood = FALSE;
 256                         }
 257                         else
 258                         {
 259                                 // perfect
 260                                 spawn_allbad = FALSE;
 261
 262                                 if(spotlistend)
 263                                         spotlistend.chain = spot;
 264                                 spotlistend = spot;
 265                                 if(!spotlist)
 266                                         spotlist = spot;
 267
 268                                 /*
 269                                 if(teamcheck)
 270                                 if(spot.team != teamcheck)
 271                                         error("invalid spawn added");
 272
 273                                 print("added ", etos(spot), "\n");
 274                                 */
 275                         }
 276                 }
 277         }
 278         if(spotlistend)
 279                 spotlistend.chain = world;
 280
 281         /*
 282                 entity e;
 283                 if(teamcheck)
 284                         for(e = spotlist; e; e = e.chain)
 285                         {
 286                                 print("seen ", etos(e), "\n");
 287                                 if(e.team != teamcheck)
 288                                         error("invalid spawn found");
 289                         }
 290         */
 291
 292         return spotlist;
 293 }
 294
 295 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 296 {
 297         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 298         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 299         local entity spot;
 300
 301         RandomSelection_Init();
 302         for(spot = firstspot; spot; spot = spot.chain)
 303                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 304
 305         return RandomSelection_chosen_ent;
 306 }
 307
 308 /*
 309 =============
 310 SelectSpawnPoint
 311
 312 Finds a point to respawn
 313 =============
 314 */
 315 entity SelectSpawnPoint (float anypoint)
 316 {
 317         local float teamcheck;
 318         local entity firstspot_new;
 319         local entity spot, firstspot, playerlist;
 320
 321         spot = find (world, classname, "testplayerstart");
 322         if (spot)
 323                 return spot;
 324
 325         teamcheck = 0;
 326
 327         if(!anypoint && have_team_spawns > 0)
 328                 teamcheck = self.team;
 329
 330         // get the list of players
 331         playerlist = findchain(classname, "player");
 332         // get the entire list of spots
 333         firstspot = findchain(classname, "info_player_deathmatch");
 334         // filter out the bad ones
 335         // (note this returns the original list if none survived)
 336         if(anypoint)
 337         {
 338                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 339         }
 340         else
 341         {
 342                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 343                 if(!firstspot_new)
 344                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 345                 firstspot = firstspot_new;
 346
 347                 // there is 50/50 chance of choosing a random spot or the furthest spot
 348                 // (this means that roughly every other spawn will be furthest, so you
 349                 // usually won't get fragged at spawn twice in a row)
 350                 if (arena_roundbased && !g_ca)
 351                 {
 352                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 353                         if(firstspot_new)
 354                                 firstspot = firstspot_new;
 355                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 356                 }
 357                 else if (random() > cvar("g_spawn_furthest"))
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 else
 360                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 361         }
 362
 363         if(cvar("spawn_debugview"))
 364         {
 365                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 366
 367                 entity e;
 368                 if(teamcheck)
 369                         for(e = firstspot; e; e = e.chain)
 370                                 if(e.team != teamcheck)
 371                                         error("invalid spawn found");
 372         }
 373
 374         if (!spot)
 375         {
 376                 if(cvar("spawn_debug"))
 377                         GotoNextMap();
 378                 else
 379                 {
 380                         if(some_spawn_has_been_used)
 381                                 return world; // team can't spawn any more, because of actions of other team
 382                         else
 383                                 error("Cannot find a spawn point - please fix the map!");
 384                 }
 385         }
 386
 387         return spot;
 388 }
 389
 390 /*
 391 =============
 392 CheckPlayerModel
 393
 394 Checks if the argument string can be a valid playermodel.
 395 Returns a valid one in doubt.
 396 =============
 397 */
 398 string FallbackPlayerModel = "models/player/marine.zym";
 399 string CheckPlayerModel(string plyermodel) {
 400         if(strlen(plyermodel) < 4)
 401                 return FallbackPlayerModel;
 402         if( substring(plyermodel,0,14) != "models/player/")
 403                 return FallbackPlayerModel;
 404         else if(cvar("sv_servermodelsonly"))
 405         {
 406                 if(substring(plyermodel,-4,4) != ".zym")
 407                 if(substring(plyermodel,-4,4) != ".dpm")
 408                 if(substring(plyermodel,-4,4) != ".md3")
 409                 if(substring(plyermodel,-4,4) != ".psk")
 410                         return FallbackPlayerModel;
 411                 // forbid the LOD models
 412                 if(substring(plyermodel, -9,5) == "_lod1")
 413                         return FallbackPlayerModel;
 414                 if(substring(plyermodel, -9,5) == "_lod2")
 415                         return FallbackPlayerModel;
 416                 if(plyermodel != strtolower(plyermodel))
 417                         return FallbackPlayerModel;
 418                 if(!fexists(plyermodel))
 419                         return FallbackPlayerModel;
 420         }
 421         return plyermodel;
 422 }
 423
 424 /*
 425 =============
 426 Client_customizeentityforclient
 427
 428 LOD reduction
 429 =============
 430 */
 431 void Client_uncustomizeentityforclient()
 432 {
 433         if(self.modelindex == 0) // no need to uncustomize then
 434                 return;
 435         self.modelindex = self.modelindex_lod0;
 436         self.skin = self.skinindex;
 437 }
 438
 439 float Client_customizeentityforclient()
 440 {
 441         entity modelsource;
 442
 443         if(self.modelindex == 0)
 444                 return TRUE;
 445
 446         // forcemodel stuff
 447
 448 #ifdef PROFILING
 449         float t0;
 450         t0 = gettime(GETTIME_HIRES); // reference
 451 #endif
 452
 453         modelsource = self;
 454
 455 #ifdef ALLOW_FORCEMODELS
 456         if(other.cvar_cl_forceplayermodelsfromxonotic)
 457                 if not(self.modelindex_lod0_from_xonotic)
 458                         modelsource = other;
 459         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 460                 modelsource = other;
 461 #endif
 462
 463         self.skin = modelsource.skinindex;
 464
 465 #if 0
 466         if(modelsource == self)
 467                 self.skin = modelsource.skinindex;
 468         else
 469                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 470 #endif
 471
 472         // self: me
 473         // other: the player viewing me
 474         float distance;
 475         float f;
 476
 477         if(other.cvar_cl_playerdetailreduction <= 0)
 478         {
 479                 if(other.cvar_cl_playerdetailreduction <= -2)
 480                         self.modelindex = modelsource.modelindex_lod2;
 481                 else if(other.cvar_cl_playerdetailreduction <= -1)
 482                         self.modelindex = modelsource.modelindex_lod1;
 483                 else
 484                         self.modelindex = modelsource.modelindex_lod0;
 485         }
 486         else
 487         {
 488                 distance = vlen(self.origin - other.origin);
 489                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 490                 if(f > sv_loddistance2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(f > sv_loddistance1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497
 498 #ifdef PROFILING
 499         float t1;
 500         t1 = gettime(GETTIME_HIRES); // reference
 501         client_cefc_accumulator += (t1 - t0);
 502 #endif
 503
 504         return TRUE;
 505 }
 506
 507 void UpdatePlayerSounds();
 508 void setmodel_lod(entity e, string modelname)
 509 {
 510         string s;
 511
 512         if(sv_loddistance1)
 513         {
 514                 // FIXME: this only supports 3-letter extensions
 515                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 516                 if(fexists(s))
 517                 {
 518                         setmodel(e, s); // players have high precision
 519                         self.modelindex_lod1 = self.modelindex;
 520                 }
 521                 else
 522                         self.modelindex_lod1 = -1;
 523
 524                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 525                 if(fexists(s))
 526                 {
 527                         setmodel(e, s); // players have high precision
 528                         self.modelindex_lod2 = self.modelindex;
 529                 }
 530                 else
 531                         self.modelindex_lod2 = -1;
 532
 533                 precache_model(modelname);
 534                 setmodel(e, modelname); // players have high precision
 535                 self.modelindex_lod0 = self.modelindex;
 536
 537                 if(self.modelindex_lod1 < 0)
 538                         self.modelindex_lod1 = self.modelindex;
 539
 540                 if(self.modelindex_lod2 < 0)
 541                         self.modelindex_lod2 = self.modelindex;
 542         }
 543         else
 544         {
 545                 precache_model(modelname);
 546                 setmodel(e, modelname); // players have high precision
 547                 self.modelindex_lod0 = self.modelindex;
 548                         // save it for possible player model forcing
 549         }
 550
 551         s = whichpack(self.model);
 552         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 553
 554         player_setupanimsformodel();
 555         UpdatePlayerSounds();
 556 }
 557
 558 /*
 559 =============
 560 PutObserverInServer
 561
 562 putting a client as observer in the server
 563 =============
 564 */
 565 void FixPlayermodel();
 566 void PutObserverInServer (void)
 567 {
 568         entity  spot;
 569
 570         race_PreSpawnObserver();
 571
 572         spot = SelectSpawnPoint (TRUE);
 573         if(!spot)
 574                 error("No spawnpoints for observers?!?\n");
 575         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 576
 577         if(clienttype(self) == CLIENTTYPE_REAL)
 578         {
 579                 msg_entity = self;
 580                 WriteByte(MSG_ONE, SVC_SETVIEW);
 581                 WriteEntity(MSG_ONE, self);
 582         }
 583
 584         DropAllRunes(self);
 585
 586         Portal_ClearAll(self);
 587
 588         if(self.flagcarried)
 589                 DropFlag(self.flagcarried, world, world);
 590
 591         if(self.ballcarried)
 592                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 593
 594         WaypointSprite_PlayerDead();
 595
 596         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 597                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 598
 599         if(self.killcount != -666) {
 600                 if(g_lms) {
 601                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 602                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 603                         else
 604                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 605                 } else
 606                         bprint ("^4", self.netname, "^4 is spectating now\n");
 607
 608                 if(self.just_joined == FALSE) {
 609                         LogTeamchange(self.playerid, -1, 4);
 610                 } else
 611                         self.just_joined = FALSE;
 612         }
 613
 614         PlayerScore_Clear(self); // clear scores when needed
 615
 616         self.spectatortime = time;
 617
 618         self.classname = "observer";
 619         self.iscreature = FALSE;
 620         self.health = -666;
 621         self.takedamage = DAMAGE_NO;
 622         self.solid = SOLID_NOT;
 623         self.movetype = MOVETYPE_NOCLIP;
 624         self.flags = FL_CLIENT | FL_NOTARGET;
 625         self.armorvalue = 666;
 626         self.effects = 0;
 627         self.armorvalue = cvar("g_balance_armor_start");
 628         self.pauserotarmor_finished = 0;
 629         self.pauserothealth_finished = 0;
 630         self.pauseregen_finished = 0;
 631         self.damageforcescale = 0;
 632         self.death_time = 0;
 633         self.dead_frame = 0;
 634         self.alpha = 0;
 635         self.scale = 0;
 636         self.fade_time = 0;
 637         self.pain_frame = 0;
 638         self.pain_finished = 0;
 639         self.strength_finished = 0;
 640         self.invincible_finished = 0;
 641         self.pushltime = 0;
 642         self.think = SUB_Null;
 643         self.nextthink = 0;
 644         self.hook_time = 0;
 645         self.runes = 0;
 646         self.deadflag = DEAD_NO;
 647         self.angles = spot.angles;
 648         self.angles_z = 0;
 649         self.fixangle = TRUE;
 650         self.crouch = FALSE;
 651
 652         self.view_ofs = PL_VIEW_OFS;
 653         setorigin (self, spot.origin);
 654         setsize (self, '0 0 0', '0 0 0');
 655         self.prevorigin = self.origin;
 656         self.items = 0;
 657         self.weapons = 0;
 658         self.model = "";
 659         FixPlayermodel();
 660         self.model = "";
 661         self.modelindex = 0;
 662         self.weapon = 0;
 663         self.weaponmodel = "";
 664         self.weaponentity = world;
 665         self.exteriorweaponentity = world;
 666         self.killcount = -666;
 667         self.velocity = '0 0 0';
 668         self.avelocity = '0 0 0';
 669         self.punchangle = '0 0 0';
 670         self.punchvector = '0 0 0';
 671         self.oldvelocity = self.velocity;
 672         self.fire_endtime = -1;
 673
 674         if(sv_loddistance1)
 675                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 676
 677         if(g_arena)
 678         {
 679                 if(self.version_mismatch)
 680                 {
 681                         Spawnqueue_Unmark(self);
 682                         Spawnqueue_Remove(self);
 683                 }
 684                 else
 685                 {
 686                         Spawnqueue_Insert(self);
 687                 }
 688         }
 689         else if(g_lms)
 690         {
 691                 // Only if the player cannot play at all
 692                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 693                         self.frags = FRAGS_SPECTATOR;
 694                 else
 695                         self.frags = FRAGS_LMS_LOSER;
 696         }
 697         else
 698                 self.frags = FRAGS_SPECTATOR;
 699
 700         MUTATOR_CALLHOOK(MakePlayerObserver);
 701 }
 702
 703 float RestrictSkin(float s)
 704 {
 705         if(!teams_matter)
 706                 return s;
 707         if(s == 6)
 708                 return 6;
 709         return mod(s, 3);
 710 }
 711
 712 void FixPlayermodel()
 713 {
 714         local string defaultmodel;
 715         local float defaultskin, chmdl, oldskin;
 716         local vector m1, m2;
 717
 718         defaultmodel = "";
 719
 720         if(cvar("sv_defaultcharacter") == 1) {
 721                 defaultskin = 0;
 722
 723                 if(teams_matter)
 724                 {
 725                         string s;
 726                         s = Team_ColorNameLowerCase(self.team);
 727                         if(s != "neutral")
 728                         {
 729                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 730                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 731                         }
 732                 }
 733
 734                 if(defaultmodel == "")
 735                 {
 736                         defaultmodel = cvar_string("sv_defaultplayermodel");
 737                         defaultskin = cvar("sv_defaultplayerskin");
 738                 }
 739         }
 740
 741         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 742         {
 743                 if(self.model != "")
 744                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 745                 self.model = ""; // force the != checks to return true
 746         }
 747
 748         if(defaultmodel != "")
 749         {
 750                 if (defaultmodel != self.model)
 751                 {
 752                         m1 = self.mins;
 753                         m2 = self.maxs;
 754                         setmodel_lod (self, defaultmodel);
 755                         setsize (self, m1, m2);
 756                         chmdl = TRUE;
 757                 }
 758
 759                 oldskin = self.skinindex;
 760                 self.skinindex = defaultskin;
 761         } else {
 762                 if (self.playermodel != self.model || self.playermodel == "")
 763                 {
 764                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 765                         m1 = self.mins;
 766                         m2 = self.maxs;
 767                         setmodel_lod (self, self.playermodel);
 768                         setsize (self, m1, m2);
 769                         chmdl = TRUE;
 770                 }
 771
 772                 oldskin = self.skinindex;
 773                 self.skinindex = RestrictSkin(stof(self.playerskin));
 774         }
 775
 776         if(chmdl || oldskin != self.skinindex)
 777                 self.species = player_getspecies(); // model or skin has changed
 778
 779         if(!teams_matter)
 780                 if(strlen(cvar_string("sv_defaultplayercolors")))
 781                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 782                                 setcolor(self, cvar("sv_defaultplayercolors"));
 783 }
 784
 785 void PlayerTouchExplode(entity p1, entity p2)
 786 {
 787         vector org;
 788         org = (p1.origin + p2.origin) * 0.5;
 789         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 790
 791         te_explosion(org);
 792
 793         entity e;
 794         e = spawn();
 795         setorigin(e, org);
 796         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 797         remove(e);
 798 }
 799
 800 /*
 801 =============
 802 PutClientInServer
 803
 804 Called when a client spawns in the server
 805 =============
 806 */
 807 //void() ctf_playerchanged;
 808 void PutClientInServer (void)
 809 {
 810         if(clienttype(self) == CLIENTTYPE_BOT)
 811         {
 812                 self.classname = "player";
 813         }
 814         else if(clienttype(self) == CLIENTTYPE_REAL)
 815         {
 816                 msg_entity = self;
 817                 WriteByte(MSG_ONE, SVC_SETVIEW);
 818                 WriteEntity(MSG_ONE, self);
 819         }
 820
 821         // player is dead and becomes observer
 822         // FIXME fix LMS scoring for new system
 823         if(g_lms)
 824         {
 825                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 826                         self.classname = "observer";
 827         }
 828
 829         if(g_arena || (g_ca && !allowed_to_spawn))
 830         if(!self.spawned)
 831                 self.classname = "observer";
 832
 833         if(gameover)
 834                 self.classname = "observer";
 835
 836         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 837                 entity spot, oldself;
 838                 float j;
 839
 840                 if(self.team < 0)
 841                         JoinBestTeam(self, FALSE, TRUE);
 842
 843                 race_PreSpawn();
 844
 845                 spot = SelectSpawnPoint (FALSE);
 846                 if(!spot)
 847                 {
 848                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 849                         return; // spawn failed
 850                 }
 851
 852                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 853
 854                 self.classname = "player";
 855                 self.wasplayer = TRUE;
 856                 self.iscreature = TRUE;
 857                 self.movetype = MOVETYPE_WALK;
 858                 self.solid = SOLID_SLIDEBOX;
 859                 if(cvar("g_playerclip_collisions"))
 860                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 861                 else
 862                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 863                 self.frags = FRAGS_PLAYER;
 864                 if(independent_players)
 865                         MAKE_INDEPENDENT_PLAYER(self);
 866                 self.flags = FL_CLIENT;
 867                 self.takedamage = DAMAGE_AIM;
 868                 if(g_minstagib)
 869                         self.effects = EF_FULLBRIGHT;
 870                 else
 871                         self.effects = 0;
 872                 self.air_finished = time + 12;
 873                 self.dmg = 2;
 874
 875                 if(inWarmupStage)
 876                 {
 877                         self.ammo_shells = warmup_start_ammo_shells;
 878                         self.ammo_nails = warmup_start_ammo_nails;
 879                         self.ammo_rockets = warmup_start_ammo_rockets;
 880                         self.ammo_cells = warmup_start_ammo_cells;
 881                         self.ammo_fuel = warmup_start_ammo_fuel;
 882                         self.health = warmup_start_health;
 883                         self.armorvalue = warmup_start_armorvalue;
 884                         self.weapons = warmup_start_weapons;
 885                 }
 886                 else
 887                 {
 888                         self.ammo_shells = start_ammo_shells;
 889                         self.ammo_nails = start_ammo_nails;
 890                         self.ammo_rockets = start_ammo_rockets;
 891                         self.ammo_cells = start_ammo_cells;
 892                         self.ammo_fuel = start_ammo_fuel;
 893                         self.health = start_health;
 894                         self.armorvalue = start_armorvalue;
 895                         self.weapons = start_weapons;
 896                 }
 897
 898                 if(g_weaponarena_random)
 899                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 900
 901                 self.items = start_items;
 902                 self.jump_interval = time;
 903
 904                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 905                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 906                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 907                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 908                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 909                 //extend the pause of rotting if client was reset at the beginning of the countdown
 910                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 911                         self.spawnshieldtime += game_starttime - time;
 912                         self.pauserotarmor_finished += game_starttime - time;
 913                         self.pauserothealth_finished += game_starttime - time;
 914                         self.pauseregen_finished += game_starttime - time;
 915                 }
 916                 self.damageforcescale = 2;
 917                 self.death_time = 0;
 918                 self.dead_frame = 0;
 919                 self.alpha = 0;
 920                 self.scale = 0;
 921                 self.fade_time = 0;
 922                 self.pain_frame = 0;
 923                 self.pain_finished = 0;
 924                 self.strength_finished = 0;
 925                 self.invincible_finished = 0;
 926                 self.pushltime = 0;
 927                 // players have no think function
 928                 self.think = SUB_Null;
 929                 self.nextthink = 0;
 930                 self.hook_time = 0;
 931                 self.dmg_team = 0;
 932
 933                 self.metertime = 0;
 934
 935                 self.runes = 0;
 936
 937                 self.deadflag = DEAD_NO;
 938
 939                 self.angles = spot.angles;
 940
 941                 self.angles_z = 0; // never spawn tilted even if the spot says to
 942                 self.fixangle = TRUE; // turn this way immediately
 943                 self.velocity = '0 0 0';
 944                 self.avelocity = '0 0 0';
 945                 self.punchangle = '0 0 0';
 946                 self.punchvector = '0 0 0';
 947                 self.oldvelocity = self.velocity;
 948                 self.fire_endtime = -1;
 949
 950                 msg_entity = self;
 951                 WRITESPECTATABLE_MSG_ONE({
 952                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 953                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 954                 });
 955
 956                 if(sv_loddistance1)
 957                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 958
 959                 self.model = "";
 960                 FixPlayermodel();
 961
 962                 self.crouch = FALSE;
 963                 self.view_ofs = PL_VIEW_OFS;
 964                 setsize (self, PL_MIN, PL_MAX);
 965                 self.spawnorigin = spot.origin;
 966                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 967                 // don't reset back to last position, even if new position is stuck in solid
 968                 self.oldorigin = self.origin;
 969                 self.prevorigin = self.origin;
 970                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 971
 972                 if(g_arena)
 973                 {
 974                         Spawnqueue_Remove(self);
 975                         Spawnqueue_Mark(self);
 976                 }
 977
 978                 else if(g_ca)
 979                         self.caplayer = 1;
 980
 981                 self.event_damage = PlayerDamage;
 982
 983                 self.bot_attack = TRUE;
 984
 985                 self.statdraintime = time + 5;
 986                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 987
 988                 if(self.killcount == -666) {
 989                         PlayerScore_Clear(self);
 990                         self.killcount = 0;
 991                 }
 992
 993                 self.cnt = WEP_LASER;
 994
 995                 CL_SpawnWeaponentity();
 996                 self.alpha = default_player_alpha;
 997                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 998                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 999
1000                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1001                 self.lms_traveled_distance = 0;
1002                 self.speedrunning = FALSE;
1003
1004                 race_PostSpawn(spot);
1005
1006                 if(cvar("spawn_debug"))
1007                 {
1008                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1009                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1010                 }
1011
1012                 //stuffcmd(self, "chase_active 0");
1013                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1014
1015                 if (cvar("g_spawnsound"))
1016                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1017
1018                 if(g_assault) {
1019                         if(self.team == assault_attacker_team)
1020                                 centerprint(self, "You are attacking!");
1021                         else
1022                                 centerprint(self, "You are defending!");
1023                 }
1024
1025                 target_voicescript_clear(self);
1026
1027                 // reset fields the weapons may use
1028                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1029                         weapon_action(j, WR_RESETPLAYER);
1030
1031                 oldself = self;
1032                 self = spot;
1033                         activator = oldself;
1034                                 SUB_UseTargets();
1035                         activator = world;
1036                 self = oldself;
1037
1038                 MUTATOR_CALLHOOK(PlayerSpawn);
1039
1040                 self.switchweapon = w_getbestweapon(self);
1041                 self.cnt = self.switchweapon;
1042                 self.weapon = 0;
1043         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1044                 PutObserverInServer ();
1045         }
1046
1047         //if(g_ctf)
1048         //      ctf_playerchanged();
1049 }
1050
1051 float ClientInit_SendEntity(entity to, float sf)
1052 {
1053         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1054         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1055         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1056         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1057         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1058
1059         if(sv_foginterval && world.fog != "")
1060                 WriteString(MSG_ENTITY, world.fog);
1061         else
1062                 WriteString(MSG_ENTITY, "");
1063         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1064         WriteByte(MSG_ENTITY, cvar("g_balance_weaponswitchdelay") * 255.0);
1065         return TRUE;
1066 }
1067
1068 void ClientInit_Spawn()
1069 {
1070         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1071 }
1072
1073 /*
1074 =============
1075 SetNewParms
1076 =============
1077 */
1078 void SetNewParms (void)
1079 {
1080         // initialize parms for a new player
1081         parm1 = -(86400 * 366);
1082 }
1083
1084 /*
1085 =============
1086 SetChangeParms
1087 =============
1088 */
1089 void SetChangeParms (void)
1090 {
1091         // save parms for level change
1092         parm1 = self.parm_idlesince - time;
1093 }
1094
1095 /*
1096 =============
1097 DecodeLevelParms
1098 =============
1099 */
1100 void DecodeLevelParms (void)
1101 {
1102         // load parms
1103         self.parm_idlesince = parm1;
1104         if(self.parm_idlesince == -(86400 * 366))
1105                 self.parm_idlesince = time;
1106
1107         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1108         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1109 }
1110
1111 /*
1112 =============
1113 ClientKill
1114
1115 Called when a client types 'kill' in the console
1116 =============
1117 */
1118
1119 void ClientKill_Now_TeamChange()
1120 {
1121         if(self.killindicator_teamchange == -1)
1122         {
1123                 self.team = -1;
1124                 JoinBestTeam( self, FALSE, FALSE );
1125         }
1126         else
1127                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1128 }
1129
1130 void ClientKill_Now()
1131 {
1132         if(self.killindicator_teamchange)
1133                 ClientKill_Now_TeamChange();
1134
1135         // in any case:
1136         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1137
1138         if(self.killindicator)
1139         {
1140                 dprint("Cleaned up after a leaked kill indicator.\n");
1141                 remove(self.killindicator);
1142                 self.killindicator = world;
1143         }
1144 }
1145 void KillIndicator_Think()
1146 {
1147         if (!self.owner.modelindex)
1148         {
1149                 self.owner.killindicator = world;
1150                 remove(self);
1151                 return;
1152         }
1153
1154         if(self.cnt <= 0)
1155         {
1156                 self = self.owner;
1157                 ClientKill_Now(); // no oldself needed
1158                 return;
1159         }
1160         else
1161         {
1162                 if(self.cnt <= 10)
1163                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1164                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1165                 {
1166                         if(self.cnt <= 10)
1167                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1168                         if(self.owner.killindicator_teamchange)
1169                         {
1170                                 if(self.owner.killindicator_teamchange == -1)
1171                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1172                                 else
1173                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1174                         }
1175                         else
1176                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1177                 }
1178                 self.nextthink = time + 1;
1179                 self.cnt -= 1;
1180         }
1181 }
1182
1183 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1184 {
1185         float killtime;
1186         entity e;
1187         killtime = cvar("g_balance_kill_delay");
1188
1189         if(g_race_qualifying)
1190                 killtime = 0;
1191
1192         self.killindicator_teamchange = targetteam;
1193
1194         if(!self.killindicator)
1195         {
1196                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1197                 {
1198                         ClientKill_Now();
1199                 }
1200                 else
1201                 {
1202                         self.killindicator = spawn();
1203                         self.killindicator.owner = self;
1204                         self.killindicator.scale = 0.5;
1205                         setattachment(self.killindicator, self, "");
1206                         setorigin(self.killindicator, '0 0 52');
1207                         self.killindicator.think = KillIndicator_Think;
1208                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1209                         self.killindicator.cnt = ceil(killtime);
1210                         self.killindicator.count = bound(0, ceil(killtime), 10);
1211                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1212
1213                         for(e = world; (e = find(e, classname, "body")) != world; )
1214                         {
1215                                 if(e.enemy != self)
1216                                         continue;
1217                                 e.killindicator = spawn();
1218                                 e.killindicator.owner = e;
1219                                 e.killindicator.scale = 0.5;
1220                                 setattachment(e.killindicator, e, "");
1221                                 setorigin(e.killindicator, '0 0 52');
1222                                 e.killindicator.think = KillIndicator_Think;
1223                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1224                                 e.killindicator.cnt = ceil(killtime);
1225                         }
1226                         self.lip = 0;
1227                 }
1228         }
1229         if(self.killindicator)
1230         {
1231                 if(targetteam)
1232                         self.killindicator.colormod = TeamColor(targetteam);
1233                 else
1234                         self.killindicator.colormod = '0 0 0';
1235         }
1236 }
1237
1238 void ClientKill (void)
1239 {
1240         ClientKill_TeamChange(0);
1241 }
1242
1243 void DoTeamChange(float destteam)
1244 {
1245         float t, c0;
1246         if(!teams_matter)
1247         {
1248                 if(destteam >= 0)
1249                         SetPlayerColors(self, destteam);
1250                 return;
1251         }
1252         if(self.classname == "player")
1253         if(destteam == -1)
1254         {
1255                 CheckAllowedTeams(self);
1256                 t = FindSmallestTeam(self, TRUE);
1257                 switch(self.team)
1258                 {
1259                         case COLOR_TEAM1: c0 = c1; break;
1260                         case COLOR_TEAM2: c0 = c2; break;
1261                         case COLOR_TEAM3: c0 = c3; break;
1262                         case COLOR_TEAM4: c0 = c4; break;
1263                         default:          c0 = 999;
1264                 }
1265                 switch(t)
1266                 {
1267                         case 1:
1268                                 if(c0 > c1)
1269                                         destteam = COLOR_TEAM1;
1270                                 break;
1271                         case 2:
1272                                 if(c0 > c2)
1273                                         destteam = COLOR_TEAM2;
1274                                 break;
1275                         case 3:
1276                                 if(c0 > c3)
1277                                         destteam = COLOR_TEAM3;
1278                                 break;
1279                         case 4:
1280                                 if(c0 > c4)
1281                                         destteam = COLOR_TEAM4;
1282                                 break;
1283                 }
1284                 if(destteam == -1)
1285                         return;
1286         }
1287         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1288                 return;
1289         ClientKill_TeamChange(destteam);
1290 }
1291
1292 void FixClientCvars(entity e)
1293 {
1294         // send prediction settings to the client
1295         stuffcmd(e, "\nin_bindmap 0 0\n");
1296         if(g_race || g_cts)
1297                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1298         if(cvar("g_antilag") == 3) // client side hitscan
1299                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1300                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1301         /*
1302          * we no longer need to stuff this. Remove this comment block if you feel
1303          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1304         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1305         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1306         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1307         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1308         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1309         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1310         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1311         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1312         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1313         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1314         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1315         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1316         stuffcmd(e, "cl_movement_edgefriction 1\n");
1317          */
1318 }
1319
1320 /*
1321 =============
1322 ClientConnect
1323
1324 Called when a client connects to the server
1325 =============
1326 */
1327 //void ctf_clientconnect();
1328 string ColoredTeamName(float t);
1329 void DecodeLevelParms (void);
1330 //void dom_player_join_team(entity pl);
1331 #ifdef UID
1332 .float uid_kicktime;
1333 .string uid;
1334 #endif
1335 void ClientConnect (void)
1336 {
1337         float t;
1338
1339         if(self.flags & FL_CLIENT)
1340         {
1341                 print("Warning: ClientConnect, but already connected!\n");
1342                 return;
1343         }
1344
1345         if(Ban_MaybeEnforceBan(self))
1346                 return;
1347
1348         DecodeLevelParms();
1349
1350         self.classname = "player_joining";
1351
1352         self.flags = FL_CLIENT;
1353         self.version_nagtime = time + 10 + random() * 10;
1354
1355         if(player_count<0)
1356         {
1357                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1358                 player_count = 0;
1359         }
1360
1361         PlayerScore_Attach(self);
1362         ClientData_Attach();
1363
1364         bot_clientconnect();
1365
1366         playerdemo_init();
1367
1368         anticheat_init();
1369
1370         race_PreSpawnObserver();
1371
1372         //if(g_domination)
1373         //      dom_player_join_team(self);
1374
1375         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1376
1377         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1378                 self.classname = "observer";
1379         } else {
1380                 if(teams_matter)
1381                 {
1382                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1383                         {
1384                                 self.classname = "player";
1385                                 campaign_bots_may_start = 1;
1386                         }
1387                         else
1388                         {
1389                                 self.classname = "observer"; // do it anyway
1390                         }
1391                 }
1392                 else
1393                 {
1394                         self.classname = "player";
1395                         campaign_bots_may_start = 1;
1396                 }
1397         }
1398
1399         self.playerid = (playerid_last = playerid_last + 1);
1400
1401         if(cvar("sv_eventlog"))
1402                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1403
1404         LogTeamchange(self.playerid, self.team, 1);
1405
1406         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1407
1408         self.netname_previous = strzone(self.netname);
1409
1410         bprint("^4", self.netname, "^4 connected");
1411
1412         if(self.classname != "observer" && (g_domination || g_ctf))
1413                 bprint(" and joined the ", ColoredTeamName(self.team));
1414
1415         bprint("\n");
1416
1417         self.welcomemessage_time = 0;
1418
1419         stuffcmd(self, strcat(clientstuff, "\n"));
1420         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1421         stuffcmd(self, "cl_particles_reloadeffects\n");
1422
1423         FixClientCvars(self);
1424
1425         // spawnfunc_waypoint sprites
1426         WaypointSprite_InitClient(self);
1427
1428         // Wazat's grappling hook
1429         SetGrappleHookBindings();
1430
1431         // get autoswitch state from player when he toggles it
1432         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1433
1434         // get version info from player
1435         stuffcmd(self, "cmd clientversion $gameversion\n");
1436
1437         // get other cvars from player
1438         GetCvars(0);
1439
1440         // set cvar for team scoreboard
1441         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1442
1443         // notify about available teams
1444         if(teams_matter)
1445         {
1446                 CheckAllowedTeams(self);
1447                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1448                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1449         }
1450         else
1451                 stuffcmd(self, "set _teams_available 0\n");
1452
1453         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1454
1455         if(g_arena || g_ca)
1456         {
1457                 self.classname = "observer";
1458                 if(g_arena)
1459                         Spawnqueue_Insert(self);
1460         }
1461         /*else if(g_ctf)
1462         {
1463                 ctf_clientconnect();
1464         }*/
1465
1466         if(teams_matter || radar_showennemies)
1467                 attach_entcs();
1468
1469         bot_relinkplayerlist();
1470
1471         self.spectatortime = time;
1472         if(blockSpectators)
1473         {
1474                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1475         }
1476
1477         self.jointime = time;
1478         self.allowedTimeouts = cvar("sv_timeout_number");
1479
1480         if(clienttype(self) == CLIENTTYPE_REAL)
1481         {
1482                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1483                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1484         }
1485
1486         if(g_lms)
1487         {
1488                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1489                 {
1490                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1491                         self.frags = FRAGS_SPECTATOR;
1492                 }
1493         }
1494
1495         if(!sv_foginterval && world.fog != "")
1496                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1497
1498         SoundEntity_Attach(self);
1499
1500         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1501         {
1502                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1503                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1504         }
1505         else
1506                 self.hitplotfh = -1;
1507
1508 #ifdef UID
1509         if(clienttype(self) == CLIENTTYPE_REAL)
1510         if not(self.uid)
1511                 self.uid_kicktime = time + 60;
1512 #endif
1513
1514         if(g_race || g_cts) {
1515                 string rr;
1516                 if(g_cts)
1517                         rr = CTS_RECORD;
1518                 else
1519                         rr = RACE_RECORD;
1520                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1521
1522                 race_send_recordtime(MSG_ONE);
1523                 race_send_speedaward(MSG_ONE);
1524
1525                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1526                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1527                 race_send_speedaward_alltimebest(MSG_ONE);
1528
1529                 float i;
1530                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1531                         race_SendRankings(i, 0, 0, MSG_ONE);
1532                 }
1533         }
1534         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1535                 send_CSQC_teamnagger();
1536
1537         CheatInitClient();
1538 }
1539
1540 /*
1541 =============
1542 ClientDisconnect
1543
1544 Called when a client disconnects from the server
1545 =============
1546 */
1547 .entity chatbubbleentity;
1548 .entity teambubbleentity;
1549 void ReadyCount();
1550 void ClientDisconnect (void)
1551 {
1552         if not(self.flags & FL_CLIENT)
1553         {
1554                 print("Warning: ClientDisconnect without ClientConnect\n");
1555                 return;
1556         }
1557
1558         CheatShutdownClient();
1559
1560         if(self.hitplotfh >= 0)
1561         {
1562                 fclose(self.hitplotfh);
1563                 self.hitplotfh = -1;
1564         }
1565
1566         anticheat_report();
1567         anticheat_shutdown();
1568
1569         playerdemo_shutdown();
1570
1571         bot_clientdisconnect();
1572
1573         if(self.entcs)
1574                 detach_entcs();
1575
1576         if(cvar("sv_eventlog"))
1577                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1578         bprint ("^4",self.netname);
1579         bprint ("^4 disconnected\n");
1580
1581         SoundEntity_Detach(self);
1582
1583         DropAllRunes(self);
1584         MUTATOR_CALLHOOK(ClientDisconnect);
1585
1586         Portal_ClearAll(self);
1587
1588         if(self.flagcarried)
1589                 DropFlag(self.flagcarried, world, world);
1590         if(self.ballcarried)
1591                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1592
1593         // Here, everything has been done that requires this player to be a client.
1594
1595         self.flags &~= FL_CLIENT;
1596
1597         if (self.chatbubbleentity)
1598                 remove (self.chatbubbleentity);
1599
1600         if (self.teambubbleentity)
1601                 remove (self.teambubbleentity);
1602
1603         if (self.killindicator)
1604                 remove (self.killindicator);
1605
1606         WaypointSprite_PlayerGone();
1607
1608         bot_relinkplayerlist();
1609
1610         // remove laserdot
1611         if(self.weaponentity)
1612                 if(self.weaponentity.lasertarget)
1613                         remove(self.weaponentity.lasertarget);
1614
1615         if(g_arena)
1616         {
1617                 Spawnqueue_Unmark(self);
1618                 Spawnqueue_Remove(self);
1619         }
1620
1621         ClientData_Detach();
1622         PlayerScore_Detach(self);
1623
1624         if(self.netname_previous)
1625                 strunzone(self.netname_previous);
1626         if(self.clientstatus)
1627                 strunzone(self.clientstatus);
1628
1629         ClearPlayerSounds();
1630
1631         if(self.personal)
1632                 remove(self.personal);
1633
1634         self.playerid = 0;
1635         ReadyCount();
1636
1637         // free cvars
1638         GetCvars(-1);
1639 }
1640
1641 .float BUTTON_CHAT;
1642 void ChatBubbleThink()
1643 {
1644         self.nextthink = time;
1645         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1646         {
1647                 if(self.owner) // but why can that ever be world?
1648                         self.owner.chatbubbleentity = world;
1649                 remove(self);
1650                 return;
1651         }
1652         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1653 #ifdef TETRIS
1654                 || self.owner.tetris_on
1655 #endif
1656         )
1657                 self.model = self.mdl;
1658         else
1659                 self.model = "";
1660 };
1661
1662 void UpdateChatBubble()
1663 {
1664         if (!self.modelindex)
1665                 return;
1666         // spawn a chatbubble entity if needed
1667         if (!self.chatbubbleentity)
1668         {
1669                 self.chatbubbleentity = spawn();
1670                 self.chatbubbleentity.owner = self;
1671                 self.chatbubbleentity.exteriormodeltoclient = self;
1672                 self.chatbubbleentity.think = ChatBubbleThink;
1673                 self.chatbubbleentity.nextthink = time;
1674                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1675                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1676                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1677                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1678                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1679                 self.chatbubbleentity.model = "";
1680                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1681         }
1682 }
1683
1684
1685 void TeamBubbleThink()
1686 {
1687         self.nextthink = time;
1688         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1689         {
1690                 if(self.owner) // but why can that ever be world?
1691                         self.owner.teambubbleentity = world;
1692                 remove(self);
1693                 return;
1694         }
1695 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1696         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1697                 self.model = "";
1698         else
1699                 self.model = self.mdl;
1700
1701 };
1702
1703 float TeamBubble_customizeentityforclient()
1704 {
1705         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1706 }
1707
1708 void UpdateTeamBubble()
1709 {
1710         if (!self.modelindex || !teams_matter)
1711                 return;
1712         // spawn a teambubble entity if needed
1713         if (!self.teambubbleentity && teams_matter)
1714         {
1715                 self.teambubbleentity = spawn();
1716                 self.teambubbleentity.owner = self;
1717                 self.teambubbleentity.exteriormodeltoclient = self;
1718                 self.teambubbleentity.think = TeamBubbleThink;
1719                 self.teambubbleentity.nextthink = time;
1720                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1721 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1722                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1723                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1724                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1725                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1726                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1727                 self.teambubbleentity.effects = EF_LOWPRECISION;
1728         }
1729 }
1730
1731 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1732 // added to the model skins
1733 /*void UpdateColorModHack()
1734 {
1735         local float c;
1736         c = self.clientcolors & 15;
1737         // LordHavoc: only bothering to support white, green, red, yellow, blue
1738              if (!teams_matter) self.colormod = '0 0 0';
1739         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1740         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1741         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1742         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1743         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1744         else self.colormod = '1 1 1';
1745 };*/
1746
1747 void respawn(void)
1748 {
1749         CopyBody(1);
1750         self.effects |= EF_NODRAW; // prevent another CopyBody
1751         PutClientInServer();
1752 }
1753
1754 void play_countdown(float finished, string samp)
1755 {
1756         if(clienttype(self) == CLIENTTYPE_REAL)
1757                 if(floor(finished - time - frametime) != floor(finished - time))
1758                         if(finished - time < 6)
1759                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1760 }
1761
1762 /**
1763  * When sv_timeout is used this function returs strings like
1764  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1765  * Called by centerprint functions
1766  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1767  */
1768 string getTimeoutText(float addOneSecond) {
1769         if (!cvar("sv_timeout") || !timeoutStatus)
1770                 return "";
1771
1772         local string retStr;
1773         if (timeoutStatus == 1) {
1774                 if (addOneSecond == 1) {
1775                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1776                 }
1777                 else {
1778                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1779                 }
1780                 return retStr;
1781         }
1782         else if (timeoutStatus == 2) {
1783                 if (addOneSecond) {
1784                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1785                         //don't show messages like "Timeout ends in 0 seconds"...
1786                         if ((remainingTimeoutTime + 1) > 0)
1787                                 return retStr;
1788                         else
1789                                 return "";
1790                 }
1791                 else {
1792                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1793                         //don't show messages like "Timeout ends in 0 seconds"...
1794                         if (remainingTimeoutTime > 0)
1795                                 return retStr;
1796                         else
1797                                 return "";
1798                 }
1799         }
1800         else return "";
1801 }
1802
1803 void player_powerups (void)
1804 {
1805         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1806         {
1807                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1808                 self.modelflags |= MF_ROCKET;
1809         }
1810         else
1811         {
1812                 SoundEntity_StopSound(self, CHAN_PLAYER);
1813                 self.modelflags &~= MF_ROCKET;
1814         }
1815
1816         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1817
1818         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1819                 return;
1820
1821         Fire_ApplyDamage(self);
1822         Fire_ApplyEffect(self);
1823
1824         if (g_minstagib)
1825         {
1826                 self.effects |= EF_FULLBRIGHT;
1827
1828                 if (self.items & IT_STRENGTH)
1829                 {
1830                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1831                         if (time > self.strength_finished)
1832                         {
1833                                 self.alpha = default_player_alpha;
1834                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1835                                 self.items &~= IT_STRENGTH;
1836                                 sprint(self, "^3Invisibility has worn off\n");
1837                         }
1838                 }
1839                 else
1840                 {
1841                         if (time < self.strength_finished)
1842                         {
1843                                 self.alpha = g_minstagib_invis_alpha;
1844                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1845                                 self.items |= IT_STRENGTH;
1846                                 sprint(self, "^3You are invisible\n");
1847                         }
1848                 }
1849
1850                 if (self.items & IT_INVINCIBLE)
1851                 {
1852                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1853                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1854                         {
1855                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1856                                 sprint(self, "^3Speed has worn off\n");
1857                         }
1858                 }
1859                 else
1860                 {
1861                         if (time < self.invincible_finished)
1862                         {
1863                                 self.items = self.items | IT_INVINCIBLE;
1864                                 sprint(self, "^3You are on speed\n");
1865                         }
1866                 }
1867                 return;
1868         }
1869
1870         if (self.items & IT_STRENGTH)
1871         {
1872                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1873                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1874                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1875                 {
1876                         self.items = self.items - (self.items & IT_STRENGTH);
1877                         sprint(self, "^3Strength has worn off\n");
1878                 }
1879         }
1880         else
1881         {
1882                 if (time < self.strength_finished)
1883                 {
1884                         self.items = self.items | IT_STRENGTH;
1885                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1886                 }
1887         }
1888         if (self.items & IT_INVINCIBLE)
1889         {
1890                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1891                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1892                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1893                 {
1894                         self.items = self.items - (self.items & IT_INVINCIBLE);
1895                         sprint(self, "^3Shield has worn off\n");
1896                 }
1897         }
1898         else
1899         {
1900                 if (time < self.invincible_finished)
1901                 {
1902                         self.items = self.items | IT_INVINCIBLE;
1903                         sprint(self, "^3Shield surrounds you\n");
1904                 }
1905         }
1906
1907         if(cvar("g_nodepthtestplayers"))
1908                 self.effects = self.effects | EF_NODEPTHTEST;
1909
1910         if(cvar("g_fullbrightplayers"))
1911                 self.effects = self.effects | EF_FULLBRIGHT;
1912
1913         // midair gamemode: damage only while in the air
1914         // if in midair mode, being on ground grants temporary invulnerability
1915         // (this is so that multishot weapon don't clear the ground flag on the
1916         // first damage in the frame, leaving the player vulnerable to the
1917         // remaining hits in the same frame)
1918         if (self.flags & FL_ONGROUND)
1919         if (g_midair)
1920                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1921
1922         if (time >= game_starttime)
1923         if (time < self.spawnshieldtime)
1924                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1925 }
1926
1927 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1928 {
1929         if(current > stable)
1930                 return current;
1931         else if(current > stable - 0.25) // when close enough, "snap"
1932                 return stable;
1933         else
1934                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1935 }
1936
1937 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1938 {
1939         if(current < stable)
1940                 return current;
1941         else if(current < stable + 0.25) // when close enough, "snap"
1942                 return stable;
1943         else
1944                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1945 }
1946
1947 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1948 {
1949         if(current > rotstable)
1950         {
1951                 if(rotframetime > 0)
1952                 {
1953                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1954                         current = max(rotstable, current - rotlinear * rotframetime);
1955                 }
1956         }
1957         else if(current < regenstable)
1958         {
1959                 if(regenframetime > 0)
1960                 {
1961                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1962                         current = min(regenstable, current + regenlinear * regenframetime);
1963                 }
1964         }
1965
1966         if(current > limit)
1967                 current = limit;
1968
1969         return current;
1970 }
1971
1972 void player_regen (void)
1973 {
1974         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1975         maxh = cvar("g_balance_health_rotstable");
1976         maxa = cvar("g_balance_armor_rotstable");
1977         maxf = cvar("g_balance_fuel_rotstable");
1978         minh = cvar("g_balance_health_regenstable");
1979         mina = cvar("g_balance_armor_regenstable");
1980         minf = cvar("g_balance_fuel_regenstable");
1981         limith = cvar("g_balance_health_limit");
1982         limita = cvar("g_balance_armor_limit");
1983         limitf = cvar("g_balance_fuel_limit");
1984
1985         max_mod = regen_mod = rot_mod = limit_mod = 1;
1986
1987         if (self.runes & RUNE_REGEN)
1988         {
1989                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1990                 {
1991                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1992                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1993                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1994                 }
1995                 else
1996                 {
1997                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1998                         max_mod = cvar("g_balance_rune_regen_hpmod");
1999                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2000                 }
2001         }
2002         else if (self.runes & CURSE_VENOM)
2003         {
2004                 max_mod = cvar("g_balance_curse_venom_hpmod");
2005                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2006                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2007                 else
2008                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2009                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2010                 //if (!self.runes & RUNE_REGEN)
2011                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2012         }
2013         maxh = maxh * max_mod;
2014         //maxa = maxa * max_mod;
2015         //maxf = maxf * max_mod;
2016         minh = minh * max_mod;
2017         //mina = mina * max_mod;
2018         //minf = minf * max_mod;
2019         limith = limith * limit_mod;
2020         limita = limita * limit_mod;
2021         //limitf = limitf * limit_mod;
2022
2023         if(g_lms && g_ca)
2024                 rot_mod = 0;
2025
2026         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2027         {
2028                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2029                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2030
2031                 // if player rotted to death...  die!
2032                 if(self.health < 1)
2033                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2034         }
2035
2036         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2037                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2038 }
2039
2040 float zoomstate_set;
2041 void SetZoomState(float z)
2042 {
2043         if(z != self.zoomstate)
2044         {
2045                 self.zoomstate = z;
2046                 ClientData_Touch(self);
2047         }
2048         zoomstate_set = 1;
2049 }
2050
2051 void GetPressedKeys(void) {
2052         MUTATOR_CALLHOOK(GetPressedKeys);
2053         if (self.movement_x > 0) // get if movement keys are pressed
2054         {       // forward key pressed
2055                 self.pressedkeys |= KEY_FORWARD;
2056                 self.pressedkeys &~= KEY_BACKWARD;
2057         }
2058         else if (self.movement_x < 0)
2059         {       // backward key pressed
2060                 self.pressedkeys |= KEY_BACKWARD;
2061                 self.pressedkeys &~= KEY_FORWARD;
2062         }
2063         else
2064         {       // no x input
2065                 self.pressedkeys &~= KEY_FORWARD;
2066                 self.pressedkeys &~= KEY_BACKWARD;
2067         }
2068
2069         if (self.movement_y > 0)
2070         {       // right key pressed
2071                 self.pressedkeys |= KEY_RIGHT;
2072                 self.pressedkeys &~= KEY_LEFT;
2073         }
2074         else if (self.movement_y < 0)
2075         {       // left key pressed
2076                 self.pressedkeys |= KEY_LEFT;
2077                 self.pressedkeys &~= KEY_RIGHT;
2078         }
2079         else
2080         {       // no y input
2081                 self.pressedkeys &~= KEY_RIGHT;
2082                 self.pressedkeys &~= KEY_LEFT;
2083         }
2084
2085         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2086                 self.pressedkeys |= KEY_JUMP;
2087         else
2088                 self.pressedkeys &~= KEY_JUMP;
2089         if (self.BUTTON_CROUCH)
2090                 self.pressedkeys |= KEY_CROUCH;
2091         else
2092                 self.pressedkeys &~= KEY_CROUCH;
2093 }
2094
2095 void update_stats (float number, float hit, float fired) {
2096 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2097 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2098
2099         if(number) {
2100                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2101                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2102         } else {
2103                 self.stat_hit = hit * sv_accuracy_data_share;
2104                 self.stat_fired = fired * sv_accuracy_data_share;
2105         }
2106 }
2107
2108 /*
2109 ======================
2110 spectate mode routines
2111 ======================
2112 */
2113
2114 .float weapon_count;
2115 void SpectateCopy(entity spectatee) {
2116         if(spectatee.weapon_count < WEP_LAST) {
2117                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2118                 spectatee.weapon_count ++;
2119         } else
2120                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2121
2122         other = spectatee;
2123         MUTATOR_CALLHOOK(SpectateCopy);
2124         self.armortype = spectatee.armortype;
2125         self.armorvalue = spectatee.armorvalue;
2126         self.ammo_cells = spectatee.ammo_cells;
2127         self.ammo_shells = spectatee.ammo_shells;
2128         self.ammo_nails = spectatee.ammo_nails;
2129         self.ammo_rockets = spectatee.ammo_rockets;
2130         self.ammo_fuel = spectatee.ammo_fuel;
2131         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2132         self.health = spectatee.health;
2133         self.impulse = 0;
2134         self.items = spectatee.items;
2135         self.metertime = spectatee.metertime;
2136         self.strength_finished = spectatee.strength_finished;
2137         self.invincible_finished = spectatee.invincible_finished;
2138         self.pressedkeys = spectatee.pressedkeys;
2139         self.weapons = spectatee.weapons;
2140         self.switchweapon = spectatee.switchweapon;
2141         self.weapon = spectatee.weapon;
2142         self.punchangle = spectatee.punchangle;
2143         self.view_ofs = spectatee.view_ofs;
2144         self.v_angle = spectatee.v_angle;
2145         self.velocity = spectatee.velocity;
2146         self.dmg_take = spectatee.dmg_take;
2147         self.dmg_save = spectatee.dmg_save;
2148         self.dmg_inflictor = spectatee.dmg_inflictor;
2149         self.angles = spectatee.v_angle;
2150         self.fixangle = TRUE;
2151         setorigin(self, spectatee.origin);
2152         setsize(self, spectatee.mins, spectatee.maxs);
2153         SetZoomState(spectatee.zoomstate);
2154
2155         anticheat_spectatecopy(spectatee);
2156 }
2157
2158 float SpectateUpdate() {
2159         if(!self.enemy)
2160                 return 0;
2161
2162         if (self == self.enemy)
2163                 return 0;
2164
2165         if(self.enemy.classname != "player")
2166                 return 0;
2167
2168         SpectateCopy(self.enemy);
2169
2170         return 1;
2171 }
2172
2173 float SpectateNext() {
2174         other = find(self.enemy, classname, "player");
2175
2176         if (!other)
2177                 other = find(other, classname, "player");
2178
2179         if (other)
2180                 self.enemy = other;
2181
2182         if(self.enemy.classname == "player") {
2183                 msg_entity = self;
2184                 WriteByte(MSG_ONE, SVC_SETVIEW);
2185                 WriteEntity(MSG_ONE, self.enemy);
2186                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2187                 self.movetype = MOVETYPE_NONE;
2188
2189                 self.enemy.weapon_count = 0;
2190
2191                 if(!SpectateUpdate())
2192                         PutObserverInServer();
2193
2194                 return 1;
2195         } else {
2196                 return 0;
2197         }
2198 }
2199
2200 /*
2201 =============
2202 ShowRespawnCountdown()
2203
2204 Update a respawn countdown display.
2205 =============
2206 */
2207 void ShowRespawnCountdown()
2208 {
2209         float number;
2210         if(self.deadflag == DEAD_NO) // just respawned?
2211                 return;
2212         else
2213         {
2214                 number = ceil(self.death_time - time);
2215                 if(number <= 0)
2216                         return;
2217                 if(number <= self.respawn_countdown)
2218                 {
2219                         self.respawn_countdown = number - 1;
2220                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2221                                 AnnounceTo(self, strcat(ftos(number), ""));
2222                 }
2223         }
2224 }
2225
2226 void LeaveSpectatorMode()
2227 {
2228         if(isJoinAllowed()) {
2229                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2230                         self.classname = "player";
2231
2232                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2233                                 JoinBestTeam(self, FALSE, TRUE);
2234
2235                         if(cvar("g_campaign"))
2236                                 campaign_bots_may_start = 1;
2237
2238                         self.stat_count = WEP_LAST;
2239
2240                         PutClientInServer();
2241
2242                         if(self.classname == "player")
2243                                 bprint ("^4", self.netname, "^4 is playing now\n");
2244
2245                         if(!cvar("g_campaign"))
2246                                 centerprint(self,""); // clear MOTD
2247
2248                         return;
2249                 } else {
2250                         if (g_ca && self.caplayer) {
2251                         }       // do nothing
2252                         else
2253                                 stuffcmd(self,"menu_showteamselect\n");
2254                         return;
2255                 }
2256         }
2257         else {
2258                 //player may not join because of g_maxplayers is set
2259                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2260         }
2261 }
2262
2263 /**
2264  * Determines whether the player is allowed to join. This depends on cvar
2265  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2266  * it checks whether the number of currently playing players exceeds g_maxplayers.
2267  * @return bool TRUE if the player is allowed to join, false otherwise
2268  */
2269 float isJoinAllowed() {
2270         if (!cvar("g_maxplayers"))
2271                 return TRUE;
2272
2273         local entity e;
2274         local float currentlyPlaying;
2275         FOR_EACH_REALPLAYER(e) {
2276                 if(e.classname == "player")
2277                         currentlyPlaying += 1;
2278         }
2279         if(currentlyPlaying < cvar("g_maxplayers"))
2280                 return TRUE;
2281
2282         return FALSE;
2283 }
2284
2285 /**
2286  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2287  * g_maxplayers_spectator_blocktime seconds
2288  */
2289 void checkSpectatorBlock() {
2290         if(self.classname == "spectator" || self.classname == "observer") {
2291                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2292                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2293                         dropclient(self);
2294                 }
2295         }
2296 }
2297
2298 float vercmp_recursive(string v1, string v2)
2299 {
2300         float dot1, dot2;
2301         string s1, s2;
2302         float r;
2303
2304         dot1 = strstrofs(v1, ".", 0);
2305         dot2 = strstrofs(v2, ".", 0);
2306         if(dot1 == -1)
2307                 s1 = v1;
2308         else
2309                 s1 = substring(v1, 0, dot1);
2310         if(dot2 == -1)
2311                 s2 = v2;
2312         else
2313                 s2 = substring(v2, 0, dot2);
2314
2315         r = stof(s1) - stof(s2);
2316         if(r != 0)
2317                 return r;
2318
2319         r = strcasecmp(s1, s2);
2320         if(r != 0)
2321                 return r;
2322
2323         if(dot1 == -1)
2324                 if(dot2 == -1)
2325                         return 0;
2326                 else
2327                         return -1;
2328         else
2329                 if(dot2 == -1)
2330                         return 1;
2331                 else
2332                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2333 }
2334
2335 float vercmp(string v1, string v2)
2336 {
2337         if(strcasecmp(v1, v2) == 0) // early out check
2338                 return 0;
2339         return vercmp_recursive(v1, v2);
2340 }
2341
2342 void ObserverThink()
2343 {
2344         if (self.flags & FL_JUMPRELEASED) {
2345                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2346                         self.welcomemessage_time = 0;
2347                         self.flags &~= FL_JUMPRELEASED;
2348                         self.flags |= FL_SPAWNING;
2349                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2350                         self.welcomemessage_time = 0;
2351                         self.flags &~= FL_JUMPRELEASED;
2352                         if(SpectateNext() == 1) {
2353                                 self.classname = "spectator";
2354                         }
2355                 }
2356         } else {
2357                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2358                         self.flags |= FL_JUMPRELEASED;
2359                         if(self.flags & FL_SPAWNING)
2360                         {
2361                                 self.flags &~= FL_SPAWNING;
2362                                 LeaveSpectatorMode();
2363                                 return;
2364                         }
2365                 }
2366         }
2367         PrintWelcomeMessage(self);
2368 }
2369
2370 void SpectatorThink()
2371 {
2372         if (self.flags & FL_JUMPRELEASED) {
2373                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2374                         self.welcomemessage_time = 0;
2375                         self.flags &~= FL_JUMPRELEASED;
2376                         self.flags |= FL_SPAWNING;
2377                 } else if(self.BUTTON_ATCK) {
2378                         self.welcomemessage_time = 0;
2379                         self.flags &~= FL_JUMPRELEASED;
2380                         if(SpectateNext() == 1) {
2381                                 self.classname = "spectator";
2382                         } else {
2383                                 self.classname = "observer";
2384                                 self.stat_count = WEP_LAST;
2385                                 PutClientInServer();
2386                         }
2387                 } else if (self.BUTTON_ATCK2) {
2388                         self.welcomemessage_time = 0;
2389                         self.flags &~= FL_JUMPRELEASED;
2390                         self.classname = "observer";
2391                         self.stat_count = WEP_LAST;
2392                         PutClientInServer();
2393                 } else {
2394                         if(!SpectateUpdate())
2395                                 PutObserverInServer();
2396                 }
2397         } else {
2398                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2399                         self.flags |= FL_JUMPRELEASED;
2400                         if(self.flags & FL_SPAWNING)
2401                         {
2402                                 self.flags &~= FL_SPAWNING;
2403                                 LeaveSpectatorMode();
2404                                 return;
2405                         }
2406                 }
2407         }
2408
2409         PrintWelcomeMessage(self);
2410         self.flags |= FL_CLIENT | FL_NOTARGET;
2411 }
2412
2413 .float touchexplode_time;
2414
2415 /*
2416 =============
2417 PlayerPreThink
2418
2419 Called every frame for each client before the physics are run
2420 =============
2421 */
2422 void() ctf_setstatus;
2423 void() nexball_setstatus;
2424 .float items_added;
2425 void PlayerPreThink (void)
2426 {
2427         self.stat_game_starttime = game_starttime;
2428         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2429         self.stat_leadlimit = cvar("leadlimit");
2430
2431         if(frametime)
2432         {
2433                 // physics frames: update anticheat stuff
2434                 anticheat_prethink();
2435         }
2436
2437         if(blockSpectators && frametime)
2438                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2439                 checkSpectatorBlock();
2440
2441         zoomstate_set = 0;
2442
2443         if(self.netname_previous != self.netname)
2444         {
2445                 if(cvar("sv_eventlog"))
2446                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2447                 if(self.netname_previous)
2448                         strunzone(self.netname_previous);
2449                 self.netname_previous = strzone(self.netname);
2450         }
2451
2452         // version nagging
2453         if(self.version_nagtime)
2454                 if(self.cvar_g_xonoticversion)
2455                         if(time > self.version_nagtime)
2456                         {
2457                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2458                                 {
2459                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2460                                         {
2461                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2462                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2463                                         }
2464                                         else
2465                                         {
2466                                                 float r;
2467                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2468                                                 if(r < 0)
2469                                                 {
2470                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2471                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2472                                                 }
2473                                                 else if(r > 0)
2474                                                 {
2475                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2476                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2477                                                 }
2478                                         }
2479                                 }
2480                                 self.version_nagtime = 0;
2481                         }
2482
2483         // GOD MODE info
2484         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2485         {
2486                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2487                 self.max_armorvalue = 0;
2488         }
2489
2490 #ifdef TETRIS
2491         if (TetrisPreFrame())
2492                 return;
2493 #endif
2494
2495         MUTATOR_CALLHOOK(PlayerPreThink);
2496
2497         if(self.classname == "player") {
2498 //              if(self.netname == "Wazat")
2499 //                      bprint(self.classname, "\n");
2500
2501                 CheckRules_Player();
2502
2503                 PrintWelcomeMessage(self);
2504
2505                 if (intermission_running)
2506                 {
2507                         IntermissionThink ();   // otherwise a button could be missed between
2508                         return;                                 // the think tics
2509                 }
2510
2511                 if(self.teleport_time)
2512                 if(time > self.teleport_time)
2513                 {
2514                         self.teleport_time = 0;
2515                         self.effects = self.effects - (self.effects & EF_NODRAW);
2516                 }
2517
2518                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2519                         UpdateSelectedPlayer();
2520
2521                 //don't allow the player to turn around while game is paused!
2522                 if(timeoutStatus == 2) {
2523                         self.v_angle = self.lastV_angle;
2524                         self.angles = self.lastV_angle;
2525                         self.fixangle = TRUE;
2526                 }
2527
2528                 if(frametime)
2529                 {
2530                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2531                         player_powerups();
2532                 }
2533
2534                 if (self.deadflag != DEAD_NO)
2535                 {
2536                         float button_pressed, force_respawn;
2537                         if(self.personal && g_race_qualifying)
2538                         {
2539                                 if(time > self.death_time)
2540                                 {
2541                                         self.death_time = time + 1; // only retry once a second
2542                                         respawn();
2543                                         self.impulse = 141;
2544                                 }
2545                         }
2546                         else
2547                         {
2548                                 if(frametime)
2549                                         player_anim();
2550                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2551                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2552                                 if (self.deadflag == DEAD_DYING)
2553                                 {
2554                                         if(force_respawn)
2555                                                 self.deadflag = DEAD_RESPAWNING;
2556                                         else if(!button_pressed)
2557                                                 self.deadflag = DEAD_DEAD;
2558                                 }
2559                                 else if (self.deadflag == DEAD_DEAD)
2560                                 {
2561                                         if(button_pressed)
2562                                                 self.deadflag = DEAD_RESPAWNABLE;
2563                                 }
2564                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2565                                 {
2566                                         if(!button_pressed)
2567                                                 self.deadflag = DEAD_RESPAWNING;
2568                                 }
2569                                 else if (self.deadflag == DEAD_RESPAWNING)
2570                                 {
2571                                         if(time > self.death_time)
2572                                         {
2573                                                 self.death_time = time + 1; // only retry once a second
2574                                                 respawn();
2575                                         }
2576                                 }
2577                                 ShowRespawnCountdown();
2578                         }
2579                         return;
2580                 }
2581
2582                 if(g_touchexplode)
2583                 if(time > self.touchexplode_time)
2584                 if(self.classname == "player")
2585                 if(self.deadflag == DEAD_NO)
2586                 if not(IS_INDEPENDENT_PLAYER(self))
2587                 FOR_EACH_PLAYER(other) if(self != other)
2588                 {
2589                         if(time > other.touchexplode_time)
2590                         if(other.classname == "player")
2591                         if(other.deadflag == DEAD_NO)
2592                         if not(IS_INDEPENDENT_PLAYER(other))
2593                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2594                         {
2595                                 PlayerTouchExplode(self, other);
2596                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2597                         }
2598                 }
2599
2600                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2601                 {
2602                         vector dist;
2603
2604                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2605                         dist = self.prevorigin - self.origin;
2606                         dist_z = 0;
2607                         self.lms_traveled_distance += fabs(vlen(dist));
2608
2609                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2610                         {
2611                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2612                                 self.lms_traveled_distance = 0;
2613                         }
2614
2615                         if(time > self.lms_nextcheck)
2616                         {
2617                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2618                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2619                                 {
2620                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2621                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2622                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2623                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2624                                 }
2625                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2626                                 self.lms_traveled_distance = 0;
2627                         }
2628                 }
2629
2630                 self.prevorigin = self.origin;
2631
2632                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2633                 {
2634                         if (!self.crouch)
2635                         {
2636                                 self.crouch = TRUE;
2637                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2638                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2639                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2640                         }
2641                 }
2642                 else
2643                 {
2644                         if (self.crouch)
2645                         {
2646                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2647                                 if (!trace_startsolid)
2648                                 {
2649                                         self.crouch = FALSE;
2650                                         self.view_ofs = PL_VIEW_OFS;
2651                                         setsize (self, PL_MIN, PL_MAX);
2652                                 }
2653                         }
2654                 }
2655
2656                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2657                 {
2658                         if(self.bloodloss_timer < time)
2659                         {
2660                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2661                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2662                         }
2663                 }
2664
2665                 FixPlayermodel();
2666
2667                 GrapplingHookFrame();
2668
2669                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2670                 //if(frametime)
2671                 {
2672                         self.items &~= self.items_added;
2673
2674                         W_WeaponFrame();
2675
2676                         self.items_added = 0;
2677                         if(self.items & IT_JETPACK)
2678                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2679                                         self.items_added |= IT_FUEL;
2680
2681                         self.items |= self.items_added;
2682                 }
2683
2684                 player_regen();
2685                 if(frametime)
2686                         player_anim();
2687
2688                 if (g_minstagib)
2689                         minstagib_ammocheck();
2690
2691                 ctf_setstatus();
2692                 nexball_setstatus();
2693
2694                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2695
2696                 //self.angles_y=self.v_angle_y + 90;   // temp
2697         } else if(gameover) {
2698                 if (intermission_running)
2699                         IntermissionThink ();   // otherwise a button could be missed between
2700                 return;
2701         } else if(self.classname == "observer") {
2702                 ObserverThink();
2703         } else if(self.classname == "spectator") {
2704                 SpectatorThink();
2705         }
2706
2707         if(!zoomstate_set)
2708                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2709
2710         float oldspectatee_status;
2711         oldspectatee_status = self.spectatee_status;
2712         if(self.classname == "spectator")
2713                 self.spectatee_status = num_for_edict(self.enemy);
2714         else if(self.classname == "observer")
2715                 self.spectatee_status = num_for_edict(self);
2716         else
2717                 self.spectatee_status = 0;
2718         if(self.spectatee_status != oldspectatee_status)
2719         {
2720                 ClientData_Touch(self);
2721                 if(g_race || g_cts)
2722                         race_InitSpectator();
2723         }
2724
2725         if(self.teamkill_soundtime)
2726         if(time > self.teamkill_soundtime)
2727         {
2728                 self.teamkill_soundtime = 0;
2729
2730                 entity oldpusher, oldself;
2731
2732                 oldself = self; self = self.teamkill_soundsource;
2733                 oldpusher = self.pusher; self.pusher = oldself;
2734
2735                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2736
2737                 self.pusher = oldpusher;
2738                 self = oldself;
2739         }
2740
2741         if(self.taunt_soundtime)
2742         if(time > self.taunt_soundtime)
2743         {
2744                 self.taunt_soundtime = 0;
2745                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2746         }
2747
2748         target_voicescript_next(self);
2749 }
2750
2751 float isInvisibleString(string s)
2752 {
2753         float i, n, c;
2754         s = strdecolorize(s);
2755         for((i = 0), (n = strlen(s)); i < n; ++i)
2756         {
2757                 c = str2chr(s, i);
2758                 switch(c)
2759                 {
2760                         case 0:
2761                         case 32:
2762                         case 160:
2763                                 break;
2764                         default:
2765                                 return FALSE;
2766                 }
2767         }
2768         return TRUE;
2769 }
2770
2771 /*
2772 =============
2773 PlayerPostThink
2774
2775 Called every frame for each client after the physics are run
2776 =============
2777 */
2778 .float idlekick_lasttimeleft;
2779 void PlayerPostThink (void)
2780 {
2781         // Savage: Check for nameless players
2782         if (isInvisibleString(self.netname)) {
2783                 self.netname = "Player";
2784                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2785         }
2786
2787         // send the clients accuracy stats to the client
2788         if(self.stat_count > 0)
2789         if(frametime)
2790         {
2791                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2792                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2793                 self.stat_count -= 1;
2794         }
2795
2796 #ifdef UID
2797         if(self.uid_kicktime)
2798         if(time > self.uid_kicktime)
2799         {
2800                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2801                 dropclient(self);
2802                 return;
2803         }
2804 #endif
2805
2806         if(sv_maxidle && frametime)
2807         {
2808                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2809                 float timeleft;
2810                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2811                 if(timeleft <= 0)
2812                 {
2813                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2814                         AnnounceTo(self, "terminated");
2815                         dropclient(self);
2816                         return;
2817                 }
2818                 else if(timeleft <= 10)
2819                 {
2820                         if(timeleft != self.idlekick_lasttimeleft)
2821                         {
2822                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2823                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2824                         }
2825                 }
2826                 else
2827                 {
2828                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2829                 }
2830                 self.idlekick_lasttimeleft = timeleft;
2831         }
2832
2833 #ifdef TETRIS
2834         if(self.impulse == 100)
2835                 ImpulseCommands();
2836         if (TetrisPostFrame())
2837                 return;
2838 #endif
2839
2840         CheatFrame();
2841
2842         if(self.classname == "player") {
2843                 CheckRules_Player();
2844                 UpdateChatBubble();
2845                 UpdateTeamBubble();
2846                 if (self.impulse)
2847                         ImpulseCommands();
2848                 if (intermission_running)
2849                         return;         // intermission or finale
2850                 GetPressedKeys();
2851         } else if (self.classname == "observer") {
2852                 //do nothing
2853         } else if (self.classname == "spectator") {
2854                 //do nothing
2855         }
2856
2857         /*
2858         float i;
2859         for(i = 0; i < 1000; ++i)
2860         {
2861                 vector end;
2862                 end = self.origin + '0 0 1024' + 512 * randomvec();
2863                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2864                 if(trace_fraction < 1)
2865                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2866                 {
2867                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2868                         break;
2869                 }
2870         }
2871         */
2872
2873         Arena_Warmup();
2874
2875         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2876
2877         if(self.waypointsprite_attachedforcarrier)
2878                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2879
2880         playerdemo_write();
2881
2882         /*
2883         if(g_race)
2884                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2885         */
2886 }