qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(to.classname == "spectator")
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(e2.classname == "spectator")
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77
  78 .vector spawnpoint_score;
  79 .string netname_previous;
  80
  81 void spawnfunc_info_player_survivor (void)
  82 {
  83         spawnfunc_info_player_deathmatch();
  84 }
  85
  86 void spawnfunc_info_player_start (void)
  87 {
  88         spawnfunc_info_player_deathmatch();
  89 }
  90
  91 void spawnfunc_info_player_deathmatch (void)
  92 {
  93         self.classname = "info_player_deathmatch";
  94         relocate_spawnpoint();
  95 }
  96
  97 void spawnpoint_use()
  98 {
  99         if(teamplay)
 100         if(have_team_spawns > 0)
 101         {
 102                 self.team = activator.team;
 103                 some_spawn_has_been_used = 1;
 104         }
 105 }
 106
 107 // Returns:
 108 //   _x: prio (-1 if unusable)
 109 //   _y: weight
 110 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 111 {
 112         float shortest, thisdist;
 113         float prio;
 114         entity player;
 115
 116         prio = 0;
 117
 118         // filter out spots for the wrong team
 119         if(teamcheck >= 0)
 120                 if(spot.team != teamcheck)
 121                         return '-1 0 0';
 122
 123         if(race_spawns)
 124                 if(spot.target == "")
 125                         return '-1 0 0';
 126
 127         if(clienttype(self) == CLIENTTYPE_REAL)
 128         {
 129                 if(spot.restriction == 1)
 130                         return '-1 0 0';
 131         }
 132         else
 133         {
 134                 if(spot.restriction == 2)
 135                         return '-1 0 0';
 136         }
 137
 138         shortest = vlen(world.maxs - world.mins);
 139         FOR_EACH_PLAYER(player) if (player != self)
 140         {
 141                 thisdist = vlen(player.origin - spot.origin);
 142                 if (thisdist < shortest)
 143                         shortest = thisdist;
 144         }
 145         if(shortest > mindist)
 146                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 147
 148         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 149         spawn_spot = spot;
 150
 151         // filter out spots for assault
 152         if(spot.target != "") {
 153                 entity ent;
 154                 float found;
 155
 156                 found = 0;
 157                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 158                 {
 159                         ++found;
 160                         if(ent.spawn_evalfunc)
 161                         {
 162                                 entity oldself = self;
 163                                 self = ent;
 164                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 165                                 self = oldself;
 166                                 if(spawn_score_x < 0)
 167                                         return spawn_score;
 168                         }
 169                 }
 170
 171                 if(!found)
 172                 {
 173                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 174                         return '-1 0 0';
 175                 }
 176         }
 177
 178         MUTATOR_CALLHOOK(Spawn_Score);
 179         return spawn_score;
 180 }
 181
 182 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 183 {
 184         entity spot;
 185         for(spot = firstspot; spot; spot = spot.chain)
 186                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 187 }
 188
 189 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 190 {
 191         entity spot, spotlist, spotlistend;
 192
 193         spotlist = world;
 194         spotlistend = world;
 195
 196         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 197
 198         for(spot = firstspot; spot; spot = spot.chain)
 199         {
 200                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 201                 {
 202                         if(spotlistend)
 203                                 spotlistend.chain = spot;
 204                         spotlistend = spot;
 205                         if(!spotlist)
 206                                 spotlist = spot;
 207                 }
 208         }
 209         if(spotlistend)
 210                 spotlistend.chain = world;
 211
 212         return spotlist;
 213 }
 214
 215 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 216 {
 217         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 218         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 219         entity spot;
 220
 221         RandomSelection_Init();
 222         for(spot = firstspot; spot; spot = spot.chain)
 223                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 224
 225         return RandomSelection_chosen_ent;
 226 }
 227
 228 /*
 229 =============
 230 SelectSpawnPoint
 231
 232 Finds a point to respawn
 233 =============
 234 */
 235 entity SelectSpawnPoint (float anypoint)
 236 {
 237         float teamcheck;
 238         entity spot, firstspot;
 239
 240         spot = find (world, classname, "testplayerstart");
 241         if (spot)
 242                 return spot;
 243
 244         if(anypoint || autocvar_g_spawn_useallspawns)
 245                 teamcheck = -1;
 246         else if(have_team_spawns > 0)
 247         {
 248                 if(have_team_spawns_forteam[self.team] == 0)
 249                 {
 250                         // we request a spawn for a team, and we have team
 251                         // spawns, but that team has no spawns?
 252                         if(have_team_spawns_forteam[0])
 253                                 // try noteam spawns
 254                                 teamcheck = 0;
 255                         else
 256                                 // if not, any spawn has to do
 257                                 teamcheck = -1;
 258                 }
 259                 else
 260                         teamcheck = self.team; // MUST be team
 261         }
 262         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 263                 teamcheck = 0; // MUST be noteam
 264         else
 265                 teamcheck = -1;
 266                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 267
 268
 269         // get the entire list of spots
 270         firstspot = findchain(classname, "info_player_deathmatch");
 271         // filter out the bad ones
 272         // (note this returns the original list if none survived)
 273         if(anypoint)
 274         {
 275                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 276         }
 277         else
 278         {
 279                 float mindist;
 280                 if (g_arena && arena_roundbased)
 281                         mindist = 800;
 282                 else
 283                         mindist = 100;
 284                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 285
 286                 // there is 50/50 chance of choosing a random spot or the furthest spot
 287                 // (this means that roughly every other spawn will be furthest, so you
 288                 // usually won't get fragged at spawn twice in a row)
 289                 if (random() > autocvar_g_spawn_furthest)
 290                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 291                 else
 292                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 293         }
 294
 295         if (!spot)
 296         {
 297                 if(autocvar_spawn_debug)
 298                         GotoNextMap(0);
 299                 else
 300                 {
 301                         if(some_spawn_has_been_used)
 302                                 return world; // team can't spawn any more, because of actions of other team
 303                         else
 304                                 error("Cannot find a spawn point - please fix the map!");
 305                 }
 306         }
 307
 308         return spot;
 309 }
 310
 311 /*
 312 =============
 313 CheckPlayerModel
 314
 315 Checks if the argument string can be a valid playermodel.
 316 Returns a valid one in doubt.
 317 =============
 318 */
 319 string FallbackPlayerModel;
 320 string CheckPlayerModel(string plyermodel) {
 321         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 322         {
 323                 // note: we cannot summon Don Strunzone here, some player may
 324                 // still have the model string set. In case anyone manages how
 325                 // to change a cvar default, we'll have a small leak here.
 326                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 327         }
 328         // only in right path
 329         if( substring(plyermodel,0,14) != "models/player/")
 330                 return FallbackPlayerModel;
 331         // only good file extensions
 332         if(substring(plyermodel,-4,4) != ".zym")
 333         if(substring(plyermodel,-4,4) != ".dpm")
 334         if(substring(plyermodel,-4,4) != ".iqm")
 335         if(substring(plyermodel,-4,4) != ".md3")
 336         if(substring(plyermodel,-4,4) != ".psk")
 337                 return FallbackPlayerModel;
 338         // forbid the LOD models
 339         if(substring(plyermodel, -9,5) == "_lod1")
 340                 return FallbackPlayerModel;
 341         if(substring(plyermodel, -9,5) == "_lod2")
 342                 return FallbackPlayerModel;
 343         if(plyermodel != strtolower(plyermodel))
 344                 return FallbackPlayerModel;
 345         // also, restrict to server models
 346         if(autocvar_sv_servermodelsonly)
 347         {
 348                 if(!fexists(plyermodel))
 349                         return FallbackPlayerModel;
 350         }
 351         return plyermodel;
 352 }
 353
 354 void setplayermodel(entity e, string modelname)
 355 {
 356         precache_model(modelname);
 357         setmodel(e, modelname);
 358         player_setupanimsformodel();
 359         UpdatePlayerSounds();
 360 }
 361
 362 /*
 363 =============
 364 PutObserverInServer
 365
 366 putting a client as observer in the server
 367 =============
 368 */
 369 void FixPlayermodel();
 370 void PutObserverInServer (void)
 371 {
 372         entity  spot;
 373     self.hud = HUD_NORMAL;
 374         race_PreSpawnObserver();
 375
 376         spot = SelectSpawnPoint (TRUE);
 377         if(!spot)
 378                 error("No spawnpoints for observers?!?\n");
 379         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 380
 381         if(clienttype(self) == CLIENTTYPE_REAL)
 382         {
 383                 msg_entity = self;
 384                 WriteByte(MSG_ONE, SVC_SETVIEW);
 385                 WriteEntity(MSG_ONE, self);
 386         }
 387
 388         if((g_race && g_race_qualifying) || g_cts)
 389         {
 390                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 391                         self.frags = FRAGS_LMS_LOSER;
 392                 else
 393                         self.frags = FRAGS_SPECTATOR;
 394         }
 395         else
 396                 self.frags = FRAGS_SPECTATOR;
 397
 398         MUTATOR_CALLHOOK(MakePlayerObserver);
 399
 400         Portal_ClearAll(self);
 401
 402         if(self.alivetime)
 403         {
 404                 if(!inWarmupStage)
 405                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 406                 self.alivetime = 0;
 407         }
 408
 409         if(self.vehicle)
 410                 vehicles_exit(VHEF_RELESE);
 411
 412         WaypointSprite_PlayerDead();
 413
 414         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 415                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 416
 417         if(self.killcount != -666)
 418         {
 419                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 420
 421                 if(self.just_joined == FALSE) {
 422                         LogTeamchange(self.playerid, -1, 4);
 423                 } else
 424                         self.just_joined = FALSE;
 425         }
 426
 427         PlayerScore_Clear(self); // clear scores when needed
 428
 429         accuracy_resend(self);
 430
 431         self.spectatortime = time;
 432
 433         self.classname = "observer";
 434         self.iscreature = FALSE;
 435         self.teleportable = TELEPORT_SIMPLE;
 436         self.damagedbycontents = FALSE;
 437         self.health = -666;
 438         self.takedamage = DAMAGE_NO;
 439         self.solid = SOLID_NOT;
 440         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 441         self.flags = FL_CLIENT | FL_NOTARGET;
 442         self.armorvalue = 666;
 443         self.effects = 0;
 444         self.armorvalue = autocvar_g_balance_armor_start;
 445         self.pauserotarmor_finished = 0;
 446         self.pauserothealth_finished = 0;
 447         self.pauseregen_finished = 0;
 448         self.damageforcescale = 0;
 449         self.death_time = 0;
 450         self.respawn_flags = 0;
 451         self.respawn_time = 0;
 452         self.stat_respawn_time = 0;
 453         self.alpha = 0;
 454         self.scale = 0;
 455         self.fade_time = 0;
 456         self.pain_frame = 0;
 457         self.pain_finished = 0;
 458         self.strength_finished = 0;
 459         self.invincible_finished = 0;
 460         self.superweapons_finished = 0;
 461         self.pushltime = 0;
 462         self.istypefrag = 0;
 463         self.think = func_null;
 464         self.nextthink = 0;
 465         self.hook_time = 0;
 466         self.deadflag = DEAD_NO;
 467         self.angles = spot.angles;
 468         self.angles_z = 0;
 469         self.fixangle = TRUE;
 470         self.crouch = FALSE;
 471
 472         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 473         self.prevorigin = self.origin;
 474         self.items = 0;
 475         WEPSET_CLEAR_E(self);
 476         self.model = "";
 477         FixPlayermodel();
 478         setmodel(self, "null");
 479         self.drawonlytoclient = self;
 480
 481         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 482         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 483
 484         self.weapon = 0;
 485         self.weaponname = "";
 486         self.switchingweapon = 0;
 487         self.weaponmodel = "";
 488         self.weaponentity = world;
 489         self.exteriorweaponentity = world;
 490         self.killcount = -666;
 491         self.velocity = '0 0 0';
 492         self.avelocity = '0 0 0';
 493         self.punchangle = '0 0 0';
 494         self.punchvector = '0 0 0';
 495         self.oldvelocity = self.velocity;
 496         self.fire_endtime = -1;
 497 }
 498
 499 .float model_randomizer;
 500 void FixPlayermodel()
 501 {
 502         string defaultmodel;
 503         float defaultskin, chmdl, oldskin, n, i;
 504         vector m1, m2;
 505
 506         defaultmodel = "";
 507         defaultskin = 0;
 508         chmdl = FALSE;
 509
 510         if(autocvar_sv_defaultcharacter == 1)
 511         {
 512                 if(teamplay)
 513                 {
 514                         string s;
 515                         s = Team_ColorName_Lower(self.team);
 516                         if(s != "neutral")
 517                         {
 518                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 519                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 520                         }
 521                 }
 522
 523                 if(defaultmodel == "")
 524                 {
 525                         defaultmodel = autocvar_sv_defaultplayermodel;
 526                         defaultskin = autocvar_sv_defaultplayerskin;
 527                 }
 528
 529                 n = tokenize_console(defaultmodel);
 530                 if(n > 0)
 531                         defaultmodel = argv(floor(n * self.model_randomizer));
 532
 533                 i = strstrofs(defaultmodel, ":", 0);
 534                 if(i >= 0)
 535                 {
 536                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 537                         defaultmodel = substring(defaultmodel, 0, i);
 538                 }
 539         }
 540
 541         if(defaultmodel != "")
 542         {
 543                 if (defaultmodel != self.model)
 544                 {
 545                         m1 = self.mins;
 546                         m2 = self.maxs;
 547                         setplayermodel (self, defaultmodel);
 548                         setsize (self, m1, m2);
 549                         chmdl = TRUE;
 550                 }
 551
 552                 oldskin = self.skin;
 553                 self.skin = defaultskin;
 554         } else {
 555                 if (self.playermodel != self.model || self.playermodel == "")
 556                 {
 557                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 558                         m1 = self.mins;
 559                         m2 = self.maxs;
 560                         setplayermodel (self, self.playermodel);
 561                         setsize (self, m1, m2);
 562                         chmdl = TRUE;
 563                 }
 564
 565                 oldskin = self.skin;
 566                 self.skin = stof(self.playerskin);
 567         }
 568
 569         if(chmdl || oldskin != self.skin) // model or skin has changed
 570         {
 571                 self.species = player_getspecies(); // update species
 572                 UpdatePlayerSounds(); // update skin sounds
 573         }
 574
 575         if(!teamplay)
 576                 if(strlen(autocvar_sv_defaultplayercolors))
 577                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 578                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 579 }
 580
 581 /*
 582 =============
 583 PutClientInServer
 584
 585 Called when a client spawns in the server
 586 =============
 587 */
 588
 589 void PutClientInServer (void)
 590 {
 591         if(clienttype(self) == CLIENTTYPE_BOT)
 592                 self.classname = "player";
 593         else if(clienttype(self) == CLIENTTYPE_REAL)
 594         {
 595                 msg_entity = self;
 596                 WriteByte(MSG_ONE, SVC_SETVIEW);
 597                 WriteEntity(MSG_ONE, self);
 598         }
 599
 600         // reset player keys
 601         self.itemkeys = 0;
 602
 603         MUTATOR_CALLHOOK(PutClientInServer);
 604
 605         if(gameover)
 606                 self.classname = "observer";
 607
 608         if(self.classname == "player") {
 609                 entity spot, oldself;
 610                 float j;
 611
 612                 accuracy_resend(self);
 613
 614                 if(self.team < 0)
 615                         JoinBestTeam(self, FALSE, TRUE);
 616
 617                 race_PreSpawn();
 618
 619                 spot = SelectSpawnPoint (FALSE);
 620                 if(!spot)
 621                 {
 622                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 623                         return; // spawn failed
 624                 }
 625
 626                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 627
 628                 self.classname = "player";
 629                 self.wasplayer = TRUE;
 630                 self.iscreature = TRUE;
 631                 self.teleportable = TELEPORT_NORMAL;
 632                 self.damagedbycontents = TRUE;
 633                 self.movetype = MOVETYPE_WALK;
 634                 self.solid = SOLID_SLIDEBOX;
 635                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 636                 if(autocvar_g_playerclip_collisions)
 637                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 638                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 639                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 640                 self.frags = FRAGS_PLAYER;
 641                 if(INDEPENDENT_PLAYERS)
 642                         MAKE_INDEPENDENT_PLAYER(self);
 643                 self.flags = FL_CLIENT;
 644                 if(autocvar__notarget)
 645                         self.flags |= FL_NOTARGET;
 646                 self.takedamage = DAMAGE_AIM;
 647                 self.effects = 0;
 648                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 649                 self.air_finished = time + 12;
 650                 self.dmg = 2;
 651                 if(autocvar_g_balance_nex_charge)
 652                 {
 653                         if(autocvar_g_balance_nex_secondary_chargepool)
 654                                 self.nex_chargepool_ammo = 1;
 655                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 656                 }
 657
 658                 if(inWarmupStage)
 659                 {
 660                         self.ammo_shells = warmup_start_ammo_shells;
 661                         self.ammo_nails = warmup_start_ammo_nails;
 662                         self.ammo_rockets = warmup_start_ammo_rockets;
 663                         self.ammo_cells = warmup_start_ammo_cells;
 664                         self.ammo_fuel = warmup_start_ammo_fuel;
 665                         self.health = warmup_start_health;
 666                         self.armorvalue = warmup_start_armorvalue;
 667                         WEPSET_COPY_EA(self, warmup_start_weapons);
 668                 }
 669                 else
 670                 {
 671                         self.ammo_shells = start_ammo_shells;
 672                         self.ammo_nails = start_ammo_nails;
 673                         self.ammo_rockets = start_ammo_rockets;
 674                         self.ammo_cells = start_ammo_cells;
 675                         self.ammo_fuel = start_ammo_fuel;
 676                         self.health = start_health;
 677                         self.armorvalue = start_armorvalue;
 678                         WEPSET_COPY_EA(self, start_weapons);
 679                 }
 680
 681                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 682                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 683                 else
 684                         self.superweapons_finished = 0;
 685
 686                 if(g_weaponarena_random)
 687                 {
 688                         if(g_weaponarena_random_with_laser)
 689                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 690                         W_RandomWeapons(self, g_weaponarena_random);
 691                         if(g_weaponarena_random_with_laser)
 692                                 WEPSET_OR_EW(self, WEP_LASER);
 693                 }
 694
 695                 self.items = start_items;
 696
 697                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 698                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 699                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 700                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 701                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 702                 //extend the pause of rotting if client was reset at the beginning of the countdown
 703                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 704                         self.spawnshieldtime += game_starttime - time;
 705                         self.pauserotarmor_finished += game_starttime - time;
 706                         self.pauserothealth_finished += game_starttime - time;
 707                         self.pauseregen_finished += game_starttime - time;
 708                 }
 709                 self.damageforcescale = 2;
 710                 self.death_time = 0;
 711                 self.respawn_flags = 0;
 712                 self.respawn_time = 0;
 713                 self.stat_respawn_time = 0;
 714                 self.scale = 0;
 715                 self.fade_time = 0;
 716                 self.pain_frame = 0;
 717                 self.pain_finished = 0;
 718                 self.strength_finished = 0;
 719                 self.invincible_finished = 0;
 720                 self.pushltime = 0;
 721                 // players have no think function
 722                 self.think = func_null;
 723                 self.nextthink = 0;
 724                 self.hook_time = 0;
 725                 self.dmg_team = 0;
 726                 self.ballistics_density = autocvar_g_ballistics_density_player;
 727
 728                 self.metertime = 0;
 729
 730                 self.deadflag = DEAD_NO;
 731
 732                 self.angles = spot.angles;
 733
 734                 self.angles_z = 0; // never spawn tilted even if the spot says to
 735                 self.fixangle = TRUE; // turn this way immediately
 736                 self.velocity = '0 0 0';
 737                 self.avelocity = '0 0 0';
 738                 self.punchangle = '0 0 0';
 739                 self.punchvector = '0 0 0';
 740                 self.oldvelocity = self.velocity;
 741                 self.fire_endtime = -1;
 742
 743                 msg_entity = self;
 744                 WRITESPECTATABLE_MSG_ONE({
 745                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 746                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 747                 });
 748
 749                 self.model = "";
 750                 FixPlayermodel();
 751                 self.drawonlytoclient = world;
 752
 753                 self.crouch = FALSE;
 754                 self.view_ofs = PL_VIEW_OFS;
 755                 setsize (self, PL_MIN, PL_MAX);
 756                 self.spawnorigin = spot.origin;
 757                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 758                 // don't reset back to last position, even if new position is stuck in solid
 759                 self.oldorigin = self.origin;
 760                 self.prevorigin = self.origin;
 761                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 762                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 763         self.hud = HUD_NORMAL;
 764
 765                 self.event_damage = PlayerDamage;
 766
 767                 self.bot_attack = TRUE;
 768
 769                 self.statdraintime = time + 5;
 770                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 771
 772                 if(self.killcount == -666) {
 773                         PlayerScore_Clear(self);
 774                         self.killcount = 0;
 775                 }
 776
 777                 CL_SpawnWeaponentity();
 778                 self.alpha = default_player_alpha;
 779                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 780                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 781
 782                 self.speedrunning = FALSE;
 783
 784                 race_PostSpawn(spot);
 785
 786                 //stuffcmd(self, "chase_active 0");
 787                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 788
 789                 target_voicescript_clear(self);
 790
 791                 // reset fields the weapons may use
 792                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 793                 {
 794                         weapon_action(j, WR_RESETPLAYER);
 795
 796                         // all weapons must be fully loaded when we spawn
 797                         entity e;
 798                         e = get_weaponinfo(j);
 799                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 800                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 801                 }
 802
 803                 oldself = self;
 804                 self = spot;
 805                         activator = oldself;
 806                                 string s;
 807                                 s = self.target;
 808                                 self.target = string_null;
 809                                 SUB_UseTargets();
 810                                 self.target = s;
 811                         activator = world;
 812                 self = oldself;
 813
 814                 spawn_spot = spot;
 815                 MUTATOR_CALLHOOK(PlayerSpawn);
 816
 817                 if(autocvar_spawn_debug)
 818                 {
 819                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 820                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 821                 }
 822
 823                 self.switchweapon = w_getbestweapon(self);
 824                 self.cnt = -1; // W_LastWeapon will not complain
 825                 self.weapon = 0;
 826                 self.weaponname = "";
 827                 self.switchingweapon = 0;
 828
 829                 if(!inWarmupStage)
 830                         if(!self.alivetime)
 831                                 self.alivetime = time;
 832
 833                 antilag_clear(self);
 834
 835                 if (autocvar_g_spawnsound)
 836                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 837         } else if(self.classname == "observer") {
 838                 PutObserverInServer ();
 839         }
 840 }
 841
 842 .float ebouncefactor, ebouncestop; // electro's values
 843 // TODO do we need all these fields, or should we stop autodetecting runtime
 844 // changes and just have a console command to update this?
 845 float ClientInit_SendEntity(entity to, float sf)
 846 {
 847         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 848         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 849         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 850         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 851         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 852         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 853         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 854         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 855         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 856         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 857         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 858         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 859         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 860         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 861         if(sv_foginterval && world.fog != "")
 862                 WriteString(MSG_ENTITY, world.fog);
 863         else
 864                 WriteString(MSG_ENTITY, "");
 865         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 866         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 867         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 868         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 869         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 870         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 871         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 872         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 873         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 874         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 875         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 876         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 877         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 878         return TRUE;
 879 }
 880
 881 void ClientInit_CheckUpdate()
 882 {
 883         self.nextthink = time;
 884         if(self.count != autocvar_g_balance_armor_blockpercent)
 885         {
 886                 self.count = autocvar_g_balance_armor_blockpercent;
 887                 self.SendFlags |= 1;
 888         }
 889         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 890         {
 891                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 892                 self.SendFlags |= 1;
 893         }
 894         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 895         {
 896                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 897                 self.SendFlags |= 1;
 898         }
 899         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 900         {
 901                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 902                 self.SendFlags |= 1;
 903         }
 904         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 905         {
 906                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 907                 self.SendFlags |= 1;
 908         }
 909         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 910         {
 911                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 912                 self.SendFlags |= 1;
 913         }
 914 }
 915
 916 void ClientInit_Spawn()
 917 {
 918         entity o;
 919         entity e;
 920         e = spawn();
 921         e.classname = "clientinit";
 922         e.think = ClientInit_CheckUpdate;
 923         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 924
 925         o = self;
 926         self = e;
 927         ClientInit_CheckUpdate();
 928         self = o;
 929 }
 930
 931 /*
 932 =============
 933 SetNewParms
 934 =============
 935 */
 936 void SetNewParms (void)
 937 {
 938         // initialize parms for a new player
 939         parm1 = -(86400 * 366);
 940 }
 941
 942 /*
 943 =============
 944 SetChangeParms
 945 =============
 946 */
 947 void SetChangeParms (void)
 948 {
 949         // save parms for level change
 950         parm1 = self.parm_idlesince - time;
 951 }
 952
 953 /*
 954 =============
 955 DecodeLevelParms
 956 =============
 957 */
 958 void DecodeLevelParms (void)
 959 {
 960         // load parms
 961         self.parm_idlesince = parm1;
 962         if(self.parm_idlesince == -(86400 * 366))
 963                 self.parm_idlesince = time;
 964
 965         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 966         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 967 }
 968
 969 /*
 970 =============
 971 ClientKill
 972
 973 Called when a client types 'kill' in the console
 974 =============
 975 */
 976
 977 .float clientkill_nexttime;
 978 void ClientKill_Now_TeamChange()
 979 {
 980         if(self.killindicator_teamchange == -1)
 981         {
 982                 JoinBestTeam( self, FALSE, TRUE );
 983         }
 984         else if(self.killindicator_teamchange == -2)
 985         {
 986                 if(blockSpectators)
 987                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 988                 PutObserverInServer();
 989         }
 990         else
 991                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 992         self.killindicator_teamchange = 0;
 993 }
 994
 995 void ClientKill_Now()
 996 {
 997         if(self.vehicle)
 998         {
 999             vehicles_exit(VHEF_RELESE);
1000             if(!self.killindicator_teamchange)
1001             {
1002             self.vehicle_health = -1;
1003             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1004             }
1005         }
1006
1007         if(self.killindicator && !wasfreed(self.killindicator))
1008                 remove(self.killindicator);
1009
1010         self.killindicator = world;
1011
1012         if(self.killindicator_teamchange)
1013                 ClientKill_Now_TeamChange();
1014
1015         // in any case:
1016         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1017
1018         // now I am sure the player IS dead
1019 }
1020 void KillIndicator_Think()
1021 {
1022         if (gameover)
1023         {
1024                 self.owner.killindicator = world;
1025                 remove(self);
1026                 return;
1027         }
1028
1029         if (self.owner.alpha < 0 && !self.owner.vehicle)
1030         {
1031                 self.owner.killindicator = world;
1032                 remove(self);
1033                 return;
1034         }
1035
1036         if(self.cnt <= 0)
1037         {
1038                 self = self.owner;
1039                 ClientKill_Now(); // no oldself needed
1040                 return;
1041         }
1042     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1043     {
1044         self.nextthink = time + 1;
1045         self.cnt -= 1;
1046     }
1047         else
1048         {
1049                 if(self.cnt <= 10)
1050                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1051                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1052                 {
1053                         if(self.cnt <= 10)
1054                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
1055                 }
1056                 self.nextthink = time + 1;
1057                 self.cnt -= 1;
1058         }
1059 }
1060
1061 float clientkilltime;
1062 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1063 {
1064         float killtime;
1065         float starttime;
1066         entity e;
1067
1068         if (gameover)
1069                 return;
1070
1071         killtime = autocvar_g_balance_kill_delay;
1072
1073         if(g_race_qualifying || g_cts)
1074                 killtime = 0;
1075
1076     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1077     {
1078                 remove(self.killindicator);
1079                 self.killindicator = world;
1080
1081         ClientKill_Now(); // allow instant kill in this case
1082         return;
1083     }
1084
1085         self.killindicator_teamchange = targetteam;
1086
1087     if(!self.killindicator)
1088         {
1089                 if(self.deadflag == DEAD_NO)
1090                 {
1091                         killtime = max(killtime, self.clientkill_nexttime - time);
1092                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1093                 }
1094
1095                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1096                 {
1097                         ClientKill_Now();
1098                 }
1099                 else
1100                 {
1101                         starttime = max(time, clientkilltime);
1102
1103                         self.killindicator = spawn();
1104                         self.killindicator.owner = self;
1105                         self.killindicator.scale = 0.5;
1106                         setattachment(self.killindicator, self, "");
1107                         setorigin(self.killindicator, '0 0 52');
1108                         self.killindicator.think = KillIndicator_Think;
1109                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1110                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1111                         self.killindicator.cnt = ceil(killtime);
1112                         self.killindicator.count = bound(0, ceil(killtime), 10);
1113                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1114
1115                         for(e = world; (e = find(e, classname, "body")) != world; )
1116                         {
1117                                 if(e.enemy != self)
1118                                         continue;
1119                                 e.killindicator = spawn();
1120                                 e.killindicator.owner = e;
1121                                 e.killindicator.scale = 0.5;
1122                                 setattachment(e.killindicator, e, "");
1123                                 setorigin(e.killindicator, '0 0 52');
1124                                 e.killindicator.think = KillIndicator_Think;
1125                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1126                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1127                                 e.killindicator.cnt = ceil(killtime);
1128                         }
1129                         self.lip = 0;
1130                 }
1131         }
1132         if(self.killindicator)
1133         {
1134                 if(targetteam == 0) // just die
1135                 {
1136                         self.killindicator.colormod = '0 0 0';
1137                         if(clienttype(self) == CLIENTTYPE_REAL)
1138                         if(self.killindicator.cnt > 0)
1139                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1140                 }
1141                 else if(targetteam == -1) // auto
1142                 {
1143                         self.killindicator.colormod = '0 1 0';
1144                         if(clienttype(self) == CLIENTTYPE_REAL)
1145                         if(self.killindicator.cnt > 0)
1146                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1147                 }
1148                 else if(targetteam == -2) // spectate
1149                 {
1150                         self.killindicator.colormod = '0.5 0.5 0.5';
1151                         if(clienttype(self) == CLIENTTYPE_REAL)
1152                         if(self.killindicator.cnt > 0)
1153                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1154                 }
1155                 else
1156                 {
1157                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1158                         if(clienttype(self) == CLIENTTYPE_REAL)
1159                         if(self.killindicator.cnt > 0)
1160                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1161                 }
1162         }
1163
1164 }
1165
1166 void ClientKill (void)
1167 {
1168         if(gameover) return;
1169         if(self.player_blocked) return;
1170         if(self.freezetag_frozen) return;
1171
1172         ClientKill_TeamChange(0);
1173 }
1174
1175 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1176 {
1177     e.killindicator = spawn();
1178     e.killindicator.owner = e;
1179     e.killindicator.think = KillIndicator_Think;
1180     e.killindicator.nextthink = time + (e.lip) * 0.05;
1181     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1182     e.killindicator.health = 1; // this is used to indicate that it should be silent
1183     e.lip = 0;
1184 }
1185
1186 void FixClientCvars(entity e)
1187 {
1188         // send prediction settings to the client
1189         stuffcmd(e, "\nin_bindmap 0 0\n");
1190         if(g_race || g_cts)
1191                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1192         if(autocvar_g_antilag == 3) // client side hitscan
1193                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1194         if(autocvar_sv_gentle)
1195                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1196         /*
1197          * we no longer need to stuff this. Remove this comment block if you feel
1198          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1199         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1200         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1201         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1202         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1203         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1204         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1205         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1206         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1207         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1208         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1209         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1210         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1211         stuffcmd(e, "cl_movement_edgefriction 1\n");
1212          */
1213 }
1214
1215 float PlayerInIDList(entity p, string idlist)
1216 {
1217         float n, i;
1218         string s;
1219
1220         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1221         if not(p.crypto_idfp)
1222                 return 0;
1223
1224         // this function allows abbreviated player IDs too!
1225         n = tokenize_console(idlist);
1226         for(i = 0; i < n; ++i)
1227         {
1228                 s = argv(i);
1229                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1230                         return 1;
1231         }
1232
1233         return 0;
1234 }
1235
1236 /*
1237 =============
1238 ClientConnect
1239
1240 Called when a client connects to the server
1241 =============
1242 */
1243 void DecodeLevelParms (void);
1244 //void dom_player_join_team(entity pl);
1245 void set_dom_state(entity e);
1246 void ClientConnect (void)
1247 {
1248         float t;
1249
1250         if(self.flags & FL_CLIENT)
1251         {
1252                 print("Warning: ClientConnect, but already connected!\n");
1253                 return;
1254         }
1255
1256         if(Ban_MaybeEnforceBanOnce(self))
1257                 return;
1258
1259         DecodeLevelParms();
1260
1261 #ifdef WATERMARK
1262         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1263 #endif
1264
1265         self.classname = "player_joining";
1266
1267         self.flags = FL_CLIENT;
1268         self.version_nagtime = time + 10 + random() * 10;
1269
1270         if(player_count<0)
1271         {
1272                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1273                 player_count = 0;
1274         }
1275
1276         PlayerScore_Attach(self);
1277         ClientData_Attach();
1278         accuracy_init(self);
1279
1280         bot_clientconnect();
1281
1282         playerdemo_init();
1283
1284         anticheat_init();
1285
1286         race_PreSpawnObserver();
1287
1288         // identify the right forced team
1289         if(autocvar_g_campaign)
1290         {
1291                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1292                 {
1293                         switch(autocvar_g_campaign_forceteam)
1294                         {
1295                                 case 1: self.team_forced = NUM_TEAM_1; break;
1296                                 case 2: self.team_forced = NUM_TEAM_2; break;
1297                                 case 3: self.team_forced = NUM_TEAM_3; break;
1298                                 case 4: self.team_forced = NUM_TEAM_4; break;
1299                                 default: self.team_forced = 0;
1300                         }
1301                 }
1302         }
1303         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1304                 self.team_forced = NUM_TEAM_1;
1305         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1306                 self.team_forced = NUM_TEAM_2;
1307         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1308                 self.team_forced = NUM_TEAM_3;
1309         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1310                 self.team_forced = NUM_TEAM_4;
1311         else if(autocvar_g_forced_team_otherwise == "red")
1312                 self.team_forced = NUM_TEAM_1;
1313         else if(autocvar_g_forced_team_otherwise == "blue")
1314                 self.team_forced = NUM_TEAM_2;
1315         else if(autocvar_g_forced_team_otherwise == "yellow")
1316                 self.team_forced = NUM_TEAM_3;
1317         else if(autocvar_g_forced_team_otherwise == "pink")
1318                 self.team_forced = NUM_TEAM_4;
1319         else if(autocvar_g_forced_team_otherwise == "spectate")
1320                 self.team_forced = -1;
1321         else if(autocvar_g_forced_team_otherwise == "spectator")
1322                 self.team_forced = -1;
1323         else
1324                 self.team_forced = 0;
1325
1326         if(!teamplay)
1327                 if(self.team_forced > 0)
1328                         self.team_forced = 0;
1329
1330         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1331
1332         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1333                 self.classname = "observer";
1334         } else {
1335                 if(teamplay)
1336                 {
1337                         if(autocvar_g_balance_teams)
1338                         {
1339                                 self.classname = "player";
1340                                 campaign_bots_may_start = 1;
1341                         }
1342                         else
1343                         {
1344                                 self.classname = "observer"; // do it anyway
1345                         }
1346                 }
1347                 else
1348                 {
1349                         self.classname = "player";
1350                         campaign_bots_may_start = 1;
1351                 }
1352         }
1353
1354         self.playerid = (playerid_last = playerid_last + 1);
1355
1356         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1357
1358     if(clienttype(self) == CLIENTTYPE_BOT)
1359         PlayerStats_AddPlayer(self);
1360
1361         if(autocvar_sv_eventlog)
1362                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1363
1364         LogTeamchange(self.playerid, self.team, 1);
1365
1366         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1367
1368         self.netname_previous = strzone(self.netname);
1369
1370         if((self.classname == STR_PLAYER && teamplay))
1371                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1372         else
1373                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1374
1375         stuffcmd(self, strcat(clientstuff, "\n"));
1376         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1377
1378         FixClientCvars(self);
1379
1380         // spawnfunc_waypoint sprites
1381         WaypointSprite_InitClient(self);
1382
1383         // Wazat's grappling hook
1384         SetGrappleHookBindings();
1385
1386         // get version info from player
1387         stuffcmd(self, "cmd clientversion $gameversion\n");
1388
1389         // get other cvars from player
1390         GetCvars(0);
1391
1392         // notify about available teams
1393         if(teamplay)
1394         {
1395                 CheckAllowedTeams(self);
1396                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1397                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1398         }
1399         else
1400                 stuffcmd(self, "set _teams_available 0\n");
1401
1402         attach_entcs();
1403
1404         bot_relinkplayerlist();
1405
1406         self.spectatortime = time;
1407         if(blockSpectators)
1408         {
1409                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1410         }
1411
1412         self.jointime = time;
1413         self.allowed_timeouts = autocvar_sv_timeout_number;
1414
1415         if(clienttype(self) == CLIENTTYPE_REAL)
1416         {
1417                 if(!autocvar_g_campaign)
1418                 {
1419                         self.motd_actived_time = -1;
1420                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1421                 }
1422
1423                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1424                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1425         }
1426
1427         if(!sv_foginterval && world.fog != "")
1428                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1429
1430         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1431         {
1432                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1433                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1434         }
1435         else
1436                 self.hitplotfh = -1;
1437
1438         if(g_race || g_cts) {
1439                 string rr;
1440                 if(g_cts)
1441                         rr = CTS_RECORD;
1442                 else
1443                         rr = RACE_RECORD;
1444
1445                 msg_entity = self;
1446                 race_send_recordtime(MSG_ONE);
1447                 race_send_speedaward(MSG_ONE);
1448
1449                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1450                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1451                 race_send_speedaward_alltimebest(MSG_ONE);
1452
1453                 float i;
1454                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1455                         race_SendRankings(i, 0, 0, MSG_ONE);
1456                 }
1457         }
1458         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1459                 send_CSQC_teamnagger();
1460
1461         CheatInitClient();
1462
1463         CSQCMODEL_AUTOINIT();
1464
1465         self.model_randomizer = random();
1466
1467         if(clienttype(self) == CLIENTTYPE_REAL)
1468                 sv_notice_join();
1469
1470         MUTATOR_CALLHOOK(ClientConnect);
1471 }
1472 /*
1473 =============
1474 ClientDisconnect
1475
1476 Called when a client disconnects from the server
1477 =============
1478 */
1479 .entity chatbubbleentity;
1480 void ReadyCount();
1481 void ClientDisconnect (void)
1482 {
1483         if(self.vehicle)
1484             vehicles_exit(VHEF_RELESE);
1485
1486         if not(self.flags & FL_CLIENT)
1487         {
1488                 print("Warning: ClientDisconnect without ClientConnect\n");
1489                 return;
1490         }
1491
1492         PlayerStats_AddGlobalInfo(self);
1493
1494         CheatShutdownClient();
1495
1496         if(self.hitplotfh >= 0)
1497         {
1498                 fclose(self.hitplotfh);
1499                 self.hitplotfh = -1;
1500         }
1501
1502         anticheat_report();
1503         anticheat_shutdown();
1504
1505         playerdemo_shutdown();
1506
1507         bot_clientdisconnect();
1508
1509         if(self.entcs)
1510                 detach_entcs();
1511
1512         if(autocvar_sv_eventlog)
1513                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1514
1515         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1516
1517         MUTATOR_CALLHOOK(ClientDisconnect);
1518
1519         Portal_ClearAll(self);
1520
1521         RemoveGrapplingHook(self);
1522
1523         // Here, everything has been done that requires this player to be a client.
1524
1525         self.flags &~= FL_CLIENT;
1526
1527         if (self.chatbubbleentity)
1528                 remove (self.chatbubbleentity);
1529
1530         if (self.killindicator)
1531                 remove (self.killindicator);
1532
1533         WaypointSprite_PlayerGone();
1534
1535         bot_relinkplayerlist();
1536
1537         accuracy_free(self);
1538         ClientData_Detach();
1539         PlayerScore_Detach(self);
1540
1541         if(self.netname_previous)
1542                 strunzone(self.netname_previous);
1543         if(self.clientstatus)
1544                 strunzone(self.clientstatus);
1545         if(self.weaponorder_byimpulse)
1546                 strunzone(self.weaponorder_byimpulse);
1547
1548         ClearPlayerSounds();
1549
1550         if(self.personal)
1551                 remove(self.personal);
1552
1553         self.playerid = 0;
1554         ReadyCount();
1555
1556         // free cvars
1557         GetCvars(-1);
1558 }
1559
1560 .float BUTTON_CHAT;
1561 void ChatBubbleThink()
1562 {
1563         self.nextthink = time;
1564         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1565         {
1566                 if(self.owner) // but why can that ever be world?
1567                         self.owner.chatbubbleentity = world;
1568                 remove(self);
1569                 return;
1570         }
1571         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1572 #ifdef TETRIS
1573                 || self.owner.tetris_on
1574 #endif
1575         )
1576                 self.model = self.mdl;
1577         else
1578                 self.model = "";
1579 }
1580
1581 void UpdateChatBubble()
1582 {
1583         if (self.alpha < 0)
1584                 return;
1585         // spawn a chatbubble entity if needed
1586         if (!self.chatbubbleentity)
1587         {
1588                 self.chatbubbleentity = spawn();
1589                 self.chatbubbleentity.owner = self;
1590                 self.chatbubbleentity.exteriormodeltoclient = self;
1591                 self.chatbubbleentity.think = ChatBubbleThink;
1592                 self.chatbubbleentity.nextthink = time;
1593                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1594                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1595                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1596                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1597                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1598                 self.chatbubbleentity.model = "";
1599                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1600         }
1601 }
1602
1603
1604 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1605 // added to the model skins
1606 /*void UpdateColorModHack()
1607 {
1608         float c;
1609         c = self.clientcolors & 15;
1610         // LordHavoc: only bothering to support white, green, red, yellow, blue
1611              if (!teamplay) self.colormod = '0 0 0';
1612         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1613         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1614         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1615         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1616         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1617         else self.colormod = '1 1 1';
1618 }*/
1619
1620 void respawn(void)
1621 {
1622         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1623         {
1624                 self.solid = SOLID_NOT;
1625                 self.takedamage = DAMAGE_NO;
1626                 self.movetype = MOVETYPE_FLY;
1627                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1628                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1629                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1630                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1631                 if(autocvar_g_respawn_ghosts_maxtime)
1632                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1633         }
1634
1635         CopyBody(1);
1636
1637         self.effects |= EF_NODRAW; // prevent another CopyBody
1638         PutClientInServer();
1639 }
1640
1641 void play_countdown(float finished, string samp)
1642 {
1643         if(clienttype(self) == CLIENTTYPE_REAL)
1644                 if(floor(finished - time - frametime) != floor(finished - time))
1645                         if(finished - time < 6)
1646                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1647 }
1648
1649 void player_powerups (void)
1650 {
1651         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1652         olditems = self.items;
1653
1654         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1655                 self.modelflags |= MF_ROCKET;
1656         else
1657                 self.modelflags &~= MF_ROCKET;
1658
1659         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1660
1661         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1662                 return;
1663
1664         Fire_ApplyDamage(self);
1665         Fire_ApplyEffect(self);
1666
1667         if not(g_minstagib)
1668         {
1669                 if (self.items & IT_STRENGTH)
1670                 {
1671                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1672                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1673                         if (time > self.strength_finished)
1674                         {
1675                                 self.items = self.items - (self.items & IT_STRENGTH);
1676                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1677                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1678                         }
1679                 }
1680                 else
1681                 {
1682                         if (time < self.strength_finished)
1683                         {
1684                                 self.items = self.items | IT_STRENGTH;
1685                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1686                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1687                         }
1688                 }
1689                 if (self.items & IT_INVINCIBLE)
1690                 {
1691                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1692                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1693                         if (time > self.invincible_finished)
1694                         {
1695                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1696                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1697                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1698                         }
1699                 }
1700                 else
1701                 {
1702                         if (time < self.invincible_finished)
1703                         {
1704                                 self.items = self.items | IT_INVINCIBLE;
1705                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1706                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1707                         }
1708                 }
1709                 if (self.items & IT_SUPERWEAPON)
1710                 {
1711                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1712                         {
1713                                 self.superweapons_finished = 0;
1714                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1715                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1716                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1717                         }
1718                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1719                         {
1720                                 // don't let them run out
1721                         }
1722                         else
1723                         {
1724                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1725                                 if (time > self.superweapons_finished)
1726                                 {
1727                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1728                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1729                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1730                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1731                                 }
1732                         }
1733                 }
1734                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1735                 {
1736                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1737                         {
1738                                 self.items = self.items | IT_SUPERWEAPON;
1739                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1740                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1741                         }
1742                         else
1743                         {
1744                                 self.superweapons_finished = 0;
1745                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1746                         }
1747                 }
1748                 else
1749                 {
1750                         self.superweapons_finished = 0;
1751                 }
1752         }
1753
1754         if(autocvar_g_nodepthtestplayers)
1755                 self.effects = self.effects | EF_NODEPTHTEST;
1756
1757         if(autocvar_g_fullbrightplayers)
1758                 self.effects = self.effects | EF_FULLBRIGHT;
1759
1760         // midair gamemode: damage only while in the air
1761         // if in midair mode, being on ground grants temporary invulnerability
1762         // (this is so that multishot weapon don't clear the ground flag on the
1763         // first damage in the frame, leaving the player vulnerable to the
1764         // remaining hits in the same frame)
1765         if (self.flags & FL_ONGROUND)
1766         if (g_midair)
1767                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1768
1769         if (time >= game_starttime)
1770         if (time < self.spawnshieldtime)
1771                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1772
1773         MUTATOR_CALLHOOK(PlayerPowerups);
1774 }
1775
1776 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1777 {
1778         if(current > stable)
1779                 return current;
1780         else if(current > stable - 0.25) // when close enough, "snap"
1781                 return stable;
1782         else
1783                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1784 }
1785
1786 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1787 {
1788         if(current < stable)
1789                 return current;
1790         else if(current < stable + 0.25) // when close enough, "snap"
1791                 return stable;
1792         else
1793                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1794 }
1795
1796 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1797 {
1798         if(current > rotstable)
1799         {
1800                 if(rotframetime > 0)
1801                 {
1802                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1803                         current = max(rotstable, current - rotlinear * rotframetime);
1804                 }
1805         }
1806         else if(current < regenstable)
1807         {
1808                 if(regenframetime > 0)
1809                 {
1810                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1811                         current = min(regenstable, current + regenlinear * regenframetime);
1812                 }
1813         }
1814
1815         if(current > limit)
1816                 current = limit;
1817
1818         return current;
1819 }
1820
1821 void player_regen (void)
1822 {
1823         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1824         maxh = autocvar_g_balance_health_rotstable;
1825         maxa = autocvar_g_balance_armor_rotstable;
1826         maxf = autocvar_g_balance_fuel_rotstable;
1827         minh = autocvar_g_balance_health_regenstable;
1828         mina = autocvar_g_balance_armor_regenstable;
1829         minf = autocvar_g_balance_fuel_regenstable;
1830         limith = autocvar_g_balance_health_limit;
1831         limita = autocvar_g_balance_armor_limit;
1832         limitf = autocvar_g_balance_fuel_limit;
1833
1834         max_mod = regen_mod = rot_mod = limit_mod = 1;
1835
1836         maxh = maxh * max_mod;
1837         //maxa = maxa * max_mod;
1838         //maxf = maxf * max_mod;
1839         minh = minh * max_mod;
1840         //mina = mina * max_mod;
1841         //minf = minf * max_mod;
1842         limith = limith * limit_mod;
1843         limita = limita * limit_mod;
1844         //limitf = limitf * limit_mod;
1845
1846         if(g_ca)
1847                 rot_mod = 0;
1848
1849         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1850         {
1851                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1852                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1853
1854                 // if player rotted to death...  die!
1855                 if(self.health < 1)
1856                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1857         }
1858
1859         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1860                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1861 }
1862
1863 float zoomstate_set;
1864 void SetZoomState(float z)
1865 {
1866         if(z != self.zoomstate)
1867         {
1868                 self.zoomstate = z;
1869                 ClientData_Touch(self);
1870         }
1871         zoomstate_set = 1;
1872 }
1873
1874 void GetPressedKeys(void) {
1875         MUTATOR_CALLHOOK(GetPressedKeys);
1876         if (self.movement_x > 0) // get if movement keys are pressed
1877         {       // forward key pressed
1878                 self.pressedkeys |= KEY_FORWARD;
1879                 self.pressedkeys &~= KEY_BACKWARD;
1880         }
1881         else if (self.movement_x < 0)
1882         {       // backward key pressed
1883                 self.pressedkeys |= KEY_BACKWARD;
1884                 self.pressedkeys &~= KEY_FORWARD;
1885         }
1886         else
1887         {       // no x input
1888                 self.pressedkeys &~= KEY_FORWARD;
1889                 self.pressedkeys &~= KEY_BACKWARD;
1890         }
1891
1892         if (self.movement_y > 0)
1893         {       // right key pressed
1894                 self.pressedkeys |= KEY_RIGHT;
1895                 self.pressedkeys &~= KEY_LEFT;
1896         }
1897         else if (self.movement_y < 0)
1898         {       // left key pressed
1899                 self.pressedkeys |= KEY_LEFT;
1900                 self.pressedkeys &~= KEY_RIGHT;
1901         }
1902         else
1903         {       // no y input
1904                 self.pressedkeys &~= KEY_RIGHT;
1905                 self.pressedkeys &~= KEY_LEFT;
1906         }
1907
1908         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1909                 self.pressedkeys |= KEY_JUMP;
1910         else
1911                 self.pressedkeys &~= KEY_JUMP;
1912         if (self.BUTTON_CROUCH)
1913                 self.pressedkeys |= KEY_CROUCH;
1914         else
1915                 self.pressedkeys &~= KEY_CROUCH;
1916
1917         if (self.BUTTON_ATCK)
1918                 self.pressedkeys |= KEY_ATCK;
1919         else
1920                 self.pressedkeys &~= KEY_ATCK;
1921         if (self.BUTTON_ATCK2)
1922                 self.pressedkeys |= KEY_ATCK2;
1923         else
1924                 self.pressedkeys &~= KEY_ATCK2;
1925 }
1926
1927 /*
1928 ======================
1929 spectate mode routines
1930 ======================
1931 */
1932
1933 void SpectateCopy(entity spectatee) {
1934         other = spectatee;
1935         MUTATOR_CALLHOOK(SpectateCopy);
1936         self.armortype = spectatee.armortype;
1937         self.armorvalue = spectatee.armorvalue;
1938         self.ammo_cells = spectatee.ammo_cells;
1939         self.ammo_shells = spectatee.ammo_shells;
1940         self.ammo_nails = spectatee.ammo_nails;
1941         self.ammo_rockets = spectatee.ammo_rockets;
1942         self.ammo_fuel = spectatee.ammo_fuel;
1943         self.clip_load = spectatee.clip_load;
1944         self.clip_size = spectatee.clip_size;
1945         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1946         self.health = spectatee.health;
1947         self.impulse = 0;
1948         self.items = spectatee.items;
1949         self.last_pickup = spectatee.last_pickup;
1950         self.hit_time = spectatee.hit_time;
1951         self.metertime = spectatee.metertime;
1952         self.strength_finished = spectatee.strength_finished;
1953         self.invincible_finished = spectatee.invincible_finished;
1954         self.pressedkeys = spectatee.pressedkeys;
1955         WEPSET_COPY_EE(self, spectatee);
1956         self.switchweapon = spectatee.switchweapon;
1957         self.switchingweapon = spectatee.switchingweapon;
1958         self.weapon = spectatee.weapon;
1959         self.nex_charge = spectatee.nex_charge;
1960         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1961         self.hagar_load = spectatee.hagar_load;
1962         self.minelayer_mines = spectatee.minelayer_mines;
1963         self.punchangle = spectatee.punchangle;
1964         self.view_ofs = spectatee.view_ofs;
1965         self.velocity = spectatee.velocity;
1966         self.dmg_take = spectatee.dmg_take;
1967         self.dmg_save = spectatee.dmg_save;
1968         self.dmg_inflictor = spectatee.dmg_inflictor;
1969         self.v_angle = spectatee.v_angle;
1970         self.angles = spectatee.v_angle;
1971         if(!self.BUTTON_USE)
1972                 self.fixangle = TRUE;
1973         setorigin(self, spectatee.origin);
1974         setsize(self, spectatee.mins, spectatee.maxs);
1975         SetZoomState(spectatee.zoomstate);
1976
1977     anticheat_spectatecopy(spectatee);
1978         self.hud = spectatee.hud;
1979         if(spectatee.vehicle)
1980     {
1981         self.fixangle = FALSE;
1982         //self.velocity = spectatee.vehicle.velocity;
1983         self.vehicle_health = spectatee.vehicle_health;
1984         self.vehicle_shield = spectatee.vehicle_shield;
1985         self.vehicle_energy = spectatee.vehicle_energy;
1986         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1987         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1988         self.vehicle_reload1 = spectatee.vehicle_reload1;
1989         self.vehicle_reload2 = spectatee.vehicle_reload2;
1990
1991         msg_entity = self;
1992
1993         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1994             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1995             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1996             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1997
1998         //WriteByte (MSG_ONE, SVC_SETVIEW);
1999         //    WriteEntity(MSG_ONE, self);
2000         //makevectors(spectatee.v_angle);
2001         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2002     }
2003 }
2004
2005 float SpectateUpdate() {
2006         if(!self.enemy)
2007             return 0;
2008
2009         if (self == self.enemy)
2010                 return 0;
2011
2012         if(self.enemy.classname != "player")
2013                 return 0;
2014
2015         SpectateCopy(self.enemy);
2016
2017         return 1;
2018 }
2019
2020
2021 float SpectateSet()
2022 {
2023         if(self.enemy.classname != "player")
2024                 return FALSE;
2025         /*if(self.enemy.vehicle)
2026         {
2027
2028                 msg_entity = self;
2029                 WriteByte(MSG_ONE, SVC_SETVIEW);
2030                 WriteEntity(MSG_ONE, self.enemy);
2031                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2032
2033                 self.movetype = MOVETYPE_NONE;
2034                 accuracy_resend(self);
2035         }
2036         else
2037         {*/
2038                 msg_entity = self;
2039                 WriteByte(MSG_ONE, SVC_SETVIEW);
2040                 WriteEntity(MSG_ONE, self.enemy);
2041                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2042                 self.movetype = MOVETYPE_NONE;
2043                 accuracy_resend(self);
2044
2045                 if(!SpectateUpdate())
2046                         PutObserverInServer();
2047         //}
2048         return TRUE;
2049 }
2050
2051 float Spectate(entity pl)
2052 {
2053         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
2054         if(pl.team != self.team)
2055                 return 0;
2056
2057         self.enemy = pl;
2058         return SpectateSet();
2059 }
2060
2061 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2062 entity CA_SpectateNext(entity start) {
2063         if (start.team == self.team) {
2064                 return start;
2065         }
2066
2067         other = start;
2068         // continue from current player
2069         while(other && other.team != self.team) {
2070                 other = find(other, classname, "player");
2071         }
2072
2073         if (!other) {
2074                 // restart from begining
2075                 other = find(other, classname, "player");
2076                 while(other && other.team != self.team) {
2077                         other = find(other, classname, "player");
2078                 }
2079         }
2080
2081         return other;
2082 }
2083
2084 float SpectateNext()
2085 {
2086         other = find(self.enemy, classname, "player");
2087
2088         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2089                 // CA and ca players when spectating enemies is forbidden
2090                 other = CA_SpectateNext(other);
2091         } else {
2092                 // other modes and ca spectators or spectating enemies is allowed
2093                 if (!other)
2094                         other = find(other, classname, "player");
2095         }
2096
2097         if (other)
2098                 self.enemy = other;
2099
2100         return SpectateSet();
2101 }
2102
2103 float SpectatePrev()
2104 {
2105         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2106         other = findchain(classname, "player");
2107         if not(other) // no player
2108                 return FALSE;
2109
2110         entity first = other;
2111         // skip players until current spectated player
2112         if(self.enemy)
2113         while(other && other != self.enemy)
2114                 other = other.chain;
2115
2116         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
2117         {
2118                 do { other = other.chain; }
2119                 while(other && other.team != self.team);
2120
2121                 if not(other)
2122                 {
2123                         other = first;
2124                         while(other.team != self.team)
2125                                 other = other.chain;
2126                         if(other == self.enemy)
2127                                 return TRUE;
2128                 }
2129         }
2130         else
2131         {
2132                 if(other.chain)
2133                         other = other.chain;
2134                 else
2135                         other = first;
2136         }
2137         self.enemy = other;
2138         return SpectateSet();
2139 }
2140
2141 /*
2142 =============
2143 ShowRespawnCountdown()
2144
2145 Update a respawn countdown display.
2146 =============
2147 */
2148 void ShowRespawnCountdown()
2149 {
2150         float number;
2151         if(self.deadflag == DEAD_NO) // just respawned?
2152                 return;
2153         else
2154         {
2155                 number = ceil(self.respawn_time - time);
2156                 if(number <= 0)
2157                         return;
2158                 if(number <= self.respawn_countdown)
2159                 {
2160                         self.respawn_countdown = number - 1;
2161                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2162                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
2163                 }
2164         }
2165 }
2166
2167 void LeaveSpectatorMode()
2168 {
2169         if(self.caplayer)
2170                 return;
2171         if(nJoinAllowed(self))
2172         {
2173                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2174                 {
2175                         self.classname = "player";
2176
2177                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2178                                 { JoinBestTeam(self, FALSE, TRUE); }
2179
2180                         if(autocvar_g_campaign)
2181                                 { campaign_bots_may_start = 1; }
2182
2183                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2184
2185                         PutClientInServer();
2186
2187                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2188                 }
2189                 else
2190                         stuffcmd(self, "menu_showteamselect\n");
2191         }
2192         else
2193         {
2194                 // Player may not join because g_maxplayers is set
2195                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2196         }
2197 }
2198
2199 /**
2200  * Determines whether the player is allowed to join. This depends on cvar
2201  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2202  * it checks whether the number of currently playing players exceeds g_maxplayers.
2203  * @return int number of free slots for players, 0 if none
2204  */
2205 float nJoinAllowed(entity ignore) {
2206         if(!ignore)
2207         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2208         // so report 0 free slots if restricted
2209         {
2210                 if(autocvar_g_forced_team_otherwise == "spectate")
2211                         return 0;
2212                 if(autocvar_g_forced_team_otherwise == "spectator")
2213                         return 0;
2214         }
2215
2216         if(self.team_forced < 0)
2217                 return 0; // forced spectators can never join
2218
2219         // TODO simplify this
2220         entity e;
2221         float totalClients = 0;
2222         FOR_EACH_CLIENT(e)
2223                 if(e != ignore)
2224                         totalClients += 1;
2225
2226         if (!autocvar_g_maxplayers)
2227                 return maxclients - totalClients;
2228
2229         float currentlyPlaying = 0;
2230         FOR_EACH_REALCLIENT(e)
2231                 if(e.classname == "player" || e.caplayer == 1)
2232                         currentlyPlaying += 1;
2233
2234         if(currentlyPlaying < autocvar_g_maxplayers)
2235                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2236
2237         return 0;
2238 }
2239
2240 /**
2241  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2242  * g_maxplayers_spectator_blocktime seconds
2243  */
2244 void checkSpectatorBlock() {
2245         if(self.classname == "spectator" || self.classname == "observer") {
2246                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2247                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2248                         dropclient(self);
2249                 }
2250         }
2251 }
2252
2253 void PrintWelcomeMessage()
2254 {
2255         if(self.motd_actived_time == 0)
2256         {
2257                 if (autocvar_g_campaign) {
2258                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2259                                 self.motd_actived_time = time;
2260                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2261                         }
2262                 } else {
2263                         if (self.BUTTON_INFO) {
2264                                 self.motd_actived_time = time;
2265                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2266                         }
2267                 }
2268         }
2269         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2270         {
2271                 if (autocvar_g_campaign) {
2272                         if (self.BUTTON_INFO)
2273                                 self.motd_actived_time = time;
2274                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2275                                 self.motd_actived_time = 0;
2276                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2277                         }
2278                 } else {
2279                         if (self.BUTTON_INFO)
2280                                 self.motd_actived_time = time;
2281                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2282                                 self.motd_actived_time = 0;
2283                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2284                         }
2285                 }
2286         }
2287         else //if(self.motd_actived_time < 0) // just connected, motd is active
2288         {
2289                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2290                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2291                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2292                 {
2293                         // instanctly hide MOTD
2294                         self.motd_actived_time = 0;
2295                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2296                 }
2297         }
2298 }
2299
2300 void ObserverThink()
2301 {
2302         float prefered_movetype;
2303         if (self.flags & FL_JUMPRELEASED) {
2304                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2305                         self.flags &~= FL_JUMPRELEASED;
2306                         self.flags |= FL_SPAWNING;
2307                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2308                         self.flags &~= FL_JUMPRELEASED;
2309                         if(SpectateNext()) {
2310                                 self.classname = "spectator";
2311                         }
2312                 } else {
2313                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2314                         if (self.movetype != prefered_movetype)
2315                                 self.movetype = prefered_movetype;
2316                 }
2317         } else {
2318                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2319                         self.flags |= FL_JUMPRELEASED;
2320                         if(self.flags & FL_SPAWNING)
2321                         {
2322                                 self.flags &~= FL_SPAWNING;
2323                                 LeaveSpectatorMode();
2324                                 return;
2325                         }
2326                 }
2327         }
2328 }
2329
2330 void SpectatorThink()
2331 {
2332         if (self.flags & FL_JUMPRELEASED) {
2333                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2334                         self.flags &~= FL_JUMPRELEASED;
2335                         self.flags |= FL_SPAWNING;
2336                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209) {
2337                         self.flags &~= FL_JUMPRELEASED;
2338                         if(SpectateNext()) {
2339                                 self.classname = "spectator";
2340                         } else {
2341                                 self.classname = "observer";
2342                                 PutClientInServer();
2343                         }
2344                         self.impulse = 0;
2345                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229) {
2346                         self.flags &~= FL_JUMPRELEASED;
2347                         if(SpectatePrev()) {
2348                                 self.classname = "spectator";
2349                         } else {
2350                                 self.classname = "observer";
2351                                 PutClientInServer();
2352                         }
2353                         self.impulse = 0;
2354                 } else if (self.BUTTON_ATCK2) {
2355                         self.flags &~= FL_JUMPRELEASED;
2356                         self.classname = "observer";
2357                         PutClientInServer();
2358                 } else {
2359                         if(!SpectateUpdate())
2360                                 PutObserverInServer();
2361                 }
2362         } else {
2363                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2364                         self.flags |= FL_JUMPRELEASED;
2365                         if(self.flags & FL_SPAWNING)
2366                         {
2367                                 self.flags &~= FL_SPAWNING;
2368                                 LeaveSpectatorMode();
2369                                 return;
2370                         }
2371                 }
2372                 if(!SpectateUpdate())
2373                         PutObserverInServer();
2374         }
2375
2376         self.flags |= FL_CLIENT | FL_NOTARGET;
2377 }
2378
2379 void PlayerUseKey()
2380 {
2381         if(self.classname != "player")
2382                 return;
2383
2384         if(self.vehicle)
2385         {
2386         vehicles_exit(VHEF_NORMAL);
2387         return;
2388         }
2389
2390         // a use key was pressed; call handlers
2391         MUTATOR_CALLHOOK(PlayerUseKey);
2392 }
2393
2394 /*
2395 =============
2396 PlayerPreThink
2397
2398 Called every frame for each client before the physics are run
2399 =============
2400 */
2401 .float usekeypressed;
2402 void() nexball_setstatus;
2403 .float items_added;
2404 void PlayerPreThink (void)
2405 {
2406         WarpZone_PlayerPhysics_FixVAngle();
2407
2408         self.stat_game_starttime = game_starttime;
2409         self.stat_round_starttime = round_starttime;
2410         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2411         self.stat_leadlimit = autocvar_leadlimit;
2412
2413         if(frametime)
2414         {
2415                 // physics frames: update anticheat stuff
2416                 anticheat_prethink();
2417         }
2418
2419         if(blockSpectators && frametime)
2420                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2421                 checkSpectatorBlock();
2422
2423         zoomstate_set = 0;
2424
2425         if(self.netname_previous != self.netname)
2426         {
2427                 if(autocvar_sv_eventlog)
2428                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2429                 if(self.netname_previous)
2430                         strunzone(self.netname_previous);
2431                 self.netname_previous = strzone(self.netname);
2432         }
2433
2434         // version nagging
2435         if(self.version_nagtime)
2436                 if(self.cvar_g_xonoticversion)
2437                         if(time > self.version_nagtime)
2438                         {
2439                                 // don't notify git users
2440                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2441                                 {
2442                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2443                                         {
2444                                                 // notify release users if connecting to git
2445                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2446                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2447                                         }
2448                                         else
2449                                         {
2450                                                 float r;
2451                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2452                                                 if(r < 0)
2453                                                 {
2454                                                         // give users new version
2455                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2456                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2457                                                 }
2458                                                 else if(r > 0)
2459                                                 {
2460                                                         // notify users about old server version
2461                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2462                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2463                                                 }
2464                                         }
2465                                 }
2466                                 self.version_nagtime = 0;
2467                         }
2468
2469         // GOD MODE info
2470         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2471         {
2472                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2473                 self.max_armorvalue = 0;
2474         }
2475
2476 #ifdef TETRIS
2477         if (TetrisPreFrame())
2478                 return;
2479 #endif
2480
2481         MUTATOR_CALLHOOK(PlayerPreThink);
2482
2483         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2484         {
2485                 if(self.BUTTON_USE && !self.usekeypressed)
2486                         PlayerUseKey();
2487                 self.usekeypressed = self.BUTTON_USE;
2488         }
2489
2490         if(clienttype(self) == CLIENTTYPE_REAL)
2491                 PrintWelcomeMessage();
2492
2493         if(self.classname == "player") {
2494
2495                 CheckRules_Player();
2496
2497                 if (intermission_running)
2498                 {
2499                         IntermissionThink ();   // otherwise a button could be missed between
2500                         return;                                 // the think tics
2501                 }
2502
2503                 //don't allow the player to turn around while game is paused!
2504                 if(timeout_status == TIMEOUT_ACTIVE) {
2505                         // FIXME turn this into CSQC stuff
2506                         self.v_angle = self.lastV_angle;
2507                         self.angles = self.lastV_angle;
2508                         self.fixangle = TRUE;
2509                 }
2510
2511                 if(frametime)
2512                 {
2513                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2514                         {
2515                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2516                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2517                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2518
2519                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2520                                 {
2521                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2522                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2523                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2524                                 }
2525                         }
2526                         else
2527                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2528
2529                         player_powerups();
2530                 }
2531
2532                 if (self.deadflag != DEAD_NO)
2533                 {
2534                         if(self.personal && g_race_qualifying)
2535                         {
2536                                 if(time > self.respawn_time)
2537                                 {
2538                                         self.respawn_time = time + 1; // only retry once a second
2539                                         self.stat_respawn_time = self.respawn_time;
2540                                         respawn();
2541                                         self.impulse = 141;
2542                                 }
2543                         }
2544                         else
2545                         {
2546                                 float button_pressed;
2547                                 if(frametime)
2548                                         player_anim();
2549                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2550
2551                                 if (self.deadflag == DEAD_DYING)
2552                                 {
2553                                         if(self.respawn_flags & RESPAWN_FORCE)
2554                                                 self.deadflag = DEAD_RESPAWNING;
2555                                         else if(!button_pressed)
2556                                                 self.deadflag = DEAD_DEAD;
2557                                 }
2558                                 else if (self.deadflag == DEAD_DEAD)
2559                                 {
2560                                         if(button_pressed)
2561                                                 self.deadflag = DEAD_RESPAWNABLE;
2562                                 }
2563                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2564                                 {
2565                                         if(!button_pressed)
2566                                                 self.deadflag = DEAD_RESPAWNING;
2567                                 }
2568                                 else if (self.deadflag == DEAD_RESPAWNING)
2569                                 {
2570                                         if(time > self.respawn_time)
2571                                         {
2572                                                 self.respawn_time = time + 1; // only retry once a second
2573                                                 respawn();
2574                                         }
2575                                 }
2576
2577                                 ShowRespawnCountdown();
2578
2579                                 if(self.respawn_flags & RESPAWN_SILENT)
2580                                         self.stat_respawn_time = 0;
2581                                 else
2582                                         self.stat_respawn_time = self.respawn_time;
2583                         }
2584
2585                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2586                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2587                                 self.stat_respawn_time *= -1;
2588
2589                         return;
2590                 }
2591
2592                 self.prevorigin = self.origin;
2593
2594                 float do_crouch = self.BUTTON_CROUCH;
2595                 if(self.hook.state)
2596                         do_crouch = 0;
2597                 if(self.health <= g_bloodloss)
2598                         do_crouch = 1;
2599                 if(self.vehicle)
2600                         do_crouch = 0;
2601                 if(self.freezetag_frozen)
2602                         do_crouch = 0;
2603                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2604                         do_crouch = 0;
2605
2606                 if (do_crouch)
2607                 {
2608                         if (!self.crouch)
2609                         {
2610                                 self.crouch = TRUE;
2611                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2612                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2613                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2614                         }
2615                 }
2616                 else
2617                 {
2618                         if (self.crouch)
2619                         {
2620                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2621                                 if (!trace_startsolid)
2622                                 {
2623                                         self.crouch = FALSE;
2624                                         self.view_ofs = PL_VIEW_OFS;
2625                                         setsize (self, PL_MIN, PL_MAX);
2626                                 }
2627                         }
2628                 }
2629
2630                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2631                 {
2632                         if(self.bloodloss_timer < time)
2633                         {
2634                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2635                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2636                         }
2637                 }
2638
2639                 FixPlayermodel();
2640
2641                 GrapplingHookFrame();
2642
2643                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2644                 //if(frametime)
2645                 {
2646                         self.items &~= self.items_added;
2647
2648                         W_WeaponFrame();
2649
2650                         self.items_added = 0;
2651                         if(self.items & IT_JETPACK)
2652                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2653                                         self.items_added |= IT_FUEL;
2654
2655                         self.items |= self.items_added;
2656                 }
2657
2658                 player_regen();
2659
2660                 // rot nex charge to the charge limit
2661                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2662                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2663
2664                 if(frametime)
2665                         player_anim();
2666
2667                 if(g_nexball)
2668                         nexball_setstatus();
2669
2670                 // secret status
2671                 secrets_setstatus();
2672
2673                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2674
2675                 //self.angles_y=self.v_angle_y + 90;   // temp
2676         } else if(gameover) {
2677                 if (intermission_running)
2678                         IntermissionThink ();   // otherwise a button could be missed between
2679                 return;
2680         } else if(self.classname == "observer") {
2681                 ObserverThink();
2682         } else if(self.classname == "spectator") {
2683                 SpectatorThink();
2684         }
2685
2686         if(!zoomstate_set)
2687                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2688
2689         float oldspectatee_status;
2690         oldspectatee_status = self.spectatee_status;
2691         if(self.classname == "spectator")
2692                 self.spectatee_status = num_for_edict(self.enemy);
2693         else if(self.classname == "observer")
2694                 self.spectatee_status = num_for_edict(self);
2695         else
2696                 self.spectatee_status = 0;
2697         if(self.spectatee_status != oldspectatee_status)
2698         {
2699                 ClientData_Touch(self);
2700                 if(g_race || g_cts)
2701                         race_InitSpectator();
2702         }
2703
2704         if(self.teamkill_soundtime)
2705         if(time > self.teamkill_soundtime)
2706         {
2707                 self.teamkill_soundtime = 0;
2708
2709                 entity oldpusher, oldself;
2710
2711                 oldself = self; self = self.teamkill_soundsource;
2712                 oldpusher = self.pusher; self.pusher = oldself;
2713
2714                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2715
2716                 self.pusher = oldpusher;
2717                 self = oldself;
2718         }
2719
2720         if(self.taunt_soundtime)
2721         if(time > self.taunt_soundtime)
2722         {
2723                 self.taunt_soundtime = 0;
2724                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2725         }
2726
2727         target_voicescript_next(self);
2728
2729         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2730         if(!self.weapon)
2731                 self.clip_load = self.clip_size = 0;
2732 }
2733
2734 float isInvisibleString(string s)
2735 {
2736         float i, n, c;
2737         s = strdecolorize(s);
2738         for((i = 0), (n = strlen(s)); i < n; ++i)
2739         {
2740                 c = str2chr(s, i);
2741                 switch(c)
2742                 {
2743                         case 0:
2744                         case 32: // space
2745                                 break;
2746                         case 192: // charmap space
2747                                 if (!autocvar_utf8_enable)
2748                                         break;
2749                                 return FALSE;
2750                         case 160: // space in unicode fonts
2751                         case 0xE000 + 192: // utf8 charmap space
2752                                 if (autocvar_utf8_enable)
2753                                         break;
2754                         default:
2755                                 return FALSE;
2756                 }
2757         }
2758         return TRUE;
2759 }
2760
2761 /*
2762 =============
2763 PlayerPostThink
2764
2765 Called every frame for each client after the physics are run
2766 =============
2767 */
2768 .float idlekick_lasttimeleft;
2769 void PlayerPostThink (void)
2770 {
2771         // Savage: Check for nameless players
2772         if (isInvisibleString(self.netname)) {
2773                 self.netname = "Player";
2774                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2775         }
2776
2777         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2778         {
2779                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2780                 {
2781                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2782                 }
2783                 else
2784                 {
2785                         float timeleft;
2786                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2787                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2788                         {
2789                                 if(!self.idlekick_lasttimeleft)
2790                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2791                         }
2792                         if(timeleft <= 0)
2793                         {
2794                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2795                                 dropclient(self);
2796                                 return;
2797                         }
2798                         else if(timeleft <= 10)
2799                         {
2800                                 if(timeleft != self.idlekick_lasttimeleft)
2801                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2802                                 self.idlekick_lasttimeleft = timeleft;
2803                         }
2804                 }
2805         }
2806
2807 #ifdef TETRIS
2808         if(self.impulse == 100)
2809                 ImpulseCommands();
2810         if (!TetrisPostFrame())
2811         {
2812 #endif
2813
2814         CheatFrame();
2815
2816         //CheckPlayerJump();
2817
2818         if(self.classname == "player") {
2819                 CheckRules_Player();
2820                 UpdateChatBubble();
2821                 if (self.impulse)
2822                         ImpulseCommands();
2823                 if (intermission_running)
2824                         return;         // intermission or finale
2825                 GetPressedKeys();
2826         }
2827
2828 #ifdef TETRIS
2829         }
2830 #endif
2831
2832         /*
2833         float i;
2834         for(i = 0; i < 1000; ++i)
2835         {
2836                 vector end;
2837                 end = self.origin + '0 0 1024' + 512 * randomvec();
2838                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2839                 if(trace_fraction < 1)
2840                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2841                 {
2842                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2843                         break;
2844                 }
2845         }
2846         */
2847
2848         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2849
2850         if(self.waypointsprite_attachedforcarrier)
2851                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2852
2853         playerdemo_write();
2854
2855         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2856         {
2857                 if not(self.stored_netname)
2858                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2859                 if(self.stored_netname != self.netname)
2860                 {
2861                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2862                         strunzone(self.stored_netname);
2863                         self.stored_netname = strzone(self.netname);
2864                 }
2865         }
2866
2867         /*
2868         if(g_race)
2869                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2870         */
2871
2872         CSQCMODEL_AUTOUPDATE();
2873 }