qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         if (g_minstagib)
 618                 minstagib_stop_countdown();
 619
 620         Portal_ClearAll(self);
 621
 622         if(self.alivetime)
 623         {
 624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                 self.alivetime = 0;
 626         }
 627
 628         if(self.vehicle)
 629             vehicles_exit(VHEF_RELESE);
 630
 631         if(self.flagcarried)
 632                 DropFlag(self.flagcarried, world, world);
 633
 634         if(self.ballcarried && g_nexball)
 635                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 636
 637         WaypointSprite_PlayerDead();
 638
 639         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 640                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 641
 642         if(self.killcount != -666) {
 643                 if(g_lms) {
 644                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 645                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 646                         else
 647                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 648                 } else
 649                         bprint ("^4", self.netname, "^4 is spectating now\n");
 650
 651                 if(self.just_joined == FALSE) {
 652                         LogTeamchange(self.playerid, -1, 4);
 653                 } else
 654                         self.just_joined = FALSE;
 655         }
 656
 657         PlayerScore_Clear(self); // clear scores when needed
 658
 659         accuracy_resend(self);
 660
 661         self.spectatortime = time;
 662
 663         self.classname = "observer";
 664         self.iscreature = FALSE;
 665         self.health = -666;
 666         self.takedamage = DAMAGE_NO;
 667         self.solid = SOLID_NOT;
 668         self.movetype = MOVETYPE_NOCLIP;
 669         self.flags = FL_CLIENT | FL_NOTARGET;
 670         self.armorvalue = 666;
 671         self.effects = 0;
 672         self.armorvalue = autocvar_g_balance_armor_start;
 673         self.pauserotarmor_finished = 0;
 674         self.pauserothealth_finished = 0;
 675         self.pauseregen_finished = 0;
 676         self.damageforcescale = 0;
 677         self.death_time = 0;
 678         self.dead_frame = 0;
 679         self.alpha = 0;
 680         self.scale = 0;
 681         self.fade_time = 0;
 682         self.pain_frame = 0;
 683         self.pain_finished = 0;
 684         self.strength_finished = 0;
 685         self.invincible_finished = 0;
 686         self.pushltime = 0;
 687         self.think = SUB_Null;
 688         self.nextthink = 0;
 689         self.hook_time = 0;
 690         self.runes = 0;
 691         self.deadflag = DEAD_NO;
 692         self.angles = spot.angles;
 693         self.angles_z = 0;
 694         self.fixangle = TRUE;
 695         self.crouch = FALSE;
 696
 697         self.view_ofs = PL_VIEW_OFS;
 698         setorigin (self, spot.origin);
 699         setsize (self, '0 0 0', '0 0 0');
 700         self.prevorigin = self.origin;
 701         self.items = 0;
 702         self.weapons = 0;
 703         self.model = "";
 704         FixPlayermodel();
 705         self.model = "";
 706         self.modelindex = 0;
 707         self.weapon = 0;
 708         self.weaponmodel = "";
 709         self.weaponentity = world;
 710         self.exteriorweaponentity = world;
 711         self.killcount = -666;
 712         self.velocity = '0 0 0';
 713         self.avelocity = '0 0 0';
 714         self.punchangle = '0 0 0';
 715         self.punchvector = '0 0 0';
 716         self.oldvelocity = self.velocity;
 717         self.fire_endtime = -1;
 718
 719         if(sv_loddistance1)
 720                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 721
 722         if(g_arena)
 723         {
 724                 if(self.version_mismatch)
 725                 {
 726                         Spawnqueue_Unmark(self);
 727                         Spawnqueue_Remove(self);
 728                 }
 729                 else
 730                 {
 731                         Spawnqueue_Insert(self);
 732                 }
 733         }
 734         else if(g_lms)
 735         {
 736                 // Only if the player cannot play at all
 737                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 738                         self.frags = FRAGS_SPECTATOR;
 739                 else
 740                         self.frags = FRAGS_LMS_LOSER;
 741         }
 742         else
 743                 self.frags = FRAGS_SPECTATOR;
 744 }
 745
 746 void FixPlayermodel()
 747 {
 748         local string defaultmodel;
 749         local float defaultskin, chmdl, oldskin;
 750         local vector m1, m2;
 751
 752         defaultmodel = "";
 753
 754         if(autocvar_sv_defaultcharacter == 1) {
 755                 defaultskin = 0;
 756
 757                 if(teamplay)
 758                 {
 759                         string s;
 760                         s = Team_ColorNameLowerCase(self.team);
 761                         if(s != "neutral")
 762                         {
 763                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 764                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 765                         }
 766                 }
 767
 768                 if(defaultmodel == "")
 769                 {
 770                         defaultmodel = autocvar_sv_defaultplayermodel;
 771                         defaultskin = autocvar_sv_defaultplayerskin;
 772                 }
 773         }
 774
 775         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 776         {
 777                 if(self.model != "")
 778                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 779                 self.model = ""; // force the != checks to return true
 780         }
 781
 782         if(defaultmodel != "")
 783         {
 784                 if (defaultmodel != self.model)
 785                 {
 786                         m1 = self.mins;
 787                         m2 = self.maxs;
 788                         setmodel_lod (self, defaultmodel);
 789                         setsize (self, m1, m2);
 790                         chmdl = TRUE;
 791                 }
 792
 793                 oldskin = self.skinindex;
 794                 self.skinindex = defaultskin;
 795         } else {
 796                 if (self.playermodel != self.model || self.playermodel == "")
 797                 {
 798                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 799                         m1 = self.mins;
 800                         m2 = self.maxs;
 801                         setmodel_lod (self, self.playermodel);
 802                         setsize (self, m1, m2);
 803                         chmdl = TRUE;
 804                 }
 805
 806                 oldskin = self.skinindex;
 807                 self.skinindex = stof(self.playerskin);
 808         }
 809
 810         if(chmdl || oldskin != self.skinindex)
 811                 self.species = player_getspecies(); // model or skin has changed
 812
 813         if(!teamplay)
 814                 if(strlen(autocvar_sv_defaultplayercolors))
 815                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 816                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 817 }
 818
 819 void PlayerTouchExplode(entity p1, entity p2)
 820 {
 821         vector org;
 822         org = (p1.origin + p2.origin) * 0.5;
 823         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 824
 825         te_explosion(org);
 826
 827         entity e;
 828         e = spawn();
 829         setorigin(e, org);
 830         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 831         remove(e);
 832 }
 833
 834 /*
 835 =============
 836 PutClientInServer
 837
 838 Called when a client spawns in the server
 839 =============
 840 */
 841 //void() ctf_playerchanged;
 842 void PutClientInServer (void)
 843 {
 844         if(clienttype(self) == CLIENTTYPE_BOT)
 845         {
 846                 self.classname = "player";
 847         }
 848         else if(clienttype(self) == CLIENTTYPE_REAL)
 849         {
 850                 msg_entity = self;
 851                 WriteByte(MSG_ONE, SVC_SETVIEW);
 852                 WriteEntity(MSG_ONE, self);
 853         }
 854
 855         // player is dead and becomes observer
 856         // FIXME fix LMS scoring for new system
 857         if(g_lms)
 858         {
 859                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 860                         self.classname = "observer";
 861         }
 862
 863         if(g_arena || (g_ca && !allowed_to_spawn))
 864         if(!self.spawned)
 865                 self.classname = "observer";
 866
 867         if(gameover)
 868                 self.classname = "observer";
 869
 870         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 871                 entity spot, oldself;
 872                 float j;
 873
 874                 accuracy_resend(self);
 875
 876                 if(self.team < 0)
 877                         JoinBestTeam(self, FALSE, TRUE);
 878
 879                 race_PreSpawn();
 880
 881                 spot = SelectSpawnPoint (FALSE);
 882                 if(!spot)
 883                 {
 884                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 885                         return; // spawn failed
 886                 }
 887
 888                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 889
 890                 self.classname = "player";
 891                 self.wasplayer = TRUE;
 892                 self.iscreature = TRUE;
 893                 self.movetype = MOVETYPE_WALK;
 894                 self.solid = SOLID_SLIDEBOX;
 895                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 896                 if(autocvar_g_playerclip_collisions)
 897                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 898                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 899                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 900                 self.frags = FRAGS_PLAYER;
 901                 if(independent_players)
 902                         MAKE_INDEPENDENT_PLAYER(self);
 903                 self.flags = FL_CLIENT;
 904                 self.takedamage = DAMAGE_AIM;
 905                 if(g_minstagib)
 906                         self.effects = EF_FULLBRIGHT;
 907                 else
 908                         self.effects = 0;
 909                 self.air_finished = time + 12;
 910                 self.dmg = 2;
 911                 if(autocvar_g_balance_nex_charge)
 912                 {
 913                         if(autocvar_g_balance_nex_secondary_chargepool)
 914                                 self.nex_chargepool_ammo = 1;
 915                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 916                 }
 917
 918                 if(inWarmupStage)
 919                 {
 920                         self.ammo_shells = warmup_start_ammo_shells;
 921                         self.ammo_nails = warmup_start_ammo_nails;
 922                         self.ammo_rockets = warmup_start_ammo_rockets;
 923                         self.ammo_cells = warmup_start_ammo_cells;
 924                         self.ammo_fuel = warmup_start_ammo_fuel;
 925                         self.health = warmup_start_health;
 926                         self.armorvalue = warmup_start_armorvalue;
 927                         self.weapons = warmup_start_weapons;
 928                 }
 929                 else
 930                 {
 931                         self.ammo_shells = start_ammo_shells;
 932                         self.ammo_nails = start_ammo_nails;
 933                         self.ammo_rockets = start_ammo_rockets;
 934                         self.ammo_cells = start_ammo_cells;
 935                         self.ammo_fuel = start_ammo_fuel;
 936                         self.health = start_health;
 937                         self.armorvalue = start_armorvalue;
 938                         self.weapons = start_weapons;
 939                 }
 940
 941                 if(g_weaponarena_random)
 942                 {
 943                         if(g_weaponarena_random_with_laser)
 944                                 self.weapons &~= WEPBIT_LASER;
 945                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 946                         if(g_weaponarena_random_with_laser)
 947                                 self.weapons |= WEPBIT_LASER;
 948                 }
 949
 950                 self.items = start_items;
 951                 self.jump_interval = time;
 952
 953                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 954                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 955                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 956                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 957                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 958                 //extend the pause of rotting if client was reset at the beginning of the countdown
 959                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 960                         self.spawnshieldtime += game_starttime - time;
 961                         self.pauserotarmor_finished += game_starttime - time;
 962                         self.pauserothealth_finished += game_starttime - time;
 963                         self.pauseregen_finished += game_starttime - time;
 964                 }
 965                 self.damageforcescale = 2;
 966                 self.death_time = 0;
 967                 self.dead_frame = 0;
 968                 self.alpha = 0;
 969                 self.scale = 0;
 970                 self.fade_time = 0;
 971                 self.pain_frame = 0;
 972                 self.pain_finished = 0;
 973                 self.strength_finished = 0;
 974                 self.invincible_finished = 0;
 975                 self.pushltime = 0;
 976                 // players have no think function
 977                 self.think = SUB_Null;
 978                 self.nextthink = 0;
 979                 self.hook_time = 0;
 980                 self.dmg_team = 0;
 981                 self.ballistics_density = autocvar_g_ballistics_density_player;
 982
 983                 self.metertime = 0;
 984
 985                 self.runes = 0;
 986
 987                 self.deadflag = DEAD_NO;
 988
 989                 self.angles = spot.angles;
 990
 991                 self.angles_z = 0; // never spawn tilted even if the spot says to
 992                 self.fixangle = TRUE; // turn this way immediately
 993                 self.velocity = '0 0 0';
 994                 self.avelocity = '0 0 0';
 995                 self.punchangle = '0 0 0';
 996                 self.punchvector = '0 0 0';
 997                 self.oldvelocity = self.velocity;
 998                 self.fire_endtime = -1;
 999
1000                 msg_entity = self;
1001                 WRITESPECTATABLE_MSG_ONE({
1002                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1003                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1004                 });
1005
1006                 if(sv_loddistance1)
1007                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1008
1009                 self.model = "";
1010                 FixPlayermodel();
1011
1012                 self.crouch = FALSE;
1013                 self.view_ofs = PL_VIEW_OFS;
1014                 setsize (self, PL_MIN, PL_MAX);
1015                 self.spawnorigin = spot.origin;
1016                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1017                 // don't reset back to last position, even if new position is stuck in solid
1018                 self.oldorigin = self.origin;
1019                 self.prevorigin = self.origin;
1020                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1021                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1022
1023                 if(g_arena)
1024                 {
1025                         Spawnqueue_Remove(self);
1026                         Spawnqueue_Mark(self);
1027                 }
1028
1029                 else if(g_ca)
1030                         self.caplayer = 1;
1031
1032                 self.event_damage = PlayerDamage;
1033
1034                 self.bot_attack = TRUE;
1035
1036                 self.statdraintime = time + 5;
1037                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1038
1039                 if(self.killcount == -666) {
1040                         PlayerScore_Clear(self);
1041                         self.killcount = 0;
1042                 }
1043
1044                 self.cnt = WEP_LASER;
1045
1046                 CL_SpawnWeaponentity();
1047                 self.alpha = default_player_alpha;
1048                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1049                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1050
1051                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1052                 self.lms_traveled_distance = 0;
1053                 self.speedrunning = FALSE;
1054
1055                 race_PostSpawn(spot);
1056
1057                 if(autocvar_spawn_debug)
1058                 {
1059                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1060                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1061                 }
1062
1063                 //stuffcmd(self, "chase_active 0");
1064                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1065
1066                 if (autocvar_g_spawnsound)
1067                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1068
1069                 if(g_assault) {
1070                         if(self.team == assault_attacker_team)
1071                                 centerprint(self, "You are attacking!");
1072                         else
1073                                 centerprint(self, "You are defending!");
1074                 }
1075
1076                 target_voicescript_clear(self);
1077
1078                 // reset fields the weapons may use
1079                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1080                 {
1081                         weapon_action(j, WR_RESETPLAYER);
1082
1083                         // all weapons must be fully loaded when we spawn
1084                         entity e;
1085                         e = get_weaponinfo(j);
1086                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1087                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1088                 }
1089                 self.weapon_forbidchange = FALSE;
1090
1091                 oldself = self;
1092                 self = spot;
1093                         activator = oldself;
1094                                 string s;
1095                                 s = self.target;
1096                                 self.target = string_null;
1097                                 SUB_UseTargets();
1098                                 self.target = s;
1099                         activator = world;
1100                 self = oldself;
1101
1102                 MUTATOR_CALLHOOK(PlayerSpawn);
1103
1104                 self.switchweapon = w_getbestweapon(self);
1105                 self.cnt = self.switchweapon;
1106                 self.weapon = 0;
1107
1108                 if(!self.alivetime)
1109                         self.alivetime = time;
1110         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1111                 PutObserverInServer ();
1112         }
1113
1114         //if(g_ctf)
1115         //      ctf_playerchanged();
1116 }
1117
1118 .float ebouncefactor, ebouncestop; // electro's values
1119 // TODO do we need all these fields, or should we stop autodetecting runtime
1120 // changes and just have a console command to update this?
1121 float ClientInit_SendEntity(entity to, float sf)
1122 {
1123         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1124         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1125         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1126         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1127         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1128         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1129         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1130         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1131         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1132         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1133         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1134         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1135         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1136         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1137         if(sv_foginterval && world.fog != "")
1138                 WriteString(MSG_ENTITY, world.fog);
1139         else
1140                 WriteString(MSG_ENTITY, "");
1141         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1142         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1143         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1144         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1145         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1146         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1147         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1148         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1149         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1150         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1151         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1152         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1153         return TRUE;
1154 }
1155
1156 void ClientInit_CheckUpdate()
1157 {
1158         self.nextthink = time;
1159         if(self.count != autocvar_g_balance_armor_blockpercent)
1160         {
1161                 self.count = autocvar_g_balance_armor_blockpercent;
1162                 self.SendFlags |= 1;
1163         }
1164         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1165         {
1166                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1167                 self.SendFlags |= 1;
1168         }
1169         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1170         {
1171                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1172                 self.SendFlags |= 1;
1173         }
1174         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1175         {
1176                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1177                 self.SendFlags |= 1;
1178         }
1179         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1180         {
1181                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1182                 self.SendFlags |= 1;
1183         }
1184         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1185         {
1186                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1187                 self.SendFlags |= 1;
1188         }
1189 }
1190
1191 void ClientInit_Spawn()
1192 {
1193         entity o;
1194         entity e;
1195         e = spawn();
1196         e.classname = "clientinit";
1197         e.think = ClientInit_CheckUpdate;
1198         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1199
1200         o = self;
1201         self = e;
1202         ClientInit_CheckUpdate();
1203         self = o;
1204 }
1205
1206 /*
1207 =============
1208 SetNewParms
1209 =============
1210 */
1211 void SetNewParms (void)
1212 {
1213         // initialize parms for a new player
1214         parm1 = -(86400 * 366);
1215 }
1216
1217 /*
1218 =============
1219 SetChangeParms
1220 =============
1221 */
1222 void SetChangeParms (void)
1223 {
1224         // save parms for level change
1225         parm1 = self.parm_idlesince - time;
1226 }
1227
1228 /*
1229 =============
1230 DecodeLevelParms
1231 =============
1232 */
1233 void DecodeLevelParms (void)
1234 {
1235         // load parms
1236         self.parm_idlesince = parm1;
1237         if(self.parm_idlesince == -(86400 * 366))
1238                 self.parm_idlesince = time;
1239
1240         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1241         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1242 }
1243
1244 /*
1245 =============
1246 ClientKill
1247
1248 Called when a client types 'kill' in the console
1249 =============
1250 */
1251
1252 .float clientkill_nexttime;
1253 void ClientKill_Now_TeamChange()
1254 {
1255         if(self.killindicator_teamchange == -1)
1256         {
1257                 self.team = -1;
1258                 JoinBestTeam( self, FALSE, FALSE );
1259         }
1260         else if(self.killindicator_teamchange == -2)
1261         {
1262                 if(g_ca)
1263                         self.caplayer = 0;
1264                 if(blockSpectators)
1265                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1266                 PutObserverInServer();
1267         }
1268         else
1269                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1270 }
1271
1272 void ClientKill_Now()
1273 {
1274         if(self.vehicle)
1275         {
1276             vehicles_exit(VHEF_RELESE);
1277             if(!self.killindicator_teamchange)
1278             {
1279             self.vehicle_health = -1;
1280             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1281             }
1282         }
1283
1284         if(self.killindicator && !wasfreed(self.killindicator))
1285                 remove(self.killindicator);
1286
1287         self.killindicator = world;
1288
1289         if(self.killindicator_teamchange)
1290                 ClientKill_Now_TeamChange();
1291
1292         // in any case:
1293         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1294
1295         // now I am sure the player IS dead
1296 }
1297 void KillIndicator_Think()
1298 {
1299         if (gameover)
1300         {
1301                 self.owner.killindicator = world;
1302                 remove(self);
1303                 return;
1304         }
1305
1306         if (!self.owner.modelindex)
1307         {
1308                 self.owner.killindicator = world;
1309                 remove(self);
1310                 return;
1311         }
1312
1313         if(self.cnt <= 0)
1314         {
1315                 self = self.owner;
1316                 ClientKill_Now(); // no oldself needed
1317                 return;
1318         }
1319     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1320     {
1321         self.nextthink = time + 1;
1322         self.cnt -= 1;
1323     }
1324         else
1325         {
1326                 if(self.cnt <= 10)
1327                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1328                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1329                 {
1330                         if(self.cnt <= 10)
1331                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1332                 }
1333                 self.nextthink = time + 1;
1334                 self.cnt -= 1;
1335         }
1336 }
1337
1338 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1339 {
1340         float killtime;
1341         entity e;
1342
1343         if (gameover)
1344                 return;
1345
1346         killtime = autocvar_g_balance_kill_delay;
1347
1348         if(g_race_qualifying || g_cts)
1349                 killtime = 0;
1350
1351     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1352     {
1353                 remove(self.killindicator);
1354                 self.killindicator = world;
1355
1356         ClientKill_Now(); // allow instant kill in this case
1357         return;
1358     }
1359
1360         self.killindicator_teamchange = targetteam;
1361
1362     if(!self.killindicator)
1363         {
1364                 if(self.modelindex && self.deadflag == DEAD_NO)
1365                 {
1366                         killtime = max(killtime, self.clientkill_nexttime - time);
1367                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1368                 }
1369
1370                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1371                 {
1372                         ClientKill_Now();
1373                 }
1374                 else
1375                 {
1376                         self.killindicator = spawn();
1377                         self.killindicator.owner = self;
1378                         self.killindicator.scale = 0.5;
1379                         setattachment(self.killindicator, self, "");
1380                         setorigin(self.killindicator, '0 0 52');
1381                         self.killindicator.think = KillIndicator_Think;
1382                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1383                         self.killindicator.cnt = ceil(killtime);
1384                         self.killindicator.count = bound(0, ceil(killtime), 10);
1385                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1386
1387                         for(e = world; (e = find(e, classname, "body")) != world; )
1388                         {
1389                                 if(e.enemy != self)
1390                                         continue;
1391                                 e.killindicator = spawn();
1392                                 e.killindicator.owner = e;
1393                                 e.killindicator.scale = 0.5;
1394                                 setattachment(e.killindicator, e, "");
1395                                 setorigin(e.killindicator, '0 0 52');
1396                                 e.killindicator.think = KillIndicator_Think;
1397                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1398                                 e.killindicator.cnt = ceil(killtime);
1399                         }
1400                         self.lip = 0;
1401                 }
1402         }
1403         if(self.killindicator)
1404         {
1405                 if(targetteam == 0) // just die
1406                 {
1407                         self.killindicator.colormod = '0 0 0';
1408                         if(clienttype(self) == CLIENTTYPE_REAL)
1409                         if(self.killindicator.cnt > 0)
1410                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1411                 }
1412                 else if(targetteam == -1) // auto
1413                 {
1414                         self.killindicator.colormod = '0 1 0';
1415                         if(clienttype(self) == CLIENTTYPE_REAL)
1416                         if(self.killindicator.cnt > 0)
1417                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1418                 }
1419                 else if(targetteam == -2) // spectate
1420                 {
1421                         self.killindicator.colormod = '0.5 0.5 0.5';
1422                         if(clienttype(self) == CLIENTTYPE_REAL)
1423                         if(self.killindicator.cnt > 0)
1424                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1425                 }
1426                 else
1427                 {
1428                         self.killindicator.colormod = TeamColor(targetteam);
1429                         if(clienttype(self) == CLIENTTYPE_REAL)
1430                         if(self.killindicator.cnt > 0)
1431                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1432                 }
1433         }
1434
1435 }
1436
1437 void ClientKill (void)
1438 {
1439         if (gameover)
1440                 return;
1441
1442         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1443         {
1444                 // do nothing
1445         }
1446     else if(self.freezetag_frozen)
1447     {
1448         // do nothing
1449     }
1450         else
1451                 ClientKill_TeamChange(0);
1452 }
1453
1454 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1455 {
1456     e.killindicator = spawn();
1457     e.killindicator.owner = e;
1458     e.killindicator.think = KillIndicator_Think;
1459     e.killindicator.nextthink = time + (e.lip) * 0.05;
1460     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1461     e.killindicator.health = 1; // this is used to indicate that it should be silent
1462     e.lip = 0;
1463 }
1464
1465 void FixClientCvars(entity e)
1466 {
1467         // send prediction settings to the client
1468         stuffcmd(e, "\nin_bindmap 0 0\n");
1469         if(g_race || g_cts)
1470                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1471         if(autocvar_g_antilag == 3) // client side hitscan
1472                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1473         if(sv_gentle)
1474                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1475         /*
1476          * we no longer need to stuff this. Remove this comment block if you feel
1477          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1478         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1479         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1480         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1481         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1482         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1483         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1484         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1485         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1486         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1487         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1488         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1489         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1490         stuffcmd(e, "cl_movement_edgefriction 1\n");
1491          */
1492 }
1493
1494 float PlayerInIDList(entity p, string idlist)
1495 {
1496         float n, i;
1497         string s;
1498
1499         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1500         if not(p.crypto_idfp)
1501                 return 0;
1502
1503         // this function allows abbreviated player IDs too!
1504         n = tokenize_console(idlist);
1505         for(i = 0; i < n; ++i)
1506         {
1507                 s = argv(i);
1508                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1509                         return 1;
1510         }
1511
1512         return 0;
1513 }
1514
1515 /*
1516 =============
1517 ClientConnect
1518
1519 Called when a client connects to the server
1520 =============
1521 */
1522 //void ctf_clientconnect();
1523 string ColoredTeamName(float t);
1524 void DecodeLevelParms (void);
1525 //void dom_player_join_team(entity pl);
1526 void set_dom_state(entity e);
1527 void ClientConnect (void)
1528 {
1529         float t;
1530
1531         if(self.flags & FL_CLIENT)
1532         {
1533                 print("Warning: ClientConnect, but already connected!\n");
1534                 return;
1535         }
1536
1537         if(Ban_MaybeEnforceBan(self))
1538                 return;
1539
1540         DecodeLevelParms();
1541
1542 #ifdef WATERMARK
1543         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1544 #endif
1545
1546         self.classname = "player_joining";
1547
1548         self.flags = FL_CLIENT;
1549         self.version_nagtime = time + 10 + random() * 10;
1550
1551         if(player_count<0)
1552         {
1553                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1554                 player_count = 0;
1555         }
1556
1557         PlayerScore_Attach(self);
1558         ClientData_Attach();
1559         accuracy_init(self);
1560
1561         bot_clientconnect();
1562
1563         playerdemo_init();
1564
1565         anticheat_init();
1566
1567         race_PreSpawnObserver();
1568
1569         //if(g_domination)
1570         //      dom_player_join_team(self);
1571
1572         // identify the right forced team
1573         if(autocvar_g_campaign)
1574         {
1575                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1576                 {
1577                         switch(autocvar_g_campaign_forceteam)
1578                         {
1579                                 case 1: self.team_forced = COLOR_TEAM1; break;
1580                                 case 2: self.team_forced = COLOR_TEAM2; break;
1581                                 case 3: self.team_forced = COLOR_TEAM3; break;
1582                                 case 4: self.team_forced = COLOR_TEAM4; break;
1583                                 default: self.team_forced = 0;
1584                         }
1585                 }
1586         }
1587         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1588                 self.team_forced = COLOR_TEAM1;
1589         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1590                 self.team_forced = COLOR_TEAM2;
1591         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1592                 self.team_forced = COLOR_TEAM3;
1593         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1594                 self.team_forced = COLOR_TEAM4;
1595         else if(autocvar_g_forced_team_otherwise == "red")
1596                 self.team_forced = COLOR_TEAM1;
1597         else if(autocvar_g_forced_team_otherwise == "blue")
1598                 self.team_forced = COLOR_TEAM2;
1599         else if(autocvar_g_forced_team_otherwise == "yellow")
1600                 self.team_forced = COLOR_TEAM3;
1601         else if(autocvar_g_forced_team_otherwise == "pink")
1602                 self.team_forced = COLOR_TEAM4;
1603         else if(autocvar_g_forced_team_otherwise == "spectate")
1604                 self.team_forced = -1;
1605         else if(autocvar_g_forced_team_otherwise == "spectator")
1606                 self.team_forced = -1;
1607         else
1608                 self.team_forced = 0;
1609
1610         if(!teamplay)
1611                 if(self.team_forced > 0)
1612                         self.team_forced = 0;
1613
1614         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1615
1616         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1617                 self.classname = "observer";
1618         } else {
1619                 if(teamplay)
1620                 {
1621                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1622                         {
1623                                 self.classname = "player";
1624                                 campaign_bots_may_start = 1;
1625                         }
1626                         else
1627                         {
1628                                 self.classname = "observer"; // do it anyway
1629                         }
1630                 }
1631                 else
1632                 {
1633                         self.classname = "player";
1634                         campaign_bots_may_start = 1;
1635                 }
1636         }
1637
1638         self.playerid = (playerid_last = playerid_last + 1);
1639
1640     if(clienttype(self) == CLIENTTYPE_BOT)
1641         PlayerStats_AddPlayer(self);
1642
1643         if(autocvar_sv_eventlog)
1644                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1645
1646         LogTeamchange(self.playerid, self.team, 1);
1647
1648         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1649
1650         self.netname_previous = strzone(self.netname);
1651
1652         bprint("^4", self.netname, "^4 connected");
1653
1654         if(self.classname != "observer" && (g_domination || g_ctf))
1655                 bprint(" and joined the ", ColoredTeamName(self.team));
1656
1657         bprint("\n");
1658
1659         stuffcmd(self, strcat(clientstuff, "\n"));
1660         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1661         stuffcmd(self, "cl_particles_reloadeffects\n");
1662
1663         FixClientCvars(self);
1664
1665         // spawnfunc_waypoint sprites
1666         WaypointSprite_InitClient(self);
1667
1668         // Wazat's grappling hook
1669         SetGrappleHookBindings();
1670
1671         // get autoswitch state from player when he toggles it
1672         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1673
1674         // get version info from player
1675         stuffcmd(self, "cmd clientversion $gameversion\n");
1676
1677         // get other cvars from player
1678         GetCvars(0);
1679
1680         // notify about available teams
1681         if(teamplay)
1682         {
1683                 CheckAllowedTeams(self);
1684                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1685                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1686         }
1687         else
1688                 stuffcmd(self, "set _teams_available 0\n");
1689
1690         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1691
1692         if(g_arena || g_ca)
1693         {
1694                 self.classname = "observer";
1695                 if(g_arena)
1696                         Spawnqueue_Insert(self);
1697         }
1698         /*else if(g_ctf)
1699         {
1700                 ctf_clientconnect();
1701         }*/
1702
1703         attach_entcs();
1704
1705         bot_relinkplayerlist();
1706
1707         self.spectatortime = time;
1708         if(blockSpectators)
1709         {
1710                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1711         }
1712
1713         self.jointime = time;
1714         self.allowedTimeouts = autocvar_sv_timeout_number;
1715
1716         if(clienttype(self) == CLIENTTYPE_REAL)
1717         {
1718                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1719                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1720         }
1721
1722         if(g_lms)
1723         {
1724                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1725                 {
1726                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1727                         self.frags = FRAGS_SPECTATOR;
1728                 }
1729         }
1730
1731         if(!sv_foginterval && world.fog != "")
1732                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1733
1734         SoundEntity_Attach(self);
1735
1736         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1737         {
1738                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1739                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1740         }
1741         else
1742                 self.hitplotfh = -1;
1743
1744         if(g_race || g_cts) {
1745                 string rr;
1746                 if(g_cts)
1747                         rr = CTS_RECORD;
1748                 else
1749                         rr = RACE_RECORD;
1750                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1751
1752                 msg_entity = self;
1753                 race_send_recordtime(MSG_ONE);
1754                 race_send_speedaward(MSG_ONE);
1755
1756                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1757                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1758                 race_send_speedaward_alltimebest(MSG_ONE);
1759
1760                 float i;
1761                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1762                         race_SendRankings(i, 0, 0, MSG_ONE);
1763                 }
1764         }
1765         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1766                 send_CSQC_teamnagger();
1767
1768         if (g_domination)
1769                 set_dom_state(self);
1770
1771         CheatInitClient();
1772
1773         if(!autocvar_g_campaign)
1774                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1775 }
1776
1777 /*
1778 =============
1779 ClientDisconnect
1780
1781 Called when a client disconnects from the server
1782 =============
1783 */
1784 .entity chatbubbleentity;
1785 void ReadyCount();
1786 void ClientDisconnect (void)
1787 {
1788         if(self.vehicle)
1789             vehicles_exit(VHEF_RELESE);
1790
1791         if not(self.flags & FL_CLIENT)
1792         {
1793                 print("Warning: ClientDisconnect without ClientConnect\n");
1794                 return;
1795         }
1796
1797         PlayerStats_AddGlobalInfo(self);
1798
1799         CheatShutdownClient();
1800
1801         if(self.hitplotfh >= 0)
1802         {
1803                 fclose(self.hitplotfh);
1804                 self.hitplotfh = -1;
1805         }
1806
1807         anticheat_report();
1808         anticheat_shutdown();
1809
1810         playerdemo_shutdown();
1811
1812         bot_clientdisconnect();
1813
1814         if(self.entcs)
1815                 detach_entcs();
1816
1817         if(autocvar_sv_eventlog)
1818                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1819         bprint ("^4",self.netname);
1820         bprint ("^4 disconnected\n");
1821
1822         SoundEntity_Detach(self);
1823
1824         DropAllRunes(self);
1825         MUTATOR_CALLHOOK(ClientDisconnect);
1826
1827         Portal_ClearAll(self);
1828
1829         if(self.flagcarried)
1830                 DropFlag(self.flagcarried, world, world);
1831         if(self.ballcarried && g_nexball)
1832                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1833
1834         // Here, everything has been done that requires this player to be a client.
1835
1836         self.flags &~= FL_CLIENT;
1837
1838         if (self.chatbubbleentity)
1839                 remove (self.chatbubbleentity);
1840
1841         if (self.killindicator)
1842                 remove (self.killindicator);
1843
1844         WaypointSprite_PlayerGone();
1845
1846         bot_relinkplayerlist();
1847
1848         if(g_arena)
1849         {
1850                 Spawnqueue_Unmark(self);
1851                 Spawnqueue_Remove(self);
1852         }
1853
1854         accuracy_free(self);
1855         ClientData_Detach();
1856         PlayerScore_Detach(self);
1857
1858         if(self.netname_previous)
1859                 strunzone(self.netname_previous);
1860         if(self.clientstatus)
1861                 strunzone(self.clientstatus);
1862         if(self.weaponorder_byimpulse)
1863                 strunzone(self.weaponorder_byimpulse);
1864
1865         ClearPlayerSounds();
1866
1867         if(self.personal)
1868                 remove(self.personal);
1869
1870         self.playerid = 0;
1871         ReadyCount();
1872
1873         // free cvars
1874         GetCvars(-1);
1875 }
1876
1877 .float BUTTON_CHAT;
1878 void ChatBubbleThink()
1879 {
1880         self.nextthink = time;
1881         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1882         {
1883                 if(self.owner) // but why can that ever be world?
1884                         self.owner.chatbubbleentity = world;
1885                 remove(self);
1886                 return;
1887         }
1888         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1889 #ifdef TETRIS
1890                 || self.owner.tetris_on
1891 #endif
1892         )
1893                 self.model = self.mdl;
1894         else
1895                 self.model = "";
1896 };
1897
1898 void UpdateChatBubble()
1899 {
1900         if (!self.modelindex)
1901                 return;
1902         // spawn a chatbubble entity if needed
1903         if (!self.chatbubbleentity)
1904         {
1905                 self.chatbubbleentity = spawn();
1906                 self.chatbubbleentity.owner = self;
1907                 self.chatbubbleentity.exteriormodeltoclient = self;
1908                 self.chatbubbleentity.think = ChatBubbleThink;
1909                 self.chatbubbleentity.nextthink = time;
1910                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1911                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1912                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1913                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1914                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1915                 self.chatbubbleentity.model = "";
1916                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1917         }
1918 }
1919
1920
1921 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1922 // added to the model skins
1923 /*void UpdateColorModHack()
1924 {
1925         local float c;
1926         c = self.clientcolors & 15;
1927         // LordHavoc: only bothering to support white, green, red, yellow, blue
1928              if (!teamplay) self.colormod = '0 0 0';
1929         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1930         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1931         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1932         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1933         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1934         else self.colormod = '1 1 1';
1935 };*/
1936
1937 .float oldcolormap;
1938 void respawn(void)
1939 {
1940         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1941         {
1942                 self.solid = SOLID_NOT;
1943                 self.takedamage = DAMAGE_NO;
1944                 self.movetype = MOVETYPE_FLY;
1945                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1946                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1947                 self.effects |= EF_ADDITIVE;
1948                 self.oldcolormap = self.colormap;
1949                 self.colormap = 512;
1950                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1951                 if(autocvar_g_respawn_ghosts_maxtime)
1952                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1953         }
1954
1955         CopyBody(1);
1956         self.effects |= EF_NODRAW; // prevent another CopyBody
1957         if(self.oldcolormap)
1958         {
1959                 self.colormap = self.oldcolormap;
1960                 self.oldcolormap = 0;
1961         }
1962         PutClientInServer();
1963 }
1964
1965 void play_countdown(float finished, string samp)
1966 {
1967         if(clienttype(self) == CLIENTTYPE_REAL)
1968                 if(floor(finished - time - frametime) != floor(finished - time))
1969                         if(finished - time < 6)
1970                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1971 }
1972
1973 void player_powerups (void)
1974 {
1975         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1976         olditems = self.items;
1977
1978         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1979         {
1980                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1981                 self.modelflags |= MF_ROCKET;
1982         }
1983         else
1984         {
1985                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1986                 self.modelflags &~= MF_ROCKET;
1987         }
1988
1989         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1990
1991         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1992                 return;
1993
1994         Fire_ApplyDamage(self);
1995         Fire_ApplyEffect(self);
1996
1997         if (g_minstagib)
1998         {
1999                 self.effects |= EF_FULLBRIGHT;
2000
2001                 if (self.items & IT_STRENGTH)
2002                 {
2003                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2004                         if (time > self.strength_finished)
2005                         {
2006                                 self.alpha = default_player_alpha;
2007                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2008                                 self.items &~= IT_STRENGTH;
2009                                 sprint(self, "^3Invisibility has worn off\n");
2010                         }
2011                 }
2012                 else
2013                 {
2014                         if (time < self.strength_finished)
2015                         {
2016                                 self.alpha = g_minstagib_invis_alpha;
2017                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2018                                 self.items |= IT_STRENGTH;
2019                                 sprint(self, "^3You are invisible\n");
2020                         }
2021                 }
2022
2023                 if (self.items & IT_INVINCIBLE)
2024                 {
2025                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2026                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2027                         {
2028                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2029                                 sprint(self, "^3Speed has worn off\n");
2030                         }
2031                 }
2032                 else
2033                 {
2034                         if (time < self.invincible_finished)
2035                         {
2036                                 self.items = self.items | IT_INVINCIBLE;
2037                                 sprint(self, "^3You are on speed\n");
2038                         }
2039                 }
2040         }
2041         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2042         {
2043                 if (self.items & IT_STRENGTH)
2044                 {
2045                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2046                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2047                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2048                         {
2049                                 self.items = self.items - (self.items & IT_STRENGTH);
2050                                 sprint(self, "^3Strength has worn off\n");
2051                         }
2052                 }
2053                 else
2054                 {
2055                         if (time < self.strength_finished)
2056                         {
2057                                 self.items = self.items | IT_STRENGTH;
2058                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2059                         }
2060                 }
2061                 if (self.items & IT_INVINCIBLE)
2062                 {
2063                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2064                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2065                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2066                         {
2067                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2068                                 sprint(self, "^3Shield has worn off\n");
2069                         }
2070                 }
2071                 else
2072                 {
2073                         if (time < self.invincible_finished)
2074                         {
2075                                 self.items = self.items | IT_INVINCIBLE;
2076                                 sprint(self, "^3Shield surrounds you\n");
2077                         }
2078                 }
2079
2080                 if(autocvar_g_nodepthtestplayers)
2081                         self.effects = self.effects | EF_NODEPTHTEST;
2082
2083                 if(autocvar_g_fullbrightplayers)
2084                         self.effects = self.effects | EF_FULLBRIGHT;
2085
2086                 // midair gamemode: damage only while in the air
2087                 // if in midair mode, being on ground grants temporary invulnerability
2088                 // (this is so that multishot weapon don't clear the ground flag on the
2089                 // first damage in the frame, leaving the player vulnerable to the
2090                 // remaining hits in the same frame)
2091                 if (self.flags & FL_ONGROUND)
2092                 if (g_midair)
2093                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2094
2095                 if (time >= game_starttime)
2096                 if (time < self.spawnshieldtime)
2097                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2098         }
2099
2100         MUTATOR_CALLHOOK(PlayerPowerups);
2101 }
2102
2103 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2104 {
2105         if(current > stable)
2106                 return current;
2107         else if(current > stable - 0.25) // when close enough, "snap"
2108                 return stable;
2109         else
2110                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2111 }
2112
2113 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2114 {
2115         if(current < stable)
2116                 return current;
2117         else if(current < stable + 0.25) // when close enough, "snap"
2118                 return stable;
2119         else
2120                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2121 }
2122
2123 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2124 {
2125         if(current > rotstable)
2126         {
2127                 if(rotframetime > 0)
2128                 {
2129                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2130                         current = max(rotstable, current - rotlinear * rotframetime);
2131                 }
2132         }
2133         else if(current < regenstable)
2134         {
2135                 if(regenframetime > 0)
2136                 {
2137                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2138                         current = min(regenstable, current + regenlinear * regenframetime);
2139                 }
2140         }
2141
2142         if(current > limit)
2143                 current = limit;
2144
2145         return current;
2146 }
2147
2148 void player_regen (void)
2149 {
2150         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2151         maxh = autocvar_g_balance_health_rotstable;
2152         maxa = autocvar_g_balance_armor_rotstable;
2153         maxf = autocvar_g_balance_fuel_rotstable;
2154         minh = autocvar_g_balance_health_regenstable;
2155         mina = autocvar_g_balance_armor_regenstable;
2156         minf = autocvar_g_balance_fuel_regenstable;
2157         limith = autocvar_g_balance_health_limit;
2158         limita = autocvar_g_balance_armor_limit;
2159         limitf = autocvar_g_balance_fuel_limit;
2160
2161         max_mod = regen_mod = rot_mod = limit_mod = 1;
2162
2163         if (self.runes & RUNE_REGEN)
2164         {
2165                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2166                 {
2167                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2168                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2169                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2170                 }
2171                 else
2172                 {
2173                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2174                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2175                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2176                 }
2177         }
2178         else if (self.runes & CURSE_VENOM)
2179         {
2180                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2181                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2182                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2183                 else
2184                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2185                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2186                 //if (!self.runes & RUNE_REGEN)
2187                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2188         }
2189         maxh = maxh * max_mod;
2190         //maxa = maxa * max_mod;
2191         //maxf = maxf * max_mod;
2192         minh = minh * max_mod;
2193         //mina = mina * max_mod;
2194         //minf = minf * max_mod;
2195         limith = limith * limit_mod;
2196         limita = limita * limit_mod;
2197         //limitf = limitf * limit_mod;
2198
2199         if(g_lms && g_ca)
2200                 rot_mod = 0;
2201
2202         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2203         {
2204                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2205                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2206
2207                 // if player rotted to death...  die!
2208                 if(self.health < 1)
2209                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2210         }
2211
2212         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2213                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2214 }
2215
2216 float zoomstate_set;
2217 void SetZoomState(float z)
2218 {
2219         if(z != self.zoomstate)
2220         {
2221                 self.zoomstate = z;
2222                 ClientData_Touch(self);
2223         }
2224         zoomstate_set = 1;
2225 }
2226
2227 void GetPressedKeys(void) {
2228         MUTATOR_CALLHOOK(GetPressedKeys);
2229         if (self.movement_x > 0) // get if movement keys are pressed
2230         {       // forward key pressed
2231                 self.pressedkeys |= KEY_FORWARD;
2232                 self.pressedkeys &~= KEY_BACKWARD;
2233         }
2234         else if (self.movement_x < 0)
2235         {       // backward key pressed
2236                 self.pressedkeys |= KEY_BACKWARD;
2237                 self.pressedkeys &~= KEY_FORWARD;
2238         }
2239         else
2240         {       // no x input
2241                 self.pressedkeys &~= KEY_FORWARD;
2242                 self.pressedkeys &~= KEY_BACKWARD;
2243         }
2244
2245         if (self.movement_y > 0)
2246         {       // right key pressed
2247                 self.pressedkeys |= KEY_RIGHT;
2248                 self.pressedkeys &~= KEY_LEFT;
2249         }
2250         else if (self.movement_y < 0)
2251         {       // left key pressed
2252                 self.pressedkeys |= KEY_LEFT;
2253                 self.pressedkeys &~= KEY_RIGHT;
2254         }
2255         else
2256         {       // no y input
2257                 self.pressedkeys &~= KEY_RIGHT;
2258                 self.pressedkeys &~= KEY_LEFT;
2259         }
2260
2261         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2262                 self.pressedkeys |= KEY_JUMP;
2263         else
2264                 self.pressedkeys &~= KEY_JUMP;
2265         if (self.BUTTON_CROUCH)
2266                 self.pressedkeys |= KEY_CROUCH;
2267         else
2268                 self.pressedkeys &~= KEY_CROUCH;
2269 }
2270
2271 /*
2272 ======================
2273 spectate mode routines
2274 ======================
2275 */
2276
2277 void SpectateCopy(entity spectatee) {
2278         other = spectatee;
2279         MUTATOR_CALLHOOK(SpectateCopy);
2280         self.armortype = spectatee.armortype;
2281         self.armorvalue = spectatee.armorvalue;
2282         self.ammo_cells = spectatee.ammo_cells;
2283         self.ammo_shells = spectatee.ammo_shells;
2284         self.ammo_nails = spectatee.ammo_nails;
2285         self.ammo_rockets = spectatee.ammo_rockets;
2286         self.ammo_fuel = spectatee.ammo_fuel;
2287         self.clip_load = spectatee.clip_load;
2288         self.clip_size = spectatee.clip_size;
2289         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2290         self.health = spectatee.health;
2291         self.impulse = 0;
2292         self.items = spectatee.items;
2293         self.last_pickup = spectatee.last_pickup;
2294         self.hit_time = spectatee.hit_time;
2295         self.metertime = spectatee.metertime;
2296         self.strength_finished = spectatee.strength_finished;
2297         self.invincible_finished = spectatee.invincible_finished;
2298         self.pressedkeys = spectatee.pressedkeys;
2299         self.weapons = spectatee.weapons;
2300         self.switchweapon = spectatee.switchweapon;
2301         self.weapon = spectatee.weapon;
2302         self.nex_charge = spectatee.nex_charge;
2303         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2304         self.hagar_load = spectatee.hagar_load;
2305         self.minelayer_mines = spectatee.minelayer_mines;
2306         self.punchangle = spectatee.punchangle;
2307         self.view_ofs = spectatee.view_ofs;
2308         self.v_angle = spectatee.v_angle;
2309         self.velocity = spectatee.velocity;
2310         self.dmg_take = spectatee.dmg_take;
2311         self.dmg_save = spectatee.dmg_save;
2312         self.dmg_inflictor = spectatee.dmg_inflictor;
2313         self.angles = spectatee.v_angle;
2314         self.fixangle = TRUE;
2315         setorigin(self, spectatee.origin);
2316         setsize(self, spectatee.mins, spectatee.maxs);
2317         SetZoomState(spectatee.zoomstate);
2318
2319         anticheat_spectatecopy(spectatee);
2320
2321         //self.vehicle = spectatee.vehicle;
2322
2323         self.hud = spectatee.hud;
2324         if(spectatee.vehicle)
2325     {
2326         setorigin(self, spectatee.origin);
2327         self.velocity = spectatee.vehicle.velocity;
2328         self.v_angle += spectatee.vehicle.angles;
2329         //self.v_angle_x *= -1;
2330         self.vehicle_health = spectatee.vehicle_health;
2331         self.vehicle_shield = spectatee.vehicle_shield;
2332         self.vehicle_energy = spectatee.vehicle_energy;
2333         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2334         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2335         self.vehicle_reload1 = spectatee.vehicle_reload1;
2336         self.vehicle_reload2 = spectatee.vehicle_reload2;
2337
2338         msg_entity = self;
2339         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2340         WriteEntity(MSG_ONE, spectatee);
2341         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2342     }
2343 }
2344
2345 float SpectateUpdate() {
2346         if(!self.enemy)
2347             return 0;
2348
2349         if (self == self.enemy)
2350                 return 0;
2351
2352         if(self.enemy.classname != "player")
2353                 return 0;
2354
2355         SpectateCopy(self.enemy);
2356
2357         return 1;
2358 }
2359
2360 float SpectateNext() {
2361         other = find(self.enemy, classname, "player");
2362
2363         if (!other)
2364                 other = find(other, classname, "player");
2365
2366         if (other)
2367                 self.enemy = other;
2368
2369         if(self.enemy.classname == "player") {
2370             if(self.enemy.vehicle)
2371             {
2372             msg_entity = self;
2373             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2374             WriteEntity(MSG_ONE, self.enemy);
2375             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2376             self.movetype = MOVETYPE_NONE;
2377             accuracy_resend(self);
2378             }
2379             else
2380             {
2381             msg_entity = self;
2382             WriteByte(MSG_ONE, SVC_SETVIEW);
2383             WriteEntity(MSG_ONE, self.enemy);
2384             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2385             self.movetype = MOVETYPE_NONE;
2386             accuracy_resend(self);
2387
2388             if(!SpectateUpdate())
2389                 PutObserverInServer();
2390         }
2391         return 1;
2392         } else {
2393                 return 0;
2394         }
2395 }
2396
2397 /*
2398 =============
2399 ShowRespawnCountdown()
2400
2401 Update a respawn countdown display.
2402 =============
2403 */
2404 void ShowRespawnCountdown()
2405 {
2406         float number;
2407         if(self.deadflag == DEAD_NO) // just respawned?
2408                 return;
2409         else
2410         {
2411                 number = ceil(self.death_time - time);
2412                 if(number <= 0)
2413                         return;
2414                 if(number <= self.respawn_countdown)
2415                 {
2416                         self.respawn_countdown = number - 1;
2417                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2418                                 AnnounceTo(self, strcat(ftos(number), ""));
2419                 }
2420         }
2421 }
2422
2423 void LeaveSpectatorMode()
2424 {
2425         if(nJoinAllowed(1)) {
2426                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2427                         self.classname = "player";
2428
2429                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2430                                 JoinBestTeam(self, FALSE, TRUE);
2431
2432                         if(autocvar_g_campaign)
2433                                 campaign_bots_may_start = 1;
2434
2435                         PutClientInServer();
2436
2437                         if(self.classname == "player")
2438                                 bprint ("^4", self.netname, "^4 is playing now\n");
2439
2440                         if(!autocvar_g_campaign)
2441                         if (time < self.jointime + autocvar_welcome_message_time)
2442                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2443
2444                         return;
2445                 } else {
2446                         if (g_ca && self.caplayer) {
2447                         }       // do nothing
2448                         else
2449                                 stuffcmd(self,"menu_showteamselect\n");
2450                         return;
2451                 }
2452         }
2453         else {
2454                 //player may not join because of g_maxplayers is set
2455                 centerprint(self, PREVENT_JOIN_TEXT);
2456         }
2457 }
2458
2459 /**
2460  * Determines whether the player is allowed to join. This depends on cvar
2461  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2462  * it checks whether the number of currently playing players exceeds g_maxplayers.
2463  * @return int number of free slots for players, 0 if none
2464  */
2465 float nJoinAllowed(float includeMe) {
2466         if(self.team_forced < 0)
2467                 return FALSE; // forced spectators can never join
2468
2469         // TODO simplify this
2470         local entity e;
2471
2472         local float totalClients;
2473         FOR_EACH_CLIENT(e)
2474                 totalClients += 1;
2475
2476         if (!autocvar_g_maxplayers)
2477                 return maxclients - totalClients + includeMe;
2478
2479         local float currentlyPlaying;
2480         FOR_EACH_REALPLAYER(e)
2481                 currentlyPlaying += 1;
2482
2483         if(currentlyPlaying < autocvar_g_maxplayers)
2484                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2485
2486         return 0;
2487 }
2488
2489 /**
2490  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2491  * g_maxplayers_spectator_blocktime seconds
2492  */
2493 void checkSpectatorBlock() {
2494         if(self.classname == "spectator" || self.classname == "observer") {
2495                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2496                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2497                         dropclient(self);
2498                 }
2499         }
2500 }
2501
2502 void ObserverThink()
2503 {
2504         if (self.flags & FL_JUMPRELEASED) {
2505                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2506                         self.flags &~= FL_JUMPRELEASED;
2507                         self.flags |= FL_SPAWNING;
2508                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2509                         self.flags &~= FL_JUMPRELEASED;
2510                         if(SpectateNext() == 1) {
2511                                 self.classname = "spectator";
2512                         }
2513                 }
2514         } else {
2515                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2516                         self.flags |= FL_JUMPRELEASED;
2517                         if(self.flags & FL_SPAWNING)
2518                         {
2519                                 self.flags &~= FL_SPAWNING;
2520                                 LeaveSpectatorMode();
2521                                 return;
2522                         }
2523                 }
2524         }
2525 }
2526
2527 void SpectatorThink()
2528 {
2529         if (self.flags & FL_JUMPRELEASED) {
2530                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2531                         self.flags &~= FL_JUMPRELEASED;
2532                         self.flags |= FL_SPAWNING;
2533                 } else if(self.BUTTON_ATCK) {
2534                         self.flags &~= FL_JUMPRELEASED;
2535                         if(SpectateNext() == 1) {
2536                                 self.classname = "spectator";
2537                         } else {
2538                                 self.classname = "observer";
2539                                 PutClientInServer();
2540                         }
2541                 } else if (self.BUTTON_ATCK2) {
2542                         self.flags &~= FL_JUMPRELEASED;
2543                         self.classname = "observer";
2544                         PutClientInServer();
2545                 } else {
2546                         if(!SpectateUpdate())
2547                                 PutObserverInServer();
2548                 }
2549         } else {
2550                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2551                         self.flags |= FL_JUMPRELEASED;
2552                         if(self.flags & FL_SPAWNING)
2553                         {
2554                                 self.flags &~= FL_SPAWNING;
2555                                 LeaveSpectatorMode();
2556                                 return;
2557                         }
2558                 }
2559                 if(!SpectateUpdate())
2560                         PutObserverInServer();
2561         }
2562
2563         self.flags |= FL_CLIENT | FL_NOTARGET;
2564 }
2565
2566 float ctf_usekey();
2567 void PlayerUseKey()
2568 {
2569         if(self.classname != "player")
2570                 return;
2571
2572         if(self.vehicle)
2573         {
2574         vehicles_exit(VHEF_NORMAL);
2575         return;
2576         }
2577
2578         // a use key was pressed; call handlers
2579         if(ctf_usekey())
2580                 return;
2581
2582         MUTATOR_CALLHOOK(PlayerUseKey);
2583 }
2584
2585 .float touchexplode_time;
2586
2587 /*
2588 =============
2589 PlayerPreThink
2590
2591 Called every frame for each client before the physics are run
2592 =============
2593 */
2594 .float usekeypressed;
2595 void() ctf_setstatus;
2596 void() nexball_setstatus;
2597 .float items_added;
2598 .float motd_actived_time; // used for both motd and campaign_message
2599 void PlayerPreThink (void)
2600 {
2601         WarpZone_PlayerPhysics_FixVAngle();
2602
2603         self.stat_game_starttime = game_starttime;
2604         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2605         self.stat_leadlimit = autocvar_leadlimit;
2606
2607         if(frametime)
2608         {
2609                 // physics frames: update anticheat stuff
2610                 anticheat_prethink();
2611         }
2612
2613         if(blockSpectators && frametime)
2614                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2615                 checkSpectatorBlock();
2616
2617         zoomstate_set = 0;
2618
2619         if(self.netname_previous != self.netname)
2620         {
2621                 if(autocvar_sv_eventlog)
2622                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2623                 if(self.netname_previous)
2624                         strunzone(self.netname_previous);
2625                 self.netname_previous = strzone(self.netname);
2626         }
2627
2628         // version nagging
2629         if(self.version_nagtime)
2630                 if(self.cvar_g_xonoticversion)
2631                         if(time > self.version_nagtime)
2632                         {
2633                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2634                                 {
2635                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2636                                         {
2637                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2638                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2639                                         }
2640                                         else
2641                                         {
2642                                                 float r;
2643                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2644                                                 if(r < 0)
2645                                                 {
2646                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2647                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2648                                                 }
2649                                                 else if(r > 0)
2650                                                 {
2651                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2652                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2653                                                 }
2654                                         }
2655                                 }
2656                                 self.version_nagtime = 0;
2657                         }
2658
2659         // GOD MODE info
2660         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2661         {
2662                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2663                 self.max_armorvalue = 0;
2664         }
2665
2666 #ifdef TETRIS
2667         if (TetrisPreFrame())
2668                 return;
2669 #endif
2670
2671         MUTATOR_CALLHOOK(PlayerPreThink);
2672
2673         if(self.BUTTON_USE && !self.usekeypressed)
2674                 PlayerUseKey();
2675         self.usekeypressed = self.BUTTON_USE;
2676
2677         if (self.motd_actived_time == 0) {
2678                 if (autocvar_g_campaign) {
2679                         if (self.classname == "player" && self.BUTTON_INFO) {
2680                                 self.motd_actived_time = time;
2681                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2682                         }
2683                 } else {
2684                         if ((self.classname == "player" || time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2685                                 self.motd_actived_time = time;
2686                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2687                         }
2688                 }
2689         } else { // showing MOTD or campaign message
2690                 if (autocvar_g_campaign) {
2691                         if (self.classname == "player") {
2692                                 if (self.BUTTON_INFO)
2693                                         self.motd_actived_time = time;
2694                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2695                                         self.motd_actived_time = 0;
2696                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2697                                 }
2698                         }
2699                 } else {
2700                         if (self.classname == "player" || (time - self.jointime) > autocvar_welcome_message_time) {
2701                                 if (self.BUTTON_INFO)
2702                                         self.motd_actived_time = time;
2703                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2704                                         self.motd_actived_time = 0;
2705                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2706                                 }
2707                         }
2708                 }
2709         }
2710
2711         if(self.classname == "player") {
2712 //              if(self.netname == "Wazat")
2713 //                      bprint(self.classname, "\n");
2714
2715                 CheckRules_Player();
2716
2717                 if (intermission_running)
2718                 {
2719                         IntermissionThink ();   // otherwise a button could be missed between
2720                         return;                                 // the think tics
2721                 }
2722
2723                 //don't allow the player to turn around while game is paused!
2724                 if(timeoutStatus == 2) {
2725                         // FIXME turn this into CSQC stuff
2726                         self.v_angle = self.lastV_angle;
2727                         self.angles = self.lastV_angle;
2728                         self.fixangle = TRUE;
2729                 }
2730
2731                 if(frametime)
2732                 {
2733                         if(self.health <= 0 && autocvar_g_deathglow)
2734                         {
2735                                 if(self.glowmod_x > 0)
2736                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2737                                 else
2738                                         self.glowmod_x = -1;
2739                                 if(self.glowmod_y > 0)
2740                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2741                                 else
2742                                         self.glowmod_y = -1;
2743                                 if(self.glowmod_z > 0)
2744                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2745                                 else
2746                                         self.glowmod_z = -1;
2747                         }
2748                         else
2749                         {
2750                                 // set weapon and player glowmod
2751                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2752
2753                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2754                                 {
2755                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2756                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2757                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2758
2759                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2760                                         {
2761                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2762                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2763                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2764                                         }
2765                                 }
2766                                 else
2767                                         self.weaponentity_glowmod = self.glowmod;
2768                         }
2769                         player_powerups();
2770                 }
2771
2772                 if (g_minstagib)
2773                         minstagib_ammocheck();
2774
2775                 if (self.deadflag != DEAD_NO)
2776                 {
2777                         float button_pressed, force_respawn;
2778                         if(self.personal && g_race_qualifying)
2779                         {
2780                                 if(time > self.death_time)
2781                                 {
2782                                         self.death_time = time + 1; // only retry once a second
2783                                         respawn();
2784                                         self.impulse = 141;
2785                                 }
2786                         }
2787                         else
2788                         {
2789                                 if(frametime)
2790                                         player_anim();
2791                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2792                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2793                                 if (self.deadflag == DEAD_DYING)
2794                                 {
2795                                         if(force_respawn)
2796                                                 self.deadflag = DEAD_RESPAWNING;
2797                                         else if(!button_pressed)
2798                                                 self.deadflag = DEAD_DEAD;
2799                                 }
2800                                 else if (self.deadflag == DEAD_DEAD)
2801                                 {
2802                                         if(button_pressed)
2803                                                 self.deadflag = DEAD_RESPAWNABLE;
2804                                 }
2805                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2806                                 {
2807                                         if(!button_pressed)
2808                                                 self.deadflag = DEAD_RESPAWNING;
2809                                 }
2810                                 else if (self.deadflag == DEAD_RESPAWNING)
2811                                 {
2812                                         if(time > self.death_time)
2813                                         {
2814                                                 self.death_time = time + 1; // only retry once a second
2815                                                 respawn();
2816                                         }
2817                                 }
2818                                 ShowRespawnCountdown();
2819                         }
2820                         return;
2821                 }
2822                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2823                 // so (self.deadflag == DEAD_NO) is always true in the code below
2824
2825                 if(g_touchexplode)
2826                 if(time > self.touchexplode_time)
2827                 if(self.classname == "player")
2828                 if(self.deadflag == DEAD_NO)
2829                 if not(IS_INDEPENDENT_PLAYER(self))
2830                 FOR_EACH_PLAYER(other) if(self != other)
2831                 {
2832                         if(time > other.touchexplode_time)
2833                         if(other.deadflag == DEAD_NO)
2834                         if not(IS_INDEPENDENT_PLAYER(other))
2835                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2836                         {
2837                                 PlayerTouchExplode(self, other);
2838                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2839                         }
2840                 }
2841
2842                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2843                 {
2844                         vector dist;
2845
2846                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2847                         dist = self.prevorigin - self.origin;
2848                         dist_z = 0;
2849                         self.lms_traveled_distance += fabs(vlen(dist));
2850
2851                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2852                         {
2853                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2854                                 self.lms_traveled_distance = 0;
2855                         }
2856
2857                         if(time > self.lms_nextcheck)
2858                         {
2859                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2860                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2861                                 {
2862                                         centerprint(self, autocvar_g_lms_campcheck_message);
2863                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2864                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2865                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2866                                 }
2867                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2868                                 self.lms_traveled_distance = 0;
2869                         }
2870                 }
2871
2872                 self.prevorigin = self.origin;
2873
2874                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2875                 {
2876                         if (!self.crouch)
2877                         {
2878                                 self.crouch = TRUE;
2879                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2880                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2881                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2882                         }
2883                 }
2884                 else
2885                 {
2886                         if (self.crouch)
2887                         {
2888                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2889                                 if (!trace_startsolid)
2890                                 {
2891                                         self.crouch = FALSE;
2892                                         self.view_ofs = PL_VIEW_OFS;
2893                                         setsize (self, PL_MIN, PL_MAX);
2894                                 }
2895                         }
2896                 }
2897
2898                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2899                 {
2900                         if(self.bloodloss_timer < time)
2901                         {
2902                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2903                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2904                         }
2905                 }
2906
2907                 FixPlayermodel();
2908
2909                 GrapplingHookFrame();
2910
2911                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2912                 //if(frametime)
2913                 {
2914                         self.items &~= self.items_added;
2915
2916                         W_WeaponFrame();
2917
2918                         self.items_added = 0;
2919                         if(self.items & IT_JETPACK)
2920                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2921                                         self.items_added |= IT_FUEL;
2922
2923                         self.items |= self.items_added;
2924                 }
2925
2926                 player_regen();
2927
2928                 // rot nex charge to the charge limit
2929                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2930                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2931
2932                 if(frametime)
2933                         player_anim();
2934
2935                 if(g_ctf)
2936                         ctf_setstatus();
2937
2938                 if(g_nexball)
2939                         nexball_setstatus();
2940
2941                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2942
2943                 //self.angles_y=self.v_angle_y + 90;   // temp
2944         } else if(gameover) {
2945                 if (intermission_running)
2946                         IntermissionThink ();   // otherwise a button could be missed between
2947                 return;
2948         } else if(self.classname == "observer") {
2949                 ObserverThink();
2950         } else if(self.classname == "spectator") {
2951                 SpectatorThink();
2952         }
2953
2954         if(!zoomstate_set)
2955                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2956
2957         float oldspectatee_status;
2958         oldspectatee_status = self.spectatee_status;
2959         if(self.classname == "spectator")
2960                 self.spectatee_status = num_for_edict(self.enemy);
2961         else if(self.classname == "observer")
2962                 self.spectatee_status = num_for_edict(self);
2963         else
2964                 self.spectatee_status = 0;
2965         if(self.spectatee_status != oldspectatee_status)
2966         {
2967                 ClientData_Touch(self);
2968                 if(g_race || g_cts)
2969                         race_InitSpectator();
2970         }
2971
2972         if(self.teamkill_soundtime)
2973         if(time > self.teamkill_soundtime)
2974         {
2975                 self.teamkill_soundtime = 0;
2976
2977                 entity oldpusher, oldself;
2978
2979                 oldself = self; self = self.teamkill_soundsource;
2980                 oldpusher = self.pusher; self.pusher = oldself;
2981
2982                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2983
2984                 self.pusher = oldpusher;
2985                 self = oldself;
2986         }
2987
2988         if(self.taunt_soundtime)
2989         if(time > self.taunt_soundtime)
2990         {
2991                 self.taunt_soundtime = 0;
2992                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2993         }
2994
2995         target_voicescript_next(self);
2996
2997         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2998         if(!self.weapon)
2999                 self.clip_load = self.clip_size = 0;
3000 }
3001
3002 float isInvisibleString(string s)
3003 {
3004         float i, n, c;
3005         s = strdecolorize(s);
3006         for((i = 0), (n = strlen(s)); i < n; ++i)
3007         {
3008                 c = str2chr(s, i);
3009                 switch(c)
3010                 {
3011                         case 0:
3012                         case 32: // space
3013                                 break;
3014                         case 192: // charmap space
3015                                 if (!autocvar_utf8_enable)
3016                                         break;
3017                                 return FALSE;
3018                         case 160: // space in unicode fonts
3019                         case 0xE000 + 192: // utf8 charmap space
3020                                 if (autocvar_utf8_enable)
3021                                         break;
3022                         default:
3023                                 return FALSE;
3024                 }
3025         }
3026         return TRUE;
3027 }
3028
3029 /*
3030 =============
3031 PlayerPostThink
3032
3033 Called every frame for each client after the physics are run
3034 =============
3035 */
3036 .float idlekick_lasttimeleft;
3037 .entity showheadshotbbox;
3038 void showheadshotbbox_think()
3039 {
3040         if(self.owner.showheadshotbbox != self)
3041         {
3042                 remove(self);
3043                 return;
3044         }
3045         self.nextthink = time;
3046         setorigin(self, self.owner.origin);
3047         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3048 }
3049 void PlayerPostThink (void)
3050 {
3051         // Savage: Check for nameless players
3052         if (isInvisibleString(self.netname)) {
3053                 self.netname = "Player";
3054                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3055         }
3056
3057         if(sv_maxidle && frametime)
3058         {
3059                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3060                 float timeleft;
3061                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
3062                 {
3063                         if(self.idlekick_lasttimeleft)
3064                         {
3065                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
3066                                 self.idlekick_lasttimeleft = 0;
3067                         }
3068                         return;
3069                 }
3070                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3071                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3072                 {
3073                         if(!self.idlekick_lasttimeleft)
3074                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3075                 }
3076                 if(timeleft <= 0)
3077                 {
3078                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3079                         AnnounceTo(self, "terminated");
3080                         dropclient(self);
3081                         return;
3082                 }
3083                 else if(timeleft <= 10)
3084                 {
3085                         if(timeleft != self.idlekick_lasttimeleft)
3086                                 AnnounceTo(self, ftos(timeleft));
3087                         self.idlekick_lasttimeleft = timeleft;
3088                 }
3089         }
3090
3091 #ifdef TETRIS
3092         if(self.impulse == 100)
3093                 ImpulseCommands();
3094         if (TetrisPostFrame())
3095                 return;
3096 #endif
3097
3098         CheatFrame();
3099
3100         if(self.classname == "player") {
3101                 CheckRules_Player();
3102                 UpdateChatBubble();
3103                 if (self.impulse)
3104                         ImpulseCommands();
3105                 if (intermission_running)
3106                         return;         // intermission or finale
3107                 GetPressedKeys();
3108         } else if (self.classname == "observer") {
3109                 //do nothing
3110         } else if (self.classname == "spectator") {
3111                 //do nothing
3112         }
3113
3114         /*
3115         float i;
3116         for(i = 0; i < 1000; ++i)
3117         {
3118                 vector end;
3119                 end = self.origin + '0 0 1024' + 512 * randomvec();
3120                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3121                 if(trace_fraction < 1)
3122                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3123                 {
3124                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3125                         break;
3126                 }
3127         }
3128         */
3129
3130         Arena_Warmup();
3131
3132         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3133
3134         if(self.waypointsprite_attachedforcarrier)
3135                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3136
3137         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3138         {
3139                 if(!self.showheadshotbbox)
3140                 {
3141                         self.showheadshotbbox = spawn();
3142                         self.showheadshotbbox.classname = "headshotbbox";
3143                         self.showheadshotbbox.owner = self;
3144                         self.showheadshotbbox.think = showheadshotbbox_think;
3145                         self.showheadshotbbox.nextthink = time;
3146                         self = self.showheadshotbbox;
3147                         self.think();
3148                         self = self.owner;
3149                 }
3150         }
3151         else
3152         {
3153                 if(self.showheadshotbbox)
3154                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3155                 remove(self.showheadshotbbox);
3156         }
3157
3158         playerdemo_write();
3159
3160         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3161         {
3162                 if(!self.stored_netname)
3163                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3164                 if(self.stored_netname != self.netname)
3165                 {
3166                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3167                         strunzone(self.stored_netname);
3168                         self.stored_netname = strzone(self.netname);
3169                 }
3170         }
3171
3172         /*
3173         if(g_race)
3174                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3175         */
3176 }