qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_Shutdown()
  17 {
  18         float i, j, ibot, jbot, idx;
  19         float fh;
  20         vector v;
  21         string prefix;
  22         if(weaponstats_buffer < 0)
  23                 return;
  24         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  25         if(autocvar_sv_weaponstats_file != "")
  26         {
  27                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
  28                 if(fh >= 0)
  29                 {
  30                         fputs(fh, "#begin statsfile\n");
  31                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  32                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  33                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  34                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  35                                 {
  36                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  37                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  38                                         if(v != '0 0 0')
  39                                         {
  40                                                 //vector is: kills hits damage
  41                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  42                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  43                                         }
  44                                 }
  45                         fputs(fh, "#end\n\n");
  46                         fclose(fh);
  47                         print("Weapon stats written\n");
  48                 }
  49         }
  50         buf_del(weaponstats_buffer);
  51         weaponstats_buffer = -1;
  52 }
  53
  54 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  55 {
  56         float idx;
  57         if(weaponstats_buffer < 0)
  58                 return;
  59         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  60                 return;
  61         if(awep > WEP_LAST || vwep > WEP_LAST)
  62                 return;
  63         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  64         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  65 }
  66 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  67 {
  68         if(damage < 0)
  69                 error("negative damage?");
  70         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  71 }
  72 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  73 {
  74         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  75 }
  76
  77 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  78 // merged player_run and player_stand to player_anim
  79 // added death animations to player_anim
  80 // can now spawn thrown weapons from anywhere, not just from players
  81 // thrown weapons now fade out after 20 seconds
  82 // created PlayerGib function
  83 // PlayerDie no longer uses hitloc or damage
  84 // PlayerDie now supports dying animations as well as gibbing
  85 // cleaned up PlayerDie a lot
  86 // added CopyBody
  87
  88 .entity pusher;
  89 .float pushltime;
  90
  91 void CopyBody(float keepvelocity)
  92 {
  93         local entity oldself;
  94         if (self.effects & EF_NODRAW)
  95                 return;
  96         oldself = self;
  97         self = spawn();
  98         self.enemy = oldself;
  99         self.lip = oldself.lip;
 100         self.colormap = oldself.colormap;
 101         self.glowmod = oldself.glowmod;
 102         self.iscreature = oldself.iscreature;
 103         self.angles = oldself.angles;
 104         self.avelocity = oldself.avelocity;
 105         self.classname = "body";
 106         self.damageforcescale = oldself.damageforcescale;
 107         self.effects = oldself.effects;
 108         self.event_damage = oldself.event_damage;
 109         self.animstate_startframe = oldself.animstate_startframe;
 110         self.animstate_numframes = oldself.animstate_numframes;
 111         self.animstate_framerate = oldself.animstate_framerate;
 112         self.animstate_starttime = oldself.animstate_starttime;
 113         self.animstate_endtime = oldself.animstate_endtime;
 114         self.animstate_override = oldself.animstate_override;
 115         self.animstate_looping = oldself.animstate_looping;
 116         self.frame = oldself.frame;
 117         self.dead_frame = oldself.dead_frame;
 118         self.pain_finished = oldself.pain_finished;
 119         self.health = oldself.health;
 120         self.armorvalue = oldself.armorvalue;
 121         self.armortype = oldself.armortype;
 122         self.model = oldself.model;
 123         self.modelindex = oldself.modelindex;
 124         self.modelindex_lod0 = oldself.modelindex_lod0;
 125         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 126         self.modelindex_lod1 = oldself.modelindex_lod1;
 127         self.modelindex_lod2 = oldself.modelindex_lod2;
 128         self.skinindex = oldself.skinindex;
 129         self.species = oldself.species;
 130         self.movetype = oldself.movetype;
 131         self.nextthink = oldself.nextthink;
 132         self.solid = oldself.solid;
 133         self.ballistics_density = oldself.ballistics_density;
 134         self.takedamage = oldself.takedamage;
 135         self.think = oldself.think;
 136         self.customizeentityforclient = oldself.customizeentityforclient;
 137         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 138         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 139         if (keepvelocity == 1)
 140                 self.velocity = oldself.velocity;
 141         self.oldvelocity = self.velocity;
 142         self.fade_time = oldself.fade_time;
 143         self.fade_rate = oldself.fade_rate;
 144         //self.weapon = oldself.weapon;
 145         setorigin(self, oldself.origin);
 146         setsize(self, oldself.mins, oldself.maxs);
 147         self.prevorigin = oldself.origin;
 148         self.reset = SUB_Remove;
 149
 150         Drag_MoveDrag(oldself, self);
 151
 152         self = oldself;
 153 }
 154
 155 float player_getspecies()
 156 {
 157         float s;
 158         get_model_parameters(self.model, self.skinindex);
 159         s = get_model_parameters_species;
 160         get_model_parameters(string_null, 0);
 161         if(s < 0)
 162                 return SPECIES_HUMAN;
 163         return s;
 164 }
 165
 166 void player_setupanimsformodel()
 167 {
 168         local string animfilename;
 169         local float animfile;
 170         // defaults for legacy .zym models without animinfo files
 171         self.anim_die1 = '0 1 0.5'; // 2 seconds
 172         self.anim_die2 = '1 1 0.5'; // 2 seconds
 173         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 174         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 175         self.anim_duckwalk = '4 1 1';
 176         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 177         self.anim_duckidle = '6 1 1';
 178         self.anim_idle = '7 1 1';
 179         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 180         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 181         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 182         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 183         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 184         self.anim_run = '13 1 1';
 185         self.anim_runbackwards = '14 1 1';
 186         self.anim_strafeleft = '15 1 1';
 187         self.anim_straferight = '16 1 1';
 188         self.anim_dead1 = '17 1 1';
 189         self.anim_dead2 = '18 1 1';
 190         self.anim_forwardright = '19 1 1';
 191         self.anim_forwardleft = '20 1 1';
 192         self.anim_backright = '21 1 1';
 193         self.anim_backleft  = '22 1 1';
 194         self.anim_melee = '23 1 1';
 195         animparseerror = FALSE;
 196         animfilename = strcat(self.model, ".animinfo");
 197         animfile = fopen(animfilename, FILE_READ);
 198         if (animfile >= 0)
 199         {
 200                 self.anim_die1         = animparseline(animfile);
 201                 self.anim_die2         = animparseline(animfile);
 202                 self.anim_draw         = animparseline(animfile);
 203                 self.anim_duck         = animparseline(animfile);
 204                 self.anim_duckwalk     = animparseline(animfile);
 205                 self.anim_duckjump     = animparseline(animfile);
 206                 self.anim_duckidle     = animparseline(animfile);
 207                 self.anim_idle         = animparseline(animfile);
 208                 self.anim_jump         = animparseline(animfile);
 209                 self.anim_pain1        = animparseline(animfile);
 210                 self.anim_pain2        = animparseline(animfile);
 211                 self.anim_shoot        = animparseline(animfile);
 212                 self.anim_taunt        = animparseline(animfile);
 213                 self.anim_run          = animparseline(animfile);
 214                 self.anim_runbackwards = animparseline(animfile);
 215                 self.anim_strafeleft   = animparseline(animfile);
 216                 self.anim_straferight  = animparseline(animfile);
 217                 self.anim_forwardright = animparseline(animfile);
 218                 self.anim_forwardleft  = animparseline(animfile);
 219                 self.anim_backright    = animparseline(animfile);
 220                 self.anim_backleft     = animparseline(animfile);
 221                 self.anim_melee        = animparseline(animfile);
 222                 fclose(animfile);
 223
 224                 // derived anims
 225                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 226                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 227
 228                 if (animparseerror)
 229                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 230         }
 231         else
 232                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 233         // reset animstate now
 234         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 235 };
 236
 237 void player_anim (void)
 238 {
 239         updateanim(self);
 240         if (self.weaponentity)
 241                 updateanim(self.weaponentity);
 242
 243         if (self.deadflag != DEAD_NO)
 244         {
 245                 if (time > self.animstate_endtime)
 246                 {
 247                         if (self.maxs_z > 5)
 248                         {
 249                                 self.maxs_z = 5;
 250                                 setsize(self, self.mins, self.maxs);
 251                         }
 252                         self.frame = self.dead_frame;
 253                 }
 254                 return;
 255         }
 256
 257         if (!self.animstate_override)
 258         {
 259                 if (!(self.flags & FL_ONGROUND))
 260                 {
 261                         if (self.crouch)
 262                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 263                         else
 264                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 265                         self.restart_jump = FALSE;
 266                 }
 267                 else if (self.crouch)
 268                 {
 269                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 270                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 271                         else
 272                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 273                 }
 274                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 275                 {
 276                         if (self.movement_x > 0 && self.movement_y == 0)
 277                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 278                         else if (self.movement_x < 0 && self.movement_y == 0)
 279                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 280                         else if (self.movement_x == 0 && self.movement_y > 0)
 281                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 282                         else if (self.movement_x == 0 && self.movement_y < 0)
 283                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 284                         else if (self.movement_x > 0 && self.movement_y > 0)
 285                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 286                         else if (self.movement_x > 0 && self.movement_y < 0)
 287                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 288                         else if (self.movement_x < 0 && self.movement_y > 0)
 289                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 290                         else if (self.movement_x < 0 && self.movement_y < 0)
 291                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 292                         else
 293                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 294                 }
 295                 else
 296                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 297         }
 298
 299         if (self.weaponentity)
 300         if (!self.weaponentity.animstate_override)
 301                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 302 }
 303
 304 void SpawnThrownWeapon (vector org, float w)
 305 {
 306         if(g_minstagib)
 307         if(self.ammo_cells <= 0)
 308                 return;
 309
 310         if(g_pinata)
 311         {
 312                 float j;
 313                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 314                 {
 315                         if(self.weapons & W_WeaponBit(j))
 316                                 if(W_IsWeaponThrowable(j))
 317                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 318                 }
 319         }
 320         else
 321         {
 322                 if(W_IsWeaponThrowable(self.weapon))
 323                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 324         }
 325 }
 326
 327 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 328 {
 329         local float take, save;
 330         vector v;
 331         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 332
 333         // damage resistance (ignore most of the damage from a bullet or similar)
 334         damage = max(damage - 5, 1);
 335
 336         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 337         take = v_x;
 338         save = v_y;
 339
 340         if(sound_allowed(MSG_BROADCAST, attacker))
 341         {
 342                 if (save > 10)
 343                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 344                 else if (take > 30)
 345                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 346                 else if (take > 10)
 347                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 348         }
 349
 350         if (take > 50)
 351                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 352         if (take > 100)
 353                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 354
 355         if (!(self.flags & FL_GODMODE))
 356         {
 357                 self.armorvalue = self.armorvalue - save;
 358                 self.health = self.health - take;
 359                 // pause regeneration for 5 seconds
 360                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 361         }
 362         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 363         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 364         self.dmg_inflictor = inflictor;
 365
 366         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 367         {
 368                 // don't use any animations as a gib
 369                 self.frame = 0;
 370                 self.dead_frame = 0;
 371                 // view just above the floor
 372                 self.view_ofs = '0 0 4';
 373
 374                 Violence_GibSplash(self, 1, 1, attacker);
 375                 self.modelindex = 0; // restore later
 376                 self.solid = SOLID_NOT; // restore later
 377         }
 378 }
 379
 380 void ClientKill_Now_TeamChange();
 381 void freezetag_CheckWinner();
 382
 383 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 384 {
 385         local float take, save, waves, sdelay, dh, da, j;
 386         vector v;
 387         float valid_damage_for_weaponstats;
 388         float excess;
 389
 390         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 391                 return;
 392
 393         dh = max(self.health, 0);
 394         da = max(self.armorvalue, 0);
 395
 396         if(!DEATH_ISSPECIAL(deathtype))
 397         {
 398                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 399                 if(self != attacker)
 400                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 401         }
 402
 403         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 404         {
 405                 // tuba causes blood to come out of the ears
 406                 vector ear1, ear2;
 407                 vector d;
 408                 float f;
 409                 ear1 = self.origin;
 410                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 411                 ear2 = ear1;
 412                 makevectors(self.angles);
 413                 ear1 += v_right * -10;
 414                 ear2 += v_right * +10;
 415                 d = inflictor.origin - self.origin;
 416                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 417                 force = v_right * vlen(force);
 418                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 419                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 420                 if(f > 0)
 421                 {
 422                         hitloc = ear1;
 423                         force = force * -1;
 424                 }
 425                 else
 426                 {
 427                         hitloc = ear2;
 428                         // force is already good
 429                 }
 430         }
 431         else
 432                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 433
 434         if (!g_minstagib)
 435         {
 436                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 437                 take = v_x;
 438                 save = v_y;
 439         }
 440         else
 441         {
 442                 save = 0;
 443                 take = damage;
 444         }
 445
 446         frag_inflictor = inflictor;
 447         frag_attacker = attacker;
 448         frag_target = self;
 449         damage_take = take;
 450         damage_save = save;
 451         damage_force = force;
 452         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 453         take = bound(0, damage_take, self.health);
 454         save = bound(0, damage_save, self.armorvalue);
 455         excess = max(0, damage - take - save);
 456
 457         if(sound_allowed(MSG_BROADCAST, attacker))
 458         {
 459                 if (save > 10)
 460                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 461                 else if (take > 30)
 462                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 463                 else if (take > 10)
 464                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 465         }
 466
 467         if (take > 50)
 468                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 469         if (take > 100)
 470                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 471
 472         if (time >= self.spawnshieldtime)
 473         {
 474                 if (!(self.flags & FL_GODMODE))
 475                 {
 476                         self.armorvalue = self.armorvalue - save;
 477                         self.health = self.health - take;
 478                         // pause regeneration for 5 seconds
 479                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 480
 481                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 482                         {
 483                                 self.pain_finished = time + 0.5;        //Supajoe
 484
 485                                 if(sv_gentle < 1) {
 486                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 487                                         {
 488                                                 if (random() > 0.5)
 489                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 490                                                 else
 491                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 492                                         }
 493
 494                                         if(sound_allowed(MSG_BROADCAST, attacker))
 495                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 496                                         if(self.health > 1)
 497                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 498                                         {
 499                                                 if(deathtype == DEATH_FALL)
 500                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 501                                                 else if(self.health > 75) // TODO make a "gentle" version?
 502                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 503                                                 else if(self.health > 50)
 504                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 505                                                 else if(self.health > 25)
 506                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 507                                                 else
 508                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 509                                         }
 510                                 }
 511
 512                                 // throw off bot aim temporarily
 513                                 local float shake;
 514                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 515                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 516                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 517                         }
 518                 }
 519                 else
 520                         self.max_armorvalue += (save + take);
 521         }
 522         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 523         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 524         self.dmg_inflictor = inflictor;
 525
 526         if(attacker == self)
 527         {
 528                 // don't reset pushltime for self damage as it may be an attempt to
 529                 // escape a lava pit or similar
 530                 //self.pushltime = 0;
 531         }
 532         else if(attacker.classname == "player")
 533         {
 534                 self.pusher = attacker;
 535                 self.pushltime = time + autocvar_g_maxpushtime;
 536         }
 537         else if(time < self.pushltime)
 538         {
 539                 attacker = self.pusher;
 540                 self.pushltime = max(self.pushltime, time + 0.6);
 541         }
 542         else
 543                 self.pushltime = 0;
 544
 545         float abot, vbot, awep;
 546         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 547         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 548
 549         valid_damage_for_weaponstats = 0;
 550         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 551         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 552         if(attacker && self != attacker)
 553         if(IsDifferentTeam(self, attacker))
 554         {
 555                 if(DEATH_ISSPECIAL(deathtype))
 556                         awep = attacker.weapon;
 557                 else
 558                         awep = DEATH_WEAPONOF(deathtype);
 559                 valid_damage_for_weaponstats = 1;
 560         }
 561
 562         if(valid_damage_for_weaponstats)
 563         {
 564                 dh = dh - max(self.health, 0);
 565                 da = da - max(self.armorvalue, 0);
 566                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 567         }
 568
 569         if (self.health < 1)
 570         {
 571                 float defer_ClientKill_Now_TeamChange;
 572                 defer_ClientKill_Now_TeamChange = FALSE;
 573
 574                 if(self.alivetime)
 575                 {
 576                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 577                         self.alivetime = 0;
 578                 }
 579
 580                 if(valid_damage_for_weaponstats)
 581                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 582
 583                 if(sv_gentle < 1) // TODO make a "gentle" version?
 584                 if(sound_allowed(MSG_BROADCAST, attacker))
 585                 {
 586                         if(deathtype == DEATH_DROWN)
 587                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 588                         else
 589                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 590                 }
 591
 592                 // get rid of kill indicator
 593                 if(self.killindicator)
 594                 {
 595                         remove(self.killindicator);
 596                         self.killindicator = world;
 597                         if(self.killindicator_teamchange)
 598                                 defer_ClientKill_Now_TeamChange = TRUE;
 599
 600                         if(self.classname == "body")
 601                         if(deathtype == DEATH_KILL)
 602                         {
 603                                 // for the lemmings fans, a small harmless explosion
 604                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 605                         }
 606                 }
 607
 608                 if(!g_freezetag)
 609                 {
 610                         // become fully visible
 611                         self.alpha = 1;
 612                         // throw a weapon
 613                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 614                 }
 615
 616                 // print an obituary message
 617                 Obituary (attacker, inflictor, self, deathtype);
 618                 race_PreDie();
 619                 DropAllRunes(self);
 620
 621         // increment frag counter for used weapon type
 622         float w;
 623         w = DEATH_WEAPONOF(deathtype);
 624         if(WEP_VALID(w))
 625         if(self.classname == "player")
 626         if(self != attacker)
 627         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 628
 629                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 630                 {
 631                         PutClientInServer();
 632                         count_alive_players(); // re-count players
 633                         freezetag_CheckWinner();
 634                         return;
 635                 }
 636
 637                 frag_attacker = attacker;
 638                 frag_inflictor = inflictor;
 639                 frag_target = self;
 640                 MUTATOR_CALLHOOK(PlayerDies);
 641                 weapon_action(self.weapon, WR_PLAYERDEATH);
 642
 643                 if(self.flagcarried)
 644                 {
 645                         if(attacker.classname != "player")
 646                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 647                         else if(attacker.team == self.team)
 648                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 649                         else
 650                                 DropFlag(self.flagcarried, world, attacker);
 651                 }
 652                 if(self.ballcarried && g_nexball)
 653                         DropBall(self.ballcarried, self.origin, self.velocity);
 654                 Portal_ClearAllLater(self);
 655
 656                 if(clienttype(self) == CLIENTTYPE_REAL)
 657                 {
 658                         stuffcmd(self, "-zoom\n");
 659                         self.fixangle = TRUE;
 660                         //msg_entity = self;
 661                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 662                         //WriteAngle (MSG_ONE, self.v_angle_x);
 663                         //WriteAngle (MSG_ONE, self.v_angle_y);
 664                         //WriteAngle (MSG_ONE, 80);
 665                 }
 666
 667                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 668                         ClientKill_Now_TeamChange();
 669
 670                 if(g_arena)
 671                         Spawnqueue_Unmark(self);
 672
 673                 if(g_freezetag)
 674                         return;
 675
 676                 // when we get here, player actually dies
 677                 // clear waypoints (do this AFTER FreezeTag)
 678                 WaypointSprite_PlayerDead();
 679
 680                 // make the corpse upright (not tilted)
 681                 self.angles_x = 0;
 682                 self.angles_z = 0;
 683                 // don't spin
 684                 self.avelocity = '0 0 0';
 685                 // view from the floor
 686                 self.view_ofs = '0 0 -8';
 687                 // toss the corpse
 688                 self.movetype = MOVETYPE_TOSS;
 689                 // shootable corpse
 690                 self.solid = SOLID_CORPSE;
 691                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 692                 // don't stick to the floor
 693                 self.flags &~= FL_ONGROUND;
 694                 // dying animation
 695                 self.deadflag = DEAD_DYING;
 696                 // when to allow respawn
 697                 sdelay = 0;
 698                 waves = 0;
 699                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 700                 if(!sdelay)
 701                 {
 702                         if(g_cts)
 703                                 sdelay = 0; // no respawn delay in CTS
 704                         else
 705                                 sdelay = autocvar_g_respawn_delay;
 706                 }
 707                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 708                 if(!waves)
 709                         waves = autocvar_g_respawn_waves;
 710                 if(waves)
 711                         self.death_time = ceil((time + sdelay) / waves) * waves;
 712                 else
 713                         self.death_time = time + sdelay;
 714                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 715                         self.respawn_countdown = 10; // first number to count down from is 10
 716                 else
 717                         self.respawn_countdown = -1; // do not count down
 718                 if (random() < 0.5)
 719                 {
 720                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 721                         self.dead_frame = self.anim_dead1_x;
 722                 }
 723                 else
 724                 {
 725                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 726                         self.dead_frame = self.anim_dead2_x;
 727                 }
 728                 // set damage function to corpse damage
 729                 self.event_damage = PlayerCorpseDamage;
 730                 // call the corpse damage function just in case it wants to gib
 731                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 732                 // set up to fade out later
 733                 SUB_SetFade (self, time + 6 + random (), 1);
 734
 735                 if(sv_gentle > 0 || autocvar_ekg) {
 736                         // remove corpse
 737                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 738                 }
 739
 740                 // reset fields the weapons may use just in case
 741                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 742                 {
 743                         weapon_action(j, WR_RESETPLAYER);
 744                         ATTACK_FINISHED_FOR(self, j) = 0;
 745                 }
 746         }
 747 }
 748
 749 .float muted; // to be used by prvm_edictset server playernumber muted 1
 750 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 751 // message "": do not say, just test flood control
 752 // return value:
 753 //   1 = accept
 754 //   0 = reject
 755 //  -1 = fake accept
 756 {
 757         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 758         float flood, privatemsgprefixlen;
 759         var .float flood_field;
 760         entity head;
 761         float ret;
 762
 763         if(Ban_MaybeEnforceBan(source))
 764                 return 0;
 765
 766         if(!teamsay && !privatesay)
 767                 if(substring(msgin, 0, 1) == " ")
 768                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 769
 770         msgin = formatmessage(msgin);
 771
 772         if(source.classname != "player")
 773                 colorstr = "^0"; // black for spectators
 774         else if(teamplay)
 775                 colorstr = Team_ColorCode(source.team);
 776         else
 777                 teamsay = FALSE;
 778
 779         if(intermission_running)
 780                 teamsay = FALSE;
 781
 782         if(msgin != "")
 783                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 784
 785         /*
 786          * using bprint solves this... me stupid
 787         // how can we prevent the message from appearing in a listen server?
 788         // for now, just give "say" back and only handle say_team
 789         if(!teamsay)
 790         {
 791                 clientcommand(self, strcat("say ", msgin));
 792                 return;
 793         }
 794         */
 795
 796         if(autocvar_g_chat_teamcolors)
 797                 namestr = playername(source);
 798         else
 799                 namestr = source.netname;
 800
 801         if(msgin != "")
 802         {
 803                 if(privatesay)
 804                 {
 805                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 806                         privatemsgprefixlen = strlen(msgstr);
 807                         msgstr = strcat(msgstr, msgin);
 808                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 809                         if(autocvar_g_chat_teamcolors)
 810                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 811                         else
 812                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 813                 }
 814                 else if(teamsay)
 815                 {
 816                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 817                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 818                 }
 819                 else
 820                 {
 821                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 822                         cmsgstr = "";
 823                 }
 824                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 825         }
 826         else
 827         {
 828                 msgstr = cmsgstr = "";
 829         }
 830
 831         fullmsgstr = msgstr;
 832         fullcmsgstr = cmsgstr;
 833
 834         // FLOOD CONTROL
 835         flood = 0;
 836         if(floodcontrol)
 837         {
 838                 float flood_spl;
 839                 float flood_burst;
 840                 float flood_lmax;
 841                 float lines;
 842                 if(privatesay)
 843                 {
 844                         flood_spl = autocvar_g_chat_flood_spl_tell;
 845                         flood_burst = autocvar_g_chat_flood_burst_tell;
 846                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 847                         flood_field = floodcontrol_chattell;
 848                 }
 849                 else if(teamsay)
 850                 {
 851                         flood_spl = autocvar_g_chat_flood_spl_team;
 852                         flood_burst = autocvar_g_chat_flood_burst_team;
 853                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 854                         flood_field = floodcontrol_chatteam;
 855                 }
 856                 else
 857                 {
 858                         flood_spl = autocvar_g_chat_flood_spl;
 859                         flood_burst = autocvar_g_chat_flood_burst;
 860                         flood_lmax = autocvar_g_chat_flood_lmax;
 861                         flood_field = floodcontrol_chat;
 862                 }
 863                 flood_burst = max(0, flood_burst - 1);
 864                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 865
 866                 // do flood control for the default line size
 867                 if(msgstr != "")
 868                 {
 869                         getWrappedLine_remaining = msgstr;
 870                         msgstr = "";
 871                         lines = 0;
 872                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 873                         {
 874                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 875                                 ++lines;
 876                         }
 877                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 878
 879                         if(getWrappedLine_remaining != "")
 880                         {
 881                                 msgstr = strcat(msgstr, "\n");
 882                                 flood = 2;
 883                         }
 884
 885                         if(time >= source.flood_field)
 886                         {
 887                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 888                         }
 889                         else
 890                         {
 891                                 flood = 1;
 892                                 msgstr = fullmsgstr;
 893                         }
 894                 }
 895                 else
 896                 {
 897                         if(time >= source.flood_field)
 898                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 899                         else
 900                                 flood = 1;
 901                 }
 902
 903                 if (timeoutStatus == 2) //when game is paused, no flood protection
 904                         source.flood_field = flood = 0;
 905         }
 906
 907         if(flood == 2) // cannot happen for empty msgstr
 908         {
 909                 if(autocvar_g_chat_flood_notify_flooder)
 910                 {
 911                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 912                         sourcecmsgstr = "";
 913                 }
 914                 else
 915                 {
 916                         sourcemsgstr = fullmsgstr;
 917                         sourcecmsgstr = fullcmsgstr;
 918                 }
 919                 cmsgstr = "";
 920         }
 921         else
 922         {
 923                 sourcemsgstr = msgstr;
 924                 sourcecmsgstr = cmsgstr;
 925         }
 926
 927         if(!privatesay)
 928         if(source.classname != "player")
 929         {
 930                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 931                         teamsay = -1; // spectators
 932         }
 933
 934         if(flood)
 935                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 936
 937         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 938         if(privatesay)
 939                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 940
 941         if(source.muted)
 942         {
 943                 // always fake the message
 944                 ret = -1;
 945         }
 946         else if(flood == 1)
 947         {
 948                 if(autocvar_g_chat_flood_notify_flooder)
 949                 {
 950                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 951                         ret = 0;
 952                 }
 953                 else
 954                         ret = -1;
 955         }
 956         else
 957         {
 958                 ret = 1;
 959         }
 960
 961         if(sourcemsgstr != "" && ret != 0)
 962         {
 963                 if(ret < 0) // fake
 964                 {
 965                         sprint(source, sourcemsgstr);
 966                         if(sourcecmsgstr != "" && !privatesay)
 967                                 centerprint(source, sourcecmsgstr);
 968                 }
 969                 else if(privatesay)
 970                 {
 971                         sprint(source, sourcemsgstr);
 972                         sprint(privatesay, msgstr);
 973                         if(cmsgstr != "")
 974                                 centerprint(privatesay, cmsgstr);
 975                 }
 976                 else if(teamsay > 0)
 977                 {
 978                         sprint(source, sourcemsgstr);
 979                         if(sourcecmsgstr != "")
 980                                 centerprint(source, sourcecmsgstr);
 981                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 982                                 if(head != source)
 983                                 {
 984                                         sprint(head, msgstr);
 985                                         if(cmsgstr != "")
 986                                                 centerprint(head, cmsgstr);
 987                                 }
 988                 }
 989                 else if(teamsay < 0)
 990                 {
 991                         sprint(source, sourcemsgstr);
 992                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 993                                 if(head != source)
 994                                         sprint(head, msgstr);
 995                 }
 996                 else if(sourcemsgstr != msgstr)
 997                 {
 998                         sprint(source, sourcemsgstr);
 999                         FOR_EACH_REALCLIENT(head)
1000                                 if(head != source)
1001                                         sprint(head, msgstr);
1002                 }
1003                 else
1004                         bprint(msgstr);
1005         }
1006
1007         return ret;
1008 }
1009
1010 float GetVoiceMessageVoiceType(string type)
1011 {
1012         if(type == "taunt")
1013                 return VOICETYPE_TAUNT;
1014         if(type == "teamshoot")
1015                 return VOICETYPE_LASTATTACKER;
1016         return VOICETYPE_TEAMRADIO;
1017 }
1018
1019 string allvoicesamples;
1020 .string GetVoiceMessageSampleField(string type)
1021 {
1022         GetPlayerSoundSampleField_notFound = 0;
1023         switch(type)
1024         {
1025 #define _VOICEMSG(m) case #m: return playersound_##m;
1026                 ALLVOICEMSGS
1027 #undef _VOICEMSG
1028         }
1029         GetPlayerSoundSampleField_notFound = 1;
1030         return playersound_taunt;
1031 }
1032
1033 .string GetPlayerSoundSampleField(string type)
1034 {
1035         GetPlayerSoundSampleField_notFound = 0;
1036         switch(type)
1037         {
1038 #define _VOICEMSG(m) case #m: return playersound_##m;
1039                 ALLPLAYERSOUNDS
1040 #undef _VOICEMSG
1041         }
1042         GetPlayerSoundSampleField_notFound = 1;
1043         return playersound_taunt;
1044 }
1045
1046 void PrecacheGlobalSound(string samplestring)
1047 {
1048         float n, i;
1049         tokenize_console(samplestring);
1050         n = stof(argv(1));
1051         if(n > 0)
1052         {
1053                 for(i = 1; i <= n; ++i)
1054                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1055         }
1056         else
1057         {
1058                 precache_sound(strcat(argv(0), ".wav"));
1059         }
1060 }
1061
1062 void PrecachePlayerSounds(string f)
1063 {
1064         float fh;
1065         string s;
1066         fh = fopen(f, FILE_READ);
1067         if(fh < 0)
1068                 return;
1069         while((s = fgets(fh)))
1070         {
1071                 if(tokenize_console(s) != 3)
1072                 {
1073                         dprint("Invalid sound info line: ", s, "\n");
1074                         continue;
1075                 }
1076                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1077         }
1078         fclose(fh);
1079
1080         if not(allvoicesamples)
1081         {
1082 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1083                 ALLVOICEMSGS
1084 #undef _VOICEMSG
1085                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1086         }
1087 }
1088
1089 void ClearPlayerSounds()
1090 {
1091 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1092         ALLPLAYERSOUNDS
1093         ALLVOICEMSGS
1094 #undef _VOICEMSG
1095 }
1096
1097 float LoadPlayerSounds(string f, float first)
1098 {
1099         float fh;
1100         string s;
1101         var .string field;
1102         fh = fopen(f, FILE_READ);
1103         if(fh < 0)
1104         {
1105                 dprint("Player sound file not found: ", f, "\n");
1106                 return 0;
1107         }
1108         while((s = fgets(fh)))
1109         {
1110                 if(tokenize_console(s) != 3)
1111                         continue;
1112                 field = GetPlayerSoundSampleField(argv(0));
1113                 if(GetPlayerSoundSampleField_notFound)
1114                         field = GetVoiceMessageSampleField(argv(0));
1115                 if(GetPlayerSoundSampleField_notFound)
1116                         continue;
1117                 if(self.field)
1118                         strunzone(self.field);
1119                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1120         }
1121         fclose(fh);
1122         return 1;
1123 }
1124
1125 .float modelindex_for_playersound;
1126 .float skinindex_for_playersound;
1127 void UpdatePlayerSounds()
1128 {
1129         if(self.modelindex == self.modelindex_for_playersound)
1130         if(self.skinindex == self.skinindex_for_playersound)
1131                 return;
1132         self.modelindex_for_playersound = self.modelindex;
1133         self.skinindex_for_playersound = self.skinindex;
1134         ClearPlayerSounds();
1135         LoadPlayerSounds("sound/player/default.sounds", 1);
1136         if(!autocvar_g_debug_defaultsounds)
1137                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1138                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1139 }
1140
1141 void FakeGlobalSound(string sample, float chan, float voicetype)
1142 {
1143         float n;
1144         float tauntrand;
1145
1146         if(sample == "")
1147                 return;
1148
1149         tokenize_console(sample);
1150         n = stof(argv(1));
1151         if(n > 0)
1152                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1153         else
1154                 sample = strcat(argv(0), ".wav"); // randomization
1155
1156         switch(voicetype)
1157         {
1158                 case VOICETYPE_LASTATTACKER_ONLY:
1159                         break;
1160                 case VOICETYPE_LASTATTACKER:
1161                         if(self.pusher)
1162                         {
1163                                 msg_entity = self;
1164                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1165                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1166                         }
1167                         break;
1168                 case VOICETYPE_TEAMRADIO:
1169                         msg_entity = self;
1170                         if(msg_entity.cvar_cl_voice_directional == 1)
1171                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1172                         else
1173                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1174                         break;
1175                 case VOICETYPE_AUTOTAUNT:
1176                         if(!sv_autotaunt)
1177                                 break;
1178                         if(!sv_taunt)
1179                                 break;
1180                         if(sv_gentle)
1181                                 break;
1182                         tauntrand = random();
1183                         msg_entity = self;
1184                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1185                         {
1186                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1187                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1188                                 else
1189                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1190                         }
1191                         break;
1192                 case VOICETYPE_TAUNT:
1193                         if(self.classname == "player")
1194                                 if(self.deadflag == DEAD_NO)
1195                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1196                         if(!sv_taunt)
1197                                 break;
1198                         if(sv_gentle)
1199                                 break;
1200                         msg_entity = self;
1201                         if (msg_entity.cvar_cl_voice_directional >= 1)
1202                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1203                         else
1204                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1205                         break;
1206                 case VOICETYPE_PLAYERSOUND:
1207                         msg_entity = self;
1208                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1209                         break;
1210                 default:
1211                         backtrace("Invalid voice type!");
1212                         break;
1213         }
1214 }
1215
1216 void GlobalSound(string sample, float chan, float voicetype)
1217 {
1218         float n;
1219         float tauntrand;
1220
1221         if(sample == "")
1222                 return;
1223
1224         tokenize_console(sample);
1225         n = stof(argv(1));
1226         if(n > 0)
1227                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1228         else
1229                 sample = strcat(argv(0), ".wav"); // randomization
1230
1231         switch(voicetype)
1232         {
1233                 case VOICETYPE_LASTATTACKER_ONLY:
1234                         if(self.pusher)
1235                         {
1236                                 msg_entity = self.pusher;
1237                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1238                                 {
1239                                         if(msg_entity.cvar_cl_voice_directional == 1)
1240                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1241                                         else
1242                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1243                                 }
1244                         }
1245                         break;
1246                 case VOICETYPE_LASTATTACKER:
1247                         if(self.pusher)
1248                         {
1249                                 msg_entity = self.pusher;
1250                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1251                                 {
1252                                         if(msg_entity.cvar_cl_voice_directional == 1)
1253                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1254                                         else
1255                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1256                                 }
1257                                 msg_entity = self;
1258                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1259                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1260                         }
1261                         break;
1262                 case VOICETYPE_TEAMRADIO:
1263                         FOR_EACH_REALCLIENT(msg_entity)
1264                                 if(!teamplay || msg_entity.team == self.team)
1265                                 {
1266                                         if(msg_entity.cvar_cl_voice_directional == 1)
1267                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1268                                         else
1269                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1270                                 }
1271                         break;
1272                 case VOICETYPE_AUTOTAUNT:
1273                         if(!sv_autotaunt)
1274                                 break;
1275                         if(!sv_taunt)
1276                                 break;
1277                         if(sv_gentle)
1278                                 break;
1279                         tauntrand = random();
1280                         FOR_EACH_REALCLIENT(msg_entity)
1281                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1282                                 {
1283                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1284                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1285                                         else
1286                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1287                                 }
1288                         break;
1289                 case VOICETYPE_TAUNT:
1290                         if(self.classname == "player")
1291                                 if(self.deadflag == DEAD_NO)
1292                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1293                         if(!sv_taunt)
1294                                 break;
1295                         if(sv_gentle)
1296                                 break;
1297                         FOR_EACH_REALCLIENT(msg_entity)
1298                         {
1299                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1300                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1301                                 else
1302                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1303                         }
1304                         break;
1305                 case VOICETYPE_PLAYERSOUND:
1306                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1307                         break;
1308                 default:
1309                         backtrace("Invalid voice type!");
1310                         break;
1311         }
1312 }
1313
1314 void PlayerSound(.string samplefield, float chan, float voicetype)
1315 {
1316         GlobalSound(self.samplefield, chan, voicetype);
1317 }
1318
1319 void VoiceMessage(string type, string msg)
1320 {
1321         var .string sample;
1322         float voicetype, ownteam;
1323         float flood;
1324         sample = GetVoiceMessageSampleField(type);
1325
1326         if(GetPlayerSoundSampleField_notFound)
1327         {
1328                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1329                 return;
1330         }
1331
1332         voicetype = GetVoiceMessageVoiceType(type);
1333         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1334
1335         flood = Say(self, ownteam, world, msg, 1);
1336
1337         if (flood > 0)
1338                 GlobalSound(self.sample, CH_VOICE, voicetype);
1339         else if (flood < 0)
1340                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1341 }
1342
1343 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1344 {
1345 //      show_message
1346 //      0 (00) automove centerprint, admin message
1347 //      1 (01) automove centerprint, no admin message
1348 //      2 (10) no centerprint, admin message
1349 //      3 (11) no centerprint, no admin message
1350
1351         float lockteams_backup;
1352
1353         lockteams_backup = lockteams;  // backup any team lock
1354
1355         lockteams = 0;  // disable locked teams
1356
1357         TeamchangeFrags(client);  // move the players frags
1358         SetPlayerColors(client, team_colour - 1);  // set the players colour
1359         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1360
1361         lockteams = lockteams_backup;  // restore the team lock
1362
1363         LogTeamchange(client.playerid, client.team, type);
1364
1365         if not(show_message & 1) // admin message
1366                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1367
1368         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1369 }