qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 void CopyBody(float keepvelocity)
 128 {
 129         entity oldself;
 130         if (self.effects & EF_NODRAW)
 131                 return;
 132         oldself = self;
 133         self = spawn();
 134         self.enemy = oldself;
 135         self.lip = oldself.lip;
 136         self.colormap = oldself.colormap;
 137         self.glowmod = oldself.glowmod;
 138         self.iscreature = oldself.iscreature;
 139         self.damagedbycontents = oldself.damagedbycontents;
 140         self.angles = oldself.angles;
 141         self.avelocity = oldself.avelocity;
 142         self.classname = "body";
 143         self.damageforcescale = oldself.damageforcescale;
 144         self.effects = oldself.effects;
 145         self.event_damage = oldself.event_damage;
 146         self.animstate_startframe = oldself.animstate_startframe;
 147         self.animstate_numframes = oldself.animstate_numframes;
 148         self.animstate_framerate = oldself.animstate_framerate;
 149         self.animstate_starttime = oldself.animstate_starttime;
 150         self.animstate_endtime = oldself.animstate_endtime;
 151         self.animstate_override = oldself.animstate_override;
 152         self.animstate_looping = oldself.animstate_looping;
 153         self.frame = oldself.frame;
 154         self.dead_frame = oldself.dead_frame;
 155         self.pain_finished = oldself.pain_finished;
 156         self.health = oldself.health;
 157         self.armorvalue = oldself.armorvalue;
 158         self.armortype = oldself.armortype;
 159         self.model = oldself.model;
 160         self.modelindex = oldself.modelindex;
 161         self.modelindex_lod0 = oldself.modelindex_lod0;
 162         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 163         self.modelindex_lod1 = oldself.modelindex_lod1;
 164         self.modelindex_lod2 = oldself.modelindex_lod2;
 165         self.skinindex = oldself.skinindex;
 166         self.species = oldself.species;
 167         self.movetype = oldself.movetype;
 168         self.nextthink = oldself.nextthink;
 169         self.solid = oldself.solid;
 170         self.ballistics_density = oldself.ballistics_density;
 171         self.takedamage = oldself.takedamage;
 172         self.think = oldself.think;
 173         self.customizeentityforclient = oldself.customizeentityforclient;
 174         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 175         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 176         if (keepvelocity == 1)
 177                 self.velocity = oldself.velocity;
 178         self.oldvelocity = self.velocity;
 179         self.fade_time = oldself.fade_time;
 180         self.fade_rate = oldself.fade_rate;
 181         //self.weapon = oldself.weapon;
 182         setorigin(self, oldself.origin);
 183         setsize(self, oldself.mins, oldself.maxs);
 184         self.prevorigin = oldself.origin;
 185         self.reset = SUB_Remove;
 186
 187         Drag_MoveDrag(oldself, self);
 188
 189         self.owner = oldself;
 190         self = oldself;
 191 }
 192
 193 float player_getspecies()
 194 {
 195         float s;
 196         get_model_parameters(self.model, self.skinindex);
 197         s = get_model_parameters_species;
 198         get_model_parameters(string_null, 0);
 199         if(s < 0)
 200                 return SPECIES_HUMAN;
 201         return s;
 202 }
 203
 204 void player_setupanimsformodel()
 205 {
 206         // defaults for legacy .zym models without animinfo files
 207         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 208         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 209         self.anim_draw = animfixfps(self, '2 1 3');
 210         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 211         self.anim_duckwalk = animfixfps(self, '4 1 1');
 212         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 213         self.anim_duckidle = animfixfps(self, '6 1 1');
 214         self.anim_idle = animfixfps(self, '7 1 1');
 215         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 216         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 217         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 218         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 219         self.anim_taunt = animfixfps(self, '12 1 0.33');
 220         self.anim_run = animfixfps(self, '13 1 1');
 221         self.anim_runbackwards = animfixfps(self, '14 1 1');
 222         self.anim_strafeleft = animfixfps(self, '15 1 1');
 223         self.anim_straferight = animfixfps(self, '16 1 1');
 224         self.anim_dead1 = animfixfps(self, '17 1 1');
 225         self.anim_dead2 = animfixfps(self, '18 1 1');
 226         self.anim_forwardright = animfixfps(self, '19 1 1');
 227         self.anim_forwardleft = animfixfps(self, '20 1 1');
 228         self.anim_backright = animfixfps(self, '21 1 1');
 229         self.anim_backleft  = animfixfps(self, '22 1 1');
 230         self.anim_melee = animfixfps(self, '23 1 1');
 231         // TODO introspect models for finding right "fps" value (1/duration)
 232         // reset animstate now
 233         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 234 }
 235
 236 void player_anim (void)
 237 {
 238         updateanim(self);
 239         if (self.weaponentity)
 240                 updateanim(self.weaponentity);
 241
 242         if (self.deadflag != DEAD_NO)
 243         {
 244                 if (time > self.animstate_endtime)
 245                 {
 246                         if (self.maxs_z > 5)
 247                         {
 248                                 self.maxs_z = 5;
 249                                 setsize(self, self.mins, self.maxs);
 250                         }
 251                         self.frame = self.dead_frame;
 252                 }
 253                 return;
 254         }
 255
 256         if (!self.animstate_override)
 257         {
 258                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 259                 {
 260                         if (self.crouch)
 261                         {
 262                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 263                                 {
 264                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 265                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 266                                         {
 267                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 268                                                 self.restart_jump = FALSE;
 269                                         }
 270                                 }
 271                         }
 272                         else
 273                         {
 274                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 275                 {
 276                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 277                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 278                     {
 279                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 280                         self.restart_jump = FALSE;
 281                     }
 282                 }
 283                         }
 284                 }
 285                 else if (self.crouch)
 286                 {
 287                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 288                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 289                         else
 290                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 291                 }
 292                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 293                 {
 294                         if (self.movement_x > 0 && self.movement_y == 0)
 295                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 296                         else if (self.movement_x < 0 && self.movement_y == 0)
 297                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 298                         else if (self.movement_x == 0 && self.movement_y > 0)
 299                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 300                         else if (self.movement_x == 0 && self.movement_y < 0)
 301                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 302                         else if (self.movement_x > 0 && self.movement_y > 0)
 303                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 304                         else if (self.movement_x > 0 && self.movement_y < 0)
 305                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 306                         else if (self.movement_x < 0 && self.movement_y > 0)
 307                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 308                         else if (self.movement_x < 0 && self.movement_y < 0)
 309                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 310                         else
 311                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 312                 }
 313                 else
 314                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 315         }
 316
 317         if (self.weaponentity)
 318         if (!self.weaponentity.animstate_override)
 319                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 320 }
 321
 322 void SpawnThrownWeapon (vector org, float w)
 323 {
 324         if(g_minstagib)
 325         if(self.ammo_cells <= 0)
 326                 return;
 327
 328         if(g_pinata)
 329         {
 330                 float j;
 331                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 332                 {
 333                         if(self.weapons & W_WeaponBit(j))
 334                                 if(W_IsWeaponThrowable(j))
 335                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 336                 }
 337         }
 338         else
 339         {
 340                 if(W_IsWeaponThrowable(self.weapon))
 341                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 342         }
 343 }
 344
 345 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 346 {
 347         float take, save;
 348         vector v;
 349         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 350
 351         // damage resistance (ignore most of the damage from a bullet or similar)
 352         damage = max(damage - 5, 1);
 353
 354         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 355         take = v_x;
 356         save = v_y;
 357
 358         if(sound_allowed(MSG_BROADCAST, attacker))
 359         {
 360                 if (save > 10)
 361                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 362                 else if (take > 30)
 363                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 364                 else if (take > 10)
 365                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 366         }
 367
 368         if (take > 50)
 369                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 370         if (take > 100)
 371                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 372
 373         if (!(self.flags & FL_GODMODE))
 374         {
 375                 self.armorvalue = self.armorvalue - save;
 376                 self.health = self.health - take;
 377                 // pause regeneration for 5 seconds
 378                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 379         }
 380         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 381         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 382         self.dmg_inflictor = inflictor;
 383
 384         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 385         {
 386                 // don't use any animations as a gib
 387                 self.frame = 0;
 388                 self.dead_frame = 0;
 389                 // view just above the floor
 390                 self.view_ofs = '0 0 4';
 391
 392                 Violence_GibSplash(self, 1, 1, attacker);
 393                 self.modelindex = 0; // restore later
 394                 self.solid = SOLID_NOT; // restore later
 395                 self.takedamage = DAMAGE_NO; // restore later
 396         }
 397 }
 398
 399 void ClientKill_Now_TeamChange();
 400 void freezetag_CheckWinner();
 401
 402 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 403 {
 404         float take, save, waves, sdelay, dh, da, j;
 405         vector v;
 406         float valid_damage_for_weaponstats;
 407         float excess;
 408
 409         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 410                 return;
 411
 412         dh = max(self.health, 0);
 413         da = max(self.armorvalue, 0);
 414
 415         if(!DEATH_ISSPECIAL(deathtype))
 416         {
 417                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 418                 if(self != attacker)
 419                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 420         }
 421
 422         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 423         {
 424                 // tuba causes blood to come out of the ears
 425                 vector ear1, ear2;
 426                 vector d;
 427                 float f;
 428                 ear1 = self.origin;
 429                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 430                 ear2 = ear1;
 431                 makevectors(self.angles);
 432                 ear1 += v_right * -10;
 433                 ear2 += v_right * +10;
 434                 d = inflictor.origin - self.origin;
 435                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 436                 force = v_right * vlen(force);
 437                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 438                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 439                 if(f > 0)
 440                 {
 441                         hitloc = ear1;
 442                         force = force * -1;
 443                 }
 444                 else
 445                 {
 446                         hitloc = ear2;
 447                         // force is already good
 448                 }
 449         }
 450         else
 451                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 452
 453         if (!g_minstagib)
 454         {
 455                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 456                 take = v_x;
 457                 save = v_y;
 458         }
 459         else
 460         {
 461                 save = 0;
 462                 take = damage;
 463         }
 464
 465         frag_inflictor = inflictor;
 466         frag_attacker = attacker;
 467         frag_target = self;
 468         damage_take = take;
 469         damage_save = save;
 470         damage_force = force;
 471         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 472         take = bound(0, damage_take, self.health);
 473         save = bound(0, damage_save, self.armorvalue);
 474         excess = max(0, damage - take - save);
 475
 476         if(sound_allowed(MSG_BROADCAST, attacker))
 477         {
 478                 if (save > 10)
 479                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 480                 else if (take > 30)
 481                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 482                 else if (take > 10)
 483                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 484         }
 485
 486         if (take > 50)
 487                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 488         if (take > 100)
 489                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 490
 491         if (time >= self.spawnshieldtime)
 492         {
 493                 if (!(self.flags & FL_GODMODE))
 494                 {
 495                         self.armorvalue = self.armorvalue - save;
 496                         self.health = self.health - take;
 497                         // pause regeneration for 5 seconds
 498                         if(take)
 499                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 500
 501                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 502                         {
 503                                 self.pain_finished = time + 0.5;        //Supajoe
 504
 505                                 if(sv_gentle < 1) {
 506                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 507                                         {
 508                                                 if (!self.animstate_override)
 509                                                 {
 510                                                         if (random() > 0.5)
 511                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 512                                                         else
 513                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 514                                                 }
 515                                         }
 516
 517                                         if(sound_allowed(MSG_BROADCAST, attacker))
 518                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 519                                         if(self.health > 1)
 520                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 521                                         {
 522                                                 if(deathtype == DEATH_FALL)
 523                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 524                                                 else if(self.health > 75) // TODO make a "gentle" version?
 525                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 526                                                 else if(self.health > 50)
 527                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 528                                                 else if(self.health > 25)
 529                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 530                                                 else
 531                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 532                                         }
 533                                 }
 534
 535                                 // throw off bot aim temporarily
 536                                 float shake;
 537                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 538                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 539                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 540                         }
 541                 }
 542                 else
 543                         self.max_armorvalue += (save + take);
 544         }
 545         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 546         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 547         self.dmg_inflictor = inflictor;
 548
 549         if(attacker == self)
 550         {
 551                 // don't reset pushltime for self damage as it may be an attempt to
 552                 // escape a lava pit or similar
 553                 //self.pushltime = 0;
 554         }
 555         else if(attacker.classname == "player")
 556         {
 557                 self.pusher = attacker;
 558                 self.pushltime = time + autocvar_g_maxpushtime;
 559         }
 560         else if(time < self.pushltime)
 561         {
 562                 attacker = self.pusher;
 563                 self.pushltime = max(self.pushltime, time + 0.6);
 564         }
 565         else
 566                 self.pushltime = 0;
 567
 568         float abot, vbot, awep;
 569         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 570         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 571
 572         valid_damage_for_weaponstats = 0;
 573         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 574         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 575         if(attacker && self != attacker)
 576         if(IsDifferentTeam(self, attacker))
 577         {
 578                 if(DEATH_ISSPECIAL(deathtype))
 579                         awep = attacker.weapon;
 580                 else
 581                         awep = DEATH_WEAPONOF(deathtype);
 582                 valid_damage_for_weaponstats = 1;
 583         }
 584
 585         if(valid_damage_for_weaponstats)
 586         {
 587                 dh = dh - max(self.health, 0);
 588                 da = da - max(self.armorvalue, 0);
 589                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 590         }
 591
 592         if (self.health < 1)
 593         {
 594                 float defer_ClientKill_Now_TeamChange;
 595                 defer_ClientKill_Now_TeamChange = FALSE;
 596
 597                 if(self.alivetime)
 598                 {
 599                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 600                         self.alivetime = 0;
 601                 }
 602
 603                 if(valid_damage_for_weaponstats)
 604                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 605
 606                 if(sv_gentle < 1) // TODO make a "gentle" version?
 607                 if(sound_allowed(MSG_BROADCAST, attacker))
 608                 {
 609                         if(deathtype == DEATH_DROWN)
 610                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 611                         else
 612                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 613                 }
 614
 615                 // get rid of kill indicator
 616                 if(self.killindicator)
 617                 {
 618                         remove(self.killindicator);
 619                         self.killindicator = world;
 620                         if(self.killindicator_teamchange)
 621                                 defer_ClientKill_Now_TeamChange = TRUE;
 622
 623                         if(self.classname == "body")
 624                         if(deathtype == DEATH_KILL)
 625                         {
 626                                 // for the lemmings fans, a small harmless explosion
 627                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 628                         }
 629                 }
 630
 631                 if(!g_freezetag)
 632                 {
 633                         // become fully visible
 634                         self.alpha = 1;
 635                         // throw a weapon
 636                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 637                 }
 638
 639                 // print an obituary message
 640                 Obituary (attacker, inflictor, self, deathtype);
 641                 race_PreDie();
 642                 DropAllRunes(self);
 643
 644         // increment frag counter for used weapon type
 645         float w;
 646         w = DEATH_WEAPONOF(deathtype);
 647         if(WEP_VALID(w))
 648         if(self.classname == "player")
 649         if(self != attacker)
 650         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 651
 652                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 653                 {
 654                         PutClientInServer();
 655                         count_alive_players(); // re-count players
 656                         freezetag_CheckWinner();
 657                         return;
 658                 }
 659
 660                 frag_attacker = attacker;
 661                 frag_inflictor = inflictor;
 662                 frag_target = self;
 663                 MUTATOR_CALLHOOK(PlayerDies);
 664                 weapon_action(self.weapon, WR_PLAYERDEATH);
 665
 666                 RemoveGrapplingHook(self);
 667
 668                 if(self.flagcarried)
 669                 {
 670                         if(attacker.classname != "player")
 671                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 672                         else if(attacker.team == self.team)
 673                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 674                         else
 675                                 DropFlag(self.flagcarried, world, attacker);
 676                 }
 677                 if(self.ballcarried && g_nexball)
 678                         DropBall(self.ballcarried, self.origin, self.velocity);
 679                 Portal_ClearAllLater(self);
 680
 681                 if(clienttype(self) == CLIENTTYPE_REAL)
 682                 {
 683                         stuffcmd(self, "-zoom\n");
 684                         self.fixangle = TRUE;
 685                         //msg_entity = self;
 686                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 687                         //WriteAngle (MSG_ONE, self.v_angle_x);
 688                         //WriteAngle (MSG_ONE, self.v_angle_y);
 689                         //WriteAngle (MSG_ONE, 80);
 690                 }
 691
 692                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 693                         ClientKill_Now_TeamChange();
 694
 695                 if(g_arena)
 696                         Spawnqueue_Unmark(self);
 697
 698                 if(g_freezetag)
 699                         return;
 700
 701                 // when we get here, player actually dies
 702                 // clear waypoints (do this AFTER FreezeTag)
 703                 WaypointSprite_PlayerDead();
 704
 705                 // make the corpse upright (not tilted)
 706                 self.angles_x = 0;
 707                 self.angles_z = 0;
 708                 // don't spin
 709                 self.avelocity = '0 0 0';
 710                 // view from the floor
 711                 self.view_ofs = '0 0 -8';
 712                 // toss the corpse
 713                 self.movetype = MOVETYPE_TOSS;
 714                 // shootable corpse
 715                 self.solid = SOLID_CORPSE;
 716                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 717                 // don't stick to the floor
 718                 self.flags &~= FL_ONGROUND;
 719                 // dying animation
 720                 self.deadflag = DEAD_DYING;
 721                 // when to allow respawn
 722                 sdelay = 0;
 723                 waves = 0;
 724                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 725                 if(!sdelay)
 726                 {
 727                         if(g_cts)
 728                                 sdelay = 0; // no respawn delay in CTS
 729                         else
 730                                 sdelay = autocvar_g_respawn_delay;
 731                 }
 732                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 733                 if(!waves)
 734                         waves = autocvar_g_respawn_waves;
 735                 if(waves)
 736                         self.death_time = ceil((time + sdelay) / waves) * waves;
 737                 else
 738                         self.death_time = time + sdelay;
 739                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 740                         self.respawn_countdown = 10; // first number to count down from is 10
 741                 else
 742                         self.respawn_countdown = -1; // do not count down
 743                 if (random() < 0.5)
 744                 {
 745                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 746                         self.dead_frame = self.anim_dead1_x;
 747                 }
 748                 else
 749                 {
 750                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 751                         self.dead_frame = self.anim_dead2_x;
 752                 }
 753                 // set damage function to corpse damage
 754                 self.event_damage = PlayerCorpseDamage;
 755                 // call the corpse damage function just in case it wants to gib
 756                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 757                 // set up to fade out later
 758                 SUB_SetFade (self, time + 6 + random (), 1);
 759
 760                 if(sv_gentle > 0 || autocvar_ekg) {
 761                         // remove corpse
 762                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 763                 }
 764
 765                 // reset fields the weapons may use just in case
 766                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 767                 {
 768                         weapon_action(j, WR_RESETPLAYER);
 769                         ATTACK_FINISHED_FOR(self, j) = 0;
 770                 }
 771         }
 772 }
 773
 774 .float muted; // to be used by prvm_edictset server playernumber muted 1
 775 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 776 // message "": do not say, just test flood control
 777 // return value:
 778 //   1 = accept
 779 //   0 = reject
 780 //  -1 = fake accept
 781 {
 782         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 783         float flood, privatemsgprefixlen;
 784         var .float flood_field;
 785         entity head;
 786         float ret;
 787
 788         if(Ban_MaybeEnforceBan(source))
 789                 return 0;
 790
 791         if(!teamsay && !privatesay)
 792                 if(substring(msgin, 0, 1) == " ")
 793                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 794
 795         msgin = formatmessage(msgin);
 796
 797         if(source.classname != "player")
 798                 colorstr = "^0"; // black for spectators
 799         else if(teamplay)
 800                 colorstr = Team_ColorCode(source.team);
 801         else
 802                 teamsay = FALSE;
 803
 804         if(intermission_running)
 805                 teamsay = FALSE;
 806
 807         if(msgin != "")
 808                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 809
 810         /*
 811          * using bprint solves this... me stupid
 812         // how can we prevent the message from appearing in a listen server?
 813         // for now, just give "say" back and only handle say_team
 814         if(!teamsay)
 815         {
 816                 clientcommand(self, strcat("say ", msgin));
 817                 return;
 818         }
 819         */
 820
 821         if(autocvar_g_chat_teamcolors)
 822                 namestr = playername(source);
 823         else
 824                 namestr = source.netname;
 825
 826         if(msgin != "")
 827         {
 828                 if(privatesay)
 829                 {
 830                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 831                         privatemsgprefixlen = strlen(msgstr);
 832                         msgstr = strcat(msgstr, msgin);
 833                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 834                         if(autocvar_g_chat_teamcolors)
 835                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 836                         else
 837                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 838                 }
 839                 else if(teamsay)
 840                 {
 841                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 842                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 843                 }
 844                 else
 845                 {
 846                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 847                         cmsgstr = "";
 848                 }
 849                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 850         }
 851         else
 852         {
 853                 msgstr = cmsgstr = "";
 854         }
 855
 856         fullmsgstr = msgstr;
 857         fullcmsgstr = cmsgstr;
 858
 859         // FLOOD CONTROL
 860         flood = 0;
 861         if(floodcontrol)
 862         {
 863                 float flood_spl;
 864                 float flood_burst;
 865                 float flood_lmax;
 866                 float lines;
 867                 if(privatesay)
 868                 {
 869                         flood_spl = autocvar_g_chat_flood_spl_tell;
 870                         flood_burst = autocvar_g_chat_flood_burst_tell;
 871                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 872                         flood_field = floodcontrol_chattell;
 873                 }
 874                 else if(teamsay)
 875                 {
 876                         flood_spl = autocvar_g_chat_flood_spl_team;
 877                         flood_burst = autocvar_g_chat_flood_burst_team;
 878                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 879                         flood_field = floodcontrol_chatteam;
 880                 }
 881                 else
 882                 {
 883                         flood_spl = autocvar_g_chat_flood_spl;
 884                         flood_burst = autocvar_g_chat_flood_burst;
 885                         flood_lmax = autocvar_g_chat_flood_lmax;
 886                         flood_field = floodcontrol_chat;
 887                 }
 888                 flood_burst = max(0, flood_burst - 1);
 889                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 890
 891                 // do flood control for the default line size
 892                 if(msgstr != "")
 893                 {
 894                         getWrappedLine_remaining = msgstr;
 895                         msgstr = "";
 896                         lines = 0;
 897                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 898                         {
 899                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 900                                 ++lines;
 901                         }
 902                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 903
 904                         if(getWrappedLine_remaining != "")
 905                         {
 906                                 msgstr = strcat(msgstr, "\n");
 907                                 flood = 2;
 908                         }
 909
 910                         if(time >= source.flood_field)
 911                         {
 912                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 913                         }
 914                         else
 915                         {
 916                                 flood = 1;
 917                                 msgstr = fullmsgstr;
 918                         }
 919                 }
 920                 else
 921                 {
 922                         if(time >= source.flood_field)
 923                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 924                         else
 925                                 flood = 1;
 926                 }
 927
 928                 if (timeoutStatus == 2) //when game is paused, no flood protection
 929                         source.flood_field = flood = 0;
 930         }
 931
 932         if(flood == 2) // cannot happen for empty msgstr
 933         {
 934                 if(autocvar_g_chat_flood_notify_flooder)
 935                 {
 936                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 937                         sourcecmsgstr = "";
 938                 }
 939                 else
 940                 {
 941                         sourcemsgstr = fullmsgstr;
 942                         sourcecmsgstr = fullcmsgstr;
 943                 }
 944                 cmsgstr = "";
 945         }
 946         else
 947         {
 948                 sourcemsgstr = msgstr;
 949                 sourcecmsgstr = cmsgstr;
 950         }
 951
 952         if(!privatesay)
 953         if(source.classname != "player")
 954         {
 955                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 956                         teamsay = -1; // spectators
 957         }
 958
 959         if(flood)
 960                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 961
 962         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 963         if(privatesay)
 964                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 965
 966         if(source.muted)
 967         {
 968                 // always fake the message
 969                 ret = -1;
 970         }
 971         else if(flood == 1)
 972         {
 973                 if(autocvar_g_chat_flood_notify_flooder)
 974                 {
 975                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 976                         ret = 0;
 977                 }
 978                 else
 979                         ret = -1;
 980         }
 981         else
 982         {
 983                 ret = 1;
 984         }
 985
 986         if(sourcemsgstr != "" && ret != 0)
 987         {
 988                 if(ret < 0) // fake
 989                 {
 990                         sprint(source, sourcemsgstr);
 991                         if(sourcecmsgstr != "" && !privatesay)
 992                                 centerprint(source, sourcecmsgstr);
 993                 }
 994                 else if(privatesay)
 995                 {
 996                         sprint(source, sourcemsgstr);
 997                         sprint(privatesay, msgstr);
 998                         if(cmsgstr != "")
 999                                 centerprint(privatesay, cmsgstr);
1000                 }
1001                 else if(teamsay > 0)
1002                 {
1003                         sprint(source, sourcemsgstr);
1004                         if(sourcecmsgstr != "")
1005                                 centerprint(source, sourcecmsgstr);
1006                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1007                                 if(head != source)
1008                                 {
1009                                         sprint(head, msgstr);
1010                                         if(cmsgstr != "")
1011                                                 centerprint(head, cmsgstr);
1012                                 }
1013                 }
1014                 else if(teamsay < 0)
1015                 {
1016                         sprint(source, sourcemsgstr);
1017                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1018                                 if(head != source)
1019                                         sprint(head, msgstr);
1020                 }
1021                 else if(sourcemsgstr != msgstr)
1022                 {
1023                         sprint(source, sourcemsgstr);
1024                         FOR_EACH_REALCLIENT(head)
1025                                 if(head != source)
1026                                         sprint(head, msgstr);
1027                 }
1028                 else
1029                         bprint(msgstr);
1030         }
1031
1032         return ret;
1033 }
1034
1035 float GetVoiceMessageVoiceType(string type)
1036 {
1037         if(type == "taunt")
1038                 return VOICETYPE_TAUNT;
1039         if(type == "teamshoot")
1040                 return VOICETYPE_LASTATTACKER;
1041         return VOICETYPE_TEAMRADIO;
1042 }
1043
1044 string allvoicesamples;
1045 .string GetVoiceMessageSampleField(string type)
1046 {
1047         GetPlayerSoundSampleField_notFound = 0;
1048         switch(type)
1049         {
1050 #define _VOICEMSG(m) case #m: return playersound_##m;
1051                 ALLVOICEMSGS
1052 #undef _VOICEMSG
1053         }
1054         GetPlayerSoundSampleField_notFound = 1;
1055         return playersound_taunt;
1056 }
1057
1058 .string GetPlayerSoundSampleField(string type)
1059 {
1060         GetPlayerSoundSampleField_notFound = 0;
1061         switch(type)
1062         {
1063 #define _VOICEMSG(m) case #m: return playersound_##m;
1064                 ALLPLAYERSOUNDS
1065 #undef _VOICEMSG
1066         }
1067         GetPlayerSoundSampleField_notFound = 1;
1068         return playersound_taunt;
1069 }
1070
1071 void PrecacheGlobalSound(string samplestring)
1072 {
1073         float n, i;
1074         tokenize_console(samplestring);
1075         n = stof(argv(1));
1076         if(n > 0)
1077         {
1078                 for(i = 1; i <= n; ++i)
1079                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1080         }
1081         else
1082         {
1083                 precache_sound(strcat(argv(0), ".wav"));
1084         }
1085 }
1086
1087 void PrecachePlayerSounds(string f)
1088 {
1089         float fh;
1090         string s;
1091         fh = fopen(f, FILE_READ);
1092         if(fh < 0)
1093                 return;
1094         while((s = fgets(fh)))
1095         {
1096                 if(tokenize_console(s) != 3)
1097                 {
1098                         dprint("Invalid sound info line: ", s, "\n");
1099                         continue;
1100                 }
1101                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1102         }
1103         fclose(fh);
1104
1105         if not(allvoicesamples)
1106         {
1107 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1108                 ALLVOICEMSGS
1109 #undef _VOICEMSG
1110                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1111         }
1112 }
1113
1114 void ClearPlayerSounds()
1115 {
1116 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1117         ALLPLAYERSOUNDS
1118         ALLVOICEMSGS
1119 #undef _VOICEMSG
1120 }
1121
1122 float LoadPlayerSounds(string f, float first)
1123 {
1124         float fh;
1125         string s;
1126         var .string field;
1127         fh = fopen(f, FILE_READ);
1128         if(fh < 0)
1129         {
1130                 dprint("Player sound file not found: ", f, "\n");
1131                 return 0;
1132         }
1133         while((s = fgets(fh)))
1134         {
1135                 if(tokenize_console(s) != 3)
1136                         continue;
1137                 field = GetPlayerSoundSampleField(argv(0));
1138                 if(GetPlayerSoundSampleField_notFound)
1139                         field = GetVoiceMessageSampleField(argv(0));
1140                 if(GetPlayerSoundSampleField_notFound)
1141                         continue;
1142                 if(self.field)
1143                         strunzone(self.field);
1144                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1145         }
1146         fclose(fh);
1147         return 1;
1148 }
1149
1150 .float modelindex_for_playersound;
1151 .float skinindex_for_playersound;
1152 void UpdatePlayerSounds()
1153 {
1154         if(self.modelindex == self.modelindex_for_playersound)
1155         if(self.skinindex == self.skinindex_for_playersound)
1156                 return;
1157         self.modelindex_for_playersound = self.modelindex;
1158         self.skinindex_for_playersound = self.skinindex;
1159         ClearPlayerSounds();
1160         LoadPlayerSounds("sound/player/default.sounds", 1);
1161         if(!autocvar_g_debug_defaultsounds)
1162                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1163                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1164 }
1165
1166 void FakeGlobalSound(string sample, float chan, float voicetype)
1167 {
1168         float n;
1169         float tauntrand;
1170
1171         if(sample == "")
1172                 return;
1173
1174         tokenize_console(sample);
1175         n = stof(argv(1));
1176         if(n > 0)
1177                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1178         else
1179                 sample = strcat(argv(0), ".wav"); // randomization
1180
1181         switch(voicetype)
1182         {
1183                 case VOICETYPE_LASTATTACKER_ONLY:
1184                         break;
1185                 case VOICETYPE_LASTATTACKER:
1186                         if(self.pusher)
1187                         {
1188                                 msg_entity = self;
1189                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1190                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1191                         }
1192                         break;
1193                 case VOICETYPE_TEAMRADIO:
1194                         msg_entity = self;
1195                         if(msg_entity.cvar_cl_voice_directional == 1)
1196                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1197                         else
1198                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1199                         break;
1200                 case VOICETYPE_AUTOTAUNT:
1201                         if(!sv_autotaunt)
1202                                 break;
1203                         if(!sv_taunt)
1204                                 break;
1205                         if(sv_gentle)
1206                                 break;
1207                         tauntrand = random();
1208                         msg_entity = self;
1209                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1210                         {
1211                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1212                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1213                                 else
1214                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1215                         }
1216                         break;
1217                 case VOICETYPE_TAUNT:
1218                         if(self.classname == "player")
1219                                 if(self.deadflag == DEAD_NO)
1220                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1221                         if(!sv_taunt)
1222                                 break;
1223                         if(sv_gentle)
1224                                 break;
1225                         msg_entity = self;
1226                         if (msg_entity.cvar_cl_voice_directional >= 1)
1227                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1228                         else
1229                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1230                         break;
1231                 case VOICETYPE_PLAYERSOUND:
1232                         msg_entity = self;
1233                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1234                         break;
1235                 default:
1236                         backtrace("Invalid voice type!");
1237                         break;
1238         }
1239 }
1240
1241 void GlobalSound(string sample, float chan, float voicetype)
1242 {
1243         float n;
1244         float tauntrand;
1245
1246         if(sample == "")
1247                 return;
1248
1249         tokenize_console(sample);
1250         n = stof(argv(1));
1251         if(n > 0)
1252                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1253         else
1254                 sample = strcat(argv(0), ".wav"); // randomization
1255
1256         switch(voicetype)
1257         {
1258                 case VOICETYPE_LASTATTACKER_ONLY:
1259                         if(self.pusher)
1260                         {
1261                                 msg_entity = self.pusher;
1262                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1263                                 {
1264                                         if(msg_entity.cvar_cl_voice_directional == 1)
1265                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1266                                         else
1267                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1268                                 }
1269                         }
1270                         break;
1271                 case VOICETYPE_LASTATTACKER:
1272                         if(self.pusher)
1273                         {
1274                                 msg_entity = self.pusher;
1275                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1276                                 {
1277                                         if(msg_entity.cvar_cl_voice_directional == 1)
1278                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1279                                         else
1280                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1281                                 }
1282                                 msg_entity = self;
1283                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1284                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1285                         }
1286                         break;
1287                 case VOICETYPE_TEAMRADIO:
1288                         FOR_EACH_REALCLIENT(msg_entity)
1289                                 if(!teamplay || msg_entity.team == self.team)
1290                                 {
1291                                         if(msg_entity.cvar_cl_voice_directional == 1)
1292                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1293                                         else
1294                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1295                                 }
1296                         break;
1297                 case VOICETYPE_AUTOTAUNT:
1298                         if(!sv_autotaunt)
1299                                 break;
1300                         if(!sv_taunt)
1301                                 break;
1302                         if(sv_gentle)
1303                                 break;
1304                         tauntrand = random();
1305                         FOR_EACH_REALCLIENT(msg_entity)
1306                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1307                                 {
1308                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1309                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1310                                         else
1311                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1312                                 }
1313                         break;
1314                 case VOICETYPE_TAUNT:
1315                         if(self.classname == "player")
1316                                 if(self.deadflag == DEAD_NO)
1317                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1318                         if(!sv_taunt)
1319                                 break;
1320                         if(sv_gentle)
1321                                 break;
1322                         FOR_EACH_REALCLIENT(msg_entity)
1323                         {
1324                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1325                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1326                                 else
1327                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1328                         }
1329                         break;
1330                 case VOICETYPE_PLAYERSOUND:
1331                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1332                         break;
1333                 default:
1334                         backtrace("Invalid voice type!");
1335                         break;
1336         }
1337 }
1338
1339 void PlayerSound(.string samplefield, float chan, float voicetype)
1340 {
1341         GlobalSound(self.samplefield, chan, voicetype);
1342 }
1343
1344 void VoiceMessage(string type, string msg)
1345 {
1346         var .string sample;
1347         float voicetype, ownteam;
1348         float flood;
1349         sample = GetVoiceMessageSampleField(type);
1350
1351         if(GetPlayerSoundSampleField_notFound)
1352         {
1353                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1354                 return;
1355         }
1356
1357         voicetype = GetVoiceMessageVoiceType(type);
1358         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1359
1360         flood = Say(self, ownteam, world, msg, 1);
1361
1362         if (flood > 0)
1363                 GlobalSound(self.sample, CH_VOICE, voicetype);
1364         else if (flood < 0)
1365                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1366 }
1367
1368 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1369 {
1370 //      show_message
1371 //      0 (00) automove centerprint, admin message
1372 //      1 (01) automove centerprint, no admin message
1373 //      2 (10) no centerprint, admin message
1374 //      3 (11) no centerprint, no admin message
1375
1376         float lockteams_backup;
1377
1378         lockteams_backup = lockteams;  // backup any team lock
1379
1380         lockteams = 0;  // disable locked teams
1381
1382         TeamchangeFrags(client);  // move the players frags
1383         SetPlayerColors(client, team_colour - 1);  // set the players colour
1384         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1385
1386         lockteams = lockteams_backup;  // restore the team lock
1387
1388         LogTeamchange(client.playerid, client.team, type);
1389
1390         if not(show_message & 1) // admin message
1391                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1392
1393         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1394 }