qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // url_fopen returned, we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  29                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  30                         n = tokenizebyseparator(cvar_purechanges, "\n");
  31                         for(i = 0; i < n; ++i)
  32                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  33                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  34                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  35                                 {
  36                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  37                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  38                                         if(v != '0 0 0')
  39                                         {
  40                                                 //vector is: kills hits damage
  41                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  42                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  43                                         }
  44                                 }
  45                         url_fputs(fh, "#end\n\n");
  46                         url_fclose(fh, WeaponStats_ready, world);
  47                         buf_del(weaponstats_buffer);
  48                         weaponstats_buffer = -1;
  49                         break;
  50                 case URL_READY_CANREAD:
  51                         // url_fclose is processing, we got a response for writing the data
  52                         // this must come from HTTP
  53                         print("Got response from weapon stats server:\n");
  54                         while((s = url_fgets(fh)))
  55                                 print("  ", s, "\n");
  56                         print("End of response.\n");
  57                         url_fclose(fh, WeaponStats_ready, world);
  58                         break;
  59                 case URL_READY_CLOSED:
  60                         // url_fclose has finished
  61                         print("Weapon stats written\n");
  62                         break;
  63                 case URL_READY_ERROR:
  64                 default:
  65                         print("Weapon stats writing failed: ", ftos(status), "\n");
  66                         break;
  67         }
  68 }
  69
  70 void WeaponStats_Shutdown()
  71 {
  72         if(weaponstats_buffer < 0)
  73                 return;
  74         if(autocvar_sv_weaponstats_file != "")
  75         {
  76                 url_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  77         }
  78         else
  79         {
  80                 buf_del(weaponstats_buffer);
  81                 weaponstats_buffer = -1;
  82         }
  83 }
  84
  85 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  86 {
  87         float idx;
  88         if(weaponstats_buffer < 0)
  89                 return;
  90         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  91                 return;
  92         if(awep > WEP_LAST || vwep > WEP_LAST)
  93                 return;
  94         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  95         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  96 }
  97 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  98 {
  99         if(damage < 0)
 100                 error("negative damage?");
 101         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 102 }
 103 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 104 {
 105         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 106 }
 107
 108 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 109 // merged player_run and player_stand to player_anim
 110 // added death animations to player_anim
 111 // can now spawn thrown weapons from anywhere, not just from players
 112 // thrown weapons now fade out after 20 seconds
 113 // created PlayerGib function
 114 // PlayerDie no longer uses hitloc or damage
 115 // PlayerDie now supports dying animations as well as gibbing
 116 // cleaned up PlayerDie a lot
 117 // added CopyBody
 118
 119 .entity pusher;
 120 .float pushltime;
 121
 122 void CopyBody(float keepvelocity)
 123 {
 124         local entity oldself;
 125         if (self.effects & EF_NODRAW)
 126                 return;
 127         oldself = self;
 128         self = spawn();
 129         self.enemy = oldself;
 130         self.lip = oldself.lip;
 131         self.colormap = oldself.colormap;
 132         self.glowmod = oldself.glowmod;
 133         self.iscreature = oldself.iscreature;
 134         self.angles = oldself.angles;
 135         self.avelocity = oldself.avelocity;
 136         self.classname = "body";
 137         self.damageforcescale = oldself.damageforcescale;
 138         self.effects = oldself.effects;
 139         self.event_damage = oldself.event_damage;
 140         self.animstate_startframe = oldself.animstate_startframe;
 141         self.animstate_numframes = oldself.animstate_numframes;
 142         self.animstate_framerate = oldself.animstate_framerate;
 143         self.animstate_starttime = oldself.animstate_starttime;
 144         self.animstate_endtime = oldself.animstate_endtime;
 145         self.animstate_override = oldself.animstate_override;
 146         self.animstate_looping = oldself.animstate_looping;
 147         self.frame = oldself.frame;
 148         self.dead_frame = oldself.dead_frame;
 149         self.pain_finished = oldself.pain_finished;
 150         self.health = oldself.health;
 151         self.armorvalue = oldself.armorvalue;
 152         self.armortype = oldself.armortype;
 153         self.model = oldself.model;
 154         self.modelindex = oldself.modelindex;
 155         self.modelindex_lod0 = oldself.modelindex_lod0;
 156         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 157         self.modelindex_lod1 = oldself.modelindex_lod1;
 158         self.modelindex_lod2 = oldself.modelindex_lod2;
 159         self.skinindex = oldself.skinindex;
 160         self.species = oldself.species;
 161         self.movetype = oldself.movetype;
 162         self.nextthink = oldself.nextthink;
 163         self.solid = oldself.solid;
 164         self.ballistics_density = oldself.ballistics_density;
 165         self.takedamage = oldself.takedamage;
 166         self.think = oldself.think;
 167         self.customizeentityforclient = oldself.customizeentityforclient;
 168         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 169         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 170         if (keepvelocity == 1)
 171                 self.velocity = oldself.velocity;
 172         self.oldvelocity = self.velocity;
 173         self.fade_time = oldself.fade_time;
 174         self.fade_rate = oldself.fade_rate;
 175         //self.weapon = oldself.weapon;
 176         setorigin(self, oldself.origin);
 177         setsize(self, oldself.mins, oldself.maxs);
 178         self.prevorigin = oldself.origin;
 179         self.reset = SUB_Remove;
 180
 181         Drag_MoveDrag(oldself, self);
 182
 183         self.owner = oldself;
 184         self = oldself;
 185 }
 186
 187 float player_getspecies()
 188 {
 189         float s;
 190         get_model_parameters(self.model, self.skinindex);
 191         s = get_model_parameters_species;
 192         get_model_parameters(string_null, 0);
 193         if(s < 0)
 194                 return SPECIES_HUMAN;
 195         return s;
 196 }
 197
 198 void player_setupanimsformodel()
 199 {
 200         local string animfilename;
 201         local float animfile;
 202         // defaults for legacy .zym models without animinfo files
 203         self.anim_die1 = '0 1 0.5'; // 2 seconds
 204         self.anim_die2 = '1 1 0.5'; // 2 seconds
 205         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 206         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 207         self.anim_duckwalk = '4 1 1';
 208         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 209         self.anim_duckidle = '6 1 1';
 210         self.anim_idle = '7 1 1';
 211         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 212         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 213         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 214         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 215         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 216         self.anim_run = '13 1 1';
 217         self.anim_runbackwards = '14 1 1';
 218         self.anim_strafeleft = '15 1 1';
 219         self.anim_straferight = '16 1 1';
 220         self.anim_dead1 = '17 1 1';
 221         self.anim_dead2 = '18 1 1';
 222         self.anim_forwardright = '19 1 1';
 223         self.anim_forwardleft = '20 1 1';
 224         self.anim_backright = '21 1 1';
 225         self.anim_backleft  = '22 1 1';
 226         self.anim_melee = '23 1 1';
 227         animparseerror = FALSE;
 228         animfilename = strcat(self.model, ".animinfo");
 229         animfile = fopen(animfilename, FILE_READ);
 230         if (animfile >= 0)
 231         {
 232                 self.anim_die1         = animparseline(animfile);
 233                 self.anim_die2         = animparseline(animfile);
 234                 self.anim_draw         = animparseline(animfile);
 235                 self.anim_duck         = animparseline(animfile);
 236                 self.anim_duckwalk     = animparseline(animfile);
 237                 self.anim_duckjump     = animparseline(animfile);
 238                 self.anim_duckidle     = animparseline(animfile);
 239                 self.anim_idle         = animparseline(animfile);
 240                 self.anim_jump         = animparseline(animfile);
 241                 self.anim_pain1        = animparseline(animfile);
 242                 self.anim_pain2        = animparseline(animfile);
 243                 self.anim_shoot        = animparseline(animfile);
 244                 self.anim_taunt        = animparseline(animfile);
 245                 self.anim_run          = animparseline(animfile);
 246                 self.anim_runbackwards = animparseline(animfile);
 247                 self.anim_strafeleft   = animparseline(animfile);
 248                 self.anim_straferight  = animparseline(animfile);
 249                 self.anim_forwardright = animparseline(animfile);
 250                 self.anim_forwardleft  = animparseline(animfile);
 251                 self.anim_backright    = animparseline(animfile);
 252                 self.anim_backleft     = animparseline(animfile);
 253                 self.anim_melee        = animparseline(animfile);
 254                 fclose(animfile);
 255
 256                 // derived anims
 257                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 258                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 259
 260                 if (animparseerror)
 261                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 262         }
 263         else
 264                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 265         // reset animstate now
 266         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 267 };
 268
 269 void player_anim (void)
 270 {
 271         updateanim(self);
 272         if (self.weaponentity)
 273                 updateanim(self.weaponentity);
 274
 275         if (self.deadflag != DEAD_NO)
 276         {
 277                 if (time > self.animstate_endtime)
 278                 {
 279                         if (self.maxs_z > 5)
 280                         {
 281                                 self.maxs_z = 5;
 282                                 setsize(self, self.mins, self.maxs);
 283                         }
 284                         self.frame = self.dead_frame;
 285                 }
 286                 return;
 287         }
 288
 289         if (!self.animstate_override)
 290         {
 291                 if (!(self.flags & FL_ONGROUND))
 292                 {
 293                         if (self.crouch)
 294                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 295                         else
 296                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 297                         self.restart_jump = FALSE;
 298                 }
 299                 else if (self.crouch)
 300                 {
 301                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 302                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 305                 }
 306                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 307                 {
 308                         if (self.movement_x > 0 && self.movement_y == 0)
 309                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 310                         else if (self.movement_x < 0 && self.movement_y == 0)
 311                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 312                         else if (self.movement_x == 0 && self.movement_y > 0)
 313                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 314                         else if (self.movement_x == 0 && self.movement_y < 0)
 315                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 316                         else if (self.movement_x > 0 && self.movement_y > 0)
 317                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 318                         else if (self.movement_x > 0 && self.movement_y < 0)
 319                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 320                         else if (self.movement_x < 0 && self.movement_y > 0)
 321                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 322                         else if (self.movement_x < 0 && self.movement_y < 0)
 323                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 324                         else
 325                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 326                 }
 327                 else
 328                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 329         }
 330
 331         if (self.weaponentity)
 332         if (!self.weaponentity.animstate_override)
 333                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 334 }
 335
 336 void SpawnThrownWeapon (vector org, float w)
 337 {
 338         if(g_minstagib)
 339         if(self.ammo_cells <= 0)
 340                 return;
 341
 342         if(g_pinata)
 343         {
 344                 float j;
 345                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 346                 {
 347                         if(self.weapons & W_WeaponBit(j))
 348                                 if(W_IsWeaponThrowable(j))
 349                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 350                 }
 351         }
 352         else
 353         {
 354                 if(W_IsWeaponThrowable(self.weapon))
 355                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 356         }
 357 }
 358
 359 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 360 {
 361         local float take, save;
 362         vector v;
 363         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 364
 365         // damage resistance (ignore most of the damage from a bullet or similar)
 366         damage = max(damage - 5, 1);
 367
 368         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 369         take = v_x;
 370         save = v_y;
 371
 372         if(sound_allowed(MSG_BROADCAST, attacker))
 373         {
 374                 if (save > 10)
 375                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 376                 else if (take > 30)
 377                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 378                 else if (take > 10)
 379                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 380         }
 381
 382         if (take > 50)
 383                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 384         if (take > 100)
 385                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 386
 387         if (!(self.flags & FL_GODMODE))
 388         {
 389                 self.armorvalue = self.armorvalue - save;
 390                 self.health = self.health - take;
 391                 // pause regeneration for 5 seconds
 392                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 393         }
 394         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 395         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 396         self.dmg_inflictor = inflictor;
 397
 398         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 399         {
 400                 // don't use any animations as a gib
 401                 self.frame = 0;
 402                 self.dead_frame = 0;
 403                 // view just above the floor
 404                 self.view_ofs = '0 0 4';
 405
 406                 Violence_GibSplash(self, 1, 1, attacker);
 407                 self.modelindex = 0; // restore later
 408                 self.solid = SOLID_NOT; // restore later
 409                 self.takedamage = DAMAGE_NO; // restore later
 410         }
 411 }
 412
 413 void ClientKill_Now_TeamChange();
 414 void freezetag_CheckWinner();
 415
 416 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 417 {
 418         local float take, save, waves, sdelay, dh, da, j;
 419         vector v;
 420         float valid_damage_for_weaponstats;
 421         float excess;
 422
 423         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 424                 return;
 425
 426         dh = max(self.health, 0);
 427         da = max(self.armorvalue, 0);
 428
 429         if(!DEATH_ISSPECIAL(deathtype))
 430         {
 431                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 432                 if(self != attacker)
 433                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 434         }
 435
 436         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 437         {
 438                 // tuba causes blood to come out of the ears
 439                 vector ear1, ear2;
 440                 vector d;
 441                 float f;
 442                 ear1 = self.origin;
 443                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 444                 ear2 = ear1;
 445                 makevectors(self.angles);
 446                 ear1 += v_right * -10;
 447                 ear2 += v_right * +10;
 448                 d = inflictor.origin - self.origin;
 449                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 450                 force = v_right * vlen(force);
 451                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 452                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 453                 if(f > 0)
 454                 {
 455                         hitloc = ear1;
 456                         force = force * -1;
 457                 }
 458                 else
 459                 {
 460                         hitloc = ear2;
 461                         // force is already good
 462                 }
 463         }
 464         else
 465                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 466
 467         if (!g_minstagib)
 468         {
 469                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 470                 take = v_x;
 471                 save = v_y;
 472         }
 473         else
 474         {
 475                 save = 0;
 476                 take = damage;
 477         }
 478
 479         frag_inflictor = inflictor;
 480         frag_attacker = attacker;
 481         frag_target = self;
 482         damage_take = take;
 483         damage_save = save;
 484         damage_force = force;
 485         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 486         take = bound(0, damage_take, self.health);
 487         save = bound(0, damage_save, self.armorvalue);
 488         excess = max(0, damage - take - save);
 489
 490         if(sound_allowed(MSG_BROADCAST, attacker))
 491         {
 492                 if (save > 10)
 493                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 494                 else if (take > 30)
 495                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 496                 else if (take > 10)
 497                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 498         }
 499
 500         if (take > 50)
 501                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 502         if (take > 100)
 503                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 504
 505         if (time >= self.spawnshieldtime)
 506         {
 507                 if (!(self.flags & FL_GODMODE))
 508                 {
 509                         self.armorvalue = self.armorvalue - save;
 510                         self.health = self.health - take;
 511                         // pause regeneration for 5 seconds
 512                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 513
 514                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 515                         {
 516                                 self.pain_finished = time + 0.5;        //Supajoe
 517
 518                                 if(sv_gentle < 1) {
 519                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 520                                         {
 521                                                 if (random() > 0.5)
 522                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 523                                                 else
 524                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 525                                         }
 526
 527                                         if(sound_allowed(MSG_BROADCAST, attacker))
 528                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 529                                         if(self.health > 1)
 530                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 531                                         {
 532                                                 if(deathtype == DEATH_FALL)
 533                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 534                                                 else if(self.health > 75) // TODO make a "gentle" version?
 535                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 536                                                 else if(self.health > 50)
 537                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 538                                                 else if(self.health > 25)
 539                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 540                                                 else
 541                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 542                                         }
 543                                 }
 544
 545                                 // throw off bot aim temporarily
 546                                 local float shake;
 547                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 548                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 549                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 550                         }
 551                 }
 552                 else
 553                         self.max_armorvalue += (save + take);
 554         }
 555         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 556         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 557         self.dmg_inflictor = inflictor;
 558
 559         if(attacker == self)
 560         {
 561                 // don't reset pushltime for self damage as it may be an attempt to
 562                 // escape a lava pit or similar
 563                 //self.pushltime = 0;
 564         }
 565         else if(attacker.classname == "player")
 566         {
 567                 self.pusher = attacker;
 568                 self.pushltime = time + autocvar_g_maxpushtime;
 569         }
 570         else if(time < self.pushltime)
 571         {
 572                 attacker = self.pusher;
 573                 self.pushltime = max(self.pushltime, time + 0.6);
 574         }
 575         else
 576                 self.pushltime = 0;
 577
 578         float abot, vbot, awep;
 579         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 580         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 581
 582         valid_damage_for_weaponstats = 0;
 583         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 584         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 585         if(attacker && self != attacker)
 586         if(IsDifferentTeam(self, attacker))
 587         {
 588                 if(DEATH_ISSPECIAL(deathtype))
 589                         awep = attacker.weapon;
 590                 else
 591                         awep = DEATH_WEAPONOF(deathtype);
 592                 valid_damage_for_weaponstats = 1;
 593         }
 594
 595         if(valid_damage_for_weaponstats)
 596         {
 597                 dh = dh - max(self.health, 0);
 598                 da = da - max(self.armorvalue, 0);
 599                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 600         }
 601
 602         if (self.health < 1)
 603         {
 604                 float defer_ClientKill_Now_TeamChange;
 605                 defer_ClientKill_Now_TeamChange = FALSE;
 606
 607                 if(self.alivetime)
 608                 {
 609                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 610                         self.alivetime = 0;
 611                 }
 612
 613                 if(valid_damage_for_weaponstats)
 614                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 615
 616                 if(sv_gentle < 1) // TODO make a "gentle" version?
 617                 if(sound_allowed(MSG_BROADCAST, attacker))
 618                 {
 619                         if(deathtype == DEATH_DROWN)
 620                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 621                         else
 622                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 623                 }
 624
 625                 // get rid of kill indicator
 626                 if(self.killindicator)
 627                 {
 628                         remove(self.killindicator);
 629                         self.killindicator = world;
 630                         if(self.killindicator_teamchange)
 631                                 defer_ClientKill_Now_TeamChange = TRUE;
 632
 633                         if(self.classname == "body")
 634                         if(deathtype == DEATH_KILL)
 635                         {
 636                                 // for the lemmings fans, a small harmless explosion
 637                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 638                         }
 639                 }
 640
 641                 if(!g_freezetag)
 642                 {
 643                         // become fully visible
 644                         self.alpha = 1;
 645                         // throw a weapon
 646                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 647                 }
 648
 649                 // print an obituary message
 650                 Obituary (attacker, inflictor, self, deathtype);
 651                 race_PreDie();
 652                 DropAllRunes(self);
 653
 654         // increment frag counter for used weapon type
 655         float w;
 656         w = DEATH_WEAPONOF(deathtype);
 657         if(WEP_VALID(w))
 658         if(self.classname == "player")
 659         if(self != attacker)
 660         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 661
 662                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 663                 {
 664                         PutClientInServer();
 665                         count_alive_players(); // re-count players
 666                         freezetag_CheckWinner();
 667                         return;
 668                 }
 669
 670                 frag_attacker = attacker;
 671                 frag_inflictor = inflictor;
 672                 frag_target = self;
 673                 MUTATOR_CALLHOOK(PlayerDies);
 674                 weapon_action(self.weapon, WR_PLAYERDEATH);
 675
 676                 if(self.flagcarried)
 677                 {
 678                         if(attacker.classname != "player")
 679                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 680                         else if(attacker.team == self.team)
 681                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 682                         else
 683                                 DropFlag(self.flagcarried, world, attacker);
 684                 }
 685                 if(self.ballcarried && g_nexball)
 686                         DropBall(self.ballcarried, self.origin, self.velocity);
 687                 Portal_ClearAllLater(self);
 688
 689                 if(clienttype(self) == CLIENTTYPE_REAL)
 690                 {
 691                         stuffcmd(self, "-zoom\n");
 692                         self.fixangle = TRUE;
 693                         //msg_entity = self;
 694                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 695                         //WriteAngle (MSG_ONE, self.v_angle_x);
 696                         //WriteAngle (MSG_ONE, self.v_angle_y);
 697                         //WriteAngle (MSG_ONE, 80);
 698                 }
 699
 700                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 701                         ClientKill_Now_TeamChange();
 702
 703                 if(g_arena)
 704                         Spawnqueue_Unmark(self);
 705
 706                 if(g_freezetag)
 707                         return;
 708
 709                 // when we get here, player actually dies
 710                 // clear waypoints (do this AFTER FreezeTag)
 711                 WaypointSprite_PlayerDead();
 712
 713                 // make the corpse upright (not tilted)
 714                 self.angles_x = 0;
 715                 self.angles_z = 0;
 716                 // don't spin
 717                 self.avelocity = '0 0 0';
 718                 // view from the floor
 719                 self.view_ofs = '0 0 -8';
 720                 // toss the corpse
 721                 self.movetype = MOVETYPE_TOSS;
 722                 // shootable corpse
 723                 self.solid = SOLID_CORPSE;
 724                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 725                 // don't stick to the floor
 726                 self.flags &~= FL_ONGROUND;
 727                 // dying animation
 728                 self.deadflag = DEAD_DYING;
 729                 // when to allow respawn
 730                 sdelay = 0;
 731                 waves = 0;
 732                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 733                 if(!sdelay)
 734                 {
 735                         if(g_cts)
 736                                 sdelay = 0; // no respawn delay in CTS
 737                         else
 738                                 sdelay = autocvar_g_respawn_delay;
 739                 }
 740                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 741                 if(!waves)
 742                         waves = autocvar_g_respawn_waves;
 743                 if(waves)
 744                         self.death_time = ceil((time + sdelay) / waves) * waves;
 745                 else
 746                         self.death_time = time + sdelay;
 747                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 748                         self.respawn_countdown = 10; // first number to count down from is 10
 749                 else
 750                         self.respawn_countdown = -1; // do not count down
 751                 if (random() < 0.5)
 752                 {
 753                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 754                         self.dead_frame = self.anim_dead1_x;
 755                 }
 756                 else
 757                 {
 758                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 759                         self.dead_frame = self.anim_dead2_x;
 760                 }
 761                 // set damage function to corpse damage
 762                 self.event_damage = PlayerCorpseDamage;
 763                 // call the corpse damage function just in case it wants to gib
 764                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 765                 // set up to fade out later
 766                 SUB_SetFade (self, time + 6 + random (), 1);
 767
 768                 if(sv_gentle > 0 || autocvar_ekg) {
 769                         // remove corpse
 770                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 771                 }
 772
 773                 // reset fields the weapons may use just in case
 774                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 775                 {
 776                         weapon_action(j, WR_RESETPLAYER);
 777                         ATTACK_FINISHED_FOR(self, j) = 0;
 778                 }
 779         }
 780 }
 781
 782 .float muted; // to be used by prvm_edictset server playernumber muted 1
 783 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 784 // message "": do not say, just test flood control
 785 // return value:
 786 //   1 = accept
 787 //   0 = reject
 788 //  -1 = fake accept
 789 {
 790         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 791         float flood, privatemsgprefixlen;
 792         var .float flood_field;
 793         entity head;
 794         float ret;
 795
 796         if(Ban_MaybeEnforceBan(source))
 797                 return 0;
 798
 799         if(!teamsay && !privatesay)
 800                 if(substring(msgin, 0, 1) == " ")
 801                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 802
 803         msgin = formatmessage(msgin);
 804
 805         if(source.classname != "player")
 806                 colorstr = "^0"; // black for spectators
 807         else if(teamplay)
 808                 colorstr = Team_ColorCode(source.team);
 809         else
 810                 teamsay = FALSE;
 811
 812         if(intermission_running)
 813                 teamsay = FALSE;
 814
 815         if(msgin != "")
 816                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 817
 818         /*
 819          * using bprint solves this... me stupid
 820         // how can we prevent the message from appearing in a listen server?
 821         // for now, just give "say" back and only handle say_team
 822         if(!teamsay)
 823         {
 824                 clientcommand(self, strcat("say ", msgin));
 825                 return;
 826         }
 827         */
 828
 829         if(autocvar_g_chat_teamcolors)
 830                 namestr = playername(source);
 831         else
 832                 namestr = source.netname;
 833
 834         if(msgin != "")
 835         {
 836                 if(privatesay)
 837                 {
 838                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 839                         privatemsgprefixlen = strlen(msgstr);
 840                         msgstr = strcat(msgstr, msgin);
 841                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 842                         if(autocvar_g_chat_teamcolors)
 843                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 844                         else
 845                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 846                 }
 847                 else if(teamsay)
 848                 {
 849                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 850                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 851                 }
 852                 else
 853                 {
 854                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 855                         cmsgstr = "";
 856                 }
 857                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 858         }
 859         else
 860         {
 861                 msgstr = cmsgstr = "";
 862         }
 863
 864         fullmsgstr = msgstr;
 865         fullcmsgstr = cmsgstr;
 866
 867         // FLOOD CONTROL
 868         flood = 0;
 869         if(floodcontrol)
 870         {
 871                 float flood_spl;
 872                 float flood_burst;
 873                 float flood_lmax;
 874                 float lines;
 875                 if(privatesay)
 876                 {
 877                         flood_spl = autocvar_g_chat_flood_spl_tell;
 878                         flood_burst = autocvar_g_chat_flood_burst_tell;
 879                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 880                         flood_field = floodcontrol_chattell;
 881                 }
 882                 else if(teamsay)
 883                 {
 884                         flood_spl = autocvar_g_chat_flood_spl_team;
 885                         flood_burst = autocvar_g_chat_flood_burst_team;
 886                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 887                         flood_field = floodcontrol_chatteam;
 888                 }
 889                 else
 890                 {
 891                         flood_spl = autocvar_g_chat_flood_spl;
 892                         flood_burst = autocvar_g_chat_flood_burst;
 893                         flood_lmax = autocvar_g_chat_flood_lmax;
 894                         flood_field = floodcontrol_chat;
 895                 }
 896                 flood_burst = max(0, flood_burst - 1);
 897                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 898
 899                 // do flood control for the default line size
 900                 if(msgstr != "")
 901                 {
 902                         getWrappedLine_remaining = msgstr;
 903                         msgstr = "";
 904                         lines = 0;
 905                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 906                         {
 907                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 908                                 ++lines;
 909                         }
 910                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 911
 912                         if(getWrappedLine_remaining != "")
 913                         {
 914                                 msgstr = strcat(msgstr, "\n");
 915                                 flood = 2;
 916                         }
 917
 918                         if(time >= source.flood_field)
 919                         {
 920                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 921                         }
 922                         else
 923                         {
 924                                 flood = 1;
 925                                 msgstr = fullmsgstr;
 926                         }
 927                 }
 928                 else
 929                 {
 930                         if(time >= source.flood_field)
 931                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 932                         else
 933                                 flood = 1;
 934                 }
 935
 936                 if (timeoutStatus == 2) //when game is paused, no flood protection
 937                         source.flood_field = flood = 0;
 938         }
 939
 940         if(flood == 2) // cannot happen for empty msgstr
 941         {
 942                 if(autocvar_g_chat_flood_notify_flooder)
 943                 {
 944                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 945                         sourcecmsgstr = "";
 946                 }
 947                 else
 948                 {
 949                         sourcemsgstr = fullmsgstr;
 950                         sourcecmsgstr = fullcmsgstr;
 951                 }
 952                 cmsgstr = "";
 953         }
 954         else
 955         {
 956                 sourcemsgstr = msgstr;
 957                 sourcecmsgstr = cmsgstr;
 958         }
 959
 960         if(!privatesay)
 961         if(source.classname != "player")
 962         {
 963                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 964                         teamsay = -1; // spectators
 965         }
 966
 967         if(flood)
 968                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 969
 970         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 971         if(privatesay)
 972                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 973
 974         if(source.muted)
 975         {
 976                 // always fake the message
 977                 ret = -1;
 978         }
 979         else if(flood == 1)
 980         {
 981                 if(autocvar_g_chat_flood_notify_flooder)
 982                 {
 983                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 984                         ret = 0;
 985                 }
 986                 else
 987                         ret = -1;
 988         }
 989         else
 990         {
 991                 ret = 1;
 992         }
 993
 994         if(sourcemsgstr != "" && ret != 0)
 995         {
 996                 if(ret < 0) // fake
 997                 {
 998                         sprint(source, sourcemsgstr);
 999                         if(sourcecmsgstr != "" && !privatesay)
1000                                 centerprint(source, sourcecmsgstr);
1001                 }
1002                 else if(privatesay)
1003                 {
1004                         sprint(source, sourcemsgstr);
1005                         sprint(privatesay, msgstr);
1006                         if(cmsgstr != "")
1007                                 centerprint(privatesay, cmsgstr);
1008                 }
1009                 else if(teamsay > 0)
1010                 {
1011                         sprint(source, sourcemsgstr);
1012                         if(sourcecmsgstr != "")
1013                                 centerprint(source, sourcecmsgstr);
1014                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1015                                 if(head != source)
1016                                 {
1017                                         sprint(head, msgstr);
1018                                         if(cmsgstr != "")
1019                                                 centerprint(head, cmsgstr);
1020                                 }
1021                 }
1022                 else if(teamsay < 0)
1023                 {
1024                         sprint(source, sourcemsgstr);
1025                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1026                                 if(head != source)
1027                                         sprint(head, msgstr);
1028                 }
1029                 else if(sourcemsgstr != msgstr)
1030                 {
1031                         sprint(source, sourcemsgstr);
1032                         FOR_EACH_REALCLIENT(head)
1033                                 if(head != source)
1034                                         sprint(head, msgstr);
1035                 }
1036                 else
1037                         bprint(msgstr);
1038         }
1039
1040         return ret;
1041 }
1042
1043 float GetVoiceMessageVoiceType(string type)
1044 {
1045         if(type == "taunt")
1046                 return VOICETYPE_TAUNT;
1047         if(type == "teamshoot")
1048                 return VOICETYPE_LASTATTACKER;
1049         return VOICETYPE_TEAMRADIO;
1050 }
1051
1052 string allvoicesamples;
1053 .string GetVoiceMessageSampleField(string type)
1054 {
1055         GetPlayerSoundSampleField_notFound = 0;
1056         switch(type)
1057         {
1058 #define _VOICEMSG(m) case #m: return playersound_##m;
1059                 ALLVOICEMSGS
1060 #undef _VOICEMSG
1061         }
1062         GetPlayerSoundSampleField_notFound = 1;
1063         return playersound_taunt;
1064 }
1065
1066 .string GetPlayerSoundSampleField(string type)
1067 {
1068         GetPlayerSoundSampleField_notFound = 0;
1069         switch(type)
1070         {
1071 #define _VOICEMSG(m) case #m: return playersound_##m;
1072                 ALLPLAYERSOUNDS
1073 #undef _VOICEMSG
1074         }
1075         GetPlayerSoundSampleField_notFound = 1;
1076         return playersound_taunt;
1077 }
1078
1079 void PrecacheGlobalSound(string samplestring)
1080 {
1081         float n, i;
1082         tokenize_console(samplestring);
1083         n = stof(argv(1));
1084         if(n > 0)
1085         {
1086                 for(i = 1; i <= n; ++i)
1087                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1088         }
1089         else
1090         {
1091                 precache_sound(strcat(argv(0), ".wav"));
1092         }
1093 }
1094
1095 void PrecachePlayerSounds(string f)
1096 {
1097         float fh;
1098         string s;
1099         fh = fopen(f, FILE_READ);
1100         if(fh < 0)
1101                 return;
1102         while((s = fgets(fh)))
1103         {
1104                 if(tokenize_console(s) != 3)
1105                 {
1106                         dprint("Invalid sound info line: ", s, "\n");
1107                         continue;
1108                 }
1109                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1110         }
1111         fclose(fh);
1112
1113         if not(allvoicesamples)
1114         {
1115 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1116                 ALLVOICEMSGS
1117 #undef _VOICEMSG
1118                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1119         }
1120 }
1121
1122 void ClearPlayerSounds()
1123 {
1124 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1125         ALLPLAYERSOUNDS
1126         ALLVOICEMSGS
1127 #undef _VOICEMSG
1128 }
1129
1130 float LoadPlayerSounds(string f, float first)
1131 {
1132         float fh;
1133         string s;
1134         var .string field;
1135         fh = fopen(f, FILE_READ);
1136         if(fh < 0)
1137         {
1138                 dprint("Player sound file not found: ", f, "\n");
1139                 return 0;
1140         }
1141         while((s = fgets(fh)))
1142         {
1143                 if(tokenize_console(s) != 3)
1144                         continue;
1145                 field = GetPlayerSoundSampleField(argv(0));
1146                 if(GetPlayerSoundSampleField_notFound)
1147                         field = GetVoiceMessageSampleField(argv(0));
1148                 if(GetPlayerSoundSampleField_notFound)
1149                         continue;
1150                 if(self.field)
1151                         strunzone(self.field);
1152                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1153         }
1154         fclose(fh);
1155         return 1;
1156 }
1157
1158 .float modelindex_for_playersound;
1159 .float skinindex_for_playersound;
1160 void UpdatePlayerSounds()
1161 {
1162         if(self.modelindex == self.modelindex_for_playersound)
1163         if(self.skinindex == self.skinindex_for_playersound)
1164                 return;
1165         self.modelindex_for_playersound = self.modelindex;
1166         self.skinindex_for_playersound = self.skinindex;
1167         ClearPlayerSounds();
1168         LoadPlayerSounds("sound/player/default.sounds", 1);
1169         if(!autocvar_g_debug_defaultsounds)
1170                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1171                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1172 }
1173
1174 void FakeGlobalSound(string sample, float chan, float voicetype)
1175 {
1176         float n;
1177         float tauntrand;
1178
1179         if(sample == "")
1180                 return;
1181
1182         tokenize_console(sample);
1183         n = stof(argv(1));
1184         if(n > 0)
1185                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1186         else
1187                 sample = strcat(argv(0), ".wav"); // randomization
1188
1189         switch(voicetype)
1190         {
1191                 case VOICETYPE_LASTATTACKER_ONLY:
1192                         break;
1193                 case VOICETYPE_LASTATTACKER:
1194                         if(self.pusher)
1195                         {
1196                                 msg_entity = self;
1197                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1198                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1199                         }
1200                         break;
1201                 case VOICETYPE_TEAMRADIO:
1202                         msg_entity = self;
1203                         if(msg_entity.cvar_cl_voice_directional == 1)
1204                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1205                         else
1206                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1207                         break;
1208                 case VOICETYPE_AUTOTAUNT:
1209                         if(!sv_autotaunt)
1210                                 break;
1211                         if(!sv_taunt)
1212                                 break;
1213                         if(sv_gentle)
1214                                 break;
1215                         tauntrand = random();
1216                         msg_entity = self;
1217                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1218                         {
1219                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1220                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1221                                 else
1222                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1223                         }
1224                         break;
1225                 case VOICETYPE_TAUNT:
1226                         if(self.classname == "player")
1227                                 if(self.deadflag == DEAD_NO)
1228                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1229                         if(!sv_taunt)
1230                                 break;
1231                         if(sv_gentle)
1232                                 break;
1233                         msg_entity = self;
1234                         if (msg_entity.cvar_cl_voice_directional >= 1)
1235                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1236                         else
1237                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1238                         break;
1239                 case VOICETYPE_PLAYERSOUND:
1240                         msg_entity = self;
1241                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1242                         break;
1243                 default:
1244                         backtrace("Invalid voice type!");
1245                         break;
1246         }
1247 }
1248
1249 void GlobalSound(string sample, float chan, float voicetype)
1250 {
1251         float n;
1252         float tauntrand;
1253
1254         if(sample == "")
1255                 return;
1256
1257         tokenize_console(sample);
1258         n = stof(argv(1));
1259         if(n > 0)
1260                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1261         else
1262                 sample = strcat(argv(0), ".wav"); // randomization
1263
1264         switch(voicetype)
1265         {
1266                 case VOICETYPE_LASTATTACKER_ONLY:
1267                         if(self.pusher)
1268                         {
1269                                 msg_entity = self.pusher;
1270                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1271                                 {
1272                                         if(msg_entity.cvar_cl_voice_directional == 1)
1273                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1274                                         else
1275                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1276                                 }
1277                         }
1278                         break;
1279                 case VOICETYPE_LASTATTACKER:
1280                         if(self.pusher)
1281                         {
1282                                 msg_entity = self.pusher;
1283                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1284                                 {
1285                                         if(msg_entity.cvar_cl_voice_directional == 1)
1286                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1287                                         else
1288                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1289                                 }
1290                                 msg_entity = self;
1291                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1292                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1293                         }
1294                         break;
1295                 case VOICETYPE_TEAMRADIO:
1296                         FOR_EACH_REALCLIENT(msg_entity)
1297                                 if(!teamplay || msg_entity.team == self.team)
1298                                 {
1299                                         if(msg_entity.cvar_cl_voice_directional == 1)
1300                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1301                                         else
1302                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1303                                 }
1304                         break;
1305                 case VOICETYPE_AUTOTAUNT:
1306                         if(!sv_autotaunt)
1307                                 break;
1308                         if(!sv_taunt)
1309                                 break;
1310                         if(sv_gentle)
1311                                 break;
1312                         tauntrand = random();
1313                         FOR_EACH_REALCLIENT(msg_entity)
1314                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1315                                 {
1316                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1317                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1318                                         else
1319                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1320                                 }
1321                         break;
1322                 case VOICETYPE_TAUNT:
1323                         if(self.classname == "player")
1324                                 if(self.deadflag == DEAD_NO)
1325                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1326                         if(!sv_taunt)
1327                                 break;
1328                         if(sv_gentle)
1329                                 break;
1330                         FOR_EACH_REALCLIENT(msg_entity)
1331                         {
1332                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1333                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1334                                 else
1335                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1336                         }
1337                         break;
1338                 case VOICETYPE_PLAYERSOUND:
1339                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1340                         break;
1341                 default:
1342                         backtrace("Invalid voice type!");
1343                         break;
1344         }
1345 }
1346
1347 void PlayerSound(.string samplefield, float chan, float voicetype)
1348 {
1349         GlobalSound(self.samplefield, chan, voicetype);
1350 }
1351
1352 void VoiceMessage(string type, string msg)
1353 {
1354         var .string sample;
1355         float voicetype, ownteam;
1356         float flood;
1357         sample = GetVoiceMessageSampleField(type);
1358
1359         if(GetPlayerSoundSampleField_notFound)
1360         {
1361                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1362                 return;
1363         }
1364
1365         voicetype = GetVoiceMessageVoiceType(type);
1366         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1367
1368         flood = Say(self, ownteam, world, msg, 1);
1369
1370         if (flood > 0)
1371                 GlobalSound(self.sample, CH_VOICE, voicetype);
1372         else if (flood < 0)
1373                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1374 }
1375
1376 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1377 {
1378 //      show_message
1379 //      0 (00) automove centerprint, admin message
1380 //      1 (01) automove centerprint, no admin message
1381 //      2 (10) no centerprint, admin message
1382 //      3 (11) no centerprint, no admin message
1383
1384         float lockteams_backup;
1385
1386         lockteams_backup = lockteams;  // backup any team lock
1387
1388         lockteams = 0;  // disable locked teams
1389
1390         TeamchangeFrags(client);  // move the players frags
1391         SetPlayerColors(client, team_colour - 1);  // set the players colour
1392         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1393
1394         lockteams = lockteams_backup;  // restore the team lock
1395
1396         LogTeamchange(client.playerid, client.team, type);
1397
1398         if not(show_message & 1) // admin message
1399                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1400
1401         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1402 }