qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         if (g_minstagib)
 408                 minstagib_stop_countdown();
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419             vehicles_exit(VHEF_RELESE);
 420
 421         if(self.flagcarried)
 422                 DropFlag(self.flagcarried, world, world);
 423
 424         if(self.ballcarried && g_nexball)
 425                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 426
 427         WaypointSprite_PlayerDead();
 428
 429         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 430                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 431
 432         if(self.killcount != -666) {
 433                 if(g_lms) {
 434                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 435                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 436                         else
 437                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 438                 } else
 439                         bprint ("^4", self.netname, "^4 is spectating now\n");
 440
 441                 if(self.just_joined == FALSE) {
 442                         LogTeamchange(self.playerid, -1, 4);
 443                 } else
 444                         self.just_joined = FALSE;
 445         }
 446
 447         PlayerScore_Clear(self); // clear scores when needed
 448
 449         accuracy_resend(self);
 450
 451         self.spectatortime = time;
 452
 453         self.classname = "observer";
 454         self.iscreature = FALSE;
 455         self.damagedbycontents = FALSE;
 456         self.health = -666;
 457         self.takedamage = DAMAGE_NO;
 458         self.solid = SOLID_NOT;
 459         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 460         self.flags = FL_CLIENT | FL_NOTARGET;
 461         self.armorvalue = 666;
 462         self.effects = 0;
 463         self.armorvalue = autocvar_g_balance_armor_start;
 464         self.pauserotarmor_finished = 0;
 465         self.pauserothealth_finished = 0;
 466         self.pauseregen_finished = 0;
 467         self.damageforcescale = 0;
 468         self.death_time = 0;
 469         self.respawn_time = 0;
 470         self.alpha = 0;
 471         self.scale = 0;
 472         self.fade_time = 0;
 473         self.pain_frame = 0;
 474         self.pain_finished = 0;
 475         self.strength_finished = 0;
 476         self.invincible_finished = 0;
 477         self.superweapons_finished = 0;
 478         self.pushltime = 0;
 479         self.think = SUB_Null;
 480         self.nextthink = 0;
 481         self.hook_time = 0;
 482         self.runes = 0;
 483         self.deadflag = DEAD_NO;
 484         self.angles = spot.angles;
 485         self.angles_z = 0;
 486         self.fixangle = TRUE;
 487         self.crouch = FALSE;
 488
 489         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 490         self.prevorigin = self.origin;
 491         self.items = 0;
 492         self.weapons = 0;
 493         self.model = "";
 494         FixPlayermodel();
 495         setmodel(self, "null");
 496         self.drawonlytoclient = self;
 497
 498         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 499         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 500
 501         self.weapon = 0;
 502         self.weaponname = "";
 503         self.switchingweapon = 0;
 504         self.weaponmodel = "";
 505         self.weaponentity = world;
 506         self.exteriorweaponentity = world;
 507         self.killcount = -666;
 508         self.velocity = '0 0 0';
 509         self.avelocity = '0 0 0';
 510         self.punchangle = '0 0 0';
 511         self.punchvector = '0 0 0';
 512         self.oldvelocity = self.velocity;
 513         self.fire_endtime = -1;
 514
 515         if(g_arena)
 516         {
 517                 if(self.version_mismatch)
 518                 {
 519                         Spawnqueue_Unmark(self);
 520                         Spawnqueue_Remove(self);
 521                 }
 522                 else
 523                 {
 524                         Spawnqueue_Insert(self);
 525                 }
 526         }
 527         else if(g_lms)
 528         {
 529                 // Only if the player cannot play at all
 530                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 531                         self.frags = FRAGS_SPECTATOR;
 532                 else
 533                         self.frags = FRAGS_LMS_LOSER;
 534         }
 535         else if(g_ca)
 536         {
 537                 if(self.caplayer)
 538                         self.frags = FRAGS_LMS_LOSER;
 539                 else
 540                         self.frags = FRAGS_SPECTATOR;
 541         }
 542         else
 543                 self.frags = FRAGS_SPECTATOR;
 544 }
 545
 546 .float model_randomizer;
 547 void FixPlayermodel()
 548 {
 549         string defaultmodel;
 550         float defaultskin, chmdl, oldskin, n, i;
 551         vector m1, m2;
 552
 553         defaultmodel = "";
 554
 555         if(autocvar_sv_defaultcharacter == 1)
 556         {
 557                 defaultskin = 0;
 558
 559                 if(teamplay)
 560                 {
 561                         string s;
 562                         s = Team_ColorNameLowerCase(self.team);
 563                         if(s != "neutral")
 564                         {
 565                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 566                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 567                         }
 568                 }
 569
 570                 if(defaultmodel == "")
 571                 {
 572                         defaultmodel = autocvar_sv_defaultplayermodel;
 573                         defaultskin = autocvar_sv_defaultplayerskin;
 574                 }
 575
 576                 n = tokenize_console(defaultmodel);
 577                 if(n > 0)
 578                         defaultmodel = argv(floor(n * self.model_randomizer));
 579
 580                 i = strstrofs(defaultmodel, ":", 0);
 581                 if(i >= 0)
 582                 {
 583                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 584                         defaultmodel = substring(defaultmodel, 0, i);
 585                 }
 586         }
 587
 588         if(defaultmodel != "")
 589         {
 590                 if (defaultmodel != self.model)
 591                 {
 592                         m1 = self.mins;
 593                         m2 = self.maxs;
 594                         setplayermodel (self, defaultmodel);
 595                         setsize (self, m1, m2);
 596                         chmdl = TRUE;
 597                 }
 598
 599                 oldskin = self.skin;
 600                 self.skin = defaultskin;
 601         } else {
 602                 if (self.playermodel != self.model || self.playermodel == "")
 603                 {
 604                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 605                         m1 = self.mins;
 606                         m2 = self.maxs;
 607                         setplayermodel (self, self.playermodel);
 608                         setsize (self, m1, m2);
 609                         chmdl = TRUE;
 610                 }
 611
 612                 oldskin = self.skin;
 613                 self.skin = stof(self.playerskin);
 614         }
 615
 616         if(chmdl || oldskin != self.skin)
 617                 self.species = player_getspecies(); // model or skin has changed
 618
 619         if(!teamplay)
 620                 if(strlen(autocvar_sv_defaultplayercolors))
 621                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 622                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 623 }
 624
 625 void PlayerTouchExplode(entity p1, entity p2)
 626 {
 627         vector org;
 628         org = (p1.origin + p2.origin) * 0.5;
 629         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 630
 631         te_explosion(org);
 632
 633         entity e;
 634         e = spawn();
 635         setorigin(e, org);
 636         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 637         remove(e);
 638 }
 639
 640 /*
 641 =============
 642 PutClientInServer
 643
 644 Called when a client spawns in the server
 645 =============
 646 */
 647 //void() ctf_playerchanged;
 648 void PutClientInServer (void)
 649 {
 650         if(clienttype(self) == CLIENTTYPE_BOT)
 651         {
 652                 self.classname = "player";
 653         }
 654         else if(clienttype(self) == CLIENTTYPE_REAL)
 655         {
 656                 msg_entity = self;
 657                 WriteByte(MSG_ONE, SVC_SETVIEW);
 658                 WriteEntity(MSG_ONE, self);
 659         }
 660
 661         // reset player keys
 662         self.itemkeys = 0;
 663
 664         // player is dead and becomes observer
 665         // FIXME fix LMS scoring for new system
 666         if(g_lms)
 667         {
 668                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 669                         self.classname = "observer";
 670         }
 671
 672         if(g_arena || (g_ca && !allowed_to_spawn))
 673         if(!self.spawned)
 674                 self.classname = "observer";
 675
 676         if(gameover)
 677                 self.classname = "observer";
 678
 679         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 680                 entity spot, oldself;
 681                 float j;
 682
 683                 accuracy_resend(self);
 684
 685                 if(self.team < 0)
 686                         JoinBestTeam(self, FALSE, TRUE);
 687
 688                 race_PreSpawn();
 689
 690                 spot = SelectSpawnPoint (FALSE);
 691                 if(!spot)
 692                 {
 693                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 694                         return; // spawn failed
 695                 }
 696
 697                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 698
 699                 self.classname = "player";
 700                 self.wasplayer = TRUE;
 701                 self.iscreature = TRUE;
 702                 self.damagedbycontents = TRUE;
 703                 self.movetype = MOVETYPE_WALK;
 704                 self.solid = SOLID_SLIDEBOX;
 705                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 706                 if(autocvar_g_playerclip_collisions)
 707                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 708                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 709                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 710                 self.frags = FRAGS_PLAYER;
 711                 if(INDEPENDENT_PLAYERS)
 712                         MAKE_INDEPENDENT_PLAYER(self);
 713                 self.flags = FL_CLIENT;
 714                 if(autocvar__notarget)
 715                         self.flags |= FL_NOTARGET;
 716                 self.takedamage = DAMAGE_AIM;
 717                 if(g_minstagib)
 718                         self.effects = EF_FULLBRIGHT;
 719                 else
 720                         self.effects = 0;
 721                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 722                 self.air_finished = time + 12;
 723                 self.dmg = 2;
 724                 if(autocvar_g_balance_nex_charge)
 725                 {
 726                         if(autocvar_g_balance_nex_secondary_chargepool)
 727                                 self.nex_chargepool_ammo = 1;
 728                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 729                 }
 730
 731                 if(inWarmupStage)
 732                 {
 733                         self.ammo_shells = warmup_start_ammo_shells;
 734                         self.ammo_nails = warmup_start_ammo_nails;
 735                         self.ammo_rockets = warmup_start_ammo_rockets;
 736                         self.ammo_cells = warmup_start_ammo_cells;
 737                         self.ammo_fuel = warmup_start_ammo_fuel;
 738                         self.health = warmup_start_health;
 739                         self.armorvalue = warmup_start_armorvalue;
 740                         self.weapons = warmup_start_weapons;
 741                 }
 742                 else
 743                 {
 744                         self.ammo_shells = start_ammo_shells;
 745                         self.ammo_nails = start_ammo_nails;
 746                         self.ammo_rockets = start_ammo_rockets;
 747                         self.ammo_cells = start_ammo_cells;
 748                         self.ammo_fuel = start_ammo_fuel;
 749                         self.health = start_health;
 750                         self.armorvalue = start_armorvalue;
 751                         self.weapons = start_weapons;
 752                 }
 753
 754                 if(self.weapons & WEPBIT_SUPERWEAPONS) // exception for minstagib, as minstanex is a superweapon
 755                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 756                 else
 757                         self.superweapons_finished = 0;
 758
 759                 if(g_weaponarena_random)
 760                 {
 761                         if(g_weaponarena_random_with_laser)
 762                                 self.weapons &~= WEPBIT_LASER;
 763                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 764                         if(g_weaponarena_random_with_laser)
 765                                 self.weapons |= WEPBIT_LASER;
 766                 }
 767
 768                 self.items = start_items;
 769
 770                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 771                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 772                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 773                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 774                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 775                 //extend the pause of rotting if client was reset at the beginning of the countdown
 776                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 777                         self.spawnshieldtime += game_starttime - time;
 778                         self.pauserotarmor_finished += game_starttime - time;
 779                         self.pauserothealth_finished += game_starttime - time;
 780                         self.pauseregen_finished += game_starttime - time;
 781                 }
 782                 self.damageforcescale = 2;
 783                 self.death_time = 0;
 784                 self.respawn_time = 0;
 785                 self.scale = 0;
 786                 self.fade_time = 0;
 787                 self.pain_frame = 0;
 788                 self.pain_finished = 0;
 789                 self.strength_finished = 0;
 790                 self.invincible_finished = 0;
 791                 self.pushltime = 0;
 792                 // players have no think function
 793                 self.think = SUB_Null;
 794                 self.nextthink = 0;
 795                 self.hook_time = 0;
 796                 self.dmg_team = 0;
 797                 self.ballistics_density = autocvar_g_ballistics_density_player;
 798
 799                 self.metertime = 0;
 800
 801                 self.runes = 0;
 802
 803                 self.deadflag = DEAD_NO;
 804
 805                 self.angles = spot.angles;
 806
 807                 self.angles_z = 0; // never spawn tilted even if the spot says to
 808                 self.fixangle = TRUE; // turn this way immediately
 809                 self.velocity = '0 0 0';
 810                 self.avelocity = '0 0 0';
 811                 self.punchangle = '0 0 0';
 812                 self.punchvector = '0 0 0';
 813                 self.oldvelocity = self.velocity;
 814                 self.fire_endtime = -1;
 815
 816                 msg_entity = self;
 817                 WRITESPECTATABLE_MSG_ONE({
 818                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 819                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 820                 });
 821
 822                 self.model = "";
 823                 FixPlayermodel();
 824                 self.drawonlytoclient = world;
 825
 826                 self.crouch = FALSE;
 827                 self.view_ofs = PL_VIEW_OFS;
 828                 setsize (self, PL_MIN, PL_MAX);
 829                 self.spawnorigin = spot.origin;
 830                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 831                 // don't reset back to last position, even if new position is stuck in solid
 832                 self.oldorigin = self.origin;
 833                 self.prevorigin = self.origin;
 834                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 835                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 836         self.hud = HUD_NORMAL;
 837
 838                 if(g_arena)
 839                 {
 840                         Spawnqueue_Remove(self);
 841                         Spawnqueue_Mark(self);
 842                 }
 843
 844                 else if(g_ca)
 845                         self.caplayer = 1;
 846
 847                 self.event_damage = PlayerDamage;
 848
 849                 self.bot_attack = TRUE;
 850
 851                 self.statdraintime = time + 5;
 852                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 853
 854                 if(self.killcount == -666) {
 855                         PlayerScore_Clear(self);
 856                         self.killcount = 0;
 857                 }
 858
 859                 CL_SpawnWeaponentity();
 860                 self.alpha = default_player_alpha;
 861                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 862                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 863
 864                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 865                 self.lms_traveled_distance = 0;
 866                 self.speedrunning = FALSE;
 867
 868                 race_PostSpawn(spot);
 869
 870                 //stuffcmd(self, "chase_active 0");
 871                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 872
 873                 if (autocvar_g_spawnsound)
 874                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 875
 876                 if(g_assault) {
 877                         if(self.team == assault_attacker_team)
 878                                 centerprint(self, "You are attacking!");
 879                         else
 880                                 centerprint(self, "You are defending!");
 881                 }
 882
 883                 target_voicescript_clear(self);
 884
 885                 // reset fields the weapons may use
 886                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 887                 {
 888                         weapon_action(j, WR_RESETPLAYER);
 889
 890                         // all weapons must be fully loaded when we spawn
 891                         entity e;
 892                         e = get_weaponinfo(j);
 893                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 894                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 895                 }
 896
 897                 oldself = self;
 898                 self = spot;
 899                         activator = oldself;
 900                                 string s;
 901                                 s = self.target;
 902                                 self.target = string_null;
 903                                 SUB_UseTargets();
 904                                 self.target = s;
 905                         activator = world;
 906                 self = oldself;
 907
 908                 spawn_spot = spot;
 909                 MUTATOR_CALLHOOK(PlayerSpawn);
 910
 911                 if(autocvar_spawn_debug)
 912                 {
 913                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 914                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 915                 }
 916
 917                 self.switchweapon = w_getbestweapon(self);
 918                 self.cnt = -1; // W_LastWeapon will not complain
 919                 self.weapon = 0;
 920                 self.weaponname = "";
 921                 self.switchingweapon = 0;
 922
 923                 if(!self.alivetime)
 924                         self.alivetime = time;
 925
 926                 antilag_clear(self);
 927         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
 928                 PutObserverInServer ();
 929         }
 930
 931         //if(g_ctf)
 932         //      ctf_playerchanged();
 933 }
 934
 935 .float ebouncefactor, ebouncestop; // electro's values
 936 // TODO do we need all these fields, or should we stop autodetecting runtime
 937 // changes and just have a console command to update this?
 938 float ClientInit_SendEntity(entity to, float sf)
 939 {
 940         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 941         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 951         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 952         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 953         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 954         if(sv_foginterval && world.fog != "")
 955                 WriteString(MSG_ENTITY, world.fog);
 956         else
 957                 WriteString(MSG_ENTITY, "");
 958         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 959         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 960         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 961         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 962         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 963         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 964         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 965         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 966         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 967         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 968         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 969         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 970         return TRUE;
 971 }
 972
 973 void ClientInit_CheckUpdate()
 974 {
 975         self.nextthink = time;
 976         if(self.count != autocvar_g_balance_armor_blockpercent)
 977         {
 978                 self.count = autocvar_g_balance_armor_blockpercent;
 979                 self.SendFlags |= 1;
 980         }
 981         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 982         {
 983                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 984                 self.SendFlags |= 1;
 985         }
 986         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 987         {
 988                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 989                 self.SendFlags |= 1;
 990         }
 991         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 992         {
 993                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 994                 self.SendFlags |= 1;
 995         }
 996         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 997         {
 998                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 999                 self.SendFlags |= 1;
1000         }
1001         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1002         {
1003                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1004                 self.SendFlags |= 1;
1005         }
1006 }
1007
1008 void ClientInit_Spawn()
1009 {
1010         entity o;
1011         entity e;
1012         e = spawn();
1013         e.classname = "clientinit";
1014         e.think = ClientInit_CheckUpdate;
1015         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1016
1017         o = self;
1018         self = e;
1019         ClientInit_CheckUpdate();
1020         self = o;
1021 }
1022
1023 /*
1024 =============
1025 SetNewParms
1026 =============
1027 */
1028 void SetNewParms (void)
1029 {
1030         // initialize parms for a new player
1031         parm1 = -(86400 * 366);
1032 }
1033
1034 /*
1035 =============
1036 SetChangeParms
1037 =============
1038 */
1039 void SetChangeParms (void)
1040 {
1041         // save parms for level change
1042         parm1 = self.parm_idlesince - time;
1043 }
1044
1045 /*
1046 =============
1047 DecodeLevelParms
1048 =============
1049 */
1050 void DecodeLevelParms (void)
1051 {
1052         // load parms
1053         self.parm_idlesince = parm1;
1054         if(self.parm_idlesince == -(86400 * 366))
1055                 self.parm_idlesince = time;
1056
1057         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1058         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1059 }
1060
1061 /*
1062 =============
1063 ClientKill
1064
1065 Called when a client types 'kill' in the console
1066 =============
1067 */
1068
1069 .float clientkill_nexttime;
1070 void ClientKill_Now_TeamChange()
1071 {
1072         if(self.killindicator_teamchange == -1)
1073         {
1074                 self.team = -1;
1075                 JoinBestTeam( self, FALSE, FALSE );
1076         }
1077         else if(self.killindicator_teamchange == -2)
1078         {
1079                 if(g_ca)
1080                         self.caplayer = 0;
1081                 if(blockSpectators)
1082                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1083                 PutObserverInServer();
1084         }
1085         else
1086                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1087 }
1088
1089 void ClientKill_Now()
1090 {
1091         if(self.vehicle)
1092         {
1093             vehicles_exit(VHEF_RELESE);
1094             if(!self.killindicator_teamchange)
1095             {
1096             self.vehicle_health = -1;
1097             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1098             }
1099         }
1100
1101         if(self.killindicator && !wasfreed(self.killindicator))
1102                 remove(self.killindicator);
1103
1104         self.killindicator = world;
1105
1106         if(self.killindicator_teamchange)
1107                 ClientKill_Now_TeamChange();
1108
1109         // in any case:
1110         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1111
1112         // now I am sure the player IS dead
1113 }
1114 void KillIndicator_Think()
1115 {
1116         if (gameover)
1117         {
1118                 self.owner.killindicator = world;
1119                 remove(self);
1120                 return;
1121         }
1122
1123         if (self.owner.alpha < 0)
1124         {
1125                 self.owner.killindicator = world;
1126                 remove(self);
1127                 return;
1128         }
1129
1130         if(self.cnt <= 0)
1131         {
1132                 self = self.owner;
1133                 ClientKill_Now(); // no oldself needed
1134                 return;
1135         }
1136     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1137     {
1138         self.nextthink = time + 1;
1139         self.cnt -= 1;
1140     }
1141         else
1142         {
1143                 if(self.cnt <= 10)
1144                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1145                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1146                 {
1147                         if(self.cnt <= 10)
1148                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1149                 }
1150                 self.nextthink = time + 1;
1151                 self.cnt -= 1;
1152         }
1153 }
1154
1155 float clientkilltime;
1156 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1157 {
1158         float killtime;
1159         float starttime;
1160         entity e;
1161
1162         if (gameover)
1163                 return;
1164
1165         killtime = autocvar_g_balance_kill_delay;
1166
1167         if(g_race_qualifying || g_cts)
1168                 killtime = 0;
1169
1170     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1171     {
1172                 remove(self.killindicator);
1173                 self.killindicator = world;
1174
1175         ClientKill_Now(); // allow instant kill in this case
1176         return;
1177     }
1178
1179         self.killindicator_teamchange = targetteam;
1180
1181     if(!self.killindicator)
1182         {
1183                 if(self.deadflag == DEAD_NO)
1184                 {
1185                         killtime = max(killtime, self.clientkill_nexttime - time);
1186                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1187                 }
1188
1189                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1190                 {
1191                         ClientKill_Now();
1192                 }
1193                 else
1194                 {
1195                         starttime = max(time, clientkilltime);
1196
1197                         self.killindicator = spawn();
1198                         self.killindicator.owner = self;
1199                         self.killindicator.scale = 0.5;
1200                         setattachment(self.killindicator, self, "");
1201                         setorigin(self.killindicator, '0 0 52');
1202                         self.killindicator.think = KillIndicator_Think;
1203                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1204                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1205                         self.killindicator.cnt = ceil(killtime);
1206                         self.killindicator.count = bound(0, ceil(killtime), 10);
1207                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1208
1209                         for(e = world; (e = find(e, classname, "body")) != world; )
1210                         {
1211                                 if(e.enemy != self)
1212                                         continue;
1213                                 e.killindicator = spawn();
1214                                 e.killindicator.owner = e;
1215                                 e.killindicator.scale = 0.5;
1216                                 setattachment(e.killindicator, e, "");
1217                                 setorigin(e.killindicator, '0 0 52');
1218                                 e.killindicator.think = KillIndicator_Think;
1219                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1220                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1221                                 e.killindicator.cnt = ceil(killtime);
1222                         }
1223                         self.lip = 0;
1224                 }
1225         }
1226         if(self.killindicator)
1227         {
1228                 if(targetteam == 0) // just die
1229                 {
1230                         self.killindicator.colormod = '0 0 0';
1231                         if(clienttype(self) == CLIENTTYPE_REAL)
1232                         if(self.killindicator.cnt > 0)
1233                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1234                 }
1235                 else if(targetteam == -1) // auto
1236                 {
1237                         self.killindicator.colormod = '0 1 0';
1238                         if(clienttype(self) == CLIENTTYPE_REAL)
1239                         if(self.killindicator.cnt > 0)
1240                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1241                 }
1242                 else if(targetteam == -2) // spectate
1243                 {
1244                         self.killindicator.colormod = '0.5 0.5 0.5';
1245                         if(clienttype(self) == CLIENTTYPE_REAL)
1246                         if(self.killindicator.cnt > 0)
1247                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1248                 }
1249                 else
1250                 {
1251                         self.killindicator.colormod = TeamColor(targetteam);
1252                         if(clienttype(self) == CLIENTTYPE_REAL)
1253                         if(self.killindicator.cnt > 0)
1254                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1255                 }
1256         }
1257
1258 }
1259
1260 void ClientKill (void)
1261 {
1262         if (gameover)
1263                 return;
1264
1265         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1266         {
1267                 // do nothing
1268         }
1269     else if(self.freezetag_frozen)
1270     {
1271         // do nothing
1272     }
1273         else
1274                 ClientKill_TeamChange(0);
1275 }
1276
1277 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1278 {
1279     e.killindicator = spawn();
1280     e.killindicator.owner = e;
1281     e.killindicator.think = KillIndicator_Think;
1282     e.killindicator.nextthink = time + (e.lip) * 0.05;
1283     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1284     e.killindicator.health = 1; // this is used to indicate that it should be silent
1285     e.lip = 0;
1286 }
1287
1288 void FixClientCvars(entity e)
1289 {
1290         // send prediction settings to the client
1291         stuffcmd(e, "\nin_bindmap 0 0\n");
1292         if(g_race || g_cts)
1293                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1294         if(autocvar_g_antilag == 3) // client side hitscan
1295                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1296         if(sv_gentle)
1297                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1298         /*
1299          * we no longer need to stuff this. Remove this comment block if you feel
1300          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1301         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1302         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1303         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1304         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1305         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1306         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1307         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1308         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1309         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1310         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1311         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1312         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1313         stuffcmd(e, "cl_movement_edgefriction 1\n");
1314          */
1315 }
1316
1317 float PlayerInIDList(entity p, string idlist)
1318 {
1319         float n, i;
1320         string s;
1321
1322         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1323         if not(p.crypto_idfp)
1324                 return 0;
1325
1326         // this function allows abbreviated player IDs too!
1327         n = tokenize_console(idlist);
1328         for(i = 0; i < n; ++i)
1329         {
1330                 s = argv(i);
1331                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1332                         return 1;
1333         }
1334
1335         return 0;
1336 }
1337
1338 /*
1339 =============
1340 ClientConnect
1341
1342 Called when a client connects to the server
1343 =============
1344 */
1345 //void ctf_clientconnect();
1346 string ColoredTeamName(float t);
1347 void DecodeLevelParms (void);
1348 //void dom_player_join_team(entity pl);
1349 void set_dom_state(entity e);
1350 void ClientConnect (void)
1351 {
1352         float t;
1353
1354         if(self.flags & FL_CLIENT)
1355         {
1356                 print("Warning: ClientConnect, but already connected!\n");
1357                 return;
1358         }
1359
1360         if(Ban_MaybeEnforceBan(self))
1361                 return;
1362
1363         DecodeLevelParms();
1364
1365 #ifdef WATERMARK
1366         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1367 #endif
1368
1369         self.classname = "player_joining";
1370
1371         self.flags = FL_CLIENT;
1372         self.version_nagtime = time + 10 + random() * 10;
1373
1374         if(player_count<0)
1375         {
1376                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1377                 player_count = 0;
1378         }
1379
1380         PlayerScore_Attach(self);
1381         ClientData_Attach();
1382         accuracy_init(self);
1383
1384         bot_clientconnect();
1385
1386         playerdemo_init();
1387
1388         anticheat_init();
1389
1390         race_PreSpawnObserver();
1391
1392         //if(g_domination)
1393         //      dom_player_join_team(self);
1394
1395         // identify the right forced team
1396         if(autocvar_g_campaign)
1397         {
1398                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1399                 {
1400                         switch(autocvar_g_campaign_forceteam)
1401                         {
1402                                 case 1: self.team_forced = COLOR_TEAM1; break;
1403                                 case 2: self.team_forced = COLOR_TEAM2; break;
1404                                 case 3: self.team_forced = COLOR_TEAM3; break;
1405                                 case 4: self.team_forced = COLOR_TEAM4; break;
1406                                 default: self.team_forced = 0;
1407                         }
1408                 }
1409         }
1410         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1411                 self.team_forced = COLOR_TEAM1;
1412         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1413                 self.team_forced = COLOR_TEAM2;
1414         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1415                 self.team_forced = COLOR_TEAM3;
1416         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1417                 self.team_forced = COLOR_TEAM4;
1418         else if(autocvar_g_forced_team_otherwise == "red")
1419                 self.team_forced = COLOR_TEAM1;
1420         else if(autocvar_g_forced_team_otherwise == "blue")
1421                 self.team_forced = COLOR_TEAM2;
1422         else if(autocvar_g_forced_team_otherwise == "yellow")
1423                 self.team_forced = COLOR_TEAM3;
1424         else if(autocvar_g_forced_team_otherwise == "pink")
1425                 self.team_forced = COLOR_TEAM4;
1426         else if(autocvar_g_forced_team_otherwise == "spectate")
1427                 self.team_forced = -1;
1428         else if(autocvar_g_forced_team_otherwise == "spectator")
1429                 self.team_forced = -1;
1430         else
1431                 self.team_forced = 0;
1432
1433         if(!teamplay)
1434                 if(self.team_forced > 0)
1435                         self.team_forced = 0;
1436
1437         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1438
1439         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1440                 self.classname = "observer";
1441         } else {
1442                 if(teamplay)
1443                 {
1444                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1445                         {
1446                                 self.classname = "player";
1447                                 campaign_bots_may_start = 1;
1448                         }
1449                         else
1450                         {
1451                                 self.classname = "observer"; // do it anyway
1452                         }
1453                 }
1454                 else
1455                 {
1456                         self.classname = "player";
1457                         campaign_bots_may_start = 1;
1458                 }
1459         }
1460
1461         self.playerid = (playerid_last = playerid_last + 1);
1462
1463         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1464
1465     if(clienttype(self) == CLIENTTYPE_BOT)
1466         PlayerStats_AddPlayer(self);
1467
1468         if(autocvar_sv_eventlog)
1469                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1470
1471         LogTeamchange(self.playerid, self.team, 1);
1472
1473         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1474
1475         self.netname_previous = strzone(self.netname);
1476
1477         bprint("^4", self.netname, "^4 connected");
1478
1479         if(self.classname != "observer" && (g_domination || g_ctf))
1480                 bprint(" and joined the ", ColoredTeamName(self.team));
1481
1482         bprint("\n");
1483
1484         stuffcmd(self, strcat(clientstuff, "\n"));
1485         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1486
1487         FixClientCvars(self);
1488
1489         // spawnfunc_waypoint sprites
1490         WaypointSprite_InitClient(self);
1491
1492         // Wazat's grappling hook
1493         SetGrappleHookBindings();
1494
1495         // get version info from player
1496         stuffcmd(self, "cmd clientversion $gameversion\n");
1497
1498         // get other cvars from player
1499         GetCvars(0);
1500
1501         // notify about available teams
1502         if(teamplay)
1503         {
1504                 CheckAllowedTeams(self);
1505                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1506                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1507         }
1508         else
1509                 stuffcmd(self, "set _teams_available 0\n");
1510
1511         if(g_arena || g_ca)
1512         {
1513                 self.classname = "observer";
1514                 if(g_arena)
1515                         Spawnqueue_Insert(self);
1516         }
1517         /*else if(g_ctf)
1518         {
1519                 ctf_clientconnect();
1520         }*/
1521
1522         attach_entcs();
1523
1524         bot_relinkplayerlist();
1525
1526         self.spectatortime = time;
1527         if(blockSpectators)
1528         {
1529                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1530         }
1531
1532         self.jointime = time;
1533         self.allowed_timeouts = autocvar_sv_timeout_number;
1534
1535         if(clienttype(self) == CLIENTTYPE_REAL)
1536         {
1537                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1538                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1539         }
1540
1541         if(g_lms)
1542         {
1543                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1544                 {
1545                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1546                         self.frags = FRAGS_SPECTATOR;
1547                 }
1548         }
1549
1550         if(!sv_foginterval && world.fog != "")
1551                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1552
1553         SoundEntity_Attach(self);
1554
1555         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1556         {
1557                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1558                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1559         }
1560         else
1561                 self.hitplotfh = -1;
1562
1563         if(g_race || g_cts) {
1564                 string rr;
1565                 if(g_cts)
1566                         rr = CTS_RECORD;
1567                 else
1568                         rr = RACE_RECORD;
1569                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1570
1571                 msg_entity = self;
1572                 race_send_recordtime(MSG_ONE);
1573                 race_send_speedaward(MSG_ONE);
1574
1575                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1576                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1577                 race_send_speedaward_alltimebest(MSG_ONE);
1578
1579                 float i;
1580                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1581                         race_SendRankings(i, 0, 0, MSG_ONE);
1582                 }
1583         }
1584         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1585                 send_CSQC_teamnagger();
1586
1587         if (g_domination)
1588                 set_dom_state(self);
1589
1590         CheatInitClient();
1591
1592         if(!autocvar_g_campaign)
1593                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1594
1595         CSQCMODEL_AUTOINIT();
1596
1597         self.model_randomizer = random();
1598 }
1599
1600 /*
1601 =============
1602 ClientDisconnect
1603
1604 Called when a client disconnects from the server
1605 =============
1606 */
1607 .entity chatbubbleentity;
1608 void ReadyCount();
1609 void ClientDisconnect (void)
1610 {
1611         if(self.vehicle)
1612             vehicles_exit(VHEF_RELESE);
1613
1614         if not(self.flags & FL_CLIENT)
1615         {
1616                 print("Warning: ClientDisconnect without ClientConnect\n");
1617                 return;
1618         }
1619
1620         PlayerStats_AddGlobalInfo(self);
1621
1622         CheatShutdownClient();
1623
1624         if(self.hitplotfh >= 0)
1625         {
1626                 fclose(self.hitplotfh);
1627                 self.hitplotfh = -1;
1628         }
1629
1630         anticheat_report();
1631         anticheat_shutdown();
1632
1633         playerdemo_shutdown();
1634
1635         bot_clientdisconnect();
1636
1637         if(self.entcs)
1638                 detach_entcs();
1639
1640         if(autocvar_sv_eventlog)
1641                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1642         bprint ("^4",self.netname);
1643         bprint ("^4 disconnected\n");
1644
1645         SoundEntity_Detach(self);
1646
1647         DropAllRunes(self);
1648         MUTATOR_CALLHOOK(ClientDisconnect);
1649
1650         Portal_ClearAll(self);
1651
1652         RemoveGrapplingHook(self);
1653         if(self.flagcarried)
1654                 DropFlag(self.flagcarried, world, world);
1655         if(self.ballcarried && g_nexball)
1656                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1657
1658         // Here, everything has been done that requires this player to be a client.
1659
1660         self.flags &~= FL_CLIENT;
1661
1662         if (self.chatbubbleentity)
1663                 remove (self.chatbubbleentity);
1664
1665         if (self.killindicator)
1666                 remove (self.killindicator);
1667
1668         WaypointSprite_PlayerGone();
1669
1670         bot_relinkplayerlist();
1671
1672         if(g_arena)
1673         {
1674                 Spawnqueue_Unmark(self);
1675                 Spawnqueue_Remove(self);
1676         }
1677
1678         accuracy_free(self);
1679         ClientData_Detach();
1680         PlayerScore_Detach(self);
1681
1682         if(self.netname_previous)
1683                 strunzone(self.netname_previous);
1684         if(self.clientstatus)
1685                 strunzone(self.clientstatus);
1686         if(self.weaponorder_byimpulse)
1687                 strunzone(self.weaponorder_byimpulse);
1688
1689         ClearPlayerSounds();
1690
1691         if(self.personal)
1692                 remove(self.personal);
1693
1694         self.playerid = 0;
1695         ReadyCount();
1696
1697         // free cvars
1698         GetCvars(-1);
1699 }
1700
1701 .float BUTTON_CHAT;
1702 void ChatBubbleThink()
1703 {
1704         self.nextthink = time;
1705         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1706         {
1707                 if(self.owner) // but why can that ever be world?
1708                         self.owner.chatbubbleentity = world;
1709                 remove(self);
1710                 return;
1711         }
1712         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1713 #ifdef TETRIS
1714                 || self.owner.tetris_on
1715 #endif
1716         )
1717                 self.model = self.mdl;
1718         else
1719                 self.model = "";
1720 }
1721
1722 void UpdateChatBubble()
1723 {
1724         if (self.alpha < 0)
1725                 return;
1726         // spawn a chatbubble entity if needed
1727         if (!self.chatbubbleentity)
1728         {
1729                 self.chatbubbleentity = spawn();
1730                 self.chatbubbleentity.owner = self;
1731                 self.chatbubbleentity.exteriormodeltoclient = self;
1732                 self.chatbubbleentity.think = ChatBubbleThink;
1733                 self.chatbubbleentity.nextthink = time;
1734                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1735                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1736                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1737                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1738                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1739                 self.chatbubbleentity.model = "";
1740                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1741         }
1742 }
1743
1744
1745 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1746 // added to the model skins
1747 /*void UpdateColorModHack()
1748 {
1749         float c;
1750         c = self.clientcolors & 15;
1751         // LordHavoc: only bothering to support white, green, red, yellow, blue
1752              if (!teamplay) self.colormod = '0 0 0';
1753         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1754         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1755         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1756         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1757         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1758         else self.colormod = '1 1 1';
1759 }*/
1760
1761 void respawn(void)
1762 {
1763         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1764         {
1765                 self.solid = SOLID_NOT;
1766                 self.takedamage = DAMAGE_NO;
1767                 self.movetype = MOVETYPE_FLY;
1768                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1769                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1770                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1771                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1772                 if(autocvar_g_respawn_ghosts_maxtime)
1773                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1774         }
1775
1776         CopyBody(1);
1777
1778         self.effects |= EF_NODRAW; // prevent another CopyBody
1779         PutClientInServer();
1780 }
1781
1782 void play_countdown(float finished, string samp)
1783 {
1784         if(clienttype(self) == CLIENTTYPE_REAL)
1785                 if(floor(finished - time - frametime) != floor(finished - time))
1786                         if(finished - time < 6)
1787                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1788 }
1789
1790 void player_powerups (void)
1791 {
1792         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1793         olditems = self.items;
1794
1795         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1796         {
1797                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1798                 self.modelflags |= MF_ROCKET;
1799         }
1800         else
1801         {
1802                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1803                 self.modelflags &~= MF_ROCKET;
1804         }
1805
1806         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1807
1808         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1809                 return;
1810
1811         Fire_ApplyDamage(self);
1812         Fire_ApplyEffect(self);
1813
1814         if (g_minstagib)
1815         {
1816                 self.effects |= EF_FULLBRIGHT;
1817
1818                 if (self.items & IT_STRENGTH)
1819                 {
1820                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1821                         if (time > self.strength_finished)
1822                         {
1823                                 self.alpha = default_player_alpha;
1824                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1825                                 self.items &~= IT_STRENGTH;
1826                                 sprint(self, "^3Invisibility has worn off\n");
1827                         }
1828                 }
1829                 else
1830                 {
1831                         if (time < self.strength_finished)
1832                         {
1833                                 self.alpha = g_minstagib_invis_alpha;
1834                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1835                                 self.items |= IT_STRENGTH;
1836                                 sprint(self, "^3You are invisible\n");
1837                         }
1838                 }
1839
1840                 if (self.items & IT_INVINCIBLE)
1841                 {
1842                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1843                         if (time > self.invincible_finished)
1844                         {
1845                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1846                                 sprint(self, "^3Speed has worn off\n");
1847                         }
1848                 }
1849                 else
1850                 {
1851                         if (time < self.invincible_finished)
1852                         {
1853                                 self.items = self.items | IT_INVINCIBLE;
1854                                 sprint(self, "^3You are on speed\n");
1855                         }
1856                 }
1857         }
1858         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1859         {
1860                 if (self.items & IT_STRENGTH)
1861                 {
1862                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1863                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1864                         if (time > self.strength_finished)
1865                         {
1866                                 self.items = self.items - (self.items & IT_STRENGTH);
1867                                 sprint(self, "^3Strength has worn off\n");
1868                         }
1869                 }
1870                 else
1871                 {
1872                         if (time < self.strength_finished)
1873                         {
1874                                 self.items = self.items | IT_STRENGTH;
1875                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1876                         }
1877                 }
1878                 if (self.items & IT_INVINCIBLE)
1879                 {
1880                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1881                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1882                         if (time > self.invincible_finished)
1883                         {
1884                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1885                                 sprint(self, "^3Shield has worn off\n");
1886                         }
1887                 }
1888                 else
1889                 {
1890                         if (time < self.invincible_finished)
1891                         {
1892                                 self.items = self.items | IT_INVINCIBLE;
1893                                 sprint(self, "^3Shield surrounds you\n");
1894                         }
1895                 }
1896                 if (self.items & IT_SUPERWEAPON)
1897                 {
1898                         self.effects = self.effects | EF_RED;
1899                         if (!(self.weapons & WEPBIT_SUPERWEAPONS))
1900                         {
1901                                 self.superweapons_finished = 0;
1902                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1903                                 sprint(self, "^3Superweapons have been lost\n");
1904                         }
1905                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1906                         {
1907                                 // don't let them run out
1908                         }
1909                         else
1910                         {
1911                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1912                                 if (time > self.superweapons_finished)
1913                                 {
1914                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1915                                         self.weapons &~= WEPBIT_SUPERWEAPONS;
1916                                         sprint(self, "^3Superweapons have broken down\n");
1917                                 }
1918                         }
1919                 }
1920                 else
1921                 {
1922                         if (time < self.superweapons_finished)
1923                         {
1924                                 self.items = self.items | IT_SUPERWEAPON;
1925                                 sprint(self, "^3You now have a superweapon\n");
1926                         }
1927                         else
1928                                 self.weapons &~= WEPBIT_SUPERWEAPONS; // just in case
1929                 }
1930         }
1931
1932         if(autocvar_g_nodepthtestplayers)
1933                 self.effects = self.effects | EF_NODEPTHTEST;
1934
1935         if(autocvar_g_fullbrightplayers)
1936                 self.effects = self.effects | EF_FULLBRIGHT;
1937
1938         // midair gamemode: damage only while in the air
1939         // if in midair mode, being on ground grants temporary invulnerability
1940         // (this is so that multishot weapon don't clear the ground flag on the
1941         // first damage in the frame, leaving the player vulnerable to the
1942         // remaining hits in the same frame)
1943         if (self.flags & FL_ONGROUND)
1944         if (g_midair)
1945                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1946
1947         if (time >= game_starttime)
1948         if (time < self.spawnshieldtime)
1949                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1950
1951         MUTATOR_CALLHOOK(PlayerPowerups);
1952 }
1953
1954 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1955 {
1956         if(current > stable)
1957                 return current;
1958         else if(current > stable - 0.25) // when close enough, "snap"
1959                 return stable;
1960         else
1961                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1962 }
1963
1964 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1965 {
1966         if(current < stable)
1967                 return current;
1968         else if(current < stable + 0.25) // when close enough, "snap"
1969                 return stable;
1970         else
1971                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1972 }
1973
1974 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1975 {
1976         if(current > rotstable)
1977         {
1978                 if(rotframetime > 0)
1979                 {
1980                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1981                         current = max(rotstable, current - rotlinear * rotframetime);
1982                 }
1983         }
1984         else if(current < regenstable)
1985         {
1986                 if(regenframetime > 0)
1987                 {
1988                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1989                         current = min(regenstable, current + regenlinear * regenframetime);
1990                 }
1991         }
1992
1993         if(current > limit)
1994                 current = limit;
1995
1996         return current;
1997 }
1998
1999 void player_regen (void)
2000 {
2001         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2002         maxh = autocvar_g_balance_health_rotstable;
2003         maxa = autocvar_g_balance_armor_rotstable;
2004         maxf = autocvar_g_balance_fuel_rotstable;
2005         minh = autocvar_g_balance_health_regenstable;
2006         mina = autocvar_g_balance_armor_regenstable;
2007         minf = autocvar_g_balance_fuel_regenstable;
2008         limith = autocvar_g_balance_health_limit;
2009         limita = autocvar_g_balance_armor_limit;
2010         limitf = autocvar_g_balance_fuel_limit;
2011
2012         max_mod = regen_mod = rot_mod = limit_mod = 1;
2013
2014         if (self.runes & RUNE_REGEN)
2015         {
2016                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2017                 {
2018                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2019                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2020                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2021                 }
2022                 else
2023                 {
2024                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2025                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2026                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2027                 }
2028         }
2029         else if (self.runes & CURSE_VENOM)
2030         {
2031                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2032                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2033                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2034                 else
2035                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2036                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2037                 //if (!self.runes & RUNE_REGEN)
2038                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2039         }
2040         maxh = maxh * max_mod;
2041         //maxa = maxa * max_mod;
2042         //maxf = maxf * max_mod;
2043         minh = minh * max_mod;
2044         //mina = mina * max_mod;
2045         //minf = minf * max_mod;
2046         limith = limith * limit_mod;
2047         limita = limita * limit_mod;
2048         //limitf = limitf * limit_mod;
2049
2050         if(g_lms && g_ca)
2051                 rot_mod = 0;
2052
2053         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2054         {
2055                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2056                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2057
2058                 // if player rotted to death...  die!
2059                 if(self.health < 1)
2060                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2061         }
2062
2063         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2064                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2065 }
2066
2067 float zoomstate_set;
2068 void SetZoomState(float z)
2069 {
2070         if(z != self.zoomstate)
2071         {
2072                 self.zoomstate = z;
2073                 ClientData_Touch(self);
2074         }
2075         zoomstate_set = 1;
2076 }
2077
2078 void GetPressedKeys(void) {
2079         MUTATOR_CALLHOOK(GetPressedKeys);
2080         if (self.movement_x > 0) // get if movement keys are pressed
2081         {       // forward key pressed
2082                 self.pressedkeys |= KEY_FORWARD;
2083                 self.pressedkeys &~= KEY_BACKWARD;
2084         }
2085         else if (self.movement_x < 0)
2086         {       // backward key pressed
2087                 self.pressedkeys |= KEY_BACKWARD;
2088                 self.pressedkeys &~= KEY_FORWARD;
2089         }
2090         else
2091         {       // no x input
2092                 self.pressedkeys &~= KEY_FORWARD;
2093                 self.pressedkeys &~= KEY_BACKWARD;
2094         }
2095
2096         if (self.movement_y > 0)
2097         {       // right key pressed
2098                 self.pressedkeys |= KEY_RIGHT;
2099                 self.pressedkeys &~= KEY_LEFT;
2100         }
2101         else if (self.movement_y < 0)
2102         {       // left key pressed
2103                 self.pressedkeys |= KEY_LEFT;
2104                 self.pressedkeys &~= KEY_RIGHT;
2105         }
2106         else
2107         {       // no y input
2108                 self.pressedkeys &~= KEY_RIGHT;
2109                 self.pressedkeys &~= KEY_LEFT;
2110         }
2111
2112         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2113                 self.pressedkeys |= KEY_JUMP;
2114         else
2115                 self.pressedkeys &~= KEY_JUMP;
2116         if (self.BUTTON_CROUCH)
2117                 self.pressedkeys |= KEY_CROUCH;
2118         else
2119                 self.pressedkeys &~= KEY_CROUCH;
2120 }
2121
2122 /*
2123 ======================
2124 spectate mode routines
2125 ======================
2126 */
2127
2128 void SpectateCopy(entity spectatee) {
2129         other = spectatee;
2130         MUTATOR_CALLHOOK(SpectateCopy);
2131         self.armortype = spectatee.armortype;
2132         self.armorvalue = spectatee.armorvalue;
2133         self.ammo_cells = spectatee.ammo_cells;
2134         self.ammo_shells = spectatee.ammo_shells;
2135         self.ammo_nails = spectatee.ammo_nails;
2136         self.ammo_rockets = spectatee.ammo_rockets;
2137         self.ammo_fuel = spectatee.ammo_fuel;
2138         self.clip_load = spectatee.clip_load;
2139         self.clip_size = spectatee.clip_size;
2140         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2141         self.health = spectatee.health;
2142         self.impulse = 0;
2143         self.items = spectatee.items;
2144         self.last_pickup = spectatee.last_pickup;
2145         self.hit_time = spectatee.hit_time;
2146         self.metertime = spectatee.metertime;
2147         self.strength_finished = spectatee.strength_finished;
2148         self.invincible_finished = spectatee.invincible_finished;
2149         self.pressedkeys = spectatee.pressedkeys;
2150         self.weapons = spectatee.weapons;
2151         self.switchweapon = spectatee.switchweapon;
2152         self.switchingweapon = spectatee.switchingweapon;
2153         self.weapon = spectatee.weapon;
2154         self.nex_charge = spectatee.nex_charge;
2155         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2156         self.hagar_load = spectatee.hagar_load;
2157         self.minelayer_mines = spectatee.minelayer_mines;
2158         self.punchangle = spectatee.punchangle;
2159         self.view_ofs = spectatee.view_ofs;
2160         self.v_angle = spectatee.v_angle;
2161         self.velocity = spectatee.velocity;
2162         self.dmg_take = spectatee.dmg_take;
2163         self.dmg_save = spectatee.dmg_save;
2164         self.dmg_inflictor = spectatee.dmg_inflictor;
2165         self.angles = spectatee.v_angle;
2166         if(!self.BUTTON_USE)
2167                 self.fixangle = TRUE;
2168         setorigin(self, spectatee.origin);
2169         setsize(self, spectatee.mins, spectatee.maxs);
2170         SetZoomState(spectatee.zoomstate);
2171
2172         anticheat_spectatecopy(spectatee);
2173
2174         //self.vehicle = spectatee.vehicle;
2175
2176         self.hud = spectatee.hud;
2177         if(spectatee.vehicle)
2178     {
2179         setorigin(self, spectatee.origin);
2180         self.velocity = spectatee.vehicle.velocity;
2181         self.v_angle += spectatee.vehicle.angles;
2182         //self.v_angle_x *= -1;
2183         self.vehicle_health = spectatee.vehicle_health;
2184         self.vehicle_shield = spectatee.vehicle_shield;
2185         self.vehicle_energy = spectatee.vehicle_energy;
2186         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2187         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2188         self.vehicle_reload1 = spectatee.vehicle_reload1;
2189         self.vehicle_reload2 = spectatee.vehicle_reload2;
2190
2191         msg_entity = self;
2192         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2193         WriteEntity(MSG_ONE, spectatee);
2194         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2195     }
2196 }
2197
2198 float SpectateUpdate() {
2199         if(!self.enemy)
2200             return 0;
2201
2202         if (self == self.enemy)
2203                 return 0;
2204
2205         if(self.enemy.classname != "player")
2206                 return 0;
2207
2208         SpectateCopy(self.enemy);
2209
2210         return 1;
2211 }
2212
2213
2214 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2215 entity CA_SpectateNext(entity start) {
2216         if (start.team == self.team) {
2217                 return start;
2218         }
2219
2220         other = start;
2221         // continue from current player
2222         while(other && other.team != self.team) {
2223                 other = find(other, classname, "player");
2224         }
2225
2226         if (!other) {
2227                 // restart from begining
2228                 other = find(other, classname, "player");
2229                 while(other && other.team != self.team) {
2230                         other = find(other, classname, "player");
2231                 }
2232         }
2233
2234         return other;
2235 }
2236
2237 float SpectateNext() {
2238         other = find(self.enemy, classname, "player");
2239         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2240                 // CA and ca players when spectating enemies is forbidden
2241                 other = CA_SpectateNext(other);
2242         } else {
2243                 // other modes and ca spectators or spectating enemies is allowed
2244                 if (!other)
2245                         other = find(other, classname, "player");
2246         }
2247
2248         if (other)
2249                 self.enemy = other;
2250
2251         if(self.enemy.classname == "player") {
2252             if(self.enemy.vehicle)
2253             {
2254             msg_entity = self;
2255             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2256             WriteEntity(MSG_ONE, self.enemy);
2257             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2258             self.movetype = MOVETYPE_NONE;
2259             accuracy_resend(self);
2260             }
2261             else
2262             {
2263             msg_entity = self;
2264             WriteByte(MSG_ONE, SVC_SETVIEW);
2265             WriteEntity(MSG_ONE, self.enemy);
2266             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2267             self.movetype = MOVETYPE_NONE;
2268             accuracy_resend(self);
2269
2270             if(!SpectateUpdate())
2271                 PutObserverInServer();
2272         }
2273         return 1;
2274         } else {
2275                 return 0;
2276         }
2277 }
2278
2279 /*
2280 =============
2281 ShowRespawnCountdown()
2282
2283 Update a respawn countdown display.
2284 =============
2285 */
2286 void ShowRespawnCountdown()
2287 {
2288         float number;
2289         if(self.deadflag == DEAD_NO) // just respawned?
2290                 return;
2291         else
2292         {
2293                 number = ceil(self.respawn_time - time);
2294                 if(number <= 0)
2295                         return;
2296                 if(number <= self.respawn_countdown)
2297                 {
2298                         self.respawn_countdown = number - 1;
2299                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2300                                 AnnounceTo(self, strcat(ftos(number), ""));
2301                 }
2302         }
2303 }
2304
2305 .float prevent_join_msgtime;
2306 void LeaveSpectatorMode()
2307 {
2308         if(nJoinAllowed(1)) {
2309                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2310                         self.classname = "player";
2311
2312                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2313                                 JoinBestTeam(self, FALSE, TRUE);
2314
2315                         if(autocvar_g_campaign)
2316                                 campaign_bots_may_start = 1;
2317
2318                         PutClientInServer();
2319
2320                         if(self.classname == "player")
2321                                 bprint ("^4", self.netname, "^4 is playing now\n");
2322
2323                         if(!autocvar_g_campaign)
2324                         if (time < self.jointime + autocvar_welcome_message_time)
2325                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2326
2327                         if (self.prevent_join_msgtime)
2328                         {
2329                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2330                                 self.prevent_join_msgtime = 0;
2331                         }
2332
2333                         return;
2334                 } else {
2335                         if (g_ca && self.caplayer) {
2336                         }       // do nothing
2337                         else
2338                                 stuffcmd(self,"menu_showteamselect\n");
2339                         return;
2340                 }
2341         }
2342         else {
2343                 //player may not join because of g_maxplayers is set
2344                 if (time - self.prevent_join_msgtime > 2)
2345                 {
2346                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2347                         self.prevent_join_msgtime = time;
2348                 }
2349         }
2350 }
2351
2352 /**
2353  * Determines whether the player is allowed to join. This depends on cvar
2354  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2355  * it checks whether the number of currently playing players exceeds g_maxplayers.
2356  * @return int number of free slots for players, 0 if none
2357  */
2358 float nJoinAllowed(float includeMe) {
2359         if(self.team_forced < 0)
2360                 return FALSE; // forced spectators can never join
2361
2362         // TODO simplify this
2363         entity e;
2364
2365         float totalClients;
2366         FOR_EACH_CLIENT(e)
2367                 totalClients += 1;
2368
2369         if (!autocvar_g_maxplayers)
2370                 return maxclients - totalClients + includeMe;
2371
2372         float currentlyPlaying;
2373         FOR_EACH_REALPLAYER(e)
2374                 currentlyPlaying += 1;
2375
2376         if(currentlyPlaying < autocvar_g_maxplayers)
2377                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2378
2379         return 0;
2380 }
2381
2382 /**
2383  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2384  * g_maxplayers_spectator_blocktime seconds
2385  */
2386 void checkSpectatorBlock() {
2387         if(self.classname == "spectator" || self.classname == "observer") {
2388                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2389                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2390                         dropclient(self);
2391                 }
2392         }
2393 }
2394
2395 .float motd_actived_time; // used for both motd and campaign_message
2396 void PrintWelcomeMessage()
2397 {
2398         if (self.motd_actived_time == 0) { // is there already a message showing?
2399                 if (autocvar_g_campaign) {
2400                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2401                                 self.motd_actived_time = time;
2402                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2403                         }
2404                 } else {
2405                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2406                                 self.motd_actived_time = time;
2407                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2408                         }
2409                 }
2410         } else { // showing MOTD or campaign message
2411                 if (autocvar_g_campaign) {
2412                         if (self.BUTTON_INFO)
2413                                 self.motd_actived_time = time;
2414                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2415                                 self.motd_actived_time = 0;
2416                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2417                         }
2418                 } else {
2419                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2420                                 if (self.BUTTON_INFO)
2421                                         self.motd_actived_time = time;
2422                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2423                                         self.motd_actived_time = 0;
2424                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2425                                 }
2426                         }
2427                 }
2428         }
2429 }
2430
2431 void ObserverThink()
2432 {
2433         float prefered_movetype;
2434         if (self.flags & FL_JUMPRELEASED) {
2435                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2436                         self.flags &~= FL_JUMPRELEASED;
2437                         self.flags |= FL_SPAWNING;
2438                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2439                         self.flags &~= FL_JUMPRELEASED;
2440                         if(SpectateNext() == 1) {
2441                                 self.classname = "spectator";
2442                         }
2443                 } else {
2444                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2445                         if (self.movetype != prefered_movetype)
2446                                 self.movetype = prefered_movetype;
2447                 }
2448         } else {
2449                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2450                         self.flags |= FL_JUMPRELEASED;
2451                         if(self.flags & FL_SPAWNING)
2452                         {
2453                                 self.flags &~= FL_SPAWNING;
2454                                 LeaveSpectatorMode();
2455                                 return;
2456                         }
2457                 }
2458         }
2459
2460         PrintWelcomeMessage();
2461 }
2462
2463 void SpectatorThink()
2464 {
2465         if (self.flags & FL_JUMPRELEASED) {
2466                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2467                         self.flags &~= FL_JUMPRELEASED;
2468                         self.flags |= FL_SPAWNING;
2469                 } else if(self.BUTTON_ATCK) {
2470                         self.flags &~= FL_JUMPRELEASED;
2471                         if(SpectateNext() == 1) {
2472                                 self.classname = "spectator";
2473                         } else {
2474                                 self.classname = "observer";
2475                                 PutClientInServer();
2476                         }
2477                 } else if (self.BUTTON_ATCK2) {
2478                         self.flags &~= FL_JUMPRELEASED;
2479                         self.classname = "observer";
2480                         PutClientInServer();
2481                 } else {
2482                         if(!SpectateUpdate())
2483                                 PutObserverInServer();
2484                 }
2485         } else {
2486                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2487                         self.flags |= FL_JUMPRELEASED;
2488                         if(self.flags & FL_SPAWNING)
2489                         {
2490                                 self.flags &~= FL_SPAWNING;
2491                                 LeaveSpectatorMode();
2492                                 return;
2493                         }
2494                 }
2495                 if(!SpectateUpdate())
2496                         PutObserverInServer();
2497         }
2498
2499         PrintWelcomeMessage();
2500         self.flags |= FL_CLIENT | FL_NOTARGET;
2501 }
2502
2503 float ctf_usekey();
2504 void PlayerUseKey()
2505 {
2506         if(self.classname != "player")
2507                 return;
2508
2509         if(self.vehicle)
2510         {
2511         vehicles_exit(VHEF_NORMAL);
2512         return;
2513         }
2514
2515         // a use key was pressed; call handlers
2516         if(ctf_usekey())
2517                 return;
2518
2519         MUTATOR_CALLHOOK(PlayerUseKey);
2520 }
2521
2522 .float touchexplode_time;
2523
2524 /*
2525 =============
2526 PlayerPreThink
2527
2528 Called every frame for each client before the physics are run
2529 =============
2530 */
2531 .float usekeypressed;
2532 void() ctf_setstatus;
2533 void() nexball_setstatus;
2534 .float items_added;
2535 void PlayerPreThink (void)
2536 {
2537         WarpZone_PlayerPhysics_FixVAngle();
2538
2539         self.stat_game_starttime = game_starttime;
2540         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2541         self.stat_leadlimit = autocvar_leadlimit;
2542
2543         if(frametime)
2544         {
2545                 // physics frames: update anticheat stuff
2546                 anticheat_prethink();
2547         }
2548
2549         if(blockSpectators && frametime)
2550                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2551                 checkSpectatorBlock();
2552
2553         zoomstate_set = 0;
2554
2555         if(self.netname_previous != self.netname)
2556         {
2557                 if(autocvar_sv_eventlog)
2558                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2559                 if(self.netname_previous)
2560                         strunzone(self.netname_previous);
2561                 self.netname_previous = strzone(self.netname);
2562         }
2563
2564         // version nagging
2565         if(self.version_nagtime)
2566                 if(self.cvar_g_xonoticversion)
2567                         if(time > self.version_nagtime)
2568                         {
2569                                 // don't notify git users
2570                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2571                                 {
2572                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2573                                         {
2574                                                 // notify release users if connecting to git
2575                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2576                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2577                                         }
2578                                         else
2579                                         {
2580                                                 float r;
2581                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2582                                                 if(r < 0)
2583                                                 {
2584                                                         // give users new version
2585                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2586                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2587                                                 }
2588                                                 else if(r > 0)
2589                                                 {
2590                                                         // notify users about old server version
2591                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2592                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2593                                                 }
2594                                         }
2595                                 }
2596                                 self.version_nagtime = 0;
2597                         }
2598
2599         // GOD MODE info
2600         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2601         {
2602                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2603                 self.max_armorvalue = 0;
2604         }
2605
2606 #ifdef TETRIS
2607         if (TetrisPreFrame())
2608                 return;
2609 #endif
2610
2611         MUTATOR_CALLHOOK(PlayerPreThink);
2612
2613         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2614         {
2615                 if(self.BUTTON_USE && !self.usekeypressed)
2616                         PlayerUseKey();
2617                 self.usekeypressed = self.BUTTON_USE;
2618         }
2619
2620         PrintWelcomeMessage();
2621
2622         if(self.classname == "player") {
2623 //              if(self.netname == "Wazat")
2624 //                      bprint(self.classname, "\n");
2625
2626                 CheckRules_Player();
2627
2628                 if (intermission_running)
2629                 {
2630                         IntermissionThink ();   // otherwise a button could be missed between
2631                         return;                                 // the think tics
2632                 }
2633
2634                 //don't allow the player to turn around while game is paused!
2635                 if(timeout_status == TIMEOUT_ACTIVE) {
2636                         // FIXME turn this into CSQC stuff
2637                         self.v_angle = self.lastV_angle;
2638                         self.angles = self.lastV_angle;
2639                         self.fixangle = TRUE;
2640                 }
2641
2642                 if(frametime)
2643                 {
2644 #ifndef NO_LEGACY_NETWORKING
2645                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2646 #endif
2647
2648                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2649                         {
2650                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2651                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2652                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2653
2654                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2655                                 {
2656                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2657                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2658                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2659                                 }
2660                         }
2661                         else
2662                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2663
2664                         player_powerups();
2665                 }
2666
2667                 if (g_minstagib)
2668                         minstagib_ammocheck();
2669
2670                 if (self.deadflag != DEAD_NO)
2671                 {
2672                         float button_pressed, force_respawn;
2673                         if(self.personal && g_race_qualifying)
2674                         {
2675                                 if(time > self.respawn_time)
2676                                 {
2677                                         self.respawn_time = time + 1; // only retry once a second
2678                                         respawn();
2679                                         self.impulse = 141;
2680                                 }
2681                         }
2682                         else
2683                         {
2684                                 if(frametime)
2685                                         player_anim();
2686                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2687                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2688                                 if (self.deadflag == DEAD_DYING)
2689                                 {
2690                                         if(force_respawn)
2691                                                 self.deadflag = DEAD_RESPAWNING;
2692                                         else if(!button_pressed)
2693                                                 self.deadflag = DEAD_DEAD;
2694                                 }
2695                                 else if (self.deadflag == DEAD_DEAD)
2696                                 {
2697                                         if(button_pressed)
2698                                                 self.deadflag = DEAD_RESPAWNABLE;
2699                                 }
2700                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2701                                 {
2702                                         if(!button_pressed)
2703                                                 self.deadflag = DEAD_RESPAWNING;
2704                                 }
2705                                 else if (self.deadflag == DEAD_RESPAWNING)
2706                                 {
2707                                         if(time > self.respawn_time)
2708                                         {
2709                                                 self.respawn_time = time + 1; // only retry once a second
2710                                                 respawn();
2711                                         }
2712                                 }
2713                                 ShowRespawnCountdown();
2714                         }
2715                         return;
2716                 }
2717                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2718                 // so (self.deadflag == DEAD_NO) is always true in the code below
2719
2720                 if(g_touchexplode)
2721                 if(time > self.touchexplode_time)
2722                 if(self.classname == "player")
2723                 if(self.deadflag == DEAD_NO)
2724                 if not(IS_INDEPENDENT_PLAYER(self))
2725                 FOR_EACH_PLAYER(other) if(self != other)
2726                 {
2727                         if(time > other.touchexplode_time)
2728                         if(other.deadflag == DEAD_NO)
2729                         if not(IS_INDEPENDENT_PLAYER(other))
2730                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2731                         {
2732                                 PlayerTouchExplode(self, other);
2733                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2734                         }
2735                 }
2736
2737                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2738                 {
2739                         vector dist;
2740
2741                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2742                         dist = self.prevorigin - self.origin;
2743                         dist_z = 0;
2744                         self.lms_traveled_distance += fabs(vlen(dist));
2745
2746                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2747                         {
2748                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2749                                 self.lms_traveled_distance = 0;
2750                         }
2751
2752                         if(time > self.lms_nextcheck)
2753                         {
2754                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2755                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2756                                 {
2757                                         centerprint(self, autocvar_g_lms_campcheck_message);
2758                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2759                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2760                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2761                                 }
2762                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2763                                 self.lms_traveled_distance = 0;
2764                         }
2765                 }
2766
2767                 self.prevorigin = self.origin;
2768
2769                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2770                 {
2771                         if (!self.crouch)
2772                         {
2773                                 self.crouch = TRUE;
2774                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2775                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2776                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2777                         }
2778                 }
2779                 else
2780                 {
2781                         if (self.crouch)
2782                         {
2783                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2784                                 if (!trace_startsolid)
2785                                 {
2786                                         self.crouch = FALSE;
2787                                         self.view_ofs = PL_VIEW_OFS;
2788                                         setsize (self, PL_MIN, PL_MAX);
2789                                 }
2790                         }
2791                 }
2792
2793                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2794                 {
2795                         if(self.bloodloss_timer < time)
2796                         {
2797                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2798                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2799                         }
2800                 }
2801
2802                 FixPlayermodel();
2803
2804                 GrapplingHookFrame();
2805
2806                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2807                 //if(frametime)
2808                 {
2809                         self.items &~= self.items_added;
2810
2811                         W_WeaponFrame();
2812
2813                         self.items_added = 0;
2814                         if(self.items & IT_JETPACK)
2815                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2816                                         self.items_added |= IT_FUEL;
2817
2818                         self.items |= self.items_added;
2819                 }
2820
2821                 player_regen();
2822
2823                 // rot nex charge to the charge limit
2824                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2825                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2826
2827                 if(frametime)
2828                         player_anim();
2829
2830                 if(g_ctf)
2831                         ctf_setstatus();
2832
2833                 if(g_nexball)
2834                         nexball_setstatus();
2835
2836                 // secret status
2837                 secrets_setstatus();
2838
2839                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2840
2841                 //self.angles_y=self.v_angle_y + 90;   // temp
2842         } else if(gameover) {
2843                 if (intermission_running)
2844                         IntermissionThink ();   // otherwise a button could be missed between
2845                 return;
2846         } else if(self.classname == "observer") {
2847                 ObserverThink();
2848         } else if(self.classname == "spectator") {
2849                 SpectatorThink();
2850         }
2851
2852         if(!zoomstate_set)
2853                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2854
2855         float oldspectatee_status;
2856         oldspectatee_status = self.spectatee_status;
2857         if(self.classname == "spectator")
2858                 self.spectatee_status = num_for_edict(self.enemy);
2859         else if(self.classname == "observer")
2860                 self.spectatee_status = num_for_edict(self);
2861         else
2862                 self.spectatee_status = 0;
2863         if(self.spectatee_status != oldspectatee_status)
2864         {
2865                 ClientData_Touch(self);
2866                 if(g_race || g_cts)
2867                         race_InitSpectator();
2868         }
2869
2870         if(self.teamkill_soundtime)
2871         if(time > self.teamkill_soundtime)
2872         {
2873                 self.teamkill_soundtime = 0;
2874
2875                 entity oldpusher, oldself;
2876
2877                 oldself = self; self = self.teamkill_soundsource;
2878                 oldpusher = self.pusher; self.pusher = oldself;
2879
2880                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2881
2882                 self.pusher = oldpusher;
2883                 self = oldself;
2884         }
2885
2886         if(self.taunt_soundtime)
2887         if(time > self.taunt_soundtime)
2888         {
2889                 self.taunt_soundtime = 0;
2890                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2891         }
2892
2893         target_voicescript_next(self);
2894
2895         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2896         if(!self.weapon)
2897                 self.clip_load = self.clip_size = 0;
2898 }
2899
2900 float isInvisibleString(string s)
2901 {
2902         float i, n, c;
2903         s = strdecolorize(s);
2904         for((i = 0), (n = strlen(s)); i < n; ++i)
2905         {
2906                 c = str2chr(s, i);
2907                 switch(c)
2908                 {
2909                         case 0:
2910                         case 32: // space
2911                                 break;
2912                         case 192: // charmap space
2913                                 if (!autocvar_utf8_enable)
2914                                         break;
2915                                 return FALSE;
2916                         case 160: // space in unicode fonts
2917                         case 0xE000 + 192: // utf8 charmap space
2918                                 if (autocvar_utf8_enable)
2919                                         break;
2920                         default:
2921                                 return FALSE;
2922                 }
2923         }
2924         return TRUE;
2925 }
2926
2927 /*
2928 =============
2929 PlayerPostThink
2930
2931 Called every frame for each client after the physics are run
2932 =============
2933 */
2934 .float idlekick_lasttimeleft;
2935 .entity showheadshotbbox;
2936 void showheadshotbbox_think()
2937 {
2938         if(self.owner.showheadshotbbox != self)
2939         {
2940                 remove(self);
2941                 return;
2942         }
2943         self.nextthink = time;
2944         setorigin(self, self.owner.origin);
2945         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2946 }
2947 void PlayerPostThink (void)
2948 {
2949         // Savage: Check for nameless players
2950         if (isInvisibleString(self.netname)) {
2951                 self.netname = "Player";
2952                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2953         }
2954
2955         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2956         {
2957                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2958                 {
2959                         if(self.idlekick_lasttimeleft)
2960                         {
2961                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2962                                 self.idlekick_lasttimeleft = 0;
2963                         }
2964                 }
2965                 else
2966                 {
2967                         float timeleft;
2968                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2969                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2970                         {
2971                                 if(!self.idlekick_lasttimeleft)
2972                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2973                         }
2974                         if(timeleft <= 0)
2975                         {
2976                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2977                                 AnnounceTo(self, "terminated");
2978                                 dropclient(self);
2979                                 return;
2980                         }
2981                         else if(timeleft <= 10)
2982                         {
2983                                 if(timeleft != self.idlekick_lasttimeleft)
2984                                         AnnounceTo(self, ftos(timeleft));
2985                                 self.idlekick_lasttimeleft = timeleft;
2986                         }
2987                 }
2988         }
2989
2990 #ifdef TETRIS
2991         if(self.impulse == 100)
2992                 ImpulseCommands();
2993         if (!TetrisPostFrame())
2994         {
2995 #endif
2996
2997         CheatFrame();
2998
2999         //CheckPlayerJump();
3000
3001         if(self.classname == "player") {
3002                 CheckRules_Player();
3003                 UpdateChatBubble();
3004                 if (self.impulse)
3005                         ImpulseCommands();
3006                 if (intermission_running)
3007                         return;         // intermission or finale
3008                 GetPressedKeys();
3009         } else if (self.classname == "observer") {
3010                 //do nothing
3011         } else if (self.classname == "spectator") {
3012                 //do nothing
3013         }
3014
3015 #ifdef TETRIS
3016         }
3017 #endif
3018
3019         /*
3020         float i;
3021         for(i = 0; i < 1000; ++i)
3022         {
3023                 vector end;
3024                 end = self.origin + '0 0 1024' + 512 * randomvec();
3025                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3026                 if(trace_fraction < 1)
3027                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3028                 {
3029                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3030                         break;
3031                 }
3032         }
3033         */
3034
3035         Arena_Warmup();
3036
3037         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3038
3039         if(self.waypointsprite_attachedforcarrier)
3040                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3041
3042         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3043         {
3044                 if(!self.showheadshotbbox)
3045                 {
3046                         self.showheadshotbbox = spawn();
3047                         self.showheadshotbbox.classname = "headshotbbox";
3048                         self.showheadshotbbox.owner = self;
3049                         self.showheadshotbbox.think = showheadshotbbox_think;
3050                         self.showheadshotbbox.nextthink = time;
3051                         self = self.showheadshotbbox;
3052                         self.think();
3053                         self = self.owner;
3054                 }
3055         }
3056         else
3057         {
3058                 if(self.showheadshotbbox)
3059                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3060                 remove(self.showheadshotbbox);
3061         }
3062
3063         playerdemo_write();
3064
3065         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3066         {
3067                 if(!self.stored_netname)
3068                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3069                 if(self.stored_netname != self.netname)
3070                 {
3071                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3072                         strunzone(self.stored_netname);
3073                         self.stored_netname = strzone(self.netname);
3074                 }
3075         }
3076
3077         /*
3078         if(g_race)
3079                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3080         */
3081
3082         CSQCMODEL_AUTOUPDATE();
3083 }