qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(accuracy_frags);
   4
   5 float weaponstats_buffer;
   6
   7 void WeaponStats_Init()
   8 {
   9         if(autocvar_sv_weaponstats_file != "")
  10                 weaponstats_buffer = buf_create();
  11         else
  12                 weaponstats_buffer = -1;
  13 }
  14
  15 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  16
  17 void WeaponStats_Shutdown()
  18 {
  19         float i, j, ibot, jbot, idx;
  20         float fh;
  21         vector v;
  22         string prefix;
  23         if(weaponstats_buffer < 0)
  24                 return;
  25         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26         if(autocvar_sv_weaponstats_file != "")
  27         {
  28                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
  29                 if(fh >= 0)
  30                 {
  31                         fputs(fh, "#begin statsfile\n");
  32                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  33                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  34                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  35                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  36                                 {
  37                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  38                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  39                                         if(v != '0 0 0')
  40                                         {
  41                                                 //vector is: kills hits damage
  42                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  43                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  44                                         }
  45                                 }
  46                         fputs(fh, "#end\n\n");
  47                         fclose(fh);
  48                         print("Weapon stats written\n");
  49                 }
  50         }
  51         buf_del(weaponstats_buffer);
  52         weaponstats_buffer = -1;
  53 }
  54
  55 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  56 {
  57         float idx;
  58         if(weaponstats_buffer < 0)
  59                 return;
  60         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  61                 return;
  62         if(awep > WEP_LAST || vwep > WEP_LAST)
  63                 return;
  64         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  65         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  66 }
  67 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  68 {
  69         if(damage < 0)
  70                 error("negative damage?");
  71         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  72 }
  73 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  74 {
  75         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  76 }
  77
  78 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  79 // merged player_run and player_stand to player_anim
  80 // added death animations to player_anim
  81 // can now spawn thrown weapons from anywhere, not just from players
  82 // thrown weapons now fade out after 20 seconds
  83 // created PlayerGib function
  84 // PlayerDie no longer uses hitloc or damage
  85 // PlayerDie now supports dying animations as well as gibbing
  86 // cleaned up PlayerDie a lot
  87 // added CopyBody
  88
  89 .entity pusher;
  90 .float pushltime;
  91
  92 void CopyBody(float keepvelocity)
  93 {
  94         local entity oldself;
  95         if (self.effects & EF_NODRAW)
  96                 return;
  97         oldself = self;
  98         self = spawn();
  99         self.enemy = oldself;
 100         self.lip = oldself.lip;
 101         self.colormap = oldself.colormap;
 102         self.glowmod = oldself.glowmod;
 103         self.iscreature = oldself.iscreature;
 104         self.angles = oldself.angles;
 105         self.avelocity = oldself.avelocity;
 106         self.classname = "body";
 107         self.damageforcescale = oldself.damageforcescale;
 108         self.effects = oldself.effects;
 109         self.event_damage = oldself.event_damage;
 110         self.animstate_startframe = oldself.animstate_startframe;
 111         self.animstate_numframes = oldself.animstate_numframes;
 112         self.animstate_framerate = oldself.animstate_framerate;
 113         self.animstate_starttime = oldself.animstate_starttime;
 114         self.animstate_endtime = oldself.animstate_endtime;
 115         self.animstate_override = oldself.animstate_override;
 116         self.animstate_looping = oldself.animstate_looping;
 117         self.frame = oldself.frame;
 118         self.dead_frame = oldself.dead_frame;
 119         self.pain_finished = oldself.pain_finished;
 120         self.health = oldself.health;
 121         self.armorvalue = oldself.armorvalue;
 122         self.armortype = oldself.armortype;
 123         self.model = oldself.model;
 124         self.modelindex = oldself.modelindex;
 125         self.modelindex_lod0 = oldself.modelindex_lod0;
 126         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 127         self.modelindex_lod1 = oldself.modelindex_lod1;
 128         self.modelindex_lod2 = oldself.modelindex_lod2;
 129         self.skinindex = oldself.skinindex;
 130         self.species = oldself.species;
 131         self.movetype = oldself.movetype;
 132         self.nextthink = oldself.nextthink;
 133         self.solid = oldself.solid;
 134         self.ballistics_density = oldself.ballistics_density;
 135         self.takedamage = oldself.takedamage;
 136         self.think = oldself.think;
 137         self.customizeentityforclient = oldself.customizeentityforclient;
 138         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 139         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 140         if (keepvelocity == 1)
 141                 self.velocity = oldself.velocity;
 142         self.oldvelocity = self.velocity;
 143         self.fade_time = oldself.fade_time;
 144         self.fade_rate = oldself.fade_rate;
 145         //self.weapon = oldself.weapon;
 146         setorigin(self, oldself.origin);
 147         setsize(self, oldself.mins, oldself.maxs);
 148         self.prevorigin = oldself.origin;
 149         self.reset = SUB_Remove;
 150
 151         Drag_MoveDrag(oldself, self);
 152
 153         self = oldself;
 154 }
 155
 156 float player_getspecies()
 157 {
 158         float s;
 159         get_model_parameters(self.model, self.skinindex);
 160         s = get_model_parameters_species;
 161         get_model_parameters(string_null, 0);
 162         if(s < 0)
 163                 return SPECIES_HUMAN;
 164         return s;
 165 }
 166
 167 void player_setupanimsformodel()
 168 {
 169         local string animfilename;
 170         local float animfile;
 171         // defaults for legacy .zym models without animinfo files
 172         self.anim_die1 = '0 1 0.5'; // 2 seconds
 173         self.anim_die2 = '1 1 0.5'; // 2 seconds
 174         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 175         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 176         self.anim_duckwalk = '4 1 1';
 177         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 178         self.anim_duckidle = '6 1 1';
 179         self.anim_idle = '7 1 1';
 180         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 181         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 182         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 183         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 184         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 185         self.anim_run = '13 1 1';
 186         self.anim_runbackwards = '14 1 1';
 187         self.anim_strafeleft = '15 1 1';
 188         self.anim_straferight = '16 1 1';
 189         self.anim_dead1 = '17 1 1';
 190         self.anim_dead2 = '18 1 1';
 191         self.anim_forwardright = '19 1 1';
 192         self.anim_forwardleft = '20 1 1';
 193         self.anim_backright = '21 1 1';
 194         self.anim_backleft  = '22 1 1';
 195         self.anim_melee = '23 1 1';
 196         self.anim_fly = '24 1 1';
 197         animparseerror = FALSE;
 198         animfilename = strcat(self.model, ".animinfo");
 199         animfile = fopen(animfilename, FILE_READ);
 200         if (animfile >= 0)
 201         {
 202                 self.anim_die1         = animparseline(animfile);
 203                 self.anim_die2         = animparseline(animfile);
 204                 self.anim_draw         = animparseline(animfile);
 205                 self.anim_duck         = animparseline(animfile);
 206                 self.anim_duckwalk     = animparseline(animfile);
 207                 self.anim_duckjump     = animparseline(animfile);
 208                 self.anim_duckidle     = animparseline(animfile);
 209                 self.anim_idle         = animparseline(animfile);
 210                 self.anim_jump         = animparseline(animfile);
 211                 self.anim_pain1        = animparseline(animfile);
 212                 self.anim_pain2        = animparseline(animfile);
 213                 self.anim_shoot        = animparseline(animfile);
 214                 self.anim_taunt        = animparseline(animfile);
 215                 self.anim_run          = animparseline(animfile);
 216                 self.anim_runbackwards = animparseline(animfile);
 217                 self.anim_strafeleft   = animparseline(animfile);
 218                 self.anim_straferight  = animparseline(animfile);
 219                 self.anim_forwardright = animparseline(animfile);
 220                 self.anim_forwardleft  = animparseline(animfile);
 221                 self.anim_backright    = animparseline(animfile);
 222                 self.anim_backleft     = animparseline(animfile);
 223                 self.anim_melee        = animparseline(animfile);
 224                 self.anim_fly          = animparseline(animfile);
 225                 fclose(animfile);
 226
 227                 // derived anims
 228                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 229                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 230
 231                 if (animparseerror)
 232                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 233         }
 234         else
 235                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 236         // reset animstate now
 237         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 238 };
 239
 240 void player_anim (void)
 241 {
 242         updateanim(self);
 243         if (self.weaponentity)
 244                 updateanim(self.weaponentity);
 245
 246         if (self.deadflag != DEAD_NO)
 247         {
 248                 if (time > self.animstate_endtime)
 249                 {
 250                         if (self.maxs_z > 5)
 251                         {
 252                                 self.maxs_z = 5;
 253                                 setsize(self, self.mins, self.maxs);
 254                         }
 255                         self.frame = self.dead_frame;
 256                 }
 257                 return;
 258         }
 259
 260         if (!self.animstate_override)
 261         {
 262                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 263                 {
 264                         if (self.crouch)
 265                         {
 266                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 267                                 {
 268                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 269                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 270                                         {
 271                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 272                                                 self.restart_jump = FALSE;
 273                                         }
 274                                 }
 275                         }
 276                         else
 277                         {
 278                                 // 21/25 is the magic number here for how long the jump animation takes to play once (numframes/framerate)
 279                                 if((self.animstate_startframe == self.anim_jump_x && time - self.animstate_starttime >= 21/25))
 280                                         setanim(self, self.anim_fly, TRUE, FALSE, FALSE);
 281
 282                                 if(self.animstate_startframe != self.anim_fly_x) // no tracing if we're in the fly anim
 283                                 {
 284                                         if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 285                                         {
 286                                                 traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 287                                                 if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 288                                                 {
 289                                                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 290                                                         self.restart_jump = FALSE;
 291                                                 }
 292                                         }
 293                                 }
 294                         }
 295                 }
 296                 else if (self.crouch)
 297                 {
 298                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 299                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 300                         else
 301                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 302                 }
 303                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 304                 {
 305                         if (self.movement_x > 0 && self.movement_y == 0)
 306                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x < 0 && self.movement_y == 0)
 308                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x == 0 && self.movement_y > 0)
 310                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x == 0 && self.movement_y < 0)
 312                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x > 0 && self.movement_y > 0)
 314                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x > 0 && self.movement_y < 0)
 316                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x < 0 && self.movement_y > 0)
 318                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x < 0 && self.movement_y < 0)
 320                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 321                         else
 322                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 323                 }
 324                 else
 325                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 326         }
 327
 328         if (self.weaponentity)
 329         if (!self.weaponentity.animstate_override)
 330                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 331 }
 332
 333 void SpawnThrownWeapon (vector org, float w)
 334 {
 335         if(g_minstagib)
 336         if(self.ammo_cells <= 0)
 337                 return;
 338
 339         if(g_pinata)
 340         {
 341                 float j;
 342                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 343                 {
 344                         if(self.weapons & W_WeaponBit(j))
 345                                 if(W_IsWeaponThrowable(j))
 346                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 347                 }
 348         }
 349         else
 350         {
 351                 if(W_IsWeaponThrowable(self.weapon))
 352                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 353         }
 354 }
 355
 356 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 357 {
 358         local float take, save;
 359         vector v;
 360         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 361
 362         // damage resistance (ignore most of the damage from a bullet or similar)
 363         damage = max(damage - 5, 1);
 364
 365         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 366         take = v_x;
 367         save = v_y;
 368
 369         if(sound_allowed(MSG_BROADCAST, attacker))
 370         {
 371                 if (save > 10)
 372                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 373                 else if (take > 30)
 374                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 375                 else if (take > 10)
 376                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 377         }
 378
 379         if (take > 50)
 380                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 381         if (take > 100)
 382                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 383
 384         if (!(self.flags & FL_GODMODE))
 385         {
 386                 self.armorvalue = self.armorvalue - save;
 387                 self.health = self.health - take;
 388                 // pause regeneration for 5 seconds
 389                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 390         }
 391         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 392         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 393         self.dmg_inflictor = inflictor;
 394
 395         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 396         {
 397                 // don't use any animations as a gib
 398                 self.frame = 0;
 399                 self.dead_frame = 0;
 400                 // view just above the floor
 401                 self.view_ofs = '0 0 4';
 402
 403                 Violence_GibSplash(self, 1, 1, attacker);
 404                 self.modelindex = 0; // restore later
 405                 self.solid = SOLID_NOT; // restore later
 406         }
 407 }
 408
 409 void ClientKill_Now_TeamChange();
 410 void freezetag_CheckWinner();
 411
 412 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 413 {
 414         local float take, save, waves, sdelay, dh, da, j;
 415         vector v;
 416         float valid_damage_for_weaponstats;
 417         float excess;
 418
 419         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 420                 return;
 421
 422         dh = max(self.health, 0);
 423         da = max(self.armorvalue, 0);
 424
 425         if(!DEATH_ISSPECIAL(deathtype))
 426         {
 427                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 428                 if(self != attacker)
 429                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 430         }
 431
 432         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 433         {
 434                 // tuba causes blood to come out of the ears
 435                 vector ear1, ear2;
 436                 vector d;
 437                 float f;
 438                 ear1 = self.origin;
 439                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 440                 ear2 = ear1;
 441                 makevectors(self.angles);
 442                 ear1 += v_right * -10;
 443                 ear2 += v_right * +10;
 444                 d = inflictor.origin - self.origin;
 445                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 446                 force = v_right * vlen(force);
 447                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 448                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 449                 if(f > 0)
 450                 {
 451                         hitloc = ear1;
 452                         force = force * -1;
 453                 }
 454                 else
 455                 {
 456                         hitloc = ear2;
 457                         // force is already good
 458                 }
 459         }
 460         else
 461                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 462
 463         if (!g_minstagib)
 464         {
 465                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 466                 take = v_x;
 467                 save = v_y;
 468         }
 469         else
 470         {
 471                 save = 0;
 472                 take = damage;
 473         }
 474
 475         frag_inflictor = inflictor;
 476         frag_attacker = attacker;
 477         frag_target = self;
 478         damage_take = take;
 479         damage_save = save;
 480         damage_force = force;
 481         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 482         take = bound(0, damage_take, self.health);
 483         save = bound(0, damage_save, self.armorvalue);
 484         excess = max(0, damage - take - save);
 485
 486         if(sound_allowed(MSG_BROADCAST, attacker))
 487         {
 488                 if (save > 10)
 489                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 490                 else if (take > 30)
 491                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 492                 else if (take > 10)
 493                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 494         }
 495
 496         if (take > 50)
 497                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 498         if (take > 100)
 499                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 500
 501         if (time >= self.spawnshieldtime)
 502         {
 503                 if (!(self.flags & FL_GODMODE))
 504                 {
 505                         self.armorvalue = self.armorvalue - save;
 506                         self.health = self.health - take;
 507                         // pause regeneration for 5 seconds
 508                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 509
 510                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 511                         {
 512                                 self.pain_finished = time + 0.5;        //Supajoe
 513
 514                                 if(sv_gentle < 1) {
 515                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 516                                         {
 517                                                 if (!self.animstate_override)
 518                                                 {
 519                                                         if (random() > 0.5)
 520                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 521                                                         else
 522                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 523                                                 }
 524                                         }
 525
 526                                         if(sound_allowed(MSG_BROADCAST, attacker))
 527                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 528                                         if(self.health > 1)
 529                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 530                                         {
 531                                                 if(deathtype == DEATH_FALL)
 532                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 533                                                 else if(self.health > 75) // TODO make a "gentle" version?
 534                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 535                                                 else if(self.health > 50)
 536                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 537                                                 else if(self.health > 25)
 538                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 539                                                 else
 540                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 541                                         }
 542                                 }
 543
 544                                 // throw off bot aim temporarily
 545                                 local float shake;
 546                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 547                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 548                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 549                         }
 550                 }
 551                 else
 552                         self.max_armorvalue += (save + take);
 553         }
 554         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 555         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 556         self.dmg_inflictor = inflictor;
 557
 558         if(attacker == self)
 559         {
 560                 // don't reset pushltime for self damage as it may be an attempt to
 561                 // escape a lava pit or similar
 562                 //self.pushltime = 0;
 563         }
 564         else if(attacker.classname == "player" || attacker.classname == "gib")
 565         {
 566                 self.pusher = attacker;
 567                 self.pushltime = time + autocvar_g_maxpushtime;
 568         }
 569         else if(time < self.pushltime)
 570         {
 571                 attacker = self.pusher;
 572                 self.pushltime = max(self.pushltime, time + 0.6);
 573         }
 574         else
 575                 self.pushltime = 0;
 576
 577         float abot, vbot, awep;
 578         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 579         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 580
 581         valid_damage_for_weaponstats = 0;
 582         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 583         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 584         if(attacker && self != attacker)
 585         if(IsDifferentTeam(self, attacker))
 586         {
 587                 if(DEATH_ISSPECIAL(deathtype))
 588                         awep = attacker.weapon;
 589                 else
 590                         awep = DEATH_WEAPONOF(deathtype);
 591                 valid_damage_for_weaponstats = 1;
 592         }
 593
 594         if(valid_damage_for_weaponstats)
 595         {
 596                 dh = dh - max(self.health, 0);
 597                 da = da - max(self.armorvalue, 0);
 598                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 599         }
 600
 601         if (self.health < 1)
 602         {
 603                 float defer_ClientKill_Now_TeamChange;
 604                 defer_ClientKill_Now_TeamChange = FALSE;
 605
 606                 if(self.alivetime)
 607                 {
 608                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 609                         self.alivetime = 0;
 610                 }
 611
 612                 if(valid_damage_for_weaponstats)
 613                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 614
 615                 if(sv_gentle < 1) // TODO make a "gentle" version?
 616                 if(sound_allowed(MSG_BROADCAST, attacker))
 617                 {
 618                         if(deathtype == DEATH_DROWN)
 619                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 620                         else
 621                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 622                 }
 623
 624                 // get rid of kill indicator
 625                 if(self.killindicator)
 626                 {
 627                         remove(self.killindicator);
 628                         self.killindicator = world;
 629                         if(self.killindicator_teamchange)
 630                                 defer_ClientKill_Now_TeamChange = TRUE;
 631
 632                         if(self.classname == "body")
 633                         if(deathtype == DEATH_KILL)
 634                         {
 635                                 // for the lemmings fans, a small harmless explosion
 636                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 637                         }
 638                 }
 639
 640                 if(!g_freezetag)
 641                 {
 642                         // become fully visible
 643                         self.alpha = 1;
 644                         // throw a weapon
 645                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 646                 }
 647
 648                 // print an obituary message
 649                 Obituary (attacker, inflictor, self, deathtype);
 650                 race_PreDie();
 651                 DropAllRunes(self);
 652
 653         // increment frag counter for used weapon type
 654         float w;
 655         w = DEATH_WEAPONOF(deathtype);
 656         if(WEP_VALID(w))
 657         if(self.classname == "player")
 658         if(self != attacker)
 659         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 660
 661                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 662                 {
 663                         PutClientInServer();
 664                         count_alive_players(); // re-count players
 665                         freezetag_CheckWinner();
 666                         return;
 667                 }
 668
 669                 frag_attacker = attacker;
 670                 frag_inflictor = inflictor;
 671                 frag_target = self;
 672                 MUTATOR_CALLHOOK(PlayerDies);
 673                 weapon_action(self.weapon, WR_PLAYERDEATH);
 674
 675                 if(self.flagcarried)
 676                 {
 677                         if(attacker.classname != "player" && attacker.classname != "gib")
 678                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 679                         else if(attacker.team == self.team)
 680                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 681                         else
 682                                 DropFlag(self.flagcarried, world, attacker);
 683                 }
 684                 if(self.ballcarried && g_nexball)
 685                         DropBall(self.ballcarried, self.origin, self.velocity);
 686                 Portal_ClearAllLater(self);
 687
 688                 if(clienttype(self) == CLIENTTYPE_REAL)
 689                 {
 690                         stuffcmd(self, "-zoom\n");
 691                         self.fixangle = TRUE;
 692                         //msg_entity = self;
 693                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 694                         //WriteAngle (MSG_ONE, self.v_angle_x);
 695                         //WriteAngle (MSG_ONE, self.v_angle_y);
 696                         //WriteAngle (MSG_ONE, 80);
 697                 }
 698
 699                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 700                         ClientKill_Now_TeamChange();
 701
 702                 if(g_arena)
 703                         Spawnqueue_Unmark(self);
 704
 705                 if(g_freezetag)
 706                         return;
 707
 708                 // when we get here, player actually dies
 709                 // clear waypoints (do this AFTER FreezeTag)
 710                 WaypointSprite_PlayerDead();
 711
 712                 // make the corpse upright (not tilted)
 713                 self.angles_x = 0;
 714                 self.angles_z = 0;
 715                 // don't spin
 716                 self.avelocity = '0 0 0';
 717                 // view from the floor
 718                 self.view_ofs = '0 0 -8';
 719                 // toss the corpse
 720                 self.movetype = MOVETYPE_TOSS;
 721                 // shootable corpse
 722                 self.solid = SOLID_CORPSE;
 723                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 724                 // don't stick to the floor
 725                 self.flags &~= FL_ONGROUND;
 726                 // dying animation
 727                 self.deadflag = DEAD_DYING;
 728                 // when to allow respawn
 729                 sdelay = 0;
 730                 waves = 0;
 731                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 732                 if(!sdelay)
 733                 {
 734                         if(g_cts)
 735                                 sdelay = 0; // no respawn delay in CTS
 736                         else
 737                                 sdelay = autocvar_g_respawn_delay;
 738                 }
 739                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 740                 if(!waves)
 741                         waves = autocvar_g_respawn_waves;
 742                 if(waves)
 743                         self.death_time = ceil((time + sdelay) / waves) * waves;
 744                 else
 745                         self.death_time = time + sdelay;
 746                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 747                         self.respawn_countdown = 10; // first number to count down from is 10
 748                 else
 749                         self.respawn_countdown = -1; // do not count down
 750                 if (random() < 0.5)
 751                 {
 752                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 753                         self.dead_frame = self.anim_dead1_x;
 754                 }
 755                 else
 756                 {
 757                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 758                         self.dead_frame = self.anim_dead2_x;
 759                 }
 760                 // set damage function to corpse damage
 761                 self.event_damage = PlayerCorpseDamage;
 762                 // call the corpse damage function just in case it wants to gib
 763                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 764                 // set up to fade out later
 765                 SUB_SetFade (self, time + 6 + random (), 1);
 766
 767                 if(sv_gentle > 0 || autocvar_ekg) {
 768                         // remove corpse
 769                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 770                 }
 771
 772                 // reset fields the weapons may use just in case
 773                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 774                 {
 775                         weapon_action(j, WR_RESETPLAYER);
 776                         ATTACK_FINISHED_FOR(self, j) = 0;
 777                 }
 778         }
 779 }
 780
 781 .float muted; // to be used by prvm_edictset server playernumber muted 1
 782 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 783 // message "": do not say, just test flood control
 784 // return value:
 785 //   1 = accept
 786 //   0 = reject
 787 //  -1 = fake accept
 788 {
 789         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 790         float flood, privatemsgprefixlen;
 791         var .float flood_field;
 792         entity head;
 793         float ret;
 794
 795         if(Ban_MaybeEnforceBan(source))
 796                 return 0;
 797
 798         if(!teamsay && !privatesay)
 799                 if(substring(msgin, 0, 1) == " ")
 800                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 801
 802         msgin = formatmessage(msgin);
 803
 804         if(source.classname != "player")
 805                 colorstr = "^0"; // black for spectators
 806         else if(teams_matter)
 807                 colorstr = Team_ColorCode(source.team);
 808         else
 809                 teamsay = FALSE;
 810
 811         if(intermission_running)
 812                 teamsay = FALSE;
 813
 814         if(msgin != "")
 815                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 816
 817         /*
 818          * using bprint solves this... me stupid
 819         // how can we prevent the message from appearing in a listen server?
 820         // for now, just give "say" back and only handle say_team
 821         if(!teamsay)
 822         {
 823                 clientcommand(self, strcat("say ", msgin));
 824                 return;
 825         }
 826         */
 827
 828         if(autocvar_g_chat_teamcolors)
 829                 namestr = playername(source);
 830         else
 831                 namestr = source.netname;
 832
 833         if(msgin != "")
 834         {
 835                 if(privatesay)
 836                 {
 837                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 838                         privatemsgprefixlen = strlen(msgstr);
 839                         msgstr = strcat(msgstr, msgin);
 840                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 841                         if(autocvar_g_chat_teamcolors)
 842                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 843                         else
 844                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 845                 }
 846                 else if(teamsay)
 847                 {
 848                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 849                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 850                 }
 851                 else
 852                 {
 853                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 854                         cmsgstr = "";
 855                 }
 856                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 857         }
 858         else
 859         {
 860                 msgstr = cmsgstr = "";
 861         }
 862
 863         fullmsgstr = msgstr;
 864         fullcmsgstr = cmsgstr;
 865
 866         // FLOOD CONTROL
 867         flood = 0;
 868         if(floodcontrol)
 869         {
 870                 float flood_spl;
 871                 float flood_burst;
 872                 float flood_lmax;
 873                 float lines;
 874                 if(privatesay)
 875                 {
 876                         flood_spl = autocvar_g_chat_flood_spl_tell;
 877                         flood_burst = autocvar_g_chat_flood_burst_tell;
 878                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 879                         flood_field = floodcontrol_chattell;
 880                 }
 881                 else if(teamsay)
 882                 {
 883                         flood_spl = autocvar_g_chat_flood_spl_team;
 884                         flood_burst = autocvar_g_chat_flood_burst_team;
 885                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 886                         flood_field = floodcontrol_chatteam;
 887                 }
 888                 else
 889                 {
 890                         flood_spl = autocvar_g_chat_flood_spl;
 891                         flood_burst = autocvar_g_chat_flood_burst;
 892                         flood_lmax = autocvar_g_chat_flood_lmax;
 893                         flood_field = floodcontrol_chat;
 894                 }
 895                 flood_burst = max(0, flood_burst - 1);
 896                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 897
 898                 // do flood control for the default line size
 899                 if(msgstr != "")
 900                 {
 901                         getWrappedLine_remaining = msgstr;
 902                         msgstr = "";
 903                         lines = 0;
 904                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 905                         {
 906                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 907                                 ++lines;
 908                         }
 909                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 910
 911                         if(getWrappedLine_remaining != "")
 912                         {
 913                                 msgstr = strcat(msgstr, "\n");
 914                                 flood = 2;
 915                         }
 916
 917                         if(time >= source.flood_field)
 918                         {
 919                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 920                         }
 921                         else
 922                         {
 923                                 flood = 1;
 924                                 msgstr = fullmsgstr;
 925                         }
 926                 }
 927                 else
 928                 {
 929                         if(time >= source.flood_field)
 930                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 931                         else
 932                                 flood = 1;
 933                 }
 934
 935                 if (timeoutStatus == 2) //when game is paused, no flood protection
 936                         source.flood_field = flood = 0;
 937         }
 938
 939         if(flood == 2) // cannot happen for empty msgstr
 940         {
 941                 if(autocvar_g_chat_flood_notify_flooder)
 942                 {
 943                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 944                         sourcecmsgstr = "";
 945                 }
 946                 else
 947                 {
 948                         sourcemsgstr = fullmsgstr;
 949                         sourcecmsgstr = fullcmsgstr;
 950                 }
 951                 cmsgstr = "";
 952         }
 953         else
 954         {
 955                 sourcemsgstr = msgstr;
 956                 sourcecmsgstr = cmsgstr;
 957         }
 958
 959         if(!privatesay)
 960         if(source.classname != "player")
 961         {
 962                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 963                         teamsay = -1; // spectators
 964         }
 965
 966         if(flood)
 967                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 968
 969         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 970         if(privatesay)
 971                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 972
 973         if(source.muted)
 974         {
 975                 // always fake the message
 976                 ret = -1;
 977         }
 978         else if(flood == 1)
 979         {
 980                 if(autocvar_g_chat_flood_notify_flooder)
 981                 {
 982                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 983                         ret = 0;
 984                 }
 985                 else
 986                         ret = -1;
 987         }
 988         else
 989         {
 990                 ret = 1;
 991         }
 992
 993         if(sourcemsgstr != "" && ret != 0)
 994         {
 995                 if(ret < 0) // fake
 996                 {
 997                         sprint(source, sourcemsgstr);
 998                         if(sourcecmsgstr != "" && !privatesay)
 999                                 centerprint(source, sourcecmsgstr);
1000                 }
1001                 else if(privatesay)
1002                 {
1003                         sprint(source, sourcemsgstr);
1004                         sprint(privatesay, msgstr);
1005                         if(cmsgstr != "")
1006                                 centerprint(privatesay, cmsgstr);
1007                 }
1008                 else if(teamsay > 0)
1009                 {
1010                         sprint(source, sourcemsgstr);
1011                         if(sourcecmsgstr != "")
1012                                 centerprint(source, sourcecmsgstr);
1013                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1014                                 if(head != source)
1015                                 {
1016                                         sprint(head, msgstr);
1017                                         if(cmsgstr != "")
1018                                                 centerprint(head, cmsgstr);
1019                                 }
1020                 }
1021                 else if(teamsay < 0)
1022                 {
1023                         sprint(source, sourcemsgstr);
1024                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1025                                 if(head != source)
1026                                         sprint(head, msgstr);
1027                 }
1028                 else if(sourcemsgstr != msgstr)
1029                 {
1030                         sprint(source, sourcemsgstr);
1031                         FOR_EACH_REALCLIENT(head)
1032                                 if(head != source)
1033                                         sprint(head, msgstr);
1034                 }
1035                 else
1036                         bprint(msgstr);
1037         }
1038
1039         return ret;
1040 }
1041
1042 float GetVoiceMessageVoiceType(string type)
1043 {
1044         if(type == "taunt")
1045                 return VOICETYPE_TAUNT;
1046         if(type == "teamshoot")
1047                 return VOICETYPE_LASTATTACKER;
1048         return VOICETYPE_TEAMRADIO;
1049 }
1050
1051 string allvoicesamples;
1052 .string GetVoiceMessageSampleField(string type)
1053 {
1054         GetPlayerSoundSampleField_notFound = 0;
1055         switch(type)
1056         {
1057 #define _VOICEMSG(m) case #m: return playersound_##m;
1058                 ALLVOICEMSGS
1059 #undef _VOICEMSG
1060         }
1061         GetPlayerSoundSampleField_notFound = 1;
1062         return playersound_taunt;
1063 }
1064
1065 .string GetPlayerSoundSampleField(string type)
1066 {
1067         GetPlayerSoundSampleField_notFound = 0;
1068         switch(type)
1069         {
1070 #define _VOICEMSG(m) case #m: return playersound_##m;
1071                 ALLPLAYERSOUNDS
1072 #undef _VOICEMSG
1073         }
1074         GetPlayerSoundSampleField_notFound = 1;
1075         return playersound_taunt;
1076 }
1077
1078 void PrecacheGlobalSound(string samplestring)
1079 {
1080         float n, i;
1081         tokenize_console(samplestring);
1082         n = stof(argv(1));
1083         if(n > 0)
1084         {
1085                 for(i = 1; i <= n; ++i)
1086                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1087         }
1088         else
1089         {
1090                 precache_sound(strcat(argv(0), ".wav"));
1091         }
1092 }
1093
1094 void PrecachePlayerSounds(string f)
1095 {
1096         float fh;
1097         string s;
1098         fh = fopen(f, FILE_READ);
1099         if(fh < 0)
1100                 return;
1101         while((s = fgets(fh)))
1102         {
1103                 if(tokenize_console(s) != 3)
1104                 {
1105                         dprint("Invalid sound info line: ", s, "\n");
1106                         continue;
1107                 }
1108                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1109         }
1110         fclose(fh);
1111
1112         if not(allvoicesamples)
1113         {
1114 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1115                 ALLVOICEMSGS
1116 #undef _VOICEMSG
1117                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1118         }
1119 }
1120
1121 void ClearPlayerSounds()
1122 {
1123 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1124         ALLPLAYERSOUNDS
1125         ALLVOICEMSGS
1126 #undef _VOICEMSG
1127 }
1128
1129 float LoadPlayerSounds(string f, float first)
1130 {
1131         float fh;
1132         string s;
1133         var .string field;
1134         fh = fopen(f, FILE_READ);
1135         if(fh < 0)
1136         {
1137                 dprint("Player sound file not found: ", f, "\n");
1138                 return 0;
1139         }
1140         while((s = fgets(fh)))
1141         {
1142                 if(tokenize_console(s) != 3)
1143                         continue;
1144                 field = GetPlayerSoundSampleField(argv(0));
1145                 if(GetPlayerSoundSampleField_notFound)
1146                         field = GetVoiceMessageSampleField(argv(0));
1147                 if(GetPlayerSoundSampleField_notFound)
1148                         continue;
1149                 if(self.field)
1150                         strunzone(self.field);
1151                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1152         }
1153         fclose(fh);
1154         return 1;
1155 }
1156
1157 .float modelindex_for_playersound;
1158 .float skinindex_for_playersound;
1159 void UpdatePlayerSounds()
1160 {
1161         if(self.modelindex == self.modelindex_for_playersound)
1162         if(self.skinindex == self.skinindex_for_playersound)
1163                 return;
1164         self.modelindex_for_playersound = self.modelindex;
1165         self.skinindex_for_playersound = self.skinindex;
1166         ClearPlayerSounds();
1167         LoadPlayerSounds("sound/player/default.sounds", 1);
1168         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1169                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1170 }
1171
1172 void FakeGlobalSound(string sample, float chan, float voicetype)
1173 {
1174         float n;
1175         float tauntrand;
1176
1177         if(sample == "")
1178                 return;
1179
1180         tokenize_console(sample);
1181         n = stof(argv(1));
1182         if(n > 0)
1183                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1184         else
1185                 sample = strcat(argv(0), ".wav"); // randomization
1186
1187         switch(voicetype)
1188         {
1189                 case VOICETYPE_LASTATTACKER_ONLY:
1190                         break;
1191                 case VOICETYPE_LASTATTACKER:
1192                         if(self.pusher)
1193                         {
1194                                 msg_entity = self;
1195                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1196                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1197                         }
1198                         break;
1199                 case VOICETYPE_TEAMRADIO:
1200                         msg_entity = self;
1201                         if(msg_entity.cvar_cl_voice_directional == 1)
1202                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1203                         else
1204                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1205                         break;
1206                 case VOICETYPE_AUTOTAUNT:
1207                         if(!sv_autotaunt)
1208                                 break;
1209                         if(!sv_taunt)
1210                                 break;
1211                         if(sv_gentle)
1212                                 break;
1213                         tauntrand = random();
1214                         msg_entity = self;
1215                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1216                         {
1217                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1218                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1219                                 else
1220                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1221                         }
1222                         break;
1223                 case VOICETYPE_TAUNT:
1224                         if(self.classname == "player")
1225                                 if(self.deadflag == DEAD_NO)
1226                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1227                         if(!sv_taunt)
1228                                 break;
1229                         if(sv_gentle)
1230                                 break;
1231                         msg_entity = self;
1232                         if (msg_entity.cvar_cl_voice_directional >= 1)
1233                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1234                         else
1235                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1236                         break;
1237                 case VOICETYPE_PLAYERSOUND:
1238                         msg_entity = self;
1239                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1240                         break;
1241                 default:
1242                         backtrace("Invalid voice type!");
1243                         break;
1244         }
1245 }
1246
1247 void GlobalSound(string sample, float chan, float voicetype)
1248 {
1249         float n;
1250         float tauntrand;
1251
1252         if(sample == "")
1253                 return;
1254
1255         tokenize_console(sample);
1256         n = stof(argv(1));
1257         if(n > 0)
1258                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1259         else
1260                 sample = strcat(argv(0), ".wav"); // randomization
1261
1262         switch(voicetype)
1263         {
1264                 case VOICETYPE_LASTATTACKER_ONLY:
1265                         if(self.pusher)
1266                         {
1267                                 msg_entity = self.pusher;
1268                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1269                                 {
1270                                         if(msg_entity.cvar_cl_voice_directional == 1)
1271                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1272                                         else
1273                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1274                                 }
1275                         }
1276                         break;
1277                 case VOICETYPE_LASTATTACKER:
1278                         if(self.pusher)
1279                         {
1280                                 msg_entity = self.pusher;
1281                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1282                                 {
1283                                         if(msg_entity.cvar_cl_voice_directional == 1)
1284                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1285                                         else
1286                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1287                                 }
1288                                 msg_entity = self;
1289                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1290                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1291                         }
1292                         break;
1293                 case VOICETYPE_TEAMRADIO:
1294                         FOR_EACH_REALCLIENT(msg_entity)
1295                                 if(!teams_matter || msg_entity.team == self.team)
1296                                 {
1297                                         if(msg_entity.cvar_cl_voice_directional == 1)
1298                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1299                                         else
1300                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1301                                 }
1302                         break;
1303                 case VOICETYPE_AUTOTAUNT:
1304                         if(!sv_autotaunt)
1305                                 break;
1306                         if(!sv_taunt)
1307                                 break;
1308                         if(sv_gentle)
1309                                 break;
1310                         tauntrand = random();
1311                         FOR_EACH_REALCLIENT(msg_entity)
1312                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1313                                 {
1314                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1315                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1316                                         else
1317                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1318                                 }
1319                         break;
1320                 case VOICETYPE_TAUNT:
1321                         if(self.classname == "player")
1322                                 if(self.deadflag == DEAD_NO)
1323                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1324                         if(!sv_taunt)
1325                                 break;
1326                         if(sv_gentle)
1327                                 break;
1328                         FOR_EACH_REALCLIENT(msg_entity)
1329                         {
1330                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1331                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1332                                 else
1333                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1334                         }
1335                         break;
1336                 case VOICETYPE_PLAYERSOUND:
1337                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1338                         break;
1339                 default:
1340                         backtrace("Invalid voice type!");
1341                         break;
1342         }
1343 }
1344
1345 void PlayerSound(.string samplefield, float chan, float voicetype)
1346 {
1347         GlobalSound(self.samplefield, chan, voicetype);
1348 }
1349
1350 void VoiceMessage(string type, string msg)
1351 {
1352         var .string sample;
1353         float voicetype, ownteam;
1354         float flood;
1355         sample = GetVoiceMessageSampleField(type);
1356
1357         if(GetPlayerSoundSampleField_notFound)
1358         {
1359                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1360                 return;
1361         }
1362
1363         voicetype = GetVoiceMessageVoiceType(type);
1364         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1365
1366         flood = Say(self, ownteam, world, msg, 1);
1367
1368         if (flood > 0)
1369                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1370         else if (flood < 0)
1371                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1372 }
1373
1374 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1375 {
1376 //      show_message
1377 //      0 (00) automove centerprint, admin message
1378 //      1 (01) automove centerprint, no admin message
1379 //      2 (10) no centerprint, admin message
1380 //      3 (11) no centerprint, no admin message
1381
1382         float lockteams_backup;
1383
1384         lockteams_backup = lockteams;  // backup any team lock
1385
1386         lockteams = 0;  // disable locked teams
1387
1388         TeamchangeFrags(client);  // move the players frags
1389         SetPlayerColors(client, team_colour - 1);  // set the players colour
1390         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1391
1392         lockteams = lockteams_backup;  // restore the team lock
1393
1394         LogTeamchange(client.playerid, client.team, type);
1395
1396         if not(show_message & 1) // admin message
1397                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1398
1399         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1400 }